      SUBROUTINE IEKPB                                                  00100014
C                                                                       00120015
C     228000,512200-512800                                        0000A 00140015
C                                                                       00146016
C     026000,221300-221600,330600-334800,502000,504000-506000     0000B 00152016
C     332400                                                     0000E  00156019
C                                                                       00160015
CCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCC00200014
C                                                                      C00300014
C                        BAKT - IEKPB                                  C00400014
C                                                                      C00500014
C STATUS - VERSION 2, MOD. 1                                            00600015
C                                                                      C00700014
C FUNCTION - IEKPB CALCULATES FOR EACH BLOCK A 'BACK TARGET' IF SUCH    00800015
C         EXISTS, AND THEN ASSIGNS THE BLOCK A 'LOOP NUMBER' ASSO-     C00900014
C         CIATED WITH THIS BACK TARGET.                                C01000014
C            LOOP NUMBERS ARE ORDERED INVERSELY WITH RESPECT TO NEST-  C01100014
C         ING -- THAT IS THE MOST DEEPLY NESTED LOOPS WILL BE AS-      C01200014
C         SIGNED THE LOWEST LOOP NUMBER.  ALL BLOCKS LACKING A BACK    C01300014
C         TARGET WILL BY CONVENTION BE TREATED AS AN OUTERMOST 'LOOP'  C01400014
C         OF THE PROGRAM.                                              C01500014
C            THE ROUTINE USES A VECTOR OF BLOCK POINTERS, TRIKL        C01600014
C         (IEKPBL), ORIGINALLY LAID OUT BY IEKPO, ORDERING              01700015
C         THEM BY NUMBER OF STEPS REMOVED FROM THE MOST PROXIMATE      C01800014
C         ENTRY POINT OF THE PROGRAM.                                  C01900014
C                                                                      C02000014
C                                                                      C02100014
C CALLED BY - IEKPO                                                   C 02200015
C                                                                     C 02300015
C CALLS - IEKAA9, IBCOM#                                              C 02400015
C                                                                       02500015
C COMMON - IEKAAA, IEKAER, IEKJA2, IEKJA4, IEKPBL                      C02600016
C                                                                      C02700014
CCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCC02800014
C                                                                       02900014
C     DEFINITION 1 -- THE BACK TARGET OF A BLOCK I IS A BLOCK J SUCH    03000014
C       THAT                                                            03100014
C         (A) BLOCK J LIES ON THE CHAIN OF BACK DOMINATORS EXTENDING    03200014
C             BACKWARD FROM BLOCK I                                     03300014
C         (B) BLOCK J HAS ONLY ONE FORWARD CONNECTION                   03400014
C         (C) THERE EXISTS A PATH FROM BLOCK I TO ITSELF WHICH DOES NOT 03500014
C             PASS THROUGH BLOCK J.                                     03600014
C        (D) IF THE NEAREST BLOCK TO I FULFILLING CONDITIONS (A)        03700014
C            AND (C) ALSO FULFILLS (B) THEN THAT IS THE BACK TARGET.    03800014
C            IF THAT BLOCK DOES NOT FULFILL CONDITION (B) THEN          03900014
C            ITS BACK TARGET IS CHOSEN TO BE THE BACK TARGET OF I.      04000016
C        (E) IF NO BLOCK SATISFIES (A) AND (C) THEN THE                 04100014
C            BACK TARGET IS ZERO.                                       04200014
C                                                                       04300014
C                                                                       04400014
C                                                                       04500014
C                                                                       04600014
C                                                                       04700014
C                                                                       04800014
C     EXAMPLE 1 --                 BLOCK    BACK TARGET                 04900014
C                                                                       05000014
C              -----                 A         NONE                     05100014
C             I  A  I                                                   05200014
C              -----                 B          A                       05300014
C        ------  I                                                      05400014
C       I      I I                   C          B                       05500014
C       I      V V                                                      05600014
C       I      -----                 D          B                       05700014
C       I     I  B  I                                                   05800014
C       I      -----                 E          A                       05900014
C       I        I  --                                                  06000014
C       I        I I  I              F          C                       06100014
C       I        V V  I                                                 06200014
C       I      -----  I              G         NONE                     06300014
C       I     I  C  I I                                                 06400014
C       I      -----  I              L          C                       06500014
C       I        I    I                                                 06600014
C       I        V    I              M         NONE                     06700014
C       I      -----  I                                                 06800014
C       I     I  D  I I                                                 06900014
C       I      -----  I                                                 07000014
C       I        I I  I                                                 07100014
C       I        I  --                                                  07200014
C       I        I                                                      07300014
C       I        V                                                      07400014
C       I      -----                                                    07500014
C       I     I  E  I                                                   07600014
C       I      -----                                                    07700014
C       I      I I I                                                    07800014
C       I      I I I                                                    07900014
C       I    --  I  --------                                            08000014
C       I   I    I           I                                          08100014
C       I  -C--  I           I                                          08200014
C       I I I  I I           I                                          08300014
C       I I I  V V           V                                          08400014
C       I I I  -----       -----                                        08500014
C       I I I I  F  I     I  G  I                                       08600014
C       I I I  -----       -----                                        08700014
C       I I I    I           I                                          08800014
C       I I  --  I           I                                          08900014
C       I I    I I           I                                          09000014
C       I I    V V           I                                          09100014
C       I I    -----         I                                          09200014
C       I I   I  L  I        I                                          09300014
C       I I    -----         I                                          09400014
C       I I    I I I         I                                          09500014
C       I  ----  I I         I                                          09600014
C       I        I I  -------                                           09700014
C        --------  I I                                                  09800014
C                  I I                                                  09900014
C                  V V                                                  10000014
C                -----                                                  10100014
C               I  M  I                                                 10200014
C                -----                                                  10300014
C                                                                       10400014
C                                                                       10500014
C     THE FOLLOWING PROPOSITIONS SIMPLIFY THE CALCULATION OF BACK       10600014
C       TARGETS --                                                      10700014
C                                                                       10800014
C     DEFINITION 2 -- A NODE IS A BLOCK WITH TWO OR MORE BACKWARD       10900014
C       CONNECTIONS.                                                    11000014
C                                                                       11100014
C       (IN EXAMPLE 1, BLOCKS B, C, F, L, AND M ARE NODES.)             11200014
C                                                                       11300014
C     LEMMA 1 --                                                        11400014
C                                                                       11500014
C       GIVEN -- (1) BLOCK(I) IS NOT A NODE                             11600014
C                (2) BLOCK(K) IS THE MOST PROXIMATE PRECEDING NODE      11700014
C                (3) THERE EXISTS A PATH FROM BLOCK(I) TO ITSELF        11800014
C       THEN --  THE PATH FROM BLOCK(I) TO ITSELF ALSO CONSTITUTES A    11900014
C                  PATH FROM BLOCK(K) TO ITSELF.                        12000014
C       PROOF -- ANY BLOCK ON THE PATH FROM BLOCK(I) TO BLOCK(I) CAN    12100014
C                  FOLLOW THAT SAME PATH TO BLOCK(I) AND THENCE TO      12200014
C                  ITSELF. BUT BLOCK(K), BY CONSTRUCTION, LIES ASTRIDE  12300014
C                  ALL PATHS TO BLOCK(I), AND IN PARTICULAR IT LIES     12400014
C                  UPON THE PATH FROM BLOCK(I) TO BLOCK(I).             12500014
C                                                                       12600014
C     LEMMA 2 --                                                        12700014
C                                                                       12800014
C       GIVEN -- (1) AND (2) AS IN LEMMA 1, AND                         12900014
C                (3) THERE EXISTS A BACK TARGET OF BLOCK(I)             13000014
C       THEN --  THERE EXISTS A BACK TARGET OF BLOCK(K), WHICH DIFFERS  13100014
C                  FROM THAT OF BLOCK(I) AT MOST IN BEING MORE          13200014
C                  PROXIMATE TO BOTH BLOCKS.                            13300014
C       PROOF -- THE THIRD HYPOTHESIS IMPLIES THE EXISTENCE OF A PATH   13400014
C                  FROM BLOCK(I) TO ITSELF, WHICH BY LEMMA 1 IS ALSO A  13500014
C                  PATH FROM BLOCK(K) TO ITSELF.                        13600014
C                THE THIRD HYPOTHESIS ALSO IMPLIES THE EXISTENCE OF A   13700014
C                  BLOCK MEETING CONDITIONS (A) THRU (D) IN THE         13800014
C                  DEFINITION OF A BACK TARGET (DEFINITION 1), RELATIVE 13900014
C                  TO BLOCK(I). BUT BY CONSTRUCTION, BLOCK(K) IS ON THE 14000014
C                  SAME CHAIN OF BACK DOMINATORS, SO THE BACK TARGET OF 14100014
C                  BLOCK(I) MEETS CONDITIONS (A) THRU (C) RELATIVE TO   14200014
C                  BLOCK(K) AS WELL. UNLESS THERE IS A MORE PROXIMATE   14300014
C                  BLOCK MEETING CONDITIONS (A) THRU (C) RELATIVE TO    14400014
C                  BLOCK(K), THE BACK TARGET OF BLOCK(I) THUS QUALIFIES 14500014
C                  AS A BACK TARGET OF BLOCK(K), AND IN EITHER CASE A   14600014
C                  BACK TARGET OF BLOCK(K) EXISTS.                      14700014
C                                                                       14800014
C     THEOREM 1 --                                                      14900014
C       GIVEN -- (1) AND (2) AS IN LEMMA 1, AND                         15000016
C                (3) THERE EXISTS A BACK TARGET OF BLOCK(I)             15100014
C       THEN  -- THE MOST PROXIMATE PRECEDING NODE AT WHICH A PATH      15200016
C                FROM BLOCK I TO ITSELF CONVERGES UPON THE CHAIN OF     15300014
C                BACK TARGETS OF BLOCK(I) COINCIDES WITH THAT OF        15400016
C                BACK DOMINATORS.                                       15500014
C                                                                       15600014
C       PROOF -- CASE I -- THE BACK TARGET OF BLOCK(I) COINCIDES WITH   15700014
C                  THAT OF BLOCK(K). (SEE BLOCK D IN THE EXAMPLE.) THEN 15800014
C                  THE ASSERTION IS SATISFIED TRIVIALLY.                15900014
C                CASE II -- THE BACK TARGET OF BLOCK(I) DIFFERS FROM    16000014
C                  THAT OF BLOCK(K). (SEE BLOCK E IN THE EXAMPLE.) BY   16100014
C                  LEMMA 2, THE BACK TARGET OF BLOCK(K) EXISTS AND IS   16200014
C                  MORE PROXIMATE. IT MUST LIE ON THE PATH FROM         16300014
C                  BLOCK(I) TO ITSELF (WHICH BY HYPOTHESIS 3 IS         16400014
C                  ASSUMED TO EXIST), OR IT WOULD SATISFY ALL THE       16500014
C                  REQUIREMENTS OF A BACK TARGET MORE PROXIMATE THAN    16600014
C                  THAT BLOCK WHICH, BY HYPOTHESIS, IS IN FACT THE BACK 16700014
C                  TARGET OF BLOCK(I).                                  16800014
C                  IT IS POSSIBLE FOR THE PATH FROM BLOCK(I) TO ITSELF  16900014
C                  TO DIVERGE FROM THE CHAIN OF BACK DOMINATORS,        17000014
C                  HOWEVER, ONLY AT SOME NODE ALONG THE CHAIN. ALL SUCH 17100014
C                  NODES BACK TO THE MOST PROXIMATE OF THOSE AT WHICH A 17200014
C                  PATH FROM BLOCK(I) TO ITSELF CONVERGES UPON THE      17300014
C                  CHAIN OF BACK DOMINATORS LIE UPON THE PATH FROM      17400014
C                  BLOCK(I) TO ITSELF -- HENCE LEMMA 2 APPLIES TO THEM  17500014
C                  AS WELL AS TO BLOCK(K).                              17600014
C                  AT THE MOST PROXIMATE NODE WHERE A PATH FROM         17700014
C                  BLOCK(I) TO ITSELF REJOINS THE PATH OF BACK          17800014
C                  DOMINATORS, THE BACK TARGET MUST IN FACT BE THAT OF  17900014
C                  BLOCK(I) SINCE THE BACK TARGET OF THIS NODE MUST BE  18000014
C                  THE VERY FIRST BLOCK ON THE CHAIN OF BACK DOMINATORS 18100014
C                  BEHIND IT WHICH SATISFIES CONDITION (B) OF THE       18200014
C                  DEFINITION.                                          18300014
C                                                                       18400014
C     COROLLARY 1 -- IF NO PATH FROM BLOCK(I) TO ITSELF CAN BE FOUND    18500014
C       VIA THE BACKWARD CONNECTIONS OF THE FIRST N-1 NODES PRECEDING   18600014
C       BLOCK(I) ON THE PATH OF BACK DOMINATORS, NON-EXISTENCE OF A     18700014
C       BACK TARGET FOR THE NTH SUCH NODE IMPLIES NON-EXISTENCE OF A    18800014
C       BACK TARGET FOR BLOCK(I).                                       18900014
C                                                                       19000014
C     COROLLARY 2 --- THEOREM 1 AND COROLLARY 1 APPLY EVEN IF BLOCK(I)  19100014
C       IS A NODE, UPON THE UNDERSTANDING THAT BLOCK(I) ITSELF IS IN    19200014
C       THAT CASE THE MOST PROXIMATE NODE 'PRECEDING' BLOCK(I) ALONG    19300014
C       THE CHAIN OF BACK DOMINATORS.                                   19400014
C                                                                       19500014
C     DEFINITION 3 -- THE DEPTH NUMBER OF A BLOCK I IS THE NUMBER OF    19600014
C       BACK TARGETS WHICH CAN BE CHAINED FROM ONE TO ANOTHER,          19700014
C       BEGINNING WITH ITS OWN AND PROCEDING THRU SUCCESSIVE BACK       19800014
C       TARGETS OF BACK TARGETS, BEFORE REACHING A BLOCK J WHICH HAS NO 19900014
C       BACK TARGET. IF BLOCK I ITSELF HAS NO BACK TARGET, ITS DEPTH    20000014
C       NUMBER IS 0.                                                    20100014
C                                                                       20200014
C     DEFINITION 4 -- A LOOP NUMBER IS AN INTEGER ASSOCIATED WITH A     20300014
C       GROUP OF BLOCKS CONSIDERED TO BE A 'LOOP'. FOR PRESENT          20400014
C       PURPOSES, THIS MEANS A GROUP OF BLOCKS WITH A COMMON BACK       20500014
C       TARGET. (NOTE -- IN SOME CASES THIS DEFINITION LEADS TO A       20600014
C       COLLECTION SOMEWHAT BROADER THAN A LOOP IN THE ORDINARY SENSE.  20700014
C       THE USAGE OF THE WORD 'LOOP' IN THIS PHASE OF THE COMPILER      20800014
C       VARIES FROM TIME TO TIME. IN GENERAL, IT MEANS A COLLECTION OF  20900014
C       BLOCKS INCLUDING AT LEAST ONE LOOP IN THE ORDINARY SENSE OF THE 21000014
C       WORD PLUS SUCH OTHER BLOCKS AS MAY BE CONVENIENT TO PROCESS     21100014
C       WITH THESE.)                                                    21200014
C                                                                       21300014
C     LOOP NUMBERS ARE ASSIGNED CONSECUTIVELY BEGINNING WITH 1, AND IN  21400014
C       SUCH FASHION THAT IF BLOCK(K) HAS A HIGHER DEPTH NUMBER THAN    21500014
C       BLOCK(I), BLOCK(K) HAS THE LOWER LOOP NUMBER.                   21600016
C                                                                       21700014
C                                                                       21800014
CCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCC21900014
C            IEKAAA = BLANK                                             22000014
      COMMON/IEKAAA/ NPTR(2,35)                                         22100014
C            IEKAER = ERCOM                                             22130016
      COMMON/IEKAER/ NERTBL(2,50)                                       22160016
C            IEKJA2 = C1520                                             22200014
      COMMON/IEKJA2/ TEMP, NEW, MCOORD, NPX, KPAD1, KPAD2,              22300014
     2               LONES (32), MASK1 (32), NOPTAB (49),               22400014
     3               MVD(128), SIZMAJ, CMAJOR(450)                      22500014
C            IEKJA4 = RMAJOR                                            22600014
      COMMON/IEKJA4/ RMAJOR(450)                                        22700014
      INTEGER TEMP, RMAJOR, CMAJOR, SIZMAJ                              22800015
C            IEKPBL = BLK                                               22900014
      COMMON/IEKPBL/ N, N1, TRIKL(1000), TRAIL(1000), TARGTS(1000)      23000014
      INTEGER        TRIKL, TRAIL, TARGTS, STATNM                       23100014
C     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 23200014
C                                                                       23300014
C                  LABEL LAYOUT                                         23400014
C                                                                       23500014
      INTEGER BPC,PB,    SN,NPBP,ILEAD,JLEAD,BSZ                        23600014
      LOGICAL*1 BYA,BYB                                                 23700014
      LOGICAL*1 COMP,DN                                                 23800014
      STRUCTURE// BPC,BYA,BYB,COMP,DN,PB,SN,NPBP,ILEAD,JLEAD,BAKTRG     23900014
      INTEGER BAKTRG, FORK                                              24000014
C                                                                       24100014
C     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   24200014
      DATA MARK/Z40000000/                                              24300014
C                                                                       24400014
C     HOUSEKEEPING --                                                   24500014
C       (1) FLAG THOSE BLOCKS WHICH HAVE MORE THAN ONE FORWARD          24600014
C           CONNECTION.                                                 24700014
C       (2) INSURE THAT DEPTH NUMBERS AND BACK TARGETS ARE INITIALLY    24800014
C           ZEROED OUT.                                                 24900014
      N1=N                                                              25000014
      MAXDN = 0                                                         25100014
  100 DO 110 L = 1,N                                                    25200014
      I = TRIKL(L)                                                      25300014
      COMP(I)=BITOFF(COMP(I),3)                                         25400014
      II = ILEAD(I)                                                     25500014
      IF((RMAJOR(II)-MARK).LT.0) COMP(I)=BITON(COMP(I),3)               25600014
      DN(I) = 0                                                         25700014
      TARGTS(L) = 0                                                     25800014
  110 CONTINUE                                                          25900014
C                                                                       26000014
C     FOR EACH BLOCK IN TURN CALCULATE A BACK TARGET. WORK              26100014
C       DOWN THE 'TRICKLE-DOWN' CHAIN, AS SET UP IN SUBROUTINE 'IEKPO'. 26200016
C       BLOCKS ARE THUS PROCESSED TIER BY TIER, IN ORDER OF THEIR       26300014
C       NUMBER OF STEPS' REMOVE FROM THE NEAREST ENTRY. THIS            26400014
C       FACILITATES THE APPLICATION OF THEOREM 1 AND ITS COROLLARIES.   26500014
C                                                                       26600014
  135 DO 245 L = 1,N                                                    26700014
      I = TRIKL(L)                                                      26800014
C                                                                       26900014
C              NO BACK DOMINATOR IMPLIES NO BACK TARGET.                27000014
C                                                                       27100014
  137 IF(PB(I) .EQ. 0) GO TO 245                                        27200014
C                                                                       27300014
C              APPLY COROLLARY 1 OF THEOREM 1. (NOTE DEPENDENCE ON      27400014
C                ORDER OF PROCESSING -- SINCE WE ARE WORKING DOWN THE   27500014
C                'TRICKLE-DOWN' CHAIN, WE CAN SAFELY ASSUME THAT THE    27600014
C                BACK TARGET OF ANY BLOCK ALONG THE CHAIN OF BACK       27700014
C                DOMINATORS HAS ALREADY BEEN PROCESSED.)                27800014
C                                                                       27900014
      K = I                                                             28000014
138   IF(TBIT(COMP(K),0)) GOTO 140                                      28100014
      K = PB(K)                                                         28200014
      GO TO 138                                                         28300014
140   IF(K.NE.I .AND. DN(K).EQ.0) GOTO 245                              28400014
C                                                                       28500014
C              A BACK TARGET IS POSSIBLE. EARMARK THE INITIAL NODE,     28600014
C                THE BLOCKS ON THE CHAIN OF BACK DOMINATORS, AND BLOCKS 28700014
C                WHICH ARE NEITHER OF THE ABOVE. LAY OUT A TRAIL OF     28800014
C                NODES ON THE CHAIN OF BACK DOMINATORS, INCLUDING K.    28900014
C                                                                       29000014
      KSAVE = K                                                         29100014
      DO 141 LL=1,N1                                                    29200014
      II = TRIKL(LL)                                                    29300014
      COMP(II)=BITOFF(COMP(II),1)                                       29400014
      COMP(II)=BITOFF(COMP(II),4)                                       29500014
  141 CONTINUE                                                          29600014
      J = K                                                             29700014
      LL = 0                                                            29800014
142   IF(.NOT.TBIT(COMP(J),0)) GOTO 143                                 29900014
      LL = LL + 1                                                       30000014
      TRAIL(LL) = J                                                     30100014
143   COMP(J)=BITON(COMP(J),1)                                          30200014
      J = PB(J)                                                         30300014
      IF(J .NE. 0) GO TO 142                                            30400014
C                                                                       30500014
C              NOTE END OF CANONICAL TRAIL (I.E., THE CHAIN OF BACK     30600014
C                DOMINATORS) AND BEGINNING OF ALTERNATE PATH.           30700014
C                                                                       30800014
      KNONND = LL                                                       30900014
      MBGIN = LL + 1                                                    31000014
      M = MBGIN                                                         31100014
      LL = 1                                                            31200014
C                                                                       31300014
C              PUT THE FIRST (OR NEXT) NODE FROM THE CANONICAL TRAIL    31400014
C                AT THE HEAD OF A NEW ALTERNATE TRAIL.                  31500014
C                                                                       31600014
  144 FORK = TRAIL(LL)                                                  31700014
      K = FORK                                                          31800014
      TRAIL(M) = FORK                                                   31900014
C                                                                       32000014
C              PROBE BACKWARD ALONG FIRST (OR NEXT) BACKWARD CONNECTION 32100014
C                OF CURRENTLY UPPERMOST INCOMPLETELY EXPLORED FORK ON   32200014
C                ALTERNATE TRAIL.                                       32300014
C                                                                       32400014
  145 ASSIGN 160 TO LASTKN                                              32500014
  150 J = JLEAD(FORK)                                                   32600014
  155 GO TO LASTKN,(160,205)                                            32700014
  160 KONECT = CMAJOR(J) - MARK                                         32800014
      IF(KONECT)170,165,175                                             32900014
  165 STATNM = 165                                                      33000014
  167 N = NPTR(2,22)                                                    33060016
      NPTR(2,22) = NPTR (2,22) +1                                       33120016
      IF (N .GT. NPTR (1,12))GO TO 168                                  33180016
      NERTBL(1,N) = 600                                                 33240019
      NERTBL (2,N) = STATNM                                             33300016
      NPTR (2,35) = 8                                                   33360016
C       CALL SYSDIR                                                     33420016
  168 CALL IEKAA9(99)                                                   33480016
  170 KONECT = KONECT + MARK                                            33600014
      GO TO 180                                                         33700014
  175 ASSIGN 205 TO LASTKN                                              33800014
C                                                                       33900014
C              BACKWARD CONNECTION KONECT COMMENCES NEXT VARIANT ON     34000014
C                BACKWARD PATH. JUMP BACK TO ITS NODE.                  34100014
C                                                                       34200014
  180 KNSAVE = KONECT                                                   34300014
181   IF(TBIT(COMP(KONECT),0)) GOTO 182                                 34400014
      KONECT = PB(KONECT)                                               34500014
      GO TO 181                                                         34600014
C                                                                       34700014
C              IF KONECT IS A NODE ON SOME PATH THAT HAS ALREADY BEEN   34800014
C                FULLY EXPLORED, A NODE ON THE PATH RIGHT NOW UNDER     34900014
C                EXAMINATION, OR A NODE OTHER THAN KSAVE ITSELF ON THE  35000014
C                CANONICAL TRAIL, GO CONSIDER NEXT BACKWARD CONNECTION. 35100014
C                                                                       35200014
182   IF(TBIT(COMP(KONECT),4)) GOTO 185                                 35300014
      IF(.NOT.TBIT(COMP(KONECT),1)) GOTO 200                            35400014
      IF(KONECT .EQ. KSAVE) GO TO 190                                   35500014
  185 J = J + 1                                                         35600014
      GO TO 155                                                         35700014
C                                                                       35800014
C              A PATH HAS BEEN FOUND FROM BLOCK(KSAVE) (THE MOST        35900014
C                PROXIMATE NODE PRECEDING BLOCK(I), OR BLOCK(I) ITSELF) 36000014
C                TO ITSELF. IF THE PATH ALSO PASSES THROUGH BLOCK(I),   36100014
C                THIS IS THE PATH WE WERE LOOKING FOR. OTHERWISE,       36200014
C                CONTINUE HUNTING.                                      36300014
C                                                                       36400014
  190 IF(KSAVE .EQ. I) GO TO 225                                        36500014
  195 IF(KONECT .EQ. KNSAVE) GO TO 185                                  36600014
      IF(KNSAVE .EQ. I) GO TO 225                                       36700014
      KNSAVE = PB(KNSAVE)                                               36800014
      GO TO 195                                                         36900014
C                                                                       37000014
C              KONECT IS ITSELF AN UNEXAMINED FORK IN THE ROAD. WE MUST 37100014
C                EXTEND THE ALTERNATE PATH CURRENTLY UNDER EXAMINATION. 37200014
C                (NOTE -- BY CONSTRUCTION, NO BLOCK THAT CAN BE         37300014
C                REACHED VIA BACKWARD TRAILS FROM BLOCK(KSAVE), OTHER   37400014
C                THAN THE LAST ONE PLACED ON THE CANONICAL TRAIL, CAN   37500014
C                BE LACKING IN BACK DOMINATORS -- ELSE WHY DID BACK     37600014
C                DOMINATORS LOOK LIKE BACK DOMINATORS.) FLAG            37700014
C                BLOCK(KONECT) AS A BLOCK ALREADY UNDER EXAMINATION.    37800014
  200 M = M+1                                                           37900014
      TRAIL(M) = KONECT                                                 38000014
      FORK = KONECT                                                     38100014
      COMP(KONECT)=BITON(COMP(KONECT),4)                                38200014
      GO TO 145                                                         38300014
C                                                                       38400014
C              ALL BACKWARD PATHS FROM THE CURRENTLY UPPERMOST FORK ON  38500014
C                THE ALTERNATE PATH HAVE BEEN CONSIDERED. STEP          38600014
C                DOWNWARD A NOTCH TO EXAMINE THE REMAINING BACKWARD     38700014
C                CONNECTIONS (IF ANY) OF THE PRECEDING FORK. (NOTE ---  38800014
C                THE CURRENT FORK HAS BEEN FLAGGED AS A BLOCK ALREADY   38900014
C                UNDER CONSIDERATION. WE LEAVE IT FLAGGED, WITH THE     39000014
C                MEANING HENCEFORTH THAT IT IS A BLOCK WHICH HAS        39100014
C                ALREADY BEEN FULLY EXPLORED. THE TWO STATES ARE        39200014
C                EQUIVALENT FOR PRESENT PURPOSES.)                      39300014
C                                                                       39400014
  205 IF(M-MBGIN)210,220,215                                            39500014
  210 STATNM = 210                                                      39600014
      GO TO 167                                                         39700014
  215 M = M-1                                                           39800014
      FORK = TRAIL(M)                                                   39900014
      GO TO 145                                                         40000014
C                                                                       40100014
C              ALL BACKWARD PATHS FROM THE NODE K TO ITSELF HAVE BEEN   40200014
C                FULLY EXPLORED, WITH THE EXCEPTION OF THOSE PASSING    40300014
C                THRU BLOCKS ON ITS CHAIN OF BACK DOMINATORS. APPLYING  40400014
C                THEOREM 1, BACK UP ONE NODE ALONG THE CHAIN OF BACK    40500014
C                DOMINATORS AND TRY AGAIN.                              40600014
C                                                                       40700014
  220 LL = LL + 1                                                       40800014
      IF(LL .LT. KNONND) GO TO 144                                      40900014
C                                                                       41000014
C              ALL PERTINENT BACKWARD PATHS HAVE BEEN EXPLORED,         41100014
C                WITHOUT SUCCESS. GIVE UP THE HUNT.                     41200014
C                                                                       41300014
      GO TO 245                                                         41400014
C                                                                       41500014
C              A PATH FROM BLOCK(I) TO ITSELF HAS BEEN FOUND, PASSING   41600014
C                THRU NODE K.  TB IS PB(K) OR TB(PB(K)) IF              41700014
C                PB(K) HAS MORE THAN ONE FORWARD CONNECTION.            41800016
C                                                                       41900014
225   CONTINUE                                                          42000014
      K=PB(K)                                                           42100014
  226 CONTINUE                                                          42200014
      IF(K .EQ. 0) GO TO 245                                            42300014
      IF(.NOT.TBIT(COMP(K),3)) GOTO 240                                 42400014
      K=0                                                               42500014
      GOTO 245                                                          42600014
C                                                                       42700014
C              A BACK TARGET HAS BEEN FOUND. NOTE IT AND NOTE THE       42800014
C                DEPTH NUMBER. THEN PROCEED TO PROCESS NEXT BLOCK.      42900014
C                                                                       43000014
  240 DN(I) = 255                                                       43100014
      IF(DN(K) .LT. 255) DN(I) = DN(K) + 1                              43200014
  242 TARGTS(L) = K                                                     43300014
      LN=DN(I)                                                          43400014
      MAXDN=MAX0(LN,MAXDN)                                              43500014
      BAKTRG(I) = K                                                     43600014
  245 CONTINUE                                                          43700014
C                                                                       43800014
C     NOW USE DEPTH NUMBER AND BACK TARGET INFORMATION TO CONSTRUCT     43900014
C       LOOP NUMBERS.                                                   44000014
C                                                                       44100014
      LOOP = 0                                                          44200014
      NESTS = 0                                                         44300014
C                                                                       44400014
C              CLEAR FLAGS NO LONGER USED AND FLAG EACH BLOCK AS        44500014
C                REQUIRING A LOOP NUMBER.                               44600014
C                                                                       44700014
      DO 250 L=1,N1                                                     44800014
      I = TRIKL(L)                                                      44900014
      COMP(I)=BITOFF(COMP(I),1)                                         45000014
      COMP(I)=BITOFF(COMP(I),4)                                         45100014
      COMP(I)=BITON(COMP(I),0)                                          45200014
  250 CONTINUE                                                          45300014
C                                                                       45400014
C              IDENTIFY ALL BLOCKS AT THE MAXIMUM REMAINING DEPTH       45500014
C                NUMBER AND ASSIGN EACH OF THEM A LOOP NUMBER           45600014
C                UNIQUELY ASSOCIATED WITH ITS OWN BACK TARGET. IN       45700014
C                PASSING, DETERMINE A NEW MAXIMUM REMAINING DEPTH       45800014
C                NUMBER. IF NO UNPROCESSED DEPTH NUMBERS REMAIN, EXIT.  45900014
C                                                                       46000014
  300 IF(MAXDN .LT. 0) GO TO 340                                        46100014
      LOOP = LOOP + NESTS                                               46200014
      MAXB4 = MAXDN                                                     46300014
      MAXDN = MAXDN - 1                                                 46400014
      NESTS = 0                                                         46500014
      DO 335 L=1,N1                                                     46600014
      I = TRIKL(L)                                                      46700014
      IF(DN(I) - MAXB4) 335,320,335                                     46800014
320   IF(.NOT.TBIT(COMP(I),0)) GOTO 335                                 46900014
      COMP(I)=BITOFF(COMP(I),0)                                         47000014
      IF(NESTS .EQ. 0) GO TO 330                                        47100014
      DO 325 LL = 1,NESTS                                               47200014
      IF(TARGTS(L) .NE. TRAIL(LL)) GO TO 325                            47300014
      GO TO 335                                                         47400014
  325 CONTINUE                                                          47500014
  330 NESTS = NESTS + 1                                                 47600014
      TRAIL(NESTS) = TARGTS(L)                                          47700014
  335 CONTINUE                                                          47800014
C     APAR P9088   03/20/67                                             47900014
C                            ASSIGN LOOP NUMBERS IN ORDER OPPOSITE      48000014
C                              TO THEIR DISCOVERY SO WE CATCH LOOPS     48100014
C                              INSIDE BADLY INITIALIZED LOOPS FIRST.    48200014
      DO 339 L=1,N                                                      48300014
      I = TRIKL(L)                                                      48400014
      IF (DN(I) .NE. MAXB4) GO TO 339                                   48500014
      DO 337 LL=1,NESTS                                                 48600014
      IF (TARGTS(L) .EQ. TRAIL(LL)) GO TO 338                           48700014
  337 CONTINUE                                                          48800014
      GO TO 339                                                         48900014
  338 DN(I) = LOOP + NESTS - LL + 1                                     49000014
  339 CONTINUE                                                          49100014
C     END APAR 9088                                                     49200014
C                                                                       49300014
C              GO PROCESS NEXT SHALLOWER LEVEL OF NESTING.              49400014
C                                                                       49500014
      GO TO 300                                                         49600014
C                                                                       49700014
C              NO MORE LEVELS. ALL DONE.                                49800014
C                                                                       49900014
340   CONTINUE                                                          50000014
      J=NPTR(2,11)                                                      50100014
      IF(.NOT.     (TBIT(J,27)  .OR.  TBIT(J,21))     )  GO TO 360      50200016
      WRITE(6,900)                                                      50300014
900   FORMAT('1'39X,'STATEMENT NUMBER DICTIONARY AFTER PROCESSING BY IEK50400016
     1PB'////'    LOC.  '5X,'  BPC'5X,'   SN'5X,'   DN'5X,              50500016
     2'   PB'5X,'ILEAD'5X,'JLEAD'5X,' COMP'5X,'NPBP'2X,'BACK TARGET')   50600016
      J=NPTR(2,17)                                                      50700014
350   WRITE(6,910)J,BPC(J),SN(J),DN(J),PB(J),ILEAD(J),JLEAD(J),         50800014
     1COMP(J),NPBP(J),BAKTRG(J)                                         50900014
910   FORMAT(2Z10,I10,8X,Z2,Z10,2I10,8X,Z2,2Z10)                        51000014
      J=BPC(J)                                                          51100014
      IF(J.NE.0) GOTO 350                                               51200014
      WRITE (6,911) (RMAJOR(I),I=1,SIZMAJ)                              51220015
911   FORMAT ('0 RMAJOR',/(10Z10))                                      51240015
      WRITE (6,912) (CMAJOR(I),I=1,SIZMAJ)                              51260015
912   FORMAT ('0 CMAJOR',/(10Z10))                                      51280015
360   CONTINUE                                                          51300014
      RETURN                                                            51400014
      END                                                               51500014
