         TITLE    'OUT'                                                 00080021
*                                                                     * 00160021
*STATUS:CHANGE LEVEL                                                  * 00240021
*                                                                     * 00320021
*FUNCTION/OPERATION:                                                  * 00400021
*        1- OUTPUT THE COMPOSITE EXTERNAL SYMBOL DICTIONARY(EDITABLE) * 00480021
*        2- BUILDS HALF EXTERNAL SYMBOL DICTIONARY                    * 00560021
*        3- BUILDS AND OUTPUTS CONTROL RECORD AND SEGTAB (1ST TXT) WHEN 00640021
*              THE PROGRAM IS IN OVERLAY                              * 00720021
*        4- BUILDS AND OUTPUTS THE SCATTER/TRANSLATION RECORDS WHEN   * 00800021
*              THE PROGRAM IS IN SCATTER                              * 00880021
*        5- READS IN THE TEXT AND RLD NOTE LISTS                      * 00960021
*        6- DETERMINES THE CONTROL SECTIONS WITH THE HIGHEST ESD ID   * 01040021
*              PER SEGMENT                                            * 01120021
*        7) INITIALIZES FOR 2ND PASS - IEWLKSCD                       * 01200021
*           A - SET 2 DECBS TO COMPLETE STATUS                        * 01280021
*           B - COMPUTES END ADDRESSES FOR 3 RLD BUFFERS              * 01360021
*           C - SETS CONTROL INFORMATION (16 BYTES) TO ZERO  IN CONTROL 01440021
*               RECORD BUFFER                                         * 01520021
*           D - PASSES PARAMETERS IN 3 GENERAL PURPOSE REGISTERS      * 01600021
*           E - COMPUTES END OF HESD ADDRESS                          * 01680021
*           F - CONVERTS TXTIO TABLE CURRENT NO.BYTES TO NO. OF ENTRYS* 01760021
*           G - SETS TTR LIST TO ZERO                                   01840021
*                                                                       01920021
*ENTRY POINT  IEWLMOUT - CONTROL SECTION NAME                         * 02000021
*                                                                     * 02080021
*INPUT:  TABLES - LISTED BELOW                                        * 02160021
*                                                                     * 02240021
*OUTPUT: TABLES - LISTED BELOW                                        * 02320021
*                                                                     * 02400021
*EXTERNAL ROUTINES: IEWLELOG - ERROR DIAGNOSTIC ROUTINE               * 02480021
*                                                                     * 02560021
*EXITS - NORMAL   IEWLMSCD - SECOND PASS PROCESSOR                    * 02640021
*                                                                     * 02720021
*        ERRORS   IEWLMFNL - FINAL PROCESSOR - WHEN THERE IS NO TEXT IN 02800021
*              THE OUTPUT LOAD MODULE THE SECOND PASS IS BY PASSED    * 02880021
*TABLES/WORK AREA:                                                    * 02960021
*                                                                     * 03040021
*        1- ALL PURPOSE TABLE                                         * 03120021
*        2- COMPOSITE EXTERNAL SYMBOL DICTIONARY                      * 03200021
*        3- RELOCATION CONSTANT TABLE                                 * 03280021
*        4- SEGMENT TABLE ONE                                         * 03360021
*        5- TEXT NOTE LIST 1 AND 2                                    * 03440021
*        6- RLD  NOTE LIST 1 AND 2                                    * 03520021
*        7- SCATTER AND TRANSLATION TABLES                            * 03600021
*        8- HALF EXTERNAL DICTIONARY                                  * 03680021
*                                                                     * 03760021
*ATTRIBUTES:                                                          * 03840021
*                                                                     * 03920021
*NOTES:                                                               * 04000021
*                                                                     * 04080021
*                                                                     * 04160021
IEWLMOUT CSECT                                                          04240021
*A109000,118000,122000,176000,616000,628000                      S21016 04320021
*C163000,165000                                                  S21016 04400021
*A162400,700000,926400,984000                                    S21016 04420021
*C936800                                                         S21016 04440021
*C938400                                                          M1602 04460021
*C219200-220000                                                  A53196 04470021
*A220800                                                         A53196 04472021
*A231200                                                         A53196 04474021
*A233600                                                         A53196 04476021
*I271200                                                        SA65083 04478000
*********************************************************************** 04480021
*                                                                       04560021
*              INTERMEDIATE OUTPUT PROCESSOR                            04640021
*                                                                       04720021
*********************************************************************** 04800021
*              REGISTER ASSIGNMENT                                    * 04880021
*********************************************************************** 04960021
ERRCODE  EQU   0                        ERR CODE                        05040021
NOTL1MXE EQU   0                        MAXIMUM NO.ENTRIES IN NOTE LST1 05120021
WRITECT  EQU   0                                                        05200021
ENDTXTIO EQU   0      USED ON BUILD SCATR/TRANS LOOP                    05280021
REG0     EQU   0                                                        05360021
REG1     EQU   1                                                        05440021
TEMP4    EQU   1                                                        05520021
NOTL1CTE EQU   1                        CURRENT NO.ENTRIES IN NOTE LST1 05600021
TTRREG   EQU   1                                                        05680021
APT      EQU   2                                                        05760021
ADTXTIOT EQU   3      USED ON BUILD SCATR/TRANS LOOP                    05840021
CESDCRCT EQU   3                                                        05920021
IOCTLADD EQU   3                        ADD OF IO CONTROL TABLE         06000021
TEMP5    EQU   3                        TEMPORARY REGISTER              06080021
CESDADD  EQU   4                                                        06160021
TRANSADD EQU   4                        ADD OF TRANSLATION  TABLE       06240021
IOCTLCTB EQU   4                        CURRENT NO.BYTES IN IO CTL TBL  06320021
TXTIOADD EQU   4                        ADD OF TXT IO TABLE             06400021
HESDCT   EQU   5                                                        06480021
NOTL2ADD EQU   5                        ADD OF NOTE LIST 2              06560021
TXTIOCT  EQU   5                        CT OF CURRENT NO BYTES IN TXTIO 06640021
BUFFRSIZ EQU   6                        SIZE OF NOTE LIST 1             06720021
CESDID   EQU   6                                                        06800021
SEGCT    EQU   6                        SEGMENT NO.                     06880021
HIARAD   EQU   6    USED IN LOOP TO BUILD SCTR TABLE IF HIAR SPECIFIED  06960021
HIIDTAB  EQU   7                        ADD OF HI ID TABLE              07040021
WRITEADD EQU   7                                                        07120021
REG7     EQU   7                                                        07200021
INDCBADD EQU   8                        ADDRESS OF INT. DCB             07280021
SCATTADD EQU   WRITEADD                                                 07360021
NOTL1ADD EQU   8                        ADD OF NOTE LIST 1              07440021
OTDCBADD EQU   8                        ADDRESS OF OUT. DCB             07520021
TEMPRTN  EQU   8                        TEMP RETURN REG            DISP 07600021
DCBADD   EQU   9                                                        07680021
RETPARM  EQU   9                        NO ENTRIES IN NOTE LIST 2       07760021
EVENREG  EQU   10                       EVEN REG OF AN EVEN ODD PAIR    07840021
HESDADD  EQU   10                                                       07920021
WORK1    EQU   10                       WORK REG                        08000021
ODDREG   EQU   11                       ODD  REG OF AN EVEN ODD PAIR    08080021
RCTADD   EQU   11                                                       08160021
BASE     EQU   12                                                       08240021
BYTSPERE EQU   13                       NO.OF BYTES PER ENTRY           08320021
SAVEAREA EQU   13                                                       08400021
TEMP1    EQU   13                                                       08480021
TEMPREG  EQU   X'D'                                                     08560021
REG14    EQU   14                                                       08640021
RETURN   EQU   14                       RETURN REGISTER                 08720021
TEMP2    EQU   14                                                       08800021
REG15    EQU   15                                                       08880021
BRANCH   EQU   15                       BRANCH REGISTER                 08960021
FIFTEEN  EQU   15                                                       09040021
TEMP3    EQU   15                                                       09120021
         SPACE 1                                                 S21016 09200021
*****************REGISTERS USED BY SUBROUTINE IDROUT*************S21016 09280021
         SPACE 1                                                 S21016 09360021
TABADD   EQU   10                      POINTER TO BEGINNING OF   S21016 09440021
*                                      AN IDR DATA TABLE         S21016 09520021
TABEND   EQU   11                      POINTER TO END OF AN IDR  S21016 09600021
*                                      DATA TABLE                S21016 09680021
DATAPTR  EQU   4                       POINTER TO BEGINNING OF   S21016 09760021
*                                      DATA IN AN IDR DATA TABLE S21016 09840021
DATALEN  EQU   5                       LENGTH OF DATA IN AN IDR  S21016 09920021
*                                      DATA TABLE                S21016 10000021
RECLEN   EQU   3                       LENGTH OF DATA IN ONE     S21016 10080021
*                                      RECORD (USED AS DECREMENT S21016 10160021
*                                      FOR UPDATING DATALEN)     S21016 10240021
MVCPTR   EQU   3                       POINTER TO DESTINATION IN S21016 10320021
*                                      EXECUTED MOVE             S21016 10400021
DATASIZE EQU   4                       LENGTH OF DATA IN A       S21016 10480021
*                                      RECORD                    S21016 10560021
ZPCOUNT  EQU   5                       NUMBER OF ENTRIES IN      S21016 10640021
*                                      AN SPZAP DATA RECORD      S21016 10720021
TIME     EQU   0                       TIME OF DAY RETURNED BY   S21016 10800021
*                                      TIME MACRO                S21016 10880021
DATE     EQU   1                       DATE RETURNED BY TIME     S21016 10960021
*                                      MACRO                     S21016 11040021
ZAPCMPR  EQU   4                       COMPARISON VALUE USED TO  S21016 11120021
*                                      DETERMINE WHETHER AN      S21016 11200021
*                                      EXTRA SPZAP IDR SHOULD    S21016 11280021
*                                      BE CREATED                S21016 11360021
*********************************************************************** 11440021
*              MASKS                                                  * 11520021
*********************************************************************** 11600021
ESDWTBIT EQU   X'01'                                                    11680021
HIAROP   EQU   X'04'                    HIAR MASK                       11760021
INC      EQU   4                                                        11840021
SDPCCM   EQU   X'02'                                                    11920021
SCATTBIT EQU   X'04'                    SCATTER MASK               DISP 12000021
OVRLYBIT EQU   X'20'                    OVERLAY MASK               DISP 12080021
CESDCNTL EQU   X'20'                                                    12160021
ESDWTOFF EQU   X'FE'                                                    12240021
         SPACE 1                                                 S21016 12320021
*******MASKS AND IMMEDIATE BYTES USED BY SUBROUTINE IDROUT*******S21016 12400021
         SPACE 1                                                 S21016 12480021
CHAIN    EQU   X'40'                   CHAIN BIT IN DATA COUNT   S21016 12560021
*                                      FIELD OF SPZAP TYPE IDR   S21016 12640021
ZAPMAX   EQU   X'53'                   VALUE OF COUNT FIELD IN   S21016 12720021
*                                      SPZAP TYPE IDR WHEN ALL   S21016 12800021
*                                      ENTRIES ARE USED AND      S21016 12880021
*                                      CHAIN BIT IS ON           S21016 12960021
NOZPDATA EQU   X'00'                   VALUE OF COUNT FIELD IN   S21016 13040021
*                                      SPZAP TYPE IDR WHEN NO    S21016 13120021
*                                      ENTRIES ARE USED AND      S21016 13200021
*                                      CHAIN BIT IS OFF          S21016 13280021
LASTIDR  EQU   X'80'                   FLAG IN IDR SUBTYPE FIELD S21016 13360021
*                                      TO INDICATE THE LAST IDR  S21016 13440021
*                                      FOR AN OUTPUT LOAD MODULE S21016 13520021
TRNSTYPE EQU   X'04'                   SUBTYPE INDICATOR FOR     S21016 13600021
*                                      IDR'S WITH TRANSLATOR     S21016 13680021
*                                      DATA                      S21016 13760021
USERTYPE EQU   X'08'                   SUBTYPE INDICATOR FOR     S21016 13840021
*                                      IDR'S WITH USER-DATA      S21016 13920021
TRUDMAX  EQU   X'FF'                   MAXIMUM BYTE COUNT FOR    S21016 14000021
*                                      TRANSLATOR AND USER-DATA  S21016 14080021
*                                      IDR'S                     S21016 14160021
ZEROFILL EQU   X'00'                   ZEROES FOR PADDING        S21016 14240021
ON       EQU   X'01'                   MASK FOR SWITCH           S21016 14320021
*                                      INDICATING A TEMPORARY    S21016 14400021
*                                      NEEDED FOR A MOVE         S21016 14480021
OFF      EQU   X'FE'                   IMMEDIATE BYTE TO TURN    S21016 14560021
*                                      OFF 'TEMPORARY NEEDED'    S21016 14640021
*                                      SWITCH                    S21016 14720021
*********************************************************************** 14800021
*              DISPLACEMENTS                                          * 14880021
*********************************************************************** 14960021
LASTESD  EQU   X'08'                   MASK FOR LAST ESD RCD IN MODULE  15040021
         SPACE 1                                                 S21016 15120021
**********SYMBOLIC DISPLACEMENTS AND LENGTHS USED BY*************S21016 15200021
*********************SUBROUTINE IDROUT***************************S21016 15280021
         SPACE 1                                                 S21016 15360021
HDRLEN   EQU   4                       LENGTH OF IDR SPZAP       S21016 15440021
*                                      HEADER                    S21016 15520021
ZAPLEN   EQU   247                     LENGTH OF SPZAP DATA IN   S21016 15600021
*                                      ONE RECORD                S21016 15680021
ZPLEN    EQU   246                     LENGTH OF SPZAP DATA - 1  S21016 15760021
*                                      (USED TO PAD WITH ZEROES) S21016 15840021
LOC      EQU   0                       NULL OFFSET               S21016 15920021
ZPRECLEN EQU   251                     LENGTH OF AN IDR SPZAP    S21016 16000021
*                                      RECORD                    S21016 16080021
UNIT     EQU   1                       OFFSET OF 1 BYTE          S21016 16160021
LEN2     EQU   2                       TWO-BYTE LENGTH           S21016 16240021
LEN3     EQU   3                       THREE-BYTE LENGTH         S21016 16260021
LEN4     EQU   4                       FOUR-BYTE LENGTH          S21016 16280021
LEN8     EQU   8                       EIGHT-BYTE LENGTH         S21016 16320021
CMPRSIZE EQU   14                      COMPARISON VALUE FOR MAX  S21016 16400021
*                                      NUMBER OF ENTRIES ALLOWED S21016 16480021
*                                      IN AN IDR SPZAP RECORD    S21016 16560021
*                                      BEFORE ADDING AN ADDI-    S21016 16640021
*                                      TIONAL SPARE RECORD       S21016 16720021
LKRECLEN EQU   18                      LENGTH OF IDR LKED RECORD S21016 16800021
LKLEN    EQU   15                      LENGTH OF IDR LKED DATA   S21016 16880021
*                                      EXCEPT FOR DATE OF LKED   S21016 16960021
DATELEN  EQU   3                       LENGTH OF PACKED DEC DATE S21016 17040021
*                                      RETURNED BY TIME MACRO    S21016 17120021
TRUDLEN  EQU   253                     GREATEST AMOUNT OF USER   S21016 17200021
*                                      OR TRANSLATOR DATA WHICH  S21016 17280021
*                                      CAN GO ONTO ONE RECORD    S21016 17360021
TURECLEN EQU   256                     MAXIMUM TRANSLATOR AND    S21016 17440021
*                                      USER-DATA RECORD SIZE     S21016 17520021
ADDLEN   EQU   3                       THREE-BYTE ADJUSTMENT FOR S21016 17600021
*                                      DETERMINING BYTE COUNT OF S21016 17680021
*                                      TRANSLATOR AND USER-DATA  S21016 17760021
*                                      RECORDS SHORTER THAN MAX  S21016 17840021
*********************************************************************** 17920021
*              SECOND PASS DISPLACEMENTS,REGISTERS AND MASKS          * 18000021
*********************************************************************** 18080021
NOEDIT2P EQU   X'02'                   NOT EDIT MASK FOR 2ND PASS       18160021
NOTEDIT  EQU   X'08'                   NOT EDITABLE MASK                18240021
         EXTRN IEWLCUDB                                                 18320021
         EXTRN IEWLCMDB                                                 18400021
         EXTRN SEGLNTAB                                                 18480021
*              OUTPUT CESD AND  BUILD HESD                              18560021
         USING OUT00100+2,BASE                                          18640021
         USING APTDSECT,APT                                             18720021
OUT00100 BALR  BASE,0                                                   18800021
*********************************************************************** 18880021
*              BUILD HESD & OUTPUT CESD(IF PGM IS NOT- NOT EDITABLE   * 18960021
*              ALSO MARK LAST ESD RECORD IF THERE IS NO TEXT          * 19040021
*********************************************************************** 19120021
         BC    15,MODID+6              BRANCH AROUND MODULE IDENT       19200021
MODID    DC    C'02MOUT'                                                19280021
         TM    APT0,X'20'              IS MAP REQUESTED                 19360021
         BC    1,OUT00105              YES                              19440021
         TM    APT0,X'40'              NO--IS XREF REQUESTED            19520021
         BC    8,OUT00110              NO                               19600021
         TM    NEWSW,X'20'             YES--ARE RLDS IN CORE            19680021
         BC    1,OUT00110              NO--DON'T DO XREF NOW            19760021
OUT00105 L     REG15,MAPAD             YES--GO TO MAP/XREF              19840021
         OI    NEWSW,X'40'             SET ENTRY FROM INTERMEDIATE BIT  19920021
         BALR  REG14,REG15                                              20000021
         NI    NEWSW,X'BF'             TURN OFF INTERMEDIATE ENTRY BIT  20080021
OUT00110 L     CESDADD,CHESD      LOAD CESD ADDRESS                     20160021
         LA    CESDID,1                 SET FIRST ID TO 1               20240021
         L     HESDADD,HESD       HESD ADDRESS                          20320021
         OI    APT1,ESDWTBIT      SET FIRST ESD WRITE ON FOR NOTE       20400021
         LH    CESDCRCT,ENCDC     CURR NO CESD ENTRIES                  20480021
         OI    APT3,NOEDIT2P                                            20560021
OUT00200 LA    FIFTEEN,15               PUT 15  IN FIFTEEN              20640021
         XC    8(4,CESDADD),8(CESDADD) SET HI WORD OF CONTROL TO ZERO   20720021
         SR    CESDCRCT,FIFTEEN         REMAING NO. CESD ENTRIES TO WT  20800021
         BC    2,OUT00300              BRANCH IF REMAINDER GTR THAN 0   20880021
         AR    FIFTEEN,CESDCRCT         REMAINDER LESS 0 /RESTORE CT    20960021
         OC    ENTOC(2),ENTOC     IS THERE ANY TEXT IN MODULE           21040021
         BC    4,OUT00300              YES                              21120021
         OI    8(CESDADD),LASTESD      NO/SET LAST RCD IN MODULE IND    21200021
OUT00300 LR    HESDCT,FIFTEEN           COUNT OF PRESENT CESD WT COUNT  21280021
         SLL   FIFTEEN,4                16(Y); Y= NO CESD LINES TO WT.  21360021
         STH   FIFTEEN,14(CESDADD)      PUT BYTE CT IN CONTROL          21440021
         STH   CESDID,12(CESDADD)       PUT ESDID IN CONTROL            21520021
         OI    8(CESDADD),CESDCNTL      SET HI BYTE TO 20 (ESD ITEM)    21600021
         LA    WRITECT,8(FIFTEEN)       INC WT BYTE CT BY 8             21680021
         LA    WRITEADD,8(CESDADD)      INC WT BYTE ADD BY 8            21760021
         TM    PDSE8,NOTEDIT      IS MODULE NOT EDITABLE                21840021
         BO    OUT00320           IF YES, DO NOT TURN 2ND S21016,A53196 21920021
*                                          PASS NE SWITCH S21016,A53196 22000021
         NI    APT3,X'FD'         SET NOT EDITABLE OFF                  22080021
         B     OUT00350                BRANCH TO PUT OUT IDR     A53196 22130021
OUT00320 TM    APTSW2,IDROUT           TEST IDR OUTPUT ENABLED   A53196 22140021
         BNO   OUT00400                IF NOT, BYPASS IDR OUTPUT A53196 22150021
OUT00350 BAL   TEMPRTN,OUT00990        GO TO WRITE/CHECK/NOTE    S21016 22160021
*                                      SUBROUTINE                S21016 22240021
         LTR   TTRREG,TTRREG            TTR EXISTS ON FIRST WT/ESD&SCAT 22320021
         BC    8,OUT00400               BRANCH ON ALL OTHER WTS         22400021
         ST    TTRREG,CTTR        SAVE TTR OF CESD                      22480021
OUT00400 LA    HESDADD,8(HESDADD)       INCREMENT HESD ADDRESS PTR      22560021
         LA    CESDADD,16(CESDADD)      INCREMENT CESD ADDRESS PTR      22640021
         LM    TEMP1,TEMP2,8(CESDADD)   LOAD LAST 4 BYTES OF A CESD LIN 22720021
         STM   TEMP1,TEMP2,0(HESDADD)   STORE IT IN HESD                22800021
         BCT   HESDCT,OUT00400          BRANC IF LOOP NOT DONE          22880021
         LA    CESDID,15(CESDID)        INC ESDID BY 15                 22960021
         LTR   CESDCRCT,CESDCRCT        HAVE ALL CESD LINES BEEN WRITEN 23040021
         BC    2,OUT00200               NO /CONTINUE WRITE OUT          23120021
         TM    APTSW2,IDROUT           TEST IDR OUTPUT ENABLED   A53196 23170021
         BNO   OUT00450                BRANCH IF NOT             A53196 23180021
         BAL   TEMPRTN,OUTIDR          AFTER LAST CESD LINE IS   S21016 23200021
*                                      WRITTEN, GO TO PROCESS    S21016 23280021
*                                      IDR'S                     S21016 23360021
OUT00450 EQU   *                       IDR OUTPUT BYPASS         A53196 23410021
         XC    8(8,HESDADD),8(HESDADD) SET LINE AFTER LAST = 0          23440021
*********************************************************************** 23520021
*              IF THERE IS NO TEXT IN MODULE BY PASS 2ND PASS/GO TO   * 23600021
*              FINAL PROCESSOR - ALSO PRINT MESSAGE - NO TEXT         * 23680021
*********************************************************************** 23760021
OUT00525 SR    TEMP1,TEMP1                                              23840021
         CH    TEMP1,ENTOC        ANY ENTRIES IN TXT ID TBL             23920021
         BC    8,OUT00970              NO / NO TXT / GO TO FINAL PROC   24000021
*********************************************************************** 24080021
*              TEST FOR OVERLAY - YES GO TO BUILD  SEGTAB CONTROL RCD * 24160021
*              AND SEGTAB RECORD  AND WRITE OUT BOTH                  * 24240021
*********************************************************************** 24320021
OUT00550 TM    PDSE7,OVRLYBIT     IS PROGRAM IN OVERLAY                 24400021
         BC    1,OUT01000               YES/ GO OUT PUT SEGTAB RCDS     24480021
*********************************************************************** 24560021
*              TEST FOR SCATTER - YES -BUILD SCATTER / TRANSLATION    * 24640021
*              TABLES AND OUTPUT BOTH AS ONE ENITY- OUT IN RECORDS    * 24720021
*              OF 1024 DEC BYTES                                      * 24800021
*********************************************************************** 24880021
         TM    PDSE7,SCATTBIT     IS PROGRAM IN SCATTER                 24960021
         BC    1,OUT02000               YES/ GO WRITE SCATTER RCD       25040021
*********************************************************************** 25120021
*              READ IN TEXT NOTE LIST AND RLD NOTE LIST                 25200021
*********************************************************************** 25280021
*              INITIALIZE REGS FOR TXT NOTE LIST READ IN                25360021
*********************************************************************** 25440021
OUT00560 LA    BYTSPERE,7              7 BYTES/ENTRY IN TXT NOTELIST    25520021
         LA    IOCTLADD,IOCT      ADDRESS OF TXT IO  CTL TBL            25600021
         LH    IOCTLCTB,ENITC     CURR NO BYTES IN TXT IO CTL TBL       25680021
         L     NOTL1ADD,TNT1      TXT NOTELIST 1 ADDR                   25760021
         L     NOTL2ADD,TNLS2          TXT NOTELIST 2 ADD               25840021
         LH    NOTL1CTE,ENT1C     CURR NO ENTRIES IN TXT NOTLST 1       25920021
         LH    NOTL1MXE,ENT1X     MAX NO ENTRIES IN TXT NOTLST 1        26000021
         BAL   RETURN,OUT00600          GO TO TXT RLD READIN ROUTINE    26080021
         STH   RETPARM,ENT2C      STORE CURR NO ENTRIES TXT NLT 2       26160021
*********************************************************************** 26240021
*              INITIALIZE REGS FOR RLD NOTE LIST READ IN                26320021
*********************************************************************** 26400021
         LA    BYTSPERE,9              9 BYTES/ENTRY IN RLD NOTELIST    26480021
         LA    IOCTLADD,IOCT+12   ADDRESS OF RLD IO CTL TBL             26560021
         LH    IOCTLCTB,ENIRC                                           26640021
         L     NOTL1ADD,RNT1      ADDR RLD  NOTELIST 1                  26720021
         L     NOTL2ADD,RNLS2     ADDR RLD  NOTELIST 2                  26800021
         LH    NOTL1CTE,ENR1C     CURRNT NO. ENTRIES IN RLD NOTELIST 1  26880021
         LH    NOTL1MXE,ENR1X     MAX NO. OF ENTRIES IN RLD NOTELIST 1  26960021
         BAL   RETURN,OUT00600          GO TO TXT- RLD READ IN RT       27040021
         STH   RETPARM,ENR2C      STORE CURRENT NO. ENTRIES IN RLDNL2   27120021
         STH   RETPARM,ENR1C      DITTO RLDNL1 FOR MAP/XREF     SA65083 27170000
**********************************************************************$ 27200021
*              DETERMINE ID OF LAST TXTIOT ENTRY PER SEGMENT          * 27280021
*              ALSO SAVE HIGEST SEGMENT NUMBER CONTAINING TEXT          27360021
**********************************************************************$ 27440021
*                                                                       27520021
OUT00570 SR    TEMP4,TEMP4              ZERO CT OF TXTIO FOR LOOP       27600021
         L     HIIDTAB,ADHIID                                           27680021
         L     HIIDTAB,0(HIIDTAB)      ADDRESS OF HI ID TABLE           27760021
         LR    TEMP1,HIIDTAB        GET START OF TABLE ADDRESS          27840021
         XC    0(256,TEMP1),0(TEMP1)   CLEAR 1ST HALF OF TABLE          27920021
         XC    256(256,TEMP1),256(TEMP1)   CLEAR 2ND HALF OF TABLE      28000021
OUT00580 L     TXTIOADD,TXTIO     ADD OF  TXTIO TABLE                   28080021
         AR    TXTIOADD,TEMP4           ADD OF NEXT ID IN TXTIO TABLE   28160021
         TM    2(TXTIOADD),X'20'        IS IT OUT OF ORDER TXT          28240021
         BC    1,OUT00581               YES--TEST END OF TXTIOT LOOP    28320021
         MVC   WORD(2),0(TXTIOADD)      MOVE ID FROM TXTIO TO WORK      28400021
         LH    TEMP1,WORD               LOAD ID                         28480021
         LR    TEMP2,TEMP1              SAVE ID                         28560021
         SLL   TEMP2,3                  RELATIVE HESD ADD FOR THIS ID   28640021
         A     TEMP2,HESD         ABSOLUTE HESD ADR FOR THIS ID         28720021
         SR    TEMP3,TEMP3              ZERO SEGMENT NO REG             28800021
         IC    TEMP3,4(TEMP2)           THIS ID LIES IN THIS SEGMENT    28880021
         AR    TEMP3,TEMP3              DOUBLE SEG NO - REL. ADD TOHIID 28960021
         LH    WORK1,0(HIIDTAB,TEMP3)   GET CURRENT HI-ID IN TABLE      29040021
         LTR   WORK1,WORK1              WAS THERE ANY PREVIOUS ID       29120021
         BC    8,NOPRVID          BR IF THIS IS THE FIRST ID FOR SEG.   29200021
         SLL   WORK1,3                  CALCULATE HESD ADDRESS          29280021
         A     WORK1,HESD               FOR THIS ID                     29360021
         CLC   1(3,TEMP2),1(WORK1)      IS NEW ID LOCATED AT A HIGHER   29440021
*                                       ADDRESS THAN PREVIOUS ID IN SEG 29520021
         BC    12,OUT00581        BR IF NOT AT A HIGHER ADDRESS         29600021
NOPRVID  EQU   *        THIS SHOULD BE AT THE STORE ID INSTRUCTION      29680021
         STH   TEMP1,0(HIIDTAB,TEMP3)   SAVE LAST TXTIOT ENTRY FOR SEG  29760021
OUT00581 LA    TEMP4,4(TEMP4)      INCREMENT TEXTIO BYTE COUNT          29840021
         CH    TEMP4,ENTOC        IS CURR. CT =  SAVED CT               29920021
         BC    4,OUT00580               NO - GO TO CONTINUE LOOP        30000021
         SR    TEMP1,TEMP1                                              30080021
         LH    SEGCT,CSNO         TOTAL CURRENT NO. SEGMENTS            30160021
OUT00582 LA    TEMP1,1(TEMP1)           INC BY 1 (CURRENT SEG)          30240021
         LR    TEMP3,TEMP1              SAVE CURRENT SEG NO.            30320021
         AR    TEMP3,TEMP3             DOUBLE CURR SEG NO               30400021
         LH    TEMP2,0(HIIDTAB,TEMP3)   LAST TXTIOT ENTRY FOR THIS SEG  30480021
         LTR   TEMP2,TEMP2              IS ID = 0                       30560021
         BC    8,OUT00583               YES  NO TXT IN THIS SEGMENT     30640021
         STH   TEMP1,ENSPC        SAVE HI SEG WITH TEXT                 30720021
         SLL   TEMP2,3                  MULT BY 8                       30800021
         A     TEMP2,HESD         ADDRESS OF HESD ENTRY                 30880021
         OI    0(TEMP2),X'40'     SET LAST TXTIOT ENTRY ON IN HESD      30960021
OUT00583 BCT   SEGCT,OUT00582           BRANCH IF LOOP NOT DONE         31040021
*********************************************************************** 31120021
* AT THIS POINT SECOND PASS INITIALIZATION IS PERFORMED                 31200021
*********************************************************************** 31280021
OUT00575 L     REG7,TTRLIST       ADDRESS OF TTR LIST                   31360021
         BCT   TEMP1,OUT00576     BRANCH TO ZERO TTR LIST               31440021
         BC    15,OUT00577        BRANCH AROUND ZEROING TTR LIST        31520021
OUT00576 SLL   TEMP1,2       CURR NO SEGMENTS -1 TIMES 4                31600021
*                                     RESTORE SEGMENT CT IF IN OVERLAY  31680021
         LA    TEMP1,3(TEMP1)     UPDATE COUNT FOR EX INSTRUCTION       31760021
         LA    REG1,256                                                 31840021
OUT00578 SR    TEMP1,REG1              CHECK FOR 256 OR MORE BYTES      31920021
         BC    4,OUT00579              NO                               32000021
         XC    0(256,REG7),0(REG7)     YES--CLEAR 256 BYTES             32080021
         AR    REG7,REG1               INCREMENT BY 256                 32160021
         BC    15,OUT00578                                              32240021
OUT00579 AR    TEMP1,REG1              RESTORE COUNT                    32320021
         EX    TEMP1,ZEROHIID          ZERO TTR L                       32400021
OUT00577 SR    REG0,REG0                                                32480021
         LA    WORK1,9                                                  32560021
         MH    WORK1,ENR2C                                              32640021
         A     WORK1,RNLS2                                              32720021
         ST    WORK1,SPACES+48         RLD NOTELIST LAST ENTRY ADDR.    32800021
         L     WORK1,TXTIO                                              32880021
         AH    WORK1,ENTOC                                              32960021
         SH    WORK1,FOUR                                               33040021
         ST    WORK1,SPACES+44         TEXT I/O TABLE LAST ENTRY ADDR   33120021
         LH    WORK1,ENCDC                                              33200021
         SLL   WORK1,3                                                  33280021
         A     WORK1,HESD                                               33360021
         ST    WORK1,SPACES+52         HESD LAST ENTRY ADDR             33440021
         LH    REG1,ENSPX              SEGTAB ID                        33520021
         CR    REG1,REG0                                                33600021
         BC    8,SCDGETID                                               33680021
OUTSCDIN SLL   REG1,3                                                   33760021
         A     REG1,HESD                                                33840021
         LA    REG1,8(0,REG1)          ADDR. FIRST HESD ENTAB ENTRY     33920021
         L     BRANCH,TPASSVCN                                          34000021
         BR    BRANCH                  GO TO SECOND PASS                34080021
SCDGETID LH    REG1,ENCDC              LAST ID                          34160021
         B     OUTSCDIN                                                 34240021
*********************************************************************** 34320021
*                                                                       34400021
*              TXT - RLD MOVE AND READ IN ROUTINE                       34480021
*                                                                       34560021
*********************************************************************** 34640021
OUT00600 STM   RETURN,BRANCH,SAVE1415                                   34720021
         SRL   IOCTLCTB,2               NO.OF BUFFERINGS                34800021
         LR    EVENREG,IOCTLCTB         NO,OF NOTE LIST BUFFERINGS      34880021
         LR    ODDREG,NOTL1MXE          NO.OF ENTRIES PER BUFFERING     34960021
         MR    EVENREG,EVENREG          TOTAL NO.OF BUFFER ENTRIES      35040021
         LA    RETPARM,0(ODDREG,NOTL1CTE)                               35120021
         LR    EVENREG,BYTSPERE         NO BYTES PER ENTRY              35200021
         LR    ODDREG,NOTL1MXE          MAX NO.NOTE LIST 1 ENTRIES      35280021
         MR    EVENREG,EVENREG          NO. BYTES IN BUFFER (NOTE LST1) 35360021
*                                       ANS IN ODDREG                   35440021
         LR    BUFFRSIZ,ODDREG          SAVE BUFFER SIZE                35520021
         LR    EVENREG,IOCTLCTB         NO.OF BUFFERINGS                35600021
         MR    EVENREG,EVENREG          RELAITIVE ADD  OF WHERE TO MOVE 35680021
*                                       CONTENTS OF NOTE LIST1-ANS-ODDR 35760021
         ST    NOTL2ADD,SAVEWORD                                        35840021
         AR    NOTL2ADD,ODDREG          ADD OF WHERE TO 1PT OF NL1TONL2 35920021
         LR    EVENREG,BYTSPERE         NO,BYTES PER ENTRY IN NOTE LIST 36000021
         LTR   ODDREG,NOTL1CTE          NO.ENTRIES IN NOTE LIST 1       36080021
         BC    8,OUT00850                                               36160021
         MR    EVENREG,EVENREG          CURRENT NO BYTES IN NOTE LIST 1 36240021
         SR    TEMP3,TEMP3                                              36320021
OUT00700 LA    TEMP1,256                                                36400021
         SR    ODDREG,TEMP1             REMAINDER TO MOVE TO NOTE LIST2 36480021
         BC    10,OUT00800              BRANCH IF REMAINDER GTR,=  0    36560021
         AR    TEMP1,ODDREG             RESTORE NO.BYTES TO MOVE        36640021
OUT00800 BCTR  TEMP1,0                  DECREMENT BY 1 FOR EX MOVE INST 36720021
         LA    TEMP2,0(NOTL2ADD,TEMP3)  ADD.OF WHERE TO MV NL1 TO NL2   36800021
         EX    TEMP1,MOVEINST           MOVE NOTE LIST 1 TO NOTE LIST 2 36880021
         LA    TEMP3,256(TEMP3)         INC BY 256                      36960021
         LA    NOTL1ADD,256(NOTL1ADD)   INC ADD OF NOTE LIST TO MOVE AD 37040021
         LTR   ODDREG,ODDREG            ANY MORE NOTE LST TO BE MOVED   37120021
         BC    2,OUT00700               BRANCH ON YES - GO TO MOVE      37200021
OUT00850 LTR   IOCTLCTB,IOCTLCTB                                        37280021
         BC    8,OUT00950                   NO                          37360021
         L     NOTL2ADD,SAVEWORD                                        37440021
OUT00900 LA    SAVEAREA,SPACES    SAVE AREA FOR POINT MACRO             37520021
         L     INDCBADD,DCBINTER        INTER DCB ADDRESS               37600021
*********************************************************************** 37680021
*              POINT TO NEXT RECORD TO READ                           * 37760021
*********************************************************************** 37840021
         POINT (INDCBADD),(IOCTLADD)                                    37920021
*                                                                     * 38000021
*              READ NEXT RECORD                                         38080021
*********************************************************************** 38160021
         READ  DECB,SF,(INDCBADD),(NOTL2ADD),(BUFFRSIZ)                 38240021
*********************************************************************** 38320021
*              CHECK FOR COMPLETION OF READ                           * 38400021
*********************************************************************** 38480021
         CHECK DECB                                                     38560021
         LA    IOCTLADD,4(IOCTLADD)     ADD OF NEXT TTR                 38640021
         AR    NOTL2ADD,BUFFRSIZ                                        38720021
         BCT   IOCTLCTB,OUT00900        BRANC IF MORE TO READ IN        38800021
OUT00950 LM    RETURN,BRANCH,SAVE1415   RESTORE  2 REGS                 38880021
         BCR   15,RETURN                RETURN TO CALLER                38960021
SAVEWORD DC    F'0'                                                     39040021
*********************************************************************** 39120021
*              PASS ERROR PARM TO ERROR ROUTINE - NO TEXT             * 39200021
*********************************************************************** 39280021
OUT00970 LH    ERRCODE,ERRPARM1         NO TXT IN LOAD MODULE           39360021
         L     BRANCH,ERDIG       ADDR OF ERROR ROUTINE                 39440021
         BALR  RETURN,BRANCH            GO TO ERR DIAGNOSTIC ROUTINE    39520021
         L     BRANCH,FNALVCON          ADD OF FINAL PROC               39600021
         BCR   15,BRANCH                GO TO ERR ROUT                  39680021
**********************************************************************  39760021
*              WRITE - CHECK - NOTE   SUBROUTINE                      * 39840021
**********************************************************************  39920021
*                   REQUIRED REGISTERS                                  40000021
*                                                                       40080021
*              TEMPRTN             -RETURN ADDRESS                      40160021
*              WRITEADD            -ADDRESS OF WRITE AREA               40240021
*              WRITECT             -WRITE BYTE CT                       40320021
*                                                                       40400021
*                   REGISTERS THAT ARE ALSO USED (NOT SAVED)            40480021
*                                                                       40560021
*              DCBADD                                                   40640021
*              SAVEAREA                                                 40720021
*              TTRREG                                                   40800021
*                                                                       40880021
*              APT                                                      40960021
*              BASE                                                     41040021
*              REGS 14 - 1                                              41120021
OUT00990 L     DCBADD,DCBLMOD          SYSLMOD DCB                      41200021
         LA    SAVEAREA,REGSA     ADDRESS OF SAVE AREA                  41280021
*********************************************************************** 41360021
*              WRITE THE NEXT RECORD                                  * 41440021
*********************************************************************** 41520021
         WRITE WDECB,SF,(DCBADD),(WRITEADD),(WRITECT)                   41600021
         CHECK WDECB                                                    41680021
         SR    TTRREG,TTRREG            TTR REG SET TO ZERO             41760021
         TM    APT1,ESDWTBIT      IS FIRST ESD WT IND = ON              41840021
         BCR   8,TEMPRTN      NO        NO                              41920021
         NI    APT1,ESDWTOFF      SET FIRST ESD WT IND = OFF            42000021
         NOTE  (DCBADD)                                                 42080021
         BCR   15,TEMPRTN               RETURN TO CALLER                42160021
*********************************************************************** 42240021
*              SETUP SEGTAB CONTROL RECORD                              42320021
*********************************************************************** 42400021
OUT01000 L     WRITEADD,TNLS2     ESD ADDRESS/WRITE OUT AREA            42480021
         LA    WRITEADD,5(WRITEADD)     WRITE OUT AREA                  42560021
         XC    0(20,WRITEADD),0(WRITEADD) ZERO CONTROL RCD AREA         42640021
         OI    0(WRITEADD),X'01'        SET CONTROL IND.(TXT TO FOLLOW) 42720021
         OI    5(WRITEADD),X'04'        SET NO. BYTES ESD ID IN CTL     42800021
         OI    8(WRITEADD),X'06'        SET READ CCW FOR FETCH          42880021
         OI    12(WRITEADD),X'40'       SET FLAG FIELD FOR FETCH        42960021
         MVC   14(2,WRITEADD),PDSE10  PUT SEGTAB LENGTH IN CONTROL      43040021
         MVC   18(2,WRITEADD),PDSE10  PUT SEGTAB LENGTH IN CONTROL      43120021
         MVC   16(2,WRITEADD),ENSPX   PUT SEGTAB ID IN CONTROL          43200021
         MVC   WORD(2),PDSE10     LENGTH OF SEGTAB                      43280021
         LH    TEMP5,WORD              LENGTH OF SEGTAB                 43360021
*********************************************************************** 43440021
*              SETUP FOR WRITE OF CONTROL RECORD                        43520021
*********************************************************************** 43600021
         NI    APT1,ESDWTOFF      SET NOTE IND= OFF                     43680021
         LA    WRITECT,20               SET WRITE CT TO 20 BYTES        43760021
         NI    APT3,X'FD'         SET 2ND PASS NOT EDIT BIT OFF         43840021
*              WHEN THIS BIT IS ON 2ND PASS DOES NOT WRITE HIS 1ST      43920021
*              CONTROL RECORD ---- IN OVERLAY HIS 1ST CONTROL RECORD    44000021
*              IS NOT THE 1ST CONTROL RECORD IN THE PGM & MUST BE WRITT 44080021
         TM    PDSE8,NOTEDIT      IS MODULE NOT EDITABLE                44160021
         BC    1,OUT01100              YES/DO NOT OUTPUT CONTROL RECORD 44240021
         BAL   TEMPRTN,OUT00990         GO TO WT OUT SEG TAB CONTROL RD 44320021
*********************************************************************** 44400021
*              BUILD IST TEXT RECORD  (SEGTAB)                        * 44480021
*********************************************************************** 44560021
*                                                                       44640021
OUT01100 LR    TEMP2,WRITEADD          ADDRESS OF AREA TO SET TO 0      44720021
         LR    TEMP1,TEMP5              BYTES OF SEGTAB TO 0  (CT)      44800021
         LA    TEMP3,256                                                44880021
OUT01200 SR    TEMP1,TEMP3             IS REMAINDER LESS THAN 256       44960021
         BC    4,OUT01300               YES                             45040021
         BCTR  TEMP3,0                 DECREMENT COUNT TO 255           45120021
         EX    TEMP3,ZEROHIID          ZERO 255 BYTES                   45200021
         LA    WRITEADD,256(WRITEADD)   INCREMENT ADD BY 256            45280021
         BC    15,OUT01200              RETURN TO 0 REMAINDER           45360021
OUT01300 AR    TEMP1,TEMP3             RESTORE COUNT                    45440021
         BCTR  TEMP1,0                 DECREMENT COUNT BY 1             45520021
         EX    TEMP1,ZEROHIID          ZERO REMAINDER                   45600021
         LR    WRITEADD,TEMP2           RESTORE BEGIN OF SEGTAB AREA    45680021
         LR    WRITECT,TEMP5                 SEGTAB LENGTH              45760021
         MVC   8(1,WRITEADD),LSTS PUT LST SEG OF REG0 SEGTAB            45840021
         MVC   10(1,WRITEADD),LSTS+1   PUT LST SEG OF REG 1 SEGTAB      45920021
         MVC   12(1,WRITEADD),LSTS+2   PUT LST SEG OF REG 2 SEGTAB      46000021
         MVC   14(1,WRITEADD),LSTS+3   PUT LST SEG OF REG 3 SEGTAB      46080021
         MVI   9(WRITEADD),X'01'                                        46160021
*                                                                       46240021
*                                                                       46320021
         SR    TEMP1,TEMP1                                              46400021
         LA    TEMP2,20(WRITEADD)                                       46480021
OUT01500 L     TEMP3,SGT1         ADD OF SEGTAB 1 (-1)                  46560021
         LA    TEMP1,1(TEMP1)                INC ADD OF SEGTAB          46640021
         AR    TEMP3,TEMP1              ADD OF NEXT ITEM IN SEGTA1      46720021
         LA    TEMP2,4(TEMP2)                INC ADD OF PRV SG IN SEGTB 46800021
         MVC   0(1,TEMP2),0(TEMP3)           MOVE PRV SG NO  TO SEGTAB  46880021
         MVI   3(TEMP2),X'03'                SET STATUS - NOT IN CORE   46960021
         CH    TEMP1,CSNO         IS LOOP DONE                          47040021
         BC    4,OUT01500                    NO                         47120021
         MVI   27(WRITEADD),X'02'            SET STATUS - IN CORE/SEG 1 47200021
*********************************************************************** 47280021
*              SETUP FOR WRITE OF SEGTAB RECORD                         47360021
*********************************************************************** 47440021
         OI    APT1,ESDWTBIT      SET NOTE IND = ON                     47520021
         BAL   TEMPRTN,OUT00990         GO TO WRITE SEGTAB RCD          47600021
         ST    TTRREG,PDSE4       SAVE TTRO OF SEGTAB IN PDS            47680021
         BC    15,OUT00560             GO BUILD REST OF HESD            47760021
*********************************************************************** 47840021
*              INITIALIZE FOR BUILDING SCATTER/TRANSLATION TABLES     * 47920021
*********************************************************************** 48000021
OUT02000 LA    TEMP5,2                                                  48080021
         LH    HESDCT,ENCDC       HESD CT = X                           48160021
         L     HESDADD,HESD            HESD ADDRESS                     48240021
         LA    SCATTADD,1(HESDCT)       X+1                             48320021
         LR    TRANSADD,SCATTADD        X+1                             48400021
         SLL   TRANSADD,3               8(X+1)                          48480021
         AR    TRANSADD,HESDADD         8(X+1) +HESD ADD = TRANS ADD    48560021
         AR    SCATTADD,SCATTADD        2(X+1)   / SLATION TABLE -4     48640021
         AR    SCATTADD,TEMP5           2(X+1)+2  - EXTRA 2 FOR PAD     48720021
         AR    TEMP5,TEMP5              4                               48800021
         XC    4(2,TRANSADD),4(TRANSADD)  SET IST TRANSADD ENTRY = 0    48880021
         LCR   TEMP1,TEMP5              2'S COMP OF 4 = FFFFFFFC        48960021
         NR    SCATTADD,TEMP1           LENGTH OF TRANSLATION TABLE     49040021
*                                       WITH PAD REMOVED IF NOT NEEDED  49120021
         STH   SCATTADD,WORD            PUT LENGTH IN PDS               49200021
         MVC   PDSE14(2),WORD                                           49280021
         LA    TEMP4,0(SCATTADD,TRANSADD)    ADD OF SCATTER TABLE -TRUE 49360021
         XC    0(8,TEMP4),0(TEMP4)      SET 1ST SCAT ENTRY = 0          49440021
         LA    SCATTADD,8(TEMP4)        ADD OF 2ND ENTRY IN SCATTER TBL 49520021
         AR    TRANSADD,TEMP5           TRUE ADD OF TRANSLATION TABLE   49600021
         AR    TEMP4,TEMP5                                              49680021
*********************************************************************** 49760021
*                BUILD SCATTER/TRANSLATION TABLES                     * 49840021
*                  FIRST PASS REFERENCED TXTIOT                       * 49920021
*********************************************************************** 50000021
*                                                                     * 50080021
* SET UP SEARCH OF TXTIOT                                             * 50160021
          SR    ENDTXTIO,ENDTXTIO   CLEAR REGISTER FOR COMPARE TO 0     50240021
         CH    ENDTXTIO,ENTOC      IS THERE AN Y TEXT                   50320021
         BC    11,OUT02050         NO/ SKIP 1ST SEARCH AND SEARCH HESD  50400021
         OI    SWITCH,TXTIOLP      SET SWITCH INDICATION TXTIO LOOP     50480021
         L     ADTXTIOT,TXTIO      ADDRESS TXTIO TABLE                  50560021
         LR    ENDTXTIO,ADTXTIOT   ADDRESS TXTIO TABLE                  50640021
         AH    ENDTXTIO,ENTOC      END ADDRESS OF TXTIO TABLE           50720021
* PROCESS TXTIOT ENTRY                                                  50800021
OUT02023 CR    ADTXTIOT,ENDTXTIO   ANY MORE TXT IN TXTIOT               50880021
         BC    11,OUT02035         NO- SET IN TXTIOT LOOP OFF           50960021
         TM    2(ADTXTIOT),X'20'   IS IT OUT OF ORDER TEXT              51040021
         BC    1,OUT02033          YES--THEN ID FOR TXTIO ENTRY ALREADY 51120021
*                                     PROCESSED, CHECK NEXT ENTRY.      51200021
* FIND HESD ENTRY                                                       51280021
         LH    TEMP1,0(ADTXTIOT)   HESD ENTRY ID (FROM TXTIOT)          51360021
         SLL   TEMP1,3             FIND REL ADDRESS HESD  (* 8)         51440021
         A     TEMP1,HESD          ADDRESS OF HESD ENTRY                51520021
         TM    0(TEMP1),X'08'          HAS HESD ENTRY BEEN PROCESSED    51600021
         BC    1,OUT02033          YES/ CHECK NEXT TXTIOT ENTRY         51680021
         B     OUT02110            NO/ PROCESS ENTRY                    51760021
OUT02030 OI    0(TEMP1),X'08'      SET PROCESSED SWITCH                 51840021
OUT02033 LA    ADTXTIOT,INC(ADTXTIOT)  UPDATE ADDR TXTIOT ENTRY         51920021
         B     OUT02023                                                 52000021
OUT02035 NI    SWITCH,X'7F'        TURN TXTIO LOOP SWITCH OFF           52080021
         B     OUT02050            SEARCH HESD                          52160021
OUT02036 NI    0(TEMP1),X'F7'      TURN PROCESSED SWITCH OFF            52240021
         B     OUT02300            CHECK END OF LOOP                    52320021
OUT02050 LR    TEMP5,HESDCT        SAVE NUMBER OF ENTRIES IN HESD       52400021
         LR    TEMP1,HESDADD            HESD ADD  // 1ST ENTRY = 0      52480021
*********************************************************************** 52560021
*********************************************************************** 52640021
*              BUILD SCATTER/TRANSLATION TABLES                       * 52720021
*********************************************************************** 52800021
OUT02100 LA    TEMP1,8(TEMP1)           INC HESD ADD                    52880021
         TM    0(TEMP1),X'08'      HAS HESD ENTRY BEEN PROCESSED        52960021
         BC    1,OUT02036          YES- TURN OFF SWITCH/ CHECK END OF   53040021
*                                      LOOP                             53120021
         TM    NEWSW,HIAROP             IS HIAR OPTION ON               53200021
         BC    8,OUT02120               NO                              53280021
         LR    HIARAD,TEMP1        HESD ADDRESS                         53360021
         S     HIARAD,HESD         RELATIVE HESD ADDRESS                53440021
         SRL   HIARAD,3            DIVIDE BY 8 TO GET HESD ID           53520021
         B     OUT02115                                                 53600021
OUT02110 TM    NEWSW,HIAROP        IS HIAR OPTION ON                    53680021
         BC    8,OUT02120           NO                                  53760021
         LH    HIARAD,0(ADTXTIOT)  HESD ID (REL. ADDR ON HIAR TABLE)    53840021
OUT02115 A     HIARAD,HIARADD      ADDRESS OF ENTRY OF HIERARCHY TABLE  53920021
OUT02120 TM    0(TEMP1),X'02'           IS HESD TYPE SD,PC OR CM        54000021
         BC    1,OUT02300               NO                              54080021
         TM    NEWSW,HIAROP             IS HIAR OPTION ON               54160021
         BC    8,OUT02140               NO                              54240021
         MVC   0(1,SCATTADD),0(HIARAD)  PUT HN IN HIGH ORDER BYTE       54320021
         B     OUT02150                                                 54400021
OUT02140 MVI   0(SCATTADD),X'00'        NO HIAR- PUT 00 IN HIGH BYTE    54480021
OUT02150 MVC   1(3,SCATTADD),1(TEMP1)   PUT SD,PC OR CM ADD IN SCTR TAB 54560021
         LR    TEMP3,SCATTADD           SAVE SCATTER ADD FOR THIS ENTRY 54640021
         SR    TEMP3,TEMP4              REL SCATTER ADD                 54720021
         SRL   TEMP3,2                  SCAT ID                         54800021
         LA    SCATTADD,4(SCATTADD)     INC TO NEXT AVAILABLE SCATENTRY 54880021
OUT02200 LR    TEMP2,TEMP1              SAVE HESD ADD FOR THIS ENTRY    54960021
         SR    TEMP2,HESDADD            REL HESD ADD                    55040021
         SRL   TEMP2,2                  2(HESD ID) OR REL TRANS ADD     55120021
         STH   TEMP3,0(TRANSADD,TEMP2)  PUT PTR TO SCAT ENT IN TRANS TB 55200021
         TM    SWITCH,TXTIOLP       IS PGM IN TXTIO TABLE SEARCH        55280021
         BC    1,OUT02030          YES SET ENTRY PROCESSED/ GO TO  NEXT 55360021
*                                         TXTIOT ENTRY                  55440021
OUT02300 BCT   HESDCT,OUT02100          BRANCH IF HESD LOOP NOT DONE    55520021
         LR    TEMP1,HESDADD           ADDRESS OF HESD                  55600021
OUT02400 LA    TEMP1,8(TEMP1)          INC HESD ADD                     55680021
         SR    TEMP3,TEMP3              0 TO BE USED AS TRANSPTER,PR,NL 55760021
         TM    0(TEMP1),X'02'           IS HESD TYPE SD,PC OR CM        55840021
         BC    8,OUT02470              YES                              55920021
         TM    0(TEMP1),X'07'           IS TYPE = NULL                  56000021
         BC    1,OUT02450               YES / GO TO PUT 0 PTR IN TRANS  56080021
         TM    0(TEMP1),X'03'           IS TYPE = LR                    56160021
         BC    12,OUT02450              NO - ER,PR /GO PUT 0 IN TRANS   56240021
         LH    TEMP2,6(TEMP1)           PICK UP ID THAT PTS TO SD OR PC 56320021
         AR    TEMP2,TEMP2              DOUBLE ID - REL TRANS TBL ADD   56400021
         LH    TEMP3,0(TRANSADD,TEMP2)  PICK UP PTR TO SCATT FOR SD -PC 56480021
OUT02450 LR    TEMP2,TEMP1              SAVE HESD ADD FOR THIS ENTRY    56560021
         SR    TEMP2,HESDADD            REL HESD ADD                    56640021
         SRL   TEMP2,2                  2(HESD ID) OR REL TRANS ADD     56720021
         STH   TEMP3,0(TRANSADD,TEMP2)  PUT PTR TO SCAT ENT IN TRANS TB 56800021
OUT02470 BCT   TEMP5,OUT02400           BRANCH IF HESD LOOP NOT DONE    56880021
*********************************************************************** 56960021
*              SET UP LOOP TO WRITE OUT SCATTER - TRANSLATION RECORD  * 57040021
*********************************************************************** 57120021
         LR    TEMP1,SCATTADD           ADD OF LAST SCATTER ENTRY + 4   57200021
         SR    TEMP1,TEMP4              NO BYTES OF SCATTER TABLE       57280021
         STH   TEMP1,WORD                                               57360021
         MVC   PDSE13(2),WORD     PUT NO SCATT BYTES IN PDS             57440021
         LR    TEMP5,SCATTADD                                           57520021
         SR    TEMP5,TRANSADD           NO BYTES     TO WRITE OUT       57600021
         OI    APT1,ESDWTBIT      SET BIT TO NOTE FIRST WRITE           57680021
OUT02500 LA    TEMP1,1020               1020                            57760021
         SR    TEMP5,TEMP1              BYTES REMAINING TO WRITE        57840021
         BC    10,OUT02600              BRANCH IF REMAINDER GREATER 0   57920021
         AR    TEMP1,TEMP5              WRITE CT = OR LESS 1020         58000021
OUT02600 LA    WRITECT,4(TEMP1)         CT + 4                          58080021
         SR    SCATTADD,WRITECT         WRITE ADDRESS                   58160021
         L     WORK1,0(SCATTADD)        SAVE 4 BYTES                    58240021
         ST    TEMP1,0(SCATTADD)        PUT WRITE CT IN HEADER - CTL    58320021
         MVI   0(SCATTADD),X'10'        PUT IN SCAT CONTROL             58400021
         BAL   TEMPRTN,OUT00990         GO WRITE OUT SCATT RCD          58480021
         ST    WORK1,0(SCATTADD)        RESTORE  4 B                    58560021
         LA    SCATTADD,4(SCATTADD)                                     58640021
         LTR   TTRREG,TTRREG            WAS A NOTE DONE ON THIS WRITE   58720021
         BC    8,OUT02700               NO                              58800021
         ST    TTRREG,WORD              SAVE TTR                        58880021
         MVC   PDSE5(3),WORD      PUT TTR IN PDS                        58960021
OUT02700 LTR   TEMP5,TEMP5              ANY MORE DATA TO WRITE          59040021
         BC    2,OUT02500               YES                             59120021
         BC    15,OUT00560              NO/RETURN TO MAIN LOOP          59200021
         EJECT                                                   S21016 59280021
*********************************************************************** 59360021
*                                                                     * 59440021
*              OUTIDR -- SUBROUTINE TO PROCESS IDR OUTPUT             * 59520021
*                                                                     * 59600021
*********************************************************************** 59680021
*                                                                     * 59760021
*                  SUBROUTINE OUTIDR RECEIVES CONTROL                 * 59840021
*                  AFTER THE LAST CESD RECORD HAS BEEN                * 59920021
*                  WRITTEN ON THE SYSLMOD DATA SET.                   * 60000021
*                  ITS FUNCTION IS TO CREATE AND WRITE                * 60080021
*                  THE CSECT IDENTIFICATION RECORDS OF                * 60160021
*                  A LOAD MODULE IMMEDIATELY FOLLOWING                * 60240021
*                  ALL CESD RECORDS ON THE SYSLMOD                    * 60320021
*                  DATA SET.                                          * 60400021
*                  IT USES THREE TABLES CREATED DURING                * 60480021
*                  INPUT PROCESSING:                                  * 60560021
*                            IDRZPTAB - IMASPZAP DATA                 * 60640021
*                            IDRTRTAB - TRANSLATOR DATA               * 60720021
*                            IDRUDTAB - USER DATA                     * 60800021
*                  THESE TABLES, COLLECTIVELY, CONTAIN                * 60880021
*                  ALL IDR DATA RECEIVED FROM ALL                     * 60960021
*                  INPUT LOAD AND OBJECT MODULES PLUS                 * 61040021
*                  USER-SUPPLIED IDR DATA RECEIVED                    * 61120021
*                  VIA THE IDENTIFY CONTROL STATEMENT.                * 61200021
*                                                              S21016 * 61280021
*********************************************************************** 61360021
         SPACE 2                                                 S21016 61440021
OUTIDR   STM   WRITECT,TABEND,TEMPSAVE   SAVE REGISTERS          S21016 61520021
         SPACE 1                                                 S21016 61600021
*********************************************************************** 61680021
*                                                                     * 61760021
*              PROCESS IDR IMASPZAP RECORD(S)                         * 61840021
*                                                              S21016 * 61920021
*********************************************************************** 62000021
         SPACE 1                                                 S21016 62080021
         MVC   IDRBUF(HDRLEN),IDRZHDR  MOVE IDR SPZAP RECORD     S21016 62160021
*                                      HEADER INTO IDR BUFFER    S21016 62240021
         LA    WRITEADD,IDRBUF         POINT TO IDR BUFFER FOR   S21016 62320021
*                                      WRITE ROUTINE             S21016 62400021
         LA    WRITECT,ZPRECLEN        LOAD RECORD LENGTH FOR    S21016 62480021
*                                      WRITE ROUTINE             S21016 62560021
         LM    TABADD,TABEND,IDRZPTAB  LOAD STARTING AND ENDING  S21016 62640021
*                                      ADDRESSES OF SPZAP DATA   S21016 62720021
*                                      TABLE                     S21016 62800021
         CR    TABADD,TABEND           ANY DATA IN TABLE?        S21016 62880021
         BE    NOZAP                   IF NOT, BRANCH            S21016 62960021
         LR    DATAPTR,TABADD          IF THERE IS DATA, POINT   S21016 63040021
*                                      TO IT                     S21016 63120021
         LR    DATALEN,TABEND          GET ENDING ADDRESS OF     S21016 63200021
*                                      DATA                      S21016 63280021
         SR    DATALEN,TABADD          SUBTRACT STARTING ADDRESS S21016 63360021
*                                      TO GET TOTAL LENGTH OF    S21016 63440021
*                                      DATA IN TABLE             S21016 63520021
         LA    RECLEN,ZAPLEN           LOAD DATA LENGTH FOR ONE  S21016 63600021
*                                      SPZAP RECORD              S21016 63680021
ZAPLOOP  CR    DATALEN,RECLEN          COMPARE LENGTH OF DATA IN S21016 63760021
*                                      TABLE TO LENGTH WHICH CAN S21016 63840021
*                                      GO ONTO ONE SPZAP RECORD  S21016 63920021
         BNH   LASTZAP                 IF ALL DATA REMAINING IN  S21016 64000021
*                                      TABLE CAN GO ONTO A       S21016 64080021
*                                      SINGLE RECORD, BRANCH     S21016 64160021
MOVEDATA MVC   ZAPDATA(ZAPLEN),LOC(DATAPTR)  IF NOT, MOVE DATA   S21016 64240021
*                                      TO FILL 1 REC TO BUFFER   S21016 64320021
         OI    ZAPCNT,ZAPMAX           SET COUNT FIELD OF REC TO S21016 64400021
*                                      SHOW 19 ENTRIES (MAXIMUM) S21016 64480021
*                                      AND TURN ON CHAIN BIT     S21016 64560021
*                                      (BIT 1 OF COUNT BYTE)     S21016 64640021
         BAL   TEMPRTN,OUT00990        GO TO WRITE THE RECORD    S21016 64720021
         LA    DATAPTR,ZAPLEN(DATAPTR) UPDATE POINTER TO DATA BY S21016 64800021
*                                      THE AMOUNT JUST WRITTEN   S21016 64880021
         SR    DATALEN,RECLEN          SUBTRACT AMOUNT JUST      S21016 64960021
*                                      WRITTEN FROM LENGTH OF    S21016 65040021
*                                      DATA REMAINING TO BE      S21016 65120021
*                                      PROCESSED                 S21016 65200021
         B     ZAPLOOP                 LOOP TO CONTINUE          S21016 65280021
*                                      PROCESSING THE REMAINING  S21016 65360021
*                                      DATA                      S21016 65440021
NOZAP    NI    ZAPCNT,NOZPDATA         TURN CHAIN BIT OFF AND    S21016 65520021
*                                      SET COUNT TO ZERO ENTRIES S21016 65600021
*                                      FOR THIS RECORD           S21016 65680021
         MVI   ZAPDATA,ZEROFILL        PAD UNUSED DATA PORTION   S21016 65760021
         MVC   ZAPDAT1(ZPLEN),ZAPDATA  OF RECORD WITH ZEROES     S21016 65840021
SHRTZAP  BAL   TEMPRTN,OUT00990        GO TO WRITE THE RECORD    S21016 65920021
         B     LKEDREC                 GO TO PROCESS LKED DATA   S21016 66000021
*                                      FOR IDR                   S21016 66080021
LASTZAP  BCTR  DATALEN,LOC             SUBTRACT ONE FROM DATA    S21016 66160021
*                                      LENGTH FOR ZERO-ORIENTED  S21016 66240021
*                                      MOVE LENGTH               S21016 66320021
         MVI   ZAPDATA,ZEROFILL        PAD UNUSED DATA PORTION   S21016 66400021
         MVC   ZAPDAT1(ZPLEN),ZAPDATA  OF RECORD WITH ZEROES     S21016 66480021
         EX    DATALEN,MOVEDATA        EXECUTE MOVE OF DATA TO   S21016 66560021
*                                      IDR BUFFER FOR SPZAP REC  S21016 66640021
         LA    DATALEN,UNIT(DATALEN)   ADD ONE TO DATA LENGTH    S21016 66720021
*                                      TO RESTORE NORMAL ONE-    S21016 66800021
*                                      ORIENTATION               S21016 66880021
         XR    DATAPTR,DATAPTR         ZERO OUT EVEN REG         S21016 66960021
*                                      TO CLEAR SIGN BIT         S21016 67040021
*                                      FOR DIVIDE (ALWAYS        S21016 67120021
*                                      A POSITIVE NUMBER)        S21016 67200021
         D     DATASIZE,ZAPSIZE        DIVIDE LENGTH OF DATA     S21016 67280021
*                                      IN RECORD BY LENGTH OF    S21016 67360021
*                                      A SINGLE DATA ITEM TO     S21016 67440021
*                                      DETERMINE THE NUMBER OF   S21016 67520021
*                                      ENTRIES IN THIS RECORD    S21016 67600021
         STC   ZPCOUNT,ZAPCNT          SET COUNT FIELD OF REC TO S21016 67680021
*                                      CORRECT NUMBER OF ENTRIES S21016 67760021
*                                      IN THIS RECORD WITH CHAIN S21016 67840021
*                                      BIT OFF                   S21016 67920021
         LA    ZAPCMPR,CMPRSIZE        GET COMPARISON VALUE      S21016 68000021
*                                      FOR NUMBER OF ENTRIES     S21016 68080021
*                                      ALLOWED WITHOUT CREATING  S21016 68160021
*                                      AN EXTRA (BLANK) REC FOR  S21016 68240021
*                                      POSSIBLE FUTURE OVERFLOW  S21016 68320021
         CR    ZPCOUNT,ZAPCMPR         DOES THIS RECORD CONTAIN  S21016 68400021
*                                      MORE THAN THE CRITICAL    S21016 68480021
*                                      NUMBER OF ENTRIES?        S21016 68560021
         BNH   SHRTZAP                 IF NOT, BRANCH (THIS WILL S21016 68640021
*                                      BE THE LAST IDR WITH      S21016 68720021
*                                      SPZAP DATA)               S21016 68800021
         OI    ZAPCNT,CHAIN            IF AN ADDITIONAL RECORD   S21016 68880021
*                                      IS NEEDED, TURN ON THE    S21016 68960021
*                                      CHAIN BIT IN THIS RECORD  S21016 69040021
         BAL   TEMPRTN,OUT00990        GO TO WRITE THIS RECORD   S21016 69120021
         B     NOZAP                   BRANCH TO CREATE A SPARE  S21016 69200021
*                                      RECORD                    S21016 69280021
         SPACE 1                                                 S21016 69360021
*********************************************************************** 69440021
*                                                                     * 69520021
*              PROCESS IDR LINKAGE EDITOR RECORD                      * 69600021
*                                                              S21016 * 69680021
*********************************************************************** 69760021
         SPACE 1                                                 S21016 69840021
LKEDREC  LA    WRITECT,LKRECLEN        SET UP RECORD LENGTH FOR  S21016 69920021
*                                      WRITE ROUTINE             S21016 70000021
         L     REG1,DEFADDR            GET ADDR. OF MDEF         S21016 70006021
         USING DEFDSECT,REG1           SET UP ADRESSABABILITY    S21016 70012021
*                                      FOR MDEF DSECT            S21016 70018021
         PACK  LKRELNO(LEN2),SGRELNO(LEN3)  PACK SYSGEN-ASSIGNED S21016 70024021
*                                      OS RELEASE NO. TO LKED    S21016 70030021
*                                      IDR HEADER                S21016 70036021
         DROP  REG1                    NO LONGER NEEDED          S21016 70042021
         SR    REG1,REG1               ZERO OUT REGISTER         S21016 70048021
         IC    REG1,LKRELNO+1          GET 2ND BYTE OF REL.NO.   S21016 70054021
         SRL   REG1,LEN4               SHIFT OUT SIGN            S21016 70060021
         STC   REG1,LKRELNO+1          STORE MODIFICATION LEVEL  S21016 70066021
*                                      WITH A LEADING ZERO       S21016 70072021
         MVC   IDRBUF(LKLEN),LKIDR     MOVE RECORD HEADER AND    S21016 70080021
*                                      LKED IDENTIFYING INFO     S21016 70160021
*                                      TO IDR BUFFER             S21016 70240021
         ST    TIME,TIMESAVE           SAVE REGISTER 0 BEFORE    S21016 70320021
*                                      ISSUEING TIME MACRO       S21016 70400021
         TIME  ,            ISSUE TIME MACRO TO GET TODAY'S DATE S21016 70480021
         ST    DATE,DATESAVE           STORE TODAY'S DATE AS     S21016 70560021
*                                      RETURNED BY TIME MACRO    S21016 70640021
         MVC   LKDATE(DATELEN),DATESAV  MOVE TODAY'S DATE TO     S21016 70720021
*                                      DATE FIELD OF RECORD (IN  S21016 70800021
*                                      PACKED DECIMAL FORMAT)    S21016 70880021
         L     TIME,TIMESAVE           RESTORE REGISTER ZERO     S21016 70960021
         LM    TABADD,TABEND,IDRTRTAB  GET STARTING AND ENDING   S21016 71040021
*                                      ADDRESSES OF TRANSLATOR   S21016 71120021
*                                      DATA TABLE                S21016 71200021
         CR    TABADD,TABEND           ANY DATA IN TABLE?        S21016 71280021
         BNE   TRNSREC                 IF SO, BRANCH TO          S21016 71360021
*                                      PROCESS TRANSLATOR DATA   S21016 71440021
TRNSDONE LM    TABADD,TABEND,IDRUDTAB  GET STARTING AND ENDING   S21016 71520021
*                                      ADDRESSES OF USER DATA    S21016 71600021
*                                      TABLE                     S21016 71680021
         CR    TABADD,TABEND           ANY DATA IN TABLE?        S21016 71760021
         BNE   USERREC                 IF SO, BRANCH TO          S21016 71840021
*                                      PROCESS USER DATA         S21016 71920021
USERDONE OI    SUBTYPE,LASTIDR         TURN ON FLAG IN SUBTYPE   S21016 72000021
*                                      FIELD OF THIS RECORD TO   S21016 72080021
*                                      INDICATE THAT IT IS THE   S21016 72160021
*                                      LAST IDR FOR THE LOAD     S21016 72240021
*                                      MODULE                    S21016 72320021
         BAL   TEMPRTN,OUT00990        GO TO WRITE THE LAST REC  S21016 72400021
         LM    WRITECT,TABEND,TEMPSAVE RESTORE REGISTERS         S21016 72480021
         BR    TEMPRTN                 RETURN TO CALLER          S21016 72560021
         SPACE 1                                                 S21016 72640021
*********************************************************************** 72720021
*                                                                     * 72800021
*              PROCESS IDR TRANSLATOR RECORD(S)                       * 72880021
*                                                              S21016 * 72960021
*********************************************************************** 73040021
         SPACE 1                                                 S21016 73120021
TRNSREC  BAL   TEMPRTN,OUT00990        GO TO WRITE THE LKED IDR  S21016 73200021
         MVI   SUBTYPE,TRNSTYPE        MOVE INDICATOR FOR        S21016 73280021
*                                      TRANSLATOR DATA TO        S21016 73360021
*                                      IDR SUBTYPE FIELD         S21016 73440021
         LA    WRITECT,TURECLEN        LOAD RECORD LENGTH FOR    S21016 73520021
*                                      WRITE ROUTINE             S21016 73600021
         LR    DATAPTR,TABADD          POINT TO START OF DATA    S21016 73680021
         LR    DATALEN,TABEND          LOAD ENDING ADDRESS OF    S21016 73760021
*                                      DATA IN TABLE             S21016 73840021
         SR    DATALEN,TABADD          SUBTRACT STARTING ADDR.   S21016 73920021
*                                      TO OBTAIN LENGTH OF DATA  S21016 74000021
TRNSLOOP LA    RECLEN,TRUDLEN          LOAD DATA LENGTH FOR ONE  S21016 74080021
*                                      RECORD                    S21016 74160021
         CR    DATALEN,RECLEN          COMPARE LENGTH OF DATA    S21016 74240021
*                                      TO LENGTH OF 1 RECORD     S21016 74320021
         BNL   TRNS0020                IF DATA LENGTH IS NOT <   S21016 74400021
*                                      RECORD LENGTH, BRANCH     S21016 74480021
         LR    RECLEN,DATALEN          ELSE, GET DATA LENGTH     S21016 74560021
TRNS0020 ST    DATAPTR,DPTRSAV         SAVE POINTER TO START OF  S21016 74640021
*                                      DATA                      S21016 74720021
TRNS0040 CLC   LOC(LEN2,DATAPTR),NULITEM  IS THIS THE START OF   S21016 74800021
*                                      A NULL ITEM?              S21016 74880021
         BE    TRNS0060                IF SO, GO TO SKIP IT      S21016 74960021
         LA    DATAPTR,UNIT(DATAPTR)   UPDATE BY ONE BYTE        S21016 75040021
         BCT   RECLEN,TRNS0040         GO TO CONTINUE SCANNING   S21016 75120021
*                                      FOR A NULL ITEM UNTIL THE S21016 75200021
*                                      COUNT IS EXHAUSTED        S21016 75280021
         LA    RECLEN,TRUDLEN          RESTORE NORMAL REC.LENGTH S21016 75360021
         L     DATAPTR,DPTRSAV         RESTORE DATA POINTER      S21016 75440021
         B     TRNS0100                GO TO PROCESS THE DATA    S21016 75520021
TRNS0060 ST    DATALEN,DLENSAV         SAVE LENGTH OF DATA       S21016 75600021
         MVC   NULLEN(LEN2),LEN2(DATAPTR)  GET LENGTH OF NULL    S21016 75680021
*                                      ITEM                      S21016 75760021
         LR    DATALEN,DATAPTR         GET STARTING ADDR. OF     S21016 75840021
*                                      NULL ITEM                 S21016 75920021
         S     DATALEN,DPTRSAV         SUBTRACT STARTING ADDR.   S21016 76000021
*                                      OF DATA FOR LENGTH OF     S21016 76080021
*                                      GOOD DATA PRECEEDING THE  S21016 76160021
*                                      NULL ITEM                 S21016 76240021
         LTR   DATALEN,DATALEN         TEST LENGTH OF GOOD DATA  S21016 76320021
         BZ    TRNS0080                IF ZERO, BRANCH           S21016 76400021
         CH    DATALEN,NULLEN          IS LENGTH OF GOOD DATA >  S21016 76480021
*                                      LENGTH OF NULL ITEM?      S21016 76560021
         BNH   TRNS0070                IF NOT, BRANCH            S21016 76640021
         OI    TEMPSW,ON               TURN SWITCH TO INDICATE   S21016 76720021
*                                      A TEMPORARY MUST BE USED  S21016 76800021
*                                      TO MOVE DATA              S21016 76880021
TRNS0070 LR    MVCPTR,DATAPTR          GET STARTING ADDR. OF     S21016 76960021
*                                      NULL ITEM                 S21016 77040021
         AH    MVCPTR,NULLEN           ADD LENGTH OF NULL ITEM   S21016 77120021
*                                      TO POINT TO END OF IT     S21016 77200021
         SR    MVCPTR,DATALEN          SUBTRACT LENGTH OF GOOD   S21016 77280021
*                                      DATA TO DETERMINE ADDR.   S21016 77360021
*                                      GOOD DATA SHOULD GO TO    S21016 77440021
         BCTR  DATALEN,LOC             SUBTRACT 1 FROM LENGTH OF S21016 77520021
*                                      GOOD DATA FOR MOVE        S21016 77600021
         L     DATAPTR,DPTRSAV         POINT BACK TO START OF    S21016 77680021
*                                      GOOD DATA                 S21016 77760021
         TM    TEMPSW,ON               IS TEMPORARY NEEDED FOR   S21016 77840021
*                                      MOVE?                     S21016 77920021
         BNO   TRNS0075                IF NOT, BRANCH            S21016 78000021
         ST    MVCPTR,MPTRSAV          SAVE POINTER TO MOVE      S21016 78080021
*                                      DESTINATION               S21016 78160021
         LA    MVCPTR,DATATEMP         POINT TO TEMPORARY        S21016 78240021
         EX    DATALEN,DATAMVC         MOVE DATA TO TEMPORARY    S21016 78320021
         LR    DATAPTR,MVCPTR          POINT TO TEMPORARY        S21016 78400021
         L     MVCPTR,MPTRSAV          RESTORE MOVE DESTINATION  S21016 78480021
         NI    TEMPSW,OFF              TURN OFF SWITCH           S21016 78560021
TRNS0075 EX    DATALEN,DATAMVC         MOVE THE GOOD DATA OVER   S21016 78640021
*                                      THE NULL ITEM             S21016 78720021
TRNS0080 L     DATALEN,DLENSAV         RESTORE THE LENGTH OF     S21016 78800021
*                                      DATA REMAINING IN TABLE   S21016 78880021
         SH    DATALEN,NULLEN          SUBTRACT LENGTH OF NULL   S21016 78960021
*                                      ITEM JUST OVERWRITTEN     S21016 79040021
         L     DATAPTR,DPTRSAV         RESTORE THE ADDR. OF NEXT S21016 79120021
*                                      DATA TO BE PROCESSED      S21016 79200021
         AH    DATAPTR,NULLEN          ADD LENGTH OF NULL ITEM   S21016 79280021
         B     TRNSLOOP                GO TO SEE IF THERE ARE    S21016 79360021
*                                      MORE NULL ITEMS           S21016 79440021
TRNS0100 CR    DATALEN,RECLEN          COMPARE LENGTH OF DATA IN S21016 79520021
*                                      TABLE TO AMOUNT OF DATA   S21016 79600021
*                                      WHICH CAN GO ONTO ONE REC S21016 79680021
         BNH   LASTRANS                IF REMAINING DATA CAN GO  S21016 79760021
*                                      ONTO ONE RECORD, BRANCH   S21016 79840021
         MVI   IDRBYTCT,TRUDMAX        ELSE, SET BYTE COUNT TO   S21016 79920021
*                                      MAX LENGTH FOR ONE REC    S21016 80000021
MOVETRUD MVC   TRUDATA(TRUDLEN),LOC(DATAPTR)  MOVE DATA FROM     S21016 80080021
*                                      TABLE TO FILL ONE RECORD  S21016 80160021
*                                      IN BUFFER                 S21016 80240021
         BAL   TEMPRTN,OUT00990        GO TO WRITE THE RECORD    S21016 80320021
         LA    DATAPTR,TRUDLEN(DATAPTR)  UPDATE POINTER TO DATA  S21016 80400021
*                                      BY AMOUNT JUST WRITTEN    S21016 80480021
         SR    DATALEN,RECLEN          UPDATE LENGTH OF DATA     S21016 80560021
*                                      REMAINING IN TABLE        S21016 80640021
         B     TRNSLOOP                LOOP TO CONTINUE          S21016 80720021
*                                      PROCESSING THE            S21016 80800021
*                                      REMAINING DATA            S21016 80880021
LASTRANS BCTR  DATALEN,LOC             SUBTRACT ONE FROM DATA    S21016 80960021
*                                      LENGTH FOR ZERO-ORIENTED  S21016 81040021
*                                      MOVE LENGTH               S21016 81120021
         EX    DATALEN,MOVETRUD        EXECUTE MOVE OF REMAINING S21016 81200021
*                                      DATA TO IDR BUFFER        S21016 81280021
         LA    DATALEN,ADDLEN(DATALEN) ADD 3 TO MOVE LENGTH TO   S21016 81360021
*                                      GET CORRECT BYTE COUNT    S21016 81440021
*                                      FOR THIS RECORD           S21016 81520021
         STC   DATALEN,IDRBYTCT        STORE BYTE COUNT INTO     S21016 81600021
*                                      BUFFER                    S21016 81680021
         LA    WRITECT,UNIT(DATALEN)   ADD ONE TO BYTE COUNT FOR S21016 81760021
*                                      ACTUAL RECORD LENGTH      S21016 81840021
         B     TRNSDONE                GO TO PROCESS TRANSLATOR  S21016 81920021
*                                      RECORD JUST BUILT AND     S21016 82000021
*                                      USER-DATA IDR'S, IF ANY   S21016 82080021
         SPACE 1                                                 S21016 82160021
*********************************************************************** 82240021
*                                                                     * 82320021
*               PROCESS IDR USER-DATA RECORD(S)                       * 82400021
*                                                              S21016 * 82480021
*********************************************************************** 82560021
         SPACE 1                                                 S21016 82640021
USERREC  BAL   TEMPRTN,OUT00990        GO TO WRITE LAST IDR WITH S21016 82720021
*                                      TRANSLATOR DATA           S21016 82800021
         MVI   SUBTYPE,USERTYPE        MOVE INDICATOR FOR        S21016 82880021
*                                      USER-SUPPLIED DATA TO     S21016 82960021
*                                      IDR SUBTYPE FIELD         S21016 83040021
         LA    WRITECT,TURECLEN        LOAD RECORD LENGTH FOR    S21016 83120021
*                                      WRITE ROUTINE             S21016 83200021
         LR    DATAPTR,TABADD          POINT TO START OF DATA    S21016 83280021
         LR    DATALEN,TABEND          LOAD ENDING ADDRESS OF    S21016 83360021
*                                      DATA IN TABLE             S21016 83440021
         SR    DATALEN,TABADD          SUBTRACT STARTING ADDRESS S21016 83520021
*                                      TO OBTAIN LENGTH OF DATA  S21016 83600021
USERLOOP LA    RECLEN,TRUDLEN          LOAD DATA LENGTH FOR ONE  S21016 83680021
*                                      RECORD                    S21016 83760021
         CR    DATALEN,RECLEN          COMPARE LENGTH OF DATA    S21016 83840021
*                                      TO LENGTH OF 1 RECORD     S21016 83920021
         BNL   USER0020                IF DATA LENGTH IS NOT <   S21016 84000021
*                                      RECORD LENGTH, BRANCH     S21016 84080021
         LR    RECLEN,DATALEN          ELSE, GET DATA LENGTH     S21016 84160021
USER0020 ST    DATAPTR,DPTRSAV         SAVE POINTER TO START OF  S21016 84240021
*                                      DATA                      S21016 84320021
USER0040 CLC   LOC(LEN2,DATAPTR),NULITEM  IS THIS THE START OF   S21016 84400021
*                                      A NULL ITEM?              S21016 84480021
         BE    USER0060                IF SO, GO TO SKIP IT      S21016 84560021
         LA    DATAPTR,UNIT(DATAPTR)   UPDATE BY ONE BYTE        S21016 84640021
         BCT   RECLEN,USER0040         GO TO CONTINUE SCANNING   S21016 84720021
*                                      FOR A NULL ITEM UNTIL THE S21016 84800021
*                                      COUNT IS EXHAUSTED        S21016 84880021
         LA    RECLEN,TRUDLEN          RESTORE NORMAL REC.LENGTH S21016 84960021
         L     DATAPTR,DPTRSAV         RESTORE DATA POINTER      S21016 85040021
         B     USER0100                GO TO PROCESS THE DATA    S21016 85120021
USER0060 ST    DATALEN,DLENSAV         SAVE LENGTH OF DATA       S21016 85200021
         MVC   NULLEN(LEN2),LEN2(DATAPTR)  GET LENGTH OF NULL    S21016 85280021
*                                      ITEM                      S21016 85360021
         LR    DATALEN,DATAPTR         GET STARTING ADDR. OF     S21016 85440021
*                                      NULL ITEM                 S21016 85520021
         S     DATALEN,DPTRSAV         SUBTRACT STARTING ADDR.   S21016 85600021
*                                      OF DATA FOR LENGTH OF     S21016 85680021
*                                      GOOD DATA PRECEEDING THE  S21016 85760021
*                                      NULL ITEM                 S21016 85840021
         LTR   DATALEN,DATALEN         TEST LENGTH OF GOOD DATA  S21016 85920021
         BZ    USER0080                IF ZERO, BRANCH           S21016 86000021
         CH    DATALEN,NULLEN          IS LENGTH OF GOOD DATA >  S21016 86080021
*                                      LENGTH OF NULL ITEM?      S21016 86160021
         BNH   USER0070                IF NOT, BRANCH            S21016 86240021
         OI    TEMPSW,ON               TURN SWITCH TO INDICATE   S21016 86320021
*                                      A TEMPORARY MUST BE USED  S21016 86400021
*                                      TO MOVE DATA              S21016 86480021
USER0070 LR    MVCPTR,DATAPTR          GET STARTING ADDR. OF     S21016 86560021
*                                      NULL ITEM                 S21016 86640021
         AH    MVCPTR,NULLEN           ADD LENGTH OF NULL ITEM   S21016 86720021
*                                      TO POINT TO END OF IT     S21016 86800021
         SR    MVCPTR,DATALEN          SUBTRACT LENGTH OF GOOD   S21016 86880021
*                                      DATA TO DETERMINE ADDR.   S21016 86960021
*                                      GOOD DATA SHOULD GO TO    S21016 87040021
         BCTR  DATALEN,LOC             SUBTRACT 1 FROM LENGTH OF S21016 87120021
*                                      GOOD DATA FOR MOVE        S21016 87200021
         L     DATAPTR,DPTRSAV         POINT BACK TO START OF    S21016 87280021
*                                      GOOD DATA                 S21016 87360021
         TM    TEMPSW,ON               IS TEMPORARY NEEDED FOR   S21016 87440021
*                                      MOVE?                     S21016 87520021
         BNO   USER0075                IF NOT, BRANCH            S21016 87600021
         ST    MVCPTR,MPTRSAV          SAVE POINTER TO MOVE      S21016 87680021
*                                      DESTINATION               S21016 87760021
         LA    MVCPTR,DATATEMP         POINT TO TEMPORARY        S21016 87840021
         EX    DATALEN,DATAMVC         MOVE DATA TO TEMPORARY    S21016 87920021
         LR    DATAPTR,MVCPTR          POINT TO TEMPORARY        S21016 88000021
         L     MVCPTR,MPTRSAV          RESTORE MOVE DESTINATION  S21016 88080021
         NI    TEMPSW,OFF              TURN OFF SWITCH           S21016 88160021
USER0075 EX    DATALEN,DATAMVC         MOVE THE GOOD DATA OVER   S21016 88240021
*                                      THE NULL ITEM             S21016 88320021
USER0080 L     DATALEN,DLENSAV         RESTORE THE LENGTH OF     S21016 88400021
*                                      DATA REMAINING IN TABLE   S21016 88480021
         SH    DATALEN,NULLEN          SUBTRACT LENGTH OF NULL   S21016 88560021
*                                      ITEM JUST OVERWRITTEN     S21016 88640021
         L     DATAPTR,DPTRSAV         RESTORE THE ADDR. OF NEXT S21016 88720021
*                                      DATA TO BE PROCESSED      S21016 88800021
         AH    DATAPTR,NULLEN          ADD LENGTH OF NULL ITEM   S21016 88880021
         B     USERLOOP                GO TO SEE IF THERE ARE    S21016 88960021
*                                      MORE NULL ITEMS           S21016 89040021
USER0100 CR    DATALEN,RECLEN          COMPARE LENGTH OF DATA IN S21016 89120021
*                                      TABLE TO AMOUNT OF DATA   S21016 89200021
*                                      WHICH CAN GO ONTO ONE REC S21016 89280021
         BNH   LASTUSER                IF REMAINING DATA CAN GO  S21016 89360021
*                                      ONTO ONE RECORD, BRANCH   S21016 89440021
         MVI   IDRBYTCT,TRUDMAX        ELSE, SET BYTE COUNT TO   S21016 89520021
*                                      MAX LENGTH FOR ONE REC    S21016 89600021
         MVC   TRUDATA(TRUDLEN),LOC(DATAPTR)  MOVE DATA FROM     S21016 89680021
*                                      TABLE TO FILL ONE RECORD  S21016 89760021
*                                      IN BUFFER                 S21016 89840021
         BAL   TEMPRTN,OUT00990        GO TO WRITE THE RECORD    S21016 89920021
         LA    DATAPTR,TRUDLEN(DATAPTR)  UPDATE POINTER TO DATA  S21016 90000021
*                                      BY AMOUNT JUST WRITTEN    S21016 90080021
         SR    DATALEN,RECLEN          UPDATE LENGTH OF DATA     S21016 90160021
*                                      REMAINING IN TABLE        S21016 90240021
         B     USERLOOP                LOOP TO CONTINUE          S21016 90320021
*                                      PROCESSING THE            S21016 90400021
*                                      REMAINING DATA            S21016 90480021
LASTUSER BCTR  DATALEN,LOC             SUBTRACT ONE FROM DATA    S21016 90560021
*                                      LENGTH FOR ZERO-ORIENTED  S21016 90640021
*                                      MOVE LENGTH               S21016 90720021
         EX    DATALEN,MOVETRUD        EXECUTE MOVE OF REMAINING S21016 90800021
*                                      DATA TO IDR BUFFER        S21016 90880021
         LA    DATALEN,ADDLEN(DATALEN) ADD 3 TO MOVE LENGTH TO   S21016 90960021
*                                      GET CORRECT BYTE COUNT    S21016 91040021
*                                      FOR THIS RECORD           S21016 91120021
         STC   DATALEN,IDRBYTCT        STORE BYTE COUNT INTO     S21016 91200021
*                                      BUFFER                    S21016 91280021
         LA    WRITECT,UNIT(DATALEN)   ADD ONE TO BYTE COUNT FOR S21016 91360021
*                                      ACTUAL RECORD LENGTH      S21016 91440021
         B     USERDONE                GO TO PROCESS LAST REC    S21016 91520021
*                                                                     * 91600021
MOVEINST MVC   0(1,TEMP2),0(NOTL1ADD)     MOVE NOTE LIST 1 TO NOTE LST2 91680021
ZEROHIID XC    0(1,HIIDTAB),0(HIIDTAB)   ZERO                           91760021
SAVE1415 DC    2F'0'                    SAVE AREA FOR REGS 14 AND 15    91840021
WORD     DC    F'0'                                                     91920021
FOUR     DC    H'4'                                                     92000021
SWITCH   DC    X'00'               SWITCHES AND INCICATORS              92080021
TXTIOLP  EQU   X'80'               TXTIO LOOP INDICATOR                 92160021
*        OTHER BITS OF SWITCH --SPARE                                   92240021
*********************************************************************** 92320021
*********************************************************************** 92400021
TPASSVCN DC    V(IEWLMSCD)              ADDR OF 2ND PASS PROCESSOR      92480021
FNALVCON DC    V(IEWLMFNL)              ADDR OF FINAL  PROCESSOR        92560021
MAPAD    DC    V(IEWLMMAP)             ADDRESS OF MAP PROCESSOR         92640021
DEFADDR  DC    V(IEWLMDEF)             ADDRESS OF MDEF CSECT     S21016 92680021
ADHIID   DC    A(SEGLNTAB)         ADDRESS OF ADDRESS OF TABLE          92720021
DCBINTER DC    AL4(IEWLCUDB)            SYSUT1 DCB                      92800021
SYSMDDCB EQU   *                                                        92880021
DCBLMOD  DC    AL4(IEWLCMDB)            SYSLMOD DCB                     92960021
         SPACE 1                                                 S21016 93040021
******************** IDR DEFINED CONSTANTS **********************S21016 93120021
         SPACE 1                                                 S21016 93200021
IDRZHDR  DC    X'80FA0100'             RECORD HEADER FOR IDR     S21016 93280021
*                                      SPZAP RECORDS             S21016 93360021
ZAPSIZE  DC    F'13'                   SIZE OF AN SPZAP ENTRY    S21016 93440021
LKIDR    DC    X'801102'               LKED IDR HEADER           S21016 93520021
         DC    CL10'360SED521'         LKED COMPONENT NAME       S21016 93600021
LKRELNO  DS    XL2'2100'               LKED VERSION/MODIFICATION S21016 93680021
*                                      LEVEL (=OS RELEASE LEVEL) S21016 93760021
NULITEM  DC    X'FFFF'                 NULL ITEM INDICATOR        M1602 93840021
DATAMVC  MVC   LOC(LOC,MVCPTR),LOC(DATAPTR)  EXECUTED MOVE       S21016 93920021
TEMPSW   DC    X'00'                   'TEMPORARY NEEDED FOR     S21016 94000021
*                                      MOVE' SWITCH (WHEN LOW    S21016 94080021
*                                      ORDER BIT = 1)            S21016 94160021
         SPACE 1                                                 S21016 94240021
******************** IDR DEFINED STORAGE ********************    S21016 94320021
         SPACE 1                                                 S21016 94400021
IDRBUF   DS    CL256                   IDR BUFFER                S21016 94480021
DATATEMP DS    CL253                   WORK AREA FOR DATA MOVING S21016 94560021
MPTRSAV  DS    F                       SAVEAREA FOR MOVE POINTER S21016 94640021
DPTRSAV  DS    F                       SAVEAREA FOR DATA POINTER S21016 94720021
DLENSAV  DS    F                       SAVEAREA FOR DATA LENGTH  S21016 94800021
TEMPSAVE DS    12F                     TEMPORARY SAVE AREA FOR   S21016 94880021
*                                      IDR OUTPUT SUBROUTINE     S21016 94960021
TIMESAVE DS    F                       SAVE AREA FOR REG 0       S21016 95040021
*                                      FOR TIME MACRO            S21016 95120021
DATESAVE DS    F                       SAVE AREA FOR REG 1       S21016 95200021
*                                      FOR TIME MACRO            S21016 95280021
NULLEN   DS    H                       LENGTH OF A NULL ITEM     S21016 95360021
         SPACE 2                                                 S21016 95440021
*****************************************************************S21016 95520021
**********         SYMBOLIC DISPLACEMENTS WITHIN       **********S21016 95600021
**********          IDR DEFINED STORAGE FIELDS         **********S21016 95680021
*****************************************************************S21016 95760021
         SPACE 2                                                 S21016 95840021
ZAPDATA  EQU   IDRBUF+4                LOCATION IN IDR BUFFER    S21016 95920021
*                                      WHERE SPZAP DATA IS       S21016 96000021
*                                      PLACED                    S21016 96080021
ZAPDAT1  EQU   IDRBUF+5                SECOND BYTE OF SPZAP DATA S21016 96160021
ZAPCNT   EQU   IDRBUF+3                LOCATION OF COUNT FIELD   S21016 96240021
*                                      IN IDR BUFFER FOR SPZAP   S21016 96320021
*                                      DATA                      S21016 96400021
LKDATE   EQU   IDRBUF+15               LOCATION FOR LKED DATE    S21016 96480021
*                                      IN IDR BUFFER             S21016 96560021
DATESAV  EQU   DATESAVE+1              LOCATION OF 1ST BYTE OF   S21016 96640021
*                                      PACKED DECIMAL DATE IN    S21016 96720021
*                                      WORD RETURNED BY TIME     S21016 96800021
*                                      MACRO                     S21016 96880021
SUBTYPE  EQU   IDRBUF+2                LOCATION OF SUBTYPE FIELD S21016 96960021
*                                      IN IDR BUFFER             S21016 97040021
IDRBYTCT EQU   IDRBUF+1                IDR BYTE COUNT FIELD      S21016 97120021
TRUDATA  EQU   IDRBUF+3                STARTING LOCATION OF USER S21016 97200021
*                                      OR TRANSLATOR DATA IN IDR S21016 97280021
*                                      BUFFER                    S21016 97360021
***************** END OF IDR SUPPORT ADDITIONS ***************** S21016 97440021
         SPACE 3                                                 S21016 97520021
         DS    43F  ********** MAINTENANCE AREA **********              97600021
*                                                                       97680021
*              TEMPORY ERROR PARMS  -  MESSAGE NUMBER IN DECIMAL        97760021
*                                                                       97840021
DISP1    EQU   X'03'                    DISP=0  SEV = 3                 97920021
MESS1    EQU   14                       NO TXT IN LOAD MOD              98000021
         DS    0F                                                       98080021
*                                                                       98160021
ERRPARM1 DC    AL1(DISP1)               NO TXT IN LOAD MODULE           98240021
         DC    AL1(MESS1)                                               98320021
         IEWAPT                                                         98400021
DEFDSECT DSECT                                                          98408021
         DS    CL4                                               S21016 98416021
         DS    AL4                                               S21016 98424021
         DS    AL4                                               S21016 98432021
         DS    AL4                                               S21016 98440021
         DS    CL4                                               S21016 98448021
SGRELNO  DS    CL4                     SYSGEN-ASSIGNED OS        S21016 98456021
*                                      RELEASE NUMBER            S21016 98464021
         END                                                            98480021
