         TITLE    'ADDRESS ASSIGNMENT'                                  00100000
*                                                                     * 00200000
*********************************************************************** 00300000
*********************************************************************** 00400000
*                                                                       00500000
*STATUS: CHANGE LEVEL                                                   00600000
*FUNCTION:                                                            * 00700000
*   1) ASSIGN LINKED ADDRESSES TO ALL CONTROL SECTIONS AND LABELS     * 00800000
*      THEREIN                                                        * 00900000
*   2) IF IN OVERLAY DETERMINE SEGMENT ADDRESSES                      * 01000000
*   3) DETERMINE PSEUDO REGISTER DISPLACEMENTS AND CUMULATIVE LENGTH  * 01100000
*   4) PRINT MESSAGE FOR ALL UNRESOLVED EXTERNAL REFERENCES           * 01200000
*   5) SET CERTAIN ESD TYPES TO NULL - DELETE LINE TYPE ER SUBTYPE    * 01300000
*      (BYTE 13 OF CESD) AS FOLLOWS                                   * 01400000
*       A) ALL CARDS EXCEPT ALIAS (F0 - B0,90)                        * 01500000
*       B) NO CALL UNMATCHED       (04)                               * 01600000
*       C) UNMATCHED LIBRARY MEMBER (02)                              * 01700000
*   6) IF IN OVERLAY COMPUTE LENGTH OF SEGTAB                         * 01800000
*   7) GO TO IEWLKENS TO DETERMINE SEGMENT NUMBERS FOR LABELS AND TO  * 01900000
*      COMPUTE ENTAB SIZES (ONLY IF IN OVERLAY)                       * 02000000
*                                                                     * 02100000
*ENTRY POINTS:                                                        * 02200000
*   1) IEWLMADA - CONTROL SECTION NAME - MAIN ENTRY POINT             * 02300000
*   2) IEWLCAD1 - LABEL - ENTERED FROM IEWLKENS TO MAKE CESD ENTRIES  * 02400000
*      FOR ENTABS                                                     * 02500000
*                                                                     * 02600000
*INPUT:                                                               * 02700000
*   1) GP REGISTER 2 - ADDRESS OF ALL PURPOSE TABLE                     02800000
*EXTERNAL ROUTINES:                                                   * 02900000
*   1) IEWLMENS    -ENTAB SIZE DETERMINATION                            03000000
*   2) IEWLMENT                                                         03100000
*   3) IEWLELOG    - ERROR DIAGNOSTIC ROUTINE                         * 03200000
*                                                                     * 03300000
*EXITS:                                                               * 03400000
*   1) IEWLMOUT (NORMAL) - INTERMEDIATE OUTPUT PROCESSOR                03500000
*   2) IEWLMFNL (NO CESD OR TEXT) FINAL PROCESSOR                       03600000
*                                                                     * 03700000
*TABLES:                                                              * 03800000
*   INPUT                                                             * 03900000
*   1) COMPOSITE EXTERNAL SYMBOL DICTIONARY                           * 04000000
*   2) ALL PURPOSE TABLE                                              * 04100000
*   3) SEGTA1 (OVERLAY ONLY)                                          * 04200000
*                                                                     * 04300000
*   INTERNALLY USED                                                   * 04400000
*   1) SEGMENT LENGTH TABLE                                           * 04500000
*                                                                     * 04600000
*   OUTPUT                                                            * 04700000
*   1) RELOCATION CONSTANT TABLE                                      * 04800000
*   2) UPDATED COMPOSITE EXTERNAL SYMBOL DICTIONARY                   * 04900000
*********************************************************************** 05000000
*********************************************************************** 05100000
*              IEWLMADA    -ADDRESS ASSIGNMENT                        * 05200000
*                                                                     * 05300000
IEWLMADA CSECT                                                          05400000
* 452000-453000                                                  A26192 05450000
*I089600                                                        SA59373 05460021
*I090100,I093800                                                SA61636 05470021
*D090100-093900                                                 SA65984 05480000
         ENTRY IEWLCAD1                                                 05500000
         ENTRY SEGLNTAB                                                 05600000
*********************************************************************** 05700000
*              REGISTER  ASSIGNMENT                                   * 05800000
*********************************************************************** 05900000
ERRCODE  EQU   0                                                        06000000
ERRSYMAD EQU   1                                                        06100000
TEMP2    EQU   1                                                        06200000
WORK4    EQU   1                                                        06250000
APT      EQU   2                                                        06300000
CSLGTH   EQU   3                        CONTROL SECTION LENGTH          06400000
WORK1    EQU   3                                                        06500000
MAXSEGCT EQU   3                        MAX.NO OF SEGMENTS              06600000
CSSEGNO  EQU   4                        CONTROL SECTION SEGMENT NO      06700000
WORK2    EQU   4                                                        06800000
CSASADD  EQU   5                        CONTROL SECTION ASSEMBLED ADD.  06900000
WORK3    EQU   5                                                        07000000
CESDCRCT EQU   6                                                        07100000
CESDCRAD EQU   7                                                        07200000
TEMP1    EQU   7                                                        07300000
SEGLGTH  EQU   8                                                        07400000
ASMADD   EQU   9                                                        07500000
CURSEGNO EQU   9                                                        07600000
LOCCTR   EQU   10                                                       07700000
ADTXTIOT EQU   11                                                       07800000
BASE     EQU   12                                                       07900000
ACUMZERO EQU   13                                                       08000000
TEST     EQU   13                                                       08050000
RETURN   EQU   14                                                       08100000
BRANCH   EQU   15                                                       08200000
EBIT     EQU   X'80'                    ENTAB PRESENT MASK              08300000
OVLYOFF  EQU   X'DF'                    MASK TO TURN OVERLAY OFF        08400000
OVRLAYBT EQU   X'20'                                                    08500000
RCCOMP   EQU   X'20'                    RELOCATION CONST IS IN COMPFORM 08600000
         USING APTDSECT,APT   DECLARE APT BASE                          08700000
         USING ADA00100+2,BASE                                          08800000
ADA00100 BALR  BASE,0                                                   08900000
         BC    15,MODID+6                                               08930000
MODID   DC    C'01MADA'                                                 08960000
*                                                                       09400000
*              INITIALIZATION                                           09500000
*                                                                       09600000
*                                                                       09700000
*              SET SEGMENT LENGTH TABLE = 0                             09800000
*                                                                       09900000
*  USE OBJECT MODULE BUFFER FOR SEG LENGTH TABLE - USE LOWER ADDRESS    09920000
         CLC   IEWLCRBB+4(4),IEWLCRBB+8                                 09940000
         BL    ADA00110            FIRST LOW- USE IT                    09960000
         L     SEGLGTH,IEWLCRBB+8  FIRST HIGH- USE SECOND               09980000
         B     ADA00115                                                 10000000
ADA00110 L     SEGLGTH,IEWLCRBB+4  USE FIRST                            10020000
ADA00115 ST    SEGLGTH,SEGLNTAB    SAVE LOW ADD AS ADD OF SEG LNGTH TAB 10040000
         SR    WORK3,WORK3         CLEAR REGISTER                       10060000
         IC    WORK3,CSNO+1        GET HIGHEST SEGMENT USED             10080000
         LA    WORK3,1(WORK3)      ADD 1 FORRE-ORIGINING                10100000
         MH    WORK3,SIX           MULT BY NUM BYTES/ENTRY FOR TOTAL    10120000
         SR    WORK2,WORK2         CLEAR REMAINDER REGISTER             10140000
         D     WORK2,CONST256      DVIDE BY 256                         10160000
         LR    TEMP1,SEGLGTH       ADDR. OF BEG SEGMNT LGTH TABLE       10180000
         LTR   WORK3,WORK3         IF LESS THAN 256 BYTES QUOTIENT = 0  10200000
         BC    2,CLRBUF            IF NOT SO, BEGIN CLEARING TABLE      10220000
         B     CLRFNL      IF QUOTIENT = 0, CLEAR NON-MULTIPLE OF 256   10240000
CLRBUF   XC    0(256,TEMP1),0(TEMP1)    CLEAR 256 BYTES                 10260000
         LA    TEMP1,256(TEMP1)        UPDATE PTR BY 256                10280000
         BCT   WORK3,CLRBUF        REDUCE QUOTIENT & IF NOTZERO- RETURN 10300000
CLRFNL   BCTR  WORK2,0             DECREMENT FOR PROPER CLEARING        10320000
         EX    WORK2,CLRLAST       CLEAR LAST NON-MULTIPLE OF 256       10340000
         XC    HIADDREG(12),HIADDREG   SET HIADDREG,BGADDREG,CURRREGN   10400000
*                                      AND NCESDCT = 0  (12 BYTES)      10500000
*                                      = 0  (10 BYTES )                 10600000
*********************************************************************** 11700000
*              TEST IF CESD CURRENT CT = 0  - YES-ERROR  /GO TO FINAL * 11800000
*              PROCESSOR                                              * 11900000
*********************************************************************** 12000000
ADA00120 BAL   RETURN,ADA02300         GO TO TEST CESD CT = 0           12100000
*********************************************************************** 12200000
*              TEST IF PROGRAM IS IN OVERLAY - YES/ COMPUTE SIZE SEGTB* 12300000
*********************************************************************** 12400000
         TM    PDSE7,OVRLAYBT      IS PROGRAM IN OVERLAY                12500000
         BC    1,ADA01000               YES  GO TO INIT SEGTAB & ENS    12600000
*********************************************************************** 12700000
*              GO TO IEWLKENS TO DETERMINE SEGMENT NUMBERS FOR LABELS * 12800000
*              REG 13 SUPPLIED BUT REGISTERS NEED NOT BE SAVED        * 12900000
*********************************************************************** 13000000
ADA00122 LA    13,SAVEREGS             SAVE REG AREA AADDRESS FOR ENS   13100000
         L     BRANCH,ENSVCON          ADDRESS OF IEWLCENS              13200000
         BALR  RETURN,BRANCH            BRANCH TO IEWLCENS              13300000
**********************************************************************  13302000
*                                                                     * 13304000
*              FIRST SEARCH  ASSIGN TEMPORARY LINKED ADDRESSES        * 13306000
*                TO ALL CSECTS REFERENCED IN THE TXTIO TABLE          * 13308000
*                                                                     * 13310000
**********************************************************************  13312000
*                                                                       13314000
* SET UP SEARCH OF TXTIO TABLE                                          13316000
         ST    TEST,SAVE13         KEEP ADDRESS OF SAVE AREA FOR REGIS  13318000
         SR    TEST,TEST                                                13320000
         CH    TEST,ENTOC               IS THERE ANY TEXT               13322000
         BC    11,ADA00140         NO TXT - SEARCH CESD                 13324000
         OI    TWELVE,X'80'             SET SWITCH INDICATNG TXTIO LOOP 13326000
         L     ADTXTIOT,TXTIO           ADDR OF TXTIO TABLE             13328000
         LR    TEST,ADTXTIOT           ADDRESS TXTIOT TABLE             13330000
         AH    TEST,ENTOC       TEST NOW CONTAINS END ADDR OF TXTIOT    13332000
ADA00123 CR    ADTXTIOT,TEST      ANY MORE TXT IN TXTIOT                13334000
         BC    11,ADA00135              NO- SET IN TXTIOT LOOP OFF      13336000
         TM    2(ADTXTIOT),X'20'        IS IT OUT OF ORDER TXT          13338000
         BC    1,ADA00133               YES--ID FOR TXTIO ENTRY ALREADY 13340000
*                                          PROCESSD. CHECK NEXT ENTRY.  13342000
* FIND CESD ENTRY                                                       13344000
         LH    CESDCRAD,0(ADTXTIOT)     CESD ENTRY ID (FROM TXTIOT)     13346000
         SLL   CESDCRAD,4               FIND REL. ADDR. ON CESD  (*16)  13348000
         A     CESDCRAD,CHESD           ADDRESS OF CESD ENTRY           13350000
         TM    08(CESDCRAD),X'08'       HAS CESD ENTRY BEEN PROCESSED   13352000
         BC    1,ADA00133               YES- CHECK NEXT TXTIOT ENTRY    13354000
         TM    8(CESDCRAD),X'0B'        IS TYPE SD OR PC                13356000
         BC    7,ERRETURN               NO-ERROR-GO TO NEXT ENTRY       13358000
         CLI   8(CESDCRAD),X'14'        IS THIS A PC FOR ENTAB OR SEGTB 13360000
         BC    7,ADA00175              NO - PROCESS CESD ENTRY          13362000
*    ERROR FOUND  LOG IT THEN CONTINUE                                  13364000
ERRETURN LA    RETURN,ADA00175                                          13366000
         L     BRANCH,ERDIG                                             13368000
         LH    ERRCODE,ERRPARM8        GIVE TXTIOT ERROR MESSAGE        13370000
         BR    BRANCH                                                   13372000
ADA00130 OI    8(CESDCRAD),X'08'        SET CESD ENTRY PROCESSED SWITCH 13374000
ADA00133 LA    ADTXTIOT,INC(ADTXTIOT)   UPDATE ADDRESS                  13376000
         B     ADA00123                 GO TO NEXT TXTIOT ENTRY         13378000
ADA00135 NI    TWELVE,X'7F'             TURN TXTIO LOOP SWITCH OFF      13380000
         B     ADA00140                 SEARCH CESD                     13382000
ADA00136 NI    8(CESDCRAD),X'F7'        SET PROCESSD SWITCH OFF         13384000
         B     ADA00400                 CHECK END OF LOOP               13386000
*********************************************************************** 13400000
*                                                                     * 13500000
*              SEARCH CESD FOR NON-PROCESSED CSECTS- NO TEXT          * 13600000
*                COMMON,  ASSIGN TEMP LINKED ADDRESSES                  13700000
*                COMPUTERELOCATION CONSTANTS (PUT IN RCT),DETERMINE   * 13800000
*                PSEUDO REGISTER DISPLACEMENTS AND TOTAL LENGTH       * 13900000
*                                                                     * 14000000
*********************************************************************** 14100000
ADA00140 LH    CESDCRCT,ENCDC           CURRENT NO. CESD ENTRIES        14200000
         L     CESDCRAD,CHESD  CESD ADD                                 14300000
         LA    WORK4,1(CESDCRCT)       CESD CURRENT CT + 1              14400000
         STH   WORK4,NCESDCT           INITIALIZE NCESD CT              14500000
ADA00150 LA    CESDCRAD,16(CESDCRAD)    POINTS TO CURRENT CESD ENTRY    14600000
    CLI    8(CESDCRAD),X'0A'                                            14610000
     BE  ADA00400                                                       14620000
         TM    8(CESDCRAD),X'08'        HAS CESD ENTRY BEEN PROCESSED   14630000
         BC    1,ADA00136               YES- SET PROCESSD SW OFF-       14660000
         NI    8(CESDCRAD),X'DF'       SET BIT 2 OF TYPE BYTE TO 0      14700000
         MVN   TESTTYPE(1),8(CESDCRAD)  MOVE LOW 4 BITS FOR ESDTYPETEST 14800000
         TM    TESTTYPE,X'02'           IS TYPE NOT SO,PC OR CM         14900000
         BC    1,ADA00850               YES                             15000000
*********************************************************************** 15500000
*              IS THIS CESD ENTRY THE PC DELETE FOR SEGTAB / YES -DONOT 15600000
*              ASSIGN AN ADDRESS TO IT ( IT IS INITIALIZED TO 0)      * 15700000
*********************************************************************** 15800000
         LR    TEMP2,CESDCRAD                                           15900000
         S     TEMP2,CHESD    REL ID                                    16000000
         SRL   TEMP2,4                  ID                              16100000
         CH    TEMP2,ENSPX    IS THIS A SEGTAB ENTRY                    16200000
         BC    8,ADA00400               YES  DO NOT ASSIGN ADDRESS      16300000
*********************************************************************** 16400000
*              USING SEGMENT NUMBER REFERENCE SEGMENT LENGTH TABLE AND* 16500000
*              FIND LENGTH OF THIS SEGMENT                            * 16600000
*********************************************************************** 16700000
ADA00175 SR    SEGLGTH,SEGLGTH                                          16800000
         IC    SEGLGTH,12(CESDCRAD)     PICK UP SEG NO OF THIS CESD ENT 16900000
         MH    SEGLGTH,SIX              MULTIPLY BY 6  (6BYTES/ENTRY)   17000000
         A     SEGLGTH,SEGLNTAB    POINTS TO AN ENTRY IN SEG LENGTH TAB 17100000
         MVI   CONSTWK,X'00'                                            17200000
         MVC   CONSTWK+1(3),0(SEGLGTH)  MOVE SEGMENT LG TO CONST+1      17300000
         L     ASMADD,8(CESDCRAD)       ASSEMBLED ADDRESS OF THIS CS    17400000
         LA    ASMADD,0(ASMADD)         REMOVE TYPE                     17500000
         L     LOCCTR,CONSTWK           LENGTH OF THIS SEGMENT          17600000
*********************************************************************** 17700000
*              IF SEGMENT LENGTH = 0  SAVE LOW 3 BITS OF ASSEMBLED ADD* 17800000
*********************************************************************** 17900000
         LTR   LOCCTR,LOCCTR            IS LENGTH = 0                   18000000
         BC    2,ADA00200               NO                              18100000
         LA    WORK1,7                  SET REG TO 7/FOR SAVING LOW 3   18200000
         NR    WORK1,ASMADD             SAVE LOW 3 BITS OF ASSEMBLED AD 18300000
         STC   WORK1,3(SEGLGTH)         STORE LOW 3 BITS OF CS INSGLGTH 18400000
*********************************************************************** 18500000
*              MAKE TEMPORARY LINKED ADDRESS (SEGMENT LENGTH) MODULO 8* 18600000
*              WITH ASSEMBLED ADDRESS - SAVE TLA IN CESD              * 18700000
*********************************************************************** 18800000
ADA00200 LR    WORK1,ASMADD             SAVE ASSEMBLED ADDRESS          18900000
         SR    WORK1,LOCCTR             MAKE TEMP LINKED ADD MOD 8 WITH 19000000
         LA    WORK2,7                   THE ASSEMBLED ADDRESS OF CS    19100000
         NR    WORK1,WORK2                                              19200000
         AR    LOCCTR,WORK1             ANS IN LOCCTR  (TLA)            19300000
         IC    WORK2,8(CESDCRAD)        SAVE  TYPE                      19400000
         ST    LOCCTR,8(CESDCRAD)       PUT TLA IN CESD                 19500000
         STC   WORK2,8(CESDCRAD)        RESTORE  TYPE                   19600000
         LR    WORK1,LOCCTR             SAVE  LOCCTR  (TLA)             19700000
*********************************************************************** 19800000
*              DETERMINE ADDRESS OF RELOCATION CONST IN RCT FOR THIS CS 19900000
*********************************************************************** 20000000
*                                                                       20100000
         LR    WORK2,CESDCRAD                                           20200000
         S     WORK2,CHESD    RELATIVE CESD ADD                         20300000
         SRL   WORK2,2                  RELATIVE RC ADD                 20400000
         A     WORK2,RECNT    ADD OF A RCT ENTRY/RCT 1-1 CESD           20500000
*********************************************************************** 20600000
*              COMPUTE RELOCATION CONSTANT  , RC = TLA - AA /PUT IN RCT 20700000
*********************************************************************** 20800000
         SR    WORK1,ASMADD             COMPUTE  RCT = TLA - ASSM ADD   20900000
         BC    11,ADA00250         IF POSITIVE  -- CONTINUE             20950000
         OI    8(CESDCRAD),X'20'   IF NEG- INCICATE NEG RELOC CONST     21000000
ADA00250 ST    WORK1,0(WORK2)           STORE TRC IN RELOC CONST TABLE  21050000
*********************************************************************** 21100000
*              ADD CS LENGTH TO CS TLA AND SAVE IN SEG LENGTH TABLE/SEG 21200000
*********************************************************************** 21300000
ADA00300 MVC   CONSTWK(4),12(CESDCRAD)  MOVE LENGTH TO CONST            21400000
         MVI   CONSTWK,X'00'           SET IST BYTE TO ZERO             21500000
         A     LOCCTR,CONSTWK          ADD LENGTH TO LOCATION CTR       21600000
         ST    LOCCTR,CONSTWK                                           21700000
         BAL   RETURN,ADA02450          GO TO TEST FOR VALID LENGTH     21800000
ADA00350 MVC   0(3,SEGLGTH),CONSTWK+1  PUT TLA + L (CURRENT SEG LG) IN  21900000
         TM    TWELVE,X'80'             IN TXTIOT LOOP?                 21920000
         BC    1,ADA00130               YES- SET CESD ENTRY PROCESSED   21940000
         L     TEST,SAVE13         RESTORE REG 13                       21960000
*                                                                       21980000
ADA00400 BCT   CESDCRCT,ADA00150         SEGLGTH TABLE /BRANCH IFNOTDON 22000000
*********************************************************************** 22100000
*              TEST FOR OVERLAY-YES/ GO TO SCAN SEG LENGTH TABLE      * 22200000
*********************************************************************** 22300000
         TM    PDSE7,OVRLAYBT IS PROGRAM IN OVERLAY                     22400000
         BC    1,ADA01100               YES                             22500000
         MVC   SIZSAVE+1(3),0(SEGLGTH)  GET PROGRAM LENGTH              22510000
         L     WORK1,SIZSAVE                                            22520000
         LA    WORK1,7(WORK1)          ROUND SIZE TO NEXT               22530000
         N     WORK1,ROUNDOFF          DOUBLE WORD                      22540000
         ST    WORK1,SIZSAVE           SAVE SIZE FOR PDS DIRECTORY      22550000
         MVC   0(3,SEGLGTH),SIZSAVE+1                                   22560000
         MVC   PDSE9(3),0(SEGLGTH) PUT PROGRAM LENGTH IN PDS            22600000
*********************************************************************** 22700000
*              SCAN CESD - RELOCATE ADDRESSES OF LRS-PROCESS ERS      * 22800000
*********************************************************************** 22900000
ADA00550 LH    CESDCRCT,ENCDC  CURRENT NO. CESD ENTRIES                 23000000
         L     CESDCRAD,CHESD  CESD ADD                                 23100000
ADA00600 LA    CESDCRAD,16(CESDCRAD)    INCREMENT TO FIRST(NEXT) ENTRY  23200000
         MVN   TESTTYPE(1),8(CESDCRAD)  MOVE LOW 4 BITS FOR ESDTYPETEST 23300000
         CLI TESTTYPE,X'0A'                                             23330000
         BC 7,ADA00601                                                  23360000
         XC 9(4,CESDCRAD),9(CESDCRAD)                                   23390000
         B ADA00650                                                     23420000
ADA00601 CLI TESTTYPE,X'02'                                             23450000
         BC    8,ADA00900               YES / GO TO ER ROUTINE          23500000
         CLI   TESTTYPE,X'07'           IS TYPE NULL                    23600000
         BC    8,ADA00700               YES / TEST END OF LOOP          23700000
         CLI   TESTTYPE,X'03'           IS TYPE = LR                    23800000
         BC    7,ADA00650               NO / GO TO  SAVE  Y             23900000
         LH    WORK1,14(CESDCRAD)       YES  LR - NOW RELOCATE TLA/ ID  24000000
         SLL   WORK1,2                  MULTIPLY BY 4                   24100000
         A     WORK1,RECNT    POINTS TO RCT ENTRY OF SD,PC,CM           24200000
         L     WORK2,0(WORK1)           RELOCATION CONSTANT = RC        24300000
         LR    WORK1,CESDCRAD                                           24400000
         S     WORK1,CHESD    REL ADD OF LR ENTRY IN RCT                24500000
         SRL   WORK1,2                                                  24600000
         A     WORK1,RECNT    ADD OF RC FOR LR                          24700000
         ST    WORK2,0(WORK1)          ST RC OF LR                      24800000
         A     WORK2,8(CESDCRAD)        ADD RC TO ASSEMBLED ADD OF LR   24900000
         IC    WORK1,8(CESDCRAD)        SAVE TYPE                       25000000
         ST    WORK2,8(CESDCRAD)        STORE LINKED ADDRESS OF THIS LR 25100000
         STC   WORK1,8(CESDCRAD)        RESTORE TYPE                    25200000
*              SAVE CURRENT CESD CT - CESD LINE NUMBER + 1 = Y          25300000
ADA00650 STH   CESDCRCT,NCESDCT         SAVE Y                          25400000
ADA00700 BCT   CESDCRCT,ADA00600        BRANCH IF LOOP OF CESD NOT DONE 25500000
*              COMPUTE NEW CESD CURRENT NUMBER ENTRIES                  25600000
         LH    CESDCRCT,NCESDCT         Y= CESD CURR CT - CESD LN NO +1 25700000
         BCTR  CESDCRCT,0               Y-1                             25800000
         LCR   CESDCRCT,CESDCRCT        Y-1 IN COMPLEMENT FORM          25900000
         AH    CESDCRCT,ENCDC      CESD ID OF LAST NON NULL LINE        26000000
         STH   CESDCRCT,ENCDC      SAVE NEW CESD CT                     26100000
         BAL   RETURN,ADA02300          GO TO TEST CESD CT = 0          26200000
         L     BRANCH,ENTVCON           GO TO ENTRY PROCESSOR           26300000
         LA    13,SAVEREGS             ADDRESS OF SAVE AREA FOR ENT     26400000
         BALR  RETURN,BRANCH            (EXPECT ENT TO RETURN ALL REGS) 26500000
ADA00800 L     BRANCH,OUTVCON           GO TO OUTPUT PROCESSOR          26600000
         BALR  RETURN,BRANCH                                            26700000
*********************************************************************** 26800000
*              TEST IF THIS IS A PSEUDO REGISTER                      * 26900000
*                                                                     * 27000000
*********************************************************************** 27100000
ADA00850 CLI   TESTTYPE,X'06'          IS TYPE = PSEUDO REGISTER        27200000
         BC    7,ADA00400              NO / GO TO TEST END OF LOOP      27300000
*********************************************************************** 27400000
*              CESD  TYPE = PSEUDO REGISTER                             27500000
*********************************************************************** 27600000
         SR    WORK1,WORK1                                              27700000
         IC    WORK1,12(CESDCRAD)       PSEUDO REGISTER ALIGNMENT       27800000
         LCR   WORK2,WORK1              2S COMPLEMENT OF ALIGNMENT      27900000
         BCTR  WORK2,0                  IS COMPLEMENT OF ALIGNMENT      28000000
         A     WORK1,PRAL          ADD PR LOC CTR TO ALIGNMENT          28100000
         NR    WORK1,WORK2              AND IS COMPLEMENT TO ADJUSTEDPR 28200000
         IC    WORK2,8(CESDCRAD)        SAVE TYPE                       28300000
         ST    WORK1,8(CESDCRAD)        STORE PSEUDO REG NEW DISPLACMNT 28400000
         STC   WORK2,8(CESDCRAD)        RESTORE TYPE                    28500000
         A     WORK1,12(CESDCRAD)       ADD PR LENGTH TO CULMULATIVE    28600000
         LA    WORK1,0(WORK1)           REMOVE HI BYTE GARBAGE          28700000
         ST    WORK1,PRAL          SAVE NEW CULMULATIVE TOTAL LGTH      28800000
         BC    15,ADA00400              BRANCH TO TEST END OF CESD LOOP 28900000
*********************************************************************** 29000000
*              TYPE = ER - DETERMINE SUBTYPE -                        * 29100000
*********************************************************************** 29200000
ADA00900 LA    RETURN,ADA00650          RETURN TO SAVE Y                29300000
         LA    TEMP2,ADA00910          ADD OF NULLIFY ROUT              29400000
*                                                                       29500000
         CLI   13(CESDCRAD),X'A0'      IS TYPE = ALIAS                  29600000
         BCR   8,RETURN                YES - RETURN TO MAIN LOOP        29700000
*                                                                       29800000
         CLI   13(CESDCRAD),X'90'      IS TYPE = NULL                   29900000
         BCR   11,TEMP2                GO TO NULLIFY CESD LINE          30000000
*                                                                       30100000
         CLI   13(CESDCRAD),X'04'      IS TYPE = NO CALL LOB MEMBER     30200000
         BCR   8,TEMP2                 YES - NULLIFY                    30300000
*                                                                       30400000
         CLI   13(CESDCRAD),X'02'      IS TYPE = NULL                   30500000
         BCR   8,TEMP2                 YES - NULLIFY                    30600000
         XC    9(4,CESDCRAD),9(CESDCRAD) SET ADD AND SEG FIELD = 0      30700000
*                                                                       30800000
         CLI   13(CESDCRAD),X'06'       IS TYPE = NEVER CALL            30900000
         BC    8,ADA00904               YES / PRINT WARNING MESSAGE -ER 31000000
*              MATCHED LIB.MEM.(TYPE 03) ARE REGULAR ERS                31100000
         CLI   13(CESDCRAD),X'05'       IS TYPE = NO CALL MATCHED       31200000
         MVI   13(CESDCRAD),X'00'       SET TYPE 05 OR 03 = 00 -REG.ER  31300000
         BC    8,ADA00904               YES / PRINT WARNING MESSAGE -ER 31400000
*                                                                       31500000
         LH    ERRCODE,ERRPARM1         ER - ASSUME NO CALL OFF         31600000
         TM    APT0,X'80'          IS NO CALL OPTION = ON               31700000
         BC    8,ADA00905               NO - SEV 3 - EXEC ONLY IF LET   31800000
ADA00904 LH    ERRCODE,ERRPARM2         ER - NO CALL ON                 31900000
ADA00905 LR    ERRSYMAD,CESDCRAD        ADDRESS OF SYMBOL OF ER         32000000
ADA00906 L     BRANCH,ERDIG        ADDRESS OF ERROR DIAGNOSTIC RT       32100000
         L     13,SAVE13           RESTORE ADDR. OF SAVE AREA           32150000
         BCR   15,BRANCH               GO TO ERROR ROUTINE - TYPE ER    32200000
*              NULL LINE                                                32300000
ADA00910 XC    0(16,CESDCRAD),0(CESDCRAD) NULLIFY LINE                  32400000
         MVI   8(CESDCRAD),X'07'       SET NULL TYPE                    32500000
         BC    15,ADA00700              RETURN TO TEST END OF LOOP      32600000
*********************************************************************** 32700000
*              TEST IF CURRENT NO SEGMENTS IS GTR THAN 1/ NO ERROR    * 32800000
*              SET PROGRAM TO NOT IN OVERLAY                          * 32900000
*********************************************************************** 33000000
ADA01000 LH    CSLGTH,CSNO         CURRENT NUMBER OF SEGMENTS           33100000
         BCT   CSLGTH,ADA01050          BRANCH IF CURRNO SEG GTR 1      33200000
         NI    PDSE7,OVLYOFF       SET PROG TO NOT IN OVERLAY           33300000
         LH    ERRCODE,ERRPARM5         LOAD ERR PARM - OVERLAY WARNING 33400000
         LA    RETURN,ADA00122          RETURN ADDRESS                  33500000
         BC    15,ADA00906              GO TO GO TO ERROR ROUTINE       33600000
ADA01050 LA    CSLGTH,1(CSLGTH)         RESTORE CURRENT NO SEGMENTS     33700000
         SLL   CSLGTH,2                 MULTIPLY BY 4                   33800000
         LA    CSLGTH,24(CSLGTH)        LENGTH OF SEGTAB                33900000
         L     WORK4,SEGLNTAB                                           34000000
         ST    CSLGTH,CONSTWK                                           34100000
         MVC   6(3,WORK4),CONSTWK+1     PUT SEGTAB LGTH IN SEGLGTH TBL  34200000
*                                       AT ENTRY PER SEGMENT 1          34300000
         MVC   PDSE10(2),CONSTWK+2  PUT LENGTH OF SEGTAB IN PDS         34400000
         SR    CSASADD,CSASADD          ASSEMBLED ADD OF SEGTAB = 0     34500000
         LA    CSSEGNO,1                SEGMENT NO = 1                  34600000
         BAL   RETURN,ADA02500         GO TO PCB ROUT                   34700000
*                                                                       34800000
         MVC   ENSPX(2),ENCDC      PUT ESDID IN PDS (SEGTAB)            34900000
         BC    15,ADA00122              GO TO SCAN CESD  (MAIN FLOW)    35000000
*                                                                       35100000
*                                                                       35200000
ADA01100 LA    CURSEGNO,1               INIT CURRENT SEGMENT =1         35300000
         L     SEGLGTH,SEGLNTAB    ADDRESS OF SEG LENGTH TABLE          35400000
         LR    WORK4,SEGLGTH            ADDRESS OF SEGLGTH              35500000
ADA01200 LA    SEGLGTH,6(SEGLGTH)       INC SEGMENT LG TBL ADD NXT ENTY 35600000
         L     WORK1,SGT1          ADDRESS OF SEGTAB1                   35700000
         SR    WORK2,WORK2                                              35800000
         IC    WORK2,0(WORK1,CURSEGNO)  PICK UP PRV SEGMENT NO.         35900000
         LTR   WORK2,WORK2              IS PREVIOUS SEGMENT NO.= 0      36000000
         BC    2,ADA02400               NO                              36100000
         LH    WORK3,CURRREGN           LOAD CURRENT REGION NO.         36200000
         ST    CURSEGNO,CONSTWK         CURR SEG NO                     36300000
         LA    WORK2,LSTS(WORK3)   ADDR OF LAST SEG OG PRES REG         36400000
         CLC   CONSTWK+3(1),0(WORK2)    IS CURR SEG IN PRES REGION      36500000
         BC    13,ADA01300              YES                             36600000
         LA    WORK3,1(WORK3)           INC CURRENT REG NO BY 1         36700000
         STH   WORK3,CURRREGN           SAVE CURR REG NO                36800000
         MVC   BGADDREG(4),HIADDREG     SET BEGIN ADDOF REG TO HIADDREG 36900000
ADA01300 L     WORK3,BGADDREG           LOAD BEGIN ADDRESS OF REGION    37000000
ADA01500 SR    WORK1,WORK1              SAVE SEGMENT (PATH) LENGTH      37100000
         IC    WORK1,3(SEGLGTH)         PICK UP FLAG BYTE FOR THIS SEG  37200000
         SR    WORK1,WORK3              3BITS OF AA - SEGLENGTH         37300000
         LA    WORK2,7                                                  37400000
         NR    WORK1,WORK2              AND OUT ALL BUT LOW 3 BITS/DIFF 37500000
         AR    WORK3,WORK1              SEGMENT LENGTH NOW MODULO 8FLAG 37600000
         ST    WORK3,CONSTWK                                            37700000
         NI    CONSTWK+3,X'F8'          AND OUT LOW 3 BITS OF SEGMENTRC 37800000
         MVC   3(3,SEGLGTH),CONSTWK+1   PUT SEGMENT RC IN LST 3BYTSEGLG 37900000
         MVC   CONSTWK+1(3),0(SEGLGTH)  MOVE LENGTH OFTHIS SEGMENT      38000000
         MVI   CONSTWK,X'00'            SET HI BYTE OF LENGTH TO ZERO   38100000
         A     WORK3,CONSTWK            ADD LENGTH OF THIS SEG TO PTHTL 38200000
         ST    WORK3,CONSTWK            PUT UPDATED SEGMENT LENGTH IN   38300000
         MVC   0(3,SEGLGTH),CONSTWK+1   SEGLGTH TBL AT THIS SEG ENTRY   38400000
         BAL   RETURN,ADA02450          GO TO TEST FOR VALID LENGTH     38500000
         CL    WORK3,HIADDREG           IS THIS ADD GTR THAN CURR HIADD 38600000
         BC    13,ADA01600              NO                              38700000
         ST    WORK3,HIADDREG           YES SAVE NEW HI ADDRESS         38800000
ADA01600 LA    CURSEGNO,1(CURSEGNO)     INC CURRENT SEGMENT CT          38900000
         CH    CURSEGNO,CSNO       IS LOOP DONE                         39000000
         BC    13,ADA01200              NO / CONTINUE LOOP              39100000
*                                                                       39200000
*              LOOP THROUGH CESD ADDING SEGMENT RC TO TLA OF (SD,PC,CM) 39300000
*                           AND TO TRC OF (SD,PC,CM)                    39400000
         L     SEGLGTH,SEGLNTAB                                         39500000
         L     CESDCRAD,CHESD      CESD ADDRESS                         39600000
         LH    CESDCRCT,ENCDC      CESD CURRENT COUNT                   39700000
ADA01700 LA    CESDCRAD,16(CESDCRAD)    INCREMENT CESD ADDRESS          39800000
         MVN   TESTTYPE(1),8(CESDCRAD)  MOVE TYPE FOR TESTING           39900000
         CLI   TESTTYPE,X'05'           IS TYPE = CM                    40000000
         BC    8,ADA01750               YES                             40100000
         TM    TESTTYPE,X'03'           IS TYPE NOT = SD,PC,(W/O RLDS)  40200000
         BC    5,ADA02000               NO  GO TO TEST END OF LOOP      40300000
ADA01750 SR    WORK1,WORK1                                              40400000
         SR    WORK1,WORK1                                              40500000
         IC    WORK1,12(CESDCRAD)       PICK UP SEG NO OF THIS CESD ID  40600000
         MH    WORK1,SIX                MULTIPLY BY 6                   40700000
         AR    WORK1,SEGLGTH            ADD SEGLGTH ADD /POINTS   ENTRY 40800000
         MVI   CONSTWK,X'00'                                            40900000
         MVC   CONSTWK+1(3),3(WORK1)    MOVE SEGMENT RC TO CONSTWK      41000000
         L     WORK1,CONSTWK            LOAD SEGMENT RELOCATION CONST   41100000
         LR    WORK2,WORK1              SAVE SEGMENT RC                 41200000
         A     WORK2,8(CESDCRAD)        ADD TEMP LINKED ADD TO SEG RC   41300000
         IC    WORK3,8(CESDCRAD)        SAVE TYPE                       41400000
         ST    WORK2,8(CESDCRAD)        STORE FINAL LINKED ADD          41500000
         STC   WORK3,8(CESDCRAD)        RESTORE TYPE                    41600000
         LR    WORK2,CESDCRAD           SAVE CURRENT CESD ADD           41700000
         S     WORK2,CHESD         FIND RELATIVE CESD ADD               41800000
         SRL   WORK2,2                  FIND RELATIVE RCT (REL)ADD      41900000
         A     WORK2,RECNT         ADDRESS OF THIS RC ENTRY             42000000
ADA01800 A     WORK1,0(WORK2)           ADD TRC TO SEG RC               42100000
         ST    WORK1,0(WORK2)          PUT FINAL RC IN RCT              42200000
ADA02000 BCT   CESDCRCT,ADA01700        BRANC IF LOOP NOT DONE          42300000
         L     WORK1,HIADDREG          GET LENGTH OF LONGEST PATH       42320000
         LA    WORK1,7(WORK1)          ROUND UP TOTAL LENGTH TO         42340000
         N     WORK1,ROUNDOFF          NEXT DOUBLE WORD                 42360000
         ST    WORK1,HIADDREG          SAVE FOR PDS DIRECTORY           42380000
         MVC   PDSE9(3),HIADDREG+1 PUT TOTAL CONTIGOUS CORE REQ         42400000
         BC    15,ADA00550              IN PDS / GO TO FINAL CESD LOOP  42500000
ADA02300 LH    CESDCRCT,ENCDC      CESD CURR CT                         42600000
         LTR   CESDCRCT,CESDCRCT       IS CESD CURR CT = 0              42700000
         BCR   2,RETURN                N/ / GO TO CALLER                42800000
         L     BRANCH,ERDIG        ERROR RT ADDRESS                     42900000
         LH    ERRCODE,ERRPARM3         CESD DOES NOT EXIST             43000000
         BALR  RETURN,BRANCH                                            43100000
         L     BRANCH,FNLVCON           ADD OF FINAL PROC               43200000
         BCR   15,BRANCH                GO TO FINAL PROC                43300000
ADA02400 MH    WORK2,SIX                                                43400000
         AR    WORK2,WORK4              ADDRESS OF A SEGLGTH ENTRY      43500000
         MVI   CONSTWK,X'00'                                            43600000
         MVC   CONSTWK+1(3),0(WORK2)    MOVE SEG LGTH OF PRVIOUS SEG.   43700000
         L     WORK3,CONSTWK                                            43800000
         LTR   WORK3,WORK3              IS PRV. SEGMENT LENGTH = 0      43900000
         BC    2,ADA01500               NO                              44000000
         SR    WORK2,WORK2                                              44100000
         IC    WORK2,0(WORK1,CURSEGNO)  PICK UP PRVIOUS SEGMENT NO.     44200000
         IC    WORK2,0(WORK1,WORK2)     USING PRV.SEG.NO PICK UP ITSPRV 44300000
         STC   WORK2,0(WORK1,CURSEGNO)  PUT PRV.OF PRV AS PRV TO THIS 1 44400000
         BC    15,ADA02400              BRANCH TO GET SEG LENGTH OF     44500000
*********************************************************************** 44600000
*              TEST IF CONTROL SECTION (OR SEGMENT) LENGTH EXCEEDS    * 44700000
*              512 K - YES PRINT ERROR MESS - SEV 3 / CONTINUE        * 44800000
*********************************************************************** 44900000
ADA02450 CLC   CONSTWK,K512        IS ADDR LESS THAN OR = TO 512 K      45000000
         BCR   13,RETURN           YES -- RETURN                        45100000
         STM   13,1,SAVEA                                        A26192 45130000
         L     BRANCH,ERDIG                                      A26192 45160000
         L     13,SAVE13                                         A26192 45190000
         LH    ERRCODE,ERRPARM6                                  A26192 45220000
         BALR  RETURN,BRANCH                                     A26192 45250000
         LM    13,1,SAVEA                                        A26192 45280000
         BCR   15,RETURN                                         A26192 45310000
*********************************************************************** 45400000
*              THE FOLLOWING BOX OF CODE WILL BE USED ON THE E LOADER * 45500000
*                        1) IT COMPUTES NO.BYTES OF ENTAB PER SEGMENT * 45600000
*                        2) IT MAKES AN ENTRY IN CESD FOR EACH SEGMENT* 45700000
*                   NOTE:  1) AND 2) ARE DONE ONLY IF A SEG HAS ENTAB * 45800000
*                                                                     * 45900000
         DROP  BASE                                                     46000000
         USING IEWLCAD1,BRANCH                                          46100000
         DS    0F                                                       46200000
IEWLCAD1 LR    TEMP1,BASE          SAVE BASE OF IEWLKENS                46300000
         L     BASE,BASADD             SET UP ADDRESSABILITY            46400000
         LR    TEMP2,RETURN        SAVE RETURN ADD OF IEWLKENS          46500000
         MH    ACUMZERO,TWELVE          CHANGE ENTAB LINES TO ENTAB     46600000
         LA    ACUMZERO,12(ACUMZERO)    BYTES                           46700000
         C     ACUMZERO,MULTSIZE       IS ENTAB  G.T. MULTIPLICITY      46720000
         BC    2,ENTABERR    YES GIVE TERMINAL ERROR MESSAGE            46740000
         CH    ACUMZERO,FOUR096        IS ENTAB G.T. ABSOLUTE MAX.      46760000
         BC    2,ENTABERR     YES, GIVE TERMINAL ERROR MESSAGE          46780000
         SR    CSASADD,CSASADD          ADDRESS OF THIS ENTAB = 0       46800000
         LR    CSLGTH,ACUMZERO          LENGTH OF THIS ENTAB (BYTES)    46900000
         LR    CSSEGNO,CURSEGNO         SEGMENT NO OF THIS ENTAB        47000000
         BAL   RETURN,ADA02500         GO TO PCB ROUTINE                47100000
         LR    BASE,TEMP1          RESTORE BASE OF IEWLKENS             47200000
         LR    RETURN,TEMP2        RESTORE RETURN ADD OF IEWLKENS       47300000
         BCR   15,RETURN               RETURN TO ENS                    47400000
ENTABERR LH    ERRCODE,ERRPARM7        SET UP FOR 454 MESSAGE           47430000
         BC    15,ADA02600+4       GO TO GIVE MSG AND TERMINATE         47460000
BASADD   DC    A(ADA00100+2)       ADDRESS OF IEWLKADA+2                47500000
         DROP  BRANCH                                                   47600000
         USING ADA00100+2,BASE                                          47700000
*********************************************************************** 47800000
*                                                                       47900000
*              PCB  - PRIVATE CODE ENTRY BUILDING                       48000000
*                                                                       48100000
*                                                                     * 48200000
*                   REQUIRED REGISTERS & PARAMETERS                   * 48300000
*                        CESDADD (11)  WORK REGISTER                  * 48400000
*                        APT      (2)- ADDRESS OF APT                 * 48500000
*                        CSLGTH        CONTROL SECTION LENGTH         * 48600000
*                        CSSEGNO       CONTROL SECTION SEGMENT NO.    * 48700000
*                        CSASADD       CONTROL SECTION ASSIGNED ADD   * 48800000
*                        BASE    (12)  BASE REGISTER                  * 48900000
*                        RETURN  (14)                                 * 49000000
*                                                                       49100000
*              REGISTERS                                                49200000
*                                                                       49300000
CESDADD  EQU   11                                                       49400000
ERRADD   EQU   15                                                       49500000
*              APT  DISPLACEMENTS                                       49600000
*              DATA CONSTANTS  AND TEMPORARY STORAGE                    49700000
PCDELETE EQU   X'14'                    CESD TYPE PC MARKED DELETE      49800000
ADA02500 LH    CESDADD,ENCDC       CURRENT NO CESD ENTRIES              49900000
         LA    CESDADD,1(CESDADD)       INC CESD CURRENT CT             50000000
         CH    CESDADD,ENCDX       IS CESD FULL                         50100000
         BC    10,ADA02600                                              50200000
         STH   CESDADD,ENCDC                                            50300000
ADA02550 SLL   CESDADD,4                                                50400000
         A     CESDADD,CHESD                                            50500000
         MVI   0(CESDADD),X'40'                                         50600000
         MVC   1(7,CESDADD),0(CESDADD)                                  50700000
         ST    CSASADD,8(CESDADD)                                       50800000
         MVI   8(CESDADD),PCDELETE                                      50900000
         ST    CSLGTH,12(CESDADD)                                       51000000
         STC   CSSEGNO,12(CESDADD)                                      51100000
         BCR   15,RETURN                                                51200000
ADA02600 LH    ERRCODE,ERRPARM4         CESD OVERFLOW                   51300000
         L     ERRADD,ERDIG                                             51400000
         BCR   15,ERRADD                                                51500000
*********************************************************************** 51600000
*                                 TEMPORARY  ERROR  PARMS             * 51700000
*********************************************************************** 51800000
DISP1    EQU   X'22'                    DISP = 2   SEV = 2   NCAL  OFF  51900000
DISP2    EQU   X'21'                    DISP = 2   SEV = 1   NCAL  ON   52000000
DISP3    EQU   X'03'                    DISP = 0   SEV = 3   NO         52100000
DISP4    EQU   X'04'                                                    52200000
DISP5    EQU   X'01'                   DISP = 0     SEV = 1             52230000
DISP6    EQU   X'02'                   DISP = 0    SEV = 2              52260000
*                                                                       52300000
*              MESSAGE NUMBERS ARE DECIMAL                              52400000
*                                                                       52500000
MESS1    EQU   13                       UNRESOLVED ER   NCALL OFF       52600000
MESS2    EQU   46                       UNRESOLVED ER   NCALL ON        52700000
MESS3    EQU   12                       NO CESD                         52800000
MESS4    EQU   25                       CESD OVERFLOW                   52900000
MESS5    EQU   20     ONLY 1 SEGMENT IN AN OVERLAY STRUCTURE            52910000
MESS6    EQU   19     OUTPUT LOAD MODULE GREATER THAN 512K              52920000
MESS7    EQU   45     ENTAB GREATER THAN MULT SIZE OR 4K                52930000
*                     TOO MANY DOWNWARD CALLS FROM SEGMENT              52940000
MESS8    EQU   38     ID FOR TEXT IN TXTIOT IS NOT SD,PC, OR CM         52950000
         DS    0F                                                       53000000
         EXTRN IEWLMLDB                                                 53100000
SYSLIBAD DC    A(IEWLMLDB)    SYSLIB DCB ADDRESS                        53200000
ERRPARM1 DC    AL1(DISP1)               UNRESOLVED XTERNAL REFERENCE    53300000
         DC    AL1(MESS1)               SEV =2  - NCALL OFF             53400000
*                                                                       53500000
ERRPARM2 DC    AL1(DISP2)               UNRESOLVED XTERNAL REF          53600000
         DC    AL1(MESS2)         SEV=1 - NCAL ON                       53700000
*                                                                       53800000
ERRPARM3 DC    AL1(DISP3)               NO CESD                         53900000
         DC    AL1(MESS3)               SEV = 3                         54000000
*                                                                       54100000
ERRPARM4 DC    AL1(DISP4)               CESD  OVERFLOW                  54200000
         DC    AL1(MESS4)                                               54300000
*                                                                       54305000
ERRPARM5 DC    AL1(DISP5)              ONLY 1 SEGMENT IN AN OVERLAY     54310000
         DC    AL1(MESS5)              PROGRAM - OVERLAY OPTION         54315000
*                                      CANCELLED                        54320000
*                                                                       54325000
ERRPARM6  DC   AL1(DISP5)       OUTPUT LOAD MODULE IS GREATER       XXX 54330000
         DC    AL1(MESS6)              THAN 512K - OUTPUT  MODULE IS    54335000
*                                      MARKED NOT EXECUTABLE            54340000
*                                                                       54345000
ERRPARM7  DC   AL1(DISP4)              ENTAB HAS EXCEEDED MULTIPLICITY  54350000
         DC    AL1(MESS7)              SIZE OR THE MAX. OF 4K.          54355000
*                                      TOO MANY DOWNWARD CALLS IN SEG.  54360000
*                                                                       54365000
ERRPARM8 DC    AL1(DISP6)              ID IN TXTIOT IS NOT SD, OR PC    54370000
         DC    AL1(MESS8)              INVALID ID MESSAGE ISSUED        54375000
*                                                                       54380000
*              MASKS & CONSTANTS                                        54400000
*                                                                       54500000
OUTVCON  DC    V(IEWLMOUT)    ADD OF OUTPRO                             54600000
ENSVCON  DC    V(IEWLMENS)    ADDRESS OF ENTAB SIZE DETERMINATION       54700000
ENTVCON  DC    V(IEWLMENT)    ADDRESS OF ENTRY PROCESSOR                54800000
FNLVCON  DC    V(IEWLMFNL)    ADDRESS OF FINAL PROCESSOR                54900000
SAVEA    DS    5F                                                A26192 54950000
CONSTWK  DC    F'0'                     WORK WORD                       55000000
SIX      DC    H'6'                     VALUE OF 6                      55100000
CLRLAST  XC    0(0,TEMP1),0(TEMP1)  INSTRUCTION FOR CLEARING TABLES     55110000
K512     DC    X'00080000'         512 K                                55120000
CONST256 DC    F'256'              USED FOR CLEARING TABLES             55130000
SIZSAVE  DC    F'0'                    AREA FOR MANIPULATING PGM SIZE   55140000
ROUNDOFF DC    X'FFFFFFF8'             MASK FOR ROUNDING TO NEXT        55150000
*                                      DOUBLE WORD                      55160000
SAVE13   DS    1F                                                       55170000
INC      EQU   4       NUMBRR OF BYTES/ENTRY ON TXTIOT                  55180000
*********************************************************************** 55200000
*              HIADDREG,BGADDREG,CURREGN,NCESDCT MUST BE IN THE CONTIG* 55300000
*              UOUS ORDER - THEY ARE REFERENCED AS A BLOCK            * 55400000
*********************************************************************** 55500000
HIADDREG DC    F'0'                     PRESENT HIGH ADDRESS OF THISREG 55600000
BGADDREG DC    F'0'                          PRESENT BEGIN ADDR OF REG  55700000
NCESDCT  DS    H                        Y - USED TO RECORD CESD CURR CT 55800000
CURRREGN DC    H'0'                     CURRENT REGION NUMBER           55900000
TWELVE   DC    H'12'                                                    56000000
         DS    0F                                                       56100000
*********************************************************************** 56200000
TESTTYPE DC    X'00'                    USED FOR TESTING ESD TYPES      56700000
*                                       HI 4 BITS= 0,LOW 4 BITS FORTYPE 56800000
FOUR096  DC    H'4096'                 CONSTANT OF 4K                   56900000
SEGLNTAB DS    F         ADDRESS OF SEGMENT LENGTH TABLE                56950000
*     TABLE ALSO USED BY IEWLMOUT FOR HI ID'S                           57000000
         DS    50F                                                      57050000
SAVEREGS DS    16F                                                      57100000
*********************************************************************** 57200000
*                                                                     * 57300000
*********************************************************************** 57400000
         IEWAPT                                                         57500000
         END                                                            57600000
