         TITLE '***IEWLMIDR*** CSECT IDENTIFICATION RECORD PROCESSOR'   00050021
**** START OF SPECIFICATIONS ****************************************** 00100021
*                                                                     * 00150021
*1MODULE-NAME = IEWLMIDR                                              * 00200021
*1DESCRIPTIVE-NAME = CSECT IDENTIFICATION RECORD PROCESSOR            * 00250021
*1DESCRIPTION = THE IDR MODULE PROCESSES INCOMING LOAD MODULE IDR'S,  * 00300021
*              IDR DATA ON OBJECT MODULE END RECORDS, AND USER -      * 00350021
*              SUPPLIED IDR DATA FROM THE IDENTIFY CONTROL STATEMENT. * 00400021
*1ASSUMPTIONS = N/A                                                   * 00450021
*1PERFORMANCE = NOT YET AVAILABLE                                     * 00500021
*1FUNCTION = THE FUNCTIONS OF THE CSECT IDENTIFICATION RECORD         * 00550021
*            PROCESSOR ARE DEPENDENT ON THE TYPE OF IDR INPUT         * 00600021
*            BEING PROCESSED:                                         * 00650021
*              LOAD MODULE IDR'S --                                   * 00700021
*                  THE IDR DATA IS EXTRACTED FROM THESE RECORDS,      * 00750021
*                  EXCEPT FOR THE LINKAGE EDITOR IDR, WHICH IS        * 00800021
*                  IGNORED. A CHECK IS MADE TO SEE WHETHER ANY OF THE * 00850021
*                  CSECT'S IDENTIFIED IN THE IDR ARE BEING DELETED    * 00900021
*                  FROM THE OUTPUT LOAD MODULE. IF SO, THE IDR DATA   * 00950021
*                  ASSOCIATED WITH SUCH CSECT'S ARE ALSO DELETED. THE * 01000021
*                  DATA WHICH IS NOT TO BE DELETED IS THEN PLACED AT  * 01050021
*                  THE END OF THE APPROPRIATE IDR DATA TABLE. IN THE  * 01100021
*                  CASE OF TRANSLATOR DESCRIPTIONS, A CHECK IS MADE   * 01150021
*                  TO SEE WHETHER AN IDENTICAL DESCRIPTION HAS        * 01200021
*                  ALREADY BEEN ENTERED INTO THE TABLE. IF SO, THE    * 01250021
*                  CSECT'S ASSOCIATED WITH THE INCOMING ITEM AND      * 01300021
*                  THOSE ASSOCIATED WITH THE EXISTING ITEM ARE        * 01350021
*                  GROUPED INTO A SINGLE TABLE ENTRY TO AVOID         * 01400021
*                  NEEDLESS REPETITION.                               * 01450021
*              OBJECT MODULE END RECORDS --                           * 01500021
*                  WHEN THESE RECORDS CONTAIN THE IDR DATA FIELD      * 01550021
*                  (ONLY PRESENT IF THE TRANSLATOR WHICH PRODUCED THE * 01600021
*                  OBJECT MODULE CONTAINS IDR SUPPORT), THAT FIELD IS * 01650021
*                  EXTRACTED FROM THE RECORD. THE RENUMBERING TABLE   * 01700021
*                  IS SCANNED TO DETERMINE THE CORRECT ESDID'S OF THE * 01750021
*                  CSECT'S TO WHICH THE INCOMING TRANSLATOR           * 01800021
*                  DESCRIPTION APPLIES. IF ANY OF THESE CSECT'S ARE   * 01850021
*                  TO BE DELETED, THEY ARE NOT IDENTIFIED ON THE IDR  * 01900021
*                  OUTPUT. IF AT LEAST ONE OF THE CSECT'S ARE TO BE   * 01950021
*                  KEPT, THE TRANSLATOR DESCRIPTION IS ADDED TO THE   * 02000021
*                  TABLE. AS IN LOAD MODULE INPUT, A CHECK IS MADE    * 02050021
*                  FOR A DUPLICATE ITEM AND, IF FOUND, THE TWO ARE    * 02100021
*                  COMBINED.                                          * 02150021
*              IDENTIFY CONTROL STATEMENT --                          * 02200021
*                  THE CESD LINE ASSOCIATED WITH THE CSECT NAME TO BE * 02250021
*                  IDENTIFIED IS CHECKED. IF THE NAME IS NOT FOUND IN * 02300021
*                  THE CESD AS AN SD-TYPE ENTRY, AN ERROR MESSAGE     * 02350021
*                  IS LOGGED, AND PROCESSING TERMINATES. IF THE CSECT * 02400021
*                  IS TO BE DELETED, THE IDENTIFY DATA IS IGNORED. IF * 02450021
*                  NOT, A CHECK IS MADE TO SEE IF THERE PREVIOUSLY    * 02500021
*                  WAS ANY USER-SUPPLIED DATA ASSOCIATED WITH THAT    * 02550021
*                  CSECT. IF SO, THE OLD DATA IS REPLACED WITH THE    * 02600021
*                  NEW INCOMING DATA. IF NOT, THE INCOMING DATA IS    * 02650021
*                  ADDED TO THE END OF THE TABLE.                     * 02700021
*            WHENEVER ANY TYPE OF DATA IS BEING ADDED TO ONE OF THE   * 02750021
*            TABLES, A CHECK IS FIRST MADE TO DETERMINE WHETHER THE   * 02800021
*            ADDITION OF THAT DATA WILL CAUSE A TABLE OVERFLOW        * 02850021
*            CONDITION. IF IT WILL, AN ERROR MESSAGE INDICATING THIS  * 02900021
*            IS LOGGED, AND PROCESSING IS TERMINATED AT THAT POINT.   * 02950021
*1RESTRICTIONS = NONE                                                 * 03000021
*1MODULE-TYPE = PROCEDURE                                             * 03050021
*    2PROCESSOR = ASSEMBLER                                           * 03100021
*    2MODULE-SIZE = NOT YET KNOWN                                     * 03150021
*    2CODE-ATTRIBUTES = REUSABLE                                      * 03200021
*    2LOAD-ATTRIBUTES = OVERLAY                                       * 03250021
*    2MAIN-ENTRY-POINT = IEWLMIDR - TO PROCESS INPUT LOAD MODULE      * 03300021
*                                   IDR'S AND OBJECT MODULE END       * 03350021
*                                   RECORDS WITH THE IDR FIELD        * 03400021
*         3LINKAGE = BALR 14,15                                       * 03450021
*         3PARAMETER-RECEIVED = POINTER-TO-PARAMETER-LIST             * 03500021
*             4HOW-PASSED = REGISTER 1                                * 03550021
*             4LENGTH-OF-LIST = 4 BYTES                               * 03600021
*                  5FIELD = POINTER TO INPUT BUFFER                   * 03650021
*                       6DISPLACEMENT = 0 BYTES                       * 03700021
*                       6TYPE = ADDRESS                               * 03750021
*    2SECONDARY-ENTRY-POINT = IEWLCIDR - TO PROCESS IDENTIFY CONTROL  * 03800021
*                                        STATEMENT                    * 03850021
*         3LINKAGE = BALR 14,15                                       * 03900021
*         3PARAMETER-RECEIVED = POINTER-TO-PARAMETER-LIST             * 03950021
*             4HOW-PASSED = REGISTER 1                                * 04000021
*             4LENGTH-OF-LIST = 12 BYTES                              * 04050021
*                  5FIELD = POINTER TO CSECT NAME TO BE IDENTIFIED    * 04100021
*                       6DISPLACEMENT = 0 BYTES                       * 04150021
*                       6TYPE = ADDRESS                               * 04200021
*                  5FIELD = POINTER TO IDENTIFY STRING LENGTH         * 04250021
*                       6DISPLACEMENT = 4 BYTES                       * 04300021
*                       6TYPE = ADDRESS                               * 04350021
*                  5FIELD = POINTER TO IDENTIFY STRING                * 04400021
*                       6DISPLACEMENT = 8 BYTES                       * 04450021
*                       6TYPE = ADDRESS                               * 04500021
*    2EXIT = FINISH                                                   * 04550021
*         3PARAMETER-RETURNED = COMPLETION CODE                       * 04600021
*             4HOW-PASSED = REGISTER 15                               * 04650021
*             4TYPE = ARITHMETIC                                      * 04700021
*                 5MODE = BINARY                                      * 04750021
*                 5LENGTH = 32 BITS                                   * 04800021
*                 5SCALING = N/A                                      * 04850021
*                 5VALUE = 0 (NORMAL COMPLETION)                      * 04900021
*    2EXIT = ABORT                                                    * 04950021
*         3PARAMETER-RETURNED = ERROR CODE                            * 05000021
*             4HOW-PASSED = REGISTER 0                                * 05050021
*             4TYPE = ARITHMETIC                                      * 05100021
*                 5MODE = BINARY                                      * 05150021
*                 5LENGTH = 16 BITS                                   * 05200021
*                 5VALUE = X'0446' (MSG. IEW0704)                     * 05250021
*    2EXIT = TABOVFLO                                                 * 05300021
*         3PARAMETER-RETURNED = ERROR CODE                            * 05350021
*             4HOW-PASSED = REGISTER 0                                * 05400021
*             4TYPE = ARITHMETIC                                      * 05450021
*                 5MODE = BINARY                                      * 05500021
*                 5LENGTH = 16 BITS                                   * 05550021
*                 5VALUE = X'0445' (MSG. IEW0694)                     * 05600021
*    2EXTERNAL-PROCEDURE = IEWLMLOG (TO LOG DIAGNOSTIC MESSAGES)      * 05650021
*         3PARAMETER-PASSED = MESSAGE CODE (IN REGISTER 0)            * 05700021
*         3PARAMETER-RETURNED = NONE                                  * 05750021
*    2EXTERNAL-MACRO = IEWAPT                                         * 05800021
*         3PARAMETER-PASSED = NONE                                    * 05850021
*         3PARAMETER-RETURNED = NONE                                  * 05900021
*    2SYSTEM-MACROS = SAVE, RETURN, OPEN, SNAP, CLOSE AND DCB         * 05950021
*    2EXTERNAL-TABLES = CESD, RENUMBERING TABLE AND IDR DATA TABLES   * 06000021
*                       (IDRTRTAB, IDRUDTAB AND IDRZPTAB)             * 06050021
*                                                                     * 06100021
**** END OF SPECIFICATIONS ******************************************** 06150021
         EJECT                                                          06200021
*********************************************************************** 06250021
*                                                                     * 06300021
*                 *******************************                     * 06350021
*                * MAIN ENTRY POINT --IEWLMIDR-- *                    * 06400021
*                 *******************************                     * 06450021
*                                                                     * 06500021
*        CONTROL IS RECEIVED AT THIS POINT FROM MODULE IEWLMINP       * 06550021
*        FOR THE PURPOSE OF ACCEPTING IDR DATA OBTAINED FROM INPUT    * 06600021
*        LOAD MODULES AND/OR INPUT OBJECT MODULES.                    * 06650021
*                                                                     * 06700021
*********************************************************************** 06750021
         SPACE                                                          06800021
IEWLMIDR CSECT                                                          06850021
*A000000                                                         S21016 06870021
*C173500-175000,181500                                           S21016 06880021
*A417500                                                          M1602 06886021
*C364500,598500                                                   M1602 06892021
*A173000                                                         A53196 06894021
*C174000                                                         A53196 06896021
*A339000                                                        SA63745 06898000
*I213500,D214000-215000,C219000                                 SA65984 06898400
         SPACE                                                          06900000
*********************************************************************** 06950021
*                                                                     * 07000021
*                  EXTERNAL ENTRY POINT DEFINITION                    * 07050021
*                                                                     * 07100021
*********************************************************************** 07150021
         SPACE                                                          07200021
         ENTRY IEWLCIDR                                                 07250021
********************CONTROL PASSED TO THIS EP FROM IEWLMSCN************ 07300021
         SPACE 3                                                        07350021
*********************************************************************** 07400021
*                                                                     * 07450021
*                  SYMBOLIC EQUATES                                   * 07500021
*                                                                     * 07550021
*********************************************************************** 07600021
         SPACE 2                                                        07650021
********************GENERAL REGISTER EQUATES*************************** 07700021
         SPACE                                                          07750021
NULLREG  EQU   0                       REGISTER USED WHEN NO BRANCHING  07800021
*                                      IS DESIRED                       07850021
GREG0    EQU   0                       GENERAL PURPOSE WORK REGISTER    07900021
PARMPTR  EQU   1                       POINTER TO PARAMETER LIST PASSED 07950021
*                                      BY CALLING PROGRAM               08000021
BUFPTR   EQU   1                       POINTER TO RECORD BEING          08050021
*                                      PROCESSED IN INPUT BUFFER        08100021
GREG1    EQU   1                       GENERAL PURPOSE WORK REGISTER    08150021
APTBASE  EQU   2                       BASE ADDRESS FOR THE ALL         08200021
*                                      PURPOSE TABLE DSECT              08250021
TABPTR   EQU   3                       POINTER TO START OF IDR DATA     08300021
*                                      TABLE                            08350021
TABNXT   EQU   4                       POINTER TO NEXT AVAILABLE BYTE   08400021
*                                      IN IDR DATA TABLE                08450021
TABEND   EQU   5                       MAXIMUM LENGTH OF IDR DATA TABLE 08500021
ITEMPTR  EQU   6                       POINTER TO IDR ITEM BEING        08550021
*                                      PROCESSED                        08600021
DATAPTR  EQU   7                       POINTER TO PORTION OF ITEM       08650021
*                                      BEING EXAMINED                   08700021
ENDBUF   EQU   8                       POINTER TO END OF INPUT RECORD   08750021
GREG8    EQU   8                       GENERAL PURPOSE WORK REGISTER    08800021
TEMPRTN  EQU   9                       RETURN REGISTER FOR INTERNAL     08850021
*                                      SUBROUTINE LINKAGES              08900021
CESDPTR  EQU   9                       POINTER TO THE START OF THE      08950021
*                                      COMPOSITE ESD TABLE              09000021
GREG9    EQU   9                       GENERAL PURPOSE WORK REGISTER    09050021
RNTPTR   EQU   10                      POINTER TO THE START OF THE      09100021
*                                      RENUMBERING TABLE                09150021
GREG10   EQU   10                      GENERAL PURPOSE WORK REGISTER    09200021
GREG11   EQU   11                      GENERAL PURPOSE WORK REGISTER    09250021
IDRBASE  EQU   12                      BASE ADDRESS FOR MODULE          09300021
SAPTR    EQU   13                      POINTER TO CALLING PROGRAM'S     09350021
*                                      SAVE AREA                        09400021
GREG13   EQU   13                      GENERAL PURPOSE WORK REGISTER    09450021
RETURN   EQU   14                      RETURN ADDRESS IN CALLING        09500021
*                                      PROGRAM                          09550021
GREG14   EQU   14                      GENERAL PURPOSE WORK REGISTER    09600021
ENTRYPT  EQU   15                      ENTRY POINT ADDRESS FOR SYSTEM   09650021
*                                      LINKAGES                         09700021
GREG15   EQU   15                      GENERAL PURPOSE WORK REGISTER    09750021
         SPACE 2                                                        09800021
*****************SYMBOLIC MASKS AND IMMEDIATE BYTES******************** 09850021
         SPACE                                                          09900021
SPZAP    EQU   X'01'                   SUBTYPE VALUE FOR IMASPZAP IDR   09950021
LKED     EQU   X'02'                   SUBTYPE VALUE FOR LINK-EDIT IDR  10000021
TRANS    EQU   X'04'                   SUBTYPE VALUE FOR TRANSLATOR IDR 10050021
USER     EQU   X'08'                   SUBTYPE VALUE FOR USER-DATA IDR  10100021
BLANK    EQU   C' '                    FLAG VALUE FOR NO IDR DATA       10150021
*                                      ON AN OBJECT MODULE END CARD     10200021
SINGLE   EQU   C'1'                    FLAG VALUE FOR SINGLE IDR ENTRY  10250021
*                                      ON AN OBJECT MODULE END CARD     10300021
DOUBLE   EQU   C'2'                    FLAG VALUE FOR DOUBLE IDR ENTRY  10350021
*                                      ON AN OBJECT MODULE END CARD     10400021
ONETRNS  EQU   X'00'                   INDICATOR VALUE FOR A SINGLE     10450021
*                                      IDR TRANSLATOR DESCRIPTION       10500021
DBLSWS   EQU   X'01'                   INDICATOR VALUE FOR A DOUBLE     10550021
*                                      IDR TRANSLATOR DESCRIPTION       10600021
SWSOFF   EQU   X'00'                   IMMEDIATE BYTE TO RE-INITIALIZE  10650021
*                                      ALL IDR SWITCHES TO ZEROES       10700021
SWSINIT  EQU   X'13'                   IMMEDIATE BYTE TO RE-INITIALIZE  10750021
*                                      THE IDR SWITCHES IN THE APT      10800021
PARTOFF  EQU   X'EF'                   IMMEDIATE BYTE TO TURN OFF       10850021
*                                      PARTIAL ENTRY INDICATOR          10900021
LASTID   EQU   X'80'                   MASK VALUE TO DETERMINE LAST ID  10950021
*                                      IN A STRING OF ESDID'S ON AN IDR 11000021
*                                      TRANSLATOR ITEM                  11050021
LSTIDOFF EQU   X'7F'                   IMMEDIATE BYTE TO TURN OFF THE   11100021
*                                      HIGH ORDER BIT IN THE LAST       11150021
*                                      CESDID IN A STRING OF CESDID'S   11200021
LSTIDFND EQU   X'80'                   SWITCH VALUE INDICATING THE      11250021
*                                      LAST ID IN A STRING OF CESDID'S  11300021
*                                      HAS BEEN FOUND                   11350021
DELETE   EQU   X'10'                   SUB-CLASSIFICATION OF A CESD     11400021
*                                      TYPE MARKED FOR DELETION         11450021
AL1VLD   EQU   X'40'                   SWITCH VALUE INDICATING AT       11500021
*                                      LEAST ONE CESDID IN A STRING     11550021
*                                      IS VALID (NOT DELETE)            11600021
TRSWOFF  EQU   X'3F'                   IMMEDIATE BYTE TO TURN OFF       11650021
*                                      SWITCHES AL1VLD AND LSTIDFND     11700021
*                                      IN LCLSWS                        11750021
CNTDITM  EQU   X'20'                   SWITCH VALUE INDICATING A        11800021
*                                      CONTINUED ENTRY IS BEING         11850021
*                                      PROCESSED                        11900021
CNTDOFF  EQU   X'DF'                   IMMEDIATE BYTE TO TURN OFF       11950021
*                                      CONTINUED ENTRY INDICATOR        12000021
CNTDID   EQU   X'10'                   SWITCH VALUE INDICATING A        12050021
*                                      CONTINUED CESDID IS BEING        12100021
*                                      PROCESSED                        12150021
CNTIDOFF EQU   X'EF'                   IMMEDIATE BYTE TO TURN OFF       12200021
*                                      CONTINUED CESDID INDICATOR       12250021
ZCHNOFF  EQU   X'BF'                   IMMEDIATE BYTE TO TURN OFF THE   12300021
*                                      'CHAIN' BIT IN AN IMASPZAP IDR   12350021
SECTDEF  EQU   X'0F'                   MASK VALUE FOR SD TYPE IN CESD   12400021
PRIVATE  EQU   X'04'                   MASK VALUE FOR PC IN CESD TYPE   12450021
OTHTYPE  EQU   X'0B'                   MASK VALUE FOR ALL BITS IN CESD  12500021
*                                      TYPE OTHER THAN PC               12550021
LOGIDNT  EQU   X'20'                   SWITCH VALUE TO INDICATE TO THE  12600021
*                                      ERROR LOG ROUTINE TO LOG A CARD  12650021
*                                      IMAGE WHOSE ADDRESS IS IN REG.1  12700021
LOGSOFF  EQU   X'DF'                   MASK VALUE TO TURN OFF LOGIDNT   12750021
*                                      SWITCH                           12800021
NE       EQU   X'08'                   MASK VALUE TO TEST IF THE LOAD   12850021
*                                      MODULE BEING PROCESSED IS 'NOT   12900021
*                                      EDITABLE' (IN PDSE8)             12950021
HIDSW    EQU   4                       PARTIAL ID INDICATOR             13000021
STRSW    EQU   12                      PARTIAL ID-STRING INDICATOR      13050021
ITMSW    EQU   8                       PARTIAL TRANS.ITEM INDICATOR     13100021
         SPACE 2                                                        13150021
*****************SYMBOLIC DISPLACEMENTS AND LENGTHS******************** 13200021
         SPACE                                                          13250021
NODISP   EQU   0                       DISPLACEMENT OF ZERO             13300021
SUBTYPE  EQU   2                       SUBTYPE FIELD IN LOAD MOD IDR'S  13350021
OBJFLAG  EQU   32                      FLAG FIELD IN OBJECT END CARDS   13400021
HEADLEN  EQU   3                       LENGTH OF IDR RECORD-HEADER      13450021
NEXTID   EQU   2                       LENGTH OF CESDID FIELD IN IDR    13500021
*                                      DATA ITEMS                       13550021
SNGTRN   EQU   16                      LENGTH OF A SINGLE IDR           13600021
*                                      TRANSLATOR DESCRIPTION           13650021
DBLTRN   EQU   31                      LENGTH OF A DOUBLE IDR           13700021
*                                      TRANSLATOR DESCRIPTION           13750021
COUNT    EQU   1                       DISPLACEMENT TO THE BYTE COUNT   13800021
*                                      FIELD IN LOAD MODULE IDR'S       13850021
ADJ      EQU   1                       ADJUSTMENT VALUE FOR COMPUTING   13900021
*                                      THE ENDING ADDR. OF A REC.       13950021
HALFID   EQU   8                       SHIFT VALUE FOR ONE BYTE         14000021
BYTE2    EQU   1                       ONE-BYTE DISPLACEMENT            14050021
RNTINDX  EQU   2                       SHIFT VALUE TO GET INDEX INTO    14100021
*                                      THE RENUMBERING TABLE            14150021
CESDINDX EQU   4                       SHIFT VALUE TO GET INDEX INTO    14200021
*                                      THE CESD                         14250021
IDLEN    EQU   2                       LENGTH OF A CESDID               14300021
HIDLEN   EQU   1                       LENGTH OF HALF A CESDID          14350021
TYPE     EQU   8                       DISPLACEMENT OF TYPE FIELD IN    14400021
*                                      A CESD ENTRY                     14450021
NOLEN    EQU   0                       NULL LENGTH                      14500021
CESDWDTH EQU   16                      WIDTH OF CESD TABLE              14550021
FSTID    EQU   1                       VALUE OF 1ST CESDID              14600021
NAMELEN  EQU   8                       LENGTH OF A CSECT NAME           14650021
UDCNT    EQU   5                       DISPLACEMENT TO BYTE COUNT FIELD 14700021
*                                      IN USER DATA IDR                 14750021
UDHEAD   EQU   6                       HEADER LENGTH IN USER DATA IDR   14800021
FULWD    EQU   4                       LENGTH OF A FULL WORD            14850021
USTRLEN  EQU   4                       DISPLACEMENT TO ADDR. OF         14900021
*                                      IDENTIFY STRING LENGTH IN        14950021
*                                      PARAMETER LIST                   15000021
UDSTR    EQU   8                       DISPLACEMENT TO ADDRESS OF       15050021
*                                      IDENTIFY STRING IN PARAMETER     15100021
*                                      LIST                             15150021
UDLEN    EQU   40                      LENGTH OF IDENTIFY STRING        15200021
DATELEN  EQU   3                       LENGTH OF DATE FIELD             15250021
RNTYPE   EQU   3                       DISPLACEMENT TO THE ESD TYPE     15300021
*                                      FIELD IN AN RNT ENTRY            15350021
PKLEN    EQU   5                       PACKED LENGTH OF V/M LEVEL AND   15400021
*                                      DATE IN TRANSLATOR ITEM          15450021
UPLEN    EQU   9                       UNPACKED LENGTH OF V/M LEVEL AND 15500021
*                                      DATE IN OBJ.END REC. IDR FIELD   15550021
TRNMLEN  EQU   10                      LENGTH OF TRANSLATOR NAME IN     15600021
*                                      OBJ.END REC. IDR FIELD           15650021
TRNM1    EQU   33                      DISPLACEMENT TO THE TRANSLATOR   15700021
*                                      NAME ON AN OBJ.END WITH IDR      15750021
TRNM2    EQU   52                      DISPLACEMENT TO THE 2ND TRANS.   15800021
*                                      NAME ON AN OBJ.END WITH IDR      15850021
VMYD1    EQU   43                      DISPLACEMENT TO THE V/M LVL. AND 15900021
*                                      DATE ON AN OBJ.END WITH IDR      15950021
VMYD2    EQU   62                      DISPLACEMENT TO THE 2ND V/M LVL. 16000021
*                                      AND DATE ON AN OBJ.END WITH IDR  16050021
UDMAXLEN EQU   46                      MAXIMUM LENGTH OF A USER DATA    16100021
*                                      ITEM ON A LOAD MODULE IDR        16150021
ZAPLEN   EQU   13                      LENGTH OF AN IMASPZAP DATA ENTRY 16200021
MSGLEN   EQU   79                      LENGTH OF MESSAGE LINE - 1       16250021
         SPACE 3                                                        16300021
*********************************************************************** 16350021
*                                                                     * 16400021
*                  END OF SYMBOLIC EQUATES                            * 16450021
*                                                                     * 16500021
*********************************************************************** 16550021
         EJECT                                                          16600021
*********************************************************************** 16650021
*********************************************************************** 16700021
**********                                                   ********** 16750021
**********           EXECUTEABLE CODE BEGINS HERE            ********** 16800021
**********                                                   ********** 16850021
*********************************************************************** 16900021
*********************************************************************** 16950021
         SPACE 2                                                        17000021
         SAVE  (14,12),T,*             SAVE CALLING PROGRAM'S REGISTERS 17050021
         BALR  IDRBASE,NULLREG         LOAD BASE ADDRESS                17100021
         USING START,IDRBASE           ESTABLISH ADDRESSABILITY FOR     17150021
*                                      MODULE                           17200021
         USING APTDSECT,APTBASE        ESTABLISH ADDRESSABILITY FOR     17250021
*                                      THE ALL PURPOSE TABLE            17300021
START    TM    APTSW2,IDROUT           TEST IDR OUTPUT ENABLED   A53196 17390021
         BNO   FINISH                  RETURN IF NOT             A53196 17396021
         L     BUFPTR,NODISP(PARMPTR)  LOAD ADDR. OF INPUT REC   A53196 17400021
         TM    IDRSWS,OBJIDR           IS INPUT AN OBJECT END CARD?     17550021
         BZ    TESTLMOD                NO, BRANCH                       17600021
         CLI   OBJFLAG(BUFPTR),BLANK   IF IT IS, DOES IT CONTAIN THE    17650021
*                                      IDR FIELD?  (BLANK IN COL.33     17700021
*                                      INDICATES NO IDR DATA PRESENT)   17750021
         BE    FINISH                  IF NOT, RETURN                   17800021
         CLI   OBJFLAG(BUFPTR),DOUBLE  IS IDR DATA A DOUBLE ENTRY?      17850021
         BNE   ONENTRY                 IF NOT, BRANCH                   17900021
         OI    IDRSWS,DBLOBJ           IF IT IS, TURN ON THE DOUBLE     17950021
*                                      ENTRY INDICATOR                  18000021
         B     IDRTRANS                GO TO PROCESS THE IDR DATA       18050021
ONENTRY  CLI   OBJFLAG(BUFPTR),SINGLE  IS IDR DATA A SINGLE ENTRY?      18100021
         BNE   FINISH                  IF NOT, THE FLAG FIELD IS        18120021
*                                      INVALID FOR IDR -- IGNORE        18140021
*                                      THE RECORD                       18160021
         B     IDRTRANS                IF IT IS, GO TO PROCESS IT       18200021
TESTLMOD TM    IDRSWS,LMDIDR           IS INPUT A LOAD MODULE IDR?      18250021
         BNO   ABORT                   IF NOT, IT IS AN ERROR           18300021
         TM    SUBTYPE(BUFPTR),LKED    IS IT A LINK-EDIT RECORD?        18350021
         BO    FINISH                  IF IT IS, RETURN                 18400021
         SR    ENDBUF,ENDBUF           ZERO REGISTER TO RECEIVE COUNT   18450021
         IC    ENDBUF,COUNT(BUFPTR)    GET BYTE COUNT FOR RECORD        18500021
         LA    ENDBUF,ADJ(ENDBUF,BUFPTR) GET ADDRESS OF END OF RECORD   18550021
         TM    SUBTYPE(BUFPTR),SPZAP   IS THIS AN IMASPZAP RECORD?      18600021
         BO    IDRSPZAP                IF IT IS, BRANCH                 18650021
         TM    SUBTYPE(BUFPTR),TRANS   IS IT A TRANSLATOR RECORD?       18700021
         BO    IDRTRANS                IF IT IS, BRANCH                 18750021
         TM    SUBTYPE(BUFPTR),USER    IS IT A USER-DATA RECORD?        18800021
         BO    IDRIDENT                IF IT IS, BRANCH                 18850021
         B     ABORT                   IF NONE OF THE ABOVE BRANCHES    18900021
*                                      HAVE BEEN TAKEN, THE SUBTYPE     18950021
*                                      FIELD OF THE RECORD CONTAINS     19000021
*                                      AN INVALID CODE                  19050021
         EJECT                                                          19100021
*********************************************************************** 19150021
*********************************************************************** 19200021
****                                                               **** 19250021
****     SUB-PROGRAM IDRTRANS PROCESSES INPUT LOAD MODULE IDR'S    **** 19300021
****     WITH TRANSLATOR DATA AND OBJECT MODULE END RECORDS        **** 19350021
****     WITH THE IDR TRANSLATOR IDENTIFICATION FIELD              **** 19400021
****                                                               **** 19450021
*********************************************************************** 19500021
*********************************************************************** 19550021
         SPACE 2                                                        19600021
IDRTRANS L     TABPTR,IDRTRTAB         GET ADDRESS OF TRANSLATOR DATA   19650021
*                                      TABLE                            19700021
         L     TABNXT,IDRTREND         GET ADDRESS OF NEXT AVAILABLE    19750021
*                                      BYTE IN TABLE                    19800021
         LR    TABEND,TABPTR           GET STARTING ADDRESS OF TABLE    19850021
         AH    TABEND,IDRTRLEN         GET ENDING ADDRESS OF TABLE      19900021
         TM    IDRSWS,OBJIDR           IS OBJECT MODULE INDICATOR ON?   19950021
         BO    POSTOBJ                 IF SO, GO TO POST                20000021
         TM    IDRSWS,LMDIDR           IS LOAD MODULE INDICATOR ON?     20050021
         BNO   ABORT                   IF NOT, IT IS AN ERROR           20100021
         L     CESDPTR,CHESD           GET THE ADDRESS OF THE CESD      20150021
         L     RNTPTR,RECNT            GET THE ADDRESS OF THE RNT       20200021
         TM    IDRSWS,PARTENT          IS LAST ITEM IN TABLE A PARTIAL  20250021
*                                      ENTRY?                           20300021
         BO    CONTIN                  IF SO, BRANCH                    20350021
         LA    ITEMPTR,HEADLEN(BUFPTR) POINT TO FIRST DATA ITEM IN REC  20400021
         LR    DATAPTR,ITEMPTR         POINT TO START OF DATA FOR       20450021
*                                      CURRENT ITEM                     20500021
SCNITEM  LA    GREG11,NEXTID(DATAPTR)  GET ENDING ADDR. OF THIS ID      20550021
         TM    LCLSWS,CNTDID           IS THIS A CONTINUED ID?          20600021
         BO    SCNITM04                IF SO, BRANCH                    20650021
         CR    GREG11,ENDBUF           IS IT COMPLETE IN THIS RECORD?   20700021
         BH    PRTLID                  IF NOT, BRANCH                   20750021
SCNITM04 TM    NODISP(DATAPTR),LASTID  IS THIS THE LAST CESDID FOR THE  20800021
*                                      CURRENT ITEM?                    20850021
         BNO   TESTID                  IF NOT, BRANCH                   20900021
         OI    LCLSWS,LSTIDFND         TURN ON 'LAST ID FOUND' SWITCH   20950021
         NI    NODISP(DATAPTR),LSTIDOFF  TURN OFF HIGH ORDER BIT OF ID  21000021
TESTID   ST    GREG1,SAVR1             SAVE GENERAL WORK REGISTER 1     21050021
         SR    GREG1,GREG1             ZERO THE REGISTER                21100021
         IC    GREG1,NODISP(DATAPTR)   GET 1ST BYTE OF CESDID           21150021
         SLL   GREG1,HALFID            SHIFT THAT BYTE                  21200021
         IC    GREG1,BYTE2(DATAPTR)    GET 2ND BYTE OF CESDID           21250021
         SLL   GREG1,RNTINDX           MULTIPLY ID BY 4 TO GET INDEX    21300021
*                                      INTO THE RENUMBERING TABLE       21350021
         AR    GREG1,RNTPTR            PT TO RNT ENTRY          SA65984 21360000
         TM    RNTYPE(GREG1),DELETE    MARKED FOR DELETE        SA65984 21370000
         BO    LSTIDTST                SKIP IDR IF SO           SA65984 21380000
         MVC   NODISP(IDLEN,DATAPTR),NODISP(GREG1)              SA65984 21390000
*              KEEP IDR ITEM IF CSECT NOT MARKED FOR DELETE     SA65984 21392000
         LH    GREG1,NODISP(,GREG1)    PICK UP RENUMBERED ID    SA65984 21394000
         SLL   GREG1,CESDINDX          MULTIPLY ID BY 16 TO GET INDEX   21600021
*                                      INTO THE CESD                    21650021
         AR    GREG1,CESDPTR           GET THE ADDRESS OF THE CESD LINE 21700021
         TM    TYPE(GREG1),DELETE      IS THIS SECTION MARKED FOR       21750021
*                                      DELETION?                        21800021
         BNO   IDOK                    IF NOT, BRANCH TO PROCESS IT     21850021
LSTIDTST TM    LCLSWS,LSTIDFND         WAS THIS THE LAST ID?    SA65984 21900000
         BZ    GETNXT                  IF NOT, BRANCH                   21950021
         TM    LCLSWS,AL1VLD           WAS AT LEAST ONE VALID ID FOUND? 22000021
         BZ    GETNXT                  IF NOT, BRANCH                   22050021
         LR    GREG1,TABNXT            GET ADDRESS OF NEXT TABLE BYTE   22100021
         BCTR  GREG1,NULLREG           SUBTRACT 2 FROM ADDRESS TO GET   22150021
         BCTR  GREG1,NULLREG           ADDRESS OF LAST ID IN TABLE      22200021
         OI    NODISP(GREG1),LASTID    TURN ON LAST ID INDICATOR        22250021
GETNXT   L     GREG1,SAVR1             RESTORE GENERAL WORK REG.1       22300021
         B     GETNXTID                GO TO GET THE NEXT CESDID        22350021
         SPACE 3                                                        22400021
*********************************************************************   22450021
*******            THE FOLOWING SECTION OF CODE ADDS          *******   22500021
*******            THE ESDID TO THE END OF THE TABLE          *******   22550021
*******                       IDRTRTAB                        *******   22600021
*********************************************************************   22650021
         SPACE 1                                                        22700021
IDOK     OI    LCLSWS,AL1VLD           TURN ON SWITCH TO INDICATE AT    22750021
*                                      LEAST ONE VALID CESDID FOUND     22800021
         LA    GREG11,NEXTID(TABNXT)   GET ADDR. OF NEXT BYTE IN TABLE  22850021
*                                      + LENGTH OF CESDID TO BE ADDED   22900021
         CR    GREG11,TABEND           WILL ADDING THE ID OVERFLOW THE  22950021
*                                      TABLE?                           23000021
         BH    TABOVFLO                IF SO, GO TO LOG THE MESSAGE     23050021
*                                      AND TERMINATE                    23100021
         TM    LCLSWS,LSTIDFND         WAS THIS THE LAST ID?            23150021
         BZ    MOVEID                  IF NOT, BRANCH                   23200021
         OI    NODISP(DATAPTR),LASTID  TURN ON THE LAST ID INDICATOR    23250021
MOVEID   MVC   NODISP(IDLEN,TABNXT),NODISP(DATAPTR)  IF NOT, MOVE THE   23300021
*                                      ID ONTO THE END OF THE TABLE     23350021
         LR    TABNXT,GREG11           UPDATE POINTER TO NEXT BYTE IN   23400021
*                                      TABLE                            23450021
         L     GREG1,SAVR1             RESTORE GENERAL WORK REG.1       23500021
GETNXTID TM    LCLSWS,CNTDID           WAS THIS A CONTINUED ID?         23550021
         BZ    ADJPTR                  IF NOT, GO TO ADJUST THE POINTER 23600021
*                                      TO THE NEXT ID                   23650021
         LA    ITEMPTR,FULWD(BUFPTR)   POINT FOLLOWING THE CONTINUED    23700021
*                                      CESDID JUST PROCESSED            23750021
         LR    DATAPTR,ITEMPTR         POINT TO THE NEXT DATA           23800021
         NI    LCLSWS,CNTIDOFF         TURN OFF CONTIUED ID SWITCH      23850021
         B     NOADJ                   BRANCH AROUND POINTER ADJUSTMENT 23900021
ADJPTR   LA    DATAPTR,NEXTID(DATAPTR) INCREMENT POINTER TO NEXT CESDID 23950021
         CR    DATAPTR,ENDBUF          HAVE WE REACHED THE END OF THE   24000021
*                                      RECORD?                          24050021
         BE    PRTLSTR                 IF SO, BRANCH                    24100021
NOADJ    TM    LCLSWS,LSTIDFND         WAS THIS THE LAST CESDID?        24150021
         BO    TRNSDESC                IF SO, GO TO HANDLE THE          24200021
*                                      TRANSLATOR DESCRIPTION           24250021
         B     SCNITEM                 LOOP TO CONTINUE SCAN            24300021
TRNSDESC LR    ITEMPTR,DATAPTR         POINT TO START OF DESCRIPTION    24350021
         CLI   NODISP(DATAPTR),ONETRNS IS THIS ITEM A SINGLE TRANSLATOR 24400021
*                                      DESCRIPTION?                     24450021
         BNE   DBLTRNS                 IF NOT, BRANCH                   24500021
         LA    DATAPTR,SNGTRN(DATAPTR) INCREMENT POINTER TO END OF ITEM 24550021
         B     AROUNDBL                BRANCH AROUND NEXT INSTRUCTION   24600021
DBLTRNS  LA    DATAPTR,DBLTRN(DATAPTR) INCREMENT POINTER TO END OF ITEM 24650021
AROUNDBL TM    LCLSWS,CNTDITM          IS THIS A CONTINUED ITEM?        24700021
         BO    TRDSC05                 IF SO, BRANCH                    24750021
         CR    DATAPTR,ENDBUF          HAVE WE REACHED THE END OF THE   24800021
*                                      RECORD?                          24850021
         BH    PRTLITEM                IF SO, BRANCH                    24900021
TRDSC05  TM    LCLSWS,AL1VLD           WAS AT LEAST 1 VALID ID FOUND?   24950021
         BZ    NOPOST                  IF NOT, BRANCH                   25000021
         BAL   TEMPRTN,POSTIDR         GO TO ADD THIS ITEM TO THE TABLE 25050021
         L     CESDPTR,CHESD           RESTORE THE POINTER TO THE CESD  25100021
NOPOST   NI    LCLSWS,TRSWOFF          TURN OFF LAST ID FOUND AND AT    25150021
*                                      LEAST 1 VALID ID SWITCHES        25200021
         TM    LCLSWS,CNTDITM          WAS THIS A CONTINUED ITEM?       25250021
         BZ    MORETEST                IF NOT, BRANCH                   25300021
         LA    DATAPTR,HEADLEN(BUFPTR) POINT TO START OF NEW RECORD     25350021
         AH    DATAPTR,CNTDLEN         POINT TO DATA AFTER CONTINUATION 25400021
*                                      OF LAST ITEM                     25450021
         NI    LCLSWS,CNTDOFF          TURN OFF CONTINUED ITEM SWITCH   25500021
MORETEST CR    DATAPTR,ENDBUF          ANY MORE ITEMS IN THIS RECORD?   25550021
         BE    TRNSFIN                 IF NOT, RETURN                   25600021
         LR    ITEMPTR,DATAPTR         POINT TO NEXT ITEM IN RECORD     25650021
         B     SCNITEM                 LOOP TO SCAN NEXT ITEM           25700021
         SPACE 3                                                        25750021
*********************************************************************   25800021
*******            THE FOLLOWING SECTION OF CODE              *******   25850021
*******          HANDLES TRANSLATOR IDR ITEMS THAT            *******   25900021
*******            ARE INCOMPLETE ON THE RECORD               *******   25950021
*******             CURRENTLY BEING PROCESSED                 *******   26000021
*********************************************************************   26050021
         SPACE 1                                                        26100021
PRTLID   MVI   PTLSWCH,HIDSW           TURN ON THE HALF-ID INDICATOR    26150021
         MVC   HIDSAV(HIDLEN),NODISP(DATAPTR)  MOVE IN THE HALF-ID      26200021
         LA    ITEMPTR,SAVPTLTR        POINT TO START OF PARTIAL ITEM   26250021
         LA    DATAPTR,FULWD(ITEMPTR)  POINT TO END OF PARTIAL ITEM     26300021
         B     PRTPOST                 GO TO POST THE PARTIAL ITEM      26350021
PRTLSTR  MVI   PTLSWCH,STRSW           TURN ON THE STRING INDICATOR     26400021
         LA    ITEMPTR,SAVPTLTR        POINT TO START OF PARTIAL ITEM   26450021
         LA    DATAPTR,FULWD(ITEMPTR)  POINT TO END OF PARTIAL ITEM     26500021
         B     PRTPOST                 GO TO POST THE PARTIAL ITEM      26550021
PRTRMOV  MVC   OBJTRN(NOLEN),NODISP(ITEMPTR)  MOVE PARTIAL TRANSLATOR   26600021
*                                      DESCRIPTION TO WORK AREA         26650021
PRTLITEM LR    GREG11,DATAPTR          GET EXPECTED ENDING ADDR.OF ITEM 26700021
         SR    GREG11,ITEMPTR          GET EXPECTED LENGTH OF ITEM      26750021
         STC   GREG11,XPTRLEN          MOVE IN EXPECTED LENGTH          26800021
         LR    GREG11,ENDBUF           GET ENDING ADDRESS OF RECORD     26850021
         SR    GREG11,ITEMPTR          GET LENGTH OF PARTIAL ITEM       26900021
         STC   GREG11,PTLTRLN          MOVE IN PARTIAL LENGTH           26950021
         BCTR  GREG11,NULLREG          SUBTRACT 1 FOR MOVE LENGTH       27000021
         EX    GREG11,PRTRMOV          MOVE IN PARTIAL ITEM DATA        27050021
         MVI   PTLSWCH,ITMSW           TURN ON THE ITEM INDICATOR       27100021
         LA    ITEMPTR,SAVPTLTR        POINT TO START OF PARTIAL ITEM   27150021
         LA    DATAPTR,FULWD(ITEMPTR)  POINT TO START OF PARTIAL DATA   27200021
         LA    DATAPTR,ADJ(GREG11,DATAPTR)  POINT TO END OF PARTIAL     27250021
*                                      ITEM                             27300021
PRTPOST  MVC   CPYLCLS(ADJ),LCLSWS     MOVE IN COPY OF LOCAL SWITCHES   27350021
*                                      INDICATING CURRENT STATUS OF     27400021
*                                      PROCESSING FOR PARTIAL ITEM      27450021
         OI    IDRSWS,PARTENT          TURN ON PARTIAL ENTRY INDICATOR  27500021
         BAL   TEMPRTN,POSTIDR         GO TO ADD THIS ITEM TO THE TABLE 27550021
         L     TABNXT,PARTBEG          POINT TO BEGINNING OF PARTIAL    27600021
*                                      ITEM                             27650021
         B     TRNSFIN                 RETURN                           27700021
CONTIN   MVC   SAVPTLTR(FULWD),NODISP(TABNXT)  MOVE PARTIAL ITEM        27750021
*                                      DESCRIPTOR WORD TO WORK AREA     27800021
         MVC   LCLSWS(ADJ),CPYLCLS     SET LOCAL SWITCHES TO REFLECT    27850021
*                                      STATUS OF PROCESSING FOR         27900021
*                                      CONTINUED ITEM                   27950021
         NI    IDRSWS,PARTOFF          TURN OFF PARTIAL ENTRY SWITCH    28000021
         SR    GREG11,GREG11           ZERO WORK REGISTER               28050021
         IC    GREG11,PTLSWCH          GET PARTIAL ITEM TYPE INDICATOR  28100021
BRTABLE  B     BRTABLE(GREG11)         BRANCHING TABLE                  28150021
         B     IDCNTIN                 CONTINUED CESDID                 28200021
         B     DSCNTIN                 CONTINUED TRANSLATOR DESCRIPTION 28250021
STCNTIN  EQU   *                       CONTINUED CESDID STRING          28300021
         LA    ITEMPTR,HEADLEN(BUFPTR) POINT TO 1ST ITEM ON             28350021
*                                      CONTINUATION RECORD              28400021
         LR    DATAPTR,ITEMPTR         GET STARTING ADDRESS OF DATA FOR 28450021
*                                      CONTINUATION RECORD              28500021
         TM    LCLSWS,LSTIDFND         WAS LAST ID FOUND IN PREVIOUS    28550021
*                                      RECORD?                          28600021
         BO    TRNSDESC                IF SO, GO TO PROCESS THE         28650021
*                                      DESCRIPTION                      28700021
         B     SCNITEM                 IF NOT, GO TO CONTINUE           28750021
*                                      PROCESSING THE STRING OF         28800021
*                                      CESDID'S                         28850021
IDCNTIN  IC    GREG11,HIDSAV           GET 1ST HALF OF CESDID FROM      28900021
*                                      PREVIOUS RECORD                  28950021
         STC   GREG11,ID1ST            MOVE IT TO WORK AREA             29000021
         IC    GREG11,HEADLEN(BUFPTR)  GET 2ND HALF OF CESDID FROM      29050021
*                                      CONTINUATION RECORD              29100021
         STC   GREG11,ID2ND            MOVE IT TO WORK AREA             29150021
         OI    LCLSWS,CNTDID           TURN ON CONTINUED ID SWITCH      29200021
         LA    DATAPTR,ID1ST           POINT TO CONTINUED CESDID        29250021
         B     SCNITEM                 GO TO PROCESS IT                 29300021
DSCNTIN  STM   GREG8,GREG9,SAVR8       SAVE WORK REG. CONTENTS          29350021
         SR    GREG8,GREG8             ZERO WORK REGISTER               29400021
         SR    GREG9,GREG9             ZERO WORK REGISTER               29450021
         IC    GREG8,PTLTRLN           GET PARTIAL ITEM LENGTH          29500021
         IC    GREG9,XPTRLEN           GET EXPECTED ITEM LENGTH         29550021
         SR    GREG9,GREG8             GET LENGTH OF CONTINUATION       29600021
         STH   GREG9,CNTDLEN           SAVE CONTINUATION LENGTH         29650021
         BCTR  GREG9,NULLREG           SUBTRACT 1 FOR MOVE LENGTH       29700021
         LA    GREG8,OBJTRN(GREG8)     GET ADDR. IN WORK AREA FOR       29750021
*                                      CONTINUATION TO START            29800021
         EX    GREG9,CTDMV             MOVE CONTINUATION TO WORK AREA   29850021
         SR    GREG8,GREG8             ZERO WORK REGISTER               29900021
         IC    GREG8,PTLTRLN           GET PARTIAL ITEM LENGTH          29950021
         BCTR  GREG8,NULLREG           SUBTRACT 1 FOR MOVE LENGTH       30000021
         EX    GREG8,PTDMV             MOVE PARTIAL ITEM TO WORK AREA   30050021
         LA    DATAPTR,OBJTRN          POINT TO START OF DESCRIPTION    30100021
*                                      IN WORK AREA                     30150021
         OI    LCLSWS,CNTDITM          TURN ON PARTIAL ITEN INDICATOR   30200021
         LM    GREG8,GREG9,SAVR8       RESTORE WORK. REG. CONTENTS      30250021
         B     TRNSDESC                GO TO PROCESS THE DESCRIPTION    30300021
PTDMV    MVC   OBJTRN(NOLEN),FULWD(TABNXT)  MOVE PARTIAL TRANSLATOR     30350021
*                                      DESCRIPTION TO WORK AREA         30400021
CTDMV    MVC   NODISP(NOLEN,GREG8),HEADLEN(BUFPTR)  MOVE CONTINUATION   30450021
*                                      OF TRANSLATOR DESCRIPTION TO     30500021
*                                      WORK AREA                        30550021
         EJECT                                                          30600021
*********************************************************************   30650021
*******            THE FOLLOWING SECTION OF CODE              *******   30700021
*******             HANDLES THE IDR FIELD OF AN               *******   30750021
*******            OBJECT MODULE END RECORD, WHEN             *******   30800021
*******                      PRESENT                          *******   30850021
*********************************************************************   30900021
         SPACE 1                                                        30950021
POSTOBJ  STM   GREG8,GREG9,SAVR8       SAVE WORK REG. CONTENTS          31000021
         SR    GREG8,GREG8             ZERO THE WORK REGISTER           31050021
         L     RNTPTR,RECNT            GET ADDRESS OF THE RENUMBERING   31100021
*                                      TABLE - 4                        31150021
RNTLOOP  LA    RNTPTR,FULWD(RNTPTR)    UPDATE POINTER TO NEXT RNT ENTRY 31200021
         CH    GREG8,NODISP(RNTPTR)    IS THIS ENTRY ZEROES ( END OF    31250021
*                                      THE RNT)?                        31300021
         BE    ADDITEM                 IF SO, BRANCH                    31350021
         TM    RNTYPE(RNTPTR),SECTDEF  IS THIS AN SD?                   31400021
         BZ    ADDID                   IF SO, BRANCH TO ADD IT          31450021
         TM    RNTYPE(RNTPTR),PRIVATE  COULD THIS BE A PC?              31500021
         BNO   RNTLOOP                 IF NOT, GO TO TRY NEXT ENTRY     31550021
         TM    RNTYPE(RNTPTR),OTHTYPE  IS THIS ENTRY A PC?              31600021
         BNZ   RNTLOOP                 IF NOT, GO TO TRY NEXT ENTRY     31650021
ADDID    TM    RNTYPE(RNTPTR),DELETE   IS IT MARKED FOR DELETION?       31700021
         BO    RNTLOOP                 IF SO, GO TO TRY NEXT ENTRY      31750021
         OI    LCLSWS,AL1VLD           TURN ON 'AT LEAST 1 VALID CESDID 31800021
*                                      FOUND' SWITCH                    31850021
         LA    GREG9,NEXTID(TABNXT)    GET ADDR. OF NEXT BYTE IN TABLE  31900021
*                                      + LENGTH OF CESDID TO BE ADDED   31950021
         CR    GREG9,TABEND            WILL ADDING THE ID OVERFLOW THE  32000021
*                                      TABLE?                           32050021
         BH    TABOVFLO                IF SO, GO TO LOG THE MESSAGE     32100021
*                                      AND TERMINATE                    32150021
         MVC   NODISP(IDLEN,TABNXT),NODISP(RNTPTR)  IF NOT, MOVE THE    32200021
*                                      ID ONTO THE END OF THE TABLE     32250021
         LR    TABNXT,GREG9            UPDATE POINTER TO NEXT BYTE IN   32300021
*                                      TABLE                            32350021
         B     RNTLOOP                 GO TO CONTINUE SEARCH LOOP       32400021
ADDITEM  TM    LCLSWS,AL1VLD           WAS AT LEAST 1 VALID ID FOUND?   32450021
         BNO   FINISH                  IF NOT, RETURN                   32500021
         MVC   TRNAME(TRNMLEN),TRNM1(BUFPTR)  MOVE TRANS. NAME TO       32550021
*                                      TEMPORARY LOCATION               32600021
         PACK  VVMM(PKLEN),VMYD1(UPLEN,BUFPTR)  CONVERT V/M LVL AND     32650021
*                                      DATE TO PACKED FORMAT AND MOVE   32700021
*                                      TO TEMPORARY LOCATION            32750021
         TM    IDRSWS,DBLOBJ           IS THIS A DOUBLE TRANSLATOR      32800021
*                                      DESCRIPTION?                     32850021
         BO    DBLNTRY                 IF SO, BRANCH                    32900021
         MVI   INDCTR,SWSOFF           INDICATE A SINGLE ENTRY          32950021
         B     SCANTRT                 GO TO SCAN TRANS. TABLE FOR A    33000021
*                                      MATCHING DESCRIPTION             33050021
DBLNTRY  MVI   INDCTR,DBLSWS           INDICATE A DOUBLE ENTRY          33100021
         MVC   TRNAME2(TRNMLEN),TRNM2(BUFPTR)  MOVE 2ND TRANS. NAME TO  33150021
*                                      TEMPORARY LOCATION               33200021
         PACK  VVMM2(PKLEN),VMYD2(UPLEN,BUFPTR)  CONVERT 2ND V/M LVL    33250021
*                                      AND DATE TO PACKED FORMAT AND    33300021
*                                      MOVE TO TEMPORARY LOCATION       33350021
         SPACE 3                                                        33400021
*********************************************************************   33450021
*******            THE FOLLOWING SECTION OF CODE              *******   33500021
*******            SCANS THE IDR TRANSLATOR TABLE             *******   33550021
*******             FOR TRANSLATOR DESCRIPTIONS               *******   33600021
*******            IDENTICAL TO THAT ON THE INPUT             *******   33650021
*******             RECORD -- IF FOUND, THE TWO               *******   33700021
*******                 ITEMS ARE COMBINED                    *******   33750021
*********************************************************************   33800021
         SPACE 1                                                        33850021
SCANTRT  C     TABPTR,IDRTREND         CHK FOR TBL END          SA63745 33900000
         BNL   POSTDSC                 IF SO, GO TO POST THE NEW ITEM   33950021
         CLC   NODISP(IDLEN,TABPTR),HZERO  IS THIS A NULL ITEM?         34000021
         BNE   SCNTRT05                IF NOT, BRANCH                   34050021
         MVC   HTEMP(IDLEN),NEXTID(TABPTR)  GET LENGTH OF NULL ITEM     34100021
         AH    TABPTR,HTEMP            ADD NULL LENGTH TO POINTER       34150021
         B     SCANTRT                 GO TO CONTINUE SCAN              34200021
SCNTRT05 ST    TABPTR,FTEMP            SAVE STARTING ADDRESS OF ITEM    34250021
IDSCAN   TM    NODISP(TABPTR),LASTID   IS THIS THE LAST ID IN STRING?   34300021
         BO    TESTDSC                 IF SO, BRANCH                    34350021
         LA    TABPTR,NEXTID(TABPTR)   UPDATE TO NEXT ID                34400021
         B     IDSCAN                  GO TO CONTINUE SCAN              34450021
TESTDSC  LA    TABPTR,NEXTID(TABPTR)   POINT TO START OF DESCRIPTION    34500021
         TM    IDRSWS,DBLOBJ           IS INPUT A DOUBLE ENTRY?         34550021
         BO    TESTDBL                 IF SO, BRANCH                    34600021
         CLC   OBJTRN(SNGTRN),NODISP(TABPTR)  DOES DESCRIPTION IN TABLE 34650021
*                                      MATCH INPUT DESCRIPTION?         34700021
         BE    MOVITM                  IF SO, BRANCH                    34750021
         B     SCNTRT10                GO TO CONTINUE TABLE SCAN        34800021
TESTDBL  CLC   OBJTRN(DBLTRN),NODISP(TABPTR)  DOES DESCRIPTION IN TABLE 34850021
*                                      MATCH INPUT DESCRIPTION?         34900021
         BE    MOVITM                  IF SO, BRANCH                    34950021
SCNTRT10 TM    NODISP(TABPTR),DBLSWS   IS THE ITEM BEING COMPARED A     35000021
*                                      DOUBLE TRANSLATOR DESCRIPTION?   35050021
         BO    SCNTRT15                IF SO, BRANCH                    35100021
         LA    TABPTR,SNGTRN(TABPTR)   UPDATE TO NEXT TRANS. ITEM       35150021
         B     SCANTRT                 GO TO CONTINUE TABLE SCAN        35200021
SCNTRT15 LA    TABPTR,DBLTRN(TABPTR)   UPDATE TO NEXT TRANS. ITEM       35250021
         B     SCANTRT                 GO TO CONTINUE TABLE SCAN        35300021
POSTDSC  TM    IDRSWS,DBLOBJ           IS THIS A DOUBLE ITEM?           35350021
         BO    PSTDBDS                 IF SO, BRANCH                    35400021
         LA    DATAPTR,SNGTRN          SET LENGTH OF A SINGLE ITEM      35450021
         B     PSTDSCR                 GO TO POST IT                    35500021
PSTDBDS  LA    DATAPTR,DBLTRN          SET LENGTH OF A DOUBLE ITEM      35550021
         B     PSTDSCR                 GO TO POST IT                    35600021
MOVITM   L     GREG8,FTEMP             GET STARTING ADDR. OF ID STRING  35650021
MOVIDSTR CR    GREG8,TABPTR            END OF STRING OF ESDID'S?        35700021
         BE    NULITM                  IF SO, BRANCH                    35750021
         LA    GREG9,NEXTID(TABNXT)    GET ADDR. OF NEXT BYTE IN TABLE  35800021
*                                      + LENGTH OF CESDID TO BE ADDED   35850021
         CR    GREG9,TABEND            WILL ADDING THE ID OVERFLOW THE  35900021
*                                      TABLE?                           35950021
         BH    TABOVFLO                IF SO, GO TO LOG THE MESSAGE     36000021
*                                      AND TERMINATE                    36050021
         MVC   NODISP(IDLEN,TABNXT),NODISP(GREG8)  IF NOT, MOVE THE     36100021
*                                      ID TO THE END OF THE TABLE       36150021
         LR    TABNXT,GREG9            UPDATE POINTER TO NEXT BYTE IN   36200021
*                                      TABLE                            36250021
         LA    GREG8,NEXTID(GREG8)     UPDATE TO NEXT CESDID            36300021
         B     MOVIDSTR                GO TO MOVE NEXT ID               36350021
NULITM   L     GREG8,FTEMP             GET STARTING ADDR. OF ID STRING  36400021
         MVC   NODISP(IDLEN,GREG8),HZERO  NULL THE ITEM           M1602 36450021
         LR    GREG9,TABPTR            GET STARTING ADDR. OF DESCR.     36500021
         SR    GREG9,GREG8             GET LENGTH OF STRING OF ID'S     36550021
         TM    IDRSWS,DBLOBJ           IS IT A DOUBLE ITEM?             36600021
         BO    DBLNULL                 IF SO, BRANCH                    36650021
         LA    GREG9,SNGTRN(GREG9)     ADD DESCRIPTION LENGTH           36700021
         LA    DATAPTR,SNGTRN          INITIALIZE DATA POINTER TO       36750021
*                                      DESCRIPTION LENGTH               36800021
         B     SGLNULL                 BRANCH AROUND ADUSTMENT FOR      36850021
*                                      DOUBLE ITEM                      36900021
DBLNULL  LA    GREG9,DBLTRN(GREG9)     ADD DESCRIPTION LENGTH           36950021
         LA    DATAPTR,DBLTRN          INITIALIZE DATA POINTER TO       37000021
*                                      DESCRIPTION LENGTH               37050021
SGLNULL  STH   GREG9,HTEMP             SAVE TOTAL ITEM LENGTH           37100021
         MVC   NEXTID(IDLEN,GREG8),HTEMP  MOVE IN ITEM LENGTH           37150021
         B     PSTDSC2                 BRANCH AROUND SETTING HIGH       37200021
*                                      ORDER BIT FOR LAST CESDID        37250021
PSTDSCR  LR    GREG8,TABNXT            POINT TO NEXT BYTE IN TABLE      37300021
         BCTR  GREG8,NULLREG           SUBTRACT 2 TO POINT TO THE LAST  37350021
         BCTR  GREG8,NULLREG           CESDID ENTERED IN THE TABLE      37400021
         OI    NODISP(GREG8),LASTID    TURN ON 'LAST ID' BIT            37450021
PSTDSC2  LA    ITEMPTR,OBJTRN          POINT TO START OF DESCRIPTION    37500021
         AR    DATAPTR,ITEMPTR         SET POINTER TO END OF DESCR.     37550021
         LM    GREG8,GREG9,SAVR8       RESTORE WORK REG. CONTENTS       37600021
         BAL   TEMPRTN,POSTIDR         GO TO ADD THIS TRANSLATOR        37650021
*                                      DESCRIPTION TO THE TABLE         37700021
TRNSFIN  ST    TABNXT,IDRTREND         UPDATE POINTER TO NEXT           37750021
*                                      AVAILABLE BYTE IN TABLE          37800021
         B     FINISH                  RETURN                           37850021
         EJECT                                                          37900021
*********************************************************************** 37950021
*********************************************************************** 38000021
****                                                               **** 38050021
****     SUB-PROGRAM IDRIDENT PROCESSES INPUT LOAD MODULE IDR'S    **** 38100021
****     WITH USER DATA AND USER DATA SPECIFIED VIA THE IDENTIFY   **** 38150021
****                    CONTROL STATEMENT                          **** 38200021
****                                                               **** 38250021
*********************************************************************** 38300021
*********************************************************************** 38350021
         SPACE 2                                                        38400021
IDRIDENT L     TABPTR,IDRUDTAB         GET ADDRESS OF USER DATA TABLE   38450021
         L     TABNXT,IDRUDEND         GET ADDRESS OF NEXT AVAILABLE    38500021
*                                      BYTE IN TABLE                    38550021
         LR    TABEND,TABPTR           GET STARTING ADDRESS OF TABLE    38600021
         AH    TABEND,IDRUDLEN         GET ENDING ADDRESS OF TABLE      38650021
         TM    IDRSWS,LMDIDR           IS LOAD MODULE INDICATOR ON?     38700021
         BO    LMODUD                  IF SO, BRANCH                    38750021
         TM    IDRSWS,USEIDR           IS IDENTIFY CARD SWITCH ON?      38800021
         BNO   ABORT                   IF NOT, IT IS AN ERROR           38850021
         STM   GREG14,GREG15,SAVR14    SAVE WORK REG. CONTENTS          38900021
         ST    GREG10,SAVR10           SAVE WORK REG. CONTENTS          38950021
         L     GREG10,NODISP(PARMPTR)  GET ADDRESS OF CSECT NAME        39000021
         L     CESDPTR,CHESD           GET CESD ADDRESS - 16            39050021
         LA    GREG14,CESDWDTH         PLACE 16 IN INCREMENT REGISTER   39100021
         ST    GREG8,SAVR8             SAVE WORK REG. CONTENTS          39150021
         LA    GREG8,FSTID             PLACE CESDID OF 1 FOR 1ST ITEM   39200021
         LH    GREG15,ENCDC            GET NO. OF ITEMS IN CESD         39250021
         SLL   GREG15,CESDINDX         MULT. BY 16 FOR CESD SIZE        39300021
         AR    GREG15,CESDPTR          ADD ADDR.OF CESD TP POINT TO     39350021
*                                      LAST ENTRY IN THE CESD           39400021
         B     INCRMNT                 GO TO INCREMENT THE CESD POINTER 39450021
CESDSRCH CLC   NODISP(NAMELEN,GREG10),NODISP(CESDPTR)  COMPARE CSECT    39500021
*                                      NAME TO BE IDENTIFIED WITH THIS  39550021
*                                      ENTRY IN THE CESD                39600021
         BE    NAMEFND                 IF THEY MATCH, BRANCH            39650021
BADMTCH  LA    GREG8,FSTID(GREG8)      UPDATE TO NEXT CESDID            39700021
INCRMNT  BXLE  CESDPTR,GREG14,CESDSRCH UPDATE POINTER TO NEXT ENTRY IN  39750021
*                                      CESD, COMPARE TO END ADDR. OF    39800021
*                                      CESD, IF NOT AT END, BRANCH TO   39850021
*                                      CONTINUE IN SEARCH LOOP          39900021
         B     BADIDENT                NAME NOT FOUND IN CESD -- GO TO  39950021
*                                      LOG ERROR MESSAGE                40000021
NAMEFND  TM    TYPE(CESDPTR),SECTDEF   IS MATCHING CESD ENTRY AN SD?    40050021
         BNZ   BADMTCH                 IF NOT, BRANCH BACK INTO LOOP    40100021
         TM    TYPE(CESDPTR),DELETE    IS THIS SD MARKED FOR DELETION?  40150021
         BO    BADMTCH                 IF SO, BRANCH BACK INTO LOOP     40200021
         STH   GREG8,HTEMP             SAVE MATCHED CESDID              40250021
         SPACE 3                                                        40300021
*********************************************************************   40350021
*******            THE FOLLOWING SECTION OF CODE              *******   40400021
*******            SCANS THE IDR USER DATA TABLE              *******   40450021
*******            FOR ANY PREVIOUS ENTRY WHICH               *******   40500021
*******            SPECIFIES THE SAME CSECT AS                *******   40550021
*******            THE IDENTIFY CONTROL CARD BEING            *******   40600021
*******            PROCESSED -- IF FOUND, THE OLD             *******   40650021
*******            DATA IS REPLACED BY THE NEW DATA           *******   40700021
*********************************************************************   40750021
         SPACE 1                                                        40800021
UDTABSCH CR    TABPTR,TABNXT           TABLE POINTER AT END OF TABLE?   40850021
         BE    POSTUD                  IF SO, BRANCH                    40900021
         CLC   NODISP(IDLEN,TABPTR),HZERO  IS THIS A NULL ITEM?         40950021
         BNE   UDTBSR05                IF NOT, BRANCH                   41000021
         MVC   HTEMP2(IDLEN),NEXTID(TABPTR)  GET LENGTH OF NULL ITEM    41050021
         AH    TABPTR,HTEMP2           POINT AFTER NULL ITEM            41100021
         B     UDTABSCH                GO TO CONTINUE SCAN              41150021
UDTBSR05 SR    GREG8,GREG8             ZERO OUT WORK REGISTER           41200021
         IC    GREG8,UDCNT(TABPTR)     GET BYTE COUNT OF USER DATA IN   41250021
*                                      THIS ITEM                        41300021
         LA    GREG8,UDHEAD(GREG8)     GET TOTAL LENGTH OF ITEM         41350021
         CLC   NODISP(IDLEN,TABPTR),HTEMP  DOES CESDID OF THIS ITEM     41400021
*                                      MATCH ID IN TABLE?               41450021
         BE    UDMATCH                 IF SO, BRANCH                    41500021
         AR    TABPTR,GREG8            UPDATE TO POINT TO NEXT ITEM     41550021
         B     UDTABSCH                GO TO CONTINUE SEARCH LOOP       41600021
UDMATCH  ST    GREG8,FTEMP             SAVE ITEM LENGTH                 41650021
         MVC   NODISP(FULWD,TABPTR),FTEMP  NULL ITEM WITH 2 BYTES OF    41700021
*                                      ZEROES AND 2-BYTE COUNT          41750021
         MVC   NODISP(IDLEN,TABPTR),HZERO  NULL THE ITEM          M1602 41770021
POSTUD   MVC   UDID(IDLEN),HTEMP       SAVE CESDID OF THIS ITEM         41800021
         L     GREG8,USTRLEN(PARMPTR)  GET ADDR. OF DATA LENGTH         41850021
         LH    GREG8,NODISP(GREG8)     GET LENGTH OF IDENTIFY DATA      41900021
         STC   GREG8,UDBTCT            STORE DATA LENGTH                41950021
         LA    ITEMPTR,UDITEM          GET ADDR. OF ITEM TO BE POSTED   42000021
         LA    GREG8,UDHEAD(GREG8)     GET LENGTH OF ITEM               42050021
         LR    DATAPTR,ITEMPTR         GET BEGINNING ADDR. OF ITEM      42100021
         AR    DATAPTR,GREG8           GET ENDING ADDR. OF ITEM         42150021
         L     GREG8,UDSTR(PARMPTR)    GET ADDR. OF USER DATA           42200021
         MVC   UDATA(UDLEN),NODISP(GREG8)  MOVE USER DATA               42250021
         STM   GREG0,GREG1,SAVR0       SAVE WORK REG. CONTENTS          42300021
         TIME  ,                       GET TODAY'S DATE                 42350021
         ST    GREG1,FTEMP             SAVE DATE                        42400021
         MVC   UDATE(DATELEN),DATESAV  MOVE DATE TO ITEM                42450021
         LM    GREG0,GREG1,SAVR0       RESTORE WORK REG. CONTENTS       42500021
         BAL   TEMPRTN,POSTIDR         GO TO POST THIS ITEM             42550021
         LM    GREG14,GREG15,SAVR14    RESTORE WORK REG. CONTENTS       42600021
         L     GREG8,SAVR8             RESTORE WORK REG. CONTENTS       42650021
         L     GREG10,SAVR10           RESTORE WORK REG. CONTENTS       42700021
         ST    TABNXT,IDRUDEND         UPDATE POINTER TO NEXT           42750021
*                                      AVAILABLE BYTE IN TABLE          42800021
         MVI   MSGBUF,BLANK            PLACE BLANK IN MSG BUFFER        42850021
         MVC   MSGBUFF(MSGLEN),MSGBUF  BLANK OUT MESSAGE LINE           42900021
         L     GREG14,NODISP(PARMPTR)  GET ADDRESS OF CSECT NAME        42950021
         MVC   MSGNAME(NAMELEN),NODISP(GREG14)  MOVE CSECT NAME INTO    43000021
*                                      MESSAGE LINE                     43050021
         L     GREG14,UDSTR(PARMPTR)   GET ADDRESS OF USER DATA         43100021
         MVC   MSGDATA(UDLEN),NODISP(GREG14)  MOVE USER DATA INTO       43150021
*                                      MESSAGE LINE                     43200021
         LH    GREG0,GOODIDNT          GET MESSAGE CODE                 43250021
         ST    GREG1,SAVR1             SAVE REG. 1 CONTENTS             43300021
         LA    GREG1,MSGBUF            POINT TO MESSAGE BUFFER          43350021
         OI    IDRSWS,LOGIDNT          TURN IDENT OPTION SWITCH FOR LOG 43400021
         L     ENTRYPT,ERDIG           GET ADDRESS OF MESSAGE LOGGING   43450021
*                                      ROUTINE                          43500021
         BALR  RETURN,ENTRYPT          LINK TO LOGGING ROUTINE          43550021
         NI    IDRSWS,LOGSOFF          TURN OFF LOG SWITCH              43600021
         L     GREG1,SAVR1             RESTORE REG. 1                   43650021
         B     FINISH                  RETURN TO CALLING ROUTINE        43700021
         EJECT                                                          43750021
*********************************************************************   43800021
*******            THE FOLLOWING SECTION OF CODE              *******   43850021
*******              HANDLES LOAD MODULE IDR'S                *******   43900021
*******             CONTAINING USER DATA ITEMS                *******   43950021
*********************************************************************   44000021
         SPACE 1                                                        44050021
LMODUD   LA    ITEMPTR,HEADLEN(BUFPTR) GET STARTING ADDR. OF 1ST ITEM   44100021
*                                      ON THE RECORD                    44150021
         TM    IDRSWS,PARTENT          IS THIS A CONTINUATION FROM THE  44200021
*                                      PREVIOUS RECORD?                 44250021
         BNO   RECSCAN                 IF NOT, BRANCH                   44300021
         MVC   PRTLEN(FULWD),NODISP(TABNXT)  GET THE LENGTH OF THE      44350021
*                                      PARTIAL ITEM                     44400021
         STM   GREG8,GREG9,SAVR8       SAVE WORK REG. CONTENTS          44450021
         L     GREG8,PRTLEN            GET PARTIAL ITEM LENGTH          44500021
         BCTR  GREG8,NULLREG           SUBTRACT 1 FOR MOVE LENGTH       44550021
         EX    GREG8,CNTDMOV           MOVE PARTIAL ITEM TO WORK AREA   44600021
         LA    GREG8,UDMAXLEN          GET MAXIMUM LENGTH OF A USER     44650021
*                                      DATA ITEM                        44700021
         L     GREG9,PRTLEN            GET LENGTH OF PARTIAL ITEM       44750021
         SR    GREG8,GREG9             GET LENGTH OF CONTINUED ITEM     44800021
         LA    ITEMPTR,UDITEM          POINT TO START OF ITEM           44850021
         AR    GREG9,ITEMPTR           GET ADDR. FOR CONTINUATION TO    44900021
*                                      START                            44950021
         BCTR  GREG8,NULLREG           SUBTRACT 1 FOR MOVE LENGTH       45000021
         EX    GREG8,MOVCTN            MOVE CONTINUATION OF ITEM TO     45050021
*                                      WORK AREA                        45100021
         OI    LCLSWS,CNTDITM          TURN ON CONTINUATION SWITCH      45150021
         NI    IDRSWS,PARTOFF          TURN OFF PARTIAL ENTRY SWITCH    45200021
         LM    GREG8,GREG9,SAVR8       RESTORE WORK REGISTERS           45250021
RECSCAN  LA    DATAPTR,UDHEAD(ITEMPTR) GET STARTING ADDR. OF DATA       45300021
         TM    LCLSWS,CNTDITM          IS THIS A CONTINUED ITEM?        45350021
         BO    RCSCN040                IF SO, BRANCH                    45400021
         CR    DATAPTR,ENDBUF          IS THIS A PARTIAL ENTRY?         45450021
         BH    PRTLUD                  IF SO, BRANCH                    45500021
RCSCN040 SR    GREG0,GREG0             ZERO WORK REGISTER               45550021
         IC    GREG0,UDCNT(ITEMPTR)    GET DATA BYTE COUNT              45600021
         AR    DATAPTR,GREG0           GET ENDING ADDR. OF ITEM         45650021
         TM    LCLSWS,CNTDITM          IS THIS A CONTINUED ITEM?        45700021
         BO    RCSCN080                IF SO, BRANCH                    45750021
         CR    DATAPTR,ENDBUF          IS THIS A PARTIAL ENTRY?         45800021
         BH    PRTLUD                  IF SO, BRANCH                    45850021
RCSCN080 MVC   HTEMP(IDLEN),NODISP(ITEMPTR)  SAVE INPUT CESDID          45900021
         LH    RNTPTR,HTEMP            GET INPUT CESDID                 45950021
         SLL   RNTPTR,RNTINDX          GET INDEX INTO THE RNT           46000021
         A     RNTPTR,RECNT            ADD STARTING ADDR. OF RNT        46050021
         TM    RNTYPE(RNTPTR),DELETE   IS THIS CSECT MARKED DELETE?     46100021
         BO    NXTITEM                 IF SO, SKIP THIS ITEM            46150021
         MVC   NODISP(IDLEN,ITEMPTR),NODISP(RNTPTR)  MOVE RENUMBERED    46200021
*                                      CESDID TO THE ITEM               46250021
         BAL   TEMPRTN,POSTIDR         GO TO POST THE ITEM              46300021
NXTITEM  TM    LCLSWS,CNTDITM          WAS THIS A CONTINUED ITEM?       46350021
         BNO   NOTCNTD                 IF NOT, BRANCH                   46400021
         SR    DATAPTR,ITEMPTR         GET LENGTH OF ITEM               46450021
         S     DATAPTR,PRTLEN          GET LENGTH OF CONTINUATION       46500021
         STH   DATAPTR,HTEMP           SAVE LENGTH OF CONTINUATION      46550021
         LA    DATAPTR,HEADLEN(BUFPTR) GET STARTING ADDR. OF DATA ON    46600021
*                                      THE RECORD                       46650021
         AH    DATAPTR,HTEMP           GET ADDR. OF 1ST ITEM ON RECORD  46700021
*                                      AFTER CONTINUATION               46750021
         NI    LCLSWS,CNTDOFF          TURN OFF CONTINUATION SWITCH     46800021
NOTCNTD  LR    ITEMPTR,DATAPTR         UPDATE TO POINT TO NEXT ITEM     46850021
         CR    DATAPTR,ENDBUF          IS THIS THE LAST ITEM ON THE     46900021
*                                      RECORD?                          46950021
         BE    UDFIN                   IF SO, BRANCH                    47000021
         B     RECSCAN                 GO TO CONTINUE SCANNING RECORD   47050021
CNTDMOV  MVC   UDITEM(NOLEN),FULWD(TABNXT)  MOVE PARTIAL ITEM SAVED IN  47100021
*                                      TABLE TO WORK AREA               47150021
MOVCTN   MVC   NODISP(NOLEN,GREG9),HEADLEN(BUFPTR)  MOVE CONTINUATION   47200021
*                                      OF PARTIAL ITEM TO WORK AREA     47250021
PRTLMOV  MVC   UDITEM(NOLEN),NODISP(ITEMPTR)  MOVE PARTIAL USER DATA    47300021
*                                      ITEM TO WORK AREA                47350021
         SPACE 3                                                        47400021
*********************************************************************   47450021
*******            THE FOLLOWING SECTION OF CODE              *******   47500021
*******             HANDLES USER DATA IDR ITEMS               *******   47550021
*******             THAT ARE INCOMPLETE ON THE                *******   47600021
*******           RECORD CURRENTLY BEING PROCESSED            *******   47650021
*********************************************************************   47700021
         SPACE 1                                                        47750021
PRTLUD   OI    IDRSWS,PARTENT          TURN ON PARTIAL ENTRY SWITCH     47800021
         LR    GREG11,ENDBUF           GET ENDING ADDR. OF PARTIAL ITEM 47850021
         SR    GREG11,ITEMPTR          GET LENGTH OF PARTIAL ITEM       47900021
         ST    GREG11,PRTLEN           SAVE LENGTH OF PARTIAL ITEM      47950021
         BCTR  GREG11,NULLREG          SUBTRACT 1 FROM LENGTH FOR       48000021
*                                      ZERO-ORIENTED MOVE LENGTH        48050021
         EX    GREG11,PRTLMOV          MOVE PARTIAL ITEM TO WORK AREA   48100021
         LA    ITEMPTR,SAVPTLUD        GET ADDRESS OF PARTIAL ITEM      48150021
         L     DATAPTR,PRTLEN          GET LENGTH OF PARTIAL ITEM       48200021
         LA    DATAPTR,FULWD(ITEMPTR,DATAPTR)  ADD LENGTH OF ITEM BYTE  48250021
*                                      COUNT AND STARTING ADDRESS OF    48300021
*                                      ITEM TO GET ENDING ADDRESS       48350021
         BAL   TEMPRTN,POSTIDR         POST PARTIAL ITEM                48400021
         L     TABNXT,PARTBEG          RESTORE ADDRESS OF NEXT BYTE IN  48450021
*                                      TABLE TO START OF PARTIAL ENTRY  48500021
UDFIN    ST    TABNXT,IDRUDEND         UPDATE POINTER TO NEXT           48550021
*                                      AVAILABLE BYTE IN TABLE          48600021
         B     FINISH                  RETURN TO CALLING ROUTINE        48650021
BADIDENT EQU   *                       LOG ERR. FOR NO SUCH CSECT FOUND 48700021
         MVI   MSGBUF,BLANK            PLACE BLANK IN MSG BUFFER        48750021
         MVC   MSGBUFF(MSGLEN),MSGBUF  BLANK OUT MESSAGE LINE           48800021
         MVC   MSGNAME(NAMELEN),NODISP(GREG10)  MOVE CSECT NAME INTO    48850021
*                                      MESSAGE LINE                     48900021
         L     GREG10,UDSTR(PARMPTR)   GET ADDRESS OF USER DATA         48950021
         MVC   MSGDATA(UDLEN),NODISP(GREG10)  MOVE USER DATA INTO       49000021
*                                      MESSAGE LINE                     49050021
         LH    GREG0,BADIDNT           GET MESSAGE CODE                 49100021
         ST    GREG1,SAVR1             SAVE REG. 1 CONTENTS             49150021
         LA    GREG1,MSGBUF            POINT TO MESSAGE BUFFER          49200021
         OI    IDRSWS,LOGIDNT          TURN ON OPTION TO LOG A CARD     49250021
*                                      NOT IN THE SYSTEM BUFFER         49300021
         L     ENTRYPT,ERDIG           GET ADDRESS OF MESSAGE LOGGING   49350021
*                                      ROUTINE                          49400021
         BALR  RETURN,ENTRYPT          LINK TO LOGGING ROUTINE          49450021
         NI    IDRSWS,LOGSOFF          TURN OFF LOG OPTION SWITCH       49500021
         L     GREG1,SAVR1             RESTORE REG. 1                   49550021
         B     FINISH                  RETURN                           49600021
         EJECT                                                          49650021
*********************************************************************** 49700021
*********************************************************************** 49750021
****                                                               **** 49800021
****     SUB-PROGRAM IDRSPZAP PROCESSES INPUT LOAD MODULE IDR'S    **** 49850021
****     WITH DATA ENTERED BY THE SERVICE AID PROGRAM IMASPZAP     **** 49900021
****                                                               **** 49950021
*********************************************************************** 50000021
*********************************************************************** 50050021
         SPACE 2                                                        50100021
IDRSPZAP L     TABPTR,IDRZPTAB         GET ADDRESS OF IMASPZAP DATA     50150021
*                                      TABLE                            50200021
         L     TABNXT,IDRZPEND         GET ADDRESS OF NEXT AVAILABLE    50250021
*                                      BYTE IN TABLE                    50300021
         LR    TABEND,TABPTR           GET STARTING ADDRESS OF TABLE    50350021
         AH    TABEND,IDRZPLEN         GET ENDING ADDRESS OF TABLE      50400021
         SR    GREG11,GREG11           ZERO WORK REGISTER               50450021
         NI    HEADLEN(BUFPTR),ZCHNOFF TURN OFF THE CHAIN BIT IN THE    50500021
*                                      IMASPZAP COUNT FIELD             50550021
         IC    GREG11,HEADLEN(BUFPTR)  GET COUNT OF IMASPZAP ENTRIES    50600021
         LTR   GREG11,GREG11           TEST THE ENTRY COUNT             50650021
         BZ    FINISH                  IF THERE ARE NO ENTRIES ON THIS  50700021
*                                      RECORD, RETURN                   50750021
         L     RNTPTR,RECNT            GET ADDRESS OF THE RNT - 4       50800021
         LA    ITEMPTR,FULWD(BUFPTR)   GET ADDRESS OF 1ST ENTRY ON REC. 50850021
ZAPLOOP  LA    DATAPTR,ZAPLEN(ITEMPTR) GET ENDING ADDRESS OF THIS ENTRY 50900021
         MVC   HTEMP(IDLEN),NODISP(ITEMPTR)  SAVE THE CESDID OF THE     50950021
*                                      ENTRY                            51000021
         LH    GREG15,HTEMP            GET THE CESDID                   51050021
         SLL   GREG15,RNTINDX          MULTIFLY THE ID BY 4 TO GET AN   51100021
*                                      INDEX INTO THE RNT               51150021
         AR    GREG15,RNTPTR           ADD THE ADDRESS OF THE RNT-4     51200021
         TM    RNTYPE(GREG15),DELETE   IS THIS CSECT MARKED DELETE?     51250021
         BO    DELZAP                  IF SO, BRANCH                    51300021
         MVC   NODISP(IDLEN,ITEMPTR),NODISP(GREG15)  MOVE THE           51350021
*                                      RENUMBERED CESDID INTO THE ENTRY 51400021
         BAL   TEMPRTN,POSTIDR         GO TO POST THE ENTRY             51450021
DELZAP   LR    ITEMPTR,DATAPTR         POINT TO THE NEXT ENTRY          51500021
         BCT   GREG11,ZAPLOOP          GO TO CONTINUE PROCESSING        51550021
*                                      CONSECUTIVE ENTRIES UNTIL        51600021
*                                      THE COUNT IS EXHAUSTED           51650021
         ST    TABNXT,IDRZPEND         UPDATE POINTER TO NEXT           51700021
*                                      AVAILABLE BYTE IN TABLE          51750021
         B     FINISH                  RETURN TO CALLING ROUTINE        51800021
         EJECT                                                          51850021
*********************************************************************** 51900021
*********************************************************************** 51950021
****                                                               **** 52000021
****     SUB-PROGRAM POSTIDR ADDS INPUT IDR DATA TO ONE OF THE     **** 52050021
****     THREE IDR DATA TABLES:  1) IDRTRTAB -- TRANSLATOR DATA    **** 52100021
****                             2) IDRZPTAB -- IMASPZAP DATA      **** 52150021
****                             3) IDRUDTAB -- USER DATA          **** 52200021
****                                                               **** 52250021
*********************************************************************** 52300021
*********************************************************************** 52350021
         SPACE 2                                                        52400021
POSTIDR  TM    IDRSWS,PARTENT          IS THIS ITEM A PARTIAL ENTRY?    52450021
         BNO   NOTPART                 IF NOT, BRANCH                   52500021
         ST    TABNXT,PARTBEG          SAVE STARTING ADDR. OF PARTIAL   52550021
*                                      ENTRY IN TABLE                   52600021
NOTPART  ST    GREG8,SAVR8             SAVE WORK REG. CONTENTS          52650021
         LR    GREG8,DATAPTR           GET ENDING ADDR. OF ITEM         52700021
         SR    GREG8,ITEMPTR           GET LENGTH OF ITEM               52750021
         AR    GREG8,TABNXT            ADD NEXT TABLE ADDR.             52800021
         CR    GREG8,TABEND            COMPARE TO END OF TABLE          52850021
         BH    TABOVFLO                IF HIGH, IT IS AN ERROR          52900021
*                                       -- GO TO LOG AND TERMINATE      52950021
         SR    GREG8,TABNXT            GET ITEM LENGTH AGAIN            53000021
         ST    GREG8,FTEMP             SAVE LENGTH OF ENTRY             53050021
         BCTR  GREG8,NULLREG           SUBTRACT 1 FOR MOVE LENGTH       53100021
         EX    GREG8,MOVEIDR           MOVE THE PARTIAL ENTRY TO THE    53150021
*                                      NEXT POSITION IN THE TABLE       53200021
         L     GREG8,FTEMP             RESTORE CORRECT ENTRY LENGTH     53250021
         AR    TABNXT,GREG8            UPDATE POINTER TO NEXT AVAILABLE 53300021
*                                      BYTE IN TABLE                    53350021
         L     GREG8,SAVR8             RESTORE WORK REG. CONTENTS       53400021
         BR    TEMPRTN                 RETURN TO PROCESSOR              53450021
MOVEIDR  MVC   NODISP(NOLEN,TABNXT),NODISP(ITEMPTR)  MOVE IDR ITEM TO   53500021
*                                      THE NEXT AVAILABLE POSITION IN   53550021
*                                      THE TABLE                        53600021
TABOVFLO EQU   *                       LOG OVERFLO MSG & TERMINATE      53650021
         LH    GREG0,OVFLMSG           GET OVERFLOW MESSAGE CODE        53700021
         L     ENTRYPT,ERDIG           GET ADDRESS OF ERROR LOGGING     53750021
*                                      ROUTINE                          53800021
         BR    ENTRYPT                 GO TO LOG ROUTINE                53850021
*                  THIS IS A TERMINAL ERROR -- THE LOG ROUTINE WILL     53900021
*                  PASS CONTROL TO IEWLMFNL TO PRINT THE MESSAGE        53950021
*                  AND TERMINATE LINKAGE EDITOR PROCESSING              54000021
         TITLE '***IEWLMIDR*** IDENTIFY CONTROL CARD PROCESSOR'         54050021
*********************************************************************** 54100021
*                                                                     * 54150021
*               ************************************                  * 54200021
*              * SECONDARY ENTRY POINT --IEWLCIDR-- *                 * 54250021
*               ************************************                  * 54300021
*                                                                     * 54350021
*        CONTROL IS RECEIVED AT THIS POINT FROM MODULE IEWLMSCN       * 54400021
*        FOR THE PURPOSE OF ACCEPTING IDR DATA SUPPLIED BY THE        * 54450021
*        USER AND PASSED TO THE LINKAGE EDITOR BY MEANS OF THE        * 54500021
*        IDENTIFY CONTROL STATEMENT.                                  * 54550021
*                                                                     * 54600021
*********************************************************************** 54650021
         SPACE 2                                                        54700021
IEWLCIDR SAVE  (14,12),T,*             SAVE CALLING PROGRAM'S REGISTERS 54750021
         L     IDRBASE,ADDISP(ENTRYPT) LOAD BASE ADDRESS FOR MODULE     54800021
         B     CSTART                  BRANCH AROUND ADRESS CONSTANT    54850021
STARTAD  DC    A(START)                ADDR OF 1ST INSTR FOR MOD BASE   54900021
ADDISP   EQU   STARTAD-IEWLCIDR        DISPLACEMENT BEYOND ENTRY POINT  54950021
*                                      TO OPTAIN BASE ADDRESS FOR THE   55000021
*                                      MODULE WHEN ENTERED HERE         55050021
CSTART   OI    IDRSWS,USEIDR           TURN ON IDENTIFY CONTROL CARD    55100021
*                                      INDICATOR                        55150021
         B     IDRIDENT                GO TO PROCESS THE DATA ON THE    55200021
*                                      IDENTIFY CARD                    55250021
FINISH   NI    IDRSWS,SWSINIT          RE-INITIALIZE IDR SWITCHES       55300021
         MVI   LCLSWS,SWSOFF           RE-INITIALIZE ALL LOCAL          55350021
*                                      SWITCHES TO ZEROES               55400021
         RETURN    (14,12),T,RC=0      RESTORE REGISTERS AND RETURN     55450021
ABORT    LH    GREG0,INTERR            GET MESSAGE CODE FOR ERROR       55500021
*                                      IN IDR INPUT                     55550021
         L     ENTRYPT,ERDIG           GET ADDRESS OF LOG ROUTINE       55600021
         BR    ENTRYPT                 GO TO LOG THE ERROR              55650021
*                                      -- THIS IS A TERMINAL            55700021
*                                         ERROR CONDITION               55750021
*                                      -- THE LOG ROUTINE               55800021
*                                         WILL NOT RETURN               55850021
         TITLE '***IEWLMIDR*** CSECT IDENTIFICATION RECORD PROCESSOR'   55900021
*********************************************************************** 55950021
*                                                                     * 56000021
*                    DEFINED STORAGE AND CONSTANTS                    * 56050021
*                                                                     * 56100021
*********************************************************************** 56150021
         SPACE 2                                                        56200021
SAVR0    DS    1F                      GENERAL PURPOSE REG SAVE AREA    56250021
SAVR1    DS    1F                      GENERAL PURPOSE REG SAVE AREA    56300021
SAVR8    DS    1F                      GENERAL PURPOSE REG SAVE AREA    56350021
SAVR9    DS    1F                      GENERAL PURPOSE REG SAVE AREA    56400021
SAVR10   DS    1F                      GENERAL PURPOSE REG SAVE AREA    56450021
SAVR11   DS    1F                      GENERAL PURPOSE REG SAVE AREA    56500021
SAVR13   DS    1F                      GENERAL PURPOSE REG SAVE AREA    56550021
SAVR14   DS    1F                      GENERAL PURPOSE REG SAVE AREA    56600021
SAVR15   DS    1F                      GENERAL PURPOSE REG SAVE AREA    56650021
FTEMP    DS    1F                      FULLWORD TEMPORARY SAVE AREA     56700021
DATESAV  EQU   FTEMP+1                 START OF PACKED DECIMAL DATE     56750021
*                                      RETURNED BY TIME MACRO           56800021
PARTBEG  DS    1F                      SAVE AREA FOR STARTING ADDR. OF  56850021
*                                      A PARTIAL ITEM IN AN IDR TABLE   56900021
SAVPTLUD DS    0F                      SAVE AREA FOR A PARTIAL USER     56950021
*                                      DATA ITEM                        57000021
PRTLEN   DS    1F                      LENGTH OF THE PARTIAL ITEM       57050021
UDITEM   EQU   *                       WORKING COPY OF A USER DATA ITEM 57100021
UDID     DS    XL2                     CESDID                           57150021
UDATE    DS    XL3                     TODAY'S DATE                     57200021
UDBTCT   DS    XL1                     BYTE COUNT OF USER DATA          57250021
UDATA    DS    XL40                    USER DATA                        57300021
HTEMP    DS    1H                      HALFWORD TEMPORARY FOR CESDID    57350021
HTEMP2   DS    1H                      HALFWORD TEMPORARY WORK AREA     57400021
IDTEMP   DS    0H                      WORK AREA FOR A CONTINUED CESDID 57450021
ID1ST    DS    XL1                     1ST HALF OF THE CESDID           57500021
ID2ND    DS    XL1                     2ND HALF OF THE CESDID           57550021
CNTDLEN  DS    1H                      SAVE AREA FOR THE LENGTH OF A    57600021
*                                      CONTINUATION OF A TRANSLATOR     57650021
*                                      DESCRIPTION                      57700021
SAVPTLTR DS    0F                      SAVE AREA FOR A PARTIAL          57750021
*                                      TRANSLATOR ITEM                  57800021
PTLSWCH  DS    XL1                     INDICATOR FOR TYPE OF PARTIAL    57850021
*                                      ITEM (BINARY VALUE):             57900021
*                                        4 = HALF OF A CESDID FOLLOWS   57950021
*                                        8 = A PARTIAL TRANSLATOR       58000021
*                                            DESCRIPTION FOLLOWS        58050021
*                                       12 = NO DATA FOLLOWS (ITEM WAS  58100021
*                                            BROKEN AFTER A COMPLETE    58150021
*                                            CESDID)                    58200021
CPYLCLS  DS    XL1                     COPY OF LCLSWS REFLECTING        58250021
*                                      CURRENT STATUS OF PROCESSING     58300021
*                                      FOR THIS ITEM                    58350021
PTLTRLN  DS    XL1                     LENGTH OF PARTIAL DESCRIPTION    58400021
*                                      WHICH FOLLOWS (IF PTLSWCH=8)     58450021
XPTRLEN  DS    XL1                     EXPECTED LENGTH OF DESCRIPTION   58500021
*                                      (IF PTLSWCH=8)                   58550021
HIDSAV   EQU   XPTRLEN                 1ST HALF OF THE CESDID BEING     58600021
*                                      PROCESSED (IF PTLSWCH=4)         58650021
OBJTRN   DS    0CL31                   IDR TRANSLATOR DATA FIELD ON AN  58700021
*                                      OBJECT MODULE END RECORD         58750021
INDCTR   DS    XL1                     INDICATOR                        58800021
*                                      BLANK = NO IDR DATA              58850021
*                                      EBCDIC 1 = ONE TRANSLATOR        58900021
*                                                 DESCRIPTION           58950021
*                                      EBCDIC 2 = TWO TRANSLATOR        59000021
*                                                 DESCRIPTIONS          59050021
TRNAME   DS    CL10                    TRANSLATOR NAME                  59100021
VVMM     DS    XL2                     VERSION/MODIFICATION LEVEL OF    59150021
*                                      TRANSLATOR                       59200021
YYDDD    DS    XL3                     DATE OF TRANSLATION              59250021
TRNAME2  DS    CL10                    2ND TRANSLATOR NAME              59300021
VVMM2    DS    XL2                     VERSION/MODIFICATION LEVEL OF    59350021
*                                      2ND TRANSLATOR                   59400021
YYDDD2   DS    XL3                     DATE OF 2ND TRANSLATION          59450021
MSGBUF   DS    CL80                    BUFFER FOR BUILDING DIAGNOSTIC   59500021
*                                      MESSAGES TO BE PASSED TO THE     59550021
*                                      LOGGING ROUTINE                  59600021
MSGBUFF  EQU   MSGBUF+1                FOR INITIALIZING THE BUFFER      59650021
MSGNAME  EQU   MSGBUF+10               FOR A CSECT NAME                 59700021
MSGDATA  EQU   MSGBUF+30               FOR USER DATA FROM AN IDENTIFY   59750021
*                                      CONTROL STATEMENT                59800021
HZERO    DS    0H                      HALFWORD OF F'S TO TEST    M1602 59830021
         DC    X'FFFF'                 FOR NULL ITEMS             M1602 59860021
*                                      NULL ITEMS                       59900021
         DS    0H                      HALF-WORD ALIGNMENT              59950021
GOODIDNT DC    X'1043'                 MESSAGE INDICATING IDENTIFY      60000021
*                                      HAS BEEN ADDED                   60050021
BADIDNT  DC    X'1244'                 MESSAGE INDICATING CSECT NAME    60100021
*                                      ON AN IDENTIFY CARD CANNOT BE    60150021
*                                      FOUND IN THE CESD                60200021
OVFLMSG  DC    X'0445'                 ERROR MESSAGE CODE FOR IDR       60250021
*                                      TABLE OVERFLOW -- TERMINAL ERROR 60300021
INTERR   DC    X'0446'                 ERROR MESSAGE CODE FOR INVALID   60350021
*                                      IDR INPUT -- TERMINAL ERROR      60400021
         EJECT                                                          60450021
LCLSWS   DC    X'00'                   LOCAL SWITCHES ***************** 60500021
*     ***********************************************************     * 60550021
*     *                BIT DESCRIPTIONS                         *     * 60600021
*     ***********************************************************     * 60650021
*     *  SYMBOLIC  *       *        *    MEANING OF BIT WHEN    *     * 60700021
*     *  NAME  OF  *  BIT  *  MASK  *         TURNED ON         *     * 60750021
*     *    MASK    *       *        *        (VALUE = 1)        *     * 60800021
*     ***********************************************************     * 60850021
*     *            *       *        *  THE LAST ID IN A STRING  *     * 60900021
*     *  LSTIDFND  *   0   *  X'80' *   OF CESDID'S HAS BEEN    *     * 60950021
*     *            *       *        *          FOUND            *     * 61000021
*     ***********************************************************     * 61050021
*     *            *       *        *  AT LEAST ONE CESDID IN   *     * 61100021
*     *   AL1VLD   *   1   *  X'40' *  A STRING IS VALID (NOT   *     * 61150021
*     *            *       *        *      MARKED DELETE)       *     * 61200021
*     ***********************************************************     * 61250021
*     *            *       *        *    THE IDR ITEM BEING     *     * 61300021
*     *  CNTDITM   *   2   *  X'20' *  PROCESSED IS CONTINUED   *     * 61350021
*     *            *       *        *  FROM THE PREVIOUS IDR    *     * 61400021
*     ***********************************************************     * 61450021
*     *            *       *        *  A CESDID IN A STRING OF  *     * 61500021
*     *   CNTDID   *   3   *  X'10' *    CESDID'S, CONTINUED    *     * 61550021
*     *            *       *        *  FROM A PREVIOUS TRANS.   *     * 61600021
*     *            *       *        *  IDR IS BEING PROCESSED   *     * 61650021
*     ***********************************************************     * 61700021
*     *    N/A     *   4   *  X'08' *         RESERVED          *     * 61750021
*     ***********************************************************     * 61800021
*     *    N/A     *   5   *  X'04' *         RESERVED          *     * 61850021
*     ***********************************************************     * 61900021
*     *    N/A     *   6   *  X'02' *         RESERVED          *     * 61950021
*     ***********************************************************     * 62000021
*     *    N/A     *   7   *  X'01' *         RESERVED          *     * 62050021
*     ***********************************************************     * 62100021
************* NOTE--INITIAL VALUE OF ALL BITS IS ZERO ***************** 62150021
         EJECT                                                          62200021
*********************************************************************** 62250021
*                                                                     * 62300021
*                     MODULE MAINTENANCE AREA                         * 62350021
*             160 BYTES ALIGNED ON A DOUBLE WORD BOUNDARY             * 62400021
*                  (APPROXIMATELY 8% OF MODULE SIZE)                  * 62450021
*                                                                     * 62500021
*********************************************************************** 62550021
         SPACE                                                          62600021
         DS    0D                      DOUBLE WORD ALIGNMENT            62650021
         DC    CL32'IEWLMIDR MAINTENANCE AREA BEGINS'  AREA IDENTIFIER  62700021
         DC    160X'00'                MAINTAINENCE SPACE               62750021
         DC    CL21'MAINTENANCE AREA ENDS'  END OF AREA IDENTIFIER      62800021
         SPACE                                                          62850021
         IEWAPT                                                         62900021
         END                                                            62950021
