IMDPRQCB START                                                          00300020
         TITLE 'QCB TRACE EXECUTOR'                                     00600020
         SPACE                                                          00900020
*********************************************************************** 01200020
*                                                                     * 01250020
* A 183500-184000,285500-28600,4835000,4955000-497800            A41229 01300020
* A 591000-596500,909500-910000,918500-921000,945500             A41229 01310020
* C 186000,288000,309500,312000,486000,495000,498000             A41229 01350020
*                                                                     * 01500020
**                    ***  QCB TRACE ROUTINE  ***                    ** 01800020
*                                                                     * 02100020
*                                                                     * 02300021
*                                                                     * 02350021
* STATUS - OS/360 RELEASE 21.0                                        * 02360021
*                                                                     * 02370021
*                                                                     * 02380021
* FUNCTION -                                                          * 02390021
*                                                                     * 02392021
*         THIS ROUTINE PRINTS A TRACE OF ALL QUEUE CONTROL BLOCKS.    * 02394021
*    FOR EACH MAJOR QCB ALL MINOR QCB'S ARE PRINTED AND WITH EACH     * 02396021
*    MINOR QCB ALL QEL'S.  THE MAJOR QCB QUEUE ORIGIN IS LOCATED      * 02398021
*    DIFFERENTLY IN MVT AND MFT SYSTEMS.                              * 02398421
*                                                                     * 02398821
*    MVT -                                                            * 02399221
*                                                                     * 02399621
*         THE ADDRESS OF THE SECONDARY CVT IS EXTRACTED FROM THE      * 02399721
*         COMMON CSECT, THE ADDRESS OF THE FIRST MAJOR QCB IS THE     * 02399821
*         FOUND AT OFFSET X'14' IN THE SECONDARY CVT.                 * 02399921
*                                                                     * 02449921
*    MFT -                                                            * 02459921
*                                                                     * 02469921
*         IF THE COMMON CSECT INDICATES THAT AN MFT DUMP IS BEING     * 02479921
*         PROCESSED, THE CVT ADDRESS IN COMMON IS USED TO READ THE    * 02489921
*         ADDRESS OF THE ENTRY POINT TO ABTERM (CVT + X'58').  THE    * 02491921
*         FIRST MAJOR QCB IS ADDRESSED BY THE FOURTH WORD OF THE      * 02493921
*         ABTERM ROUTINE.                                             * 02495921
*                                                                     * 02497921
*    IN THE CASE OF PCP SYSTEMS, NO QCB'S EXIST, CONSEQUENTLY         * 02498321
*    IMDPRQCB PRINTS A DIAGNOSTIC AND EXITS.                          * 02498721
*                                                                     * 02499121
*    THE CONSTANTS 100 MAJOR QCB'S, 100 MINOR QCB'S AND 100 QEL'S     * 02499521
*    ARE USED TO DETECT INFINITE LOOPS IN THE QCB CHAINS.  IF MORE    * 02499621
*    THAN THE LIMIT OF A PARTICULAR CONTROL BLOCK IS TO BE FORMATTED  * 02499721
*    IT IS ASSUMED THAT THERE IS A LOOP IN THE CHAIN, A DIAGNOSTIC    * 02499821
*    MESSAGE IS ISSUED AND FORMATTING OF QCB'S ON THAT CHAIN IS       * 02549821
*    TERMINATED.  IMDPRQCB CONTINUES BY FORMATTING QCB'S ON THE NEXT  * 02559821
*    HIGHER CHAIN, EG, IF A LOOP IS DETECTED IN A QEL CHAIN,          * 02569821
*    FORMATTING CONTINUES WITH THE NEXT MINOR QCB AND ITS QEL'S.      * 02579821
*                                                                     * 02589821
*                                                                     * 02591821
* ENTRY POINTS -                                                      * 02593821
*                                                                     * 02595821
*    IMDPRQCB IS THE MAIN AND ONLY ENTRY POINT.  THIS ROUTINE         * 02597821
*    RECEIVES CONTROL FROM THE CONTROL/SCAN CSECT, IMDPRMSC IN        * 02598221
*    MODULE IMDPRCTL, WHENEVER THE QCBTRACE CONTROL STATEMENT IS      * 02598621
*    ENCOUNTERED.                                                     * 02599021
*                                                                     * 02599421
*                                                                     * 02599521
* INPUT -                                                             * 02599621
*                                                                     * 02599721
*    INFORMATION FROM THE DUMP DATA SET WHICH IS REQURED TO LOCATE    * 02633121
*    THE QCB QUEUES AND THE QCB DATA ITSELF IS OBTAINED BY USE OF     * 02643121
*    THE BRREAD PRIVATE MACRO INSTRUCTION.  THIS MACRO EXPANDS TO     * 02653121
*    THE CALLING SEQUENCE TO THE READ CONTROL ROUTINE IMDPRRDC.       * 02663121
*                                                                     * 02665121
*    THE FOLLOWING INFORMATION FROM THE IMDPRDMP COMMON CSECT IS      * 02665521
*    INPUT TO IMDPRQCB:                                               * 02665921
*                                                                     * 02666321
*    SWA:                                                             * 02666421
*         RDRSW - USED IN THE IMDPRQCB ERROR HANDLER TO DETERMINE     * 02666521
*         WHETHER CONTROL STATEMENTS ARE BEING ENTERED FROM THE       * 02677621
*         CONSOLE OR THE SYSIN DATA SET.  IN CASE CONTROL STATEMENTS  * 02687621
*         ARE BEING ENTERED FROM THE CONSOLE, THE QCB TRACE ERROR     * 02688021
*         MESSAGE IS ISSUED TO THE CONSOLE.                           * 02688421
*                                                                     * 02688821
*    SWB:                                                             * 02692521
*         IOERR AND FMTERR - THESE SWITCHES ARE USED IN THE IMDPRQCB  * 02694521
*         ERROR HANDLER TO DETERMINE THE CAUSE OF THE ERROR.          * 02694921
*                                                                     * 02695321
*    SWD:                                                             * 02695721
*         FLSHMODE - IF THIS SWITCH IS ON WHEN IMDPRQCB IS ENTERED,   * 02696121
*         CONTROL RETURNS IMMEDIATELY TO IMDPRCTL AND NO PROCESSING   * 02696221
*         TAKES PLACE.                                                * 02746221
*                                                                     * 02756221
*    SWE:                                                             * 02766221
*         MVTSW - TO DETERMINE THE TYPE OF THE DUMPED SYSTEM.         * 02776221
*                                                                     * 02786221
*    CVTADDR - TO OBTAIN THE ADDRESS OF THE CVT IN THE DUMPED SYSTEM  * 02788221
*    WHEN AN MFT QCB TRACE IS BEING PRODUCED.                         * 02790221
*                                                                     * 02792221
*    SECCVTA - TO OBTAIN THE ADDRESS OF THE SECONDARY CVT IN THE DUMP * 02794221
*    SYSTEM WHEN AN MVT QCB TRACE IS BEING PRODUCED.                  * 02794621
*                                                                     * 02795021
*    LINECNT - NUMBER OF LINES PER PAGE AS SPECIFIED BY LINECNT       * 02795421
*    PARAMETER IN PARM FIELD OF IMDPRDMP EXEC CARD.                   * 02795821
*                                                                     * 02795921
*    LINENUMB - CURRENT LINE NUMBER, USED TO DETERMINE POINT AT       * 02796021
*    WHICH NEW QCB TRACE PAGE TITLES SHOULD BE PRINTED.               * 02796121
*                                                                     * 02812821
*                                                                     * 02822821
* OUTPUT -                                                            * 02824821
*                                                                     * 02826821
*    ALL OUTPUT FOR THE QCB TRACE FUNCTION OF IMDPRDMP IS DIRECTED    * 02828821
*    BY IMDPRQCB.                                                     * 02829221
*                                                                     * 02829321
*    IF AN ERROR IS ENCOUNTERED DURING THE QCB TRACE, THE ERROR       * 02829421
*    MESSAGE IS WRITTEN TO THE SYSPRINT DATA SET;  AND IF CONTROL     * 02835021
*    STATEMENTS ARE BEING ENTERED FROM THE CONSOLE, THE ERROR MESSAGE * 02837021
*    IS ALSO WRITTEN TO THE CONSOLE.                                  * 02839021
*                                                                     * 02839421
*                                                                     * 02839821
* EXTERNAL REFERENCES -                                               * 02840221
*                                                                     * 02840321
*    IMDPRDMP ROUTINES:                                               * 02840421
*                                                                     * 02840521
*    1.  IMDPRWTR - TO WRITE OUTPUT TO THE PRINTER DATA SET.  CALLING * 02880321
*         SEQUENCE TO IMDPRWTR IS GENERATED BY THE BRWRITE PRIVATE    * 02890321
*         MACRO INSTRUCTION.                                          * 02900321
*                                                                     * 02910321
*    2.  IMDPRRDC - THE DUMP READ CONTROL ROUTINE.  DUMP INFORMATION  * 02920321
*         IS OBTAINED BY USE OF THE BRREAD PRIVATE MACRO INSTRUCTION, * 02933621
*         WHICH GENERATES THE CALLING SEQUENCE TO IMDPRRDC.           * 02943621
*                                                                     * 02945621
*    3.  ADRCNVT - THE THREE BYTE, BINARY TO CHARACTER HEX,           * 02946021
*         CONVERSION ROUTINE IN IMDPRSYN.                             * 02946421
*                                                                     * 02946821
*    4.  IMDPRMSG - TO WRITE THE QCB TRACE ERROR MESSAGE ON THE       * 02951221
*         SYSPRINT DATA SET.  THE BRPRTMSG PRIVATE MACRO INSTRUCTION  * 02953221
*         IS USED TO INVOKE IMDPRMSG.                                 * 02955221
*                                                                     * 02955621
*    OS/360 SERVICES -                                                * 02955721
*                                                                     * 02966721
*    WTO - IF CONTROL STATEMENTS ARE BEING ENTERED FROM THE CONSOLE,  * 02976721
*         THE QCB TRACE ERROR MESSAGE IS WRITTEN TO THE CONSOLE BY    * 02977121
*         MEANS OF WTO.                                               * 02977521
*                                                                     * 02977921
*                                                                     * 02981621
* EXITS, NORMAL -                                                     * 02983621
*                                                                     * 02984021
*    CONTROL ALWAYS RETURNS TO IMDPRMSC IN MODULE IMDPRCTL.  ALL      * 02984421
*    ERRORS ARE HANDLED BY IMDPRQCB.                                  * 02984821
*                                                                     * 02985221
*                                                                     * 02988921
* EXITS, ERROR - NONE.                                                * 02990921
*                                                                     * 02991321
*                                                                     * 02991721
* TABLES/WORK AREA - NONE.                                            * 02992121
*                                                                     * 02992521
*                                                                     * 03042521
* ATTRIBUTES - REUSABLE.                                              * 03052521
*                                                                     * 03062521
*                                                                     * 03072521
* CHARACTER CODE DEPENDENCY - EBCDIC.                                 * 03082521
*                                                                     * 03084521
*                                                                     * 03086521
* NOTES - NONE.                                                       * 03088521
*                                                                     * 03090521
*********************************************************************** 03090921
         EJECT                                                          03092521
*/*IMDPRQCB: CHART (SEQ) */                                             03350021
*/*HEADER                                                               03360021
*/*IMDPRQCB - QCB TRACE EXECUTOR FLOWCHARTS                             03370021
*/*                                                   PAGE #      */    03380021
*/*IMDPRQCB: E START */                                                 03392021
*/* P SET UP ADDRESSABILITY */                                          03394021
*/* P SET UP ERROR RTN ADDR */                                          03396021
*/* D (YES,QCBDONE,NO,) IS THIS FLUSH MODE */                           03398021
*/* S BRWRITE: SKIP TO TOP OF PAGE */                                   03398421
*/* D (YES,QCBTRC1,NO,) MVT DUMP */                                     03398821
*/* S BRREAD: GET ABTERM POINTER FROM CVT */                            03399221
*/* P (,QCBTRC2) POINT TO TOP QCB ADDR PTR (12 INTO ABTERM) */          03399621
*/*QCBTRC1: P POINT TO TOP QCB ADDR PTR (20 INTO 2ND CVT) */            03399721
*/*QCBTRC2: S BRREAD: GET TOP QCB ADDR PTR */                           03399821
*/* S BRREAD: GET TOP QCB ADDR */                                       03399921
*/* P SAVE TOP QCB ADDR */                                              03449921
*/* D (YES,NOQCBS,NO,) IS THE ADDR = 0 */                               03459921
*/* P SET MAJOR QCB LIMIT COUNT = 100 */                                03469921
*/*MAJLOOP: P SAVE MAJ QCB COUNT */                                     03479921
*/* D (YES,MAJLOOP1,NO,) TOP OF PAGE */                                 03489921
*/* S QCBPRNT: SPACE A LINE */                                          03491921
*/*MAJLOOP1: D (YES,QCBDONE,NO,) PTR TO NEXT MAJ QCB = 0 */             03493921
*/* S BRREAD: GET A QCB */                                              03495921
*/* P SAVE PTR TO NEXT MAJOR QCB */                                     03497921
*/* P MOVE 'MAJOR' TO BUFFER */                                         03498321
*/* S ADRCNVT: CONVERT THE MAJOR QCB ADDR */                            03498721
*/* P MOVE 'NAME' TO BUFFER */                                          03499121
*/* S BRREAD: GET PTR TO FIRST MINOR */                                 03499521
*/* P SAVE ADDR OF FIRST MINOR */                                       03499621
*/* S BRREAD: GET FIRST PART OF NAME FROM MAJOR */                      03499721
*/* P MOVE FIRST PART OF NAME TO BUFFER */                              03499821
*/* S BRREAD: GET 2ND PART OF NAME */                                   03533221
*/* P MOVE 2ND PART OF NAME TO BUFFER */                                03543221
*/* S QCBPRNT: PRINT MAJOR */                                           03553221
*/* P (,MINLOOP) SET MINOR QCB LIMIT = 100 */                           03563221
*/*MINLOOP: P SAVE LOOP COUNT */                                        03565221
*/* D (YES,MINLOOP1,NO,) TOP OF PAGE */                                 03565621
*/* S QCBPRNT: SPACE 1 LINE */                                          03566021
*/*MINLOOP1: D (NO,MINLOOP3,YES,) ADDR OF NEXT MINOR = 0 */             03566421
*/* D (NO,MAJLOOP,YES,) REACHED MAJOR QCB LIMIT */                      03566521
*/*  S QCBPRNT: SPACE A LINE */                                         03577621
*/* P MOVE QCB LOOP MSG TO BUFFER */                                    03587621
*/*  S (,QCBDONE) QCBPRNT: PRINT THE MSG */                             03588021
*/*MINLOOP3: S BRREAD: GET NEXT MINOR */                                03588421
*/* P SAVE ADDR OF FIRST QEL */                                         03588821
*/* S BRREAD: GET ADDR OF NEXT MINOR */                                 03592521
*/* P SAVE ADDR OF NEXT MINOR */                                        03594521
*/* P MOVE 'MINOR' TO BUFFER */                                         03594921
*/* S ADRCNVT: CONVERT QCB ADDR */                                      03595321
*/* P MOVE 'NAME' TO BUFFER */                                          03595721
*/* S BRREAD: GET THE NAME FIELD OF MINOR QCB */                        03596121
*/* D (YES,QCBMIN2,NO,) IS LENGTH OF MINOR NAME = 0 */                  03596221
*/* S HEXCNVT: CONVERT PROT. KRY OR 'FF' */                             03646221
*/* D (LOW,QCBMIN2,HIGH,QCBMIN1,EQU,) COMPARE NAME LENGTH TO 1 */       03656221
*/* P (,QCBMIN2) MOVE NAME TO BUFFER */                                 03666221
*/*QCBMIN1: P MOVE 2 BYTES OF NAME TO BUFFER */                         03676221
*/* P DECREASE LENGTH BY TWO */                                         03686221
*/* D (NO,QCBMIN2,YES,) IS LENGTH > 0 */                                03688221
*/* P SET UP PTRS FOR REMAINDER OF NAME */                              03690221
*/*NMLOOP1: P SET INCREMENT VALUE = 4; SET COMP. REG FOR BXLE */        03692221
*/*NMLOOP2: S BRREAD: GET 4 BYTES OF NAME */                            03694221
*/* P DECREMENT LENGTH BY 4 */                                          03694621
*/* D (NO,LASTMOVE,YES,) IS LENGTH > 0 */                               03695021
*/* P MOVE 4 BYTES OF NAME TO BUFFER */                                 03695421
*/* P UP PTR TO NEXT BYTES OF NAME */                                   03695821
*/* D (NO,NMLOOP2,YES,) FUL LINE */                                     03695921
*/* S QCBPRNT: PRINT THE LINE */                                        03696021
*/* P (,NMLOOP1) RESET BUFFER PTR */                                    03696121
*/*LASTMOVE: P ADD FOUR BACK TO LENGTH */                               03712821
*/* D (YES,QCBMIN2,NO,) IS IT NOW = 0 */                                03722821
*/* P MOVE LAST PART OF NAME TO BUFFER */                               03724821
*/*QCBMIN2: S (,QCBQEL1) QCBPRNT: PRINT THE LINE */                     03726821
*/*QCBQEL1: P SET QEL LIMIT TO 100 */                                   03728821
*/*QCBQEL1A: D (NO,QCBQEL1B,YES,) ADDR OF NEXT QEL = 0 */               03729221
*/* D (NO,MINLOOP,YES,) IS MINOR LIMIT = 0 */                           03729321
*/* S QCBPRNT: SPACE A LINE */                                          03729421
*/* P MOVE QCB LOOP MSG TO BUFFER */                                    03735021
*/* S (,MAJLOOP) QCBPRNT: PRINT THE MSG */                              03737021
*/*QCBQEL1B: S BRREAD: GET A QEL */                                     03739021
*/* P SAVE NEXT QEL ADDR AND MUST COMPLETE FLAGS */                     03739421
*/* P MOVE 'QEL' TO BUFFER */                                           03739821
*/* S ADRCNVT: CONVERT QEL ADDR */                                      03740221
*/* P MOVE 'TCB' TO BUFFER */                                           03740321
*/* S BRREAD: GET TCB ADDR */                                           03740421
*/* S ADRCNVT: CONVERT TCB ADDR */                                      03740521
*/* S BRREAD: GET EXCLUSIVE OR SHARED FLAGS */                          03780321
*/* D (NO,QCBQEL2,YES,) IS IT SHARED */                                 03790321
*/* P (,QCBQEL3) MOVE 'SHARED' TO BUFFER */                             03800321
*/*QCBQEL2: P MOVE 'EXCLUSIVE' TO BUFFER */                             03810321
*/*QCBQEL3: D (NO,QCBQEL4,YES,) IS IT SYSTEM MUST COMPLETE */           03820321
*/* P (,QCBQEL5) MOVE 'SYSTEM MUST COMPLETE' TO BUFFER */               03833621
*/*QCBQEL4: D (NO,QCBQEL5,YES,) IS IT STEP MUST COMPLETE */             03843621
*/* P (,QCBQEL5) MOVE 'STEP MUST COMPLETE' TO BUFFER */                 03845621
*/*QCBQEL5: S QCBPRNT: PRINT THIS QEL */                                03846021
*/* D (NO,QCBQEL1A,YES,) QEL LIMIT CNT = 0 */                           03846421
*/* S QCBPRNT: SPACE LINE */                                            03846821
*/* P MOVE QEL LOOP MSG TO BUFFER */                                    03851221
*/* S (,MINLOOP) QCBPRNT: PRINT THE MSG */                              03853221
*/*QCBPRNT: P SAVE REGS */                                              03855221
*/* D (YES,QCBTITLE,NO,) TOP OF PAGE */                                 03855621
*/*QCBPRT: S BRWRITE: PRINT THE LINE */                                 03855721
*/* P RESTORE REGS */                                                   03866721
*/* R RETURN VIA R9 */                                                  03876721
*/*QCBTITLE: P SAVE CURRENT BUFFER CONTENTS */                          03877121
*/* P CLEAR BUFFER */                                                   03877521
*/* P MOVE TITLE TO BUFFER */                                           03877921
*/* S BRWRITE: PRINT TITLE */                                           03881621
*/* P (,QCBPRT) RESTORE LINE TO PRINT */                                03883621
*/*NOQCBS: P MOVE NO QCB MSG TO BUFFER */                               03884021
*/* S (,QCBDONE) QCBPRNT: PRINT THE MSG */                              03884421
*/*QCBERROR: P SET UP ADDRESSABILITY */                                 03884821
*/* P MOVE QCB ERROR MSG TO WTO LIST */                                 03885221
*/* P MOVE ERROR MSG (BASED ON ERROR SW) TO WTO LIST */                 03888921
*/* S BRPRTMSG: PRINT ERROR MSG ON SYSPRINT */                          03889021
*/* D (YES,QCBDONE,NO,) COMMANDS COMING FROM SYSIN */                   03891021
*/* L WRITE MSG TO OPERATOR */                                          03891421
*/* M TURN OFF ERROR SWITCHES */                                        03891821
*/*QCBDONE: P RESTORE PREVIOUS ERROR RTN ADDR */                        03892221
*/* P RESTORE REGS */                                                   03892321
*/* R RETURN */                                                         03892421
*/*IMDPRQCB: END */                                                     03892621
         EJECT                                                          03896321
         EQUATES                                                        03900020
         COMMON                                                         04200020
*                                                                 M3179 04250020
         OUTBUFM                                                        04500020
IMDPRQCB CSECT                                                          04800020
CVTBTERM EQU   52                                                       05100020
         STM   R14,R12,12(R13)     SAVE CALLER'S REGISTERS              05400020
         BALR  BASE1,0             ESTABLISH REG 11 AS BASE             05700020
         USING *,BASE1                                                  06000020
QCBBASE  LA    R0,QCBSAVE          SAVE AREA CHAINNING                  06300020
         ST    R0,8(R13)                                                06600020
         ST    R13,QCBSAVE+4                                            06900020
         LR    R13,R0                                                   07200020
         SPACE                                                          07500020
         USING COMMON,COMBASE      COMMON CSECT BASED ON REG 12         07800020
         USING OUTBUF,BUFREG                                            08100020
         SPACE                                                          08400020
         MVC   QCBERSV,ERRADDR     SAVE CURRENT ERROR ROUTINE ADDR      08700020
         LA    R15,QCBERROR        LOAD ADDR OF QCBTRACE ERROR ROUTINE  09000020
         ST    R15,ERRADDR         STORE AS ERROR ADDRESS               09300020
         TM    SWD,FLSHMODE        IS THIS FLUSH MODE                   09600020
         BO    QCBDONE             YES--RETURN AND DON'T DO ANYTHING    09900020
*                                  HAS BEEN DONE                        10200020
         BRWRITE SKIP              SKIP TO LINE ONE                     10500020
         L     BUFREG,CURBUF       LOAD BUFFER ADDRESS                  10800020
        TM    SWE,MVTSW          IS THIS MVT SYSTEM?                    11100020
         BO    QCBTRC1             YES GET QCB ORIGIN FOR 2-ND CVT      11400020
         L     PREG,CVTADDR        GET THE CVT PTR                      11700020
         LA    PREG,CVTBTERM(PREG)  POINT TO THE ADDR OF ABTERM         12000020
         BRREAD  (PREG),DATA,TJID=0                                     12300020
         L     PREG,0(PREG)       GET THE ADDR OF ABTERM                12600020
         LA    PREG,12(PREG)    GET THE ADDR OF TOP QCB                 12900020
         B     QCBTRC2                                                  13200020
QCBTRC1  EQU   *                                                        13500020
         L     PREG,SECCVTA        LOAD ADDR OF SECONDARY CVT           13800020
         LA    PREG,IEAQQCBO(PREG) LOAD ADDR OF QCB ORIGIN PTR          14100020
QCBTRC2        EQU   *                                                  14400020
         BRREAD  (PREG),DATA,TJID=0                                     14700020
         L     PREG,0(PREG)        LOAD QCB ORIGIN PTR                  15000020
         BRREAD  (PREG)                                                 15300020
         MVC   NMAJ(4),0(PREG)     MOVE MAJOR QCB ADDR TO NMAJ          15600020
         OC    NMAJ+1(3),NMAJ+1    ARE THERE ANY MAJOR QCBS             15900020
         BZ    NOQCBS              NO--WRITE MSG AND RETURN             16200020
         SPACE 2                                                        16500020
*********************************************************************** 16800020
*                                                                     * 17100020
*   MAJOR QCB ROUTINE                                                 * 17400020
*                                                                     * 17700020
*********************************************************************** 18000020
         SPACE                                                          18300020
         LA    R3,100              SET LIMIT OF QCB COUNT        A41229 18350020
MAJLOOP  ST    R3,MAJCOUNT         STORE CURRENT COUNTER VALUE   A41229 18400020
         LH    R7,LINENUM          LOAD NUMB OF LINES PER PAGE - 2      18600020
         C     R7,LINECNT          AM I AT TOP OF PAGE                  18900020
         BNH   MAJLOOP1            YES--BYPASS SPACING                  19200020
         BAL   R9,QCBPRNT          LINES                                19500020
MAJLOOP1 L     R2,NMAJ             LOAD PTR TO NEXT MAJOR QCB           19800020
         LA    R2,0(R2)            CLEAR HIGH ORDER BYTE                20100020
         LTR   R2,R2               IS IT ZERO                           20400020
         BZ    QCBDONE             YES--ALL DONE                        20700020
         BRREAD  (R2)                                                   21000020
         MVC   NMAJ(4),0(PREG)     SAVE ADDR OF NEXT MAJOR QCB          21300020
         MVC   ADDR(5),MAJOR       MOVE 'MAJOR' TO BUFFER               21600020
         ST    R2,WORK1            STORE QCB ADDR TO BE CONVERTED       21900020
         LA    PREG,WORK1          ADDR OF VALUE TO BE CONVERTED        22200020
         LA    R4,ADDR+6           LOCATION OF QCB ADDR IN BUFFER       22500020
         L     R15,AADRCNVT        LOAD ADDR OF ADRCNVT ROUTINE         22800020
         BALR  RETREG,R15          LINK TO IT                           23100020
         MVC   ADDR+15(4),QCBNAME  MOVE 'NAME' TO BUFFER                23400020
         LA    PREG,8(R2)          ADDR OF PTR TO FIRST MINOR           23700020
         BRREAD  (PREG)                                                 24000020
         MVC   NMIN(4),0(PREG)     SAVE ADDR OF FIRST MINOR             24300020
         LA    PREG,12(R2)         ADDR OF NAME                         24600020
         BRREAD  (PREG)                                                 24900020
         MVC   ADDR+20(4),0(PREG)  MOVE FIRST PART OF NAME              25200020
         LA    PREG,16(R2)                                              25500020
         BRREAD  (PREG)                                                 25800020
         MVC   ADDR+24(4),0(PREG)  MOVE SECOND PART OF NAME             26100020
         BAL   R9,QCBPRNT          GO PRINT MAJOR                       26400020
         SPACE 2                                                        26700020
*********************************************************************** 27000020
*                                                                     * 27300020
*   MINOR QCB ROUTINE                                                 * 27600020
*                                                                     * 27900020
*********************************************************************** 28200020
         SPACE                                                          28500020
         LA    R3,100              SET LIMIT OF MINOR QCB LOOP   A41229 28550020
MINLOOP  ST    R3,MINCOUNT         STORE CURRENT COUNT VALUE     A41229 28600020
         LH    R7,LINENUM          LOAD NUMB OF LINES PER PAGE - 2      28800020
         C     R7,LINECNT          AM I AT TOP OF PAGE                  29100020
         BNH   MINLOOP1            YES--BYPASS SPACING                  29400020
         BAL   R9,QCBPRNT          SPACE ONE LINE                       29700020
MINLOOP1 L     R2,NMIN             LOAD ADDR OF NEXT MINOR              30000020
         LA    R2,0(R2)            CLEAR HIGH ORDER BYTE                30300020
         LTR   R2,R2               IS IT ZERO                           30600020
         BNZ   MINLOOP3            NO--BRANCH AROUND COUNT TEST  A41229 30950020
         L     R3,MAJCOUNT         PICK UP CURREM MAJOR CNT      A41229 30960020
         BCT   R3,MAJLOOP          BRANCH IF NOT ZERO BACK TO    A41229 31000020
*                                  FORMAT NEXT MAJOR             A41229 31050020
         BAL   R9,QCBPRNT          SPACE A LINE                  A41229 31060020
         MVC   QCBLOOP+17(3),QCB   MOVE 'QCB' TO LOOP MESSAGE    A41229 31100020
         MVC   ADDR(L'QCBLOOP),QCBLOOP  MOVE MSG TO OUTPUT LINE  A41229 31150020
         BAL   R9,QCBPRNT          LINK TO PRINT ROUTINE         A41229 31160020
         B     QCBDONE             EXIT                          A41229 31170020
MINLOOP3 BRREAD  (R2)                                            A41229 31200020
         MVC   NQEL(4),0(PREG)     SAVE ADDR OF FIRST QEL               31500020
         LA    PREG,8(R2)          ADDR OF PTR TO NEXT MINOR            31800020
         BRREAD  (PREG)                                                 32100020
         MVC   NMIN(4),0(PREG)     SAVE ADDR OF NEXT MINOR              32400020
         MVC   ADDR+6(5),MINOR     MOVE 'MINOR' TO BUFFER               32700020
         ST    R2,WORK1            STORE QCB ADDR TO BE CONVERTED       33000020
         LA    PREG,WORK1                                               33300020
         LA    R4,ADDR+12                                               33600020
         L     R15,AADRCNVT        LOAD ADDR OF ADRCNVT ROUTINE         33900020
         BALR  RETREG,R15          LINK TO IT                           34200020
         MVC   ADDR+21(4),QCBNAME  MOVE 'NAME' TO BUFFER                34500020
         LA    PREG,12(R2)                                              34800020
         BRREAD  (PREG)                                                 35100020
         SR    R3,R3               CLEAR R3                             35400020
         IC    R3,0(PREG)          LOAD LENGTH OF MINOR NAME            35700020
         LTR   R3,R3               LENGTH ZERO                          36000020
         BZ    QCBMIN2             YES--NO NAME                         36300020
         LA    R5,1(PREG)          ADDR OF PROT KEY OR 'FF' IN MINOR    36600020
         LA    R4,ADDR+26          ADDR OF WHERE TO PUT IT              36900020
         LR    R8,R1               SAVE R1                              37200020
         HEXCNVT (4),(5),1         CONVERT IT TO BE PRINTED             37500020
         LR    R1,R8               RESTORE R1                           37800020
         CH    R3,ONEA             COMPARE LN TO 1                      38100020
         BL    QCBMIN2             ZERO--NO NAME                        38400020
         BH    QCBMIN1             TWO OR MORE                          38700020
         MVC   ADDR+30(1),2(PREG)  MOVE NAME TO BUFFER                  39000020
         B     QCBMIN2             PRINT MINOR                          39300020
         SPACE                                                          39600020
QCBMIN1  MVC   ADDR+30(2),2(PREG)  MOVE FIRST 2 BYTES OF NAME           39900020
         SH    R3,TWO              DECR LENGTH                          40200020
         BNP   QCBMIN2             GO TO PRINT MINOR                    40500020
         LA    R2,16(R2)           ADDR OF REMAINDER OF NAME            40800020
         LA    R8,ADDR+32          LOC OF BEG OF NM IN BUFFER           41100020
NMLOOP1  LA    R4,4                LOAD INCR TO R4                      41400020
         LA    R5,ADDR+115         LOAD END ADDR (COMMPARITOR)          41700020
NMLOOP2  BRREAD  (R2)                                                   42000020
         SH    R3,FOUR             SUBTRACT 4 FROM LENGTH               42300020
         BNP   LASTMOVE            BR OUT IF LE 0 FOR LAST MOVE         42600020
         MVC   0(4,R8),0(PREG)     MOVE 4 BYTES OF NAME                 42900020
         LA    R2,4(R2)            INCR TO NEXT FOUR BYTES OF NAME      43200020
         BXLE  R8,R4,NMLOOP2       LOOP FOR ENTIRE PAGE IF NECESSARY    43500020
         BAL   R9,QCBPRNT          LINE FULL--PRINT IT                  43800020
         LA    R8,ADDR+30          LOAD BEG OF NM IN BUFFER             44100020
         B     NMLOOP1             START WITH NEW LINE                  44400020
         SPACE                                                          44700020
LASTMOVE AH    R3,FOUR             ADD THE 4 BACK                       45000020
         BZ    QCBMIN2             ALL DONE--PRINT                      45300020
         BCTR  R3,0                DECR 1 FOR EXECUTE                   45600020
         EX    R3,QCBMOVE          MOVE LAST PART OF NAME               45900020
QCBMIN2  BAL   R9,QCBPRNT          PRINT MINOR                          46200020
         SPACE 2                                                        46500020
*********************************************************************** 46800020
*                                                                     * 47100020
*   QEL ROUTINE                                                       * 47400020
*                                                                     * 47700020
*********************************************************************** 48000020
         SPACE                                                          48300020
QCBQEL1  LA    R3,100              SET LIMIT OF NUMBER OF QELS   A41229 48350020
QCBQEL1A L     R2,NQEL             LOAD ADDR OF NEXT QEL         A41229 48600020
         LA    R2,0(R2)            CLEAR HIGH ORDER BYTE                48900020
         LTR   R2,R2               TEST FOR ZERO                        49200020
         BNZ   QCBQEL1B            BR IF DONE WITH QEL'S         A41229 49500020
         L     R3,MINCOUNT         PICK UP QCB COUNT             A41229 49550020
         BCT   R3,MINLOOP          BRANCH IF NOT TOO MANY        A41229 49600020
*                                  MINORS TO PRINT NEXT MINOR    A41229 49650020
         BAL   R9,QCBPRNT          SPACE A LINE                  A41229 49700020
         MVC   QCBLOOP+17(3),QCB   MOVE 'QCB' TO LOOP MSG        A41229 49750020
         MVC   ADDR(L'QCBLOOP),QCBLOOP  MOVE MSG TO OUTPUT LINE  A41229 49760020
         BAL   R9,QCBPRNT          LINK TO PRINT ROUTINE         A41229 49770020
         B     MAJLOOP             BRANCH TO PRINT NEXT MAJOR    A41229 49780020
QCBQEL1B BRREAD  (R2)                                            A41229 49800020
         MVC   NQEL(4),0(PREG)     SAVE ADDR OF NEXT QEL AND MUST COMP  50100020
*                                  FLAGS OF THIS QEL                    50400020
         MVC   ADDR+12(3),QEL      MOVE 'QEL' TO BUFFER                 50700020
         ST    R2,WORK1            SET UP TO INSERT QEL ADDR IN BUFFER  51000020
         LA    PREG,WORK1                                               51300020
         LA    R4,ADDR+16                                               51600020
         L     R15,AADRCNVT        LOAD ADDR OF ADRCNVT ROUTINE         51900020
         BALR  RETREG,R15          LINK TO IT                           52200020
         MVC   ADDR+25(3),TCB      MOVE 'TCB' TO BUFFER                 52500020
         LA    PREG,8(R2)          ADDR OF TCB ADDR                     52800020
         BRREAD  (PREG)                                                 53100020
         LA    R4,ADDR+29          PLACE TCB ADDR IN OUTPUT BUFFER      53400020
         L     R15,AADRCNVT        LOAD ADDR OF ADRCNVT ROUTINE         53700020
         BALR  RETREG,R15          LINK TO IT                           54000020
         LA    PREG,4(R2)          ADDR OF SHRD AND EXCL FLAGS          54300020
         BRREAD  (PREG)                                                 54600020
         TM    0(PREG),X'80'       TEST FOR SHARED                      54900020
         BZ    QCBQEL2             BR IF EXCLUSIVE                      55200020
         MVC   ADDR+38(6),SHAR     MOVE 'SHARED' TO BUFFER              55500020
         B     QCBQEL3                                                  55800020
QCBQEL2  MVC   ADDR+38(9),EXCL     MOVE 'EXCLUSIVE' TO BUFFER           56100020
QCBQEL3  TM    NQEL,X'20'          IS IT SYSTEM MUST COMPLETE           56400020
         BZ    QCBQEL4             BR IF NOT                            56700020
         MVC   ADDR+50(20),SYSMCPLT MOVE 'SYSTEM MUST COMPLETE' TO      57000020
*                                  BUFFER                               57300020
         B     QCBQEL5             BR TO PRINT                          57600020
QCBQEL4  TM    NQEL,X'10'          IS IT STEP MUST COMPLETE             57900020
         BZ    QCBQEL5             BR IF NOT TO PRINT                   58200020
         MVC   ADDR+50(18),STPMCPLT MOVE 'STEP MUST COMPLETE' TO BUFFER 58500020
QCBQEL5  BAL   R9,QCBPRNT          PRINT THIS QEL                       58800020
         BCT   R3,QCBQEL1A         LOOP THROUGH ALL QEL'S        A41229 59100020
*                                  ASSOCIATED WITH CURRRENT      A41229 59400020
*                                  MINIOR                        A41229 59450020
***  FALL THROUGH MEANS TOO MANY QEL-S ***                       A41229 59500020
         BAL   R9,QCBPRNT          SPACE A LINE                  A41229 59502020
         MVC   QCBLOOP+17(3),QEL   MOVE 'QEL' TO LOOP MSG        A41229 59510020
         MVC   ADDR(L'QCBLOOP),QCBLOOP  MOVE MSG TO OUTPUT LINE  A41229 59550020
         BAL   R9,QCBPRNT          BRANCH TO PRINT MESSAGE       A41229 59600020
         B     MINLOOP             BR TO PRINT NEXT MINOR        A41229 59650020
         SPACE 3                                                        59700020
*********************************************************************** 60000020
*                                                                     * 60300020
*   THIS ROUTINE PRINTS THE TITLE AND QUEUE CONTROL BLOCKS            * 60600020
*                                                                     * 60900020
*********************************************************************** 61200020
         SPACE                                                          61500020
QCBPRNT  ST    R1,QCBREGS          SAVE REGS                            61800020
         STM   R6,R9,QCBREGS+4                                          62100020
         L     BUFREG,CURBUF       LOAD ADDR OF BUFFER                  62400020
         L     LINEREG,LINECNT     LOAD LINE COUNT                      62700020
         LH    R7,LINENUMB         LOAD NUMBER OF LINES/PAGE            63000020
         SH    R7,TWO                                                   63300020
         CR    LINEREG,R7          AM I AT TOP OF PAGE                  63600020
         BNL   QCBTITLE            YES--PRINT QCB PAGE TITLE            63900020
QCBPRT   BRWRITE 1                 GO PRINT                             64200020
         L     R1,QCBREGS          RESTORE                              64500020
         LM    R7,R9,QCBREGS+8     REGISTERS                            64800020
         BR    R9                  RETURN TO CALLER                     65100020
         SPACE 2                                                        65400020
QCBTITLE MVC   QCBBUFSV(132),ADDR  SAVE PRESENT BUFFER                  65700020
         MVI   ADDR,X'40'          CLEAR BUFFER                         66000020
         MVC   ADDR+1(131),ADDR                                         66300020
         MVC   ADDR+26(68),QCBTTL  MOVE TITLE TO BUFFER                 66600020
         BRWRITE 3                 GO PRINT TITLE AND SPACE 3 LINES     66900020
         MVC   ADDR(132),QCBBUFSV  RESTORE LINE TO BE PRINTED IN        67200020
*                                  CURRENT BUFFER                       67500020
         B     QCBPRT              GO PRINT LINE                        67800020
         EJECT                                                          68100020
*********************************************************************** 68400020
*                                                                     * 68700020
*   NO MAJOR QCBS....WRITE A MSG TO THAT EFFECT AND RETURN            * 69000020
*                                                                     * 69300020
*********************************************************************** 69600020
         SPACE                                                          69900020
NOQCBS   MVC   ADDR(13),NOQMSG     MOVE MSG TO BUFFER                   70200020
         BAL   R9,QCBPRNT          PRINT MSG                            70500020
         B     QCBDONE             END QCB TRACE                        70800020
         SPACE 2                                                        71100020
*********************************************************************** 71400020
*                                                                     * 71700020
*   PERMANENT I/O OR FORMAT ERROR ON TAPE DURRING QCB TRACE....       * 72000020
*                  ****   TERMINATE TRACE   ****                      * 72300020
*                                                                     * 72600020
*********************************************************************** 72900020
         SPACE                                                          73200020
         DROP  BASE1                                                    73500020
         USING *,R15               ERROR HANDLER TEMP BASED ON REG 15   73800020
QCBERROR LA    R13,QCBSAVE         POINT TO QCB'S SAVE AREA             74100020
         LM    R14,R12,12(R13)     RESTORE QCB'S REGS                   74400020
         DROP  R15                                                      74700020
         USING QCBBASE,BASE1                                            75000020
         MVC   QCBERWTO+31(26),QCBERMSG  MOVE QCB ERROR MSG TO          75300020
*                                        WTO LIST                       75600020
         MVC   QCBWORK1(1),SWB     FETCH SWITCH INDICATING ERROR TYPE   75900020
         NI    QCBWORK1,IOERR+FMTERR  RESET ALL BUT POSSIBLE I/O        76200020
*                                        AND FORMAT ERRORS              76500020
         SR    R3,R3               CLEAR REG 3 FOR IC                   76800020
         IC    R3,QCBWORK1         ERROR SWITCHES TO REG 3              77100020
         SRL   R3,4                SHIFT RIGHT TO USE AS INDEX          77400020
         L     R5,AERRMSGA(R3)     LOAD CORRECT ERROR MSG ADDRESS       77700020
         MVC   QCBERWTO+4(26),0(R5)  MOVE ERROR MSG TO WTO LIST         78000020
         BRPRTMSG  QCBERWTO+4,53   PRINT ERROR MSG ON SYSPRINT          78300020
         TM    SWA,RDRSW           IF COMMANDS ARE BEING ENTERED FROM   78600020
*                                  SYSIN,                               78900020
         BZ    QCBDONE             BRANCH OUT BEFORE ISSUING WTO        79200020
*                                  OTHERWISE, TELL OPERATOR ABOUT       79500020
*                                  ERROR                                79800020
         WTO   MF=(E,QCBERWTO)                                          80100020
         NI    SWB,255-IOERR-FMTERR  RESET I/O AND FORMAT ERROR         80400020
*                                    INDICATORS                         80700020
         EJECT                                                          81000020
*********************************************************************** 81300020
*                                                                     * 81600020
*   ALL DONE....RETURN TO CALLER                                      * 81900020
*                                                                     * 82200020
*********************************************************************** 82500020
         SPACE                                                          82800020
QCBDONE  MVC   ERRADDR,QCBERSV     RESTORE PREVIOUS ERROR ROUTINE ADDR  83100020
         L     R13,QCBSAVE+4       RESTORE CALLER'S REGISTERS           83400020
         LM    R14,R12,12(R13)                                          83700020
         BR    RETREG              RETURN TO CALLER                     84000020
         SPACE 2                                                        84300020
*  EXECUTABLE INSTRUCTION                                               84600020
         SPACE                                                          84900020
QCBMOVE  MVC   0(0,R8),0(PREG)                                          85200020
         EJECT                                                          85500020
*********************************************************************** 85800020
*                                                                     * 86100020
*   CONSTANTS AND SAVE AREAS FOR QCBTRACE ROUTINE                     * 86400020
*                                                                     * 86700020
*********************************************************************** 87000020
         SPACE                                                          87300020
QCBERWTO DC    AL2(57)             ERROR WTO LIST                       87600020
         DC    X'8000'                                                  87900020
         DC    CL53' '                                                  88200020
         DC    X'0200'             DESC                                 88500020
         DC    X'4000'             ROUTCDE                              88800020
         SPACE                                                          89100020
QCBSAVE  DC    18F'0'              QCB TRACE SAVE AREA                  89400020
QCBREGS  DC    5F'0'                                                    89700020
QCBERSV  DC    F'0'                SAVE AREA FOR ERRADDR                90000020
NMAJ     DC    F'0'                                                     90300020
NMIN     DC    F'0'                                                     90600020
NQEL     DC    F'0'                                                     90900020
MAJCOUNT DC    F'0'              - NUMBER OF MAJOR QCB'S F'MTED  A41229 90950020
MINCOUNT DC    F'0'              - NUMBER OF MINOR QCB'S F'MTED  A41229 91000020
QCBWORK1 DS    C                                                        91200020
MAJOR    DC    C'MAJOR'                                                 91500020
MINOR    DC    C'MINOR'                                                 91800020
QCB      DC    C'QCB'                                            A41229 91850020
QEL      DC    C'QEL'                                            A41229 92100020
SHAR     DC    C'SHARED'                                                92400020
EXCL     DC    C'EXCLUSIVE'                                             92700020
SYSMCPLT DC    C'SYSTEM MUST COMPLETE'                                  93000020
STPMCPLT DC    C'STEP MUST COMPLETE'                                    93300020
QCBTTL   DC    C'* * * *    Q U E U E  C O N T R O L  B L O C K  T R A X93600020
               C E    * * * *'                                          93900020
QCBERMSG DC    CL26'QCB TRACE ABORTED'                                  94200020
NOQMSG   DC    C'NO MAJOR QCBS'                                         94500020
QCBLOOP  DC    C'INFINITE LOOP IN XXX CHAIN'                     A41229 94550020
QCBNAME  DC    C'NAME'                                                  94800020
QCBBUFSV DS    132C                SAVE AREA FOR OUTPUT LINE WHILE      95100020
*                                  PAGE IS TITLED                       95400020
         SPACE 2                                                        95700020
         END                                                            96000020
