         TITLE 'IEWLMRAT   RLD/TXT PROCESSOR'                           00040000
*                 R L D / T X T    P R O C E S S O R                    00080000
         SPACE 2                                                        00120000
*FUNCTION/OPERATION -- THIS MODULE WILL HANDLE TEXT AND RLD RECORDS   * 00160000
*  FROM BOTH LOAD MODULES AND OBJECT MODULES.  IT WILL RECEIVE CONTROL* 00200000
*  FROM THE INPUT PROCESSOR AND WILL PUT ITS OUTPUT ON AN INTERMEDIATE* 00240000
*  FILE FOR USE BY THE SECOND PASS IF THE OUTPUT EXCEEDS THE SPACE    * 00280000
*  AVAILABLE IN THE OUTPUT BUFFER.  IN GENERAL THE RLD/TXT PROCESSOR  * 00320000
*  ORDERS THE INFORMATION FOR THE SECOND PASS PROCESSOR.              * 00360000
*                                                                     * 00400000
*ENTRY POINTS -- CONTROL IS PASSED BY THE INPUT PROCESSOR TO LOCATION * 00440000
*  IEWLMRAT                                                           * 00480000
*                                                                     * 00520000
*INPUT -- THE INPUT PROCESSOR SUPPLIES INFORMATION IN REGISTERS       * 00560000
*  REG 4 (RLD ONLY) -- BYTE COUNT OF RLD INPUT                          00600000
*  REG 6 (RLD ONLY) -- LOCATION IN STORAGE OF RLD INPUT                 00640000
*  REG 3 (TXT ONLY) -- ASSEMBLED ADDRESS OF FIRST BYTE OF TEXT        * 00680000
*  REG 6 (TXT ONLY) -- ID OF THIS TEXT RECORD                         * 00720000
*  REG 8 (TXT ONLY) -- LENGTH OF LOAD MODULE INPUT                      00760000
*                                                                     * 00800000
*OUTPUT -- IF ALL THE OUTPUT INFORMATION CAN BE CONTAINED IN THE OUT- * 00840000
*  PUT BUFFER, IT REMAINS IN STORAGE.  IF IT EXCEEDS THE CAPACITY OF  * 00880000
*  THE BUFFER ALL OF THE INFORMATION IS WRITTEN OUT ON AN INTERMEDIATE* 00920000
*  FILE.                                                              * 00960000
*                                                                     * 01000000
*EXTERNAL ROUTINES.                                                   * 01040000
*  ERROR DIAGNOSTIC ROUTINE -- OUTPUTS ERROR MESSAGES                 * 01080000
*  ESD PROCESSOR -- PLACES ENTRIES IN DELINK TABLE                    * 01120000
*                                                                     * 01160000
*EXITS                                                                * 01200000
*  NORMAL -- RETURN TO INPUT PROCESSOR                                * 01240000
*  ERRORS -- INTERNAL TABLES MAY OVERFLOW                             * 01280000
*     A)  CALLS LIST -- TOO MANY CALLS IN OVERLAY STRUCTURE           * 01320000
*     B)  RLD NOTE LIST -- TOO MANY CONTROL SECTIONS THAT CONTAIN RLD * 01360000
*           ITEMS                                                     * 01400000
*     C)  TEXT NOTE LIST -- TOO MANY CONTROL SECTIONS THAT CONTAIN    * 01440000
*           TEXT OR THERE ARE EXCESSIVE RE-ORIGINS WITHIN THE INPUT   * 01480000
*     D)  TEXT ID IS ILLEGAL.  TEXT RECORD IS IGNORED.                * 01520000
*                                                                     * 01560000
*TABLES                                                               * 01600000
*  THE FOLLOWING TABLES IN THE ALL PURPOSE TABLE ARE USED --          * 01640000
*                                                                     * 01680000
*     CALLS LIST-IN OVERLAY, LIST OF CALLS TO OTHER CONTROL SECTIONS, * 01720000
*        USED IN CREATION OF ENTABS                                   * 01760000
*                                                                     * 01800000
*     COMPOSITE ESD - USED TO GET ASSEMBLED ADDRESS OF CONTROL SECTION* 01840000
*                                                                     * 01880000
*     RENUMBERING TABLE -- USED TO RENUMBER RLD AND TEXT ITEMS        * 01920000
*                                                                     * 01960000
         EJECT                                                          02000000
*  TEXT I/O TABLE -- 4 BYTES PER ENTRY                                * 02040000
*                                                                     * 02080000
*        *************************                                    * 02120000
*        *           *           *                                    * 02160000
*        *     ID    * FLG--MULT *                                    * 02200000
*        *           *           *                                    * 02240000
*        *************************                                    * 02280000
*        '           '           '                                    * 02320000
*        '  2 BYTES  '  2 BYTES  '                                    * 02360000
*        '           '           '                                    * 02400000
*                                                                     * 02440000
*  FOR EACH CHANGE, IN THE INPUT STREAM, OF AN ID OR A MULTIPLICITY,  * 02480000
*  AN ENTRY IS MADE IN THE TEXT I-O TABLE.  THE 'ID' IS THE ID OF A   * 02520000
*  TXT RECORD.  THE 'MULTIPLICITY' IS CALCULATED FOR EACH TEXT RECORD * 02560000
*  THAT IS PRESENTED.  A CHANGE IN MULTIPLICITY WILL OCCUR --         * 02600000
*    1) FOR EACH TEXT RECORD THAT IS A MULTIPLE OF UT1SIZE.           * 02640000
*      (UT1SIZE IS THE SIZE OF THE TEXT BUFFER AND THE MAXIMUM SIZE   * 02680000
*      OF A TEXT RECORD FROM A LOAD MODULE)                           * 02720000
*    2) FOR EACH RE-ORIGIN OF TEXT WITHIN A CONTROL SECTION (THE CON- * 02760000
*      TROL SECTION BEING GREATER THAN UT1SIZE).                      * 02800000
*                                                                     * 02840000
*  TEXT NOTE LIST -- 7 BYTES PER ENTRY                                * 02880000
*                                                                     * 02920000
*  THERE IS A ONE-TO-ONE CORRESPONDENCE BETWEEN THE TEXT I-O TABLE    * 02960000
*  AND THE TEXT NOTE LIST.  THE 'NTH' ENTRY OF THE TEXT I-O TABLE     * 03000000
*  REFERS TO THE 'NTH' RECORD OF THE TEXT NOTE LIST.  THE NOTE LIST   * 03040000
*  RELATES WHERE THE TEXT RECORD HAS BEEN WRITTEN ON THE DISK THROUGH * 03080000
*  THE 3 BYTE TTR ENTRY.  IF THE INPUT DECK HAS BEEN SHUFFLED OR IF   * 03120000
*  THERE ARE RE-ORIGINS WITHIN THE CONTROL SECTION (REPRESENTED BY    * 03160000
*  THE ID IN THE TXT I/O TABLE) THEN THE CONTROL SECTION CAN NOT BE   * 03200000
*  GATHERED AT ONE TIME.  THEREFORE, 'PIECES' OF TEXT WHICH ARE CALLED* 03240000
*  'DENSE' RECORDS ARE PLACED ON THE INTERMEDIATE FILE.  THE 2 BYTE   * 03280000
*  RELATIVE ADDRESS (OFFSET) DEFINES WHERE THIS 'PIECE' OF TEXT OCCURS* 03320000
*  WITHIN THE TEXT BUFFER.  THE SECOND PASS PROCESSOR WILL GATHER ALL * 03360000
*  THE 'PIECES' FOR EACH CONTROL SECTION AND MERGE THEM.              * 03400000
*                                                                     * 03440000
*        *******************************************                  * 03480000
*        *            *                *           *                  * 03520000
*        *   OFFSET   *  TTR/STG ADDR  *  LENGTH   *                  * 03560000
*        *            *                *           *                  * 03600000
*        *******************************************                  * 03640000
*        '            '                '           '                  * 03680000
*        '  2 BYTES   '    3 BYTES     '  2 BYTES  '                  * 03720000
*        '            '                '           '                  * 03760000
*                                                                     * 03800000
*                                                                     * 03840000
*                                                                     * 03850000
         EJECT                                                          03860000
*                                                                     * 03870000
*  TEXT I/O CONTROL TABLE -- 4 BYTES PER ENTRY                        * 03880000
*                                                                     * 03920000
*  TO SAVE SPACE THE TEXT NOTE LIST IS NOT KEPT 'COMPLETELY' IN CORE. * 03960000
*  INSTEAD, WHEN IT REACHES A MAXIMUM VALUE, IT IS WRITTEN ON AN      * 04000000
*  INTERMEDIATE FILE AND THE RESULTANT TTR IS PLACED IN THE TEXT I/O  * 04040000
*  CONTROL TABLE.                                                     * 04080000
*                                                                     * 04120000
*                                                                     * 04200000
*        ************************                                     * 04240000
*        *      *               *                                     * 04280000
*        *   0  *      TTR      *                                     * 04320000
*        *      *               *                                     * 04360000
*        ************************                                     * 04400000
*        '      '               '                                     * 04440000
*        '   1  '               '                                     * 04480000
*        ' BYTE '    3 BYTES    '                                     * 04520000
*        '      '               '                                     * 04560000
*                                                                     * 04600000
*                                                                     * 04640000
*                                                                     * 04650000
*                                                                     * 04660000
*  RLD NOTE LIST -- 9 BYTES PER ENTRY                                 * 04680000
*                                                                     * 04720000
*        ****************************************************         * 04760000
*        *1.         *2.         *3.         *4.            *         * 04800000
*        *     ID    * FLG--MULT *  LENGTH   * TTR/ACCM LNG *         * 04840000
*        *           *           *           *              *         * 04880000
*        ****************************************************         * 04920000
*        '           '           '           '              '         * 04960000
*        '  2 BYTES  '  2 BYTES  '  2 BYTES  '   3 BYTES    '         * 05000000
*        '           '           '           '              '         * 05040000
*                                                                     * 05080000
*  1. THE ID IS THE ID OF THE CONTROL SECTION IN WHICH THE RLD ITEMS  * 05120000
*     OCCUR                                                           * 05160000
*  2. THE LOWEST MULTIPLICITY OF AN ADDRESS FIELD, OF AN RLD ITEM IN  * 05200000
*     THIS RLD RECORD, IS STORED HERE.                                * 05240000
*  3. THE NUMBER OF BYTES IN THE RLD RECORD IS DIVIDED BY 4 AND SAVED * 05280000
*     IN THIS TWO BYTE ENTRY.  (WORD COUNT)                           * 05320000
*  4. THE ACCUMULATED WORD COUNT OF GROUPED ENTRIES IS SAVED HERE,    * 05360000
*     EXCEPT WHEN IT IS IN THE LAST ENTRY OF A RECORD WRITTEN OUT ON  * 05400000
*     THE INTERMEDIATE DATA SET.  THEN IT HOLDS THE TTR OF THE RECORD.* 05440000
*                                                                     * 05480000
         EJECT                                                          05490000
*                                                                     * 05500000
*                                                                     * 05520000
*  THE RLD I/O CONTROL TABLE - 4 BYTES PER ENTRY                      * 05560000
*                                                                     * 05600000
*  TO SAVE SPACE THE RLD NOTE LIST IS NOT KEPT 'COMPLETELY' IN CORE.  * 05640000
*  INSTEAD, WHEN IT REACHES A MAXIMUM VALUE, IT IS WRITTEN ON AN      * 05680000
*  INTERMEDIATE DATA SET AND THE RESULTANT TTR IS PLACED IN THE RLD   * 05720000
*  I/O CONTROL TABLE.                                                 * 05760000
*                                                                     * 05800000
*        ************************                                     * 05840000
*        *      *               *                                     * 05880000
*        *   0  *      TTR      *                                     * 05920000
*        *      *               *                                     * 05960000
*        ************************                                     * 06000000
*        '      '               '                                     * 06040000
*        '   1  '               '                                     * 06080000
*        ' BYTE '    3 BYTES    '                                     * 06120000
*        '      '               '                                     * 06160000
*                                                                     * 06200000
*                                                                     * 06240000
*                                                                     * 06280000
*                                                                     * 06320000
*ATTRIBUTES                                                           * 06360000
*  1) REUSABLE                                                        * 06400000
*                                                                     * 06440000
*NOTES -- NONE                                                        * 06480000
*                                                                     * 06520000
*                                                                     * 06560000
*                                                                     * 06600000
*                                                                     * 06640000
*    *    *    *    *    *    *    *    *    *    *    *    *    *    * 06680000
*                                                                     * 06720000
*    *    *    *    *    *    *    *    *    *    *    *    *    *    * 06760000
         SPACE 2                                                        06800000
     TITLE  'IEWLMRAT   RLD/TXT PROCESSOR  --  RLD EQUIVALENCIES'       06840000
IEWLMRAT CSECT                 ENTRY POINT                              06880000
* 280500-280800,292000,298400                                    A20457 06890000
* 730000-730350                                                  A19655 06900000
* 867600                                                         A22517 06910000
* 840800-842800                                                  A34759 06911021
* 556000,632000-634000,721600-724400                             A30147 06913021
* 730050-730400                                                  A33791 06916021
* 250400                                                         A36529 06918021
*A277200                                                         A38313 06918121
*A902400                                                         S21016 06918221
*C435600-436000,437200-470000,472000-480300,883200-885200        S21016 06918421
*C885600-896800,898000-901600                                    S21016 06918621
*C178240                                                         A43127 06919321
*A502400                                                         A43127 06919621
*C256800,A256100,257700-257900                                   A52402 06919700
*C277520,A277520                                           M0513,A49482 06919821
*A204500-204760,224500-224784,472100                             A53300 06919900
*A108000,C204600,C224600                                        SA53762 06933221
*I277360                                                        SA57133 06943221
*I495300,C516800,I526400,I774800,C775200,D775600,I902710        SA56444 06945221
*I714800                                                        SA56444 06945621
*I336000,I383600,C386000                                        SA59588 06946021
*I224784,I436400                                                SA69196 06946421
         SPACE 1                                                        06946721
         EXTRN IEWLCUDB                                                 06960000
         SPACE 2                                                        07000000
*                  MASKS, FLAGS, OFFSETS AND VALUES                     07040000
         SPACE 2                                                        07080000
*                       FOR ALL PURPOSE TABLE                           07120000
         SPACE 1                                                        07160000
EOD      EQU   X'01'     END-OF-DATA FLAG IN NEWSW                      07200000
RT       EQU   X'02'     TEXT FLAG IN APT0  (RLD/TEXT)                  07240000
DEL      EQU   X'10'     DELETE FLAG IN APT1                            07280000
EX       EQU   X'20'     LOAD MODULE FLAG IN APT1  (LD MOD/OBJ MOD)     07320000
OI       EQU   X'20'     OVERLAY FLAG IN PDSE7                          07360000
TUPAS    EQU   X'20'     2 PASS OPERATION IS CURRENT                    07400000
DELOFF   EQU   X'EF'     MASK OUT DELETE FLAG IN APT1                   07440000
ANY      EQU   X'EF'     FLAGS FOR ANY RLD ATTRIBUTES IN PDSE8          07480000
         SPACE 2                                                        07520000
*                       FOR RENUMBERING TABLE                           07560000
         SPACE 1                                                        07600000
DID      EQU   0         OFFSET FOR 'R' ID                              07640000
DF       EQU   2         OFFSET FOR FLAG IN RNT                         07680000
DT       EQU   3         OFFSET FOR TYPE IN RNT                         07720000
DSAV     EQU   X'04'     DELINK VALUE SAVED FLAG IN RNT                 07760000
CH       EQU   X'40'     CHAINED FLAG FOR TYPE IN RNT                   07800000
         SPACE 2                                                        07840000
*                             FOR DCB                                   07880000
         SPACE 1                                                        07920000
PHL      EQU   0         INITIAL DATA COUNT                             07960000
PHADD    EQU   0         INITIAL DATA AREA LOCATION                     08000000
LENGTH   EQU   6         OFFSET FOR DATA COUNT                          08040000
ADD      EQU   12        OFFSET FOR DATA AREA LOCATION                  08080000
DCBOPN   EQU   X'10'     SUCCESSFUL OPEN                                08120000
OPNFLGS  EQU   48        OPEN FLAGS IN DCB                              08160000
         SPACE  2                                                       08200000
*                           FOR RLD ITEM                                08240000
         SPACE 1                                                        08280000
CONT     EQU   1         CONTINUATION FLAG IN FA                        08320000
RELOFF   EQU   X'7F'     MASK OUT RELATIVE FLAG                         08360000
NREL     EQU   X'80'     NONRELATIVE FLAG IN 'R' POINTER                08400000
REL      EQU   X'80'     RELATIVE FLAG IN FA FIELD                      08440000
CONTN    EQU   X'FE'     CONTINUATION FLAG IN FA MASK OUT               08480000
ANYR     EQU   X'F0'     ANY TYPE FLAGS IN FA                           08520000
         EJECT                                                          08560000
*                            FOR MODULE                                 08600000
         SPACE 1                                                        08640000
BUFFRN2  EQU   X'01'     BUFFER 2 IS CURRENT                            08680000
BUFF1    EQU   X'02'     BUFFER 1 FULL                                  08720000
FNLCHK   EQU   X'02'     FINAL CHECK AT EOD                             08760000
CHKNOW   EQU   X'04'     CHECK LAST WRITE NOW                           08800000
BUFF2    EQU   X'04'     BUFFER 2 FULL                                  08840000
FULL2    EQU   X'06'     BUFFERS 1 AND 2 BOTH FULL                      08880000
BUFW1    EQU   X'08'     BUFFER 1 WRITTEN                               08920000
PURGE    EQU   X'08'     PURGE FLAG                                     08940000
BUFW2    EQU   X'10'     BUFFER 2 WRITTEN                               08960000
RNBUF2   EQU   X'10'     RLD'S-IN-BUFFER-2 FLAG                         09000000
NLFULL   EQU   X'10'     NOTE LIST FULL FLAG                            09040000
MCT      EQU   12        MAX SIZE FOR RLD/TXT I/O CONTROL TABLE         09080000
CKNNLF   EQU   X'14'     CHECK NOW AND NOTE LIST FULL                   09100000
WRIT2    EQU   X'18'     BUFFERS 1 AND 2 BOTH WRITTEN                   09120000
FULLR    EQU   X'20'     RLD I/O CONTROL TABLE FULL FLAG                09160000
BUF1CHK  EQU   X'20'     BUFFER 1 CHECKED FLAG                          09200000
BUF2CHK  EQU   X'40'     BUFFER 2 CHECKED FLAG                          09240000
NOPNR1   EQU   X'7F'     BUFFER 1 OPENER FLAG MASK OUT                  09280000
CONTOVN  EQU   X'7F'     CONTINUATION OVERFLOW FLAG MASK OUT            09320000
CONTOV   EQU   X'80'     CONTINUATION OVERFLOW FLAG                     09360000
OPNR1    EQU   X'80'     BUFFER 1 OPENER FLAG                           09400000
OP1BF2   EQU   X'81'     OPENER 1 AND BUFFER 2 NOW FLAGS                09440000
NBUF2CHK EQU   X'BF'     BUFFER 2 CHECKED FLAG MASK OUT                 09480000
NBUF1CHK EQU   X'DF'     BUFFER 1 CHECKED FLAG MASK OUT                 09520000
N2BUFWF  EQU   X'E1'     BOTH BUFFERS FULL AND WRITTEN FLAGS MASK OUT   09540000
NBUF2WF  EQU   X'EB'     BUFFER 2 FULL-WRITTEN FLAGS MASK OUT           09560000
NLFLCHKN EQU   X'EB'     NOTE LIST FULL + CHK NOW FLAGS MASK OUT        09600000
NBUFW2   EQU   X'EF'     BUFFER 2 WRITTEN FLAG MASK OUT                 09640000
RNBUF1   EQU   X'EF'     RLD'S-IN-BUFFER-1 MASK                         09680000
NBUF1WF  EQU   X'F5'     BUFFER 1 FULL-WRITTEN FLAGS MASK OUT           09720000
NBUFW1   EQU   X'F7'     BUFFER 1 WRITTEN FLAG MASK OUT                 09760000
NPURGE   EQU   X'F7'     PURGE FLAG MASK OUT                            09780000
NCHKNOW  EQU   X'FB'     CHECK NOW FLAG MASK OUT                        09800000
NBUFF2   EQU   X'FB'     BUFFER 2 FULL FLAG MASK OUT                    09840000
NBUFF1   EQU   X'FD'     BUFFER 1 FULL FLAG MASK OUT                    09880000
NFNLCHK  EQU   X'FD'     FINAL CHECK FLAG MASK OUT                      09920000
BUFLIP   EQU   X'FE'     EXTRACT CURRENT BUFFER FLAG MASK               09960000
BUFFRN1  EQU   X'FE'     BUFFER 1 CURRENT MASK                          10000000
STMULT   EQU   X'02'               FOR MAXIMUM STRING                   10040000
STMULT1  EQU   X'00'                  MULTIPLICITY                      10080000
         EJECT                                                          10120000
*                           FOR NOTE LIST                               10160000
         SPACE 1                                                        10200000
NFLGS    EQU   X'03'     NO FLAGS MASK                                  10240000
BUFN2    EQU   X'10'     BUFFER 2 HOLDS CURRENT RLD'S                   10280000
TTRF     EQU   X'40'     TTR IS PRESENT/END-OF-BUFFER                   10320000
NICF     EQU   X'6F'     RLD'S NOT-IN-CORE MASK                         10360000
INCF     EQU   X'80'     RLD'S IN-CORE FLAG                             10400000
GPF      EQU   X'BF'     SET GROUP FLAG MASK                            10440000
FLGS     EQU   X'FC'     ALL FLAGS MASK                                 10480000
         SPACE 2                                                        10520000
*                             FOR CESD                                  10560000
         SPACE 1                                                        10600000
DSAVOF   EQU   X'EF'     MASK OUT DELETE FLAG IN CESD                   10640000
         SPACE 2                                                        10680000
*                            ERROR CODES                                10720000
         SPACE 1                                                        10760000
ERRLM    EQU   X'317'    LOAD MODULE SOURCE ERROR               SA53762 10800021
ERRC     EQU   X'423'    CALLS LIST OVERFLOW                            10840000
ERRRM    EQU   X'425'    RLD I/O CONTROL TABLE OVERFLOW                 10880000
         EJECT                                                          10920000
*                       REGISTER ASSIGNMENTS                            10960000
         SPACE 1                                                        11000000
R0       EQU   0         SAVE/RESTORE, ERROR CODE, WORK REG             11040000
GR1      EQU   1         CESD ID, LINK THROUGH MULTDET, RESULTANT TTR   11080000
XS3      EQU   1         'R' ID                                         11120000
XAPT     EQU   2         POINTER TO APT                                 11160000
XRMK2    EQU   3         BYTE CT OF PROCESSED ENTRIES IN RLD I/O CTL TB 11200000
XAA      EQU   3         CURRENT LOC IN TEXT BUFFER                     11240000
GR3      EQU   3         POINTER TO CESD, ASSEMBLED ADDR IN FA          11280000
XJM1     EQU   4         INPUT REC BYTE CT, TEXT OUTPUT BUFFER BYTE CT  11320000
XPSAV    EQU   4         'P' ID, POINTER TO ID IN RNT                   11360000
GR4      EQU   4         START OF RLD STRING, DIVISION WORK REG         11400000
GR5      EQU   5         START RNT, DIVISION WORK REG                   11440000
XRET2    EQU   5         LINK THROUGH WRITE ROUTINE                     11480000
XPRLD    EQU   6         ORIGINAL POINTER TO START OF RLD STRING,       11520000
*                            CURRENT FA POINTER                         11560000
XBCNT    EQU   7         BYTE COUNT OF PROCESSED ITEMS                  11600000
XIBCNT   EQU   8         RLD STRING BYTE COUNT                          11640000
XRET     EQU   9         LINK THROUGH BUFFERING ROUTINE                 11680000
GR9      EQU   9         CURRENT RNT ENTRY POINTER                      11720000
XOBCNT   EQU   10        BYTE COUNT OF ITEMS IN RLD BUFFER              11760000
XDCB     EQU   10        POINTER TO SYSUT1 DCB                          11800000
XSTR     EQU   11        POINTER TO START OF RLD STRING                 11840000
RBASE    EQU   12        MODULE BASE REGISTER                           11880000
GR13     EQU   13        BASE REGISTER FOR MODULE SAVE AREA, POINTER    11920000
*                            TO CURRENT CESD ENTRY                      11960000
R14      EQU   14        RETURN LINK, WRITE DATA LENGTH                 12000000
XS1      EQU   14        POINTER TO CURRENT DELINK ENTRY, TO CURRENT    12040000
*                            CALLS LIST ENTRY, TO CURRENT CESD ENTRY,   12080000
*                            TEXT NOTE LIST OFFSET                      12120000
XS2      EQU   15        POINTER TO CURRENT RLD BUFFER ENTRY,           12160000
*                            TO CURRENT TEXT NOTE LIST ENTRY, TO        12200000
*                            CURRENT TEXT BUFFER ENTRY, WORK REG        12240000
R15      EQU   15        BRANCH ADDRESS, WRITE DATA LOC, CURRENT LOAD   12280000
*                            MODULE BUFFER ENTRY, WORK REG              12320000
XRIO     EQU   15        CURRENT RLD NOTE LIST ENTRY POINTER            12360000
         TITLE 'IEWLMRAT   RLD/TXT PROCESSOR  --  ENTRY AND EXIT'       12400000
*                           R L D / T X T                               12440000
*              C O M M O N   E N T R Y   AND   E X I T                  12480000
*                              ROUTINE                                  12520000
         SPACE 2                                                        12560000
*     THIS ROUTINE RECEIVES CONTROL FROM THE INPUT PROCESSOR.  IT SAVES 12600000
*  THE RETURN ADDRESS, DIFERENTIATES BETWEEN RLD AND TEXT MATERIAL, AND 12640000
*  PASSES CONTROL TO THE PROPER PROCESSING ROUTINE.  AT THE CONCLUSION  12680000
*  OF THIS PROCESSING, IT RE-ESTABLISHES THE RETURN ADDRESS AND RETURNS 12720000
*  CONTROL THERETO.                                                     12760000
*     EVENT SEQUENCE FOR ENTRY --                                       12800000
*        ESTABLISH BASE REGISTER FOR COMMON ROUTINES AND RLD PROCESSOR. 12840000
*        SAVE RETURN ADDRESS.                                           12880000
*        LOAD REMAINING BUFFERRED BYTE COUNT                            12920000
*        PROCEED TO PURGE RLD AND TEXT BUFFERS IF ENTRY IS FROM         12960000
*           END-OF-DATA.                                                13000000
*        DIRECT CONTROL TO EITHER THE RLD OR TEXT PROCESSING ROUTINE.   13040000
*        RELINQUISH CONTROL TO ERROR ROUTINE IF INPUT LENGTH IS         13080000
*           GREATER THAN MAXIMUM.                                       13120000
*        CLEAR STRING COUNT AND SAVE INPUT BYTE COUNT FOR RLD           13160000
*           PROCESSING ROUTINE.                                         13200000
*     EVENT SEQUENCE FOR PURGE/EXIT --                                  13240000
*        PURGE --                                                       13280000
*           CLEAR STRING COUNT ACCUMULATOR                              13320000
*           LINK TO RLD PURGE ROUTINE.                                  13360000
*           LINK TO TEXT PURGE ROUTINE.                                 13400000
*        EXIT --                                                        13440000
*           SAVE RLD BUFFERRED BYTE COUNT (RLD RETURN).                 13480000
*           LOAD RETURN ADDRESS (TEXT RETURN).                          13520000
*           RETURN TO CALLER.                                           13560000
         SPACE 2                                                        13600000
*IEWLMRAT  CSECT               ENTRY POINT AND NAME                     13640000
         BALR  RBASE,R0        L BASE REGISTER                          13680000
RATLOC   EQU   *               DEFINE BASE LOCATION                     13720000
         USING *,RBASE         DEFINE BASE REGISTER                     13760000
         USING APTDSECT,XAPT                                            13800000
         BC    15,MODIDR+6     SKIP IDENTITY                            13840000
MODIDR   DC    C'00MRAT'       MODULE IDENTITY IN CHARACTERS            13880000
         L     XBCNT,TXT001AD  L BASE REGISTER FOR TEXT PROCESSING RTN  13920000
         USING IEWLMTXT,XBCNT  DEFINE BASE REGISTER FOR TEXT PROCESSOR  13960000
         ST    R14,INADD1      SAVE CALLER RETURN ADDRESS               14000000
         LH    XOBCNT,OBCNT    L REMAINING BUFFERRED COUNT              14040000
         TM    NEWSW,EOD       CHK FOR END-OF-DATA                      14080000
         BC    7,ECPRG         BC IF YES TO PURGE ROUTINES              14120000
         LTR   XJM1,XJM1       NO -- CHK IF INPUT BYTE COUNT IS ZERO    14160000
         BC    8,TXTRET        IGNORE ZERO LENGTH TXT OR RLD INPUT      14200000
         TM    APT0,RT         CHK IF RLD OR TEXT                       14240000
         BC    8,RATIN         BC IF RLD                                14280000
         L     XS2,TXTBFEND    L LOC OF END OF TEXT BUFFER              14320000
         S     XS2,TXTBFBEG    LESS LOC OF START OF TEXT BUFFER         14360000
         CR    XJM1,XS2        CHK IF INPUT GREATER THAN SPAN           14400000
         BC    2,ERR3        INPUT RECORD LARGER THAN TXTBUFFER         14440000
         BCR   15,XBCNT        GO TO PROCESS TEXT                       14480000
RATIN    LH    XS2,ENRLD2X     RLD -- L SIZE OF RLD INPUT BUFFER        14520000
         CR    XJM1,XS2        CHK IF INPUT GREATER                     14560000
         BC    2,ERR1          BC IF YES -- ERROR                       14600000
         SR    XIBCNT,XIBCNT   CLEAR STRING COUNT ACCUMULATOR           14640000
         STH   XJM1,TTR1       SAVE RLD INPUT BYTE COUNT                14680000
RATINX   BC    15,RLD001       GO TO PROCESS RLD'S                      14720000
         SPACE 1                                                        14760000
ECPRG    SR    XIBCNT,XIBCNT   CLEAR STRING COUNT ACCUMULATOR           14800000
         BAL   XRET,RLDBUF     INPUT BYTE CT ZERO -- PURGE RLD          14840000
ECPRGX   STH   XIBCNT,OBCNT    CLEAR PREVIOUS BUFFERRED COUNT           14880000
         LA    XRET,TXTRET     SET INTERMEDIATE RETURN                  14920000
         L     R14,TXTBUFAD    L LOC OF TEXT PURGE ROUTINE              14960000
         BCR   15,R14          GO TO TEXT PURGE ROUTINE                 15000000
         SPACE 1                                                        15040000
RLDRET   STH   XOBCNT,OBCNT    SAVE BUFFERRED BYTE COUNT                15080000
         SPACE 1                                                        15120000
TXTRET   L     R15,INADD1      L RETURN ADDRESS                         15160000
         BALR  R14,R15         RETURN (WITH LINK)                       15200000
         SPACE 1                                                        15240000
MOVEJM1  MVC   0(0,XS2),0(XSTR)  MOVE INSTR TO MOVE ITEM TO BUFFER      15280000
         BC    15,RLD0161      CONTINUE PROCESSING IF LINKED            15320000
         SPACE 1                                                        15360000
MOVEJM1A MVC   0(4,XS2),SAVIDS   MOVE 'R' AND 'P' ID'S INTO BUFFER      15400000
         SPACE 1                                                        15440000
         TITLE 'IEWLMRAT   RLD/TXT PROCESSOR  --  WRITE ROUTINE'        15480000
*                          R L D / T X T                                15520000
*                     C O M M O N   W R I T E                           15560000
*                             ROUTINE                                   15600000
         SPACE 1                                                        15640000
*  THIS ROUTINE WRITES THE RLD AND TEXT INTERMEDIATE OUTPUT AS WELL   * 15680000
*  AS THE RLD AND TEXT NOTE LISTS AS REQUIRED.  AT ENTRY A TEST IS    * 15720000
*  MADE FOR RECORD SIZE ZERO.  ZERO SHOWS THE INPUT MODULE CONTAINED  * 15760000
*  NO TEXT OR RLD ITEMS OR THAT THE RLD ITEMS OCCURRED IN A MODULE    * 15800000
*  MARKED DELETE.  IN THE ZERO LENGTH CASE NO WRITE TAKES PLACE.      * 15840000
*  IF SYSUT1 HAS NOT BEEN OPENED PREVIOUSLY, IT IS OPENED NOW.          15880000
         SPACE 2                                                        15920000
RLDBUFR  LTR   R14,R14         CHK IF SIZE IS ZERO OR LESS              15960000
         BCR   12,XRET         BC IF YES -- RETURN                      16000000
COMBUF   LA    GR13,REGSA      SIZE NOT ZERO -- L LOC OF SAVE AREA      16040000
BUFFRET  L     XDCB,DCBAD      L LOC OF SYSUT1 DCB                      16080000
         STH   R14,DECBJM+LENGTH   SET DATA LENGTH IN DECB              16120000
         ST    R15,DECBJM+ADD   SET DATA AREA LOC IN DECB               16160000
         SPACE 1                                                        16200000
         TM    OPNFLGS(XDCB),DCBOPN  CHK IF DCB OPENED                  16240000
         BC    1,COMBUF2       BC IF YES                                16280000
         SPACE 1                                                        16320000
         MVC   DDNAME(8),40(XDCB)   NO -- RESERVE DD NAME               16340000
         OPEN  ((XDCB),(OUTIN))   OPEN SYSUT1 DCB                       16360000
         SPACE 1                                                        16400000
         TM    OPNFLGS(XDCB),DCBOPN   CHK IF OPEN SUCCESSFUL            16440000
         BC    1,COMBUF2       BC IF YES                                16480000
ABEND1   LA    GR1,DDNAME      NO -- L LOC OF DD NAME                   16510000
         LH    R0,OPNERR       L ERROR CODE                             16540000
         LA    R14,TXTRET      L RETURN ADDRESS                         16570000
         L     R15,ERDIG       L LOC OF ERROR ROUTINE                   16600000
         BCR   15,R15          GO TO ERROR ROUTINE                      16630000
         SPACE 1                                                        16680000
COMBUF2  WRITE DECBJM,SF,(XDCB),PHADD,PHL                               16720000
         BCR   15,XRET2        RETURN                                   16760000
         SPACE  1                                                       16800000
COMCHK   LA    GR13,REGSA      L LOC OF SAVE AREA                       16840000
         L     XDCB,DCBAD      L ADDRESS OF SYSUT1 DCB                  16880000
         SPACE  1                                                       16920000
         CHECK DECBJM                                                   16960000
         SPACE 1                                                        17000000
         NOTE  (XDCB)                                                   17040000
         SPACE 1                                                        17080000
         SR    XOBCNT,XOBCNT   CLEAR BUFFERRED BYTE COUNT               17120000
         BCR   15,XRET2        RETURN                                   17160000
         SPACE 2                                                        17170000
OPNERR   DC    X'241C'         FAILURE TO OPEN DCB CODE                 17180000
DDNAME   DC    C'SYSUT1  '                                              17190000
         SPACE 2                                                        17200000
   TITLE 'IEWLMRAT   RLD/TXT PROCESSOR  --  ERROR ROUTINE INTERFACE'    17240000
*                    E R R O R     R O U T I N E                        17280000
*                         I N T E R F A C E                             17320000
         SPACE 2                                                        17360000
         SPACE 1                                                        17400000
ERR1     LH    R0,ERROM        L OBJECT MODULE ERROR CODE               17440000
         TM    APT1,EX         CHK IF IS OBJECT MODULE                  17480000
         BC    8,ERROR         BC IF YES TO ERROR ROUTINE INTERFACE     17520000
ERR2     LA    R0,ERRLM        NO -- L ERROR CODE FOR LOAD MODULE       17560000
         SPACE 2                                                        17600000
*                   COMMON EXIT TO ERROR ROUTINE                        17640000
         SPACE 1                                                        17680000
ERROR    L     R15,ERDIG                                                17720000
         LA    R14,TXTRET                                               17760000
         BCR   15,R15                                                   17800000
         SPACE                                                          17804000
*     ERROR CAUSE BY INPUT EECORD LARGER THAN THAN THE TEXT BUFFER      17808000
*        REQUIRE ERROR MSG AND A DUMMY READ                             17812000
         SPACE                                                          17816000
ERR3     LA    R0,ERRLM           LOAD MODULE RRROR MSG                 17820000
ERR3A    L     R15,ERDIG      ESTABLISH ADDR OF ERROR RTN        A43127 17824021
         BALR  R14,R15    PRINT ERROR MSG AND RETURN TO                 17828000
         LA    GR9,1            ISSUE BUMMY READ OF 1 TO ADVANCE TO     17832000
         B     READ0        TO THE NEXT RECORD                          17836000
     TITLE 'IEWLMRAT   RLD/TXT PROCESSOR  --  MULTIPLICITY ROUTINE'     17840000
*                            C O M M O N                                17880000
*        M U L T I P L I C I T Y   D E T E R M I N A T O R              17920000
*                              ROUTINE                                  17960000
         SPACE 2                                                        18000000
*     THIS ROUTINE DETERMINES THE LOWEST MULTIPLICITY IDENTITY          18040000
*  AND RELOCAND OF TEXT ITEM                                            18080000
*     XS1 AND XS2 = CBRC                                                18120000
*     XAA = ASSEMBLED ADDRESS OF 1ST BYTE OF TEXT                       18160000
*     XAA = GR3, GR3 = ADDRESS FIELD FOR RLD ITEM                       18200000
         SPACE 2                                                        18240000
         SPACE 2                                                        18280000
MULTDET  SLL   XS1,4           MULTIPLY 'ID' BY 16 (CESD LENGTH)        18320000
         A     XS1,CHESD       ADD LOC OF START OF CESD                 18360000
         L     XS1,8(XS1)      L TYPE/ADDRESS FROM EXTRACTED ENTRY      18400000
         LA    XS1,0(XS1)      CLEAR TO ASSEMBLED ADDRESS               18440000
         LCR   XS1,XS1         FORM COMPLEMENTED ADDRESS                18480000
         A     XS1,TXTBFBEG    ADD LOC OF TEXT BUFFER TO FORM CURRENT   18520000
*                                   BUFFER RELOCATION CONSTANT  (CBRC)  18560000
         LR    XS2,XS1         L CBRC IN XS2                            18600000
         LR    R0,XS1          SAVE REGISTER  (CBRC)                    18640000
         AR    XS2,XAA         ADD ASSEMBLED ADDRESS OF TEXT TO CBRC    18680000
         S     XS2,TXTBFBEG    SUBTRACT LOC OF TEXT BUFFER              18720000
         SR    XS1,XS1         CLEAR REMAINDER REGISTER                 18760000
         D     XS1,MULTSIZE    DIVIDE BY BUFFER SIZE FOR MULTIPLICITY   18800000
         N     XS2,STRUNC      LIMIT MULTIPLICITY TO 10 BITS            18840000
         BCR   15,GR1          RETURN                                   18880000
         SPACE 2                                                        18920000
         TITLE 'IEWLMRAT   RLD/TXT PROCESSOR  --  RLD PROCESSING'       18960000
*                 R L D    P R O C E S S I N G                          19000000
*                            ROUTINE                                    19040000
         SPACE 2                                                        19080000
*     THIS ROUTINE IS ENTERED FOR EACH 'R' AND 'P' FIELD.  IT RENUMBERS 19120000
*  THE 'R' AND 'P' POINTERS VIA THE RENUMBERING TABLE AND DETERMINES    19160000
*  WHEN IT IS NECESSARY TO ENTER THE DELINK ROUTINE.  THE ACTUAL        19200000
*  SETTING OF THE DELINK ENTRY WAS DONE BY THE ESD PROCESSOR.           19240000
*     XBCNT = CUMULATIVE BYTE COUNT OF INPUT RLD ITEMS WHICH HAVE BEEN  19280000
*        PROCESSED.  WHEN XBCNT = TTR1, END OF INPUT HAS BEEN REACHED.  19320000
*     XIBCNT = STRING BYTE COUNT.   A STRING CONSISTS OF A GROUP OF     19360000
*        CONTIGUOUS RLD ITEMS, EACH WITH A 'P' ID FIELD OF THE SAME ID. 19400000
*        ONE ENTRY FOR EACH STRING IS MADE IN THE RLD NOTE LIST.        19440000
*     XSTR = POINTER TO START OF A STRING -- INITIAL 'R' ID.            19480000
*     XPRLD = POINTER TO CURRENT FLAG-ADDRESS ITEM.  AT ENTRY XPRLD     19520000
*        HOLDS THE LOCATION OF THE FIRST RLD ITEM IN AN INPUT RECORD.   19560000
*        SUBSEQUENTLY IT IS THE POINTER TO THE FA FIELD OF EACH CURRENT 19600000
*        ITEM.                                                          19640000
         SPACE 1                                                        19680000
RLD001   SR    XBCNT,XBCNT     INITIALIZE INPUT COUNT TO ZERO           19720000
         MVC   ENCT(2),ENR1C   SET CURRENT NOTE LIST ENTRY COUNT        19760000
RLD002   SR    XIBCNT,XIBCNT   INITIALIZE STRING COUNT TO ZERO          19800000
         SPACE 1                                                        19840000
RLD002A  LA    XBCNT,8(XBCNT)  STEP BY 8 NO OF BYTES PROCESSED          19880000
         LR    XSTR,XPRLD      L START OF CURRENT STRING                19920000
         L     R14,BUFSTLOC    L BUFFERED STRING LOCATION               19960000
         LTR   R14,R14         CHK IF LOCATION SET                      20000000
         BC    7,RLD002B       BC IF YES                                20040000
         ST    XSTR,BUFSTLOC   NO -- SET WITH CURRENT STRING LOC        20080000
RLD002B  MVC   SAVIDS(4),0(XSTR)   RESERVE 'R' AND 'P' ID'S             20120000
         MVC   SAVIDR(2),0(XSTR)   SAVE RLD ITEM 'R' ID                 20160000
         LA    XPRLD,4(XPRLD)  STEP TO LOC OF NEXT FA FIELD             20200000
         MVI   STM,STMULT      RESET STRING MULTIPLICITY                20240000
         LH    XPSAV,SAVIDS+2           L 'P' NUMBER AND                20280000
         SLL   XPSAV,2           QUADRUPLE  (ID FIELD LENGTH)           20320000
         A     XPSAV,RECNT     ADD LOC OF RNT-4 TO FORM CURRENT RNT LOC 20360000
         CLC   DID(2,XPSAV),CONZO  IS RENUMBERED ID ZERO                20400000
         BC    8,ERR1          BC IF ZERO -- ERROR                      20440000
         LH    GR3,ENCDX               MAX # CESD = MAX # RNT'S  A53300 20450000
         SLL   GR3,2                   MULTIPLY BY 4     A53300,SA53762 20460021
         A     GR3,RECNT               GET HIGHEST ADDR OF RNT-4 A53300 20470000
         A     GR3,FOUR                HIGHEST VALID ADDR OF RNT A53300 20472000
         CR    GR3,XPSAV               IS IT A VALID P PTR?      A53300 20474000
         BL    ERR1                    NO - IEW0222              A53300 20476000
         OI    APT1,DEL        SET DELETE FLAG                          20480000
         TM    DT(XPSAV),DEL   IS P A DELETE                            20520000
         BC    1,RLD012        BC IF YES TO SKIP PROCESSING             20560000
         NI    APT1,DELOFF     NO -- RESET DELETE FLAG OFF              20600000
RLD003   CLC   DID(2,XPSAV),PREP  IS CURRENT P SAME AS PREVIOUS P       20640000
         BC    8,RLD0042       BC IF YES TO CONTINUE STRING             20680000
         LR    XRET,XOBCNT     L BUFFERRED BYTE COUNT                   20720000
         AR    XRET,XIBCNT     ADD CURRENT STRING COUNT                 20760000
         LA    XRET,4(XRET)    STEP BY 4                                20800000
         C     XRET,RLDSIZE    CHK AGAINST MAXIMUM BUFFER SIZE          20840000
         BC    10,RLD0042      BC IF EQUAL OR GREATER                   20880000
RLD0031  BAL   XRET,RLDBUF     NO -- GO TO BUFFER PREVIOUS STRING       20920000
*                                NOTE -- BUFFERING WILL NOT OCCUR IF    20960000
*                                    PREVIOUS P WAS A DELETE OR IF THIS 21000000
*                                    IS THE FIRST P POINTER IN A MODULE 21040000
RLD004   SR    XIBCNT,XIBCNT   RESET STRING COUNT TO ZERO               21080000
         TM    RLDFLGS,CONTOV  CHK FOR CONTINUATION OVERFLOW FLAG       21120000
         BC    8,RLD0041       BC IF NO                                 21160000
         NI    RLDFLGS,CONTOVN   CLEAR CONTINUATION OVERFLOW FLAG       21200000
         CH    XBCNT,TTR1      CHK IF INPUT EXHAUSTED                   21240000
         BC    10,RLDRET       RETURN IF YES                            21280000
         L     XSTR,SBACKUP    SET NEW STRING ORIGIN                    21320000
         ST    XSTR,BUFSTLOC   SET NEW BUFFERRED STRING LOC             21360000
         LR    XPRLD,XSTR      L NEW STRING ORIGIN                      21400000
         LA    XPRLD,4(XPRLD)   SET TO LOC OF NEXT FA FIELD             21440000
         LA    XBCNT,4(XBCNT)  STEP BY 4 NO OF INPUT BYTES PROCESSED    21480000
         LA    XPSAV,SAVIDS+2  RESERVE 'P' ID                           21520000
         BC    15,RLD0041A                                              21560000
RLD0041  ST    XSTR,BUFSTLOC   SET NEW BUFFERRED STRING LOC             21600000
RLD0041A MVC   PREP(2),DID(XPSAV)   RESERVE CURRENT 'P' AS PREVIOUS 'P' 21640000
RLD0042  MVC   SAVIDS+2(2),0(XPSAV)   SAVE NEW 'P' ID FOR RLD ITEM      21680000
RLD0043  NI    PDSE8,ANY       SET RLD FLAG ON                          21720000
         LA    XIBCNT,8(XIBCNT)  STEP STRING COUNT BY 8                 21760000
         LH    GR4,SAVIDR      L 'R' ID OF CURRENT ITEM                 21800000
         N     GR4,RIDMSK      CLEAR TO 'R' ID                          21840000
         LA    R14,RLD010      L PROCEED ADDRESS FOR 'P' RENUMBERING    21880000
         SPACE 2                                                        21920000
*                  RENUMBER 'ID' POINTER ROUTINE                        21960000
*                     WITH DELINK IF REQUIRED                           22000000
         SPACE 1                                                        22040000
RLD004A  LR    R0,R14          SAVE REGISTER 14                         22080000
         L     GR3,CHESD       L START OF CESD                          22120000
         L     GR5,RECNT       L START OF RNT-4                         22160000
         LR    GR9,GR4         L RLD 'ID'                               22200000
         SLL   GR9,2           QUADRUPLE  (ENTRY LENGTH)                22240000
         AR    GR9,GR5         ADD RNT START TO FORM CURRENT ENTRY LOC  22280000
         TM    0(XPRLD),X'30'  IS RLD A PSEUDO-REGISTER                 22320000
         BC    1,RLD012        BC IF YES -- SKIP RENUMBERING            22360000
         CLC   DID(2,GR9),CONZO  IS RENUMBERED ID ZERO                  22400000
         BC    8,ERR1          BC IF YES -- ERROR                       22440000
         LH    GR3,ENCDX               MAX # CESD = MAX # RNT'S  A53300 22450000
         SLL   GR3,2                   MULTIPLY BY FOUR  A53300,SA53762 22460021
         A     GR3,RECNT               GET HIGHEST ADDR OF RNT-4 A53300 22470000
         A     GR3,FOUR                HIGHEST VALID RNT ADDR    A53300 22472000
         CR    GR3,GR9                 VALID R PTR?              A53300 22474000
         L     GR3,CHESD               RESTORE START OF CESD - DOES     22476000
*                                      NOT CHANGE COND CODE      A53300 22478000
         BL    ERR1                    NO - ERROR IEW0222        A53300 22478400
         MVC   TEMP(1),3(GR9)          GET RNT TYPE             SA69196 22478821
         NI    TEMP,X'0F'              GET RID OF FLAGS         SA69196 22479221
         CLI   TEMP,X'04'              TEST FOR PC              SA69196 22479621
         BNE   RLD004B                 BRANCH IF NOT PC         SA69196 22479721
         TM    3(GR9),X'10'            TEST FOR DELETE FLAG     SA69196 22479821
         BNO   RLD004B                 BRANCH IF NOT PC DELETE  SA69196 22479921
         LH    GR1,0(,GR9)             GET CESD ID              SA69196 22493221
         LR    GR13,GR1                SET UP WORK REG          SA69196 22503221
         SLL   GR13,4                  CALC CESD OFFSET         SA69196 22505221
         AR    GR13,GR3                GET CESD POINTER         SA69196 22505621
         NC    13(3,GR13),13(GR13)     TEST FOR 0-LENGTH PC     SA69196 22506021
         BNZ   RLD004B                 BRANCH IF NOT 0-LENGTH   SA69196 22506421
         LA    R0,X'023E'              SET UP MESSAGE 622       SA69196 22506521
         B     ERROR                   GO TO LOG ERROR          SA69196 22506621
RLD004B  EQU   *                                                SA69196 22511021
         LH    GR1,DID(GR9)    L UPDATED ID                             22515621
         LR    GR13,GR1        USE UPDATED ID                           22520000
         SLL   GR13,4          MULTIPLY BY 16  (ENTRY LENGTH)           22560000
         AR    GR13,GR3        ADD START OF CESD TO FORM CURRENT LOC    22600000
         TM    DT(GR9),DEL     IS TYPE IN RNT A DELETE                  22640000
         BC    8,RLD008        BC IF NO                                 22680000
         TM    DF(GR9),DSAV    YES, IS DELETE -- IS DELINK VALUE SAVED  22720000
         BC    1,RLD007        BC IF YES                                22760000
         TM    0(XPRLD),ANYR   DELINK NOT SAVED -- IS TYPE NON-BRANCH   22800000
         BC    5,RLD0061       BC IF NO TO SKIP DELINKING               22840000
         SPACE 1                                                        22880000
RLD005   L     R15,ADDEL       NON-BRANCH TYPE -- L LOC OF DELINK RTN   22920000
         BALR  R14,R15         GO TO PERFORM DELINK                     22960000
         LR    R14,R0          RESTORE REGISTER 14                      23000000
         SPACE 1                                                        23040000
RLD0061  NI    8(GR13),DSAVOF  SET DELETE FLAG OFF IN CESD              23080000
         TM    DF(GR9),DSAV    IS DELINK VALUE SAVED                    23120000
         BC    8,RLD008        BC IF NO                                 23160000
RLD007   TM    0(XPRLD),ANYR   IS RNT TYPE A NON-BRANCH                 23200000
         BC    5,RLD009        BC IF NO                                 23240000
MOVEJM2  MVC   DELR(2),DID(GR9)  SAVE RENUMBERED ID                     23280000
         OI    APTSWS,X'08'    SET DELINKED 'R' RECEIVED FLAG           23320000
         BCR   15,R14          RETURN TO DELINK CALLER                  23360000
         SPACE 1                                                        23400000
RLD008   TM    DT(GR9),CH      IS RNT TYPE FLAGGED AS CHAINED           23440000
         MVC   SAVIDS(2),DID(GR9)   SAVE RENUMBERED ID FOR OUTPUT       23480000
*                                NOTE -- THIS INSTRUCTION DOES NOT      23520000
*                                  CHANGE CONDITION CODE                23560000
         BCR   8,R14           NOT CHAINED -- MOVE INSTR OK -- RETURN   23600000
         MVC   SAVIDS(2),14(GR13)   CHAINED -- OVERWRITE FIRST MOVE     23640000
         BCR   15,R14          RETURN TO CALLER                         23680000
         SPACE 1                                                        23720000
RLD009   LA    XS1,5           L SIZE OF DELINK TABLE ENTRY             23760000
         MH    XS1,0(GR9)      MULTIPLY BY ENTRY NUMBER                 23800000
         A     XS1,DLKT        ADD START OF DELINK TABLE TO FORM DELINK 23840000
*                                ENTRY LOC                              23880000
         MVC   SAVIDS(2),0(XS1)   RENUMBER 'R' WITH DELINK TABLE ID     23920000
         LR    R14,R0          RESTORE REGISTER 14                      23960000
         BCR   15,R14          RETURN TO CALLER                         24000000
         SPACE 2                                                        24040000
         EJECT                                                          24080000
*                 OVERLAY CALLS LIST ENTRY ROUTINE                      24120000
         SPACE 1                                                        24160000
*         IF OVERLAY IS SPECIFIED,  AND IF THE REFERENCE IS TO A 4-BYTE 24200000
*  CONSTANT, THIS ROUTINE IS ENTERED.  IF THE REFERENCE AND THE POINTER 24240000
*  ARE IN THE SAME CSECT NO ACTION IS TAKEN.  IF THE 'P' ID IS DIFERENT 24280000
*  FROM THE PREVIOUS 'P' ENTERED, THE 2 BYTE CHAINING FIELD IS CLEARED, 24320000
*  THE NEW 'P' IS INSERTED IN THE NEXT 2 BYTE AREA, AND THE CURRENT 'R' 24360000
*  ID FOLLOWS IN THE NEXT 2 BYTE AREA.  IF THE NEW 'P' ID MATCHES THE   24400000
*  PREVIOUS 'P', THE CURRENT 'R' ID IS ENTERED DIRECTLY IN THE FIRST 2  24440000
*  BYTES.  THE UPDATED CUMULATIVE CALLS LIST BYTE COUNT IS SAVED IN APT 24480000
*  (ENCLC).  WHEN THIS CALLS LIST LENGTH EXCEEDS MAXIMUM (ENCLX),  AN   24520000
*  ERROR INDICATION IS GENERATED.                                       24560000
         SPACE 1                                                        24600000
RLDCALL  TM    PDSE7,OI        CHK FOR OVERLAY                          24640000
         BC    8,RLD012        BC IF NO -- SKIP CALLS LIST ENTRY        24680000
         TM    0(XPRLD),X'0C'  IS OVERLAY -- CHK IF 4 BYTE CONSTANT     24720000
         BC    12,RLD012       BC IF NO -- SKIP CALLS LIST ENTRY        24760000
         SPACE 1                                                        24800000
         LH    XS1,ENCLC       L CURRENT BYTE COUNT OF CALLS LIST       24840000
         A     XS1,CLLT        ADD START OF CALLS LIST TO FORM CURRENT  24880000
*                                  ENTRY LOCATION                       24920000
         LH    XS3,SAVIDS      L CURRENT 'R' ID                         24960000
         N     XS3,RIDMSK      CLEAR TO 'R' ID                          25000000
         TM    APTSWS,X'08'            IS DELINK VALUE SAVED?    A36529 25010021
         BZ    RLDCLA                  NO, BRANCH OUT            A36529 25020021
         MH    XS3,FIVEFIVE            YES, MULT DELINK ID BY 5  A36529 25030021
         A     XS3,DLKT                ADD TO DELINK TABLE ADDR  A36529 25040021
         MVC   DLKTSAVE(2),0(XS3)      SAVE TRUE R ID            A36529 25050021
         LH    XS3,DLKTSAVE            PICK UP TRUE R ID         A36529 25060021
RLDCLA   LH    XS2,SAVIDS+2            PICK UP CURRENT P ID      A36529 25070021
         CR    XS2,XS3         CHK IF 'R' EQUALS 'P'  (IN SAME CSECT)   25080000
         BC    8,RLD012        RETURN IF YES -- NO ENTRY REQUIRED       25120000
         CH    XS2,CALLCURP    DOES 'P' EQUAL PREVIOUS 'P'              25160000
         BC    8,CALLR         BC IF YES                                25200000
CALLPANR MVI   0(XS1),0        NO --    CLEAR                           25240000
         MVI   1(XS1),0             CHAINING FIELD                      25280000
         STH   XS2,2(XS1)      SET CURRENT 'P' IN CALLS LIST            25320000
         STH   XS2,CALLCURP    SAVE NEW 'P' FOR FUTURE CHECK            25360000
         LA    XS1,4(XS1)      STEP ENTRY POINTER BY 4 TO 'R' AREA      25400000
CALLR    STH   XS3,0(XS1)      SET CURRENT 'R' IN CALLS LIST            25440000
         LA    XS1,2(XS1)      STEP ENTRY POINTER TO NEXT 'R' FIELD     25480000
*                                   (OR NEXT ENTRY)                     25520000
         S     XS1,CLLT        SUBTRACT CALLS LIST START TO GET BYTE CT 25560000
         STH   XS1,ENCLC       SAVE UPDATED CALLS LIST BYTE COUNT       25600000
         AH    XS1,SIX                 ADD SIX BYTES TO COUNT    A52402 25610000
         CH    XS1,ENCLX       CHK IF BYTE COUNT IS AT OVERFLOW SIZE    25640000
         BNH   CALLR01         NO -- CONTINUE                    A52402 25680000
         LA    R0,ERRC         YES -- L CALLS LIST OVERFLOW ERROR CODE  25720000
         BC    15,ERROR        GO TO ERROR ROUTINE INTERFACE            25760000
CALLR01  SH    XS1,SIX                 SET BACK TO TRUE COUNT    A52402 25770000
         B     RLD012                  CONTINUE PROCESSING       A52402 25780000
SIX      DC    H'6'                    SIX BYTES                 A52402 25790000
         SPACE 2                                                        25800000
         EJECT                                                          25840000
*     THIS SEQUENCE IS ENTERED FOR EACH FLAG-ADDRESS FIELD (FA).  IT    25880000
*  POSTS THE FLAG FIELD WITH THE PROPER INDICATION FOR AN ABSOLUTE OR   25920000
*  A RELATIVE RELOCATION CONSTANT OR FOR A PSEUDO-REGISTER.  IT FINDS   25960000
*  THE LOWEST MULTIPLICITY IN A STRING OF RLD ITEMS OF THE SAME 'P'     26000000
*  POINTER AND ENTERS THAT MULTIPLICITY IN THE RLD NOTE LIST ENTRY FOR  26040000
*  THAT 'P' POINTER.                                                    26080000
         SPACE 2                                                        26120000
RLD010   EQU   *               DEFINE SYMBOL                            26160000
         NI    0(XPRLD),X'7F'          CLEAR POSSIBLE FLAGS FROM        26200000
*                                   PREVIOUS SECOND PASS PROCESSING     26240000
*                                        (IF EXECUTABLE MODULE)         26280000
         TM    0(XPRLD),X'30'  IS THIS A PSEUDO-REGISTER                26320000
         BC    1,RLD012        YES -- SKIP PROCESSING                   26360000
         TM    0(XPRLD),X'10'  IS FLAG A BRANCH TYPE                    26400000
         BC    1,RLDCALL       YES -- GO TO CHK FOR OVERLAY             26440000
         TM    DT(GR9),DEL     CHK IF DELETE FLAG IN RNT                26480000
         BC    8,RLD010A       BC IF NOT DELETE                         26520000
         SPACE 1                                                        26560000
         BAL   R14,RLD004A     DELETE -- DELINK IF REQUIRED             26600000
         SPACE 1                                                        26640000
RLD010A  MVC   FLAG(1),DT(GR9) GET TYPE BYTE FROM RNT                   26680000
         NI    FLAG,X'07'      ISOLATE TYPE FLAGS                       26720000
         CLI   FLAG,X'06'      IS PSEUDO-REGISTER                       26760000
         BC    7,RLD011        BC IF NO                                 26800000
         OI    0(XPRLD),X'20'  YES -- FLAG RLD ITEM AS PR               26840000
         BC    15,RLD012                                                26880000
         SPACE 1                                                        26920000
RLD011   CLI   FLAG,X'02'      IS EXTERNAL REFERENCE                    26960000
         BC    8,RLD012        BC IF YES                                27000000
         TM    DT(GR9),DEL     NO -- CHK FOR DELETE IN RNT              27040000
         BC    1,RLD012        YES -- FLAG REMAINS ABSOLUTE             27080000
         OI    0(XPRLD),REL    NOT DELETE -- FLAG AS RELATIVE           27120000
RLD012   LH    XS1,SAVIDS+2    L CURRENT 'P' ID                         27160000
         L     GR3,0(XPRLD)         EXTRACT ASSEMBLED ADDRESS           27200000
         LA    GR3,0(GR3)               FROM RLD FA FIELD               27240000
         TM    APT1,DEL        IS 'P' A DELETE                          27280000
         BC    1,RLD0122       YES -- GO TO CHK FOR CONTINUED STRING    27320000
         SPACE 2                                                        27360000
*                ESTABLISH MULTIPLICITY OF CURRENT ITEM                 27400000
         SPACE 1                                                        27440000
         BAL   GR1,MULTDET     NOT DELETE -- GO TO OBTAIN MULTIPLICITY  27480000
         SPACE 1                                                        27520000
         STH   XS2,POSMULT     RESERVE POSSIBLE NEW LOWEST MULTIPLICITY 27560000
         MVC   NFLG(1),RLDMULT      EXTRACT FLAGS FROM                  27600000
         NI    NFLG,FLGS              NOTE LIST MODEL                   27640000
         NI    RLDMULT,NFLGS   CLEAR FLAGS IN MODEL (ID MULTIPLICITY)   27680000
         NI    STM,NFLGS       CLEAR FLAGS IN STRING MULTIPLICITY       27720000
         LR    R0,XIBCNT               CURRENT STRING LENGTH     A38313 27728021
         AR    R0,XOBCNT               ADD BUFFER BYTE COUNT     A38313 27736021
         CLC   SAVIDS+2(2),PREP         LOOK FOR SAME P PTR     SA57133 27738021
         BNE   RLD01202                 BRANCH NOT THE SAME     SA57133 27740021
         TM    APTSWS,X'08'             WAS DELINK R PTR SAVED  SA57133 27742021
         BNO   RLD01200                 BRANCH IF NOT           SA57133 27742421
         CLC   DELR(2),PRER             LOOK FOR SAME R PTR     SA57133 27742821
         BNE   RLD01202                 BRANCH IF NOT           SA57133 27743221
         B     RLD01201                 GO HANDLE CHAINED ITEM  SA57133 27743321
RLD01200 CLC   SAVIDS(2),PRER           LOOK FOR SAME R PTR     SA57133 27743421
         BNE   RLD01202                 BRANCH IF NOT           SA57133 27743521
RLD01201 SH    R0,SFOUR                 ALLOW FOR CHAINED ITEM  SA57133 27743621
RLD01202 EQU   *                                                SA57133 27743721
         C     R0,RLDSIZE              COMPARE TO MAX BUFF COUNT A38313 27744021
         BH    RLD0120                 IF >, SKIP   M0513,A49482,A38313 27752021
*                                      MULT DETER   M0513,A49482,A38313 27754021
         CLC   POSMULT(2),RLDMULT  IS THIS LOWEST MULTIPLICITY OF ID    27760000
         BC    10,RLD0120      BC IF NO TO CHK STRING MULTIPLICITY      27800000
         STH   XS2,RLDMULT     YES -- SET NEW LOWEST MULT IN MODEL      27840000
RLD0120  CLC   POSMULT(2),STM  IS THIS LOWEST MULTIPLICITY OF STRING    27880000
         BC    10,RLD0121      NO -- GO TO CHK FOR CONTINUATION         27920000
         STH   XS2,STM         YES -- SAVE NEW LOWEST STRING MULT       27960000
RLD0121  OC    RLDMULT(1),NFLG SET FLAGS IN RLD MODEL                   28000000
         OC    STM(1),NFLG     SET FLAGS IN STRING COMPARATOR           28040000
RLD0122  TM    APTSWS,X'08'                                             28045000
         BC    8,RLD0122X         BRANCH IF NOT                  A20457 28050000
         MVC   SAVIDS(2),DELR     MOVE DELINK 'R' POINTER        A20457 28060000
         OI    SAVIDS,NREL        SET NON-RELATIVE FLAG          A20457 28070000
RLD0122X TM    0(XPRLD),CONT      CHK FOR CONTINUATION FLAG      A20457 28080000
         LA    XPRLD,4(XPRLD)  STEP TO NEXT FA FIELD (OR END OF STRING) 28120000
*                              NOTE -- THIS INSTRUCTION WILL NOT CHANGE 28160000
*                                CONDITION CODE                         28200000
         BC    8,RLD013A       BC IF NO                                 28240000
         TM    APT1,DEL        IS 'P' A DELETE                          28280000
         BC    1,RLD0124       BC IF YES                                28320000
         LR    R0,XIBCNT       CONTINUE STRING -- L CURRENT STRING CT   28360000
         AR    R0,XOBCNT       ADD BUFFERRED BYTE COUNT                 28400000
         LR    XS1,XPRLD       L CURRENT STRING ITEM POINTER            28440000
         SH    XS1,SFOUR       SUBTRACT 4                               28480000
         C     XIBCNT,RLDSIZE  CHK IF STRING EQUALS BUFFER              28520000
         BC    8,RLD0125       BC IF YES                                28560000
         C     R0,RLDSIZE      STRING IS LESS, CHK TOTAL COUNT          28600000
         BC    4,RLD0124       BC IF TOTAL LESS THAN BUFFER             28640000
         CLC   SAVIDS(2),PRER  CHK IF CURRENT 'R' SAME AS PREVIOUS 'R'  28680000
         BC    7,RLD0122A      BC IF NOT SAME                           28720000
         CLC   SAVIDS+2(2),PREP  SAME -- CHK 'P' SAME AS PREVIOUS 'P'   28760000
         BC    8,RLD0123       BC IF SAME                               28800000
RLD0122A C     R0,RLDSIZE      NOT SAME -- CHK TOTAL WITH BUFFER SIZE   28840000
         BC    8,RLD0125       BC IF EQUAL                              28880000
         SH    XS1,SFOUR       SUBTRACT 4 FROM STRING POINTER           28920000
         BC    15,RLD0125                                               28960000
RLD0123  C     R0,RLDSIZE      CHK TOTAL WITH BUFFER SIZE               29000000
         BC    2,RLD0125       BC IF GREATER                            29040000
RLD0124  LA    XBCNT,4(XBCNT)  SAME -- STEP BY 4 INPUT BYTE COUNT       29080000
         LA    XIBCNT,4(XIBCNT)  STEP BY 4 CURRENT STRING COUNT         29120000
         TM    APT1,DEL        IS 'P' A DELETE                          29160000
         BC    1,RLD0122X         YES - GO TO END OF STRING      A20457 29200000
         BC    15,RLD010       NO -- GO TO CHECK NEXT FA ITEM           29240000
         SPACE 1                                                        29280000
RLD0125  OI    RLDFLGS,CONTOV  SET CONTINUATION-OVERFLOW FLAG           29320000
         ST    XS1,SBACKUP     SAVE FOR REPLACEMENT STRING POINTER      29360000
*                                                                       29400000
*      IF DELINKING HAS TAKEN PLACE, THIS ROUTINE MOVES THE DELINKED    29440000
*  'R' POINTER INTO THE STRING ID, CLEARS THE DELINK FLAG IN APT, SETS  29480000
*  THE NON-RELATIVE FLAG IN THE 'R' ID AND CLEARS THE RELATIVE FLAG     29520000
*  IN EACH FA FIELD IN THE STRING.                                      29560000
*                                                                       29600000
RLD013A  TM    APTSWS,X'08'    CHK IF ANY DELINK 'R' RECEIVED           29640000
         BC    8,RLD013        BC IF NO -- CONTINUE RLD PROCESSING      29680000
         NI    APTSWS,X'F7'    CLEAR DELINK FLAG IN APT                 29720000
         LR    R0,XSTR         SAVE START OF STRING                     29760000
         LA    XSTR,4(0,XSTR)  INCREMENT TO FA FIELD                    29880000
RLD013B  NI    0(XSTR),RELOFF  CLEAR RELATIVE FLAG IN FA                29920000
         LA    XSTR,4(0,XSTR)  INCREMENT TO NEXT FLAG FIELD             29960000
         CR    XSTR,XPRLD      CHK IF AT END OF STRING                  30000000
         BC    5,RLD013B       BC IF NO TO CONTINUE STRING PROCESSING   30040000
         LR    XSTR,R0         YES -- RESTORE STRING POINTER            30080000
         SPACE  2                                                       30120000
*IF CONTINUATION BIT NOT SET, NEXT ITEM IS A NEW R+P OR WE ARE AT       30160000
*THE END OF OUR INPUT RECORD                                            30200000
         SPACE 1                                                        30240000
RLD013   TM    APT1,DEL        IS 'P' A DELETE                          30280000
         BC    1,RLD0156       IF YES, GO TO CHK END-OF-INPUT           30320000
         SPACE 1                                                        30360000
*        WE HAVE COME TO THE END OF A STRING OF                         30400000
*RLD ITEMS. WHAT FOLLOWS THIS STRING MAY BE ANOTHER RLD ITEM WITH A NEW 30440000
*R AND P OR WE MAY BE AT THE END OF THE RLD INPUT. BEFORE WE FIND       30480000
*OUT WHICH IS TRUE, THE OLD STRING MUST BE MOVED INTO THE RLD BUFFER.   30520000
*IF THE RLD STRING WILL NOT FIT INTO THE BUFFER, THE BUFFER IS FIRST    30560000
*PURGED. THE OLD STRING WILL THEN BE MOVED IN.                          30600000
         SPACE 1                                                        30640000
RLD014   L     XS2,RLDOUT1     L START OF RLD BUFFER 1 -- DATA LOC      30680000
         TM    BUFFS,BUFFRN2   CHK IF BUFFER 2 IS CURRENT               30720000
         BC    8,*+8           BC IF NO                                 30760000
         L     XS2,RLDOUT2     L START OF RLD BUFFER 2 -- DATA LOC      30800000
         AR    XS2,XOBCNT      ADD BUFFERRED COUNT TO BUFFER LOC        30840000
         LR    XS1,XIBCNT             L CURRENT STRING BYTE COUNT       30880000
         AR    XS1,XOBCNT          AND FORM CURRENT BUFFER BYTE COUNT   30920000
RLD0151  BCTR  XIBCNT,0        REDUCE FOR EXACT MOVE COUNT              30960000
         CLC   SAVIDS(4),PRER  CHK IF CURRRNT 'ID'S' SAME AS PREVIOUS   31060000
         BC    7,RLD0152       BC IF NOT BOTH SAME                      31160000
RLD015   SH    XS2,SFOUR       GET ADDRESS OF PREVIOUS FA FIELD         31400000
         OI    0(XS2),CONT     SET CONTINUATION FLAG IN PREVIOUS FA     31440000
         LA    XS2,4(XS2)      RESTORE BUFFER LOC                       31480000
         LA    XSTR,4(XSTR)    STEP INPUT POINTER TO SKIP 'R' AND 'P'   31520000
         SH    XIBCNT,SFOUR    REDUCE STRING COUNT  (LESS 'R' AND 'P')  31560000
         EX    XIBCNT,MOVEJM1   MOVE CURRENT STRING INTO OUTPUT BUFFER  31600000
         BC    15,RLD015X      SKIP INSERT OF ID'S                      31640000
         SPACE 1                                                        31680000
RLD0152  C     XS1,RLDSIZE     CHK AGAINST MAXIMUM BUFFER SIZE          31720000
         BC    12,RLD0153      BC IF EQUAL OR LESS                      31760000
         TM    RLDFLGS,CONTOV  MORE -- CHK FOR CONTINUATION-OVERFLOW    31800000
         BC    8,RLD016        BC IF NO TO PURGE BUFFER                 31840000
         LA    XIBCNT,1(XIBCNT)   YES -- RECOMPENSATE STRING COUNT      31880000
         BC    15,RLD0031      BC TO CONTINUATION PURGE                 31920000
RLD0153  EX    XIBCNT,MOVEJM1  MOVE CURRENT STRING INTO OUTPUT BUFFER   31960000
RLD0154  EX    0,MOVEJM1A      MOVE CURRENT STRING ID'S INTO BUFFER     32000000
RLD015X  L     R14,BUFSTCT     L BUFFERRED STRING COUNT                 32040000
         LA    XIBCNT,1(XIBCNT)  RECOMPENSATE STRING COUNT              32080000
         AR    R14,XIBCNT      ADD CURRENT STRING COUNT                 32120000
         ST    R14,BUFSTCT     SAVE UPDATED BUFFERED STRING COUNT       32160000
         LR    R14,XS2         L LOC OF CURRENT OUT BUFFER STRING       32200000
         AR    R14,XIBCNT      ADD CURRENT STRING COUNT                 32240000
         SH    R14,SFOUR       GET LOC OF TERMINAL F/A FIELD            32280000
         NI    0(R14),CONTN    CLEAR TERMINAL ITEM CONTINUATION FLAG    32320000
         AR    XOBCNT,XIBCNT   UPDATE BUFFER BYTE COUNT                 32360000
         STH   XOBCNT,OBCNT    SAVE UPDATED COUNT IN MODEL              32400000
         TM    RLDFLGS,CONTOV  CHK FOR CONTINUATION OVERFLOW FLAG       32440000
         BC    1,RLD0031       BC IF YES TO PURGE BUFFER                32480000
         C     XOBCNT,RLDSIZE  CHK BUFFERRED CT WITH MAXIMUM BUFFER     32520000
         LA    XRET,RLD0156    L RETURN ADDRESS                         32540000
*                                   NOTE -- THIS INSTRUCTION DOES NOT   32560000
*                                      CHANGE CONDITION CODE            32580000
         BC    11,RLDBUF       BC IF NOT LESS TO PURGE BUFFER           32600000
RLD0155  MVC   PRER(4),SAVIDS  SAVE CURRENT 'ID'S' AS PREVIOUS 'ID'S'   32620000
RLD0156  CH    XBCNT,TTR1      CHK IF END-OF-INPUT                      32640000
         BC    4,RLD002        NO -- CONTINUE PROCESSING RLD ITEMS      32660000
RLDRETX  BC    15,RLDRET       YES -- RETURN TO CALLER                  32680000
***                                 CLOSE TIMER HOOK                    32700000
         SPACE 2                                                        32760000
RLD016   LA    XIBCNT,1(XIBCNT)   RECOMPENSATE STRING COUNT             32800000
RLD0161  BAL   XRET,RLDBUF     PURGE RLD BUFFER                         32840000
         MVC   PREP(2),SAVIDS+2  INITIALIZE 'P' ID FOR NEW BUFFER       32880000
         MVC   RLDMULT(2),STM  SET STRING MULTIPLICITY IN ID MULTIPCTY  32920000
         B     RLD014               THEN INSERT STRING                  32960000
         EJECT                                                          33000000
*             FORM RLD NOTE LIST AND INITIATE WRITE OUT                 33040000
*                  RLD BUFFER/RLD NOTE LIST ROUTINE                     33080000
         SPACE 1                                                        33120000
RLDBUF   L     R14,BUFSTCT     L BUFFERED STRING COUNT                  33160000
         LTR   R14,R14         CHK IF ANY BYTE COUNT                    33200000
         BC    7,RLDBUF1       BC IF SOME                               33240000
         LR    R14,XIBCNT      L CURRENT STRING BYTE COUNT              33280000
         LTR   XIBCNT,XIBCNT   CHK IF ANY                               33320000
         BC    7,RLDBUF1       BC IF SOME                               33360000
RLDBUFA  TM    NEWSW,EOD       NONE -- CHK FOR END-OF-DATA              33400000
         BCR   8,XRET          RETURN IF NOT                            33440000
         LTR   XOBCNT,XOBCNT   EOD -- CHK FOR ANY BUFFERED CT REMAINING 33480000
         BC    7,RLDBUF1A      CONTINUE IF ANY                          33520000
         TM    NEWSW,TUPAS     NONE -- CHK FOR 2 PASS NOW               33560000
         BC    8,RLDBFRTN      RETURN IF NO                             33600000
         OI    RLDFLGS,FNLCHK          INDICATE PURGE, NO DATA  SA59588 33610021
         BC    15,RLDBUF3B     YES, 2 PASS -- CONTINUE PURGE CHECK      33640000
         SPACE 1                                                        33680000
RLDBUF1  TM    APT1,EX         CHK IF EXECUTABLE (LOAD) MODULE          33720000
         BC    8,RLDBUF1A      BC IF NO                                 33760000
         CLC   TTR1(2),ENRLD2X   LD MODULE -- CHK IF INPUT OVER MAXIMUM 33800000
         BC    2,ERR2          BC IF OVER MAXIMUM -- ERROR              33840000
         SPACE 1                                                        33880000
RLDBUF1A SRL   R14,2           DIVIDE BUFFERRED STRING COUNT BY 4       33920000
         STH   R14,WDCNT       SAVE WORD COUNT IN MODEL                 33960000
         TM    NEWSW,TUPAS     CHK FOR 2 PASS NOW                       34000000
         BC    1,RLDBUF1C      BC IF YES                                34040000
         NI    RLDMULT,RNBUF1  SET RLD'S-IN-BUFFER-1 FLAG               34080000
         L     R14,RLDOUT1     L LOC OF OUT-BUFFER 1                    34120000
         TM    BUFFS,BUFFRN2   CHK IF BUFFER 2 IS CURRENT               34160000
         BC    8,RLDBUF1B      BC IF NO                                 34200000
         OI    RLDMULT,RNBUF2  YES -- SET RLD'S-IN-BUFFER-2 FLAG        34240000
         L     R14,RLDOUT2     L LOC OF OUT-BUFFER 2                    34280000
RLDBUF1B NI    RLDMULT,GPF     SET GROUP FLAG IN MODEL                  34320000
         OI    RLDMULT,INCF    SET RLD-IN-CORE FLAG IN MODEL            34360000
RLDBUF1C LR    R15,XOBCNT      L CURRENT BUFFERRED BYTE COUNT           34400000
         SLL   R15,6           REDUCE TO WORD COUNT IN MODEL POSITION   34480000
         ST    R15,RTTR1       SAVE ACCUMULATED WORD COUNT IN MODEL     34520000
         SPACE 1                                                        34560000
         MVC   SFLIP(1),BUFFS  HOLD CURRENT BUFFER FLAG                 34600000
         NI    SFLIP,BUFFRN2   EXTRACT CURRENT BUFFER FLAG              34640000
         XI    SFLIP,BUFFRN2   FLIP NEXT BUFFER FLAG                    34680000
         LR    XS1,XIBCNT      L STRING COUNT                           34720000
         AR    XS1,XOBCNT      ADD BUFFERED BYTE COUNT                  34760000
         C     XS1,RLDSIZE     CHK AGAINST MAXIMUM BUFFER COUNT         34800000
         BC    13,RLDBUF3      BC IF NOT GREATER                        34840000
RLDBUF2  OI    RLDMULT,TTRF    SET END-OF-BUFFER FLAG IN MODEL          34880000
         TM    BUFFS,BUFFRN2   CHK IF BUFFER 2 IS CURRENT               34920000
         BC    8,RLDBUF2A      BC IF NO                                 34960000
         OI    BUFFS,BUFF2     YES -- SET BUFFER 2 FULL FLAG            35000000
         BC    15,RLDBUF2B                                              35040000
RLDBUF2A OI    BUFFS,BUFF1     SET BUFFER 1 FULL FLAG                   35080000
RLDBUF2B TM    NEWSW,TUPAS     CHK FOR 2 PASS NOW                       35120000
         BC    1,RLDBUF4A      BC IF YES                                35160000
         TM    BUFFS,BUFFRN2   NO -- CHK IF BUFFER 2 IS CURRENT         35200000
         BC    1,RLDBUF4       BC IF YES                                35240000
         STH   XOBCNT,OBCNT    SAVE CURRENT BUFFERRED BYTE COUNT        35280000
         MVC   OPREP(14),PREP  SAVE CURRENT MODEL FOR OPENER 1          35320000
         OI    BUFFS,OP1BF2    SET OPENER AND BUFFER 2 NOW FLAGS        35360000
         SR    XOBCNT,XOBCNT   CLEAR BUFFER 1 COUNT                     35400000
         SPACE 1                                                        35440000
         SPACE 1                                                        35480000
RLDBUF3  LH    XRIO,ENR1C      L CURRENT NOTE LIST ENTRY COUNT          35520000
         LA    XRIO,1(XRIO)    STEP FOR CHECK                           35560000
         CH    XRIO,ENR1X      CHK IF NOTE LIST WILL BE FULL            35600000
         BC    4,RLDBUF3A      BC IF NO                                 35640000
         TM    NEWSW,TUPAS     CHK FOR TWO PASS MODE                    35660000
         BC    1,RLDBUF32      BC IF YES                                35680000
         TM    BUFFS,BUFFRN2   ONE PASS MODE -- CHK FOR BUFFER 2 NOW    35700000
         BC    1,RLDBUF32      BC IF YES                                35720000
RLDBUF31 OI    RLDFLGS,NLFULL  SET NOTE LIST FULL FLAG                  35740000
RLDBUF32 OI    RLDFLGS,CHKNOW  SET CHECK NOW FLAG                       35760000
         OI    NEWSW,TUPAS     SET 2 PASS NOW FLAG                      35840000
         BC    15,RLDBUF2                                               35880000
RLDBUF3A TM    NEWSW,EOD       CHK FOR END-OF-DATA NOW                  35920000
         BC    8,RLDBUF6C      BC IF NO                                 35960000
RLDBUF3B OI    RLDMULT,TTRF    SET END-OF-BUFFER FLAG IN MODEL          36000000
         TM    NEWSW,TUPAS     CHK FOR TWO PASS FLAG                    36040000
         BC    8,RLDBUF6C      BC IF NO                                 36080000
         SPACE 1                                                        36120000
RLDBUF4  OI    NEWSW,TUPAS     SET 2 PASS FLAG                          36160000
RLDBUF4A TM    BUFFS,OPNR1     CHK FOR BUFFER 1 OPENER FLAG             36200000
         BC    8,RLDBUF5       BC IF NO                                 36240000
         STH   XOBCNT,OBCNT    SAVE CURRENT BUFFERRED BYTE COUNT        36280000
         MVC   CPREP(14),PREP  SAVE CURRENT MODEL FOR RESUME            36320000
         MVC   PREP(14),OPREP  RESTORE OPENER 1 MODEL TO CURRENT MODEL  36360000
         LH    XOBCNT,OBCNT    RESTORE OPENER 1 BUFFERRED BYTE COUNT    36400000
         NI    BUFFS,BUFFRN1   SET BUFFER 1 CURRENT FLAG                36440000
         SPACE 1                                                        36480000
RLDBUF5  L     XRIO,RNT1       L NOTE LIST STARTING LOC                 36520000
         SH    XRIO,SNINE      LESS 9 -- 1 ENTRY LENGTH                 36560000
         LH    XS1,ENR1C       L NOTE LIST ENTRY COUNT                  36600000
         LTR   XS1,XS1         CHK IF ANY COUNT                         36640000
         BC    7,*+8           BC IF SOME                               36680000
         LA    XS1,1(XS1)      NONE -- SET TO ONE                       36720000
RLDBUF5A LA    XRIO,9(XRIO)    STEP NOTE LIST ENTRY LOC ONE ENTRY       36760000
         NI    2(XRIO),NICF    CLEAR IN-CORE AND BUFFER 2 FLAGS         36800000
         BCT   XS1,RLDBUF5A    LOOP TO NEXT ENTRY                       36840000
         SPACE 1                                                        36880000
RLDBUF6  TM    BUFFS,WRIT2     CHK IF ANY BUFFER WRITTEN YET            36920000
         BC    8,RLDBUF7C      BC IF NONE                               36960000
         OI    RLDFLGS,CHKNOW  SET CHECK NOW FLAG                       37000000
RLDBUF6A STH   XOBCNT,OBCNT    SAVE CURRENT BUFFERRED BYTE COUNT        37040000
         MVC   CPREP(14),PREP  SAVE CURRENT MODEL FOR CHECK             37080000
         MVC   PREP(14),LPREP  RESTORE RESERVE MODEL TO CHECK           37120000
         LH    XOBCNT,OBCNT    RESTORE RESERVED BUFFERRED BYTE COUNT    37160000
         SPACE  1                                                       37200000
RLDWCHK  L     GR1,SAVETTR     L RESERVED TTR                           37240000
****             REMOVE ABOVE INSTRUCTION IF OVERLAP IS ADDED           37280000
****                           AND REPLACE WITH                         37320000
****     BAL   XRET2,COMCHK    CHECK AND NOTE                           37360000
         SPACE  1                                                       37400000
         SPACE 1                                                        37440000
         NI    RLDMULT,NICF    SET NOT-IN-CORE FLAG IN MODEL            37480000
         OI    RLDMULT,TTRF    SET TTR FLAG IN MODEL                    37520000
         ST    GR1,RTTR1       SET TTR IN MODEL                         37560000
         SPACE 1                                                        37600000
         TM    BUFFS,BUFFRN2   CHK IF BUFFER 2 IS CURRENT               37640000
         BC    1,RLDBUF6B      BC IF YES                                37680000
         OI    BUFFS,BUF2CHK   NO -- SET BUFFER 2 CHECKED FLAG          37720000
         NI    BUFFS,NBUF2WF   CLEAR BUFFER 2 FULL AND WRITTEN FLAGS    37760000
         BC    15,RLDBUF6C                                              37800000
RLDBUF6B OI    BUFFS,BUF1CHK   SET BUFFER 1 CHECKED FLAG                37840000
         NI    BUFFS,NBUF1WF   CLEAR BUFFER 1 FULL-WRITTEN FLAGS        37880000
RLDBUF6C LA    XRIO,9          L RLD NOTE LIST ENTRY LENGTH             37920000
         MH    XRIO,ENCT       MULTIPLY BY ENTRY COUNT                  37960000
         A     XRIO,RNT1       ADD NOTE LIST STARTING LOC TO FORM       38000000
*                                   CURRENT ENTRY LOC                   38040000
         MVC   0(9,XRIO),PREP  MOVE MODEL INTO RLD NOTE LIST ENTRY      38080000
RLDBUF6D SR    R14,R14         CLEAR REGISTER                           38120000
RLDBUF6X ST    R14,BUFSTCT     CLEAR BUFFERRED STRING COUNT             38160000
         ST    R14,BUFSTLOC    CLEAR BUFFERED STRING LOCATION           38200000
         TM    RLDFLGS,CHKNOW  CHK FOR CHECK NOW                        38240000
         BC    8,RLDBUF7       BC IF NO                                 38280000
         MVC   PREP(14),CPREP  YES -- RESTORE CURRENT MODEL             38320000
         LH    XOBCNT,OBCNT    RESTORE CURRENT BUFFERRED BYTE COUNT     38360000
         TM    RLDFLGS,FNLCHK          CHECK FOR NO DATA        SA59588 38370021
         BO    RLDBUF71                BRANCH IF NO DATA        SA59588 38380021
RLDBUF7  LH    XRIO,ENCT       L RLD NOTE LIST ENTRY COUNT              38400000
         LA    XRIO,1(XRIO)    UPDATE BY 1                              38440000
         STH   XRIO,ENR1C      SAVE NEW COUNT IN APT                    38480000
         CH    XRIO,ENR1X      CHK IF NOTE LIST IS FULL                 38520000
         BC    10,RLDBUF7A     BC IF NOT LESS                           38560000
RLDBUF71 NI    RLDFLGS,NCHKNOW   LESS -- CLEAR CHECK NOW FLAGS  SA59588 38600021
         BC    15,RLDBUF7C     GO TO WRITE                              38640000
RLDBUF7A TM    RLDFLGS,NLFULL  NOT LESS -- CHK FOR NOTE LIST FULL FLAG  38680000
         BC    1,RLDBUF7B      BC IF YES                                38720000
         OI    RLDFLGS,NLFULL  NO -- SET NOTE LIST FULL FLAG NOW        38760000
         BC    15,RLDBUF7C     GO TO WRITE                              38800000
RLDBUF7B NI    RLDFLGS,NLFLCHKN  CLEAR NOTE LIST FULL + CHK NOW FLAGS   38840000
         SPACE 1                                                        38880000
*THE RLD NOTE LIST IS FULL. AN ENTRY IS NOW MADE IN THE RLD I/O CONTROL 38920000
*TABE.IT CONTAINS A MAXIMUM OF 3 TTR'S OF THE RLD NOTE LIST. AN OVER-   38960000
*FLOW CONDITION WILL OCCUR IF THE NOTE LIST MUST BE PURGED AND THE RLD  39000000
*I/O CONTROL TABLE IS FULL.THE WORDS 'NOTE' AND 'MARK' ARE INTER-       39040000
*CHANGEABLE. HISTORICALLY BOTH TERMS HAVE BEEN USED.                    39080000
         SPACE 1                                                        39120000
BUFRMK2  TM    RLDFLGS,FULLR   CHK IF I/O CONTROL TABLE FULL            39160000
         BC    8,BUFROK        BC IF NOT FULL -- CONTINUE               39200000
         LA    R0,ERRRM        L ERROR CODE FOR I/O CTL TABLE OVERFLOW  39240000
         BC    15,ERROR        GO TO ERROR ROUTINE INTERFACE            39280000
         SPACE 1                                                        39320000
BUFROK   LA    R14,9           L LENGTH OF NOTE LIST ENTRY              39360000
         MH    R14,ENR1C       MULTIPLY BY ENTRY CT TO FORM DATA CT     39400000
         L     R15,RNT1        L DATA LOC                               39440000
         SPACE 1                                                        39480000
         BAL   XRET2,RLDBUFR   GO TO WRITE OUT NOTE LIST                39520000
         SPACE 1                                                        39560000
         BAL   XRET2,COMCHK    GO TO CHECK LAST WRITE                   39600000
         SPACE 1                                                        39640000
         SPACE                                                          39680000
         LA    XS1,IOCT+12     L LOC OF START OF RLD I/O CTL TABLE      39720000
         LR    XRMK2,XS1              L SAME IN XRMK2 AND               39760000
         AH    XRMK2,ENIRC         ADD CURRENT LENGTH OF TABLE          39800000
*THE TTR CONTAINED IN REG 1, IS STORED IN THE CURRENT RLD I/O CONTROL   39840000
*TABLE ENTRY                                                            39880000
         ST    GR1,0(XRMK2)    SAVE RLD NOTE LIST TTR IN CURRENT RLD    39920000
*                                 I/O CONTROL TABLE ENTRY               39960000
         LA    XRMK2,4(XRMK2)  STEP TO NEXT ENTRY LOC                   40000000
         SR    XRMK2,XS1       SUBTRACT LOC OF TABLE START              40040000
BUFRMK2D STH   XRMK2,ENIRC     SAVE UPDATED TABLE BYTE COUNT IN APT     40080000
*IF THE RLD I/O CONTROL TABLE IS FULL, THE 'FULLR' INDICATOR IS SET     40120000
*THIS MEANS THAT NO MORE BUFFERINGS OF THE RLD NOT LIST CAN OCCUR.      40160000
         CLI   ENIRC+1,MCT     CHK IF RLD I/O CTRL TABLE FULL           40200000
         BC    4,BUFRMK3       BC IF NO TO CONTINUE                     40240000
         OI    RLDFLGS,FULLR   YES -- SET OVERFLOW FLAG                 40280000
BUFRMK3  SR    R0,R0                      RESET TO ZERO                 40320000
         NI    BUFFS,N2BUFWF   RESET BOTH FULL AND WRITTEN FLAGS        40340000
         STH   R0,ENR1C             RLD NOTE LIST ENTRY COUNT           40360000
         STH   R0,ENCT         RESET ENTRY COUNT IN MODEL               40400000
         OI    RLDFLGS,PURGE       SET PURGE FLAG                       40420000
         SPACE 2                                                        40440000
RLDBUF7C TM    NEWSW,TUPAS     CHK FOR 2 PASS FLAG                      40480000
         BC    8,RLDBUFBK      NO -- GO TO RETURN                       40520000
RLDBUF7D LTR   XOBCNT,XOBCNT   CHK FOR ANY BUFFERRED COUNT              40560000
         BC    8,RLDBUF8A      BC IF NONE                               40600000
         TM    RLDMULT,TTRF    CHK FOR END-OF-BUFFER FLAG               40640000
         BC    8,RLDBUF8A      BC IF NO                                 40680000
         LR    R14,XOBCNT      L BUFFERED BYTE COUNT IN REG E           40720000
         TM    BUFFS,BUFFRN2   CHK IF BUFFER 2 IS CURRENT               40760000
         BC    1,RLDBUF7E      BC IF YES                                40800000
         L     R15,RLDOUT1     NO -- L LOC OF BUFFER 1                  40840000
         SPACE 1                                                        40880000
         BAL   XRET2,RLDBUFR   GO TO WRITE OUT BUFFER 1                 40920000
         BAL   XRET2,COMCHK            CHECK AND NOTE                   40960000
****             REMOVE ABOVE INSTRUCTION IF OVERLAP IS ADDED           41000000
         ST    GR1,SAVETTR             SAVE TTR                         41040000
****             REMOVE ABOVE INSTRUCTION IF OVERLAP IS ADDED           41080000
         SPACE 1                                                        41120000
         OI    BUFFS,BUFW1     SET BUFFER 1 WRITTEN FLAG                41160000
         NI    BUFFS,NBUF1CHK  CLEAR BUFFER 1 CHECKED FLAG              41200000
         BC    15,RLDBUF7F                                              41240000
RLDBUF7E L     R15,RLDOUT2     L LOC OF BUFFER 2                        41280000
         SPACE 1                                                        41320000
         BAL   XRET2,RLDBUFR   GO TO WRITE OUT BUFFER 2                 41360000
         BAL   XRET2,COMCHK            CHECK AND NOTE                   41400000
****             REMOVE ABOVE INSTRUCTION IF OVERLAP IS ADDED           41440000
         ST    GR1,SAVETTR             SAVE TTR                         41480000
****             REMOVE ABOVE INSTRUCTION IF OVERLAP IS ADDED           41520000
         SPACE 1                                                        41560000
         OI    BUFFS,BUFW2     SET BUFFER 2 WRITTEN FLAG                41600000
         NI    BUFFS,NBUF2CHK  CLEAR BUFFER 2 CHECKED                   41640000
RLDBUF7F STH   XOBCNT,OBCNT    SAVE CURRENT BUFFERRED BYTE COUNT        41680000
         MVC   LPREP(14),PREP  SAVE WRITTEN MODEL FOR CHECK             41720000
         SR    XOBCNT,XOBCNT   CLEAR BUFFERRED BYTE COUNT               41760000
         TM    BUFFS,OPNR1     CHK FOR BUFFER 1 OPENER FLAG             41800000
         BC    8,RLDBUF8       BC IF NO                                 41840000
         MVC   PREP(14),CPREP  RESTORE CURRENT MODEL                    41880000
         LH    XOBCNT,OBCNT    RESTORE CURRENT BUFFERRED BYTE COUNT     41920000
         OI    BUFFS,BUFFRN2   SET BUFFER 2 CURRENT FLAG                41960000
         NI    BUFFS,NOPNR1    CLEAR BUFFER 1 OPENER FLAG               42000000
RLDBUF8  TM    BUFFS,FULL2     CHK FOR 2 BUFFERS FULL                   42040000
         BC    1,RLDBUF6       LOOP TO CHECK, THEN WRITE                42080000
         TM    RLDFLGS,PURGE   CHK FOR PURGE FLAG                       42088000
         BC    8,RLDBUF8A      BC IF NONE                               42096000
         NI    RLDFLGS,NPURGE  YES -- CLEAR PURGE FLAG                  42104000
         BC    15,RLDBUF6D     GO TO STEP NOTE LIST ENTRY COUNT         42112000
RLDBUF8A TM    RLDFLGS,CHKNOW  CHK FOR CHECK NOW FLAG                   42120000
         BC    1,RLDBUF6A      BC IF YES TO CHECK                       42160000
         TM    RLDFLGS,FNLCHK  CHK IF FINAL CHECK FLAG                  42200000
         BC    1,RLDBUF8B      BC IF YES                                42240000
         TM    NEWSW,EOD       CHK FOR END-OF-DATA NOW                  42280000
         BC    8,RLDBUF8C      BC IF NO                                 42320000
         OI    RLDFLGS,FNLCHK  SET FINAL CHECK FLAG                     42360000
         BC    15,RLDBUF3B     LOOP TO FINAL CHECK                      42400000
RLDBUF8B NI    RLDFLGS,NFNLCHK    CLEAR FINAL CHECK FLAG                42440000
RLDBUF8C TM    RLDMULT,TTRF    CHK FOR END-OF-BUFFER FLAG               42480000
         BC    8,RLDBUFBK      BC IF NO                                 42520000
         NI    BUFFS,BUFFRN1   CLEAR BUFFER 2 CURRENT FLAG              42560000
         OC    BUFFS(1),SFLIP  SET FLAG FOR NEXT BUFFER                 42600000
RLDBUFBK SR    XRIO,XRIO       CLEAR REGISTER                           42640000
         BCTR  XRIO,0          INVERT                                   42680000
         STH   XRIO,PRER       RESET PREVIOUS 'R' ID                    42720000
         STH   XRIO,PREP       RESET PREVIOUS 'P' ID                    42760000
RLDBFBK1 LH    XRIO,ENR1C         L UPDATED NOTE LIST ENTRY COUNT       42800000
         STH   XRIO,ENCT                  AND SET IN MODEL              42840000
         MVI   RLDMULT,STMULT  RESET RLD ITEM MULTIPLICITY              42880000
         SPACE 1                                                        42920000
*       CHECK FOR END-OF-OUTPUT-MODULE FLAG.  INITIALIZE PROCESS        42960000
*                 FLAGS IF FOUND AND RETURN TO CALLER.                  43000000
         SPACE 1                                                        43040000
RLDBFRTN TM    NEWSW,EOD       CHK FOR END-OF-OUTPUT-MODULE FLAG        43080000
         BCR   8,XRET          RETURN IF NO                             43120000
         MVI   PRER,X'FF'      YES -- INITIALIZE PREVIOUS 'R' ID        43160000
         MVC   PRER+1(3),PRER  INITIALIZE PREVIOUS 'P' ID               43200000
         MVI   WDCNT,X'00'            INITIALIZE                        43240000
         MVC   WDCNT+1(21),WDCNT    CONTROL AREAS                       43280000
           MVC   CALLCURP(2),CONZO                                26211 43300000
         BCR   15,XRET         RETURN                                   43320000
         SPACE 2                                                        43360000
     TITLE 'IEWLMRAT   RLD/TXT PROCESSOR  --  RLD CONSTANTS'            43400000
DCBAD    DC    A(IEWLCUDB)                                              43440000
ADDEL    DC    V(IEWLCDLK)                                              43480000
*                                    PROCESSED CSECTS IN BUFFER         43520000
ERROM    DC    X'1216'                                                  43640000
TEMP     DS    X                       RNT TYPE BUFFER          SA69196 43650021
         SPACE 2                                                        43680000
         SPACE 2                                                        47040000
TXT001AD DC    A(IEWLMTXT)     LOC OF TEXT PROCESSING ROUTINE           47080000
TXTBUFAD DC    A(TXTBUF) LOC OF TEXT PURGE ROUTINE                      47120000
RATADR   DC    A(RATLOC) RLD STANDARD BASE REGISTER VALUE               47160000
FOUR     DC    F'4'                    OFFSET FOR RNT TABLE      A53300 47210000
         SPACE 2                                                        48040000
SPACH    DC    25D'0'    PATCH AREA                                     48080000
     TITLE 'IEWLMRAT   RLD/TXT PROCESSOR  --  TEXT PROCESSING'          48120000
IEWLMTXT CSECT                                                          48160000
         SPACE 3                                                        48163000
*                                                                       48166000
*                     T E X T    P R O C E S S O R                      48169000
*                                                                       48172000
         SPACE 2                                                        48175000
*      THIS ROUTINE PROCESSES ALL TXT INPUT FOR EVERY LINKEDIT. THE ID  48178000
*  IS RENUMBERED VIA THE RENUMBERING TABLE AND THE MULTIPLICITY IS      48181000
*  DETERMINED AS A FUNCTION OF A SYSLMOD RECORD.   AFTER SPACE HAS BEEN 48184000
*  ALLOCATED IN THE TXTBUFFER AND AN ENTRY MADE IN THE TXTIO TABLE AND  48187000
*  TEXT NOTELIST(FIRST APPEARANCE ONLY),THE TEXT IS MOVED(OBJ) OR READ  48190000
*  DIRECTLY(LM) INTO THE TXTBUFFER.                                     48193000
         SPACE 2                                                        48203000
*                                                                       48213000
*              GENERAL  REGISTER UTILIZATION                            48223000
*                                                                       48233000
RID1     EQU   1         GENERAL WORK REGISTER IN INITIAL LOAD MODULE   48243000
*                             PROCESSING                                48253000
COUNT    EQU   4         WILL MAINTAIN INPUT COUNT AS PASSED BY LMINP   48263000
RID      EQU   5         WILL MAINTAIN RENUMBERED ID                    48273000
REG6     EQU   6         WORK REGISTER FOR LM PROCESSING & TXTBUF       48283000
RIP      EQU   6         LOCATION OF OBJECT MODULE TEXT PRIOR TO MOVE   48293000
*                        INTO PROPER LOCATION IN THE TEXT BUFFER        48303000
TXTBASE  EQU   7         BASE REGISTER FOR TEXT PROCESSOR -             48313000
*                        REG 12 IS BASE FOR RLD PROCESSOR               48323000
XSTX     EQU   7         LINK REGISTER WHEN RETURNING TO MINP FOR LM    48333000
DCBADD   EQU   8         READ. REG 8 HAS DCB ADDRESS                    48343000
GR8      EQU   8         GENERAL WORK REG                               48353000
XTMK2    EQU   8         WORK REG WHEN TEXT NOTE LIST WRITTEN           48363000
READCNT  EQU   9         REGISTER TO PASS LENGTH TO MINP FOR LM READ    48373000
RLK      EQU   9         GENERAL                                        48383000
BUFFADDR EQU   10        LOCATION FOR LM READ PASSED TO MINP            48393000
XP1      EQU   10        GENERAL                                        48403000
XP2      EQU   11        GENERAL                                        48413000
* REG12 - RLD PROCESSOR BASE - REQUIRED WHEN RETURNING FOR ANY COMMON   48423000
*     AREA (WRITE ROUTINE,ERROR HANDLING,AND NORMAL RETURN )            48433000
         EJECT                                                          48443000
         SPACE                                                          48453000
*                                                                       48463000
*                   MASKS AND FLAGS FOR IEWLMTXT                        48473000
*                                                                       48483000
         SPACE                                                          48493000
FLAGOUT  EQU   X'03'            MASK TO ZERO FLAG FIELD IN TXTIO        48760000
READSW   EQU   X'04'      INDICATOR WHEN A READ IS TO BE ISSUED         48800000
READOFF  EQU   X'FB'        TURN OFF THE READ SW                        48840000
DENSE1   EQU   X'40'        FOR INTERNAL INDICATOR                      48920000
DENSE    EQU   X'20'                                                    48960000
TTRDEN   EQU   X'60'              MASK FOR TTR AND DENSE RECORD         49000000
INCORE   EQU   X'80'              MASK FOR TXTIO FLAG                   49040000
NOLEN    EQU   X'80'                                                    49080000
ERRM1    EQU   X'226'                                                   49120000
EOF      EQU   X'01'     END OF INPUT SWITCH                            49160000
FULLT    EQU   X'40'                                                    49200000
ERRTI    EQU   X'226'                                                   49240000
ERRTM    EQU   X'424'                                                   49280000
SHORTRD  EQU   X'20'            MASK FOR SHORT READ FOR LM              49320000
*                     ALL ITEMS IN CONTROL RECORD TO BE DELETED         49360000
SHORTRD1 EQU   X'DF'         MASK TO RESET SHORT READ SWITCH            49400000
NOLEN1   EQU   X'10'                                                    49440000
NOLEN2   EQU   X'08'       NOLENGTH INDICATOR FOR NAME CARD             49480000
NOLEN3   EQU   X'18'          MASK FOR NOLENGTH IN GENERAL              49520000
NOGRPPG  EQU  X'10'           FLAG SIGNIFING A NONGROUPED PURGE REQ101  49530000
SPTXTON  EQU   X'80'                   FLAG FOR SPEC LM TEXT    SA56444 49532021
SPTXTOFF EQU   X'7F'                   RESET SPEC LM TEXT FLAG  SA56444 49534021
         SPACE 2                                                        49540000
*    *    *    *    *    *    *    *    *    *    *    *    *    *    * 49560000
         EJECT                                                          49570000
         BC    15,MODIDT+6    BRANCH AROUND IDENTIFIER                  49580000
MODIDT   DC    C'00MTXT'      IDENTIFIER                                49590000
         TM    APT1,EX        IS LOAD MODULE                            49600000
         BC    1,TXTLM        YES - BRANCH                              49640000
TXT0011  LTR   RID,RID        IS TXT ID EQU ZERO                        49680000
         BC    8,TXTILL       YES - ERROR                               49720000
         CH    RID,ENCDX      TXT ID G.T. NUMBER OF ESD ITEMS           49760000
         BC    2,TXTILL       YES - ERROR                               49800000
         SLL   RID,2          CALCULATE RENUMBER LINE                   49840000
         A     RID,RECNT       ENTRY                                    49880000
         CLC   DID(2,RID),CONZO1     IS RENUMBERED ID EQU ZERO          49920000
         BC    8,TXTILL       YES - ERROR                               49960000
         TM    DT(RID),DEL    IS THIS ID TO BE DELETED                  50000000
         BC    1,TXTLM2                                                 50040000
         TM    DT(RID),DT     TYPE NOT SD OR PC - INVALID               50080000
         BC    8,TXT00151                                               50120000
*                          IF ERROR BRANCH TAKEN   MODULE MARKED NOT    50160000
*                          EXECUTABLE UNLESS 'LET' SPECIFIED            50200000
TXTILL   LA    R0,ERRTI                                                 50240000
         TM    APT1,EX        IS IT A LOAD MODULE?               A43127 50250021
         BO    ERR3A          YES-ISSUE MSG AND FLUSH NEXT REC   A43127 50260021
         B     ERROR                                                    50280000
*                                                                       50320000
TXT00151 LH    RID,DID(RID)   RID=NEW UPDATED ID                        50360000
         LR    XS1,RID        XS1=NEW UPDATED ID                        50400000
         STH   XS1,CURID                                                50440000
* DETERMINE MULTIPLICITY AND CHECK FOR '512' MAXIMUM                    50480000
         SLL   XS1,4                                                    50520000
         A     XS1,CHESD  XS1=ABSOLUTE ADDR OF ENT. IN CESD             50560000
         L     XS1,8(XS1) XS1=TYPE AND ASSEMBLED ADDRESS                50600000
         LA    XS1,0(XS1) XS1=ASSEMBLED ADDR OF CONTROL SECTION         50640000
         SR    XAA,XS1    ASSM ADDR NOW RELATIVE ZERO                   50680000
         LR    GR9,XAA                                                  50720000
         SR    GR8,GR8        DIVIDE BY SYSLMOD SIZE TO DETERINE        50760000
         D     GR8,MULTSIZE     MULTIPLICITY AND DISPLACEMENT           50800000
         STH   GR9,CMULN                                                50840000
         STH   GR8,CDISP                                                50880000
         CH    GR9,MAXMULT     BRANCH IF WE HAVE NOT EXCEED             50920000
         BC    4,TXTINT         THE NUMBER OF MULTIPLICITIES            50960000
         LA    R0,ERRTM      INPUT HAS EXCEEDED MULT LIMIT              51000000
         B     ERROR                                                    51040000
* PASS INITIAL  CHECKS                                                  51080000
* INITIALIZE     -  WILL SAVE MUCH REPETITION LATER                     51120000
*       TXTFREE - ADDRESS OF NEXT FREE ENTRY IN TXTIO TABLE             51160000
*       TNTFREE - ADDRESS OF NEXT FREE ENTRY IN TXT NOTE LIST           51200000
TXTINT   L    GR1,TXTIO                                                 51240000
         AH   GR1,ENTOC    DISPLACEMENT IN TXTIO                        51280000
         ST   GR1,TXTFREE                                               51320000
         LA    R0,7        MULTIPLY NUMBER OF ENTRIES BY 7              51360000
         MH    R0,ENT1C                                                 51400000
         A     R0,TNT1                                                  51440000
         ST    R0,TNTFREE                                               51480000
* WE KNOW THE CURRENT ID AND MULTIPLICITY                               51520000
         CLC   PID(2),CURID   CHECK IF ID IA A REPEAT                   51560000
         BC    7,TXT002          NO - BRANCH                            51600000
         CLC   PMULN(2),CMULN   HAS THE MULT CHANGED                    51640000
         BC    7,TXT002X     YES - BRANCH                       SA56444 51680021
         TM    APT1,EX    IS THIS A LOAD MODULE                         51690000
         BC    1,TXTLM3       YES BRANCH  ID ID THE SAME                51700000
         TM    SWITCH,DENSE1  WAS LAST THING WE WE DEALING WITH A DENSE 51720000
         BC    1,TXTDEN         RECORD                                  51760000
         L     GR1,LASTTNT      OBTAIN LAST NOTELIST ADDR               51880000
         B     TXTINSRT                                                 51920000
* SECOND PHASE                                                          51960000
* THE ID  AND OR MULT HAVE CHANGED -                                    52000000
*                                                                       52040000
*                                                                       52080000
TXT002   TM    SWITCH,NOLEN   WAS PREVIOUS ENTRY A NO LENGTH            52120000
         BC    14,TXT002A                                               52160000
*                                                                       52200000
TXTN1    MVC   HOLD1(4),CURID      PRESERVE CURRENT ID                  52240000
         MVC   CURID(2),PID        RESTORE OLD ID                       52280000
         TM    SWITCH,DENSE1        IS THERE DENSE ENTRY TO CLEAR UP    52320000
         BC    14,TXTN5         NO - BRANCH                             52360000
         L     XS1,TNTFREE       SET UP PARAMETER FOR                   52400000
         SH    XS1,TSEVEN          DENSE PURGE                          52440000
         BAL   XP2,TXTNIO         GO TO DENSE PURGE                     52480000
TXTN5    NI    SWITCH,X'3F'      CLEAR DENSE AND NOLEN BITS             52520000
         OI    SWITCH,NOLEN2                                            52560000
         B     BUFFALL    FIND NUMBER OF MULT AND LENGTH OF             52600000
*                                   LAST ONE                            52640000
TXT002X  OI    SWITCH+1,SPTXTON        INDICATE CHANGED MULT    SA56444 52650021
TXT002A  TM    SWITCH,DENSE1   WAS PREVIOUS ENTRY DENSE                 52680021
         BC    14,TXT002B         BRANCH LAST NOT DENSE                 52720000
         NI    SWITCH,X'BF'   TUNN OF INDICATOR                         52760000
         L     XS1,TNTFREE        WRITE OUT                             52800000
         SH    XS1,TSEVEN   SET UP NOTELIST ADDR                        52840000
         BAL   XP2,TXTNIO         WRITE OUT LAST PIECE                  52880000
TXT002B  MVC   PID(4),CURID    UPDATE PAST ID TO AGREE WITH CURRENT     52920000
         TM    APT1,EX      IS THIS A LOAD MOD                          52925000
         BC    8,TXT003      NO - BRANCH                                52930000
         TM    SWITCH,READSW     HAS THE READ BEEN ISSUED               52935000
         BC    8,TXT002BB       YES  BRANCH                             52940000
         L     R0,TXTBFBEG     ADD THE TXTBUF ADDR TO THE               52945000
         A     R0,BUFDISP       DISPLAC IN THE BUFF TO FIND             52950000
         AR    R0,COUNT                IF THE NEXT READ WILL FIT        52955000
         AH    R0,CDISP                ADD WHAT'S BEEN ALLOCATED A38306 52957021
         C     R0,TXTBFEND                                              52960000
         BC    12,TXT002BB       BR IF IT WILL FIR                      52965000
         BAL   RLK,TXTBUF                                               52970000
         SR    RLK,RLK     RESET DISPLACE IN TXTBUF TO                  52975000
         ST    RLK,BUFDISP      XERO                                    52980000
TXT002BB TM    APT1,EX                                                  52985000
         BC    1,BUFALLOC                                               53000000
*                                                                       53040000
*  NOW CAN SEARCH TXTIO TO SEE IF THIS ID AND MULT HAVE EVER APPEARED   53080000
*     BEFORE                                                            53120000
*                                                                       53160000
TXT003   SR    GR8,GR8        GR8 WILL CONTAIN NOTE LIST DISPLACEMENT   53200000
         L     XS1,TXTFREE    IN TXTIO TABLE                            53240000
         L     XS2,TXTIO                                                53280000
         CR    XS1,XS2        ANYTHING IN THE TABLE                     53320000
         BC    8,TXTNEW                                                 53360000
TXT003A  CLC   CURID(2),0(XS2) COMPARE ID FIELD FIRST                   53400000
         BC    8,TXT003B       BRANCH ON A MATCH                        53440000
TXT003C  LA    XS2,4(XS2)                                               53480000
         LA    GR8,7(GR8)                                               53520000
         CR    XS2,XS1                                                  53560000
         BC    4,TXT003A                                                53600000
*  HAVE NEW ID  - TEST IF LENGTH PRESENT IN CESD                        53640000
TXTNEW   TM    SWITCH,NOLEN3                                            53680000
         BC    7,TXTNL6B        ENTRY NO FOUND  RETURN                  53720000
         LH    XS1,CURID                                                53760000
         SLL   XS1,4                                                    53800000
         A     XS1,CHESD                                                53840000
         CLC   13(3,XS1),CONZO1    CESD LENGTH EQU ZERO                 53880000
         BC    7,TXT003D      BRANCH IF LENGTH SPECIFIED                53920000
         OI    SWITCH,NOLEN                                             53960000
TXT003D  B     BUFALLOC                                                 54000000
*                                                                       54040000
*ID MATCHED-MUST CHECK MULT -  FIRST 10 BITS OF TXTIO ENTRY             54080000
TXT003B  LH    GR5,2(XS2)                                               54120000
         N     GR5,MULTONLY     ZERO OUT THE TOP 22 BITS                54160000
         CH    GR5,CMULN                                                54200000
         BC    8,TXTOLD       CONTINUE PROCESS ON A MATCH               54240000
         SH    XS1,SFOUR    POSITION TO LAST ENTRY IN TXTIO        101  54248000
         CLC   0(2,XS1),CURID  HAS THE ID CHANGED WE ARE PROCESSING101  54256000
         BC    7,ABAFIX             YES-  MUST SET NONGRP PURGE NEC101  54264000
TXT003B1 LA    XS1,4(XS1)     RESTORE THE ADDR OF FREE TXTIO ADDR  101  54272000
         B     TXT003C        OR CONTINUE SEARCH                        54280000
*                                                                       54320000
ABAFIX   OI    SWITCH+1,NOGRPPG   SIGNIFY A NONGROUPED PURGE NEC   101  54330000
         B     TXT003B1          GO BACJ TO RESTORE TXTIO FREE ADDR101  54340000
TXTOLD   TM    SWITCH,NOLEN3                                            54360000
         BC    7,TXTNL3                                                 54400000
         TM    2(XS2),INCORE       CHECK IF ALREADY WRITTEN             54440000
*  XP1- SIZE LAST MULT   XS2-TXTIO ADDR   GR8-TNT1 DISP                 54480000
         BC    8,TXTOLD1      BRANCH IF NOT                             54520000
         LH    GR1,ENITC      HAS THE NOTELIST BEEN WRITTEN             54560000
         LTR   GR1,GR1                                                  54600000
         BC    8,TXTOLDA         IF NOT  BRANCH                         54640000
         LA    GR1,7                                                    54680000
         MH    GR1,TXTNOTE                                              54720000
         SR    GR8,GR1          SUB ACTUAL BYTES WRITTEN                54760000
TXTOLDA  L     GR1,TNT1                                                 54800000
         AR    GR1,GR8                                                  54840000
         B     TXTINSRT                                                 54880000
TXTOLD1  L     GR8,BUFDISP     BEFORE SIGNALLING DENSE INFO             54920000
         A     GR8,MULTSIZE         CHECK THAT MULT SIZE CAN BE ALLOC   54960000
         A     GR8,TXTBFBEG          IF NOT  IT WILL ENTER PURGE        55000000
         C     GR8,TXTBFEND       EXPECTING LAST ITEM TO BE DENSE       55040000
         BC    12,TXTOLD2                                               55080000
         BAL   RLK,TXTBUF2          PURGE BEFORE SETTING SENSE          55120000
         SR    RLK,RLK            RESET PARA AFTER PURGE                55160000
         ST    RLK,BUFDISP                                              55200000
TXTOLD2  OI    SWITCH,DENSE1                                            55240000
         B     BUFALLOC                                                 55280000
*                                                                       55320000
*BUFALLOC  THIS ROUTINE WILL ALLOCATE REQUIRED SIZE IN BUFFER           55360000
*        PIECE     1 MULT                                               55400000
*        CSECT     1 MULT EXECPT FOR LAST                               55440000
*                       LAST MULT ACTUAL SIZE                           55480000
*                                                                       55520000
BUFALLOC TM    SWITCH,DENSE1  DEALING WITH OUT OF ORDER TEXT            55560000
         BC    8,BUFFALL               NO,BRANCH                 A30147 55570021
         TM    APT1,EX                 IS IT LOAD MODULE         A30147 55580021
         BC    8,BUF1                  NO,BRANCH                 A30147 55590021
         L     XS2,MULTSIZE            YES,PICK UP OUTPUT RECSIZEA30147 55600021
         SH    XS2,CDISP               MULTSIZE-CDISP=TRUE SIZE  A30147 55610021
         B     BUFOUT                  GO TO ALLOCATE THAT MUCH  A30147 55620021
BUFFALL  TM    SWITCH,NOLEN   NOLENGTH WILL ALSO GET FULL MULT ALLOC    55640000
         BC    1,BUF1         UNTIL REAL SIZE KNOWN                     55680000
         LH    XS1,CURID      MUST CHECK SIZE IN CESD                   55720000
         SLL   XS1,4                                                    55760000
         A     XS1,CHESD                                                55800000
         CLC   13(3,XS1),CONZO1     IS CESD LENGTH ZERO                 55810000
         BC    7,BUFFALL1                                               55820000
         LH    R0,ERRNOLEN     LOAD ERROR PARA                          55830000
         LR    GR1,XS1                                                  55840000
         B     ERROR                                                    55850000
BUFFALL1 CLC   13(3,XS1),MULTSIZE+1  IF THE CESD SIZE EXCEEDS MULT      55860000
         BC    2,BUF2              BRANCH                               55880000
         LH    XS2,14(XS1)         SIZE = CESD SIZE                     55920000
         SR    XP2,XP2     SET HIGHEST MULT TO ZER/                     55960000
         B     BUFOUT11                                                 56000000
BUF2     L     XP2,12(XS1)    PICK UP ACTUAL CESD LENGTH                56040000
         LA    XP2,0(XP2)    CLEAR HIGH ORDER BYTE                      56080000
         SR    XP1,XP1                                                  56120000
         D     XP1,MULTSIZE                                             56160000
         LTR   XP1,XP1            IF THE REMAINDER IS ZERO IT IS        56200000
         BC    7,BUF1A            NECESSARY TO DECREMENT THE MULT ONE   56240000
         BCTR  XP2,0                                                    56280000
         L     XP1,MULTSIZE       INSERT FULL SIZE                      56320000
BUF1A    TM    SWITCH,NOLEN3                                            56360000
         BC    7,BUF1A1                                                 56400000
         CH    XP2,CMULN           IS THIS THE LAST MULT                56440000
         BC    7,BUF1               FULL MULT                           56480000
BUF1A1   LR    XS2,XP1          GET CORRECT LENGTH FOR NO LEN           56520000
BUFOUT11 LA    XS2,7(XS2)              MUST ALLOC THE LAST MULT ON      56560021
         N     XS2,DBLWRD                 A DOUBLEWORD BOUNDARY         56600021
         TM    SWITCH,NOLEN3                                            56640000
         BC    8,BUFOUT                                                 56680000
         LR    XP1,XS2          SAVE LENGTH FOR NO LENGTH               56720000
         B     TXTNL2                                                   56760000
BUF1     L     XS2,MULTSIZE                                             56800000
BUFOUT   LR    R0,R15                                                   56840000
         L     GR1,BUFDISP                                              56880000
         A     GR1,TXTBFBEG                                             56920000
         ST    GR1,BUFSTART                                             56960000
         A     R0,BUFDISP                                               57000000
         ST    R0,BUFDISP                                               57040000
         A     R0,TXTBFBEG        HAVE WE EXCEEDED BUFFER LIMITS        57080000
         C     R0,TXTBFEND                                              57120000
         BC    12,BUFCLR     ******REMOVE WHENBUFCLR NO LONGER          57160000
*         NECESSARY    REPLACE WITH    BC   10,BUFENT                   57200000
         ST    XS2,BUFDISP                                              57240000
         ST    XS2,SPACES                                               57280000
         BAL   RLK,TXTBUF          YES - PURGE                          57320000
         TM    APT1,EX     IS THIS A LOAD MOD                           57360000
         BC    14,BUFOUT1                                               57400000
         L     XP1,LMLEN     SET LENGTH PARA FOR MOVE                   57440000
         L     GR8,TXTBFBEG        SET UP TO ADDR                       57480000
         L     GR9,BUFSTART    SET UP FROM AD                           57520000
         BAL   XP2,LMMOVE                                               57560000
BUFOUT1  L     GR1,TXTBFBEG    RESER POINTERS                           57600000
         L     XS2,SPACES                                               57640000
         ST    GR1,BUFSTART                                             57680000
         B     BUFCLR       ********REMOVE WHEN BUFCLR NO LONGER        57720000
*         NECESSARY    REPLACE WITH    B   BUFENT                       57760000
*                                                                       57800000
TXTNL2   STH   XP2,CMULN           KNOW IDENTIFICATION OF LAST MULT     57840000
         B     TXT003              GO SEARCH TXTIO FOR ENTRY TO CORRECT 57880000
*                                   LENGTH                              57920000
*                                                                       57960000
*           THIS IS A SUBROUTINE TO CLEAR THE ALLOCATED                 58000000
*           PORTION OF THE BUFFER -   THIS IS NECESSARY IN ORDER TO     58040000
*             SYSGEN THE NUCLEUS AND SHOULD BE REMOVED WHEN             58080000
*            FETCH NO LONGER REQUIRES ZEROS IN BUFFER                   58120000
*                                                                       58160000
BUFCLR   TM    PDSE7,X'04'        IF SCATTER NOT SPECIFIED - WILL       58200000
         BC    8,BUFENT           AVOID CLEARING BUFFER                 58240000
         TM    APT1,EX            MUST ALSO AVOID IF LOAD MOD INPUT     58280000
         BC    8,BUFCLR4       IF IS LM   WILL AVOID CLEARING IF        58320000
         TM    SWITCH,READSW        THE READ HAS BEEN ISSUED            58360000
         BC    8,BUFENT         SINCE IT IS IMPOSSIBLE TO TELL          58400000
BUFCLR4  LR    XP2,XS2      WHAT THE GROUPING WAS                       58440000
         LA    XP1,256                                                  58480000
         L     GR1,BUFSTART       GR1 - STARTING ADDR OF AREA           58520000
BUFCLR1  CR    XP1,XP2            LENGTH GT 256                         58560000
         BC    10,BUFCLR2         NO - BRANCH                           58600000
         XC    0(256,GR1),0(GR1)                                        58640000
         SR    XP2,XP1            DECREMENT COUNT                       58680000
         AR    GR1,XP1            INCREMENT ADDR                        58720000
         B     BUFCLR1                                                  58760000
BUFCLR2  BCTR  XP2,0                                                    58800000
         EX    XP2,BUFCLR3                                              58840000
         B     BUFENT                                                   58880000
*                                                                       58920000
BUFCLR3  XC    0(1,GR1),0(GR1)                                          58960000
*                                                                       59000000
*                                                                       59040000
* BUFENT MAKES ALL NECESSARY ENTRIES IN TXTIO TABLE AND TXT NOTE LIST   59080000
*        R15 CONTAINS ALLOCATED SIZE                                    59120000
*        BUFSTART CONTAINS BUFF STARTING ADDR FOR AREA                  59160000
BUFENT  SR     XP2,XP2                                                  59200000
         TM    SWITCH,DENSE1                                            59240000
         BC    1,BUFENT1      AVOID THE DIVIDE BUT CHECK FOR FULL TABLE 59280000
         C     XS2,UT1SIZE    WAS LARGER THAN UT1 ALLOC                 59320000
         BC    12,BUFENT1     NO - BRANCH                               59360000
         LR    XP2,XS2                                                  59400000
         SR    XP1,XP1                                                  59440000
         D     XP1,UT1SIZE                                              59480000
         ST    XP1,DISPLAC    DISPLAC IN LAST SECTION                   59520000
         LTR   XP1,XP1        WILL THE DIVIDE COME OUT EVEN             59560000
         BC    8,BUFENT1A                                               59600000
BUFENT1  LA    XP2,1(XP2)     XP2 HAS NUMBER OF ENTRIES REQUIRED        59640000
BUFENT1A LR    GR9,XP2                                                  59680000
         SLL   GR9,2        MUST INSURE THAT THE TXTIO                  59720000
         AH    GR9,ENTOC       HAS NOT BEEN OVERFLOWED                  59760000
         CH    GR9,ENTOX         IF IT HAS  IT IS A                     59800000
         BC    12,BUFENT1B       UNRECOVERABLE ERROR                    59840000
         LA    R0,ERRTM        AND THE JOB IS TERMINATED                59880000
         B     ERROR                                                    59920000
BUFENT1B LR    GR9,XP2                                                  59960000
         AH    GR9,ENT1C                                                60000000
         CH    GR9,ENT1X      INSURE ALL REQUIRED ENTRIES CAN BE        60040000
         BC    12,BUFENT2          MADE BEFORE ATTEMPTING ANY           60080000
         LR    GR3,XP2      SAVE REG XP2 WHEN ENTERING PURGES           60120000
         MVC   HOLD3+8(1),SWITCH       MUST MAINTAIN SWITCH             60160000
         ST    XS2,BUFDISP                                              60200000
         BAL  RLK,TXTBUF2                                               60240000
         TM    APT1,EX       IS THIS A LOAD MODULE                      60280000
         BC    14,BUFENT1D        IF NOT  BRANCH                        60320000
         L     RLK,BUFSTART       WAS THERE ANY THING IN THE            60360000
         C     RLK,TXTBFBEG        THAT WAS NOT ALLOC I                 60400000
         BC    8,BUFENT1D         IF NOT   NO SWEAT                     60440000
         L     XP1,LMLEN       IF THERE WAS  IT MUST                    60480000
         L     GR8,TXTBFBEG         IT MUST BE MOBED TO THE FRONT       60520000
         BAL   XP2,LMMOVE     OF THE BUFFER AND RECORDED                60560000
BUFENT1D L     RLK,TXTBFBEG                                             60600000
         MVC   SWITCH(1),HOLD3+8         RESTORE SWITCH AFTER PURGE     60640000
         ST    RLK,BUFSTART                                             60680000
         BAL   RLK,BUFTMK2                                              60720000
         L     XS2,BUFDISP                                              60760000
         LR    XP2,GR3                                                  60800000
BUFENT2  ST    XS2,HOLD        LENGTH IN HOLD                           60840000
         ST    XS2,HOLD3      MUST PRESERVE THE ALLOC LENGTH            60880000
         MVC   HOLD1(4),CURID                                           60920000
         OI    HOLD1+2,INCORE  MARK ENTRY AS INCORE                     60960000
         L     GR8,TNTFREE        INIT TNT1 FREE ADDR                   61000000
         MVC   0(2,GR8),CONZO1     MUST INSURE ZERO DISP FIELD          61040000
BUFENT5  L     GR1,TXTFREE                                              61080000
         TM    SWITCH,DENSE1                                            61120000
         BC    1,BUFDEN                                                 61160000
BUFENTA  MVC   0(4,GR1),HOLD1      INSERT ID & MULT IN TXTIO            61200000
         MVC   5(2,GR8),HOLD+2     PUT LENGTH IN NOTELIST               61240000
         MVC   2(3,GR8),BUFSTART+1  AND STARTING ADDR                   61280000
         BAL   GR1,TXTPTR         UPDATE ALL INTERNAL PTRS              61320000
         BCT   XP2,BUFENT4         HAVE WE MADE ALL NECESARY ENTRIES    61360000
         L     XS2,HOLD3      MUST PRESERVE THE ALLOC LENGTH            61400000
         ST    XP2,HOLD+4          ZERO AREA AS WE LEAVE                61440000
         TM    APT1,EX            IS THIS A LOAD MODULE                 61480000
         BC    8,BUFENTA1          BR ON OBJENT INPUT                   61520000
         TM    SWITCH,READSW       HAS THE READ BEEN ISSUED             61560000
         BC    8,TXTLM5       YES  BRANCH                               61600000
         LA    GR3,TXTLM5        SET RETURN ADDR AFTER READ             61640000
         B     TXTREAD                                                  61680000
BUFENTA1 LR    GR1,GR8     SET UP A PARA FOR OBJ INPUT                  61720000
         B     TXTINSRT                                                 61760000
BUFENT4  OI    HOLD1+2,DENSE                                            61800000
         LH    R0,HOLD+6           UPDATE DISP                          61840000
         A     R0,UT1SIZE                                               61880000
         STH   R0,HOLD+6                                                61920000
         LA    GR8,7(GR8)                                               61960000
         MVC   0(2,GR8),HOLD+6     INSERT DISPLACEMENT IN NEXT ENTRY    62000000
         S     XS2,UT1SIZE                                              62040000
         C     XS2,UT1SIZE                                              62080000
         BC    10,BUFENT6           HIGH OR EQU                         62120000
         MVC   HOLD+2(2),DISPLAC+2 MOVE APPROPRIATE LENGTH              62160000
         B     BUFENT5              INTO HOLD AREA                      62200000
BUFENT6  MVC   HOLD+2(2),UT1SIZE+2                                      62240000
         B     BUFENT5                                                  62280000
*                                                                       62320000
*                                                                       62360000
BUFDEN   MVC   0(2,GR8),CDISP   WILL ONLY BE THRU HERE ONCE             62400000
         OI    HOLD1+2,DENSE      MARK WORK AREA DENSE FOR ENTRY        62460000
         L     R0,BUFSTART           MUST REESTABLISH THE               62480000
         AH    R0,CDISP         FROMAD FOR THE PURGE    TXTNIO          62500000
         ST    R0,FROMAD           THIS WILL BE THE STARTING ADDR       62520000
         TM    APT1,EX     CAN BE A LOAD WHEN CONFIG REQUIRES THAT A    62540000
         BC    1,BUFDEN1         ID BE READ BUT WILL NOT FIT IN BUFFER  62560000
*       BUT HAS BEEN ALLOCATED - CAUSED BY GROUPED INPUT                62580000
         ST    GR4,HOLD                                                 62640000
         AR    R0,GR4                                                   62720000
         ST    R0,TOADDR                                                62760000
         LH    XP1,CDISP                                                62800000
         AR    XP1,GR4    WILL PIECE EXTEND BEYOND MYLT                 62840000
         C     XP1,MULTSIZE     NO   BRANCH                             62880000
         BC    12,BUFENTA                                               62920000
         SR    XP1,GR4     OBTAIN TRUE ADDR THAT WILL FIT               62960000
         LNR   XP1,XP1                                                  63000000
         A     XP1,MULTSIZE                                             63040000
         ST    XP1,HOLD                                                 63080000
         ST    XP1,TOADDR     CHANGE TO ADDR TO PREVENT LATTER MATCH    63120000
         B     BUFENTA                                                  63160000
BUFDEN1  SH    R0,CDISP                REALIGN                   A30147 63210021
         ST    R0,FROMAD               FROM ADDR                 A30147 63260021
         B     BUFENTA                                                  63320000
* THE TXT IS ADDED IN THE BUFFER AS THE LAST STEP - SPACE HAS BEEN      63400000
*  ALLOCATED IF NECESSARY AND RECORDED IN THE TXTIOT AND TXT NOTE LIST  63440000
*        REG1 WILL CONTAIN THE APPROP NOTE LIST ADDR                    63480000
*                                                                       63520000
TXTINSRT LH    R0,CDISP       TEST IF END OF PIECE WILL EXCEED          63560000
         ST    GR1,LASTTNT        SAVE NOTE LIST ADDR                   63600000
         AR    R0,GR4             MULTIPLICITY BOUNDRY                  63640000
         C     R0,MULTSIZE                                              63680000
         BC    2,TXTSPLT      BRANCH IF SPLITTING NECESSARY             63720000
         BAL   RLK,TXTMOVE                                              63760000
         B     TXTRET                                                   63800000
*                                                                       63840000
TXTMOVE  MVC   HOLD+1(3),2(GR1)    OBTAIN BUFFER ADDR                   63880000
         L     GR1,HOLD                                                 63920000
         AH    GR1,CDISP                                                63960000
         BCTR  GR4,0               DECREMENT LENGTH                     64000000
         EX    GR4,TXTMVE          MOVE  INTO  BUFFER                   64040000
         LA    GR4,1(GR4)          RESET LENGTH                         64080000
         BR    RLK                                                      64120000
*                                                                       64160000
TXTMVE   MVC   0(1,GR1),0(RIP)                                          64200000
*                                                                       64240000
TXTSPLT  LR    GR8,GR4      THE TXT HAS SPANNED TEO MULTIPLICITIES      64280000
         L     GR4,MULTSIZE      MOVE AS MUCH AS WILL FIT               64320000
         SH    GR4,CDISP         READJUST PARAMETERS AND REENTER        64360000
         BAL   RLK,TXTMOVE                                              64400000
         SR    GR8,GR4        UPDATE LOCATION                           64440000
         AR    RIP,GR4       -UPDATE LOCATION                           64480000
         LR    GR4,GR8           RESTORE LINGTH                         64520000
         LA    R0,1                                                     64560000
         AH    R0,CMULN                                                 64600000
         STH   R0,CMULN       UPDATE MULTIPLICITY                       64640000
         SR    R0,R0          AND                                       64680000
         STH   R0,CDISP       ZERO DISPLACEMENT                         64720000
         B     TXT002A                                                  64760000
*                                                                       64800000
* TXTEND - EOF RECEIVED - IF NOLENGTH CSECT - LENGTH MUST BE POSTED     64840000
*         AT THIS TIME -  ALSO THE BUFFER MUST BE CLEANED IF NECESSARY  64880000
*                                                                       64920000
TXTEND   TM    SWITCH,DENSE1                                            64960000
         BC    14,TXTENDA                                               65000000
         L     XS1,TNTFREE             OBTAIN LAST NOTELIST             65040000
         SH    XS1,TSEVEN         ADDR FOR TXTNIO                       65080000
         BAL   XP2,TXTNIO                                               65120000
         NI    SWITCH,X'BF'        CLEAN UP DENSE SW                    65160000
TXTENDA  TM    SWITCH,NOLEN                                             65200000
         BC    14,TXTEND1   BRANCH IF NOT NOLENGTH                      65240000
         OI    SWITCH,NOLEN1      NOLENGTH CLEANUP                      65280000
         ST    RLK,RETURNAD       SAVE RETURN ADDR                      65320000
         B     TXTN1                                                    65360000
TXTENDNL NI    SWITCH,X'EF'         TURN OFF CLEAN UP                   65400000
         L     RLK,RETURNAD      RESTORE RETURN ADDR                    65440000
TXTEND1  L     GR1,TXTIO    TEST FIRST ENTRY TXTIO TABLE TO SEE         65480000
         TM    2(GR1),INCORE         IF IT HAS BEEN WRITTEN OUT         65520000
         BC    1,TXTEND2A    NO   TEST IF OVERLAY IS SPECIFIED          65560000
TXTEND1A ST    RLK,RETURNAD        SAVE RETURN ADDR                     65600000
         BAL   RLK,TXTBUF2    CLEAR TXTBUFFER                           65640000
         L     RLK,RETURNAD      RESTORE RETURN ADDR                    65680000
TXTEND2  SR    R0,R0                                                    65720000
         STH   R0,SWITCH     CLEAN UP  SWITCH FOR NEXG INTERATION  101  65740000
         ST    R0,BUFDISP    CLEAR BUFFER DISP                          65760000
         STH   R0,PID           MADE RAT REENTERABLE                    65800000
         STH   R0,TXTNOTE          REINITIALIZE TO ZER/                 65840000
         STH   R0,TXTWR     CLEAR NUMBER OF ENTRIES WR IN TXTIO         65880000
         BR    RLK                                                      65920000
TXTEND2A TM    PDSE7,X'20'        IF OVLY SPEC  MUST FORCE              65960000
         BC    1,TXTEND1A          2 PASS SITUATION                     66000000
         TM    SWITCH+1,NOGRPPG      IS A NONGROUPED PURGE REQUIRED101  66010000
         BC    1,TXTEND1A          YES  BRANCH TO PURGE            101  66020000
         B     TXTEND2                                                  66040000
*THIS ROUTINE  WILL CHECK IF THE NEW DENSE PIECE IS CONTIGUOUS WITH     66080000
* THE EXISTING  DENSE RECORD IN THE BUFFER                              66120000
*   IF IT IS IT WILL BE ADDED                                           66160000
*  -IF NOT-  THE EXISTING PIECE WILL BE WRITTEN AND NEW ONE ADDED       66200000
*              KNOW ID AND MULT ARE SAME AS PREVIOUS                    66240000
*                                                                       66280000
TXTDEN   L     XS1,TNTFREE     IF A DENSE RECORD PRESENT IT WILL ALWAYS 66320000
         SH    XS1,TSEVEN    BE THE LAAT ENTRY  CORRECT TNT1 ADDR       66360000
         MVC   HOLD+1(3),2(XS1) OBTAIN BUFFER ADDR                      66400000
         L     GR9,HOLD                                                 66440000
         AH    GR9,CDISP       GR9 CONTAINS WHERE NEW PIECE WOULD BEGIN 66480000
         L     GR1,TOADDR                                               66520000
         CR    GR9,GR1         PIECE                                    66560000
         BC    8,TXTDEN1      IF EQU NEW CAN BE ADDED AFTER OLD AFTER   66600000
*                             FIRST ENSURING LENGTH WON'T EXCEED MULT   66640000
         AR    GR9,GR4                                                  66680000
         C     GR9,FROMAD      PIECE WE WISH TO ADD EQ BEGINNING OF OLD 66720000
         BC    7,TXTDEN2      NO BRANCH                                 66760000
         SR    GR9,GR4                                                  66800000
         ST    GR9,FROMAD     AND INCREMENT LENGTH                      66840000
         MVC   0(2,XS1),CDISP      DD OF PIECE                          66880000
         LR    R0,GR4                                                   66920000
TXTDENA1 MVC   HOLD+2(2),5(XS1) RETRIEVE OLD LENGTH                     66960000
         AH    R0,HOLD+2                                                67000000
         STH   R0,HOLD+2        ADD ADDITIONAL                          67040000
         MVC   5(2,XS1),HOLD+2                                          67080000
         LR    GR1,XS1         SET UP PARA FOR TXTINSRT                 67120000
         B     TXTINSRT                                                 67160000
* THE TXT IS TO BE ADDED BEHIND PRESENT PIECE - MUST CHECK FIRST TO     67200000
*  ENSURE DOESN'T EXCEED MULT BOUNDRIES                                 67240000
TXTDEN1  LH    GR9,CDISP                                                67280000
         AR    GR9,GR4                                                  67320000
         LR    R0,GR4                                                   67360000
         L     GR1,TOADDR          BRANCH IF ALL FIT -                  67400000
         AR    GR1,GR4        SIMPLY INCREASE LENGTH                    67440000
         ST    GR1,TOADDR                                               67480000
         C     GR9,MULTSIZE                                             67520000
         BC    12,TXTDENA1                                              67560000
         SR    GR9,GR4            IF EXCEEDS MULT LIMIT - ENTER SIZE    67600000
         LNR   GR9,GR9             THAT WILL FIT - INSERT ROUTINE WILL  67640000
         A     GR9,MULTSIZE        TAKE CARE OF OVERLAP                 67680000
         LR    R0,GR9         SET UP REG ZERO WITH CORRECT LEN          67700000
         B     TXTDENA1                                                 67720000
*                                                                       67760000
*THE TXT WAS NOT CONTIGUOUS  -  WILL WRITE OUT EXISTING PIECE           67800000
*                                                                       67840000
TXTDEN2  LA    XP2,BUFALLOC                                             67880000
         B     TXTNIO                                                   67920000
*                                                                       67960000
* THIS ROUTINE  IS USED WHENEVER A  SECTION OF OUT OF ORDER TEXT IS TO  68000000
*   BE WRITTEN OUT  -  IT WILL MAKE ADDITIONAL ENTRIES IF SIZE OF       68040000
*   PIECE EXCEEDS UT1                                                   68080000
*                                                                       68120000
TXTNIO   LR    GR8,XS1                                                  68160000
         ST    XRET2,HOLD3    RESERVE REG5                              68200000
         L     GR1,TXTFREE    CHECK IF LAST ENTRY HAS ALREADY BEEN      68240000
         SH    GR1,SFOUR      WRITTEN  CAN HAPPEN IN ISOLATED           68280000
         TM    2(GR1),DENSE      WAS THE LAST ENTRY MADE DENSE          68320000
         BCR   8,XP2       IF NOT  RETURN IMMEDIATLY                    68360000
         TM    2(GR1),INCORE       HAS THE LAST DENSE ENTRY             68400000
         BCR   8,XP2     WRITTEN  --     YES RETURN                     68440000
         L     XS2,FROMAD                                               68480000
TXTNIOA  MVC   HOLD+2(2),5(GR8)    RETRIEVE  LENGTH                     68520000
         LH    XS1,HOLD+2       IF PIECE SIZE EXCEEDS UT1 - BRANCH      68560000
         CH    XS1,UT1SIZE+2                                            68600000
         BC    2,TXTNI1                                                 68640000
         BAL   XRET2,COMBUF                                             68680000
         BAL   XRET2,COMCHK                                             68720000
         ST    GR1,HOLD                                                 68760000
         MVC   2(3,GR8),HOLD      RECORD TTR                            68800000
         TM    APT1,EX    IS THIS A LOAD MODULE                         68810000
         BC    1,TXTNIOB                                                68820000
         L     R0,BUFDISP                                               68840000
         S     R0,MULTSIZE                                              68880000
         ST    R0,BUFDISP         FREE ALLOC BUFFER AREA                68920000
TXTNIOB  LA    R0,4        SET TO DECREMENT TO LAST TXTIO ENTRY         68960000
         L     GR1,TXTFREE                                              69000000
         SR    GR1,R0                                                   69040000
         NI    2(GR1),FLAGOUT      ZERO FLAG FIELD                      69080000
         OI    2(GR1),TTRDEN                                            69120000
         L     XRET2,HOLD3   PRESERVE REG5                              69160000
         BR    XP2                                                      69200000
TXTNI1   L     GR1,TXTFREE        MAKE ADDITIONAL ENTRY                 69240000
         LA    R0,4                                                     69280000
         SR    GR1,R0                                                   69320000
         MVC   4(4,GR1),0(GR1)                                          69360000
         MVC   5(2,GR8),UT1SIZE+2     INSERT UT1 LENGTH                 69400000
         S     XS1,UT1SIZE                                              69440000
         STH   XS1,HOLD1+4        NEW LENGTH                            69480000
         MVC   HOLD1+1(3),2(GR8)     OBTAIN BUFFER ADDR                 69520000
         MVC   HOLD1+6(2),0(GR8)         AND THE DISPLACEMENT           69560000
         LA    R0,1                THE LENGTH OF THE ENTRY EXCEEDS      69600000
         AH    R0,ENT1C       UT1 -  FIRST MAKE EXTRA TABLE             69640000
         CH    R0,ENT1X       ENTRIES                                   69680000
         BC    12,TXTN3                                                 69720000
         STM   XS1,XS2,SPACES                                           69760000
         BAL   RLK,TXTBUF1     PURGE AVOIDING DENSE CHECK               69800000
         SR    RLK,RLK   ZERO BUFFER DISPLACEMENT AFTER                 69840000
         ST    RLK,BUFDISP    PURGING BUFFER                            69880000
         BAL   RLK,BUFTMK2                                              69920000
         LM    XS1,XS2,SPACES                                           69960000
         B     TXTN2                                                    70000000
TXTN3    L     XS1,UT1SIZE         CORRECT LENGTH FOR FIRST WRITE       70040000
         NI    2(GR1),FLAGOUT      ZERO FLAG FIELD                      70080000
         OI    2(GR1),TTRDEN                                            70120000
         BAL   XRET2,COMBUF                                             70160000
         BAL   XRET2,COMCHK                                             70200000
         ST    GR1,HOLD                                                 70240000
         MVC   2(3,GR8),HOLD      STORE TTR                             70280000
TXTN2    L     GR8,TNTFREE                                              70320000
         LH    GR1,HOLD1+6                                              70360000
         A     GR1,UT1SIZE                                              70400000
         STH   GR1,HOLD1+6                                              70440000
         MVC   0(2,GR8),HOLD1+6                                         70480000
         MVC   2(5,GR8),HOLD1+1                                         70520000
         BAL   GR1,TXTPTR                                               70560000
         LH    XS2,HOLD1+6                                              70580000
         A     XS2,HOLD1         RESET STARTING ADDR                    70600000
         LA    XS2,0(XS2)                                               70620000
         B     TXTNIOA        REENTER CHECKING NEWLY CREATED ENTRY WITH 70640000
*                        DECREMENTED LENGTH                             70680000
*                                                                       70720000
TXTPTR   LA    R0,1                                                     70760000
         AH    R0,ENT1C                                                 70800000
         STH   R0,ENT1C                                                 70840000
         LA    R0,4                                                     70880000
         AH    R0,ENTOC                                                 70920000
         STH   R0,ENTOC                                                 70960000
         LA    R0,4                                                     71000000
         A     R0,TXTFREE                                               71040000
         ST    R0,TXTFREE                                               71080000
         LA    R0,7                                                     71120000
         A     R0,TNTFREE                                               71160000
         ST    R0,TNTFREE                                               71200000
         BR    GR1                                                      71240000
*                                                                       71280000
* LOAD MODULE PROCESSOR                                                 71320000
*                                                                       71360000
*      FIRST STEP IS TO DETERMINE IF ALL ID'S ARE TO BE DELETED         71400000
*       IF SO - READ WILL BE ISSUED WILL ZERO LENGTH                    71440000
TXTLM    LA    READCNT,1    SET UP PARA FOR ZERO READ                   71480000
         NI    SWITCH+1,SPTXTOFF       RESET SPEC TXT FLAG      SA56444 71490021
         L     REG6,RLDINPAD   INITIALIZE ID-LENGTH PTR                 71520000
         L     COUNT,12(REG6)      COUNT SET FOR TOTAL INPUT            71560000
         LA    COUNT,0(COUNT)     CLEAR THE HIGH ORDER BYTE             71600000
         ST    COUNT,LMLEN         SAVE INPUT RECORD LENGTH             71640000
         LH    R0,4(REG6)                                               71680000
         AH    REG6,6(REG6)                                             71720000
         LA    REG6,16(REG6)                                            71760000
         ST    REG6,IDLENPTR                                            71800000
         AR    R0,REG6                                                  71840000
         ST    R0,CREND  INIT ID-LENGTH LIST END PTR                    71880000
         LR    RID1,RID       CALCULATE RENUMBER                        71920000
TXTLM1   SLL   RID1,2          ENTRY                                    71960000
         A     RID1,RECNT                                               72000000
         TM    DT(RID1),DEL    IS THIS ID TO BE DELETED                 72040000
         BC    7,TXTLM1A          CONTINUE SEARCH IF DELETE             72080000
         OI    SWITCH,READSW         INDICATE READ IS REQUIRED          72120000
         B     TXT0011                                                  72480000
TXTLM1A  LA    RIP,4(RIP)          ONTINUE SEARCH                       72520000
         C     RIP,CREND     WAS THAT THE LAST ONE                      72560000
         BC    10,READ0                                                 72600000
         LH    RID1,0(RIP)                                              72640000
         B     TXTLM1                                                   72680000
READ0    OI    SWITCH,SHORTRD      ALL ITEMS IN THIS RECORD ARE TO BE   72720000
*      DELETED                                                          72760000
         LA    BUFFADDR,HOLD1        BUMMY AREA FOR ARTIFICAL           72800000
         B     READ0A          READ                                     72840000
TXTREAD  LR    READCNT,COUNT        SET UP COUNT FOR READ               72880000
         ST    XS2,TXTALLOC                                             72920000
         L     BUFFADDR,BUFSTART                                        72960000
         AH    BUFFADDR,CDISP         COMPUTE CORRECT LOCATION          73000000
         TM    SWITCH,DENSE1           IS THIS RECORD DENSE      A33791 73001021
         BC    8,READ0B                NO, BRANCH                A33791 73002021
         SH    BUFFADDR,CDISP          YES,RESET BUFR START ADDR A33791 73003021
READ0B   NI    SWITCH,READOFF          ALL SET TO READ           A33791 73033021
READ0A   L     DCBADD,IEWLCLAC      ADDR OF CURRENT READ BLOCK          73080000
         L     DCBADD,0(DCBADD)           ADDR OF DECB FOR THE READ     73120000
         L     REG6,INPADD         ESTABLISH  BASE FOR READ             73160000
         L     XP2,RDMACRO                                              73200000
         LR    COUNT,TXTBASE     REG4 WILL HOLD BASE UNTIL RETURN       73240000
         BALR  XSTX,XP2                                                 73280000
         LR    TXTBASE,COUNT                                            73320000
         TM    SWITCH,SHORTRD       A SHORT READ TO BE ISSUED           73360000
         BC    14,TXTGREAD        NO  BRANCH                            73400000
         NI    SWITCH,SHORTRD1      RESET SWITCH                        73440000
         B     TXTRET                                                   73480000
TXTGREAD L     COUNT,IDLENPTR                                           73520000
         LH    RID,0(COUNT)   MUST RESTOTE ID                           73560000
         LH    COUNT,2(COUNT)                                           73600000
         SR    GR1,GR1      PREPARE TO ZERO ACCUNLEN                    73640000
         ST    GR1,ACUMLEN                                              73680000
         L     XS2,TXTALLOC       OBTAIN AMOUNT OF BUFFER ALLOC         73720000
         BR    GR3                                                      73760000
*                                                                       73800000
*   ID IS TO BE DELETED                                                 73840000
*                                                                       73880000
TXTLM2   TM    APT1,EX                                                  73920000
         BC    8,TXTRET     RETURN FOR OBJECT MODULES                   73960000
         TM    SWITCH,READSW       HAS THE READ BEEN ISSUED             74000000
         BC    8,TXTLM2A       YES  BRANCH                              74040000
         TM    SWITCH,NOLEN      IS A NOLEN OUTSTANDING                 74050000
         BC    14,TXTLM2C          NO -  AVOID NOLEN CLEAN UP           74060000
         OI    SWITCH,X'20'            SET FLAG TO RETURN               74070000
         B     TXTN1          START NOLEN CLEAN UP                      74080000
TXTLM2D  NI    SWITCH,X'DF'          RESET INCICATOR                    74090000
TXTLM2C  L     GR3,BUFDISP         SET TO DO THE READ                   74100000
         A     GR3,TXTBFBEG            NEW                              74120000
         ST    GR3,BUFSTART            BEFSTART                         74160000
         SR    GR3,GR3                                                  74200000
         STH   GR3,CDISP               CLEAR DISP                       74240000
         L     R0,TXTBFBEG       ESTABLISH BEGINNING OF TXTBUF          74246000
         A     R0,BUFDISP        AND OBTAIN THE FIRST FREE AREA         74252000
         AR    R0,COUNT        AND ADD TOTAL LENGTH OF INPUT RECORD     74258000
         C     R0,TXTBFEND       WILL IT OVERFLOW BUFFER                74264000
         BC    12,TXTLM2B         BRANCH IF IT WILL FIT                 74270000
         BAL   RLK,TXTBUF      PURGE THE TXTBUF                         74276000
         SR    RLK,RLK         AND ZERO THE BUFFER DISPLACEMENT         74282000
         ST    RLK,BUFDISP                                              74288000
         L     RLK,TXTBFBEG       MUST RESET BUFSTART TO THR BEG        74294000
         ST    RLK,BUFSTART        OF THE BUFFER TO POSITION READ       74300000
TXTLM2B  BAL   GR3,TXTREAD          NOW DO THE READ BEFORE COMTINUING   74306000
TXTLM2A  L     RLK,IDLENPTR                                             74320000
         LR    XS1,RLK                                                  74360000
         LA    RLK,4(RLK)                                               74400000
         C     RLK,CREND    IF THIS IS THE LAST ID  THERE IS NO NEED    74440000
         BC    10,TXTRET    TO MOVE THE REMAINING BUFFER ENTY UP        74480000
         LH    XS1,2(XS1)   XS1 CONTAINS LENGTH TO BE DELETED           74520000
         LNR   XP1,XS1                                                  74560000
         A     XP1,LMLEN    XP1 CONTAIN AMOUNT OF TXT IN BUFFER TO BE   74600000
         L     GR8,BUFDISP  MOVED                                       74640000
         A     GR8,TXTBFBEG                                             74680000
         LR    RLK,GR8                                                  74720000
         AR    RLK,XS1      FROMAD                                      74760000
         BAL   XP2,LMMOVE                                               74800000
         B     TXTLM4                                                   74840000
* THIS RTN WILL BE USED TO OVERLAY DELETED ID'S IN THE BUFFER AND       74880000
*  MOVE ANY REMAINING TXT IN THE BUFFER TO THE BEGINNING IF A FULL      74920000
*  MULTIPLICITY CAN NOT BE ALLOCATED                                    74960000
*                                                                       75000000
* INCOMING PARAMETERS ARE     GR8  - TO ADDR                            75040000
*                             GR9  - FROMAD                             75080000
*                             XP1  - AMOUNT TO BE MOVED                 75120000
LMMOVE   LA    GR1,256        SET UP TEST COUNT                         75160000
LMMOVE3  CR    GR1,XP1        IF THE INCOMING COUNT IS LESS THAN THAT   75200000
         BC    10,LMMOVE1    WE ONLY HAVE ONE MOVE                      75240000
         MVC   0(256,GR8),0(RLK)    MOVE COUNT                          75280000
         SR    XP1,GR1      AND THE PARAMETERS ADJUSTED ACCORDINGLY     75320000
         AR    GR8,GR1         INCREMENT TO AND FROM ADDRESSES          75360000
         AR    RLK,GR1                                                  75400000
         B     LMMOVE3                                                  75440000
LMMOVE1  BCTR  XP1,0                                                    75480000
         EX    XP1,TLMMVE                                               75520000
LMMOVE2  BR    XP2                                                      75560000
*                                                                       75600000
TLMMVE   MVC   0(1,GR8),0(RLK)                                          75640000
*                                                                       75680000
* ID & MULT AGREE WITH LAST - THIS MULT HAS BE ALLOCATED BUT IF LENGTH  75720000
*     EXCEEDS PRESENT BUFFER BOUNDRIES - ANOTHER MUST BE ALLOC          75760000
*                                                                       75800000
TXTLM3   NI    SWITCH,X'BF'   INSURE DENSE SW IS OFF                    75820000
         SH    GR1,SFOUR     OBTAIN LAST TXTIO ADDR                     75840000
         TM    2(GR1),INCORE    HAS THAT ENTRY BEEN WRITTEN             75880000
         BC    1,TXTLM3A         BRANCH IF STILL IN CORE                75920000
TXTLM3D  OI    SWITCH,DENSE1    MARK ENTRY OUT OF ORDER                 75960000
         B     BUFALLOC       AND ALLOC AND ENTER IN TABLES             76000000
TXTLM3A  L     R0,BUFSTART        CHECK IF RECORD WILL FIT IN BUFFER    76007000
         AH    R0,CDISP          ADD THE BUFFER START AND THE DISP      76014000
         AR    R0,COUNT        AND THE LENGTH OF THE INCOMING RECORD    76021000
         C     R0,TXTBFEND        DIES THE INCOMING RECORD EXCEED       76028000
         BC    12,TXTLM3C        BUFFER LIMITS                          76035000
         BAL   RLK,TXTBUF                                               76042000
         SR    RLK,RLK     PURGE AND RESET BUFFER INCREMENT             76049000
         ST    RLK,BUFDISP        TO ZERO                               76056000
         B     TXTLM3D    SINCE JUST PURGED MUST MARK OUT OF ORDER      76063000
TXTLM3C  BAL   GR3,TXTREAD       READ THJ LOAD MOD INPUT RECORD         76070000
         LH    GR8,CDISP           WILL THIS INPUT EXCEED MUL           76080000
         AR    GR8,COUNT                                                76120000
         C     GR8,MULTSIZE                                             76160000
         BC    12,TXTLM4      BRANCH ON LOW OR EQUAL                    76200000
*  IT IS NECESSARY TO READJUSNT TO THE TRUE AMOUNT THAT                 76208000
*         MUST BE ALLOCATED                                             76216000
         S     GR8,MULTSIZE         CDISP+COUNT-MULTSIZE IS             76224000
         LR    COUNT,GR8      THE TRUE AMOUNT LEFT TO ALLOC             76232000
         LH    GR9,CMULN                                                76240000
         LA    GR9,1(GR9)     BUMP MULT                                 76280000
         STH   GR9,CMULN      AND ALLOCATE SPACE IN BUFFER              76320000
         STH   GR9,PMULN          UPDATE TO CHECK NEXT ENTRY            76360000
         B     BUFALLOC                                                 76400000
*                                                                       76440000
* THE PRESENT ENTRY HAS BEEN FULLY PROCESSED - IF THAT WAS LAST ENTRY   76480000
*  WE WILL RETURN - IF NOT WE WILL READJUST PARAMETERS AND REENTER      76520000
*                                                                       76560000
TXTLM4   L     GR8,IDLENPTR                                             76600000
         LR    GR9,GR8                                                  76640000
         LA    GR8,4(GR8)     BUMP IDLENPTR AND SEE                     76680000
         C     GR8,CREND      IF PAST END OF CONTROL RECORD             76720000
         BC    10,TXTRET    BRANCH HIGH OR EQY                          76760000
         LH    GR9,2(GR9)     PICK UP NEXT LENGTH                       76800000
         LR    GR1,GR9                                                  76840000
         LNR   GR1,GR1                                                  76880000
         A     GR1,LMLEN                                                76920000
         ST    GR1,LMLEN                                                76960000
         A     GR9,ACUMLEN                                              77000000
         ST    GR9,ACUMLEN                                              77040000
         L     XAA,RLDINPAD   NOW OBTAIN ASSM OF THIS ID                77080000
         L     XAA,8(XAA)                                               77120000
         LA    XAA,0(XAA)                                               77160000
         AR    XAA,GR9                                                  77200000
         ST    GR8,IDLENPTR        KEEP UPDATED IDLENPTR                77240000
         LH    COUNT,2(GR8)        OBTAIN NEW LENGTH                    77280000
         LH    RID,0(GR8)           AND ID                              77320000
         B     TXT0011                                                  77360000
* ONE MULTIPLICITY HAS BE ALLOCATED - TEST IF THERE IS MORE PRESENTLY   77400000
* IN THE BUFFER THAT MUST BE ALLOCATED AND ENTERED IN TABLES            77440000
*                                                                       77480000
TXTLM5   TM    SWITCH+1,SPTXTON        CHECK FOR SPEC TEXT      SA56444 77490021
         BNO   TXTLM5A                 BRANCH IF NOT APPLIC     SA56444 77500021
         NI    SWITCH+1,SPTXTOFF       SET FLAG OFF             SA56444 77510021
         AH    COUNT,CDISP             ADJUST FOR TEXT DISPLAC  SA56444 77512021
TXTLM5A  SR    COUNT,XS2      SUBTRACT ALLOCATED SIZE FROM LENGTH       77520021
         BNP   TXTLM4      BRANCH ON ZERO OR LESS CHECK NEXT ID         77600021
         LH    GR9,CMULN                                                77640000
         LA    GR9,1(GR9)     IF NOT FINISHED WITH THIS ID - BUMP MULT  77680000
         STH   GR9,CMULN      AND REALLOCATE                            77720000
         STH   GR9,PMULN          UPDATE TO CHECK NEXT ENTRY            77760000
         B     TXT002A                                                  77800000
*AN ENTRY IS TO BE MADE IN THE TXT I/O CONTROL TABLE. UNLESS IT IS FULL 77840000
BUFTMK2  TM    IOCTSTAT,FULLT    IS TXT I/O CNTL TABLE FULL             77880000
         BC    8,BUFTOK                                                 77920000
*TABLE IS FULL. ERROR                                                   77960000
         LA    R0,ERRTM                                                 78000000
         B     ERROR                                                    78040000
BUFTOK   LA    R14,7                                                    78080000
         MH    R14,ENT1X                                                78120000
*R14=NUMBER OF BYTES IN NOTE LIST.                                      78160000
         L     R15,TNT1           R15=START OF MARK LIST                78200000
         BAL   XRET2,COMBUF                                             78240000
         BAL   XRET2,COMCHK                                             78280000
         LA    XTMK2,IOCT                                               78320000
         LR    XS1,XTMK2                                                78360000
         AH    XTMK2,ENITC                                              78400000
*STORE THE TTR IN THE CURRENT ENTRY OF THE TXT I/O CONTROL TABLE        78440000
         ST    GR1,0(XTMK2)   STORE TTR OF TXT NOTE LIST                78480000
         LA    XTMK2,4(XTMK2)                                           78520000
         SR    XTMK2,XS1                                                78560000
*THE UPDATED BYTE COUNT IS NOW STORED                                   78600000
         STH   XTMK2,ENITC        STORE BYTE COUNT                      78640000
         LH    R0,ENT1C       KEEP TRACK OF ACTURL ENTERIES             78680000
         AH    R0,TXTNOTE    WRITTEN                                    78720000
         STH   R0,TXTNOTE                                               78760000
*TEST FOR OVERFLOW                                                      78800000
         CLI   ENITC+1,MCT        IS TEXT I/O TABLE FULL                78840000
         BC    4,TXT017    NO,CONTINUE                                  78880000
         OI    IOCTSTAT,FULLT    INDICATE TXT I/O CNTL TABLE IS FULL    78920000
*                          CAN NOT BE PURGED AGAIN                      78960000
TXT017   SR    R0,R0                                                    79000000
         STH   R0,ENT1C  RESET TXT NOTELIST CURRENT BYTE COUNT TO ZERO  79040000
         L     R0,TNT1            RESET INTERNAL POINTER                79080000
         ST    R0,TNTFREE                                               79120000
         BCR   15,RLK                                                   79160000
*                                    PROCESSED CSECTS IN BUFFER         79200000
*                                                                       79240000
* THIS ROUTINE WILL CLEAR THE BUFFER AND MARK ENTRIES WRITTEN*          79280000
*                                                                       79320000
TXTBUF   TM    NEWSW,EOF        IS THIS END OF INPUT                    79360000
         BC    1,TXTEND                                                 79400000
         LTR   COUNT,COUNT    ZERO LENGTH IS IGNORED                    79440000
         BCR   8,RLK                                                    79480000
TXTBUF2  TM    SWITCH,DENSE1      FIRST CHECK IF LAST THISG IN BUFFER   79520000
         BC    14,TXTBUF1         IS A PIECE OF OUT OF ORDER TEXT       79560000
         L     XS1,TNTFREE                                              79600000
         SH    XS1,TSEVEN      SET UP PARAMETER FOR TXTNIO              79640000
         BAL   XP2,TXTNIO         WRITE IT AND RET                      79680000
         NI    SWITCH,X'BF'                                             79720000
TXTBUF1  CLC   TXTWR(2),ENTOC     ANYTHING IN TABLE                     79760000
         BCR   8,RLK                                                    79800000
         STM   RID,REG6,HOLD3         MUST MAINTAIN REGS 5 AND 6        79840000
         TM    PDSE7,X'20'        OVERLAY OPTION SPECIFIED              79880000
         BC    1,TXTENT1          WRITE ON E RECORD PER ENTRY           79920000
         CLC   MULTSIZE(4),UT1SIZE                                      79960000
         BC    2,TXTENT1          BRANCH MULT HIGH                      80000000
         TM    SWITCH,NOLEN        IS THERE AN OUTSTANDING NOLEN TO     80010000
         BC    1,TXTENT1     BE POSTED   YES   WE CAN NOT GROUP         80020000
         TM    SWITCH+1,NOGRPPG       DO WE NEED A NON GROUPED PURGE101 80026000
         BC    1,TXTENT1      YES  PURGE WITHOUT GROUPING          101  80032000
*                                                                       80040000
*   AFTER HERE SYSUT1 WILL BE GROUPED AS MUCH AS POSSIBLE               80080000
*                                                                       80120000
*                                                                       80160000
*                                                                       80200000
         LH    REG6,ENTOC    REG6 WILL BE USED TO PROVIDE LIMIT         80240000
         A     REG6,TXTIO                                               80280000
         ST    REG6,TSCNEND    SAVE END ADDR                            80320000
         LH    REG6,TXTWR    BYTES WRITTEN IN TXTIO                     80360000
         LR    GR8,REG6        TO TXTIO ENTRY                           80400000
         SRL   GR8,2                                                    80440000
         SH    GR8,TXTNOTE        SUB NUMBER OF ENTERIES WRITTEN        80480000
TXTB2A   A     REG6,TXTIO    NOW REGS XSTX AND GR8 CONTAIN EFFECTIVE    80520000
         MH    GR8,TSEVEN                                               80560000
         A     GR8,TNT1       ADDR OF ENTRIES TO BE WRITTEN             80600000
TXTB2    TM    2(REG6),INCORE                                           80640000
         BC    1,TXTB1                                                  80680000
         LH    GR1,TXTACUM        HIT OUT OF ORDER                      80720000
         LTR   GR1,GR1           CLEAR PREVIOUS GROUPING IF NEC         80760000
         BC    7,TXTBWR             OR ADVANCE TO ENEXT                 80800000
TXTB2C   LA    REG6,4(REG6)   BUMP PTRS TO NEXT ENTRY                   80840000
         LA    GR8,7(GR8)                                               80880000
         C     REG6,TSCNEND                                             80920000
         BC    10,TXTBEND                                               80960000
         B     TXTB2                                                    81000000
*                                                                       81040000
TXTB1    NI    2(REG6),X'7F'  MARK THIS ENTRY NOT IN CORE               81080000
         LH    GR1,TXTACUM    HAVE WE STARTED A GROUPING                81120000
         LTR   GR1,GR1                                                  81160000
         BC    7,TXTB3        YES - BRANCH                              81200000
         MVC   HOLD+2(2),5(GR8)   PARAMETER FOR WRITE                   81240000
         LH    XS1,HOLD+2      ACQUIRE LENGTH                           81280000
         MVC   HOLD+1(3),2(GR8) AND                                     81320000
         L     XS2,HOLD             BUFFER ADDR                         81360000
TXTB1A   STH   XS1,TXTACUM                                              81400000
         B     TXTB2C                                                   81440000
*                                                                       81480000
*  GROUPING HAS STARTED - FIRST TEST WILL SEE IF ADDITIONAL LENGTH WILL 81520000
*    EXCEED LIMITS REGARDLESS OF ABILITY TO BE GROUPED - IF IT WOULD    81560000
*    FIT - THEN ELIGIBILITY IS TESTED                                   81600000
*                                                                       81640000
TXTB3    MVC   HOLD+2(2),5(GR8)    ADD NEW LENGTH TO ACUM LENGTH        81680000
         AH    GR1,HOLD+2           AND TEST AGAINST UT1SIZE            81720000
         C     GR1,UT1SIZE                                              81760000
         BC    2,TXTBWR            WRITE PREVIOUS ENTRY                 81800000
         LA    R0,4                ADDITIONAL LENGTH WILL FIT - IS LAST 81840000
         SR    REG6,R0              MULT ZERO                           81880000
         MVC   HOLD(4),0(REG6)                                          81920000
         NI    HOLD+2,FLAGOUT                                           81960000
         LA    GR1,1        CONSECUTIVE                                 82000000
         A     GR1,HOLD      BUMP                                       82040000
         AR    REG6,R0      RESTORE PTR TO PRESENT TXTIO ENTRY          82080000
         C     GR1,0(REG6)    WAS LAST ONE GREATER THAN PRESENT         82120000
         BC    8,TXTB3A                                                 82160000
         CLC   2(2,REG6),CONZO1   IF PRESENT MULT=0  CHECK IF LAST      82200000
*                ENTRY IS LAST MULT                                     82240000
         BC    7,TXTBWR                                                 82280000
         SR    REG6,R0                                                  82320000
*  SINCE PRESENT ENTRY IS MULT ZERO  AND AFTER INSURING ID              82360000
*   NOT THE SAME   CHECK IF PREVIOUS ISLAST ONE                         82400000
         CLC   0(2,REG6),4(REG6)       ARET THE ID S THE SAME           82440000
         BC    8,TXTBWR1                                                82480000
         CLC   2(2,REG6),CONZO1    MULT CHANGE                          82490000
         BNE   TXTBWR1                                                  82500000
         LH    GR1,0(REG6)                                              82520000
         AR    REG6,R0          RESTORE TO PRESENT ENTRY                82560000
         SLL   GR1,4              WAS COMPLETE CSECT SO THE PRESENT     82600000
         A     GR1,CHESD          ENTRY CAN BE GROUPED WITH IT          82640000
         L     XP2,12(GR1)                                              82680000
         LA    XP2,0(XP2)     OBTAIN LENGTH FROM CESD                   82720000
         SR    XP1,XP1                                                  82760000
         D     XP1,MULTSIZE                                             82800000
         LTR   XP1,XP1                                                  82840000
         BC    7,TXTB4A                                                 82880000
         BCTR  XP2,0                                                    82920000
TXTB4A   CH    XP2,HOLD+2   HIGHEST MULT EQU LST                        82960000
         BC    7,TXTBWR                                                 83000000
TXTB3A   MVC   HOLD+2(2),5(GR8)   - UPDATE ACUM LENGTH                  83040000
         AH    XS1,HOLD+2                                               83080000
         B     TXTB1A                                                   83120000
*                                                                       83160000
*                                                                       83200000
TXTBEND  LH    GR1,ENTOC                                                83240000
         STH   GR1,TXTWR        UPDATE NUMBER OF BYTES WRITTEN          83280000
         LH    GR1,TXTACUM      BEFORE LEAVEING MUST WRITE ANY          83320000
         LTR   GR1,GR1             PARTIAL GROUPING                     83360000
         BC    8,TXTENTRT                                               83400000
         OI    SWITCH,X'01'       END SW                                83440000
         B     TXTBWR                                                   83480000
TXTBWR1  AR    REG6,R0      RESTORE PTR TO PRESENT TXTIO                83520000
TXTBWR   BAL   XRET2,COMBUF                                             83560000
         BAL   XRET2,COMCHK                                             83600000
         ST    GR1,HOLD          SAVE TTR IN LAST                       83640000
         LA    GR1,7               PROCESSED ENTRY                      83680000
         SR    GR8,GR1                                                  83720000
         MVC   2(3,GR8),HOLD      STORE TTR                             83760000
         AR    GR8,GR1                                                  83800000
         LA    R0,4      RESET R0                                       83840000
         SR    REG6,R0              AND                                 83880000
         OI    2(REG6),X'40'       TTR FLAG IN TXTIO                    83920000
         AR    REG6,R0                                                  83960000
         SR    GR1,GR1                                                  84000000
         STH   GR1,TXTACUM         NO LONGER GROUPING - THIS GROUP      84040000
         TM    SWITCH,X'01'            LAST WRITE SWITCH ON?     A34759 84070021
         BC    14,TXTENT2              NO, GO TEST DENSE SWITCH  A34759 84100021
         NI    SWITCH,X'FE'            YES, TURN THE SWITCH OFF  A34759 84130021
         B     TXTENTRT                RETURN                    A34759 84160021
TXTENT2  TM    2(REG6),DENSE           IS NEXT RECORD DENSE      A34759 84190021
         BC    1,TXTB2C                YES, SKIP IT              A34759 84220021
         B     TXTB1                   NO, PROCESS IT            A34759 84250021
TXTENT1  CLC   TXTWR(2),ENTOC     ONE RECORD PER ENTRY  LENGHT WILL     84320000
         BC    7,TXTENT11       BE UT1 OR ACTUAL WHICHEER               84360000
TXTENTRT LM    RID,REG6,HOLD3         MUST MAINTAIN REGS 5 AND 6        84400000
         BCR   15,RLK                                                   84440000
TXTENT11 LH    GR13,TXTWR                                               84480000
         LA    R0,4                                                     84520000
         AR    R0,GR13                                                  84560000
         STH   R0,TXTWR           BUMP TXTWR                            84600000
         A     GR13,TXTIO                                               84640000
         TM    2(GR13),INCORE    WAS THE FIRST ENTRY ALREADY WR         84680000
         BC    14,TXTENT1                                               84720000
         NI    2(GR13),X'7F'      TURN OFF OLD INDICATOR                84760000
         OI    2(GR13),X'40'       MARK TTR                             84800000
         S     GR13,TXTIO                                               84840000
         SRL   GR13,2                                                   84880000
         LA    R0,7      SIZE OF ONE NOTE LIST ENTRY                    84920000
         STH   R0,HOLD+2                                                84960000
         SH    GR13,TXTNOTE                                             85000000
         MH    GR13,HOLD+2                                              85040000
         A     GR13,TNT1                                                85080000
         MVC   DISPLAC(2),0(GR13)                                       85120000
         MVC   HOLD+1(3),2(GR13)                                        85160000
         L     XS2,HOLD           ADDR CORRECT AND ADD ANY DISP         85200000
         AH    XS2,DISPLAC         TO IT   USUALLY ZERO                 85240000
         MVC   HOLD+2(2),5(GR13)   OBTAIN ENTRY LENGTH                  85280000
         CLC   HOLD+2(2),UT1SIZE+2   INSURE SPECIFY LINGTH LESS  UT1    85320000
         BC    4,TXTENT2A      IF LENGTH SPECIFIES LESS THAN UT1        85360000
         L     XS1,UT1SIZE        USE ACTUAL LENGTH                     85400000
         B     TXTENT3                                                  85440000
TXTENT2A LH    XS1,HOLD+2                                               85480000
TXTENT3  LR    REG6,GR13                                                85520000
         BAL   XRET2,COMBUF                                             85560000
         BAL   XRET2,COMCHK                                             85600000
         ST    GR1,HOLD     SAVE TTR                                    85640000
         MVC   2(3,REG6),HOLD      SAVE TTR                             85680000
         B     TXTENT1                                                  85720000
***********************************************************             85760000
*                                                                       85800000
*                     WHERE THE ACTUAL LENGTH IS POSTED FOR             85840000
*                    NOLENGTH CSECTS                                    85880000
*                                                                       85920000
***********************************************************             85960000
TXTNL3   LR    XS1,XS2                                                  86000000
         TM    2(XS2),INCORE    IS THE PRESENT ENTRY TO BE POSTED       86010000
         BC    8,TXTNLB       IN CORE NOW -  YES POST GOOD LEN          86020000
         S     XS1,TXTIO      OBTAIN NUMBER OF ENTRIES IN TXTIO         86040000
         SRL   XS1,2          IF THAT NUMBER EXCEEDS MAX ALLOWABLE AT   86080000
         LA    XS1,1(XS1)   ADD ONE TO GET TRUE ENTRY NUMBER            86120000
         LH    RLK,TXTNOTE                                              86160000
TXTNL4   CH    XS1,TXTNOTE    COMPARE THE ENTRY NUMBER TO THE           86200000
*   NUMBER OF ENTRIES WRITTEN.   IF LESS OR EQU WILL HAVE UNTRUE        86240000
*   LENGTH POSTED                                                       86280000
         BC    4,TXTNLB        MUST POST UNTRUE LENGTH INDIC            86320000
         BC    7,TXTNLC    BRANCH NOT EQU   EQU  CHECK FOR ZERO         86360000
         LTR   RLK,RLK     FALL THRU IF NORELIST NEVER WR               86400000
         BC    7,TXTNLB      COMPUTE TRUE NOTELIST                      86440000
TXTNLC   MH    RLK,TSEVEN       DISPLACEMENT                            86480000
         SR    GR8,RLK       TRUE DISPLACEMENT                          86520000
TXTNL6   STH   XP1,HOLD+2      POSTED -                                 86560000
         A     GR8,TNT1          OBTAIN NOTE LIST ADDR AND POST         86600000
         MVC   5(2,GR8),HOLD+2     PROPER LENGTH                        86640000
TXTNL6A  CLC   MULTSIZE(4),UT1SIZE WAS MORE THAN ONE ENTRY MADE         86680000
         BC    2,TXTNL5            YES - BRANCH                         86720000
TXTNL6B  LA    GR8,7(GR8)     WASTHE HIGHEST MULT THE LAST ENTRY  IF    86760000
         C     GR8,TNTFREE     IT WAS   IT IS THE ALAST THING IN THE    86800000
         BC    8,TXTNL7         BUFFER AND THE BUFFER DISP CAN BE ADJ   86840000
         BAL   RLK,TXTBUF1     IF NOT  WE MUST FORCE TWO PASS TO CLEAR  86880000
         SR    RLK,RLK         RESET THE BUFFER DISPLACEMENT TO         86890000
         ST    RLK,BUFDISP       ZERO                                   86900000
TXTNL6C  NI    SWITCH,X'F7'    ANY GAPES IN THE BUFFER                  86920000
         TM    SWITCH,X'20'       SHOULD RETURN TO LM DELETE            86930000
         BC    1,TXTLM2D          YES                                   86940000
         TM    SWITCH,NOLEN1    NO LENGTH CLEAN UP                      86960000
         BC    1,TXTENDNL                                               87000000
         MVC   CURID(4),HOLD1      RESTORE PARA FOR PRESENT ID          87040000
         B     TXT002B                                                  87080000
*THE NOTELIST HAS BEEN WRITE OUT AT LEAST ONCE - BE CERTAIN APPLICABLE  87120000
* ENTRY STILL IN CORE                                                   87160000
TXTNLB   OI    2(XS2),X'08'    IF NOT  SET BIT FOR UNTRUE LENGTH        87200000
         B     TXTNL6C            AND RETURN                            87260000
TXTNL7   L     GR8,BUFDISP    PRESENT DISPLACEMENT MINUS ALLOC          87320000
         S     GR8,MULTSIZE     SIZE   PLUS THE READ LENGTH  IS THE     87360000
         AH    GR8,HOLD+2                                               87400000
         ST    GR8,BUFDISP     NEW PROPER BUFFER DISP                   87440000
         B     TXTNL6C                                                  87480000
TXTNL5   LA    XS2,4(XS2)      INCREMENT TXTIO ADDR                     87520000
         LA    GR8,7(GR8)     LESS THAN MULT- POSSIBLE THAT EXTRA       87560000
         S     XP1,UT1SIZE    ENTRIES HAVE BEEN MADE                    87600000
         C     XP1,UT1SIZE                                              87640000
         BC    2,TXTNL5                                                 87680000
         LTR   XP1,XP1            BRANCH IF LESS THAN ZERO              87720000
         BC    12,TXTNL9    VAL 0 OR NEG PRESENT ENTRY NOT REQ   A22517 87760000
         STH   XP1,HOLD                                                 87800000
         MVC   5(2,GR8),HOLD   NOVE IN PROPER LENGTH TO LAST PIECE      87840000
TXTNL5A  CLC   0(4,XS2),4(XS2)    IS THE NEXT ONE THE AAME              87880000
         BC    7,TXTNL6B     PREPARE TO RETURN                          87920000
         LA    XS2,4(XS2)      INCREMENT TXTIO ADDR                     87960000
         LA    GR8,7(GR8)         INCREMENT NOTELIST ADDR               87980000
TXTNL9   CLC   0(4,XS2),4(XS2)    IS THE NEXT ONE THE SAME              88000000
         BC    8,TXTNL8        YES  BRANCH                              88040000
         MVC   0(2,XS2),CONZO1     ZERO THE EXTRA ID                    88080000
         B     TXTNL6B                                                  88120000
TXTNL8   MVC   0(2,XS2),CONZO1                                          88160000
         LA    XS2,4(XS2)      INCREMENT TXTIO ADDR                     88200000
         LA    GR8,7(GR8)         INCREMENT NOTELIST ADDR               88220000
         B     TXTNL9    CONTINUE    TO CHECK OOR END                   88240000
*                                                                       88280000
ERRNOLEN DC    X'243D'      NO LENGTH SPACIFIED IN CESD                 88540000
RDMACRO  DC    V(IEWLERDM)                                              89720000
INPADD   DC    V(IEWLCINP)                                              89760000
         DS    25F               PATCH AREA                             90200000
         IEWAPT                                                         90240000
         EJECT                                                          90240221
*********************************************************************** 90240421
*                                                                     * 90240621
*              THE FOLLOWING SECTION IS THE COMBINED WORK AREA        * 90240821
*              USED BY THE INPUT RLD AND TEXT PROCESSORS. THIS        * 90241021
*              WORK AREA HAS BEEN PROMOTED TO THE ROOT SEGMENT        * 90241221
*              IN ORDER TO ALLOW A CHANGE IN THE OVERLAY TREE         * 90241421
*              STRUCTURE OF THE 44K DESIGN OF LINKAGE EDITOR F.       * 90241621
*                                                              S21016 * 90241821
*                                                                     * 90242021
*********************************************************************** 90242221
         SPACE 2                                                        90242421
         DS    0F                                                       90242621
DELR     DC    X'0000'          DELINKED R POINTER SAVE AREA            90242821
CONZO    DC    H'0'                                                     90243021
*                    RLD NOTE LIST ENTRY MODEL                          90243221
         SPACE 1                                                        90243421
         CNOP  0,4       ALIGN TO START PREP ON HALF WORD               90243621
PRER     DC    X'FFFF'   PREVIOUS 'R' ID                                90243821
PREP     DC    X'FFFF'   PREVIOUS 'P' ID                                90244021
RLDMULT  DC    X'0200'   FLAG-MULTIPLICITY FIELD                        90244221
*                          BIT 0 -- 0 -- RLD NOT IN CORE                90244421
*                                   1 -- RLD IN CORE                    90244621
*                          BIT 1 -- 0 -- GROUPED ENTRY                  90244821
*                                   1 -- TTR ENTRY                      90245021
*                          BIT 2 -- RESERVED                            90245221
*                          BIT 3 -- 0 -- IN BUFFER 1                    90245421
*                                   1 -- IN BUFFER 2                    90245621
*                          BIT 4 -- RESERVED                            90245821
*                          BIT 5 -- RESERVED                            90246021
*                          BITS 6-15 -- MULTIPLICITY ID                 90246221
WDCNT    DC    X'0000'   RLD WORD COUNT                                 90246421
RTTR1    DC    X'00000000'   TTR/ACCUMULATED WORD COUNT FIELD           90246621
OBCNT    DC    X'0000'   RLD BYTE COUNT                                 90246821
ENCT     DC    X'0000'   RLD NOTE LIST ENTRY COUNT                      90247021
         DC    X'0000'   RESERVED                                       90247221
RLDFLGS  DC    X'0'      RLD PROCESSING FLAGS                           90247421
*                          BIT 0 -- 1 -- CONTINUED STRING OVERFLOWS     90247621
*                                          BUFFER                       90247821
*                          BIT 1 -- 1 -- NEW GROUPED STRING OVERFLOWS   90248021
*                                          BUFFER                       90248221
*                          BIT 2 -- 0 -- I/O CONTROL TABLE NOT FULL     90248421
*                                   1 -- I/O CONTROL TABLE FULL         90248621
*                          BIT 3 -- 0 -- NOTE LIST NOT FULL             90248821
*                                   1 -- NOTE LIST FULL                 90249021
*                          BIT 4 -- 0 -- NO NOTE LIST PURGE NOW         90249221
*                                   1 -- NOTE LIST PURGED NOW           90249421
*                          BIT 5 -- 0 -- NO CHECK LAST WRITE NOW        90249621
*                                   1 -- CHECK LAST WRITE NOW           90249821
*                          BIT 6 -- 0 -- NOT FINAL CHECK                90250021
*                                   1 -- FINAL CHECK AT EOD             90250221
         EJECT                                                          90250421
BUFFS    DC    X'0'      RLD BUFFER CONTROL FLAGS                       90250621
*                          BIT 0 -- 1 -- BUFFER 1 OPENER                90250821
*                          BIT 1 -- 1 -- BUFFER 2 CHECKED               90251021
*                          BIT 2 -- 1 -- BUFFER 1 CHECKED               90251221
*                          BIT 3 -- 1 -- BUFFER 2 WRITTEN               90251421
*                          BIT 4 -- 1 -- BUFFER 1 WRITTEN               90251621
*                          BIT 5 -- 1 -- BUFFER 2 FULL                  90251821
*                          BIT 6 -- 1 -- BUFFER 1 FULL                  90252021
*                          BIT 7 -- 0 -- BUFFER 1 CURRENT               90252221
*                                   1 -- BUFFER 2 CURRENT               90252421
         SPACE 1                                                        90252621
         SPACE 1                                                        90252821
BUFSTCT  DC    F'0'      BUFFERRED STRING COUNT                         90253021
BUFSTLOC DC    F'0'      BUFFERRED STRING STARTING LOCATION             90253221
         SPACE 2                                                        90253421
*          MODEL TO HOLD WRITE TIME ENVIRONMENT FOR CHECK USE           90253621
         SPACE 1                                                        90253821
         CNOP  2,4       ALIGN TO START LPREP ON HALF WORD              90254021
LPREP    DC    X'0000'   CESD ID FIELD                                  90254221
LRLDMULT DC    X'0200'   FLAG-ADDRESS FIELD                             90254421
LWDCNT   DC    X'0000'   RLD WORD COUNT                                 90254621
LRTTR1   DC    X'00000000'     TTR/STORAGE ADDRESS FIELD                90254821
LOBCNT   DC    X'0000'   RLD BYTE COUNT                                 90255021
LENCT    DC    X'0000'   RLD NOTE LIST ENTRY COUNT                      90255221
         DC    X'0000'   RESERVED                                       90255421
         SPACE 2                                                        90255621
*            MODEL TO HOLD INITIAL BUFFER LOAD ENVIRONMENT              90255821
         SPACE 1                                                        90256021
         CNOP  2,4       ALIGN TO START OPREP ON HALF WORD              90256221
OPREP    DC    X'0000'   CESD ID FIELD                                  90256421
ORLDMULT DC    X'0200'   FLAG-ADDRESS FIELD                             90256621
OWDCNT   DC    X'0000'   RLD WORD COUNT                                 90256821
ORTTR1   DC    X'00000000'     TTR/STORAGE ADDRESS FIELD                90257021
OOBCNT   DC    X'0000'   RLD BYTE COUNT                                 90257221
OENCT    DC    X'0000'   RLD NOTE LIST ENTRY COUNT                      90257421
         DC    X'0000'   RESERVED                                       90257621
         SPACE 2                                                        90257821
*      MODEL TO HOLD CURRENT ENVIRONMENT WHILE PREVIOUS ONE IS USED     90258021
         SPACE 1                                                        90258221
         CNOP  2,4       ALIGN TO START CPREP ON HALF WORD              90258421
CPREP    DC    X'0000'   CESD ID FIELD                                  90258621
CRLDMULT DC    X'0200'   FLAG-ADDRESS FIELD                             90258821
CWDCNT   DC    X'0000'   RLD WORD COUNT                                 90259021
CRTTR1   DC    X'00000000'     TTR/STORAGE ADDRESS FIELD                90259221
COBCNT   DC    X'0000'   RLD BYTE COUNT                                 90259421
CENCT    DC    X'0000'   RLD NOTE LIST ENTRY COUNT                      90259621
         DC    X'0000'   RESERVED                                       90259821
         SPACE 2                                                        90260021
TTR1     DC    F'0'      STORAGE FOR TTR OR INPUT COUNT                 90260221
INADD1   DC    F'0'      RETURN TO INPUT PROCESSOR                      90260421
SBACKUP  DC    F'0'      SAVE AREA FOR REPLACEMENT STRING POINTER       90260621
SAVIDS   DC    F'0'      SAVE AREA FOR REPLACEMENT ID'S                 90260821
SAVETTR  DC    F'0'      SAVE AREA FOR TTR                              90261021
STRUNC   DC    X'000003FF'     MULTIPLICITY SIZE LIMITOR                90261221
RIDMSK   DC    X'00007FFF'     MASK FOR 'R' ID                          90261421
         SPACE 1                                                        90261621
SAVIDR   DC    H'0'      RESERVE AREA FOR RLD ITEM 'R' ID               90261821
CALLCURP DC    H'0'                                                     90262021
POSMULT  DC    H'0'      RESERVE AREA FOR POSSIBLE LOWEST MULTIPLICITY  90262221
STM      DC    X'0200'   RESERVE AREA FOR STRING MULTIPLICITY           90262421
SONE     DC    H'1'      DECIMAL 1                                      90262621
SFOUR    DC    H'4'      DECIMAL 4                                      90262821
SSEVEN   DC    H'7'      DECIMAL 7                                      90263021
SNINE    DC    H'9'      DECIMAL 9                                      90263221
         SPACE 1                                                        90263421
NFLG     DC    X'0'      TEMPORARY RESERVE AREA FOR FLAGS               90263621
FLAG     DC    X'0'                                                     90263821
         SPACE 1                                                        90264021
SFLIP    DC    X'00'     TEMPORARY STORAGE FOR BUFFER FLAGS             90264221
         DS    0H                                                A36529 90264421
FIVEFIVE DC    H'5'                                              A36529 90264621
DLKTSAVE DC    H'0'                                              A36529 90264821
*                                                                       90265021
****************TXT CONSTANTS***************                            90265221
*                                                                       90265421
         DS    0F                                                       90265621
DBLWRD   DC    X'FFFFFFF8'          MASK TO ZERO LST THREE BITS         90265821
MULTONLY DC    X'000003FF'           MASK TO ZERO ALL BUT MULT          90266021
IOCTSTAT DC    X'00'       I/O CONTROL TABLE OVFLO IND                  90266221
*         ENTRIES WRITTEN                                               90266421
TXTWR    DC    H'0'     CONTAINS DISPLACEMENT IN TXTIO TABLE OF         90266621
BUFSTART DC    F'0'                                                     90266821
BUFDISP  DC    F'0'                                                     90267021
HOLD     DC    2F'0'          MISC  FOR ENTER INFO INTO TABLES          90267221
TXTFREE  DC    F'0'           FIRST FREE ADDR IN TXTIO                  90267421
TNTFREE  DC    F'0'           FIRST FREE ADDR IN NOTELIST               90267621
TXTNOTE  DC    H'0'     HOLDS THE ACTUAL NUMBER OF ENTRIES OF THE       90267821
*  TXT NOTELIST THAT HAVE BEEN WRITTEN.   IT WILL NOT GE THE MAX IN     90268021
*  SITUATIONS REQUIRE MULTIPLE ENTRIES                                  90268221
CURID    DC    2X'0'          MAINTAINS CURRENT ID AND MULTIPLICITY     90268421
CMULN    DC    2X'0'                                                    90268621
PID      DC    2X'0'          MAINTAINS  PAST ID & MULT                 90268821
PMULN    DC    2X'0'                                                    90269021
MAXMULT  DC    H'512'                                                   90269221
TSEVEN   DC    H'7'       CCONSTANT USED TO DECREMENT NOTELIST ADDR     90269421
SWITCH   DC    XL2'00'                                                  90269621
*   BIT 0       NO LENGTH INDICATOR                                     90269821
*   BIT 1       DENSE INDICATOR  (NOT RELATED TO TXTIO FLAG)            90270021
*   BIT 2       LOAD MODULE INDICATOR FOR DUMMY READ                    90270221
*   BIT 3       NOLENGTH AND HAVE RECEIVED NEW ID   POST TRUE LEN       90270421
*   BIT 4       NOLEN CLEAN UP ON END OF ENPUT                          90270621
*   BIT 5       LOAD MODULE READ TO BE ISSUED                           90270821
*   BIT 6       RESERVED                                                90270921
*   BIT 7       LAST WRITE SIGNAL WHEN GROUPING ON UT1                  90271021
*   BIT 8       FLAG FOR SPECIAL LOAD MODULE TEXT SITUATION     SA56444 90271121
*   BIT 9-10    RESERVED                                                90321121
*   BIT 11      FLAG FOR NONGROUPED PURGE REQUIRED                      90331121
*   BIT 12-15   RESERVED                                                90341121
HOLD1    DS    2F                                                       90371121
DISPLAC  DC    F'0'                                                     90421121
TXTALLOC EQU   *       USED FOR LM TO MAINTAIN ALLOC SIZE               90471121
LASTTNT  DC    F'0'               MAINTAIN LAST NOTELIST ADDR           90521121
FROMAD   DC    F'0'      START & END FOR DENSE RECORDS                  90571121
TOADDR   DC    F'0'                                                     90621121
CDISP    DC    H'0'                DISPLACEMENT IN MULTIPLICITY         90671121
ACUMLEN  DC    F'0'      WILL ACCUMULATE LENGTH OF LM RECORD TO ENABLE  90721121
LMLEN    DS    F      WILL HOLD TOTAL LENGTH OF LM INPUT RECORD         90771121
*                    RECOMPUTATION OF ASSM ADDR                         90821121
RETURNAD EQU   *               SAVES RETURN WHEN PROCESS FINISHED       90871121
IDLENPTR DS    1F                  PTR TO ID-LENGTH ENTRY               90921121
CREND    DS    1F                  PTR TO END OF ID-LENGTH LIST         90971121
CONZO1   DC    F'0'      CONSTANT OF ZERO                               91021121
TXTACUM  DC    H'0'                                                     91071121
TSCNEND  DS    F      END OF SCN                                        91121121
HOLD3    DS    3F                                                       91171121
         END                                                            91221121
