 TITLE 'IEWLMSCD - LINKAGE EDITOR SECOND PASS PROCESSOR'                00200000
*********************************************************************** 00260000
*STATUS:  CHANGE LEVEL 0                                              * 00320000
*FUNCTION/OPERATION:                                                  * 00380000
*        1) READS TEXT AND RLD RECORDS FROM THE INTERMEDIATE FILE IF  * 00440000
*              RECORDS ARE NOT ALREADY IN CORE                        * 00500000
*        2) RELOCATES ALL ADDRESS CONSTANTS IN THE TEXT RECORDS       * 00560000
*        3) CREATES AND WRITES RLD/CONTROL AND TEXT RECORDS IN A      * 00620000
*              FORMAT ACCEPTABLE TO PROGRAM FETCH                     * 00680000
*        4) CREATES ENTAB AND TTR LIST,WHEN OVERLAY IS SPECIFIED      * 00740000
*        THE SECOND PASS PROCESSOR(IEWLMSCD AND IEWLMREL) OPERATES IN * 00800000
*AN OVERLAP ENVIRONMENT.   READS, WHEN NEEDED FROM SYSUT1, ARE OVER-  * 00860000
*LAPPED WITH WRITES ON SYSLMOD.  I/O OPERATIONS ARE ALSO OVERLAPPED   * 00920000
*WITH PROCESSING OF RLDS.                                             * 00980000
*        IN ORDER TO HAVE AN EFFECTIVE AND EFFICIENT OVERLAP SYSTEM,  * 01040000
*INFORMATION ABOUT EACH UNIT OF TEXT MUST BE RETAINED UNTIL THAT TEXT * 01100000
*IS PROCESSED AND WRITTEN OUT.  THIS INFORMATION IS MAINTAINED IN     * 01160000
*CONTROL BLOCKS.  BY RETAINING THIS INFORMATION IN CONTROL BLOCKS,    * 01220000
*NEEDLESS SEARCHING OF TABLES IS AVOIDED AND UNCHECKED READ AND WRITES* 01280000
*CAN BE CONTROLLED.                                                   * 01340000
*        TWO TEXT CONTROL BLOCKS ARE MAINTAINED --- ONE FOR THE       * 01400000
*CURRENT TEXT BEING PROCESSED AND ONE FOR THE NEXT TEXT TO BE         * 01460000
*PROCESSED.  THIS SECOND CONTROL BLOCK IS ALSO USED TO RETAIN INFOR-  * 01520000
*MATION ABOUT AN UNCHECKED WRITE OF TEXT UNTIL ANOTHER WRITE IS ISSUED* 01580000
*OR THE TEXT CONTROL BLOCK IS NEEDED FOR A LOOK-AHEAD READ.           * 01640000
*        CONTROL BLOCKS EXIST ALSO FOR EACH RLD BUFFER.  THE RLD INPUT* 01700000
*BUFFERS ARE MAINTAINED AS TWO DISTINCT BUFFERS CONTROLLED BY TWO     * 01760000
*CONTROL BLOCKS.  BY MAINTAINING THE RLD NOTELIST ENTRY ADDRESSES,    * 01820000
*EACH RLD SET CAN BE ADDRESSED DIRECTLY WHEN NEEDED,THUS ELIMINATING  * 01880000
*NEEDLESS SCANNING OF ALL RLDS IN THE BUFFER.  THIS ALSO ELIMINATES   * 01940000
*REDUNDANT SCANS OF THE RLD NOTELIST.  CONTROL BLOCKS ARE ASSOCIATED  * 02000000
*WITH EACH OF THE RLD OUTPUT BUFFERS, WHICH ALLOWS CONTROL OF ALL     * 02060000
*THREE BUFFERS AT ONE TIME.  THE RLD BUFFERS, IN TURN, ARE ASSOCIATED * 02120000
*WITH THE CURRENT TEXT CONTROL BLOCK AS THEY ARE USED BY THE CURRENT  * 02180000
*TEXT.                                                                * 02240000
*                                                                     * 02300000
*        THE SECOND PASS BEGINS BY MAKING SURE THAT THERE IS TEXT     * 02360000
*READY TO PROCESS AND THAT THE NEXT TEXT TO BE PROCESSED IS IDENTIFIED* 02420000
*AND READ IF NECESSARY.  AN ID-LENGTH LIST ENTRY IS THEN MADE IN THE  * 02480000
*PREVIOUS CONTROL RECORD AND THE RECORD WRITTEN OUT IF THE CURRENT    * 02540000
*TEXT IS LAST IN THE GROUP AND THERE ARE RLDS FOR THE TEXT IN THE     * 02600000
*CURRENT GROUPING.  THIS ALLOWS OVERLAPPING OF THE CONTROL RECORD     * 02660000
*WRITE AND THE ACTUAL PROCESSING OF THE TEXT.  NEXT, ALL RLDS FOR THE * 02720000
*CURRENT TEXT ARE READ INTO CORE AND ASSOCIATED WITH THE TEXT THROUGH * 02780000
*THE TEXT CONTROL BLOCK. THE TEXT IS RELOCATED AND THE PROCESSED RLDS * 02840000
*MOVED TO THE OUTPUT BUFFERS.  IF THE PREVIOUS CONTROL RECORD HAS NOT * 02900000
*BEEN WRITTEN,  IT IS WRITTEN AT THIS TIME.  THE TEXT IS WRITTEN AND  * 02960000
*ALL RLD RECORDS EXCEPT ONE ARE WRITTEN.  IF THE MODULE IS IN OVERLAY,* 03020000
*AN ENTAB IS CREATED AFTER EVERY SEGMENT REQUIRING ONE.  THE TEXT     * 03080000
*CONTROL BLOCKS ARE SWITCHED AND PROCESSING RESUMES ON THE NEXT TEXT. * 03140000
*WHEN THE LAST FOR THE LOAD MODULE HAS BEEN PROCESSED, CONTROL IS     * 03200000
*TRANSFERRED TO THE FINAL PROCESSOR.                                  * 03260000
*                                                                     * 03320000
*                                                                     * 03380000
*ENTRY POINTS:                                                        * 03440000
*       -IEWLMSCD FROM IEWLMOUT                                       * 03500000
*       -WRTTXT FROM IEWLMREL TO WRITE A TEXT RECORD                  * 03560000
*       -WRTCRRLD FROM IEWLMREL TO WRITE A CR/RLD RECORD              * 03620000
*       -CHECKRD FROM IEWLMREL TO CHECK A READ                        * 03680000
*       -CHECKWRT FROM IEWLMREL TO CHECK A WRITE                      * 03740000
*       -GETIDMUL FROM IEWLMREL TO GET NEXT TEXT TO PROCESS           * 03800000
*                                                                     * 03860000
*INPUT: 1) TEXT AND RLDS RECORDS (SEE IEWLMRAT)                       * 03920000
*       2) TEXT I/O TABLE AND TEXT NOTELIST (SEE IEWLMRAT)            * 03980000
*       3) RLD NOTELIST (SEE IEWLMRAT)                                * 04040000
*       4) HESD TABLE (SEE IEWLMOUT)                                  * 04100000
*       5) DELINK TABLE (SEE IEWLMRAT)                                * 04160000
*       6) RELOCATION CONSTANT TABLE (SEE IEWLMADA)                   * 04220000
*       7) SEGTAB1 TABLE (SEE IEWLMADA)                               * 04280000
*       8) REGISTER 1 -ADDRESS OF 1ST HESD ENTAB ENTRY                * 04340000
*OUTPUT: RLD/CONTROL AND TEXT RECORDS IN LOAD MODULE FORMAT ACCEPTABLE* 04400000
*              TO PROGRAM FETCH. THE CONTROL INFORMATION INCLUDES     * 04460000
*              THE FOLLOWING:                                         * 04520000
*        BYTE 0 CONTAINS CONTROL INDICATORS                           * 04580000
*              X'01' A TEXT RECORD FOLLOWS THIS CONTROL RECORD        * 04640000
*              X'02' THIS CONTROL RECORD CONTAINS RLDS ONLY           * 04700000
*              X'03' THIS CONTROL RECORD CONTAINS RLDS AND A TEXT     * 04760000
*                   RECORD FOLLOWS                                    * 04820000
*              X'05' THIS IS THE LAST CONTROL RECORD FOR THIS SEGMENT,* 04880000
*                   NO RLDS ARE PRESENT AND A TEXT RECORD FOLLOWS     * 04940000
*              X'06' THIS IS THE LAST CONTROL RECORD FOR THE SEGMENT, * 05000000
*                   NO TEXT FOLLOWS AND RLDS ARE PRESENT IN THE RECORD* 05060000
*              X'07' THIS IS THE LAST CONTROL RECORD FOR THE SEGMENT, * 05120000
*                   RLDS ARE PRESENT ANT TEXT FOLLOWS                 * 05180000
*              X'0D' THIS IS THE LAST CONTROL RECORD FOR THIS SEGMENT * 05240000
*                   AND LOAD MODULE, NO RLDS ARE PRESENT AND A TEXT   * 05300000
*                   RECORD FOLLOWS                                    * 05360000
*              X'0E' THIS IS THE LAST CONTROL RECORD FOR THIS SEGMENT * 05420000
*                   AND LOAD MODULE, RLDS ARE PRESENT BUT NO TEXT     * 05480000
*                   RECORD FOLLOWS                                    * 05540000
*              X'0F' THIS IS THE LAST CONTROL RECORD FOR THIS SEGMENT * 05600000
*                   AND LOAD MODULE, RLDS ARE PRESENT AND TEXT FOLLOWS* 05660000
*        BYTES 1 THRU 3 CONTAIN ZEROS                                 * 05720000
*        BYTES 4 AND 5 CONTAIN THE NUMBER OF BYTES OF ID-LENGTH IN    * 05780000
*              THIS CONTROL RECORD.  FOR CONTROL INDICATORS 02,06,AND * 05840000
*              0E THIS WILL BE ZERO                                   * 05900000
*        BYTES 6 AND 7 CONTAIN THE NUMBER OF BYTES OF RLD INFORMATION * 05960000
*              IN THE CONTROL RECORD                                  * 06020000
*        BYTES 8 THRU 11 CONTAIN THE READ BITS AND THE LINKAGE EDITOR * 06080000
*              ASSIGNED ADDRESS OF THE TEXT WHICH FOLLOWS             * 06140000
*        BYTES 12 THRU 15  CONTAIN THE FLAGS AND THE LENGTH OF THE    * 06200000
*              TEXT RECORD THAT FOLLOWS                               * 06260000
*        FOR CONTROL INDICATORS  02,06 AND 0E, BYTES 8 THRU 15 WILL BE* 06320000
*              ZERO. THE TEXT RECORDS WILL CONTAIN THE NUMBER OF BYTES* 06380000
*              OF TEXT INDICATED IN THE CONTROL RECORD WHICH PRECEDES * 06440000
*              IT.                                                    * 06500000
*                                                                     * 06560000
*EXTERNAL ROUTINES:                                                   * 06620000
*        IEWLMREL- AT IEWLMREL FOR INITIALIZATION                     * 06680000
*                - AT RELOCATE FOR RELOCATION                         * 06740000
*                - AT SCDENTAB TO CREATE AN ENTAB AND ITS RLDS        * 06800000
*        IEWLCR03- ERROR ROUTINE FOR SYNCHRONOUS ERRORS ON XDAP WRITE * 06860000
*                                                                     * 06920000
*EXITS: NORMAL- TO IEWLMFNL       L  15,ADFINAL                       * 06980000
*                                 BR 15                               * 07040000
*       ERROR-  NONE                                                  * 07100000
*                                                                     * 07160000
*TABLES/WORK AREAS: - REFER TO LINKAGE EDITOR PLM FOR DETAILED        * 07220000
*        DESCRIPTIONS                                                 * 07280000
*        1) ALL PURPOSE TABLE                                         * 07340000
*        2) HESD                                                      * 07400000
*        3) DELINK TABLE                                              * 07460000
*        4) TEXT I/O TABLE                                            * 07520000
*        5) TEXT NOTELIST                                             * 07580000
*        6) RLD NOTELIST                                              * 07640000
*        7) TTR LIST                                                  * 07700000
*        8) TEXT CONTROL BLOCKS(SEE IEWLMREL FOR BLOCK DESCRIPTIONS)  * 07760000
*        9) RLD CONTROL BLOCKS(SEE IEWLMREL)                          * 07820000
*                                                                     * 07880000
*ATTRIBUTES: REUSABLE                                                 * 07940000
*                                                                     * 08000000
*NOTES: THE SECOND PASS IN DETERMINING THE NUMBER OF BYTES READ, USES * 08060000
*        THE RESIDUAL BYTE COUNT IN THE CCW OF THE IOB USED BY BSAM TO* 08120000
*        PERFORM THE READ. TO ACCESS THIS COUNT REQUIRES KNOWLEDGE OF * 08180000
*        THE IOB ADDRESS IN THE DECB USED IN ISSUING THE READ AND     * 08240000
*        THE FORMAT OF THE IOB. IF EITHER OF THESE FORMATS ( IOB  OR  * 08300000
*        DECB ) CHANGE THIS PART OF THE CODE IN THE READ TEXT ROUTINE * 08360000
*        MUST BE CHECKED FOR ACCURACY. ANY CHANGE IN CCW FORMAT WILL  * 08420000
*        ALL AFFECT FORMATTING OF CONTROL RECORDS.                    * 08480000
*********************************************************************** 08540000
IEWLMSCD CSECT                                                          08600000
* 141500,147900,148000,1481000                                   A24469 08601000
* 148200,370100,649100,708500,730100,733100,765900,           A24469    08601300
* 766200,766000,766100                                        A24469    08601600
* 179630,179660,179690,179720,179750,179780,179810,179840,     PTF20888 08602000
* 179870,179900,179930,179960,179990,180020,180050,180080,     PTF20888 08603000
* 180110,788900                                                PTF20888 08604000
* 202700,213500,422700,422800,422900,460700,482300,490600,       A23945 08605000
* 490800,492200,494900,522500,527300,531500,782800,783000        A23945 08606000
* 490600-490800                                                  A28339 08608000
* 170600-171800                                                  A26874 08608121
* 202700,213500,422700-422900,460700,482300,490610-490800,       A23945 08608321
* 494900,522500,527300,531500,782800-783000                      A23945 08608621
* 243800-246200                                                  A33838 08608921
* 384800,425000,496400                                           A33762 08609221
* 609200                                                         A32340 08609521
*D093200,097400-098600,105200-105800,110600,113000,130400,       A42052 08610521
*D143000-143600,144800-145400,769400-770600,778400-779600,785600 A42052 08611521
*C147900-148200,149300,173600,185600,533000-764600,              A42052 08612521
*C766100-766200,816800-999999                                    A42052 08613521
*A282800,356600,496200,777800,782800                             A42052 08614521
*I142400,I390200                                                SA66746 08614900
****  OUTPUT RLD CONTROL BLOCK INDICATORS                               08615521
LASTUSED EQU   X'20'                   LAST RLD BUFFER FILLED           08620000
LASTOFF  EQU   X'DF'                                                    08630000
***        TEXT CONTROL BLOCK                                       *** 08660000
*                         BYTE 1                                      * 08720000
USED     EQU   X'E0'                    TXT CTRL. BLOCK IN USE          08780000
INUSE    EQU   X'80'                    CONTROL BLOCK IN USE            08840000
NOTINUSE EQU   X'7F'                                                    08900000
BEINGWT  EQU   X'40'                    TEXT BEING WRITTEN              08960000
WRTCKD   EQU   X'3F'                    WRITE CHECKED - CB NOT IN USE   09020000
BEINGRD  EQU   X'20'                    TEXT BEING READ                 09080000
RDCHKD   EQU   X'DF'                    READ CHECKED                    09140000
RLDS     EQU   X'10'                                                    09200000
FIRSTXT  EQU   X'08'                    TEXT FIRST IN GROUP             09260000
ENDINDIC EQU   X'06'                   END OF GROUP AND SEG             09380000
LASTXT   EQU   X'04'                    TEXT LAST IN GROUP              09440000
SEGMTEND EQU   X'02'                    TEXT IS LAST IN SEGMENT         09500000
MODULEND EQU   X'01'                    TEXT IS LAST IN MODULE          09560000
*                     BYTE 2                                          * 09620000
XDAP     EQU   X'80'                    XDAP WRITE NEEDED               09680000
PREV     EQU   X'07'                    TEST IF PREV CR/RLD WRITTEN     09920000
BUF1PREV EQU   X'24'                    BFR.1 HAS ID-LENGTH LIST        09980000
BUF2PREV EQU   X'12'                    BFR.2 HAS ID-LENGTH LIST        10040000
BUF3PREV EQU   X'09'                    BFR.3 HAS ID-LENGTH LIST        10100000
OUTBUF1  EQU   X'20'                    OUTPUT BFR.1 IS BEING USED      10160000
BUF1OFF  EQU   X'DF'                                                    10190000
OUTBUF2  EQU   X'10'                                                    10220000
BUF2OFF  EQU   X'EF'                                                    10280000
OUTBUF3  EQU   X'08'                                                    10340000
BUF3OFF  EQU   X'F7'                                                    10400000
*                           BYTE  3                                   * 10460000
MORETXT  EQU   X'08'                   MORE TEXT TO PROCESS IN SEGMENT  10640000
TEXTOFF  EQU   X'F7'                                                    10700000
***         TEXT  I/O TABLE  INDICATORS                             *** 10760000
INCORE   EQU   X'80'                    TEXT IN CORE                    10820000
TTRENTRY EQU   X'40'                    ENTRY CONTAINS TTR              10880000
OUTORDER EQU   X'20'                    TEXT IS OUT-OF-ORDER            10940000
TEXTDONE EQU   X'10'                    TEXT IS PROCESSED               11000000
*                                             INCORRECT LENGTH          11120000
***      RLD  NOTELIST INDICATORS                                   *** 11180000
*INCORE  EQU   X'80'                    RLDS IN CORE                    11240000
*TTRENTRY EQU  X'40'                   TTR ENTRY                        11360000
BUF2     EQU   X'10'                    RLDS IN BFR2                    11420000
*              CONTROL RECORD INDICATORS                              * 11480000
MODEND   EQU   X'08'                    LAST TXT FOR LOAD MODULE        11540000
SEGEND   EQU   X'04'                    LAST TXT FOR SEGMENT            11600000
RLD      EQU   X'02'                    RLDS PRESENT IN RECORD          11660000
RLDOFF   EQU   X'FD'                                                    11720000
TXT      EQU   X'01'                    TEXT FOLLOWS                    11780000
*                                                                     * 11840000
*                   NEWSW2 INDICATORS IN APT                          * 11900000
MORERLDS EQU   X'80'                    MORE RLDS STILL TO BE READ      11960000
MOREOFF  EQU   X'7F'                                                    12020000
SPLTMOVD EQU   X'40'                    SPLIT RLD MOVED TO OUTPUT BFR.  12080000
MOVDOFF    EQU   X'BF'                                            23971 12110000
SPLITRLD EQU   X'08'                    SPLIT RLD SAVED IN HESD         12140000
SPLITOFF EQU   X'F7'                                                    12200000
NOCTLREC EQU   X'04'                   NO RLDS FOR PRECEDING TEXT       12260000
NOCROFF  EQU   X'FB'                                                    12320000
GROUPOFF EQU   X'FD'                   RLDS ARE NOT TO BE GROUPED       12380000
*        APT3  SWITCH INDICATORS                                      * 12440000
*FIRSTXT EQU   X'08'                    FIRST TEXT OF LOAD MODULE       12500000
SEGSTART EQU   X'04'                    TEXT  IS FIRST IN SEGMENT       12560000
SEGOFF   EQU   X'FB'                                                    12620000
RLDSINGP EQU   X'02'                   RLDS IN GROUP                    12680000
RLDSOFF  EQU   X'FD'                                                    12740000
SCTR     EQU   X'04'                    SCATTER OPTION ON               12800000
DC       EQU   X'80'                    DC OPTION ON                    12860000
OVLY     EQU   X'20'                    OVERLAY OPTION                  12920000
LKAZERO  EQU   X'BF'                    LKA IS NOT ZERO                 12980000
*                                                                     * 13100000
*                        REGISTER USAGE                               * 13160000
*                                                                     * 13220000
SAVEAREA EQU   13                  SAVE AREA                            13280000
RETURN   EQU   14                  NSI REGISTER FOR BALR                13340000
BRANCH   EQU   15                  FIRST LEVEL BRANCH REGISTER          13400000
WORK0    EQU   0                   GENERAL WORK REGISTER                13460000
PARM     EQU   1                   PARM.REG. AND WORK REG.              13520000
APT      EQU   2                   BASE REGISTER FOR APT                13580000
CURTXTCB EQU   3                   ADDRESS OF CURRENT TXT CONTROL BLOCK 13640000
NXTTXTCB EQU   4                   ADDRESS OF NEXT TEXT CONTROL BLOCK   13700000
WORK1    EQU   5                   WORK REGISTER                        13760000
WORK2    EQU   6                   WORK REGISTER                        13820000
WORK3    EQU   7                   WORK REGISTER                        13880000
PREVCREC EQU   8                   ADDRESS OF RLD CONTROL BLOCK FOR     13940000
*                                         PREVIOUS  CR/RLD RECORD       14000000
WORK8    EQU   8                       GENERAL WORK REGISTER-GETIDMUL   14060000
WORK9    EQU   9                       GENERAL WORK REGISTER            14120000
BASE2    EQU   10                                                A24469 14150000
BRANCHX  EQU   11                  SECOND LEVEL BRANCH REGISTER         14180000
BASE     EQU   12                  BASE REGISTER FOR SCD                14240000
REG0     EQU   0                       ERR MSG PARAM REG        SA66746 14290000
REG14    EQU   14                      LINKAGE REG              SA66746 14340000
REG15    EQU   15                      LINKAGE REG              SA66746 14390000
         ENTRY GETIDMUL                 LOOKAHEAD/READAHEAD ROUTINE     14420000
         EXTRN IEWLCMDB                SYSLMOD DCB ADDRESS              14600000
         EXTRN IEWLCUDB                SYSUT1 DCB ADDRESS               14660000
         BALR  BASE,0                                                   14720000
         USING *,BASE                   BASE REGISTER FOR IEWLMSCD      14780000
         L     BASE2,ADSIO             PICK UP ADDR OF IEWLMSIO  A42052 14800021
         ST    BASE2,BASEREG           SAVE SIO BASE REG         A42052 14820021
         USING IEWLMSIO,BASE2          ESTAB ADDRABILITY FOR SIO A42052 14840021
         B     MODID+10                                                 14860021
MODID    DC    C'27MSCD'                                                14900000
BASEREG  DS    1F                      STORAGE FOR SIO BASE REG  A42052 14930021
         USING APTDSECT,APT             BASE REGISTER FOR APT           14960000
*                 INITIALIZATION MOVED TO IEWLMREL FOR SPACE          * 15020000
         L     BRANCH,ADREL                                             15080000
         BALR  RETURN,BRANCH           BRANCH TO MREL FOR INIT.         15140000
*                                                                     * 15200000
         L     BASE2,BASEREG           RESTORE SIO BASE REG      A42052 15230021
         MVC   FREEADDR(4),TXTBFBEG    INIT FIRST FREE ADDR IN BFR.     15260000
         MVC   CURSEG(2),ONE                                            15320000
         MVC   SRCHSEG(2),ONE          INITIALIZE SEG. NO. AND MULT.    15380000
         MVC   SRCHMULT(2),ZERO                                         15440000
*                                                                     * 15500000
*    THIS ROUTINE MAKES SURE THAT AN ID-MULT ARE READY TO PROCESS AND * 15560000
*        A LOOKAHEAD IS DONE FOR THE NEXT ID-MULT TO PROCESS          * 15620000
*                                                                     * 15680000
GETID    TM    0(CURTXTCB),USED         TEXT CTRL. BLK. IN USE          15740000
         BZ    GETID1                   NO                              15800000
         TM    0(CURTXTCB),BEINGWT      TEXT BEING WRITTEN              15860000
         BO    GETID2                   YES                             15920000
         TM    0(CURTXTCB),BEINGRD      TEXT BEING READ                 15980000
         BZ    GETID3                  ID-MULT IS READY TO PROCESS      16040000
         BAL   BRANCHX,CHECKRD          CHECK READ                      16100000
         NI    0(CURTXTCB),RDCHKD       MARK READ CHECKED               16160000
         B     GETID3                                                   16220000
GETID1   LR    PARM,CURTXTCB                                            16280000
         NI    0(CURTXTCB),X'00'       CLEAR FLAG BITS                  16340000
         NI    2(CURTXTCB),X'00'                                        16400000
         SR    WORK0,WORK0             INDIC PRIME READ                 16460000
         BAL   RETURN,GETIDMUL          BRANCH TO READY ID-MULT         16520000
         B     GETID                                                    16580000
GETID2   BAL   BRANCHX,CHECKWRT         CHECK WRITE                     16640000
         NI    0(CURTXTCB),WRTCKD       MARK WRITE CHECKED-CB FREE      16700000
         B     GETID                                                    16760000
GETID3   L     WORK1,12(CURTXTCB)                                       16820000
         MVC   CURID(2),0(WORK1)       GET CURR. ID                     16880000
         MVC   CURMULT(2),2(WORK1)     GET CURR MULT                    16940000
         NI    CURMULT,X'03'           CLEAR HIGH ORDER BITS            17000000
         TM    0(CURTXTCB),FIRSTXT     IS TEXT FIRST OF GROUP    A26874 17030021
         BZ    LOOKAHED                NO, BRANCH OUT            A26874 17060021
         TM    APT3,SEGSTART           WORKING IN NEW SEGMENT    A26874 17090021
         BO    GETID3A                 YES, GO TO UPDATE SEG NO. A26874 17120021
         CLC   CURSEG+1(1),SRCHSEG+1   CURR SAME AS SRCH?        A26874 17150021
         BE    LOOKAHED                YES, BRANCH OUT           A26874 17180021
GETID3A  LH    WORK1,CURID             NO, UPDATE CURR. SEG.     A26874 17210021
         SLL   WORK1,3                                                  17240000
         A     WORK1,HESD                                               17300000
GETID3B  EQU   *                                                 A42052 17310021
         ST    WORK1,SAVESTOR          SAVE REG                  A42052 17320021
         LH    WORK1,CURSEG            PICK UP LAST SEG #        A42052 17330021
         LA    WORK1,ON1(WORK1)        ADD ONE TO SEG #          A42052 17340021
         STH   WORK1,CURSEG            REPLACE OLD SEG #         A42052 17350021
         L     WORK1,SAVESTOR          RESTORE REG               A42052 17360021
         CLC   CURSEG+ON1(ON1),FOR(WORK1)  COMPARE UPDATED SEG # A42052 17370021
*                                      WITH NEXT SEG # FROM TIOT A42052 17380021
         BE    SCDANDY                 EQUAL SO BRANCH           A42052 17390021
         OI    SSWITCH+ON1,SEGNO       NOT EQUAL, TURN ON SWITCH A42052 17400021
SCDANDY  EQU   *                                                 A42052 17410021
*                                                                     * 17420000
********    UPDATE ENTRY LIST TO HAVE ONLY ONE PATH    ***************  17480000
*                                                                     * 17540000
         LH    WORK1,CURSEG                                             17600000
         L     WORK3,SELST             GET BEGINNING OF ENTRY LIST      17660000
         A     WORK1,SGT1              GET CURR. SEG ENTRY IN SEGTA1    17720000
ENTLST1  C     WORK3,CURENTRY          LOOKING AT THE CURRENT ENTRY     17780000
         BE    LOOKAHED                YES                              17840000
         CLC   2(1,WORK3),0(WORK1)     NO, ARE SEGMENTS IN SAVE PATH    17900000
         BH    ENTLST3                 NO                               17960000
*   SEE IF REGION OF SEGMENT IN ENTRY LIST IS SAME AS CURRENT REGION    17963000
*                                                              PTF20888 17966000
         LA    WORK2,LSTS         LOAD ADD. OF REGION LIST     PTF20888 17969000
TEMP1    CLC   0(1,WORK2),CURSEG+1  IS CUR. SEG. IN THIS REG.  PTF20888 17972000
         BC    10,STORE           YES - STORE THIS REG.        PTF20888 17975000
         LA    WORK2,1(WORK2)     INCREMENT LIST ADD.          PTF20888 17978000
         B     TEMP1                                           PTF20888 17981000
STORE    MVC   CURRGN(1),0(WORK2)  STORE CURR. REGION          PTF20888 17984000
         LA    WORK2,LSTS         LOAD ADD. OF REGION LIST     PTF20888 17987000
TEMP2    CLC   0(1,WORK2),2(WORK3)  IS ENTRY LIST SEGMENT IN   PTF20888 17990000
*                                            THIS REGION       PTF20888 17993000
         BC    10,COMP            YES - BRANCH                 PTF20888 17996000
         LA    WORK2,1(WORK2)     INCREMENT LIST ADDRESS       PTF20888 17999000
         B     TEMP2                                           PTF20888 18002000
COMP     CLC   0(1,WORK2),CURRGN  IS ENTRY LIST SEGMENT IN SAME         18005000
*                                 REGION AS CURRENT SEGMENT    PTF20888 18008000
         BC    7,ENTLST3          NO - DIFFERENT REGIONS       PTF20888 18011000
ENTLST2  LA    WORK3,6(WORK3)          YES, UPDATE TO NEXT ENTRY        18020000
         B     ENTLST1                                                  18080000
ENTLST3  CLI   2(WORK3),X'01'          KEEP ENTRY FOR ROOOT SEGMENT     18140000
         BE    ENTLST2                                                  18200000
         ST    WORK3,CURENTRY          1ST FREE ADDR IN ENTRY LIST      18260000
         S     WORK3,SELST             BYTES IN ENTRY LIST              18320000
         SR    WORK2,WORK2                                              18380000
         D     WORK2,SIX                                                18440000
         STH   WORK3,ENELTC            CUR NO OF ENTRIES IN ENTRY LIST  18500000
LOOKAHED TM    SSWITCH+ON1,SEGNO       NOT EQUL SWT ON           A42052 18510021
         BZ    LOOKAHD2                NO SO BRANCH              A42052 18520021
         NI    SSWITCH+ON1,SEGNOOFF    TURN SWITCH OFF           A42052 18530021
         L     WORK1,SAVESTOR          RESTORE REG               A42052 18540021
         B     GETID3B                 GET NEXT SEG NO.          A42052 18550021
LOOKAHD2 TM    ZRO(NXTTXTCB),USED      HAS NEXT ID MULT BEEN READA42052 18560021
         BZ    LKAHED1                  NO                              18620000
         TM    0(NXTTXTCB),BEINGWT                                      18680000
         BZ    SPECTEST                YES                              18740000
         BAL   BRANCHX,CHECKWRT         CHECK WRITE                     18800000
         NI    0(NXTTXTCB),WRTCKD       MARK WRITE CHECKED              18860000
         B     LOOKAHED                                                 18920000
LKAHED1  LR    PARM,NXTTXTCB                                            18980000
         NI    0(NXTTXTCB),X'00'       CLEAR FLAG BITS                  19040000
         NI    2(NXTTXTCB),X'00'                                        19100000
         LA    WORK0,1                 INDIC LOOKAHEAD READ             19160000
         BAL   RETURN,GETIDMUL          BRANCH TO READY NEXT ID-MULT    19220000
*                                                                     * 19280000
*   SET END INDICATORS WHEN LAST MULTIPLICITY OF LAST CSECT OF SEGMENT* 19340000
*         OR MODULE IS A DS AREA                                      * 19400000
*                                                                    *  19460000
SPECTEST TM    0(NXTTXTCB),INUSE       IS CURR TEXT LAST OF SEGMENT     19520000
         BO    CONTREC                 NO                               19580000
         TM    2(CURTXTCB),MORETXT     IS THERE MORE TEXT IN SEG        19640000
         BZ    SPECT1                  NO                               19700000
         NI    2(CURTXTCB),TEXTOFF     TURN INDIC OFF                   19760000
         B     CONTREC                                                  19820000
SPECT1   LH    WORK1,CURID                                              19880000
         SLL   WORK1,3                                                  19940000
         A     WORK1,HESD                                               20000000
         TM    0(WORK1),X'40'          IS CURR CSECT MARKED LAST IN SEG 20060000
         BZ    CONTREC                 NO                               20120000
         OI    0(CURTXTCB),ENDINDIC    SET END INDICATORS               20180000
         XC    GROUPLNG(2),GROUPLNG    INIT GROUP CT. FOR NEXT SEG.     20240000
         CLC   CURSEG(2),ENSPC         IS CURR TEXT LAST OF MODULE      20300000
         BNE   CONTREC                 NO                               20360000
         OI    0(CURTXTCB),MODULEND    YES, SET END OF MODULE INDIC     20420000
*                                                                     * 20480000
*        MAKE ID-LENGTH LIST ENTRY IN PREVIOUS CONTROL RECORD         * 20540000
*                                                                     * 20600000
CONTREC  LA    BRANCHX,CCWADD           READY BRANCH REGISTER           20660000
         L     WORK3,8(PREVCREC)                                        20720000
         CLC   4(4,PREVCREC),12(PREVCREC) IS THIS LAST ENTRY            20780000
         BL    CONT30                  NO                               20840000
         TM    0(WORK3),RLD             MORE THAN 60 CSECTS GROUPED     20900000
         BO    CONT40                   NO                              20960000
         OI    0(CURTXTCB),LASTXT       YES,SET LAST TEXT OF GROUP      21020000
         TM    0(NXTTXTCB),USED         NEXT ID-MULT READ OR BEING WRT. 21080000
         BZ    CONT10                   NO                              21140000
         TM    0(NXTTXTCB),BEINGWT      MAYBE                           21200000
         BZ    CONT20                   YES                             21260000
CONT10   XC    GROUPLNG(2),GROUPLNG     ZERO GROUP LENGTH               21320000
         B     CONT30                                                   21380000
CONT20   MVC   26(2,NXTTXTCB),24(NXTTXTCB) CORRECT GROUP LENGTH         21440000
         OI    0(NXTTXTCB),FIRSTXT      SET 1ST TXT IN GROUP INDICATOR  21500000
         L     WORK2,8(NXTTXTCB)                                        21560000
         SH    WORK2,24(NXTTXTCB)                                       21620000
         ST    WORK2,4(NXTTXTCB)       UPDATE BE OF TEXT                21680000
         MVC   GROUPLNG(2),24(NXTTXTCB) UPDATE LNG FOR GROUPING         21740000
         ST    WORK2,PREVBEG           RESET TEXT BEG. ADDR      A23945 21760021
         MVC   29(3,NXTTXTCB),CCWDISP+1  RESET CCW ADDR          A23945 21780021
CONT30   L     WORK2,4(PREVCREC)                                        21800000
         MVC   16(2,WORK2),CURID       MAKE ID-LENGTH LIST ENTRY        21860000
         MVC   18(2,WORK2),24(CURTXTCB)                                 21920000
         LA    WORK2,4(WORK2)                                           21980000
         ST    WORK2,4(PREVCREC)        UPDATE 1ST FREE ADDR FIELD      22040000
         LH    WORK2,2(PREVCREC)       UPDATE ID-LENGTH FIELD           22100000
         LA    WORK2,4(WORK2)                                           22160000
         STH   WORK2,2(PREVCREC)       UPDATE ID-LENGTH FIELD           22220000
         BR    BRANCHX                                                  22280000
CONT40   BAL   BRANCHX,CONT30           BRANCH-MAKE ID-LENGTH LST ENTRY 22340000
         MVC   CONTSAVE(16),0(WORK3)    SAVE CONTROL INFORMATION        22400000
         XC    0(16,WORK3),0(WORK3)     ZERO CONTROL INFORMATION        22460000
         OI    0(WORK3),RLD             SET RLD'S PRESENT               22520000
         MVC   6(2,WORK3),CONTSAVE+6    RESTORE RLD BYTE COUNT          22580000
         LR    PARM,PREVCREC                                            22640000
         BAL   RETURN,WRTCRRLD          WRITE AN RLD RECORD             22700000
         BAL   BRANCHX,CHECKWRT        CHECK WRITE                      22760000
         NI    0(PREVCREC),WRTCKD      MARK CHECKED                     22820000
         OI    0(PREVCREC),INUSE                                        22880000
         L     WORK3,8(PREVCREC)       BFR. BEG. ADDR.                  22940000
         MVC   0(16,WORK3),CONTSAVE                                     23000000
         NI    0(WORK3),RLDOFF          SET RLD PRESENT BIT OFF         23060000
         LH    WORK2,6(WORK3)           BYTES OF RLD INFORMATION        23120000
         XC    6(2,WORK3),6(WORK3)      ZERO RLD BYTE FIELD             23180000
         LA    WORK2,16(WORK3,WORK2)    BEGINNING OF ID-LENGTH LIST     23240000
         LH    WORK1,2(PREVCREC)        BYTES OF ID                     23300000
         BCTR  WORK1,0                                                  23360000
         EX    WORK1,MOVE              MOVE ID-LENGTH LIST              23420000
         LA    WORK1,1(WORK3,WORK1)                                     23480000
         ST    WORK1,4(PREVCREC)        UPDATE 1ST FREE ADDRESS         23540000
*                                                                     * 23600000
*     MOVE CCW DISPLACEMENT INFORMATION TO THE CONTROL RECORD         * 23660000
*                                                                     * 23720000
CCWADD   TM    0(CURTXTCB),FIRSTXT      TEXT 1ST IN GROUP               23780000
         BZ    RLDSCAN                  NO                              23840000
         MVC   8(4,WORK3),28(CURTXTCB) YES, PUT CCW DISP IN CR          23900000
         OI    0(WORK3),TXT             SET TXT PRESENT INDICATOR       23960000
         NI    APT3,RLDSOFF            SET RLDS FOR GROUP INDIC OFF     24020000
         TM    PDSE7,OVLY              IS PROGRAM IN OVLY               24020600
         BO    CCW0                    YES, ORIGIN OF SEGTAB =0         24021200
         TM    APT3,FIRSTXT            FIRST TXT OF LOAD MODULE         24028000
         BZ    CCW0                    NO                               24036000
         NC    29(3,CURTXTCB),29(CURTXTCB)  IS LKA OF 1ST TEXT =0       24044000
         BZ    CCW0                    YES                              24052000
         NI    PDSE8,LKAZERO            NO, TURN OFF LKA=0 INDIC.       24060000
         MVC   PDSE12(3),29(CURTXTCB)   MOVE LKA INTO PDS               24068000
*                                                                     * 24080000
*   CHECK FOR SAVED SPLIT RLD - MOVE SPLIT RLD TO OUTPUT BUFFER       * 24140000
*                                                                     * 24200000
CCW0     TM    NEWSW2,SPLITRLD         HAS SPLIT RLD BEEN SAVED         24260000
         BZ    RLDSCAN                  NO                              24320000
         TM    1(CURTXTCB),BUF1PREV  DOES BUFFER1 HAVE CNTRLRCD  A33838 24340021
         BO    CCW4            YES,GO TO CHECK BUFFER2           A33838 24360021
         L     WORK1,OUTCB1    NO,PICK UP BUFFER1 CB AND CHECK ITA33838 24380021
         TM    0(WORK1),X'40'          IS IT WRITTEN YET         A33838 24400021
         BZ    CCW1                    YES, USE IT               A33838 24420021
         BAL   BRANCHX,CHECKWRT        NO, GO TO CHECK WRITE     A33838 24440021
         B     CCW1                    GO TO USE BUFFER1         A33838 24460021
CCW4     L     WORK1,OUTCB2            USE BUFFER 2              A33838 24480021
         TM    0(WORK1),X'40'          IS IT WRITTEN YET         A33838 24500021
         BZ    CCW5                    YES, GO TO USE IT         A33838 24520021
         BAL   BRANCHX,CHECKWRT        NO, GO TO CHECK WRITE     A33838 24540021
CCW5     OI    1(CURTXTCB),OUTBUF2   INDICATE BUFFER2 BEING USED A33838 24560021
         B     CCW2                                                     24680000
CCW1     OI    1(CURTXTCB),OUTBUF1      INDICATE BFR1 BEING USED        24740000
CCW2     OI    0(WORK1),INUSE           MARK CTRL BLK USED              24800000
         L     WORK2,8(WORK1)           GET BUFFER BEG.                 24860000
         XC    0(16,WORK2),0(WORK2)     CLEAR THE CONTROL RECORD        24920000
         OI    0(WORK2),RLD             SET RLD INDIC ON                24980000
         MVI   7(WORK2),X'08'           PUT IN RLD BYTE CT              25040000
         L     WORK3,HESD                                               25100000
         MVC   16(8,WORK2),0(WORK3)    MOVE SAVED RLD TO OUTPUT BUFFER  25160000
         TM    0(WORK3),X'80'          IS R MARKED DELINK               25220000
         BZ    CCW3                    NO                               25280000
         NI    0(WORK3),X'7F'          TURN OFF DELINK BIT              25340000
         LH    WORK3,0(WORK3)                                           25400000
         MH    WORK3,FIVE                                               25460000
         A     WORK3,DLKT              DELINK TABLE ENTRY FOR R PTR     25520000
         MVC   16(2,WORK2),0(WORK3)    CHANGE TO DELINKED R PTR         25580000
CCW3     LA    WORK2,8(WORK2)                                           25640000
         ST    WORK2,4(WORK1)           SAVE 1ST FREE ADDR.             25700000
         NI    NEWSW2,SPLITOFF          SET SPLIT RLD SAVED INDIC OFF   25760000
         OI    NEWSW2,SPLTMOVD          SPLIT RLD HAS BEEN MOVED        25820000
         ST    WORK1,CBTOUSE            SAVE CTRL. BLK. ADDR            25880000
           OI  APT3,RLDSINGP                                      23971 25900000
           ST  WORK1,LASTBUF                                      23971 25920000
*                                                                     * 25940000
*                                                                     * 26000000
*      PRELIMINARY SCAN OF RLD NOTELIST TO SEE IF TEXT HAS RLD'S.  IF * 26060000
*      THE TEXT HAS RLD'S AND IT IS THE LAST TEXT FOR THE GROUP, THE  * 26120000
*      CONTROL RECORD WRITE CAN BE OVERLAPPED WITH RLD READ'S AND     * 26180000
*      THE PROCESSING OF TEXT.                                        * 26240000
*                                                                     * 26300000
*                                                                     * 26360000
RLDSCAN  L     WORK1,RNLS2              START OR RLD NOTELIST           26420000
         LH    WORK2,ENR2C              NO. OF RLD NOTELIST ENTRIES     26480000
         LTR   WORK2,WORK2             IS NOTELIST EMPTY                26540000
         BZ    LASTTEXT                YES                              26600000
COMPID   CLC   CURID(2),0(WORK1)        CUR. ID = NOTELIST ENTRY ID     26660000
         BNE   NEXTENT                                                  26720000
         MVC   TEMP(2),2(WORK1)                                         26780000
         NI    TEMP,X'03'               CLEAR INDICATORS                26840000
         CLC   CURMULT(2),TEMP          CUR. MULT  = ENTRY MULT         26900000
         ST    WORK1,RLDION             SAVE ADDR OF NOTELIST ENTRY     26960000
         BE    CRREADY                  YES                             27020000
NEXTENT  LA    WORK1,9(WORK1)           UPDATE TO NEXT NOTELIST ENTRY   27080000
         BCT   WORK2,COMPID                                             27140000
         B     LASTTEXT                 NO RLD'S FOR TEXT               27200000
*                                                                     * 27260000
*        WRITE PREVIOUS CONTROL RECORD IF READY TO BE WRITTEN           27320000
*                                                                     * 27380000
CRREADY  OI    0(CURTXTCB),RLDS         SET RLD'S FOR TXT IN CTRL BLK   27440000
         OI    APT3,RLDSINGP           SET RLDS IN GROUP INDIC          27500000
         TM    0(CURTXTCB),LASTXT       IS TXT LAST IN GROUP            27560000
         BZ    READYRLD                 NO                              27620000
         LR    PARM,PREVCREC                                            27680000
         BAL   RETURN,WRTCRRLD          GO TO WRITE PREVIOUS CTRL. REC. 27740000
         NC    1(1,CURTXTCB),1(PREVCREC) MARK PREV.CTRL.REC.WRITTEN     27800000
*                                                                     * 27860000
*     GET ALL NEEDED RLDS AND PASS CONTROL TO IEWLMREL TO RELOCATE    * 27920000
*                                                                     * 27980000
READYRLD L     PARM,RLDION              GET 1ST NOTELIST ENTRY FOR      28040000
*                                              NEEDED RLD'S             28100000
         BAL   RETURN,RDRLD             GO TO GET ALL NEEDED RLD'S      28160000
         L     BRANCHX,RELOC                                            28220000
         BALR  RETURN,BRANCHX          GO TO RELOCATE RLDS              28280000
         L     BASE2,BASEREG           RESTORE SIO BASE REG      A52052 28310021
         TM    NEWSW2,MORERLDS          MORE RLDS STILL TO READ         28340000
         BO    READYRLD                 YES, GO TO READ                 28400000
*                                                                     * 28404000
** SPECIAL TESTING TO FIND LEAST FILLED BUFFER TO USE FOR ID-LENGTH***  28408000
*                                                                     * 28412000
         ST    PARM,LASTBUF            SAVE CB ADDR OF LAST BFR FILLED  28416000
LASTTEXT TM    0(CURTXTCB),LASTXT      IS CURRENT TEXT LAST OF GROUP    28420000
         BZ    LASTTXT                 NO                               28424000
         TM    APT3,RLDSINGP           WERE THERE ANY RLDS FOR GROUP    28428000
         BZ    LASTTXT                 NO                               28432000
          NI    NEWSW2,MOVDOFF                                    23971 28434000
         L     PARM,LASTBUF            YES, THEN SET INDIC IN CB OF     28436000
         TM    0(PARM),INUSE           EMPTY BUFFER--SPLIT ADCON ONLY   28440000
         BZ    LASTTXT                 YES                              28444000
         OI    0(PARM),LASTUSED              LAST BUFFER FILLED         28448000
*                                                                     * 28460000
* CHECK IS MORE TEXT IN CURRENT GROUP. IF MORE TEXT, GO TO PROCESS    * 28520000
*     IT.  IF ALL TEXT PROCESSED FOR GROUP PREPARE TO WRITE THE TEXT  * 28580000
*                                                                     * 28640000
LASTTXT  TM    0(CURTXTCB),LASTXT       CURR. TXT LAST IN GROUP         28700000
         BO    LASTTXT0                YES                              28760000
         MVI   0(CURTXTCB),X'00'       CLEAR INDICATORS                 28820000
         B     SGEND0                  GO TO PROCESS NEXT TEXT OF GROUP 28880000
LASTTXT0 NI    NEWSW2,GROUPOFF         RLDS ARE NOT TO BE GROUPED       28940000
         TM    1(CURTXTCB),PREV         PREVIOUS CR/RLD WRITTEN YET     29000000
         BZ    TEXTWRIT                 YES                             29060000
         TM    APT3,RLDSINGP           ANY RLDS FOR FOLLOWING TXT       29120000
         BO    LASTTXT2                                                 29180000
         TM    0(CURTXTCB),SEGMTEND    IS TEXT LAST IN SEGMENT          29240000
         BZ    LASTTXT2                NO                               29300000
         TM    PDSE7,OVLY              IS OVERLAY SPECIFIED             29360000
         BZ    LASTTXT1                NO                               29420000
         CLC   CURSEG+1(1),ENTABSEG    IS AN ENTAB NEEDED               29480000
         BE    LASTTXT2                YES                              29540000
*                                                                     * 29600000
*      SET-UP AND WRITE PREVIOUS CONTROL RECORD IF NOT ALREADY WRITTEN* 29660000
*                                                                     * 29720000
LASTTXT1 L     WORK2,8(PREVCREC)       BEG. OF BUFFER                   29780000
         OI    0(WORK2),SEGEND         SET END OF SEG IN CR             29840000
         CLC   CURSEG(2),ENSPC         LAST SEG OF MODULE               29900000
         BNE   LASTTXT2                                                 29960000
         OI    0(WORK2),MODEND         SET END OF MOD. IN CR            30020000
LASTTXT2 LR    PARM,PREVCREC                                            30080000
         BAL   RETURN,WRTCRRLD         BRANCH TO WRITE PREV CTRL REC    30140000
         NC    1(1,CURTXTCB),1(PREVCREC) MARK PREV.CTRL.REC.WRITTEN     30200000
*                                                                     * 30260000
*          WRITE A TEXT RECORD                                        * 30320000
*                                                                     * 30380000
TEXTWRIT TM    0(CURTXTCB),INUSE       HAS TEXT BEEN WRITTEN            30440000
         BO    WRIT00                  NO                               30500000
         TM    1(CURTXTCB),XDAP        IS XDAP WRITE NEEDED             30560000
         BZ    WRIT0                   NO                               30620000
WRIT00   BAL   RETURN,WRTTXT            BRANCH TO WRITE TEXT            30680000
*                                                                     * 30740000
*    WRITE ALL RLD RECORDS EXCEPT ONE                                 * 30800000
*                                                                     * 30860000
WRIT0    TM    1(CURTXTCB),OUTBUF1     IS BUFFER 1 BEING USED           30900000
         BZ    WRIT10                  NO                               30940000
         L     PARM,OUTCB1                                              30980000
         TM    0(PARM),LASTUSED        IS IT THE LAST BUFFER FILLED     31020000
         BZ    WRIT1                   NO                               31060000
            LR PREVCREC,PARM                                            31100000
         OI    1(CURTXTCB),BUF1PREV    YES,USE FOR ID-LENGTH            31140000
         B     WRIT10                                                   31180000
WRIT1    BAL   RETURN,WRTCRRLD         WRITE BUF 1                      31220000
         NI    1(CURTXTCB),BUF1OFF     TURN OFF BUF 1 BEING USED        31260000
WRIT10   TM    1(CURTXTCB),OUTBUF2     IS BUF 2 BEING USED              31300000
         BZ    WRIT20                  NO                               31340000
         L     PARM,OUTCB2                                              31380000
         TM    0(PARM),LASTUSED        IS IT THE LAST BUFFER FILLED     31420000
         BZ    WRIT2                   NO                               31460000
         OI    1(CURTXTCB),BUF2PREV    YES,USE FOR ID-LENGTH            31500000
            LR PREVCREC,PARM                                            31540000
         B     WRIT20                                                   31580000
WRIT2    BAL   RETURN,WRTCRRLD         WRITE BUF 2                      31620000
         NI    1(CURTXTCB),BUF2OFF     TURN OFF BUF 2 BEING USED        31660000
WRIT20   TM    1(CURTXTCB),OUTBUF3     IS BUF 3 BEING USED              31700000
         BZ    WRIT4                   NO                               31740000
         L     PARM,OUTCB3                                              31780000
         TM    0(PARM),LASTUSED        IS IT THE LAST BUFFER FILLED     31820000
         BZ    WRIT3                   NO                               31860000
         OI    1(CURTXTCB),BUF3PREV    YES,USE FOR ID-LENGTH            31900000
            LR PREVCREC,PARM                                            31940000
         B     TSTSGEND                                                 31980000
WRIT3    BAL   RETURN,WRTCRRLD         WRITE BUF 3                      32020000
         NI    1(CURTXTCB),BUF3OFF     TURN OFF BUF 3 BEING USED        32060000
         B     TSTSGEND                                                 32100000
WRIT4    TM    0(PREVCREC),LASTUSED    HAS PREV CTRL REC BEEN IDENT     32140000
         BO    TSTSGEND                YES                              32180000
         OI    NEWSW2,NOCTLREC          NO,SET NO CTRL.RECS. IN USE     32220000
WRIT5    L     PREVCREC,OUTCB1         USE BFR1. AS PREV. CR            32300000
         TM    0(PREVCREC),BEINGWT     IS IT BEING WRITTEN              32360000
         BO    WRIT6                   YES                              32420000
         OI    1(CURTXTCB),BUF1PREV                                     32480000
         B     TSTSGEND                                                 32540000
WRIT6    L     PREVCREC,OUTCB2         YES, THEN USE BFR2 AS PREV CR    32600000
         OI    1(CURTXTCB),BUF2PREV                                     32660000
*                                                                     * 32900000
*  TEST FOR END OF SEGMENT--IF NOT SWITCH TEXT CONTROL BLOCKS AND     * 32960000
*             RETURN TO PROCESS NEXT TEXT                             * 33020000
*                                                                     * 33080000
TSTSGEND XC    2(2,PREVCREC),2(PREVCREC) ZERO ID-LENGTH FIELD           33140000
         TM    0(CURTXTCB),SEGMTEND     IS TEXT LAST IN SEGMENT         33200000
         BO    SGEND1                   YES                             33260000
         NI    NEWSW2,NOCROFF          INIT NO CTRL REC INDIC           33320000
         TM    0(PREVCREC),INUSE       DOES CONT. REC CONTAIN RLDS      33380000
         BO    SGEND0                  YES                              33440000
SGEND    MVC   4(4,PREVCREC),8(PREVCREC) 1ST FREE ADDR = BFR BEG        33500000
         XC    2(2,PREVCREC),2(PREVCREC) ZERO ID-LENGTH FIELD           33560000
         OI    0(PREVCREC),INUSE       MARK CB IN USE                   33620000
         L     WORK1,8(PREVCREC)                                        33680000
         XC    0(16,WORK1),0(WORK1)    ZERO CONTROL RECORD              33740000
SGEND0   XR    CURTXTCB,NXTTXTCB        SWITCH TEXT CONTROL BLOCKS      33800000
         XR    NXTTXTCB,CURTXTCB                                        33860000
         XR    CURTXTCB,NXTTXTCB                                        33920000
         MVC   1(1,CURTXTCB),1(NXTTXTCB) TRANSFER INDICATORS            33980000
         MVC   1(2,NXTTXTCB),ZERO      ZERO WHEN NOT LAST TEXT OF GROUP 34040000
         NI    0(PREVCREC),LASTOFF                                      34070000
         B     GETID                                                    34100000
*                                                                     * 34160000
*               END OF SEGMENT LOGIC                                  * 34220000
*                                                                     * 34280000
SGEND1   NI    0(PREVCREC),LASTOFF     CLEAR LAST BUFFER USED INDIC     34320000
         TM    PDSE7,OVLY              IS OVERLAY SPECIFIED             34360000
         BZ    SGEND1A                 NO                               34400000
         CLC   CURSEG+1(1),ENTABSEG    IS AN ENTAB NEEDED               34460000
         BNE   SGEND1A                                                  34520000
         LA    RETURN,SGEND3           GET RETURN ADDRESS               34580000
         L     BRANCHX,ADENTAB                                          34640000
         BR    BRANCHX                 GO TO CREATE ENTAB               34700000
SGEND1A  OI    APT3,SEGSTART           YES,SET SEG BEG FOR NEXT SEG     34760000
         TM    NEWSW2,NOCTLREC          ANY RLDS STILL IN BUFFERS       34820000
         BO    SGEND3                   NO                              34880000
         CLC   CURSEG(2),ENSPC          IS THIS THE LAST SEGMENT        34940000
         BL    SGEND2                   NO                              35000000
         L     WORK1,8(PREVCREC)        YES                             35060000
         OI    0(WORK1),MODEND          SET END OF MODULE INDICATOR     35120000
SGEND2   L     WORK1,8(PREVCREC)                                        35180000
         OI    0(WORK1),SEGEND          SET END OF SEGMENT INDIC.       35240000
         LR    PARM,PREVCREC                                            35300000
         BAL   RETURN,WRTCRRLD          GO TO WRITE CONTROL RECORD      35360000
         NC    1(1,CURTXTCB),1(PREVCREC)                                35420000
         NI    0(CURTXTCB),X'FD'       CLEAR END OF SET INDIC           35480000
SGEND3   NI    NEWSW2,NOCROFF          INIT. NO CTRL REC INDIC          35540000
         NI    0(CURTXTCB),X'F0'       TURN OFF SEGMENT END INDIC--     35600000
*                                           TO REUSE TSTSGEND CODING    35660000
         L     BASE2,BASEREG           RESTORE SIO BASE REG      A42052 35690021
         CLC   CURSEG(2),ENSPC          ANY MORE SEGMENTS TO PROCESS    35720000
         BL    WRIT5                   YES                              35840000
*                                                                     * 35900000
*     PROCESSING COMPLETE - GO TO FINAL PROCESSOR                     * 35960000
*                                                                     * 36020000
         TM    0(PREVCREC),BEINGWT      CHECK FOR UNCHECKED CR WRITE    36080000
         BO    ENDCHECK                                                 36140000
         TM    0(CURTXTCB),BEINGWT      CHECK FOR UNCHECKED TEXT WRITE  36200000
         BZ    FINISH                                                   36260000
ENDCHECK BAL   BRANCHX,CHECKWRT         GO TO CHECK LAST WRITE          36320000
FINISH   L     BRANCH,ADFINAL                                           36380000
         BR    BRANCH                   GO TO FINAL PROCESSOR           36440000
*                                                                     * 36500000
*                                                                     * 36560000
*                                                                     * 36620000
*            LOOK-AHEAD / READ-AHEAD ROUTINE                          * 36680000
*                                                                     * 36740000
*                                                                     * 36800000
*                                                                     * 36860000
GETIDMUL EQU   *                                                        36920000
         STM   WORK1,BRANCHX,SAVEREG1  SAVE REGISTER USED               36980000
         L     BASE2,BASEREG      RESTORE SECOND BASE REG.      A24469  37010000
         ST    RETURN,RETURNRG          SAVE RETURN REGISTER            37040000
         L     WORK1,SRCHBEG                                            37100000
         CLC   SRCHMULT(2),ZERO         WORKING WITH NEW CSECT          37160000
         BNE   IDMUL50                  NO                              37220000
*                                                                     * 37280000
*  SEARCH FOR TEXT I/O TABLE ENTRY FOR CURRENT ID AND MULTIPLICITY    * 37340000
*                                                                     * 37400000
IDMUL10  CL    WORK1,TXTIOEND           AT END OF TEXT I/O TABLE        37460000
         BH    IDMUL90                  YES                             37520000
         TM    2(WORK1),TEXTDONE        IS TEXT ALREADY PROCESSED       37580000
         BZ    IDMUL30                                                  37640000
IDMUL20  LA    WORK1,4(WORK1)           UPDATE TO NEXT ENTRY            37700000
         B     IDMUL10                                                  37760000
IDMUL30  TM    2(WORK1),OUTORDER        IS TEXT OUT-OF-ORDER TEXT       37820000
         BO    IDMUL20                                                  37880000
         LH    WORK2,0(WORK1)           GET ID                          37940000
         SLL   WORK2,3                  MULT. BY SIZE OF ENTRY          38000000
         A     WORK2,HESD               HESD ENTRY FOR ID               38060000
         CLC   SRCHSEG+1(1),4(WORK2)   IS ID IN CURRENT SEGMENT         38120000
         BNE   IDMUL20                  NO                              38180000
         MVC   SRCHID(2),0(WORK1)       SET SEARCH ID = ENTRY ID        38240000
         ST    WORK1,IDBEG                                              38300000
         L     WORK3,4(WORK2)                                           38360000
         LA    WORK3,0(WORK3)           LENGTH OF CSECT                 38420000
         LH    WORK2,LSTMULSZ          PICK UP LAST MULT SIZE    A33762 38440021
         LA    WORK2,7(WORK2)          ROUND TO                  A33762 38460021
         N     WORK2,DBLWRDDD          DOUBLE WORD BOUNDARY      A33762 38480021
         STH   WORK2,LSTMULSS          SAVE IT                   A33762 38500021
         SR    WORK2,WORK2             ZERO OUT WORK2 REG        A33762 38520021
         D     WORK2,MULTSIZE                                           38540000
         STH   WORK2,LSTMULSZ          SAVE LAST MULT. SIZE             38600000
         LTR   WORK2,WORK2              IS THE REMAINDER ZERO           38660000
         BC    7,IDMUL40                NO                              38720000
         MVC   LSTMULSZ(2),MULTSIZE+2  SAVE LAST MULT SIZE              38780000
         BCTR  WORK3,0                  DECR. HIGH MULT. BY 1           38840000
IDMUL40  STH   WORK3,HIGHMULT           SAVE HIGHEST MULT. FOR ID       38900000
IDMUL50  MVC   TEMP(2),2(WORK1)        GET ENTRY MULT                   38960000
         NI    TEMP,X'03'               CLEAR OUT FLAG BITS             39020000
         CLC   TEMP(2),HIGHMULT        COMPARE TO HIGH MULT     SA66746 39070000
         BNH   IDMUL51                 BRANCH IF VALID          SA66746 39072000
         LA    REG0,X'0438'            LOG MSG IEW0564          SA66746 39074000
         L     REG15,ERDIG             GET LINK TO ERROR RTN    SA66746 39076000
         BALR  REG14,REG15             GO TO LOG MSG, QUIT      SA66746 39078000
IDMUL51  EQU   *                       ERROR MSG BYPASS         SA66746 39078400
         CLC   TEMP(2),SRCHMULT        ENTRY MULT = SEARCH MULT         39080000
         BE    IDMUL150                                                 39140000
IDMUL60  LA    WORK1,4(WORK1)           INDEX TO NEXT TXTIOT ENTRY      39200000
         ST    WORK1,SRCHBEG                                            39260000
         CL    WORK1,TXTIOEND           AT END OF TEXT I/O TABLE        39320000
         BH    IDMUL70                 YES                              39380000
         CLC   0(2,WORK1),SRCHID        ENTRY ID = SEARCH ID            39440000
         BE    IDMUL50                  YES, CHECK MULT.                39500000
         B     IDMUL60                  NO, UPDATE TO NEXT ENTRY        39560000
*                                                                     * 39620000
*   MULTIPLICITY WITH NO TEXT ----COMPENSATE FOR IT                   * 39680000
*                                                                     * 39740000
IDMUL70  CLC   SRCHMULT(2),ZERO        IS FIRST MULT MISSING            39800000
         BNE   IDMUL75                 NO                               39860000
         LH    WORK2,SRCHID            GET TEXT ID                      39920000
         SLL   WORK2,3                                                  39980000
         A     WORK2,HESD                                               40040000
         MVC   CCWDISP+1(3),1(WORK2)   INIT CCWDISP =LKA                40100000
         B     IDMUL77                                                  40160000
IDMUL75  L     WORK3,CCWDISP                                            40220000
         A     WORK3,MULTSIZE                                           40280000
         ST    WORK3,CCWDISP            UPDATE CCW DISP. BY MULT. SIZE  40340000
IDMUL77  LH    WORK2,SRCHMULT                                           40400000
         LA    WORK2,1(WORK2)                                           40460000
         STH   WORK2,SRCHMULT           UPDATE SEARCH MULT.             40520000
         CH    WORK2,HIGHMULT           IS IT A VALID MULT FOR THIS ID  40580000
         BH    IDMUL80                  NO                              40640000
         MVC   SRCHBEG(4),IDBEG                                         40700000
         L     WORK1,IDBEG                                              40760000
         B     IDMUL50                                                  40820000
IDMUL80  XC    SRCHMULT(2),SRCHMULT     SET SEARCH MULT = 0             40880000
         L     WORK1,IDBEG                                              40940000
         LA    WORK1,4(WORK1)                                           41000000
         ST    WORK1,SRCHBEG                                            41060000
         B     IDMUL10                                                  41120000
*                                                                     * 41180000
*        ALL  TEXT FOR A SEGMENT HAS BEEN  PROCESSED                  * 41240000
*                                                                     * 41300000
IDMUL90  LH    WORK2,SRCHSEG                                            41360000
         LA    WORK2,1(WORK2)                                           41420000
         STH   WORK2,SRCHSEG            UPDATE TO NEXT SEGMENT          41480000
         MVC   SRCHBEG(4),TXTIO         INIT SEARCH POINTER             41540000
IDMUL130 TM    0(PARM),FIRSTXT         IS TEXT FIRST OF GROUP           41600000
         BZ    IDMUL140                                                 41660000
         MVC   29(3,PARM),CCWDISP+1    PUT CCW DISP IN TXT CTRL BLK.    41720000
IDMUL140 L     RETURN,RETURNRG          RESTORE REGISTERS               41780000
         LM    WORK1,BRANCHX,SAVEREG1  RESTORE REGISTERS USED           41840000
         BR    RETURN                   RETURN                          41900000
*                                                                     * 41960000
*             GET CCW DISPLACEMENT INFORMATION                        * 42020000
*                                                                     * 42080000
IDMUL150 ST    WORK1,12(PARM)           STORE TXTIOT ENTRY ADDR.IN CB   42140000
         CLC   SRCHMULT(2),ZERO         WORKING WITH NEW CSECT          42200000
         BNE   IDMUL170                 NO                              42260000
         LH    WORK2,0(WORK1)           GET ID                          42320000
         SLL   WORK2,3                                                  42380000
         A     WORK2,HESD                                               42440000
         L     WORK3,CCWDISP           PICK UP CCW DISP          A33762 42446021
         LA    WORK3,0(WORK3)          CLEAR HIGH ORDER BYTE     A33762 42452021
         AH    WORK3,LSTMULSS          ADD TO LAST MULT SIZE     A33762 42458021
         ST    WORK3,CCWDISP           SAVE IT TEMPORARILY       A33762 42464021
         CLC   CCWDISP+1(3),1(WORK2)   IS THE NEXT CSECT ADJA.   A33762 42470021
         MVC   CCWDISP+1(3),1(WORK2)   REPLACE IT ANY WAY        A33762 42476021
         BE    IDMUL180                YES,GROUPING POSSIBLE     A33762 42482021
         OI    SSWITCH,X'01'           NO,DO NOT ALLOW GROUPING  A33762 42488021
         B     IDMUL180                                                 42560000
IDMUL170 L     WORK2,CCWDISP                                            42620000
         A     WORK2,MULTSIZE                                           42680000
         ST    WORK2,CCWDISP            UPDATE CCW DISP. FOR CUR. MULT. 42740000
*                                                                     * 42800000
*      GET FIRST AND LAST TXTIOT ENTRIES FOR GROUP                    * 42860000
*                                                                     * 42920000
IDMUL180 CL    WORK1,TXTIO              CURRENT ENTRY FIRST IN TABLE    42980000
         BE    IDMUL182                 YES                             43040000
         SH    WORK1,FOUR               DECR. TO PRECEDING ENTRY        43100000
         TM    2(WORK1),TTRENTRY        IS THIS A TTR ENTRY             43160000
         BZ    IDMUL180                 NO                              43220000
         LA    WORK1,4(WORK1)           YES,UPDATE TO FIRST GROUP ENTRY 43280000
IDMUL182 ST    WORK1,16(PARM)           SAVE AS BEG. ENTRY              43340000
IDMUL184 TM    2(WORK1),TTRENTRY        IS THIS A TTR ENTRY             43400000
         BO    IDMUL185                 YES                             43460000
         CL    WORK1,TXTIOEND           IS THIS THE LAST ENTRY          43520000
         BE    IDMUL185                 YES                             43580000
         LA    WORK1,4(WORK1)           NO, INCR. TO THE NEXT ENTRY     43640000
         B     IDMUL184                                                 43700000
IDMUL185 ST    WORK1,20(PARM)           SAVE AS END ENTRY               43760000
         L     WORK1,12(PARM)                                           43820000
         TM    2(WORK1),INCORE          IS THE TEXT IN CORE             43880000
         BO    IDMUL300                 YES                             43940000
*                                                                     * 44000000
*    CHECK IF RECORD CAN BE READ IN BOTTOM OF BUFFER                  * 44060000
*                                                                     * 44120000
         SR    WORK2,WORK2              CLEAR FOR ACCUM. RECORD LENGTH  44180000
         L     WORK3,TXTIO                                              44240000
         L     WORK1,16(PARM)           GET  BEG. GROUP ENTRY           44300000
         LNR   WORK3,WORK3                                              44360000
         AR    WORK3,WORK1                                              44420000
         SRL   WORK3,2                  GET ENTRY NUMBER                44480000
         MH    WORK3,SEVEN                                              44540000
         A     WORK3,TNLS2              GET ADDR.OF CORRES.NOTELIST     44600000
IDMUL190 MVC   TEMP(2),5(WORK3)              ENTRY - GET LENGTH         44660000
         AH    WORK2,TEMP               ADD LENGTH TO ACCUM RECORD CT.  44720000
         CL    WORK1,20(PARM)           IS THIS LAST ENTRY FOR GROUP    44780000
         BE    IDMUL210                 YES                             44840000
         LA    WORK1,4(WORK1)           NO, UPDATE TO NEXT TXTIOT ENTRY 44900000
         LA    WORK3,7(WORK3)           UPDATE TO NEXT NOTELIST ENTRY   44960000
         B     IDMUL190                                                 45020000
IDMUL210 LR    WORK1,WORK2                                              45080000
         MVC   TTRPOINT(3),2(WORK3)    GET TTR FOR POINT                45140000
         A     WORK1,FREEADDR                                           45200000
         CL    WORK1,TXTBFEND           WILL REC. FIT IN BOTTOM OF BFR. 45260000
         BH    IDMUL220                 NO, CHECK IF FITS AT TOP        45320000
         BAL   RETURN,RDTXT             YES, BRANCH TO READ NEEDED TXT  45380000
         B     IDMUL301                                                 45440000
*                                                                     * 45500000
*   CHECK TO SEE IF RECORD CAN BE READ AT TOP OF BFR.-CHECK FOR A     * 45560000
*                   POSSIBLE SPLIT  ADDRESS CONSTANT                  * 45620000
IDMUL220 LTR   WORK0,WORK0              WORKING WITH CUR. OR NEXT TXTCB 45680000
         BZ    IDMUL230                CURR TXTCB                       45740000
         TM    0(CURTXTCB),INUSE        IS OTHER TXTCB IN USE           45800000
         BZ    IDMUL240                 NO,TEXT WILL FIT AT TOP OF BFR. 45860000
         L     WORK3,4(CURTXTCB)        GET BEG. ADDR. OF TEXT          45920000
         OI    0(CURTXTCB),LASTXT       SET LAST TXT IN GROUP INDIC.    45980000
         XC    GROUPLNG(2),GROUPLNG    INIT GROUPLNG                    46040000
         B     IDMUL235                                                 46100000
IDMUL230 TM    0(NXTTXTCB),INUSE        IS OTHER TXTCB IN USE           46160000
         BZ    IDMUL240                 NO, TEXT WILL FIT AT TOP OF BFR 46220000
         L     WORK3,4(NXTTXTCB)                                        46280000
IDMUL235 A     WORK2,TXTBFBEG                                           46370000
         CLR   WORK2,WORK3              WILL TEXT FIT AT TOP OF BFR.    46460000
         BNH   IDMUL240                                                 46520000
         OI    2(CURTXTCB),MORETXT     SET MORE TEXT TO PROCESS         46580000
         L     WORK3,CCWDISP                                            46586000
         S     WORK3,MULTSIZE                                           46592000
         ST    WORK3,CCWDISP           RESET CCW DISP                   46598000
         MVC   SRCHBEG(4),IDBEG                                         46604000
         LTR   WORK0,WORK0             IS THIS A PRIME READ             46610000
         BNZ   IDMUL130                NO                               46616000
         BAL   BRANCHX,CHECKWRT        CHECK WRITE                      46622000
         NI    0(NXTTXTCB),WRTCKD      MARK WRITE CHECKED               46628000
         B     IDMUL130                                                 46640000
IDMUL240 MVC   FREEADDR(4),TXTBFBEG    SET FIRST FREE ADDR TO BFR BEG   46700000
         CLC   SRCHMULT(2),ZERO         WORKING WITH NEW CSECT          46760000
         BE    IDMUL250                 YES                             46820000
         CLC   SRCHID(2),CURID          WORKING WITH NEW CSECT          46880000
         BNE   IDMUL250                 YES                             46940000
         LH    WORK3,CURMULT                                            47000000
         LA    WORK3,1(WORK3)                                           47060000
         CH    WORK3,SRCHMULT           NO,CHECK FOR CONTIGUOUS MULT.   47120000
         BNE   IDMUL250                NOT CONTIGUOUS--READ             47180000
         OI    2(CURTXTCB),MORETXT     SET MORE TEXT TO PROCESS         47240000
         L     WORK3,CCWDISP                                            47300000
         S     WORK3,MULTSIZE                                           47360000
         ST    WORK3,CCWDISP           RESET CCW DISPLACEMENT           47420000
         B     IDMUL130                                                 47480000
IDMUL250 BAL   RETURN,RDTXT             BRANCH TO READ TEXT AT BFR.TOP  47540000
         B     IDMUL301                                                 47600000
*                                                                     * 47660000
*     THE NEEDED TEXT IS IN CORE - DETERMINE TEXT GROUPING            * 47720000
*                                                                     * 47780000
IDMUL300 BAL   RETURN,RDTXT             GO TO READ IN OUT-OF-ORDER TXT  47840000
IDMUL301 TM    PDSE8,DC                 IS DC SPECIFIED                 47900000
         BZ    IDMUL305                YES                              47960000
         TM    PDSE7,SCTR               IS SCATTER SPECIFIED            48020000
         BZ    IDMUL310                 NO                              48080000
IDMUL305 OI    0(PARM),LASTXT           SET LAST TEXT IN GROUP INDIC.   48140000
         XC    GROUPLNG(2),GROUPLNG     ZERO GROUPLNG                   48200000
IDMUL310 L     WORK1,12(PARM)          CURRENT TXTIOT ENTRY             48260000
         LR    WORK3,WORK1                                              48320000
         S     WORK3,TXTIO                                              48380000
         SRL   WORK3,2                                                  48440000
         MH    WORK3,SEVEN                                              48500000
         A     WORK3,TNLS2                                              48560000
         MVC   24(2,PARM),5(WORK3)      SAVE TEXT LENGTH IN TXTCB       48620000
         LH    WORK3,0(WORK1)                                           48680000
         SLL   WORK3,3                                                  48740000
         A     WORK3,HESD                                               48800000
         LR    WORK8,WORK3             SAVE HESD ENTRY ADDR             48860000
         L     WORK3,4(WORK3)           GET CSECT LENGTH FROM HESD      48920000
         LA    WORK3,0(WORK3)                                           48980000
         AH    WORK3,GROUPLNG                                           49040000
         CL    WORK3,MULTSIZE          IS GROUP LNG+CSECT LNG GT.MULT   49100000
         BNH   IDMUL330                NO                               49160000
IDMUL324 LH    WORK3,GROUPLNG     LOAD GROUP LENGTH            A23945   49220000
         LTR   WORK3,WORK3              IS GROUP LENGTH = 0             49280000
         BZ    IDMUL325                 YES                             49340000
         OI    0(CURTXTCB),LASTXT       SET LAST TEXT FOR GROUP         49400000
         XC    GROUPLNG(2),GROUPLNG     SET GROUP LENGTH = 0            49460000
IDMUL325 OI    0(PARM),FIRSTXT          SET FIRST TEXT OF GROUP         49520000
         B     IDMUL340                                                 49580000
IDMUL330 TM    SSWITCH,1               IS GROUPING ALLOWED       A33762 49600021
         MVI   SSWITCH,0               RESET SWITCH ANYWAY       A33762 49620021
*                                      TO CARRY CONDITION CODE   A42052 49630021
         BO    IDMUL324                NO GROUPING               A33762 49640021
         LH    WORK3,GROUPLNG          SWITCH OFF,ALLOW GROUPING A33762 49660021
         LTR   WORK3,WORK3              IS GROUP LENGTH = 0             49700000
         BZ    IDMUL325                 YES                             49760000
IDMUL340 OI    2(WORK1),TEXTDONE        MARK TEXT PROCESSED             49820000
         OI    0(PARM),INUSE            MARK TXTCB  IN USE              49880000
*                                                                     * 49940000
*     CALC. BEGINNING AND END TEXT ADDRESS FOR TEXT CTRL. BLK         * 50000000
*                                                                     * 50060000
         TM    0(PARM),FIRSTXT         IS CURR TEXT 1ST OF GROUP        50120000
         BZ    IDMUL345                NO                               50180000
         LA    BRANCHX,IDMUL344                                         50240000
         L     WORK2,12(PARM)          CUR TXTIOT ENTRY OF GROUP        50300000
IDMUL343 S     WORK2,TXTIO                                              50360000
         SRL   WORK2,2                 GET ENTRY NO.                    50420000
         MH    WORK2,SEVEN                                              50480000
         A     WORK2,TNLS2             CORRES. NOTELIST ENTRY           50540000
         BR    BRANCHX                                                  50600000
IDMUL344 MVC   PREVBEG+1(3),2(WORK2)                                    50660000
IDMUL345 MVC   5(3,PARM),PREVBEG+1     GET BEG. TEXT ADDR               50720000
         LA    BRANCHX,IDMUL347                                         50780000
         L     WORK2,12(PARM)                                           50840000
         B     IDMUL343                                                 50900000
IDMUL347 MVC   9(3,PARM),2(WORK2)      TEXT ADDR OF CURR OF GROUP       50960000
         MVC   TEMP(2),5(WORK2)        CALC END ADDR                    51020000
         LH    WORK2,TEMP                                               51080000
         A     WORK2,8(PARM)                                            51140000
         ST    WORK2,8(PARM)           SAVE AS TEXT END ADDR            51200000
*                                                                     * 51260000
*                    SET-UP FOR NEXT LOOK-AHEAD                       * 51320000
*                                                                     * 51380000
         CLC   SRCHMULT(2),HIGHMULT     IS MULT = HIGHEST MULT.         51440000
         BNE   IDMUL350                 NO                              51500000
         XC    SRCHMULT(2),SRCHMULT    ZERO SEARCH MULT                 51560000
         LH    WORK3,24(PARM)                                           51620000
         AH    WORK3,GROUPLNG                                           51680000
         STH   WORK3,GROUPLNG           UPDATE  GROUP LENGTH            51740000
         STH   WORK3,26(PARM)           PUT ACCUM. GROUP LENGTH IN CB   51800000
         L     WORK3,IDBEG                                              51860000
         LA    WORK3,4(WORK3)                                           51920000
         ST    WORK3,SRCHBEG            SET SRCHBEG TO NEXT ENTRY       51980000
         TM    0(WORK8),X'40'          IS ID LAST ID WITH TEXT IN SEG   52040000
         BZ    IDMUL348                NO                               52100000
         OI    0(PARM),ENDINDIC        SET END INDIC IN TXTCB           52160000
         XC    GROUPLNG(2),GROUPLNG    INIT GROUP CT. FOR NEXT SEG.     52220000
         CLC   SRCHSEG(2),ENSPC        IS SEGMENT LAST SEGMENT          52280000
         BNE   IDMUL348                NO                               52340000
         OI    0(PARM),MODULEND        SET LAST TEXT OF MODULE          52400000
IDMUL348 CLC   HIGHMULT(2),ZERO        CAN CURR. TXT BE GROUPED WITH    52460000
*                                        NEXT TEXT                      52520000
         BZ    IDMUL130                YES                              52580000
         OI    0(PARM),LASTXT          NO                               52640000
         XC    GROUPLNG(2),GROUPLNG    ZERO GROUP LENGTH                52700000
         B     IDMUL130                 GO TO RETURN                    52760000
IDMUL350 LH    WORK3,SRCHMULT                                           52820000
         LA    WORK3,1(WORK3)                                           52880000
         STH   WORK3,SRCHMULT           UPDATE SEARCH MULT              52940000
         MVC   26(2,PARM),24(PARM)     SET GROUP LENGTH = MULT.SIZE     53000000
         OI    0(PARM),LASTXT           SET LAST TEXT FOR GROUP INDIC.  53060000
         XC    GROUPLNG(2),GROUPLNG     ZERO GROUP LENGTH               53120000
         MVC   SRCHBEG(4),IDBEG                                         53180000
         B     IDMUL130                 GO TO RETURN                    53240000
*                                                                     * 76520000
*                   CONSTANTS                                         * 76580000
SAVEREG1 DS    7F                 SAVE AREA                    A24496   76600000
SAVESTOR DS    1F                      SAVE WORK1 FOR SEGNO      A42052 76620021
ZERO     DC    X'0000'                                                  76640000
ONE      DC    H'1'                                                     76700000
FOUR     DC    H'4'                                                     76760000
FIVE     DC    H'5'                                                     76820000
SIX      DC    F'6'                                                     76880000
SRCHSEG  DC    H'0'                     SEGMENT NO. BEING SEARCHED      77120000
SRCHID   DC    H'0'                     ID BEING SEARCHED               77180000
SRCHMULT DC    H'0'                     MULT. BEING SEARCHED            77240000
OUTCB1   DC    V(OTRLDCB1)              RLD OUTPUT CONTROL BLOCKS       77300000
OUTCB2   DC    V(OTRLDCB2)                                              77360000
OUTCB3   DC    V(OTRLDCB3)                                              77420000
INCB1    DC    V(INRLDCB1)              RLD INPUT CONTROL BLOCKS        77480000
INCB2    DC    V(INRLDCB2)                                              77540000
ADREL    DC    V(IEWLMREL)              RELOCATION ROUTINE              77600000
RELOC    DC    V(RELOCATE)             ENTRY IN IEWLMREL FOR RELOC.     77660000
ADENTAB  DC    V(SCDENTAB)                                              77720000
ADFINAL  DC    V(IEWLMFNL)              FINAL PROCESSOR                 77780000
ADSIO    DC    A(IEWLMSIO)             ADDR OF IEWLMSIO          A42052 77810021
MOVE     MVC   16(0,WORK3),0(WORK2)     MOVE ID-LENGTH LIST TO BEG. OF  78020000
*                                            RLD OUTPUT BUFFER          78080000
***                                                                 *** 78140000
*                       SAVE AREAS                                    * 78200000
***                                                                 *** 78260000
LSTMULSS DC    H'0'                                              A33762 78270021
SSWITCH  DC    H'0'                                              A33762 78280021
*                                      BITS FOR SSWITCH+ONE      A42052 78282021
SEGNO    EQU   X'80'                   SEG # NOT = 1+LAST SEG #  A42052 78284021
SEGNOOFF EQU   X'7F'                   TURN OFF BIT              A42052 78286021
         DS    0F                                                       78290021
DBLWRDDD DC    X'FFFFFFF8'                                       A33762 78300021
RLDION   DS    1F                       RLD NOTELIST ENTRY ADDR.        78320000
LASTBUF  DS    1F                      CB ADDR OF LAST BUFFER FILLED    78350000
TTRPOINT DC    F'0'                    SAVE AREA FOR TTR0 FOR POINT     78380000
RETURNRG DS    1F                      SAVE AREA FOR RETURN REG         78440000
TEMP     DS    1H                       TEMP STORAGE AREA               78620000
HIGHMULT DS    1H                       HIGHEST MULT. FOR ID            78680000
LSTMULSZ DC    H'0'                    SAVE AREA FOR LAST MULT SIZE     78740000
CURRGN   DS    XL1                TEMP. STORAGE FOR REGION NO. PTF20888 78890000
*                                          ROUTINES                     78920000
PATCH    DS    25F     ********PATCH AREA   **************************  79520000
         IEWAPT                                                         80180000
*                                                                     * 80240000
*                   APT  REDEFINITIONS                                * 80300000
*                                                                     * 80360000
CURENTAB EQU   IOCT                     HESD ADDR.OF NEXT ENTAB ENTRY   80420000
LKAENTAB EQU   IOCT+4                   ENTAB LKA                       80480000
ENTABSEG EQU   IOCT+8                   ENTAB SEGMENT NUMBER            80540000
GROUPLNG EQU   IOCT+10                  ACCUMULATED GROUP LENGTH        80600000
CCWDISP  EQU   IOCT+12                  CCW DISPLACEMENT                80660000
CBTOUSE  EQU   IOCT+20                  CTRL.BLK.ADDR.FOR BFR.WITH      80720000
*                                            SPLIT RLD                  80780000
CURSEG   EQU   EPSM                     CURRENT SEGMENT                 80840000
CURID    EQU   EPSM+4                   CURREND ID                      80900000
CURMULT  EQU   EPSM+6                   CURRENT MULTIPLICITY            80960000
TEMPSTOR EQU   SPACES                   SAVE AREA FOR I/O SUBROUTINES   81020000
CONTSAVE EQU   SPACES+28                TEMP SAVE AREA FOR CTRL. INFO.  81080000
TXTIOEND EQU   SPACES+44                END ADDR.OF TXT I/O TABLE       81140000
ENDRLDNT EQU   SPACES+48                END ADDR.OF RLD NOTELIST+1      81200000
IDBEG    EQU   SPACES+52                WHERE TO RESUME SEARCH OF       81260000
*                                            TXTIOT FOR NEW MULT.OF ID  81320000
SRCHBEG  EQU   SPACES+56                WHERE TO RESUME SEARCH OF       81380000
*                                            TXTIOT FOR NEW ID          81440000
CURENTRY EQU   SPACES+60               FIRST FREE ADDR IN ENTRY LIST    81500000
FREEADDR EQU   SPACES+64               FIRST FREE ADDR IN TEXT BUFFER   81560000
PREVBEG  EQU   SPACES+68               ADDR OF 1ST TEXT OF GROUP        81620000
 TITLE 'IEWLMSIO - SECOND PASS I/O'                                     81650021
IEWLMSIO CSECT                                                          81680021
*C816800-999999                                                  A42052 81710021
*   *   *  *   *   *   *  *   *   *   *   *   *   *   *   *   *   *   * 81740021
*  THIS CSECT WAS CREATED FROM THE I/O ROUTINES THAT WERE FORMERLY IN * 81770021
*  THE CSECT IEWLMSCD.  THE ROUTINES INCLUDED IN THIS CSECT ARE:      * 81800021
*        WRTTXT: TO WRITE OUT THE TEXT USED BY IEWLMSCD AND           * 81830021
*                IEWLMREL                                             * 81860021
*        WRTCRRLD: TO WRITE OUT CONTROL RLD RECORDS, USED BY          * 81890021
*                IEWLMSCD AND IEWLMREL                                * 81920021
*        CHECKRD: TO CHECK READS, USED BY IEWLMSCD AND IEWLMREL       * 81950021
*        CHECKWRT: TO CHECK THE WRITES, USED BY IEWLMSCD AND          * 81980021
*                IEWLMREL                                    A42052   * 82010021
*   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   * * 82040021
FIRSTOFF EQU   X'F7'                                                    82070021
*                     BYTE 2                                          * 82100021
NOTXDAP  EQU   X'7F'                    REGULAR WRITE NEEDED            82130021
DUMMY    EQU   X'40'                    DUMMY WRITE                     82160021
DUMMYOFF EQU   X'BF'                    REGULAR WRITE                   82190021
*                           BYTE  3                                   * 82220021
RLDIN1   EQU   X'80'                    INPUT BFR1 CONTAINS NEEDED RLDS 82250021
RLDIN2   EQU   X'20'                    INPUT BFR2 CONTAINS NEEDED RLDS 82280021
***         TEXT  I/O TABLE  INDICATORS                             *** 82310021
BADLNG   EQU   X'08'                   CORRES. NOTELIST ENTRY HAS       82340021
*                                             INCORRECT LENGTH          82370021
***      RLD  NOTELIST INDICATORS                                   *** 82400021
*INCORE  EQU   X'80'                    RLDS IN CORE                    82430021
OUTCORE  EQU   X'6F'                                                    82460021
*TTRENTRY EQU  X'40'                   TTR ENTRY                        82490021
*              CONTROL RECORD INDICATORS                              * 82520021
*        APT3  SWITCH INDICATORS                                      * 82550021
*FIRSTXT EQU   X'08'                    FIRST TEXT OF LOAD MODULE       82580021
NRLD1TXT EQU   X'01'                    ONE TEXT REC - NO RLDS          82610021
*                                                                     * 82640021
*                        REGISTER USAGE                               * 82670021
*                                                                     * 82700021
R10      EQU   10                                                       82730021
R11      EQU   11                                                       82760021
R12      EQU   12                                                       82790021
R13      EQU   13                                                       82820021
R14      EQU   14                                                       82850021
R15      EQU   15                                                       82880021
ZRO      EQU   0                                                        82910021
ON1      EQU   1                                                        82940021
FOR      EQU   4                                                        82970021
EIGHT    EQU   8                                                        83000021
TWELVE   EQU   12                                                       83030021
TWENTY4  EQU   24                                                       83060021
         ENTRY WRTTXT                                                   83090021
         ENTRY WRTCRRLD                                                 83120021
         ENTRY CHECKRD                                                  83150021
         ENTRY CHECKWRT                                                 83180021
SIO0010  EQU   *                                                        83210021
         SAVE  (14,12),T,*              SAVE REGS AND NAME CSECT        83240021
***    *     *     *    *    *    *    *    *    *    *    *    *   *** 83270021
*                                                                     * 83300021
*             ROUTINE TO SET-UP AND READ TEXT                           83330021
*                                                                     * 83360021
***    *     *     *    *    *    *    *    *    *    *    *    *   *** 83390021
RDTXT    EQU   *                                                        83420021
         STM   R14,R12,TWELVE(R13)     SAVE REGS                        83450021
         BALR  R10,0                    *  *  *  *  *  *  *  *  *  *  * 83480021
         LA    R11,RDTXT-SIO0010+6      *  ESTABLISH ADDRESSIBILITY   * 83510021
         SR    R10,R11                  *  *  *  *  *  *  *  *  *  *  * 83540021
         ST    R13,SIOSAVE1+FOR         *                             * 83570021
         LR    R15,R13                  *  ESTABLISH SAVE AREAS       * 83600021
         LA    R13,SIOSAVE1             *                             * 83630021
         ST    R13,EIGHT(R15)           *  *  *  *  *  *  *  *  *  *  * 83660021
         L     WORK1,12(PARM)           CURRENT TXTIOT ENTRY            83690021
         L     WORK2,TXTIO                                              83720021
         LNR   WORK2,WORK2                                              83750021
         AR    WORK2,WORK1                                              83780021
         SRL   WORK2,2                                                  83810021
         MH    WORK2,SEVEN                                              83840021
         A     WORK2,TNLS2              CORRES. NOTELIST ENTRY          83870021
         MVC   CURTXTAD+1(3),2(WORK2)  BFR. ADDR. FOR OUT-OF ORDER READ 83900021
         CLR   PARM,CURTXTCB            LOOKAHEAD OR PRIME READ         83930021
         BE    RDTXT30                  PRIME READ                      83960021
*                                                                     * 83990021
*              CHECK ANY UNCHECKED READS                              * 84020021
*                                                                     * 84050021
         TM    0(CURTXTCB),BEINGRD      LOOKAHEAD READ INITIATED        84080021
         BZ    RDTXT50                  NO                              84110021
         NI    0(CURTXTCB),RDCHKD                                       84140021
         B     RDTXT40                                                  84170021
RDTXT30  TM    0(NXTTXTCB),BEINGRD                                      84200021
         BZ    RDTXT50                  NO                              84230021
         NI    0(NXTTXTCB),RDCHKD                                       84260021
RDTXT40  BAL   BRANCHX,CHCKRD2          YES GO TO CHECK THE READ        84290021
RDTXT50  TM    2(WORK1),INCORE          IS TEXT IN CORE                 84320021
         BO    RDTXT70                  YES,GO TO READ OUT-OF-ORDER TXT 84350021
         L     PARM,FREEADDR            1ST FREE ADDR. IN BUFFER        84380021
         BAL   BRANCHX,SCDREAD          BRANCH TO READ TEXT             84410021
         L     PARM,SIOSAVE1+FOR        RESTORE ADDR OF                 84440021
         L     PARM,TWENTY4(PARM)       TXT CNTROL BLOCK                84470021
         OI    0(PARM),BEINGRD          SET BEING READ INDIC.           84500021
         L     WORK1,16(PARM)           1ST TXTIOT ENTRY                84530021
         L     WORK2,TXTIO                                              84560021
         LNR   WORK2,WORK2                                              84590021
         AR    WORK2,WORK1                                              84620021
         SRL   WORK2,2                                                  84650021
         MH    WORK2,SEVEN                                              84680021
         A     WORK2,TNLS2              CORRES. NOTELIST ENTRY          84710021
         L     WORK3,FREEADDR           GET 1ST FREE ADDR.BEORE READ    84740021
RDTXT60  OI    2(WORK1),INCORE          MARK TEXT IN CORE               84770021
         MVC   2(3,WORK2),FREEADDR+1    STORAGE ADDR. OF TEXT           84800021
         CL    WORK1,12(PARM)           LOOKING AT CURRENT ENTRY        84830021
         BNE   RDTXT65                  NO                              84860021
         MVC   CURTXTAD+1(3),2(WORK2)  BFR.ADDR.FOR OUT-OR-ORDER READS  84890021
         TM    2(WORK1),BADLNG         IS LENGTH INCORRECT              84920021
         BZ    RDTXT65                 NO                               84950021
         MVC   5(2,WORK2),LSTMULSZ      CORRECT LENGTH IN NOTELIST      84980021
RDTXT65  MVC   TEMP(2),5(WORK2)        MOVE TEXT LENGTH FOR ALIGN.      85010021
         AH    WORK3,TEMP               UPDATE STORAGE ADDR.            85040021
         ST    WORK3,FREEADDR           SAVE FOR MVC                    85070021
         CL    WORK1,20(PARM)          IS THIS LAST ENTRY IN GROUP      85100021
         BE    RDTXT70                  YES                             85130021
         LA    WORK1,4(WORK1)           UPDATE TO NEXT TXTIOT ENTRY     85160021
         LA    WORK2,7(WORK2)          UPDATE TO NEXT NOTELIST ENTRY    85190021
         B     RDTXT60                                                  85220021
*              SEARCH  FOR OUT-OF-ORDER TEXT                          * 85250021
RDTXT70  TM    2(WORK1),OUTORDER        IS ENTRY MARKED OUT-OF-ORDER    85280021
         BZ    RDTXT90                  NO                              85310021
         TM    2(WORK1),INCORE         IS TXT IN CORE                   85340021
         BO    RDTXT90                YES                               85370021
         CLC   0(2,WORK1),SRCHID        IS ID = CURRENT ID              85400021
         BNE   RDTXT90                 NO                               85430021
         MVC   TEMP(2),2(WORK1)                                         85460021
         NI    TEMP,X'03'                                               85490021
         CLC   TEMP(2),SRCHMULT         IS MULT = CURRENT MULT          85520021
         BNE   RDTXT90                                                  85550021
         MVC   TTRPOINT(3),2(WORK2)    TTR  FOR  POINT                  85580021
         MVC   TEMP(2),0(WORK2)        MOVE DISP. FOR ALIGNMENT         85610021
         L     PARM,SIOSAVE1+FOR       RESTORE REG 1                    85640021
         L     PARM,TWENTY4(PARM)      FROM SAVE AREA                   85670021
         TM    0(PARM),BEINGRD         ANY OUTSTANDING READ             85700021
         BZ    RDTXT80                 NO, GO TO READ                   85730021
         BAL   BRANCHX,CHCKRD2         YES, CHECK IT                    85760021
         NI    0(PARM),RDCHKD          MARK READ CHECKED                85790021
RDTXT80  L     PARM,CURTXTAD           ADDR OF TEXT                     85820021
         AH    PARM,TEMP                READ ADDR.                      85850021
         BAL   BRANCHX,SCDREAD          BRANCH TO READ OUT-OF-ORDER TXT 85880021
         BAL   BRANCHX,CHCKRD2         CHECK READ                       85910021
RDTXT90  LA    WORK1,4(WORK1)           UPDATE TO NEXT TXTIOT ENTRY     85940021
         LA    WORK2,7(WORK2)           UPDATE TO NEXT NOTELIST ENTRY   85970021
         CL    WORK1,TXTIOEND           AT END OF TEXT I/O TABLE        86000021
         BNH   RDTXT70                 NO                               86030021
         B     SIOEXIT1                 RETURN                          86060021
*                                                                     * 86090021
*                                                                     * 86120021
*              ROUTINE TO SET-UP AND READ RLD'S                       * 86150021
*                                                                     * 86180021
*                                                                     * 86210021
RDRLD    EQU   *                                                        86240021
         STM   R14,R12,TWELVE(R13)      SAVE REGS                       86270021
         BALR  R10,0                    *  *  *  *  *  *  *  *  *  *  * 86300021
         LA    R11,RDRLD-SIO0010+6      *  ESTABLISH ADDRESSIBILITY   * 86330021
         SR    R10,R11                  *  *  *  *  *  *  *  *  *  *  * 86360021
         ST    R13,SIOSAVE1+FOR         *                             * 86390021
         LR    R15,R13                  *  ESTABLISH SAVE AREAS       * 86420021
         LA    R13,SIOSAVE1             *                             * 86450021
         ST    R13,EIGHT(R15)           *  *  *  *  *  *  *  *  *  *  * 86480021
         NI    NEWSW2,MOREOFF          SET MORE RLDS INDIC OFF          86510021
         LR    WORK1,PARM               SAVE CURRENT NOTELIST ENTRY   * 86540021
         TM    2(WORK1),INCORE          IS NEEDED RECORD IN CORE        86570021
         BO    RDRLD30                 YES                              86600021
         L     WORK3,INCB1              RLD INPUT BUFFER 1 IN USE       86630021
         TM    0(WORK3),INUSE                                           86660021
         BZ    RDRLD60                  NO                              86690021
         L     WORK3,INCB2             RLD INPUT BFR. 2 IN USE          86720021
         TM    0(WORK3),INUSE                                           86750021
         BZ    RDRLD60                  NO                              86780021
         NI    0(WORK3),NOTINUSE        YES, FREE BUFFER 2              86810021
         L     WORK2,8(WORK3)           ADDR OF 1ST NOTELIST ENTRY      86840021
RDRLD20  NI    2(WORK2),OUTCORE         MARK ENTRY NOT IN CORE          86870021
         CL    WORK2,16(WORK3)          ALL ENTRIES MARKED NOT IN CORE  86900021
         BE    RDRLD60                  YES                             86930021
         LA    WORK2,9(WORK2)           INCR. TO NEXT NOTELIST ENTRY    86960021
         B     RDRLD20                                                  86990021
*                                                                     * 87020021
*        RLD ENTRY IN CORE - ADD PERTINENT DATA TO CONTROL BLOCKS     * 87050021
RDRLD30  TM    2(WORK1),BUF2            RLD'S IN BUFFER 2               87080021
         BZ    RDRLD40                  NO                              87110021
         OI    2(CURTXTCB),RLDIN2       BUFFER 2 USED IN TXT CTRL BLK   87140021
         L     WORK3,INCB2              GET CTRL BLK ADDR FOR BFR2      87170021
         B     RDRLD60                                                  87200021
RDRLD40  OI    2(CURTXTCB),RLDIN1       BUFFER 1 USED IN TXT CTRL BLK   87230021
         L     WORK3,INCB1              GET CTRL BLK ADDR FOR BFR1      87260021
RDRLD60  ST    WORK1,12(WORK3)          PUT CURR.NOTELIST ENTRY IN CB   87290021
RDRLD70  CL    WORK1,RNLS2             IS IT THE 1ST NOTELIST ENTRY     87320021
         BE    RDRLD80                 YES                              87350021
         SH    WORK1,NINE               NO                              87380021
         TM    2(WORK1),TTRENTRY        IS IT A TTR ENTRY               87410021
         BZ    RDRLD70                 NO                               87440021
         LA    WORK1,9(WORK1)           YES                             87470021
RDRLD80  ST    WORK1,8(WORK3)          BEG. NOTELIST ENTRY FOR GROUP    87500021
RDRLD90  CL    WORK1,ENDRLDNT          SINGLE NOTELIST ENTRY?    A32340 87530021
         BC    10,RDRLD200             YES--RETURN               A32340 87560021
         TM    2(WORK1),TTRENTRY       IS IT A TTR ENTRY         A32340 87590021
         BO    RDRLD100                YES                              87620021
         LA    WORK1,9(WORK1)           NO, INCR. TO NEXT ENTRY         87650021
         B     RDRLD90                                                  87680021
RDRLD100 ST    WORK1,16(WORK3)         END NOTELIST ENTRY FOR GROUP     87710021
         MVC   TTRPOINT(3),6(WORK1)    SAVE TTR OR STORAGE ADDR         87740021
         TM    2(WORK1),INCORE         ARE RLDS IN CORE                 87770021
         BO    RDRLD150                YES                              87800021
         TM    0(NXTTXTCB),BEINGRD      ANY UNCHECKED TEXT READS        87830021
         BZ    RDRLD110                 NO                              87860021
         BAL   BRANCHX,CHCKRD2          YES, CHECK TEXT READ            87890021
         NI    0(NXTTXTCB),RDCHKD      MARK READ CHECKED                87920021
RDRLD110 L     PARM,4(WORK3)            BEGINNING OF BUFFER             87950021
         BAL   BRANCHX,SCDREAD          READ RLD RECORD                 87980021
         BAL   BRANCHX,CHCKRD2          CHECK RLD RECORD READ           88010021
         L     WORK2,8(WORK3)           START OF NOTELIST ENTRIES       88040021
         OI    0(WORK3),INUSE           MARK CTRL.BLK. IN USE           88070021
RDRLD120 OI    2(WORK2),INCORE          SET RLD'S IN CORE INDICATOR     88100021
         TM    0(WORK3),BUF2            ARE RLD'S IN BUFFER 2           88130021
         BZ    RDRLD130                 NO                              88160021
         OI    2(WORK2),BUF2            YES, SET BUFFER 2 INDICATOR     88190021
         OI    2(CURTXTCB),RLDIN2       BFR2 CONTAINS RLD'S             88220021
         B     RDRLD140                                                 88250021
RDRLD130 OI    2(CURTXTCB),RLDIN1       BFR1 CONTAINS RLD'S             88280021
RDRLD140 CL    WORK2,16(WORK3)          LAST NOTELIST ENTRY FOR RECORD  88310021
         BE    RDRLD150                 YES                             88340021
         LA    WORK2,9(WORK2)           NO, INCR. TO NEXT ENTRY         88370021
         B     RDRLD120                                                 88400021
*                                                                     * 88430021
*     UPDATE TO NEXT GROUP OR END OF RLD NOTELIST                     * 88460021
*                                                                     * 88490021
RDRLD150 L     WORK1,16(WORK3)          END OF CURRENT NOTELIST GROUP   88520021
         LA    WORK1,9(WORK1)           UPDATE TO NEXT ENTRY            88550021
RDRLD160 CL    WORK1,ENDRLDNT           END OF NOTELIST                 88580021
         BH    RDRLD200                YES, RETURN                      88610021
*        CHECK FOR MORE RLD RECORDS FOR CURRENT TEXT                  * 88640021
         CLC   0(2,WORK1),CURID         DOES ENTRY ID = CURRENT ID      88670021
         BNE   RDRLD180                 NO                              88700021
         MVC   TEMP(2),2(WORK1)         YES, DOES ENTRY MULT=CURR.MULT  88730021
         NI    TEMP,X'03'                                               88760021
         CLC   TEMP(2),CURMULT                                          88790021
         BE    RDRLD190                 YES                             88820021
RDRLD180 LA    WORK1,9(WORK1)           NO, INCR TO NEXT NOTELIST ENTRY 88850021
         B     RDRLD160                                                 88880021
*      CHECK IF ALL NEEDED RLDS CAN BE ACCOMMODATED IN INPUT BUFFERS  * 88910021
RDRLD190 TM    2(WORK1),INCORE          IS RLD RECORD IN CORE           88940021
         BO    RDRLD30                  YES                             88970021
         L     WORK3,INCB1                                              89000021
         TM    0(WORK3),INUSE           IS BUFFER 1 IN USE              89030021
         BZ    RDRLD60                  NO, GO TO READ IN RECORD        89060021
         L     WORK3,INCB2              IS BUFFER 2 IN USE              89090021
         TM    0(WORK3),INUSE                                           89120021
         BZ    RDRLD60                  NO,GO TO READ IN RECORD         89150021
         ST    WORK1,RLDION             SAVE ADDR FOR LATER READ        89180021
         OI    NEWSW2,MORERLDS          SET MORE RLDS INDICATOR         89210021
RDRLD200 EQU   *                                                        89240021
         B     SIOEXIT1                 RETURN                          89270021
***  *   *     *    *    *    *    *    *    *    *    *    *    *  *** 89300021
*                                                                     * 89330021
*              SET-UP ROUTINE FOR THE WRITING OF TEXT                 * 89360021
*                                                                     * 89390021
***  *   *     *    *    *    *    *    *    *    *    *    *    *  *** 89420021
WRTTXT   EQU   *                                                        89450021
         STM   R14,R12,TWELVE(R13)      SAVE REGS                       89480021
         BALR  R10,0                    *  *  *  *  *  *  *  *  *  *  * 89510021
         LA    R11,WRTTXT-SIO0010+6     *  ESTABLISH ADDRESSIBILITY   * 89540021
         SR    R10,R11                  *  *  *  *  *  *  *  *  *  *  * 89570021
         ST    R13,SIOSAVE1+FOR         *                             * 89600021
         LR    R15,R13                  *  ESTABLISH SAVE AREAS       * 89630021
         LA    R13,SIOSAVE1             *                             * 89660021
         ST    R13,EIGHT(R15)           *  *  *  *  *  *  *  *  *  *  * 89690021
         L     WORK9,SYSLMDCB           ADDR. OF SYSLMOD DCB            89720021
         LH    WORK2,26(CURTXTCB)      RECORD LENGTH                    89750021
         L     WORK3,4(CURTXTCB)        TEXT BEGINNING                  89780021
*        CHECK  FOR ANY  UNCHECKED WRITES                             * 89810021
         L     WORK1,OUTCB1             CHECK IF ANY RLD OUTPUT BFRS.   89840021
         TM    0(WORK1),BEINGWT              ARE  BEING WRITTEN         89870021
         BO    WRTTXT10                                                 89900021
         L     WORK1,OUTCB2                                             89930021
         TM    0(WORK1),BEINGWT                                         89960021
         BO    WRTTXT10                                                 89990021
         L     WORK1,OUTCB3                                             90020021
         TM    0(WORK1),BEINGWT                                         90050021
         BZ    WRTTXT20                                                 90080021
WRTTXT10 BAL   BRANCHX,CHCKWT2          CHECK UNCHECKED WRITE           90110021
         NI    0(WORK1),WRTCKD          TURN OFF BEING WRT. AND IN USE  90140021
WRTTXT20 TM    1(CURTXTCB),XDAP         IS XDAP WRITE NEEDED            90170021
         BO    WRTTXT99                 YES, GO TO ISSUE XDAP           90200021
         TM    PDSE7,OVLY              IS OVERLAY SPECIFIED             90230021
         BZ    WRTTXT30                NO                               90260021
         TM    APT3,SEGSTART           YES, IS THIS 1ST TXT OF SEG      90290021
         BZ    WRTTXT30                 NO                              90320021
         NI    APT3,SEGOFF              TURN OFF FIRST TEXT OF SEG.     90350021
         BAL   BRANCHX,NOTEMCRO         BRANCH TO GET TTR               90380021
         LH    WORK1,CURSEG                                             90410021
         SLL   WORK1,2                                                  90440021
         A     WORK1,TTRLIST            ADDR. OF TTR LIST ENTRY FOR SEG 90470021
         ST    PARM,0(WORK1)            MAKE ENTRY FOR CURR. SEG.       90500021
WRTTXT30 BAL   BRANCHX,SCDWRITE         GO TO WRITE TEXT                90530021
         OI    0(CURTXTCB),BEINGWT                                      90560021
         TM    1(CURTXTCB),DUMMY        IS THIS A DUMMY WRITE           90590021
         BZ    WRTTXT40                 NO                              90620021
         BAL   BRANCHX,CHCKWT2          CHECK WRITE OF TEXT             90650021
         NI    0(CURTXTCB),WRTCKD                                       90680021
         BAL   BRANCHX,NOTEMCRO         CONVERT DISK ADDR.TO TTR        90710021
         AH    PARM,NEXTTTR                                             90740021
         ST    PARM,TTRPOINT                                            90770021
         MVC   CONTSAVE(16),4(WORK9)    SAVE DCB INFO. BEFORE POINT     90800021
         STM   RETURN,PARM,TEMPSTOR    SAVE REG BEFORE POINT            90830021
         L     PARM,SYSLMDCB                                            90860021
         POINT (1),TTRPOINT                                             90890021
         LM    RETURN,PARM,TEMPSTOR    SAVE REG BEFORE POINT            90920021
         MVC   XDAPBLOK+36(8),5(WORK9)  DISK ADDR. TO XDAP ECB          90950021
         MVC   4(16,WORK9),CONTSAVE     RESTORE BSAM INFO TO DCB        90980021
         NI    1(CURTXTCB),DUMMYOFF     TURN DUMMY WRITE OFF            91010021
WRTTXT40 TM    APT3,FIRSTXT             IS THIS FIRST TXT OF LOAD MOD.  91040021
         BZ    WRTTXT90                 NO, BRANCH TO RETURN            91070021
         NI    APT3,FIRSTOFF            TURN OFF 1ST TEXT INDIC.        91100021
         TM    PDSE7,OVLY               IS OVERLAY OPTION SPECIFIED     91130021
         BZ    WRTTXT50                NO                               91160021
         L     WORK1,TTRLIST                                            91190021
         LA    WORK1,4(WORK1)                                           91220021
         MVC   0(4,WORK1),PDSE4         MAKE ENTRY FOR SEG.1 IN TTRLIST 91250021
         B     WRTTXT90                 BRANCH TO RETURN                91280021
WRTTXT50 TM    0(CURTXTCB),BEINGWT      HAS TEXT WRITE BEEN CHECKED     91310021
         BZ    WRTTXT60                 YES                             91340021
         BAL   BRANCHX,CHCKWT2          NO, BRANCH TO CHECK IT          91370021
         NI    0(CURTXTCB),WRTCKD       MARK TXTCB NOT IS USE           91400021
WRTTXT60 BAL   BRANCHX,NOTEMCRO         CONVERT DISK ADDR. TO TTR       91430021
         ST    PARM,PDSE4               STORE TTR OF FIRST TXT IN PDS   91460021
         MVC   PDSE10(2),26(CURTXTCB)   LENGTH OF FIRST TXT TO PDS      91490021
WRTTXT70 TM    PDSE7,SCTR               IS SCATTER OPTION SPECIFIED     91520021
         BZ    WRTTXT80                 NO                              91550021
         MVC   PDSE15(2),CURID          YES, ENTER CURR.ID INTO PDS     91580021
WRTTXT80 TM    0(CURTXTCB),MODULEND     IS TEXT LAST IN MODULE          91610021
         BZ    WRTTXT90                 NO, BRANCH TO RETURN            91640021
         TM    APT3,RLDSINGP           ANY RLDS FOR TEXT                91670021
         BO    WRTTXT90                 YES, BRANCH TO RETURN           91700021
         OI    PDSE7,NRLD1TXT           SET NO RLDS -ONE TEXT REC INDIC 91730021
WRTTXT90 EQU   *                                                        91760021
         B     SIOEXIT1                 RETURN                          91790021
WRTTXT99 NI    1(CURTXTCB),NOTXDAP      TURN OFF XDAP INDICATOR         91820021
         STM   RETURN,PARM,TEMPSTOR    SAVE BEFORE XDAP                 91850021
         XDAP  XDAPBLOK,WI,(WORK9),(WORK3),(WORK2),,,MF=E               91880021
         WAIT  1,ECB=XDAPBLOK           WIAT FOR COMPLETION OF XDAP     91910021
         LM    RETURN,PARM,TEMPSTOR    RESTORE REG. AFTER XDAP          91940021
         TM    XDAPBLOK,X'7F'           IS XDAP SUCCESSFUL              91970021
         BO    WRTTXT90                                                 92000021
         L     BRANCH,ADSNX             ADDR. OF ERROR ROUTINE          92030021
         LA    PARM,XDAPBLOK+4         ADDRESS OF IOB                   92060021
         BR    BRANCH                   BRANCH TO ERROR ROUTINE         92090021
         XDAP  XDAPBLOK,WI,,,,,,MF=L    EXPAND XDAP ECB                 92120021
***    *     *     *    *    *    *    *    *    *    *    *    *     * 92150021
*                                                                     * 92180021
*        SET-UP ROUTINE TO WRITE THE CONTROL RECORD OR RLD RECORD     * 92210021
*                                                                     * 92240021
***    *     *     *    *    *    *    *    *    *    *    *    *   *** 92270021
WRTCRRLD EQU   *                                                        92300021
         STM   R14,R12,TWELVE(R13)      SAVE REGS                       92330021
         BALR  R10,0                    *  *  *  *  *  *  *  *  *  *  * 92360021
         LA    R11,WRTCRRLD-SIO0010+6   *  ESTABLISH ADDRESSIBILITY   * 92390021
         SR    R10,R11                  *  *  *  *  *  *  *  *  *  *  * 92420021
         ST    R13,SIOSAVE1+FOR         *                             * 92450021
         LR    R15,R13                  *  ESTABLISH SAVE AREAS       * 92480021
         LA    R13,SIOSAVE1             *                             * 92510021
         ST    R13,EIGHT(R15)           *  *  *  *  *  *  *  *  *  *  * 92540021
         L     WORK3,8(PARM)            GET BEGINNING OF BUFFER         92570021
         TM    0(WORK3),TXT             CR/RLD OR RLD RECORD            92600021
         BZ    RLDWRT10                 GO TO WRITE RLD RECORD          92630021
         MVC   14(2,WORK3),26(CURTXTCB) GROUP LENGTH TO CTRL.REC.       92660021
         OI    8(WORK3),X'06'           SET READ BITS                   92690021
         OI    12(WORK3),X'40'          SET FLAGS                       92720021
         MVC   4(2,WORK3),2(PARM)       ID-LENGTH TO CTRL. REC          92750021
RLDWRT10 LR    WORK2,CURTXTCB           CHECK ANY UNCHECKED WRITES      92780021
         TM    0(WORK2),BEINGWT                                         92810021
         BO    RLDWRT20                                                 92840021
         LR    WORK2,NXTTXTCB                                           92870021
         TM    0(WORK2),BEINGWT                                         92900021
         BO    RLDWRT20                                                 92930021
         L     WORK2,OUTCB1                                             92960021
         TM    0(WORK2),BEINGWT                                         92990021
         BO    RLDWRT20                                                 93020021
         L     WORK2,OUTCB2                                             93050021
         TM    0(WORK2),BEINGWT                                         93080021
         BO    RLDWRT20                                                 93110021
         L     WORK2,OUTCB3                                             93140021
         TM    0(WORK2),BEINGWT                                         93170021
         BZ    RLDWRT40                 GO TO WRITE RECORD              93200021
RLDWRT20 BAL   BRANCHX,CHCKWT2          CHECK PREVIOUS WRITE            93230021
         NI    0(WORK2),WRTCKD          FREE CTRL. BLOCK                93260021
RLDWRT40 LH    WORK2,4(WORK3)           CALC. LENGTH OF RECORD          93290021
         AH    WORK2,6(WORK3)                                           93320021
         LA    WORK2,16(WORK2)                                          93350021
         BAL   BRANCHX,SCDWRITE         BRANCH TO WRITE A RECORD        93380021
         OI    0(PARM),BEINGWT          MARK CTRL.BLK BEING WRITTEN     93410021
         B     SIOEXIT1                 RETURN                          93440021
*                                                                     * 93470021
*                            CHECK  ROUTINE                           * 93500021
*                                                                     * 93530021
CHECKRD  EQU   *                                                        93560021
         STM   R14,R12,TWELVE(R13)      SAVE REGS                       93590021
         BALR  R10,0                    *  *  *  *  *  *  *  *  *  *  * 93620021
         LA    R11,CHECKRD-SIO0010+6    *  ESTABLISH ADDRESSIBILITY   * 93650021
         SR    R10,R11                  *  *  *  *  *  *  *  *  *  *  * 93680021
CHCKRD1  ST    R13,SIOSAVE2+FOR         *                             * 93710021
         LR    R11,R13                  *  ESTABLISH SAVE AREAS       * 93740021
         LA    R13,SIOSAVE2             *                             * 93770021
         ST    R13,EIGHT(R11)           *  *  *  *  *  *  *  *  *  *  * 93800021
         LA    PARM,RDDECB              READ DECB                       93830021
         B     CHECK                                                    93860021
CHCKRD2  SAVE  (14,12),T               SAVE REGS,ENTRY IF FROM IEWLMSIO 93890021
         B     CHCKRD1                 CONTINUE                         93920021
CHECKWRT EQU   *                                                        93950021
         STM   R14,R12,TWELVE(R13)      SAVE REGS                       93980021
         BALR  R10,0                    *  *  *  *  *  *  *  *  *  *  * 94010021
         LA    R11,CHECKWRT-SIO0010+6   *  ESTABLISH ADDRESSIBILITY   * 94040021
         SR    R10,R11                  *  *  *  *  *  *  *  *  *  *  * 94070021
CHCKWT1  ST    R13,SIOSAVE2+FOR         *                             * 94100021
         LR    R11,R13                  *  ESTABLISH SAVE AREAS       * 94130021
         LA    R13,SIOSAVE2             *                             * 94160021
         ST    R13,EIGHT(R11)           *  *  *  *  *  *  *  *  *  *  * 94190021
         LA    PARM,WTDECB              WRITE DECB                      94220021
         B     CHECK                   GO TO CHECK                      94250021
CHCKWT2  SAVE  (14,12),T               SAVE REGS, ENTRY FROM WITHIN SIO 94280021
         B     CHCKWT1                 CONTINUE                         94310021
CHECK    EQU   *                                                        94340021
         CHECK (1)                     CHECK                            94370021
         B     SIOEXIT2                 RETURN                          94400021
*                                                                     * 94430021
*                                                                     * 94460021
*                        READ  ROUTINE                                * 94490021
*                                                                     * 94520021
*                                                                     * 94550021
SCDREAD  STM   BRANCHX,PARM,TEMPSTOR    SAVE REGS. #11-#1               94580021
         L     PARM,SYSUTDCB                                            94610021
         POINT (1),TTRPOINT                                             94640021
         L     BRANCHX,TEMPSTOR+24     RESTORE READ ADDR.-POINT CHANGED 94670021
         LA    BRANCHX,0(BRANCHX)      ZERO OUT HIGH ORDER BYTE  A30173 94700021
         L     BRANCH,TXTBFEND         PICK UP TXTBUF END ADDR   A30173 94730021
         SR    BRANCH,BRANCHX          TAKE THE DIFFERENCE       A30173 94760021
         C     BRANCH,UT1SIZE          GREATER THAN UT1SIZE?     A30173 94790021
         BNH   SCDREADA                NO, GO TO READ THAT MUCH; A30173 94820021
*   OUT OF ORDER TEXT MAY HAVE ITS RECORD SIZE > ITS ACTUAL SIZE A30173 94850021
         L     BRANCH,UT1SIZE          YES-ONLY READ UP TO MAX.  A30173 94880021
SCDREADA READ  RDDECB,SF,IEWLCUDB,(BRANCHX),(BRANCH)                    94910021
         LM    BRANCHX,PARM,TEMPSTOR    RESTORE REGISTERS               94940021
         BR    BRANCHX                                                  94970021
***    *     *     *    *    *    *    *    *    *    *    *    *   *** 95000021
*                                                                     * 95030021
*                       WRITE   ROUTINE                               * 95060021
*                                                                     * 95090021
***    *     *     *    *    *    *    *    *    *    *    *    *   *** 95120021
SCDWRITE STM   BRANCHX,PARM,TEMPSTOR   SAVE REGISTERS                   95150021
         WRITE WTDECB,SF,IEWLCMDB,(WORK3),(WORK2)                       95180021
         LM    BRANCHX,PARM,TEMPSTOR                                    95210021
         BR    BRANCHX                                                  95240021
*                     ******************                                95270021
*                                                                     * 95300021
NOTEMCRO STM   RETURN,PARM,TEMPSTOR    SAVE REGISTERS                   95330021
         L     PARM,SYSLMDCB                                            95360021
         NOTE  (1)                                                      95390021
         LM    RETURN,WORK0,TEMPSTOR   RESTORE REGISTERS                95420021
         BR    BRANCHX                  RETURN                          95450021
SIOEXIT1 EQU   *                                                        95480021
         L     R13,SIOSAVE1+FOR        RESTORE REG 13                   95510021
SIORETRN EQU   *                                                        95540021
         RETURN (14,12),T              RETURN                           95570021
SIOEXIT2 EQU   *                                                        95600021
         L     R13,SIOSAVE2+FOR        RESTORE REG 13                   95630021
         LM    R14,R12,TWELVE(R13)     RESTORE REGS                     95660021
         BR    R11                     RETURN                           95690021
*********************************************************************** 95720021
*     DECLARES                                                        * 95750021
**********************************************************************  95780021
SAVEREG2 DS    7F                 SAVE AREA                    A24496   95810021
PARMSAVE DS    2F                       SAVE AREA FOR REG 1             95840021
SEVEN    DC    H'7'                                                     95870021
NINE     DC    H'9'                     RLD NOTELIST ENTRY SIZE         95900021
NEXTTTR  DC    H'0256'                  TO INCREMENT TTR ADDR           95930021
ADSNX    DC    V(IEWLCRO3)             ERROR ROUTINE                    95960021
SYSLMDCB DC    A(IEWLCMDB)             ADDR OF SYSLMOD DCB              95990021
SYSUTDCB DC    A(IEWLCUDB)             SYSUT1 DCB ADDRESS               96020021
***                                                                 *** 96050021
*                       SAVE AREAS                                    * 96080021
***                                                                 *** 96110021
SIOSAVE1 DS    18F                      REG SAVE AREA FOR EXTERNAL RTNS 96140021
SIOSAVE2 DS    18F                     REG SAVE AREA, INTERNAL RTNS     96170021
CURTXTAD DC    F'0'                    BFR.ADDR OF CURRENT TEXT         96200021
PATCHSIO DS    25F     ********PATCH AREA   **************************  96230021
         END                                                            96260021
*********************************************************************** 96290021
