         TITLE    'INCLUDE PROCESSOR AND AUTOMATIC LIBRARY CALL PROC.'  00100000
*                                                                       00200000
*STATUS: CHANGE LEVEL 000                                               00300000
*                                                                       00400000
*FUNCTION/OPERATION:                                                    00500000
*  1-THE INCLUDE PROCESSOR INCLUDES INTO THE CURRENT INPUT A DATA SET   00600000
*    THAT HAS BEEN REQUESTED BY AN INCLUDE STATEMENT.   TO DO THIS,IT   00700000
*    TAKES THE FIRST ITEM OF THE INCLUDE CHAIN AND MAKES IT READY TO BE 00800000
*    READ BY THE INPUT PROCESSOR. THIS ITEM CAN INDICATE A SEQUENTIAL   00900000
*    DATA SET OR A PARTITIONED DATA SET .                               01000000
*       1-A-  IF IT INDICATES A SEQUENTIAL DATA SET, THE ITEM CONTAINS  01100000
*             THE DDNAME, ON WHICH 'OPEN' IS PERFORMED.                 01200000
*             THE DATA SET IS THEN READY TO BE READ BY THE INPUT PRO-   01300000
*             -CESSOR                                                   01400000
*       1-B-  IF IT INDICATES A PARTITIONED DATA SET , THE ITEM CON-    01500000
*             -TAINS THE MEMBER NAME AND A POINTER TO THE DDNAME.       01600000
*             'OPEN' IS PERFORMED ON THE DDNAME. 'BLDL' IS PERFORMED    01700000
*             ON THE MEMBERNAME. 'FIND' POSITIONS TO BEGINNING OF MEM-  01800000
*             -BER                                                      01900000
*    THE INCLUDE PROCESSOR KNOWS AFTER 'OPEN' WHAT DATA SET IS COMING,  02000000
*    BY LOOKING AT THE FIELD 'RECFM' (RECORD FORMAT). THIS DCB FIELD    02100000
*    IS ZEROED BEFORE EACH OPEN ,AND RECEIVES WHAT HAS BEEN SPECIFIED   02200000
*    IN THE DCB FIELD OF THE DDCARD (OR WHAT WAS IN THE DSCB, IF APPLI- 02300000
*    -CABLE)                                                            02400000
*  2-THE AUTOMATIC LIBRARY CALL PROCESSOR (IEWLCAUT), TRY TO RESOLVE    02500000
*    THE EXTERNAL REFERENCES IN THE CESD ,WHICH ARE STILL UNRESOLVED AT 02600000
*    THE END OF THE PRIMARY INPUT STREAM.   IT CALLS FROM PARTITIONED   02700000
*    DATA SETS,MEMBERS WHOSE NAMES ARE THE EXTERNAL REFERENCES IN THE   02800000
*    CESD.                                                              02900000
*          IT BEGINS BY THE EXTERNAL REFERENCES WHOSE CALLS HAVE BEEN   03000000
*    GUIDED (BY MEANS OF A LIBRARY CARD)TOWARDS A SPECIFIED DATA SET.   03100000
*    THESE CALLS ARE MADE DATA SET BY DATA SET, ALL THE CALLS INSIDE    03200000
*    A SINGLE DATA SET BEING MADE CONSECUTIVELY.                        03300000
*          IT CONTINUES WITH THE EXTERNAL REFERENCES NOT GUIDED BY      03400000
*    LIBRARY CARDS ; IT SEARCHES FOR THESE NAMES ON THE STANDARD LIBRA- 03500000
*    -RY WHOSE NAME IS IN THE ALL PURPOSE TABLE . THE STANDARD LIBRARY  03600000
*    DSNAME IS 'SYSLIB' WHEN THE LINKAGE EDITOR GETS CONTROL FROM THE   03700000
*    TASK SCHEDULER ; IT IS THE FOURTH ITEM IN THE PARAMETER LIST WHEN  03800000
*    THE LINKAGE EDITOR IS 'LINKED TO'                                  03900000
*                                                                       04000000
*ENTRY POINTS:                                                          04100000
*    IEWLMINC   FOR THE INCLUDE PROCESSOR                             * 04200000
*    IEWLCAUT   FOR THE AUTOMATIC LIBRARY CALL PROCESSOR                04300000
*                                                                       04400000
*               CALLING SEQ.       L     15,=V(IEWLMINC)              * 04500000
*                                  BALR  14,15                          04600000
*           L     15,=V(IEWLCAUT)                                       04700000
*           BALR  14,15                                                 04800000
*    NO DATA IS PASSED DIRECTLY UPON CALLING,BUT IS FOUND IN OR BY      04900000
*    MEANS OF THE ALL PURPOSE TABLE WHOSE ADDRESS IS CONSTANTLY IN      05000000
*    REGISTER 2                                                         05100000
*                                                                       05200000
*INPUT:   1-ALL PURPOSE TABLE                                           05300000
*         2-ITEMS IN THE CESD:                                          05400000
*********************************************************************** 05500000
*BYTES 0-7*BYT 8*BYT 9*BYT 10-11*BYT 13*BYT 14-15*  DESIGNATION       * 05600000
* SYMBOL  *TYPE *     *         *SUBTYP*         *                    * 05700000
*********************************************************************** 05800000
*MEMBER-  *X'02'* CHAIN ADDRESS *X'D0' * POINTER *CONTROL INCLUDE     * 05900000
*NAME     *     *               *      * TO DDNAM*WITH PTER           * 06000000
*********************************************************************** 06100000
*DDNAME   *X'02'* CHAIN ADDRESS *X'C0' *         *CONTROL INCLUDE     * 06200000
*         *     *               *      *         *WITHOUT PTER        * 06300000
*********************************************************************** 06400000
*DDNAME   *X'02'*               *X'B0' * PTER,IF * DDNAME ITEM        * 06500000
*         *     *               *      * FOR LIB.*                    * 06600000
*********************************************************************** 06700000
*MBER NAME*X'02'*     *REVRS CH-*X'02' *DIRECT CH* UNMATCHED LIBRARY  * 06800000
*         *     *     *AIN PTER *      *AIN PTER * MEMBER             * 06900000
*********************************************************************** 07000000
*MBER NAME*X'02'*     *REVERSE  *X'03' *DCT CHAIN* MATCHED LIBRARY    * 07100000
*         *     *     *CH. PTER *      *PTER     * MEMBER             * 07200000
*********************************************************************** 07300000
*SYMBOL   *X'02'*               *X'04' *         * NO CALL,UNMATCHED  * 07400000
*********************************************************************** 07500000
*SYMBOL   *X'02'*               *X'05' *         * NO CALL,MATCHED    * 07600000
*********************************************************************** 07700000
*SYMBOL   *X'02'*               *X'06' *         * NEVER CALL         * 07800000
*********************************************************************** 07900000
*                                                                       08000000
*         3-THE INFORMATION SLOT BY OPEN IN OUR LIBRARY DCB (IEWLKLDB)  08100000
*         4-THE DIRECTORY ENTRIES OF THE MEMBERS ON WHICH WE BLDL       08200000
*                                                                       08300000
*OUTPUT:                                                                08400000
*   FLAGS IN THE ALL PURPOSE TABLE                                      08500000
*                                                                       08600000
*EXTERNALS ROUTINES                                                     08700000
*   IEWLMLOG   ERROR ROUTINE                                          * 08800000
*   IEWLMADA   ADDRESS ASSIGNMENT                                     * 08900000
*   IEWLMINP   INPUT PROCESSOR                                        * 09000000
*   IEWLMEND   END PROCESSOR                                     A33452 09050020
*                                                                       09100000
*EXITS-NORMAL:                                                          09200000
*           1- RETURN TO THE CALLER EXCEPT IN CASE 2-                   09300000
*           2- WHEN IEWLCAUT (AUTOMATIC LIBRARY CALL)IS CALLED AND NO   09400000
*              EXTERNAL REFERENCE CORRESPONDING TO AN AVAILABLE MEMBER  09500000
*              CAN BE FOUND, CONTROL IS PASSED TO IEWLKADA (ADDRESS)    09600000
*              ASSIGNMENT)                                              09700000
*     -ERROR:                                                           09800000
*********************************************************************** 09900000
*ERR CODE* OTHER PARAMS *    CONDITION CAUSING ERROR                  * 10000000
*IN REG0 *              *                                             * 10100000
*********************************************************************** 10200000
*X'222B' *LIB. DDNNAME  * OPEN UNSUCCESSFUL ON SPECIFIED LIBRARY      * 10300000
*        *ADDR. IN R1   *                                             * 10400000
*********************************************************************** 10500000
*X'3222' *MBR.NAM IN R13* MEMBER NOT FOUND ON LIBRARY                 * 10600000
*        *LIB.NAM IN R1 *                                             * 10700000
*********************************************************************** 10800000
*X'2235' *LIB.NAM IN R1 * OBJECT MODULE BUFFER'S SIZE EXCEEDED        * 10900000
*********************************************************************** 11000000
*X'2233' *LIB.NAM IN R1 * INCL.CRD.INDICATES OBJECT MODULE BUT RECFM=U* 11100000
*********************************************************************** 11200000
*X'2234' *LIB.NAM IN R1 * DATA SET CONTAINS UNACCEPTABLE RECFM (I.E.  * 11300000
*        *              * OTHER THAN F OR U                           * 11400000
*********************************************************************** 11500000
*X'321B' *LIB.NAM IN R1 * LOAD MODULE CANNOT BE PROCESSED BY MODEL E  * 11600000
*        *MBRNAME IN R13* LINK.EDITOR ('DOWNARD UNCOMPATIBILITY')     * 11700000
*********************************************************************** 11800000
*                                                                       11900000
*TABLES/WORK AREAS:                                                     12000000
*                  CESD,APT, PREVIOUSLY MENTIONED                       12100000
*ATTRIBUTES                                                             12200000
*           IEWLCINC IS IN A SEGMENT OF AN OVERLAY STRUCTURE            12300000
*           AS DESCRIBED HERE (TABLES CONSIDERED AS INPUT) IT IS        12400000
*           REUSABLE                                                    12500000
*                                                                       12600000
*NOTES    IEWLMINC CONTAINS THE MACROS CVT,DCBD,DCB,OPEN,               12700000
*            BLDL,FIND,CLOSE                                            12800000
********************                                                    12900000
IEWLMINC CSECT                                                          13000000
* 158050-158070                                                  A21340 13030000
* 449700                                                         A28317 13060000
ERR7LTL  EQU   X'222B'    ERR OPEN FAILED ON SPECIFIED LIBRARY          13100000
ERR8LTL  EQU   X'3222'    ERR.  MEMBER NOT FOUND ON SPECIFIED LIBRARY   13200000
ERR9LTL EQU   X'2235'    ERR  SYSLIN BUFF SIZE EXCEEDED                 13300000
ERR11LTL EQU   X'2233'  L.E. CRD SYNTAX CONFLICTS WITH RECFM OF LIB     13400000
ERR12LTL EQU   X'2234'  SPECIFIED DATA SET CONTAINS NON ACCEPTABLE RCFM 13500000
ERR13LTL EQU   X'321B'     ERROR:'MODULE FROM SPECIFIED LIBRARY CANNOT  13600000
*                          BE PROCESSED BY LEVEL E LINKAGE EDITOR'      13700000
*                          MEMBER NAME AND DDNAME PRINTED               13800000
BLDSIZ   EQU   26      SIZE OF ENTRY IN BLDL LIST                       13850000
APT      EQU   2                                                        13900000
         EXTRN  IEWLCEOD                                                14000000
         EXTRN IEWLCRO1                                                 14100000
         USING APTDSECT,APT                                             14200000
         USING BLDLMBRN,6                                               14250000
         USING  IHADCB,07                                               14300000
         ST    12,8(15)               SAVE BASE OF CALLER               14500000
         BC    15,12(15)                                                14600000
         DC    XL4'00000000'                                            14700000
         BALR  12,0                                                     14800000
         USING *,12                                                     14900000
         BC    15,MODID+6              BRANCH AROUND MODULE IDENT       14930000
MODID    DC    C'03MINC'                                                14960000
INCLU050 STM   13,11,SAVAREA          SAVE OTHER REGISTERS OF CALLER    15000000
         L     07,SYSLIBAD   ADDR OF LIB DCB                            15100000
         NI    IND3,X'DF'   RESET 'AUTO LIB ' TO OFF                    15200000
**********                                                              15300000
*                                                                       15400000
*  CHOOSE IN THE INCLUDE CHAIN THE FIRST ITEM TO BE INCLUDED            15500000
*                                                                       15600000
*                                                                       15700000
INCLU100 L     09,CRRTINCL            INITIATE THE INCLUDE CHAIN BREA-  15800000
         TM    APT2,X'08'              HAS INCLUDE BEEN INITIATED       15801000
        BC    8,INCLU115              NO                                15802000
         TM    IND3,X'10'              IS SINGLE BLDL MODE IN OPERATION 15803000
         BC    1,INCLU115              YES                              15804000
INCLU110 TM    IND3,X'08'              WAS BLDL DONE ON LIST            15809000
        BC    1,GETNEXT1                                                15810000
INCLU115 OI    APT2,X'08'              SET INCLUDE PREVIOUSLY INITIATED 15811000
         CLI   13(9),X'D0'             IS THIS LINE INCL WITH POINTER   15812000
         BC    8,INCLU160              YES                              15813000
         OI    IND3,X'80'              SET PHSICAL SEQUENTIAL ON        15814000
         LR    8,9                                                      15815000
         BAL   14,LIBOP                TO OPEN LIBRARY                  15816000
         BAL   14,NULLINE              TO NULL LINE                     15817000
         ST    9,CRRTINCL              UPDATE CRRTINCL                  15818000
         ST    9,INCBRKPT              AND BREAK POINT                  15819000
         BC    15,INCLU155             TOWARDS INPUT                    15820000
INCLU160 NI    IND3,X'7F'              TURN OFF PHYSICAL SEQUENTIAL IND 15821000
         TM    IND3,X'10'              CHECK FOR SINGLE BLDL MODE       15822000
         BC    8,INCLU168              NO                               15823000
         LA    6,SINGBLDL              ADDRESS OF SINGLE BLDL LIST      15824000
         BC    15,INCLU250                                              15825000
INCLU168 MVC   PTRSAV(2),14(9)         SAVE DDNAME POINTER              15826000
INCLU170 CLI   NUMENT+1,X'00'          FIRST ENTRY IN LIST              15827000
         BC    7,INCLU172              NO                               15828000
         L     6,TABLSTRT              YES--GET START OF TABLE          15829000
         SH    6,ENTSIZ                MAKE IT ONE ENTRY PRIOR          15830000
         BC    15,INCLU180                                              15831000
INCLU172 LH    6,NUMENT                NUMBER OF ENTRIES                15832000
        MH    6,ENTSIZ                TIMES ENTRY SIZE                  15833000
         A     6,TABLSTRT              ADD START OF TABLE               15834000
INCLU171 SH    6,ENTSIZ                GO TO PREVIOUS ENTRY             15835000
         CLC   0(8,6),0(9)             COMPARE NEW ENTRY TO PREVIOUS    15836000
         BC    8,INCLU182              IF EQUAL IGNORE IT               15837000
         BC    4,INCLU180              IS HIGH PUT IT  IN TABLE         15838000
         MVC   BLDSIZ(10,6),0(6)       IF LOW MOVE PREVIOUS ENTRY DOWN  15839000
         C     6,TABLSTRT              CHECK IF END OF TABLE            15840000
         BC    7,INCLU171              NO                               15841000
         SH    6,ENTSIZ                TO MOVE INTO FIRST ENTRY         15842000
INCLU180 MVC   BLDSIZ(8,6),0(9)        MOVE NAME TO LIST                15843000
         LH    5,NUMENT                CURRENT ENTRY NUMBER             15844000
         LA    5,1(0,5)                UPDATE BY ONE                    15845000
         STH   5,NUMENT                SAVE NEW NUMBER                  15846000
         STH   5,BLDSIZ+8(0,6)         IS ALSO SEQUENCE NUMBER          15847000
         TM    IND3,X'20'              IS ENTRY FROM AUTOCALL           15848000
         BC    8,INCLU182              NO--LEAVE SEQUENCE NUMBER IN     15849000
         S     9,CHESD                 YES--SAVE ID INSTEAD             15850000
         SRL   9,4                                                      15851000
         STH   9,BLDSIZ+8(0,6)                                          15852000
INCLU182 TM    IND3,X'20'              IS ENTRY FROM AUTOCALL           15853000
         BC    1,TESTMAX               YES--BYPASS NULL,CHAIN CHECK     15854000
         BAL   14,NULLINE              GO NULL THE LINE                 15855000
         LTR   9,9                     IS THIS END OF CHAIN             15856000
         BC    8,INCLU185              YES                              15857000
TESTMAX  CH    5,MAXENTRY              IS TABLE FULL                    15858000
         BC    8,INCLU185              YES                              15859000
         TM    IND3,X'20'              IS ENTRY FROM AUTOCALL           15860000
         BCR   1,14                    YES--RETURN TO AUTOCALL          15861000
         CLI   13(9),X'D0'             IS NEXT ITEM INCLUE WITH PTR     15862000
         BC    7,INCLU185              NO                               15863000
         LH    5,14(9)                 YES--IS IT SAME POINTER          15864000
         CH    5,PTRSAV                                                 15865000
         BC    8,INCLU172              YES                              15866000
INCLU185 TM    IND3,X'20'              IS AUTO LIB IN OPERATION         15867000
         BC    1,INCLU186              YES                              15868000
         ST    9,CRRTINCL              UPDATE CRRTINCL                  15869000
         ST    9,INCBRKPT              AND BREAK POINT                  15870000
         LH    8,PTRSAV                DDNAME POINTER                   15871000
         SLL   8,4                     TIMES SIXTEEN                    15872000
         A     8,CHESD                 PLUS CESD ADDRESS                15873000
INCLU186 LH    5,NUMENT                MOVE SEQUENCE NUMBERS TO APPEND  15874000
         LA    10,APPEND                                                15875000
        LA    6,BLDLLST                                                 15876000
MOVESEQ  MVC   0(2,10),8(6)                                             15877000
         LA    10,2(0,10)              UPDATE POINTERS                  15878000
         LA    6,BLDSIZ(0,6)                                            15879000
         BCT   5,MOVESEQ               LOOP                             15880000
INCLU175 BAL   14,LIBOP                TO OPEN LIBRARY                  15881000
         TM    IND3,X'40'              ANY OPEN ERROR                   15882000
         BC    8,BUILDLST              NO--DO BLDL                      15883000
         BC    15,GETNEXT5             YES                              15884000
BUILDLST LA    13,REGSA                ADDRESS OF SAVE AREA             15885000
         BLDL  (7),NUMENT              ISSUE BLDL                       15886000
         STC   15,TEMP1                                                 15887000
         CLI   TEMP1,X'08'             CHECK FOR COMPLETION CODE = 8    15888000
         BC    7,BUILDOK               NO--IS OK                        15889000
         LH    5,NUMENT                IS 8 ENSURE ALL ENTRIES IGNORED  15890000
         LA    6,BLDLLST                                                15891000
BUILDBAD MVI   10(6),X'00'                                              15892000
         AH    6,ENTSIZ                                                 15893000
         BCT   5,BUILDBAD                                               15894000
BUILDOK  OI    IND3,X'08'              SET BLDL DONE ON LIST INDICATOR  15895000
         B     GETNEXT1                GO TO READ FIRST MODULE          15896000
GETNEXT  CLC   CURINCNO(1),NUMENT+1    ARE ALL ITEMS IN LIST DONE       15897000
         BC    7,INCLU200              NO                               15898000
GETNEXT5 NI    IND3,X'F7'              YES--TURN OFF BLDL DONE ON LIST  15899000
         MVI   CURINCNO,X'00'          INITIALIZE CURRENT INCLUDE NO    15900000
         MVI   NUMENT+1,X'00'          INITIALIZE NUMBER OF ENTRIES     15901000
         TM    IND3,X'20'              IS AUTO LIB IN OPERATION         15902000
         BC    8,INCLU155              NO--GO CHECK FOR MORE INCLUDES   15903000
         TM    IND3,X'40'              YES--WAS THERE AN ERROR          15904000
         BC    1,AUTOCL1               YES--RETURN TO AUTOCALL          15905000
         BC    15,INCLU201             NO--GO READ MODULE               15906000
GETNEXT1 LA    10,APPEND-2             ADDRESS OF APPENDAGE SEQ NUMBERS 15907000
         SR    6,6                                                      15908000
         IC    6,CURINCNO              UPDATE CURINCNO                  15909000
         LA    6,1(0,6)                                                 15910000
         STC   6,CURINCNO                                               15911000
         TM    IND3,X'20'              IS AUTOLIB IN OPERATION          15912000
         BC    8,GETNEXT9              NO                               15913000
         AR    10,6                    GET ADDRESS OF NEXT ID NUMBER    15914000
         AR    10,6                    REG10 + 2 * REG6                 15915000
         LH    10,0(0,10)              GET ID NUMBER                    15916000
         SLL   10,4                    CONVERT TO CESD ADDRESS          15917000
         A     10,CHESD                                                 15918000
         MVC   TEMP1(1),8(10)          GET TYPE                         15919000
         NI    TEMP1,X'0F'             AND OUT LEFT HALF                15920000
         CLI   TEMP1,X'02'             IS ITEM STILL UNRESOLVED         15921000
         BC    8,GETNEXT8              YES--GO TO READ IT               15922000
         OI    IND3,X'40'              INDICATE MODULE NOT FOUND        15923000
         BC    15,GETNEXT4             NO--GO CHECK FOR MORE IN LIST    15924000
GETNEXT9 SR    6,6                     FIND NEXT ITEM TO BE READ        15925000
GETNEXT2 LA    6,1(0,6)                                                 15926000
         LA    10,2(0,10)                                               15927000
         CLC   CURINCNO(1),1(10)       IS THIS NEXT ITEM TO BE READ     15928000
         BC    7,GETNEXT2              NO--TRY NEXT                     15929000
GETNEXT8 BCTR  6,0                                                      15930000
         MH    6,ENTSIZ                                                 15931000
         A     6,TABLSTRT              ADD START OF TABLE               15932000
         CLI   10(6),X'00'             WAS MODULE FOUND                 15933000
         BC    7,GETNEXT3              YES                              15934000
         LA    14,GETNEXT4             NO--GIVE ERROR MESSAGE           15935000
         ST    14,SAV14L1              PREPARE RETURN ADDRESS           15936000
         LA    8,LIBOPEN               ADDRESS OF DDNAME OPEN           15937000
         BC    15,INCLU615             GO PRINT ERROR MESSAGE           15938000
GETNEXT4 CLC   CURINCNO(1),NUMENT+1    ARE ALL ITEMS IN LIST DONE       15939000
         BC    8,GETNEXT5              YES                              15940000
         BC    15,GETNEXT1             NO--GO CHECK NEXT ONE            15941000
GETNEXT3 TM    IND3,X'20'              IS AUTOCALL ON                   15942000
         BC    8,GETNEXT7              NO                               15943000
         L     8,SAVAD  GET ADDRESS OF DDNAME FOR AUTOCALL OR LIB CALL  15944000
         BC    15,GETNEXT6                                              15945000
GETNEXT7 LH    8,PTRSAV                GET POINTER TO DDNAME            15946000
         SLL   8,4                     POINTER TIMES FOUR               15947000
         A     8,CHESD                 PLUS CESD ADDRESS                15948000
GETNEXT6 BAL   14,LIBOP                CHECK IF LIBRARY STILL OPEN      15949000
         TM    IND3,X'40'              ANY ERROR                        15950000
         BC    1,GETNEXT5              YES--SKIP REST OF LIST           15951000
         LA    14,GETNEXT              PREPARE ADDRESS OF EXIT          15952000
         ST    14,SAV14L1                                               15953000
         BC    15,INCLU602             TO FIND AND PREPARE TO READ      15954000
* AS IEWLCINC IS GIVEN CNTRL, THE CHAIN ADDR. IN THE LINE 'CRRTINCL'    16100000
* IS NECESSERALY NON NULL                                               16200000
NULLINE  MVI   8(9),X'07'              NULLIFY TYPE                     16300000
         MVI   7(09),C','   ALTER THE SYMBOL                            16400000
         MVC   12(4,09),FLCD       STICK NULL LINE TO HOLES CHAIN       16500000
         ST    09,FLCD             UPDATE FLCD                          16600000
         L     9,8(9)   LD CHAIN ADDR (AND TYPE)                        16700000
         LA    9,0(9)   (WIPE TYPE)                                     16800000
         LTR   9,9                     IS POINTER ZERO (END OF CHAIN)   16830000
         BCR   8,14                    YES--RETURN TO CALLER            16860000
         ST    9,CRRTINCL      UPDATE CRRTINCL                          16900000
         TM    IND3,X'20'              IS SINGLE BLDL MODE ON           16930000
         BCR   1,14                    YES--RETURN                      16960000
INCLU120 ST    09,INCBRKPT      INITIATE INCLUDE BREAK POINT            17000000
         BCR   15,14                   RETURN                           17050000
         OI   APT2,X'08'   SET 'INCLUDE PREVIOUSLY INITIATED'           17100000
**                                    ADDR.OF INCLUDE LINE NOW IN  9    17200000
**********                                                              17300000
*                                                                       17400000
*  DETERMINE IF THIS IS THE INCLUDING OF A MEMBER OF A PARTITIONED      17500000
*  DATA SET , OR A PHYSICAL SEQUENTIAL DATA SET                         17600000
*                                                                       17700000
*                                                                       17800000
         CLI   13(09),X'D0'         IS THIS LINE CNTRL.INCL WITH PTER   17900000
         BC    8,INCLU250            YES                                18000000
         OI    IND3,X'80'            SET 'PHYSICAL SEQUENTIAL' ON.      18100000
         LR    8,9             TAKE ADDR.OF THIS LINE AS ADDR.OF -      18200000
*                            - NEWDDNAME SYMBOL                         18300000
**        NEWDDNAME  POINTED TO BY REG. 8                               18400000
**********                                                              18500000
*                                                                       18600000
*  BRANCH TO THE SUBROUTINE LIBOP                                       18700000
*                                                                       18800000
INCLU150 BAL   14,LIBOP                                                 18900000
*                                                                       19000000
*                                                                       19100000
**********                                                              19200000
*                                                                       19300000
*                                                                       19400000
*  SET THE 'INCLUDE' BIT ON IN THE ALL PURPOSE TABLE, IN CASE MORE      19500000
*  INCLUDE WILL HAVE TO BE DONE AFTER THIS ONE .                        19600000
*  THE INPUT PROCESSOR WILL TEST THIS BIT AT THE END OF THE INCLUDED    19700000
*  DATA SET , TO DECIDE IF THE INCLUDE PROCESSOR HAS TO BE GIVEN        19800000
*  CONTROL AGAIN                                                        19900000
*                                                                       20000000
*                                                                       20100000
INCLU155 OC    CRRTINCL(4),CRRTINCL    IS CHAIN ADDRESS 0               20200000
         BC    8,INCLU300      YES                                      20300000
         OI    APT1,X'80'   SET INCLUDE BIT TO 1                        20400000
         TM    IND3,X'40'        WAS MODULE 'NOT FOUND'                 20500000
         BC    1,INCLU100        BR. IF NOT FOUND                       20600000
**********                                                              20700000
*                                                                       20800000
*                                                                       20900000
*  GO TO THE INPUT PROCESSOR                                            21000000
*                                                                       21100000
*                                                                       21200000
INCLU200 TM    IND3,X'08'              WAS BLDL DONE ON LIST            21220000
         BC    8,INCLU201              NO                               21240000
         TM    IND3,X'20'              YES--IS AUTOLIB IN OPERATION     21260000
         BC    1,INCLU201              YES--DON'T SET MORE INCLUDES     21280000
         OI    APT1,X'80'              NO--SET MORE INCLUDES TO COME    21300000
INCLU201 LA    15,INCLU050+8                                            21320000
         SH    15,FOURTEEN                                              21400000
         MVC   SAVAREA+60(4),0(15)                                      21500000
         MVC   SAVAREA+8(4),INPUTPRA                                    21600000
         LM    13,12,SAVAREA                                            21700000
         BCR  15,15                                                     21800000
*                                                                       21900000
*  MAKE DDNAME AND MEMBER NAME AVAILABLE FOR THE LIBOP SUBROUTINE       22000000
*                                                                       22100000
*                                                                       22200000
INCLU250 NI    IND3,X'7F'        RESET  'PHYSICAL SEQUENTIAL' TO 0      22300000
*                             LOOK FOR NEWDDNAME ADDR. :                22400000
         LH    8,14(09)       LOAD  CHAINED ID                          22500000
         SLL   8,4            MULTIPLY ID BY 16                         22600000
         A     8,CHESD             ADD CESD ADDR. MINUS 16              22700000
*          NEWDDNAME  POINTED TO BY REGISTER 8                          22800000
         MVC   BLDLMBRN(8),0(09)   MOVE MBRNAME INTO THE BLDL AREA      22900000
         BAL   14,NULLINE              TO NULL LINE AND UPDATE POINTER  22920000
         C     9,INCBRKPT              HAS BREAK POINT BEEN REACHED     22940000
         BC    7,INCLU150              NO--STAY IN SINGLE BLDL MODE     22960000
         NI    IND3,X'EF'              YES--TURN OFF SINGLE BLDL        22980000
         BC    15,INCLU150                                              23000000
INCLU300 NI    APT1,X'7F'          RESET INCLUDE BIT TO 0               23100000
         NI    APT2,X'F7'              TURN OFF INCLUDE INITIATED BIT   23150000
*                  (WHEN THIS MODULE WILL BE FINISHED, THE INPUT        23200000
*                   PROCESSOR MUST NOT BRANCH TO THE INCLUDE PROC.)     23300000
* (INPUT PROC. WILL HAVE THEN TO SWITCH LIBADRC  TO SYSLIN )            23400000
*  NULLIFICATION OF DDNAME LINE LAST USED                               23500000
*                                                                       23600000
* ONE CANNOT DESTRUCT THE LAST USED DDLINE HERE BECAUSE THIS DDLINE     23700000
* MIGHT BE THE BASE OF A LIBRAARY CHAIN                                 23800000
         TM    IND3,X'40'   WAS THERE A LIBOP FAILURE                   23900000
         BC   8,INCLU310        NO                                      24000000
         NI    APT1,X'DF'  RESET 'LOAD MODULE BIT ' TO 0                24100000
         LA    6,IEWLCRBN                                               24200000
         ST    6,IEWLCLAC         IEWLCLAC TO SYSLIN                    24300000
INCLU310 BC   15,INCLU200   TOWARDS INPUT PROCESSOR                     24400000
*****                                                                   24500000
*                                                                       24600000
*                                                                       24700000
*                                                                       24800000
* SUBROUTINE LIBOP  ,IS COMMON TO INCLUDE PROCESSOR AND ...             24900000
*  ..AUTOMATIC LIBRARY CALL PROCESSOR                                   25000000
*                                                                       25100000
*                                                                       25200000
*                                                                       25300000
* WHEN THE SUBROUTINE LIBOP GETS CONTROL, IT SUPPOSES THAT THE          25400000
* DDNAME IS POINTED TO BY REG. 8 . IF THE DATA SET IS A MEMBER TO FIND  25500000
* IN A LIBRARY , LIBOP ALSO SUPPOSES THE MEMBER NAME IS IN THE          25600000
* BLDL AREA (AT BLDLMBRN).                                              25700000
*   REGISTER  7  CONTAINS THE ADDRESS OF THE LIBRARY DCB                25800000
* LIBOP CHECKS IF THE DATA SET WOULD NOT BE ALREADY OPENED.             25900000
* LIBOP WORKS ON THE 'SYSLIB' DCB WHICH IS IN THE ALL PURPOSE           26000000
* TABLE(APT).THIS DCB CAN BE EITHER PARTIONED OR SEQUENTIAL             26100000
* LIBOP TESTS THE INDICATORS IND3 (OF THIS MODULE) AND APT3(OF THE APT) 26200000
*                                                                       26300000
*                                                                       26400000
LIBOP    ST    14,SAV14L1                                               26500000
*                             SET LIBADRC ON SYSLIB READ CONTROL BLOCK  26600000
         NI   IND3,X'BF'    RESET 'LIBOP FAILURE' TO 0                  26700000
         LA    14,IEWLCRBB             SET IEWLCLAC                     26800000
         ST    14,IEWLCLAC             TO SYSLIB READ BLOCK             26900000
         TM    APT3,X'01'          IS  SYSLIB OPENED ?                  27000000
         BC    8,INCLU350          NO                                   27100000
         TM    IEWLCRBB+24,X'80'   IS THERE AN UNCHECKED READ           27200000
         BC    1,LIBOPA                NO                               27300000
         OI    IEWLCRBB+24,X'88'   YES-INDICATE IGNORE EOF OR ERR       27400000
         L     1,IEWLCRBB          ADDRESS OF SYSLIB DECB               27500000
         LA    13,REGSA                ADDRESS OF SAVE AREA             27600000
         CHECK (1)                                                      27700000
         NI    IEWLCRBB+24,X'F7'   TURN OFF IGNORE BIT                  27800000
LIBOPA   TM    IND3,X'80'              IS PHYSICAL SEQUENTIAL ON        27900000
         BC    1,INCLU320   GO TO CLOSE                                 28000000
         CLC   0(8,8),LIBOPEN        COMPARE NEW DDNAME TO DDNAME OPEN  29000000
         BC   8,INCLU455   BR. IF EQUAL                                 30000000
INCLU320 LA    13,REGSA                ADDRESS OF SAVE AR%A             30100000
         CLOSE ((07))                                                   30300000
         NI   APT3,X'FE'   TURN 'SYSLIB OPENED' TO OFF                  30400000
INCLU350 MVC   0(SPLDCBLG,07),SPLEDCBP   LAY FRESH COPY OF AN           30600000
*                                            UNOPENED PO DCB (THIS      30700000
*                                  ZEROES WHAT NEED TO BE 0 BEFORE OPEN 30800000
         TM    IND3,X'80'           IS 'PHYSICAL SEQUENTIAL' ON         30900000
         BC    8,INCLU450           NO                                  31000000
INCLU400 MVI   DCBDSORG,X'40'       MAKE THE DCB TO BE A PHYS.SEQ. ONE  31100000
         MVC   DCBSYNAD+1(3),SYNADAD+1  MOVE IN SYNAD FOR BSAM          31150000
INCLU450 MVC   DCBDDNAM(8),0(8)     SLOT NEWDDNAME INTO FIELD OF DCB    31200000
         MVC   LIBOPEN(8),0(8)         SAVE DDNAME                      31250000
         LA    13,REGSA        ADDR OF REG SAVE AREA FOR SYSTEM MACRO   31300000
         OPEN  ((07))                                                   31400000
         TM   DCBOFLGS,X'10'  IS OPEN FLG 'ON' IN SYSLIB DCB            31500000
         BC   1,INCLU453     YES                                        31600000
         LR    1,8            DDNAME ADDR.                              31700000
         LH    0,ERR7         ERROR.  OPEN FAILED ON SPECIFIED LIBRARY  31800000
         L     15,ERDIG                                                 31900000
         BALR  14,15                                                    32000000
         NI    APT3,X'FE'   SET 'SYSLIB NOT OPENED'                     32100000
         OI   IND3,X'40'    SET 'LIBOP FAILURE'                         32200000
         BC   15,INCLU610   TO EXIT OF LIBOP                            32300000
INCLU453 OI   APT3,X'01'   SET 'SYSLIB OPENED'                          32400000
INCLU455 MVC  TEMP1(1),DCBRECFM                                         32500000
         NI    TEMP1,X'C0'    SAVE ONLY F OR U INDICATORS               32600000
         CLI   TEMP1,X'C0'    IS IT A  U FORMAT                         32800000
         BC    8,INCLU500      YES                                      32900000
         CLI   TEMP1,X'80'   IS IT A 'F' FORMAT                         33000000
         BC    8,INCLU460    YES                                        33100000
         LH    0,ERR12    ERROR CODE INTO 0                             33200000
         LR    1,8                                                      33300000
         L     15,ERDIG                                                 33400000
         BALR  14,15                                                    33500000
         OI    IND3,X'40'    SET FAILURE BIT 'ON'                       33600000
         BC    15,INCLU610      EXIT OF LIBOP                           33700000
INCLU460 NI    APT1,X'DF'              RESET LOAD MOD BIT TO ZERO       33800000
         MVI   IEWLCRBB+19,X'01'   INDICATE TO PRIME BUFFERS            33900000
         OI    IEWLCRBB+24,X'80'                                        34000000
         TM    IEWLCRBB+24,X'04'   WAS BLOCK SIZE OK                    34100000
         BC    8,INCLU550              YES                              34200000
         LH    0,ERR9                  NO--GIVE ERROR MESSAGE           34300000
         BC    15,INCLU510                                              34400000
INCLU500 TM    IND3,X'80'  DOES CONTROL CARD ANNOUNCES PHYS.SEQ.        34500000
         BC    8,INCLU520     NO                                        34600000
         LH    0,ERR11    ERR CODE,SEVERITY,DISPOSITION,INTO 1          34700000
INCLU510 LR    1,8      ADDR OF DDNAME INTO 1                           34800000
         L     15,ERDIG                                                 34900000
         BALR  14,15    BR TO ERR ROUTINE                               35000000
         OI    IND3,X'40'   SET LIBOP FAILURE                           35100000
         BC    15,INCLU610   TO EXIT OF LIBOP                           35200000
INCLU520 OI    APT1,X'20'  SET BIT 'LOAD MODULE'TO ONE                  35300000
INCLU550 EQU   *                                                        35400000
INCLU600 TM    IND3,X'80'         IS THE DATA SET PHYSICAL SEQUENTIAL   35500000
         BC    1,INCLU610         YES                                   35600000
         TM    IND3,X'10'              IS SINGLE BLDL MODE ON           35630000
         BC    8,INCLU610              NO--RETURN                       35660000
         LA    13,REGSA        ADDR OF REG SAVE AREA FOR SYSTEM MACRO   35700000
        BLDL  (7),BLDLDES1                                              35800000
         XI    *+1,X'FF'        ***DEBUG TOKEN ***                      35900000
         LTR   15,15              TEST RETURN CODE IN 15                36000000
         BC    7,INCLU615         BR.IF MODULE SEARCH NOT SUCCESSFUL    36100000
INCLU602 NI    IND3,X'BF'              RESET MODULE NOT FOUND BIT       36200000
         TM    APT1,X'20'                                        A26878 36210000
         BC    8,INCLU605                                        A26878 36220000
         TM    BLDLATT2,X'01'      IS INC MODULE REFRESHABLE            36250000
         BC    8,INCNREFR           NO                                  36300000
INCLU601 TM    APT1,X'20'          IS COMING MODULE A LOAD MODULE       36350000
         BC    8,INCLU605   NO                                          36400000
*            LOGIC  FOR  THE OUTPUT DIRECTORY                           36500000
         OI    BLDLATT1,X'3F'                                           36600000
         NC    PDSE7(1),BLDLATT1                                        36700000
         TM    BLDLATT2,X'08'   IS MODULE NOT EDIT ABLE                 36800000
         BC    8,INCLU605                                               36900000
INCLERNE LH    0,ERR13    ERR CODE IN REG 0                             37000000
         LA    13,BLDLMBRN    ADDR. OF MBER NAME INTO 13                37100000
         BC    15,INCLU510    TO ERROR AND LIBOP FAILURE EXIT           37200000
INCNREFR NI    PDSE8,X'FE'         IF INC MODULE IS NOT REFRESHABLE     37220000
*                         THEN ENTIRE LOAD MODULE WILL NOT BE.        * 37240000
         B     INCLU601                                                 37260000
INCLU605 LA    13,REGSA       ADDR OF REG SAVE AREA FOR SYSTEM MACRO    37300000
         FIND  (7),BLDLTTR1,C                                           37400000
INCLU610 L     14,SAV14L1                                               37500000
         BCR   15,14             RETURN FROM THIS SUBROUTINE LIBOP      37600000
*                                                                       37700000
*****                                                                   37800000
INCLU615 OI    IND3,X'40'     SET 'MODULE NOT FOUND' BIT TO 1           37900000
         TM    IND3,X'20'    IS THIS AUTO LIB                           38000000
         BC    7,INCLU610       YES, TO EXIT OF LIBOP                   38100000
         LH    0,ERR8                                                   38200000
         LR    1,8                 DDNAME   ADDR                        38300000
         LA   13,BLDLMBRN      MEMBER NAME ADDR.                        38400000
         L     15,ERDIG                                                 38500000
         BALR  14,15                                                    38600000
         ST    10,SAVE10               SAVE CONTENTS OF REG 10   A33452 38608020
         L     10,RCCB                 ADDR OF CHNG/REPL CHAIN   A33452 38616020
         LTR   10,10                   DOES IT CONTAIN ZEROS?    A33452 38624020
         BZ    INCLU620                YES - BRANCH              A33452 38632020
         LR    10,12                   SAVE BASE IN REG 10       A33452 38640020
         LA    13,REGSA                ADDR OF SAVE AREA         A33452 38648020
         L     15,ENDADDR              ADDR OF IEWLMEND          A33452 38656020
         BALR  14,15                   GO TO DELETE CHNG/REPL    A33452 38664020
*                                      CHAIN FROM THE CESD       A33452 38672020
         LR    12,10                   RESTORE BASE REG          A33452 38680020
INCLU620 L     10,SAVE10               RESTORE REG 10            A33452 38688020
         BC    15,INCLU610    TOWARD RETURN FROM LIBOP                  38700000
         ENTRY IEWLCAUT                                                 38800000
         CNOP  0,4                                                      38900000
IEWLCAUT S    15,16(15)      SET 15 AT ADDRESS VALUE OF IEWLCINC        39000000
         ST    12,8(15)      PASS VALUE OF REG. 12                      39100000
          LA    12,14(15)   PUT IN 12 THE ADDRESS CORRESP. TO THE       39200000
*                      UNIQUE 'USING' STATEMENT OF THIS CSECT           39300000
         BC    15,*+8                                                   39400000
         DC    A(IEWLCAUT-IEWLMINC)                                     39500000
         STM   13,11,SAVAREA                                            39600000
         L     07,SYSLIBAD   ADDR OF LIBRARY DCB                        39700000
         OI    IND3,X'20'    SET 'AUTO LIB '  ON                        39800000
         TM    IND3,X'08'              WAS BLDL DONE ON LIST            39830000
         BC    1,GETNEXT1              YES--GO GET NEXT MODULE          39860000
         NI   IND3,X'7F'     SET PHYSICAL SEQUENTIAL TO 0               39900000
AUTOCL1  L     4,CHESD                                                  40000000
         LH    3,ENCDC             INITIALIZE COUNT FOR CESD SCAN       40100000
         LTR   3,3                                                      40200000
         BC    8,INCLU710              BRANCH IF NOTHING IN CESD        40400000
         TM    APT0,X'01'              WAS A LIBRARY CARD READ          40600000
          BC    8,INCLU670   NO                                         40900000
*                                                                       41000000
*                                                                       41100000
*   ESD SCANNING TO FIND DDNAMES WITH POINTER                           41200000
*                                                                       41300000
*                                                                       41400000
*                                                                       41500000
INCLU630 LA    4,16(4)                                                  41600000
         MVC   TEMP1(1),8(4)    TAKE TYPE FIELD OF THIS LINE            41700000
         NI    TEMP1,X'0F'      CLEAR INFORMATION OTHER THAN TYPE       41800000
         CLI   TEMP1,X'02'      IS TYPE  ER                             41900000
         BC    7,INCLU660       BR.IF NOT                               42000000
         CLI   13(4),X'B0'     IS SUBTYPE DDNAME                        42100000
         BC    7,INCLU660       BR.IF NOT                               42200000
         LH    15,14(4)         LOAD THE 2 BYTE PTER TO LIB.MBER        42300000
         LTR   15,15            IS IT NULL                              42400000
         BC    8,INCLU640       BR IF YES   GO TO NULLIFY THIS DDNAMLIN 42500000
INCLU635 SLL   15,4             MULTIPLY  THE PTER BY 16                42600000
         A     15,CHESD            ADD ADDR. OF CESD MINUS 16           42700000
         MVC   TBPTRSAV(2),14(15)  SAV.PTR.FOUND IN LINE JUST REACHED   42800000
         CLI   13(15),X'03'        IS THIS A MATCHED LIBR.MBR.          42900000
         BC    7,INCLU650      BR. IF NOT                               43000000
         TM    9(15),X'80'   HAS A BLDL ALREADY BEEN DONE ON THIS       43100000
*                                  MEMBER                               43200000
         BC    1,INCLU650          BR. IF YES                           43300000
         OI    9(15),X'80'   SET BIT 'BLDL ALREADY ATTEMPTED'           43400000
         LR    8,4    PTER TO DDNAME IN 8 FOR LIBOP SUBROUTINE          43600000
         ST    8,SAVAD                 SAVE DDNAME ADDRESS              43650000
         LR    9,15                    ADDRESS OF MEMBER NAME INTO 9    43750000
         BAL   14,INCLU170             GO PUT NAME IN LIST              43850000
         B     INCLU650                GO CHECK FOR END OF CESD         43950000
INCLU640 MVI   8(4),X'07'          MAKE TYPE'NULL'                      44100000
         XC    0(8,4),0(4)         MAKE SYMBOL BINARY ZEROS             44200000
         MVC   12(4,4),FLCD        STICK THIS LINE TO HOLES CHAIN       44300000
         ST    4,FLCD              UPDATE HOLES CHAIN BEGIN ADDR        44400000
         BC    15,INCLU660                                              44500000
INCLU650 LH    15,TBPTRSAV         IS THE SAVED TWO BYTES PTER =0       44600000
         LTR   15,15                                                    44700000
         BC    7,INCLU635          BR. IF NOT                           44800000
         CLI   NUMENT+1,X'00'          ANY ITEMS LEFT IN BLDL LIST      44930000
         BC    7,INCLU186              YES--GO PURGE THEM               44960000
INCLU660 BCT   3,INCLU630              LOOP TO TAKE NXT CESD LNE A28317 44970000
* (THIS LINE WAS NOT PROPERLY CHANGED TO FIX A21451 FOR RELEASE 18)     44980000
*                                                                       45000000
*                                                                       45100000
* ESD SCANNING TO FIND PURE ER'S                                        45200000
*                                                                       45300000
*                                                                       45400000
INCLU670 L     4,CHESD             INITIATE SCAN FOR ...                45500000
         LH    3,ENCDC             STANDARD(SYSLIB) LIBRARY CALLS       45600000
         LA    8,LIBNAME           FIX SYSLIB AS NEW DDNAME             45700000
         ST    8,SAVAD                 SAVE DDNAME ADDRESS              45750000
INCLU680 LA    4,16(4)             SCAN CESD                            45800000
         MVC   TEMP1(1),8(4)       TAKE TYPE FIELD FROM THIS LINE       45900000
         NI    TEMP1,X'0F'         CLEAR INFORMATION OTHER THAN TYPE    46000000
         CLI   TEMP1,X'02'         IS TYPE ER                           46100000
         BC    7,INCLU700      BR. IF NOT                               46200000
         CLI   13(4),X'00'         IS SUBTYPE NULL (ONLY ONE TO BE CALL 46300000
*                                  FROM SYSLIB)                         46400000
         BC    7,INCLU690          BR.IF NOT                            46500000
         TM    9(4),X'80'         A BLDL PREVIOUSLY ATTEMPTD FOR MBER ? 46600000
         BC    1,INCLU700           BR.IF YES                           46700000
         OI    9(4),X'80'           MARK THIS MBER 'BLDL PREVLY ATTPTD' 46900000
         LR    9,4                     ADDRESS OF MEMBER NAME INTO 9    47000000
         BAL   14,INCLU170             GO PUT NAME IN LIST              47100000
         BC    15,INCLU700             GO CHECK FOR END OD LIST         47200000
INCLU690 CLI   13(4),X'90'          IS SUBTYPE 'CONTROL OVERLAY'        47500000
         BC    7,INCLU700           BR.IF NOT                           47600000
         MVI  8(4),X'07'   NULLIFY THE LINE                             47700000
*TO ZEROE THE SYMBOL WOULD TAKE ME TIME. THE SYMB HAS FEW CHANCE TO BE  47800000
* MATCHED BY ESD PROC. IF IT IS,NULL TYPE WILL LEAD TO NO CONFUSION     47900000
         MVC   12(4,4),FLCD        STICK THIS LINE TO THE HOLE CHAIN    48000000
         ST    4,FLCD              UPDATE FLCD                          48100000
INCLU700 BCT   3,INCLU680          TAKE NXT ELT.OF THE CESD             48200000
         CLI   NUMENT+1,X'00'          ANY ITEMS LEFT IN BLDL LIST      48230000
         BC    7,INCLU186              YES--GO PURGE THEM               48260000
INCLU710 LA    6,IEWLCRBN                                               48400000
         ST    6,IEWLCLAC                                               48500000
* THE SYSLIN READ BLOCK                                                 48600000
         L     15,RATADD               GO TO TXT/RLD FOR PURGE          48620000
         OI    NEWSW,X'01'             INDICATE PURGE TO TXT/RLD        48640000
         BALR  14,15                                                    48660000
         USING *,15                    RETURNS ON 15                    48680000
         L     15,ADRASSEY                                              48700000
         DROP  15                                                       48800000
         BCR   15,15               GO TO  ADDRESS ASSIGNMENT            48900000
         DS    0F                                                       49000000
SAVAREA  DC    16F'0'                                                   49002000
SAV14L1  DC    F'0'                                                     49004000
SAVE10   DC    F'0'                                              A33452 49005020
         EXTRN IEWLMLDB                                                 49006000
        EXTRN IEWLCADA                                                  49008000
         EXTRN APTEXLST                                                 49010000
INPUTPRA DC    V(IEWLMINP)                                              49012000
ENDADDR  DC    V(IEWLMEND)                                       A33452 49013020
SYSLIBAD DC    A(IEWLMLDB)                                              49014000
ERR7     DC    AL2(ERR7LTL)                                             49016000
ERR8     DC   AL2(ERR8LTL)                                              49018000
ERR9     DC    AL2(ERR9LTL)                                             49020000
ERR11    DC    AL2(ERR11LTL)                                            49022000
ERR12    DC    AL2(ERR12LTL)                                            49024000
ERR13    DC    AL2(ERR13LTL)                                            49026000
FOURTEEN DC    X'000E'                                                  49028000
TBPTRSAV DC    X'0000'                                                  49030000
TEMP1    DC    X'00'                                                    49032000
IND3     DC    X'00'                   SWITCHES                         49034000
*              X'80'  PHYSICAL SEQUENTIAL                               49036000
*              X'40'  MODULE NOT FOUND                                  49038000
*              X'20'  AUTOLIB IN OPERATION                              49040000
*              X'10'  SINGLE BLDL IN OPERATION                          49042000
*              X'08'  BLDL DONE ON LIST                                 49044000
*              X'04'  BLDL LIST FULL                                    49046000
         DS    0F                                                       49048000
SPLEDCBP DCB   DSORG=PO,MACRF=(R),EODAD=IEWLCEOD,SYNAD=IEWLCRO2,       X49050000
               LRECL=80,EXLST=APTEXLST                                  49052000
DCBPNDM1 EQU   *                                                        49054000
SPLDCBLG EQU   DCBPNDM1-SPLEDCBP       LENGTH OF DCB                    49056000
         EXTRN IEWLCRO2                                                 49058000
SYNADAD  DC    A(IEWLCRO1)                                              49060000
ADRASSEY DC    V(IEWLMADA)             ADDRESS OF ADDRESS ASSIGNMENT    49062000
RATADD   DC    V(IEWLMRAT)             ADDRESS OF TXT/RLD PROCESSOR     49064000
NUMENT   DC    H'00'                   NUMBER OF ENTRIES IN LIST        49066000
ENTSIZ   DC    H'26'                                                    49068000
BLDLLST  DC    260C' '                                                  49070000
MAXENTRY DC    H'10'                   MAXINUM NUMBER OF ENTRIES        49072000
APPEND   DS    20C                                                      49074000
SAVAD    DS    1F                                                       49076000
TABLSTRT DC    A(BLDLLST)                                               49078000
PTRSAV   DC    H'0'                    SAVE POINTER TO DDNAME           49080000
CURINCNO DC    X'00'                   CURRENT ITEM BEING READ          49082000
         DS    0H                                                       49084000
BLDLDES1 DC    X'0001' 1ST BYTE OF LIST DESCRIPTION FIELD (NO OF ENTR.) 49100000
BLDLDES2 DC    X'0036' 2ND BYTE OF LIST DESCRIPTION FIELD (LGTH OFEACH) 49200000
SINGBLDL DC    26C' '                                                   49220000
PATCHARE DC    50F'0'                  TEMPORARY PATCH AREA             49240000
DUMMY    DSECT                                                          49260000
BLDLMBRN DC    XL8'00'   MEMBER NAME                                    49300000
BLDLTTR1 DC    XL4'00'   TTR OF FIRST RECORD OF PDS & CONCAT.NO.        49400000
BLDLZEUS DC    XL2'00'   ZERO BYTE (JOB/LINK LIB.IND.) AND USER DESCR.  49500000
BLDLTTR2 DC    XL4'00'   TTR OF FIRST TEXT RECORD AND ZERO              49600000
BLDLTTR3 DC    XL3'00'   TTR OF NOTE LIST OR SCAT.TRANS.TBL.            49700000
BLDLN0NL DC    XL1'00'   NO OF ENTRIES IN NOTE LIST (OR ZERO)           49800000
BLDLATT1 DC    XL1'00'   FIRST BYTE OF ATTRIBUTES                       49900000
*                      BIT 0   , X'80'    REENTERABLE                   50000000
*                      BIT 1   , X'40'    REUSABLE                      50100000
*                      BIT 2   , X'20'    OVERLAY                       50200000
*                      BIT 3   , X'10'    IN TEST                       50300000
*                      BIT 4   , X'08'    ONLY LOADABLE                 50400000
*                      BIT 5   , X'04'    BLOCK-SCATTER (BLOCK=0)       50500000
*                      BIT 6   , X'02'    EXECUTABLE                    50600000
*                      BIT 7   , X'01'    MOD.CONTAINS 1 TXT RCD,NO RLD 50700000
BLDLATT2 DC    XL1'00'   SECOND BYTE OF ATTRIBUTES                      50800000
*                      BIT 0   , X'80'   NO DOWNWARD COMPATIBILITY IF=1 50900000
*                      BIT 1   , X'40'   ORIGIN OF 1ST TXT RCD IS ZERO  51000000
*                      BIT 2   , X'20'   LINK.EDIT.ASSIGND ENTR.PT.=0   51100000
*                      BIT 3   , X'10'   MOD.CONTAINS RLD ITEMS         51200000
*                      BIT 4   , X'08'   MOD.CAN BE REPROCESSED BY LKED 51300000
*                      BIT 5   , X'04'   MOD.DOES'NT CONTAIN SYM CARDS  51400000
BLDLE9   DC   XL3'00' TOTAL MAIN STORAGE REQUIREMENT OF THIS MODULE     51500000
BLDLE10  DC   XL2'00' LENGTH OF FIRST TXT RECORD                        51600000
BLDLE11  DC   XL3'00' ENTRY POINT ADDRESS                               51700000
BLDLE12  DC   XL3'00' ORIGIN OF FIRST TXT RECORD                        51800000
*                                                                       51900000
BLDLE13  DC    XL2'00'      NO. OF BYTES IN SCATTER LIST                52000000
BLDLE14  DC    XL2'00'      NO. OF BYTES IN THE TRANSLATION TBLE        52100000
BLDLE15  DC    XL2'00'      ESDID OF THE 1ST TXT RCD                    52200000
BLDLE16  DC    XL2'00'      ESDID OF THE CONTR.SECT.CONTAINING ENTRY PT 52300000
*                                                                       52400000
BLDLE17  DC    XL3'00'      ENTRY PT OF MAIN MBER NAME                  52500000
BLDLE18  DC    XL8'00'      MEMBER NAME OF MODULE                       52600000
*  SAMPLE DCB FOR A PARTIONED ORGANISATION TO BE READ                   52700000
         DS    0F                                                       52800000
         IEWAPT                                                         55700000
         DCBD  DSORG=(PS,PO)                                            55900000
         END                                                            56000000
