         TITLE    'SYM RECORD PROCESSOR'                                00500000
*********************************************************************** 01000000
*                                                                       01500000
*STATUS: CHANGE LEVEL                                                   02000000
*                                                                       02500000
*FUNCTION/OPERATION:                                                    03000000
*   PASS SYMS AND ESDS WHEN THE LOAD MODULE OUTPUT OF THE LINKAGE       03500000
*   EDITOR HAS THE ATTRIBUTE - TEST. SYM CARDS AND ESDS CARDS FROM AN   04000000
*   OBJECT MODULE ARE PACKED 3 CARDS PER RECORD (240 BYTES),EXCEPT FOR  04500000
*   THE LAST RECORD PER OBJECT MODULE WHICH MAY BE EITHER 80,160 OR     05000000
*   240 BYTES. SYM RECORDS FROM LOAD MODULES ARE PASSED IN THE SAME     05500000
*   FORM AS THEY ARE READ IN. IF A LOAD MODULE (AS PART OF INPUT) DOES  06000000
*   NOT CONTAIN SYM RECORDS THEN THE ESD RECORDS ARE PASSED. ALL SYM    06500000
*   RECORDS CONSIST OF A 4 BYTE HEADER PRECEEDING THE SYM/ESD DATA. THE 07000000
*   FIRST BYTE IS A 40(HEX),THE SECOND BYTE WILL BE EITHER A (1XXXXXXX) 07500000
*   WHICH MEANS THAT THIS SYM RECORD CONTAINS ESDS FROM A LOAD MODULE   08000000
*   THAT WAS NOT IN TEST WHEN IT WAS ORIGINALLY LINK-EDITED; OR IT MAY  08500000
*   BE A (0XXXXXXX) WHICH IS THE OPPOSITE OF (1XXXXXXX). BYTES 3 AND 4  09000000
*   WILL CONTAIN THE DATA BYTE COUNT IN THIS SYM RECORD.                09500000
*                                                                       10000000
*ENTRY POINTS:                                                          10500000
*        IEWLMSYM - CONTROL SECTION NAME                              * 11000000
*                                                                       11500000
*INPUT:                                                                 12000000
*    SYM/ESD CARDS OR SYM/ESD RECORDS                                   12500000
*                                                                       13000000
*OUTPUT:                                                                13500000
*   SYM RECORDS                                                         14000000
*                                                                       14500000
*EXTERNAL ROUTINES:                                                     15000000
*    N/A                                                                15500000
*                                                                       16000000
*EXITS:                                                                 16500000
*    NORMAL:                                                            17000000
*    RETURNS VIA ADDRESS PASSED IN REGISTER 14                          17500000
*    ERRORS:                                                            18000000
*    N/A                                                                18500000
*                                                                       19000000
*TABLES/WORK AREAS:                                                     19500000
*    LOAD MODULE BUFFER                                                 20000000
*    ALL PURPOSE TABLE                                                  20500000
*                                                                       21000000
*    REGISTER INPUT                                                     21500000
*    REGISTER  2 - ADDRESS OF ALL PURPOSE TABLE                         22000000
*    REGISTER  4 - BYTE CT = 80 OR 0; 0 MEANS PURGE SYM BUFFER          22500000
*    REGISTER  6 - ADDRESS OF SYM/ESD CARD TO BE MOVED TO BUFFER        23000000
*    REGISTER 13 - ADDRESS OF A REGISTER SAVE AREA (16 WORDS)           23500000
*    REGISTER 14 - RETURN ADDRESS                                       24000000
*                                                                       24500000
*ATTRIBUTES:                                                            25000000
*   REUSABLE                                                            25500000
*NOTES:                                                                 26000000
*    IEWLCSYM  ASSUMES 2 BITS WILL BE INITIALIZED TO 0 AT THE END OF    26500000
*    EACH INPUT MODULE, THEY ARE USED FOR INITIALIZATION .              27000000
*    1) USED TO INDICATE INITIALIZATION OF BUFER BYTE COUNT (1 = INIT)  27500000
*    2) NO SYM RECORDS HAVE BEEN PROCESSD IN THIS MODULE (1= SYMS SEEN) 28000000
*********************************************************************** 28500000
*********************************************************************** 29000000
*                                                                     * 29500000
*                   SYM  PROCESSOR -  COMMON TO E AND F               * 30000000
*                                                                     * 30500000
*********************************************************************** 31000000
*********************************************************************** 31500000
*        REGISTER ASSIGNMENT                                          * 32000000
*********************************************************************** 32500000
APT      EQU   2                   ADDRESS OF ALL PURPOSE TABLE         33000000
BUFFCT   EQU   3                                                        33500000
INCT     EQU   4                   INPUT PARM - NO BYTES OF SYM (80)    34000000
BUFFADD  EQU   5                   ADDRESS OF LOAD MODULE BUFFER        34500000
INADD    EQU   6                   INPUT PARM - ADDRESS OF SYMS TO MVE  35000000
TEMP1    EQU   7                   TEMPORARY REG                        35500000
BASE     EQU   12                  BASE REGISTER                        36000000
TEMP2    EQU   13                  13 - ADD OF SYSLMOD DCB              36500000
*********************************************************************** 37000000
*        ALL PURPOSE TABLE DISPLACEMENTS                              * 37500000
*********************************************************************** 38000000
DISP     EQU   0                       DISPO WHERE TO PUT REGS REL 13   38500000
INIT     EQU   X'04'               BIT TEST - FOR FIRST TIME ENTER      39000000
LOADMOD  EQU   X'20'                    LOAD MODULE BIT                 39500000
SYMCTL   EQU   X'40'               CTL IND. FOR HEADER OF SYM RCD       40000000
SYMLDMOD EQU   X'20'                   SYM RECORD IN LOAD MOD           40500000
SYMPRES  EQU   X'04'                    SYM PRESENT BIT                 41000000
IEWLMSYM CSECT                                                          41500000
         EXTRN IEWLCMDB                                                 42000000
*                                                                       42500000
*        SAVE ALL REGISTERS AND INITIALIZE BASE (REGISTER 12)           43000000
         USING *,15                                                     43100000
         BC    15,MODID+6                                               43200000
MODID   DC     C'00MSYM'                                                43300000
*                                                                       43500000
         STM   14,12,DISP(13)          SAVE ALL REGISTERS               44000000
         USING SYM00100,BASE                                            44500000
         BALR  BASE,0                   INITIALIZE BASE REGISTER        45000000
         USING APTDSECT,APT        ESTABLISH BASE REG FOR APT DSECT     45500000
*                                                                       46000000
*        INITIALIZE                                                     46500000
*                                                                       47000000
         DROP   15                                                      47200000
SYM00100 ST    13,SAVERG13             SAVE ADDRESS OF CALLERS AREA     47500000
         L     BUFFADD,RLDINPAD    RLD INPUT BUFFER ADDRESS             48000000
         OI    PDSE8,SYMPRES       SET SYM PRESENT IN LD MD             48500000
*                                                                       49000000
*                                                                       49500000
         TM    APT1,LOADMOD        IS THIS A LOAD MODULE                50000000
         BC    8,SYM00600               NO                              50500000
*                                                                       51000000
*                                                                       51500000
         CLI   0(BUFFADD),SYMCTL        IS THIS A SYM RECORD            52000000
         BC    7,SYM00700               NO / IT IS AN ESD -             52500000
*                                                                       53000000
*                                                                       53500000
         OI    APT2,SYMLDMOD       SET IND = ON / SYM IN LD MODULE      54000000
SYM00200 LH    BUFFCT,2(BUFFADD)        PICK UP LENGTH OF THIS DATA     54500000
*                                                                       55000000
*                                                                       55500000
         LTR   INCT,INCT                IS BUFFER TO BE PURGED          56000000
         BC    2,SYM00800              NO/OBJECT MOD - CK COUNT = 240   56500000
*                                                                       57000000
*        INITIALIZE FOR WRITE ,CHECK ROUTINE                            57500000
*                                                                       58000000
SYM00300 LA    BUFFCT,4(BUFFCT)         INC WRITE CT 4 - FOR HEADER     58500000
         MVI   0(BUFFADD),SYMCTL        PUT HEADER ON DATA / SYM RCD    59000000
         L     TEMP1,DCBLMOD                                            59500000
         LA    TEMP2,REGSA         ADD TO SAVE REGISTER AREA            60000000
*                                                                       60500000
*        WRITE SYM RECORD ON OUTPUT FILE                                61000000
*                                                                       61500000
         WRITE SYMDECB,SF,(TEMP1),(BUFFADD),(BUFFCT)                    62000000
*                                                                       62500000
*        CHECK THE WRITE                                                63000000
*                                                                       63500000
         CHECK SYMDECB                                                  64000000
*                                                                       64500000
*                                                                       65000000
SYM00400 SR    BUFFCT,BUFFCT           ZERO BUFFER BYTE CT              65500000
         OI    APT2,INIT           SET INDICATOR - ENTERED FOR THIS MOD 66000000
*                                                                       66500000
*                                                                       67000000
         LTR   INCT,INCT                IS IN BYTE CT = 0               67500000
         BC    2,SYM00900               NO / GET DATA LENGTH AND CONT.  68000000
*                                                                       68500000
*        RESTORE REGISTERS AND RETURN TO CALLER                         69000000
*                                                                       69500000
SYM00500 L     13,SAVERG13             RESTORE ADD OF CALLERS SAVEAREA  70000000
         LM    14,12,DISP(13)          RESTORE CALLERS REGISTERS        70500000
         BCR   15,14                    RETURN TO CALLER                71000000
*                                                                       71500000
*                                                                       72000000
SYM00600 TM    APT2,INIT           1ST TIME ENTERED IN OBJECT MOD       72500000
         BC    8,SYM00400              YES / GO TO RESTORE CT TO = 0    73000000
         MVI   1(BUFFADD),X'00'         SET NO ESD FROM LOAD MOD(NOT IN 73500000
*                                      TEST) IN THIS RECORD             74000000
         BC    15,SYM00200              NO  / GO GET LENGTH OF DATA     74500000
*                                                                       75000000
*                                                                       75500000
SYM00700 TM    APT2,SYMLDMOD       HAVE SYM BEEN SEEN YET (INLDMD)      76000000
         BC    1,SYM00500               YES / DONOT PASS ESDS/DONE B 4  76500000
         LA    BUFFADD,4(BUFFADD)       INC BUFF ADD TO START OF DATA 4 77000000
         MVI        1(BUFFADD),X'80'    SET ESDS FROM LOAD MODULE  (NOT 77500000
*                                      IN TEST) IN THIS RECORD          78000000
         BC    15,SYM00200             NO / PROCESS ESDS AS SYMS        78500000
*                                                                       79000000
*                                                                       79500000
SYM00800 LA    TEMP1,240                240- MAX NO.SYM BYTES IN BUFFER 80000000
         CLR   BUFFCT,TEMP1             IS BUFFER FULL                  80500000
         BC    8,SYM00300               YES / GO TO PURGE BUFFER        81000000
*                                                                       81500000
*        MOVE SYM/ESD TO BUFFER - UPDATE BUFFER BYTE CT - GO TO RETURN  82000000
*                                                                       82500000
SYM00900 AR    INCT,BUFFCT             INC CT BY 80                     83000000
         STH   INCT,2(BUFFADD)         RESTORE BUFFER CT                83500000
         AR    BUFFADD,BUFFCT           ADDRESS OF WHERE TO PUT SYMS    84000000
         MVC   4(80,BUFFADD),0(INADD)   MOVE SYMS TO LOAD MOD BUFFER    84500000
         BC    15,SYM00500              GO TO RESTORE REGS              85000000
SAVERG13 DS    F                       SAVE CALLERS REG 13              85500000
DCBLMOD  DC    A(IEWLCMDB)                                              86000000
         IEWAPT                                                         86500000
*                                                                       87000000
*                                                                       87500000
*********************************************************************** 88000000
         END                                                            88500000
