IMDPRPJB START                                                          00100021
         TITLE 'IMDPRPJB - PRINT BY JOBNAME'                            00200021
*********************************************************************** 00300021
*                                                                     * 00400021
*             ***  IMDPRPJB - PRINT JOBNAME EXECUTOR  ***             * 00500021
*                                                                     * 00600021
* STATUS -- OS/360 RELEASE 21.0                                       * 00700021
*                                                                     * 00800021
* FUNCTION --                                                         * 00900021
*                                                                     * 01000021
*         THIS MODULE SCANS THE JOBNAMES IN THE 'PRINT JOBNAME'       * 01100021
*    CONTROL STATEMENT PARAMETER AND FILLS IN THE JOBNAME TABLE IN THE* 01200021
*    COMMON CSECT IMDPRCOM.  IF THE 'JOBNAME' PARAMETER IS CORRECT,   * 01300021
*    IMDPRPJB PROCESSING CONTINUES WITH FINDING THE REGION BOUNDARIES * 01400021
*    FOR THE JOBS IN THE JOBNAME TABLE.  THIS IS DONE BY FIRST CALLING* 01500021
*    THE ALL REGIONS ROUTINE, IMDPRFUR, TO CAUSE THE JSTCB ADDRESS OF * 01600021
*    EACH TASK IN THE DUMP SYSTEM TO BE ENQUEUED ON THE TCB LIST.     * 01700021
*    EACH ENTRY IN THE JOBNAME TABLE IS COMPARED AGAINST THE TASK I/O * 01800021
*    TABLE FOR EACH JSTCB ON THE TCB LIST.  IF A MATCH IS FOUND AND   * 01900021
*    THE REGION WAS NOT ROLLED OUT WHEN THE DUMP WAS WRITTEN, THE TCB * 02000021
*    REMAINS ON TCB LIST.  IF A MATCH IS NOT FOUND FOR A PARTICULAR   * 02100021
*    TCB, THE TCB ADDRESS IS DEQUEUED FROM THE TCB LIST.  AFTER ALL   * 02200021
*    THE THE TCBS HAVE BEEN PROCESSED IF A MATCH IS NOT FOUND IN ANY  * 02300021
*    OF THE TASK I/O TABLES, AN ERROR MESSAGE IS PRODUCED AND THE NEXT* 02400021
*    JOBNAME IN THE TABLE IS PROCESSED.                               * 02500021
*         THOSE TCB'S REMAINING AFTER ALL THE TCBS ON THE TCB LIST    * 02600021
*    HAVE BEEN PROCESSED, ARE USED AS INPUT TO THE SERVICE MODULES -  * 02700021
*    IMDPRFUR, IMDPRFUB, IMDPRFSR, AND IMDPRDPS.  THESE MODULES ARE   * 02800021
*    USED TO PROCESS THE TCBS, DETERMINE THE REGION BOUNDARIES, FORMAT* 02900021
*    THE CONTROL BLOCKS, AND PRINT THE STORAGE ASSOCIATED WITH EACH   * 03000021
*    REGION.                                                          * 03100021
*                                                                     * 03200021
* ENTRY POINTS --                                                     * 03300021
*                                                                     * 03400021
*         IMDPRPJB IS THE MAIN AND ONLY ENTRY POINT.  THIS MODULE     * 03500021
*    RECEIVES CONTROL FROM THE MODULE IMDPRCTL WHEN THE JOBNAME IN THE* 03600021
*    'PRINT JOBNAME' CONTROL STATEMENT IS ENCOUNTERED.                * 03700021
*                                                                     * 03800021
* INPUT --                                                            * 03900021
*                                                                     * 04000021
*         THE COMMON CSECT, IMDPRCOM, WHICH CONTAINS VALUES OF        * 04100021
*    SWITCHES, CONSTANTS. AND TRT TABLES.  SPECIFICALLY, THE DELIMITER* 04200021
*    CODE OF THE FIRST DELIMITER THIS ROUTINE WILL PROCESS (DELIMCD), * 04300021
*    AND THE BEGINNING (KYWDBGN) AND ENDING (KYWDEND) ADDRESSES OF THE* 04400021
*    KEYWORD.                                                         * 04500021
*                                                                     * 04600021
* OUTPUT --                                                           * 04700021
*                                                                     * 04800021
*         THE CONTROL BLOCKS AND THE STORAGE ALLOCATED TO THE TASK    * 04900021
*    SPECIFIED IN THE 'JOBNAME' KEYWORD IF THE JOB IS FOUND.  IF THE  * 05000021
*    JOB IS NOT FOUND, A DIAGNOSTIC MESSAGE, IMD162I, IS PRINTED.     * 05100021
*                                                                     * 05200021
* EXTERNAL REFERENCES --                                              * 05300021
*                                                                     * 05400021
*         1.  BRREAD - TO READ THE JOBNAMES IN THE TASK I/O TABLES AND* 05500021
*                      THE TCB FIELDS                                 * 05600021
*                                                                     * 05700021
*         2.  BRWRITE - TO SKIP VARIOUS AMOUNTS FOR SPACING OF OUTPUT,* 05800021
*                        AND TO WRITE TO THE 'PRINTER' DATA SET.      * 05900021
*                                                                     * 06000021
*         3.  BRPRTMSG - TO WRITE MESSAGES TO THE SYSPRINT DATA SET.  * 06100021
*                                                                     * 06200021
*         4.  IMDPRFUR - TO ENQUEUE ALL TCBS IN THE DUMP SYSTEM INTO  * 06300021
*                        THE TCB LIST.                                * 06400021
*                                                                     * 06500021
*         5.  IMDPRFUB - TO DETERMINE THE REGION BOUNDARIES OF THE    * 06600021
*                        TCBS REMAINING ON THE TCB LIST, FOR PRINTING.* 06700021
*                                                                     * 06800021
*         6.  IMDPRESR - TO FORMAT THE CONTROL BLOCKS.                * 06900021
*                                                                     * 07000021
*         7.  IMDPRDPS - TO FORMAT AND PRINT AREAS OF MAIN STORAGE    * 07100021
*             THAT ARE ENQUEUED ON THE PRINT CONTROL BLOCKS QUEUE.    * 07200021
*                                                                     * 07300021
*         OS/360 SERVICES                                             * 07400021
*                                                                     * 07500021
*         1.  WTO - TO WRITE MESSAGES TO THE OPERATORS CONSOLE IN THE * 07600021
*                   CASE THAT THE CONTROL CARDS ARE NOT BEING READ IN,* 07700021
*                   OR THAT A PARTICULAR JOB WAS NOT FOUND.           * 07800021
*                                                                     * 07900021
* EXITS,NORMAL --                                                     * 08000021
*                                                                     * 08100021
*         IMDPRPJB RETURNS TO IMDPRCTL                                * 08200021
*                                                                     * 08300021
* EXITS,ERROR --                                                      * 08400021
*                                                                     * 08500021
*         NONE                                                        * 08600021
*                                                                     * 08700021
* TABLES/WORK AREAS --                                                * 08800021
*                                                                     * 08900021
*         THE COMMON CSECT, IMDPRCOM, WHICH CONTAINS VALUES OF THE    * 09000021
*    DELIMITERS, AND BEGINNING AND ENDING ADDRESSES OF THE KEYWORD.   * 09100021
*                                                                     * 09200021
* ATTRIBUTES -- REUSEABLE                                             * 09300021
*                                                                     * 09400021
* CHARACTER CODE DEPENDENCY -- EBCDIC                                 * 09500021
*                                                                     * 09600021
* NOTES --                                                            * 09700021
*                                                                     * 09800021
*         INTERNAL ERROR RECOVERY ROUTINE                             * 09900021
*                                                                     * 10000021
*         JBPRTER IS THE ENTRY POINT OF AN INTERNAL ERROR ROUTINE USED* 10100021
*    TO RECOVER FROM ERRORS OCCURRING WHEN READING THE JOBNAMES FROM  * 10200021
*    THE TASK I/O TABLE.                                              * 10300021
*                                                                     * 10400021
*********************************************************************** 10500021
         EJECT                                                          10600021
*/*IMDPRPJB: CHART (AMODE,SEQ) */                                       10600521
*/*HEADER                                                               10601021
*/*IMDPRPJB    VALIDATES JOBNAME AND INDICATES RELATED STORAGE          10601521
*/*                                                    PAGE  #  */      10602021
*/*IMDPRPJB: E ENTRY */                                                 10602521
*/*JBBASE: M HOUSE KEEPING AND INITIALIZATIONS */                       10603021
*/*JOBNAME: P SET JOBNAME SWITCH */                                     10603521
*/*  P GET ADDRESS OF SYNTAX ERROR MESSAGE ADDRESSES AND STORE IT */    10604021
*/*  P GET ADDRESS OF SYNTAX ERROR MESSAGE ROUTINE */                   10604521
*/*  P SET RETURN ADDRESS FOR EXIT FROM ERROR MESSAGE ROUTINE */        10605021
*/*  P GET ADDRESS OF 1ST JOB MASK */                                   10605521
*/*  P (,DELHDLR) GET DELIMITER CODE */                                 10606021
*/*  D (O,%L2,1,%L2,2,SCAN,3,%L2,4,%L2,5,%L2) WHAT IS INDEX VALUE? */   10606521
*/*  P (,DELHDLR) GET ADDRESS OF 2ND JOB MASK */                        10607021
*/*  D (0,%L2,1,JOBNAME4,2,%L2,3,JOBNAME4,4,%L8,5,%L2) WHAT IS INDEX    10607521
*/*VALUE? */                                                            10608021
*/*%L8: D (YES,%L5,NO,) IS LEFT PAREN SWITCH ON? */                     10608521
*/*  M TURN LEFT PAREN SWITCH OFF */                                    10609021
*/*JOBNAME1: P (,SCAN) BRANCH TO SCAN */                                10609521
*/*  D (YES,%L3,NO,) IS PARM LENGTH ZERO? */                            10610021
*/*  P (,DELHDLR) GET ADDRESS OF 3RD JOB MASK */                        10610521
*/*  D (0,%L2,1,JOBNAME5,2,%L2,3,%L2,4,%L2,5,) WHAT IS INDEX VALUE */   10611021
*/*  D (YES,,NO,%L5) IS LEFT PAREN SWITCH ON? */                        10611521
*/*  M RESET LEFT PAREN SWITCH */                                       10612021
*/*  P GET ADDRESS OF THE LAST DELIMITER */                             10612521
*/*  P INCREMENT PTR FOR NEXT SCAN AND STORE IT */                      10613021
*/*  D (YES,,NO,%L1) IS THIS A VALID DELIMITER? */                      10613521
*/*  P STORE DELIMITER CODE */                                          10614021
*/*JOBNAME5: D (YES,,NO,%L9) IS PARM LENGTH ZERO? */                    10614521
*/*%L10: P CLEAR INDEX AREA */                                          10615021
*/*  P GET ADDRESS OF THE JOBNAME TABLE */                              10615521
*/*JOBNAME3: D (YES,JOBNAME2,NO,) IS JOBNAME ALREADY USED */            10616021
*/*  P SET JOB VALID BIT FOR THIS JOBNAME */                            10616521
*/*  P GET ADDRESS OF THE JOBNAME */                                    10617021
*/*  P GET ADDRESS OF THE BEGINNING OF THE NAME */                      10617521
*/*  P CLEAR JOBNAME FIELD */                                           10618021
*/*  N MOVE JOBNAME FROM TEMPORARY AREA */                              10618521
*/*  L JOBMOVE   -  MOVE THE JOBNAME */                                 10619021
*/*  D (YES,JOBNAME1,NO,JBNMDN) IS LEFT PAREN SWITCH ON? */             10619521
*/*JOBMOVE: P MOVE MESSAGES INTO WTO AREA */                            10620021
*/*JOBNAME2: D (YES,%L4,N0,) IS THIS END OF JOB TABLE? */               10620521
*/*  P (,JOBNAME3) INCREMENT PTR TO NEXT ADDRESS */                     10621021
*/*JOBNAME4: D (YES,%L3,NO,JOBNAME5) IS PARM LENGTH ZERO? */            10621521
*/*DELHDLR: P CLEAR INDEX AREA */                                       10622021
*/*  P DIVIDE DELIMITER CODE-USE RESULT TO GET INDEX TO BRANCH TABLE */ 10622521
*/*  R RETURN TO CALLER + INDEX */                                      10623021
*/*SCAN: N SCAN MESSAGE BUFFER */                                       10623521
*/*  P GET ADDRESS OF THE LAST DELIMITER */                             10624021
*/*  P COMPUTE AND STORE ADDRESS OF THE NEXT PARAMETER */               10624521
*/*  P MOVE ADDRESS OF THE NEXT PARAMETER TO TEMPORARY AREA */          10625021
*/*  P CLEAR DELIMITER CODE AREA */                                     10625521
*/*  D (YES,,NO,%L6) IS THIS A VALID DELIMITER? */                      10626021
*/*  P STORE ADDRESS OF THE DELIMITER */                                10626521
*/*  P STORE THE DELIMITER CODE */                                      10627021
*/*  P COMPUTE THE LENGTH OF THE DELIMITER */                           10627521
*/*  P PUT LENGTH IN REG 3 */                                           10628021
*/*  R RETURN TO CALLER */                                              10628521
*/*JBNMDN: N JOBNAME ROUTINE-COMPARE JOBNAME IN TIOTS TO TABLE */       10629021
*/*  D (YES,JOBDONE,NO,) IS THIS FLUSH MODE? */                         10629521
*/*  L BRWRITE     -  SKIP A PAGE */                                    10630021
*/*  P GET ADDRESS OF CURRENT OUTPUT BUFFER */                          10630521
*/*  P CHANGE ADDRESSABILITY (BASE REG) */                              10631021
*/*  P MOVE TITLE INTO OUTAREA */                                       10631521
*/*  L BRWRITE     -  WRITE THE TITLE */                                10632021
*/*  M RESET SEQUENCE SWITCH */                                         10632521
*/*  P STORE PREVIOUS ERROR ROUTINE ADDRESS */                          10633021
*/*  P  GET ADDRESS OF ERROR ROUTINE FOR JOBPRINT AND STORE IT */       10633521
*/*  P GET ADDRESS OF ALL REGIONS ROUTINE */                            10634021
*/*  N GET ALL JSTCB'S ON TCB LIST */                                   10634521
*/*  L IMDPRFUR */                                                      10635021
*/*JOBPRNT1: P ZERO TCB COUNTER */                                      10635521
*/*  M SET SEQUENCE SWITCH */                                           10636021
*/*  N THIS SWITCH IS USED ONLY IN THE EVENT OF AN ERROR TO DETERMINE   10636521
*/*WHERE */                                                             10637021
*/*  N IN JOBPRINT TO RETURN CONTROL AFTER WRITING AN ERROR MESSAGE*/   10637521
*/*JOBLOOPA: P GET TCB COUNT */                                         10638021
*/*  P ADD 1 TO COUNT AND STORE IT */                                   10638521
*/*JOBLOOPB: M RESET FIRST TIME SWITCH */                               10639021
*/*  P GET TCB COUNT */                                                 10639521
*/*  P GET ADDRESS OF TCB RETRIEVE ROUTINE */                           10640021
*/*  L IMDPRTSV */                                                      10640521
*/*  D (YES,,NO,JOBPRNT2) WAS THERE ANOTHER TCB? */                     10641021
*/*  P STORE ADDRESS OF JSTCB */                                        10641521
*/*  P GET TCB TIOT PTR ADDRESS */                                      10642021
*/*  L BRREAD GET TIOT PTR */                                           10642521
*/*  P GET TIOT ADDRESS */                                              10643021
*/*  D (YES,,NO,JOBPRNT4) IS THERE A TIOT? */                           10643521
*/*  D (YES,,NO,JOBPRNT4) IS TIOT ADDR VALID? */                        10644021
*/*JOBLOOPD:   L BRREAD       -  GET THE NEXT TIOT */                   10644521
*/*  P CLEAR INDEX AREA */                                              10645021
*/*JOBLOOPC: P GET ADDRESS OF JOBNAME */                                10645521
*/*  P GET NAME MASK TO CHECK JOBVALID BIT */                           10646021
*/*  D (YES,,NO,JOBPRNT8) IS JOBNAME VALID? */                          10646521
*/*  D (YES,JOBFND,NO,) IS IT SAME AS TIOT JOB NAME? */                 10647021
*/*JOBPRNT8: D (YES,JOBPRNT3,NO,) LAST JOBNAME IN LIST? */              10647521
*/*  P (,JOBLOOPC) INCREMENT PTR TO JOBNAME LIST */                     10648021
*/*JOBPRNT3: D (YES,,NO,JOBPRNT4) IS COND CODE ZERO? */                 10648521
*/*  M SET CONDITION CODE TO 15 */                                      10649021
*/*  D (YES,,NO,JOBPRNT4) IS THIS A MVT DUMP? */                        10649521
*/*JOBPRNTF: M SET COUNT TO 2 */                                        10650021
*/*  P GET ADDRESS OF MOTHER PTR */                                     10650521
*/*JOBLOOPG: L BRREAD      -   GET MOTHER TIOT */                       10651021
*/*  P GET MOTHER PTR */                                                10651521
*/*  D (YES,JOBPRNTE,NO,) SAME AS MASTER SCHED ADDR? */                 10652021
*/*  D (YES,,NO,JOBLOOPG) IS COUNT ZERO? */                             10652521
*/*JOBPRNT4: P GET ADDRESS OF TCB REMOVE ROUTINE */                     10653021
*/*  L (,JOBLOOPB) IMDPRPCB */                                          10653521
*/*JOBPRNTE: P (,JOBLOOPD) GET ADDRESS OF STEPNAME IN TIOT */           10654021
*/*JOBFND: P GET ADDRESS OF JOBNAME FROM LIST THAT MATCHES THE TIOT     10654521
*/*JOBNAME */                                                           10655021
*/*  P GET ADDRESS OF FLAG BYTE WHICH CONTAINS ROLLED OUT BIT */        10655521
*/*  L BRREAD       -  GET FLAG BYTE CONTAINING ROLLED OUT BIT */       10656021
*/*  D (YES,JOBFND1,NO,) IS JOB STEP ROLLED OUT? */                     10656521
*/*  M (,JOBLOOPA) TURN THE JOB FOUND BIT ON */                         10657021
*/*JOBFND1: M (,JOBPRNT4) TURN ON JOB ROLLED OUT BIT */                 10657521
*/*JOBPRNT2: P GET ADDRESS OF THE JOBNAME LIST */                       10658021
*/*JOBLOOPE: D (YES,,NO,JOBPRNT5) WAS JOB FOUND? */                     10658521
*/*JOBPRNT7: D (YES,JOBPRNT6,NO,) IS THIS LAST ENTRY ON LIST? */        10659021
*/*  P (,JOBLOOPE) GET NEXT JOBNAME ON LIST */                          10659521
*/*JOBPRNT5: D (YES,,NO,JOBPRNT7) IS JOBNAME VALID? */                  10660021
*/*  D (YES,,NO,JOBPRNTA) IS JOB ROLLED OUT? */                         10660521
*/*  P (,JOBPRNTB) MOVE 'ROLLED OUT' MESSAGE TO WTO AREA */             10661021
*/*JOBPRNTA: P MOVE 'NOT FOUND' MESSAGE TO WTO AREA */                  10661521
*/*JOBPRNTB: P MOVE JOBNAME TO TEMPORARY AREA */                        10662021
*/*  P MOVE JOBNAME TO WTO AREA */                                      10662521
*/*  L BRPRTMSG WRITE JOB NOT FOUND MESSAGE ON SYSPRINT */              10663021
*/*  D (YES,JOBPRNT7,NO,) IS READER SW ON? */                           10663521
*/*JOBWTO: L (,JOBPRNT7) WTO      -  WRITE MESSAGE TO OPERATOR */       10664021
*/*JOBPRNT6: P GET ADDRESS OF JOBNAME LIST */                           10664521
*/*JOBLOOPF: D (YES,JOBPRNTC,NO,) IS THIS THE LAST NAME? */             10665021
*/*  P (,JOBLOOPF) GET THE NEXT JOBNAME */                              10665521
*/*JOBPRNTC: M RESET THE SEQUENCE SWITCH */                             10666021
*/*  P RESTORE ADDRESS FOR RETURN FROM PREVIOUS ERROR MESSAGE ROUTINE   10666521
*/**/                                                                   10667021
*/*  P GET TCBLIST */                                                   10667521
*/*  D (YES,,NO,JOBDONE) ANYTHING TO BE PRINTED? */                     10668021
*/*  L BRWRITE    -  SPACE TWO LINES BEFORE FORMAT */                   10668521
*/*  P ZERO TJID PARAMETER */                                           10669021
*/*  P GET ADDRESS OF FORMAT SERVICE ROUTINE */                         10669521
*/*  L IMDPRFSR */                                                      10670021
*/*  L BRWRITE    - SKIP A PAGE */                                      10670521
*/*  P GET ADDRESS OF REGION BOUNDARY ROUTINE */                        10671021
*/*  L REGION BOUNDARY */                                               10671521
*/*  P GET ADDRESS OF THE PRINT STORAGE ROUTINE */                      10672021
*/*  L IMDPRSTG */                                                      10672521
*/*  L TCBREMV REMOVE ALL TCBS FROM TCBLIST */                          10672921
*/*JOBDONE: M EXIT LINKAGE */                                           10673021
*/*  R END */                                                           10673521
*/*  P CHANGE BASE REGISTER */                                          10674021
*/*JBPRTER: N JOBPRINT ERROR ROUTINE */                                 10674521
*/*  M USE REG 15 AS BASE REGISTER */                                   10675021
*/*  P GET ON PJB'S SAVE AREA */                                        10675521
*/*  P RESTORE REGISTERS TO BEFORE LAST EXIT */                         10676021
*/*  P CHANGE BASE REGISTER */                                          10676521
*/*  P GET ADDRESS OF OUTPUT BUFFER */                                  10677021
*/*  L BRWRITE   -  SKIP A LINE */                                      10677521
*/*  P GET ADDRESS OF WHERE TO MOVE THE MESSAGE */                      10678021
*/*  P GET LENGTH OF THE MESSAGE */                                     10678521
*/*  P DECREMENT THE LENGTH BY 5 */                                     10679021
*/*  P GET ADDRESS OF THE ERROR MESSAGE */                              10679521
*/*  L JOBMOVE  -  MOVE ERROR MESSAGE TO OUTPUT BUFFER */               10680021
*/*  P INCREMENT THE LENGTH  AND SAVE IN REG 3 */                       10680521
*/*  L BRWRITE   -  PRINT ERROR MESSAGE ON DUMP */                      10681021
*/*  P SET THE PARAMETERS FOR THE PRINT ROUTINE */                      10681521
*/*  L BRPRTMSG  - PRINT ERROR MESSAGE ON SYSPRINT */                   10682021
*/*  D (YES,JBPRTER1,NO,) ARE CONTROL CARDS BEING READ? */              10682521
*/*  P GET ADDRESS OF WTO MESSAGE AREA */                               10683021
*/*  L WTO      -   TELL OPERATOR ABOUT ERROR */                        10683521
*/*JBPRTER1: D (YES,,NO,JOBPRNT1) IS SEQUENCE SW ON? */                 10684021
*/*  P (,JOBPRNT4) RESTORE TCB ADDRESS TO REGISTER 2 */                 10684521
*/*%L1: L (,JOBDONE) SYNTAX */                                          10685021
*/*%L2: L (,JOBDONE) SYNTAXA */                                         10685521
*/*%L3: L (,JOBDONE) SYNTAXB */                                         10686021
*/*%L4: L (,JOBDONE) SYNTAXC */                                         10686521
*/*%L5: L (,JOBDONE) SYNTAXD */                                         10687021
*/*%L6: L (,JOBDONE) SYNTAXE */                                         10687521
*/*%L9: P (,%L10) DECREMENT THE PARAMETER LENGTH BY 1 */                10688021
*/*IMDPRPJB:    END */                                                  10688521
         EJECT                                                          10689021
         EQUATES                                                        10700021
         COMMON                                                         10800021
*                                                                 M3179 10900021
         OUTBUFM                                                        11000021
IMDPRPJB CSECT                                                          11100021
         STM   R14,R12,12(R13)     SAVE CALLER'S REGS                   11200021
         BALR  BASE1,0             ESTABLISH REG 11 AS BASE             11300021
         USING *,BASE1                                                  11400021
JBBASE   LA    R2,JOBSAVE          SAVE AREA CHAINING                   11500021
         ST    R13,JOBSAVE+4                                            11600021
         ST    R2,8(R13)                                                11700021
         LR    R13,R2                                                   11800021
         SPACE                                                          11900021
         USING COMMON,COMBASE      REG 12 IS COMMON CSECT POINTER       12000021
         USING SYNEPS,R15                                               12100021
         SPACE                                                          12200021
JOBNAME  OI    SWA,JBNMSW          SET JOBNAME SWITCH                   12300021
         LA    R15,JBNSYNA         ADDR OF SYNTAX ERROR MSG ADDRS       12400021
         ST    R15,SYNMSGA         STORE IT                             12500021
         L     R15,ASYNTAX         POINT TO SYNTAX ERROR MSG WRITER     12600021
         LA    R14,JOBDONE         RETURN FROM SYNTAX ERROR TO EXIT     12700021
         LA    R1,JOBMSK1                                               12800021
         L     R2,DELIMCD                                               12900021
         BAL   R6,DELHDLR          TEST DELIMITER                       13000021
         B     SYNTAXA             ERROR RETURN                         13100021
         BAL   R6,SCAN                                                  13200021
         LA    R1,JOBMSK2                                               13300021
         BAL   R6,DELHDLR          TEST DELIMITER                       13400021
         B     SYNTAXA             ERROR RETURN                         13500021
         B     JOBNAME4            COMMA OR BLANK                       13600021
*                                  RETURN CODE 8 TO INDICATE            13700021
*                                  RIGHT PAREN.                         13800021
         TM    PRSW,LFTPAREN       IS LEFT PAREN SW ALREADY ON          13900021
         BO    SYNTAXD             YES - ERROR                          14000021
         OI    PRSW,LFTPAREN       NO - TURN IT ON                      14100021
JOBNAME1 BAL   R6,SCAN                                                  14200021
         LTR   R3,R3               IS LENGTH ZERO                       14300021
         BZ    SYNTAXB             YES--ERROR                           14400021
         LA    R1,JOBMSK3                                               14500021
         BAL   R6,DELHDLR                                               14600021
         B     SYNTAXA             ERROR RETURN                         14700021
         B     JOBNAME5            COMMA                                14800021
*                                  RETURN CODE 8 TO INDICATE            14900021
*                                  RIGHT PAREN.                         15000021
         TM    PRSW,LFTPAREN       IS LEFT PAREN SW ON                  15100021
         BZ    SYNTAXD             NO - ERROR                           15200021
         NI    PRSW,255-LFTPAREN   RESET LEFT PAREN SWITCH              15300021
         L     R1,KYWDEND          ADDR RIGHT PAREN                     15400021
         LA    R1,1(R1)                                                 15500021
         ST    R1,KYWDEND                                               15600021
         TRT   0(2,R1),BLNK        SCAN FOR NEXT DELIMITER              15700021
         BZ    SYNTAX                                                   15800021
         ST    R2,DELIMCD                                               15900021
JOBNAME5 BCTR  R3,0                DECR LNGH FOR EXECUTE                16000021
         SR    R5,R5               CLEAR INDEX                          16100021
         LA    R7,JBNAMEA          JOBNAME ADDR TABLE                   16200021
JOBNAME3 TM    0(R7),JOBVALID      IS IT ALREADY USED                   16300021
         BO    JOBNAME2            YES--LEAVE IT                        16400021
         OI    0(R7),JOBVALID      SET JOB VALID BIT FOR THIS JOBNAME   16500021
*                                  ENTRY                                16600021
         L     R7,0(R7)            NO--LOAD ADDR OF NAME                16700021
         L     R2,KYWDBGN          ADDR OF BEGINNING OF NAME            16800021
         MVI   0(R7),X'40'         CLEAR JOBNAME                        16900021
         MVC   1(7,R7),0(R7)       FIELD                                17000021
         EX    R3,JOBMOVE          MOVE JOBNAME                         17100021
         TM    PRSW,LFTPAREN       IS LEFT PAREN SW ON                  17200021
         BO    JOBNAME1            YES--ANOUTHER JOBNAME                17300021
         B     JBNMDN              NO--NONE LEFT                        17400021
         SPACE                                                          17500021
JOBNAME2 TM    0(R7),JOBLAST       IS THIS THE END OF TABLE             17600021
         BO    SYNTAXC             YES--ERROR                           17700021
         LA    R7,4(R7)            INCR TO NEXT ADDR                    17800021
         B     JOBNAME3            LOOP                                 17900021
          SPACE                                                         18000021
JOBNAME4 LTR   R3,R3               IS LENGTH ZERO                       18100021
         BZ    SYNTAXB             YES--ERROR                           18200021
         B     JOBNAME5            NO--GO MOVE JOBNAME                  18300021
         EJECT                                                          18400021
DELHDLR  SR    R5,R5               CLEAR INDEX REG                      18500021
         SRL   R2,2                DIVIDE DELIMITER CODE BY 4           18600021
         IC    R5,0(R2,R1)         LOAD INDEXING FACTOR INTO R5         18700021
         B     0(R5,R6)            RETURN ON R6 INDEXED BY R5           18800021
         SPACE 2                                                        18900021
*********************************************************************** 19000021
*                                                                     * 19100021
*                        SCAN MESSAGE BUFFER                          * 19200021
*                                                                     * 19300021
*********************************************************************** 19400021
         SPACE                                                          19500021
SCAN     L     R1,KYWDEND          ADDR OF LAST DELIMITER               19600021
         AH    R1,ONEA             ADDR OF NEXT PARAMETER               19700021
         ST    R1,KYWDBGN          SAVE NEXT PARAMETER ADDR             19800021
         LR    R3,R1               SAVE TEMP IN R3                      19900021
         SR    R2,R2               ZERO DILIMITER CODE REG              20000021
         TRT   0(9,R1),BLNK        TO NEXT DELIMITER                    20100021
         BZ    SYNTAXE             TOO BIG                              20200021
         ST    R1,KYWDEND          SAVE ADDR OF DELIMITER               20300021
         ST    R2,DELIMCD          SAVE DELIMITER CODE                  20400021
         SR    R1,R3               LENGTH OF PARAMETER IN R1            20500021
         LR    R3,R1               LOAD LENGTH TO R3                    20600021
         BR    R6                  RETURN                               20700021
         EJECT                                                          20800021
*********************************************************************** 20900021
*                                                                     * 21000021
**                     ***  JOBNAME ROUTINE  ***                     ** 21100021
*                                                                     * 21200021
*                                                                     * 21300021
*       JOBNAME WAS SPECIFIED....COMPARE JOBNAME TO JOBNAME IN        * 21400021
*       TIOTS FOR AN EQUAL AND PRINT IT'S REGION                      * 21500021
*                                                                     * 21600021
*********************************************************************** 21700021
         SPACE                                                          21800021
JBNMDN   TM    SWD,FLSHMODE        IS THIS FLUSH MODE                   21900021
         BO    JOBDONE             YES - GO TO EXIT                     22000021
         BRWRITE  SKIP                                                  22100021
         L     BUFREG,CURBUF       POINT TO CURRENT OUTPUT BUFFER       22200021
         USING OUTBUF,BUFREG                                            22300021
         MVC   ADDR+39(L'PJBTITLE),PJBTITLE                             22400021
         BRWRITE  2                                                     22500021
         NI    SWB,255-SEQ1        RESET SEQUENCE SW                    22600021
         MVC   ERADRSV2,ERRADDR    SAVE PREVIOUS ERROR ROUTINE ADDR     22700021
         LA    R15,JBPRTER         LOAD ADDR OF ERR ROUT FOR JOBPRINT   22800021
         ST    R15,ERRADDR         ENABLE ERROR ROUTINE                 22900021
         L     R15,AALLRGN         GET ADDRESS OF ALL REGIONS ROUTINE   23000021
         BALR  RETREG,R15          LINK TO IT - GET ALL JSTCB'S ON      23100021
*                                  TCB LIST                             23200021
JOBPRNT1 XC    TCBCNTR,TCBCNTR     ZERO TCB COUNTER                     23300021
         OI    SWB,SEQ1            SET SEQUENCE SW (USED ONLY IN THE    23400021
*                                  EVENT OF AN ERROR TO DETERMINE WHERE 23500021
*                                  IN JOBPRINT TO RETURN CONTROL AFTER  23600021
*                                  WRITING ERROR MSG)                   23700021
JOBLOOPA LH    R2,TCBCNTR          LOAD TCB COUNT                       23800021
         AH    R2,ONEA             ADD ONE TO COUNT                     23900021
         STH   R2,TCBCNTR          STORE BACK UPDATED COUNT             24000021
JOBLOOPB NI    JOBPRNT3+1,X'0F'    RESET FIRST TIME SWITCH              24100021
         LH    R2,TCBCNTR          LOAD TCB COUNT TO R2                 24200021
         L     R15,ATCBRTRV        LOAD ADDR OF TCB RETRIEVE ROUTINE    24300021
         BALR  RETREG,R15          GO GET TCB ADDR                      24400021
         LTR   R2,R2               WAS THERE ANOTHER TCB                24500021
         BZ    JOBPRNT2            NO--GO SEE IF I FOUND ANY            24600021
         ST    R2,JOBTCB           SAVE JSTCB ADDR IN CASE OF ERROR     24700021
         LA    PREG,TCBTIOT(R2)    TCB TIOT PTR ADDR                    24800021
         BRREAD  (PREG),,TJID=0                                         24900021
         L     PREG,0(PREG)        TIOT ADDRESS                         25000021
         LTR   R6,PREG             TEST FOR ZERO AND SAVE IN R6         25100021
         BZ    JOBPRNT4            REMOVE TCB FROM LIST IF NO TIOT      25200021
         C     R6,ADDRMAX          COMPARE TIOT ADDR TO MAX             25300021
         BH    JOBPRNT4            GT ADDRMAX--REMOVE TCB FROM LIST     25400021
JOBLOOPD BRREAD  (PREG)                                                 25500021
         SR    R5,R5               CLEAR INDEX                          25600021
JOBLOOPC L     R7,JBNAMEA(R5)      LOAD ADDR OF JOBNAME                 25700021
         L     R8,NAMEAMSK         LOAD MASK TO TEST JOBVALID BIT       25800021
         NR    R8,R7               IS JOBNAME VALID                     25900021
         BZ    JOBPRNT8            NO--DON'T COMP                       26000021
         CLC   0(8,PREG),0(R7)     COMPARE TO TIOT                      26100021
         BE    JOBFND              BR IF EQUAL                          26200021
JOBPRNT8 LTR   R7,R7               IS THIS THE LAST JOBNAME IN LIST     26300021
         BM    JOBPRNT3            BR IF YES                            26400021
         LA    R5,4(R5)            STEP TO NEXT NAME                    26500021
         B     JOBLOOPC            LOOP THROUGH JOBNAME LIST            26600021
         SPACE                                                          26700021
JOBPRNT3 BC    0,JOBPRNT4          BR ON SECOND ENTRY FOR A GIVEN TCB   26800021
         OI    JOBPRNT3+1,X'F0'    SET FIRST TIME SWITCH                26900021
         TM    SWE,MVTSW           IS THIS AN MVT DUMP                  27000021
         BZ    JOBPRNT4            NO--IT'S PCP OR MFT...DON'T COMPARE  27100021
*                                  AGAINST STEPNAME OF TIOT             27200021
JOBPRNTF LA    R3,2                LOAD COUNT TO R3                     27300021
         LA    PREG,MOTHER(R2)     LOAD ADDR OF MOTHER POINTER          27400021
JOBLOOPG BRREAD  (PREG)                                                 27500021
         L     PREG,0(PREG)        LOAD MOTHER POINTER                  27600021
         C     PREG,MSTRTCB        COMPARE IT TO THE MASTER SCHED TCB   27700021
*                                  ADDRESS                              27800021
         BE    JOBPRNTE            EQUAL--TCB ADDR IN R2 IS AN INIT TCB 27900021
         LA    PREG,MOTHER(PREG)   LOAD ADDR OF THIS TCB'S MOTHER PTR   28000021
         BCT   R3,JOBLOOPG         LOOP FOR COUNT IN R3                 28100021
         SPACE                                                          28200021
JOBPRNT4 L     R15,ATCBREMV        LOAD ADDR OF TCB REMOVE ROUTINE      28300021
         BALR  RETREG,R15          REMOVE THE TCB FROM THE TCBLIST      28400021
         B     JOBLOOPB            SINCE I HAVE REMOVED A TCB FROM THE  28500021
*                                  TCB LIST I DON'T WANT TO INCREMENT   28600021
*                                  THE COUNT                            28700021
         SPACE                                                          28800021
JOBPRNTE LA    PREG,8(R6)          ADDR OF STEP NAME IN TIOT            28900021
         B     JOBLOOPD            AN INITIATOR'S TIOT CONTAINS THE     29000021
*                                  JOBNAME IN THE STEPNAME FIELD        29100021
         SPACE                                                          29200021
JOBFND   LA    R5,JBNAMEA(R5)      ADDR OF EQ JOBNM ADDR                29300021
         LA    PREG,TCBFLGS+4(R2)  ADDR OF FLAG BYTE WHICH CONTAINS     29400021
*                                  ROLLED OUT BIT                       29500021
         BRREAD  (PREG)                                                 29600021
         TM    0(PREG),ROLLOUT     IS JOB STEP ROLLED OUT               29700021
         BO    JOBFND1             BR IF IT IS                          29800021
         OI    0(R5),JBFNDBIT      IF NOT SET THE JOB FOUND BIT         29900021
         B     JOBLOOPA            GET THE NEXT TCB                     30000021
JOBFND1  OI    0(R5),ROLLOUT       SET THE JOB ROLLED OUT BIT           30100021
         B     JOBPRNT4            GET THE NEXT TCB                     30200021
         SPACE                                                          30300021
JOBPRNT2 LA    R5,JBNAMEA          ADDR OF JOBNAME LIST                 30400021
JOBLOOPE TM    0(R5),JBFNDBIT      WAS JOB FOUND                        30500021
         BZ    JOBPRNT5            NO--TELL OPERATOR                    30600021
JOBPRNT7 TM    0(R5),JOBLAST       IS THIS THE LAST                     30700021
         BO    JOBPRNT6            YES                                  30800021
         LA    R5,4(R5)            STEP TO NEXT ADDR                    30900021
         B     JOBLOOPE            LOOP                                 31000021
         SPACE                                                          31100021
JOBPRNT5 TM    0(R5),JOBVALID      IS JOBNAME VALID                     31200021
         BZ    JOBPRNT7            NO--GO TO NEXT                       31300021
         TM    0(R5),ROLLOUT       IS THE JOB ROLLED OUT                31400021
         BZ    JOBPRNTA            BR IF NOT                            31500021
         MVC   JOBWTO+29(10),ROLLMSG  MOVE ROLLED OUT MSG TO WTO        31600021
         B     JOBPRNTB                                                 31700021
JOBPRNTA MVC   JOBWTO+29(10),FNDMSG  MOVE NOT FOUND MSG TO WTO          31800021
JOBPRNTB L     R7,0(R5)            JOBNAME ADDR TO R7                   31900021
         MVC   JOBWTO+20(8),0(R7)  MOVE JOBNAME TO WTO                  32000021
         BRPRTMSG  JOBWTO+8,31     PRINT JOB NOT FOUND ON SYSPRINT      32100021
         TM    SWA,RDRSW           IS READER SW ON ?                    32200021
         BO    JOBPRNT7            YES--DON'T WRITE TO OPERATOR         32300021
JOBWTO   WTO   'IMD162I JOB          NOT FOUND ',ROUTCDE=(2),DESC=7     32400021
         B     JOBPRNT7            LOOK AT ALL                          32500021
         SPACE                                                          32600021
JOBPRNT6 LA    R4,JBNAMEA          ADDR OF JOBNAME LIST                 32700021
JOBLOOPF NI    0(R4),JOBLAST       RESET ALL BUT LAST BIT               32800021
         BNZ   JOBPRNTC            BR TO CONTINUE IF LAST NAME          32900021
         LA    R4,4(R4)            STEP INDEX                           33000021
         B     JOBLOOPF            LOOP                                 33100021
         SPACE                                                          33200021
JOBPRNTC NI    SWB,255-SEQ1        RESET SEQUENCE SW                    33300021
         MVC   ERRADDR,ERADRSV2    RESTORE PREVIOUS ERROR ROUT ADDR     33400021
         L     R15,TCBLIST         TEST TCBLIST FOR ANYTHING TO BE      33500021
         LTR   R15,R15             PRINTED                              33600021
         BZ    JOBDONE             EXIT IF NOTHING TO DO                33700021
         BRWRITE  2                SPACE TWO LINES BEFORE FORMAT        33800021
         SR    R0,R0               ZERO TJID PARM                       33900021
         L     R15,AFORMAT         POINT TO FORMAT SERVICE ROUTINE      34000021
         BALR  RETREG,R15          LINK TO PRINT CONTROL BLOCKS         34100021
         BRWRITE  SKIP                                                  34200021
         L     R15,ARGNBND         LOAD ADDR OF REGION BOUNDRY ROUT     34300021
         BALR  RETREG,R15          LINK TO IT - GET REGIONS OF ALL      34400021
*                                  TASKS ON TCB LIST ENQUEUED FOR       34500021
*                                  PRINTING                             34600021
         L     R15,APRTSTG         GET ADDR OF PRINT STORAGE ROUTINE    34700021
         BALR  RETREG,R15          LINK TO PRINT REGIONS                34800021
         L     R15,ATCBREMV        ADDR OF TCB REMOVE ROUTINE    A48075 34850021
         SR    R2,R2               TO INDICATE REMOVAL OF ALL    A48075 34860021
*                                  TCB ADDRESSES                 A48075 34870021
         BALR  RETREG,R15          LINK TO IT                    A48075 34880021
         SPACE                                                          34900021
JOBDONE  L     R13,4(R13)          EXIT LINKAGE                         35000021
         LM    R14,R12,12(R13)     RESTORE CALLER'S REGISTERS           35100021
         BR    RETREG              RETURN                               35200021
         SPACE                                                          35300021
         DROP  BASE1,R15                                                35400021
         EJECT                                                          35500021
*********************************************************************** 35600021
*                                                                     * 35700021
*                       JOBPRINT ERROR ROUTINE                        * 35800021
*                                                                     * 35900021
*********************************************************************** 36000021
         SPACE                                                          36100021
         USING JBPRTER,R15                                              36200021
JBPRTER  LA    R13,JOBSAVE         GET ON PJB'S SAVE AREA               36300021
         LM    R14,R12,12(R13)     RESTORE REG'S TO BEFORE LAST EXIT    36400021
         DROP  R15                                                      36500021
         USING SYNEPS,R15          RE-ESTABLISH SYNEPS                  36600021
         USING JBBASE,BASE1        SHIFT BACK TO REG 11 AS BASE         36700021
         L     BUFREG,CURBUF       LOAD OUTPUT BUFFER ADDR              36800021
         BRWRITE 1                 SPACE A LINE                         36900021
         LA    R7,ADDR             ADDR OF WHERE TO MOVE MSG TO R7      37000021
         LH    R1,JBPRERM          LOAD LN OF MSG                       37100021
         SH    R1,FIVE             DECR LN 5 FOR EXECUTE                37200021
         LA    R2,JBPRERM+4        ADDR OF ERROR MSG                    37300021
         EX    R1,JOBMOVE          MOVE ERROR MSG TO OUTPUT BUFFER      37400021
         LA    R3,1(R1)            INCR LN AND SAVE IN R3               37500021
         BRWRITE 1                 PRINT ERROR MSG ON DUMP              37600021
         LR    R1,R2               ADDR OF MSG TO R1                    37700021
         LR    R2,R3               LN OF MSG TO R2                      37800021
         BRPRTMSG  (R1),(R2)       PRINT ERROR MSG ON SYSPRINT          37900021
         TM    SWA,RDRSW           TEST IF READING CONTROL CARDS  M3518 38000021
         BO    JBPRTER1            YES--DON'T WTO THE ERROR MSG   M3518 38100021
         LA    R1,JBPRERM          NO--TELL OPERATOR ABOUT THE ERROR    38200021
         WTO   MF=(E,(1))          WTO THE ERROR MSG                    38300021
JBPRTER1 TM    SWB,SEQ1            TEST SEQ SW TO DETERMINE RET PT      38400021
         BZ    JOBPRNT1            NOT ON--CONTINUE AT JOBPRNT1         38500021
         L     R2,JOBTCB           RESTORE TCB ADDR TO R2               38600021
         B     JOBPRNT4            ON--CONTINUE AT JOBPRTN4             38700021
         EJECT                                                          38800021
***  STATIC STORAGE  ***                                                38900021
         SPACE                                                          39000021
JOBMOVE  MVC   0(0,R7),0(R2)       EXECUTED INSTRUCTION                 39100021
         SPACE                                                          39200021
JOBSAVE  DC    18F'0'              PJB'S SAVE AREA                      39300021
ERADRSV2 DC    F'0'                SAVE AREA FOR ERROR ROUTINE ADDR     39400021
JOBTCB   DC    F'0'                SAVE AREA FOR JSTCB IN JOBPRINT      39500021
JBPRERMA DC    A(JBPRERM)          ADDR OF JOBPRINT ERROR MSG           39600021
NAMEAMSK DC    AL1(JOBVALID)                                            39700021
         DC    AL3(0)                                                   39800021
TCBCNTR  DC    H'0'                                                     39900021
JBNSYNA  DC    A(JBNSYN1)                                               40000021
         DC    A(JBNSYN2)                                               40100021
         DC    A(JBNSYN3)                                               40200021
         DC    A(STGSYN4)                                               40300021
         DC    A(JBNSYN5)                                               40400021
JOBMSK1  DC    X'000004000000'                                          40500021
JOBMSK2  DC    X'000400040800'                                          40600021
JOBMSK3  DC    X'000400000008'                                          40700021
FNDMSG   DC    CL10'NOT FOUND'                                          40800021
PJBTITLE DC    C'* * * *  P R I N T  J O B N A M E  * * * *'            40900021
         EJECT                                                          41000021
JBNSYN1  WTO   '        DELIMITER ERROR IN JOBNAME OPERAND LIST',MF=L, X41100021
               ROUTCDE=(2),DESC=7                                       41200021
JBNSYN2  WTO   '        NAME MISSING FROM JOBNAME OPERAND LIST',MF=L,  X41300021
               ROUTCDE=(2),DESC=7                                       41400021
JBNSYN3  WTO   '        TOO MANY JOBNAMES IN LIST',MF=L,               X41500021
               ROUTCDE=(2),DESC=7                                       41600021
JBNSYN5  WTO   '        JOBNAME LENGTH GREATER THAN 8',MF=L,           X41700021
               ROUTCDE=(2),DESC=7                                       41800021
STGSYN4  WTO   '        UNBALANCED PARENTHESIS',MF=L,                  X41900021
               ROUTCDE=(2),DESC=7                                       42000021
JBPRERM  WTO   'IMD166I FORMAT ERROR DURING JOBNAME SEARCH',MF=L,      X42100021
               ROUTCDE=(2),DESC=7                                       42200021
         EJECT                                                          60000021
         SYNEPS                                                         60100021
         SPACE                                                          60200021
         END                                                            60300021
