 TITLE 'IEWLMREL - SECOND PASS RELOCATION'                              00100000
*********************************************************************** 00310000
*STATUS: CHANGE LEVEL 0                                               * 00380000
*FUNCTION/OPERATION:                                                  * 00450000
*        1) RELOCATION                                                * 00520000
*        2) CREATION OF ENTAB AND ITS RLDS                            * 00590000
*        3) SECOND PASS INITIALIZATION                                * 00660000
*ENTRY POINTS:                                                        * 00730000
*        IEWLMREL- FOR SECOND PASS INITIALIZATION                     * 00800000
*        RELOCATE- FOR RELOCATION                                     * 00870000
*        SCDENTAB- FOR CREATION OF ENTAB AND ITS RLDS                 * 00940000
*                                                                     * 01010000
*INPUT: - SAME TABLES AS IEWLMSCD                                     * 01080000
*                                                                     * 01150000
*OUTPUT: ENTAB TEXT AND ENTAB RLD RECORDS. THE SIZE OF THE ENTAB IS   * 01220000
*              LIMITED ONLY  BY THE MAXIMUM RECORD SIZE ON SYSLMOD    * 01290000
*                                                                     * 01360000
*EXTERNAL ROUTINES:                                                   * 01430000
*        GETIDMUL- TO GET NEXT TEXT TO PROCESS                        * 01500000
*        WRTTXT- TO WRITE A TEXT RECORD                               * 01570000
*        WRTCRRLD- TO WRITE A CR/RLD RECORD                           * 01640000
*        CHECKRD - TO CHECK A READ                                    * 01710000
*        CHECKWRT- TO CHECK A WRITE                                   * 01780000
*EXITS: NORMAL-RETURN VIA REGISTER 14 TO CALLER                       * 01850000
*       ERROR ---  ENTRY LIST EXCEEDED      L  15,ERDIG               * 01920000
*                                           L  0,ERCODE44             * 01990000
*                                           BR 15                     * 02060000
*TABLES/WORK AREAS: - REFER TO LINKAGE EDITOR PLM FOR DETAILED        * 02130000
*        DESCRIPTIONS                                                 * 02200000
*        1) ALL PURPOSE TABLE                                         * 02270000
*        2) HESD                                                      * 02340000
*        3) DELINK TABLE                                              * 02410000
*        4) RELOCATION CONSTANT TABLE                                 * 02480000
*        5) RLD NOTELIST                                              * 02550000
*        6) TEXT CONTROL BLOCKS(SEE LABELS TXTCB1 AND TXTCB2)         * 02620000
*        7) RLD CONTROL BLOCKS(SEE LABELS INRLDCB1,INRLDCB2,OTRLDCB1, * 02690000
*              OTRLDCB2, AND OTRLDCB3)                                * 02760000
*        8) SEGTAB1                                                   * 02830000
*                                                                     * 02900000
*ATTRIBUTES:  REUSABLE                                                * 02970000
*NOTES:  NONE                                                         * 03040000
*                                                                     * 03110000
*********************************************************************** 03180000
*                                                                     * 03250000
*   THE PROLOGUE FOR THIS ROUTINE IS INCORPORATED IN THE PROLOGUE     * 03320000
*                   FOR IEWLMSCD                                      * 03390000
*                                                                     * 03460000
IEWLMREL CSECT                                                          03530000
* 692600,694000                                                  A22109 03560000
* 276200,276600                                                  A36027 03570021
* 732500-733900,739600,740200                                    A36529 03580021
*A359400,C360100                                                 A48242 03590021
*C363600,A363600                                                 A48242 03592021
*A407700,C408400                                                 A48242 03594021
*A411200,C411900                                                 A48242 03596021
*A693300                                                         A48242 03598021
*A855700                                                         A48242 03598421
*A585500,I608000-608597,I610500                                 SA69469 03598821
*I455800-455988                                                 SA69197 03599221
*********************************************************************** 03600000
*                       FLAG INDICATORS                               * 03670000
*********************************************************************** 03740000
ABSOLUTE EQU   X'1F'                   TO MARK RLD ABSOLUTE             03810000
*                                                                     * 03880000
*                   NEWSW2 INDICATORS IN APT                          * 03950000
MORERLDS EQU   X'80'                    MORE RLDS STILL TO BE READ      04020000
SPLTMOVD EQU   X'40'                    SPLIT RLD MOVED TO OUTPUT BFR.  04090000
MOVDOFF  EQU   X'BF'                                                    04160000
RPSAVED  EQU   X'20'                    R+P SAVED FROM PREV. RECORD.    04230000
RPSAVOFF EQU   X'DF'                                                    04300000
ABS      EQU   X'10'                   ABSOLUTE RELOCATION NEEDED       04370000
REL      EQU   X'EF'                   RELATIVE RELOCATION NEEDED       04440000
SPLITRLD EQU   X'08'                    SPLIT RLD SAVED IN HESD         04510000
GROUPRLD EQU   X'02'                   USE SAME BUFFER--GROUP RLDS      04580000
GROUPOFF EQU   X'FD'                   RLDS ARE NOT TO BE GROUPED       04650000
RPINBFR  EQU   X'01'                    R+P ALREADY MOVE TO BUFFER      04720000
NOTINBFR EQU   X'FE'                                                    04790000
*                                                                     * 04860000
*                  CONTROL RECORD INDICATORS                          * 04930000
*                                                                     * 05000000
TXT      EQU   X'01'                    TEXT FOLLOWS                    05070000
RLD      EQU   X'02'                    RLDS PRESENT                    05140000
RLDOFF   EQU   X'FD'                                                    05210000
SEGEND   EQU   X'04'                    LAST TEXT FOR SEGMENT           05280000
MODEND   EQU   X'08'                    LAST TEXT FOR MODULE            05350000
*   TEXT CONTROL BLOCK INDICATORS                                     * 05420000
*                              BYTE 1                                 * 05490000
INUSE    EQU   X'80'                    CONTROL BLOCK IN USE            05560000
BEINGWT  EQU   X'40'                    TEXT BEING WRITTEN              05630000
WRTCKD   EQU   X'3F'                                                    05700000
BEINGRD  EQU   X'20'                    TEXT BEING READ                 05770000
RDCKD    EQU   X'DF'                    READ IS CHECKED                 05840000
FIRSTXT  EQU   X'08'                    FIRST TEXT OF GROUP             05910000
LASTXT   EQU   X'04'                    LAST TEXT OF GROUP              05980000
TESTWRT  EQU   X'C0'                    TEST IF TEXT WRITTEN YET        06050000
*                              BYTE2                                  * 06120000
XDAP     EQU   X'80'                    XDAP WRITE NEEDED               06190000
DUMMY    EQU   X'40'                    DUMMY WRITE NEEDED              06260000
PREV     EQU   X'07'                    TEST FOR PREVIOUS CONTROL REC.  06330000
*                              BYTE3                                    06400000
RLDSIN1  EQU   X'C0'                    TEST FOR UNPROCESSED RLDS-BFR1  06470000
RLDSIN2  EQU   X'30'                    TEST FOR UNPROCESSED RLDS-BFR2  06540000
BUF1PROC EQU   X'40'                    RLDS IN BUFFER 1 PROCESSED      06610000
BUF1OFF  EQU   X'3F'                                                    06680000
BUF2PROC EQU   X'10'                    RLDS IN BUFFER 2 PROCESSED      06750000
BUF2OFF  EQU   X'CF'                                                    06820000
*    RLD INPUT CONTROL BLOCK INDICATORS                               * 06890000
*INUSE    EQU  X'80'                    CONTROL BLOCK IN USE            06960000
*NOTINUSE EQU  X'7F'                                                    07030000
*   RLD  NOTELIST INDICATORS                                            07100000
PROCESSD EQU   X'20'                   RLDS ALL PROCESSED IN SET        07170000
BUF2     EQU   X'10'                   RLDS IN BFR. 2                   07240000
SPLT     EQU   X'08'                    RLD SET HAS A SPLIT RLD         07310000
SPLTOFF  EQU   X'F7'                                                    07380000
JUSTPROC EQU   X'04'                    RLD SET CONTAINS RELOCATED RLDS 07450000
*                                            TO MOVE                    07520000
JUSTOFF  EQU   X'FB'                                                    07590000
*       RLD OUTPUT CONTROL BLOCK INDICATORS                           * 07660000
*INUSE   EQU   X'80'                    CONTROL BLOCK IN USE            07730000
NOTINUSE EQU   X'7F'                                                    07800000
*BEINGWT EQU   X'40'                    CONTROL BLOCK BEING WRITTEN     07870000
*WRTCKD  EQU   X'3F'                    TURN OFF BEING WRITTEN+IN USE   07940000
*      RLD ITEM INDICATORS                                              08010000
UNRESER  EQU   X'80'                    UNRESOLVED EXTERNAL REFERENCE   08080000
*                                            INDICATOR IN RLD           08150000
PROC     EQU   X'40'                    RLD HAS BEEN PROCESSED          08220000
PROCOFF  EQU   X'BF'                    PROCESSED BIT OFF               08290000
CONT     EQU   X'01'                    NEXT FA FIELD IS CHAINED        08360000
CONTOFF  EQU   X'FE'                                                    08430000
RELREL   EQU   X'7F'                   TURN OFF RELATIVE INDICATOR      08500000
*                                                                     * 08570000
*                   APT3 INDICATORS                                   * 08640000
*                                                                     * 08710000
SEGSTART EQU   X'04'                   TEXT IS FIRST IN SEGMENT         08780000
*                                                                     * 08850000
*                  REGISTER  USAGE                                    * 08920000
*                                                                     * 08990000
SAVEAREA EQU   13                      SAVE AREA REGISTER               09060000
RETURN   EQU   14                       RETURN REGISTER                 09130000
BRANCH   EQU   15                      BASE REGISTER IN IEWLMREL        09200000
WORK0    EQU   0                        GENERAL WORK REGISTER           09270000
WORK1    EQU   1                        PARM REG.AND GENERAL WORK REG.  09340000
APT      EQU   2                        BASE REG FOR APT                09410000
CURTXTCB EQU   3                       ADDRESS OF CURRENT TEXT CTRL BLK 09480000
WORK4    EQU   4                        GENERAL WORK REGISTER           09550000
HESDADDR EQU   5                        HESD ENTRY ADDR.-USED IN RELOC. 09620000
OUTRLDCB EQU   5                        ADDR.OF.CTRL.BLK.FOR OUTPUT     09690000
*                                            BFR.-USED IN MVRLD         09760000
WORK2    EQU   6                        WORK REG -USED IN DIVIDE INSTR  09830000
WORK3    EQU   7                        WORK REG -USED IN DIVIDE INSTR  09900000
INRLDCB  EQU   8                        ADDR.OF CTRL.BLK.FOR INPUT BFR. 09970000
*                                            CONTAINING NEEDED RLD'S    10040000
PREVCREC EQU   8                        PREV CTRL REC - USED ONLY IN    10110000
*                                            SCDENTAB                   10180000
NOTLSENT EQU   9                        CURR.RLD NOTELIST ENTRY         10250000
RLDSETAD EQU   10                       RLD SET BUFFER ADDR             10320000
BRANCHX  EQU   11                      SECOND LEVEL BR. REG--MVRLD      10390000
WORK5    EQU   11                      GENERAL WORK REGISTER--MREL      10460000
BASE     EQU   12                       BASE REG.FOR IEWLMSCD           10530000
*                             ERROR CODES                             * 10600000
HEX1     EQU   X'1'                     BITMAP INDIC-INVAL.2 BYTE ADCON 10670000
HEX2     EQU   X'2'                     BITMAP INDIC-INVAL.VCON IN OVLY 10740000
ERCODE44 EQU   X'42C'                   ENTRY LIST OVERFLOWED           10810000
         ENTRY RELOCATE                                                 10880000
         ENTRY  SCDENTAB                                                10950000
         ENTRY OTRLDCB1                 RLD OUTPUT CONTROL BLOCK 1      11020000
         ENTRY OTRLDCB2                 RLD OUTPUT CONTROL BLOCK 2      11090000
         ENTRY OTRLDCB3                 RLD OUTPUT CONTROL BLOCK 3      11160000
         ENTRY INRLDCB1                 RLD INPUT CONTROL BLOCK  1      11230000
         ENTRY INRLDCB2                 RLD INPUT CONTROL BLOCK  2      11300000
         USING *,BRANCH                                                 11370000
         B     MODID+6                                                  11440000
MODID    DC    C'19MREL'                                                11510000
         USING APTDSECT,APT             BASE FOR APT                    11580000
         LA    SAVEAREA,REGSA           APT SAVE AREA FOR IOCS          11650000
         ST    WORK1,CURENTAB           HESD ADDR. OF NEXT ENTAB ENTRY  11720000
         MVC   LKAENTAB+1(4),1(WORK1)     HESD--SET-UP BY IEWLMOUT      11790000
         MVC   CURENTRY(4),SELST       INIT CURR ENTRY ADDR TO BEG      11860000
         MVI   NEWSW2,X'00'            INIT. APT SWITCH AREA            11930000
         NI    APT3,X'F1'              INIT APT SWITCH AREA             12000000
**********************************************************************  14310000
*                                                                     * 14380000
*        INITIALIZATION OF TXT AND RLD CONTROL BLOCKS                 * 14450000
*                                                                     * 14520000
INIT     SR    WORK1,WORK1                                              14590000
         ST    WORK1,TXTCB1                                             14660000
         ST    WORK1,TXTCB2                                             14730000
         STH   WORK1,OTRLDCB1+2                                         14800000
         STH   WORK1,OTRLDCB2+2                                         14870000
         STH   WORK1,OTRLDCB3+2                                         14940000
         MVI   OTRLDCB1,X'00'          CLEAR FLAG FIELD OF OUTPUT BFR   15010000
         MVI   OTRLDCB2,X'00'               CONTROL BLOCKS              15080000
         MVI   OTRLDCB3,X'00'                                           15150000
         MVC   INRLDCB1(4),OF           SET RLD ADDR TO F'S             15220000
         MVC   INRLDCB2(4),OF                                           15290000
         MVC   INRLDCB1+4(4),RLDINBF1   BEG. OF RLD INPUT BUFFER 1      15360000
         MVC   INRLDCB2+4(4),RLDINBF2   BEG. OF RLD INPUT BUFFER 2      15430000
         L     WORK1,RLDOUTBF           BEG. AND END OF RLD OUTPUT BFRS 15500000
         ST    WORK1,OTRLDCB1+8                                         15570000
         LA    WORK1,236(WORK1)        (END-4 SO CAN ALWAYS ADD         15640000
         ST    WORK1,OTRLDCB1+12       ONE ID-LENGTH LIST ENTRY         15710000
         LA    WORK1,20(WORK1)                                          15780000
         ST    WORK1,OTRLDCB2+8                                         15850000
         LA    WORK1,236(WORK1)                                         15920000
         ST    WORK1,OTRLDCB2+12                                        15990000
         LA    WORK1,20(WORK1)                                          16060000
         ST    WORK1,OTRLDCB3+8                                         16130000
         LA    WORK1,236(WORK1)                                         16200000
         ST    WORK1,OTRLDCB3+12                                        16270000
*                                                                     * 16340000
*              INITIALIZATION OF CONSTANT AREAS                       * 16410000
*                                                                     * 16480000
         MVC   SRCHBEG(4),TXTIO         BEGINNING ADDR.OF TEXT I/O TBL. 16550000
         OI    APT3,FIRSTXT             SET 1ST TEXT OF MODULE ON       16620000
         LA    CURTXTCB,TXTCB1                                          16690000
         LA    WORK4,TXTCB2                                             16760000
         OI    INRLDCB2,BUF2                                            16830000
         LA    PREVCREC,OTRLDCB1        ADDR. OF CTRL. BLK. FOR PREV.CR 16900000
         OI    1(CURTXTCB),X'24'       PREV. CR. IS IN BFR. 1           16970000
         MVC   4(4,PREVCREC),8(PREVCREC) FIRST FREE ADDR.= BFR.BEG.     17040000
         OI    0(PREVCREC),INUSE                                        17110000
         L     WORK2,8(PREVCREC)                                        17180000
         XC    0(16,WORK2),0(WORK2)     ZERO THE CONTROL RECORD         17250000
         XC    CCWDISP(4),CCWDISP                                       17320000
         XC    GROUPLNG(2),GROUPLNG                                     17390000
         BR    RETURN                                                   17460000
RELOCATE STM   WORK0,BRANCH,SAVE       SAVE REGISTERS                   17530000
*                                                                     * 17600000
*                    COMPUTE  BUFFER  RELOCAND                        * 17670000
*                                                                     * 17740000
         L     WORK5,8(CURTXTCB)                                        17810000
         SH    WORK5,24(CURTXTCB)       BEGINNING OF TXT FOR CURR ID    17880000
         ST    WORK5,TXTBEG                                             17950000
         LH    WORK2,CURMULT                                            18020000
         MH    WORK2,MULTSIZE+2        MULT . MULT SIZE                 18090000
         LH    HESDADDR,CURID                                           18160000
         SLL   HESDADDR,3                                               18230000
         A     HESDADDR,HESD           CALCULATE CURRENT HESD ENTRY     18300000
         LH    WORK3,CURID                                              18370000
         SLL   WORK3,2                                                  18440000
         A     WORK3,RECNT             ADDR OF REL CNST TABLE ENTRY     18510000
         L     WORK3,0(WORK3)          GET REL RELOC CONSTANT           18580000
         AR    WORK5,WORK3                                              18650000
         L     WORK4,0(HESDADDR)       TYPE AND LKA                     18720000
         LA    WORK4,0(WORK4)                                           18790000
         SR    WORK5,WORK4                                              18860000
         SR    WORK5,WORK2              BFREL=BEG.OF TXT+REL RELO CNST  18930000
         ST    WORK5,BFREL                    -LKA-(MULT NO* MULT SIZE) 19000000
         SR    WORK3,WORK4                                              19070000
         ST    WORK3,INPUTADR          SAVE INPUT ADDR FOR MULT UPDATE  19140000
*                                                                     * 19210000
*        DETERMINE IN WHICH BUFFER RLD'S ARE LOCATED                  * 19280000
*                                                                     * 19350000
TSTBUF1  TM    2(CURTXTCB),RLDSIN1      ARE THERE UNPROC. RLD'S IN BFR1 19420000
         BC    11,TSTBUF2               NO                              19490000
         LA    INRLDCB,INRLDCB1         YES,GET ADDR.OF BFR.CTRL.BLOCK  19560000
         B     RLDADDR                                                  19630000
TSTBUF2  TM    2(CURTXTCB),RLDSIN2      ARE THERE UNPROC. RLD'S IN BFR2 19700000
         BC    11,MVRLD                 NO,GO TO MOVE RLDS              19770000
         LA    INRLDCB,INRLDCB2         GET ADDR.OF BFR.CTRL BLOCK      19840000
*                                                                     * 19910000
*              CALCULATE STORAGE ADDRESS OF RLD SET                   * 19980000
*                                                                     * 20050000
RLDADDR  L     NOTLSENT,12(INRLDCB)     GET RLD NOTELIST ENTRY ADDR     20120000
         CL    NOTLSENT,8(INRLDCB)     IS THIS 1ST ENTRY                20190000
         BNE   RLDADDR1                NO                               20260000
         L     RLDSETAD,4(INRLDCB)     USE BEG OF BUFFER                20330000
         B     RELOC                                                    20400000
RLDADDR1 LR    RLDSETAD,NOTLSENT                                        20470000
         SH    RLDSETAD,FOUR                                            20540000
         MVC   TEMPAREA(4),0(RLDSETAD) GET BOUNDARY ALIGN               20610000
         L     RLDSETAD,TEMPAREA                                        20680000
         LA    RLDSETAD,0(RLDSETAD)                                     20750000
         SLL   RLDSETAD,2                                               20820000
         A     RLDSETAD,4(INRLDCB)      STORAGE ADDR.OF RLD SET         20890000
*                                                                     * 20960000
*                   DETERMINE BYTES OF RLD INFORMATION IN SET         * 21030000
*                                                                     * 21100000
RELOC    MVC   TEMPAREA(2),4(NOTLSENT)                                  21170000
         LA    WORK1,4                                                  21240000
         MH    WORK1,TEMPAREA                                           21310000
         STH   WORK1,RLDBYTES           BYTES OF RLD INFORMATION        21380000
RELOC00  MVC   RSAVE(2),0(RLDSETAD)     SAVE  R PTR                     21450000
         NI    RSAVE,X'7F'              CLEAR DELINK BIT                21520000
         ST    RLDSETAD,PREVRPAD        SAVE ADDR OF PREV R AND P PTR   21590000
*                                                                     * 21660000
RELOC10  LA    RLDSETAD,4(RLDSETAD)     UPDATE TO FA FIELD              21730000
         LH    WORK1,RLDBYTES                                           21800000
         SH    WORK1,FOUR               DECR. RLD BYTE COUNT            21870000
         LTR   WORK1,WORK1              IS RLD SET ALL PROCESSED        21940000
         BZ    RELOC150                 YES                             22010000
         STH   WORK1,RLDBYTES           SAVE REMAINING COUNT            22080000
         TM    0(RLDSETAD),PROC         IS RLD ALREADY PROCESSED        22150000
         BO    RELOC120                 YES                             22220000
*                                                                     * 22290000
*        COMPUTE TEXT BUFFER ADDRESS OF ADCON                         * 22360000
*                                                                     * 22430000
         L     WORK1,0(RLDSETAD)        RLD FA FIELD                    22500000
         LA    WORK1,0(WORK1)           CLEAR FLAG FIELD                22570000
         A     WORK1,BFREL              BFR RELOCAND + RLD ADDR         22640000
         ST    WORK1,ADCONADR           SAVE ADCON'S TEXT BUFFER ADDR   22710000
*                                                                     * 22780000
*        DETERMINE IF RLD ITEM IS WITHIN CURRENT TEXT LIMITS          * 22850000
*                                                                     * 22920000
         C     WORK1,TXTBEG             COMPARE TO BEGINNING OF TEXT    22990000
         BL    RELOC120                 NO, NOT WITHIN THIS TXT RECORD  23060000
         C     WORK1,8(CURTXTCB)        COMPARE TO END ADDR             23130000
         BL    RELOC20                  YES, IT IS WITHIN THIS TXT REC  23200000
         CLC   1(3,RLDSETAD),1(INRLDCB) NO,CHECK IF LOW RLD ADDR.       23270000
         BNL   RELOC120                       SHOULD BE UPDATED         23340000
         MVC   1(3,INRLDCB),1(RLDSETAD)                                 23410000
         B     RELOC120                 GO TO PROCESS NEXT RLD ITEM     23480000
*                                                                     * 23550000
*                 TEST FOR A SPLIT ADDRESS CONSTANT                   * 23620000
*                                                                     * 23690000
RELOC20  TM    0(RLDSETAD),X'04'        IS LENGTH OF ADCON = 3 BYTES    23760000
         BO    RELOC30                  NO                              23830000
         LA    WORK3,2                  YES,LENGTH-1 SAVED              23900000
         AR    WORK1,WORK3              CALC END OF ADCON               23970000
         B     RELOC50                                                  24040000
RELOC30  TM    0(RLDSETAD),X'08'        IS LENGTH OF ADCON = 4 BYTES    24110000
         BZ    RELOC40                  NO,  MUST BE TWO BYTES          24180000
         LA    WORK3,3                  YES,LENGTH-1 SAVED              24250000
         AR    WORK1,WORK3              CALC END OF ADCON               24320000
         B     RELOC50                                                  24390000
RELOC40  TM    0(RLDSETAD),X'20'        IS IT A PSEUDO REG TYPE         24460000
         BZ    ERROR01                  NO, SET BIT MAP ERROR INDICATOR 24530000
         LA    WORK3,1                  YES, LENGTH-1 SAVED             24600000
         AR    WORK1,WORK3              CALC END OF ADCON               24670000
RELOC50  STH   WORK3,LENGTH             SAVE ADCON LENGTH-1             24740000
         C     WORK1,8(CURTXTCB)        COMP END OF ADCON TO END OF BFR 24810000
         BL    RELOC60                                                  24880000
         BAL   RETURN,SPLTADCN          GO TO SPLIT ADCON ROUTINE       24950000
RELOC60  L     WORK3,PREVRPAD                                           25020000
         TM    0(WORK3),X'80'           IS TYPE A DELINK                25090000
         LH    WORK3,RSAVE              GET CURRENT R PTR               25160000
         LR    WORK0,WORK3                                              25230000
         BNO   RELOC70                  NO,  TEST FOR OVERLAY           25300000
*                                                                     * 25370000
*              DELINK THE ADDRESS CONSTANT                            * 25440000
*                                                                     * 25510000
         MH    WORK3,FIVE                                               25580000
         A     WORK3,DLKT               COMPUTE DELINK TABLE ENTRY ADDR 25650000
         MVC   DLNKR(2),0(WORK3)        GET R PTR FROM DELINK TABLE     25720000
         LH    WORK0,DLNKR              WORK0 CONTAINS TRUE R PTR       25790000
         MVC   DLNKSAVE+1(3),2(WORK3)  SAVE DELIND VALUE                25860000
RELOC70  TM    PDSE7,X'20'              IS THE PGM IN OVERLAY           25930000
         BO    SCDOVLY                  YES                             26000000
*                                                                     * 26070000
*   MOVE ADCON FROM TEXT BUFFER TO WORK REG FOR RELOCATION            * 26140000
*                                                                     * 26210000
RELOC75  L     WORK3,ADCONADR           GET TEXT ADDR OF ADCON          26280000
         LA    WORK1,ADCON+3            END ADDR OF ADCON SAVE AREA     26350000
         SH    WORK1,LENGTH                                             26420000
         LH    WORK4,LENGTH                                             26490000
         EX    WORK4,MOVE               MOVE ADCON TO GET BNDY. ALIGN.  26560000
         L     WORK4,ADCON                                              26630000
         ST    WORK1,RELADCON           STORAGE ADDR OF RELO ADCON      26700000
*                                                                     * 26770000
*     TEST TYPE TO DETERMINE WHAT TYPE OF RELOCATION TO PERFORM       * 26840000
*                                                                     * 26910000
         TM    0(RLDSETAD),X'80'        IS IT RELATIVE                  26980000
         BZ    RELOC130                 NO                              27050000
         NI    0(RLDSETAD),RELREL      SET OFF REL. INDIC.              27120000
         NI    NEWSW2,REL              SET REL. RELOC. INDIC.           27190000
         BAL   RETURN,FRELFAC           TO FETCH REL. RELOC. FACTOR     27260000
         SLL   WORK3,8                 PROPAGATE SIGN BIT               27330000
         SRA   WORK3,8                                                  27400000
*                                                                     * 27470000
*                        PERFORM  RELOCATION                          * 27540000
*                                                                     * 27610000
         TM    0(RLDSETAD),X'90'       UNRESOLVED VCON           A26871 27615021
         BNO   RELOC90                 NO-GO AND RELOCATE        A36027 27620021
         SR    WORK4,WORK4        YES - CLEAR REG. AND RETURN    A26871 27640000
         OI    0(RLDSETAD),PROC   MARK RLD PROCESSED             A26871 27650000
         B     RELOC110                                          A36027 27660021
RELOC90  TM    0(RLDSETAD),X'02'        DOES RLD INDICATE SUBT.         27680000
         BZ    RELOC95                  NO                              27750000
         LCR   WORK3,WORK3              COMPLEMENT FOR SUBTRACT         27820000
RELOC95  AR    WORK4,WORK3              RELOCATE ADCON                  27890000
*                                                                     * 27960000
*           PLACE RELOCATED ADDRESS CONSTANT BACK INTO TEXT           * 28030000
*                                                                     * 28100000
RELOC100 ST    WORK4,ADCON              PUTS RELOC. ADCON INTO WK AREA  28170000
         L     WORK3,RELADCON           ADDR. OF RELOCATED ADCON        28240000
         L     WORK1,ADCONADR           TEXT BUFFER ADDR OF ADCON       28310000
         LH    WORK2,LENGTH                                             28380000
         EX    WORK2,MOVE               RELOC ADCON MOVE BACK INTO TEXT 28450000
*                                                                     * 28520000
*            RELOCATE THE ADDRESS FIELD OF CURRENT RLD ITEM           * 28590000
*                                                                     * 28660000
RELOC110 LH    WORK1,CURID                                              28730000
         NI    NEWSW2,REL              SET REL. RELOC. INDIC.           28800000
         BAL   RETURN,FRELFAC1          TO FETCH RELOCATION FACTOR      28870000
         L     WORK4,0(RLDSETAD)        GET RLD ADDR.                   28940000
         LA    WORK4,0(WORK4)          CLEAR FLAG FIELD                 29010000
         AR    WORK4,WORK3                                              29080000
         ST    WORK4,TEMPAREA                                           29150000
         MVC   1(3,RLDSETAD),TEMPAREA+1 UPDATE RLD ADDR FIELD           29220000
         OI    0(RLDSETAD),PROC         MARK RLD PROCESSED              29290000
*                                                                     * 29360000
*              UPDATE TO NEXT RLD ITEM                                * 29430000
*                                                                     * 29500000
RELOC120 TM    0(RLDSETAD),X'01'        IS IT A FA CONTINUATION         29570000
         BO    RELOC10                  YES, RETURN                     29640000
         LA    RLDSETAD,4(RLDSETAD)     NO, UPDATE TO NEXT RLD ITEM     29710000
         LH    WORK1,RLDBYTES                                           29780000
         SH    WORK1,FOUR                                               29850000
         STH   WORK1,RLDBYTES           DECR. RLD BYTE COUNT            29920000
         LTR   WORK1,WORK1             RLD SET ALL PROCESSED            29990000
         BZ    RELOC150                YES                              30060000
         B     RELOC00                  RETURN TO PROCESS NEXT RLD      30130000
*                                                                     * 30200000
*                   ABSOLUTE  RELOCATION                              * 30270000
*                                                                     * 30340000
RELOC130 TM    0(RLDSETAD),X'30'        IS IT A PSEUDO REG - TYPE 2     30410000
         BO    RELOC135                 YES                             30480000
         L     WORK1,PREVRPAD                                           30550000
         TM    0(WORK1),X'80'           IS DELINKING REQUIRED           30620000
         BO    RELOC140                 YES                             30690000
RELOC131 OI    NEWSW2,ABS              SET ABS. RELOC. INDIC.           30760000
         BAL   RETURN,FRELFAC           TO FETCH ABS. RELOC. FACTOR     30830000
         TM    0(RLDSETAD),X'70'        IS TYPE ABSOLUTE                30900000
         BZ    RELOC90                  YES, GO TO RELOCATE             30970000
*                                       NO, TYPE IS 'BRANCH' OR PSEUDO1 31040000
         LR    WORK4,WORK3              USE RELOC. FAC. AS ADCON VALUE  31110000
         B     RELOC100                 RETURN TO RELOCATE              31180000
RELOC135 L     WORK4,PRAL               USE  ACCUM LNC AS ADCON VALUE   31250000
         B     RELOC100                 RETURN TO RELOCATE              31320000
RELOC140 L     WORK2,DLNKSAVE          GET DELIND VALUE                 31390000
         TM    0(RLDSETAD),X'02'        DOES SIGN INDICATE SUBTRACT     31460000
         BO    RELOC145                 YES                             31530000
         LCR   WORK2,WORK2              COMPLEMENT VALUE                31600000
RELOC145 AR    WORK4,WORK2              ADD DELINK VALUE TO ADCON       31670000
         NI    0(RLDSETAD),ABSOLUTE    MARK RLD ABSOLUTE                31740000
         B     RELOC131                                                 31810000
RELOC150 OI    2(NOTLSENT),JUSTPROC    RLD SET JUST PROCESSED           31880000
         CLC   FF(3),1(INRLDCB)         IS RLD SET ALL RELOCATED        31950000
         BE    RELOC160                 YES                             32020000
         L     WORK3,0(INRLDCB)         NO, UPDATE LOWEST MULTIPLICITY  32090000
         LA    WORK3,0(WORK3)                                           32160000
         A     WORK3,INPUTADR                                           32230000
         SR    WORK2,WORK2                                              32300000
         D     WORK2,MULTSIZE          WORK3 CONTAINS UPDATED MULT      32370000
         STH   WORK3,TEMP                                               32440000
         NI    2(NOTLSENT),X'FC'       SAVE ONLY INDIC.                 32510000
         OC    TEMP(1),2(NOTLSENT)     SET INDICATORS IN NEW MULT       32580000
         MVC   2(2,NOTLSENT),TEMP       UPDATE LOWEST MULTIPLICITY      32650000
         MVC   1(3,INRLDCB),FF         REINITIAL F'S IN INRLDCB         32720000
         B     RELOC170                                                 32790000
RELOC160 OI    2(NOTLSENT),PROCESSD     SET PROCESSED BIT FOR RLD SET   32860000
*                                                                     * 32930000
*        CHECK FOR OTHER NEEDED RLD'S IN GROUPING                     * 33000000
*                                                                     * 33070000
RELOC170 CL    NOTLSENT,16(INRLDCB)     MORE RLD SETS IN GROUP          33140000
         BNE   RELOC190                YES                              33210000
         TM    0(INRLDCB),X'10'         WORKING IN BUFFER 1             33280000
         BZ    RELOC180                 YES                             33350000
         OI    2(CURTXTCB),BUF2PROC     NO,SET RLD'S IN BFR 2 PROCESSED 33420000
         B     TSTBUF1                                                  33490000
RELOC180 OI    2(CURTXTCB),BUF1PROC     SET RLD'S IN BUFFER 1 PROCESSED 33560000
         B     TSTBUF1                                                  33630000
RELOC190 LA    NOTLSENT,9(NOTLSENT)     INCR. TO NEXT NOTELIST ENTRY    33700000
         CLC   CURID(2),0(NOTLSENT)     CURRENT ID = ENTRY ID           33770000
         BNE   RELOC170                 NO                              33840000
         MVC   TEMPAREA(2),2(NOTLSENT)                                  33910000
         NI    TEMPAREA,X'03'          CLEAR INDICATORS                 33980000
         CLC   CURMULT(2),TEMPAREA     CURRENT MULT = ENTRY MULT        34050000
         BNE   RELOC170                 NO                              34120000
         ST    NOTLSENT,12(INRLDCB)     UPDATE NOTELIST FIELD OF CB     34190000
         B     TSTBUF1                  RETURN TO PROCESS               34260000
*                                                                     * 34330000
*   SUBROUTINE TO FETCH THE NEEDED RELOCATION FACTOR - WORK3 CONTAINS * 34400000
*     THE RELOCATION FACTOR ON EXIT - WORK0 CONTAINS R PTR ON ENTRANCE* 34470000
*                                                                     * 34540000
FRELFAC  LR    WORK1,WORK0              USE SAVED ID TO INDEX HESD      34610000
FRELFAC1 LR    WORK3,WORK1                                              34680000
         SLL   WORK3,3                                                  34750000
         A     WORK3,HESD                                               34820000
         TM    0(WORK3),X'0F'           TEST FOR UNRESOLVED EXTERNAL    34890000
         BC    8,TEST                                                   34960000
      TM   0(WORK3),X'05'                                               35030000
         BC    5,TEST                                                   35100000
         OI    0(RLDSETAD),UNRESER      SET UNRESOLVED EXT.REF.INDIC.   35170000
TEST     TM    NEWSW2,ABS              REL OR ABS RELOCATION NEEDED     35240000
         BO    GET                      ABS. - USE LKA FIELD FROM HESD  35310000
         LR    WORK3,WORK1              REL. - GET RELOC.FACTOR FROM    35380000
         SLL   WORK3,2                       THE REL. RELOC. CONST. TBL 35450000
         A     WORK3,RECNT                                              35520000
GET      L     WORK3,0(WORK3)           GET RELOC FACTOR                35590000
         LA    WORK3,0(WORK3)           CLEAR HIGH ORDER BYTE           35660000
         BR    RETURN                   RETURN                          35730000
*                                                                     * 35800000
*                   OVERLAY RELOCATION  ROUTINE                       * 35870000
*                                                                     * 35940000
SCDOVLY  NI    VCONSW,LN3OFF            INIT 3-BYT VCON SWCH OFF A48242 35990021
         TM    0(RLDSETAD),X'60'        IS IT A V-TYPE ADCON     A48242 36010021
         BC    5,RELOC75               NO,RETURN                        36080000
         TM    0(RLDSETAD),X'10'                                        36150000
         BZ    RELOC75                  NO, RETURN                      36220000
         TM    0(RLDSETAD),X'0C'        IS LENGTH = 4 BYTES             36290000
         BM    ERROR02A                 NO - POSSIBLE ERROR      A48242 36360021
*                                       GO TURN ON SWITCH        A48242 36410021
RETRN    EQU   *                        AND CONTINUE             A48242 36420021
*                                                                     * 36430000
*              OBTAIN  'FROM'  SEGMENT                                * 36500000
*                                                                     * 36570000
         SR    WORK5,WORK5                                              36640000
         NI    0(RLDSETAD),RELREL      SET OFF RELATIVE INDIC.          36710000
         IC    WORK5,4(HESDADDR)        GET SEG. NO. FROM HESD          36780000
*                                                                     * 36850000
*              OBTAIN   'TO'   SEGMENT                                * 36920000
*                                                                     * 36990000
         OI    NEWSW2,ABS              SET ABS. RELOC. INDIC.           37060000
         BAL   RETURN,FRELFAC                                           37130000
         TM    0(RLDSETAD),X'80'        IS RLD MARKED 'UNRESOLVED ER'   37200000
         BO    RELOC75                  YES, RETURN TO NON-OVERLAY      37270000
         LR    WORK3,WORK0                                              37340000
         SLL    WORK3,3                                                 37410000
         A     WORK3,HESD              HESD ADDR OF R PTR               37480000
         SR    WORK1,WORK1                                              37550000
         IC    WORK1,4(WORK3)           GET SEG NO. FROM HESD           37620000
         BAL   RETURN,CPTH              GO TO COMMON PATH ROUTINE       37690000
*                                                                     * 37760000
*        TEST   RESULTS TO DETERMINE TYPE OF CALL                     * 37830000
*                                                                     * 37900000
         IC    WORK1,4(WORK3)                                           37970000
         CLR   WORK5,WORK1                                              38040000
         BE    RELOC75                 UPWARD CALL-NO ENTAB NEEDED      38110000
         IC    WORK1,4(HESDADDR)                                        38180000
         CLR   WORK5,WORK1                                              38250000
         BE    OVLY70                  DOWNWARD CALL-ENTAB NEEDED       38320000
*                                                                     * 38390000
*        TEST TO DETERMINE IF IT IS WITHIN OR ACROSS A REGION         * 38460000
*                                                                     * 38530000
         ST    SAVEAREA,SAVE13         SAVE REG. 13 TEMPORARILY         38600000
         LA    SAVEAREA,OVLY30          INITIALIZE                      38670000
OVLY10   LA    RETURN,4                 LOOP CT = 4 REGIONS             38740000
         LA    WORK5,LSTS                                               38810000
         SR    WORK2,WORK2                                              38880000
OVLY20   IC    WORK2,0(WORK5)           GET HIGHEST SEG OF REGION       38950000
         CLR   WORK1,WORK2              COMPARE TO 'TO' AND 'FROM' SEG  39020000
         BCR   13,SAVEAREA              SEG. IS IN REGION               39090000
         LA    WORK5,1(WORK5)           SEG NOT IN REGION -UPDATE TO    39160000
         BCT   RETURN,OVLY20                 NEXT REGION                39230000
OVLY30   ST    WORK5,TEMPAREA           FOUND REGION FOR 'FROM' SEG     39300000
         LA    SAVEAREA,OVLY40                                          39370000
         IC    WORK1,4(WORK3)           GET 'TO' SEGMENT                39440000
         B     OVLY10                   GO TO FIND ITS REGION           39510000
OVLY40   CL    WORK5,TEMPAREA           ARE SEGMENTS IN SAME REGION     39580000
         L     SAVEAREA,SAVE13         RESTORE REG 13                   39650000
         BNE   OVLY70                   NO                              39720000
*                                                                     * 39790000
*              SEGMENTS IN SAME REGION-TEST FOR EXCLUSIVE CALL        * 39860000
*                                                                     * 39930000
         L     WORK2,SELST                                              40000000
         LH    WORK5,ENELTC                                             40070000
         LTR   WORK5,WORK5                                              40140000
         BZ    RELOC75                 NO ENTRIES-INVALID EXCLUS. CALL  40210000
OVLY50   CH    WORK0,0(WORK2)           ENTRY IN ENTRY LIST FOR CALL    40280000
         BE    OVLY60                   YES                             40350000
         LA    WORK2,6(WORK2)                                           40420000
         BCT   WORK5,OVLY50                                             40490000
         B     RELOC75                  INVALID EXCLUSIVE CALL          40560000
*                                                                     * 40630000
*        PLACE CUR. SEG.NO. AND ENTAB ADDR. INTO ADCON TEXT LOCATION  * 40700000
*                                                                     * 40770000
OVLY60   TM    VCONSW,LEN3              IS IT A 3-BYTE VCON?     A48242 40820021
         BO    ERROR02B                 IF SO, IT IS A ERROR     A48242 40830021
         L     WORK5,ADCONADR           TXT ADDR OF ADCON        A48242 40840021
*        PLACE CUR.SEG.NO. AND ENTAB ADDR INTO ADCON TEXT LOCATION    * 40910000
         MVC   1(3,WORK5),3(WORK2)      ENTAB ENTRY ADDR.               40980000
         MVC   0(1,WORK5),CURSEG+1      CUR. SEG. NO.                   41050000
         B     RELOC110                 RETURN TO RELOCATE              41120000
OVLY70   TM    VCONSW,LEN3              IS IT A 3-BYTE VCON?     A48242 41170021
         BO    ERROR02B                 IF SO, IT IS AN ERROR    A48242 41180021
         LH    WORK5,ENELTC                                      A48242 41190021
         CH    WORK5,ENELTX             ENTRY LIST FULL                 41260000
         LA    RETURN,ERCODE44                                          41330000
         BNL   ERROR                    GO TO ERROR EXIT                41400000
         LTR   WORK5,WORK5              ENTRY LIST EMPTY                41470000
         BZ    OVLY90                   YES                             41540000
*                                                                     * 41610000
*        SCAN ENTRY LIST ON  ID  FOR SAVED R                          * 41680000
*                                                                     * 41750000
         L     WORK2,SELST                                              41820000
OVLY80   CH    WORK0,0(WORK2)           SAVED R = ENTRY LIST ID         41890000
         BE    OVLY60                   YES                             41960000
         LA    WORK2,6(WORK2)                                           42030000
         BCT   WORK5,OVLY80                                             42100000
*                                                                     * 42170000
*        ENTRY LIST FOR ID DOES NOT EXIST - CREATE AN ENTRY           * 42240000
*                                                                     * 42310000
OVLY90   L     WORK2,CURENTRY                                           42380000
         STH   WORK0,0(WORK2)           R PTR TO ENTRY LIST             42450000
         MVC   2(1,WORK2),CURSEG+1      CURRENT SEGMENT TO ENTRY LIST   42520000
         MVC   3(3,WORK2),LKAENTAB+1    ENTAB LKA                       42590000
*                                                                     * 42660000
*        PLACE CUR.SEG.NO.AND ENTAB ADDR.INTO ADCON TEXT LOCATION     * 42730000
*                                                                     * 42800000
         L     WORK5,ADCONADR                                           42870000
         MVC   0(4,WORK5),2(WORK2)      MODIFY VALUE OF ADCON           42940000
         LA    WORK2,6(WORK2)                                           43010000
         ST    WORK2,CURENTRY           UPDATE ENTRY LIST 1ST FREE ADDR 43080000
         L     WORK1,LKAENTAB                                           43150000
         LA    WORK1,12(WORK1)                                          43220000
         ST    WORK1,LKAENTAB           UPDATE TO NEXT ENTAB LINE ADDR. 43290000
         LH    WORK1,ENELTC                                             43360000
         LA    WORK1,1(WORK1)           INC. ENTRY LIST COUNT           43430000
         STH   WORK1,ENELTC                                             43500000
         B     RELOC110                 RETURN TO RELOCATE              43570000
*                                                                     * 43640000
*              SPLIT ADDRESS CONSTANT ROUTINE                         * 43710000
*                                                                     * 43780000
SPLTADCN STM   WORK0,BRANCH,SAVERET    SAVE ALL REGISTERS               43850000
         OI    2(NOTLSENT),SPLT         SET SPLIT ADCON IN RLD SET      43920000
         ST    RLDSETAD,SPLITADR        SAVE START ADDR OF SPLIT RLD    43990000
         L     WORK2,SAVE+16            GET ADDR OF OTHER TEXT CTRL BLK 44060000
         TM    0(WORK2),INUSE           IS IT IN USE                    44130000
         BO    SPLT7                    YES                             44200000
SPLT2    L     WORK3,4(CURTXTCB)        BEG. OF TEXT IN BUFFER          44270000
         L     WORK1,BFREL                                              44340000
         A     WORK1,TXTBFBEG                                           44410000
         S     WORK1,TXTBEG                                             44480000
         ST    WORK1,BFREL             UPDATE BUFFER RELOC. CONSTANT    44550000
         A     WORK1,0(RLDSETAD)                                        44620000
         ST    WORK1,ADCONADR          UPDATE ADCON ADDRESS             44690000
         L     WORK1,TXTBFBEG           BEG. OF TEXT BUFFER             44760000
         ST    WORK1,TXTBEG            UPDATE TEXT BEG. ADDR            44830000
         ST    WORK1,4(CURTXTCB)        UPDATE BEG. OF TEXT IN BUFFER   44900000
         L     WORK5,MULTSIZE           SIZE OF TEXT                    44970000
         LA    WORK4,255                YES                             45040000
SPLT3    CH    WORK5,CON256             MORE THAN 256 BYTES TO MOVE     45110000
         BL    SPLT5                    NO                              45180000
         EX    WORK4,MOVE               MOVE 256 BYTES                  45250000
         SH    WORK5,CON256             DECR TXT SIZE                   45320000
         AH    WORK3,CON256             UPDATE TXT BUFFER PTRS          45390000
         AH    WORK1,CON256                                             45460000
         B     SPLT3                                                    45530000
SPLT5    EQU  *                                                 SA69197 45580021
         LTR  WORK5,WORK5              ANY REMAINDER?           SA69197 45590021
         BNP   SPLT6                   NO, BRANCH               SA69197 45592021
         LR    WORK4,WORK5             YES, GET VALUE           SA69197 45594021
         BCTR  WORK4,0                 DECREMENT COUNT FOR MOVE SA69197 45596021
         EX    WORK4,MOVE              MOVE REMAINDER           SA69197 45598021
         AR    WORK1,WORK5             UPDATE TEXT BUFFER PTR   SA69197 45598421
SPLT6    EQU   *                                                SA69197 45598821
         ST    WORK1,8(CURTXTCB)        UPDATE END OF TEXT IN BUFFER    45600021
         ST    WORK1,FREEADDR          UPDATE 1ST FREE ADDR             45670000
         LR    WORK1,WORK2                                              45740000
         LA    WORK0,1                 LOOKAHEAD READ INDIC             45810000
         L     BRANCHX,ADGET                                            45880000
         BALR  RETURN,BRANCHX           GO TO READ IN NEXT MULT         45950000
SPLT7    TM    0(WORK2),BEINGRD         IS IT BEING READ                46020000
         BO    SPLT8                    YES                             46090000
         TM    0(WORK2),BEINGWT         IS IT BEING WRITTEN             46160000
         BZ    SPLT9                    NO                              46230000
         L     RETURN,ADCHKWRT                                          46300000
         BALR  BRANCHX,RETURN          CHECK WRITE                      46370000
         NI    0(WORK2),WRTCKD          MARK TEXT CTRL BLK NOT IN USE   46440000
         B     SPLT2                       AND NOT BEING WRITTEN        46510000
SPLT8    L     RETURN,ADCHKRD                                           46580000
         BALR  BRANCHX,RETURN          CHECK READ                       46650000
         NI    0(WORK2),RDCKD           MARK TEXT CTRL BLK NOT BEING RD 46720000
SPLT9    LM    WORK0,BRANCH,SAVERET    RESTORE ALL REGISTERS            46790000
         BR    RETURN                   RETURN                          46860000
*                                                                     * 46930000
* DETERMINE THE HIGHEST SEGMENT IN THE COMMON PATH BETWEEN 2 SEGMENTS * 47000000
*                                                                     * 47070000
CPTH     L     WORK2,SGT1                                               47140000
CPTH1    CLR   WORK5,WORK1                                              47210000
         BCR   8,RETURN                 SEGMENTS EQUAL - RETURN         47280000
         BH    CPTH2                                                    47350000
         XR    WORK5,WORK1              SWITCH REGISTERS                47420000
         XR    WORK1,WORK5                                              47490000
         XR    WORK5,WORK1                                              47560000
CPTH2    IC    WORK5,0(WORK2,WORK5)                                     47630000
         LTR   WORK5,WORK5              SEGMENT ENTRY > 0               47700000
         BH    CPTH1                   YES                              47770000
         LA    WORK5,1                  NO, SET SEGMENT = 1             47840000
         BR    RETURN                   RETURN                          47910000
*                                                                     * 47980000
*                                                                     * 48050000
*     MOVE  RELOCATED RLDS FROM INPUT BUFFER TO OUTPUT BUFFER         * 48120000
*                                                                     * 48190000
*                                                                     * 48260000
MVRLD    TM    NEWSW2,SPLTMOVD          CHECK IF SPLIT RLD IN BUFFER    48330000
         BO    MVRLD20                  YES                             48400000
         TM    NEWSW2,GROUPRLD         SHOULD RLDS BE GROUPED           48470000
         BZ    MVRLD00                 NO                               48540000
         NI    NEWSW2,GROUPOFF         SET RLD GROUP INDIC OFF          48610000
         L     OUTRLDCB,SAVEBFCB       USE PREV BUFFER CTRL BLK         48680000
         B     MVRLD30                                                  48750000
*                                                                     * 48820000
*                  FIND  A FREE OUTPUT RLD BUFFER                     * 48890000
*                                                                     * 48960000
MVRLD00  LA    OUTRLDCB,OTRLDCB1        IS BUFFER 1 FREE                49030000
         TM    0(OUTRLDCB),INUSE                                        49100000
         BZ    MVRLD25                  YES                             49170000
         LA    OUTRLDCB,OTRLDCB2        IS BUFFER 2 FREE                49240000
         TM    0(OUTRLDCB),INUSE                                        49310000
         BZ    MVRLD25                  YES                             49380000
         LA    OUTRLDCB,OTRLDCB3        IS BUFFER 3 FREE                49450000
         TM    0(OUTRLDCB),INUSE                                        49520000
         BZ    MVRLD25                  YES                             49590000
         TM    0(OUTRLDCB),BEINGWT      IS BUFFER 3 BEING WRITTEN       49660000
         BO    MVRLD10                  YES                             49730000
         LA    OUTRLDCB,OTRLDCB2        IS BUFFER 2 BEING WRITTEN       49800000
         TM    0(OUTRLDCB),BEINGWT                                      49870000
         BO    MVRLD10                  YES                             49940000
         LA    OUTRLDCB,OTRLDCB1        IS BUFFER 1 BEING WRITTEN       50010000
         TM    0(OUTRLDCB),BEINGWT                                      50080000
         BZ    MVRLD210                 NO, ALL BUFFERS IN USE - WRITE  50150000
MVRLD10  L     RETURN,ADCHKWRT                                          50220000
         BALR  BRANCHX,RETURN          BRANCH TO CHECK WRITE            50290000
         NI    0(OUTRLDCB),WRTCKD       WRITE CHECKED -CB NOT IN USE    50360000
         B     MVRLD25                                                  50430000
MVRLD20  L     OUTRLDCB,CBTOUSE         CB.ADDR.FOR BFR.WITH SPLIT RLD  50500000
         NI    NEWSW2,MOVDOFF           TURN OFF SPLIT RLD MOVED INDIC. 50570000
         B     MVRLD28                                                  50640000
MVRLD25  L     WORK2,8(OUTRLDCB)        GET BEG. ADDR. OF BUFFER        50710000
         XC    0(16,WORK2),0(WORK2)     CLEAR THE CONTROL RECORD        50780000
         MVC   4(4,OUTRLDCB),8(OUTRLDCB) FIRST FREE ADDR= BFR.BEG.      50850000
MVRLD28  MVC   TEMP(1),1(OUTRLDCB)                                      50920000
         XI    TEMP,X'FF'               FLIP BITS                       50990000
         NI    TEMP,X'38'               ALL BITS OFF EXCEPT BFR. INDIC. 51060000
         OC    1(1,CURTXTCB),TEMP       ASSOCIATE BFR. WITH TXTCB       51130000
         OI    0(OUTRLDCB),INUSE        MARK OUTPUT CB USED             51200000
         XC    2(2,OUTRLDCB),2(OUTRLDCB) ZERO ID LENGTH FIELD           51270000
MVRLD30  TM    NEWSW2,RPSAVED           HAVE R AND P PTRS.BEEN SAVED    51340000
         BO    MVRLD100                                                 51410000
*                                                                     * 51480000
*        DETERMINE IN WHICH BUFFER THE PROCESSED RLDS ARE             * 51550000
*                                                                     * 51620000
MVRLD35  TM    2(CURTXTCB),BUF1PROC     PROCESSED RLDS IN BUFFER 1      51690000
         LA    INRLDCB,INRLDCB1                                         51760000
         BO    MVRLD40                  YES                             51830000
         TM    2(CURTXTCB),BUF2PROC     PROCESSED RLDS IN BUFFER 2      51900000
         LA    INRLDCB,INRLDCB2                                         51970000
         BO    MVRLD40                  YES                             52040000
         TM    NEWSW2,MORERLDS         ARE THERE MORE RLDS FOR TEXT     52110000
         BZ    MVRLD36                 NO, CHECK FOR EMPTY BUFFER       52180000
         OI    NEWSW2,GROUPRLD         YES, SET RLD GROUP INDIC.        52250000
         ST    OUTRLDCB,SAVEBFCB       SAVE CTRL BLK ADDRESS            52320000
         B     MVRLD37                                                  52390000
MVRLD36  L     WORK2,4(OUTRLDCB)       FIRST FREE ADDRESS               52460000
         LR    WORK1,OUTRLDCB                                           52490000
         CL    WORK2,8(OUTRLDCB)       HAS ANYTHING BEEN ADDED TO BFR   52530000
         BNE   MVRLD37                 YES                              52600000
         NI    0(WORK2),RLDOFF         NO, TURN RLD INDIC. OFF          52670000
         NI    0(OUTRLDCB),NOTINUSE    MARK CTRL BLK NOT IN USE         52740000
         NC    1(1,CURTXTCB),1(OUTRLDCB)                                52810000
MVRLD37  LM    2,15,SAVE+8             RESTORE REGISTER 0,2-15          52850000
         L     0,SAVE                                                   52890000
         BR    RETURN                   RETURN,ALL RELOCATED RLDS MOVED 52950000
*                                                                     * 53020000
*          IDENTIFY NOTELIST ENTRY PERTAINING TO THE RLDS THAT        * 53090000
*                  ARE TO BE MOVED                                    * 53160000
*                                                                     * 53230000
MVRLD40  L     WORK2,8(OUTRLDCB)                                        53300000
         OI    0(WORK2),RLD             SET RLDS PRESENT INDIC IN CR    53370000
         L     NOTLSENT,8(INRLDCB)      ADDR. OF 1ST NOTELIST ENTRY     53440000
MVRLD50  CLC   0(2,NOTLSENT),CURID     ENTRY ID = CURRENT ID            53510000
         BNE   MVRLD60                                                  53580000
         TM    2(NOTLSENT),JUSTPROC     RLD SET HAS RELOC.RLDS TO MOVE  53650000
         BO    MVRLD80                  YES                             53720000
MVRLD60  LA    NOTLSENT,9(NOTLSENT)     UPDATE TO NEXT ENTRY            53790000
         CL    NOTLSENT,16(INRLDCB)     ALL RLDS MOVED FROM BUFFER      53860000
         BNH   MVRLD50                  NO                              53930000
         L     WORK2,4(OUTRLDCB)                                        54000000
         AH    WORK2,TWELVE                                             54070000
         NI    0(WORK2),CONTOFF        SET CONT. OFF IN LAST FA FIELD   54140000
         TM    0(INRLDCB),BUF2          ALL RLDS MOVED FROM INPUT BFR2  54210000
         BO    MVRLD70                  YES                             54280000
         NI    2(CURTXTCB),BUF1OFF      NO RLDS IN BFR1 FOR CURR. TEXT  54350000
         B     MVRLD35                                                  54420000
MVRLD70  NI    2(CURTXTCB),BUF2OFF      NO RLDS IN BFR2 FOR CURR. TEXT  54490000
         B     MVRLD35                                                  54560000
MVRLD80  NI    2(NOTLSENT),JUSTOFF      TURN RLDS TO MOVE INDIC. OFF    54630000
         ST    NOTLSENT,12(INRLDCB)                                     54700000
*                                                                     * 54770000
*    CALCULATE  ADDRESS AND EXTENT OF RLD SET IN BUFFER               * 54840000
*                                                                     * 54910000
         MVC   TEMPAREA(2),4(NOTLSENT)  LENGTH OF RLD SET               54980000
         LH    WORK2,TEMPAREA                                           55050000
         SLL   WORK2,2                  MULT. TO GET BYTES OF RLD       55120000
         CL    NOTLSENT,8(INRLDCB)     IS THIS 1ST ENTRY FOR BUFFER     55190000
         BNE   MVRLD90                 NO                               55260000
         L     RLDSETAD,4(INRLDCB)     YES USE BEG. OF BUFFER           55330000
         B     MVRLD95                                                  55400000
MVRLD90  SH    NOTLSENT,THREE                                           55470000
         MVC   TEMPAREA+1(3),0(NOTLSENT) GET DISP.OF RLDS FROM BFR.BEG. 55540000
         L     RLDSETAD,TEMPAREA                                        55610000
         LA    RLDSETAD,0(RLDSETAD)     CLEAR HIGH ORDER BYTES          55680000
         SLL   RLDSETAD,2                                               55750000
         A     RLDSETAD,4(INRLDCB)      ADDR. OF RLD SET IN BUFFER      55820000
MVRLD95  AR    WORK2,RLDSETAD                                           55890000
         ST    WORK2,RLDSTEND           SAVE RLD SET END ADDR.          55960000
*                                                                     * 56030000
*      CALCULATE BEGIN AND END OF TEXT                                * 56100000
*                                                                     * 56170000
         LH    WORK2,CURMULT                                            56240000
         MH    WORK2,MULTSIZE+2         DISPLACEMENT FROM BEG. OF CSECT 56310000
         LH    WORK1,CURID                                              56380000
         SLL   WORK1,3                                                  56450000
         A     WORK1,HESD                                               56520000
         L     WORK3,0(WORK1)                                           56590000
         LA    WORK3,0(WORK3)                                           56660000
         AR    WORK2,WORK3              DISPLACEMENT FROM BEG.OF MODULE 56730000
         ST    WORK2,MULTBEG            START DISP. OF MULT.            56800000
         A     WORK2,MULTSIZE                                           56870000
         ST    WORK2,MULTEND            END  DISP. OF  MULT.            56940000
*                                                                     * 57010000
*    CHECK FOR SPLIT RLD FROM PREVIOUS TEXT AND FOR SPLIT RLD         * 57080000
*                      IN CURRENT TEXT                                * 57150000
*                                                                     * 57220000
         NI    NEWSW2,NOTINBFR         TURN OFF R+P IN BFR.             57290000
         MVI   RPPTRS,X'FF'             SET PREV. R PTR TO HIGHEST R    57360000
         TM    NEWSW2,SPLTMOVD          HAS SPLIT RLD BEEN MOVED TO BFR 57430000
         BZ    MVRLD100                                                 57500000
         L     WORK2,8(OUTRLDCB)                                        57570000
         MVC   RPPTRS(2),16(WORK2)     SET R PTR TO SPLIT RLD R PTR     57640000
         OI    NEWSW2,RPINBFR           TURN ON  R+P IN BFR. INDICATOR  57710000
MVRLD100 L     NOTLSENT,12(INRLDCB)     NOTELIST ENTRY ADDR.            57780000
MVRLD102 TM    NEWSW2,RPSAVED           R+P SAVED FROM PREV RLD RECORD  57850000
         BZ    MVRLD105                 NO                              57920000
         NI    NEWSW2,RPSAVOFF          SET R+P SAVED INDIC OFF         57990000
         L     RLDSETAD,RESUMEAD        GET ADDR OF CHAIN               58060000
         B     MVRLD120                                                 58130000
MVRLD105 MVC   RSAVE(2),0(RLDSETAD)                                     58410000
         TM    RSAVE,X'80'             IS R PTR MARKED DELINK           58480000
         BZ    MVRLD110                NO                       SA69469 58550021
         NI    RSAVE,X'7F'             TURN OFF DELINK BIT              58620000
         SR    WORK2,WORK2             CLEAR REGISTER            A28315 58650000
         LH    WORK2,RSAVE                                              58690000
         MH    WORK2,FIVE                                               58760000
         A     WORK2,DLKT              DELINK TABLE ENTRY FOR R PTR     58830000
         MVC   RSAVE(2),0(WORK2)       UPDATE R PTR                     58900000
MVRLD110 LA    RLDSETAD,4(RLDSETAD)     UPDATE TO FA FIELD              59530000
MVRLD120 TM    0(RLDSETAD),PROC         IS RLD PROCESSED                59600000
         BZ    MVRLD140                 NO                              59670000
         TM    2(NOTLSENT),SPLT         IS THERE A SPLIT RLD IN SET     59740000
         BZ    MVRLD121                NO                               59810000
         CL    RLDSETAD,SPLITADR       IS THIS A SPLIT RLD              59880000
         BE    MVRLD145                YES                              59950000
MVRLD121 L     WORK2,0(RLDSETAD)        GET RLD ADD?                    60020000
         LA    WORK2,0(WORK2)                                           60090000
*                                                                     * 60160000
*    CHECK IF  RLD REFERS TO CURRENT MULTIPLICITY                     * 60230000
*                                                                     * 60300000
         CL    WORK2,MULTBEG                                            60370000
         BL    MVRLD140                                                 60440000
         CL    WORK2,MULTEND                                            60510000
         BNL   MVRLD140                                                 60580000
         TM    NEWSW2,RPINBFR           ARE R+P PTRS.ALREADY IN BUFFER  60650000
         L     WORK2,4(OUTRLDCB)        FIRST FREE ADDR                 60720000
         BO    MVRLD125                 YES                             60790000
*                                                                     * 60800021
*      CHECK IF RLDS CAN BE CHAINED WITH PREVIOUS RLDS                  60810021
*                                                                     * 60820021
MVRLD106 CLC   RPPTRS(2),RSAVE         DOES PREV R = NEW R      SA69469 60840021
         BNE   MVRLD108                 NO                      SA69469 60850021
         CL    WORK2,8(OUTRLDCB)       ANYTHING IN BUFFER       SA69469 60854021
         BE    MVRLD108                NO                       SA69469 60856021
         OI    NEWSW2,RPINBFR          SET R AND P IN BUFFER    SA69469 60858021
         OI    12(WORK2),CONT          SET CONT BIT IN PREV FA  SA69469 60858421
         B     MVRLD123                                         SA69469 60859621
MVRLD108 MVC   RPPTRS(2),RSAVE         SAVE NEW R PTR           SA69469 60859721
*                                                                     * 60860000
*          CHECK IF ROOM IN OUTPUT RLD BUFFER                         * 60930000
*                                                                     * 61000000
MVRLD123 EQU   *                                                SA69469 61050021
         CLC   4(4,OUTRLDCB),12(OUTRLDCB) IS THERE ROOM FOR R-P PTR.    61070000
         BNL   MVRLD180                 NO                              61140000
         L     WORK3,12(OUTRLDCB)                                       61210000
         SH    WORK3,EIGHT                                              61280000
         CR    WORK2,WORK3              IS THERE ROOM TO ADD R+P AND FA 61350000
         BH    MVRLD180                 NO                              61420000
         CL    WORK2,8(OUTRLDCB)       1ST ENTRY IN BUFFER              61490000
         BE    MVRLD122                YES                              61560000
         NI    12(WORK2),CONTOFF       MAKE SURE CONT. INDIC OFF        61630000
MVRLD122 MVC   16(4,WORK2),RPPTRS      MOVE R+P TO OUTPUT BUFFER        61700000
         LA    WORK2,4(WORK2)                                           61770000
         ST    WORK2,4(OUTRLDCB)        UPDATE 1ST FREE ADDR.           61840000
         OI    NEWSW2,RPINBFR           SET INDICATOR  R+P  IN BFR      61910000
         B     MVRLD130                                                 61980000
MVRLD125 CLC   4(4,OUTRLDCB),12(OUTRLDCB) IS THERE ROOM TO ADD FA       62050000
         BNL   MVRLD170                 NO                              62120000
         OI    12(WORK2),CONT          MAKE SURE CONT INDIC ON          62190000
*                                                                     * 62260000
*         MOVE RLD INFORMATION FROM INPUT TO OUTPUT BUFFER            * 62330000
*                                                                     * 62400000
MVRLD130 MVC   16(4,WORK2),0(RLDSETAD) MOVE FA TO OUTPUT BUFFER         62470000
         NI    16(WORK2),PROCOFF       TURN OFF PROCESSED INDICATOR     62540000
         LA    WORK2,4(WORK2)                                           62610000
         ST    WORK2,4(OUTRLDCB)        UPDATE 1ST FREE ADDR.           62680000
MVRLD140 TM    0(RLDSETAD),CONT         IS RLD MARKED CONTINUATION      62750000
         BZ    MVRLD160                 NO                              62820000
         B     MVRLD110                YES                              62890000
MVRLD145 L     WORK2,HESD                                               62960000
         MVC   0(4,WORK2),RPPTRS        MOVE SAVED R+P PTRS TO HESD     63030000
         MVC   4(4,WORK2),0(RLDSETAD)   MOVE FA FIELD                   63100000
         NI    4(WORK2),X'BE'           TURN PROC. AND CONT BITS OFF    63170000
         OI    NEWSW2,SPLITRLD          SET SPLIT RLD SAVED IN HESD     63240000
         NI    2(NOTLSENT),SPLTOFF      TURN SPLIT RLD IN SET OFF       63310000
         TM    0(RLDSETAD),CONT         IS CONT. INDICATED              63380000
         BO    MVRLD110                                                 63450000
MVRLD160 NI    NEWSW2,NOTINBFR          TURN OFF R+P IN BFR. INDIC.     63520000
         LA    RLDSETAD,4(RLDSETAD)     UPDATE TO NEXT R+P FIELD        63590000
         CL    RLDSETAD,RLDSTEND        ARE RLDS ALL MOVED FROM SET     63660000
         BL    MVRLD100                 NO                              63730000
         L     WORK2,8(OUTRLDCB)       BUFFER BEGINNING                 63800000
         L     WORK3,4(OUTRLDCB)       1ST FREE ADDR                    63870000
         OI    0(WORK2),RLD            SET RLDS PRESEND INDIC           63940000
         SR    WORK3,WORK2                                              64010000
         ST    WORK3,4(WORK2)          STORE RLD BYTE COUNT IN BUFFER   64080000
         TM    0(CURTXTCB),LASTXT      IS TEXT LAST IN GROUP            64150000
         BO    MVRLD60                 YES                              64220000
         OI    NEWSW2,GROUPRLD         SET RLDS TO BE GROUPED INDIC     64290000
         ST    OUTRLDCB,SAVEBFCB       SAVE CTRL BLK ADDR               64360000
         B     MVRLD60                  YES, DET.IF MORE SETS IN GROUP  64430000
*                                            TO BE MOVED                64500000
*                                                                     * 64570000
* THE RLD OUTPUT BUFFER IS FULL --COMPLETE INFORMATION IN BUFFER      * 64640000
*        CONTROL RECORD AND BUFFER CONTROL BLOCK                      * 64710000
*                                                                     * 64780000
MVRLD170 L     WORK2,12(OUTRLDCB)                                       64850000
MVRLD180 ST    RLDSETAD,RESUMEAD        SAVE ADDR.OF WHERE TO RESUME    64880000
         NI    12(WORK2),CONTOFF        SET CONT. OFF IN PREV FA FIELD  64920000
         OI    NEWSW2,RPSAVED           SET R+P SAVED INDICATOR         65060000
         NI    NEWSW2,NOTINBFR         TURN OFF R-P IN BFR.             65130000
         L     WORK2,8(OUTRLDCB)        BUFFER BEGINNING                65200000
         L     WORK3,4(OUTRLDCB)        1ST FREE ADDR                   65270000
         OI    0(WORK2),RLD             SET RLDS PRESENT INDIC          65340000
         SR    WORK3,WORK2                                              65410000
         ST    WORK3,4(WORK2)           STORE RLD BYTE COUNT IN BUFFER  65480000
         B     MVRLD00                  GO TO FIND FREE OUTPUT BUFFER   65550000
*                                                                     * 65620000
*      ALL RLD OUTPUT BUFFERS ARE FULL- FREE ONE FOR USE              * 65690000
*                                                                     * 65760000
MVRLD210 TM    1(CURTXTCB),PREV         CHECK IF ONE CONTAINS THE       65830000
         BC    7,MVRLD230                    1D-LENGTH LIST             65900000
         TM    1(CURTXTCB),XDAP         HAS DUMMY WRITE BEEN WRITTEN    65970000
         BO    MVRLD220                 YES                             66040000
         TM    NEWSW2,MORERLDS          ARE THE MORE RLDS TO PROCESS    66110000
         BZ    MVRLD260                 NO                              66180000
         OI    1(CURTXTCB),DUMMY        SET DUMMY WRITE INDICATOR       66250000
         L     BRANCHX,ADWRTTXT                                         66320000
         BALR  RETURN,BRANCHX           BRANCH TO WRITE DUMMY TXT       66390000
         OI    1(CURTXTCB),XDAP         SET XDAP INDICATOR              66460000
MVRLD220 LA    WORK1,OTRLDCB1          WRITE RLD RECORD 1               66530000
         L     WORK4,SAVE+16           RESTORE NEXT TXTCB ADDR FOR      66600000
*                                            WRTCRRLD CHECK             66670000
         L     BRANCHX,ADWRTCR                                          66740000
         BALR  RETURN,BRANCHX           BRANCH TO WRITE RLD RECORD      66810000
         NC    1(1,CURTXTCB),1(WORK1)    TAKE CR REC OFF TXTCB          66880000
         B     MVRLD00                  RETURN TO CONTINUE MOVES        66950000
*                                                                       67020000
MVRLD230 L     WORK1,SAVE+32           ADDR OF PREV. CONTROL RECORD CB  67090000
         OI    0(CURTXTCB),LASTXT       SET LAST TEXT IN GROUP          67160000
         L     WORK2,SAVE+16            NEXT TEXT CONTROL BLOCK         67230000
         TM    0(WORK2),INUSE           HAS SOME TEXT BEEN READ AHEAD   67300000
         BO    MVRLD250                 YES                             67370000
         XC    GROUPLNG(2),GROUPLNG    CLEAR GROUP LENGTH               67440000
MVRLD240 L     BRANCHX,ADWRTCR                                          67510000
         L     WORK4,SAVE+16           RESTORE NEXT TXTCB ADDR FOR      67580000
*                                            WRTCRRLD CHECK             67650000
         BALR  RETURN,BRANCHX           BRANCH TO WRITE PREV CTRL. REC. 67720000
         NC    1(1,CURTXTCB),1(WORK1)    TAKE CR REC OFF TXTCB          67790000
         B     MVRLD00                  RETURN TO CONTINUE MOVES        67860000
MVRLD250 TM    0(WORK2),BEINGWT         IS IT BEING WRITTEN             67930000
         BO    MVRLD240                 YES                             68000000
         OI    0(WORK2),FIRSTXT         SET 1ST TEXT IN GROUP INDIC.    68070000
         MVC   26(2,WORK2),24(WORK2)   CORRECT GROUP LENGTH             68140000
         L     WORK0,8(WORK2)                                           68210000
         SH    WORK0,24(WORK2)                                          68280000
         ST    WORK0,4(WORK2)          UPDATE BEG OF TEXT               68350000
         ST    WORK0,PREVBEG           UPDATE BEG. ADDR OF TEXT GROUP   68420000
         MVC   29(3,WORK2),CCWDISP+1   UPDATE CCW DISP                  68490000
         MVC   GROUPLNG(2),24(WORK2)   UPDATE LNG FOR GROUPING          68560000
         B     MVRLD240                                                 68630000
MVRLD260 TM    0(CURTXTCB),TESTWRT      HAS TEXT BEEN WRITTEN YET       68700000
         BC    11,MVRLD220              YES, GO TO WRITE RLD RECORD     68770000
         L     BRANCHX,ADWRTTXT                                         68840000
         BALR  RETURN,BRANCHX           BRANCH TO WRITE TEXT            68910000
         B     MVRLD220                                                 68980000
*                                                                     * 69050000
*                        ERROR  ROUTINES                              * 69120000
*                                                                     * 69190000
ERROR01  OI    BITMAP+7,HEX1      SET INVALID TWO BYTE ADCON     A22109 69260000
         B     RELOC120                 RETURN TO PROCESS NEXT ADCON    69330000
ERROR02A OI    VCONSW,LEN3              TURN ON 3-BYTE VCON SW   A48242 69380021
         B     RETRN                    AND CONTINUE PROCESSING  A48242 69390021
ERROR02B NI    VCONSW,LN3OFF            TURN OFF 3-BYTE VCON SW  A48242 69392021
ERROR02  OI    BITMAP+7,HEX2      SET INVALID VCON IN OVERLAY    A22109 69400000
         B     RELOC120                 RETURN TO PROCESS NEXT ADCON    69470000
ERROR    L     BRANCH,ERDIG                                             69540000
         LR    WORK0,RETURN             ERROR CODE                      69610000
         BR    BRANCH                   GO TO ERROR DIAGNOSTICS ROUTINE 69680000
***    *     *     *    *    *    *    *    *    *    *    *    *   *** 69750000
*                                                                     * 69820000
*              ENTAB AND ENTAB/RLD CREATION ROUTINE                   * 69890000
*                                                                     * 69960000
***    *     *     *    *    *    *    *    *    *    *    *    *   *** 70030000
SCDENTAB EQU   *                                                        70100000
         ST    RETURN,SAVERET                                           70170000
         L     WORK2,CURENTAB           HESD ADDR.OF CURRENT ENTAB      70240000
         LR    WORK3,WORK2                                              70310000
         S     WORK2,HESD                                               70380000
         SRL   WORK2,3                                                  70450000
         STH   WORK2,CURID              CALC. ENTAB ID                  70520000
*                                                                     * 70590000
*   MAKE ID-LENGTH LIST ENTRY FOR ENTAB, THEN WRITE THE CONTROL       * 70660000
*   RECORD.  THERE IS ALWAYS ROOM FOR THE ENTAB ID-LENGTH, BECAUSE    * 70730000
*           4 BYTES ARE LEFT IN EVERY RLD RECORD                      * 70800000
*                                                                     * 70870000
         TM    0(PREVCREC),INUSE       DOES PREV CR CONTAIN RLDS        70940000
         BO    SCDENT10                YES                              71010000
         MVC   4(4,PREVCREC),8(PREVCREC) INIT 1ST FREE ADDR             71080000
         OI    0(PREVCREC),INUSE                                        71150000
         L     WORK2,8(PREVCREC)       BEG. OF BUFFER                   71220000
         XC    0(16,WORK2),0(WORK2)    CLEAR THE CONTROL INFOR          71290000
SCDENT10 L     WORK2,4(PREVCREC)        1ST FREE ADDR IN PREV. CR       71360000
         MVC   16(2,WORK2),CURID        MAKE ID-LENGTH LIST ENTRY IN    71430000
         MVC   18(2,WORK2),6(WORK3)          PREV. CR.                  71500000
         MVI   3(PREVCREC),X'04'        ID-LENGTH =4                    71570000
         L     WORK2,8(PREVCREC)                                        71640000
         OI    0(WORK2),TXT             SET TEXT FOLLOWS IN CR          71710000
         MVC   26(2,CURTXTCB),6(WORK3)  LENGTH OF ENTAB TO CB           71780000
         MVC   9(3,WORK2),1(WORK3)      MOVE LKA TO CR                  71850000
         MVC   LKAENTAB+1(3),1(WORK3)  GET LKA ADDR                     71920000
         OI    8(WORK2),X'06'                                           71990000
         MVC   14(2,WORK2),6(WORK3)     ENTAB LENGTH TO CR              72060000
         OI    12(WORK2),X'40'                                          72130000
         LR    WORK1,PREVCREC                                           72200000
         L     BRANCHX,ADWRTCR                                          72270000
         BALR  RETURN,BRANCHX           GO TO WRITE PREV CTRL REC       72340000
         NC    1(1,CURTXTCB),1(PREVCREC) TAKE CR REC OFF TXTCB          72410000
*                                                                     * 72480000
*         CREATE ENTAB AND WRITE IT                                   * 72550000
*                                                                     * 72620000
         L     WORK1,TXTBFBEG           BEGINNING OF TEXT BUFFER        72690000
         ST    WORK1,4(CURTXTCB)        BEG.OF TEXT IN CB               72760000
         LH    WORK0,26(CURTXTCB)       LENGTH OF ENTAB                 72830000
         SH    WORK0,TWELVE             INIT.  DISP.                    72900000
         L     WORK3,SELST              START OF ENTRY LIST             72970000
SCDENT15 MVC   0(2,WORK1),BRINST        SET IN 1ST 2 BYTES OF ENTAB     73040000
         STH   WORK0,2(WORK1)           SET IN DISP.                    73110000
SCDENT20 CLC   CURSEG+1(1),2(WORK3)     SEARCH ENTRY LIST FOR CUR.SEG.  73180000
         BNE   SCDNT25A                NOT FOUND                 A36529 73280021
SCDENT25 LH    WORK2,0(WORK3)                                           73460000
         SLL   WORK2,3                                                  73530000
         A     WORK2,HESD                                               73600000
         XC    4(8,WORK1),4(WORK1)                                      73670000
         MVC   5(4,WORK1),1(WORK2)      MOVE ADDR. AND SEG.NO.TO ENTAB  73740000
         LA    WORK1,12(WORK1)          INCR.TO NEXT LINE IN ENTAB      73810000
         SH    WORK0,TWELVE             DECR. DISP                      73880000
         BZ    SCDENT30                 BRANCH WHEN OFFSET =0           73950000
SCDNT25A LH    WORK2,ENELTC            NO. ENTS IN ENTRY LIST    A36529 73960021
         MH    WORK2,SIX               MULTIPLY BY 6             A33441 73970021
         A     WORK2,SELST             ADD TO LIST BEG ADDR      A33441 73980021
         LA    WORK3,6(WORK3)          INCR TO NEXT LIST ENTRY   A36529 73985021
         CR    WORK3,WORK2             SEARCHED THRU WHOLE LIST? A33441 73990021
         BNL   SCDENT31                YES                       A33441 74000021
         B     SCDENT15                                                 74090000
SCDENT31 LA    WORK1,12(WORK1)         UPDATE ENTAB ENTRY ADDR   A33441 74100021
         SH    WORK0,TWELVE            END OF ENTAB?             A33441 74110021
         BZ    SCDENT30                YES-GO TO CREATE LST LINE A33441 74120021
         B     SCDENT31                NO-BRANCH BACK            A33441 74130021
SCDENT30 ST    WORK1,8(CURTXTCB)        LAST ENTRY ADDR.                74160000
         MVC   0(8,WORK1),SVCLINE       SET UP LAST LINE OF ENTAB       74230000
         LH    WORK3,ENSPX              GET SEGTAB ID                   74300000
         SLL   WORK3,3                                                  74370000
         A     WORK3,HESD                                               74440000
         MVC   9(3,WORK1),1(WORK3)      MOVE SEGTAB ADDR TO ENTAB       74510000
         MVC   8(1,WORK1),CURSEG+1      CURRENT SEG.NO. TO ENTAB        74580000
         NI    1(CURTXTCB),X'00'        CLEAR FLAG BITS OF TXTCB        74650000
         L     BRANCHX,ADWRTTXT                                         74720000
         BALR  RETURN,BRANCHX           BRANCH TO WRITE ENTAB           74790000
*                                                                     * 74860000
*    CREATE ENTAB RLDS IN OUTPUT BUFFER AND WRITE THEM OUT            * 74930000
*                                                                     * 75000000
         LA    PREVCREC,OTRLDCB1        USE BFR1 AND BFR2               75070000
         LA    WORK3,OTRLDCB2                                           75140000
         L     WORK1,LKAENTAB           ADDR. OF BEG.OF ENTAB           75210000
         LA    WORK1,4(WORK1)           INCR. TO FIRST LKA              75280000
         LH    WORK0,26(CURTXTCB)                                       75350000
         A     WORK0,LKAENTAB                                           75420000
         SH    WORK0,TWELVE             ADDR.OF LAST ENTRY IN ENTAB     75490000
SCDENT50 L     WORK2,8(PREVCREC)        ADDR. OF RLD BFR.BEG.           75560000
         OI    0(PREVCREC),INUSE       MARK RLD CTRL BLK IN USE         75630000
         XC    0(16,WORK2),0(WORK2)     CLEAR CTRL.REC.                 75700000
         MVC   4(4,PREVCREC),8(PREVCREC)                                75770000
         OI    0(WORK2),RLD             SET RLDS PRESENT INDIC.         75840000
         XC    16(2,WORK2),16(WORK2)    SET R PTR.TO ZERO               75910000
         MVC   18(2,WORK2),CURID        SET P PTR = ENTAB ID            75980000
SCDENT60 LA    WORK2,4(WORK2)           UPDATE 1ST FREE ADDR.           76050000
         CL    WORK2,12(PREVCREC)       ROOM FOR 4 BYTES IN BUFFER      76120000
         BNL   SCDENT80                 NO                              76190000
         ST    WORK1,16(WORK2)          MAKE RLD FA FIELD FOR ENTAB     76260000
         MVI   16(WORK2),X'1D'               ENTRY                      76330000
         LA    WORK1,12(WORK1)          UPDATE TO NEXT LKA FIELD        76400000
         CR    WORK1,WORK0              RLD FOR EACH 12 BYTES OF ENTAB  76470000
         BL    SCDENT60                 NO                              76540000
         AH    WORK1,FIVE               INCR. TO SEGTAB ADDR.           76610000
         ST    WORK1,20(WORK2)          UPDATE LAST RLD ITEM TO POINT   76680000
         MVI   20(WORK2),X'18'               TO SEGTAB ADDR.            76750000
         L     WORK1,8(PREVCREC)        BEG.OF BFR.                     76820000
         LA    WORK2,8(WORK2)          UPDATE FOR LAST 2 RLD ENTRIES    76890000
         S     WORK2,8(PREVCREC)        RLD BYTES                       76960000
         STH   WORK2,6(WORK1)           SET RLD BYTES IN CR.            77030000
         OI    0(WORK1),SEGEND          SET END OF SEG.INDIC.IN CR      77100000
         CLC   CURSEG(2),ENSPC          IS THIS LAST SEGMENT            77170000
         BNE   SCDENT70                 NO                              77240000
         OI    0(WORK1),MODEND          YES,SET END OF MOD. INDIC.IN CR 77310000
SCDENT70 LR    WORK1,PREVCREC                                           77380000
         L     BRANCHX,ADWRTCR                                          77450000
         BALR  RETURN,BRANCHX           BRANCH TO WRITE RLD RECORD      77520000
         NC    1(1,CURTXTCB),1(PREVCREC) TAKE CR REC OFF TXTCB          77590000
         L     WORK1,CURENTAB                                           77660000
         LA    WORK1,8(WORK1)           UPDATE TO NEXT ENTAB ENTRY      77730000
         ST    WORK1,CURENTAB                                           77800000
         MVC   LKAENTAB+1(4),1(WORK1)  GET LKA AND SEG NO OF NEXT ENTAB 77870000
         OI    APT3,SEGSTART           SET 1ST TEXT OF SEG INDIC        77940000
         XC    0(3,CURTXTCB),0(CURTXTCB)  CLEAR INDIC IN CURR. TXT CB   78010000
         XC    GROUPLNG(2),GROUPLNG    INIT GROUP CT. FOR NEXT SEG.     78080000
         L     RETURN,SAVERET                                           78150000
         BR    RETURN                   RETURN TO PROCESS NEXT SEGMENT  78220000
SCDENT80 S     WORK2,8(PREVCREC)        BYTES OF RLD                    78290000
         ST    WORK1,TEMPAREA          SAVE ADDR OF ADCON               78360000
         L     WORK1,8(PREVCREC)                                        78430000
         STH   WORK2,6(WORK1)           BYTES OF RLD INFO IN CR         78500000
         LR    WORK1,PREVCREC                                           78570000
         L     BRANCHX,ADWRTCR                                          78640000
         BALR  RETURN,BRANCHX           BRANCH TO WRITE AN RLD RECORD   78710000
         NC    1(1,CURTXTCB),1(PREVCREC) TAKE CR REC OFF TXTCB          78780000
         XR    PREVCREC,WORK3           SWITCH BUFFERS                  78850000
         XR    WORK3,PREVCREC                                           78920000
         XR    PREVCREC,WORK3                                           78990000
         L     WORK1,TEMPAREA          RESTORE ADDRESS OF ADCON         79060000
         B     SCDENT50                                                 79130000
MOVE     MVC   0(1,WORK1),0(WORK3)                                      79200000
*                     ******************                                79270000
         DS    0F                                                       79340000
TXTCB1   EQU   *                   TEXT CONTROL BLOCK                   79410000
         DC    F'0'                FLAGS                                79480000
         DC    F'0'                BEGINNING ADDRESS OF TEXT IN BUFFER  79550000
         DC    F'0'                END ADDRESS OF TEXT IN BUFFER        79620000
         DC    F'0'                ADDRESS OF TXTIOT ENTRY MARKING THE  79690000
*                                       BEGINNING OF THE TEXT GROUPING  79760000
         DC    F'0'                ADDRESS OF TXTIOT ENTRY FOR TEXT     79830000
*                                       BEING PROCESSED                 79900000
         DC    F'0'                ADDRESS OF TXTIOT ENTRY MARKING THE  79970000
*                                       END OF THE TEXT GROUPING        80040000
         DC    H'0'                LENGTH OF CURRENT TEXT               80110000
           DC    H'0'                ACCUMULATED TEXT LENGTH            80180000
         DC    F'0'                    CCW DISPLACEMENT                 80250000
TXTCB2   EQU   *                   TEXT CONTROL BLOCK                   80320000
         DC    F'0'                FLAGS                                80390000
         DC    F'0'                BEGINNING ADDRESS OF TEXT IN BUFFER  80460000
         DC    F'0'                END ADDRESS OF TEXT IN BUFFER        80530000
         DC    F'0'                ADDRESS OF TXTIOT ENTRY MARKING THE  80600000
*                                       BEGINNING OF THE TEXT GROUPING  80670000
         DC    F'0'                ADDRESS OF TXTIOT ENTRY FOR TEXT     80740000
*                                       BEING PROCESSED                 80810000
         DC    F'0'                ADDRESS OF TXTIOT ENTRY MARKING THE  80880000
*                                       END OF THE TEXT GROUPING        80950000
         DC    H'0'                LENGTH OF CURRENT TEXT               81020000
         DC    H'0'                ACCUMULATED TEXT LENGTH              81090000
         DC    F'0'                    CCW DISPLACEMENT                 81160000
OTRLDCB1 EQU   *                   RLD OUTPUT CONTROL BLOCK             81230000
         DC    X'00DB'                                                  81300000
         DC    H'0'                BYTES OF ID-LENGTH LIST              81370000
         DC    F'0'                ADDRESS OF 1ST FREE ADDR. IN BUFFER  81440000
         DC    F'0'                ADDRESS OF BEGINNING OF BUFFER       81510000
         DC    F'0'                ADDRESS OF END OF BUFFER             81580000
OTRLDCB2 EQU   *                   RLD OUTPUT CONTROL BLOCK             81650000
         DC    X'00ED'                                                  81720000
         DC    H'0'                                                     81790000
         DC    F'0'                                                     81860000
         DC    F'0'                                                     81930000
         DC    F'0'                                                     82000000
OTRLDCB3 EQU   *                   RLD  OUTPUT CONTROL BLOCK            82070000
         DC    X'00F6'                                                  82140000
         DC    H'0'                                                     82210000
         DC    F'0'                                                     82280000
         DC    F'0'                                                     82350000
         DC    F'0'                                                     82420000
INRLDCB1 EQU   *                   RLD INPUT CONTROL BLOCK              82490000
         DS    1X                  FLAGS                                82560000
         DS    3X                  LOWEST RLD ADDRESS OF UNPROCESSED    82630000
*                                       RLD'S IN RLD SET                82700000
         DC    F'0'                ADDRESS OF BEGINNING OF BUFFER       82770000
         DC    F'0'                ADDRESS OF RLDION ENTRY MARKING THE  82840000
*                                       BEGINNING OF RLD GROUPING       82910000
         DC    F'0'                ADDRESS OF CURRENT RLDION ENTRY      82980000
*                                       BEING PROCESSED                 83050000
         DC    F'0'                ADDRESS OF RLDION ENTRY MARKING THE  83120000
*                                       END OF THE RLD GROUPING         83190000
INRLDCB2 EQU   *                   RLD INPUT CONTROL BLOCK              83260000
         DS    1X                                                       83330000
         DS    3X                                                       83400000
         DC    F'0'                                                     83470000
         DC    F'0'                                                     83540000
         DC    F'0'                                                     83610000
         DC    F'0'                                                     83680000
*                   SAVE AREAS                                          83750000
LENGTH   DS    1H                       LENGTH OF ADCON-1               83820000
DLNKR    DS    1H                       DELINK R SAVED                  83890000
RSAVE    DS    1H                       SAVE AREA FOR R PTR             83960000
RLDBYTES DS    1H                       BYTES OF RLD INFO IN RLD SET    84030000
SAVERET  DS    16F                      SAVE AREA FOR RETURN REG        84100000
MULTBEG  DS    1F                      BEG BUFFER ADDR OF MULT          84170000
MULTEND  DS    1F                      END BUFFER ADDR OF MULT          84240000
RESUMEAD DS    1F                       ADDR OF REMAINING FA'S IN CHAIN 84310000
RLDSTEND DS    1F                       RLD SET END ADDR.               84380000
BFREL    DS    1F                       BUFFER RELOCAND                 84450000
ADCON    DS    1F                       ADCON MOVED HERE FOR ALIGNMENT  84520000
TXTBEG   DS    1F                      BEGINNING OF TXT FOR CURR ID     84590000
PREVRPAD DS    1F                      ADDR  OF LAST R + P PTR.         84660000
SAVE13   DS    1F                      TEMPORARY SAVE AREA FOR REG. 13  84730000
TEMPAREA DS    1F                       TEMP SAVE AREA                  84800000
ADCONADR DS    1F                      TEXT BUFFER ADDR OF ADCON        84870000
RELADCON DS    1F                       BEGIN ADDR OF RELOCATE ADCON    84940000
SAVEBFCB DS    1F                      PREV RLD BUFFER CB SAVE AREA     85010000
DLNKSAVE DC    F'0'                    SAVE DELINK VALUE                85080000
INPUTADR DS    1F                      ADDR OF CSECT ON INPUT           85150000
TEMP     DS    1H                      TEMPORARY SAVE AREA              85220000
*                                         IN WORK AREA                  85290000
SAVE     DS    18F                      SAVE AREA FOR IEWLMREL          85360000
*                   CONSTANT AREAS                                      85430000
OF       DC    X'00FFFFFF'             SET FLAGS & RLD ADDR IN RLD CB   85500000
FF       DC    X'FFFFFF'                COMPARE FOR UPDATE MULTIPLICITY 85570000
VCONSW   DC    X'00'                    VCON LENGTH SWITCH       A48242 85620021
LEN3     EQU   X'80'                    VCON LENGTH = 3 BYTES    A48242 85630021
LN3OFF   EQU   X'7F'                    TO TURN OFF LEN3 BIT     A48242 85632021
THREE    DC    H'3'                                                     85640000
FOUR     DC    H'4'                                                     85710000
FIVE     DC    H'5'                                                     85780000
SIX      DC    H'6'                    DECIMAL 6                 A33441 85810021
SEVEN    DC    H'7'                                                     85850000
EIGHT    DC    H'8'                                                     85920000
TWELVE   DC    H'12'                                                    85990000
CON256   DC    H'256'                                                   86060000
BRINST   BC    15,0(15)                                                 86130000
SVCLINE  SVC   45                                                       86200000
         L     15,4(15)                                                 86270000
         BCR   15,15                                                    86340000
ADWRTTXT DC    V(WRTTXT)                WRITE TEXT ROUTINE              86410000
ADWRTCR  DC    V(WRTCRRLD)              WRITE CR/RLD ROUTINE            86480000
ADCHKWRT DC    V(CHECKWRT)              ADDR. OF CHECK ROUTINE(WRITE)   86550000
ADCHKRD  DC    V(CHECKRD)               ADDR. OF CHECK ROUTINE(READ)    86620000
ADGET    DC    V(GETIDMUL)              ADDR OF LOOKAHEAD/READAHEAD     86690000
PATCH    DS    25F     ********PATCH AREA   **************************  86760000
         IEWAPT                                                         86830000
CURENTAB EQU   IOCT                     HESD ADDR.OF NEXT ENTAB ENTRY   86900000
LKAENTAB EQU   IOCT+4                   ENTAB LKA                       86970000
GROUPLNG EQU   IOCT+10                  ACCUMULATED GROUP LENGTH        87040000
CCWDISP  EQU   IOCT+12                 CCW DISP ACEMENT                 87110000
SPLITADR EQU   IOCT+16                  SPLIT RLD ADDR.IN INPUT BUFFER  87180000
CBTOUSE  EQU   IOCT+20                  CTRL.BLK.ADDR.FOR BFR.WITH      87250000
*                                            SPLIT RLD                  87320000
CURSEG   EQU   EPSM                     CURRENT SEGMENT                 87390000
RPPTRS   EQU   EPSM+2                   SAVED R PTR.FOR CHAINING        87460000
CURID    EQU   EPSM+4                   CURREND ID                      87530000
CURMULT  EQU   EPSM+6                   CURRENT MULTIPLICITY            87600000
SRCHBEG  EQU   SPACES+56               WHERE TO RESUME SEARCH OF        87670000
*                                           TXTIOT FOR NEW ID           87740000
CURENTRY EQU   SPACES+60           FIRST FREE ENTRY IN ENTRY LIST       87810000
FREEADDR EQU   SPACES+64               FIRST FREE ADDR IN TEXT BUFFER   87880000
PREVBEG  EQU   SPACES+68               ADDR OF 1ST TEXT OF GROUP        87950000
         END                                                            88020000
         NC    1(1,CURTXTCB),1(PREVCREC) TAKE CR REC OFF TXTCB          93700000
         XR    PREVCREC,WORK3           SWITCH BUFFERS                  93800000
         XR    WORK3,PREVCREC                                           93900000
         XR    PREVCREC,WORK3                                           94000000
         B     SCDENT50                                                 94100000
MOVE     MVC   0(1,WORK1),0(WORK3)                                      94200000
*                   SAVE AREAS                                          94300000
LENGTH   DS    1H                       LENGTH OF ADCON-1               94400000
DLNKR    EQU   *                        DELINK R SAVED                  94500000
RSAVE    DS    1H                       SAVE AREA FOR R PTR             94600000
RLDBYTES DS    1H                       BYTES OF RLD INFO IN RLD SET    94700000
SAVERET  DS    16F                      SAVE AREA FOR RETURN REG        94800000
MULTBEG  DS    1F                      BEG BUFFER ADDR OF MULT          94900000
MULTEND  DS    1F                      END BUFFER ADDR OF MULT          95000000
CURENTRY DS    1F                  FIRST FREE ENTRY IN ENTRY LIST       95100000
RESUMEAD DS    1F                       ADDR OF REMAINING FA'S IN CHAIN 95200000
RLDSTEND DS    1F                       RLD SET END ADDR.               95300000
BFREL    DS    1F                       BUFFER RELOCAND                 95400000
ADCON    DS    1F                       ADCON MOVED HERE FOR ALIGNMENT  95500000
TXTBEG   DS    1F                      BEGINNING OF TXT FOR CURR ID     95600000
PREVRPAD DS    1F                      ADDR  OF LAST R + P PTR.         95700000
SAVE13   DS    1F                      TEMPORARY SAVE AREA FOR REG. 13  95800000
TEMPAREA DS    1F                       TEMP SAVE AREA                  95900000
ADCONADR DS    1F                      TEXT BUFFER ADDR OF ADCON        96000000
RELADCON DS    1F                       BEGIN ADDR OF RELOCATE ADCON    96100000
TEMP     DS    1H                      TEMPORARY SAVE AREA              96200000
*                                         IN WORK AREA                  96300000
SAVE     DS    18F                      SAVE AREA FOR IEWLMREL          96400000
*                   CONSTANT AREAS                                      96500000
FF       DC    X'FFFFFF'                COMPARE FOR UPDATE MULTIPLICITY 96600000
THREE    DC    H'3'                                                     96700000
FOUR     DC    H'4'                                                     96800000
FIVE     DC    H'5'                                                     96900000
SEVEN    DC    H'7'                                                     97000000
EIGHT    DC    H'8'                                                     97100000
TWELVE   DC    H'12'                                                    97200000
CON256   DC    H'256'                                                   97300000
BRINST   DC    X'47FF'                  BC 15                           97400000
SVCLINE  DC    X'0A2D58FF000407FF'      SVC 45,L 15,4(15),BCR 15,15     97500000
OUTCB1   DC    V(OTRLDCB1)              RLD OUTPUT CONTROL BLOCKS       97600000
OUTCB2   DC    V(OTRLDCB2)                                              97700000
OUTCB3   DC    V(OTRLDCB3)                                              97800000
INCB1    DC    V(INRLDCB1)              RLD INPUT CONTROL BLOCKS        97900000
INCB2    DC    V(INRLDCB2)                                              98000000
ADWRTTXT DC    V(WRTTXT)                WRITE TEXT ROUTINE              98100000
ADWRTCR  DC    V(WRTCRRLD)              WRITE CR/RLD ROUTINE            98200000
ADCHKWRT DC    V(CHECKWRT)              ADDR. OF CHECK ROUTINE(WRITE)   98300000
ADCHKRD  DC    V(CHECKRD)               ADDR. OF CHECK ROUTINE(READ)    98400000
ADGET    DC    V(GETIDMUL)              ADDR OF LOOKAHEAD/READAHEAD     98500000
PTCHAREA DS    99F     **************TEMPORARY FOR PATCHES************* 98600000
         IEWAPT                                                         98700000
CURENTAB EQU   IOCT                     HESD ADDR.OF NEXT ENTAB ENTRY   98800000
LKAENTAB EQU   IOCT+4                   ENTAB LKA                       98900000
GROUPLNG EQU   IOCT+10                  ACCUMULATED GROUP LENGTH        99000000
SPLITADR EQU   IOCT+16                  SPLIT RLD ADDR.IN INPUT BUFFER  99100000
CBTOUSE  EQU   IOCT+20                  CTRL.BLK.ADDR.FOR BFR.WITH      99200000
*                                            SPLIT RLD                  99300000
CURSEG   EQU   EPSM                     CURRENT SEGMENT                 99400000
RPPTRS   EQU   EPSM+2                   SAVED R PTR.FOR CHAINING        99500000
CURID    EQU   EPSM+4                   CURREND ID                      99600000
CURMULT  EQU   EPSM+6                   CURRENT MULTIPLICITY            99700000
         END                                                            99800000
