 TITLE 'IEYFORT2---CONTROLS LOADING AND DELETION OF COMPILER MODULES'   00010000
         PRINT NOGEN                                                    00020000
         MACRO                                                          00030000
&LABEL   INITIAL                                                        00040000
&LABEL   EQU   *                                                        00050000
         USING *,15                                                     00060000
         STM   FIRST,LAST,SAVE    STORE REGS IN LOCAL AREA              00070000
         L     BASEREG,BADCON     LOAD BASE REGISTER                    00080000
         DROP  15                                                       00090000
         USING BASADR,BASEREG                                           00100000
         MEND                                                           00110000
         EJECT                                                          00120000
IEYFORT2 START                                                          00130000
         EXTRN ROLLTABL                                                 00140000
BASADR   EQU   *                                                        00150000
X1       EQU   9                  BXLE REGS                             00160000
X2       EQU   10                 BXLE INCREMENT.  MUST BE EVEN         00170000
X3       EQU   11                 BXLE COMPARAND.  MUST BE X2+1         00180000
X4       EQU   12                 WORK REG                              00190000
X5       EQU   7                                                        00200000
X6       EQU   6                                                        00210000
RETURN   EQU   14                 RETURN REG FOR LINKED ENTRY POINT>    00220000
BASEREG  EQU   8                  BASE REGISTER                         00230000
FIRST    EQU   6                  FIRST REG FOR STM-LM                  00240000
LAST     EQU   14                 LAST REG OF SAVE RANGE                00250000
*  FOLLOWING TWO EQUATES ARE FOR ENTRIES IN LOAD MODULE TABLE           00260000
EPLOC    EQU   0                  ADDRESS OF MODULE IF LOADED ELSE ZERO 00270000
BLDLPTR  EQU   4                  ADR OF BLDL ENTRY FOR MODULE          00280000
NZERO    EQU   7                  CONDITION CODE FOR NOT ZERO           00290000
LASTROLL EQU   240                HIGHEST REGULAR ROLL NO. TIMES 4      00300000
ROLLADR  EQU   3488               DISP OF ROLL ADR TABLE FROM ROLL BASE 00310000
BASE     EQU   0                  DISP OF BASES FROM ROLL BASE          00320000
TOP      EQU   260                DISP OF TOPS FROM ROLL BASE           00330000
BOTTOM   EQU   516                DISP OF BOTTOMS FROM ROLL BASE        00340000
NEXTIN   EQU   0                  NEXT REGULAR ROLL ADR TABLE POINTER   00350000
LASTIN   EQU   4                  DISP  OF LAST ROLL ADR TABLE ENTRY    00360000
*                                 ADCON FROM ROLL ADR EXTRN             00370000
CODE     EQU   248                CODE ROLL I.D.                        00380000
MODSIZE  EQU   24                  MODULE SIZE FIELD IN BLDL ENTRY 5210 00385016
         ENTRY INIT                                                     00390000
         ENTRY REINIT                                                   00400000
         ENTRY NEXT                                                     00410000
         ENTRY SCRATCH                                                  00420000
         ENTRY ALLOUT                                              5210 00425016
         EJECT                                                          00430000
INIT     INITIAL                                                        00440000
         LA    0,BLIST            POINT TO LIST FOR BLDL                00450000
         SR    1,1                INDICATE LINK OR JOB LIB              00460000
         BLDL  (1),(0)            BLDL FOR COMPILER MODULES             00470000
LOADALL  LM    X1,X3,XADRS        LOAD INDEXES TO STEP THRU LOAD TABLE  00480000
LOADLOOP L     0,BLDLPTR(X1)      LOAD ADR OF BLDL ENTRY                00490000
         LOAD  DE=(0)             AND LOAD NEXT MODULE                  00500000
         ST    0,EPLOC(X1)        STORE ENTRY POINT IN LOAD TABLE       00510000
         BXH   X1,X2,LOADLOOP     INDEX THRU LOAD TABLE                 00520000
INITEXIT ST    X3,CURRENT         RESET CURRENT MODULE POINTER          00530000
         L     15,=V(IEYINT)      POINT TO INTERPRETOR CSECT            00540000
         LM    FIRST,LAST,SAVE    RESTORE REGISTERS                     00550000
         BR    15                 GO START NEW COMPILATION              00560000
         EJECT                                                          00570000
REINIT   INITIAL                                                        00580000
         LM    X1,X4,XADRS        SET UP REGS TO INDEX THRU LOAD TABLE  00590000
REINLOOP C     X4,EPLOC(X1)       IS THIS MODULE STILL LOADED           00600000
         BE    DELETE             IF NOT GO SCRATCH ALL MODULES         00610000
         BXH   X1,X2,REINLOOP     ELSE INDEX THRU REST OF ENTRIES       00620000
         B     INITEXIT           ALL MODULES STILL LOADED.  EXIT       00630000
DELETE   L     X1,XADRS           RESET INDEX                           00640000
DLOOP    C     X4,EPLOC(X1)       IS THIS MODULE STILL LOADED           00650000
         BE    DBXH               IF NOT GO STEP THRU REST OF TABLE     00660000
         L     0,BLDLPTR(X1)      ELSE POINT TO BLDL ENTRY FOR MODULE   00670000
         DELETE DE=(0)            AND DELETE IT                         00680000
         ST    X4,EPLOC(X1)       ZERO ENTRY POINT TO SHOW DELETION     00690000
DBXH     BXH   X1,X2,DLOOP        INDEX THRU TABLE, DELETING ALL        00700000
         B     LOADALL            THEN GO RE-LOAD ALL MODULES           00710000
         EJECT                                                          00720000
NEXT     INITIAL                                                        00730000
         L     13,=V(SAVR)        POINT TO SAVE AREA IN FORT            00740000
         L     X1,CURRENT  POINT TO LOAD TABLE ENTRY OF CURRENT MODULE  00750000
         LA    15,8(X1)           ADR OF LOAD TABLE ENTRY FOR NEXT MOD. 00760000
         ST    15,CURRENT         STORE ADR LOAD TABLE ENTRY FOR NEXT   00770000
         L     15,EPLOC(15)       ENTRY POINT OF NEXT MODULE            00780000
         LTR   15,15              IF ZERO NEXT MODULE NOT LOADED        00790000
         BC    NZERO,NEXTEXIT     IF LOADED EXIT TO IT                  00800000
         L     0,BLDLPTR(X1)      ELSE POINT TO BLDL ENTRY OF CURRENT   00810000
         DELETE DE=(0)            AND DELETE CURRENT                    00820000
         MVC   EPLOC(4,X1),ZERO   ZERO ENTRY POINT TO SHOW DELETION     00830000
         C     X1,UNFADR          DID WE JUST SCRATCH UNIFY             00840000
         BNE   NOTALL             IF NO THEN SKIP TEST FOR SPACE        00850000
         MVI   PRESSUNF+1,X'0'    SET SWITCH FOR ONCE ONLY EXECUTION    00860000
*  FOLLOWING GETMAIN AND FREEMAIN TESTS TO SEE IF THERE IS ROOM FOR GEN 00870000
CHKGEN   GETMAIN EC,LV=15000,A=GENCORE  REQUEST ENOUGH CORE FOR GEN     00880000
         B     *+4(15)            REG 15=0 IF SUPPLIED, 4 IF NOT        00890000
         B     OK                 BR. IF ENOUGH CORE FOR GEN WAS GOTTEN 00900000
         B     PRESSUNF           GO PRESS AND FREE ROLL CORE           00910000
OK       FREEMAIN E,LV=15000,A=GENCORE  SURRENDER GEN CORE              00920000
NOTALL   L     0,BLDLPTR+8(X1)    POINT TO BLDL ENTRY FOR NEXT MODULE   00930000
         LOAD  DE=(0)             LOAD MODULE VIA BLDL ENTRY            00940000
         ST    0,EPLOC+8(X1)      STORE ADR TO SHOW ITS LOADED          00950000
         LR    15,0               LOAD ENTRY POINT IN BRANCH REG        00960000
NEXTEXIT LM    FIRST,LAST,SAVE    RESTORE REGS                          00970000
         BR    15                 AND GO TO NEXT MODULE                 00980000
         EJECT                                                          00990000
PRESSUNF BC    0,NOGOOD           GO QUIT THE SECOND TIME THROUGH       01000000
         MVI   PRESSUNF+1,X'F0'   SET SWITCH TO QUIT THE 2ND TIME THRU  01010000
         ST    X1,PRESAVE         SAVE X1                               01020000
         L     15,=V(PRESS)       LOAD ADR OF PRESS ROUTINE IN IEYINT   01030000
         MVI   1(15),X'F0'        SET FLAG TO INDICATE OUTSIDE CALL     01040000
         LM    FIRST,LAST,SAVE    RESTORE REGISTERS                     01050000
         BALR  11,15              GO PRESS ROLL STORAGE                 01060000
         USING *,11                                                     01070000
         STM   FIRST,LAST,SAVE    RE-ESTABLISH ADDRESSABILITY           01080000
         L     BASEREG,BADCON                                           01090000
         DROP  11                                                       01100000
         USING BASADR,BASEREG                                           01110000
         L     X6,TABS            POINT TO ROLL ADR TABLE CONTROL WORDS 01120000
*  THE FIRST WORD POINTS TO THE NEXT REGULAR ROLL ADR TABLE ENTRY,      01130000
* WHICH IS ALSO THE FIRST CODE/POLISH ENTRY.  THE SECOND WORD POINTS    01140000
* TO THE LAST ROLL ADR TABLE ENTRY, WHICH IS THE LAST CODE/POLISH ENTRY 01150000
         L     X4,ROLLSAVE        LOAD ROLLBR                           01160000
         L     X3,NEXTIN(X6)      POINT TO 1ST CODE/POLISH ENTRY        01170000
         L     X1,LASTROLL+BASE+4(X4) LAST USED ROLL POSITION           01180000
         SRL   X1,10              EXTRACT POINTER TO ROLL ADR TABLE     01190000
         N     X1,MASK1                                                 01200000
         SR    X5,X5              COUNTER FOR NUMBER OF BLOCKS FREED    01210000
FLOOP    S     X3,FOUR            POINT TO NEXT LOWER ROLL ADR ENTRY    01220000
         CR    X1,X3              IS THIS BLOCK USED                    01230000
         BE    ALLDONE            IF YES EXIT                           01240000
         L     X2,ROLLADR(X3,X4)  LOAD ADR OF UNUSED BLOCK              01250000
         FREEMAIN R,LV=4096,A=(X2) FREE THE UNUSED BLOCK                01260000
         LA    X5,4(X5)           BUMP COUNT OF ROLL ADR BYTES FREED    01270000
         B     FLOOP                                                    01280000
*  FOLOWING CODE SHIFT ALL CODE/POLISH ROLL ADR TABLE ENTRIES           01290000
*  DOWN SO THEY IMMEDIATELY FOLLOW THE LAST REGULAR ENTRY.              01300000
ALLDONE  LTR   X5,X5              WERE ANY BLOCKS FREED                 01310000
         BZ    NOGOOD             IF NO GO QUIT                         01320000
         LA    X1,4(X1)           X1 POINTS TO TARGET OF MOVE, THE      01330000
*                                 POSITION FOLLOWING LAST REG. ENTRY    01340000
         L     X2,LASTIN(X6)      POINT TO LAST CODE/POLISH ENTRY       01350000
         SR    X2,X5              DUNK BY NO. OF WORDS FREED TO POINT   01360000
*                                 TO NEW POSITION OF LAST ENTRY         01370000
         ST    X2,LASTIN(X6)      AND STORE BACK IN IEYINT              01380000
         SR    X2,X1              CALC LENGTH OF CODE/POLISH ENTRIES    01390000
         LA    X2,7(X2)           BUMP TO EXECUTE INSTRUCTION VALUE,    01400000
*                                 INCLUDING THE ZERO WORD THATS KEPT    01410000
*                                 AFTER THE LAST CODE/POLISH ENTRY.     01420000
         L     X3,NEXTIN(X6)      POINT TO 1ST CODE/POLISH ENTRY        01430000
         ST    X1,NEXTIN(X6)      STORE NEW POSITION OF FIRST ENTRY     01440000
         LA    X3,ROLLADR(X3,X4)  LOAD COMPLETE ADR OF OLD POSITION     01450000
         LA    X1,ROLLADR(X1,X4)  LOAD COMPLETE ADR OF NEW POSITION.    01460000
MLOOP    C     X2,CON255          IS AMOUNT TO MOVE GT 256              01470000
         BNH   SMOVE              IF NO BRANCH                          01480000
         MVC   0(256,X1),0(X3)    ELSE MOVE 256 BYTES                   01490000
         LA    X1,256(X1)         BUMP TARGET                           01500000
         LA    X3,256(X3)         BUMP SOURCE                           01510000
         S     X2,CON256          DUNK LENGTH                           01520000
         B     MLOOP              AND LOOP FOR REST OF MOVE             01530000
SMOVE    EX    X2,MVC             MOVE CODE/POLISH POINTERS TO NEW LOC. 01540000
*  FOLLOWING CODE DUNKS CODE AND POLISH BASES, TOPS, AND BOTTOMS SO     01550000
*  THEY POINT TO THE NEW LOCATIONS OF THE CODE/POLISH ROLL ADR ENTRIES  01560000
         LA    X2,CODE            LOAD CODE ROLL REFERENCE NO.          01570000
         LA    X3,2               COUNTER FOR BCT INSTRUCTION           01580000
         SLL   X5,10              SHIFT TO GET DUNK AMOUNT FOR CODE/POL 01590000
DUNK     L     X1,BASE(X2,X4)     LOAD BASES                            01600000
         SR    X1,X5              DUNK TO NEW POSITION                  01610000
         ST    X1,BASE(X2,X4)     AND RESTORE                           01620000
         L     X1,TOP(X2,X4)                                            01630000
         SR    X1,X5              DUNK TO NEW POSITION                  01640000
         ST    X1,TOP(X2,X4)                                            01650000
         L     X1,BOTTOM(X2,X4)                                         01660000
         SR    X1,X5              DUNK TO NEW POSITION                  01670000
         ST    X1,BOTTOM(X2,X4)                                         01680000
         LA    X2,4(X2)           POINT TO POLISH                       01690000
         BCT   X3,DUNK            LOOP FOR POLISH ROLL                  01700000
         L     X1,BASE(X2,X4)     LOAD EXTRA BASE FOLLOWING POLISH      01710000
         SR    X1,X5              ADJUST                                01720000
         ST    X1,BASE(X2,X4)                                           01730000
         L     X1,PRESAVE         RESTORE INDEX REG                     01740000
         B     CHKGEN             AND GO SEE IF GEN WILL FIT NOW.       01750000
NOGOOD   EQU   *                                                        01760000
         L     15,=V(IEYNOCR)     ELSE GO TERMINATE COMPILATION         01770000
         LM    FIRST,LAST,SAVE          RESTORE REGS              53119 01775021
         BR    15                                                       01780000
         EJECT                                                          01790000
SCRATCH  INITIAL                                                        01800000
         LM    X1,X4,CURRENT      SET UP REGS TO INDEX LOAD TABLE       01810000
SCRLOOP  LA    X2,8(X2)           POINT TO NEXT MODULE PRIOR TO CURRENT 01820000
         CR    X1,X2              HAVE WE REACHED CURRENT MOD. IN TABLE 01830000
         BE    CHECK              IF YES SEE IF ANY PRIOR WERE DELETED  01840000
         LM    15,0,EPLOC(X2)     LOAD ENTRY POINT AND BLDL TABLE ADR   01850000
         LTR   15,15              IF ZERO MOD. IS ALREADY SCRATCHED     01860000
         BZ    SCRLOOP            STEP THRU TABLE SCRATCHING ALL PRIORS 01870000
         DELETE DE=(0)            SCRATCH THIS PRIOR MODULE             01880000
         SR    X4,X4              ZERO REG MEANS WE DELETED A PRIOR     01890000
         ST    X4,EPLOC(X2)       ZERO ENTRY TO SHOW DELETION           01900000
         B     SCRLOOP            LOOP TO DELETE ALL REMAINING PRIORS   01910000
CHECK    LTR   X4,X4              COULD WE DELETE ANY PRIOR MODULES     01920000
         BZ    SOME               IF YES GO INDICATE AND EXIT           01930000
         LA    X2,8               SET INCREMENT REG FOR BXH             01940000
CLOOP    BXH   X1,X2,CDONE        LOOP THRU LOAD TABLE BEYOND CURRENT   01950000
         LM    15,0,EPLOC(X1)     LOAD ENTRY ADR AND BLDL POINTER       01960000
         LTR   15,15              IS MODULE STILL LOADED                01970000
         BZ    CLOOP              IF NOT LOOP                           01980000
         DELETE DE=(0)            DELETE MODULE BEYOND CURRENT          01990000
         SR    X4,X4              ZERO REG MEANS WE DELETED SOMETHING   02000000
         ST    X4,EPLOC(X1)       ZERO ENTRY POINT TO SHOW DELETION     02010000
         B     CLOOP              LOOP FOR REST THAT FOLLOW CURRENT     02020000
SOME     EQU      *                                                     02030000
         CLI   *,X'FF'             SET CC 4 TO INDICATE DELETION        02040000
         LM    FIRST,LAST,SAVE    RESTORE REGS                          02050000
         BR    RETURN             AND RETURN                            02060000
CDONE    LTR   X4,X4              WAS ANYTHING DELETED AFTER CURRENT    02070000
         BZ    SOME               IF YES GO INDICATE AND EXIT           02080000
         CLI   *,X'0'             SET CC 2 TO INDICATE NONE DELETED     02090000
         LM    FIRST,LAST,SAVE    RESTORE REGS                          02100000
         BR    RETURN             AND RETURN                            02110000
         EJECT                                                     5210 02110816
ALLOUT   INITIAL                                                   5210 02111616
         LM    X1,X4,XADRS         SET UP REGS TO INDEX THRU LOAD TABLE 02112416
ALLOUT2  C     X4,EPLOC(X1)        IS THIS MODULE STILL LOADED     5210 02113216
         BE    ALLOUT3             IF NOT GO STEP THRU REST OF TABLE210 02114016
         L     0,BLDLPTR(X1)       ELSE POINT TO BLDL ENTRY FOR MODULE  02114816
         DELETE DE=(0)             AND DELETE IT                   5210 02115616
         ST    X4,EPLOC(X1)        ZERO ENTRY POINT TO SHOW DELETION210 02116416
ALLOUT3  BXH   X1,X2,ALLOUT2       INDEX THRU TABLE, DELETING ALL  5210 02117216
         LM    FIRST,LAST,SAVE     RESTORE REGISTERS               5210 02118016
         BR    14                  RETURN TO IEYFINAL              5210 02118816
         EJECT                                                          02120000
*    ****  BLDL TABLE FOR COMPILER LOAD MODULES ****                    02130000
BLIST    DC    H'5',H'70'         BLDL CONTROL FIELD                    02140000
BALL     DC    C'IEYALL  ',5X'0',FL1'56',56X'0'                         02150000
BEXT     DC    C'IEYEXT  ',5X'0',FL1'56',56X'0'                         02160000
BGEN     DC    C'IEYGEN  ',5X'0',FL1'56',56X'0'                         02170000
BPAR     DC    C'IEYPAR  ',5X'0',FL1'56',56X'0'                         02180000
BUNF     DC    C'IEYUNF  ',5X'0',FL1'56',56X'0'                         02190000
*                    ****  LOAD TABLE   ****                            02200000
*    ***   EPLOC   - FIRST WORD OF EACH ENTRY.  POINTS TO MODULE, IF    02210000
*                               MODULE IS CURRENTLY LOADED, ELSE ZERO.  02220000
*    ***   BLDLPTR - SECOND WORD OF EACH ENTRY  POINTS TO BLDL TABLE    02230000
*                               ENTRY FOR MODULE, WHICH IS USED TO LOAD 02240000
*                               AND DELETE MODULE.                      02250000
LPAR     DC    A(0,BPAR)          PARSE LOAD TABLE ENTRY                02260000
         DC    A(0,BALL)          ALLOCATE LOAD TABLE ENTRY             02270000
LUNF     DC    A(0,BUNF)          UNIFY LOAD TABLE ENTRY                02280000
         DC    A(0,BGEN)          GENERATE LOAD TABLE ENTRY             02290000
LEXT     DC    A(0,BEXT)          EXIT LOAD TABLE ENTRY                 02300000
CURRENT  DC    A(0,LPAR-8,LEXT,1) FIRST WORD POINTS TO CURRENT MOD.     02310000
XADRS    DC    A(LEXT),F'-8',A(LPAR-8,0)                                02320000
UNFADR   DC    A(LUNF)            ADCON TO CHECK IF UNF IS CURRENT MOD. 02330000
GENCORE  DC    F'0'               FOR GEN GETMAIN                       02340000
ZERO     DC    F'0'               CONSTANT                              02350000
BADCON   DC    A(BASADR)          BASE VALUE                            02360000
FOUR     DC    F'4'               CONSTANT                              02370000
MASK1    DC    X'00000FFC'        MASK TO EXTRACT ROLL ADR POINTER      02380000
CON256   DC    F'256'             CONSTANT                              02390000
CON255   DC    F'255'             CONSTANT                              02400000
TABS     DC    A(ROLLTABL)        ADR OF TWO ROLL ADR TABLE POINTERS    02410000
PRESAVE  DS    F                                                        02420000
*                                 IN IEYINT.                            02430000
MVC      MVC   0(0,X1),0(X3)      MOVE INSTR TO SHIFT CODE AND POLISH   02440000
*                                 POINTERS IN ROLL ADR TABLE            02450000
SAVE     DS    9F                 SAVE AREA                             02460000
ROLLSAVE EQU   SAVE+16            SAVE LOCATION FOR ROLLBR              02470000
         END                                                            02480000
