         TITLE    'CROSS REFERENCE AND MODULE MAP'                      00100000
IEWLMMAP CSECT                                                          00200000
* 084600,191600,316000,349000,437600,588600,602000,689000        S20007 00250020
*A051000,674000,786000                                           A41571 00260021
*C134000-135000                                                  A41571 00270021
*                                                                     * 00300000
*THIS CSECT IS CALLED IF MAP OR XREF IS SPECIFIED.                    * 00400000
*IT PRODUCES THE REQUESTED DATA.                                      * 00500000
*                                                                     * 00600000
*ENTRY ONLY AT IEWLMMAP BY ANY MEANS                                  * 00700000
*                                                                     * 00800000
*INPUT: SYSLMOD LOAD MODULE                                           * 00900000
*                                                                     * 01000000
*OUTPUT: MAP ON PRINTER                                               * 01100000
*                                                                     * 01200000
*EXIT: NORMAL RETURN                                                  * 01300000
*                                                                     * 01400000
*XCESDTAB IS THE ADDRESS OF THE TABLE WHERE COMPOSITE ESD ENTRIES     * 01500000
*ARE COLLECTED (16-BYTE ENTRIES).                                     * 01600000
*XADDCESD IS THE ADDRESS OF THE TABLE OF ADDRESSES FROM ESD ENTRIES   * 01700000
*FOR THE PRESENT SEGMENT (4-BYTE ENTRIES).                            * 01800000
*XAD2CESD IS THE ADDRESS OF THE TABLE CORRESPONDING TO XADDCESD CON-  * 01900000
*TAINING RESPECTIVE ENTRY NUMBERS (2-BYTE ENTRIES).                   * 02000000
*RLDIN IS RLD INPUT BUFFER.                                           * 02100000
*PRLIN IS PRINT OUTPUT BUFFER.                                        * 02200000
*PRHDR IS SAVED HEADER BUFFER.                                        * 02300000
*                                                                     * 02400000
*REUSABLE                                                             * 02500000
*                                                                     * 02600000
R0       EQU   0                                                        02700000
R1       EQU   1                                                        02800000
RPAR     EQU   1                                                        02900000
RJ       EQU   1                                                        03000000
APT      EQU   2                                                        03100000
RD       EQU   3                                                        03200000
RENTRY   EQU   4                                                        03300000
RI       EQU   4                                                        03400000
RPLACE   EQU   4                                                        03500000
RF       EQU   5                                                        03600000
RST      EQU   5                                                        03700000
RST2     EQU   6                                                        03800000
RG       EQU   6                                                        03900000
RWORK    EQU   7                                                        04000000
RH       EQU   7                                                        04100000
RIN      EQU   7                                                        04200000
RA       EQU   8                                                        04300000
RB       EQU   9                                                        04400000
RE       EQU   10                                                       04500000
RC       EQU   11                                                       04600000
RBASE    EQU   12                                                       04700000
RSAVREG  EQU   13                                                       04800000
R14      EQU   14                                                       04900000
R15      EQU   15                                                       05000000
         EXTRN IEWLCMDB                                                 05100000
         EXTRN APTXLIST                ADDRESS OF OPEN EXIT LIST A41571 05130021
         ENTRY JFCBADDR                ADDRESS OF SYSLMOD JFCB   A41571 05160021
ALBIT    EQU   X'80'                                                    05200000
XREFBIT  EQU   X'40'                 BIT SET FOR XREF OPTION            05300000
OVERBIT  EQU   X'20'                 OVERLAY BIT                        05400000
ESDIND   EQU   X'20'                 ESD INDICATOR                      05500000
PRIVCODE EQU   X'04'                 PRIVATE CODE                       05600000
HEXTEN   EQU   X'10'                 HEXADECIMAL TEN FOR CONVERSION     05700000
DECTEN   EQU   X'0A'                 DECIMAL TEN FOR CONVERSION         05800000
PRIVDEL  EQU   X'14'                 CODE FOR ENTAB AND SEGTAB          05900000
NEVCALL  EQU   X'06'                 NEVER CALL BITS                    06000000
CUMLNREQ EQU   X'30'                    FLAG FOR CUM PSEUDO REG LN REQ  06100000
EOMOD    EQU   X'08'                 END OF MODULE BIT                  06200000
SKIP     EQU   X'0B'                   IMMEDIATE SPACE                  06260000
SINGLE   EQU   X'09'                   PRINT AND SPACE                  06320000
DOUBLE   EQU   X'11'                   PRINT AND SPACE 2                06380000
TRIPLE   EQU   X'19'                   PRINT AND SPACE 3                06440000
SKIP2    EQU   X'13'                   IMMEDIATE SPACE 2                06500000
SKIP3    EQU   X'1B'                   IMMEDIATE SPACE 3                06560000
RESTORE  EQU   X'8B'                   SKIP TO CHANNEL 1                06620000
TSO      EQU   X'80'                   TSO SWITCH IN APTSWS      S20007 06660020
         USING *,R15                 SET UP BASE ADDRESSABILITY         06700000
         USING APTDSECT,APT       ESTABLISH ADDRESSABILITY FOR APT      06800000
START    EQU   *                     FOR LATER STATEMENT OF BASE ADDR   06900000
         BC    15,MODID+6              BRANCH AROUND MODULE IDENT       06950000
MODID    DC    C'05MMAP'                                                07000000
         NC    ENCDC(2),ENCDC          TEST FOR NO ESDS                 07050000
         BC    7,MAP000                                                 07100000
         BR    R14                     RETURN                           07200000
MAP000   EQU   *                                                        07400000
         OI    NEWSW,X'10'             INDICATE MAP/XREF IN OPERATION   07450000
         STM   R14,RBASE,SPACES+12 SAVE REG                             07500000
         LR    RBASE,R15             LOAD PERMANENT BASE                07600000
         USING START,RBASE           PROPER USING                       07700000
         DROP  R15                   OLD BASE                           07800000
         LA    RSAVREG,REGSA      LOAD SAVE AREA ADDRESS                07900000
         EJECT                                                          08000000
*                                                                       08100000
*        THIS PROGRAM PRODUCES A MEMORY MAP AND A CROSS REFERENCE       08200000
*        TABLE AS SUPPLEMENTARY OUTPUT FROM THE LINKAGE EDITOR          08300000
*                                                                       08400000
         TM    APTSWS,TSO          TSO MODE?                     S20007 08410020
         BZ    TSO1               NO - BRANCH                    S20007 08420020
         LA    RA,40               CHANGE LINE COUNTS            S20007 08430020
         STH   RA,COUNT                                          S20007 08440020
         LA    RA,20(RA)                                         S20007 08450020
         STH   RA,COUNT2                                         S20007 08460020
TSO1     LH    RA,ENCDC            NUMBER OF CESD ENTRIES        S20007 08470020
         LA    RA,20(0,RA)             ADD SAFETY FACTOR                08520000
         TM    NEWSW,X'40'             IS ENTRY FROM INTERMEDIATE       08540000
         BC    8,ALLOC                 NO--DO GETMAIN FOR CESD          08560000
         L     R1,CHESD                YES--USE CESD IN CORE            08580000
         LA    R1,16(0,R1)             INCREMENT TO FIRST ENTRY         08600000
         B     ALLOCA                                                   08620000
ALLOC    LH    R0,ENCDX                MAXIMUM NUMBER OF ENTRIES        08640000
         SLL   R0,4                  MULTIPLY BY SIXTEEN                08700000
         ST    R0,SAVMAIN            SAVE LENGTH OF AREA OBTAINED       09200000
         L     R1,CHESD                USE CESD FOR TABLES              09300000
ALLOCA   ST    R1,XCESDTAB             STORE ADDRESS OF CESD            09350000
         LH    R1,ENR1C                NO. OF ENTRIES IN RLD NOTELIST   09400000
         MH    R1,RLDNTSZ              TIMES BYTES PER ENTRY            09450000
         L     R0,RNT1                 INITIALIZE SAVRLDNT              09500000
         AR    R1,R0                                                    09550000
         ST    R1,RLDNTEND             SAVE END ADDRESS                 09600000
         SH    R0,RLDNTSZ              ONE ENTRY BEFORE BEGINNING       09650000
         ST    R0,SAVRLDNT                                              09700000
         LM    R0,R1,IEWLCRBB+4        ADDRESSES OF SYSLIB OBJ BUFFERS  09750000
         CR    R0,R1                   USE LOWER ADDRESS AS START       09800000
         BNH   ALLOCB                       FOR WORK AREA               09850000
         LR    R0,R1                                                    09900000
ALLOCB   ST    R0,XAD2CESD                                              09950000
*                                                                       10100000
*        FIRST, A HEADER IS PUT OUT WITH A SKIP TO ONE.                 10200000
*                                                                       10300000
         MVI   CNTLCH,SKIP2            SKIP TWO LINES                   10400000
         TM    APTSWS,TSO          TSO MODE?                     S20007 10430020
         BC    1,MAP0005           YES - BRANCH                  S20007 10460020
         MVC   LINCOUNT+1(1),LINECNT+1  INITIALIZE LINE COUNTER         10500000
         CLI   LINCOUNT+1,X'0A'      TEST FOR ROOM ON PAGE              10600000
         BC    3,MAP0005             NO                                 10700000
         MVI   CNTLCH,RESTORE          RESTORE PAGE CHARACTER           10800000
         MVI   LINCOUNT+1,NUMBLINS+2   SET LINE COUNTER                 10900000
MAP0005  EQU   *                                                        11000000
         BAL   R14,CNTRL               TO CARRIAGE CONTROL ROUTNIE      11050000
         TM    APT0,XREFBIT       TEST FOR XREFS                        11100000
         BC    3,PUTHC               PUT XREF HDR                       11200000
         MVC   PRLIN+55(10),TOPHDM   NO  PUT MAP HEADER                 11300000
         B     PUTHEAD               PUT HEADER                         11400000
TOPHDM   DC    C'MODULE MAP'         MAP HEADER                         11500000
TOPHDC   DC    C'CROSS REFERENCE TABLE'                                 11600000
SGHD     DC    C'NAME    ORIGIN  LENGTH  SEG. NO.'                      11700000
SEGHD    EQU   SGHD+24               ADDR OF WORDS SEG. NO.             11800000
NAMLOC   DC    C'NAME   LOCATION'                                       11900000
PUTHC    MVC   PRLIN+49(21),TOPHDC   MOVE IN XREF HEADER                12000000
PUTHEAD  LA    R15,PUTLINS                                              12100000
         L     RD,DCBLMOD            LOAD ADDRESS OF DCB                12200000
         MVI   PRLIN,DOUBLE            PRINT AND SPACE 2                12250000
         BALR  R14,R15               CALL PRINT SUBROUTINE              12300000
         TM    NEWSW,X'40'             IS ENTRY FROM INTERMEDIATE       12360000
         BC    1,L1OUT                 YES--BYPASS READ                 12420000
*                                                                       12500000
*        END OF DATA EXIT IS REPLACED BY SPECIAL ONE FOR THIS CSECT.    12600000
*                                                                       12700000
         MVC   SAVEODAD(3),33(RD)    SAVE END OF DATA ADDRESS           12800000
         MVC   33(3,RD),SPECEOD      LOAD SPECIAL ADDRESS               12900000
MAPPOINT CLOSE ((RD))                CLOSE SYSLMOD FOR OUTPUT           13300000
         TM    JFCBADDR,X'80'          IS SYSLMOD OPEN J REQUIRD A41571 13320021
         BZ    NORMLOPN                NO--BRANCH                A41571 13340021
         GETMAIN EU,LV=200,A=JFCBADDR  GETMAIN AN AREA FOR JFCB  A41571 13360021
         L     1,XLSTADDR              GET SYSLMOD EXIT LST ADDR A41571 13380021
         MVC   5(3,1),JFCBADDR+1       JFCB AREA ADDR TO EXT LST A41571 13400021
         RDJFCB ((RD),(INPUT))         ISSUE RDJFCB FOR SYSLMOD  A41571 13420021
         L     6,JFCBADDR              LOAD JFCB ADDR INTO REG   A41571 13440021
         MVC   44(8,6),PDSE1           MOVE MEM NAME INTO JFCB   A41571 13460021
         OI    52(6),X'08'             INHIBT JFCB RETRN TO JOBQ A41571 13480021
         OPEN  ((RD),(INPUT)),TYPE=J   OPEN J SYSLMOD FOR INPUT  A41571 13500021
         B     ARNDOPN                 BYPASS NORMAL OPEN        A41571 13520021
NORMLOPN OPEN  ((RD))                  OPEN SYSLMOD FOR INPUT    A41571 13540021
ARNDOPN  LA    R0,CTTR                 LOAD DCB ADDRESS          A41571 13560021
         POINT (RD),(0)              POINT TO FIRST ESD                 13600000
         L     RIN,XCESDTAB          LOAD INPUT PTR W ADDR OF TBL       13700000
         LR    RST,RIN               SVE START REG                      13800000
MAP001   READ  DECB2,SF,(RD),RLDIN,256  READ RECORD FROM MODULE         13900000
         CHECK DECB2                                                    14000000
         TM    RLDIN,ESDIND          TEST FOR ESD INDICATOR             14100000
L0SW     BC    0,L1OUT               NOP SW SET BY 1ST ESD              14200000
         BC    8,MAP001              LOOP TO READ ANOTHER RECORD        14300000
         MVI   L0SW+1,X'80'          SET SW FOR ESD FOUND               14400000
         LH    RA,RLDIN+6            LOAD NUMBER OF ESD BYTES           14500000
         EX    RA,ESDMVC             EXECUTE MOVE TO ESD TABLE          14600000
         AR    RIN,RA                INCREMENT POINTER                  14700000
         TM    RLDIN,EOMOD           TEST FOR LAST ESD + NO TEXT        14800000
         BC    3,L1OUT               READ NO MORE                       14900000
         B     MAP001                LOOP TO READ AGAIN                 15000000
ESDMVC   MVC   0(0,RIN),RLDIN+8      EXECUTED TO MOVE ESD TO TABLE      15100000
SAVEND   DS    1F                    SAVE LIMIT OF ESDS                 15200000
*                                                                       15300000
*        PROCESS ASSEMBLED ESD ENTRIES                                  15400000
*                                                                       15500000
L1OUT    L     RST,XCESDTAB            ADDRESS OF CESD                  15570000
         NC    ENR1C(2),ENR1C          CHECK FOR NO RLDS                15640000
         BC    7,L1GO                  IF THERE ARE RLDS                15710000
         MVI   L5SW2+1,X'00'         PREVENT XREFS                      15800000
L1GO     LH    RIN,ENCDC               NUMBER OF CESD ENTRIES           15840000
         SLL   RIN,4                   TIMES 16 FOR NUMBER OF BYTES     15880000
         A     RIN,XCESDTAB            ADD START OF TABLE               15920000
         BCTR  RIN,0                   DECREMENT BY ONE                 15960000
         ST    RIN,SAVEND            SAVE                               16000000
         TM    SAVATS,OVERBIT     TEST FOR OVERLAY                      16100000
         BC    3,L1CONT              YES                                16200000
         MVI   L2SW+1,X'00'          PROC ALL ENTRIES                   16300000
         MVC   SEGHD(8),SEGHD-1      BLANK OUT SEG. NO. FROM HDR        16400000
L1CONT   LA    RIN-1,16              LOAD STOPPING FACTOR               16500000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   16600000
*                                                                       16700000
MAP002   EQU   L1CONT                LOOP TO PROCESS A SEGMENT          16800000
*                                                                       16900000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   17000000
         TM    APT0,XREFBIT       TEST FOR CROSS REFERENCES             17200000
L1SW     BC    0,NONEWHDR            SKIP HEADER IF NO XREFS AFTER 1ST  17300000
         MVI   L1SW+1,X'80'          MAKE NOP BRANCH FROM NOW ON        17400000
         MVC   PRHDR+2(117),PRHDR+1  PREVENT LAST HEADER FROM PRINTIN   17500000
         MVC   PRLIN+2(28),PRLIN+1   BLANK OUT POSS RESIDUE             17600000
         MVI   CNTLCH,SKIP             SKIP A LINE                      17670000
         BAL   R14,CNTRL                                                17740000
         LA    R15,PUTLINS             ADDRESS OF PRINT ROUTINE         17810000
         MVC   PRLIN+3(15),CTLSEC                                       17900000
         MVC   PRLIN+41(5),ENTRY     PUT HEADER                         18000000
         TM    APTSWS,TSO          TSO MODE?                     S20007 18030020
         BC    1,MAP0025           YES - BRANCH                  S20007 18060020
         CLI   LINCOUNT+1,X'05'      TEST FOR BOTTOM OF PAGE            18100000
         BC    3,MAP0025             NO  GO AHEAD AND PRINT             18200000
         MVI   LINCOUNT+1,X'01'      RESET LINE COUNTER FOR SKIP        18300000
MAP0025  EQU   *                                                        18400000
         MVI   PRLIN,DOUBLE            PRINT AND DOUBLE SPACE           18450000
         BALR  R14,R15               CALL SUBR TO PRIT LINE             18500000
         MVC   PRLIN+5(32),SGHD      MOVE IN SEG HEADER                 18700000
         MVC   PRLIN+43(15),NAMLOC                                      18800000
         MVC   PRLIN+63(15),NAMLOC                                      18900000
         TM    APTSWS,TSO          TSO MODE?                     S20007 18930020
         BC    1,TEMP              YES - BRANCH                  S20007 18960020
         MVC   PRLIN+83(15),NAMLOC                                      19000000
         MVC   PRLIN+103(15),NAMLOC                                     19100000
TEMP     MVI   PRLIN,DOUBLE        PRINT + DOUBLE SPACE          S20007 19160020
         MVC   PRHDR(119),PRLIN        SAVE HEADER FOR NEW PAGE         19220000
         BALR  R14,R15               CALL SUBROUTINE                    19300000
NONEWHDR LA    RENTRY,1              INIT ENTRY COUNTER                 19500000
         L     RB,RNT1                 ADDRESS OF RLD NOTELIST          19520000
         SH    RB,RLDNTSZ              MINUS SIZE OF ENTRY              19540000
         ST    RB,SAVRLDNT                                              19560000
         L     RB,XAD2CESD           INIT ADDR OF 2 BYTE TABLE          19600000
         ST    RB,SAVID                INITIALIZE SAVID TO FIRST        19650000
*                                                                       19700000
*        LOOP TO SELECT ESD ENTRIES FOR THIS SEGMENT                    19800000
*                                                                       19900000
L2        CLI  8(RST),X'0A'                                             19950000
      BE   L2CTL                                                        20000000
       TM   8(RST),X'03'                                                20050000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   20100000
*                                                                       20200000
MAP003   EQU   L2                    LOOP TO SELECT ESD ENTRIES         20300000
*                                                                       20400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   20500000
         BC    8,PROCSEG             PROCESS SEGTION                    20600000
         TM    8(RST),X'06'          TEST FOR PSEUDO REG  OR NULL       20700000
         BC    3,L2CTL               YES  LOP TO NEXT                   20800000
         TM    8(RST),X'05'          TEST FOR COMMON                    20900000
         BC    3,PROCSEG             YES  TREAT AS SECTION              21000000
         BC    8,L2CTL               EXTERNAL REF = UNRESOLVED          21100000
         LH    RPAR,14(0,RST)        LOAD SECT ENTRY NO. AS PARAMETER   21200000
         BAL   R14,SEGSUBR           CALL SUBR TO LOCATE ENTRY          21300000
         CH    RPAR,SEGNO            IN THIS SEGMENT                    21400000
L2SW     BC    7,L2CTL               NO  LOOP AGAIN                     21500000
         STH   RENTRY,0(0,RB)        STORE ENTRY NUMBER                 21600000
         LA    RB,2(0,RB)            ADVANCE POINTERS                   21900000
L2CTL    LA    RENTRY,1(0,RENTRY)    ADVANCE ENTRY NUMBER               22100000
         BXLE  RST,RIN-1,L2          LOOP CTL STEPS THRU ESDS           22200000
         ST    RB,IDEND                SAVE ADDRESS OF END OF ID LIST   22250000
         C     RB,XAD2CESD           TEST FOR NO ENTRIES                22300000
         BC    8,L5SW2-4             OMIT PROCESSING                    22400000
         EJECT                                                          22500000
*                                                                       22600000
*        THE FOLLO WING PROGRAM SORTS THE ENTRIES FOR                   22700000
*        THIS SEGMENT USING TWO TABLES, ON EOF TWO BYTE ENTRIES         22800000
*        AND  ONE OF 4 BYTE (ADDRESS) ENTRIES ON WHICH THE              22900000
*        SORT IS DONE.                                                  23000000
*                                                                       23100000
*        SORT REGISTER USAGE IS AS FOLLOWS                              23200000
*        RA    ADDRESS OF CURRENT COMPARAND IN FOUR BYTE TABLE          23300000
*        RB    ADDRESS OF LAST ENTRY FULLY SORTED IN FOUR BYTE TABLE    23400000
*        RC    LIMIT FOR SORT = END OF FOUR BYTE TABLE                  23500000
*        RD    COMPARAND                                                23600000
*        RE    PLUS FOUR FOR INCREMENT                                  23700000
*        RF    USED FOR EXCHANGE OF TWO BYTE ENTRIES                    23800000
*        RG    MINUS FOUR FOR DECREMENT                                 23900000
*        RH    LIMIT FOR SORT = START OF FOUR BYTE TABLE                24000000
*        RI    ADDRESS OF CURRENT ENTRY IN TWO BYTE TABLE               24100000
*        RJ    ADDRESS OF TWO BYTE ENTRY FOR LAST FULLY SORTED ITEM     24200000
*                                                                       24300000
         LR    RC,RB                   END OF TWO BYTE TABLE            24360000
         LA    RE,2                    LOAD INCREMENT FOR SORT          24420000
         SR    RC,RE                 SUBTRACT 4 FOR LIMIT               24500000
         BCTR  RC,0                  AND 1 MORE                         24600000
         LNR   RG,RE                 LOAD DECREMENT FOR SORT            24700000
         L     RA,XAD2CESD             ADDR OF 2 BYTE TABLE             24800000
         CR    RA,RC                 TEST FOR BUT ONE ENTRY             24900000
         BC    3,MAP0055             YES  SKIP SORT                     25000000
         L     RI,XAD2CESD           LOAD ADDR OF 2 BYTE TABLE          25100000
         LR    RH,RA                 LOAD START ADDRESS                 25200000
         BCTR  RH,0                  MINUS ONE FOR LIMIT                25300000
SL1      LR    RJ,RI                 LOAD CURRENT ADDR FOR 2BYTE TBL    25400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   25500000
*                                                                       25600000
MAP004   EQU   SL1                   MAJOR SORT LOOP                    25700000
*                                                                       25800000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   25900000
         LR    RB,RA                 LOAD CURRENT ADDR FOR 4BYTE TBL    26000000
SL2      LH    RD,0(0,RA)              CESD ID                          26010000
         BCTR  RD,0                    MINUS ONE                        26020000
         SLL   RD,4                    TIMES 16                         26030000
         A     RD,XCESDTAB             PLUS CESD ADDRESS                26040000
         L     RD,8(0,RD)              ASSIGNED ADDRESS                 26050000
         LA    RD,0(0,RD)                                               26060000
         LH    RF,2(0,RA)              CESD ID NEXT ENTRY               26070000
         BCTR  RF,0                    MINUS ONE                        26080000
         SLL   RF,4                    TIMES 16                         26090000
         A     RF,XCESDTAB             PLUS ADDRESS OF CESD             26100000
         L     RF,8(0,RF)              LKED ASSIGNED ADDRESS            26110000
         LA    RF,0(0,RF)                                               26120000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   26200000
*                                                                       26300000
MAP005   EQU   SL2                   MINOR SORT LOOP                    26400000
*                                                                       26500000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   26600000
         CR    RD,RF                   COMPARE ADDRESSES                26700000
         BC    4,INORD               IN ORDER                           26800000
         BC    2,XCHANGE             MUST BE EXCHANGED                  26900000
*        MUST NOW TEST FOR SECT FOLLOWING SYMBOL AT SAME LOCATION.      27000000
         ST    RPAR,RPARSAV          SAVE PARAM REGISTER                27100000
         LH    RPAR,2(0,RI)          LOAD ENTRY NUMBER OF LAST AS PAR   27200000
         BAL   R14,SEGSUBR           SUBR TO LOCATE CESD ENTRY          27300000
         L     RPAR,RPARSAV          RESTORE PARAMETER REGISTER         27400000
         TM    8(R15),X'03'          TEST FOR CSECT OR PRIVATE          27500000
         BC    8,XCHANGE             BRANCH IF SO TO EXCHANGE           27600000
         TM    8(R15),X'05'          TEST FOR COMMON                    27700000
         BC    12,INORD              BRANCH TO IN ORDER IF NOT          27800000
XCHANGE  LH    RF,0(0,RI)              LOAD ID OF CESD ITEM             28000000
         MVC   0(2,RI),2(RI)         EXCHANGE ENTRIES                   28200000
         STH   RF,2(0,RI)                                               28300000
         BCTR  RI,0                  DECREMENT POINTER BY 2             28400000
         BCTR  RI,0                                                     28500000
         BXH   RA,RG,SL2             DECR & LOOP BACK THRU TBL TO ST    28600000
INORD    LR    RA,RB                 RELOAD PTR FROM CURRENT            28700000
         LR    RI,RJ                 RELOAD PTR FROM CURRENT            28800000
         LA    RI,2(0,RI)            ADD 2 TO 2BYTE PTR                 28900000
         BXLE  RA,RE,SL1             INCR PTR &LOOP BACK TIL DONE       29000000
         EJECT                                                          29100000
*                                                                       29200000
*        THE FOLLOW ING PROGRAM PROCESSE THE SORTED ESD ENTRIES         29300000
*        FOR A SEGMNENT AND PRODUCES A MEMORY MAP.                      29400000
*                                                                       29500000
MAP0055  SR    RPLACE,RPLACE         ZERO REG FOR ENTRY COUNTER         29600000
         L     RST,XAD2CESD          LOAD PT RTO TOP OF 2BYTE TABLE     29700000
         LR    RST2,RST                                                 29800000
         LA    RC-1,2                  INCREMENT FOR BXLE               29900000
         AR    RC,RC-1               RESTORE LIMIT TO END               30000000
L5       LH    RPAR,0(0,RST)         LOAD ENTRY NUMBER                  30100000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   30200000
*                                                                       30300000
MAP006   EQU   L5                    LOOP THROUGH TABLE ENTRIES         30400000
*                                                                       30500000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   30600000
         BAL   R14,SEGSUBR           CALL SUBR TO LOCATE ENTRY          30700000
         LR    RA,R15                SAVE POINTER                       30800000
         TM    8(R15),X'03'          TEST FOR SECT OR PRIV CODE         30900000
         BC    8,PUTSECT             YES                                31000000
         TM    8(R15),X'05'          \)ST FOR COMMON                    31100000
         BC    12,L5CONT1            NO  CONTINUE                       31200000
         B     PUTSECT               HANDLE AS SECTION                  31300000
PROCSEG  CLC   SEGNO+1(1),12(RST)    TEST FOR THIS SEGMENT NUMBER       31400000
         B     L2SW                  TEST IN LINE                       31500000
L5CONT1  CH    RPLACE,COUNT        LINE FINISHED?                S20007 31600020
         BC    7,L5CONT2             NO  CONTINUE                       31700000
         SR    RPLACE,RPLACE         REZERO REG                         31800000
         LA    R15,PUTLINS           SUBR TO PRINT                      31900000
         BALR  R14,R15               CALL SUBROUTINE                    32000000
L5CONT2  LR    RWORK,RPLACE          COMPUTE PLACE FOR LABEL            32100000
         LA    RPLACE,20(0,RPLACE)   INCR NAME COUNTER                  32200000
         LA    RWORK,PRLIN(RWORK)    ADD ADDR OF PR LINE TO REG         32300000
         L     RPAR,8(0,RA)            LOAD ADDRESS OF THIS ENTRY       32400000
         BAL   R14,BINBCDS           CALL CONVERSION SUBROUTINE         32500000
         LR    R15,RA                RESTORE POINTER                    32600000
         MVC   41(8,RWORK),0(R15)    MOVE IN NAME                       32700000
         MVC   51(6,RWORK),COLLECT   MOVE IN LOC                        32800000
L5CTL    LA    RST,2(0,RST)          ADD 2 TO TABLE POINTER             32900000
         BXLE  RST2,RC-1,L5          INCR PTR & LOOP TIL END            33000000
         LA    R15,PUTLINS           SUBR PUT LINE TO PUT LABELS LEFT   33100000
         BALR  R14,R15               CALL SUBROUTINE                    33200000
         TM    APT0,XREFBIT       TEST FOR CROSS REFS CALL              33300000
L5SW2    BC    3,XREFS               YES  NOP IF NO MORE RLDS           33400000
XRRET    LA    R15,PUTLINS             ADDRESS OF PRINT SUBROUTINE      33450000
         BALR  R14,R15                                                  33500000
         CLI   CUMLEN+5,C' '           TEST FOR ANY CUM LEN REQ         33550000
         BC    8,NXTSEGNO            NO                                 33600000
         MVC   PRLIN+3(58),CUMREQ    DENOTE CUM LENGTH REQUEST          33800000
         BALR  R14,R15               CALL SUBROUTINE                    33900000
         MVC   CUMLEN(6),CUMLEN-1    BLANK OUT CUN LENGTH               34000000
NXTSEGNO CLC   CSNO(2),SEGNO      TEST FOR HIGHEST SEGMENT NUMBER       34100000
         BC    8,CLEANUP             YES  GET FINAL ITEMS               34200000
         LH    RA,SEGNO              LOAD SEGMENT NUMBER                34300000
         LA    RA,1(0,RA)            ADD 1 TO SEGMENT NO.               34400000
         STH   RA,SEGNO              RESTORE                            34500000
         L     RIN,SAVEND            RESTORE INPUT REGISTER             34600000
         L     RST,XCESDTAB          LOAD ADDRESS OF ESD TABLE          34700000
         BC    15,L1CONT             LOOP TO NEXT SEGMENT               34800000
COUNT    DC    H'80'                 RECORD LENGTH - TSO         S20007 34860020
COUNT2   DC    H'120'                RECORD LENGTH - MVT         S20007 34920020
SAVEODAD DS    3C                    SAVE END OF DATA ADDRESS HERE      35000000
SPECEOD  DC    AL3(XRRET)            ADDR OF ALTERNATE EO DATA EXIT     35100000
         EJECT                                                          35300000
*                                                                       35400000
*        ROUTINE TO PUT OUT SECTION LINE                                35500000
*                                                                       35600000
PUTSECT  LTR   RPLACE,RPLACE         TEST FOR NO LSYMBOLS               35700000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   35800000
*                                                                       35900000
MAP007   EQU   PUTSECT               ROUTINE TO PROCESS SECTION         36000000
*                                                                       36100000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   36200000
         BC    8,L5CONT3             NONE                               36300000
         LA    R15,PUTLINS           SUBR TO PRINT                      36400000
         BALR  R14,R15               CALL SUBROUTINE                    36500000
L5CONT3  L     RPAR,8(0,RA)            LOAD ADDRESS OF SECT             36600000
         LA    R15,BINBCDS           SUBR TO CVT FROM BIN TO BCD        36700000
         BALR  R14,R15               CALL SUBROUTINE                    36800000
         MVC   PRLIN+13(6),COLLECT   MOVE IN ADDRESS                    36900000
         LR    RWORK,RA              RESTORE POINTER TO ENTRY           37000000
         L     RPAR,12(0,RWORK)      LOAD ADDRESS FOR CONVERSION        37100000
         BALR  R14,R15               CALL SUBROUTINE                    37200000
         MVC   PRLIN+21(6),COLLECT   MOVE IN ADDRESS                    37300000
SECCONT  TM    8(RWORK),X'80'        TEST FO LIBRARY                    37400000
         BC    8,*+8                 NO                                 37500000
         MVI   PRLIN+11,C'*'         MOVE IN LIBR DESIGNATUON           37600000
         MVC   PRLIN+3(8),0(RWORK)   MOVE IN NAME                       37700000
         TM    8(RWORK),X'01'        TEST FOR COMMONP                   37800000
         BC    8,NOTCOM              NOT COMMON                         37900000
         CLI   0(RWORK),C' '         TEST FOR BLANK                     38000000
         BC    7,OVERTEST            OMIT OTHER TESTS                   38100000
         MVC   PRLIN+2(9),BLANKCOM   DESIGNATE BLANK COMMON             38200000
         B     OVERTEST              OMIT OTHER TESTS                   38300000
NOTCOM   CLI   8(RWORK),PRIVDEL      TEST FOR SEGTAB OR ENTAB           38400000
         BC    7,SEGTSTS             NO                                 38500000
         MVC   PRLIN+2(6),ENTAB      SET ENTAB DESIGNATOR               38600000
L5SW3    BC    0,SEGPRINT            SW FOR ENTABS FROM NOW ON          38700000
         MVI   L5SW3+1,X'F0'         SET SW FOR ENTAB HENCEFORTH        38800000
         MVC   PRLIN+2(7),SEGTAB     LOAD SEGTAB DESIGNATOR             38900000
         B     SEGPRINT              BYPASS UNNEEEDED TESTS             39000000
SEGTSTS  TM    8(RWORK),PRIVCODE     TEST FOR PRIVATE CODE              39100000
         BC    8,OVERTEST            NO  TEST OVERLAY NEXT              39200000
         MVC   PRLIN+2(9),PRIVATE    PLACE PRIVATE DESIGNATOR           39300000
OVERTEST TM    SAVATS,OVERBIT     TEST FOR OVERLAY                      39400000
         BC    8,PRINTSEC            NO  PRINT LINE                     39500000
SEGPRINT SR    RPAR,RPAR             CLEAR REG FOR PARAMETER            39600000
         IC    RPAR,12(0,RWORK)      INSERT SEGMENT NUMBER              39700000
         CVD   RPAR,COLLECT-1        CONVERT TO DECIMAL                 39800000
         UNPK  COLLECT(5),COLLECT+5(3) UNPACK QUANTITY                  39900000
        MVC   PRLIN+30(3),COLLECT     MOVE INTO PRINT LINE              39940000
         CLI   PRLIN+30,C'0'           CHECK FOR LEADING ZERO           39980000
         BC    7,PRINTSEC              NO                               40020000
         MVI   PRLIN+30,C' '           MOVE IN BLANK                    40060000
         CLI   PRLIN+31,C'0'         TEST FOR LEADING ZERO              40100000
         BC    7,PRINTSEC            NO  CONTINUE                       40200000
         MVI   PRLIN+31,C' '         REPLACE ZERO WITH LEADING BLANK    40300000
PRINTSEC LA    R15,PUTLINS           LOAD ADDR OF SUBR TO PRINT LINE    40400000
         SR    RPLACE,RPLACE         ZERO REGISTER                      40500000
         BALR  R14,R15               CALL SUBROUTINE                    40600000
         BC    15,L5CTL              LOOP TO NEXT TABLE ENTRY           40700000
         DS    0F                    ALIGN TO FULL WORD BOUNDARY        40800000
DCBLMOD  DC    AL4(IEWLCMDB)                                            40900000
WKWORD   DC    AL4(0)                WORD ON BOUNDRY                    41000000
SAVMAIN  DS    2F                    WORDS FOR FREE MAIN MACRO          41100000
XCESDTAB EQU   SAVMAIN+4             ADDRESS OF CESD ENTRIES            41200000
XADDCESD DS    1F                    ADDRESS FO 4 BYTE TABLE            41300000
XAD2CESD DS    1F                    ADDRESS OF 2 BYTE TABLE            41400000
SAVID    DC    F'0'                    POINTER TO CURRENT ID            41409000
SAVRLDNT DC    F'0'                    POINTER TO CURRENT RLD NOTELIST  41418000
RLDNTEND DC    F'0'                    END OF RLD NOTELIST              41427000
IDEND    DC    F'0'                    END OF ID LIST                   41436000
ALIGNF   DC    F'0'                    TO ALIGN ADDRESS TO FULL WORD    41445000
SAVAD    DC    F'0'                    SAVE ADDRESS OF SECTION          41454000
RMASK    DC    X'00007FFF'             MASK OUT HI ORDER BIT R POINTER  41463000
ALIGNH   DC    H'0'                    TO ALIGN COUNT TO HALF WORD      41472000
FIVE     DC    H'5'                    SIZE OF DELINK TABLE ENTRY       41481000
RLDNTSZ  DC    H'9'                    SIZE OF RLD NOTELIST             41490000
SEGNO    DC    AL2(1)                CURRENT SEGMENT NUMBER             41500000
PRIVATE  DC    C'$PRIVATE '          PRIVATE CODE DESIGNATOR            41600000
ENTAB    DC    C'$ENTAB'             ENTAB DESIGNATOR                   41700000
SEGTAB   DC    C'$SEGTAB'            SEGTAB DESIGNATOR                  41800000
BLANKCOM DC    C'$BLANKCOM'          BL ANK COMMON DESIGNATOR           41900000
CTLSEC   DC    C'CONTROL SECTION'                                       42000000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   42100000
         EJECT                                                          42200000
*                                                                       42300000
*        THIS ROUTINE PROCESSE RLD ENRTIES TO GET X REF TABLE           42400000
*                                                                       42500000
XREFS    EQU   *                                                        42600000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   42700000
*                                                                       42800000
MAP008   EQU   XREFS                 ROUTINE TO PROCESS RLDS FOR SEG    42900000
*                                                                       43000000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   43100000
         MVC   PRHDR+2(117),PRHDR+1  PREVENT LAST HEADER FROM PRINTIN   43200000
         MVI   CNTLCH,SKIP2            IMMEDIATE SKIP 2 LINES           43270000
         BAL   R14,CNTRL                                                43340000
         LA    R15,PUTLINS             ADDRESS OF PRINT ROUTNIE         43410000
         MVC   PRLIN+3(30),CRHEAD    PUT IN XREF HEADER                 43500000
         MVC   PRLIN+34(15),CTLSEC                                      43600000
         MVC   PRLIN+51(8),SEGHD                                        43700000
         TM    APTSWS,TSO          TSO MODE?                     S20007 43710020
         BC    1,TEMP2             YES - BRANCH                  S20007 43720020
         MVC   PRLIN+60(59),PRLIN+1    COMPLETE HEADING                 43730000
TEMP2    LA    RST,PRLIN           ADDRESS OF PRINT LINE         S20007 43760020
         MVI   PRLIN,DOUBLE            PRINT AND DOUBLE SPACE           43800000
         MVC   PRHDR(119),PRLIN        SAVE HEADER FOR NEW PAGE         43840000
         BALR  R14,R15               CALL SUBROUTINE                    43900000
         LA    RC-1,4                                                   44000000
         LNR   RA,RC-1               LOAD DECREMENTFOR BXH              44100000
         SR    RA+1,RA+1             ZERO FOR TEST OF BXH               44200000
         TM    NEWSW,X'40'             IS ENTRY FROM INTERMEDIATE       44208000
         BC    8,XL1CONT               NO--CARD ALREADY READ            44216000
MAP009   TM    NEWSW,X'40'             IS ENTRY FROM INTERMEDIATE       44224000
         BC    8,MAP009A               NO--GO READ A RECORD             44232000
MAP0091  L     RD,SAVID                ADDRESS OF CURRENT ID            44240000
         L     RC,SAVRLDNT             ADDRESS OF RLD NOTELIST ITEM     44248000
MAP0090  LA    RC,9(0,RC)              UPDATE TO NEXT RLD NOTELIST      44256000
MAP00901 C     RC,RLDNTEND             IS END OF LIST REACHED           44264000
         BNL   MAP0092                 YES                              44272000
         CLC   0(2,RC),0(RD)           ARE RLDS FOR THIS ID             44280000
         BC    7,MAP0090               NO--CHECK NEXT ENTRY             44288000
         MVC   ALIGNF+1(3),6(RC)       YES--GET ADDRESS OF RLD DATA     44296000
         MVC   ALIGNH(2),4(RC)         AND NUMBER OF BYTES              44304000
         ST    RC,SAVRLDNT             SAVE POINTER TO RLD NOTELIST     44312000
         L     RD,ALIGNF               DISPLACEMENT OF RLD DATA         44320000
         AR    RD,RD                   TIMES 4                          44328000
         AR    RD,RD                                                    44336000
         TM    2(RC),X'10'             IS IT IN BUFFER 2                44344000
         BC    1,MAP0093               YES                              44352000
         A     RD,RLDOUT1              NO--ADD ADDRESS OF BUFFER 1      44360000
         BC    15,MAP0094                                               44368000
MAP0093  A     RD,RLDOUT2              ADD ADDRESS OF BUFFER 2          44376000
MAP0094  LH    RC,ALIGNH               NUMBER OF WORDS OF RLD DATA      44384000
         AR    RC,RC                   TIMES FOUR                       44392000
         AR    RC,RC                                                    44400000
         SR    RD,RC                   START OF RLD DATA                44408000
         B     XL3                     GO TO PROCESS RLDS               44416000
MAP0092  LA    RD,2(0,RD)              UPDATE POINTER TO NEXT ID        44424000
         C     RD,IDEND                IS END OF ID LIST REACHED        44432000
         BNL   XRRET                   YES--CHECK FOR ANOTHER SEGMENT   44440000
         ST    RD,SAVID                NO--SAVE ADDRESS OF ID           44448000
         L     RC,RNT1                 AND START AT TOP OF RLD NOTELIST 44456000
         B     MAP00901                TO SEARCH LIST FOR THIS ID       44464000
MAP009A  L     RD,DCBLMOD              ADDRESS OF SYSLMOD DCB           44472000
         READ  DECB4,SF,(RD),RLDIN,256                                  44500000
XL1      EQU   MAP009                                                   44600000
         CHECK DECB4                                                    44700000
XL1CONT  TM    RLDIN,X'02'           TEST FOR RLD                       44800000
         BC    8,RLDOUTA               TEST FURTHER                     44900000
XL1A     LA    RD,RLDIN+16           INIT REG TO 1ST RLD DATA           45000000
         LH    RC,RLDIN+6            LOAD COUNT OF RLD DATA             45100000
XL3      TM    4(RD),X'20'           TEST FOR PSEUDO                    45200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   45300000
*                                                                       45400000
MAP010   EQU   XL3                   LOOP TO PROCESS RLD ENTRY          45500000
*                                                                       45600000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   45700000
         BC    12,XL3CONT            NO  GO ON                          45800000
         TM    4(RD),CUMLNREQ        TEST FOR PSEUDO REG LENGTH REQ     45900000
         BC    12,XL3A               NO                                 46000000
         CLI   CUMLEN+5,C' '         TEST FOR ONE ALREADYENCOUNTERED    46100000
         BC    7,XL3A                YES                                46200000
         L     RPAR,4(0,RD)          LOAD ADDRESS FOR CONVERSION        46300000
         BAL   R14,BINBCDS           CALL CONVERSION SUBROUTINE         46400000
         MVC   CUMLEN(6),COLLECT     MOVE IN ADDRESS                    46500000
XL3A     TM    4(RD),X'01'           TEST FOR CONTINUATION              46600000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   46800000
*                                                                       46900000
MAP011   EQU   XL3A                  LOOP TO PASS OVER RLD ENTRIES      47000000
*                                                                       47100000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   47200000
         BC    8,XGETNXT2              NO--GET NEXT RLD ITEM            47300000
         SR    RD,RA                 ADD 4 TO REG                       47400000
         BXH   RC,RA,XL3A            LOOP                               47500000
         B     RLDOUTA                                                  47550000
XL4      MVC   4(26,RST),3(RST)        BLANK OUT UNWANTED ADDRESS NAME  47600000
         B     XL3A                    SKIP OVER ANY CONTINUATIONS      47650000
XL3CONT  LH    RPAR,2(0,RD)          LOAD POINTER                       47700000
         BAL   R14,SEGSUBR           CALL SUBR TO LOCATE ENTRY          47800000
         CH    RPAR,SEGNO            TEST FOR THIS  SEGMENT             47900000
         BC    7,XRRET               NO  RETURN                         48000000
         L     RPAR,4(0,RD)          LOAD ADDRESS FOR CONVERSION        48100000
         TM    NEWSW,X'40'             IS ENTRY FROM INTERMEDIATE       48120000
         BC    8,XL4CONT               NO                               48140000
         LH    R14,2(0,RD)             GET P POINTER                    48160000
         SLL   R14,2                   TIMES 4                          48180000
         A     R14,RECNT               PLUS START OF RELCTN CNST TABLE  48200000
         L     R14,0(0,R14)            GET RELOCATION CONSTANT          48220000
         ST    R14,SAVAD               SAVE IT FOR POSSIBLE LATER USE   48240000
         AR    RPAR,R14                ADD RELOCATION CONSTANT          48260000
XL4CONT  BAL   R14,BINBCDS             CALL CONVERSION SUBROUTINE       48280000
         MVC   4(6,RST),COLLECT        MOVE IN ADDRESS                  48340000
         LH    RPAR,0(0,RD)          LOAD ENTRY NUMBER                  48400000
         TM    0(RD),X'80'             IS DELINK BIT ON                 48410000
         BC    8,XL5CONT               NO--HAVE REAL R POINTER          48420000
         N     RPAR,RMASK              YES--GET REAL R POINTER          48430000
         MH    RPAR,FIVE               R POINTER TIMES LENGTH OF DELINK 48440000
         A     RPAR,DLKT               PLUS ADDRESS OF DELINK TABLE     48450000
         MVC   ALIGNH(2),0(RPAR)       ALIGN R POINTER TO HALF WORD     48460000
         LH    RPAR,ALIGNH             REAL R POINTER FROM DELINK TABLE 48470000
XL5CONT  STH   RPAR,ALIGNH             SAVE R POINTER                   48480000
         LTR   RPAR,RPAR             TEST R POINTER FOR ZERO            48500000
         BC    8,XL4                 BYPASS ENTAB ENTRIES               48600000
         BAL   R14,SEGSUBR           CALL SUBR TO LOCATE ENTRY          48700000
         LR    RPLACE,R15            SAVE ADDR IN CONVENIENT REG        48800000
         MVC   22(8,RST),0(RPLACE)     MOVE IN SYMBOL                   48900000
         CLI   8(RPLACE),X'02'       TEST FOR UNRESOLVED                49000000
         BC    8,UNRES               YES                                49100000
      CLI   8(RPLACE),X'0A'                                             49110000
       BC   8,WXT                                                       49120000
         CLI   8(RPLACE),X'07'         TEST FOR NULL                    49130000
         BC    8,XL4                   YES--OMIT REFERENCE              49160000
         TM    8(RPLACE),X'03'       TEST FOR CONTROL SECTIOMN          49200000
         BC    8,RLDSECT             YES                                49300000
         TM    8(RPLACE),X'05'       TEST FOR SECTION                   49400000
         BC    3,RLDSECT             YES                                49500000
         CLC   14(2,RPLACE),2(RD)    TEST FOR INTERNAL REFERENCE        49600000
         BC    8,XL4                 YES  SKIP THIS REFERENCE           49700000
         LH    RPAR,14(0,RPLACE)     LOAD REF NO. FOR THIS ENTRY        49800000
         BAL   R14,SEGSUBR           CALL SUBR TO LOCATE ENTRY          49900000
         LR    RPLACE,R15            PLACE ADDR IN CONVENIENT REG       50000000
RLDSECT  CLC   ALIGNH(2),2(RD)         CHECK FOR SAME ID                50060000
*        NOTE--RPOINTER WAS PUT IN ALIGNH AT XL5CONT                    50120000
         BC    8,XL4                 YES  SKIP THIS ONE                 50200000
        MVC   38(8,RST),0(RPLACE)     MOVE IN SECTION NAME              50300000
         TM    SAVATS,OVERBIT     TEST FOR OVERLAY                      50400000
         BC    8,MAP0119             OMIT SEGMENT NUMBER                50500000
         SR    RPAR,RPAR             CLEAR PARAMETER REG                50600000
         IC    RPAR,12(RPLACE)       INSERT SEG NO                      50700000
         CVD   RPAR,COLLECT-1        CONVERT TO DECIMAL                 50800000
         UNPK  COLLECT(5),COLLECT+5(3) UNPACK QUANTITY                  50900000
         MVC   53(3,RST),COLLECT       MOVE INTO PRINT LINE             50950000
         CLI   53(RST),C'0'            CHECK FOR LEADING ZERO           51000000
         BC    7,MAP0119               NO                               51050000
         MVI   53(RST),C' '            YES--MOVE IN BLANK               51100000
         CLI   54(RST),C'0'            CHECK FOR LEADING ZERO           51150000
         BC    7,MAP0119             NO  CONTINUE                       51200000
         MVI   54(RST),C' '            MOVE IN BLANK                    51300000
MAP0119  LA    R15,PUTLINS           LOAD ADDRESS OF PRINT ROUTINE      51400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   51500000
*                                                                       51600000
*        CODING FOR MULTIPLE RLD ENTRIES                                51700000
*                                                                       51800000
XL2      TM    4(RD),X'01'           TEST FOR ANOTHER ADDR              51900000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   52000000
*                                                                       52100000
MAP012   EQU   XL2                   LOOP FOR SAME R AND P POINTERS     52200000
*                                                                       52300000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   52400000
         BC    8,XGETNXT             NO                                 52500000
         MVC   SVAR1(34),22(RST)       SAVE DATA FROM POINTERS          52540000
         LA    R14,PRLIN                                                52580000
         TM    APTSWS,TSO          TSO MODE?                     S20007 52590020
         BC    1,MAP0122           YES - BRANCH                  S20007 52600020
         CR    R14,RST                 IS LINE FULL                     52620000
         BC    7,MAP0122               YES--GO PRINT                    52660000
         LA    RST,60(0,RST)           NO--SET TO SECOND HALF OF LINE   52700000
         B     MAP0123                                                  52740000
MAP0122  BALR  R14,R15                 TO PRINT ROUTINE                 52780000
         LA    RST,PRLIN               SET RST TO FIRST OF LINE         52820000
MAP0123  SR    RD,RA                   ADD 4 TO POINTER                 52860000
         MVC   22(34,RST),SVAR1        RESTORE DATA                     52900000
         L     RPAR,4(0,RD)          LOAD ADDRESS FOR CONVERSION        53000000
         TM    NEWSW,X'40'             IS ENTRY FROM INTERMEDIATE       53040000
         BC    8,MAP0125               NO                               53080000
         A     RPAR,SAVAD              YES--ADD ASSIGNED ADDRESS        53120000
MAP0125  BAL   R14,BINBCDS             CALL CONVERSION SUBROUTINE       53160000
         MVC   4(6,RST),COLLECT        MOVE IN NEW ADDRESS              53230000
         LA    R15,PUTLINS           LOAD ADDR FO PRINT SUBR            53300000
         BXH   RC,RA,XL2             LOOP & DECR COUNT                  53400000
         B     RLDOUTA                 EXIT                             53500000
*                                                                       53600000
*        END FO CODING FOR MULTIPLE ENTRIES                             53700000
*                                                                       53800000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   53900000
XGETNXT  LA    R14,PRLIN                                                53930000
         TM    APTSWS,TSO          TSO MODE?                     S20007 53940020
         BC    1,MAP0124           YES - BRANCH                  S20007 53950020
        CR    R14,RST                 IS LINE FULL                      53960000
        BC    7,MAP0124               YES--GO PRINT                     53990000
         LA    RST,60(0,RST)          SET RST TO SECOND HALF OF LINE    54020000
        B     XGETNXT2                                                  54050000
MAP0124  BALR  R14,R15                 TO PRINT ROUTINE                 54080000
         LA    RST,PRLIN               SET RST TO FIRST OF PRINT LINE   54110000
XGETNXT2 AR    RC,RA                   SUBTRACT 4 FROM COUNT            54140000
RLDOUT   LA    RD,8(0,RD)            ADD 8 TO POINTER                   54200000
         BXH   RC,RA,XL3             GET NEXT RLD IF ANY                54300000
RLDOUTA  TM    NEWSW,X'40'             IS ENTRY FROM INTERMEDIATE       54350000
         BC    1,MAP0091               YES--BYPASS READ                 54400000
        TM    RLDIN,X'09'             TEST FOR EOMOD OR TXT NEXT        54450000
         BC    8,XL1                 THERE IS SUCH A CARD               54500000
         TM    RLDIN,EOMOD           TEST FOR END OF MOD                54600000
         BC    3,XRRET               YES                                54700000
         L     RD,DCBLMOD                                               54800000
         READ  DECB5,SF,(RD),RLDIN,1    SKIP OVER TEXT RECORD           54900000
         CHECK DECB5                                                    55000000
         B     XL1                   EXIT RLD RTN                       55100000
UNRES    MVC   37(11,RST),UNRESOLV     MOVE IN '$UNRESOLVED'            55200000
         CLI   13(RPLACE),NEVCALL    TEST FOR NEVER CALL                55300000
         BC    7,MAP0119             NO  LEAVE UNRESOLVED               55400000
         MVC   37(11,RST),NEVERCAL     MOVE IN '$NEVER-CALL'            55500000
         B     MAP0119               RETURN TO MAIN LINE                55600000
WXT   MVC   37(14,RST),UNRESOLV                                         55630000
      B   MAP0119                                                       55660000
RLDIN    DS    64F                   RLD READ INTO HERE                 55700000
UNRESOLV  DC C'$UNRESOLVED(W)'                                          55800000
NEVERCAL DC    C'$NEVER-CALL'        NEVER CALL DESIGNATOR              55900000
SVAR1    DS    34C                   SAVE AREA                          56000000
CRHEAD   DC    C'LOCATION  REFERS TO SYMBOL  IN'                        56100000
CUMREQ   DC    C'LOCATION        REQUESTS CUMULAT'                      56200000
         DC    C'IVE PSEUDO REGISTER LENGTH'                            56300000
CUMLEN   EQU   CUMREQ+9              LOC OF ADDRESS                     56400000
         EJECT                                                          56500000
*                                                                       56600000
*        THIS ROUTINE ENDS THE MAP                                      56700000
*                                                                       56800000
CLEANUP  SR    RPLACE,RPLACE         ZERO REG CTR REGISTER              56900000
         MVC   PRHDR+2(117),PRHDR+1  PREVENT LAST HEADER FROM PRINTIN   57000000
         MVC   PRLIN+2(30),PRLIN+1   BLANK OUT POSS INTERNAL REF        57100000
         C     RPLACE,PRAL        TEST FOR NO PSEUDO REGISTERS          57200000
         BC    8,ENTOT1              NONE  OMIT PROCESSING              57300000
         L     RC,SAVEND             LOAD POINTER TO LAST ESD           57400000
         LA    RC-1,16               LOAD INDEXING FACTOR               57500000
         L     RST2,XCESDTAB         LOAD ADDR OF ESD TABLE             57600000
*                                                                       57700000
*        LIST PSEUDO REGISTERS                                          57800000
*                                                                       57900000
         MVC   PRLIN+20(100),PRLIN+19  BLANK OUT ERSIDUE                58000000
         MVC   PRLIN+2(16),PSEUDOS                                      58100000
         MVI   PRLIN,DOUBLE            PRINT AND DOUBLE SPACE           58150000
         LA    R15,PUTLINS           PRINT SUBROUTINE                   58200000
         BALR  R14,R15               CALL SUBROUTINE                    58300000
         MVC   PRLIN+5(22),NAMOLEN   CREATE HEADER                      58500000
         MVC   PRLIN+35(22),NAMOLEN                                     58600000
         TM    APTSWS,TSO          TSO MODE?                     S20007 58630020
         BC    1,TEMP3             YES - BRANCH                  S20007 58660020
         MVC   PRLIN+65(22),NAMOLEN                                     58700000
         MVC   PRLIN+95(22),NAMOLEN                                     58800000
TEMP3    MVI   PRLIN,TRIPLE        PRINT AND TRIPLE SPACE        S20007 58860020
         MVC   PRHDR(119),PRLIN                                         58920000
         BALR  R14,R15               CALL SUBROUTINE                    59000000
L7       TM    8(RST2),X'06'         TEST FOR PSEUDO                    59300000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   59400000
*                                                                       59500000
MAP013   EQU   L7                    LOOP TO PROCESS PSEUDO REGS        59600000
*                                                                       59700000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   59800000
         BC    12,L7CTL              NO                                 59900000
         TM    8(RST2),X'01'         TEST FOR PSEUDO                    60000000
         BC    3,L7CTL               NO  GO TO NEXT ESD ENTRY           60100000
ONEFND   CH    RPLACE,COUNT2       LINE FULL?                    S20007 60200020
         BC    7,L7CONT              NO                                 60300000
         SR    RPLACE,RPLACE         REZERO POINTER                     60400000
         LA    R15,PUTLINS           SUBR TO PUT 1 LINE                 60500000
         BALR  R14,R15               CALL SUBROUTINE                    60600000
L7CONT   LR    RWORK,RPLACE          FORM ACTUAL PRINT ADDR             60700000
         LA    RWORK,PRLIN(RWORK)                                       60800000
         L     RPAR,8(0,RST2)        LOAD ADDDRESS FOR CONVERSION       60900000
         LA    R15,BINBCDS           CONVERT SUBR                       61000000
         BALR  R14,R15               CALL SUBROUTINE                    61100000
         MVC   3(8,RWORK),0(RST2)    MOVE IN NAME                       61200000
         MVC   13(6,RWORK),COLLECT   MOVE IN LOC                        61300000
         L     RPAR,12(0,RST2)       LOAD ADDRESS FOR CONVERSION        61400000
         BALR  R14,R15               CALL SUBROUTINE                    61500000
         MVC   21(6,RWORK),COLLECT   MOVE TO PRINT LINE                 61600000
         LA    RPLACE,30(0,RPLACE)   ADD TO COUNTER                     61700000
L7CTL    BXLE  RST2,RC-1,L7          LOOP TO NEXT ESD TIL LAST          61800000
         LTR   RPLACE,RPLACE         TEST FOR NO PSEUDO REGS            61900000
         BC    8,ENTOT               BRANCH AROUND PUT                  62000000
         LA    R15,PUTLINS           SUBR TO PRINT LINE                 62100000
         MVI   PRLIN,DOUBLE            PRINT AND DOUBLE SPACE           62150000
         BALR  R14,R15               CALL SUBROUTINE                    62200000
*                                                                       62500000
*        PUT OUT ENTRY ADDRESS AND TOTAL LENGTH                         62600000
*                                                                       62700000
ENTOT    L     RPAR,PRAL          LOAD PSEUDO LENGTH                    62800000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   62900000
*                                                                       63000000
MAP014   EQU   ENTOT                 ROUTINE FOR LENGTH OF PSEUDOS      63100000
*                                                                       63200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   63300000
         MVC   PRHDR+2(117),PRHDR+1  BLANK OUT PRINT HEADER             63400000
         BAL   R14,BINBCDS           CALL CONVERSION SUBROUTINE         63500000
         MVC   PRLIN+2(32),CUMPS     PUT IN INDICATOR                   63600000
         MVC   PRLIN+36(6),COLLECT   MOVE IN QUANTITY                   63700000
         LA    R15,PUTLINS           SUBROUTINE TO PNINT LINE           63800000
         BALR  R14,R15               CALL SUBROUTINE                    63900000
ENTOT1   MVC   PRLIN+2(13),ENTADD    LOAD INDICATOR                     64000000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   64100000
*                                                                       64200000
IEWLMAPX EQU   ENTOT1                  ENTRY AFTER SYNAD EXIT           64260000
         ENTRY IEWLMAPX                                                 64320000
*                                                                       64400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   64500000
         MVC   PRHDR+2(117),PRHDR+1  BLANK OUT PRINT HEADER             64600000
         MVC   WKWORD+1(3),PDSE11  MOVE ENTRY ADDRESS                   64700000
         L     RPAR,WKWORD           LOAD FULL WORD                     64800000
         TM    PDSE3,ALBIT         TEST FOR ALIAS                       64900000
         BC    8,MAP0153             NO  ENTRY ADDRESS CORRECT          65000000
         L     RPAR,IOCT           PICK UP RIGHT ENTRY ADDRESS          65100000
         SRL   RPAR,8                                                   65200000
MAP0153  EQU   *                                                        65300000
         BAL   R14,BINBCDS           CALL CONVERSION SUBROUTINE         65400000
         MVC   PRLIN+18(6),COLLECT   STORE NUMBER                       65500000
         LA    R15,PUTLINS           PRINT LINE                         65600000
         BALR  R14,R15               CALL SUBROUTINE                    65700000
         MVC   PRLIN+2(12),TOTLEN    LOAD TITLE                         65800000
         MVC   WKWORD+1(3),PDSE9   LOAD TOTAL LENGTH IN FULL WORD       65900000
         L     R1,WKWORD             LOAD IN FOLL WORD                  66000000
         BAL   R14,BINBCDS           CALL CONVERSION SUBROUTINE         66100000
         MVC   PRLIN+18(6),COLLECT   STORE NUMBER                       66200000
         MVI   PRLIN,DOUBLE            PRINT AND DOUBLE SPACE           66250000
         LA    R15,PUTLINS           PRINT LINE                         66300000
         BALR  R14,R15               CALL SUBROUTINE                    66400000
         MVI   L2SW+1,X'70'          RESET SWITCHES                     66600000
         MVI   L1SW+1,X'00'                                             66700000
         MVI   L5SW3+1,X'00'                                            66800000
         MVI   L5SW2+1,X'30'                                            66900000
         TM    NEWSW,X'40'             IS ENTRY FROM INTERMEDIATE       66960000
         BC    1,MAP0154               YES--BYPASS FREEMAIN AND CLOSE   67020000
         L     RA,DCBLMOD                                               67100000
         MVC   33(3,RA),SAVEODAD     RESTORE END OF DATA ADDRESS        67200000
         CLOSE ((RA))                                                   67400000
         TM    JFCBADDR,X'80'          WAS OPEN J REQUIRED       A41571 67450021
         BZ    MAP0154                 NO--BRANCH                A41571 67500021
         FREEMAIN E,LV=200,A=JFCBADDR  FREE JFCB AREA            A41571 67550021
MAP0154  MVC   SEGHD(8),SAVSEG         RESTORE SEG. NO. TO HDRS         67600000
         MVI   SEGNO+1,X'01'                                            67800000
         MVI   L0SW+1,X'00'                                             67900000
         MVC   LINECNT+1(1),LINCOUNT+1 RESTORE LINE COUNT TO APT        67930000
         NI    NEWSW,X'EF'             INDICATE MAP/XREF NOT OPERATING  67960000
         LM    R14,RBASE,SPACES+12                                      68000000
         BR    R14                     RETURN                           68300000
         DS    0F                                                       68600000
PSEUDOS  DC    C'PSEUDO REGISTERS'      HEADER FOR PSEUDO REGISTERS     69000000
NAMOLEN  DC    C'NAME    ORIGIN  LENGTH'  HEADER FOR PSEUDOS            69100000
CUMPS    DC    C'TOTAL LENGTH OF PSEUDO REGISTERS' LINE FOR OUT PUT     69200000
ENTADD   DC    C'ENTRY ADDRESS'                                         69300000
ENTRY    EQU   ENTADD                WORD ENTRY                         69400000
TOTLEN   DC    C'TOTAL LENGTH'                                          69500000
SAVSEG   DC    C'SEG. NO.'           FOR RESTORATION FO SEG. NO.        69600000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   69700000
         EJECT                                                          70700000
*                                                                       70800000
*        THIS SUBROUTINE TAKES A BINARY QUANTITY FROM RPAR              70900000
*        AND CONVERTS IT TO PRINT CHARACTERS TO THE BASE                71000000
*        INDICATED BY THE VARIABLE TEN.  THIS RESULT IS PLACED          71100000
*        IN THE SIX CHARACTER AREA COLLECT.  THE SUBROUTINE             71200000
*        RETURNS ON REGISTER R14.                                       71300000
*                                                                       71400000
BINBCDS  LA    RPAR,0(0,RPAR)        CLEAR HIGH ORDER BITS              71500000
         LTR   RPAR,RPAR             TEST FOR ZERO                      71600000
         BC    7,CVTCONT             NO                                 71700000
         MVC   COLLECT(6),ZERO       STORE ZERO INDICATOR               71800000
         BR    R14                   RETURN                             71900000
TEN      DC    A(16)                   DIVIDE CONSTANT                  72000000
ZERO     DC    C'    00'             ZERO INDICATOR                     72100000
CVTCONT  ST    RPAR,COLLECT-1        PLACE BINARY QUANT IN BUFFER       72200000
         UNPK  COLLECT(7),COLLECT(4)  UNPACK BINARY QUANTITY            72300000
         MVZ   COLLECT(6),COLLECT-1  ZERO ALL ZONES FOR TRANSLATE       72400000
         TR    COLLECT(6),TRTABLE    TRANSLATE FOR PRINTING             72500000
*                                                                       72600000
*        CHANGE LEADING ZEROS TO BLANKS                                 72700000
*                                                                       72800000
         LA    R0,1                  LOAD INCREMENT                     72900000
         LA    RPAR,COLLECT          LOAD START ADDRESS                 73000000
HIZEROS  CLI   0(RPAR),C'0'          TEST FOR ZERO                      73100000
         BCR   7,R14                 NO  DONE SO RETURN                 73200000
         MVI   0(RPAR),C' '          REPLACE ZERO WITH LEADING BLANK    73300000
         BXH   RPAR,R0,HIZEROS       INCR + LOOP TO NEXT DIGIT ALWAYS   73400000
BUFFER   DS    1D                    DOUBLE WORD AREA FOR CONVERSION    73500000
COLLECT  EQU   BUFFER+1              ADDRESS OF CONVERTED DATA          73600000
TRTABLE  DC    C'0123456789ABCDEF '  TABLE FOR TRANSLATION              73700000
         EJECT                                                          73800000
*                                                                       73900000
*        THIS SUBROUTINE PUTS OUT A LINE FROM PRLIN AND THEN            74000000
*        BLANKS IT OUT.                                                 74100000
*                                                                       74200000
         DS    0H                                                       74300000
PUTLINS  STM   RE,R15,PRSAV          SAVE REGISTERS                     74500000
SET4LINE LA    RE,PRLIN              SET FOR PRINT OF LINE              74900000
         TM    APTSWS,TSO          TSO MODE?                     S20007 74930020
         BC    1,PRINT             YES - BRANCH                  S20007 74960020
         LH    R15,LINCOUNT          LOAD LINE COUNT INTO REGISTER      75000000
         BCT   R15,CHKSNGL                                              75020000
         B     CHKHDR                  IF AT END OF PAGE                75040000
CHKSNGL  CLI   PRLIN,SINGLE            WAS SINGLE SPACE REQUESTED       75060000
         BE    NOPAGE                  YES--GO PRINT                    75080000
         BCT   R15,CHKDBL              NO--DECREMENT COUNT AGAIN        75100000
         B     CHKHDR                  IF AT END OF PAGE                75120000
CHKDBL   CLI   PRLIN,DOUBLE            WAS DOUBLE SPACE REQUESTED       75140000
         BE    NOPAGE                  YES--GO PRINT                    75160000
         BCT   R15,NOPAGE              NO--MUST BE TRIPLE--DECREMENT    75180000
CHKHDR   CLC   PRLIN+1(118),PRHDR+1    IS THIS LINE HEADER              75200000
         BE    HEADPNT                 YES--DON'T PRINT TWICE           75220000
         LA    RE,PRHDR                SET TO PRINT HEADER              75240000
HEADPNT  MVI   LINCOUNT+1,NUMBLINS     RESET LINE COUNTER               75260000
         L     R15,IEWLCWBB+20         ADDRESS OF PRINT BUFFER          75300000
         MVI   0(R15),RESTORE          INSERT CONTROL CH FOR RESTORE    75340000
         L     R15,PRNTAD              ADDRESS OF PRINT ROUTINE         75380000
         BALR  R14,R15                                                  75420000
         B     PRINT                 GO TO PRINT                        75500000
NOPAGE   STC   R15,LINCOUNT+1        STORE UPDATED LINE COUNT           75600000
         CLI   LINCOUNT+1,X'02'      TEST FOR BOTTOM OF PAGE            75700000
         BC    3,PRINT               NO  GO AHEAD AND PRINT             75800000
         CLC   PRLIN+1(118),PRHDR+1  TEST FOR HEADER                    75900000
         BE    HEADPNT                 NO DOUBLE HEAD PRINT             76000000
PRINT    L     RC,IEWLCWBB+20      ADDRESS OF PRINT BUFFER              76100000
         MVC   0(121,RC),0(RE)         MOVE MESSAGE TO PRINT BUFFER     76200000
         L     R15,PRNTAD              ADDRESS OF PRINT ROUTINE         76300000
         BALR  R14,R15                                                  76400000
         TM    APTSWS,TSO          TSO MODE?                     S20007 76430020
         BC    1,PREXIT            YES - BRANCH                  S20007 76460020
         LA    R15,PRHDR             LOAD FOR TEST FOR HEADER           76500000
         CR    R15,RE                TEST FOR HEADER LAST               76600000
         BE    SET4LINE              YES  PUT OUT PROPER LINE           76700000
PREXIT   LM    RE,R15,PRSAV          NO  RESTORE REGISTERS              76800000
         MVI   PRLIN,SINGLE          SET PRLIN BUFFER TO SINGLE SPACE   77100000
         MVC   PRLIN+2(118),PRLIN+1  BLANK OUT PRINT LINE               77200000
         BR    R14                   EXIT                               77300000
*                                                                       77320000
*        THIS SUBROUTINE PERFORMS IMMEDIATE SKIP OPERATIONS, USING      77340000
*        THE CARRIAGE COTNROL CHARACTER FROM LOCATION CNTLCH            77360000
*                                                                       77380000
CNTRL    ST    R14,SAV14               SAVE R14                         77400000
         TM    APTSWS,TSO          TSO MODE?                     S20007 77406020
         BC    1,CNTRLB            YES - BRANCH                  S20007 77412020
         LH    R15,LINCOUNT                                             77420000
         BCT   R15,CNTRLA              DECREMENT LINE COUNT             77440000
         B     NEWPAGE                 IF AT END OF PAGE                77460000
CNTRLA   CLI   CNTLCH,SKIP             WAS SKIP ONE REQUESTED           77480000
         BE    CNTRLB                  YES                              77500000
         BCT   R15,CNTRLB              NO--DECREMENT LINE COUNT AGAIN   77520000
NEWPAGE  MVI   LINCOUNT+1,X'01'        INDICATE END OF PAGE             77540000
         BR    R14                     AND RETURN                       77560000
CNTRLB   STH   R15,LINCOUNT            STORE UPDATED LINE COUNT         77580000
         L     R15,IEWLCWBB+20         ADDRESS OF PRINT BUFFER          77600000
         MVC   0(1,R15),CNTLCH         MOVE IN CONTROL CHARACTER        77620000
         L     R15,PRNTAD              ADDRESS OF PRINT ROUTINE         77640000
         BALR  R14,R15                                                  77660000
         L     R14,SAV14               RESTORE R14                      77680000
         BR    R14                     RETURN                           77700000
SAV14    DC    F'0'                                                     77720000
CNTLCH   DC    AL1(SKIP)                                                77740000
         DS    0F                                                       77760000
PRSAV    DS    6F                    SAVE AREA                          77800000
RPARSAV  EQU   PRSAV+8               SAVE R1 IN SORT OVER BASE SAVE     77900000
NUMBLINS EQU   53                    NUMBER OF LINES ON PAGE AFTER 1ST  78000000
LINCOUNT DC    AL2(54)               COUNTER OF LINES ON A PAGE         78100000
PRHDR    DC    AL1(DOUBLE)             CONTROL CH PRINT AND SPACE 2     78200000
         DC    4C'                              '                       78300000
PRLIN    DC    AL1(SINGLE)             CONTROL CH PRINT AND SPACE       78400000
         DC    4C'                              '  BUFFER               78500000
PRNTAD   DC    V(IEWLEPNT)             ADDRESS OF PRINT ROUTINE         78600000
JFCBADDR DC    F'00'                   ADDR OF JFCB AREA         A41571 78630021
XLSTADDR DC    A(APTXLIST)             ADDR OF SYSLMOD EXIT LIST A41571 78660021
         EJECT                                                          78700000
*                                                                       78800000
*        THIS SUBROUTINE TAKES AN ANTRY NUMBER FROM RPAR                78900000
*        AND RETURNS THE ADDRESS OF THAT ENTRY IN R15                   79000000
*        AND ITS SEGMENT NUMBER IN RPAR                                 79100000
*                                                                       79200000
SEGSUBR  SLL   RPAR,4                MULT BY 16                         79400000
         L     R15,XCESDTAB          LOAD ADDRESS OF ESD TABLE          79500000
         AR    R15,RPAR              ADD PARAMETER                      79600000
         S     R15,TEN               AND SUBTRACT SIXTEEN               79700000
         SR    RPAR,RPAR             CLEAR REG                          79800000
         IC    RPAR,12(0,R15)        INSERT SEG NUMBER                  79900000
         BR    R14                   RETURN                             80000000
*                                                                       80100000
         IEWAPT                                                         80200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   80300000
         END                                                            80400000
