IMDPRPMS START                                                          00400020
         TITLE 'IMDPRPMS - ABSOLUTE STORAGE EXECUTOR'                   00800020
*********************************************************************** 00801021
*                                                                     * 00802021
*             ***  IMDPRPMS - PRINT STORAGE EXECUTOR  ***             * 00803021
*                                                                     * 00804021
* STATUS -- OS/360 RELEASE 21.0                                       * 00805021
*                                                                     * 00806021
* FUNCTION --                                                         * 00807021
*                                                                     * 00808021
*         THIS MODULE SCANS THE PARAMETER FIELDS OF THE PRINT STORAGE * 00809021
*    CONTROL STATEMENT AND CHECKS FOR THE ADDRESSES OF THE STORAGE    * 00810021
*    AREAS TO BE PRINTED.  IF THE PARAMETER FIELD IS NOT CODED ALL THE* 00811021
*    STORAGE IS PRINTED.  IF THE LAST ADDRESS IN A PAIR OF ADDRESSES  * 00812021
*    IN THE PARAMETER FIELD IS NOT CODED, A DEFAULT VALUE OF THE      * 00813021
*    HIGHEST ADDRESS IN THE DUMP IS SUBSTITUTED.  IF A SYNTAX ERROR IS* 00814021
*    DISCOVERED THE RELATED PRINT CONTROL BLOCKS ARE PURGED AND       * 00815021
*    CONTROL IS RETURNED TO IMDPRCTL.                                 * 00816021
*         THE PRINT CONTROL BLOCK (PCB) CSECT, OF THE IMDPRDPS SERVICE* 00817021
*    MODULE, IS USED TO ENQUEUE THE REQUESTED ABSOLUTE STORAGE        * 00818021
*    LOCATIONS ON THE PCB QUEUE FOR LATER PROCESSING BY THE MODULE    * 00819021
*    IMDPRDPS.                                                        * 00820021
*         IF THE PARAMETER FIELD IS INCORRECTLY CODED, ERROR MESSAGES * 00821021
*    ARE GENERATED.                                                   * 00822021
*         IMDPRPMS ALSO SERVICES THE REQUEST OF IMDPRCTL TO PRINT THE * 00823021
*    ENTIRE DUMP TAPE, WHEN 'ERRSW' IS ON IN IMDPRCOM.  IN THIS CASE, * 00824021
*    A PCB DESCRIBING LOCATION 0 TO THE HIGHEST ADDRESS IN THE DUMP IS* 00825021
*    CONSTRUCTED AND THE MODULE IMDPRDPS IS CALLED TO PRINT THIS      * 00826021
*    STORAGE.                                                         * 00827021
*                                                                     * 00828021
* ENTRY POINTS --                                                     * 00829021
*                                                                     * 00830021
*         IMDPRPMS IS THE MAIN AND ONLY ENTRY POINT.  THIS MODULE     * 00831021
*    RECEIVES CONTROL WHEN THE 'STORAGE' PARAMETER OF THE PRINT       * 00832021
*    STORAGE CONTROL STATEMENT IS ENCOUNTERED.  ALSO, WHEN AN ERROR   * 00833021
*    HAS OCCURRED IN DUMP INITIALIZATION AND THE ERROR CODE IS 1.     * 00834021
*                                                                     * 00835021
* INPUT --                                                            * 00836021
*                                                                     * 00837021
*         THE COMMON CSECT, IMDPRCOM, WHICH CONTAINS VALUES OF        * 00838021
*    SWITCHES, CONSTANTS, AND TRT TABLES.  SPECIFICALLY, THE DELIMITER* 00839021
*    CODE OF THE FIRST DELIMITER THIS ROUTINE WILL PROCESS (DELIMCD), * 00840021
*    AND THE BEGINNING (KYWDBGN) AND ENDING (KYWDEND) ADDRESSES OF THE* 00841021
*    KEYWORD.                                                         * 00842021
*                                                                     * 00843021
* OUTPUT --                                                           * 00844021
*                                                                     * 00845021
*         THE STORAGE REQUESTED BY THE PRINT STORAGE CONTROL STATEMENT* 00846021
*                                                                     * 00847021
* EXTERNAL REFERENCES --                                              * 00848021
*                                                                     * 00849021
*         1.  IMDPRPCB - TO ENQUEUE THE REQUESTED STORAGE LOCATIONS ON* 00850021
*             THE PRINT CONTROL BLOCK QUEUE.                          * 00851021
*                                                                     * 00852021
*         2.  IMDPRDPS - TO FORMAT AND PRINT AREAS OF MAIN STORAGE    * 00853021
*             THAT ARE ENQUEUED ON THE PRINT CONTROL BLOCK QUEUE.     * 00854021
*                                                                     * 00855021
*         3.  BRWRITE - TO PRINT THE ABSOLUTE STORAGE TITLE ON THE    * 00856021
*             PRINTER DATA SET.                                       * 00857021
*                                                                     * 00858021
* EXITS,NORMAL --                                                     * 00859021
*                                                                     * 00860021
*         IMDPRPMS RETURNS TO IMDPRCTL                                * 00861021
*                                                                     * 00862021
* EXITS,ERROR --                                                      * 00863021
*                                                                     * 00864021
*         NONE                                                        * 00865021
*                                                                     * 00866021
* TABLES/WORK AREAS --                                                * 00867021
*                                                                     * 00868021
*         THE COMMON CSECT, IMDPRCOM, WHICH CONTAINS VALUES OF THE    * 00869021
*    DELIMITERS, AND BEGINNING AND ENDING ADDRESSES OF THE KEYWORD.   * 00870021
*                                                                     * 00871021
* ATTRIBUTES -- REUSEABLE                                             * 00872021
*                                                                     * 00873021
* CHARACTER CODE DEPENDENCY -- EBCDIC                                 * 00874021
*                                                                     * 00875021
* NOTES -- NONE                                                       * 00876021
*                                                                     * 00877021
*********************************************************************** 00878021
         EJECT                                                          04450021
*/*IMDPRPMS: CHART (AMODE,SEQ) */                                       04450521
*/*HEADER                                                               04451021
*/*IMDPRPMS    DETERMINES THE STORAGE LOCATIONS TO BE PRINTED OUT       04451521
*/*                                                     PAGE # */       04452021
*/*IMDPRPMS: E ENTRY */                                                 04452521
*/*  M HOUSE KEEPING AND INITIALIZATIONS */                             04453021
*/*STORAGE: M ZERO STORAGE SWITCH */                                    04453521
*/*  D (YES,ERRSERV,NO,) IS ERROR SERVICE SWITCH ON? */                 04454021
*/*  P GET ADDRESS OF SYNTAX ERROR MESSAGE ADDRESSES AND STORE IT */    04454521
*/*  P GET ADDRESS OF SYNTAX ERROR MESSAGE ROUTINE */                   04455021
*/*  P SET RETURN ADDRESS FOR EXIT FROM ERROR MESSAGE ROUTINE */        04455521
*/*  P GET ADDRESS OF 1ST DELIMITER MASK*/                              04456021
*/*  P GET DELIMITER CODE */                                            04456521
*/*  P DIVIDE DELIMITER CODE-USE RESULT TO GET INDEX TO BRANCH TABLE */ 04457021
*/*  D (0,%L2,1,STRG5,2,SCAN,3,STRG5,4,%L2,5,%L2) WHAT IS INDEX         04457521
*/*VALUE?*/                                                             04458021
*/*  P GET ADDRESS OF 2ND DELIMITER MASK*/                              04458521
*/*  P GET DELIMITER CODE-USE RESULT TO GET INDEX TO BRANCH TABLE */    04459021
*/*  D (0,%L2,1,STRG4,2,%L2,3,STRG4,4,%L8,5,%L2) WHAT IS INDEX VALUE?   04459521
*/**/                                                                   04460021
*/*%L8: D (YES,%L5,NO,) IS LEFT PAREN SWITCH ON?*/                      04460521
*/*  M TURN LEFT PAREN SWITCH ON */                                     04461021
*/*STGLOOP: P SCAN: SCAN MESSAGE BUFFER  */                             04461521
*/*  P GET ADDRESS OF 3RD DELIMITER MASK*/                              04462021
*/*  P DIVIDE DELIMITER CODE-USE RESULT TO GET INDEX TO BRANCH TABLE */ 04462521
*/*  D (0,%L2,1,STRG4,2,%L2,3,%L2,4,%L2,5,) WHAT IS INDEX VALUE? */     04463021
*/*  D (YES,,NO,%L5) IS LEFT PAREN SWITCH ON? */                        04463521
*/*  M RESET LEFT PAREN SWITCH */                                       04464021
*/*  P GET ADDRESS OF LAST DELIMITER */                                 04464521
*/*  P INCREMENT ADDRESS BY 1 */                                        04465021
*/*  D (YES,,NO,%L1) IS THIS A VALID DELIMITER? */                      04465521
*/*  P STORE DELIMITER CODE */                                          04466021
*/*STRG4: D (YES,STRG6,NO,) IS PARM LENGTH ZERO? */                     04466521
*/*  D (YES,%L3,NO,) IS THE PARM LENGTH > 6? */                         04467021
*/*  P GET BEGINNING ADDRESS OF THE PARAMETER */                        04467521
*/*  P MOVE LOCATION OF LENGTH VALUE */                                 04468021
*/*HEXCHEK: D (YES,NEXTHEX,NO,) 1ST BYTE OF PARAM NUMERIC? */           04468521
*/*  D (YES,,NO,%L2) IS IT A HEX-ALPHA? */                              04469021
*/*NEXTHEX: P INCREMENT POINTER TO NEXT BYTE */                         04469521
*/*  D (YES,,NO,%L9) IS PARM LENGTH ZERO? */                            04470021
*/*  P GET THE ADDRESS OF THE PARAMETER */                              04470521
*/*  P STRGA: TRANSLATE ADDRESS TO UNPACKED HEX */                      04471021
*/*STRG7: M CHANGE THE STORAGE SWITCH */                                04471521
*/*  D (YES,STRG2,NO,) IS STORAGE SWITCH ZERO */                        04472021
*/*  P STORE STARTING ADDRESS */                                        04472521
*/*STRG3: D (YES,STGLOOP,NO,) IS LEFT PAREN SWITCH ON? */               04473021
*/*STGDONE: P GET MAXIMUM ADDRESS */                                    04473521
*/*  P STORE ADDRESS IN P-LIST */                                       04474021
*/*  D (YES,,NO,STGDONE2) IS STORAGE SWITCH ON? */                      04474521
*/*STGDONE1: P GET ADDRESS OF THE P-LIST */                             04475021
*/*  P GET ADDRESS OF THE PCB ENQUE ROUTINE */                          04475521
*/*  L IMDPRPCB */                                                      04476021
*/*STGDONE2: D (YES,CLEAN,NO,) IS THIS FLUSH MODE? */                   04476521
*/*STGPRINT: L BRWRITE        - SKIP A PAGE */                          04477021
*/*  P GET BUFFER ADDRESSES */                                          04477521
*/*  P MOVE IN STORAGE TITLE */                                         04478021
*/*  L BRWRITE  - PRINT THE TITLE */                                    04478521
*/*  P GET ADDRESS OF THE PRINT STORAGE ROUTINE */                      04479021
*/*  L IMDPRSTG */                                                      04479521
*/*STGEXIT: M EXIT LINKAGE */                                           04480021
*/*  R RETURN */                                                        04480521
*/*STRGA: D (YES,,NO,%L10) IS PARM LENGTH ZERO? */                      04481021
*/*%L11: P TRANSLATE BEGINNING ADDRESS TO UNPACKED HEX */               04481521
*/*  P ADJUST COUNT FOR PACKING */                                      04482021
*/*  P PACK HEX ADDRESS */                                              04482521
*/*  P REMOVE THE SIGN */                                               04483021
*/*  P PUT THE ADDRESS IN REG 1 */                                      04483521
*/*  R RETURN TO CALLER */                                              04484021
*/*STRG6: D (YES,,NO,%L4) IS STORAGE SWITCH ON? */                      04484521
*/*  P (,STRG7) GET MAXIMUM ADDRESS */                                  04485021
*/*STRG2: P STORE ENDING ADDRESS */                                     04485521
*/*  P GET ADDRESS OF THE P-LIST */                                     04486021
*/*  P GET ADDRESS OF THE PCB ENQUE ROUTINE */                          04486521
*/*  L IMDPRPCB */                                                      04487021
*/*  P RESTORE RETURN ADDRESS FOR EXIT FROM ERROR MSG RTN */            04487521
*/*  P (,STRG3) RESTORE SYNTAX ERROR ADDRESSES */                       04488021
*/*STRG5: P ZERO PARAMETER LENGTH */                                    04488521
*/*  P STORE ZERO AS STARTING ADDRESS */                                04489021
*/*  P SET MAXIMUM ENDING ADDRESS */                                    04489521
*/*  M SET SWITCH TO REQUEST REGISTERS (GPR) */                         04490021
*/*  M (,STGDONE1) RESET PRINT SWITCH */                                04490521
*/*ERRSERV: P ZERO PARAMETER LENGTH */                                  04491021
*/*  P STORE ZERO AS STARTING ADDRESS */                                04491521
*/*  D (YES,,NO,NOTOP) IS COMMON CSECT DATA VALID? */                   04492021
*/*  P (,STERHIGH) GET TOP-OF-BOX */                                    04492521
*/*NOTOP: P GET APPROXIMATE TOP-OF-BOX */                               04493021
*/*STERHIGH: P STORE TOP ADDRESS */                                     04493521
*/*  P GET ADDRESS OF THE P-LIST */                                     04494021
*/*  P GET ADDRESS OF THE PCB ENQUE ROUTINE */                          04494521
*/*  L (,STGPRINT) HMDPRPCB */                                          04495021
*/*CLEAN: P GET ADDRESS OF THE P-LIST */                                04495521
*/*  P INDICATE DEQUE */                                                04496021
*/*  P GET ADDRESS OF THE PCB ENQUE ROUTINE */                          04496521
*/*  L IMDPRPCB */                                                      04497021
*/*  D (YES,STGEXIT,NO,CLEAN) IS PCB DEQUEUED? */                       04497521
*/*SCAN: N SCAN MESSAGE BUFFER */                                       04498021
*/*  P GET ADDRESS OF THE LAST DELIMITER */                             04498521
*/*  P COMPUTE AND STORE ADDRESS OF THE NEXT PARAMETER */               04499021
*/*  P CLEAR DELIMITER CODE AREA */                                     04499521
*/*  P SCAN FOR THE NEXT DELIMITER */                                   04500021
*/*  D (YES,,NO,%L6) IS THIS A VALID DELIMITER? */                      04500521
*/*  P STORE ADDRESS OF THE DELIMITER */                                04501021
*/*  P STORE DELIMITER CODE */                                          04501521
*/*  P COMPUTE THE LENGTH OF THE DELIMITER */                           04502021
*/*  P PUT LENGTH IN REG3 */                                            04502521
*/*  R RETURN TO CALLER */                                              04503021
*/*%L1: L (,STGDONE2) SYNTAX */                                         04503521
*/*%L2: L (,STGDONE2) SYNTAXA */                                        04504021
*/*%L3: L (,STGDONE2) SYNTAXB */                                        04504521
*/*%L4: L (,STGDONE2) SYNTAXC */                                        04505021
*/*%L5: L (,STGDONE2) SYNTAXD */                                        04505521
*/*%L6: L (,STGDONE2) SYNTAXE */                                        04506021
*/*%L9: P (,HEXCHEK) DECREMENT PARAMETER LENGTH BY 1 */                 04506521
*/*%L10: P (,%L11) DECREMENT PARAMETER LENGTH BY 1 */                   04507021
*/*IMDPRPMS: END*/                                                      04507521
         EJECT                                                          04508021
         EQUATES                                                        04800020
         COMMON                                                         05200020
*                                                                 M3179 05250020
         OUTBUFM                                                        05600020
IMDPRPMS CSECT                                                          06000020
         STM   R14,R12,12(13)      SAVE CALLERS REGISTERS               06400020
         BALR  BASE1,0             ESTABLISH REG 11 AS BASE             06800020
         USING *,BASE1                                                  07200020
         LA    R2,PMSSAVE          SAVE AREA CHAINING                   07600020
         ST    R13,PMSSAVE+4                                            08000020
         ST    R2,8(R13)                                                08400020
         LR    R13,R2              ENTRY COMPLETE                       08800020
         SPACE                                                          09200020
         USING OUTBUF,BUFREG                                            09600020
         USING COMMON,COMBASE      REG 12 IS COMMON CSECT POINTER       10000020
         USING SYNEPS,R15                                               10400020
         SPACE                                                          10800020
STORAGE  MVI   STGSW,0             ZERO STORAGE SWITCH                  11200020
         TM    PRSW,ERRSW          TEST FOR PRINT STORAGE ERROR         11600020
*                                  SERVICE                              12000020
         BO    ERRSERV             BRANCH TO ENQUE WHOLE BOX            12400020
         LA    R15,STGSYNA         ADDR OF SYNTAX ERROR MSG ADDRS       12800020
         ST    R15,SYNMSGA         STORE IT                             13200020
         L     R15,ASYNTAX         POINT TO SYNTAX ERROR MSG ROUTINE    13600020
         LA    R14,STGDONE2        SET RETURN ADDRESS TO EXIT           14000020
         LA    R1,STOMSK1          ADDR OF DELIMITER MASK               14400020
         L     R2,DELIMCD          LOAD DELIMITER CODE                  14800020
         SR    R5,R5               TEST DELIMITER                       15200020
         SRL   R2,2                                                     15600020
         IC    R5,0(R2,R1)         LOAD INDEXING FACTOR INTO REG 5      16000020
         B     *+4(R5)             BRANCH ON INDEX VALUE                16400020
         B     SYNTAXA             ERROR RETURN                         16800020
         B     STRG5               COMMA OR BLANK--PRINT EVERYTHING     17200020
         BAL   R6,SCAN             EQUAL SIGN                           17600020
         LA    R1,STOMSK2          DELIMITER MASK ADDR                  18000020
         SR    R5,R5               TEST DELIMITER                       18400020
         SRL   R2,2                                                     18800020
         IC    R5,0(R2,R1)         LOAD INDEXING FACTOR INTO REG 5      19200020
         B     *+4(R5)             BRANCH ON INDEX VALUE                19600020
         B     SYNTAXA             ERROR RETURN                         20000020
         TM    PRSW,LFTPAREN       IS LEFT PAREN SW ALREADY ON          20800020
         BO    SYNTAXD             YES - ERROR                          21200020
         OI    PRSW,LFTPAREN       NO - TURN IT ON                      21600020
         OI    SWD,GPRSFND         SET SW FOR PRINT            &S21001P 21700000
STGLOOP  BAL   R6,SCAN             SCAN FOR NEXT PARM                   22000020
         LA    R1,STOMSK3          DELIMITER MASK ADDR                  22400020
         SR    R5,R5               TEST DELIMITER                       22800020
         SRL   R2,2                                                     23200020
         IC    R5,0(R2,R1)         LOAD INDEXING FACTOR INTO REG 5      23600020
         B     *+4(R5)             BRANCH ON INDEX VALUE                24000020
         B     SYNTAXA             ERROR RETURN                         24400020
         B     STRG4               COMMA                                24800020
         TM    PRSW,LFTPAREN       IS LEFT PAREN SW ON                  25200020
         BZ    SYNTAXD             NO - ERROR                           25600020
         NI    PRSW,255-LFTPAREN   RESET LEFT PAREN SW                  26000020
         L     R1,KYWDEND          ADDR OF RIGHT PAREN                  26400020
         LA    R1,1(R1)                                                 26800020
         ST    R1,KYWDEND                                               27200020
         TRT   0(2,R1),BLNK        SCAN FOR NEXT DELIMITER              27600020
         BZ    SYNTAX                                                   28000020
         ST    R2,DELIMCD                                               28400020
STRG4    LTR   R3,R3               IS LENGTH ZERO                       28800020
         BZ    STRG6               YES                                  29200020
         C     R3,SIX              COMPARE LENGTH TO SIX                29600020
         BH    SYNTAXB             LENGTH GT SIX IS AN ERROR            30000020
         L     R1,KYWDBGN          GET BEGINNING ADDR                   30400020
         LR    R6,R3               GET LENGTH                           30800020
HEXCHEK  TM    0(R1),X'F0'         IS IT NUMERIC DIGIT                  31200020
         BO    NEXTHEX             YES - CHECK NEXT DIGIT               31600020
         CLI   0(R1),C'A'          IS IT HEX-ALPHA                      32000020
         BL    SYNTAXA             NO - ERROR                           32400020
         CLI   0(R1),C'F'                                               32800020
         BH    SYNTAXA                                                  33200020
NEXTHEX  LA    R1,1(R1)            INCREMENT TO NEXT DIGIT              33600020
         BCT   R6,HEXCHEK          LOOP ON LENGTH                       34000020
         L     R1,KYWDBGN          LOAD BEGINNING ADDR                  34400020
         BAL   R6,STRGA            CONVERT ADDR TO BINARY               34800020
STRG7    XI    STGSW,X'FF'         CHANG AND TEST SWITCH                35200020
         BZ    STRG2               BR IF TO STORE ENDING ADDR           35600020
         ST    R1,LOW              STORE STARTING ADDR                  36000020
STRG3    TM    PRSW,LFTPAREN       IS THE LEFT PAREN SW ON              36400020
         BO    STGLOOP             YES--LOOP                            36800020
         B     STGDONE             NO--ALL DONE                         37200020
         SPACE                                                          37600020
STRG6    TM    STGSW,X'FF'         IS STORAGE SW ON                     38000020
         BZ    SYNTAXC             NO--STARTING ADDR WAS OMITTED        38400020
         L     R1,ADDRMAX          LOAD MAX ADDR                        38800020
         B     STRG7               CONTINUE                             39200020
         SPACE                                                          39600020
STRG2    ST    R1,HIGH             STORE ENDING ADDR                    40000020
         LA    R1,PCBLIST          POINT TO PCB ENQUEUE P-LIST          40400020
         L     R15,APCBENQ         LOAD ADDR OF PCB ENQ ROUTINE         40800020
         BALR  RETREG,R15          ENQ TO BE PRINTED                    41200020
         LA    R14,STGDONE2        RESTORE RETURN ADDRESS         M1147 41600020
         L     R15,ASYNTAX         RESTORE SYNTAX ERROR ADDRESS   M1147 42000020
         B     STRG3               CONTINUE                             42400020
         SPACE                                                          42800020
STRGA    BCTR  R3,0                DECR FOR EXECUTE                     43200020
         EX    R3,STRGTR           TRANSLATE TO UNPACKED HEX            43600020
         LA    R2,X'70'            L1 FOR PACK                          44000020
         OR    R2,R3               OR L2 WITH L1                        44400020
         EX    R2,STRGPACK         PACK TO HEX INTO WORK1               44800020
         MVO   WORK1+1(4),WORK1+4(4) GET RID OF SIGN                    45200020
         L     R1,WORK1            LOAD HEX ADDRESS INTO R1             45600020
         BR    R6                  RETURN                               46000020
         SPACE                                                          46400020
STRG5    SR    R3,R3               SET UP TO PRINT EVERYTHING           46800020
         ST    R3,LOW              STORE ZERO STARTING ADDRESS          47200020
         L     R3,ADDRMAX          SET MAXIMUM ENDING ADDRESS           47600020
         ST    R3,HIGH                                                  48000020
         OI    SWD,GPRSFND         REQUEST REGS FOR 'P S'               48400020
         NI    SWA,255-PRNTSW      RESET PRNTSW                         48800020
         B     STGDONE1                                                 49200020
         SPACE                                                          49600020
ERRSERV  SR    R3,R3               START AT LOCATION ZERO               50000020
         ST    R3,LOW                                                   50400020
         TM    SWC,MSTRSW          TEST IF COMMON CSECT DATA IS VALID   50800020
         BZ    NOTOP               BRANCH IF NOT                        51200020
         L     R3,ADDRMAX          GET TOP-OF-BOX FROM COMMON           51600020
         B     STERHIGH                                                 52000020
NOTOP    L     R3,ADDRMAX1         APPROX. TOP                          52400020
STERHIGH ST    R3,HIGH                                                  52800020
         OI    SWD,GPRSFND         REQUEST GPRS BE PRINTED              52850020
         LA    R1,PCBLIST          POINT TO PCB LIST                    53200020
         L     R15,APCBENQ         POINT TO PCB ENQUE ROUTINE           53600020
         BALR  RETREG,R15                                               54000020
         B     STGPRINT            BRANCH TO PRINT STORAGE              54400020
         SPACE                                                          54800020
STGDONE  TM    STGSW,X'FF'         IS STORAGE SW ON (STARTING ADDR      55200020
*                                  JUST STORED)                         55600020
         L     R4,ADDRMAX          LOAD MAXIMUM ADDR AS ENDING ADDR     56000020
         ST    R4,HIGH             STORE IN P-LIST                      56400020
         BZ    STGDONE2            NO--STARTING AND ENDING ADDRS ARE    56800020
*                                  ALREADY ENQUEUED                     57200020
STGDONE1 LA    R1,PCBLIST          POINT TO P-LIST                      57600020
         L     R15,APCBENQ         POINT TO PCB ENQUEUE ROUTINE         58000020
         BALR  RETREG,R15          ENQ TO BE PRINTED                    58400020
STGDONE2 TM    SWD,FLSHMODE        IS THIS FLUSH MODE                   58800020
         BO    CLEAN               IS SO, BRANCH TO PRUGE PCB'S         59200020
         TM    SWC,MSTRSW          FORMAT ERROR & CONSOLE MODE?  XM5582 59250000
         BZ    CLEAN               IF SO, LEAVE                  XM5582 59350000
STGPRINT BRWRITE  SKIP             PAGE                                 59600020
         L     BUFREG,CURBUF       GET BUFFER ADDRESS                   60000020
         MVC   ADDR+28(63),STGTITLE  MOVE IN ABSOLUTE STORAGE TITLE     60400020
         BRWRITE  2                PRINT TITLE                          60800020
         L     R15,APRTSTG         IF NOT, LINK TO PRINT STORAGE ROUTN  61200020
         BALR  RETREG,R15                                               61600020
         SPACE                                                          62000020
STGEXIT  L     R13,4(R13)          EXIT LINKAGE                         62400020
         LM    R14,R12,12(R13)                                          62800020
         BR    RETREG                                                   63200020
         SPACE                                                          63600020
CLEAN    LA    R1,PCBLIST          POINT TO INFO RETURN AREA            64000020
         LNR   R1,R1               INDICATE DEQUEUE                     64400020
         L     R15,APCBENQ         GET ADDRESS OF PCB ENQUEUE ROUTINE   64800020
         BALR  RETREG,R15          LINK TO IT                           65200020
         LTR   R15,R15             ZERO RETURN MEANS PCB DEQUEUED       65600020
         BZ    CLEAN               SO - GO TRY AGAIN                    66000020
         B     STGEXIT             4 CODE MEANS NO MORE                 66400020
         SPACE 2                                                        66800020
*********************************************************************** 67200020
*                                                                     * 67600020
*   SCAN MESSAGE BUFFER                                               * 68000020
*                                                                     * 68400020
*********************************************************************** 68800020
         SPACE                                                          69200020
SCAN     L     R3,KYWDEND          ADDR OF LAST DELIMITER               69600020
         AH    R3,ONEA             ADDR OF NEXT PARAMETER               70000020
         ST    R3,KYWDBGN          SAVE NEXT PARAMETER ADDR             70400020
         SR    R2,R2               CLEAR DELIMITER REG                  70800020
         TRT   0(9,R3),BLNK        SCAN FOR NEXT DELIMITER              71200020
         BZ    SYNTAXE             TOO BIG                              71600020
         ST    R1,KYWDEND          SAVE ADDR OF DELIMITER               72000020
         ST    R2,DELIMCD          SAVE DELIMITER CODE                  72400020
         SR    R1,R3               LENGTH OF PARAMETER IN REG 1         72800020
         LR    R3,R1               RETURN LENGTH IN REG 3               73200020
         BR    R6                  RETURN                               73600020
         EJECT                                                          74000020
*********************************************************************** 74400020
*                                                                     * 74800020
*   CONSTANTS FOR ABSOLUTE STORAGE ROUTINE                            * 75200020
*                                                                     * 75600020
*********************************************************************** 76000020
         SPACE                                                          76400020
STRGTR   TR    0(0,R1),HEXTABL                                          76800020
STRGPACK PACK  WORK1(0),0(0,R1)                                         77200020
         SPACE                                                          77600020
PMSSAVE  DC    18F'0'              REGISTER SAVE AREA                   78000020
PCBLIST  DS    0F                  P-LIST TO PCB ENQUEUE                78400020
LOW      DS    F                   STARTING ADDR                        78800020
HIGH     DS    F                   ENDING ADDR                          79200020
TJID     DC    H'0'                TJID (UNUSED IN PMS)                 79600020
         DS    C                   KEY (UNUSED IN PMS)                  80000020
STGSYNA  DC    A(STGSYN1)                                               80400020
         DC    A(STGSYN2)                                               80800020
         DC    A(STGSYN3)                                               81200020
         DC    A(STGSYN4)                                               81600020
         DC    A(STGSYN2)                                               82000020
STOMSK1  DC    X'000408040000'                                          82400020
STOMSK2  DC    X'000000000400'                                   XM5583 82800000
STOMSK3  DC    X'000400000008'                                          83200020
STGTITLE DC    C'* * * *   A B S O L U T E  S T O R A G E  P R I N T   X83600020
                * * * *'                                                84000020
STGSYN1  WTO   '        DELIMITER ERROR IN STORAGE OPERAND LIST',MF=L, X84400020
               ROUTCDE=(2),DESC=7                                       84800020
STGSYN2  WTO   '        LENGTH OF STORAGE ADDRESS GREATER THAN 6',MF=L,X85200020
               ROUTCDE=(2),DESC=7                                       85600020
STGSYN3  WTO   '        STARTING OMITTED IN STORAGE OPERAND',MF=L,     X86000020
               ROUTCDE=(2),DESC=7                                       86400020
STGSYN4  WTO   '        UNBALANCED PARENTHESIS',MF=L,                  X86800020
               ROUTCDE=(2),DESC=7                                       87200020
         EJECT                                                          87600020
         SYNEPS                                                         88000020
         SPACE                                                          88400020
         END                                                            88800020
