          TITLE   'ENTRY POINT PROCESSOR'                               00300000
*********************************************************************** 00600000
*              IEWLMENT - ENTRY POINT PROCESSOR - ALIAS TABLE BUILDER * 00900000
*********************************************************************** 01200000
*                                                                       01500000
*              ENTRY POINT - IEWLMENT - CONTROL SECTION NAME          * 01800000
*                                                                       02100000
*              INPUT -                                                  02400000
*                  A)  1) COMPOSITE EXTERNAL DICTIONARY                 02700000
*                      2) RELOCATION CONSTANT TABLE                     03000000
*                      4) ENTRY POINT SYMBOL OR ASSEMBLED ADD AND ESDID 03300000
*                      3) INDICATION IF ENTRY POINT HAS BEEN RECIEVED   03600000
*                      4)ALIAS TABLE                                    03900000
*                                                                       04200000
*                 B)   1) GP REGISTER  2 -ADDRESS OF ALL PURPOSE TABLE  04500000
*                      2) GP REGISTER 13 -ADDRESS OF A REG SAVE AREA    04800000
*                      3) GP REGISTER 14 -CALLER RETURN ADDRESS         05100000
*                                                                       05400000
*********************************************************************** 05700000
*********************************************************************** 06000000
*                   DETERMINE ENTRY POINT  AND ASSOCIATED ESDID       * 06300000
*                                                                     * 06600000
*              PROCEDURE:                                             * 06900000
*                                                                     * 07200000
*               (A) BUILD ALIAS TABLE USING ALIAS CHAIN IN CESD       * 07500000
*               (B) HAS AN ENTRY POINT BEEN DEFINED ?                 * 07800000
*                  (1)YES - IS IT SYMBOLIC ?                          * 08100000
*                     (A)YES-FIND SYMBOL IN CESD  (NOT FOUND IS ERROR)* 08400000
*                            IS SYMBOL TYPE = SD OR LR (NO IS ERROR)  * 08700000
*                            IS SYMBOL IN SEGMENT 1 (NO IS AN ERROR)  * 09000000
*                     (B)NO - ENTRY POINT IS AN ASSEMBLED ADDRESS     * 09300000
*                            USING GIVEN ESDID FIND LINKED ADDRESS    * 09600000
*                            USING ESDID CHECK ADDRESS TO BE IN SEG 1 * 09900000
*                             (NOT IN SEGMENT 1 IS AN ERROR)          * 10200000
*                  (2)NO  -  FIND LOWEST LINKED ADDRESS FOR TYPE SD OR* 10500000
*                            PC (NOT DELETE) IN CESD IN SEGMENT 1     * 10800000
*                            (NOT FOUND IS AN ERROR)                  * 11100000
*                                                                     * 11400000
*                                                                     * 11700000
*********************************************************************** 12000000
*                                                                       12300000
*              REGISTER USAGE                                           12600000
*                                                                       12900000
IEWLMENT CSECT                                                          13000000
* 615000                                                         A30670 13100020
ERRCODRG EQU   0                                                   REGS 13200000
ERRSYM   EQU   1                        ERROR SYMBOL ADDRESS       REGS 13500000
ALIASTBL EQU   3                       ADDRESS OF ALIAS TABLE           13800000
WORK1    EQU   5                       WORK REG                         14100000
APT      EQU   2                        APT                        REGS 14400000
CESDCT   EQU   11                       CESD CURR CT               REGS 14700000
BASE     EQU   12                                                  REGS 15000000
WORK2    EQU   13                                                       15300000
RCTADD   EQU   8                       ADDRESS OF RCT              REGS 15600000
RETURN   EQU   14                                                  REGS 15900000
TEMP4    EQU   9                                                        16200000
TEMP3    EQU   10                                                       16500000
EVEN     EQU   14                      EVEN REG OF AN EVEEN /ODD PAIR   16800000
TEMP1    EQU   6                        TEMPORARY WORK                  17100000
ALIASADD EQU   7                        ADDRESS OF ALIAS ENTRY IN CESD  17400000
BRANCH   EQU   15                                                  REGS 17700000
CESDADD  EQU   8                        CESD ADDRESS             REGS   18000000
ENTRYCD  EQU   X'02'                    ENTRY CARD RECIEVED- MASK       18300000
OVERLYBT EQU   X'20'                    OVERLAY MASK               DISP 18600000
ENTPTSYM EQU   X'04'                    SYMBOLIC ENTRY PT MASK          18900000
ENTPTRCD EQU   X'08'                    ENTRY PT RECVD IND.             19200000
NULL     EQU   X'07'                                               DISP 19500000
DISP     EQU   0                        REL DISP TO SAVE CALLERS REGS   19800000
*                                                                       20100000
*********************************************************************** 20700000
*              SAVE ALL REGISTERS                                     * 21000000
*********************************************************************** 21300000
         STM   14,12,DISP(13)                                           21600000
         USING ENT00050+2,BASE                                          21900000
         USING APTDSECT,APT                                             22200000
ENT00050 BALR  BASE,0                                                   22500000
         BC    15,MODID+6              BRANCH AROUND MODULE IDENT       22600000
MODID    DC    C'01MENT'                                                22700000
         ST    13,SAVERG13                                              22800000
         NI    WORKBYTE,X'00'           INITIALIZE WORKBYTE TO ZERO     23100000
*********************************************************************** 23400000
*              CHAIN THROUGH CESD FINDING ALIASES - SCAN CESD FOR A   * 23700000
*               SYMBOL MATCH                                          * 24000000
*                  1) MATCH - SAVE ESD ID IN ALIAS TABLE              * 24300000
*                  2) NO MATCH - PUT 0 FOR ESDID IN ALIAS TABLE       * 24600000
*********************************************************************** 24900000
*********************************************************************** 25200000
*              ALIAS  TABLE  BUILDER                                    25500000
*********************************************************************** 25800000
*              THE FOLLOWING EXPLAINS THE ALIAS TABLE BUILDING TECH   * 26100000
*                                                                     * 26400000
*                1) THE ALIAS SYMBOL IS PLACED IN THE ALIAS TABLE  IN * 26700000
*                   BYTE LOCATIONS 1-8                                * 27000000
*                2) IF A MATCH BETWEEN THE ALIAS SYMBOL AND AN SD OR  * 27300000
*                   LR SYMBOL IN SEG 1 IS NOT FOUND - A 0 IS PUT BYTES* 27600000
*                   9 AND 10 OF THE ALIAS TABLE                       * 27900000
*                3) IF A MATCH IS FOUND THE ESD ID OF THIS SYMBOL IN  * 28200000
*                   THE ALIAS CHAIN IS SAVED IN BYTES 9 AND 10 OF THE * 28500000
*                   ALIAS TABLE - THIS ESDID (OR POINTER TO THE CESD) * 28800000
*                   POINTS TO A LINE OF ESD TYPE NULL (07 HEX)FOUND IN* 29100000
*                   BYTE 8 OF THE CESD ENTRY - IN BYTES 10-12 THE     * 29400000
*                   ADDRESS OF LR OR SD IS SAVED - BYTES 13 AND 14 ARE* 29700000
*                   NOT USED - BYTES 15-16 CONTAIN THE ESD ID OF THE  * 30000000
*                   SD WHICH THE ALIAS SYMBOL MATCHED OR THE SD IN    * 30300000
*                   WHICH THE LR(WHICH THE ALIAS SYMBOL MATCHED) RESID* 30600000
*                   ES -  THIS ESD ID IS SAVED FOR SCATTER LOADING    * 30900000
*                4) THE CESD ENTRIES WHICH WERE CHAINED TOGETHER IN THE 31200000
*                   FIRST PASS TO RECORD ALIAS SYMBOLS ARE NOW USED TO* 31500000
*                   RECORD THE SYMBOL'S ADDRESS AND ID WHEN NEEDED.   * 31800000
*                5) THE INFORMATION IS USED BY THE FINAL PROCESSOR IN * 32100000
*                   STOWING ALIASES                                   * 32400000
*********************************************************************** 32700000
*                                                                       33000000
ENT00150 L     ALIASADD,ALCB       ADDRESS OF FIRST ALIAS ITEM          33300000
         L     ALIASTBL,ALAS       ADDRESS OF ALIAS TABLE               33600000
         L     TEMP1,CHESD         ADDRESS OF CESD                      33900000
         LH    TEMP3,ENCDC         CESD CT                              34200000
ENT00155 LR    CESDADD,TEMP1            RESTORE CESD ADD                34500000
         LR    CESDCT,TEMP3             RESTORE CESD CT                 34800000
ENT00160 LTR   ALIASADD,ALIASADD        ARE  THERE ANY MORE ALIASES     35100000
         BC    8,ENT00200               NO /GO TO FIND ENTRY ADDRESS    35400000
         MVC   0(8,ALIASTBL),0(ALIASADD) MV ALIAS SYMBOL TO ALIAS TABLE 35700000
         MVI   8(ALIASADD),NULL           SET THIS CESD LINE- TYPE NULL 36000000
         L     WORK1,8(ALIASADD)       ADDREAS OF NEXT ALIAS SYMBOL     36300000
ENT00190 LA    CESDADD,16(CESDADD)      INCREMENT TO FIRST(NEXT) ENTRY  36600000
         CLC   0(8,CESDADD),0(ALIASTBL) DOES ALIAS SYM = THIS CESD SYM  36900000
         BC    7,ENT00192               NO /BRANCH TO TEST END CESDLOOP 37200000
         LR    ERRSYM,CESDADD           ADDRESS OF ALIAS TABLE          37500000
         MVC   9(7,ALIASADD),9(CESDADD) MOVE ADD OF LR OR SD TO NULL    37800000
*                                       LINE,ALSO MOVE ID/L FIELD       38100000
         LA    WORK2,ENT00192           RETURN ADDRESS IF TYPE NE SD,LR 38400000
         LA    TEMP4,ENT01191           RETURN IF TYPE = LR             38700000
         BAL   RETURN,ENT01800          GO TO TEST TYPE FOR SD OR LR    39000000
         SR    CESDADD,TEMP1           RELATIVE CESD ADD OF SYMBOL      39300000
         SRL   CESDADD,4               ID OF SYMBOL                     39600000
         STH   CESDADD,14(ALIASADD)    PUT ID OF SD IN LD LINE          39900000
ENT01191 CLI   12(ERRSYM),X'01'         IS  SD OR LR IN SEG 1           40200000
         BC    7,ENT00198               NO / GO TO PRINT ERROR MESSAGE  40500000
         SR    ALIASADD,TEMP1           RELATIVE ADD OF AE LINE         40800000
         SRL   ALIASADD,4               ID OF AE LINE                   41100000
ENT00191 STH   ALIASADD,8(ALIASTBL)     PUT ID OF AE LINE IN ALIAS TBL  41400000
         LA    ALIASTBL,10(ALIASTBL)    INCREMENT TO NEXT ALIAS SYMBOL  41700000
         LA    ALIASADD,0(WORK1)        RESTORE ADD OF NEXT ALIAS SYM   42000000
         BC    15,ENT00155              BRANCH TO TEST END OF ALIASLOOP 42300000
ENT00192 BCT   CESDCT,ENT00190          BRANCH IF CESD LOOP NOT DONE    42600000
ENT00197 SR    ALIASADD,ALIASADD                                        42900000
         BC    15,ENT00191              BRANCH STORE 0 ID - CONTINUE    43200000
*                                                                       43500000
ENT00198 LH    ERRCODRG,ERRPARM9        ERROR- ALIAS SYMBOL NOT IN SEG1 43800000
         LA    RETURN,ENT00197          RETURN ADDRESS                  44100000
         BC    15,ENT00500              GO TO /GO TO ERROR ROUT.        44400000
*********************************************************************** 44700000
*              DETERMINE ENTRY POINT OF MODULE                          45000000
*********************************************************************** 45300000
ENT00200 TM    APT1,ENTPTRCD       ENTRY POINT RECEIVED                 45600000
         BC    8,ENT01250               NO / GO FIND 1ST GOOD BYTE SEG1 45900000
         TM    APT1,ENTPTSYM       ENTRY PT SYMBOLIC                    46200000
         BC    8,ENT01200               NO - GO FIND ABSOLUTE           46500000
*********************************************************************** 46800000
*              ENTRY POINT IS SYMBOLIC                                * 47100000
*********************************************************************** 47400000
ENT00300 LA    CESDADD,16(CESDADD)      INC CESD ADD                    47700000
         CLC   EPSM(8),0(CESDADD)  DOES ENTRY SYMBOL =  CESD SYMBOL     48000000
         BC    8,ENT00600               YES / GO TO FIND ITS ADD        48300000
ENT00350 BCT   CESDCT,ENT00300          BRANCH IF LOOP NOT DONE         48600000
         LH    ERRCODRG,ERRPARM3       SYMBOL NOT SD,LR IN CESD-ENTRY   48900000
         TM    APT1,ENTRYCD        HAS AN ENTRY CD BEEN RECEIVED        49200000
         BC    1,ENT00400               YES                             49500000
         LH    ERRCODRG,ERRPARM4       SYMBOL NOT SD,LR IN CESD-ENTRY   49800000
ENT00400 LA    ERRSYM,EPSM         ADDRESS OF SYMBOL                    50100000
ENT00450 LA    RETURN,ENT01100          RETURN ADDRESS                  50400000
ENT00500 L     BRANCH,ERDIG        ADD OF ERROR DIAGNOSTIC ROUTINE      50700000
         BCR   15,BRANCH                GO TO ERROR DIAGNOTIC ROUTINE   51000000
ENT00600 MVC   LKDENTPT+1(3),9(CESDADD) SAVE ENTRY PT ADDRESS           51300000
         LA    WORK2,ENT00350           RETURN IF TYPE NOT ACCEPTABLE   51600000
         LA    TEMP4,ENT00800           RETURN IF TYPE = SD OR LR       51900000
         BAL   RETURN,ENT01800          GO TO TEST TYPE- SD,LR,SD W RLD 52200000
ENT00800 CLI   12(CESDADD),X'01'        ENTRY PT IN SEGMENT 1           52500000
         BC    7,ENT01700               NO / INVALID ENTRY POINT        52800000
ENT00900 SR    CESDADD,TEMP1            RELATIVE ADD                    53100000
         SRL   CESDADD,4                CS  ID                          53400000
         STH   CESDADD,LKDENTID         SAVE ID                         53700000
         OC    LKDENTPT(3),LKDENTPT    IS ENTRY POINT ADD = 0           54000000
         BC    8,ENT01000              YES                              54300000
         NI    PDSE8,X'DF'         SET IND IN PDS - ADD NOT = 0         54600000
ENT01000 MVC   PDSE16(2),LKDENTID   PUT ID IN PDS                       54900000
         MVC   PDSE11(3),LKDENTPT+1 PUT ADD IN PDS                      55200000
*********************************************************************** 55500000
*              RESTORE ALL REGISTERS - RETURN TO CALLER               * 55800000
*********************************************************************** 56100000
ENT01100 L     13,SAVERG13              RESTORE ADD OF CALLERS SAVEREA  56400000
         LM    14,12,DISP(13)           RESTORE USER REGISTERS          56700000
         BCR   15,14                    RETURN TO CALLER                57000000
*********************************************************************** 57300000
*              ENTRY POINT  IS AN ASSEMBLED ADDRESS FROM AN END CARD  * 57600000
*********************************************************************** 57900000
ENT01200 MVC   LKDENTID(2),PDSE16  PUT ID ON BOUNDRY                    58200000
         LH    CESDADD,LKDENTID         LOAD ID                         58500000
         LH    ERRCODRG,ERRPARMA        INVALID ENTRY PT ID -NO PT ADD  58800000
         LTR   TEMP4,CESDADD            SAVE ID AND TEST FOR ZERO       59100000
         BC    8,ENT00450               GO PRINT ERROR - INVALID ID     59400000
         CLR   TEMP4,TEMP3              DOES ID POINT INTO CESD         59700000
         BC    2,ENT00450               NO-GO PRINT ERROR- INVALID ID   60000000
         SLL   CESDADD,4               RELATIVE CESD ADD                60300000
         AR    CESDADD,TEMP1           ADDRESS OF CESD ENTRY            60600000
         MVN   WORKBYTE(1),8(CESDADD)  MOVE TYPE TO TEST IT             60900000
         TM    WORKBYTE,X'03'          IS TYPE = SD,PC OR LR            61200000
         BC    4,ENT00450              NO - ERROR ON ID          A30670 61500020
         SLL   TEMP4,2                  RCT RELATIVE ADD                61800000
         A     TEMP4,RECNT         RCT ADD OF RC FOR THIS CS            62100000
         TM    APTSWS,X'20'        IS END PT ADD TO BE RELOCATED        62400000
         BC    8,ENT01230         ABSOLUTLY - NO                        62700000
         LA    TEMP4,8(CESDADD)        REG POINTS TO TYPE- ADDRESS      63000000
ENT01230 L     TEMP4,0(TEMP4)     LOAD RC OR CESD ADD TYPE              63300000
         A     TEMP4,EPSM          ADD ASSEMBLED ADD TO RC              63600000
         LA    TEMP4,0(TEMP4)          CLEAR HI ORDER BYTE              63900000
         ST    TEMP4,LKDENTPT           SAVE ADD ON BOUNDRY             64200000
         LH    ERRCODRG,ERRPARMB        INVALID ENTRY PT ADD-PRINT ADD  64500000
         L     WORK1,8(CESDADD)         LINKED ADD OF CONTROL SEC       64800000
         LA    WORK1,0(WORK1)           CLEAR HI BYTE TO ZERO           65100000
         CR    TEMP4,WORK1              IS ENTRY PT ADD GTR CONT SEC AD 65400000
         BC    4,ENT01240               NO,GO TO PRINT ERROR MESS       65700000
         A     WORK1,12(CESDADD)        UPPER BOUND OF CONTROL SECTION  66000000
         LA    WORK1,0(WORK1)           CLEAR HI BYTE TO ZERO           66300000
         CLR   TEMP4,WORK1              IS ENTRY POINT LESS THAN UPP BD 66600000
         BC    11,ENT01240              NO,GO TO PRINT ERROR MESSAGE    66900000
         CLI   12(CESDADD),X'01'       IS ENTRY POINT IN SEG 1          67200000
         BC    8,ENT00900               YES / GO TO SAVE ENTRY POINT    67500000
         LH    ERRCODRG,ERRPARM7        ENTRY POINT NOT IN SEG 1 PARM   67800000
ENT01240 MVI   LKDENTPT,X'00'           SET HI BYTE OF ADD TO ZERO      68100000
         UNPK  EPSM(8),LKDENTPT(5) UNPACK 4 BYTE ADDRESS                68400000
         TR    EPSM(8),TABLE-C'0'  TRANSLATE BINARY TO HEX              68700000
         LM    EVEN,BRANCH,EPSM                                         69000000
         SRDL  EVEN,8                                                   69300000
         STM   EVEN,BRANCH,EPSM                                         69600000
         MVI   EPSM,C'0'           SET HI BYTE TO ZERO                  69900000
         BC    15,ENT00400              GO TO ERROR ROUTINE             70200000
*********************************************************************** 70500000
*              NO ENTRY POINT SPECIFIED BY PROBLEM PROGRAM            * 70800000
*********************************************************************** 71100000
ENT01250 MVC   LKDENTPT+1(3),THREEFS   SET LKDENTPT TO HIGHEST POS ADD  71400000
         LR    TEMP4,TEMP1                                              71700000
ENT01300 LA    TEMP4,16(TEMP4)          INC TEMP1 BY 16 (TEMP1 PTST     72000000
         MVC   WORKBYTE(1),8(TEMP4)     MOVE TYPE TO WORKBYTE           72300000
         NI    WORKBYTE,X'1F'           REMOVE TOP 3BITS -              72600000
         CLI   WORKBYTE,X'0C'           IS TYPE NOT ACCEPTABLE          72900000
         BC    2,ENT01400               YES / CONTINUE LOOP             73200000
         TM    WORKBYTE,X'13'           IS TYPE = SD OR PC(NOT DELETE)  73500000
         BC    5,ENT01400               NO/ GO TO TEST END OF LOOP      73800000
         CLI   12(TEMP4),X'01'          IS CS  IN  SEG 1                74100000
         BC    7,ENT01400               NO / GO TO TEST END OF LOOP     74400000
         CLC   9(3,TEMP4),LKDENTPT+1   IS THIS CS ADD LESS PRV ADD      74700000
         BC    11,ENT01400              NO / GO TEST END OF LOOP        75000000
         LR    CESDADD,TEMP4            SAVE CESD ADD OF LOW CS ADD     75300000
         MVC   LKDENTPT+1(3),9(TEMP4)   SAVE NEW LOW CS ADD             75600000
ENT01400 BCT   CESDCT,ENT01300          BRANCH IF LOOP NOT DONE         75900000
         CLC   LKDENTPT+1(3),THREEFS    HAS A CS BEEN FOUND             76200000
         BC    7,ENT00900               YES / SAVE ADD AND ID           76500000
         TM    PDSE7,OVERLYBT      IS PROGRAM IN OVERLAY                76800000
         BC    8,ENT01100               NO/ GO TO GO TO ERROR ROUTINE   77100000
         LH    ERRCODRG,ERRPARM8        NO ENTRY PT DEFINED IN SEG 1    77400000
         BC    15,ENT00450              GO TO - GO TO ERROR DIAG        77700000
*                                        NO ENTRY PT DEFINED BY PRB.PG. 78000000
ENT01700 LH    ERRCODRG,ERRPARM5        SYMBOL FROM ENTRY CD NOT IN SG1 78300000
         TM    APT1,ENTRYCD        HAS AN ENTRY CARD BEEN RECEIVED      78600000
         BC    1,ENT00400               YES / GO TO PASS RETURN ADD     78900000
         LH    ERRCODRG,ERRPARM6        SYMBOL FROM END CARD NOT IN SG1 79200000
         BC    15,ENT00400              GO TO PASS RETURN ADDRESS       79500000
*********************************************************************** 79800000
*              TEST TYPE = HEX(08,03,08)                                80100000
*********************************************************************** 80400000
ENT01800 MVN   WORKBYTE(1),8(CESDADD)   MOVE LOW 4 BITS TO TEST TYPE    80700000
         CLI   WORKBYTE,X'08'           IS TYPE AN ACCEPTABLE ONE       81000000
         BCR   2,WORK2                  NO /  RETURN                    81300000
         CLI   WORKBYTE,X'03'           IS TYPE = LR                    81600000
         BCR   8,TEMP4                  YES / RETURN                    81900000
         TM    WORKBYTE,X'07'           IS NOT SD OR SD WITH RLDS OR LR 82200000
         BCR   5,WORK2                  YES / RETURN                    82500000
         BCR   15,RETURN                RETURN - SD                     82800000
THREEFS  DC    XL3'FFFFFF'                                              83100000
LKDENTPT DS    F                        ENTRY POINT                     83400000
LKDENTID DS    H                        ENTRY POINT ID                  83700000
SAVERG13 DS    F                        SAVE AREA FOR ADDRESS OF CALL-  84000000
*                                                                       84300000
WORKBYTE DC    X'00'                    USED TO TEST TYPE OF ESDS       84600000
*********************************************************************** 84900000
*              ERROR  PARAMETERS -  ALL ARE SEVERITY 3 - NON EXECUTABLE 85200000
*********************************************************************** 85500000
*                                       DISP      SEVERITY   MESS.NO.   85800000
ENT3     EQU   X'2305'                  2         3         05          86100000
ENT4     EQU   X'2306'                  2         3         06          86400000
ENT5     EQU   X'2307'                  2         3         07          86700000
ENT6     EQU   X'2308'                  2         3         08          87000000
ENT7     EQU   X'2309'                  2         3         09          87300000
ENT8     EQU   X'030B'                  0         3         0B          87600000
ENT9     EQU   X'222F'                  2         2         2F          87900000
ENTA     EQU   X'0303'                  0         3         03          88200000
ENTB     EQU   X'2303'                  2         3         03          88500000
         DS    0F                                                       88800000
ERRPARM3 DC    AL2(ENT3)                SYMBOL NOT AN EXTERNAL NAME-ENT 89100000
ERRPARM4 DC    AL2(ENT4)                SYMBOL NOT AN EXTERNAL NAME-END 89400000
ERRPARM5 DC    AL2(ENT5)                SYMBOL NOT DEFINED IN ROOT -ENT 89700000
ERRPARM6 DC    AL2(ENT6)                SYMBOL NOT DEFINED IN ROOT -END 90000000
ERRPARM7 DC    AL2(ENT7)                ENTRY POINT ADDRESS NOT IN ROOT 90300000
ERRPARM8 DC    AL2(ENT8)               NO CONTROL SECTION IN ROOT       90600000
ERRPARM9 DC    AL2(ENT9)                INVALID ALIAS ENTRY POINT \SEG1 90900000
ERRPARMA DC    AL2(ENTA)               INVALID ENTRY PT - NO ADDRESS    91200000
ERRPARMB DC    AL2(ENTB)               INVALID ENTRY PT -  ADDRESS      91500000
*********************************************************************** 91800000
*              TABLE OF HEX CHARACTERS - USED IN BINARY CONVERSION    * 92100000
*********************************************************************** 92400000
TABLE    DC    C'0'                                                     92700000
         DC    C'1'                                                     93000000
         DC    C'2'                                                     93300000
         DC    C'3'                                                     93600000
         DC    C'4'                                                     93900000
         DC    C'5'                                                     94200000
         DC    C'6'                                                     94500000
         DC    C'7'                                                     94800000
         DC    C'8'                                                     95100000
         DC    C'9'                                                     95400000
         DC    C'A'                                                     95700000
         DC    C'B'                                                     96000000
         DC    C'C'                                                     96300000
         DC    C'D'                                                     96600000
         DC    C'E'                                                     96900000
         DC    C'F'                                                     97200000
*                                                                       97500000
         IEWAPT                                                         97800000
         END                                                            98100000
