         TITLE    'ENTER SEGMENT NUMBERS'                               00200000
*********************************************************************** 00400000
*                                                                     * 00600000
*STATUS: CHANGE LEVEL                                                 * 00800000
*                                                                     * 01000000
*FUNCTION/OPERATION:                                                  * 01200000
*    1) ENTER SEGMENT NUMBERS FOR LABEL REFERENCES IN CESD            * 01400000
*    2) DETERMINE NUMBER OF ENTAB LINES REQUIRED PER SEGMENT (OVERLAY)* 01600000
*                                                                     * 01800000
*ENTRY POINTS:                                                        * 02000000
*    IEWLMENS- CONTROL SECTION NAME                                     02200000
*                                                                     * 02400000
*INPUT:                                                               * 02600000
*    1) REG 2 - ADDRESS OF ALL PURPOSE TABLE                          * 02800000
*    2) REG 13- ADDRESS OF CALLER SUPPLIED REGISTER SAVE AREA         * 03000000
*    3) TABLES LISTED BELOW                                           * 03200000
*                                                                     * 03400000
*OUTPUT:                                                              * 03600000
*    1) UPDATED COMPOSITE EXTERNAL SYMBOL DICTIONARY-LABEL REFERENCES * 03800000
*    2) COUNT OF ENTAB LINES PER SEGMENT                              * 04000000
*                                                                     * 04200000
*EXTERNAL ROUTINES:                                                   * 04400000
*    1) IEWLELOG - ERROR DIAGNOSTIC ROUTINE                           * 04600000
*    2) IEWLCAD1 - AN ENTRY POINT IN EITHER IEWLKADA OR IEWLFADA      * 04800000
*        A) IEWLCAD1 IS ENTERED FROM IEWLKENS TO RECORD THE NUMBER OF * 05000000
*           LINES OF ENTAB -   REQUIRED PER SEGMENT-                  * 05200000
*          1)IN THE 'E' LINKAGE EDITOR IEWLCAD1 COMPUTES THE SIZE OF  * 05400000
*        THE ENTAB USING THE NUMBER OF LINES PASSED FROM IEWLKENS     * 05600000
*            AND MAKES AN ENTRY IN THE CESD OF TYPE PRIVATE CODE MARKD* 05800000
*            DELETE                                                   * 06000000
*          2)IN THE 'F' LINKAGE EDITOR IEWLCAD1 RECORDS THE ENTAB LINE* 06200000
*            COUNT IN THE SEGMENT LENGTH TABLE AND SETS THE 'E' BIT TO* 06400000
*            1-INDICATING THERE IS AN ENTAB FOR THIS SEGMENT          * 06600000
*        B) IEWLCAD1 IS ENTERED FOR EACH SEGMENT WHICH CONTAINS AN    * 06800000
*           ENTAB                                                     * 07000000
*                                                                     * 07200000
*EXITS:                                                               * 07400000
*   RETURNS TO ADDRESS PASSED IN REGISTER 14                          * 07600000
*                                                                     * 07800000
*TABLES:                                                              * 08000000
*   1) CALLS LIST                                                     * 08200000
*   2) COMPOSITE EXTERNAL SYMBOL DICTIONARY                           * 08400000
*   3) DOWNWARDS CALLS LIST (INTERNAL)                                * 08600000
*   4) SEGMENT TABLE 1                                                * 08800000
*   5) ALL PURPOSE TABLE                                              * 09000000
*                                                                     * 09200000
*ATTRIBUTES:                                                          * 09400000
*                                                                     * 09600000
*********************************************************************** 09800000
IEWLMENS CSECT                                                          10000000
*                                                                     * 10200000
*                                                                     * 10400000
*                                                                       10600000
*                                                                       10800000
*                                                                       11000000
*********************************************************************** 11200000
*                                                                       11400000
*             REGISTERS USED IN IEWLKENS                              * 11600000
*********************************************************************** 11800000
*                                                                       12000000
ERRCODRG EQU   0                        ERROR CODE REGISTER             12200000
WORK4    EQU   0                        WORK                            12400000
WORK1    EQU   1                        WORK                            12600000
ERRSYMRG EQU   1                        ADDRESS OF SYMBOL               12800000
APT      EQU   2                        ALL PURPOSE TABLE ADDRESS       13000000
CALLADD  EQU   3                        ADDRESS OF CALLS LIST           13200000
TEMP2    EQU   3                       TEMPORARY WORK REGISTER          13400000
CURCHNAD EQU   3                        CURRENT CHAIN ADDRESS           13600000
CURINDEX EQU   4                        CURRENT INDEX                   13800000
CURPPTR  EQU   5                        CURRENT P POINTER               14000000
CURRPTR  EQU   6                        CURRENT R POINTER               14200000
CURPSEGN EQU   7                        CURRENT P SEGMENT NUMBER        14400000
CURRSEGN EQU   8                        CURRENT R SEGMENT NUMBER        14600000
CURSEGNO EQU   9                        CURRENT SEGMENT NUMBER          14800000
TEMP1    EQU   9                       TEMPORARY WORK REGISTER          15000000
BASE     EQU   12                       BASE REGISTER                   15200000
ACUMZERO EQU   13                       ACCUMULATO                      15400000
CULTOTCT EQU   14                       CULMULATIVE TOTAL NO. BYTES -2  15600000
RETURN   EQU   14                       RETURN (RETURN FROM CPTH)       15800000
WORK2    EQU   10                       WORK                            16000000
BRANCH   EQU   15                                                       16200000
CULRELCT EQU   15                       CULMULATIVE REL. NO. BYTES      16400000
ERRADDRG EQU   15                       ADDRESS OF ERROR ROUTINE        16600000
WORK3    EQU   15                       WORK                            16800000
WORK5    EQU   15                       WORK   (NOT USED PRESENTLY)     17000000
*********************************************************************   17200000
*              DISPLACEMENTS                                            17400000
*********************************************************************   17600000
DISP     EQU   0                       DISPLACEMENT FOR SAVE AREA       17800000
*********************************************************************** 18000000
*              MASKS                                                    18200000
OVLYBIT  EQU   X'20'                    MASK FOR TESTING FOR OVERLAY    18400000
*                                                                       18600000
XCAL     EQU   X'04'                    XCAL TEST MASK                  18800000
*********************************************************************** 19000000
*********************************************************************** 19200000
*              SAVE CALLERS REGISTERS AND INITIALIZE BASE  REGISTER     19400000
*********************************************************************** 19600000
         STM   14,12,DISP(13)           SAVE CALLERS REGS               19800000
         USING ENS00500+2,BASE                                          20000000
         USING APTDSECT,APT   ESTABLISH ADDRESSABILITY FOR  APT         20200000
ENS00500 BALR  BASE,0                   INITIALIZE BASE                 20400000
         BC    15,MODID+6              BRANCH AROUND MODID              20460000
MODID    DC    C'01MENS'                                                20520000
         ST    13,SAVERG13              SAVE 13 -ADD OF CALLERS  REGS   20600000
*********************************************************************** 20800000
*                                                                       21000000
*********************************************************************** 21200000
*              SCAN CESD  - PUT PROPER  SG NO OF LR IN CESD LR ENTRY    21400000
*********************************************************************** 21600000
ENS0070  L     WORK1,CHESD        CESD ADD                              21800000
         LH    WORK2,ENCDC         CESD CURR CT                         22000000
ENS00750 LA    WORK1,16(WORK1)         INC CESD ADD                     22200000
         MVN   TESTTYPE(1),8(WORK1)     MOVE TYPE TO TEST FOR LR        22400000
         CLI   TESTTYPE,X'03'           IS TYPE = LR                    22600000
         BC    7,ENS00770               NO / GO TEST END OF LOOP        22800000
*********************************************************************** 23000000
*              TYPE = LR                                                23200000
*********************************************************************** 23400000
         LH    WORK3,14(WORK1)         ID                               23600000
         SLL   WORK3,4                 REL ADD                          23800000
         A     WORK3,CHESD        ADD OF CS                             24000000
         MVC   12(1,WORK1),12(WORK3)   PUT CS.SG.NO. IN SG.FD. OF LR    24200000
ENS00770 BCT   WORK2,ENS00750          BRANCH IF LOOP NOT DONE          24400000
*********************************************************************** 24600000
*              TEST FOR OVELAY / NO RETURN TO CALLER /YES CONTINUE PROC 24800000
*********************************************************************** 25000000
         TM    PDSE7,OVLYBIT       IS PROGRAM IN OVERLAY                25200000
         BC    8,ENS115                 NO/ GO TO RETURN TO CALLER      25400000
*********************************************************************** 25600000
*              TEST FOR NO ENTRYS IN CALLS LIST - NO V CONSTANTS-ERR  * 25800000
*********************************************************************** 26000000
         NI    PSEGONE,X'00'           INIT-TO TEST FOR VALID CALL      26200000
*                                      FROM SEGMENT 1                   26400000
         SR    ACUMZERO,ACUMZERO                                        26600000
         CH    ACUMZERO,ENCLC      IS CALL LIST EMPTY                   26800000
         BC    8,ENS110                YES / GO TO PRINT ERROR MESS.    27000000
*********************************************************************** 27200000
*              SCAN CALLS LIST AND INSERT RELAYIVE ADDRESS (CA)       * 27400000
*********************************************************************** 27600000
         L     CALLADD,CLLT        ADDRESS OF CALLS LIST                27800000
         SR    CULTOTCT,CULTOTCT                                        28000000
ENS00800 SR    CULRELCT,CULRELCT                                        28200000
ENS00900 LA    CULRELCT,2(CULRELCT)     INCREMENT CUL RELATIVE CT BY 2  28400000
         CH    ACUMZERO,0(CALLADD,CULRELCT)  IS CALLS LIST ENTRY = 0    28600000
         BC    7,ENS00900                    NO                         28800000
         STH   CULRELCT,0(CALLADD)       T)  INSERT CURRENT CHAIN ADD.  29000000
         LA    CALLADD,0(CALLADD,CULRELCT)                              29200000
         LA    CULTOTCT,0(CULTOTCT,CULRELCT) IN CHAIN / FIND TOTAL CT   29400000
         CH    CULTOTCT,ENCLC      IS SCAN DONE                         29600000
         BC    7,ENS00800              NO                               29800000
*                                                                       30000000
*                                                                       30200000
         NI    PSEGONE,X'00'            INIT. TO TEST VALID CALL FR SG1 30400000
*********************************************************************** 30600000
*              SET DOWNWARD CALLS LIST (ENTRY LIST) TO ZERO + INITALIZE 30800000
*********************************************************************** 31000000
         L     WORK1,RECNT         ADD OF ENTRY LIST                    31200000
         SR    TEMP1,TEMP1                                              31400000
         LH    TEMP2,ENCDC                                              31600000
         SRL   TEMP2,2                 NO. OF FULL WORDS IN LIST        31800000
         LA    TEMP2,1(TEMP2)          IF CESD CT LESS 4-SRL = 0 - T2 0 32000000
ENS011   LA    WORK1,4(WORK1)          INC ADDRESS OF NEXT ENTRY        32200000
         ST    TEMP1,4(WORK1)           SET THIS ENTRY TO 0             32400000
         BCT   TEMP2,ENS011            BRANCH IF LOOP NOT DONE          32600000
         SR    CURSEGNO,CURSEGNO                                        32800000
*********************************************************************** 33000000
*              INCREMENT CURRENT SEGMENT NUMBER/TEST IF ALL SEGMENTS    33200000
*              PROCESSED/YES RETURN TO CALLER / NO CONTINUE             33400000
*********************************************************************** 33600000
ENS015   LA    CURSEGNO,1(CURSEGNO)                                     33800000
         L     CURCHNAD,CLLT       ADD OF CALLS LIST                    34000000
         SR    ACUMZERO,ACUMZERO                                        34200000
         CH    CURSEGNO,CSNO       HAVE ALL SEGMENTS BEEN PROCESSED     34400000
         BC    2,ENS110                YES                              34600000
*********************************************************************** 34800000
*              INITIALIZE TO FIND NEXT P IN CALLS LIST                  35000000
*********************************************************************** 35200000
ENS017   SR    CURINDEX,CURINDEX                                        35400000
         SR    CURPSEGN,CURPSEGN                                        35600000
         LA    CURINDEX,2(CURINDEX)          INDEX TO P PTR             35800000
         LH    CURPPTR,0(CURCHNAD,CURINDEX)  CURRENT P PTR              36000000
         LR    WORK1,CURPPTR                 CURRENT P PTR              36200000
         SLL   WORK1,4                       MULT BY 16                 36400000
         A     WORK1,CHESD         POINTS TO CESD LINE  ID=P            36600000
         IC    CURPSEGN,12(WORK1)       CURRENT SEGMENT NO OF P         36800000
*********************************************************************** 37000000
*              DOES THE CONTROL SECTION WITH ITS ESDID = THIS P LIE IN  37200000
*              THE CURRENT SEGMENT/ NO GO TO TEST END OF CALLS LIST     37400000
*********************************************************************** 37600000
*********************************************************************** 37800000
*              TEST FOR A CONTROL SECTION IN SEGMENT 1                  38000000
*********************************************************************** 38200000
         LA    WORK1,1                  INIT WORK1 TO 1                 38400000
         CLR   WORK1,CURPSEGN           IS THIS P IN SEGMENT 1          38600000
         BC    7,ENS018                 NO / CONTINUE                   38800000
         OI    PSEGONE,X'80'            SET IND A CALL FROM SEG 1 SEEN  39000000
ENS018   CLR   CURSEGNO,CURPSEGN        DOES CURR.P SEG.NO.= CURR.SEG.  39200000
         BC    7,ENS1200                NO                              39400000
*********************************************************************** 39600000
*              INCREMENT TO NEXT CALLS LIST ENTRY / TEST IF ALL RS FOR  39800000
*              THIS P HAVE BEEN PROCESSED                               40000000
*********************************************************************** 40200000
ENS020   LA    CURINDEX,2(CURINDEX)     INCREMENT TO NEXT R OR CHAIN    40400000
         CH    CURINDEX,0(CURCHNAD)     IS SCAN FOR THIS P PTR DONE     40600000
         BC    8,ENS1200                YES                             40800000
*********************************************************************** 41000000
*              USING R POINTER REFERENCE CESD TO DETERMINE WHAT ITS     41200000
*              TYPE IS / ER,PR NO GOOD                                  41400000
*********************************************************************** 41600000
         LH    CURRPTR,0(CURCHNAD,CURINDEX)  PICK UP CURRENT R PTR      41800000
         LR    WORK1,CURRPTR                 CURRENT R PTR              42000000
         SLL   WORK1,4                       MULT BY 16                 42200000
         A     WORK1,CHESD         POINTS TO ENTRY IN CESD R=ID         42400000
*********************************************************************** 42600000
         MVN   TESTTYPE,8(WORK1)        MOVE LOW 4 BITS FOR TEST        42800000
         CLI   TESTTYPE,X'08'           IS TYPE = SD WITH RLDS          43000000
         BC    2,ENS020                 HIGH - GO TO NEXT R OR CA       43200000
         BC    8,ENS030                 YES - PROCESS SD                43400000
         CLI   TESTTYPE,X'05'           IS TYPE = CM                    43600000
         BC    2,ENS020                 HIGH - GO TO NEXT R OR CA       43800000
         BC    8,ENS030                 YES - PROCESS CM                44000000
         TM    TESTTYPE,X'03'           IS TYPE = SD OR LR              44200000
         BC    4,ENS020                 NO - GO TO PROCESS NEXT R OR CA 44400000
*                                       TYPES SD,SD W/RLD,LR,CM OK      44600000
*********************************************************************** 44800000
*              FIND SEGMENT NUMBER OF THIS R POINTER - USE CESD         45000000
*********************************************************************** 45200000
ENS030   SR    CURRSEGN,CURRSEGN                                        45400000
         IC    CURRSEGN,12(WORK1)       PICK UP SEGMENT NO OF R = SR    45600000
*********************************************************************** 45800000
*              TEST FOR UPWARD CALL - YES - NO ENTAB LINES REQUIRED     46000000
*********************************************************************** 46200000
         CLR   CURRSEGN,CURPSEGN        DOES  SR = SP                   46400000
         BC    8,ENS020                 YES UPWARD CALL / NO LINES      46600000
         LR    WORK1,CURRSEGN           PASS SR TO COMMON PATH          46800000
         LR    WORK2,CURPSEGN           PASS SP TO COMMON PATH          47000000
         BAL   RETURN,ENS1500                                           47200000
         CLR   WORK2,CURRSEGN           DOES  SR = SC                   47400000
         BC    8,ENS020                 YES  (UPWARD CALL) / NO LINES   47600000
*********************************************************************** 47800000
*              TEST FOR DOWNWARD CALL - YES - MAY REQUIRE ENTAB         48000000
*********************************************************************** 48200000
         CLR   WORK2,CURPSEGN           DOES  SP = SC                   48400000
         BC    8,ENS080                 YES  (DOWNWARD CALL)            48600000
*********************************************************************** 48800000
*              DETERMINE  REGION NUMBERS FOR SEGMENT NUMBERS P AND R    49000000
*********************************************************************** 49200000
         SR    WORK1,WORK1                                              49400000
         SR    WORK2,WORK2                                              49600000
         SR    WORK4,WORK4                                              49800000
ENS040   IC    WORK4,LSTS(WORK1)   HI SEG OF THIS REG                   50000000
         LA    WORK1,1(WORK1)                REG NO.FOR SP IN WORK1     50200000
         CR    CURPSEGN,WORK4          DOES SP LIE IN THIS REG          50400000
         BC    2,ENS040                NO                               50600000
ENS050   IC    WORK4,LSTS(WORK2)   HI SEG OF THIS REG                   50800000
         CR    CURRSEGN,WORK4  DOES SR LIE IN THIS REG                  51000000
         LA    WORK2,1(WORK2)                REG NO.FOR SR IN WORK2     51200000
         BC    2,ENS050                NO                               51400000
*********************************************************************** 51600000
*              DO BOTH SEGMENTS LIE IN THE SAME REGION / YES MAY B ERR  51800000
*********************************************************************** 52000000
         CLR   WORK1,WORK2              DOES  RSP = RSR                 52200000
         BC    7,ENS080                 NO / CALL TO DIFFERENT REGION   52400000
*********************************************************************** 52600000
*              CONVERT SEGMENT NUMBER FROM WHICH THIS EXCLUSIVE CALL  * 52800000
*              HAS BEEN MADE FROM BINARY TO DECIMAL FOR PRINTING MESS.* 53000000
*********************************************************************** 53200000
         LR    WORK3,CURPSEGN           FROM SEGMENT                    53400000
         CVD   WORK3,CVDAREA            CONVERT TO DECIMAL              53600000
         UNPK  CVDAREA+0(5),CVDAREA+6(3)  UNPACK TO SUPPLY ZONE         53800000
         CLI   CVDAREA,C'0'            IS FIRST DIGIT ZERO              53900000
         BC    7,ENS055                NO                               54000000
         MVI   CVDAREA,C' '            YES--MOVE IN BLANK               54100000
         CLI   CVDAREA+1,C'0'          IS SECOND DIGIT ZERO             54200000
         BC    7,ENS055                NO                               54300000
         MVI   CVDAREA+1,C' '          YES--MOVE IN BLANK               54400000
ENS055   MVI   CVDAREA+3,C' '                                           54600000
         MVC   CVDAREA+4(4),CVDAREA+3  BLANK REMAINING FIVE CHARACTERS  54800000
*                                       PRINTING 8 CHARACTERS           55000000
*********************************************************************** 55200000
*              USING DOWNWARD CALLS LIST DETERMINE IF THERE IS AN ENTAB 55400000
*              IN A SEGMENT COMMON TO CURRENT(SP) TO SYMBOL WITH ESDID  55600000
*              = TO R /YES-IS VALID XCAL / NO- IS INVALID XCALL         55800000
*********************************************************************** 56000000
         L     WORK3,RECNT         ENTRY LIST ADDRESS                   56200000
         IC    WORK4,4(WORK3,CURRPTR)   GET ENTRY AT THIS R = SPCR      56400000
         LTR   WORK2,WORK4              DOES SEG.NO = 0/ PUT SPCR WORK2 56600000
         BC    8,ENS070                 YES/NO PREVIOUS CALLS TO THIS R 56800000
         LR    WORK1,CURPSEGN           PASS SP TO CPTH                 57000000
         BAL   RETURN,ENS1500           GO TO COMMON PATH  ANS =  SC    57200000
         CLR   WORK2,WORK4              DOES SC = SPCR                  57400000
         BC    7,ENS070                 NO /NO CALL TO THIS R FROM A    57600000
*                                       SEGMENT IN ROOT PATH OF SP      57800000
*********************************************************************** 58000000
*              TEST IF XCALL OPTION SPECIFIED - YES -EXECUTE            58200000
*********************************************************************** 58400000
         LH    ERRCODRG,ERRPARM1        ASSUME XCALL ON/NO ERROR-WARN   58600000
         TM    APT0,XCAL           IS XCAL OPTION = ON                  58800000
         BC    1,ENS060                 XCALL ON/ GO PRINT WARNING      59000000
         LH    ERRCODRG,ERRPARM2        XCALL OFF /EXECUTE ON LET ONLY  59200000
*                                       SEVERITY 3                      59400000
*********************************************************************** 59600000
*              GO TO ERROR DIAGNOSTIC ROUTINE TO PRINT MESSAGE          59800000
*********************************************************************** 60000000
ENS060   ST    ACUMZERO,SAVECT          SAVE ENTAB COUNT                60200000
         LR    ACUMZERO,CURRPTR         ID OF R - TO SYMBOL             60400000
         SLL   ACUMZERO,4               RELATIVE ADD OF SYMBOL          60600000
         A     ACUMZERO,CHESD      TRUE ADDRESS OF SYMBOL               60800000
         L     ERRADDRG,ERDIG      ERROR ADD                            61000000
         LA    ERRSYMRG,CVDAREA        ADDRESS OF SEGMENT NUMBER        61200000
         BALR  RETURN,ERRADDRG                                          61400000
         L     ACUMZERO,SAVECT          RESTORE COUNT OF ENTAB LINES    61600000
         BC    15,ENS020                                                61800000
*********************************************************************** 62000000
*              AN INVALID CALL HAS BEEN DETECTED  SET UP TO PRINT MESS. 62200000
*********************************************************************** 62400000
ENS070   LH    ERRCODRG,ERRPARM3        INVALID XCALL / EXECUTE ON LET  62600000
         BC    15,ENS060                                                62800000
*********************************************************************** 63000000
*              TEST IF A PREVIOUS CALL HAS BEEN MADE TO THIS SYMBOL     63200000
*              FROM A SEGMENT COMMON TO THE CURRENT SEGMENT             63400000
*********************************************************************** 63600000
ENS080   L     WORK3,RECNT         ADD OF DOWNWARD CALLS LIST           63800000
         SR    WORK2,WORK2                                              64000000
         IC    WORK2,4(WORK3,CURRPTR)   GET SEG NO OF PREVIOUS CALL     64200000
         LTR   WORK4,WORK2              WAS THERE A PREVIOUS CALL       64400000
         BC    8,ENS090                 NO                              64600000
         LR    WORK1,CURPSEGN           PASS SP TO CPTH                 64800000
         BAL   RETURN,ENS1500           GO TO COMMON PATH/ANS IS = SC   65000000
         CLR   WORK2,WORK4              DOES SC = SPCR                  65200000
         BC    8,ENS020                 YES /AN ENTAB LINE EXISTS IN    65400000
*                                       THE ROOT PATH OF SP FOR R       65600000
*********************************************************************** 65800000
*              PUT THE CURRENT SEGMENT NUMBER IN THE DOWNWARDS CALL     66000000
*              LIST AT THE R TH ENTRY-- R IS THE ESDID OF THE CALLED    66200000
*              SYMBOL                                                   66400000
*********************************************************************** 66600000
ENS090   L     WORK3,RECNT                                              66800000
         STC   CURPSEGN,4(WORK3,CURRPTR)                                67000000
         LA    ACUMZERO,1(ACUMZERO)                                     67200000
*********************************************************************** 67400000
*              TEST IF A CALL HAS BEEN MADE FROM SEG 1 - YES-TO VALID   67600000
*              SYMBOL / YES - SET INDICATOR IN PSEGONE -BIT 2           67800000
*********************************************************************** 68000000
         TM    PSEGONE,X'80'            IS THIS CALL FROM SEGMENT 1     68200000
         BC    8,ENS020                 NO /                            68400000
         OI    PSEGONE,X'40'            YES / AN A VALID CALL WAS  MADE 68600000
         BC    15,ENS020                                                68800000
*********************************************************************** 69000000
*              TEST IF A VALID CALL HAS BEEN FROM SEGMENT 1 TO A SYMBOL 69200000
*              NOT IN SEGMENT 1                                         69400000
*********************************************************************** 69600000
ENS110   LH    ERRCODRG,ERRPARM4                                        69800000
         TM    PSEGONE,X'40'                                            70000000
         BC    1,ENS115                 YES/ DO NOT PRINT ERROR MESS    70200000
         L     ERRADDRG,ERDIG      ADD OF ERROR DIAGNOSTIC ROUTINE      70400000
         BALR  RETURN,ERRADDRG          GO TO ERROR DIAGNOSTIC ROUTINE  70600000
*********************************************************************** 70800000
*              RESTORE REGISTERS AND RETURN TO CALLER                   71000000
*********************************************************************** 71200000
ENS115   L     13,SAVERG13              RESTORE ADDRESS OF CALLERS AREA 71400000
         LM    14,12,DISP(13)           RESTORE CALLERS REGISTERS       71600000
         BCR   15,14                    RETURN TO CALLER                71800000
*********************************************************************** 72000000
*              SET INDICATOR FOR PROCESSING A CONTROL SECTION IN SG1TO0 72200000
*********************************************************************** 72400000
ENS1200  NI    PSEGONE,X'7F'            SET P IN SEGMENT 1 TO 0         72600000
*********************************************************************** 72800000
*              TEST FOR END OF PROCESSING CURRENT SEGMENT               73000000
*********************************************************************** 73200000
         AH    CURCHNAD,0(CURCHNAD)     ADD.CURRENT CHAIN ADDRESS TO    73400000
*                                       ADD.OF PREVIOUS CHAIN ADDRESS   73600000
ENS010   LH    WORK1,0(CURCHNAD)        CURRENT CHAIN                   73800000
         LTR   WORK1,WORK1              IS SCAN FOR CURRENT SEGMENT DON 74000000
         BC    2,ENS017                NO  / LOOK AT NEXT P             74200000
*********************************************************************** 74400000
*              TEST IF THERE ANY ENTAB LINES FOR THIS SEGMENT/ YES GO   74600000
*              TO IEWLCAD1 TO RECORD COUNT.                             74800000
*********************************************************************** 75000000
         LTR   ACUMZERO,ACUMZERO        ANY ENTAB LINES FOR THIS SEG    75200000
         BC    8,ENS015                 NO  GO TO PROCESS NXT SEGMENT   75400000
         LM    RETURN,BRANCH,ENS1300    SET UP RETURN & BRANCH REGS     75600000
         BCR   15,BRANCH                GO TO PCEB / ENTER ENTAB INCESD 75800000
*********************************************************************** 76000000
*********************************************************************** 76200000
*              CPTH -  COMMON PATH SUBROUTINE                         * 76400000
*                                                                     * 76600000
*                                                                     * 76800000
*********************************************************************** 77000000
*                                                                     * 77200000
*                   REQUIRED REGISTERS  & PARAMETERS                  * 77400000
*                        BASE                                         * 77600000
*                        WORK1     SEG A  (NOT SAVED)                 * 77800000
*                        WORK2     SEG B  (NOT SAVED)  ANS PUT HERE   * 78000000
*                        WORK3     WORK REGISTER (NOT SAVED)          * 78200000
*                        RETURN    RETURN ADDRESS                     * 78400000
*                        APT       ALL PURPOSE TABLE                  * 78600000
*********************************************************************** 78800000
*********************************************************************** 79000000
ENS1500  L     WORK3,SGT1          ADDRESS OF SEGTAB1                   79200000
ENS1600  CLR   WORK2,WORK1              DOES  SEG B = SEG A             79400000
         BCR   8,RETURN                 YES - ANS IN WORK 2             79600000
         BC    2,ENS1700                NO  -SEG B GTR SEG A            79800000
         XR    WORK2,WORK1              NO  -SEG B LOW SEG A            80000000
         XR    WORK1,WORK2              EXCHANGE PARAMETERS             80200000
         XR    WORK2,WORK1                                              80400000
ENS1700  IC    WORK2,0(WORK3,WORK2)     GET PREVIOUS SEGMENT NUMBER     80600000
         LTR   WORK2,WORK2              IS PREVIOUS SEGMENT NUMBER = 0  80800000
         BC    2,ENS1600                NO                              81000000
         LA    WORK2,1                  SET ANS = 1                     81200000
         BCR   15,RETURN                                                81400000
*********************************************************************** 81600000
*********************************************************************** 81800000
ENS1300  DC    A(ENS015)                RETURN ADDRESS                  82000000
         DC    V(IEWLCAD1)                                              82200000
SIX      DC    H'6'                     CONSTANT OF 6                   82400000
*                                                                       82600000
TESTTYPE DC    X'00'                    USED FOR TESTING LOW 4 BITS OF  82800000
*                                       ESD TYPE                        83000000
PSEGONE  DC    X'00'                    USED TO INDICATE AVALID CALL    83200000
*                                       FROM SEGMENT 1                  83400000
*                                       BIT 1- INIT= 0  1= CALL FROMSG1 83600000
*                                       BIT 2- INIT= 0  1= CALL FROMSG1 83800000
*                                        TO A VALID SYMBOL NOT IN SEG 1 84000000
CVDAREA  DS    2D          '            PRINT IMAGE FOR XCALL MESSAGE   84200000
SAVECT   DC    F'0'                     SAVE  ENTAB COUNT WHEN GOING TO 84400000
*                                       ERROR DIAGNOSTIC ROUTINE        84600000
SAVERG13 DS    F                        ADDRESS OF CALLERS REG SAVEAREA 84800000
*********************************************************************** 85000000
*              ERROR PARAMETERS                                       * 85200000
*********************************************************************** 85400000
MESS1    EQU   X'3110'                                                  85600000
MESS2    EQU   X'3211'                                                  85800000
MESS3    EQU   X'3212'                                                  86000000
MESS4    EQU   X'020F'                                                  86200000
ERRPARM1 DC    AL2(MESS1)               WARNING XCLUSIVE CALL-XCALL ON  86400000
ERRPARM2 DC    AL2(MESS2)               ERROR XCLUSIVE  CALL -XCALL OFF 86600000
ERRPARM3 DC    AL2(MESS3)               ERROR INVALID XCLUSIVE CALL     86800000
ERRPARM4 DC    AL2(MESS4)               NO CALLS FROM SEG 1 TO VALID    87000000
*                                                                       87200000
*                                                                       87400000
*                                                                       87600000
*********************************************************************** 87800000
         IEWAPT                                                         88000000
*********************************************************************** 88200000
         END                                                            88400000
