         TITLE    'ATTRIBUTES AND OPTIONS PROCESSOR'                    00100000
*                                                                     * 00200000
*********************************************************************** 00300000
*                                                                     * 00400000
*                                                                     * 00500000
* STATUS -  CHANGE LEVEL  000                                         * 00600000
*                                                                     * 00700000
* FUNCTION/OPERATION -   THIS ROUTINE SCANS & ANALYZES THE ATTRIBUTES * 00800000
* & OPTIONS CONTROL INFORMATION WHICH IS PASSED TO IT INDIRECTLY      * 00900000
* FROM THE PARAMETER LIST.                                            * 01000000
*                                                                     * 01100000
*     THIS PARAMETER INFORMATION INDICATES WHAT MODULE ATTRIBUTES     * 01200000
*  AND  L/E.  PROCESSING OPTIONS ARE TO BE USED IN GENERATING THE     * 01300000
*  TYPE OF LOAD MODULE DESIRED. THE INFORMATION IS BASED ON THE       * 01400000
*  PARAMETERS  SPECIFIED IN THE  'EXEC' CONTROL CARD BY THE           * 01500000
*  PROGRAMMER USER, OR THOSE PASSED BY A LINK, XCTL, OR ATTACH MACRO  * 01600000
*   FROM ANOTHER PROGRAM.                                             * 01700000
*                                                                     * 01800000
*  THESE OPTIONS & ATTRIBUTES ARE CHECKED FOR VALIDITY & ARE ALSO     * 01900000
*  ANALYZED  TO   DETERMINE IF THEY ARE REQUESTED IN COMBINATIONS     * 02000000
* WHICH  ARE  ALLOWABLE. THE RESULTS OF THIS PROCESSING ARE THEN      * 02100000
* INDICATED BY  -                                                       02200000
*                                                                     * 02300000
*  1.- THE SETTING OF INTERNAL INDICATORS IN THE ALL PURPOSE TABLE    * 02400000
*  2.- PRINTED MESSAGES INDICATING WHAT ATTRIBUTES/OPTIONS  WERE      * 02500000
*  SPECIFIED & WHETHER OR NOT THEY  WERE VALID & ACCEPTED.            * 02600000
*                                                                     * 02700000
*  THIS ROUTINE HAS A CHARACTER CODE DEPENDENCE                       * 02800000
*       THE HEXADECIMAL REPRESENTATION OF A ZERO                      * 02900000
*            IS EXPECTED TO BE  F0                                    * 03000000
*       THE ZONE OF ANY DIGIT IS EXPECTED TO BE  F                    * 03100000
*                                                                     * 03200000
*                                                                     * 03300000
*  ENTRY POINTS -                                                     * 03400000
*                                                                     * 03500000
*   (1)  IEWLMOPT = MODULE NAME                                       * 03600000
*                                                                     * 03700000
* ENTERED FROM INITIAL PROCESSOR - BY  THIS'CALLING  SEQUENCE '-      * 03800000
*                                                                     * 03900000
*       L  1,       ADDRESS OF PARAMETER LIST BYTE  COUNT             * 04000000
*       L  15,      IEWLMOPT = ENTRY POINT                            * 04100000
*       BALR 14,15  LINKAGE                                           * 04200000
*                                                                     * 04210000
* ENTERED FORM SCN -'BY THIS CALLING SEQUENCE'                        * 04220000
*  L RA = LENGTH OF PARMS ON THE PARM CARD.                           * 04230000
*  L RB = ADDRESS OF THE PARMS IN THE SYSLIN BUFFER.                  * 04240000
* L RF = ADDRESS OF IEWLMOPT (ENTRY POINT).                           * 04250000
* BALR RE,RF                                                          * 04260000
*                                                                     * 04270000
*                                                                     * 04300000
*                                                                     * 04400000
*  INPUT -                                                            * 04500000
*                                                                     * 04600000
*        THE PARAMETER LIST ADDRESS IS PASSED  IN REG. NO.1  WHICH IS * 04700000
* USED TO OBTAIN A  BYTE COUNT & ASSOCIATED PARAMETER INFORMATION.    * 04800000
*                                                                     * 04900000
*                                                                     * 05000000
*      THE FOLLOWING  ARE COMPLETE LISTS  OF  THE  'ATTRIBUTE   AND   * 05100000
*  OPTION ' SYMBOLS  WHICH ARE AVAILABLE  FOR  USE, AND  THEY WILL    * 05200000
*  DETERMINE THE CHARACTERISTICS OF THE LOAD  MODULE TO BE CREATED.     05300000
*                                                                     * 05400000
*      (A)       - MODULE  ATTRIBUTES -                               * 05500000
*                                                                     * 05600000
* 1.- SCTR =  FORMAT OF MODULE IS SUITABLE FOR EITHER SCATTER OR      * 05700000
*             BLOCK LOADING.                                          * 05800000
*                                                                     * 05900000
* 2.- OVLY =  MODULE STRUCTURED IN OVERLAY.                           * 06000000
*                                                                     * 06100000
* 3.- HIAR = MODULE TO BE LOADED INTO SELECTED STORAGE HIERARCHIES.   * 06200000
*                                                                     * 06300000
* 4.- RENT = MODULE IS RE-ENTERABLE                                   * 06400000
*                                                                     * 06500000
* 5.- REUS = MODULE IS SERIALLY  RE-USABLE                            * 06600000
*                                                                     * 06700000
* 6.- REFR = MODULE IS REFRESHABLE                                    * 06800000
*                                                                     * 06900000
* 7.- TEST = MODULE CONTAINS TESTING SYMBOL TABLES FOR USE BY THE     * 07000000
*            TEST TRANSLATOR                                          * 07100000
*                                                                     * 07200000
*                                                                     * 07300000
*      (B) -  PROCESSING  OPTIONS -                                   * 07400000
*                                                                     * 07500000
*                                                                     * 07600000
*  1.-  NCAL  =     NO  AUTOMATIC  LIBRARY  CALL .                    * 07700000
*                                                                     * 07800000
*  2.-  LET   =    LOAD MODULE IS MARKED EXECUTABLE - ALLOWING MINOR  * 07900000
*                  ERROR  CONDITIONS DETECTED  DURING PROCESSING.     * 08000000
*                                                                     * 08100000
*  3.- XCAL   =    ALLOWS 'EXCLUSIVE BRANCH'  TYPE ERRORS , ONLY.     * 08200000
*                                                                     * 08300000
*  4.- LIST   =   OUTPUTS LISTING OF ALL L/E. CONTROL  STATEMENTS.    * 08400000
*                  IN CARD - IMAGE FORMATS.                           * 08500000
*                                                                     * 08600000
*  5.- MAP    =   PRODUCES A MAP  OF THE LOAD MODULE'S STRUCTURE.     * 08700000
*                                                                     * 08800000
*  6.- XREF   =  PRODUCES A CROSS - REFERENCE TABLE OF THE            * 08900000
*                 MODULE WHICH ALSO INCLUDES A MAP.                   * 09000000
*                                                                     * 09100000
*                                                                     * 09200000
* 7.- PRINT  = WRITE HEADERS, ALLOW XREF,MAP,LIST IF SPECIFIED.       * 09209000
* 8.-NOPRINT =  PRINT ONLY ERRORS.                                    * 09218000
* 9.-NOXREF  =  DO NOT PERFORM AN XREF LISTING FOR THIS MODULE.       * 09227000
*10.- NOCALL =  DO NOT PERFORM AUTOMATIC CALL FOR UNRESOLVED ERS.     * 09236000
*11.- CALL   =  PERFORM AUTOMATIC CALL ON SYSLIB FOR UNRESOLVED ERS.  * 09245000
*12.- NORENT =  DO NOT MARK THIS MODULE AS RE-ENTRANT.                * 09254000
*13.- NOREUS =  DO NOT MARK THIS MODULE AS RE-USEABLE.                * 09263000
*14.- TERM   =  THE TERMINAL IS BEING SUPPORTED.                      * 09272000
*15.- NOTERM = THE TERMINAL  IS NOT BEING SUPPORTED FOR THIS RUN.     * 09281000
*                                                                     * 09290000
*  * SPECIAL OPTIONS -                                                * 09300000
*                                                                     * 09400000
*  1. - DC    =  'DOWNWARD COMPATIBILTY' - MEANS THIS MODULE IS       * 09500000
*                 ACCEPTABLE AS INPUT  TO ALL LEVELS OF LINKAGE       * 09600000
*                 EDITORS.                                            * 09700000
*                                                                     * 09800000
* 2. -  OL    = ' ONLY LOADABLE '- INDICATOR IS SET - ON.             * 09900000
*                                                                     * 10000000
* 3. -  NE    = ' NOT EDITABLE ' -MEANS  THAT  THE ' ESD ' INFORMATION* 10100000
*                IS ELIMINATED  AND THEREFORE THIS MODULE WILL  NOT   * 10200000
*                BE ACCEPTED  BY  LINKAGE EDITOR FOR RE-PROCESSING.   * 10300000
*                                                                     * 10400000
* 4.- SIZE = OPTION PERMITTING SPECIFICATION OF                         10500000
*                 A) MAXIMUM NUMBER BYTES OF MAIN  STORAGE AVAILABLE    10600000
*                   TO THE LINKAGE EDITOR  (VALUE1)                     10700000
*                   WHERE VALUE1=(DESIGN PT X 1024) TO 9999999          10800000
*                              OR (DP K) TO 9999K                       10900000
*                 B) SIZE OF LOAD MODULE BUFFER (VALUE2)                11000000
*                   WHERE VALUE2= 6144 TO 102400                        11100000
*                              OR 6K TO 100K                            11200000
*                                                                       11300000
*                 THE FOLLOWING FORMATS ARE ACCEPTED:                 * 11400000
*                               SIZE=VALUE1                           * 11500000
*                                 SIZE=(VALUE1)                       * 11600000
*                                   SIZE=(,VALUE2)                    * 11700000
*                                     SIZE=(VALUE1,VALUE2)            * 11800000
*                                       SIZE=(,)                      * 11900000
*                 DEFAULT VALUES ARE SET DURING SYSTEM GENERATION     * 12000000
*                                                                     * 12100000
*                                                                     * 12200000
*                                                                     * 12300000
*                                                                     * 12400000
*      THESE PARAMETERS MUST BE SPECIFIED IN CERTAIN VALID            * 12500000
*  COMBINATIONS (INDICATED IN TABLE) IN ORDER TO BE ACCEPTED FOR      * 12600000
*  ANY GIVEN LINKAGE EDITOR PROCESSING.                               * 12700000
*                                                                     * 12800000
* ** TABLE - COMBINATIONS OF  'INCOMPATIBLE' ATTRIBUTES & OPTIONS **  * 12900000
*---------------------------------------------------------------------* 13000000
*                                                                     * 13100000
* PARM. SPECIFIED  ***  COMBINATIONS - 'NOT ALLOWABLE ' WITH.         * 13200000
* ---------------        ------------------------------------         * 13300000
*                                                                     * 13400000
*   1.  SCTR       *    OVLY                                          * 13500000
*                                                                     * 13600000
*   2.  OVLY       *    SCTR,RENT, REUS, HIAR, REFR                   * 13700000
*                                                                     * 13800000
*   3.  HIAR       *    OVLY                                          * 13900000
*                                                                     * 14000000
*   4.  RENT       *    REUS, REFR, OVLY                              * 14100000
*                                                                     * 14200000
*   5.  REUS       *    RENT, REFR, OVLY                              * 14300000
*                                                                     * 14400000
*   7.  TEST       *    NE                                       M4593* 14500020
*                                                                     * 14600000
*   6.  REFR       *    RENT, REUS, OVLY                              * 14700000
*                                                                     * 14800000
*   8.  LET        *    XCAL                                          * 14900000
*                                                                     * 15000000
*   9.  XCAL       *    LET                                           * 15100000
*                                                                     * 15200000
*   10. MAP        *    XREF, NE                                      * 15300000
*                                                                     * 15400000
*   11. XREF       *    MAP, NE                                       * 15500000
*                                                                     * 15600000
*   12. NE         *    MAP, XREF, TEST                               * 15700000
*                                                                     * 15800000
*   13. NCAL       *    -N/A-                                         * 15900000
*                                                                     * 16000000
*   14. LIST       *    -N/A-                                         * 16100000
*                                                                     * 16200000
*   15. OL         *    -N/A-                                         * 16300000
*                                                                     * 16400000
*   16. DC         *    -N/A-                                         * 16500000
*                                                                     * 16600000
*   17. SIZE       *    -N/A-                                         * 16700000
*                                                                     * 16800000
*---------------------------------------------------------------------* 16900000
*                                                                     * 17000000
*  OUTPUT -                                                           * 17100000
*                                                                     * 17200000
*        MESSAGES ARE PRINTED - OUT, TO INFORM  THE USER OF  WHAT -   * 17300000
*  LINKAGE EDITOR OPTIONS & ATTRIBUTES WERE PROCESSED & AS TO         * 17400000
*  WHETHER OR NOT THEY ARE VALID & COMPATIBLE.                        * 17500000
*                                                                     * 17600000
* IN THE CASE OF THE NOPRINT OPTION THE ONLY FORM OF OUTPUT ON SYSPRINT 17620000
* THAT SHALL OCCUR IS, THE PRINTING OF ERROR MEASAGES.                * 17640000
         TITLE '* *  OPTIONS PROCESSOR FOR LINKAGE EDITOR F VERSION 2*' 17660000
*                                                                     * 17700000
*   EXTERNAL  ROUTINES -      NONE                                    * 17800000
*                                                                     * 17900000
*  EXITS - NORMAL -                                                   * 18000000
*                                                                     * 18100000
*        AT THE COMPLETION OF PROCESSING ALL OPTIONS/ATTRIBUTES,      * 18200000
*  RETURN CONTROL IS TRANSFERED BACK  TO THE INITIALIZER (THAT IS TO  * 18300000
*  THE NEXT SEQUENTIAL INSTRUCTION, THE POINT AT WHICH EXIT  WAS      * 18400000
*  MADE  FROM  ' IEWLMINT ' MODULE).                                  * 18500000
*                                                                     * 18600000
*                                                                     * 18700000
*                                                                     * 18800000
*  EXITS - ERROR -  NONE                                              * 18900000
*                                                                     * 19000000
*  TABLES/WORK AREAS -  N/A.                                          * 19100000
*                                                                     * 19200000
*  ATTRIBUTES -  N/A.                                                 * 19300000
*                                                                     * 19400000
*  NOTES -  N/A.                                                      * 19500000
*                                                                     * 19600000
*                                                                     * 19700000
*********************************************************************** 19800000
*                                                                       19900000
*                                                                       20000000
IEWLMOPT CSECT                                                          20080000
*                                                                A24467 20160000
* 403200,693600,706400-707200,711200                              M3028 20200020
* 145000,341600-347200                                            M4593 20220020
* 694400                                                          M4507 20230000
*C311200,I324800,C702400                                        SA57107 20232021
         SPACE 1                                                        20240000
R0       EQU   0    PARAMATER  REGISTER                                 20320000
R1       EQU   1    PARAMATER  REGISTER                                 20400000
R2       EQU   2                                                        20480000
R3       EQU   3                                                        20560000
R4       EQU   4                                                        20640000
R5       EQU   5                                                        20720000
R6       EQU   6                                                        20800000
R7       EQU   7                                                        20880000
R8       EQU   8                                                        20960000
R9       EQU   9                                                        21040000
RA       EQU   10                                                       21120000
RB       EQU   11                                                       21200000
RC       EQU   12   BASE REGISTER                                       21280000
RD       EQU   13   SAVE AREA POINTER REGISTER                          21360000
RE       EQU   14   RETURN REGISTER                                     21440000
RF       EQU   15   GO TO REGISTER                                      21520000
 EJECT                                                                  21600000
PARMREG  EQU   1                                                        21680000
DISP8    EQU   8                                                        21760000
BYTES8   EQU   8                                                        21840000
CONCODE8 EQU   8                                                        21920000
DISP4    EQU   4                                                        22000000
DISP1    EQU   1                                                        22080000
DISP2    EQU   2                                                        22160000
BYTES1   EQU   1                                                        22240000
BYTES4   EQU   4                                                        22320000
BLANK    EQU   C' '                                                     22400000
K        EQU   C'K'                                                     22480000
COMMA    EQU   C','                                                     22560000
LPAREN   EQU   C'('                                                     22640000
RPAREN   EQU   C')'                                                     22720000
NULL     EQU   X'00'                                                    22800000
NOOVLY   EQU   X'BF'                                                    22880000
EQUAL    EQU   C'='                                                     22960000
SIZE     EQU   X'01'                                                    23040000
LPRENRCV EQU   X'02'                                                    23120000
RPRENRCV EQU   X'04'                                                    23200000
VAL1RCVD EQU   X'08'   VALUE1 RECIEVED OR ACCEPTED FOR DEFAULT          23280000
GENOPTST EQU   X'10'     INDICATES A GENERATED DEFAULT ACTIVATED        23360000
USEDEF   EQU   X'20'   ERROR ENCOUNTERED WHICH NEGATES USER VALUES DEF. 23440000
KFORM    EQU   X'40'                                                    23520000
INCOMPT  EQU   X'80'  INCOMPATABLE OPTIONS MESSAGE NECESSARY            23600000
NOXML    EQU   X'97' RST MASK TO TURN OFF XREF,MAP AND LIST FOR NOPRINT 23680000
SCNDTIME EQU   X'20'  MOTP ENTERED FOR THE SECOND TIME                  23760000
RESET    EQU   X'F0'   RESET MASK FOR SIZE SWITCHES                     23840000
NUMBER   EQU   X'F0'   MASK FOR CHECKING VALID NUMERICAL ZONES          23920000
RSTKFORM EQU   X'BF'   RESET MASK  FOR K FORM                           24000000
HIAR     EQU   X'04'                                                    24080000
NOHIAR   EQU   X'FB'                                                    24160000
SCTR     EQU   X'04'                                                    24240000
NOSCTR   EQU   X'FB'                                                    24320000
RENT     EQU   X'10'                                                    24400000
XREF     EQU   X'40'                                                    24480000
TEST     EQU   X'10'                                                    24560000
REFR     EQU   X'01'                                                    24640000
CALL     EQU   X'7F'                                                    24720000
NORNR    EQU   X'3F'                                                    24800000
RENTREUS EQU   X'C0'                                                    24880000
NOREFR   EQU   X'FE'                                                    24960000
MAP      EQU   X'20'                                                    25040000
NE       EQU   X'08'                                                    25120000
NONE     EQU   X'F7'                                                    25200000
NOMAP    EQU   X'DF'                                                    25280000
NOXREF   EQU   X'BF'                                                    25360000
NOLIST   EQU   X'F7'                                                    25440000
NOTERM   EQU   X'FD'                                                    25520000
NOTEST   EQU   X'EF'                                                    25600000
DCBS     EQU   X'10'                                                    25680000
TERM     EQU   X'02'                                                    25760000
OL       EQU   X'08'                                                    25840000
NCAL     EQU   X'80'                                                    25920000
XCAL     EQU   X'04'                                                    26000000
LET      EQU   X'10'                                                    26080000
REUS     EQU   X'40'                                                    26160000
LIST     EQU   X'08'                                                    26240000
DC       EQU   X'7F'                                                    26320000
OVLY     EQU   X'20'                                                    26400000
NORENT   EQU   X'7F'                                                    26480000
NOREUS   EQU   X'BF'                                                    26560000
TABLEEND EQU   X'FF'                                                    26640000
MULT1024 EQU   10                                                       26720000
NEWPAGE  EQU   X'19'                                                    26800000
 EJECT                                                                  26880000
         USING VRT,R6                                                   26960000
         USING APTDSECT,R2                                              27040000
         USING DEFDSECT,R1                                              27120000
         USING *,15                                                     27200000
         STM   RE,RD,SAVEA              SAVE REGISTERS                  27280000
         DROP 15                                                        27360000
         BALR  RC,R0                                                    27440000
         USING *,RC                                                     27520000
         BC    15,MOID+6                                                27600000
MOID     DC    C'01MOPT'                                                27680000
 EJECT                                                                  27760000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 27840000
*                                                                     * 27920000
*  THIS IS THE OPTION SCANNING ROUTINE . IT WILL CHECK THE PARM.      * 28000000
*   FIELD FOR VALID OPTIONS. INVALID OPTIONS AND VALID OPTIONS WILL   * 28080000
*    BE PLACED IN THE PRINT BUFFER TO BE PRINTED UPON RETURN TO INT.  * 28160000
*    PARMREG HAS POINTER TO 1ST BYTE OF THE PARAMATER FIELD PASSED ON * 28240000
*    THE EXEC CARD.                                                   * 28320000
* R6 ALWAYS POINTS TO A WORK AREA                                     * 28400000
* R2 ALWAYS POINTS TO APT                                             * 28480000
* R8 WHILE SCANNING FOR PARAMATERS HAS THE ADR OF NXT AVAIL POS IN    * 28560000
* PARAMATER MESSAGE TO PLACE THE PARAMATER                              28640000
*                                                                     * 28720000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 28800000
  SPACE 2                                                               28880000
         TM    APTSWS,SCNDTIME    SECOND TIME IN OPT                    28960000
         BZ    OPT01                                                    29040000
         L     R6,TXTIO           USE THE TXTIO TABLE FOR BUFFER        29120000
         MVI   NOTVLD,TABLEEND    DO NOT ACCEPT TABLE ALLOCATING PARMS. 29200000
         MVI   MESGNO1,NEWPAGE     ITERATIONS MUST BEGIN ON NEW PAGE    29280000
         B     OPT02                                                    29360000
 SPACE 1                                                                29440000
OPT01    LH    RA,0(0,PARMREG)     NO. OF BYTES PASSED IN THE LIST      29520000
         LA    RB,DISP2(0,PARMREG) ADDRESS OF THE FIRST BYTE            29600000
         SPACE 1                                                        29680000
         GETMAIN R,LV=274         ACQUIRE DYNAMIC WORK SPACE            29760000
         LR    R6,R1              PRIME DSCT REG                        29840000
         SPACE 1                                                        29920000
OPT02    MVI   INTERN1,NULL       CLEAR THE SWITCHES                    30000000
         XC    MSGONE(4),MSGONE                                         30080000
         XC    MSGTWO(4),MSGTWO                                         30160000
         XC    MSGTHREE(4),MSGTHREE                                     30240000
         LTR   RA,RA               IS LENGTH THAT WAS PASSED = 0        30320000
         BNP   NOTANY             NO PARAMATERS                         30400000
         MVI   TRTBUF,NULL        CLEAR FIRST BYTE                      30480000
         MVC   TRTBUF+BYTES1(255),TRTBUF CLR REST OF BUFFER             30560000
         SPACE 1                                                        30640000
         MVI   TRTBUF+COMMA,COMMA MOVE COMMA TO COMMA DISPLACEMENT      30720000
         MVI   TRTBUF+EQUAL,EQUAL MOVE EQUAL TO EQUAL DISPLACEMENT      30800000
         MVI   TRTBUF+LPAREN,LPAREN MOVE IN LEFT PARENTHESIS            30880000
         MVI   TRTBUF+RPAREN,RPAREN MOVE IN RIGHT PARENTHESIS           30960000
         MVI   TRTBUF+BLANK,BLANK MOVE IN A BLANK(MAKES PARMS FREE-FORM 31040000
         MVC   OPTIONS(108),BLK1 RESET THE LINE                         31120021
         MVC   GENDFLTS(20),BLK2    CLEAR THE LINE                      31200000
         LA    R8,OPTIONS         ADDRESS OF PLACE OPTIONS AREA         31280000
         L     R1,DEFADR          ADDRESS OF DEF                        31360000
SCANOPT  BCTR  RA,0                -1 FOR MACHINE LENGTH OF LIST        31440000
         LR    R0,R2               SAVE DSECT BASE                      31520000
         EX    RA,SCAN             SCAN FOR = OR                        31600000
         BNE   OPTFOUND            IF STOPPED CHECK FOR VALID OPTION    31680000
         LA    R9,DISP1(0,RA)     PRINE R 9 WITH TRUE LENGTH            31760000
         TM    INTERN1,SIZE       WAS I IN THE SIZE SEARCH              31840000
         BO    OPT111             IF SO CONTINUE SIZE EXTRACTION        31920000
         LTR   R7,RA              TRANSFER THE LENGTH                   32000000
         BP    LASTSCN            IF MORE THAN 0 CONTINUE SCAN          32080000
OPTEXIT  BCTR  R8,0                -1 TO GET ADDRESS OF LAST COMMA      32160000
         CLI   0(R8),RPAREN       STOPPED LAST BY A )                   32240000
         BE    EXIT               IF SO DO NOT BLANK IT OUT             32320000
         MVI   0(R8),BLANK         BLANK OUT LAST COMMA                 32400000
EXIT     EQU   *                                                        32480000
         LA    R3,MESGNO1              POINT TO START OF TEXT   SA57107 32530021
         SR    R8,R3                   CALC LENGTH OF TEXT      SA57107 32540021
         STC   R8,HEADRS               SAVE ACTUAL TEXT LENGTH  SA57107 32550021
 EJECT                                                                  32560000
*** TEST FOR ALLOWABLE OPTIONS                                          32640000
 SPACE 1                                                                32720000
         TM    NEWSW,HIAR         IS HIAR OPTION ON                     32800000
         BZ    OPT11B             NO PROCESS OTHER OPTIONS              32880000
         OI    PDSE7,SCTR         SET SCTR OPTION ON                    32960000
OPT11B   TM    APT0,XREF          IS XREF OPTION ON                     33040000
         BZ    OPT12              NO                                    33120000
         TM    APT0,MAP           IS MAP OPTION ON                      33200000
         BZ    OPT13              BRANCH IF NOT                         33280000
         NI    APT0,NOMAP         SET MAP OPTION OFF                    33360000
         B     OPT13                                                    33440000
OPT12    TM    APT0,MAP           IS THE MAP OPTION ON                  33520000
         BZ    OPT14              NO                                    33600000
OPT13    TM    PDSE8,NE           IS NE OPTION ON                       33680000
         BZ    OPT14              NO                                    33760000
         NI    PDSE8,NONE         SET NE OFF - WANTS MAP -              33840000
         OI    INTERN1,INCOMPT    INDICATE INCOMPATABLE OPTIONS         33920000
OPT14    TM    PDSE7,TEST         IS TEST ON                            34000000
         BZ    OPT16              NO                                    34080000
         TM    PDSE8,NE                IS NE ON                   M4593 34380020
         BZ    OPT16              NO CONTINUE                           34800000
         NI    PDSE8,NONE         CLEAR NE INDICATOR                    34880000
         OI    INTERN1,INCOMPT    INDICATE INCOMPATABLE OPTIONS         34960000
OPT16    TM    PDSE7,OVLY         IS OVERLAY OPTION ON                  35040000
         BZ    OPT26              EXIT                                  35120000
         TM    PDSE7,RENTREUS     IS RENT OR REUS ON                    35200000
         BNZ   OPT16B             YES -RESET OPTION -                   35280000
         TM    PDSE8,REFR         IS REFR ON                            35360000
         BZ    OPT16A             NO -TEST FOR SCTR-                    35440000
OPT16B   NI    PDSE8,NOREFR       CLEAR REFR                            35520000
         NI    PDSE7,NORNR        CLEAR REUS AND RENT                   35600000
         OI    INTERN1,INCOMPT    INDICATE INCOMPATABLE OPTIONS         35680000
OPT16A   TM    PDSE7,SCTR         IS SCTR ON                            35760000
         BZ    OPT26              EXIT                                  35840000
         NI    PDSE7,NOSCTR       CLEAR SCTR                            35920000
         NI    NEWSW,NOHIAR       CLEAR HIAR                            36000000
         OI    INTERN1,INCOMPT    INDICATE INCOMPATABLE OPTIONS         36080000
OPT26    EQU   *    ** END OF INCOMPATABLE OPTIONS SCAN **              36160000
 EJECT                                                                  36240000
***                                                                     36320000
*** THIS SECTION CHECKS IF USER SPECD VAL 1 OR 2                        36400000
*** DEFAULTS VALUES NOT SPECD DEFAULTS BOTH IF CONFLICT WITH DESIGN PT. 36480000
**                                                                      36560000
*** R3 = VALUE 1  0 IF SPECIFIED INCORRECTLY OR IF USER WANTS DEFAULT   36640000
*** R4 = VALUE 2  0 IF SPECIFIED INCORRECTLY OR IF USER WANTS DEFAULT   36720000
         SPACE 2                                                        36800000
         L     R1,DEFADR           ADDRESS OF IEWLMDEF                  36880000
         MVC   IDENT(BYTES4),DEFNAME DESIGN NAME OF EDITOR              36960000
         LM    R3,R4,VALUE1       USER(IF SPECD) R3=VALUE1,R4=VALUE2    37040000
         LM    R9,RB,DEFDSNPT DEFAULTS R9=DSNPT,RA=DEFVAL1,RB=DEFVAL2   37120000
  SPACE 1                                                               37200000
         TM    INTERN1,USEDEF     SIZE SPECD INCORRECTLY                37280000
         BO    OPT320             IF SO USE DEFAULTS                    37360000
         LTR   R3,R3               DID USER SPECIFY A VALID VALUE       37440000
         BP    OPT300                                                   37520000
         LR    R3,RA              GET DEFAULT VALUE 1                   37600000
         ST    RA,VALUE1          USE DEFAULT VALUE 1                   37680000
         OI    INTERN1,USEDEF     INDICATE DEFAULT(S) USED              37760000
         B     OPT330              CHECK VALUE2                         37840000
         SPACE 1                                                        37920000
OPT300   CR    R3,R9              IS VALUE 1 LT DSNPT                   38000000
         BNL   OPT330              NO CHECK VALUE 2                     38080000
OPT320   STM   RA,RB,VALUE1       USE DEFAULT VALUES 1 AND 2            38160000
         B     OPT380               DEF VALUES IN EXIT                  38240000
OPT330   LTR   R4,R4              DID USER SPEC. VALUE 2                38320000
         BNP   OPT350              USER WANTS DEFAULT VALUE 2           38400000
         CR    R3,R4              IS VALUE 2 GT VALUE 1                 38480000
         BL    OPT350              YES  ERROR                           38560000
         C     R4,MINVAL2         VALUE 2 LT MINIMUM                    38640000
         BL    OPT350              USE DEFAULT VALUE2                   38720000
         C     R4,MAXVAL2         DOES VALUE 2 EXCEED MAXIMUM           38800000
         BNH   OPT390              VALUE 2 ACCEPTABLE                   38880000
OPT350   ST    RB,VALUE2          USE DEFAULT VALUE 2                   38960000
         SPACE 1                                                        39040000
OPT380   OI    INTERN1,USEDEF      INDICATE VALUE DEFAULTED             39120000
 EJECT                                                                  39200000
***                                                                     39280000
*** THIS SECTION SETS UP A MESSAGE INDICATING THE VALUES USED AND       39360000
** WETHER THEY ARE DEFAULTS OR VARIABLE OPTIONS SPECIFIED BY THE USER,  39440000
***                                                                     39520000
 SPACE 2                                                                39600000
OPT390   LA    R8,VALUES          ADDRESS OF MESSAGE 1 VALUES USED SLOT 39680000
         L     R1,VALUE1          QUANTITY VALUE1                       39760000
         BAL   RE,OPT500          DELETE LEADING ZEROS - PLACE IN MSG   39840000
         MVI   0(R8),COMMA        INSERT THE COMMA SEPARATOR            39920000
         LA    R8,DISP1(0,R8)     BUMP POINTER TO NEXT BLANK            40000000
         L     R1,VALUE2          QUANTITY VALUE2                       40080000
         BAL   RE,OPT500          DELETE LEADING ZEROS - PLACE IN MSG   40160000
         MVI   0(R8),RPAREN       INSERT THE R PAREN TERMINATOR         40240000
         TM    INTERN1,USEDEF          DEFAULTS USED?             M3028 40280020
         BZ    OPT510                  NO                         M3028 40320020
         MVC   DEFAULTM+10(17),DEFS    YES - MOVE IN DEFAULT      M3028 40360020
OPT510   EQU   *                                                        40400000
 SPACE 2                                                                40480000
***                                                                     40560000
***      THIS SECTION SETS UP THE MESSAGES RETURNED TO INT              40640000
***   THIS SECTION DELETS HEADER MESSAGES WHEN THE NO PRINT OPTION      40720000
*** HAS BEEN CODED IN THE PARAMATER FIELD.                              40800000
***                                                                     40880000
 SPACE 2                                                                40960000
         LM    R3,R5,HEADRS       LN AND ADR OF MESSAGES 1 AND 2        41040000
         STM   R3,R4,MSGONE       PS TO INT THROUGH APT                 41120000
OPT775   TM    INTERN1,INCOMPT    WERE THERE INCOMPATABLE OPTIONS       41200000
         BZ    OPT800             NO -DO NOT ISSUE MESSAGE -            41280000
         ST    R5,MSGTHREE        SAVE IN APT                           41360000
OPT800   EQU   *                                                        41440000
 EJECT                                                                  41520000
***                                                                     41600000
*** EPILOG                                                              41680000
***                                                                     41760000
 SPACE 1                                                                41840000
         TM    APTSWS,SCNDTIME    SECOND TIME IN OPT                    41920000
         BO    OPT999             DO NOT ISSUE THE FREE MAIN            42000000
         FREEMAIN R,LV=274,A=(6) FREE DYNAMIC WORK SPACE                42080000
 SPACE 2                                                                42160000
RETURN   LM    RE,RD,SAVEA                                              42240000
         BR    RE                       RETURN                          42320000
    SPACE 1                                                             42400000
*        THIS SECTION PRINTS THE HEADER MESSAGES AFTER A PARM CARD      42480000
*        HAS  BEEN ENCOUNTERED.  IEWLMINT PRINTS THE MESSAGES FROM      42560000
*        THE PARMS ON THE EXEC CARD.                                    42640000
*                                                                       42720000
OPT999   EQU   *                                                        42800000
         L     RF,=V(IEWLEPNT)    ADDRESS OF THE PRINT ROUTINE          42880000
         LA    R3,MSGONE               GET ADDRESS OF LENGTH AND ADD.   42960000
*                                      OF FIRST MESSAGE                 43040000
         LA    R5,MSGTHREE        PRIME END REG                         43120000
         LA    R4,4               INDEX                                 43200000
OPT997   L     R8,IEWLCWBB+20     ADDRESS OF SYSPRINT BUFFER            43280000
         SR    R9,R9                                                    43360000
         IC    R9,0(0,R3)              GET LENGTH OF THE MESSAGE        43440000
         LTR   R9,R9              IS IT ZERO                            43520000
         BZ    OPT998             NO PRINT SKIP                         43600000
         L     RB,0(0,R3)              PUT ADDRESS OF MESSAGE IN RB     43680000
         EX    R9,MVOPT2M         MOOE THE OPTION TO THE MESSAGE        43760000
         BALR  RE,RF              PRINT THE HEADER                      43840000
OPT998   BXLE  R3,R4,OPT997                                             43920000
         B     RETURN                                                   44000000
         EJECT                                                          44080000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 44160000
*                                                                     * 44240000
*RB  IS USED TO HOLD THE LAST(STOPPED AT) ADDRESS IN THE PARM FIELD   * 44320000
*RA  IS USED TO HOLD THE NUMBER OF BYTES OF OPTIONS LEFT IN PARM FIELD* 44400000
* R9 IS USED TO HOLD THE TRUE LENGTH OF AN OPTION FOR ADDRESS UPDATEING 44480000
* R7 IS USED TO HOLD MACHINE LENGTH OF OPTION FOR EX INSTRUCTIONS.    * 44560000
*                                                                     * 44640000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 44720000
         SPACE 2                                                        44800000
OPTFOUND STC   R2,FUNCBYTE         SAVE THE STOPPER BYTE.               44880000
         LR    R2,R0               RESTORE DSECT BASE.                  44960000
         LR    R7,R1               TIC CURRENT(STOPPED AT) ADDRESS.     45040000
         SR    R7,RB               LAST ADR-CUR ADR = LENGTH OF OPTION  45120000
         LR    R9,R7              TRANSFERR LENGTH TO R9                45200000
         TM    INTERN1,SIZE  AM I LOOKING FOR SIZE AFT(SIZE=)           45280000
         BZ    CHECKOPT            IF NOT DETERMINE IF VALID OPTION.    45360000
         MVI   TRTBUF+EQUAL,NULL DELETE = FROM TRT TABLE                45440000
* R7 CONTAINS TRUE LENGTH NOT MACH LENGTH BECAUSE (, MEANS DEFAULT      45520000
* THAT VALUE WHERE AS LIST,,, MEANS IGNORE AND WOULD NOT CAUSE VAL1 OR  45600000
* VAL2 RCVD SWITCH SETTING                                              45680000
         SPACE 1                                                        45760000
         TM    INTERN1,LPRENRCV    ( RECIEVED ?                         45840000
         BZ    OPT101              NO                                   45920000
         CLI   FUNCBYTE,COMMA      STOPPED BY COMMA                     46000000
         BE    OPT100              YES CHECK IF VAL1 RCVD YET           46080000
         CLI   FUNCBYTE,BLANK     STOPPED BY A BLANK                    46160000
         BE    OPT107             YES SKIP FREE FORM                    46240000
* AT THIS POINT HAD TO BE STOPPED BY A ) BECAUSE NO OTHERS ARE STOPPERS 46320000
         OI    INTERN1,RPRENRCV    SET ) RECIEVED                       46400000
         TM    INTERN1,VAL1RCVD    VALUE 1 RECIEVED YET                 46480000
         BO    OPT102              YES CHECK FOR VALUE 2 RECIEVED       46560000
         LA    RF,VALUE1          ADDRESS OF VALUE1                     46640000
         BAL   RE,MOVEVAL          CHANGE RADIX OF VALUE POINTED BY RB  46720000
         OI    INTERN1,VAL1RCVD   INDICATE VALUE 1 R*CIEVED             46800000
         B     OPT103                                                   46880000
         SPACE 1                                                        46960000
OPT101   CLI   FUNCBYTE,LPAREN     STOPPED BY (                         47040000
         BE    OPT104              YES CHECK LENGTH                     47120000
         CLI   FUNCBYTE,COMMA      STOPPED BY ,                         47200000
         BE    OPT105              YES                                  47280000
         CLI   FUNCBYTE,BLANK     STOPPED BY A BLANK                    47360000
         BE    OPT112             YES SKIP FREE FORM                    47440000
         CLI   FUNCBYTE,EQUAL     STOPPED BY EQUAL -FREE FORM -         47520000
         BE    OPT112             YES SKIP FREE FORM                    47600000
         B     SIZEINVL            -ERROR- POSSIBLE *SIZE=)*            47680000
         SPACE 1                                                        47760000
OPT104   OI    INTERN1,LPRENRCV   SET ( RECIEVED                        47840000
         B     OPT112                                                   47920000
         SPACE 1                                                        48000000
OPT100   TM    INTERN1,VAL1RCVD    VALUE 1 RECIEVED YET                 48080000
         BO    OPT102              YES CHECK IF VALUE 2 RECIEVED        48160000
         LA    RF,VALUE1          ADDRESS OF VALUE1                     48240000
         BAL   RE,MOVEVAL          CONVERT FROM RADIX 10 TO RADIX 2     48320000
         OI    INTERN1,VAL1RCVD    INDICATE VALUE 1 RECIEVED            48400000
         B     GOBY                CONTINUE                             48480000
         SPACE 1                                                        48560000
OPT102   LA    RF,VALUE2          ADDRESS OF VALUE2                     48640000
OPT106   BAL   RE,MOVEVAL         CONVERT FROM RADIX 10 TO RADIX 2      48720000
OPT103   NI    INTERN1,RESET       CLEAR SWITCHES USED FOR SIZE SRCH    48800000
         MVI   TRTBUF+EQUAL,EQUAL RESTORE = SIGN TO TRT TABLE           48880000
         B     GOBY                CONTINUE                             48960000
 SPACE 1                                                                49040000
OPT105   LA    RF,VALUE1          ADDRESS OF VALUE1                     49120000
         B     OPT106             END OF SCAN -SIZE=100K-               49200000
OPT107   TM    INTERN1,VAL1RCVD   VALUE 1 RECIEVED YET                  49280000
         BO    OPT108             YES                                   49360000
         LA    RF,VALUE1          ADDRESS OF VALUE1                     49440000
         BAL   RE,MOVEVAL                                               49520000
         B     GOBY                                                     49600000
 EJECT                                                                  49680000
OPT108   LA    RF,VALUE2          ADDRESS OF VALUE2                     49760000
         BAL   RE,MOVEVAL                                               49840000
         B     GOBY                                                     49920000
 SPACE 1                                                                50000000
OPT111   LR    R7,R9              LAST SCAN R7=R9                       50080000
         B     OPT100 CONTINUE                                          50160000
         SPACE 2                                                        50240000
SIZEINVL OI    INTERN1,USEDEF      SIZE SPEC. INVALIDLY                 50320000
* AT THIS POINT POSSIBLE TOGIVE MESSAGE                                 50400000
         B     INVALIDR                                                 50480000
         SPACE 1                                                        50560000
ZEROLN   LA    RB,DISP1(0,RB)      UPDATE LAST(STOPPED AT) ADDRESS.     50640000
         B     TSTCNT1                                                  50720000
         EJECT                                                          50800000
CHECKOPT EQU   *                   ENTRY FOR FIRST TIME                 50880000
         LTR   R9,R7               TRANSFER BACK TO AND TEST FOR 0 INR9 50960000
         BNP   OPT112             LENGTH OF OPTION 0 (,,OR==OR=,OR,=)   51040000
* ,( OR (( OR =( OR (= OR (, OR ), OR )= OR )) OR ,) OR ),              51120000
         BCTR  R7,0                -1 FOR MACHINE LENGTH                51200000
LASTSCN  EQU   *                                                        51280000
         LA    R3,OPTFIELD        ADDRESS OF ACCEPTABLE OPTIONS         51360000
         SR    R4,R4              CLEAR LENGTH REGISTER                 51440000
         SR    R5,R5              CLEAR INDEX REG                       51520000
         SPACE 1                                                        51600000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 51680000
*                                                                     * 51760000
* DETERMINES IF OPTION IS A VALID SELECTION IF NOT INSERT INVALID& SKIP 51840000
*                                                                     * 51920000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 52000000
         SPACE 1                                                        52080000
CHKOPT   IC    R4,0(0,R3)     LENGTH OF THE OPTION                      52160000
         CR    R4,R9              LN OF OPT IN LIST=LN OF OPT FOUND     52240000
         BNE   UPPTR              NO CHECK THE NEXT ENTRY               52320000
         EX    R7,COMPOPT         COMPARE THE TWO OPTIONS FOR =         52400000
         BE    OPT10              SET THE OPTION                        52480000
         SPACE 1                                                        52560000
UPPTR    LA    R3,1(R4,R3)        LN OF INST+LN BYTE(1)+LN OPT=NXT OPT  52640000
         LA    R5,DISP4(0,R5)     UP INDEX TO NEXT OPTION SETTER        52720000
         CLI   0(R3),TABLEEND     END OF ACCEPTABLE OPTIONS             52800000
         BNE   CHKOPT             CHECK THE NEXT OPTION IN THE LIST     52880000
* AT THIS POINT THE OPTION WAS NOT ONE OF THE ACCEPTABLE OPTIONS        52960000
 SPACE 1                                                                53040000
INVALIDR MVC   0(7,R8),INVMSG     OPTION INVALID MOVE MSG TO BUFFER     53120000
         MVC   7(BYTES1,R8),FUNCBYTE MOVE STOPPER BYTE                  53200000
         LA    R8,DISP8(0,R8)      UPDATE POINTER                       53280000
         B     RSTPTR              SAVE   POINTER                       53360000
OPT10    EX    R0,SETOPTS(R5)     SET OR RESET THE SWITCH(OPTION)       53440000
GOBY     EX    R7,MVOPT2M          MOVE THE OPTION TO HEADER MESSAGE    53520000
OPT112   EQU   *                                                        53600000
         LA    R3,0(R8,R9)        LN OF OPT+MSG ADR=POS FOR STOPPER     53680000
         MVC   0(BYTES1,R3),FUNCBYTE MOVE IN THE STOPPER BYTE           53760000
         LTR   R9,R9              WAS THE LENGTH OF THE OPTION 0        53840000
         BNP   SHRT               IF SO SKIP THE ALTERNATE INS          53920000
         CLI   FUNCBYTE,BLANK     WAS THE STOPPER A BLANG               54000000
         BE    OPT113             IF SO DO NOT MOVE IT                  54080000
         LA    R8,DISP2(R7,R8)     A(MSG)+MACH. LENGTH+2(,+1)=NEW PTR.  54160000
RSTPTR   LA    RB,DISP1(R9,RB)    UPDATE THE ADDRESS                    54240000
TSTCNT1  SR    RA,R9               LENGTH LEFT - AMMOUNT PROCESSED.     54320000
TSTCNT2  LTR   RA,RA               IS LENGTH STILL >0                   54400000
         BNP   OPTEXIT             TERMINATE  IF O OR -                 54480000
         B     SCANOPT             CONTINUE                             54560000
         SPACE 2                                                        54640000
SHRT     CLI   0(R3),BLANK        STOPPED BY A BLANK CHARACTER          54720000
         BE    ZEROLN             DO NOT MOVE BLANKS TO MESSAGE         54800000
         LA    R8,DISP1(R7,R8)                                          54880000
         B     ZEROLN                                                   54960000
  SPACE 1                                                               55040000
OPT113   LA    R8,0(R9,R8)        DO NOT INCLUDE THE LENGTH OF THE BLK  55120000
         B     RSTPTR                                                   55200000
 SPACE 1                                                                55280000
         EJECT                                                          55360000
***                                                                     55440000
*** UPON ENTRY R1 HAS THE VALUE TO BE CONVERTED                         55520000
*** THIS SECTION DELETES LEADING ZEROES FORM NUMBERS TO PRINT           55600000
***                                                                     55680000
 SPACE 1                                                                55760000
OPT500   LA    R4,7               MAX LENGTH OF THE VALUE               55840000
         CVD   R1,WORK            CONVERT TO DECIMAL NUMBER             55920000
         OI    WORK+7,X'0F'       CHANGE ZONE                           56000000
         UNPK  WORK1,WORK+DISP4(BYTES4)   UNPACK FOR PRINTING           56080000
         LA    RB,WORK1+DISP1     ADDRESS OF UNPACKED VALUE             56160000
OPT508   CLI   0(RB),C'0'         IS THIS A LEADING ZERO                56240000
         BNE   OPT512             DON'T DELETE                          56320000
         LA    RB,1(0,RB)         CHECK THE NEXT ONE                    56400000
         BCT   R4,OPT508          CONTINUE DLETING LEADING ZEROS        56480000
OPT512   LA    R4,WORK1+BYTES8     LAST BYTE OF VALUE IN WORK           56560000
         SR    R4,RB              AM NUL-LN OF VAL=NO VLD NON-ZERO      56640000
         BCTR  R4,0               - 1 FOR THE EXECUTE LENGTH            56720000
         EX    R4,MVOPT2M         MOVE THE VALUE TO THE MESSAGE         56800000
         LA    R8,DISP1(R4,R8) MC LN OF VAL+1ST ADR=ADR OF NXT BLK      56880000
         BR    RE                 RETURN                                56960000
 EJECT                                                                  57040000
***                                                                     57120000
***  UPON ENTRY INTO THIS ROUTINE (WHICH CONVERTS DECIMAL NUMBER IN K O 57200000
***  EXPLICIT FORMAT TO A HEXADECIMAL NUMBER)                           57280000
***  R1  UTILITY                                                        57360000
***  R2  BASE OF DSECT                                                  57440000
***  R3  UTILITY                                                        57520000
***  R4  UTILITY                                                        57600000
***  R5  POINTS TO THE LOCATION TO PLACE IT IN                          57680000
***  R7  MACHINE LENGTH OF VALUE   R9-1                                 57760000
***  R9 LENGTH OF VALUE (TRUE)                                          57840000
***  RA  # BYTES LEFT IN PARM FIELD                                     57920000
***  RB  POINTS TO THE VALUE TO BE CONVERTED                            58000000
***  RE HOLDS THE RETURN ADDRESS                                        58080000
         SPACE 2                                                        58160000
MOVEVAL  LTR   R4,R9               LN OF VALUE 0 -USE DEFAULT-          58240000
         BCR   CONCODE8,RE         YES -RETURN USER DEFAULTS THIS VALUE 58320000
         BCTR  R7,0               LN OF OPT-1 = MACH LN                 58400000
         LA    R1,0(RB,R7) MACH.LN+A(VAL)=A(LAST BYTE OF VAL)*R7=R9-1*  58480000
         CLI   0(R1),K             IS VALUE IMPLICIT  K                 58560000
         BNE   EXPLICIT                                                 58640000
         OI    INTERN1,KFORM       INDICATE IMPLICIT VALUE              58720000
         TM    INTERN1,VAL1RCVD   VALUE 1 RECIEVED YET                  58800000
         BZ    OPT600             YES CHECK LENTH                       58880000
         LA    R3,4                MAX.NO.CHARS. FOR IMPLICIT VALUE     58960000
OPT633   BCTR  R4,0               -1 FROM CHAR CNT, TO NOT CHECK K      59040000
         BCTR  R7,0       -1 FROM CHAR CNT FOR K                        59120000
OPT750   CR    R3,R9              CHARACTER COUNT OF VALUE TOO BIG      59200000
         BL    SIZEINVL                                                 59280000
CHKZONES BCTR  R4,0                                                     59360000
         LA    R5,0(RB,R4)         LAST NUMBER IN STRING                59440000
         LR    R1,RB              STARTING ADDRESS OF VALUE             59520000
         LA    R4,1               INDEX                                 59600000
NUMCK    TM    0(R1),NUMBER        ARE THE ZONES VALID                  59680000
         BNO   SIZEINVL            ZONES INVALID                        59760000
         BXLE  R1,R4,NUMCK        CONTINUE CHECKING ZONES               59840000
         XC    WORK,WORK          CLEAR WORK                            59920000
         EX   R7,PACK      PACK VALUE                                   60000000
         CVB   R1,WORK             CONVERT TO RADIX 2                   60080000
         TM    INTERN1,KFORM       WAS VALUE IMPLICIT                   60160000
         BZ    STOREVAL            NO                                   60240000
         NI    INTERN1,RSTKFORM    RESET SW                             60320000
         SLL   R1,MULT1024        MULT BY 1024 MAKE EXPLICIT            60400000
         LA    R7,1(R7)   ADD 1 TO IMPL. CHAR CNT FOR MACH LN           60480000
STOREVAL ST    R1,0(0,RF)         RECORD THE VALUE                      60560000
         BR    RE                                                       60640000
         SPACE 1                                                        60720000
EXPLICIT TM    INTERN1,VAL1RCVD   VALUE 1 RECIEVED YET                  60800000
         BO    OPT700             YES CHECK VALUE 2 RECIEVED            60880000
         LA    R3,6                MAX NO CHARS FOR EXPLICIT FORM       60960000
         B     OPT750                                                   61040000
         SPACE 2                                                        61120000
OPT600   LA    R3,5                MAX.NO.CHARS. FOR IMPLICIT VALUE     61200000
         B     OPT633                                                   61280000
         SPACE 2                                                        61360000
OPT700   LA    R3,7                MAX NO CHARS FOR EXPLICIT FORM       61440000
         B     OPT750                                                   61520000
         SPACE 1                                                        61600000
NOTANY   MVC   OPTIONS+2(BYTES4),NONEM  NO OPTIONS SPECIFIED            61680000
         B     EXIT                                                     61760000
         SPACE 1                                                        61840000
***   THIS SECTION ISOLATES THOSE  OPTIONS SET ON BY GENERATED          61920000
***   DEFAULTS                                                          62000000
***                                                                     62080000
 SPACE 1                                                                62160000
OPT950   NC    SAVATS(BYTES1),0(R3) ISOLATE OPTIONC                     62240000
         BR    RE                                                       62320000
 SPACE 1                                                                62400000
MVOPT2M  MVC   0(0,R8),0(RB)     MOVE OPTION TO HEADER MESSAGE          62480000
COMPOPT  CLC   0(0,RB),1(R3) COMPARE FOR VALID OPTION                   62560000
SCAN     TRT   0(0,RB),TRTBUF      TRT THROUGH THE PARM FIELD           62640000
PACK     PACK  WORK,0(0,RB)  PACK SIZE FOR RADIX CONVERSION             62720000
TSWITCH  TM    SAVATS,0 TEST THE ISOLATED OPTIONS                       62800000
         EJECT                                                          62880000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 62960000
*                                                                     * 63040000
* THESE ARE THE ALLOWABLE OPTIONS.                                    * 63120000
*                                                                     * 63200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 63280000
         SPACE 2                                                        63360000
OPTFIELD EQU   *                  ** LINKAGE EDITOR OPTIONS **          63440000
 SPACE 1                                                                63520000
GENLST2  EQU   *                                                        63600000
         DC    X'04',C'XREF'      CROSS REFERENCE LISTING               63680000
         DC    X'03',C'MAP'       A MAP OF THE OUTPUT MODULE            63760000
         DC    X'04',C'LIST'      LIST THE CONTROL CARDS                63840000
GENLST1  EQU   *                                                        63920000
         DC    X'04',C'RENT'      MODULE IS RE-ENTRANT                  64000000
         DC    X'04',C'REUS'      MODULE IS SERIALLY RE-USEABLE         64080000
         DC    X'04',C'TEST'      MARK MODULE TEST                      64160000
         DC    X'03',C'LET'       DO NOT MARK NOT EXECUTABLE FOR ERRORS 64240000
         DC    X'04',C'XCAL'      IGNORE EXCLUSIVE CALLS IN OVERLAY     64320000
         DC    X'04',C'NCAL'      NO AUTOMALIC CALL LIBRARY             64400000
         DC    X'02',C'OL'        MARK -FETCH ONLY BY LOAD MACRO-       64480000
         DC    X'02',C'NE'        NOT-EDITABLE- NO CESD PRODUCED        64560000
         DC    X'02',C'DC'        1K RECORDS ON SYSLMOD FOR E'15-18-    64640000
         DC    X'04',C'REFR'      MATK -REFETCH AT ANY POINT- ER RECVY  64720000
         DC    X'04',C'TERM'      SUPPORT TERMINAL IN OS/TS             64800000
         DC    X'04',C'CALL'      USE SYSLIB FOR UNRES ERS              64880000
***                                                                     64960000
*** NEGATIVE OPTIONS SUPPORT                                            65040000
***                                                                     65120000
         DC    X'06',C'NOTEST'    DO NOT MARK IN TEST                   65200000
         DC    X'06',C'NOTERM'    NO TERMINAL SUPPORT                   65280000
         DC    X'06',C'NOLIST'    DO NOT LIST CONTROL CARDS             65360000
         DC    X'06',C'NOXREF'    NO CROSS-REFERENCE LISTING            65440000
         DC    X'05',C'NOMAP'     NO MAP OF LOAD MODULE                 65520000
         DC    X'06',C'NORENT'    MODULE NOT REENTRABLE                 65600000
         DC    X'06',C'NOREUS'    MODULE NOT REUSEABLE                  65680000
         DC    X'06',C'NOCALL'    SAME AS NCAL                          65760000
NOTVLD   EQU   *                                                        65840000
         DC    X'04',C'HIAR'      NOTE STORAGE HIARCHIES                65920000
         DC    X'04',C'SIZE'      USE FOLLOWING SIZES FOR EDIT RUN      66000000
         DC    X'04',C'DCBS'      USE DDCARD DCBBLKSIZE IF CAN          66080000
         DC    X'04',C'OVLY'      MODULE IS AN OVERLAY STRUCTURE        66160000
         DC    X'04',C'SCTR'      MARK MODULE BLOCK OR SCATTER LOAD     66240000
         DC    X'FF'              *** END OF OPTIONS ***                66320000
  EJECT                                                                 66400000
SETOPTS  DS    0H                                                       66480000
 SPACE 1                                                                66560000
         OI    APT0,XREF          XREF OPTION                           66640000
         OI    APT0,MAP           MAP OPTION                            66720000
         OI    APT0,LIST          LIST OPTION                           66800000
         OI    PDSE7,RENTREUS     RENT, AND REUS                        66880000
         OI    PDSE7,REUS         REUSABLE REUS OPTION                  66960000
         OI    PDSE7,TEST         TEST OPTION                           67040000
         OI    APT0,LET           LET OPTION                            67120000
         OI    APT0,XCAL          XCAL - EXCLUSIVE CALLS- OPTION        67200000
         OI    APT0,NCAL          NCAL - NO CALL- OPTION                67280000
         OI    PDSE7,OL            OL ONLY LOADABLE OPTION              67360000
         OI    PDSE8,NE           NOT EDITABLE -NE- OPTION              67440000
         NI    PDSE8,DC           DC OPTION                             67520000
         OI    PDSE8,REFR         MARK REFRESHABLE                      67600000
         OI    NEWSW,TERM         INDICATE TERMINAL OUTPUT              67680000
         NI    APT0,CALL          PERFORM AUTOCALL FOR UNRES - ER       67760000
         NI    PDSE7,NOTEST       RESET TEST ATTRIBUTE                  67840000
         NI    NEWSW,NOTERM       NO TERMINAL OUTPUT                    67920000
         NI    APT0,NOLIST        NO LIST                               68000000
         NI    APT0,NOXREF        NO XREF                               68080000
         NI    APT0,NOMAP         NO MAP                                68160000
         NI    PDSE7,NORENT       INDICATE NOT-REENTRANT                68240000
         NI    PDSE7,NOREUS       INDICATE NOT REUSEABLE                68320000
         OI    APT0,NCAL          NO AUTO CALL                          68400000
         OI    NEWSW,HIAR         HIARCHY OPTION                        68480000
         OI    INTERN1,SIZE       SIZEOPTION                            68560000
         OI    APTSWS,DCBS        DCBS OPTION                           68640000
         OI    PDSE7,OVLY         OVLY OPTION                           68720000
         OI    PDSE7,SCTR         SCTR OPTION ON                        68800000
 EJECT                                                                  68880000
         DS    0F                                                       68960000
GENSET1  DC    AL4(2,GENLST1,GENMASK1,3)                                69040000
GENSET2  DC    AL4(GENLST2,GENMASK2,3)                                  69120000
DEFADR   DC    V(IEWLMDEF)                                              69200000
HEADRS   DC    AL1(152),AL3(MESGNO1) LEN AND ADDR OF MSG 1      SA57107 69280021
         DC    AL1(59),AL3(MESGNO2)    LENGTH AND ADDR OF MSG 2   M3028 69360020
         DC    AL1(029),AL3(MESGNO3) LENGTH AND ADDRESS OF MESSAGE 3    69440000
MINVAL2  DC    A(6*1024) MINIMUM VALUE 2                                69520000
MAXVAL2  DC    A(100*1024)                                              69600000
GENMASK1 DC    AL1(RENT,REUS,TEST)                                      69680000
GENMASK2 DC    AL1(XREF,MAP,LIST)                                       69760000
    SPACE 1                                                             69840000
INVMSG   DC    CL7'INVALID'                                             69920000
MESGNO1  DC    X'09'                                                    70000000
IDENT    DC    C'XXXX-LEVEL LINKAGE EDITOR OPTIONS SPECIFIED'           70080000
BLK1     DC    CL1' '  BLANK TO RESET THE LINE                          70160000
OPTIONS  DC    27CL4' '                                         SA57107 70240021
MESGNO2  DC    X'09'                                                    70320000
DEFAULTM DC    CL11' '                 LEADING BLANKS                   70400000
         DC    C'VARIABLE OPTIONS USED -  SIZE=('                       70480000
VALUES   DC    CL16' '                                                  70560000
BLK2     DC    CL1' '  BLANK TO CLEAR LINE                              70800000
GENDFLTS DC    8CL4' '                                                  70880000
MESGNO3  DC    X'09'                                                    70960000
         DC    C'   ** OPTIONS INCOMPATIBLE **'                         71040000
DEFS     DC    CL17'DEFAULT OPTION(S)'                            M3028 71120020
NONEM    DC    C'NONE'                                                  71200000
         DS    0F                                                       71280000
SAVEA    DS    16F  SAVE AREA                                           71360000
         DS    20F   PROVIDE 20 FULL WORDS OF MAINTENANCE AREA *******  71440000
     EJECT                                                              71520000
VRT      DSECT                                                          71600000
         DS    0D                                                       71680000
WORK     DC    1D'0'                                                    71760000
WORK1    DC    1D'0'                                                    71840000
TRTBUF   DC    256XL1'0'                                                71920000
FUNCBYTE DC XL1'0'                                                      72000000
INTERN1 DC XL1'0'                                                       72080000
APTDSECT IEWAPT                                                         72160000
 EJECT                                                                  72240000
DEFDSECT DSECT                                                          72320000
DEFID    DS    CL4 MODULE IDENTIFIER                                    72400000
DEFDSNPT DS    F   DESIGN POINT                                         72480000
DEFVAL1  DS    F   DEFAULT VALUE 1                                      72560000
DEFVAL2  DS    F   DEFAULT VALUE 2                                      72640000
DEFNAME  DS    CL4 EDITOR NAME F44,F88,F128,F256                        72720000
         END                                                            75300000
