SNCK     TITLE '   FORTRAN SYNTAX CHECKER MODULE  '                     00020020
*                                                                       00040020
*        IPDSN, CHECKER MODULE                                          00060020
*                                                                       00080020
*        IPDSN, THE CHECKER MODULE, VERIFIES THE SYNTAX OF              00100020
*        FORTRAN STATEMENTS.  IT IS COMPOSED OF TWO SEGMENTS,           00120020
*        IPDSNEXC, THE EXECUTIVE, AND IPDSNCKR, THE CHECKER.            00140020
*                                                                       00160020
*        ALL ENTRIES AND EXITS OF THE SYNTAX CHECKER FROM THE           00180020
*        ENVIRONMENTAL SYSTEM GO THROUGH THE EXECUTIVE SEGMENT.         00200020
*                                                                       00220020
*        ALL CALLS TO THE ERROR MESSAGE GENERATOR, IPDER, ARE ALSO      00240020
*        MADE EXCLUSIVELY BY THE EXECUTIVE SEGMENT.                     00260020
*                                                                       00280020
*        THE OPERATION OF THIS MODULE DEPENDS UPON THE PROPERTIES OF    00300020
*        THE INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET      00320020
*        SPECIFIED IN THE INTRODUCTORY COMMENTS TO ITS CONTROL SECTIONS 00340020
*        IPDSNEXC AND IPDSNCKR.                                         00360020
*                                                                       00380020
         MACRO                                                          00400020
         BOMBR                                                          00420020
         ORG   *-4                                                      00440020
         DC    4X'00'                                                   00460020
         MEND                                                           00480020
         MACRO                                                          00500020
&NMTSTAM TSTAM &FAILLOC                                                 00520020
*                             TEST FOR ALPHAMERIC                       00540020
&NMTSTAM CLI   WKASCHRS,CKRA       IS IT LESS THAN A IN EBCDIC COLL SEQ 00560020
         BNL   A&SYSNDX             NO, DO ALPHA/NUMBER TEST            00580020
         CLI   WKASCHRS,CKR$        YES, IS IT $                        00600020
         BNE   &FAILLOC              NO, TEST FAILS                     00620020
         B     E&SYSNDX              YES, TEST SUCCEEDS                 00640020
A&SYSNDX TRT   WKASCHRS(1),CKRAMTBL                                     00660020
         BC    7,&FAILLOC          NOT ALPHAMERIC                       00680020
E&SYSNDX EQU   *                   ALPHAMERIC                           00700020
         MEND                                                           00720020
*                                                                       00740020
*                                                                       00760020
         MACRO                                                          00780020
&NMTSTAL TSTAL &FAILLOC                                                 00800020
*                             TEST FOR ALPHABETIC                       00820020
&NMTSTAL CLI   WKASCHRS,CKRZ       IS IT GREATER THAN Z IN EBCDIC SEQ.  00840020
         BH    &FAILLOC             IF SO, NOT ALPHABETIC (EVEN IF A/M) 00860020
*                                                                       00880020
         TSTAM &FAILLOC                                                 00900020
         MEND                                                           00920020
*                                                                       00940020
*                                                                       00960020
         MACRO                                                          00980020
&NMUPDSC UPDSC                                                          01000020
&NMUPDSC L     REGSRCPT,WKASRCUP   UPDATE SOURCE POINTER                01020020
         MEND                                                           01040020
*                                                                       01060020
*                                                                       01080020
         MACRO                                                          01100020
&NMSVERP SVERP &REGISTR                                                 01120020
*                                       SET ERROR PT FROM CURR SRCE PT  01140020
         AIF   ('&REGISTR' EQ '').NOREG                                 01160020
&NMSVERP L     &REGISTR,WKASRCCR                                        01180020
         ST    &REGISTR,WKAERRSC                                        01200020
         MEXIT                                                          01220020
.NOREG   ANOP                                                           01240020
&NMSVERP MVC   WKAERRSC,WKASRCCR                                        01260020
         MEND                                                           01280020
*                                                                       01300020
*                                                                       01320020
         MACRO                                                          01340020
&NMGTNB1 GTNB1                                                          01360020
&NMGTNB1 BAL   REGLRETN,CKRGTNB1   GET NEXT NON-BLANK CHARACTER         01380020
         MEND                                                           01400020
*                                                                       01420020
*                  ASSEMBLY PARAMETERS FOR DEBUGGING                    01440020
*                                                                       01460020
         LCLC  &EXCALMS,&EXCALMT   EXECUTIVE VARIABLES FOR DEBUGGING    01480020
         LCLC  &ITNLDBG            LEVEL OF INTERNAL DEBUGGING DONE BY  01500020
*                                   IPDSNCKR                            01520020
*                                                                       01540020
*                  THE LAST  SETC  TO DEFINE A SYMBOL DETERMINES        01560020
*                  THE SUBSEQUENT VALUE OF THE SYMBOL. HENCE, ASSEMBLY  01580020
*                  PARAMETERS MAY BE CHANGED FOR DEBUGGING BY           01600020
*                  REORDERING SETC CARDS.                               01620020
*                                                                       01640020
&EXCALMT SETC  '*+1'                                                    01660020
&EXCALMS SETC  '*+1'               *+1 USED TO CAUSE SPECIFICATION     C01680020
                                   ERRORS WHEN DEBUGGING                01700020
&EXCALMT SETC  'EXCALMT'                                                01720020
&EXCALMS SETC  'EXCALMS'                                                01740020
*                                                                       01760020
&ITNLDBG SETC  ''                  NO DEBUGGING                         01780020
&ITNLDBG SETC  'L'                 LIMITED DEBUGGING                    01800020
&ITNLDBG SETC  'E'                 EXTENDED DEBUGGING                   01820020
*                                                                       01840020
*                                                                       01860020
*                  NUMBERS ARE REFERRED TO BEGINNING WITH ZERO,         01880020
*                  EXCEPT FOR CARD COLUMNS, WHICH ARE REFERRED TO       01900020
*                  STARTING FROM 1.  E.G.,  BYTES 0-3 OF A FULL-WORD,   01920020
*                  BITS 0-7 OF A BYTE,  COLUMNS 1-80 OF A CARD.         01940020
*                                                                       01960020
         EJECT                                                          01980020
*                                                                       02000020
*                                                                       02020020
*NAME OF ROUTINE..                                                      02040020
*        IPDSNEXC                                                       02060020
*                                                                       02080020
*FUNCTION..                                                             02100020
*        THE EXECUTIVE SEGMENT OF THE SYNTAX CHECKER MODULE             02120020
*        MANAGES WORK AREAS AND LANGUAGE DEFINITION TABLE MODULES,      02140020
*        SCANS INPUT BUFFER CHAIN FOR SOURCE STATEMENTS,                02160020
*        CALLS THE SYNTAX CHECKER PROPER TO DIAGNOSE SYNTAX ERRORS,     02180020
*        CALLS THE ERROR PROCESSOR TO CONSTRUCT ERROR MESSAGES, AND     02200020
*        SETS UP PROPER RETURNS TO THE CALLING SYSTEM.                  02220020
*                                                                       02240020
*                                                                       02260020
*ENTRY.. IPDSNEXC. CALLED VIA STANDARD CALLING SEQUENCE.                02280020
*                                                                       02300020
*INPUT..                                                                02320020
*              WHEN EXECUTIVE IS CALLED, REGISTER 1 POINTS TO           02340020
*                  DC A(FIRST BUFFER IN CHAIN),                         02360020
*                  DC A(COMMUNICATIONS AREA, 4 WORDS),                  02380020
*                  DC X'80',                                            02400020
*                  DC AL3(OPTIONS WORD).                                02420020
*                                                                       02440020
*                         THE AMOUNT OF SPACE FOR EXPANSION IS THE      02460020
*                         DIFFERENCE BETWEEN THIS NUMBER AND THE        02480020
*                         NUMBER OF BYTES USED IN THE CODING OF THE     02500020
*                                                                       02520020
*                                                                       02540020
*COMMENTS BEGIN IN COLUMNS        35   40   45      IN EXECUTIVE        02560020
*                                                                       02580020
*                                 PARAMETERS PASSED BY SYSTEM.          02600020
*                                 REGPARAM USED AS DSECT REGISTER.      02620020
IPDSNSNP DSECT                                                          02640020
SNPRMBFR DS    F                  ADDRESS OF FIRST BUFFER IN CHAIN.     02660020
SNPRMCOM DS    F                  ADDRESS OF 4-WORD COMMUNICATION AREA. 02680020
SNPRMOPT DS    F                  ADDRESS OF OPTIONS WORD.              02700020
*                                                                       02720020
*                                                                       02740020
*                                 FORMAT OF COMMUNICATIONS AREA,4 WDS.  02760020
IPDSNCOM DSECT                                                          02780020
COMWRKAD DS    0F                 FULL WORD ADDRESS, FOR WORK AREA.     02800020
COMENTRY DS    XL1                FIRST BYTE CONTAINS ENTRY INFORMTN., C02820020
                                  REST OF COMM. AREA IS SET BY IPDSNEXC 02840020
COMNWBUF EQU   X'80'              NORMAL ENTRY.  NEW BUFFER.            02860020
COMFNTRY EQU   X'A0'              FINAL ENTRY                           02880020
COMAFRC8 EQU   X'C0'              ENTRY AFTER RETURN CODE 8             02900020
COMARC12 EQU   X'90'              ENTRY AFTER RETURN CODE 12            02920020
COMWORKA DS    XL3                WORK AREA ADDRESS IN BYTES 1-3.       02940020
COMERRAD DS    F                  ADDRESS OF ERROR MESSAGE.             02960020
         DS    2F                 AREA FOR PORTION OF GETMAIN PARAMLIST 02980020
*                                                                       03000020
*                                 FORMAT OF OPTIONS WORD.               03020020
IPDSNOPT DSECT                                                          03040020
OPTLEVEL DS    XL1                LEVEL OF FORTRAN WANTED, E,G, OR H,   03060020
*                                 FOR THIS BUFFER CHAIN                 03080020
*              X'00'                  LEVEL H                           03100020
*              X'01'                  LEVEL E                           03120020
*              X'02'                  LEVEL G                           03140020
*              X'03'                  LEVEL TSO                         03160020
*              X'04'                  LEVEL G1                          03180020
OPTTABS  DS    XL1                INTERROGATED AT INITIAL CALL ONLY.    03200020
*                                 BIT6=1 SAYS LOAD IPDAGH SYNTAX TABLE  03220020
*                                 BIT7=1           IPDTEE               03240020
OPTLNLNG DS    XL1                LENGTH OF LINES IN BUFFER CHAIN.      03260020
OPTBYTE3 DS    XL1                BITS FOR OTHER INFORMATION.           03280020
EXCNLNUM EQU   X'40'              BIT 1=1 SPECIFIES NO LINE NUMBERS     03300020
*                                 BIT 1=0 FOR LINE NUMBERED DATA SET    03320020
EXCBFSPN EQU   X'10'              BIT 3 = 1  RC12 ALLOWED TO BE GIVEN   03340020
*                                 BIT 3 = 0  RC12 NOT ALLOWED           03360020
EXCVRLNG EQU   X'08'              BIT 4=1 SPECIFIES VARIABLE LENGTH     03380020
*                                      RECORDS                          03400020
*                                 BIT 4=0 SPECIFIES FIXED LENGTH        03420020
EXCFRFRM EQU   X'04'              BIT 5=1 SPECIFIES FREE-FORM SOURCE    03440020
*                                 BIT 5=0 SPECIFIES STANDARD-FORM       03460020
*                                                                       03480020
*OUTPUT..IPDSNCOM AREA IS SET OR DESTROYED AS DESCRIBED ABOVE. FIRST    03500020
*        BYTE OF IT IS UNCHANGED EXCEPT DURING INITIAL CALL, WHEN IT IS 03520020
*        RESTORED AFTER POSSIBLY BEING CHANGED DURING THE               03540020
*        EXECUTION OF THE CONDITIONAL GETMAIN. WHEN IPDSNEXC RETURNS    03560020
*        TO ITS CALLER AFTER OTHER THAN A FINAL CALL, REGISTER 15       03580020
*        CONTAINS ONE OF THE FOLLOWING RETURN CODES...                  03600020
*              0 - REQUESTS A NEW BUFFER CHAIN.                         03620020
*              4 - REQUESTS A NEW BUFFER CHAIN AND INDICATES THERE IS A 03640020
*                  MESSAGE TO BE SENT.                                  03660020
*              8 - INDICATES THAT CHECKING OF THE CURRENT BUFFER CHAIN  03680020
*                  IS NOT COMPLETE AND THERE IS A MESSAGE TO BE SENT.   03700020
*             12 - REQUESTS A NEW BUFFER WHICH WILL BE PROCESSED AS AN  03720020
*                  EXTENSION OF THE PREVIOUS BUFFER.                    03740020
*             16 - INDICATES THE CHECKER IS NOT OPERATIONAL BECAUSE A   03760020
*                  CONDITIONAL GETMAIN FAILED DURING THE INITIAL CALL.  03780020
*             20 - INDICATES BUFFER CHAIN NOT CHECKED BECAUSE THE       03800020
*                  SYNTAX TABLE NOW REQUESTED BY THE VALUE IN OPTLEVEL  03820020
*                  WAS NOT REQUESTED AT INITIAL CALL.                   03840020
*                                                                       03860020
*EXTERNAL REFERENCES..                                                  03880020
*        SUPERVISOR SERVICES USED ARE GETMAIN, FREEMAIN, LOAD, AND DE-  03900020
*        LETE. SUBROUTINES CALLED ARE IPDSNCKR AND IPDERERR. THE        03920020
*        MESSAGE TABLE, IPDERMSG, IS PASSED TO IPDERERR. THE SYNTAX     03940020
*        DEFINITION TABLES, IPDAGH AND IPDTEE, ARE LOAD'ED AND          03960020
*        PASSED TO IPDSNCKR.                                            03980020
*                                                                       04000020
*ERROR CONDITIONS..                                                     04020020
*        INABILITY TO LOAD A SYNTAX TABLE CAUSES ABEND. CONDITIONAL     04040020
*        GETMAIN FAILURE CAUSES RETURN CODE 16. SYNTAX DEFINITION       04060020
*        TABLE NOT ALREADY LOAD'ED BUT REQUESTED IN OPTLEVEL CAUSES RE- 04080020
*        TURN CODE 20. A NUMBER OF PROGRAM OR MACHINE ERRORS, SUCH AS   04100020
*        NO CARDS IN A BUFFER CHAIN, ARE DETECTED. THESE RESULT IN THE  04120020
*        MESSAGE 'SYSTEM OR SYNTAX CHECKER FAILURE' WITH RETURN CODE    04140020
*        4 OR 8.                                                        04160020
*                                                                       04180020
*NOTES.. IPDSNEXC DOES NOT PROVIDE A SAVE AREA FOR THE CONDITIONAL      04200020
*        GETMAIN.                                                       04220020
*        REFER TO 'IBM SYSTEM/360 OPERATING SYSTEM SUPERVISOR AND DATA  04240020
*        MANAGEMENT MACRO INSTRUCTIONS,' FORM C28-6647, FOR DEFINITIONS 04260020
*        OF THE SYSTEM MACROS.                                          04280020
*        THE OPERATION OF CONTROL SECTION IPDSNEXC DEPENDS ON THE       04300020
*        FOLLOWING PROPERTIES OF THE INTERNAL REPRESENTATION OF THE     04320020
*        EXTERNAL CHARACTER SET---                                      04340020
*                                                                       04360020
*            CHARACTER CODE DEPENDENCY         INSTR. SEQUENCE AFFECTED 04380020
*                                                                       04400020
*          1.DECIMAL NUMBERS MUST BE         1.EXCGES ROUTINE WHICH     04420020
*            CODED SO THAT THEIR COLLATING     CHECKS STATEMENT LABEL   04440020
*            SEQUENCE REMAINS ASCENDING        FIELD.                   04460020
*            FROM 0 TO 9 WITH NO OTHER                                  04480020
*            CHARACTERS INTERSPERSED.                                   04500020
*                                                                       04520020
*          2.THE LOADING OF MODULES          2.EXCLODTB TABLE --        04540020
*            REQUIRES THAT THE REPRE-          REASSEMBLE TO REDEFINE   04560020
*            SENTATION OF THE MODULE           INTERNAL REPRESENTATION  04580020
*            NAME IN THE LIBRARY AND           OF THE MODULE NAMES.     04600020
*            IN THE LOAD SEQUENCE BE                                    04620020
*            IDENTICAL.                                                 04640020
         EJECT                                                          04660020
IPDSNEXC CSECT                                                          04680020
*********************************************************************** 04700020
*                                                                       04720020
*        LENGTH OF CSECT                                                04740020
*                                                                       04760020
EXCLENGT   EQU 2496       MUST BE INTEGRAL MULT OF 8                    04780021
*                                                                       04800020
*                         THIS  EQU  DEFINES THE LENGTH OF THIS  CSECT. 04820020
*                         CSECT.  IF THE CODING OF THE  CSECT  IS       04840020
*                         EXPANDED TO A NUMBER OF BYTES LARGER THAN     04860020
*                         THAT SPECIFIED BY THIS  EQU  , THE  EQU       04880020
*                         MUST BE CHANGED TO SPECIFY A SIZE AT LEAST    04900020
*                         AS LARGE AS THE CODING.                       04920020
*                                                                       04940020
*********************************************************************** 04960020
*              REGISTER CONVENTIONS. R2 IS LINKAGE REGISTER. IT MUST    04980020
*              BE SAVED IN SUBROUTINES. R3 - RD                         05000020
*              ARE BASES OR CONTAIN GLOBAL VALUES. THEY MUST BE         05020020
*              SAVED, SET, OR UPDATED IN SUBROUTINES. RE - R1 ARE       05040020
*              LOCAL WORK REGS WHICH MAY BE DESTROYED IN SUBROUTINES.   05060020
R0       EQU   0                                                        05080020
R1       EQU   1                                                        05100020
R2       EQU   2                  LINKAGE REGISTER                      05120020
R3       EQU   3                                                        05140020
R4       EQU   4                                                        05160020
R5       EQU   5   INDEX TO WKATINU TABLE                               05180020
R6       EQU   6                  LOC OF COLUMN 1 OF A CARD             05200020
R7       EQU   7                                                        05220020
R8       EQU   8                                                        05240020
R9       EQU   9                  OPTION WORD DSECT REGISTER.           05260020
REGCOMMA EQU   10                 COMMUNICATIONS AREA DSECT REG.        05280020
REGPARAM EQU   11                 POINTER TO PARAMETERS PASSED.         05300020
RC       EQU   12                 INSTRUCTION BASE                      05320020
RD       EQU   13                 BASE FOR WORK AREA (IPDSNWKA)         05340020
RE       EQU   14                                                       05360020
RF       EQU   15                                                       05380020
*              CONDITION CODES                                          05400020
CC0      EQU   8                                                        05420020
CC1      EQU   4                                                        05440020
CC2      EQU   2                                                        05460020
CC3      EQU   1                                                        05480020
NC0      EQU   15-8                                                     05500020
NC1      EQU   15-4                                                     05520020
NC2      EQU   15-2                                                     05540020
NC3      EQU   15-1                                                     05560020
*        RETURN CODES SENT BY EXECUTIVE                                 05580020
RC0      EQU   0                  NO ERROR MSG.  REQUEST NEW BUFFER.    05600020
RC4      EQU   4                  ERROR MSG.  REQUEST NEW BUFFER.       05620020
RC8      EQU   8                  ERROR MSG.  CKR TO CONTINUE CHECKING  05640020
*                                      SAME BUFFER ON NEXT CALL.        05660020
RC12     EQU   12                 NO ERROR MSG.  REQUEST NEW BUFFER.    05680020
RC16     EQU   16                 CONDITIONAL GETMAIN FAILURE.          05700020
RC20     EQU   20                 TABLE REQUESTED NOT LOADED.           05720020
*        ERROR CODE SYMBOLS FOR IPDERERR                                05740020
ERSYSBUG EQU   0                  SYSTEM OR MACHINE ERROR               05760020
ERINVST  EQU   25                 STATEMENT EXPECTED                    05780020
ERMT1320 EQU   70                MORE THAN 1320 CHARACTERS              05800020
ERSTANO  EQU   84                 INVALID STATEMENT NO.                 05820020
ERFSTCON EQU   100                CONTINUATION ENCOUNTERED BEFORE ANY  C05840020
                                  STATEMENT IN BUFFER                   05860020
ERCOMNSG EQU   102                COMMENT CARD(S) INTERSPERSED         C05880020
                                  WITHIN CONTINUATION CARDS             05900020
ERMANYLN EQU   104                TOO MANY LINES IN STMNT               05920020
ERTMYDIG EQU   150               TOO MANY DIGITS IN STMT NUMBER (F-F)   05940020
ERSTNCIL EQU   152               STMT NO.NOT COMPLETE ON INITIAL LINE  C05960020
                                 (FREE-FORM)                            05980020
ERMISCNT EQU   154                LAST LINE IS CONTINUED LINE           06000020
ERCHIVPS EQU   156               INVALID CHAR.PRECEDES STATEMENT (F-F)  06020020
*              OTHER EQU'S                                              06040020
EXCZERO  EQU   C'0'                                                     06060020
EXCNINE  EQU   C'9'                                                     06080020
EXCAST   EQU   C'*'                                                REA  06090020
EXCBLANK EQU   C' '                                                     06100020
EXCOMMNT EQU   C'C'                                                     06120020
EXCQUOTE EQU   C'"'                                                     06140020
EXCFRCTN EQU   C'-'                                                     06160020
EXCDOLAR EQU   C'$'                                                     06180020
EXCLTRA  EQU   C'A'                                                     06200020
EXCLTRZ  EQU   C'Z'                                                     06220020
EXCFOLD  EQU   X'40'                                                    06240020
EXCNEGT  EQU   X'80'                                                    06260020
*                                                                       06280020
*        SYNTAX CHECKER FAILURE CODES ISSUED BY EXECUTIVE.  01-0F.      06300020
*        ISSUED IN CONJUNCTION WITH MSG 'SYSTEM OR SYNTAX CHECKER       06320020
*        FAILURE'.  IPDER ADDS 255 TO NUMBER (ONE OF BELOW) SET IN      06340020
*        WKASFAIL BY EXECUTIVE, THEN ABOVE MSG IS ISSUED WITH SPECIAL   06360020
*        NUMBER CODE GREATER THAN 255.                                  06380020
*                                                                       06400020
SYERBUF1 EQU   X'01'              NO RECORDS IN BUFFER CHAIN            06420020
SYERBUF2 EQU   X'02'              ST FORM-VAR LENGTH.  MEANINGLESS COMB 06440020
SYNGREG1 EQU   X'03'              ZERO LENGTH VARBL-LNGTH RECORD  F-F   06460020
SYERITF1 EQU   X'04'              ILLEGAL ENTRY AFTER RETURN CODE 8     06480020
SYERREG1 EQU   X'05'              MISHANDLING OF RELATIVE LINE NOS.     06500020
SYEROPT1 EQU   X'06'              ILLEGAL CHANGE OF OPTNS WRD BY SYSTEM 06520020
*                                                                       06540020
*                                                                       06560020
*                                                                       06580020
*                                                                       06600020
         USING *,15                                                     06620020
         B     IPDSNFEG           BR TO BEGINNING OF PROGRAM            06640020
         DC    CL8'IPDSNEXC'                                            06660020
         DROP  15                                                       06680020
IPDSNFEG STM   14,12,12(RD)       SAVE REGS IN CALLER SAVE AREA         06700020
         LR    RC,RF              RC = BASE FOR INSTRUCTIONS            06720020
         USING IPDSNEXC,RC                                              06740020
         LR    REGPARAM,1         REGPARAM, REG. FOR SYSTEM PARAMETERS. 06760020
         USING IPDSNSNP,REGPARAM                                        06780020
         L     REGCOMMA,SNPRMCOM  REGCOMMA, REG. FOR COMMUNICTN. AREA.  06800020
         USING IPDSNCOM,REGCOMMA                                        06820020
         L     R9,SNPRMOPT        R9 = REG FOR OPTIONS WORD             06840020
         USING IPDSNOPT,R9                                              06860020
         LR    R6,RD              SAVE RD IN CASE OF INITIAL ENTRY      06880020
         L     RD,COMENTRY        RD= LOC OF WORK AREA IF NOT           06900020
         LTR   RD,RD                   INITIAL ENTRY                    06920020
         BM    EXCNOTFS           BR IF NOT AN INITIAL ENTRY            06940020
*                                                                       06960020
*              INITIAL ENTRY. GET WORK AREA.                            06980020
         MVC   COMERRAD(12),GETM  MOVE GETMAIN LIST TO COMMUNICATIONS  C07000020
                                  AREA                                  07020020
         IC    RD,COMENTRY        SAVE FIRST BYTE OF COMMUNICATION AREA 07040020
         LA    R1,COMERRAD        R1= LOC OF GETMAIN LIST               07060020
*                                           GET STORAGE & PUT LOC OF    07080020
*                                           IT IN FRST WORD OF COM AREA 07100020
         GETMAIN A=(REGCOMMA),MF=(E,(1))                                07120020
         STC   RD,COMENTRY        RESTORE FRST BYTE OF COM AREA         07140020
         LTR   RF,RF              WAS STORAGE GOTTEN                    07160020
         LR    RD,R6              RESTORE SAVE AREA PTR IN CASE OF      07180020
*                                    GETMAIN FAILURE                    07200020
         LA    RF,RC16            BR TO RETURN WITH CODE 16 IF          07220020
         BNZ   EXCEXIT            NO.                                   07240020
         L     RD,COMENTRY        YES. RD=LOC OF WORK AREA              07260020
         USING IPDSNWKA,RD                                              07280020
         ST    RD,8(R6)           STORE FORWARD CHAIN IN CALLER'S AREA  07300020
         ST    R6,4(RD)           STORE BACK CHN IN OUR SAVE AREA       07320020
         MVC   WKADNAME,=CL8'IPDSNWKA'                                  07340020
         XC    WKASERTB,WKASERTB  INITIALIZE TRT TABLE TO ZEROES        07360020
         MVI   BLDLSWH,X'00'    INITIALIZE THE SWITCH FOR ISSUE BLDL    07370021
*                                                                       07380020
*                                                                       07400020
*                                                                       07420020
*                                                                       07440020
*              LOAD SYNTAX TABLES REQUESTED BY BITS IN OPTTABS          07460020
         SR    R6,R6              R6 IS INDEX TO EXCSYNXS TABLE         07480020
         LA    R5,EXCLODTB        R5 IS LOC OF CORRESPONDING ENTRY IN  C07500020
                                  EXCLODTB TABLE.                       07520020
EXCLODNG IC    R2,8(R5)           R2=EXCLODTB ENTRY CONTROL BYTE        07540020
         SR    R0,R0              R0=0 IN CASE THIS TABLE NOT NEEDED    07560020
         EX    R2,EXCLODTM        DOES A 1 BIT IN OPTTABS REQUEST THIS C07580020
                                  SYNTAX DEFINITION BE LOADED           07600020
         BZ    EXCLODST           BR IF NO.                             07620020
*                                 YES. LOAD THE ENTRY POINT WHOSE NAME  07640020
         LA    R0,1     WE LIST ONE ENTRY                               07641021
         STH   R0,FF                                                    07642021
         LA    R0,58    ENTRY IS 14 BYTES LONG                          07643021
         STH   R0,LL                                                    07644021
         MVC   NAME(8),0(R5)   MOVE IN NAME FIELD FOR BLDL              07645021
         XC    TTR(50),TTR                                              07646021
         BLDL  0,BLDLLIST                                               07647021
         LTR   RF,RF           CHECK FOR IPDTEE OR IPDAGH MISSING       07648021
         BZ    LOADTBL                                                  07649021
         MVI   BLDLSWH,X'01'   TABLE MISSING, SET SWITCH                07650021
         B     EXCFINAL        FOR BLDL ON                              07651021
LOADTBL  LOAD  DE=NAME                                                  07661021
EXCLODST ST    R0,EXCSYNXS(R6)    STORE LOC OR ZERO IN EXCSYNXS ENTRY.  07680020
         LA    R5,LDELT(R5)       R5= LOC OF NEXT EXCLODTB ENTRY        07700020
         LA    R6,4(R6)           INCR EXCSYNXS INDEX                   07720020
         CH    R6,=Y(NUMTBLS*4)   ANY MORE ENTRIES...                   07740020
         BL    EXCLODNG           BR IF YES.                            07760020
*                                                                       07780020
*                                 NO. INITIALIZATION DONE.              07800020
         L     R1,SNPRMBFR                                              07820020
         LTR   R1,R1              IS THERE A BUFFER CHAIN               07840020
         BZ    EXCRCO             BR IF NO TO REQUEST ONE WITH RC = 0.  07860020
         B     EXCNEB10           YES. GO TO PROCESS IT                 07880020
EXCLODTM TM    OPTTABS,0          THIS INSTR. IS 'EX'ECUTED             07900020
GETM     GETMAIN EC,LV=WKARLENT,SP=1,MF=L                               07920020
*                                                                       07940020
*                                                                       07960020
*                                                                       07980020
*                                                                       08000020
*        TABLE OF SYNTAX DEFINITION ENTRY NAMES. THE BYTE FOLLOWING     08020020
*        EACH NAME INDICATES WHICH BIT IN OPTTABS REQUESTS THE LOADING  08040020
*        OF THIS DEFINITION. ENTRIES ARE IN SAME ORDER AS EXCSYNXS TABL 08060020
EXCLODTB DC    C'IPDTEE  '        DEFINITION FOR LEVEL E                08080020
         DC    X'01'                                                    08100020
LDELT    EQU   *-EXCLODTB         LENGTH OF ENTRIES IN THIS TABLE       08120020
         DC    C'IPDAGH  '        DEF FOR LEVELS G, G1, H, AND TSO      08140020
         DC    X'02'                                                    08160020
NUMTBLS  EQU   (*-EXCLODTB)/LDELT NO. OF TABLE ENTRIES                  08180020
*        TABLE OF DISPLACEMENTS IN EXCSYNXS TABLE NEEDED BY EACH LEVEL  08200020
*        IN ORDER TO PICK UP ADDR OF ASSOCIATED SYNTAX DEFINITION.      08220020
*        ONE ENTRY IN EXCADRDF FOR EACH LEVEL OF FORTRAN RECOGNIZED BY  08240020
*        CHECKER.  ENTRIES ARE IN ORDER BY OPTLEVEL CODE ASSOCIATED     08260020
*        WITH EACH LEVEL.  THE TABLE EXCSYNXS EXISTS IN THE WORKAREA    08280020
*        AND CONTAINS ONE FULL WORD ENTRY FOR EACH SYNTAX DEFINITION    08300020
*        TABLE.                                                         08320020
*                                 DISPLACEMENT IN EXCSYNXS TABLE FOR    08340020
*                                 DEFINITION USED BY                    08360020
EXCADRDF DC    X'04'                   LEVEL H                          08380020
         DC    X'00'                         E                          08400020
         DC    X'04'                         G                          08420020
         DC    X'04'                         TSO                        08440020
         DC    X'04'                         G1                         08460020
*                                                                       08480020
*                                                                       08500020
*                                                                       08520020
*                                                                       08540020
*                                                                       08560020
*        FINAL ENTRY. DELETE TABLES & RELEASE WORK AREA.                08580020
EXCFINAL LA    R6,NUMTBLS         R6 = COUNT OF ENTRIES IN EXCLODTB     08600020
         LA    R5,EXCLODTB        R5= LOC OF NAME OF ENTRY PNT OF      C08620020
                                  SYNTAX TABLE                          08640020
EXCFIN5  DELETE EPLOC=(R5)        DELETE IT                             08660020
         LA    R5,LDELT(R5)       INCR R5 TO NEXT EXCLODTB ENTRY        08680020
         BCT   R6,EXCFIN5         BR IF THERE IS ANOTHER ENTRY          08700020
*              RELEASE WORK AREA.                                       08720020
         SR    R6,R6                                                    08726021
         IC    R6,BLDLSWH                                               08732021
         LA    R1,0(RD)           R1= LOC OF STORAGE TO RELEASE         08740020
         L     RD,4(RD)           SAVE LOC OF CALLERS SAVE AREA.        08760020
         FREEMAIN R,A=(1),SP=1,LV=WKARLENT                              08780020
         LTR   R6,R6                                                    08784021
         BZ    EXCEXIT               RETURN                             08788021
         LA    RF,RC20          TABLE MISSING SET RETURN CODE=20        08792021
         B     EXCEXIT                                                  08796021
         EJECT                                                          08820020
*              NOT INITIAL ENTRY                                        08840020
EXCNOTFS ST    RD,8(R6)           STORE FRWRD CHAIN IN CLLER SAVE AREA  08860020
         ST    R6,4(RD)           STORE BACK CHAIN IN OURS.             08880020
         LM    R2,R8,28+EXCSVRGS RESTORE REGS 2-8 FROM LAST TIME        08900020
         TM    COMENTRY,COMFNTRY  TEST FOR FINAL CALL                   08920020
         BO    EXCFINAL           BR IF FINAL CALL.                     08940020
         TM    COMENTRY,COMAFRC8  HAS BUFFER BEEN COMPLETELY CHECKED    08960020
         BCR   CC3,R2             NO. BR TO CONTINUE                   C08980020
                                  FROM WHERE LEFT OFF LAST TIME         09000020
*                                                                       09020020
*                                                                       09040020
*                                                                       09060020
*                                                                       09080020
*        INTERMEDIATE ENTRY. NEW BUFFER.                                09100020
         L     R1,SNPRMBFR        IS THERE A BUFFER OR                  09120020
EXCNEB5  LTR   R1,R1              ARE THERE ANY RCDS IN WHOLE BUF CHN   09140020
         BNZ   EXCNEB10           BR IF THERE IS AN ADDR                09160020
         TM    COMENTRY,COMARC12  IS THIS AN ENTRY AFTER RC12           09180020
         BNO   EXCNEB6            BR IF NO                              09200020
         XC    EXCCRBUF(4),EXCCRBUF    SET EXCCRBUF = 0                 09220020
         TM    OPTBYTE3,EXCFRFRM                                        09240020
         BNO   EXCGES             ST.-FRM.  BR TO STMNT LBL CHECK       09260020
         BAL   R2,EXCALMR         OUTPUT MSG INDICATING STMNT IS NOT    09280020
         DC    Y(RC8*256+ERMISCNT)     COMPLETE WITH RETURN CODE = 8    09300020
         B     EXCGES             BR TO SYNTAX CHECK INCOMPLETE STMNT   09320020
EXCNEB6  MVI   WKASFAIL,SYERBUF1  SET UP WKASFAIL WITH FAIL CODE        09340020
         BAL   R2,EXCALMS         BR TO ISSUE MSG                       09360020
         DC    Y(RC4*256)              WITH RETURN CODE = 4             09380020
*                                YES. DO NEW BUFFER INITIALIZATION.     09400020
EXCNEB10 CLI   0(R1),0            ANY RECORDS IN THIS BUFFER            09420020
         BNE   EXCNEB12           BR IF YES                             09440020
EXCNEB11 MVC   EXCNXBUF,0(R1)     NO.  GET LOC OF NEXT BUFFER           09460020
         OI     0(R1),EXCRLSBF    SET BIT TO ALLOW BUFFER RELEASE       09480020
         L     R1,EXCNXBUF                                              09500020
         B     EXCNEB5           BR TO CHECK NEXT BUFFER IN CHAIN       09520020
*                                                                       09540020
*                                                                       09560020
EXCNEB12 TM    0(R1),X'80'        IS HIGH ORDER BIT ON                  09580020
         BNO   EXCNEB15           NO.  CONTINUE PROCESSING              09600020
         NI    0(R1),X'00'        YES.  SET BIT OFF                     09620020
         B    EXCNEB11            GET LOC OF NEXT BUFFER                09640020
*                                                                       09660020
*                                                                       09680020
EXCNEB15 LA    R0,4(R1)           STORE LOC OF COL 1 OF 1ST RECORD AND  09700020
         STM   R0,R1,EXCNXCRD     LOC OF BUFFER CONTAINING IT           09720020
         SR    RF,RF                                                    09740020
         TM    COMENTRY,COMARC12  IS THIS AN ENTRY AFTER RC12           09760020
         BNO   EXCNEB17           BR IF NO                              09780020
*********************************************************************** 09800020
*     THE FOLLOWING SECTION OF CODE CHECKS THE INTEGRITY OF THE OPTIONS 09820020
*     WORD.  R3 SHOULD CONTAIN A BR ADDR IF FREE-FORM SOURCE OPTION WAS 09840020
*     SPECIFIED AT INITIAL ENTRY.  R3 SHOULD CONTAIN ZERO IF            09860020
*     STANDARD-FORM WAS IN EFFECT.                                      09880020
*********************************************************************** 09900020
         TM    OPTBYTE3,EXCFRFRM                                        09920020
         BNO   EXCNEB16           BR IF STANDARD-FORM                   09940020
         LTR   R3,R3              DOES R3 CONTAIN A BR ADDR             09960020
         BNZ   EXCNEB16           YES.  CONTINUE PROCESSING.            09980020
         MVI   WKASFAIL,SYEROPT1  MOVE FAIL CODE INTO WKASFAIL          10000020
         BAL   R2,EXCALMS         SEND 'SYSTEM OR SYNTAX CHECKER        10020020
         DC    Y(RC4*256)         FAILURE' MSG WITH RETURN CODE = 4     10040020
EXCNEB16 EQU   *                                                        10060020
*********************************************************************** 10080020
         STH   RF,EXCNXBRL        INITIALIZE RECORDS RELATIVE POSITION  10100020
*                                      WITHIN BUFFER TO ZERO            10120020
         B     EXCNNB30           BR TO CONTINUE PROCESSING             10140020
EXCNEB17 ST    RF,EXCNXBRL        INITIALIZE RECORDS RELATIVE POSITION  10160020
*                                      WITHIN BUFFER CHAIN AND          10180020
*                                      WITHIN BUFFER TO ZERO            10200020
*********************************************************************** 10220020
*     IF ST. FORM-VAR. LENGTH IN EFFECT, ISSUE MSG WITH RC4.            10240020
*********************************************************************** 10260020
         TM    OPTBYTE3,EXCFRFRM  IS SOURCE STANDARD FORM               10280020
         BO    EXCNEB18           BR IF NO                              10300020
         TM    OPTBYTE3,EXCVRLNG  ARE VARIABLE LENGTH RECORDS USED      10320020
         BNO   EXCNEB18           BR IF NO                              10340020
         MVI   WKASFAIL,SYERBUF2  SET UP WKASFAIL WITH FAIL CODE        10360020
         BAL   R2,EXCALMS         BR TO ISSUE                           10380020
         DC    Y(RC4*256)              MESSAGE WITH RETURN CODE = 4     10400020
*              IS TABLE REQUESTED IN OPTIONS WORD PRESENT               10420020
EXCNEB18 IC    RF,OPTLEVEL        RF INDICATES WHICH LANGUAGE           10440020
         STC   RF,WKALEVEL       DEFINITION TO USE, SAVE LEVEL          10460020
         IC    RF,EXCADRDF(RF)    DISPLACEMENT TO EXCSYNXS TBL ENTRY    10480020
         L     RF,EXCSYNXS(RF)    DEFINITION ADDR OR ZERO               10500020
         LTR   R0,RF             IS TABLE PRESENT                       10520020
         LA    RF,RC20                                                  10540020
         BZ    &EXCALMT          RETURN WITH CODE 20 IF NOT             10560020
         ST    R0,WKADEEF        YES. SAVE LOC OF TABLE IN PARAM        10580020
*                                LIST FOR IPDSNCKR                      10600020
         BAL   R2,EXCNESIT       DO NEW STATEMENT INITIALIZATION        10620020
         EJECT                                                          10640020
*        SKIP OVER COMMENT & CONTINUATION RECORDS TIL FIRST RECORD OF   10660020
*        A STATEMENT IS FOUND.                                          10680020
EXCNEB30 BAL   R2,EXCGETRC       GET A RECORD                           10700020
         BZ    EXCRCO             BR IF NO MORE TO RETURN WITH CODE = 0 10720020
         TM    OPTBYTE3,EXCFRFRM                                        10740020
         BO    EXCNEB35           BR IF FREE-FORM SOURCE                10760020
*                                                                       10780020
*        STANDARD-FORM SOURCE.  CHECK FOR COMMENT AND                   10800020
*        FOR CONTINUATION LINES.                                        10820020
         CLI   0(R6),EXCOMMNT    IS THIS A COMMENT LINE                 10840020
         BE    EXCNEB30           BR IF YES TO GET NEXT RECORD          10860020
*                            IS THIS A CONTINUATION LINE                10880020
         CLI   5(R6),EXCBLANK                                           10900020
         BE    EXCNNB            IF COL. 6 IS BLANK,  NO CONTINUATION   10920020
         CLI   5(R6),EXCZERO                                            10940020
         BE    EXCNNB            IF COL. 6 IS ZERO, NO CONTINUATION     10960020
*                            YES.  THIS IS A CONTINUATION RECORD        10980020
         TS    EXCFSCON          IS IT THE FIRST                        11000020
         BC    CC1,EXCNEB30       BR IF NO.                             11020020
         NC    EXCNXBUF,EXCNXBUF YES. IS THERE ANOTHER RECORD           11040020
         LA    R2,=Y(RC4*256+ERFSTCON) IF NOT, SEND MSG WITH CODE=4     11060020
         BC    CC0,EXCALMR        BR TO ISSUE MSG WITH RC = 4           11080020
         BAL   R2,EXCALMR        IF YES, BR TO OUTPUT                   11100020
         DC    Y(RC8*256+ERFSTCON)     MSG WITH RC = 8                  11120020
         B     EXCNEB30          AND GET THE NEXT RECORD.               11140020
*                                                                       11160020
*        FREE-FORM SOURCE.  CHECK FOR COMMENT LINES.  CONTINUATION      11180020
*        LINES CANNOT BE IDENTIFIED.                                    11200020
EXCNEB35 EQU   *                                                        11220020
         LR    R1,R6              R1 = LOC OF 1ST COL OF TEXT           11240020
         LR    R4,R6              R1 = LOC OF 1ST COL OF TEXT           11260020
         AR    R4,R8              R4 = ADDR OF LAST BYTE OF LINE        11280020
EXCNEB36 CLI   0(R1),EXCBLANK     IS CHAR A BLANK                       11300020
         BNE   EXCNEB38           BR IF NO                              11320020
EXCNEB37 CR    R1,R4              IS THIS THE LAST BYTE OF TEXT         11340020
         BE    EXCNEB39           BR IF YES                             11360020
         LA    R1,1(R1)           POINT TO NEXT COL                     11380020
         B     EXCNEB36           BR TO SEE IF CHAR A BLANK             11400020
EXCNEB38 CLI   0(R1),EXCQUOTE     IS THIS A COMMENT LINE                11420020
         BE    EXCNEB30           BR IF YES TO GET NEXT RECORD          11440020
         CLI   0(R1),EXCAST            ALTERNATE COMMENT           REA  11446020
         BE    EXCNEB30                YES - GET NEXT RECORD       REA  11452020
EXCNEB39 EQU   *                                                        11460020
         MVI   WKACNCOL,C' '     INITIALIZE CONTINUATION SWITCH         11480020
*                                                                       11500020
         LA    R3,EXCNNB06        INITIALIZE R3 WITH BR ADDR            11520020
*                                     FOR LOOP CONTROL.                 11540020
*                                                                       11560020
*                                                                       11580020
*                                                                       11600020
*                                                                       11620020
*        FIRST RECORD OF A STATEMENT HAS BEEN EXCGETRC'ED.              11640020
EXCNNB   BAL   R2,EXCNESIT       DO STATEMENT INITIALIZATION            11660020
         MVC   EXCFSCRD(INF),EXCCRCRD SAVE LOC OF FIRST RECORD          11680020
         LA    R7,WKACHRST        INITIALIZE R7 SO THAT IT WILL POINT   11700020
*                                      TO LAST CHAR MOVED + 1           11720020
         TM    OPTBYTE3,EXCFRFRM  IS THIS FREE-FORM SOURCE              11740020
         BO    EXCNNB06           BR IF FREE-FORM                       11760020
*                                 NO.  THIS IS STANDARD-FORM SOURCE.    11780020
         MVC   WKACHRST(5),0(R6)       PUT LABEL FIELD IN CHAR STRING   11800020
         LA    R7,5(0,R7)         END OF STRING POINTS TO LAST          11820020
*                                      POSITION OF LABEL FIELD + 1      11840020
         B     EXCNNB10           BR TO PROCESS STANDARD-FORM SOURCE    11860020
*        COLLECT LINES OF STATEMENT.                                    11880020
*        STANDARD FORM.  SAVE CONTENTS OF COLUMN 6.                     11900020
*                        CHECK FOR EMBEDDED COMMENTS.                   11920020
*        FREE-FORM.  CHECK FOR CONTINUATION INDICATOR.                  11940020
*                    AFTER STATEMENT IS COMPLETE, GET LINE OF NEXT      11960020
*                    STATEMENT.                                         11980020
EXCNNB06 LR    R4,R6              R6 = LOC OF 1ST COL. OF TEXT          12000020
         AR    R4,R8              R4 = ADDR. OF LAST BYTE OF LINE       12020020
*                                                                       12040020
*        FREE-FORM SOURCE.  CHECK FOR CONTINUATION INDICATOR.           12060020
*        LAST HYPHEN OF LINE IS CONTINUATION SYMBOL.                    12080020
EXCNNB07 CLI   0(R4),EXCBLANK     IS CHAR A BLANK                       12100020
         BNE   EXCNNB08           NO.  BR IF FOUND NONBLANK             12120020
         SH    R8,EXCH1           ADJUST LENGTH                         12140020
         CR    R4,R6              YES.  IS IT IN COL 1                  12160020
         BE    EXCNNB08           BR IF YES                             12180020
         BCT   R4,EXCNNB07        GO SEE IF PRECEDDING CHAR A BLANK     12200020
EXCNNB08 EQU   *                                                        12220020
         CLI   0(R4),EXCFRCTN     IS CONTINUATION SYMBOL PRESENT        12240020
         BNE   EXCNNB15           NO.  BR TO PREPARE FOR CHECKER CALL   12260020
         MVI   WKACNCOL,EXCFRCTN  SET CONTINUATION SWITCH               12280020
         SH    R8,EXCH1           ADJUST LENGTH                         12300020
         SH    R4,EXCH1          ADJUST LOC OF LAST BYTE OF TEXT        12320020
         B     EXCNNB20           BR TO UPDATE WKATINU TBL              12340020
*                                                                       12360020
*        STANDARD-FORM SOURCE.  SAVE CONTENTS OF COLUMN 6 FOR LATER     12380020
*        USE BY CHECKER.                                                12400020
EXCNNB10 MVC   WKACNCOL(1),5(R6) SAVE CONTENTS OF CONTINATION COL.      12420020
*                                     FOR USE BY CHECKER, $300.         12440020
         LA    R6,6(0,R6)         R6 = PNTR TO COL. 7 OF FORTRAN        12460020
*                                      SOURCE LINE                      12480020
         SH    R8,EXCH6           R8 = LENGTH-1 OF LINE (WITHOUT        12500020
*                                      LABEL FIELD OR CONTINUATION      12520020
*                                      COLUMN)                          12540020
         B     EXCNNB20           BR TO UPDATE WKATINU TBL              12560020
*        FREE-FORM SOURCE.  LAST LINE OF STATEMENT REACHED.  MUST       12580020
*        READ IN ONE MORE CARD IN PREPARATION FOR NEXT CALL             12600020
EXCNNB15 LA    R3,EXCGES          BR REG. CONTAINS EXIT ADDR            12620020
*                                                                       12640020
*********UPDATE WKATINU TBL******************************************** 12660020
*        STORE DISPLACEMENT.  STORE DATA SET OR RELATIVE LINE NUMBER.   12680020
*        ISSUE ERROR MESSAGES FOR LINE TOO LONG OR TOO MANY LINES       12700020
*        IN STATEMENT.                                                  12720020
EXCNNB20 CH    R5,EXCH200         IS THIS ENTRY PAST END OF TBL         12740020
         BL    EXCNNB22           NO.  CONTINUE CHECKING                12760020
         TS    EXCEXSLN           WERE THERE EXTRA STMNT LINES BEFORE   12780020
         BC    CC1,EXCNNB30       YES.  FLUSH LINE.  GET NEXT RECORD.   12800020
         BAL   R2,EXCALMR         SEND TOO MANY STMNT LINES MSG         12820020
         DC    Y(RC8*256+ERMANYLN)     WITH RETURN CODE = 8             12840020
         B     EXCNNB30           GET THE NEXT RECORD                   12860020
EXCNNB22 LTR   R8,R8              IS THIS A ZERO LENGTH LINE            12880020
         BM    EXCNNB24           YES.  UPDATE WKATINU TABLE            12900020
         LR    R1,R8              R1 = LENGTH - 1                       12920020
         AH    R1,WKATINU(R5)     R1 = DISPL-1 OF LAST CHAR OF          12940020
*                                      LINE FROM BEGNG OF CHAR STRING   12960020
         CH    R1,EXCH1325        WILL IT GO PAST END OF CHAR STRING    12980020
         BL    EXCNNB23           NO.  CONTINUE PROCESSING              13000020
         TS    EXCEXSLN           WERE THERE EXTRA STMNT LINES BEFORE   13020020
         BC    CC1,EXCNNB30       YES.  FLUSH LINE.  GET NEXT RECORD    13040020
         SH    R1,EXCH1325        SET UP LENGTH-1 FOR                   13060020
         BCTR  R1,0                    PARTIAL MOVE                     13080020
         SR    R8,R1              R8 = ENOUGH CHARS TO FILL UP          13100020
*                                      CHAR STRING - 1                  13120020
         BAL   R2,EXCALMF         SEND LINE TOO LONG MSG                13140020
         DC    Y(RC8*256+ERMT1320)     WITH RETURN CODE = 8             13160020
         B     EXCNNB30           GET THE NEXT RECORD                   13180020
EXCNNB23 EX    R8,EXCEXMOV        EXECUTE MOVE CHARACTER STRING    REA  13200020
EXCNNB24 LNR   R4,RC              R4 WILL REMAIN NEGATIVE IF DATA SET   13220020
*                                 LINE NOS. ARE USED               REA  13240020
         LA    R8,1(0,R8)         R8=LENGTH                        REA  13260020
         LA    R7,0(R7,R8)        UPDATE PNTR TO CHAR STRING            13280020
         TM    OPTBYTE3,EXCNLNUM  ARE THERE LINE NUMBERS                13300020
         BNO   EXCNNB25           BR IF YES                             13320020
         LH    R4,EXCCRREL        R4 = RELATIVE LINE NUMBER             13340020
         B     EXCNNB27           UPDATE WKATINU TABLE                  13360020
EXCEXMOV MVC   0(0,R7),0(R6)                                            13380020
EXCNNB25 TM    OPTBYTE3,EXCFRFRM  IS SOURCE FREE-FORM                   13400020
         BO    EXCNNB26           YES.                                  13420020
*                                 SOURCE IS STANDARD FORM.              13440020
         SH    R6,EXCH6           R6 = PNTR TO COL. 1 OF FORTRAN TEXT   13460020
EXCNNB26 BAL   RF,EXCLNRTN        GET DATA SET LINE NUMBER              13480020
EXCNNB27 AH    R8,WKATINU(R5)     STORE DISPL FROM BEGNG OF CHAR STRING 13500020
         STH   R8,WKATINU(R5)     IN WKATINU TBL                        13520020
         LA    RF,WKATINU(R5)     RF = ADDR OF DISPL IN WKATINU TBL     13540020
         LH    R0,WKATINU(R5)     R0 = DISPL                            13560020
         STH   R0,10(RF)          PUT CURNT DISPL INTO NEXT DISPL SLOT  13580020
         LA    R5,2(R5)           R5 POINTS TO LINE NO. SLOT IN         13600020
*                                      WKATINU TBL                      13620020
         LTR   R4,R4              IS THIS A DATA SET LINE NUMBER        13640020
         BM    EXCDSLN            BR IF YES                             13660020
         STH   R4,WKATINU(R5)     NO.  THEN PUT RELATIVE LINE           13680020
*                                      NUMBER IN TBL                    13700020
         B     EXCNNB29           BR TO UPDATE TABLE INDEX              13720020
EXCDSLN  LA    RF,WKATINU(R5)     RF=ADDR OF WKATINU TABLE              13740020
*                                      PLUS DISPLACEMENT                13760020
         MVC   0(8,RF),WKAERNUM   MOVE DATA SET LINE NO. TO             13780020
*                                      WKATINU TBL                      13800020
EXCNNB29 LA    R5,8(R5)           UPDATE TBL INDEX TO NEXT ENTRY        13820020
*                                                                       13840020
*        GET NEXT RECORD                                                13860020
*                                                                       13880020
EXCNNB30 BAL   R2,EXCGETRC       GET NEXT RECORD.                       13900020
         BZ    EXCNNB60           BR IF NO MORE RECORDS IN CHAIN        13920020
         TM    OPTBYTE3,EXCFRFRM  IS SOURCE FREE-FORM                   13940020
         BCR   CC3,R3             YES. USE BRANCH REGISTER ADDRESS      13960020
*                                                                       13980020
*        STANDARD FORM.  CHECK FOR EMBEDDED COMMENT LINES.              14000020
*                                                                       14020020
         CLI   0(R6),EXCOMMNT    IS THIS A COMMENT LINE                 14040020
         BNE   EXCNNB40           NO. BR TO CHK FOR CONTINUATION        14060020
         TS    EXCFSCOM          YES. FIRST SINCE THE BEGINNING OF THIS 14080020
         BC    CC1,EXCNNB30       STMNT...  BR IF NO.                   14100020
         MVC   EXCSVCRD(INF),EXCCRCRD YES, SAVE ITS LOC IN CASE OF ERR  14120020
         BAL    RF,EXCLNRTN       GET DATA SET LINE NUMBER              14140020
         MVC   EXCSVLNN,WKAERNUM  SAVE DATA SET LINE NUMBER             14160020
         B     EXCNNB30           GET NEXT RECORD                       14180020
EXCNNB40 CLI   5(R6),EXCBLANK     BR TO STMNT LABEL ROUTINE             14200020
         BE    EXCGES                  IF NOT CONTINUATION LINE.        14220020
         CLI   5(R6),EXCZERO           ZERO OR BLANK IN COL. 6          14240020
         BE    EXCGES                  INDICATES NO CONTINUATION        14260020
*              GOT ANOTHER CONTINUATION LINE.  HAS A COMMENT LINE BEEN  14280020
         CLC   EXCFSCOM,EXCOMSG  ENCOUNTERED AND NO MESSAGE SENT.       14300020
         BE    EXCNNB10           BR IF NOT THE CASE.                   14320020
         MVI   EXCOMSG,255       YES. SET COMMENT MSG SENT SWTCH ON     14340020
         BAL   R2,EXCALMP        SEND MSG RE COMMENT LINE INTERSPERSED  14360020
         DC    Y(RC8*256+ERCOMNSG) AMONG CONTINUATIONS WITH RC = 8      14380020
         B     EXCNNB10           CONTINUE PROCESSING                   14400020
EXCNNB60 TM    OPTBYTE3,EXCFRFRM                                        14420020
         BO    EXCNNB62           BR IF FREE-FORM                       14440020
         TM    OPTBYTE3,EXCBFSPN  IS RETURN CODE 12 ALLOWED             14460020
         BNO   EXCGES             BR IF NO                              14480020
         SR    R3,R3              IF ST-FORM, R3 SET TO ZERO.  AID IN   14500020
*                                      CHECKING INTEGRITY OF OPTNS WRD  14520020
EXCNNB61 LA    RF,RC12            R15 CONTAINS RC12                     14540020
         B     EXCALMT            BR TO ISSUE RETURN CODE 12            14560020
EXCNNB62 C     R3,=A(EXCGES)      IF FR-FRM STMNT COMPLETE,R3=A(EXCGES) 14580020
         BCR   CC0,R3             BR IF STMNT COMPLETE                  14600020
         TM    OPTBYTE3,EXCBFSPN  IS RETURN CODE 12 ALLOWED             14620020
         BO    EXCNNB61           BR IF YES                             14640020
         BAL   R2,EXCALMR         OUTPUT MSG INDICATING STMNT IS NOT    14660020
         DC    Y(RC8*256+ERMISCNT)     COMPLETE WITH RETURN CODE = 8    14680020
         B     EXCGES             BR TO SYNTAX CHECK INCOMPLETE STMNT   14700020
*                                                                       14720020
*        ALL LINES OF STATEMENT HAVE BEEN GATHERED.  WKATINU TABLE      14740020
*        IS COMPLETE.  CHECK FOR ERRORS IN STMNT LABEL.                 14760020
*                                                                       14780020
EXCGES   MVC   EXCSVCRD(INF),EXCCRCRD SAVE LOC OF FRST RECORD OF NEXT   14800020
*                                     STATEMENT                         14820020
         LA    RF,WKATINU(R5)     RF=ADDR OF WKATINU TABLE              14840020
*                                      PLUS DISPLACEMENT                14860020
         OI    0(RF),X'80'        STORE NEGATIVE VALUE AT END OF        14880020
*                                      WKATINU TBL                      14900020
*        INITIALIZE FOR STMNT LABEL CHECK                               14920020
         LA    R1,WKACHRST        R1 CONTAINS BEGNG ADDR OF CHAR STRING 14940020
         BCTR  R7,0               STORE ADDR OF LAST CHAR IN            14960020
         ST    R7,WKAENDST         CHAR STRING IN WKAENDST              14980020
         LA    RE,1              INCREMENT VALUE FOR LOOP CONTROL       15000020
         SR    R6,R6              R6 = COUNT OF NO. OF DIGITS IN LBL    15020020
         TM    OPTBYTE3,EXCFRFRM                                        15040020
         BO    EXCGES02           BR IF FREE-FORM TO COMPLETE INITLZTN  15060020
         LA    R0,WKACHRST+5      ADDR TO BEGIN PROCESSING WITH         15080020
*                                      (BEGNG OF CHAR STRING)           15100020
         ST    R0,WKABEGST        INITIALIZE WKABEGST TO THE BEGNG      15120020
*                                      OF THE CHAR STRING               15140020
         LA    RF,WKACHRST+4      ST. FORM. RF=COMPARAND FOR LOOP CNTRL 15160020
*                                 RF = ADDR OF COL. 5 OF INITIAL LINE   15180020
         B     EXCGES05           BR TO CHK LBL                         15200020
*                                      FOR FREE-FORM ONLY               15220020
EXCGES02 CR    R7,R1              IS THIS A ZERO LENGTH STMNT           15240020
         BL    EXCGES66           YES.  PUT OUT MSG.                    15260020
         L     RF,WKAENDST        RF = COMPARAND FOR LOOP CONTROL       15280020
*                                    = ADDR OF END OF CHAR STRING       15300020
*                                                                       15320020
*        STATEMENT LABEL CHECK                                          15340020
*                                                                       15360020
EXCGES05 CLI   0(R1),EXCBLANK    IS CHARACTER SCANNED A BLANK           15380020
         BE    EXCGES20           YES.  BR TO CONTINUE                  15400020
**********************CHARACTER DEPENDENT CODE FOLLOWS***************** 15420020
         CLI   0(R1),EXCZERO     IS CHARACTER A ZERO                    15440020
         BE    EXCGES18           YES.  BR TO SET SWITCH.               15460020
         BH    EXCGES10           NO.  BR IF HIGH TO CHK FOR DIGIT      15480020
**********************END OF CHARACTER DEPENDENT CODE****************** 15500020
*                                                                       15520020
         TM    OPTBYTE3,EXCFRFRM  IF STANDARD-FORM, STMNT LABEL ERROR   15540020
         BNO   EXCGES22           HAS BEEN FOUND.  BR TO ISSUE ERR MSG  15560020
*                                                                       15580020
         CLI   0(R1),EXCDOLAR     FREE-FORM. CHK FOR $ AS ALPHABETIC    15600020
         BE    EXCGES08           BR IF $ FOUND                         15620020
**********************CHARACTER DEPENDENT CODE FOLLOWS***************** 15640020
         MVC   EXCFCHAR,0(R1)     FOLD ANY LOWER CASE ALPHABETIC        15660020
         OI    EXCFCHAR,EXCFOLD   TO UPPER CASE                         15680020
         CLI   EXCFCHAR,EXCLTRA   IF CHARACTER IS BELOW A IN COLLATING  15700020
         BL    EXCGES15           SEQUENCE, BRANCH.                     15720020
         CLI   EXCFCHAR,EXCLTRZ   IF CHAR IS ABOVE Z IN COLLATING       15740020
         BH    EXCGES15           SEQUENCE, BR.                         15760020
**********************END OF CHARACTER DEPENDENT CODE****************** 15780020
*                                                                       15800020
*        FIRST CHAR OF STMNT PORTION (FREE-FORM) HAS BEEN FOUND         15820020
EXCGES08 ST    R1,WKABEGST        STORE START ADDR NEEDED BY CHECKER    15840020
         B     EXCGES25           BR TO CHK FOR ANY ERRORS DETECTED     15860020
*                                      IN STMNT LBL                     15880020
*        CHECK FOR DIGIT OF STMNT LABEL                                 15900020
**********************CHARACTER DEPENDENT CODE FOLLOWS***************** 15920020
EXCGES10 CLI   0(R1),EXCNINE      CHK IF CHAR IS GT 9 IN COLLATING      15940020
         BH    EXCGES15           SEQUENCE.  BR IF YES.                 15960020
**********************END OF CHARACTER DEPENDENT CODE****************** 15980020
         OI    EXCSLERR,EXCDGLBL  SET BIT INDICATING LBL CONTAINS DIGIT 16000020
         TM    OPTBYTE3,EXCFRFRM                                        16020020
         BNO   EXCGES20           BR IF STANDARD-FORM TO CONT SCAN      16040020
*                                     ON INITIAL LINE                   16060020
EXCGES12 TM    EXCSLERR,EXCSLER2+EXCEXTCH TEST INVAL STMNT AND EXTRAN.  16080020
*                                 CHARS SWITCHS                         16100020
         BC    CC0+CC3,EXCGES19   BR IF BOTH ZERO OR BOTH ONE           16120020
         OI    EXCSLERR,EXCSLER2  SET INVAL STMNT SW BECAUSE EXTRANEOUS 16140020
         B     EXCGES19                SWITCH WAS ALREADY SET           16160020
*                                                                       16180020
*        EXTRANEOUS CHARACTER FOUND                                     16200020
EXCGES15 TM    EXCSLERR,EXCEXTCH  TEST IF SW HAS ALREADY BEEN SET       16220020
         BO    EXCGES20           BR IF YES TO CONTINUE SCAN            16240020
         ST    R1,WKAERRSC       STORE POINTER TO CHARACTER IN ERROR    16260020
         OI    EXCSLERR,EXCEXTCH  INDICATE EXTRANEOUS CHAR FOUND        16280020
         B     EXCGES20           BR TO CONTINUE SCAN                   16300020
*                                                                       16320020
*        ZERO  FOUND IN STMNT LABEL                                     16340020
EXCGES18 TM    EXCSLERR,EXCSLZRO  HAS ZERO ALREADY BEEN FOUND           16360020
         BO    EXCGES19           YES. BR.                              16380020
         ST    R1,WKATERSC        ST SOURCE POINTER IN CASE 0 STMNT LBL 16400020
         OI    EXCSLERR,EXCSLZRO  SET ZERO FOUND SWITCH                 16420020
EXCGES19 LA    R6,1(R6)           INCR DIGIT CNT                        16440020
         ST    R1,EXCSVLBL        SAVE LOC OF LAST LABEL DIGIT          16460020
EXCGES20 BXLE  R1,RE,EXCGES05     UPDATE SOURCE PT. BR TO CONT SCAN     16480020
*                                                                       16500020
*********IF STANDARD FORM, END OF LABEL FIELD REACHED.***************** 16520020
*********FREE-FORM.  END OF CHAR STR REACHED BUT NO STMNT FOUND.        16540020
         OI    EXCSLERR,EXCSLER1  SET SW FOR STMNT FIELD MISSING        16560020
         B     EXCGES25           BR TO CHECK FOR DETECTED ERRORS       16580020
*                                                                       16600020
*        NON-DIGIT FOUND IN STMNT LABEL OF STANDARD-FORM SOURCE         16620020
*        OR ZERO LABEL FOUND IN STANDARD-FORM SOURCE                    16640020
EXCGES22 LA    R1,WKACHRST        R1 = BEGNG ADDR OF CHAR STRING        16660020
         ST    R1,WKAERRSC        WKAERRSC = BEGNG ADDR OF CHAR STRING  16680020
         BAL   R2,EXCALMYA        BR TO ISSUE MSG                       16700020
         DC    Y(RC8*256+ERSTANO)      WITH RETURN CODE = 8             16720020
         B     EXCGES29           BR TO TURN ON SW                      16740020
*                                                                       16760020
*        ISSUE MSGS RELATED TO STATEMENT LABEL ERRORS FOUND.            16780020
*        DEPENDS UPON SETTING OF EXCSLERR.                              16800020
*                                                                       16820020
EXCGES25 TM    EXCSLERR,EXCDGLBL  HAS A DIGIT 1-9 BEEN FOUND            16840020
         BO    EXCGES30           YES. STMNT LBL PRESENT.  BR.          16860020
         TM    EXCSLERR,EXCSLZRO  HAS A ZERO BEEN FOUND.                16880020
         BNO   EXCGES60           NO. NO STMNT LBL FOUND. BR.           16900020
         TM    OPTBYTE3,EXCFRFRM  IF STANDARD-FORM                      16920020
         BNO   EXCGES22           BR TO ISSUE MSG                       16940020
         MVC   WKAERRSC,WKATERSC  MOVE ADDR OF ERR CHARS AND TEXT       16960020
EXCGES28 BAL   R2,EXCALMQ         BR TO OUTPUT MSG 'INVALID ST.NO.'     16980020
         DC    Y(RC8*256+ERSTANO)      WITH RETURN CODE = 8             17000020
EXCGES29 OI    EXCSLERR,EXCLBMSG  TURN ON SW INDICATING MSG ALREADY     17020020
*                                 SENT FOR ZERO AS INVAL STMNT LBL      17040020
EXCGES30 MVI   WKASNOSW,1         SET STMNT LBL SWITCH FOR CHECKER      17060020
         TM    OPTBYTE3,EXCFRFRM  IF STANDARD-FORM,                     17080020
         BNO   EXCLCR             BR TO CALL CHECKER                    17100020
EXCGES40 TM    EXCSLERR,EXCSLER2  HAS AN INVAL STMNT NO. BEEN FOUND DUE 17120020
         BNO   EXCGES50                TO EXTRANEOUS CHARS.  BR IF NO.  17140020
         TM    EXCSLERR,EXCLBMSG  IF MSG FOR INVAL STMNT LBL (ZERO) HAS 17160020
         BO    EXCGES50           BEEN SENT, DON'T SEND AGAIN.  BR.     17180020
         BAL   R2,EXCALMQ        OUTPUT MSG WITH CHARS IN ERROR         17200020
         DC    Y(RC8*256+ERSTANO)      WITH RETURN CODE = 8             17220020
EXCGES50 CH    R6,EXCH5          HOW MANY DIGITS WERE FOUND IN LABEL    17240020
         BNH   EXCGES55           BR IF FEWER THAN SIX                  17260020
         BAL   R2,EXCALMF         ISSUE ERR MSG WITH NO SOURCE CHARS    17280020
         DC    Y(RC8*256+ERTMYDIG)     IN ERROR WITH RETURN CODE = 8    17300020
EXCGES55 LA    R0,WKACHRST        R0 = ADDR OF CHAR STRING              17320020
         AH    R0,WKATINU              PLUS 1ST DISPL                   17340020
*                                    = ADDR OF 1ST CHAR ON 2ND LINE     17360020
         C     R0,EXCSVLBL        WAS STMNT LBL CONTINUED PAST 1ST LINE 17380020
         BH    EXCGES60           BR IF NO                              17400020
         BAL   R2,EXCALMF        OUTPUT ERR MSG WITH NO SOURCE CHARS.   17420020
         DC    Y(RC8*256+ERSTNCIL)     WITH RETURN CODE = 8             17440020
EXCGES60 TM    OPTBYTE3,EXCFRFRM  REMAINING ERRORS RELATED TO FREE-FORM 17460020
         BNO   EXCLCR             BR TO CALL CHECKER IF ST. FORM        17480020
         TM    EXCSLERR,EXCSLER2+EXCLBMSG IF EXTRAN CHARS OCCURRED IN   17500020
         BC    CC1+CC3,EXCGES61   LBL OR MSG ALREADY SENT, BR.          17520020
         TM    EXCSLERR,EXCEXTCH  HAVE EXTRANEOUS CHARS BEEN FOUND      17540020
         BNO   EXCGES61           NO.  DO NOT ISSUE MSG.  BR.           17560020
         BAL   R2,EXCALMQ         ISSUE ERR MSG 'EXTRANEOUS CHARS       17580020
         DC    Y(RC8*256+ERCHIVPS)     PRECEDE STATEMENT' WITH RC = 8   17600020
EXCGES61 TM    EXCSLERR,EXCSLER1  WAS STMNT FIELD MISSING               17620020
         BO    EXCGES66           YES.  GO TO ISSUE MSG                 17640020
         TM    EXCEXSLN,X'80'     WAS THERE A MSG SENT ALREADY          17660020
         BO    EXCLCR             BR IF YES TO CALL CHECKER             17680020
         CH    R6,EXCH5           HOW MANY DIGITS WERE FOUND IN THE LBL 17700020
         BNL   EXCLCR             IF 5 OR GREATER, AMOUNT OF CHARACTERS 17720020
*                                      IN STRING ALREADY CHECKED        17740020
         LA    R0,5               R0 = MAXIMUM NO. OF DIGITS ALLOWED IN 17760020
         SR    R0,R6              LABEL - ACTUAL NO. OF DIGITS IN LABEL 17780020
         AH    R6,EXCH1320        R6 =                                  17800020
         LA    R0,WKACHRST             (WKACHRST-1) +                   17820020
         AR    R6,R0                        1320 +                      17840020
         BCTR  R6,0                              NO. OF DIGITS IN LBL   17860020
         CR    R7,R6              IF WKAENDST IS LESS THAN OR EQUAL     17880020
*                                 TO 1320 + NO. OF DIGITS IN LABEL +    17900020
         BNH   EXCLCR             (WKACHRST-1), THEN CALL CHECKER       17920020
*                                                                       17940020
         BAL   R2,EXCALMF         SEND LINE TOO LONG MSG                17960020
         DC    Y(RC8*256+ERMT1320)     WITH RETURN CODE = 8             17980020
         OI    EXCEXSLN,X'80'     SET SW TO INDICATE MSG SENT           18000020
EXCGES65 B     EXCLCR             BR TO CALL CHECKER                    18020020
EXCGES66 EQU   *                                                        18040020
         MVI   WKAERRCD,ERINVST   MOVE ERR CODE INTO WKAERRCD           18060020
         XC    WKAERRSC,WKAERRSC  INDICATE NO CHAR STRING IN MSG        18080020
         B     EXCLCR10           BR TO SEE IF THERE IS ANOTHER STMNT   18100020
*                                                                       18120020
*              FRST CARD OF NEXT STATEMENT HAS BEEN FOUND. CALL CHECKER 18140020
EXCLCR   MVI   WKASFAIL,0         INITIALIZE RESULT BYTE = OK           18160020
         L     RF,=V(IPDSNCKR)   RF= SYNTAX-CHECKER-PROPER ENTRY POINT  18180020
         ST    R9,WKAOPTPT        SET UP LOC OF WORK AREA AND OF        18200020
         ST    RD,WKAWADDR        OPTIONS WORD IN IPDSNCKR PARAM LIST   18220020
         LA    R1,WKACKPRM        R1= LOC OF PARAM LIST                 18240020
*                                                                       18260020
         BALR  RE,RF              CALL IPDSNCKER                        18280020
         CLI   WKASFAIL,0         WAS SYSBUG DETECTED                   18300020
         BNE   EXCLCR8            BR IF YES.                            18320020
         TM    WKACERSW,EXCNCKER  NO. WAS SNYTAX ERROR IN STMNT         18340020
         BO    EXCLCR5            DETECTED...  BR IF YES.               18360020
EXCLCR4  NC    EXCSVBUF,EXCSVBUF  NO. IS THERE ANOTHER STMNT IN CHAIN   18380020
         BC    NC0,EXCLCR20       BR IF YES TO GET IT.                  18400020
EXCRCO   SR    RF,RF              RETURN TO INTERFACE WITH CODE=0 TO    18420020
         B     EXCALMT            GET ANOTHER BUFFER CHAIN.             18440020
*                                                                       18460020
*                                                                       18480020
*                                                                       18500020
*              SYNTAX ERROR DETECTED.                                   18520020
EXCLCR5  TM    WKAERRCD,1         IS THIS A TERMINAL MSG FOR STMNT      18540020
         BO    EXCLCR10           BR IF YES.                            18560020
         BAL   R2,EXCALMY         NO. WRITE MESSAGE                     18580020
         DC    Y(RC8*256)         WITH RETURN CODE 8                    18600020
         B     EXCLCR             RECALL IPDSNCKR TO CHECK REMAINDER    18620020
*                                                                       18640020
*                                                                       18660020
*                                                                       18680020
*              TERMINATING ERROR FOR THIS STATEMENT DETECTED            18700020
EXCLCR8  MVI   WKAERRCD,ERSYSBUG  IF SYSBUG, SET ERROR CODE.            18720020
         EX    0,EXCALMS2         SET WKAERRSC TO INDICATE NO ERROR    C18740020
                                  STRING AND USE LINE NO OF FRST CARD  C18760020
                                  IN STATEMENT.                         18780020
EXCLCR10 EX    0,EXCLCR4          IS THERE A NEXT STMNT IN CHAIN        18800020
         LA    R2,=Y(RC4*256)     IF NO SEND MSG WITH RETURN CODE 4     18820020
         BC    CC0,EXCALMY        TO GET A NEW BUFFER.                  18840020
         BAL   R2,EXCALMY         IF YES, SEND MSG                      18860020
         DC    Y(RC8*256)              WITH RETURN CODE = 8             18880020
EXCLCR20 MVC   EXCNXCRD(INF),EXCSVCRD  INITIALIZE GET CARD ROUTINE TO   18900020
         BAL   R2,EXCGETRC             PICK UP FRST CARD OF NEXT STMNT. 18920020
         TM    OPTBYTE3,EXCFRFRM  IF FREE-FORM,                         18940020
         BO    EXCNEB35           BR TO SKIP OVER COMMENT LINES.        18960020
         B     EXCNNB             STANDARD-FORM. BR TO PROCESS STMNT.   18980020
         EJECT                                                          19000020
*        ENTRY WITH LOC OF RETURN CODE & ERROR CODE IN R2 AND NOT       19020020
*        YET HAVING FOUND A RECORD.  NO ERROR CHAR STRING.              19040020
EXCALMS  MVI   WKAERNUM,C' '      LINE NUMBER = BLANKS                  19060020
         MVC   WKAERNUM+1(7),WKAERNUM                                   19080020
         SR    RF,RF              AND                                   19100020
         STH   RF,WKAERPOS        RELATIVE POSITION IN CHAIN = 0        19120020
         LA    RF,EXCALM25        BAL RF,EXCALMS2   B EXCALM25          19140020
EXCALMS2 XC    WKAERRSC,WKAERRSC  INDICATE NO CHAR STRING IN MSG        19160020
EXCALMS5 MVC   WKAERRCD,1(R2)     WKAERRCD=ERROR CODE                   19180020
         BR    RF                 RETURN                                19200020
*                                                                       19220020
*                                                                       19240020
*                                                                       19260020
*        ENTRY WITH LOC OF RETURN AND ERROR CODES IN R2 AND RECORD      19280020
*        SPECIFIED IN EXCCRRCRD INF AREA. NO ERROR CHAR STRING.         19300020
EXCALMR  EX    0,EXCALMS2         INDICATE NO CHAR STRING IN MSG        19320020
*        ENTRY WHEN LOC OF CHAR STRING IS IN WKAERRSC.                  19340020
EXCALMR2 EX    0,EXCALMS5         WKAERRCD = ERROR CODE                 19360020
         MVC   WKAERPOS,EXCCRREL  SET UP REL LINE NO. FROM EXCCR INFO   19380020
         TM    OPTBYTE3,EXCNLNUM  IF DATA SET IS NOT LINE NUMBERED      19400020
         BO    EXCALM25                DO NOT SET UP WKAERNUM           19420020
         L     R6,EXCCRCRD        PREPARE TO GET LINE NO. FROM RECORD   19440020
         TM    OPTBYTE3,EXCVRLNG  IS SOURCE VARIABLE LENGTH             19460020
         BNO   EXCALMR3           BR IF NO.                             19480020
         LA    R6,12(R6)          YES.  R6 POINTS TO COL 1 OF TEXT      19500020
EXCALMR3 EQU   *                                                        19520020
         BAL   RF,EXCLNRTN        BR TO ROUTINE TO GET LINE NUMBER      19540020
         B     EXCALM25           BR TO CALL IPDER                      19560020
*                                                                       19580020
*                                                                       19600020
*                                                                       19620020
*        ENTRY WITH LOC OF RETURN AND ERROR CODES IN R2 AND RECORD      19640020
*        SPECIFIED IN EXCFSCRD INF AREA.  NO ERROR CHAR. STRING         19660020
EXCALMF  MVC   WKAERNUM,WKATINU+2 IF DATA SET IS LINE NUMBERED, LINE    19680020
*                                      NO. IS FOUND IN FIRST ENTRY OF   19700020
*                                      WKATINU TABLE.                   19720020
         MVC   WKAERPOS,EXCFSREL WKAERPOS=REL POSIT IN 'FS' AREA        19740020
         B     EXCALMP2           BR TO CONTINUE                        19760020
*                                                                       19780020
*                                                                       19800020
*                                                                       19820020
*        ENTRY WITH LOC OF RETURN AND ERROR CODES IN R2 AND RECORD      19840020
*        SPECIFIED IN EXCSVCRD INF AREA. NO ERROR CHAR STRING.          19860020
EXCALMP  MVC   WKAERNUM,EXCSVLNN  DATA SET LINE NUMBER HAS BEEN SAVED   19880020
         MVC   WKAERPOS,EXCSVREL  WKAERPOS= REL POSIT NO IN 'SV' AREA   19900020
EXCALMP2 BAL   RF,EXCALMS2        SET WKAERRSC AND WKAERRCD             19920020
         B     EXCALM25           BR TO CALL IPDER                      19940020
*                                                                       19960020
*                                                                       19980020
*                                                                       20000020
*        ENTRY WITH RETURN AND ERROR CODES IN R2, LOCATION OF           20020020
*        CHARS IN ERROR SPECIFIED IN WKAERRSC.                          20040020
EXCALMQ  EX    0,EXCALMS5        WKAERRCD = ERROR CODE                  20060020
*                                                                       20080020
*                                                                       20100020
*                                                                       20120020
*        ENTRY WITH ERROR CODE IN WKAERRCD, LOC OF RETURN CODE IN R2,   20140020
*        AND LOCATION OF CHARS IN ERROR SPECIFIED IN WKAERRSC.          20160020
EXCALMY  L     R0,WKAERRSC        R0 CONTAINS ADDR OF CHARS IN ERR      20180020
         LTR   R0,R0              IS ADDR RETURNED FROM CKR NEGATIVE    20200020
         BNP   EXCALMY7           YES, BR.  NO SOURCE ERR CHARS.        20220020
         LA      R1,WKACHRST-1    R1 HAS ADDR OF BEGINNING OF CHAR      20240020
*                                      STRING MINUS ONE                 20260020
*                                 WKATINU CONTAINS DISPL OF SOURCE      20280020
*                                 CHARS FROM WKACHRST-1                 20300020
         SR    R0,R1              DIFFERENCE = DISPL OF CHARS IN ERR    20320020
         SR    R1,R1              R1 IS INDEXING REG FOR TINU TBL       20340020
EXCALMY2 LH    RE,WKATINU(R1)     GET DISPL FROM TINU TBL ENTRY         20360020
         LTR   RE,RE                                                    20380020
         BM    EXCALMY7           IF ENTRY NEG, END OF TBL. BR.         20400020
         CR    R0,RE              ARE ERR CHARS WITHIN THIS LINE        20420020
         BNH   EXCALMY3           YES. BR TO SET UP ERROR INFO.         20440020
         LA    R1,10(R1)          INCREMENT INDEX REGISTER              20460020
         B     EXCALMY2           BR TO CONTINUE TBL COMPARE            20480020
EXCALMY3 SR    RE,R0              DETERMINE NO. CHARS IN ERR MSG MINUS  20500020
*                                      ONE, I.E. NO. CHARS ON LINE      20520020
*                                      BEYOND THE ONE POINTED TO.       20540020
         CH    RE,EXCH5           MORE THAN FIVE CHARS TO END OF LINE   20560020
         BNL   EXCALMY4           YES. BR TO MOVE SIX CHARS.            20580020
         MVI   WKAERCHR,C' '      BLANK OUT AREA WHERE SOURCE           20600020
         MVC   WKAERCHR+1(5),WKAERCHR   CHARS ARE TO BE MOVED           20620020
         B     EXCALMY5           BR TO MOVE CHARS                      20640020
EXCALMY4 LA    RE,5               SET UP RE FOR MOVE OF SIX CHARS       20660020
EXCALMY5 L     RF,WKAERRSC        RF CONTAINS ADDR OF CHARS IN ERR      20680020
         EX    RE,EXCALMYY        MOVE ERR CHARS TO MSG AREA            20700020
EXCALMY6 LA    RF,WKATINU+2       RF HAS ADDR OF WKATINU ENTRY WITH     20720020
         LA    RF,0(RF,R1)             REL LINE NO. OR DATA SET LINE NO 20740020
         MVC   WKAERPOS,0(RF)     MOVE REL LINE NO. OR DATA SET LINE    20760020
         MVC   WKAERNUM,0(RF)          NO. TO IPDERWKA                  20780020
         B     EXCALM25           BR TO CALL IPDER                      20800020
EXCALMY7 SR    R1,R1              INITIALIZE R1 FOR SCAN THRU TINU TBL  20820020
EXCALMY8 LH    RE,WKATINU(R1)     SCAN TINU FOR NEGATIVE DISPL (END     20840020
         LTR   RE,RE                   OF TABLE)                        20860020
         BM    EXCALMY9           BR IF NEGATIVE                        20880020
         LA    R1,10(R1)          INCR INDEX REG                        20900020
         B     EXCALMY8           CONTINUE TO SCAN                      20920020
EXCALMY9 SH    R1,EXCH10          BACK UP PTR TO LAST VALID ENTRY OF    20940020
         EX    0,EXCALMS2         ERROR PAST END OF STMNT               20960020
         B     EXCALMY6                TINU TABLE                       20980020
*                                                                       21000020
*                                                                       21020020
*     AN ERROR HAS BEEN FOUND IN THE LABEL OF A STANDARD-FORM STMNT     21040020
EXCALMYA MVC   WKAERRCD,1(R2)     WKAERRCD=ERROR CODE                   21060020
         MVI   WKAERCHR,C' '      BLANK OUT AREA WHERE SOURCE           21080020
         MVC   WKAERCHR+1(5),WKAERCHR  CHARS ARE TO BE MOVED            21100020
         L     RF,WKAERRSC        RF CONTAINS ADDR OF CHARS IN ERROR    21120020
         MVC   WKAERCHR(5),0(RF)  MOVE ERROR CHARS                      21140020
         SR    R1,R1              WKATINU INDEX SHOULD POINT TO         21160020
*                                      FIRST LINE ENTRY                 21180020
         B     EXCALMY6           BR FOR LINE NO. HANDLING              21200020
EXCALMYY MVC   WKAERCHR(0),0(RF)  MVC FOR MOVE OF ERROR CHARS           21220020
*                                                                       21240020
*                                                                       21260020
*                                                                       21280020
*        WKAERRCD,WKAERNUM,WKAERPOS,WKAERRSC HAVE NOW BEEN SET UP.      21300020
*        SET UP REST OF CALLING SEQUENCE TO IPDERERR.                   21320020
EXCALM25 LA    R1,OPTBYTE3                                              21340020
         ST    R1,WKAEROPT        LOC. OF 4TH BYTE OF OPTION WORD       21360020
         LA    R1,IPDERWKA        R1=LOC. OF WORK AREA FOR IPDERERR     21380020
         L     RF,=A(IPDERERR)                                          21400020
         MVI   WKASFAIL,0         PRESET RESULT BYTE OK                 21420020
*                                                                       21440020
         BALR  RE,RF              CALL IPDERRERR                        21460020
         CLI   WKASFAIL,0         DID SYSBUG OCCUR                      21480020
         BE    EXCALM30           BR IF NO                              21500020
EXCALM27 MVI   WKAERRCD,ERSYSBUG  YES. WKAERRCD= SYSBUG CODE            21520020
         B     EXCALM25           RE-CALL IPDERERR FOR SYSBUG MSG       21540020
EXCALM30 LA    R1,WKAERBFR        PUT LOC OF MSG IN WORD 2 OF           21560020
         ST    R1,COMERRAD        COMMUNICATION AREA FOR INTERFACE      21580020
         SR    RF,RF              GET RETURN CODE                       21600020
         IC    RF,0(R2)                                                 21620020
         LA    R2,2(R2)           INCR RETURN REG OVER HALFWORD PARAM   21640020
*                                                                       21660020
*                                                                       21680020
*                                                                       21700020
*        ENTRY WITH RETURN CODE IN RF AND NO MSG TO BE SENT.            21720020
EXCALMT  CH    RF,EXCH8           IS CODE = 8                           21740020
         BE    EXCALM40           YES.  RETURN.                         21760020
         LA    R2,EXCALM77        NO. SET RETURN REG TO ISSUE MSG IF    21780020
*                                 INTERFACE TRIES TO CONTINUE CHECKING  21800020
*                                 SAME BUFFER.                          21820020
EXCALM40 STM   R2,R8,28+EXCSVRGS SAVE REGS IN CASE OF RETURN CODE 8.    21840020
         L     RD,EXCSVRGS+4      R13 = LOC OF CALLER SAVE AREA         21860020
EXCEXIT  L     RE,12(RD)          RESTORE 14 & 2-12.                    21880020
         LM    R2,RC,28(RD)                                             21900020
         MVI   12(RD),X'FF'       SET RETURN INDICATION                 21920020
         BR    RE                 RETURN                                21940020
*                                                                       21960020
*                                                                       21980020
*                                                                       22000020
*        UNSOLICITED REQUEST BY INTERFACE TO CONTINUE CHECKING BUFFER.  22020020
EXCALM77 MVI   WKASFAIL,SYERITF1  SET UP WKASFAIL WITH FAIL CODE        22040020
         BAL   R2,EXCALMS         SEND SYSBUF MSG                       22060020
         DC    Y(RC4*256+ERSYSBUG)     WITH RETURN CODE = 4             22080020
*                                                                       22100020
         EJECT                                                          22120020
*                                                                       22140020
*        SET UP EXCNXCRD LOCATION INFO AREA.                            22160020
*        BAL   R2,EXCGETRC       GET A RECORD & SET R6= LOC OF COL. 1   22180020
*        RETURN                                     R8= LENGTH OF TEXT  22200020
*                                                       MINUS ONE       22220020
*                                AND PUT LOCATION INFO IN EXCCRCRD      22240020
*                                 AREA. SETS  EXCNXCRD AREA TO LOCATION 22260020
*              INFO FOR NEXT RECORD. OPERATES INDEPENDENTLY OF EXCNESIT 22280020
*              INITIALIZATION. CON CODE=0 INDICATES NO MORE RECORDS.    22300020
*              WHEN  THE ONE GOTTEN IS THE LAST ONE, EXCNXBUF IS ZERO.  22320020
*                                                                       22340020
EXCGETRC LM    R0,R1,EXCNXCRD    GET LOCS OF NEXT RECORD & ITS BUFFER   22360020
         STM   R0,R1,EXCCRCRD    STORE AS LOC OF CURRENT RECORD         22380020
         LTR   R1,R1              IS THERE ONE...                       22400020
         BCR   CC0,R2             RETURN WITH ZERO CON CODE IF NO       22420020
*                                     BUFFER.                           22440020
         LR    R6,R0             SET R6= COL 1 OF CURRENT RECORD        22460020
         L     RF,EXCNXBRL        STORE REL LINE NO. IN BUFFER AND      22480020
         ST    RF,EXCCRBRL       IN BUFFER CHAIN OF CURRENT RECORD      22500020
         LA    RF,1(RF)                                                 22520020
         STH   RF,EXCNXREL       AND OF NEW NEXT RECORD.                22540020
         SRA   RF,16                                                    22560020
         BM    EXCGRCE1           SYSTEM ERROR. BR TO SET WKASFAIL.     22580020
         LA    RF,1(RF)                                                 22600020
         STH   RF,EXCNXBRL                                              22620020
*                                                                       22640020
*                                                                       22660020
*                                                                       22680020
*        DETERMINE LOCATION OF NEXT RECORD IN BUFFER.  DEPENDS ON       22700020
*        WHETHER RECORDS ARE FIXED LENGTH OR VARIABLE LENGTH.           22720020
*        FIRST, DETERMINE IF NEXT RECORD IS IN CURRENT BUFFER.          22740020
         IC    RE,0(R1)          RE = NO. RECS IN BUFFER                22760020
         N     RE,=F'127'         ZERO OUT BITS 0 THROUGH 24            22780020
         CR    RE,RF             IS NEXT RECORD BEYOND BUFFER           22800020
         BNH   EXCGRC5            BR IF YES                             22820020
*                                                                       22840020
         TM    OPTBYTE3,EXCVRLNG                                        22860020
         BO    EXCGRC3            BR IF VARIABLE LENGTH                 22880020
*                                                                       22900020
*        FIXED LENGTH.  GET LINE LENGTH FROM OPTIONS WORD.              22920020
         SR    R0,R0                                                    22940020
         IC    R0,OPTLNLNG       OPTIONS WORD PROVIDES LINE LENGTH      22960020
         AR    R0,R6             R0 = ADDR. OF NEXT RECORD.             22980020
         ST    R0,EXCNXCRD        STORE ADDR. OF NEXT RECORD            23000020
EXCGRC2  LH    R8,EXCH71          INITIALIZE R8 = LENGTH OF TEXT - 1    23020020
         B     EXCGRC4            BR TO CONTINUE                        23040020
*                                                                       23060020
*        VARIABLE LENGTH.  GET LINE LENGTH FROM BUFFER.                 23080020
EXCGRC3  MVC   WKATEMPH,0(R6)     LINE LENGTH IS FIRST TWO BYTES OF     23100020
         LH    R0,WKATEMPH        CURRENT RECORD                        23120020
         AR    R0,R6             R0 = ADDR. OF NEXT RECORD              23140020
         ST    R0,EXCNXCRD        STORE ADDR. OF NEXT RECORD            23160020
EXCGRC35 LH    R8,WKATEMPH        R8 SET TO TOTAL LINE LENGTH           23180020
         SH    R8,EXCH4          SUBTRACT 4 FOR FULL WORD OF BINARY 0'S 23200020
         LA    R6,4(R6)          ADDR. OF TEXT PORTION IS PAST BIN 0'S  23220020
         SH    R8,EXCH1           SUB 1 TO INDICATE TEXT LNG MINUS 1    23240020
         BM    EXCGRCE2           SYSTEM ERROR. BR TO SET WKASFAIL.     23260020
         TM    OPTBYTE3,EXCNLNUM                                        23280020
         BO    EXCGRC4            BR IF NOT A LINE NUMBERED DATA SET    23300020
         LA    R6,8(R6)          ADDR. OF TEXT PORTION IS PAST LINE NO. 23320020
         SH    R8,EXCH8          SUBTRACT DOUBLE WORD LINE NO FROM LINE 23340020
*                                     LENGTH.                           23360020
*                                                                       23380020
EXCGRC4  LTR   R0,R6              SET CON CODE NON-ZERO.                23400020
         BR    R2                RETURN WITH CON CODE NON-ZERO          23420020
*        NO MORE RECORDS IN CURRENT BUFFER                              23440020
EXCGRC5  EQU   *                                                        23460020
         OI    0(R1),EXCRLSBF     SET BIT TO ALLOW BUFFER RELEASE       23480020
         MVC   EXCNXBUF+1(3),1(R1) GET LOC OF NEXT BUF FROM             23500020
         L     R1,EXCNXBUF             POINTER IN CURRENT BUF           23520020
         LTR   R1,R1                                                    23540020
         BZ    EXCGRC15           BR IF NO NEXT BUFFER                  23560020
         CLI   0(R1),0           ANY RECORDS IN NEXT BUFFER             23580020
         BE    EXCGRC5            BR IF NO TO CONTINUE CHAINING         23600020
EXCGRC10 XC    EXCNXBRL,EXCNXBRL ZERO REL. POSITION IN BUFFER           23620020
         LA    R0,4(R1)          LOC OF NEXT RECORD = LOC. OF NEXT      23640020
*                                BUFFER + 4.                            23660020
         ST    R0,EXCNXCRD        STORE ADDR. OF NEXT RECORD            23680020
EXCGRC15 TM    OPTBYTE3,EXCVRLNG                                        23700020
         BNO   EXCGRC2            BR IF FIXED LENGTH                    23720020
         MVC   WKATEMPH,0(R6)     VARIABLE-LENGTH.  COMPLETE INITIAL-   23740020
         B     EXCGRC35          IZATION FOR CURRENT RECORD.            23760020
EXCGRCE1 MVI   WKASFAIL,SYERREG1  SET WKASFAIL NON-ZERO                 23780020
         B     EXCGRCE3           BR.                                   23800020
EXCGRCE2 MVI   WKASFAIL,SYNGREG1  SET UP WKASFAIL WITH FAIL CODE        23820020
EXCGRCE3 BAL   R2,EXCALMS         BR TO ISSUE MSG                       23840020
         DC    Y(RC4*256)              WITH RETURN CODE = 4             23860020
*                                                                       23880020
*                                                                       23900020
*                                                                       23920020
*        BAL   R2,EXCNESIT        NEW STATEMENT INITIALIZATION ROUTINE  23940020
EXCNESIT XC    WKACERSW(EXCSLERR+1-WKACERSW),WKACERSW ZERO SOME SWITCHS 23960020
         MVI   WKASFAIL,0         INITIALIZE WKASFAIL TO ZERO           23980020
         SR    R5,R5              START WKATINU INDEX AT ZERO           24000020
         TM    OPTBYTE3,EXCFRFRM                                        24020020
         BNO   EXCNES10           BR IF STANDARD-FORM                   24040020
         STH   R5,WKATINU         INITIALIZE 1ST DISPL TO ZERO          24060020
         BR    R2                 RETURN                                24080020
EXCNES10 LA    R0,5               IN ST-FORM, DISPL SHOULD INCLUDE      24100020
         STH   R0,WKATINU         THE LABEL FIELD                       24120020
         BR    R2                 RETURN                                24140020
*                                                                       24160020
*        ROUTINE TO OBTAIN DATA SET LINE NUMBER FROM RECORD IN BUFFER.  24180020
*        R6 IS LOCATION OF COL. 1 OF RECORD.                            24200020
*        EXCLNRTN WILL PUT LINE NUMBER IN WKAERNUM.                     24220020
*                                                                       24240020
*        ROUTINE SHOULD NOT BE CALLED IF DATA SET IS NOT LINE NUMBERED. 24260020
*                                                                       24280020
*        CALLED BY       BAL   RF,EXCLNRTN                              24300020
*                                                                       24320020
EXCLNRTN LA    R0,8                                                     24340020
         LR    R1,R6              R1 CONTAINS LOC. OF COL. 1            24360020
         SR    R1,R0              SUBTRACT 8 FROM ADDR.                 24380020
         TM    OPTBYTE3,EXCVRLNG  IF VARIABLE-LENGTH, R1 NOW            24400020
         BO    EXCLNRT1                POINTS TO LINE NO., BR.          24420020
         IC    R0,OPTLNLNG        IF FIXED-LENGTH, ADD LINE LENGTH      24440020
         AR    R1,R0                   TO R1 TO GET ADDR OF LINE NO.    24460020
EXCLNRT1 MVC   WKAERNUM,0(R1)     MOVE LINE NO. TO WKAERNUM             24480020
         BR    RF                 RETURN                                24500020
*                                                                       24520020
*        CONSTANTS USED BY EXECUTIVE                                    24540020
*                                                                       24560020
EXCH1    DC    H'1'                                                     24580020
EXCH4    DC    H'4'                                                     24600020
EXCH5    DC    H'5'                                                     24620020
EXCH6    DC    H'6'                                                     24640020
EXCH8    DC    H'8'                                                     24660020
EXCH10   DC    H'10'                                                    24680020
EXCH71   DC    H'71'                                                    24700020
EXCH200  DC    H'200'                                                   24720020
EXCH1320 DC    H'1320'                                                  24740020
EXCH1325 DC    H'1325'                                                  24760020
         LTORG                                                          24780020
EXCSOFAR EQU   *-IPDSNEXC         TROUBLE IF THIS EXCEEDS EXCLENGT      24800020
EXCEXPAN EQU   EXCLENGT-EXCSOFAR                                        24820020
         DC    (EXCEXPAN)C'X'     EXPANSION SPACE FILLED WITH X'S       24840020
EXCCSEND EQU   *                                                        24860020
         EXTRN IPDERERR                                                 24880020
         EJECT                                                          24900020
*                                                                       24920020
*                                                                       24940020
*NAME OF ROUTINE..                                                      24960020
*        IPDSNCKR, THE CHECKER ROUTINE.                                 24980020
*                                                                       25000020
*STATUS..                                                               25020020
*        VERSION 1 / MODIFICATION 0                                     25040020
*                                                                       25044021
*        CHANGE LEVEL 02  OCT 71   RELEASE 21                           25048021
*        D417400-418000,418600-419600                            A43116 25052021
*        D                                                              25052821
*        C047800,A073700-076510,C076610,A087260-087320                  25053621
*        A087840-08796,D088000,A798820-798960                  PTM2013  25054421
*                                                                       25055221
*                                                                       25056021
*                                                                       25060020
*FUNCTION..                                                             25080020
*                   THE FUNCTION OF THE CHECKER IS TO EDIT A            25100020
*                   SINGLE FORTRAN STATEMENT FOR SYNTACTIC              25120020
*                   ERRORS BY MATCHING THE SOURCE STATEMENT             25140020
*                   AGAINST A TABLE THAT DEFINES THE SYNTAX             25160020
*                   FOR FORTRAN IV SYNTAX.                              25180020
*                                                                       25200020
*ENTRY..                                                                25220020
*        IPDSNCKR                                                       25240020
*        THE CHECKER IS CALLED AT ITS SINGLE ENTRY POINT, IPDSNCKR,     25260020
*        BY THE EXECUTIVE, IPDSNEXC, VIA A STANDARD CALLING SEQUENCE.   25280020
*        REGISTER 1 POINTS TO A PARAMETER LIST.                         25300020
*                                                                       25320020
*INPUT..                                                                25340020
*        WHEN THE CHECKER IS CALLED, REGISTER 1 POINTS TO A PARAMETER   25360020
*        LIST OF THE FORM--                                             25380020
*                   DS   F    INITIAL SUPPLIED SOURCE POINTER           25400020
*                   DS   A    ADDR OF DEFINITION TABLE, EG, IPDAGH      25420020
*                   DS   A    ADDR OF WORK AREA OF FORMAT IPDSNWKA      25440020
*                   DS   A    ADDR OF OPTIONS WORD OF FORMAT IPDSNOPT   25460020
*                                                                       25480020
*        ONCE POINTED TO THE WORK AREA, THE CHECKER CAN REFERENCE ALL   25500020
*        FIELDS DEFINED IN THE DSECT IPDSNWKA, INCLUDING THE PARAMETER  25520020
*        LIST ITSELF, WHICH MUST BE WITHIN THE WORK AREA.               25540020
*                                                                       25560020
*        THE INITIAL SUPPLIED SOURCE POINTER GIVES THE CHECKER          25580020
*        THE BEGINNING CHARACTER OF THE STATEMENT TO BE CHECKED.        25600020
*                                                                       25620020
*        THE DEFINITION TABLE ADDRESS GIVES THE CHECKER THE LOCATION    25640020
*        OF THE FORTRAN LANGUAGE DEFINITION TABLE THAT DIRECTS THE      25660020
*        SYNTAX CHECKING.                                               25680020
*                                                                       25700020
*        WKACERSW AND WKASFAIL ARE PRESET TO ZERO WHEN THE CHECKER      25720020
*        IS CALLED FOR A NEW STATEMENT.                                 25740020
*                                                                       25760020
*OUTPUT..                                                               25780020
*        THE CHECKER'S OUTPUT CONSISTS OF INFORMATION RETURNED TO       25800020
*        THE EXECUTIVE IN THEIR MUTUAL WORK AREA (IPDSNWKA).            25820020
*                                                                       25840020
*        THE CHECKER RETURNS IN ONE OF THREE WAYS--                     25860020
*        1.AT SATISFACTORY COMPLETION OF CHECKING A STATEMENT,          25880020
*          WKACERSW SWITCH BYTE IS ZERO(OFF),WKASFAIL IS ZERO,          25900020
*        2.ON ENCOUNTERING AN ERROR IN STATEMENT CHECKING--             25920020
*          WKACERSW SWITCH BYTE IS 01  (ON), WKASFAIL IS ZERO,          25940020
*          WKAERRSC CONTAINS A POINTER TO THE SOURCE CHARACTER          25960020
*          SUSPECTED TO BE IN ERROR,                                    25980020
*          WKAERRCD CONTAINS THE ERROR MESSAGE CODE NUMBER IN BITS 0-6, 26000020
*          WKAERRTM, BIT 7 OF WKAERRCD, IS ON (1) IF NO FURTHER         26020020
*          CHECKING IS TO BE DONE ON THE CURRENT STATEMENT, IE, THE     26040020
*          ERROR IS TERMINAL. IF WKAERRTM IS OFF (0), THE CHECKER       26060020
*          EXPECTS TO BE RECALLED TO CONTINUE CHECKING THE SAME         26080020
*          STATEMENT.                                                   26100020
*        3.ON ENCOUNTERING AN INVALID CONDITION THAT INDICATES A        26120020
*          PROGRAM FAILURE IN SOME PART OF THE SYNTAX CHECKER--         26140020
*          WKACERSW IS ON,(X'01'), WKASFAIL IS NON-ZERO (FAILURE CODE   26160020
*          X'11' TO X'1F')                                              26180020
*                                                                       26200020
*EXTERNAL REFERENCES..                                                  26220020
*        NONE.                                                          26240020
*        SINCE THE CHECKER HAS NO STANDARD LINKAGES TO SUBROUTINES      26260020
*        IT DOES NOT NEED,AND THEREFORE DOES NOT HAVE, A SAVE AREA      26280020
*        POINTED TO BY REGISTER 13.                                     26300020
*                                                                       26320020
*ERROR CONDITIONS..                                                     26340020
*        THE ERROR CONDITIONS INDICATED WITH AN ASTERISK (*) ARE        26360020
*        TESTED FOR ONLY WHEN THE CONDITIONAL ASSEMBLY PARAMETER        26380020
*        &ITNLDBG IS SET FOR DEBUGGING.                                 26400020
*          *   INVALID OP-CODE IN DEFINITION TABLE                      26420020
*          *   TOO MANY RIGHT BRACES,  OR TOO MANY )S IN DEFINITION     26440020
*          *   INVALID LITERAL LENGTH IN DEFINITION TABLE               26460020
*          *   ILLEGAL TABLE FUNCTION OPCODE IN DEFINITION TABLE        26480020
*          *   ERROR IN HANDLING LINE NEST STACK                        26500020
*          *   INVALID ACTION CODE IN DEFINITION TABLE                  26520020
*        WKASFAIL WILL CONTAIN AN ERROR CODE.                           26540020
*                                                                       26560020
*EXITS,NORMAL..                                                         26580020
*        CONTROL IS RETURNED TO THE CALLER WITH INFORMATION LEFT AS     26600020
*        DESCRIBED UNDER OUTPUT, CONDITIONS 1. AND 2.                   26620020
*                                                                       26640020
*EXITS,ERROR..                                                          26660020
*        CONTROL IS RETURNED TO THE CALLER WITH INFORMATION LEFT AS     26680020
*        DESCRIBED UNDER OUTPUT, CONDITION 3.                           26700020
*                                                                       26720020
*TABLES/WORK AREAS..                                                    26740020
*        CKROPNDX,TABLE OF DISPLACEMENTS TO OPERATOR ROUTINES.          26760020
*        CKRACNDX, TABLE OF DISPLACEMENTS TO ACTION CODE ROUTINES.      26780020
*        CKRAMTBL, TRT TABLE FOR A THROUGH Z AND 0 THROUGH 9.           26800020
*        IPDSNWKA, WORK AREA DSECT.                                     26820020
*        WKATINUE, TABLE FOUND IN WORK AREA FOR LOCATING THE LINES OF   26840020
*                  A STATEMENT.                                         26860020
*        WKASERTB, TRT TABLE BUILT IN WORK AREA FOR CHARACTER SCAN.     26880020
*                                                                       26900020
*ATTRIBUTES..                                                           26920020
*        REENTRABLE,REFRESHABLE                                         26940020
*                                                                       26960020
*NOTES..                                                                26980020
*        THE CHECKER DOES NOT HAVE A SAVE AREA. IT DOES NOT NEED        27000020
*        A SAVE AREA BECAUSE IT DOES NOT PERFORM ANY STANDARD           27020020
*        LINKAGES. IT SAVES REGISTER 13 IN THE WORK AREA AND RESTORES   27040020
*        IT PRIOR TO RETURNING TO ITS CALLER.                           27060020
*                                                                       27080020
*        THE CHECKER USES THE 16-WORD AREA WKACKRGS TO SAVE ITS OWN     27100020
*        REGISTERS BETWEEN CALLS FROM THE EXECUTIVE.  BY RELOADING      27120020
*        ITS REGISTERS, ONE OF WHICH SPECIFIES A BRANCH ADDRESS,        27140020
*        THE CHECKER CAN CONTINUE CHECKING A STATEMENT BEYOND AN ERROR  27160020
*        AFTER RETURNING CONTROL TO, AND BEING RECALLED BY, THE         27180020
*        EXECUTIVE.                                                     27200020
*                                                                       27220020
*        WKANLIST, THE LINE NEST LIST, AND WKAQLIST, THE QUALIFICATION  27240020
*        LIST, ARE ARRANGED AS PUSH DOWN STACKS GROWING TOWARDS         27260020
*        ONE ANOTHER (WKALIST LOWER-TO-HIGHER-NUMBERED LOCATIONS,       27280020
*        WKAQLIST, HIGHER-TO LOWER LOCATIONS).                          27300020
*                                                                       27320020
*        THE OPERATION OF CONTROL SECTION IPDSNCKR DEPENDS ON THE       27340020
*        FOLLOWING PROPERTIES OF THE INTERNAL REPRESENTATION OF THE     27360020
*        EXTERNAL CHARACTER SET--                                       27380020
*                                                                       27400020
*            CHARACTER CODE DEPENDENCY         INSTR. SEQUENCE AFFECTED 27420020
*                                                                       27440020
*          1.DECIMAL NUMBERS MUST BE         1.ROUTINES USING CKR9--    27460020
*            CODED SO THAT THEIR COLLATING           CKRDIGIT,          27480020
*            SEQUENCE REMAINS ASCENDING              CKRNUMBR(6 PLACES) 27500020
*            FROM 0 TO 9 WITH NO OTHER               CKRSTATM(2 PLACES) 27520020
*            CHARACTERS INTERSPERSED.                CKRHOLLR,CKRAR700, 27540020
*                                                    CKRAR701,CKREVALU  27560020
*                                                                       27580020
*          2.DECIMAL NUMBERS MUST BE         2.CKREVALU SUBROUTINE      27600020
*            CODED SO THAT THE LOW                                      27620020
*            ORDER 4 BITS, WHEN CONSIDERED                              27640020
*            AS A BINARY INTEGER, IDENTIFY                              27660020
*            THE VALUE OF THE DIGIT.                                    27680020
*                                                                       27700020
*          3.COMPARISON OF CHARACTERS        3.REASSEMBLE ENTIRELY (TO  27720020
*            TO CHARACTER CONSTANTS            'REDEFINE' INTERNAL      27740020
*            DEPENDS UPON AN INTERNAL          REPRESENTATION OF        27760020
*            REPRESENTATION EQUIVALENT TO      CHARACTER CONSTANTS)     27780020
*            THE ONE USED AT ASSEMBLY TIME.                             27800020
*                                                                       27820020
*          4.THE END-OF-SOURCE SPECIAL       4.WKASPCHR EQU ---         27840020
*            CHARACTER MUST NOT MATCH THE                               27860020
*            INTERNAL REPRESENTATION OF                                 27880020
*            ANY CHARACTER IN THE FORTRAN                               27900020
*            CHARACTER SET.                                             27920020
*                                                                       27940020
*          5.TESTS FOR FORTRAN ALPHABETICS   5.ALL THE PLACES WHICH     27960020
*            AND ALPHAMERICS ARE DEPENDENT     REFER TO CKR$, CKRA, OR  27980020
*            UPON THE EBCDIC 8-BIT CODES       CKRZ--                   28000020
*            OF THOSE 37 CHARACTERS.             TSTAM AND TSTAL MACRO  28020020
*                                                DEFINITIONS, CKRLETTR  28040020
*                                                AND CKRAR500 ROUTINES  28060020
*                                              THE TRANSLATE-AND-TEST   28080020
*                                              TABLE, CKRAMTBL, USED BY 28100020
*                                              THE TSTAM AND TSTAL      28120020
*                                              MACROS.                  28140020
*                                                                       28160020
*                                                                       28180020
         EJECT                                                          28200020
IPDSNCKR CSECT                     CHECKER                              28220020
         SPACE 2                                                        28240020
*********************************************************************** 28260020
*                                                                       28280020
*        LENGTH OF CSECT                                                28300020
*                                                                       28320020
CKRLENGT EQU   4960                MUST BE INTEGRAL MULT. OF 8          28340020
*                                                                       28360020
*                         THIS  EQU  DEFINES THE LENGTH OF THIS  CSECT. 28380020
*                         THE AMOUNT OF SPACE FOR EXPANSION IS THE      28400020
*                         DIFFERENCE BETWEEN THIS NUMBER AND THE        28420020
*                         NUMBER OF BYTES USED IN THE CODING OF THE     28440020
*                         CSECT.  IF THE CODING OF THE  CSECT  IS       28460020
*                         EXPANDED TO A NUMBER OF BYTES LARGER THAN     28480020
*                         THAT SPECIFIED BY THIS  EQU  , THE  EQU       28500020
*                         MUST BE CHANGED TO SPECIFY A SIZE AT LEAST    28520020
*                         AS LARGE AS THE CODING.                       28540020
*                                                                       28560020
*********************************************************************** 28580020
*                                                                       28600020
*                                                                       28620020
*                                                                       28640020
*                   REGISTER ASSIGNMENT                                 28660020
*                                                                       28680020
REGZEROW EQU   0                                                        28700020
REGWORKA EQU   1              *    WORK REGISTERS                     * 28720020
REGWORKB EQU   2              *     NOT PRESERVED BY                  * 28740020
REGWORKC EQU   3              *      LOCAL SUBROUTINES                * 28760020
REGNSTPT EQU   4              LINE NEST LIST POINTER                    28780020
REGWORKN EQU   REGNSTPT                                                 28800020
REGQALPT EQU   5              QUALIFICATION LIST POINTER                28820020
REGWORKQ EQU   REGQALPT                                                 28840020
REGSRCPT EQU   6              SOURCE POINTER                            28860020
REGDEFBS EQU   7              DEFINITION TABLE BASE                     28880020
REGOPCDE EQU   8              OPCODE REGISTER,HIGH-ORDER 3 BYTES ZERO   28900020
REGDEFPT EQU   9              DEFINITION TABLE POINTER                  28920020
REGTDFPT EQU   10             DEFINITION TABLE REFERNC FOR TABLE FUNCT. 28940020
REGCHRCT EQU   REGTDFPT       WKAVALUE,CHAR CTR USED AROUND EXCGTCHR'S. 28960020
REGXTRBS EQU   11             2ND BASE FOR CHECKER PROGRAM              28980020
REGCKRBS EQU   12             CHECKER PROGRAM BASE                      29000020
REGWKABS EQU   13             WORK AREA BASE                            29020020
REGLRETN EQU   14             SUBROUTINE RETURN REGISTER                29040020
REGLCALL EQU   15             SUBROUTINE ENTRY POINT REGISTER           29060020
REG0     EQU   0                                                        29080020
REG1     EQU   1                                                        29100020
REG13    EQU   13                                                       29120020
REG15    EQU   15                                                       29140020
REGOPNDX EQU   15             CONTAINS DISPL. FROM INTRP TO OPER. RTNE. 29160020
*                                                                       29180020
         EJECT                                                          29200020
         USING *,15                                                     29220020
         B     CKRNWOLD            BR TO 1ST INSTRUCTION                29240020
         DC    CL8'IPDSNCKR'       NAME OF CSECT                        29260020
         DROP  9,10,11,12,13,15                                         29280020
*********************************************************************** 29300020
*                                                                     * 29320020
*        THIS ROUTINE DETERMINES WHETHER THE CHECKER HAS BEEN         * 29340020
*        CALLED TO START CHECKING A NEW STATEMENT OR TO CONTINUE      * 29360020
*        CHECKING A STATEMENT IN PROGRESS.                            * 29380020
*                                                                     * 29400020
*                                                                     * 29420020
*********************************************************************** 29440020
*                                                                       29460020
CKRNWOLD EQU   *                                                        29480020
         SAVE  (14,12)                                                  29500020
         LR    REGCKRBS,REG15      ESTABLISH BASE FOR PROGRAM           29520020
         USING IPDSNCKR,REGCKRBS                                        29540020
         LA    REGXTRBS,4095(REGCKRBS)                                  29560020
         USING IPDSNCKR+4095,REGXTRBS                                   29580020
       L     REG15,12(REG1)      GET LOC. OF WKA FROM PARAM LIST        29600020
         USING IPDSNWKA,REG15                                           29620020
         ST    REG13,WKASVR13                                           29640020
         DROP  REG15                                                    29660020
         LR    REGWKABS,REG15      ESTABLISH BASE FOR WORK AREA         29680020
         USING IPDSNWKA,REGWKABS                                        29700020
*                                                                       29720020
*                                                                       29740020
*                                                                       29760020
*                                  REGISTER 13 IS USED AS THE WKA BASE  29780020
*                                                                       29800020
*                                  IPDSNCKR DOES NOT NEED,AND THEREFORE 29820020
*                                  DOES NOT HAVE A SAVE AREA            29840020
*                                                                       29860020
*                                                                       29880020
*                                                                       29900020
         TM    WKACERSW,EXCNCKER   IS THIS A NEW SOURCE STATEMENT       29920020
*                                                                       29940020
         BO    CKRCONTN                 NO, GO CONTINUE CHECKING OLD    29960020
*                                        STATEMENT                      29980020
*                                       YES                             30000020
*********************************************************************** 30020020
*                                                                     * 30040020
*        THIS ROUTINE PERFORMS INITIALIZATION FOR A NEW STATEMENT     * 30060020
*                                                                     * 30080020
*********************************************************************** 30100020
*                                                                       30120020
CKRINTLZ EQU   *                                                        30140020
*                                                                       30160020
         L     REGDEFBS,8(REG1)    ESTABLISH BASE FOR DEFINITION TABLE  30180020
         USING DEFTABLE,REGDEFBS                                        30200020
         L     REGSRCPT,0(REG1)    GET INITL. SOURCE PT FROM PARAM.LIST 30220020
*                                                                       30240020
*                                                                       30260020
*                                                                       30280020
*                                                                       30300020
*                                                                       30320020
*                   INITIALIZE SWITCH SETTINGS                          30340020
*                                                                       30360020
         NI    WKAFALSW,255-CKRFALSW    SET OFF FAILURE SWITCH          30380020
         NI    WKAGLCMT,255-CKRGLCMT    SET OFF GLOBAL (STMT) COMMIT SW 30400020
         AIF   ('&ITNLDBG'  EQ '').NOKINIT                              30420020
         OI    WKAKSWCH,CKRKFAIL         SET ON K SWITCHES              30440020
.NOKINIT ANOP                                                           30460020
*                                                                       30480020
*                   INITIALIZE NEST AND QUALIFICATION LIST POINTERS,    30500020
*                   ZERO NEST AND QUALIFICATION INFORMATION,BUT SET ON  30520020
*                    QUALIFICATION COMMIT SWITCH TO COMMIT TOP LINE     30540020
*                   INITIALIZE MESSAGE TABLE ENTRY ADDRESS              30560020
*                                                                       30580020
         LA    REGNSTPT,WKANLIST   ESTABLISH BASE FOR NEST LIST ENTRIES 30600020
         USING NLSLNEST,REGNSTPT                                        30620020
         ST    REGNSTPT,WKAADNLS                                        30640020
*                                                                       30660020
         LA    REGQALPT,WKAQLIST   ESTABLISH BASE FOR QUAL.LIST ENTRIES 30680020
         USING QLSQUALF,REGQALPT                                        30700020
         ST    REGQALPT,WKATPQLS    AND SAVE TOP LOC OF QUAL LIST       30720020
*                                                                       30740020
         XC    WKALNEST,WKALNEST   ZERO NEST INFO  (LEVEL = 0)          30760020
         MVI   WKANFMSG,CKRSBUGT    BUT DEFAULT ERR MSG TO SYSTEM OR    30780020
*                                    SYNTAX CHECER FAILURE              30800020
*                                                                       30820020
*                                                                       30840020
         XC    WKAQUALF,WKAQUALF   ZERO QUAL INFO  (LEVEL = 0)          30860020
*                                                                       30880020
         OI    WKAQSWCH,CKRCMTSW    BUT COMMIT TOP LINE                 30900020
*                                                                       30920020
         LA    REGWORKA,WKAMSGTB   INITIALIZE MESSAGE ENTRY ADDRESS     30940020
         ST    REGWORKA,WKAMSGAD    TO TOP OF MSG. TABLE                30960020
*                                                                       30980020
*                                                                       31000020
*                   INITIALIZE DEFINITION TABLE POINTER AND             31020020
*                   NEST TO FIRST LINE IN LANGUAGE DEFINITION           31040020
*                                                                       31060020
         LA    REGDEFPT,0          ZERO INITL DEFN TBL DISPL IN POINTER 31080020
*                                                                       31100020
         GTNB1                                                          31120020
         L     REGSRCPT,WKASRCCR   THEN POINT TO 1ST NON-BLANK CHARACT. 31140020
         ST    REGSRCPT,WKABEGSC    IN STATEMENT                        31160020
*                                  SET UP OP-CODE REGISTER, IT WILL     31180020
         LA    REGOPCDE,0               ALWAYS HAVE HI-ORDER 3BYTES 0   31200020
         B     CKRSYNS                  AND NEST FOR FIRST DEFN LINE    31220020
*                                                                       31240020
*********************************************************************** 31260020
*                                                                     * 31280020
*        THE FOLLOWING ROUTINE, WHICH IS THE INTERPRETER,             * 31300020
*        USES THE SYNTACTIC OP-CODE FROM THE DEFINITION TABLE         * 31320020
*        IN CONJUCTION WITH THE OPERATOR ROUTINES BRANCH TABLE        * 31340020
*        TO LOCATE AND BRANCH TO THE APPROPRIATE OPERATOR ROUTINE     * 31360020
*                                                                     * 31380020
*********************************************************************** 31400020
*                                                                       31420020
CKRINTRP EQU   *                                                        31440020
         IC    REGOPCDE,DEFOPCDE(REGDEFPT)    INSERTION OF SYN. OP-CODE 31460020
*                                                                       31480020
         AIF   ('&ITNLDBG' EQ '').NOOPCHK                               31500020
         C     REGOPCDE,CKRINVOP             IS OP-CODE VALID           31520020
         BNL   CKROPFAL            INDICATE AN INVALID OP-CODE          31540020
.NOOPCHK ANOP                                                           31560020
*                                                                       31580020
         LA    REGDEFPT,1(0,REGDEFPT)        DEF.PT USED, MAY BE INCR'D 31600020
*                                  WILL HALT ON LH IF NOT AN EVEN NO.   31620020
         LH    REGOPNDX,CKROPNDX(REGOPCDE)   OP-CODE INDEXES BRANCH TBL 31640020
*                                             TO PROVIDE OPER RTNE INDX 31660020
         B     CKRINTRP(REGOPNDX)            BRANCH TO APPROP OPER RTNE 31680020
*                                                                       31700020
*                                                                       31720020
*                                                                       31740020
*********************************************************************** 31760020
*                                                                     * 31780020
*        THE FOLLOWING ROUTINES, CKRLBRCE AND CKRLPARN, PUSH DOWN     * 31800020
*        THE CURRENT QUALIFICATION INFO AS AN ENTRY ON THE END OF THE * 31820020
*        QUALIFICATION LIST AND BUILD A NEW QUALIFICATION             * 31840020
*                                                                     * 31860020
*         CKRLBRCE--ALTERNATIVE QUALIFICATION (LEFT BRACE)            * 31880020
*         CKRLPARN--OPTIONAL QUALIFICATION (LEFT PARENTHESIS)         * 31900020
*                                                                     * 31920020
*********************************************************************** 31940020
*                                                                       31960020
CKRLBRCE LA    REGWORKB,DEFFIELD(REGDEFPT)   PT WORK REG  TO FALSE,TRUE 31980020
*                                             DISPLACEMENTS IN TABLE    32000020
         LA    REGDEFPT,2(0,REGDEFPT)        INCR DEF POINTER PAST F,T  32020020
         B     CKRLQUAL                 GO DO COMMON BEGIN QUAL PROC'NG 32040020
*                                                                       32060020
CKRLPARN LA    REGWORKB,DEFFIELD(REGDEFPT)   POINT WORK REG TO FALSE    32080020
*                                             DISPLACEMENT IN TABLE     32100020
         LA    REGDEFPT,1(0,REGDEFPT)        INCR DEF POINTER PAST F    32120020
*                                                                       32140020
*                   COMMON BEGIN QUALIFICATION PROCESSING               32160020
*                                                                       32180020
CKRLQUAL S     REGQALPT,CKRLNQLK             GET LOC FOR QUALLIST ENTRY 32200020
*                                                                       32220020
         CR    REGQALPT,REGNSTPT   BE SURE THERE IS SPACE FOR Q ENTRY   32240020
         BL    CKRQOFLO                 (IF NOT, GO PROC.LIST OVERFLOW) 32260020
*                                                                       32280020
         MVC   QLSQUALF,WKAQUALF   MOVE QUALIFICATION  INFO TO LIST     32300020
*                                                                       32320020
*                   BUILD NEW QUALIFICATION INFORMATION                 32340020
*                                                                       32360020
         MVC   WKAQFALS(2),0(REGWORKB)  SAVE FALSE(, TRUE) DISPL'S IN Q 32380020
*                                                                       32400020
         GTNB1                                                          32420020
         L     REGSRCPT,WKASRCCR   SPACE PAST ANY BLANK CHARS.          32440020
         ST    REGSRCPT,WKAQSCPT   SAVE CURRENT VALUE OF SOURCE PT IN Q 32460020
*                                                                       32480020
         STH   REGDEFPT,WKAQDFBK   SAVE CURR VALUE OF DEFN PT IN QUAL   32500020
         IC    REGWORKA,WKANLVLN                                        32520020
         STC   REGWORKA,WKAQNLVL   SET LEVEL OF NESTING FROM LINE NEST  32540020
*                                                                       32560020
         MVI   WKAQICNT,0          ZERO ITERATION COUNT IN QUALIFICAT'N 32580020
*                                                                       32600020
         NI    WKAQSWCH,255-CKRCMTSW    SET OFF COMMIT SWITCH           32620020
*                                                                       32640020
         B     CKRINTRP            GO INTERPRET NEXT OPERATOR           32660020
*                                                                       32680020
*                                                                       32700020
*                                                                       32720020
*********************************************************************** 32740020
*                                                                     * 32760020
*        THE FOLLOWING ROUTINE, CKRRBRCE, PERFORMS PROCESSING TO      * 32780020
*        TERMINATE THE CHECKING OF A LIST OF ALTERNATIVES. IT         * 32800020
*        RECEIVES CONTROL AFTER  ANY    ALTERNATIVE SUCCEEDS OR       * 32820020
*        AFTER THE LAST ALTERNATIVE FAILS.                            * 32840020
*                                                                     * 32860020
*********************************************************************** 32880020
*                                                                       32900020
CKRRBRCE EQU   *                                                        32920020
*                                                                       32940020
         L     REGWORKA,WKAQSCPT   PICK UP SOURCE PT FOR POSSBL BACKUP  32960020
*                                                                       32980020
         MVC   WKAQUALF,QLSQUALF        POP UP QUALIFICATION LIST AND   33000020
         LA    REGQALPT,CKRQUALL(0,REGQALPT) ADJ QUAL LIST POINTER      33020020
         AIF   ('&ITNLDBG' NE 'E').NOERBCK                              33040020
*                                                                       33060020
         C     REGQALPT,WKATPQLS        CHECK FOR                       33080020
         BH    CKREXCRB                  TOO MANY RIGHT BRACES          33100020
.NOERBCK ANOP                                                           33120020
*                                                                       33140020
         TM    WKAFALSW,CKRFALSW        DID LAST TEST FAIL              33160020
         BZ    CKRINTRP                  NO, GO INTERPRET NEXT OPERATOR 33180020
         LR    REGSRCPT,REGWORKA    YES,BACK UP CURRENT SOURCE PT       33200020
         ST    REGSRCPT,WKASRCCR                                        33220020
         B     CKRFAIL               AND GO PROCESS FAILURE             33240020
*                                                                       33260020
*********************************************************************** 33280020
*                                                                     * 33300020
*        THE FOLLOWING ROUTINE, CKRRPARN, PERFORMS PROCESSING TO      * 33320020
*        TERMINATE  THE CHECKING OF AN OPTIONAL ITEM IN THE           * 33340020
*        SYNTACTIC DEFINITION. IT RECEIVES CONTROL WHETHER THE        * 33360020
*        OPTIONAL DEFINITION WAS SATISFIED OR NOT.                    * 33380020
*                                                                     * 33400020
*                                                                     * 33420020
*********************************************************************** 33440020
*                                                                       33460020
CKRRPARN TM    WKAFALSW,CKRFALSW        DID LAST TEST FAIL              33480020
         BZ    CKRSVCTR                  NO                             33500020
         NI    WKAFALSW,255-CKRFALSW     YES,SET OFF FAILURE SWITCH     33520020
         L     REGSRCPT,WKAQSCPT          AND BACK UP TO RETEST SOURCE  33540020
*                                                                       33560020
CKRSVCTR MVC   WKASVICT,WKAQICNT        SAVE ITER CT (MAY BE 0) FOR ACT 33580020
*                                                                       33600020
         MVC   WKAQUALF,QLSQUALF        POP UP QUALIFICATION LIST       33620020
         LA    REGQALPT,CKRQUALL(0,REGQALPT)   (ADJ. QUAL LIST POINTER) 33640020
         AIF   ('&ITNLDBG' NE 'E').NOERPCK                              33660020
*                                                                       33680020
         C     REGQALPT,WKATPQLS        CHECK FOR                       33700020
         BH    CKREXCRP                  TOO MANY RIGHT PARENTHESES     33720020
*                                                                       33740020
.NOERPCK ANOP                                                           33760020
*                                                                       33780020
         B     CKRINTRP                 GO INTERPRET NEXT OPERATOR      33800020
*                                                                       33820020
*********************************************************************** 33840020
*                                                                     * 33860020
*        THE FOLLOWING ROUTINE DETERMINES THE NEXT OPERATOR TO BE     * 33880020
*        EXAMINED AFTER ONE OF SEVERAL ALTERNATIVES HAS BEEN TESTED.  * 33900020
*        IT RECEIVES CONTROL WHETHER THE TEST ON THE PRECEDING        * 33920020
*        ALTERNATIVE WAS SUCCESSFUL OR NOT                            * 33940020
*                                                                     * 33960020
*                                                                     * 33980020
*********************************************************************** 34000020
*                                                                       34020020
CKROR    TM    WKAFALSW,CKRFALSW        DID PRECEDING TEST FAIL         34040020
         BZ    CKRALTOK                  NO                             34060020
         NI    WKAFALSW,255-CKRFALSW     YES, SET OFF FAILURE SWITCH    34080020
         L     REGSRCPT,WKAQSCPT          AND BACK UP SOURCE POINTER    34100020
*                                          TO RETEST SOURCE AGAINT NEXT 34120020
*                                           ALTERNATIVE                 34140020
         IC    REGWORKB,DEFFIELD(REGDEFPT) SAVE DISP TO 'OR' OR RT BRCE 34160020
         STC   REGWORKB,WKAQFALS            PAST NEXT ALTERNATIVE       34180020
*                                                                       34200020
         LA    REGDEFPT,1(0,REGDEFPT)     INCREMENT DEFINITION POINTER  34220020
*                                          TO NEXT OPERATOR             34240020
         B     CKRINTRP                     AND GO INTERPRET IT         34260020
*                                                                       34280020
CKRALTOK SR    REGDEFPT,REGDEFPT        PRECEDING ALTERNATIVE WAS       34300020
         IC    REGDEFPT,WKAQTRUE         SATISFIED, UPDATE DEF'N POINTR 34320020
         AH    REGDEFPT,WKANDFPT          TO RIGHT BRACE(DEFN+TRU DISP) 34340020
*                                                                       34360020
         B     CKRINTRP                    AND GO INTERPRET THAT OPCODE 34380020
*                                                                       34400020
*                                                                       34420020
*********************************************************************** 34440020
*                                                                     * 34460020
*        THE FOLLOWING ROUTINE COMMITS THE DEFINITION TO A            * 34480020
*        PARTICULAR ALTERNATIVE OR OPTION                             * 34500020
*                                                                     * 34520020
*                                                                     * 34540020
*********************************************************************** 34560020
*                                                                       34580020
CKRCOMIT OI    WKAQSWCH,CKRCMTSW        SET ON QUALIFICATION COMMIT SW  34600020
*                                                                       34620020
         B     CKRINTRP                 GO INTERPRET NEXT OPERATOR      34640020
*                                                                       34660020
*                                                                       34680020
*********************************************************************** 34700020
*                                                                     * 34720020
*        THE FOLLOWING ROUTINE COMMITS THE DEFINITION TO A            * 34740020
*        PARTICULAR STATEMENT                                         * 34760020
*                                                                     * 34780020
*                                                                     * 34800020
*********************************************************************** 34820020
*                                                                       34840020
CKRSTCMT EQU   *                                                        34860020
         OI    WKAGLCMT,CKRGLCMT   SET ON GLOBAL (STATEMENT) COMMIT SW  34880020
         CLC   WKANLVLN,WKAQNLVL        ANY QUALIF AT CURRNT NEST LEVEL 34900020
         BNE   CKRTOPQL                  NO                             34920020
         LR    REGWORKB,REGQALPT         YES,INITLZ PT TO COMMIT QUAL'S 34940020
CKRCMTQE OI    QLSQSWCH-QLSQUALF(REGWORKB),CKRCMTSW    COMMIT Q ENTRY   34960020
*                                                   IS LIST QUAL ENTRY  34980020
         CLC   WKANLVLN,QLSQNLVL-QLSQUALF(REGWORKB)  AT NEST LEVEL      35000020
         BNE   CKRTPQEN                             NO                  35020020
         MVI   QLSQNLVL-QLSQUALF(REGWORKB),1  YES,SET Q ENTRY LEVEL=1   35040020
*                                                                       35060020
         LA    REGWORKB,CKRQUALL(0,REGWORKB)      ADJUST PT TO NEXT ENT 35080020
         B     CKRCMTQE                            AND GO TEST ITS LVL  35100020
*                                                                       35120020
CKRTPQEN EQU   *                        QUAL ENTRY IS ABOVE CURR N LVL  35140020
         MVI   QLSQNLVL-QLSQUALF(REGWORKB),0        SET Q ENTRY LEVEL=0 35160020
         LA    REGWORKB,CKRQUALL(0,REGWORKB)    AND SAVE NEW TOP OF Q   35180020
         ST    REGWORKB,WKATPQLS         LIST IN CASE MORE SPACE NEEDED 35200020
*                                                                       35220020
         MVI   WKAQNLVL,1               SET QUALIF LEVEL=1 TO MATCH NST 35240020
*                                                                       35260020
CKRNSTL1 OI WKAQSWCH,CKRCMTSW     COMMIT CURRENT QUALIFICATION          35280020
*                                                                       35300020
         MVI   WKANLVLN,1               SET CURR LEVEL OF NESTING = 1   35320020
*                                                                       35340020
         LA    REGNSTPT,WKANLIST        AND BEGIN AT TOP OF NEST LIST   35360020
*                                        AGAIN  (NEST LIST STRIPPED)    35380020
         B     CKRINTRP                 NOW,GO INTERPRET NEXT OPERATOR  35400020
*                                                                       35420020
*                                                                       35440020
CKRTOPQL MVI   WKAQNLVL,0               SET QUALIF LEVEL=0, TO IGNORE   35460020
*                                        ALL PREVIOUS ALTERNATIVES      35480020
         LA    REGQALPT,WKAQLIST        AND BEGIN AT TOP OF QUAL LIST   35500020
         ST    REGQALPT,WKATPQLS         AGAIN (QUAL LIST STRIPPED)     35520020
         B     CKRNSTL1                 GO COMMIT THE QUAL AND STRIP    35540020
*                                        THE NEST LIST                  35560020
*                                                                       35580020
*                                                                       35600020
*********************************************************************** 35620020
*                                                                     * 35640020
*        THE FOLLOWING ROUTINES, CKRITIND AND CKRITDEF,PROCESS THE RE-* 35660020
*        ITERATION,OR ATTEMPTED REPETITION,OF AN OPTIONAL DEFINITION  * 35680020
*        ON SUBSEQUENT CHARACTERS OF THE SOURCE. THE DEFINITE         * 35700020
*        ITERATION (CKRITDEF) IS LIMITED BY A MAXIMUM NUMBER OF       * 35720020
*        TIMES THE DEFINITION MAY BE MATCHED AGAINST SOURCE. THESE    * 35740020
*        ROUTINES ARE ENTERED ONLY AFTER SATISFACTION OF THE          * 35760020
*        PRECEDING OPTIONAL DEFINITION(IE,AFTER SUCCESSFUL ITERATION) * 35780020
*                                                                     * 35800020
*                                                                     * 35820020
*********************************************************************** 35840020
*                                                                       35860020
CKRITIND IC    REGWORKB,WKAQICNT                                        35880020
         LA    REGWORKB,1(0,REGWORKB)   INCREMENT THE ITERATION COUNT   35900020
         STC   REGWORKB,WKAQICNT         (FOR POSSIBLE ACTION RTNE USE) 35920020
*                                                                       35940020
CKRREPET ST    REGSRCPT,WKAQSCPT        SAVE NEWLY UPDATED VALUE OF     35960020
*                                        SOURCE POINTER IN QUALIFICAT'N 35980020
*                                         FOR BACKUP IF ITERATION FAILS 36000020
*                                                                       36020020
         NI    WKAQSWCH,255-CKRCMTSW    REINITLZ COMMIT SWITCH OFF      36040020
*                                                                       36060020
         LH    REGDEFPT,WKAQDFBK        BACK UP THE DEFINITION TABLE    36080020
*                                        POINTER IMMED BEYOND THE  (    36100020
         B     CKRINTRP                 AND GO INTERPRET THE FIRST OP-  36120020
*                                        CODE IN THE ITER'N PARENTHESES 36140020
*                                                                       36160020
*                                                                       36180020
CKRITDEF EQU   *                                                        36200020
         LA    REGWORKA,DEFFIELD(REGDEFPT)   GET LOC OF ITER'N LIMIT, N 36220020
*                                                                       36240020
         LA    REGDEFPT,1(0,REGDEFPT)   (AND UPDATE DEF'N PT BEYOND IT) 36260020
*                                                                       36280020
         IC    REGWORKB,WKAQICNT        INCREMENT ITERATION COUNT BY 1  36300020
         LA    REGWORKB,1(0,REGWORKB)                                   36320020
         STC   REGWORKB,WKAQICNT                                        36340020
*                                                                       36360020
         CLC   WKAQICNT,0(REGWORKA)     IS ITERATION COUNT UP TO LIMIT  36380020
*                                                                       36400020
         BNL   CKRINTRP                  IF SO, GO INTERPRET NEXT OPCDE 36420020
*                                                                       36440020
         B     CKRREPET                  OTHERWISE, GO REPEAT THE       36460020
*                                                                       36480020
*                                                                       36500020
*********************************************************************** 36520020
*                                                                     * 36540020
*        THE FOLLOWING ROUTINE PROCESSES NESTING TO A SYNTACTIC       * 36560020
*        LINE IN THE DEFINITION. IT RECEIVES CONTROL WHEN A           * 36580020
*        SYMBOLIC-NAME CORRESPONDING TO A DEFINITION LINE IS          * 36600020
*        ENCOUNTERED IN THE DEFINITION.  THE CURRENT NEST INFORMATION * 36620020
*        IS PUSHED DOWN INTO THE NEST LIST, AND A NEW NEST IS BUILT   * 36640020
*        FOR THE NEW LINE.                                            * 36660020
*                                                                     * 36680020
*                                                                     * 36700020
*********************************************************************** 36720020
*                                                                       36740020
CKRSYNS  LA    REGTDFPT,DEFFIELD(REGDEFPT)  OBTAIN LOC IN DEFN TBL      36760020
CKRSYNST EQU   *                                                        36780020
CKRADDNS EQU   *                                                        36800020
         LA    REGWORKB,CKRNESTL(0,REGNSTPT) BE SURE THERE IS SPACE     36820020
         CR    REGWORKB,REGQALPT              FOR ANOTHER NEST          36840020
         BH    CKRNOFLO                        IN THE NEST LIST         36860020
*                                                                       36880020
         MVC   NLSLNEST,WKALNEST        PLACE CURR. NEST AT END OF LIST 36900020
         LR    REGNSTPT,REGWORKB         AND INCREMENT NEST LIST POINTR 36920020
*                                                                       36940020
*                                                                       36960020
         LA    REGDEFPT,2(0,REGDEFPT)   INCR. DEFN PT ON CURR LINE      36980020
         STH   REGDEFPT,WKANDFBK         AND SAVE IN NEST TO GO BACK    37000020
*                                                                       37020020
         MVC   WKANDFPT,0(REGTDFPT)     SAVE DISPL TO DEFN LINE IN      37040020
         LH    REGDEFPT,WKANDFPT         NEST AND AS NEW DEFN PT        37060020
*                                                                       37080020
         IC    REGWORKB,WKANLVLN        INCREMENT LEVEL OF NESTING      37100020
         LA    REGWORKB,1(0,REGWORKB)        BY 1                       37120020
         STC   REGWORKB,WKANLVLN                                        37140020
*                                                                       37160020
         B     CKRINTRP            INTERPRET OPERATOR ON NEW LINE       37180020
*                                                                       37200020
*                                                                       37220020
*********************************************************************** 37240020
*                                                                     * 37260020
*        THE FOLLOWING ROUTINES, M AND N, TEST  THE SOURCE FOR A      * 37280020
*        FORTRAN NAME.  THE TEST FAILS IF THE FIRST CHARACTER         * 37300020
*        EXAMINED IS NOT ALPHABETIC (A THROUGH Z OR $).   IF MORE     * 37320020
*        THAN FIVE ALPHAMERIC CHARACTERS FOLLOW THE FIRST CHARACTER,  * 37340020
*        CKRMNAME (M) FAILS, BUT CKRNAME (N) ISSUES A 'NAME TOO       * 37360020
*        LONG' MESSAGE AND SUCCEEDS AFTER ABSORBING THE LAST          * 37380020
*        ALPHAMERIC CHARACTER.                                        * 37400020
*                                                                     * 37420020
*                                                                     * 37440020
*********************************************************************** 37460020
*                                                                       37480020
CKRMNAME EQU   *                                                        37500020
         NI    WKASWTCH,255-CKRLGNMA    INDICATE LONG NAME NOT ALLOWED  37520020
         B     CKRNAMES            BR TO COMMON PT IN NAME PROC'G       37540020
*                                                                       37560020
CKRNAME  EQU   *                                                        37580020
         OI    WKASWTCH,CKRLGNMA        INDICATE LONG NAME ALLOWED      37600020
*                                                                       37620020
CKRNAMES EQU   *                                                        37640020
         BAL   REGLRETN,CKRGTNB1        GO GET NEXT NON-BLANK SRCE CHAR 37660020
*                                                                       37680020
         TSTAL CKRFAIL                  IF NOT ALPHABETIC, FAIL         37700020
*                                       IN CASE OF SUBSEQ ERROR, SAVE   37720020
*                                        POINTER TO 1ST CHAR OF NAME    37740020
         SVERP REGWORKA                                                 37760020
*                                                                       37780020
         LA    REGCHRCT,0               INITIALIZE COUNT OF SUBSEQ CHRS 37800020
*                                        IN NAME                        37820020
*                                                                       37840020
CKRNAMUP UPDSC                          UPDATE SOURCE POINTER           37860020
*                                                                       37880020
*                                                                       37900020
         BAL   REGLRETN,CKRGTNB1        GO GET NEXT NON-BLANK SRCE CHAR 37920020
*                                                                       37940020
         TSTAM CKRNAMNM                 IF NOT ALPHAMERIC, END NAME     37960020
*                                                                       37980020
         LA    REGCHRCT,1(0,REGCHRCT)   INCR. COUNT OF A/M CHARS AFTER  38000020
*                                        1ST LETTER OF NAME             38020020
*                                                                       38040020
         C     REGCHRCT,CKRFULL6        IS NAME TOO LONG                38060020
         BL    CKRNAMUP                  NO, GO LOOK AT NEXT CHARACTER  38080020
*                                                                       38100020
         TM    WKASWTCH,CKRLGNMA         YES, IS A LONG NAME ALLOWED    38120020
         BO    CKRNAMUP                   YES, GO LOOK AT NEXT CHAR     38140020
         B     CKRFAIL                    NO, FAIL ON M OPERATOR        38160020
*                                                                       38180020
CKRNAMNM EQU   *                        END OF NAME                     38200020
         C     REGCHRCT,CKRFULL6   IS NAME TOO LONG                     38220020
         BL    CKRINTRP             NO, GO INTERPRET NEXT OPERATOR      38240020
         MVI   WKAERRCD,CKRLGNMC    YES, SET UP   ERROR MESSAGE         38260020
         B     CKRREINT              AND GO ISSUE IT BEFORE INTERPRETNG 38280020
*        NUMERIC CONSTANT IN REAL OR INTEGER FORM.  THE K OPERATOR    * 38300020
*        SWITCHES, TYPE (INTEGER,ON OR REAL,OFF),    LENGTH (D OR E), * 38320020
*        AND VALUE (NON-ZERO OR ZERO) DESCRIBE THE NUMBER FOUND OR    * 38340020
*        INDICATE (BY INTEGER, D)  THAT THE SOURCE IS NOT A NUMBER.   * 38360020
*                                                                     * 38380020
*                                                                     * 38400020
*********************************************************************** 38420020
*                                                                       38440020
CKRNUMBR EQU   *                                                        38460020
         SR    REGWORKB,REGWORKB   COUNT INITIALIZATION,                38480020
         ST    REGWORKB,WKALDZCT        ZERO LEADING-ZEROES COUNT,      38500020
         ST    REGWORKB,WKADGTCT             DIGIT COUNT, AND           38520020
         ST    REGWORKB,WKAZROCT             ZERO COUNT                 38540020
*                                                                       38560020
         BAL   REGLRETN,CKRGTNB1   GET NEXT NON-BLANK SOURCE CHARACTER  38580020
*                                                                       38600020
*                                  IN CASE OF SUBSEQUENT ERROR, SAVE    38620020
*                                   POINTER TO BEG. OF EXPECTED NUMBER  38640020
         SVERP REGWORKA                                                 38660020
         MVI   WKAEXPSN,WKAEXINT   INITIALIZE WKAEXPSN. USED AS SWCH TO 38680020
*                                  DIAGNOSE EXTRANEOUS EXPONENTS.       38700020
*                                                                       38720020
*                                  TEST FOR THE BEGINNING OF A NUMBER   38740020
*                                                                       38760020
         CLI   WKASCHRS,CKR0       COMPARE 1ST CHAR TO ZERO             38780020
         BL    CKRTFRAC             LOWER,GO TRY DEC.PT,MAY BE FRACTION 38800020
         BE    CKRJZROS             ZERO, GO COUNT IT AS LEADING-ZERO   38820020
         CLI   WKASCHRS,CKR9        GT 0, IS IT GREATER THAN 9          38840020
         BNH   CKRCTDGT              NO, GO COUNT IT AS A DIGIT         38860020
*                                    NOT A DIGIT                        38880020
CKRTFRAC CLI   WKASCHRS,CKRDOT        IS IT A (DECIMAL) POINT           38900020
         BE    CKRDECPT                YES, GO PERFORM DEC. PT PROCESSG 38920020
*                                      NO                               38940020
CKRNOTNO OI    WKAKSWCH,CKRKFAIL        SOURCE IS NOT A NUMBER          38960020
         B     CKRFAIL             BR TO OPERATOR FAILURE ROUTINE       38980020
*                                                                       39000020
*                                                                       39020020
CKRJZROS L     REGWORKA,WKALDZCT        INCR.COUNT OF LEADING ZEROES    39040020
         LA    REGWORKA,1(0,REGWORKA)    BY 1                           39060020
         ST    REGWORKA,WKALDZCT                                        39080020
*                                                                       39100020
CKRUPBYD UPDSC                     UPDATE SOURCE POINTER                39120020
*                                                                       39140020
         BAL   REGLRETN,CKRGTNB1    AND REQUEST NEXT NON-BLANK CHARACTR 39160020
*                                                                       39180020
         CLI   WKASCHRS,CKR0       COMPARE CHAR TO ZERO                 39200020
         BL    CKRTMIXD             LOWER, GO TRY DEC.PT,MAY BE  X.X    39220020
         BE    CKRTDGCT             ZERO, CHECK WHETHER STILL LEADING 0 39240020
         CLI   WKASCHRS,CKR9        GREATER THAN 0, IS IT GT 9          39260020
         BNH   CKRCTDGT              NO, GO COUNT IT AS A DIGIT         39280020
CKRTMIXD CLI   WKASCHRS,CKRDOT       NOT A DIGIT, IS IT A (DECML) POINT 39300020
         BE    CKRDECPT               YES, GO PERFORM DEC. PT PROCESSG  39320020
*                                                                       39340020
         CLI   WKASCHRS,CKRE          NO, IS IT E FOR EXPONENT FORM     39360020
         BNE   CKRTINTD                NO, GO TRY DOUBLE-PRECISION      39380020
         L     REGWORKA,WKADGTCT   YES, SAVE DIGIT COUNT                39400020
         ST    REGWORKA,WKATENPW    AS POWER OF TEN                     39420020
CKREXPNE NI    WKAKSWCH,255-CKRKLEND   YES, SET LENGTH SW OFF FOR LEN 4 39440020
         B     CKREXPON                 AND GO DO EXPONENT PROCESSING   39460020
*                                                                       39480020
CKRTINTD CLI   WKASCHRS,CKRD          IS IT D FOR DBL-PRECISN EXP. FORM 39500020
         BNE   CKRINTEG                NO, GO PROC.NUMBER AS AN INTEGER 39520020
         L     REGWORKA,WKADGTCT   YES, SAVE DIGIT COUNT                39540020
         ST    REGWORKA,WKATENPW    AS POWER OF TEN                     39560020
CKREXPND OI    WKAKSWCH,CKRKLEND       YES, SET LENGTH SW ON  FOR LEN 8 39580020
         B     CKREXPON                 AND GO DO EXPONENT PROCESSING   39600020
*                                                                       39620020
CKRTDGCT L     REGWORKB,WKADGTCT   DIGIT IS ZERO,                       39640020
         LTR   REGWORKB,REGWORKB    IS IT A LEADING-ZERO                39660020
         BZ    CKRJZROS              YES, GO COUNT IT AS SUCH           39680020
CKRCTDGT L     REGWORKB,WKADGTCT     NO,                                39700020
         LA    REGWORKB,1(0,REGWORKB)     INCREMENT DIGIT COUNT  BY 1   39720020
         ST    REGWORKB,WKADGTCT                                        39740020
         B     CKRUPBYD               AND GO UPDATE SOURCE POINTER      39760020
*                                                                       39780020
CKRINTEG L     REGWORKB,WKADGTCT   IS INTEGER TOO LARGE                 39800020
         C     REGWORKB,CKRINTMX    (MORE THAN 10 DIGITS LONG)          39820020
         BL    CKRINTOK             NO                                  39840020
         BH    CKRINTLG            YES,GREATER THAN 10 DIGITS           39860020
*                                  EXACTLY 10 DIGITS, CHECK FURTHER     39880020
         L     REGSRCPT,WKAERRSC   BACK UP SOURCE PT TO BEGINNING OF NO 39900020
         STH   REGWORKB,WKASRCNT    AND ASK FOR THE 10-CHARACTERS AGAIN 39920020
*                                                                       39940020
         BAL   REGLRETN,CKRGTNBS   GET 10 NON BLANK CHARS.              39960020
         UPDSC                                                          39980020
         CLC   WKASCHRS(L'CKRMAXIG),CKRMAXIG IS INTEG GT MAX ALLOWED    40000020
         BNH   CKRINTOK            IF NOT, INTEGER OK                   40020020
CKRINTLG EQU   *                                                        40040020
*                                                                       40060020
         MVI   WKAERRCD,CKRLGINC    YES, SET UP ERROR MESSAGE           40080020
*                                    AND RETURN POINT AS IF INTEGER OK  40100020
         BAL   REGLRETN,CKRTSTML     AND GO ISSUE ERROR MESSAGE         40120020
*                                                                       40140020
CKRINTOK EQU   *                   SET SWITCHES FOR A VALID INTEGER     40160020
         CLI   WKASCHRS,CKRH       UNLESS FOLLOWED BY H  FOR            40180020
         BE    CKRNOTNO             HOLLERITH CONSTANT                  40200020
         OI    WKAKSWCH,CKRKTYPI        TYPE = INTEGER                  40220020
         NI    WKAKSWCH,255-CKRKLEND    LENGTH = 4                      40240020
*                                                                       40260020
CKRTVALU L     REGWORKB,WKADGTCT   IS VALUE ZERO                        40280020
         C     REGWORKB,WKAZROCT    (DIGIT COUNT = ZERO COUNT)          40300020
         BH    CKRNTZRO              NO                                 40320020
         NI    WKAKSWCH,255-CKRKVALU YES, VALUE = ZERO                  40340020
         B     CKRINTRP            INTERPRET NEXT OPERATOR              40360020
*                                                                       40380020
CKRNTZRO OI    WKAKSWCH,CKRKVALU         VALUE NOT ZERO                 40400020
         B     CKRINTRP                                                 40420020
*                                                                       40440020
*                                                                       40460020
CKRDECPT EQU   *                                                        40480020
         L     REGWORKA,WKADGTCT   SAVE COUNT OF SIGNIF DIGITS LEFT OF  40500020
         ST    REGWORKA,WKATENPW    DECIMAL POINT  AS  POWER OF TEN     40520020
         STC   REGWORKA,WKANONZS     AND AS SWITCH BYTE                 40540020
*                                                                       40560020
         L     REGWORKA,WKASRCCR   SAVE CURR SOURCE LOC. FOR BACKUP     40580020
         ST    REGWORKA,WKACSVSC    IN CASE POINT NOT PART OF NUMBER    40600020
*                                                                       40620020
         UPDSC                     UPDATE SOURCE POINTER BEYOND DEC.PT. 40640020
*                                  CHECK FOR RELATIONAL OR LOGICAL      40660020
*                                  OPERATOR                             40680020
         BAL   REGLRETN,CKRKLOGL   BR TO COMPARE ROUTINE                40700020
*                                                                       40720020
*                                                                       40740020
         BC    CC2,CKRMONUM        CC2 INDICATES NO LOGL OP FOLLOWS     40760020
*                                  DECIMAL POINT                        40780020
         BC    CC1,CKRNOMOR        CC1 INDICATES END OF SOURCE          40800020
*                                  REACHED                              40820020
CKRBAKUP L     REGSRCPT,WKACSVSC   RESTORE SOURCE POINTER TO . OF OP    40840020
*                                                                       40860020
         L     REGWORKB,WKADGTCT   DID ANY DIGITS PRECEDE THE .         40880020
         A     REGWORKB,WKALDZCT    (ZERO OR NOT)                       40900020
         BNZ   CKRINTEG            SOME  DIGIT(S), SOURCE IS AN INTEGER 40920020
*                                         ITERATION                     40940020
         B     CKRNOTNO            OTHERWISE, NOT A NUMBER              40960020
*                                                                       40980020
*                                  SOURCE POINTER IS STILL IMMEDIATELY  41000020
*                                   BEYOND DECIMAL POINT                41020020
CKRMONUM BAL   REGLRETN,CKRGTNB1   GET NEXT NON-BLANK SOURCE CHARACTER  41040020
*                                                                       41060020
         CLI   WKASCHRS,CKR0       IS DECIMAL POINT FOLLOWED BY A DIGIT 41080020
         BL    CKRNOMOR            NO                                   41100020
         CLI   WKASCHRS,CKR9                                            41120020
         BH    CKRNOMOR           NO                                    41140020
         L     REGWORKB,WKADGTCT    YES,ADD 1 TO DIGIT COUNT            41160020
         LA    REGWORKB,1(0,REGWORKB)                                   41180020
         ST    REGWORKB,WKADGTCT                                        41200020
         CLI   WKASCHRS,CKR0        IF DIGIT ZERO,                      41220020
         BNE   CKRNZDIG           BR IF NON-ZERO                        41240020
         L     REGWORKA,WKAZROCT     ADD 1 TO ZERO COUNT                41260020
         LA    REGWORKA,1(0,REGWORKA)                                   41280020
         ST    REGWORKA,WKAZROCT                                        41300020
         CLI   WKANONZS,0          ANY NONZERO DIGITS ENCOUNTERED,      41320020
         BNE   CKRUPMON            YES                                  41340020
         L     REGWORKA,WKATENPW   NO, REDUCE POWER OF 10 FOR DECIMAL   41360020
         S     REGWORKA,=F'1'       PLACE INDICATED BY THIS 0           41380020
         ST    REGWORKA,WKATENPW                                        41400020
         B     CKRUPMON           UPDATE SOURCE POINTER                 41420020
CKRNZDIG MVI   WKANONZS,255        INDICATE NON-ZERO DIGIT ENCOUNTERED  41440020
*                                                                       41460020
CKRUPMON UPDSC                     UPDATE SOURCE POINTER                41480020
*                                                                       41500020
         B     CKRMONUM             AND GO LOOK FOR ANOTHER DIGIT       41520020
*                                                                       41540020
CKRNOMOR EQU   *                   NO MORE DIGITS                       41560020
         L     REGWORKB,WKADGTCT   WERE THERE ANY DIGITS (ZERO OR NOT)  41580020
         A     REGWORKB,WKALDZCT    BEFORE OR AFTER THE .               41600020
         BZ    CKRTKCMT             IF NO DIGITS, NOT A NUMBER          41620020
*                                                                       41640020
CKRRDORE CLI   WKASCHRS,CKRE       IS CHARACTER EXPONENTIAL E OR D      41660020
         BE    CKREXPNE                 E                               41680020
         CLI   WKASCHRS,CKRD                                            41700020
         BE    CKREXPND                 D                               41720020
         NI    WKAKSWCH,255-CKRKLEND    LENGTH 4 (E)                    41820020
         B     CKRREAL            BR TO SET SW FOR REAL NUMBER          41840020
*                                                                       41980020
CKRREAL  NI    WKAKSWCH,255-CKRKTYPI    REAL NUMBER                     42000020
*                                                                       42020020
*                                  IF NO. IS NOT YET ENDED,DIAGNOSE     42040020
*                                   ERROR AND BYPASS REMAINING .DIGITS  42060020
*                                                                       42080020
         CLI   WKASCHRS,WKASPCHR   WAS END OF SOURCE REACHED            42100020
         BE    CKRTVALU            IF SO, NO MORE CHARS. TO EXAMINE     42120020
         GTNB1                     NO                                   42140020
         CLI   WKASCHRS,CKRDOT     IS THERE A DOT AFTER THE NUMBER      42160020
         BNE   CKRTVALU            NO                                   42180020
*                                  YES,                                 42200020
CKRNXDOT SVERP REGWORKA            SAVE POSSIBLE ERROR POINTER TO .     42220020
*                                                                       42240020
         L     REGWORKA,WKASRCCR   THEN SAVE LOCATION OF . FOR BACKUP   42260020
         ST    REGWORKA,WKACSVSC    IN CASE PART OF REL. OR LGL OP      42280020
*                                                                       42300020
         UPDSC                     UPDATE SOURCE POINTER BEYOND DOT     42320020
*                                                                       42340020
*                                  CHECK FOR RELATIONAL OR LOGICAL      42360020
*                                  OPERATOR                             42380020
         BAL   REGLRETN,CKRKLOGL   BR TO COMPARE ROUTINE                42400020
*                                                                       42420020
*                                                                       42440020
         BC    CC2+CC1,CKRBDECL    CC2 OR CC1 INDICATES NO LOGL OP      42460020
*                                  FOLLOWED DECIMAL POINT               42480020
CKRRBAKP L     REGSRCPT,WKACSVSC   REL.OR LGL OP,RESTORE SOURCE PT TO . 42500020
         B     CKRTVALU            AND GO TEST VALUE OF NO. FOR 0       42520020
*                                                                       42540020
*                                  NOT RELATIONAL OR LOGICAL OPERATOR,  42560020
CKRBDECL MVI   WKAERRCD,CKRINVDC   DIAGNOSE INVALID DECIMAL POINT       42580020
         TM    WKAGLCMT,CKRGLCMT   (UNLESS STATEMENT NOT COMMITED, IN   42600020
         BZ    CKRNOTNO             WHICH CASE FAIL NUMBER TEST)        42620020
         LA    REGLRETN,CKRLKDGT    AND THEN CONTINUE TO LOOK FOR MORE  42640020
         B     CKRTSTML              DIGITS AND/OR DECIMAL POINTS       42660020
*                                                                       42680020
CKRPSDGT UPDSC                                                          42700020
*                                                                       42720020
CKRLKDGT CLI   WKASCHRS,WKASPCHR   WAS END OF SOURCE REACHED            42740020
         BE    CKRTVALU            YES. BR TO EVALUATE NUMBER.          42760020
         GTNB1                     GET NEXT NON-BLANK CHAR              42780020
         CLI   WKASCHRS,CKR0                                            42800020
         BL    CKRTRYEX            BR IF NOT A DIGIT                    42820020
         CLI   WKASCHRS,CKR9                                            42840020
         BNH   CKRPSDGT           DIGIT, SPACE PAST IT                  42860020
*                                                                       42880020
CKRTRYEX CLI   WKASCHRS,CKRD       IF NOT DIGIT, IS IT AN EXPONENT      42900020
         BNE   CKRTRYX1            NO.  BR.                             42920020
         CLI   WKAEXPSN,WKAEXINT   YES.  IS IT THE FIRST EXPONENT       42940020
         BE    CKREXPND            YES. BR TO SET WKAKSWCH              42960020
         B     CKRBMRX1            NO. INDICATE INVALID EXPONENT.       42980020
CKRTRYX1 CLI   WKASCHRS,CKRE       IF NOT A D, IS IT AN E               43000020
         BNE   CKRTRYDT            NO. BR.                              43020020
         CLI   WKAEXPSN,WKAEXINT   YES.  IS IT THE FIRST EXPONENT       43040020
         BE    CKREXPNE            YES. BR TO SET WKAKSWCH              43060020
CKRBMRX1 SVERP REGWORKA            NO. INDICATE INVALID EXPONENT        43080020
         MVI   WKAERRCD,CKRXPNGC   INVALID EXP., DIAGNOSE.              43100020
         BAL   REGLRETN,CKRBMRLX   BR TO ISSUE MSG                      43120020
*                                  BYPASS REMAINDER OF EXPONENT         43140020
CKRBMRX2 UPDSC                     UPDATE SOURCE POINTER                43160020
         GTNB1                     GET NEXT NON-BLANK CHARACTER         43180020
         CLI   WKASCHRS,CKRMINUS   SPECIAL CHECK FOR SIGN               43200020
         BE    CKRBMRX2                 AFTER D OR E                    43220020
         CLI   WKASCHRS,CKRPLUS                                         43240020
         BE    CKRBMRX2            BR TO BYPASS SIGN                    43260020
         B     CKRLKDGT            CHECK FOR SUBSEQUENT DIGITS          43280020
*                                                                       43300020
CKRTRYDT CLI   WKASCHRS,CKRDOT     NOT A DIGIT, IS IT A DOT             43320020
         BNE   CKRTVALU            NO,NUMBER EXHAUSTED                  43340020
         B     CKRNXDOT            ANOTHER DOT                          43360020
*                                                                       43380020
CKRTKCMT EQU   *                   . WITHOUT DIGITS,                    43400020
         TM    WKAQSWCH,CKRCMTSW    ARE WE COMMITTED TO FINDING A NUMBR 43420020
         BZ    CKRNOTNO            IF NOT,FAIL                          43440020
         MVI   WKAERRCD,CKRKWODC    IF SO, SET UP ERROR MESSAGE (REAL   43460020
*                                    NUMBER MUST HAVE AT LEAST 1 DIGIT) 43480020
         LA    REGLRETN,CKRRDORE     AND RETURN POINTER AS IF THERE     43500020
*                                     WERE DIGITS                       43520020
         B     CKRTSTML                AND GO ISSUE ERROR MESSAGE       43540020
*                                                                       43560020
*                                                                       43580020
CKREXPON EQU   *                   DIAGNOSE FORM OF EXPONENT            43600020
         NI    WKAKSWCH,255-CKRKTYPI    REAL NUMBER                     43620020
*                                  SAVE POINTER TO E OR D IN CASE       43640020
         SVERP REGWORKA             OF EXPONENT ERROR                   43660020
*                                                                       43680020
         UPDSC                     UPDATE SOURCE POINTER BEYOND E OR D  43700020
*                                                                       43720020
         BAL   REGLRETN,CKRGTNB1   GET 1ST CHAR  OF EXPONENT FROM SOURC 43740020
*                                                                       43760020
         MVI   WKAEXPSN,CKRPLUS    INITLZ FOR NO SIGN, MEANING POSITIVE 43780020
*                                                                       43800020
         CLI   WKASCHRS,CKRMINUS   SKIP SIGN, IF ANY                    43820020
         BE    CKRUPBYS            -                                    43840020
         CLI   WKASCHRS,CKRPLUS                                         43860020
         BNE   CKRTXDGT            BR IF NEITHER - NOR +                43880020
*                                                                       43900020
CKRUPBYS IC    REGWORKA,WKASCHRS   SAVE ACTUAL SIGN                     43920020
         STC   REGWORKA,WKAEXPSN                                        43940020
         UPDSC                                                          43960020
*                                                                       43980020
         GTNB1                                                          44000020
*                                                                       44020020
CKRTXDGT CLI   WKASCHRS,CKR9       TEST FOR A DIGIT IN EXPONENT         44040020
         BH    CKRINVEX            INVALID, IF NO DIGITS                44060020
         CLI   WKASCHRS,CKR0                                            44080020
         BL    CKRINVEX           INVALID, IF NO DIGITS                 44100020
         BAL   REGLRETN,CKREVALU   EVALUATE THE EXPONENT                44120020
         LA    REGWORKB,3          BE SURE EXPONENT HAS FEWER THAN 3    44140020
         CH    REGWORKB,WKACNTDG    DIGITS (INCLUDING LEADING ZEROES)   44160020
         BNH   CKRINVEX              OTHERWISE, INVALID                 44180020
         CLI   WKAEXPSN,CKRMINUS  IS EXPONENT NEGATIVE                  44200020
         BNE   CKRTSZRO           NO                                    44220020
         LNR   REGCHRCT,REGCHRCT   SIGN THE EXPONENT                    44240020
CKRTSZRO L     REGWORKB,WKADGTCT   IS NUMBER ZERO                       44260020
         C     REGWORKB,WKAZROCT                                        44280020
         BE    CKRCKSIZ            IF SO, EXPONENT ALONE IS ORD.OF MAG. 44300020
         A     REGCHRCT,WKATENPW   NO,COMBINE ORDER OF MAG OF NUMBER    44320020
*                                   W/O EXPON WITH VALUE OF EXPONENT    44340020
*                                    FOR RANGE TEST                     44360020
CKRCKSIZ C     REGCHRCT,CKRF0076   IS MAGNITUDE BETWEEN 10**(-78)       44380020
         BH    CKRBDSIZ                      AND  10**76                44400020
         C     REGCHRCT,CKRFM078                                        44420020
         BNL   CKRTRYEX            YES, SIZE ACCEPTABLE                 44440020
CKRBDSIZ L     REGWORKB,WKADGTCT   NO,                                  44460020
         C     REGWORKB,WKAZROCT   IF NUMBER IS ZERO,                   44480020
         BE    CKRINVEX             DIAGNOSE INVALID EXPONENT,          44500020
         MVI   WKAERRCD,CKRINVRC   NONZERO, DIAGNOSE OUT OF LIMITS      44520020
         B     CKRCREAL            AND SET RETURN TO CONTINUE           44540020
*                                                                       44560020
CKRINVEX MVI   WKAERRCD,CKRXPNGC    INVALID EXP.,DIAGNOSE AND THEN      44580020
CKRCREAL LA    REGLRETN,CKRTRYEX   CONTINUE TO SCAN FOR EXTRANEOUS EXP. 44600020
CKRBMRLX TM    WKAGLCMT,CKRGLCMT   (UNLESS STATEMENT NOT COMMITTED, IN  44620020
         BZ    CKRNOTNO             WHICH CASE FAIL NUMBER TEST)        44640020
         B     CKRTSTML            GO REPORT ERROR                      44660020
*                                                                       44680020
*        ROUTINE FOR K OPERATOR TO COMPARE SOURCE CHARS FOR             44700020
*        POSSIBLE LOGICAL OR RELATIONAL OPERATOR.                       44720020
*        EXIT WITH ONE OF THREE CONDITION CODES...                      44740020
*              CC 0                LOGL OR RELATIONAL OPERATOR FOUND    44760020
*              CC 1                END OF SOURCE FOUND                  44780020
*              CC 2                NUMBER OR EXPONENT FOUND             44800020
*                                       OR NON-NUMERIC                  44820020
*                                                                       44840020
*        CALLED BY  BAL  REGLRETN,CKRKLOGL                              44860020
*                                                                       44880020
CKRKLOGL ST    REGLRETN,WKASVRTN                                        44900020
         L     REGWORKA,CKRFULL2                                        44920020
         STH   REGWORKA,WKASRCNT   REQUEST NEXT TWO                     44940020
         BAL   REGLRETN,CKRGTNBS   NON-BLANK CHARS FROM SOURCE          44960020
*                                                                       44980020
         CLI   WKASCHRS,CKR0       IF THE NEXT CHAR IS A DIGIT          45000020
         BL    CKRKLOG1            SET CONDITION CODE = 2               45020020
         CLI   WKASCHRS,CKR9       AND EXIT                             45040020
         BNH   CKRKLNM             FROM ROUTINE                         45060020
CKRKLOG1 CLI   WKAMVCNT+1,0        WAS END OF SOURCE REACHED            45080020
         BE    CKRKLND             YES. EXIT WITH CC 1.                 45100020
         LH    REGWORKA,WKASCHRS   NO. TEST FOR RELATIONAL OP  EQ       45120020
         CH    REGWORKA,CKREQ                                           45140020
         BE    CKRKLBCK            BR TO EXIT WITH CC 0                 45160020
         CLI   WKASCHRS,CKRE       NO EQ, IS IT EXPONENTIAL E OR D      45180020
         BE    CKRKLNM             IF E, EXIT WITH CC 2                 45200020
         CLI   WKASCHRS,CKRD                                            45220020
         BE    CKRKLNM             IF D, EXIT WITH CC 2                 45240020
         CH    REGWORKA,CKRGT      TEST FOR GT                          45260020
         BE    CKRKLBCK                           YES,  CC 0            45280020
         CH    REGWORKA,CKRLT                LT                         45300020
         BE    CKRKLBCK                           YES,  CC 0            45320020
         CH    REGWORKA,CKRGE                GE                         45340020
         BE    CKRKLBCK                           YES,  CC 0            45360020
         CH    REGWORKA,CKRLE                LE                         45380020
         BE    CKRKLBCK                           YES,  CC 0            45400020
         CH    REGWORKA,CKRNE                NE                         45420020
         BE    CKRKLBCK                           YES,  CC 0            45440020
         CH    REGWORKA,CKRORE     CHK FOR LOGICAL OP   OR              45460020
         BE    CKRKLBCK                           YES,  CC 0            45480020
         CH    REGWORKA,CKRAN                AN(D)                      45500020
         BE    CKRKLBCK                           YES,  CC 0            45520020
CKRKLNM  LPR   R0,REGLRETN         SET CONDITION CODE = 2               45540020
         B     CKRKLRTN            EXIT                                 45560020
CKRKLND  LNR   R0,REGLRETN         SET CC  = 1                          45580020
         B     CKRKLRTN            EXIT                                 45600020
CKRKLBCK SR    R0,R0               SET CC = 0                           45620020
CKRKLRTN L     REGLRETN,WKASVRTN   RESTORE RETURN REG                   45640020
         BR    REGLRETN            RETURN                               45660020
*                                                                       45680020
*                                                                       45700020
*                                                                       45720020
*********************************************************************** 45740020
*                                                                     * 45760020
*        THE FOLLOWING ROUTINE TESTS THE SOURCE FOR A STATEMENT       * 45780020
*        NUMBER, 1 TO 5 SIGNIFICANT DIGITS, VALUE OF NUMBER           * 45800020
*        GREATER THAN ZERO.                                           * 45820020
*                                                                     * 45840020
*                                                                     * 45860020
*********************************************************************** 45880020
*                                                                       45900020
CKRSTATM EQU   *                   TEST FOR A STATEMENT NUMBER          45920020
*                                                                       45940020
         BAL   REGLRETN,CKRGTNB1   GET NEXT NON-BLANK SOURCE CHAR       45960020
*                                                                       45980020
         SVERP REGWORKB            SAVE POSSIBLE ERROR POINTER          46000020
         LA    REGCHRCT,0          INITLZ NO. OF SIGNIF. DIGITS TO 0    46020020
*                                                                       46040020
         CLI   WKASCHRS,CKRPLUS    TEST FOR SIGN (INVALID IF PRESENT)   46060020
         BE    CKRSSGND                +                                46080020
         CLI   WKASCHRS,CKRMINUS       -                                46100020
         BNE   CKRTSDGT            IF NO SIGN,BR TO SEEK DIGITS         46120020
CKRSSGND LA    REGCHRCT,2048(0,REGCHRCT)    SIGNED, INVALIDATE DIGIT CT 46140020
         UPDSC                     BUT BYPASS SIGN AND EXAMINE DIGITS   46160020
         GTNB1                                                          46180020
*                                                                       46200020
CKRTSDGT EQU   *                                                        46220020
         CLI   WKASCHRS,CKR0       IF NOT A DIGIT, FAIL,                46240020
         BL    CKRFAIL              NOT A STATEMENT NUMBER              46260020
         CLI   WKASCHRS,CKR9                                            46280020
         BH    CKRFAIL            NOT A STATEMENT NUMBER                46300020
CKRTLDG0 CLI   WKASCHRS,CKR0       IS CHARACTER A LEADING ZERO          46320020
         BNE   CKRPAST0            NO                                   46340020
         UPDSC                     YES, UPDATE SOURCE POINTER           46360020
*                                                                       46380020
         BAL   REGLRETN,CKRGTNB1    AND REQUEST ANOTHER CHARACTER       46400020
*                                                                       46420020
         B     CKRTLDG0            LOOK FOR ANOTHER LEADING ZERO        46440020
*                                                                       46460020
CKRPAST0 EQU   *                                                        46480020
*                                                                       46500020
CKRTSNOD CLI   WKASCHRS,CKR0       IS CHARACTER A DIGIT                 46520020
         BL    CKRTSNOL               NO                                46540020
         CLI   WKASCHRS,CKR9                                            46560020
         BH    CKRTSNOL              NO                                 46580020
         LA    REGCHRCT,1(0,REGCHRCT) YES,   INCR. DIGIT COUNT BY 1     46600020
*                                                                       46620020
         UPDSC                          UPDATE SOURCE POINTER           46640020
*                                                                       46660020
         GTNB1                                                          46680020
*                                                                       46700020
         B     CKRTSNOD                 AND TEST FOR ANOTHER SIGNIF.DGT 46720020
*                                                                       46740020
CKRTSNOL C     REGCHRCT,CKRFULL6        IS STATEMENT NO 1-5 SIGNIFICANT 46760020
         BNL   CKRBDSNO                  DIGITS IN LENGTH               46780020
         LTR   REGCHRCT,REGCHRCT                                        46800020
         BNZ   CKRINTRP                 YES, GOOD STATEMENT NUMBER      46820020
CKRBDSNO EQU   *                   NO,                                  46840020
         MVI   WKAERRCD,CKRINVSC   SET UP ERROR MESSAGE AND GO ISSUE IT 46860020
         B     CKRREINT             THEN ACCEPT SOURCE AS STATEMENT NO. 46880020
*                                                                       46900020
*                                                                       46920020
*                                                                       46940020
*********************************************************************** 46960020
*                                                                     * 46980020
*        THE FOLLOWING ROUTINE TESTS THE SOURCE FOR A HOLLERITH FIELD * 47000020
*        DESCRIPTOR OR A HOLLERITH CONSTANT.  THE TEST FAILS UNLESS   * 47020020
*        A WIDTH VALUE FOLLOWED BY H IS FOUND IN THE SOURCE.          * 47040020
*                                                                     * 47060020
*                                                                     * 47080020
*********************************************************************** 47100020
*                                                                       47120020
CKRHOLLR EQU   *                                                        47140020
         BAL   REGLRETN,CKRGTNB1   GET NEXT NON-BLANK CHAR.FROM SOURCE  47160020
*                                                                       47180020
         CLI   WKASCHRS,CKR0       FAIL IMMEDIATELY IF 1ST CHARACTER    47200020
         BL    CKRFAIL              IS NOT A DIGIT                      47220020
         CLI   WKASCHRS,CKR9                                            47240020
         BH    CKRFAIL             IS NOT A DIGIT                       47260020
*                                  SOURCE BEGINS WITH A DIGIT,EVALUATE  47280020
         BAL   REGLRETN,CKREVALU   THIS AND CONSECUTIVE DIGITS TO       47300020
*                                   COMPUTE A WIDTH VALUE (SET UP ERROR 47320020
*                                    POINTER TO 1ST DIGIT)              47340020
*                                  (VALUE RET'D IN WKAVALUE & REGCHRCT) 47360020
         ST    REGCHRCT,WKAWIDTH   SAVE VALUE AS WIDTH                  47380020
*                                                                       47400020
         CLI   WKASCHRS,C'H'       IS CHAR AFTER WIDTH AN H             47420020
         BNE   CKRFAIL             NO, FAIL                             47440020
         UPDSC                      UPDATE THE SOURCE POINTER BEYOND H  47460020
         LTR   REGCHRCT,REGCHRCT   IF WIDTH = 0,                        47480020
         BZ    CKRINVLW            DIAGNOSE AND ACCEPT, OTHERWISE,      47500020
         C     REGCHRCT,CKRF255    CHECK FOR WIDTH GREATER THAN 255     47520020
         BH    CKRWHIGH            DIAGNOSE IF TOO BIG                  47540020
CKRSKIPH EQU   *                                                        47560020
         STH   REGCHRCT,WKASRCNT   SKIP OVER THE WIDTH                  47580020
         BAL   REGLRETN,CKRSKANY     OF CHARACTERS                      47600020
*                                                                       47620020
         TM    WKASNDSW,EXCNSEND   WAS END OF SOURCE ENCOUNTERED        47640020
         BO    CKRINCPH             IF SO, GO INDICATE INCOMPL.H ERROR  47660020
*                                   NO,                                 47680020
         UPDSC                     UPDATE SOURCE PT BEYOND CHARS SKIPPD 47700020
         B     CKRINTRP            GO INTERPRET NEXT OPERATOR           47720020
*                                                                       47740020
CKRINVLW MVI   WKAERRCD,CKRINVWC   SET UP ERROR MESSAGE FOR INVALID W   47760020
         B     CKRREINT             AND ISSUE IT BEFORE ACCEPTING H FLD 47780020
*                                                                       47800020
CKRWHIGH MVI   WKAERRCD,CKRINVWC   SET UP ERROR MSG FOR INVALID W       47820020
         LA    REGLRETN,CKRSKIPH   AND ISSUE IT BEFORE RTNING TO SPACE  47840020
         B     CKRTSTML            PAST H FIELD                         47860020
*                                                                       47880020
CKRINCPH MVI   WKAERRCD,CKRINCHT   SET UP TERMINAL ERROR MESSAGE FOR    47900020
*                                   INCOMPLETE H FIELD AND              47920020
         B     CKRTMRET              STOP CHECKING STATEMENT            47940020
*                                                                       47960020
*                                                                       47980020
*                                                                       48000020
*********************************************************************** 48020020
*                                                                     * 48040020
*        THE FOLLOWING ROUTINE TESTS THE SOURCE FOR A CHARACTER       * 48060020
*        STRING (MAXIMUM LENGTH 255 CHARACTERS) ENCLOSED IN SINGLE    * 48080020
*        QUOTES.                                                      * 48100020
*                                                                     * 48120020
*                                                                     * 48140020
*********************************************************************** 48160020
*                                                                       48180020
CKRCSTRG EQU   *                   TEST FOR CHARACTER STRING IN QUOTES  48200020
*                                                                       48220020
         BAL   REGLRETN,CKRGTNB1   GET NEXT NON-BLANK CHARACTER         48240020
*                                                                       48260020
         CLI   WKASCHRS,CKRSGLQT   IF FIRST CHARACTER IS NOT '          48280020
         BNE   CKRFAIL              FAIL IMMEDIATELY, OTHERWISE,        48300020
*                                  COMMITTED TO CHARACTER STRING        48320020
*                                  SAVE POSSIBLE ERROR POINTER          48340020
         SVERP REGWORKA                                                 48360020
         LA    REGCHRCT,0          INITLZ STRING LENGTH TO ZERO         48380020
         LA    REGWORKA,1          SET UP TO REQUEST 1 CHARACTER        48400020
         STH   REGWORKA,WKASRCNT   AT A TIME                            48420020
*                                                                       48440020
CKRUPDCS UPDSC                     UPDATE SOURCE POINTER                48460020
*                                  AND REQUEST NEXT CHAR.(MAY BE BLANK) 48480020
         BAL   REGLRETN,CKRGTANY    FROM SOURCE                         48500020
*                                                                       48520020
         CLI   WKASCHRS,CKRSGLQT   IS CHARACTER A SINGLE QUOTE          48540020
         BE    CKRFDQTE             YES                                 48560020
         TM    WKASNDSW,EXCNSEND    NO, IS SOURCE EXHAUSTED             48580020
         BO    CKRQTMIS              IF SO,ERROR--CLOSING QUOTE MISSING 48600020
CKRCTSTR C     REGCHRCT,CKRF255      NO, IS COUNT ALREADY UP TO 255     48620020
         BNL   CKRLNGCS               IF SO,ERROR-CHAR.STRING TOO LONG  48640020
         LA    REGCHRCT,1(0,REGCHRCT) NO, INCREMENT STRING COUNT BY 1   48660020
         B     CKRUPDCS                AND REQUEST NEXT CHARACTER       48680020
*                                                                       48700020
CKRFDQTE UPDSC                     UPDATE SOURCE POINTER                48720020
*                                   AND REQUEST NEXT CHARACTER          48740020
         BAL   REGLRETN,CKRGTANY     (MAY BE BLANK) FROM SOURCE         48760020
*                                                                       48780020
         CLI   WKASCHRS,CKRSGLQT   IS IT ANOTHER SINGLE QUOTE           48800020
         BE    CKRCTSTR             YES, GO COUNT 2 QUOTES AS 1 CHAR(') 48820020
*                                                                       48840020
         LTR   REGCHRCT,REGCHRCT    NO,END OF STRING, ANY CHARS.        48860020
         BNZ   CKRINTRP              YES, GO INTERPRET NEXT OPERATOR    48880020
*                                                                       48900020
         MVI   WKAERRCD,CKREMTCC     NO, DIAGNOSE LITERAL WITHOUT CHARS 48920020
         B     CKRREINT               BEFORE INTERPRETING NEXT OP-CODE  48940020
*                                                                       48960020
CKRQTMIS MVI   WKAERRCD,CKRQTMST   SET UP ERROR MSG FOR CLOSING ' MISSG 48980020
         B     CKRTMRET             AND ISSUE TERMINAL ERROR MESSAGE    49000020
*                                                                       49020020
CKRLNGCS MVI   WKAERRCD,CKRLGCST   SET UP ERROR MSG FOR LONG CHAR. STRG 49040020
         B     CKRTMRET              AND ISSUE TERMINAL ERROR MESSAGE   49060020
*                                                                       49080020
*                                                                       49100020
*                                                                       49120020
*********************************************************************** 49140020
*                                                                     * 49160020
*        THE FOLLOWING ROUTINES, CKRQUOTE AND CKRNOTQT, TEST THE      * 49180020
*        SOURCE FOR THE PRESENCE OR ABSENCE, RESPECTIVELY, OF THE     * 49200020
*        LITERAL CITED.                                               * 49220020
*        IN EITHER TEST, HOWEVER, IF THE LITERAL IS MATCHED, THE      * 49240020
*        SOURCE POINTER IS UPDATED BEYOND IT.                         * 49260020
*                                                                     * 49280020
*                                                                     * 49300020
*********************************************************************** 49320020
*                                                                       49340020
CKRQUOTE OI    WKASWTCH,CKRMATCH        INDICATE LITERAL MATCH REQUIRED 49360020
         B     CKRQTCOM                 AND BR TO COMMON PROCESSING     49380020
CKRNOTQT NI    WKASWTCH,255-CKRMATCH    INDICATE NON-MATCH REQUIRED     49400020
*                                                                       49420020
CKRQTCOM LA    REGCHRCT,0                                               49440020
         IC    REGCHRCT,DEFFIELD(REGDEFPT)   GET LENGTH OF LITERAL      49460020
         STH   REGCHRCT,WKASRCNT        AND USE AS LENGTH OF REQUEST    49480020
         AIF   ('&ITNLDBG'  EQ  '').NOSZCK                              49500020
         LTR   REGCHRCT,REGCHRCT        (BE SURE LENGTH                 49520020
         BZ    CKRBDLTS                   IS IN ALLOWABLE RANGE)        49540020
         CLI   WKASRCNT+1,WKASCMAX                                      49560020
         BH    CKRBDLTS                 (OTHERWISE INDICATE MALFUNCTN)  49580020
.NOSZCK  ANOP                                                           49600020
         BAL   REGLRETN,CKRGTNBS         FOR NON-BLANK SOURCE CHARS     49620020
         LA    REGWORKB,DEFARGUM(REGDEFPT)   GET POINTER TO LITERAL     49640020
         LA    REGDEFPT,1(REGCHRCT,REGDEFPT) UD DEFN POINTER PAST LITRL 49660020
         BCTR  REGCHRCT,0          DECR. LENGTH BY 1 FOR EX INSTRUCTION 49680020
         EX    REGCHRCT,CKRCOMPR   COMARE LITERAL TO SOURCE CHARS OBTND 49700020
         BNE   CKRNOMAT            NOT A MATCH                          49720020
*                                                                       49740020
         UPDSC                     MATCH, UPDATE SOURCE POINTER         49760020
*                                                                       49780020
         TM    WKASWTCH,CKRMATCH   IS A MATCH WHAT IS REQUIRED          49800020
         BO    CKRINTRP             YES, TEST IS SUCCESSFUL             49820020
         B     CKRFAIL              NO, FAIL                            49840020
*                                                                       49860020
CKRNOMAT TM    WKASWTCH,CKRMATCH   NOT MATCHED, IS A MATCH REQUIRED     49880020
         BZ    CKRINTRP             NO, TEST IS SUCCESSFUL              49900020
         B     CKRFAIL              YES, FAIL                           49920020
*                                                                       49940020
*                                                                       49960020
*                                                                       49980020
*********************************************************************** 50000020
*                                                                     * 50020020
*        THE FOLLOWING ROUTINES, CKRSCAN AND CKRSCANF, SCAN THE       * 50040020
*        REMAINDER OF THE SOURCE FOR THE PRESENCE OR ABSENCE,         * 50060020
*        RESPECTIVELY, OF THE GIVEN CHARACTER.                        * 50080020
*                                                                     * 50100020
*                                                                     * 50120020
CKRLNQLK DC    A(CKRQUALL)         LENGTH OF QUALIFICATION              50140020
*********************************************************************** 50160020
*                                                                       50180020
CKRSCAN  OI    WKASWTCH,CKRMATCH   INDICATE THAT FIND IS REQUIRED       50200020
         B     CKRSCANB                 AND BR TO COMMON PROCESSING     50220020
*                                                                       50240020
CKRSCANF NI    WKASWTCH,255-CKRMATCH    FIND NOT REQUIRED               50260020
CKRSCANB IC    REGWORKA,DEFFIELD(REGDEFPT)   OBTAIN GIVEN CHAR.         50280020
         STC   REGWORKA,WKASRCHX                                        50300020
         BAL   REGLRETN,CKRSERCH   SEARCH REMAINDER OF SOURCE FOR MATCH 50320020
         LA    REGDEFPT,1(0,REGDEFPT)     TO IT, THEN UPDATE DEF'N PT   50340020
         TM    WKASNDSW,EXCNSEND   WAS MATCH FOUND BEFORE END OF SOURCE 50360020
         BO    CKRNOMAT             NO                                  50380020
         TM    WKASWTCH,CKRMATCH    YES, IS FIND REQUIRED               50400020
         BO    CKRINTRP              YES, TEST IS SUCCESSFUL            50420020
         B     CKRFAIL               NO, FAIL                           50440020
*                                                                       50460020
*                                                                       50480020
*********************************************************************** 50500020
*                                                                       50520020
*                                                                     * 50540020
*        THE FOLLOWING ROUTINE INVOKES SOME ACTION CODE SUBROUTINE    * 50560020
*        TO PERFORM A SPECIAL-PURPOSE TEST OR OTHER TASK.             * 50580020
*                                                                     * 50600020
*                                                                     * 50620020
*********************************************************************** 50640020
*                                                                       50660020
CKRACTN  LA    REGTDFPT,DEFFIELD(REGDEFPT)  OBTAIN LOC IN DEFN TBL      50680020
         LA    REGDEFPT,1(0,REGDEFPT)   INCR DEFN. PT PAST ACTION CODE  50700020
         B     CKRACTNB                 AND BR TO COMMON PROCESSING     50720020
CKRACTNT EQU   *                                                        50740020
         LA    REGDEFPT,2(0,REGDEFPT)   INCR. DEFN. PT PAST TABLE REF   50760020
*                                        TO POINT TO NEXT OPERATOR      50780020
CKRACTNB EQU   *                                                        50800020
         MVI   WKAERRCD,0               ZERO ERROR CODE                 50820020
*                                                                       50840020
*                                                                       50860020
*********************************************************************** 50880020
*                                                                     * 50900020
*        THE FOLLOWING SECTION DETERMINES THE ROUTINE ASSOCIATED      * 50920020
*        WITH THE GIVEN ACTION CODE.                                  * 50940020
*                                                                     * 50960020
*        AN INVALID ACTION CODE IS DETECTED.                          * 50980020
*                                                                     * 51000020
*                                                                     * 51020020
*********************************************************************** 51040020
         IC    REGOPCDE,0(REGTDFPT)     OBTAIN  ACTION CODE             51060020
         AIF   ('&ITNLDBG' EQ '').NOACCHK                               51080020
         CH    REGOPCDE,CKRINVAC        IS ACTION CODE VALID            51100020
         BNL   CKRACFAL            INDICATE AN INVALID ACTION CODE      51120020
.NOACCHK ANOP                                                           51140020
*                                  WILL HALT ON LH IF NOT AN EVEN NO.   51160020
         LH    REGOPNDX,CKRACNDX(REGOPCDE)   ACTION CODE INDEXES B TBL  51180020
         B     CKRACTN(REGOPNDX)        BRANCH TO APPROP. ACTION RTNE   51200020
*                                                                       51220020
*                                                                       51240020
*                                                                       51260020
*********************************************************************** 51280020
*                                                                     * 51300020
*        THE FOLLOWING ROUTINES, 100 SERIES, PERFORM TESTS            * 51320020
*        ASSOCIATED WITH THE OUTCOME OF A PRIOR K OPERATOR            * 51340020
*        CHECK TO DETERMINE THE CHARACTERISTICS OF A NUMBER.          * 51360020
*                                                                     * 51380020
*                                                                     * 51400020
*********************************************************************** 51420020
*                                                                       51440020
*  100                             100, TEST FOR NON-ZERO INTEGER       51460020
CKRAR100 TM    WKAKSWCH,CKRKFAIL                                        51480020
         BO    CKRACTRT             IF SW SETTINGS INVALID,RETURN IMMED 51500020
*                                                                       51520020
         TM    WKAKSWCH,CKRKTYPI+CKRKVALU    IF TYPE=INTEG,VALUE NONZRO 51540020
         BO    CKRACTRT                       OK                        51560020
*                                                                       51580020
         MVI   WKAERRCD,CKRNZIRC             OTHERWISE,SET ERR.MSG CODE 51600020
         B     CKRACTRT                       BEFORE RETURNING          51620020
*                                                                       51640020
*                                                                       51660020
*                                                                       51680020
*  101                             101, TEST FOR NON-ZERO               51700020
CKRAR101 TM    WKAKSWCH,CKRKFAIL                                        51720020
         BO    CKRACTRT             IF SW SETTINGS INVALID,RETURN IMMED 51740020
         TM    WKAKSWCH,CKRKVALU                                        51760020
         BO    CKRACTRT            IF NON-ZERO, OK                      51780020
         MVI   WKAERRCD,CKRNZRQC    OTHERWISE, SET ERROR MESSAGE CODE   51800020
         B     CKRACTRT             BEFORE RETURNING                    51820020
*                                                                       51840020
*                                                                       51860020
*                                                                       51880020
*  102                                                                  51900020
CKRAR102 TM    WKAKSWCH,CKRKTYPI   102, TEST FOR INTEGER                51920020
         BO    CKRACTRT             OK (IF A NUMBER)                    51940020
         MVI   WKAERRCD,CKRINTRC    NUMBER NOT INTEGER,SET ERR MSG CODE 51960020
         B     CKRACTRT              BEFORE RETURNING                   51980020
*                                                                       52000020
*                                                                       52020020
*                                                                       52040020
*  103                             103,                                 52060020
CKRAR103 EQU   *                                                        52080020
         MVC   WKASVKSW,WKAKSWCH   SAVE K OPERATOR SWITCHES             52100020
         B     CKRACTRT             (OF REAL PORTION OF COMPLEX NUMBER) 52120020
*                                                                       52140020
*                                                                       52160020
*                                                                       52180020
*  104                             104,                                 52200020
CKRAR104 TM    WKAKSWCH,CKRKFAIL   COMPLEX NUMBER TEST                  52220020
         BO    CKRACTRT             RETURN IMMED.IF NOT A NUMBER        52240020
*                                                                       52260020
         TM    WKAKSWCH,CKRKTYPI   BE SURE BOTH PORTIONS ARE REAL,      52280020
         BO    CKRABDCX              RATHER  THAN INTEGERS              52300020
         TM    WKASVKSW,CKRKTYPI                                        52320020
         BO    CKRABDCX            (OTHERWISE DIAGNOSE)                 52340020
*                                                                       52360020
         TM    WKAKSWCH,CKRKLEND   BE SURE BOTH PORTIONS HAVE THE SAME  52380020
         BO    CKRATLND             LENGTH ATTRIBUTE                    52400020
         TM    WKASVKSW,CKRKLEND                                        52420020
         BZ    CKRACTRT             BOTH REAL, LENGTH 4, OK             52440020
CKRABDCX MVI   WKAERRCD,CKRICPXC    LENGTHS INCOMPATIBLE,SET ERR MSG CD 52460020
         B     CKRACTRT              BEFORE RETURNING                   52480020
*                                                                       52500020
CKRATLND TM    WKASVKSW,CKRKLEND                                        52520020
         BO    CKRACTRT            BOTH REAL, LENGTH 8, OK              52540020
         B     CKRABDCX            LENGTHS INCOMPATIBLE                 52560020
*                                                                       52580020
*                                                                       52600020
*                                                                       52620020
*  105                             105,                                 52640020
CKRAR105 TM    WKAKSWCH,CKRKFAIL   TEST FOR DATA SET REFERENCE NO. FORM 52660020
         BO    CKRACTRT             IF NOT A NUMBER, RETURN IMMEDIATELY 52680020
*                                                                       52700020
         TM    WKAKSWCH,CKRKTYPI+CKRKVALU    MUST BE A NONZERO INTEGER, 52720020
         BNO   CKRABDSN                                                 52740020
         LA    REGWORKB,2                                               52760020
         C     REGWORKB,WKADGTCT                                        52780020
         BNL   CKRACTRT                      NO MORE THAN 2 DIGITS LONG 52800020
*                                                                       52820020
CKRABDSN MVI   WKAERRCD,CKRIDSNC             OTHERWISE,SET ERR MSG CODE 52840020
         B     CKRACTRT                       BEFORE RETURNING          52860020
*                                                                       52880020
*                                                                       52900020
*                                                                       52920020
* 106                              106, TEST FOR REAL NUMBER            52940020
CKRAR106 EQU   *                                                        52960020
         TM    WKAKSWCH,CKRKFAIL    IF NOT A NUMBER,                    52980020
         BO    CKRACTRT              RETURN IMMEDIATELY                 53000020
*                                                                       53020020
         TM    WKAKSWCH,CKRKTYPI                                        53040020
         BZ    CKRACTRT            IF REAL RATHER THAN INTEGER, OK      53060020
         MVI   WKAERRCD,CKRRLRQC    OTHERWISE, SET ERROR MESSAGE CODE   53080020
         B     CKRACTRT              BEFORE RETURNING                   53100020
*                                                                       53120020
*                                                                       53140020
*                                                                       53160020
*********************************************************************** 53180020
*                                                                     * 53200020
*        THE FOLLOWING ROUTINES, 200 SERIES, TEST THE ITERATION       * 53220020
*        COUNT TO DETERMINE WHETHER TOO MANY SUBSCRIPTS MAY HAVE      * 53240020
*        BEEN WRITTEN.                                                * 53260020
*                                                                     * 53280020
*                                                                     * 53300020
*********************************************************************** 53320020
*                                                                       53340020
*  200                                                                  53360020
CKRAR200 EQU   *                                                        53380020
*                                  200,CHECK FOR POSS.TOO MANY PRECEDG  53400020
         CLI   WKALEVEL,WKALEVLE   TEST LEVEL                           53420020
         BE    CKRAEPSM            BR IF LEVEL  E                       53440020
         CLI   WKASVICT,6          IS ITER. COUNT GREATER THAN 6        53460020
CKRATPXS BNH   CKRACTRT             NO, OK                              53480020
CKRAPXSB MVI   WKAERRCD,CKRPXSBC    POSSIBLY TOO MANY, SET ERR MSG CODE 53500020
CKRASERP SVERP                    ,  AND ERROR POINTER                  53520020
         B     CKRACTRT               BEFORE RETURNING                  53540020
*                                                                       53560020
CKRAEPSM CLI   WKASVICT,2          E, IS ITER. COUNT GREATER THAN 2     53580020
         B     CKRATPXS            BR TO TEST                           53600020
*                                                                       53620020
*                                                                       53640020
*                                                                       53660020
*  201                                                                  53680020
CKRAR201 EQU   *                   201, CHECK FOR TOO MANY SUBS. NOW    53700020
         CLI   WKALEVEL,WKALEVLE   TEST LEVEL                           53720020
         BE    CKRAENWM            BR IF LEVEL  E                       53740020
         CLI   WKAQICNT,6          WERE THERE EXACTLY 6 ITER'NS ALREADY 53760020
CKRATXSN BNE   CKRACTRT             NO, DON'T ISSUE A DIAGNOSTIC        53780020
CKRAEXSB MVI   WKAERRCD,CKREXSBC    TOO MANY, SET ERROR MESSAGE CODE    53800020
         B     CKRASERP               AND POINTER                       53820020
*                                                                       53840020
CKRAENWM CLI   WKAQICNT,2         WERE THERE EXACTLY 2 ITER'NS ALREADY  53860020
         B     CKRATXSN            BR TO TEST                           53880020
*                                                                       53900020
*                                                                       53920020
*                                                                       53940020
*  202                                                                  53960020
CKRAR202 EQU   *                                                        53980020
*                                  202, CHECK FOR TOO MANY SUBS PRECEDG 54000020
         CLI   WKALEVEL,WKALEVLE   TEST LEVEL                           54020020
         BE    CKRAEMPR            BR IF LEVEL  E                       54040020
         CLI   WKASVICT,6          IS ITER. COUNT GREATER THAN 6        54060020
CKRATXSP BNH   CKRACTRT             NO, OK                              54080020
         MVI   WKAERRCD,CKRXSBPC   TOO MANY PRECEDING,SET ERR.MSG CODE  54100020
         B     CKRASERP             AND POINTER                         54120020
*                                                                       54140020
CKRAEMPR CLI   WKASVICT,2          E, IS ITER. COUNT GREATER THAN 2     54160020
         B     CKRATXSP            BR TO TEST                           54180020
CKRAR203 EQU   *                                                        54200020
*                                                                       54220020
*                                                                       54240020
*                                                                       54260020
*********************************************************************** 54280020
*                                                                     * 54300020
*        THE FOLLOWING TWO ROUTINES TEST THE LABEL FIELD OF           * 54320020
*        END AND FORMAT STATEMENTS.                                   * 54340020
*                                                                     * 54360020
*                                                                     * 54380020
*********************************************************************** 54400020
*                                                                       54420020
*  300                             300,BE SURE ONLY 'END' APPEARS ON CD 54440020
CKRAR300 EQU   *                                                        54460020
CKRATLDC TM    WKASNOSW,EXCNSTNO   TEST FOR STATEMENT NUMBER            54480020
         BO    CKRAIEND                         ILLEGALLY ON 'END' CARD 54500020
*                                  NO STATEMENT NUMBER                  54520020
         CLI   WKACNCOL,C' '       BE SURE THAT CONTINUATION COLUMN IS  54540020
         BE    CKRAFEND            BLANK (END MAY NOT EXCEED 1 CARD)    54560020
*                                                                       54580020
CKRAIEND MVI   WKAERRCD,CKRIENDT   SET ERROR MSG CODE FOR END STATEMENT 54600020
         B     CKRABGEP           ERROR APPLIES TO ENTIRE STMNT         54601020
CKRAFEND EQU   *                                                        54602020
         L     R3,WKAOPTPT                                              54603020
         USING IPDSNOPT,R3                                              54604020
         TM    OPTBYTE3,EXCFRFRM  IS SOURCE FREE-FORM                   54605020
         DROP  R3                                                       54606020
         BNO   CKRACTRT           NO.  RETURN                           54607020
         L     R3,WKAENDST        R3 = ADDR OF D OF END                 54608020
         LA    R2,WKACHRST        R2 = ADDR OF BEGNG OF CHAR STRING     54609020
         SR    R3,R2              R3 = COLUMN NO. - 1                   54610020
         C     R3,CKRF66          IS D OF END PAST COL 66               54611020
         BL    CKRACTRT           NO.   RETURN                          54612020
         MVI   WKAERRCD,CKRIENDF  SET ERROR MSG CODE FOR END STMNT      54613020
*                                  SINCE ERROR APPLIES TO ENTIRE STATM, 54620020
CKRABGEP L     REGWORKA,WKABEGSC   SET ERROR SOURCE POINTER             54640020
         ST    REGWORKA,WKAERRSC     TO BEGINNING OF STATEMENT          54660020
         B     CKRACTRT            RETURN                               54680020
*                                                                       54700020
*                                                                       54720020
*                                                                       54740020
* 301                              301,                                 54760020
CKRAR301 TM    WKASNOSW,EXCNSTNO   CHECK THAT FORMAT STATM. IS LABELLED 54780020
         BO    CKRACTRT             WITH A STATEMENT NUMBER             54800020
         MVI   WKAERRCD,CKRMSNOC   OTHERWISE,SET ERROR MESSAGE CODE     54820020
         B     CKRABGEP            (AND   ERROR  SOURCE PT) BEFORE RETN 54840020
*                                                                       54860020
*                                                                       54880020
*                                                                       54900020
*********************************************************************** 54920020
*                                                                     * 54940020
*        THE FOLLOWING ROUTINES, 400 SERIES, CHECK LEVEL OF FORTRAN-- * 54960020
*        400. DEBUG SUPPORTED BY G, G1, AND CODE-AND-GO.              * 54980020
*        401. LIST-DIRECTED I/O SUPPORTED BY G1 AND CODE-AND-GO.      * 55000020
*                                                                     * 55020020
*                                                                     * 55040020
*********************************************************************** 55060020
*                                                                       55080020
CKRAR400 EQU   *                   CHECK FOR DEBUG SUPPORT              55100020
*                                                                       55120020
         CLI   WKALEVEL,WKALEVLG   DEBUG SUPPORTED IF LEVEL IS          55140020
         BNL   CKRACTRT            G, G1, OR CODE-AND-GO                55160020
*                                                                       55180020
         MVI   WKAERRCD,CKRNODBT   NO,SET ERROR MSG CODE--DEBUG NOT     55200020
*                                   SUPPORTED                           55220020
         B     CKRABGEP             AND POINT TO BEGIN. OF STATEMENT    55240020
*                                                                       55260020
*                                                                       55280020
*                                                                       55300020
*  401                             401,                                 55320020
CKRAR401 EQU   *                   CHECK FOR LIST-DIRECTED I/O SUPPORT  55340020
*                                                                       55360020
         CLI   WKALEVEL,WKALEVLG   LIST-DIRECTED I/O SUPPORTED IF       55380020
         BH    CKRACTRT            LEVEL IS G1 OR CODE-AND-GO           55400020
*                                  NO,                                  55420020
         SVERP                                                          55440020
         MVI   WKAERRCD,CKRLDILC   SET ERROR MSG CODE--LIST-DIRECTED NG 55460020
         B     CKRACTRT                                                 55480020
*                                                                       55500020
*                                                                       55520020
*                                                                       55540020
*********************************************************************** 55560020
*                                                                     * 55580020
*        THE FOLLOWING ROUTINE CHECKS THE IMPLICIT RANGE              * 55600020
*        SPECIFICATION FOR  L ( '-' / HIGHER L ), I.E.,LETTER(ALPHA-  * 55620020
*        BETIC)  OPTIONALLY FOLLOWED BY HYPHEN HIGHER LETTER.         * 55640020
*                                                                     * 55660020
*                                                                     * 55680020
*********************************************************************** 55700020
*                                                                       55720020
*  500                             500,                                 55740020
CKRAR500 EQU   *                   TEST RANGE OF IMPLICIT STATEMENT     55760020
*                                                                       55780020
         GTNB1                     GET NEXT NON-BLANK SOURCE CHARACTER  55800020
         SVERP REGWORKA            SET POSSIBLE ERROR POINTER           55820020
*                                  IS FIRST RANGE CHARACTER ALPHABETIC  55840020
         TSTAL CKRABDIM             IF NOT, GO ISSUE AN ERROR MESSAGE   55860020
         IC    REGWORKA,WKASCHRS                                        55880020
         STC   REGWORKA,WKAIMPL1   SAVE LETTER, THEN                    55900020
         UPDSC                     UPDATE SOURCE POINTER BEYOND IT      55920020
*                                                                       55940020
         GTNB1                     GET POSSIBLE HYPHEN                  55960020
         CLI   WKASCHRS,CKRHYPHN                                        55980020
         BNE   CKRACTRT            IF LETTER NOT FOLLOWED BY HYPHEN, OK 56000020
*                                  OTHERWISE, HYPHEN MUST BE FOLLOWED   56020020
*                                   BY A HIGHER LETTER                  56040020
*                                                                       56060020
         CLI   WKAIMPL1,CKR$       IS L1 THE HIGHEST FORTRAN ALPHABETIC 56080020
         BE    CKRABDIM             IF SO, GO ISSUE ERROR MESSAGE       56100020
*                                  NO,                                  56120020
         UPDSC                     UPDATE SOURCE POINTER                56140020
         GTNB1                     AND GET NEXT NON-BLANK SOURCE CHAR   56160020
         CLC   WKASCHRS(1),WKAIMPL1     IS L2 HIGHER THAN L1            56180020
         BH    CKRATLTR            SHOULD BE A HIGHER LETTER            56200020
*                                   (WHERE Z IS HIGHER THAN A)          56220020
         CLI   WKASCHRS,CKR$                                            56240020
         BE    CKRAGDL2            OR $, DEFINED TO BE HIGHEST LETTER   56260020
*                                  NO,                                  56280020
CKRABDIM MVI   WKAERRCD,CKRINIMT   SET ERROR CODE FOR INVALID RANGE     56300020
         B     CKRACTRT            AND RETURN                           56320020
*                                                                       56340020
CKRATLTR TSTAL CKRABDIM            BE SURE L2 IS A LETTER               56360020
*                                  OK,                                  56380020
CKRAGDL2 UPDSC                     UPDATE SOURCE POINTER BEYOND L2      56400020
         B     CKRACTRT            AND RETURN                           56420020
*                                                                       56440020
*                                                                       56460020
*                                                                       56480020
*********************************************************************** 56500020
*                                                                     * 56520020
*        THE FOLLOWING ROUTINES ARE USED IN THE CHECKING OF           * 56540020
*        I/O LISTS.                                                   * 56560020
*                                                                     * 56580020
*        600-602  TO VERIFY THAT THE INDEX VARIABLE OF AN             * 56600020
*                 IMPLIED  DO  IS NOT SUBSCRIPTED                     * 56620020
*                                                                     * 56640020
*        603   TO LOOK AHEAD TO VERIFY THAT A  )  CLOSES AN           * 56660020
*              IMPLIED  DO.                                           * 56680020
*                                                                     * 56700020
*                                                                     * 56720020
*********************************************************************** 56740020
*                                                                       56760020
* 600                         600, INITIALIZE SUBSCRIPTING SWITCH OFF   56780020
CKRAR600 EQU   *                                                        56800020
         NI    WKASWTCH,255-CKRSUBSC                                    56820020
         B     CKRACTRT            RETURN                               56840020
*                                                                       56860020
*                                                                       56880020
*                                                                       56900020
*  601                             601, SET SUBSCRIPTING SWITCH ON      56920020
CKRAR601 EQU   *                                                        56940020
         OI    WKASWTCH,CKRSUBSC                                        56960020
         B     CKRACTRT            RETURN                               56980020
*                                                                       57000020
*                                                                       57020020
*                                                                       57040020
*  602                             602,ISSUE ERR MSG IF SUBSCR'G INDICD 57060020
CKRAR602 TM    WKASWTCH,CKRSUBSC   IS SUBSCRIPTING SW ON                57080020
         BZ    CKRACTRT            NO,RETURN                            57100020
*                                  VARIABLE IS SUBSCRIPTED,             57120020
         MVI   WKAERRCD,CKRVRSBC    SET UP ERROR MESSAGE AND            57140020
         SVERP REGWORKA             ERROR SOURCE POINTER                57160020
         B     CKRACTRT            RETURN                               57180020
*                                                                       57200020
*                                                                       57220020
*                                                                       57240020
*  603                             603,LOOK AHEAD FOR RIGHT PARENTHESIS 57260020
CKRAR603 EQU   *                                                        57280020
         GTNB1                     GET NEXT NON-BLANK SOURCE CHARACTER  57300020
         CLI   WKASCHRS,C')'       IS IT A RIGHT PARENTHESIS            57320020
         BE    CKRACTRT             YES,RETURN WITHOUT UP'ING SOURCE PT 57340020
*                                                                       57360020
         MVI   WKAERRCD,CKRRPRQT    NO, SET ERROR MESSAGE CODE          57380020
         SVERP REGWORKA              AND POINTER TO SOURCE IN ERROR     57400020
         B     CKRACTRT            RETURN                               57420020
CKRAR604 EQU   *                                                        57440020
CKRAR605 EQU   *                                                        57460020
CKRAR606 EQU   *                                                        57480020
CKRAR607 EQU   *                                                        57500020
CKRAR608 EQU   *                                                        57520020
CKRAR609 EQU   *                                                        57540020
CKRAR610 EQU   *                                                        57560020
CKRAR611 EQU   *                                                        57580020
CKRAR612 EQU   *                                                        57600020
CKRAR613 EQU   *                                                        57620020
*                                                                       57640020
*                                                                       57660020
*                                                                       57680020
*********************************************************************** 57700020
*                                                                     * 57720020
*        THE FOLLOWING ROUTINES (700 SERIES) CHECK WIDTH AND          * 57740020
*        DECIMAL PLACES SPECIFICATIONS.                               * 57760020
*                                                                     * 57780020
*                                                                     * 57800020
*********************************************************************** 57820020
*                                                                       57840020
*  700                             700, CHECK WIDTH SPECIFICATION       57860020
CKRAR700 EQU   *                                                        57880020
         GTNB1                     GET NEXT NON-BLANK SOURCE CHARACTER  57900020
         CLI   WKASCHRS,CKR0                                            57920020
         BL    CKRAFALS             IF NOT A DIGIT, FAIL                57940020
         CLI   WKASCHRS,CKR9                                            57960020
         BH    CKRAFALS           IF NOT A DIGIT, FAIL                  57980020
*                                   DIGIT, EVALUATE THE WIDTH           58000020
         BAL   REGLRETN,CKREVALU        RETURNED IN WKAVALUE & REGCHRCT 58020020
         C     REGCHRCT,CKRF255                                         58040020
         BH    CKRAHIWD            BR IF WIDTH GREATER THAN 255         58060020
         ST    REGCHRCT,WKAWIDTH   SAVE THE WIDTH SPECIFICATION         58080020
         LTR   REGCHRCT,REGCHRCT                                        58100020
         BNZ   CKRACTRT            GOOD WIDTH                           58120020
         B     CKRABDWD            0 WIDTH, INVALID                     58140020
*                                                                       58160020
CKRAHIWD MVC   WKAWIDTH,CKRF255    WIDTH GREATER THAN 255,SET IT TO 255 58180020
*                                   AND                                 58200020
CKRABDWD MVI   WKAERRCD,CKRINVWC     SET ERROR MESSAGE CODE (ERROR.PT   58220020
*                                     SET BY CKREVALU)                  58240020
         B     CKRACTRT                BEFORE RETURNING                 58260020
*                                                                       58280020
*                                                                       58300020
*                                                                       58320020
*  701                             701,CHECK DECIMAL PLACES SPECIFICATN 58340020
CKRAR701 GTNB1                     GET NEXT NON-BLANK SOURCE CHARACTER  58360020
         CLI   WKASCHRS,CKR0                                            58380020
         BL    CKRADCPU            IF 1ST CHAR. IS NOT A DIGIT,         58400020
         CLI   WKASCHRS,CKR9            GO ISSUE                        58420020
         BH    CKRADCPU                    AN ERROR MESSAGE             58440020
*                                  DIGIT, EVALUATE THE DEC.PLACES SPECN 58460020
         BAL   REGLRETN,CKREVALU   (VALUE RETD IN WKAVALUE & REGCHRCT)  58480020
         C     REGCHRCT,WKAWIDTH                                        58500020
         BNH   CKRACTRT            BE SURE DEC.PLACES LT OR EQ WIDTH    58520020
         MVI   WKAERRCD,CKRDCXWC   OTHERWISE, SET ERROR CODE (PT TO D)  58540020
         B     CKRACTRT            BEFORE RETURNING                     58560020
*                                                                       58580020
CKRADCPU MVI   WKAERRCD,CKRDCPUC   ERROR CODE--DEC.PLACES MUST BE SPECD 58600020
         SVERP REGWORKA            SET ERROR POINTER TO CURR SOURCE LOC 58620020
         B     CKRACTRT            THEN RETURN                          58640020
*                                                                       58660020
*                                                                       58680020
*                                                                       58700020
*********************************************************************** 58720020
*                                                                     * 58740020
*        THE FOLLOWING SUBROUTINE EVALUATES CONTINUOUS DIGITS IN      * 58760020
*        THE SOURCE TO COMPUTE A VALUE IN WKAVALUE AND REGCHRCT.      * 58780020
*        THE NUMBER OF CONTINUOUS DIGITS IS LEFT IN WKACNTDG.         * 58800020
*                                                                     * 58820020
*        THE LEFTMOST DIGIT IS IN WKASCHRS (FOLLOWING  GTNB1)         * 58840020
*        WHEN THIS ROUTINE IS CALLED.                                 * 58860020
*                                                                     * 58880020
*                                                                     * 58900020
*********************************************************************** 58920020
*                                                                       58940020
CKREVALU ST    REGLRETN,WKASVRTN   SAVE RETURN REGISTER                 58960020
*                                                                       58980020
         SVERP REGWORKA            SAVE POSSIBLE ERROR POINTER          59000020
*                                                                       59020020
         IC    REGCHRCT,WKASCHRS   INITLZ, VALUE= VALUE OF SOURCE DIGIT 59040020
         N     REGCHRCT,=F'15'                                          59060020
*                                                                       59080020
         LA    REGWORKB,1         INITIALIZE NO. OF CONTIN. DIGITS = 1  59100020
CKRNXTDG STH   REGWORKB,WKACNTDG    (INCLUDE LEADING ZEROES)            59120020
*                                                                       59140020
         UPDSC                     UPDATE SOURCE POINTER                59160020
*                                                                       59180020
         GTNB1                     REQUEST NEXT NON-BLANK CHARACTER     59200020
*                                                                       59220020
         CLI   WKASCHRS,CKR0       IS NEW CHARACTER A DIGIT             59240020
         BL    CKRVALRT             IF NOT, VALUE HAS BEEN COMPUTED     59260020
         CLI   WKASCHRS,CKR9                                            59280020
         BH    CKRVALRT                                                 59300020
*                                                                       59320020
         C     REGCHRCT,CKRF100M   IF VALUE EXCEEDS 100,000,000         59340020
         BH    CKRUPDCT             STOP COMPUTING TO AVOID OVERFLOW    59360020
*                                    (MAX.VALUE COMPUTED=1,000,000,009) 59380020
*                                                                       59400020
         LA    REG1,10             10 TIMES VALUE                       59420020
         MR    REG0,REGCHRCT                      INTO REG 1            59440020
*                                                                       59460020
         IC    REGCHRCT,WKASCHRS   NEW DIGIT                            59480020
         N     REGCHRCT,=F'15'            PLUS                          59500020
         AR    REGCHRCT,REG1                  REG 1,YIELDS NEW VALUE    59520020
*                                                                       59540020
CKRUPDCT LH    REGWORKB,WKACNTDG                                        59560020
         LA    REGWORKB,1(0,REGWORKB)   INCREMENT NO. OF DIGITS BY 1    59580020
*                                                                       59600020
         B     CKRNXTDG            GO LOOK FOR ANOTHER DIGIT            59620020
*                                                                       59640020
CKRVALRT EQU   *                                                        59660020
         ST    REGCHRCT,WKAVALUE   SAVE VALUE                           59680020
         L     REGLRETN,WKASVRTN    RESTORE RETURN REGISTER             59700020
         BR    REGLRETN              AND GO BACK TO CALLER              59720020
*                                                                       59740020
*                                                                       59760020
*                                                                       59780020
*********************************************************************** 59800020
*                                                                     * 59820020
*        THE FOLLOWING ROUTINE CHECKS FOR END OF SOURCE, IE,          * 59840020
*        NO REMAINING NON-BLANK CHARACTERS IN SOURCE.                 * 59860020
*                                                                     * 59880020
*                                                                     * 59900020
*********************************************************************** 59920020
*                                                                       59940020
* 800                              800, CHECK FOR END OF SOURCE         59960020
CKRAR800 EQU   *                                                        59980020
         CLI   WKASCHRS,WKASPCHR                                        60000020
         BE    CKRACTRT            IF                                   60020020
         GTNB1                                                          60040020
         TM    WKASNDSW,EXCNSEND                                        60060020
         BO    CKRACTRT            NO REMAINING NON-BLANK CHARS, GOOD   60080020
         B     CKRAFALS             OTHERWISE, INDICATE FAILURE         60100020
*                                                                       60120020
*                                                                       60140020
*                                                                       60160020
*********************************************************************** 60180020
*                                                                     * 60200020
*                                                                     * 60220020
*        THE FOLLOWING ROUTINE UNCONDITIONALLY FAILS                  * 60240020
*                                                                     * 60260020
*                                                                     * 60280020
*********************************************************************** 60300020
*                                                                       60320020
*                                                                       60340020
* 801                              801, FAIL                            60360020
CKRAR801 EQU   *                                                        60380020
CKRAFALS OI    WKAFALSW,CKRFALSW   INDICATE FAILURE                     60400020
*                                                                       60420020
*                                                                       60440020
*                                                                       60460020
CKRACTRT EQU   *                                                        60480020
*                                                                       60500020
         TM    WKAFALSW,CKRFALSW        DID ACTION ROUTINE TEST FAIL    60520020
         BO    CKRFAIL                   YES, FAIL                      60540020
         CLI   WKAERRCD,0                NO, ANY (ERROR) MSG TO ISSUE   60560020
         BE    CKRTSNOP                  NO                             60580020
         TM    WKAQSWCH,CKRCMTSW         YES, IS THIS OPTION COMMITTED  60600020
         BO    CKRREINT                  YES, GO ISSUE ERROR MESSAGE    60620020
         B     CKRFAIL                   NO, JUST FAIL                  60640020
CKRTSNOP CLI   WKASFAIL,0                WAS ACTION RTNE OPERATIONAL    60660020
         BE    CKRINTRP                    YES, ACTION RTNE SUCCEEDED   60680020
         B     CKRERRET                     NO, SAVE REGS TO DEBUG      60700020
*                                                                       60720020
*                                                                     * 60740020
*********************************************************************** 60760020
*                                                                     * 60780020
*        THE FOLLOWING ROUTINE PLACES AN ERROR MESSAGE CODE FROM      * 60800020
*        THE DEFINITION INTO THE CURRENT LINE NEST.                   * 60820020
*                                                                     * 60840020
*                                                                     * 60860020
*********************************************************************** 60880020
*                                                                       60900020
CKRMESSG EQU   *                                                        60920020
         IC    REGWORKB,DEFFIELD(REGDEFPT)   MOVE MESSAGE CODE          60940020
         STC   REGWORKB,WKANFMSG              TO CURRENT LINE NEST      60960020
*                                                                       60980020
         LA    REGDEFPT,1(0,REGDEFPT)        UPDATE DEF'N TABLE POINTER 61000020
*                                                                       61020020
         B     CKRINTRP                       AND GO INTERPRET NEXT OP. 61040020
*                                                                       61060020
*                                                                       61080020
*                                                                       61100020
*********************************************************************** 61120020
*                                                                     * 61140020
*        THE FOLLOWING ROUTINE LOOKS UP THE SOURCE IN A TABLE OF      * 61160020
*        LITERALS.                                                    * 61180020
*                                                                     * 61200020
*        IF THE OPERATOR IS +TABLENAME, AND A TABLE ARGUMENT IS       * 61220020
*        MATCHED, THE OPERATOR FUNCTION OF THAT ARGUMENT IS           * 61240020
*        LINKED TO.                                                   * 61260020
*                                                                     * 61280020
*        IF THE OPERATOR IS -TABLENAME, THE TEST FAILS IF A MATCHING  * 61300020
*        ARGUMENT IS FOUND.                                           * 61320020
*                                                                     * 61340020
*                                                                     * 61360020
*********************************************************************** 61380020
*                                                                       61400020
CKRTABL  LA    REGTDFPT,DEFFIELD(REGDEFPT)  OBTAIN LOC IN DEFN TBL      61420020
CKRTABLT BCTR  REGTDFPT,0               GET TABLE OP-CODE               61440020
         IC    REGWORKA,0(REGTDFPT)     (+ OR -)                        61460020
         STC   REGWORKA,WKATBLOP         AND SAVE IT FOR LATER TESTING  61480020
*                                                                       61500020
         MVC   WKATEMPH(2),1(REGTDFPT)        POINT TO ACTUAL           61520020
         LH    REGTDFPT,WKATEMPH               TABLE OF LITERALS        61540020
         LA    REGTDFPT,DEFFIELD(REGTDFPT)                              61560020
*                                                                       61580020
         STM   REGNSTPT,REGQALPT,WKASAVNQ    (SAVE REGS N AND Q)        61600020
*                                                                       61620020
         LR    REGWORKQ,REGTDFPT             OBTAIN POINTER Q           61640020
         MVC   WKATEMPH,1(REGWORKQ)          BEYOND LAST TABLE ENTRY    61660020
         AH    REGWORKQ,WKATEMPH             FOR TABLE END TESTING      61680020
*                                                                       61700020
         LA    REGWORKN,0                    AND USE IT TO GET LENGTH N 61720020
         IC    REGWORKN,0(REGWORKQ)           OF LONGEST LITERAL        61740020
         AIF   ('&ITNLDBG' EQ '').NOMXATS                               61760020
         CLI   0(REGWORKQ),WKASCMAX     BE SURE THAT LENGTH NOT         61780020
         BH    CKRLGLLS                  GT MAX.ALLOWABLE CHAR REQUEST  61800020
         CLI   0(REGWORKQ),0              OR ZERO                       61820020
         BE    CKRLGLLS                 (OTHERWISE INDIC. MALFUNCTION)  61840020
.NOMXATS ANOP                                                           61860020
         LA    REGTDFPT,3(0,REGTDFPT)   POINT TO FIRST TABLE ENTRY      61880020
*                                                                       61900020
         STH   REGWORKN,WKASRCNT        REQUEST N (LONGEST-LIT'RL-SIZE) 61920020
         BAL   REGLRETN,CKRGTNBS         NON-BLANK CHARS. FROM SOURCE   61940020
*                                                                       61960020
CKRTTBND CR    REGTDFPT,REGWORKQ        IS TABLE OF LITERALS EXHAUSTED  61980020
         BNL   CKRTBEND                  YES                            62000020
*                                                                       62020020
*                                        NO,                            62040020
         IC    REGWORKN,0(0,REGTDFPT)       OBTAIN ACTUAL SIZE OF ARGUM 62060020
         BCTR  REGWORKN,0          (DECR. IT BY 1 FOR EX INSTR.)        62080020
         EX    REGWORKN,CKRTCMPR        COMPAR.ARGUMENT TO SOURCE CHARS 62100020
*                                            DO THEY MATCH              62120020
         BE    CKRTBMAT                       YES                       62140020
         LA    REGTDFPT,5(REGWORKN,REGTDFPT)  NO, INCR. TABLE POINTER   62160020
         B     CKRTTBND                        AND GO COMPARE NEXT ARG  62180020
*                                                                       62200020
CKRTBMAT EQU   *                   SOURCE MATCH TO TABLE ARGUMENT       62220020
         LA    REGWORKN,1(REGWORKN)        RESTORE ARGUMENT SIZE        62240020
         CH    REGWORKN,WKAMVCNT   IF ARGUMENT MATCHED WAS SHORTER THAN 62260020
         BNL   CKRTBUPS             LENGTH OF SOURCE OBTAINED,          62280020
         STH   REGWORKN,WKASRCNT     RE-OBTAIN LENGTH-OF-ARG CHARACTERS 62300020
         BAL   REGLRETN,CKRGTNBS      FROM SOURCE AND THEN              62320020
*                                                                       62340020
CKRTBUPS UPDSC                         UPDATE SOURCE POINTER            62360020
         LA    REGWORKB,1(REGWORKN,REGTDFPT) OBTAIN LOC OF ARG FUNC OP  62380020
         LA    REGTDFPT,2(REGWORKN,REGTDFPT) SET SPEC.DEF.PT IMM BYD OP 62400020
         LM    REGNSTPT,REGQALPT,WKASAVNQ    (RESTORE REGS N AND Q)     62420020
         CLI   WKATBLOP,CKRPLTBL   IS OPERATOR +TABLENAME               62440020
         BE    CKRTFUNC             YES, EXAMINE THE FUNCTION OP-CODE   62460020
*                                   NO,                                 62480020
         LA    REGDEFPT,2(REGDEFPT) INCR DEFN TBL POINTER TO NEXT OPER. 62500020
         B     CKRFAIL              AND FAIL ON ARGUMENT MATCH          62520020
*                                                                       62540020
CKRTFUNC EQU   *                                                        62560020
         CLI   0(REGWORKB),CKRSYMLN                                     62580020
         BE    CKRSYNST                 NEST   TO SYMBOLIC LINE         62600020
*                                                                       62620020
         CLI   0(REGWORKB),CKRPLTBL                                     62640020
         BE    CKRTABLT                 SEARCH ANOTHER TABLE IF +TABLE  62660020
         CLI   0(REGWORKB),CKRMITBL                                     62680020
         BE    CKRTABLT                                      OR -TABLE  62700020
*                                                                       62720020
         AIF   ('&ITNLDBG' EQ '').NOTOPTS                               62740020
         CLI   0(REGWORKB),CKRACTON     IS IT ACTION RTNE OP-CODE       62760020
         BNE   CKRTOPFL            (INDICATE MALFUNC. IF NONE OF ABOVE) 62780020
.NOTOPTS ANOP                                                           62800020
         CLI   1(REGWORKB),X'FF'   IS IT NULL                           62820020
         BNE   CKRACTNT            NO,  INVOKE ACTION CODE ROUTINE      62840020
*                                                                       62860020
*                                       NULL,                           62880020
         LA    REGDEFPT,2(REGDEFPT) INCR DEFN TBL POINTER TO NEXT OPER. 62900020
         B     CKRINTRP                  AND GO INTERPRET NEXT OPERATOR 62920020
*                                                                       62940020
CKRTBEND EQU   *                   EXHAUSTED TABLE WITHOUT FINDING A    62960020
         LM    REGNSTPT,REGQALPT,WKASAVNQ    MATCH (RESTORE REGS N & Q) 62980020
         LA    REGDEFPT,2(REGDEFPT) INCR DEFN TBL POINTER TO NEXT OPER. 63000020
*                                                                       63020020
         CLI   WKATBLOP,CKRMITBL   IS OPERATOR -TABLENAME               63040020
         BE    CKRINTRP             IF SO, TEST IS SUCCESSFUL           63060020
         B     CKRFAIL              NO, FAIL                            63080020
*                                                                       63100020
*                                                                       63120020
*                                                                       63140020
*********************************************************************** 63160020
*                                                                     * 63180020
*        THE FOLLOWING ROUTINE PROCESSES THE END-OF-DEFINITION-LINE   * 63200020
*        OPERATOR.  IF THE CURRENT LINE IS AT LEVEL 1, THE CHECKING   * 63220020
*        OF THE CURRENT STATEMENT IS TERMINATED NORMALLY. OTHERWISE,  * 63240020
*        THE LINE  NEST  LIST  IS POPPED UP, AND CHECKING CONTINUES   * 63260020
*        AT THE POINT IN THE DEFINITION IMMEDIATELY FOLLOWING THE     * 63280020
*        SYMBOLIC-NAME OF THE LINE JUST ENDED.                        * 63300020
*                                                                     * 63320020
*                                                                     * 63340020
*********************************************************************** 63360020
*                                                                       63380020
CKRSYUNS EQU   *                   UNNEST CURRENT LINE                  63400020
*                                                                       63420020
         CLI   WKANLVLN,1          IS CURRENT LINE LEVEL 1 (TOP)        63440020
*                                                                       63460020
         BNH   CKRNMLND             IF SO, NORMAL END OF STATMT CHECKNG 63480020
*                                                                       63500020
         BAL   REGLRETN,CKRUNEST    NO, UNNEST THIS LINE TO CONTINUE    63520020
*                                    CHECKING ON PREVIOUS LINE          63540020
         B     CKRINTRP            AND GO INTERPRET THE NEXT OPERATOR   63560020
*                                                                       63580020
*                                                                       63600020
CKRNMLND EQU   *                                                        63620020
         CLI   WKACERSW,0          UNLESS PRIOR CKR-DETECTED ERROR      63640020
         BE    CKRTSEXS                                                 63660020
*  400                             400,                                 63680020
CKRNOMSG MVI   WKACERSW,0          (IN WHICH CASE, TURN OFF SWITCH      63700020
         B     CKRNMLRT            BEFORE NORMAL RETURN)                63720020
*                                  CHECK THAT NO SOURCE FOLLOWS STATEM. 63740020
CKRTSEXS CLI   WKASCHRS,WKASPCHR                                        63760020
         BE    CKRNMLRT            IF SOURCE-END, NORMAL RETURN         63780020
         GTNB1                                                          63800020
         TM    WKASNDSW,EXCNSEND                                        63820020
         BO    CKRNMLRT           IF SOURCE-END SW ON, NORMAL RETURN    63840020
*                                  OTHERWISE, ISSUE EXCESS SOURCE       63860020
         SVERP REGWORKA             TERMINAL ERROR MESSAGE              63880020
         MVI   WKAERRCD,CKREXSCT                                        63900020
         B     CKRTMRET            GO ISSUE ERROR MESSAGE               63920020
*                                                                       63940020
*                                                                       63960020
*                                                                       63980020
CKRUNEST EQU   *                   POP UP NEST LIST                     64000020
         LH    REGDEFPT,WKANDFBK   RELOAD SYN DEFN POINTER TO NEXT      64020020
*                                   ENTRY ON PREVIOUS LINE              64040020
*                                                                       64060020
         S     REGNSTPT,CKRLNNSK   DECREMENT NEST LIST POINTER          64080020
*                                                                       64100020
         AIF   ('&ITNLDBG' NE 'E').NOUNSTS                              64120020
         C     REGNSTPT,WKAADNLS    (BE SURE POINTER IS STILL WITHIN    64140020
         BL    CKREXCUN               BOUNDS OF NEST LIST)              64160020
*                                                                       64180020
.NOUNSTS ANOP                                                           64200020
         MVC   WKALNEST,NLSLNEST   AND POP UP NEST FROM LIST            64220020
*                                                                       64240020
         BR    REGLRETN            THEN RETURN                          64260020
*                                                                       64280020
*                                                                       64300020
*                                                                       64320020
*********************************************************************** 64340020
*                                                                     * 64360020
*        THE FOLLOWING ROUTINE RECEIVES CONTROL WHEN AN OPERATOR      * 64380020
*        ROUTINE DETECTS FAILURE.                                     * 64400020
*                                                                       64420020
*        IF THE DEFINITION IS COMMITTED TO THE FAILING PATH, ERROR    * 64440020
*        MESSAGE INFORMATION IS SET,   REGISTERS ARE SAVED FOR        * 64460020
*        POSSIBLE RECALL, AND CONTROL IS RETURNED TO THE EXECUTIVE    * 64480020
*        FOR ISSUANCE OF THE ERROR MESSAGE.                           * 64500020
*                                                                     * 64520020
*        IF THE DEFINITION IS NOT COMMITTED AT THIS POINT, ANY        * 64540020
*        UNNESTING REQUIRED TO BRING THE LEVEL OF NESTING UP TO       * 64560020
*        THE QUALIFICATION LEVEL IS PERFORMED,AND CHECKING CONTINUES  * 64580020
*        BEYOND THE CURRENT ALTERNATIVE OR OPTION.                    * 64600020
*                                                                     * 64620020
*                                                                     * 64640020
*********************************************************************** 64660020
*                                                                       64680020
CKRFAIL  EQU   *                   OPERATOR FAILURE ROUTINE             64700020
*                                                                       64720020
         OI    WKAFALSW,CKRFALSW   SET ON FAILURE INDICATOR (SWITCH)    64740020
*                                                                       64760020
         TM    WKAQSWCH,CKRCMTSW   IS DEF'N COMMITTED TO THIS PATH      64780020
         BZ    CKRTRYNX             NO                                  64800020
*                                   YES, SET UP ERROR MESSAGE INFO      64820020
         IC    REGWORKB,WKANFMSG                                        64840020
         STC   REGWORKB,WKAERRCD   GET ERROR MSG CODE FROM LINE NEST    64860020
         L     REGWORKB,WKASRCCR                                        64880020
         ST    REGWORKB,WKAERRSC   SET ERROR POINTER TO LOC OF CURR SRC 64900020
*                                                                       64920020
CKRREINT LA    REGLRETN,CKRINTRP   IF RECALLED, WILL INTERP NEXT OPCODE 64940020
*                                                                       64960020
CKRTSTML CLI   WKASCHRS,WKASPCHR   IS RESTART CHAR. BEYOND SOURCE END   64980020
         BNE   CKRTSMSG            NO,MAY BE ABLE TO CONTINUE CHECKING  65000020
         OI    WKAERRCD,WKAERRTM    YES INDICATE THAT ERROR IS TERMINAL 65020020
CKRTSMSG EQU   *                                                        65040020
*                                                                       65060020
*                   IF MESSAGE INFORMATION IS UNIQUE,SAVE AND ISSUE ERR 65080020
*                    MESSAGE, OTHERWISE, DO NOT ISSUE MESSAGE AND       65100020
*                     CONTINUE UNLESS ERROR WAS TERMINAL                65120020
*                                                                       65140020
         LA    REGWORKA,WKAMSGTB        BEGINNING OF MESSAGE TABLE      65160020
         L     REGWORKB,WKAMSGAD        LOCATION FOR NEXT MESSAGE       65180020
         MVC   0(1,REGWORKB),WKAERRCD   SAVE MESSAGE INFO--ERROR CODE   65200020
         NI    0(REGWORKB),255-WKAERRTM  AS EVEN NO., FOLLOWED BY       65220020
         MVC   1(3,REGWORKB),WKAERRSC+1   FAILING CHARACTER ADDRESS     65240020
CKRNXMSG CR    REGWORKA,REGWORKB   ANY (MORE) MESSAGES FOR COMPARISON   65260020
         BNL   CKRSVUPT            (IF NOT,GO ISSUE UNIQUE MSG)         65280020
         CLC   0(4,REGWORKB),0(REGWORKA) YES,IF IDENTICAL MESSAGE WAS   65300020
*                                        ALREADY ISSUED                 65320020
         LA    REGWORKA,4(0,REGWORKA)                                   65340020
         BNE   CKRNXMSG           NO, SEE IF MORE MSGS FOR COMPARISON   65360020
         TM    WKAERRCD,WKAERRTM                                        65380020
         BO    CKRNOMSG                 QUIT IF ERROR WAS TERMINAL      65400020
*                                                                       65420020
         NI    WKAFALSW,255-CKRFALSW    NON-TERMINAL, CONTINUE CHECKING 65440020
         BR    REGLRETN                  STATEMENT W/O RECORDING ERROR  65460020
*                                         (SEE  CKRCONTN)               65480020
*                                                                       65500020
CKRSVUPT LA    REGWORKA,4(0,REGWORKA)                                   65520020
         ST    REGWORKA,WKAMSGAD        UNIQUE MESSAGE, ISSUE IT        65540020
         LA    REGWORKC,WKAMGTND                                        65560020
         CR    REGWORKA,REGWORKC         (IF MESSAGE TABLE IS FILLED,   65580020
         BL    CKRERRET           BR IF TABLE NOT FILLED                65600020
         OI    WKAERRCD,WKAERRTM           MESSAGE IS TERMINAL)         65620020
*                                                                       65640020
CKRTMRET EQU   *                                                        65660020
CKRERRET STM   REG0,REG15,WKACKRGS  SAVE REGISTERS IN CASE OF RECALL    65680020
*                                   (OR FOR DEBUGGING)                  65700020
         OI    WKACERSW,EXCNCKER   SET ON CHECKER-DETECTED-ERROR SWITCH 65720020
*                                                                       65740020
CKRNMLRT L     REG13,WKASVR13      RESTORE CALLER'S SAVE AREA REGISTER  65760020
         RETURN (14,12),T               AND REST OF CALLERS REGISTERS   65780020
*                                                                       65800020
*                                  AND RETURN CONTROL TO CALLING        65820020
*                                    PROGRAM (EXECUTIVE)                65840020
*                                                                       65860020
CKRTRYNX EQU   *                   TRY NEXT ALTERNATIVE                 65880020
         CLC   WKANLVLN,WKAQNLVL   IS NEST AT LEVEL OF CURRENT QUAL     65900020
         BNH   CKRNXALT             YES, GO TRY NEXT OPTION             65920020
         BAL   REGLRETN,CKRUNEST     IF NOT, UNNEST A LEVEL             65940020
         B     CKRTRYNX               AND TRY AGAIN                     65960020
*                                                                       65980020
CKRNXALT LA    REGDEFPT,0          SET DEFINITION POINTER FROM QUAL     66000020
         IC    REGDEFPT,WKAQFALS   FALSE DISPL TO NEXT 'OR'             66020020
*                                  OR RIGHT BRACE OR )                  66040020
         AH    REGDEFPT,WKANDFPT                                        66060020
*                                                                       66080020
         B     CKRINTRP            AND GO INTERPRET THAT OPERATOR       66100020
*                                                                       66120020
*                                                                       66140020
*********************************************************************** 66160020
*                                                                     * 66180020
*        THE FOLLOWING ROUTINE RECEIVES CONTROL WHEN THE CHECKER      * 66200020
*        IS RECALLED AFTER AN ERROR MESSAGE HAS BEEN ISSUED.          * 66220020
*                                                                     * 66240020
*        ERROR SWITCHES ARE RESET, REGISTERS ARE RESTORED             * 66260020
*        (DEFINITION, SOURCE, AND LIST POINTERS ARE ALL               * 66280020
*        IN REGISTERS),   AND CONTROL IS TRANSFERRED AS DETERMINED    * 66300020
*        PRIOR TO THE RETURN-AND-RECALL--OFTEN TO CKRINTRP TO         * 66320020
*        EXAMINE THE NEXT OPERATOR.                                   * 66340020
*                                                                     * 66360020
*                                                                     * 66380020
*********************************************************************** 66400020
*                                                                       66420020
CKRCONTN EQU   *                                                        66440020
         NI    WKAFALSW,255-CKRFALSW    SET OFF FAILURE INDICATOR       66460020
*                                                                       66480020
         LM    REG0,REG15,WKACKRGS      RESTORE CHECKER'S REGISTERS     66500020
*                                                                       66520020
*                                                                       66540020
         BR    REGLRETN                 AND BRANCH AS DETERMINED PRIOR  66560020
*                                        TO ISSUANCE OF ERROR MESSAGE   66580020
*                                        TO CONTINUE CHECKING THE       66600020
*                                        STATEMENT.                     66620020
*                                                                       66640020
*                                                                       66660020
*                                                                       66680020
*********************************************************************** 66700020
*                                                                     * 66720020
*        THE FOLLOWING ROUTINES PROCESS IMPENDING OVERFLOW OF THE     * 66740020
*        NEST/QUALIFICATION LISTS.                                    * 66760020
*                                                                     * 66780020
*        ANY QUALIFICATION ENTRIES THAT HAVE LOGICALLY BEEN           * 66800020
*        ELIMINATED BY A STATEMENT COMMIT ARE PHYSICALLY ELIMINATED   * 66820020
*        TO CREATE MORE LIST SPACE.                                   * 66840020
*                                                                     * 66860020
*        IF NO SPACE CAN BE OBTAINED FOR EXPANSION, A MESSAGE         * 66880020
*        IS RETURNED TO THE EXECUTIVE INDICATING THAT CHECKING OF     * 66900020
*        THE CURRENT STATEMENT MUST BE TERMINATED BECAUSE OF THE      * 66920020
*        CHECKER'S TABLE SIZE LIMITATIONS.                            * 66940020
*                                                                     * 66960020
*                                                                     * 66980020
*********************************************************************** 67000020
*                                                                       67020020
CKRNOFLO EQU   *                                                        67040020
         BAL   REGLRETN,CKRLOFLO   GET SOME MORE LIST SPACE IF POSSIBLE 67060020
         B     CKRADDNS            ADD A NEST IN THE SPACE PROVIDED     67080020
*                                                                       67100020
*                                                                       67120020
CKRQOFLO EQU   *                                                        67140020
         BAL   REGLRETN,CKRLOFLO   GET MORE LIST SPACE, IF POSSIBLE     67160020
         B     CKRLQUAL            ADD A QUAL IF ENOUGH SPACE PROVIDED  67180020
*                                                                       67200020
*                                                                       67220020
CKRLOFLO EQU   *                                                        67240020
         LA    REGWORKA,WKAQLIST                                        67260020
         C     REGWORKA,WKATPQLS   ANY EXTRANEOUS QUALIFICATION ENTRIES 67280020
         BNH   CKROFLOW             NO                                  67300020
         L     REGWORKB,WKATPQLS    YES,INITIALIZE TO FILL UP GAP       67320020
         ST    REGWORKA,WKATPQLS                                        67340020
CKRSFQLS S     REGWORKB,CKRLNQLK                                        67360020
         S     REGWORKA,CKRLNQLK                                        67380020
         MVC   0(CKRQUALL,REGWORKA),0(REGWORKB)   MOVE TOP Q ENTRY 1ST, 67400020
         CR    REGWORKB,REGQALPT   CONTINUE UNTIL ALL Q ENTRIES         67420020
         BH    CKRSFQLS            MOVED                                67440020
*                                                                       67460020
         LR    REGQALPT,REGWORKA    ADJUST QUAL PT TO SPACE VACATED IN  67480020
         S     REGWORKA,CKRLNQLK     LIST                               67500020
         BR    REGLRETN               AND RETURN                        67520020
*                                                                       67540020
CKROFLOW SVERP REGWORKA            SET ERROR POINTER TO CURR SOURCE LOC 67560020
         MVI   WKAERRCD,CKROFLOT   SET TML MSG CODE FOR LIST OVERFLOW   67580020
         B     CKRTMRET             AND GO ISSUE THE MESSAGE            67600020
*                                                                       67620020
*                                                                       67640020
*                                                                       67660020
         AIF   ('&ITNLDBG'  EQ  '').NOCKRDB                             67680020
*********************************************************************** 67700020
*                                                                     * 67720020
*        THE FOLLOWING ROUTINES NOTIFY THE EXECUTIVE THAT THE         * 67740020
*        SYNTAX CHECKER IS NOT OPERATIONAL BECAUSE OF AN ERROR        * 67760020
*        IN THE DEFINITION OR A PROGRAMMING ERROR IN IPDSNCKR.        * 67780020
*                                                                     * 67800020
*        A PARTICULAR FAILURE CODE IS ASSOCIATED WITH EACH TYPE       * 67820020
*        OF ERROR.  REGISTERS WILL BE SAVED IN WKACKRGS--THE COMMENTS * 67840020
*        PROVIDE AN AID TO DEBUGGING.                                 * 67860020
*                                                                     * 67880020
*                                                                     * 67900020
*********************************************************************** 67920020
*                                                                       67940020
CKROPFAL EQU   *                                                        67960020
         MVI   WKASFAIL,X'11'      INVALID (UNDEFINED) OP-CODE          67980020
         B     CKRERRET            (OPCODE RT-ADJUSTED IN REGOPCDE,     68000020
*                                   DEFFIELD+REGDEFPT IS LOC OF OPCODE) 68020020
CKREXCRB EQU   *                                                        68040020
         MVI   WKASFAIL,X'12'      TOO MANY RIGHT BRACES                68060020
         B     CKRERRET            (DEFFIELD-1+REGDEFPT IS LOC OF RTBRC 68080020
*                                                                       68100020
CKREXCRP MVI   WKASFAIL,X'13'      TOO MANY RIGHT PARENTHESES           68120020
         B     CKRERRET             (DEFFIELD-1+REGDEFPT IS LOC OF ))   68140020
*                                                                       68160020
CKRLGLLS MVI   WKASFAIL,X'14'      LONGEST TABLE ARG.0 OR TOO LONG      68180020
*                                   (LENGTH IN REGWORKN, POINTED TO IN  68200020
         B     CKRERRET              DEFN TABLE BY REGWORKQ)            68220020
*                                                                       68240020
CKRTOPFL MVI   WKASFAIL,X'15'      ILLEGAL OR INVALID TABLE FUNCT.OPCDE 68260020
*                                   (REGWORKB POINTS TO OPCODE IN DEF)  68280020
         B     CKRERRET           BR TO SAVE REGS                       68300020
*                                                                       68320020
CKREXCUN MVI   WKASFAIL,X'16'      TOO MANY UNNESTINGS                  68340020
*                                  (DEFFIELD-1+REGDEFPT IS LOC  OF END- 68360020
         B     CKRERRET             OF-DEFN-LINE OPCODE)                68380020
*                                                                       68400020
CKRACFAL MVI   WKASFAIL,X'17'      INVALID (UNDEFINED) ACTION CODE      68420020
*                                   ACTION CODE RT-ADJUSTED IN REGOPCDE 68440020
*                                  (POINTED TO IN DEFN TABLE BY         68460020
*                                   REGTDFPT)                           68480020
         B     CKRACTRT            RETURN TO ACTION CODE PROCESSR       68500020
*                                                                       68520020
CKRBDLTS MVI   WKASFAIL,X'18'      INVALID LITERAL LENGTH (IN REGCHRCT  68540020
*                                   AND WKASRCNT).  DEFFIELD+REGDEFPT   68560020
         B     CKRERRET              IS LOC OF LENGTH BYTE              68580020
*                                                                       68600020
*                                                                       68620020
.NOCKRDB ANOP                                                           68640020
         EJECT                                                          68660020
*                                                                       68680020
*        CHARACTER GETTING ROUTINES                                     68700020
*                                                                       68720020
*        CALLING SEQUENCE--                                             68740020
*        SET   R6, I.E., REGSRCPT = SUPPLIED SOURCE POINTER             68760020
*        BAL   RE,GET CHARACTER ROUTINE                                 68780020
*        RETURN              THESE ROUTINES DESTROY REGISTERS 15 TO 3.  68800020
*                                                                       68820020
*                            WKAENDST AND R6 ARE INPUTS TO ALL OF THE   68840020
*                            ROUTINES.                                  68860020
*                                                                       68880020
*                            THE SUPPLIED SOURCE POINTER CONTAINS THE   68900020
*                            ADDRESS IN THE CHARACTER STRING AT WHICH   68920020
*                            TO START PROCESSING.  IF THERE ARE NO MORE 68940020
*                            SOURCE CHARACTERS BIT 0 IS SET TO ONE      68960020
*                            BEFORE THESE ROUTINES ARE ENTERED.         68980020
*                                                                       69000020
*                            ALL ROUTINES EXCEPT CKRSERCH SET WKASRCUP  69020020
*                            (UPDATE SOURCE POINTER) TO THE NEXT        69040020
*                            CHARACTER FOLLOWING THE LAST ONE GOTTEN OR 69060020
*                            SKIPPED, OR NEGATIVE IF THERE IS NO NEXT   69080020
*                            ONE.                                       69100020
*                                                                       69120020
*                            ALL OF THE ROUTINES SET WKASNDSW BIT 7=1   69140020
*                            (SOURCE END SWITCH) IF THE REQUEST IS NOT  69160020
*                            SATISFIED.  IF THE REQUEST IS SATISFIED    69180020
*                            BIT 7=0.                                   69200020
*                                                                       69220020
*                            ALL ROUTINES EXCEPT CKRSERCH SET WKASRCCR  69240020
*                            (CURRENT SOURCE POINTER) NEGATIVE IF       69260020
*                            ROUTINE IS ENTERED WITH NO CHARACTERS LEFT 69280020
*                            TO CHECK.                                  69300020
*                                                                       69320020
         EJECT                                                          69340020
*********************************************************************** 69360020
*                                                                       69380020
*        BAL   RE,CKRGTNB1   GET ONE NON BLANK CHARACTER.               69400020
*        RETURN              THIS HAS THE SAME SPEC AS CKRGTNBS         69420020
*                            EXCEPT THAT WKASRCNT IS NOT AN INPUT,      69440020
*                            WKAMVCNT IS NOT AN OUTPUT, AND IT IS       69460020
*                            ASSUMED THE REQUEST IS FOR ONE NON-BLANK   69480020
*                            CHARACTER.                                 69500020
*                                                                       69520020
*********************************************************************** 69540020
CKRGTNB1 LTR   R2,REGSRCPT         R2 = LOC OF CHAR TO START AT         69560020
         BM    CKRNONB             BR IF ALREADY OUT OF CHARS           69580020
         L     R1,WKAENDST         R1 = LOC OF LAST COL OF CHAR STR     69600020
         LA    R0,1                R0 = 1 FOR BXLE                      69620020
CKRLOOK  CLI   0(R2),C' '          IS CURRENT CHAR A BLANK              69640020
         BC    NC0,CKRGOTNB        BR IF FOUND NON BLANK                69660020
         BXLE  R2,R0,CKRLOOK       YES. LOOP UNLESS JUST DID LAST COL   69680020
*                                       OF CHAR STRING                  69700020
CKRNONB  OI    WKASRCCR,WKANOMOR  SET CURRENT S. P. NEGATIVE            69720020
         ST    REGSRCPT,WKASRCUP   UPDATE S.P. = SUPPLIED S.P.          69740020
         MVI   WKASCHRS,WKASPCHR   MOVE END OF SOURCE CHAR TO BUFFER    69760020
CKRNONB1 OI    WKASNDSW,EXCNSEND   SET ON SOURCE END SWITCH             69780020
CKRNONB2 OI    WKASRCUP,WKANOMOR  SET UPDATE S. P. NEGATIVE             69800020
         BR    RE                  RETURN                               69820020
CKRGOTNB NI    WKASNDSW,255-EXCNSEND   SET SOURCE END SW OFF            69840020
         MVC   WKASCHRS(1),0(R2)   MOVE NON BLANK CHAR TO BUFFER        69860020
         L     RF,WKAOPTPT                                              69880020
         USING IPDSNOPT,RF                                              69900020
         TM    OPTBYTE3,EXCFRFRM  IS SOURCE STANDARD FORM               69920020
         DROP  RF                                                       69940020
         BNO   CKRNOTCG           YES.  BR AROUND CHAR DEPENDENT CODE   69960020
*******************CHARACTER DEPENDENT CODE FOLLOWS*******************  69980020
         CLI   WKASCHRS,CKRLZ                                           70000020
         BH    CKRNOTCG           BR IF HIGH                            70020020
         CLI   WKASCHRS,CKRLA                                           70040020
         BL    CKRNOTCG           BR IF LOW                             70060020
         OI    WKASCHRS,CKRFOLD    FOLD LOWER CASE TO UPPER CASE        70080020
CKRNOTCG EQU   *                                                        70100020
*******************CHARACTER DEPENDENT CODE***************************  70120020
         ST    R2,WKASRCCR         SET CURRENT S.P. = LOC OF NON BLANK  70140020
CKRGONB4 LA    R2,1(R2)            SET UPDATE S.P. = NEXT               70160020
         ST    R2,WKASRCUP              CHAR IN STRING                  70180020
CKRGONB5 CLR   R2,R1               IS IT BEYOND END OF STRING           70200020
         BH    CKRNONB2            YES. BR TO SET UPDATE S.P. NEG.      70220020
         BR    RE                  NO. RETURN                           70240020
         EJECT                                                          70260020
*********************************************************************** 70280020
*                                                                       70300020
*        ENTRY TO SKIP THE NEXT X SOURCE CHARACTERS.                    70320020
*                                                                       70340020
*        BAL   RE,CKRSKANY   THIS HAS SAME SPEC AS CKRGTANY EXCEPT THAT 70360020
*        RETURN              THE CONTENT  OF WKASCHRS IS UNPREDICTABLE  70380020
*                            AND WKASRCNT MAY SPECIFY A LARGER NUMBER   70400020
*                            THAN THE SIZE OF WKASCHRS.                 70420020
*                                                                       70440020
*********************************************************************** 70460020
CKRSKANY LA    RF,CKRSKIP          SET SW TO INDICATE SKANY             70480020
         B     CKRSKOGT            GO TO COMMON ROUTINE                 70500020
*********************************************************************** 70520020
*                                                                       70540020
*        ENTRY TO GET THE NEXT X SOURCE CHARS.                          70560020
*                                                                       70580020
*        SET   WKASRCNT= NO OF CHARS WANTED, BUT NOT MORE THAN WILL     70600020
*                            FIT IN WKASCHRS.                           70620020
*        BAL   RE,CKRGTANY   THE CHARS ARE MOVED TO WKASCHRS. IF        70640020
*        RETURN              THERE IS  NOT ENOUGH SOURCE AN END OF      70660020
*                            SOURCE CHARACTER IS APPENDED TO THE LAST   70680020
*                            ONE MOVED IN THE BUFFER. WKAMVCNT IS SET   70700020
*                            TO THE NUMBER OF CHARACTERS FOUND.         70720020
*                            WKASRCCR IS SET NEGATIVE                   70740020
*********************************************************************** 70760020
CKRGTANY LA    RF,CKRGET           SET SW TO INDICATE GTANY             70780020
*                                                                       70800020
CKRSKOGT XC    WKAMVCNT(2),WKAMVCNT     SET MVCNT = 0                   70820020
         LTR   R2,REGSRCPT         REGSRCPT = LOC OF CHAR TO START AT   70840020
         BM    CKRNONB             BR IF ALREADY OUT OF CHARS           70860020
         ST    R2,WKASRCCR         CURRENT S.P. = SUPPLIED S.P.         70880020
         LA    R3,WKASCHRS         R3 = RESULT BUFFER PNTR              70900020
         NI    WKASNDSW,255-EXCNSEND    SET END SW OFF                  70920020
CKRSKGT1 BR    RF                  BR ACCORDING TO REG 15               70940020
CKRGET   IC    RF,0(0,R2)                                               70960020
         L     R1,WKAOPTPT                                              70980020
         USING IPDSNOPT,R1                                              71000020
         TM    OPTBYTE3,EXCFRFRM  IS SOURCE STANDARD FORM               71020020
         DROP  R1                                                       71040020
         BNO   CKRNCHNG           YES.  BR AROUND CHAR DEPENDENT CODE   71060020
*****    CHARACTER DEPENDENT CODE *****                                 71080020
         CLI   0(R2),CKRLZ                                              71100020
         BH    CKRNCHNG           BR IF HIGH                            71120020
         CLI   0(R2),CKRLA                                              71140020
         BL    CKRNCHNG           BR IF LOW                             71160020
         O     RF,CKRCAPCN         FOLD LOWER CASE TO UPPER CASE        71180020
*****    CHARACTER DEPENDENT CODE *****                                 71200020
CKRNCHNG STC   RF,0(0,R3)                                               71220020
         LH    RF,WKAMVCNT         INCREMENT                            71240020
         LA    RF,1(0,RF)               MVCNT                           71260020
         STH   RF,WKAMVCNT              BY ONE                          71280020
         LA    R3,1(0,R3)          UPDATE RESULT BUFFER PNTR TO POINT   71300020
*                                       TO NEXT POSITION                71320020
         CH    RF,WKASRCNT         IS MVCNT LESS THAN SRCNT             71340020
         L     R1,WKAENDST         R1 = LOC OF LAST COL OF CHAR STR     71360020
         BNL   CKRGONB4           BR IF NO                              71380020
         LA    R2,1(0,R2)          YES. R2 = LOC OF NEXT CHAR POSITION  71400020
         CR    R2,R1               IS R2 BEYOND END OF SOURCE           71420020
         BH    CKRGTNB4            YES.                                 71440020
         B     CKRGET              NO.                                  71460020
CKRSKIP  L     RF,WKASRCCR         IS SRCNT                             71480020
         AH    RF,WKASRCNT              PLUS SUPPLIED SOURCE POINTER    71500020
         C     RF,WKAENDST              GREATER THAN ADDR OF END OF STR 71520020
         BNH   CKRSKIP1            NO.                                  71540020
         B     CKRNONB1           BR IF OUT OF CHARS                    71560020
CKRSKIP1 ST    RF,WKASRCUP        SET WKASRCUP = SUPPLIED S.P. + SRCNT  71580020
         LH    RF,WKASRCNT         MVCNT = SRCNT                        71600020
         STH   RF,WKAMVCNT                                              71620020
         BR    RE                  RETURN                               71640020
         EJECT                                                          71660020
*********************************************************************** 71680020
*                                                                       71700020
*        ENTRY TO SEARCH FOR A SPECIFIED CHARACTER                      71720020
*                                                                       71740020
*        SET   WKASRCHX= CHARACTER TO BE SEARCHED FOR                   71760020
*        BAL   RE,CRRSERCH   SEARCH SOURCE FOR SPECIFIED CHARACTER.     71780020
*        RETURN              WKASRCUP IS SET TO POINT TO IT IF FOUND.   71800020
*                            IF NOT FOUND, WKASRCUP IS SET NEGATIVE     71820020
*                            (AND SOURCE END SWITCH IS SET ON).         71840020
*                                                                       71860020
*********************************************************************** 71880020
CKRSERCH LTR   R1,REGSRCPT         R1 = LOC OF CHAR TO START AT         71900020
         BM    CKRNONB1            BR IF ALREADY OUT OF CHARS           71920020
*              CKRNONB1...         END OF SOURCE SW SET ON              71940020
*                                  UPDATE PNTR SET NEGATIVE             71960020
*                                  RETURN                               71980020
         SR    RF,RF                                                    72000020
         IC    RF,WKASRCHX         RF = CHAR TO SEARCH FOR              72020020
*******************CHARACTER DEPENDENT CODE FOLLOWS*******************  72040020
         LA    R0,CKRFOLD                                               72060020
         STC   R0,WKASERTB(RF) SET BYTE IN TRT TABLE FOR CHAR TO NON-0. 72080020
         L     R2,WKAOPTPT                                              72100020
         USING IPDSNOPT,R2                                              72120020
         TM    OPTBYTE3,EXCFRFRM  IS SOURCE STANDARD FORM               72140020
         DROP  R2                                                       72160020
         BNO   CKR22              YES.  BR AROUND CHAR DEPENDENT CODE   72180020
         CLI   WKASRCHX,CKRA                                            72200020
         BL    CKR22              BR IF LOW                             72220020
         CLI   WKASRCHX,CKRZ                                            72240020
         BH    CKR22              BR IF HIGH                            72260020
         SR    RF,R0               CAPITAL LETTER,SET TRT TABLE TO      72280020
         STC   R0,WKASERTB(RF)      TEST FOR CORR.LOWER CASE LETTER TOO 72300020
*******************CHARACTER DEPENDENT CODE***************************  72320020
CKR22    L     R2,WKAENDST         R2 = LOC OF LAST COL OF CHAR STR     72340020
         SR    R2,R1               R2 = NUM-1 OF CHARS LEFT IN STRING   72360020
         BM    CKRNOMR             BR IF STRING LENGTH LESS THAN ZERO   72380020
         CL    R2,CKRF255          IS STRING LENGTH GRTR THAN 255       72400020
         BNH   CKR23               BR IF NO                             72420020
         L     R2,CKRF255          R2 = SCAN LENGTH (255)               72440020
CKR23    EX    R2,CKRSERT          SCAN FOR CHAR                        72460020
         BC    NC0,CKRSMTCH        BR IF CHAR FOUND                     72480020
         LA    R1,1(R1,R2)         UPDATE R1 TO START AT NEXT CHAR      72500020
         B     CKR22                    ADDR AFTER LAST SCAN            72520020
CKRNOMR  EQU   *                                                        72540020
         ST    R1,WKASRCUP                                              72560020
         OI    WKASRCUP,WKANOMOR  SET WKASRCUP NEGATIVE                 72580020
         OI    WKASNDSW,EXCNSEND   INDICATE END OF SOURCE REACHED       72600020
         B     CKR24              BR TO RESET TRT TABLE                 72620020
CKRSMTCH ST    R1,WKASRCUP         LOWER 3 BYTES OF WKASRCUP =          72640020
*                                       LOC OF CHAR FOUND               72660020
         NI    WKASNDSW,255-EXCNSEND    SET SOURCE END SW OFF           72680020
CKR24    SR    R2,R2               RESTORE BYTE IN TRT TABLE            72700020
         STC   R2,WKASERTB(RF)          TO ZERO                         72720020
*******************CHARACTER DEPENDENT CODE FOLLOWS*******************  72740020
         OR    RF,R0               'OR' IN FOLDING CONSTANT,POSSIBLY    72760020
*                                   RE-ZEROING A ZERO BYTE,BUT ASSURING 72780020
         STC   R2,WKASERTB(RF)       THAT BYTE CORR.TO CAP.LETTER IS 0  72800020
*******************CHARACTER DEPENDENT CODE***************************  72820020
CKR25    BR    RE                 RETURN                                72840020
         EJECT                                                          72860020
*********************************************************************** 72880020
*                                                                       72900020
*        ENTRY TO GET THE NEXT X NON BLANK SOURCE CHARS.                72920020
*                                                                       72940020
*        SET   WKASRCNT AS IN CKRGTANY.                                 72960020
*        BAL   RE,CKRGTNBS   SAME AS CKRGTANY, EXCEPT THAT ONLY NON-    72980020
*        RETURN              BLANK CHARACTERS ARE MOVED, AND THAT       73000020
*                            WKASRCCR SPECIFIES FIRST NON-BLANK         73020020
*                            CHARACTER FOUND.                           73040020
*                            IF NONE ARE FOUND, WKASRCCR IS SET         73060020
*                            NEGATIVE                                   73080020
*                                                                       73100020
*********************************************************************** 73120020
CKRGTNBS XC    WKAMVCNT(2),WKAMVCNT     SET MVCNT = 0                   73140020
         LTR   R2,REGSRCPT         R2 = LOC OF CHAR TO START AT         73160020
         BM    CKRNONB             BR IF ALREADY OUT OF CHARS           73180020
         L     R1,WKAENDST         R1 = LOC OF LAST COL OF CHAR STR     73200020
         NI    WKASNDSW,255-EXCNSEND    SET SOURCE END SW OFF           73220020
*                                       'FIRST TIME THRU' SWITCH        73240020
         OI    WKASRCCR,WKANOMOR  SET CURRENT S. P. NEGATIVE            73260020
*                                                                       73280020
         LA    R3,WKASCHRS         R3 = RESULT BUFFER PNTR              73300020
         LA    R0,1                R0 = 1 FOR BXLE                      73320020
CKRGTNBL CLI   0(R2),C' '          IS CURRENT CHAR A BLANK              73340020
         BNE   CKRGTNB2            BR IF FOUND NON BLANK                73360020
CKRGTNBE BXLE  R2,R0,CKRGTNBL      YES. LOOP UNLESS JUST DID LAST       73380020
*                                       COL OF CHAR STR                 73400020
CKRGTNB4 MVI   0(R3),WKASPCHR      MOVE END OF SOURCE CHAR TO BUFFER    73420020
         B     CKRNONB1           BR                                    73440020
*              CKRNONB1 ...        END OF SOURCE SW SET ON              73460020
*                                  UPDATE PNTR SET NEGATIVE             73480020
*                                  RETURN                               73500020
CKRGTNB2 TM    WKASRCCR,WKANOMOR  IS CURRENT S. P. NEGATIVE             73520020
         BNO   CKRGTNB3           BR IF NO                              73540020
         ST    R2,WKASRCCR         YES. SET CURRENT S.P. = LOC OF NON   73560020
*                                       BLANK                           73580020
CKRGTNB3 IC    R0,0(R2)                                                 73600020
         L     RF,WKAOPTPT                                              73620020
         USING IPDSNOPT,RF                                              73640020
         TM    OPTBYTE3,EXCFRFRM  IS SOURCE STANDARD FORM               73660020
         DROP  RF                                                       73680020
         BNO   CKRNOCHG           YES.  BR AROUND CHAR DEPENDENT CODE   73700020
*******************CHARACTER DEPENDENT CODE FOLLOWS*******************  73720020
         CLI   0(R2),CKRLZ                                              73740020
         BH    CKRNOCHG           BR IF HIGH                            73760020
         CLI   0(R2),CKRLA                                              73780020
         BL    CKRNOCHG           BR IF LOW                             73800020
         O     R0,CKRCAPCN                                              73820020
CKRNOCHG EQU   *                                                        73840020
*******************CHARACTER DEPENDENT CODE***************************  73860020
         STC   R0,0(0,R3)         STORE CHAR IN RESULT BUFFER           73880020
         LA    R0,1               RESET R0=1 FOR BXLE                   73900020
         LH    RF,WKAMVCNT         INCREMENT                            73920020
         LA    RF,1(0,RF)               MVCNT                           73940020
         STH   RF,WKAMVCNT              BY ONE                          73960020
         LA    R3,1(0,R3)          UPDATE RESULT BUFFER TO POINT TO     73980020
*                                       NEXT POSITION                   74000020
         CH    RF,WKASRCNT        IS MVCNT LESS THAN SRCNT              74020020
         BL    CKRGTNBE            YES.                                 74040020
         B     CKRGONB4            NO.                                  74060020
         EJECT                                                          74080020
*                                                                       74100020
*                                                                       74120020
*                   SYNTAX OPERATOR ROUTINES BRANCH TABLE               74140020
*                                                                       74160020
*                     INDEX                  OPERATOR  CODE             74180020
CKRSYNOP DS    0H                                                       74200020
*                                                                       74220020
CKROPNDX DC    Y(CKRLBRCE-CKRINTRP)     LEFT BRACE     00               74240020
         DC    Y(CKRRBRCE-CKRINTRP)     RIGHT BRACE    02               74260020
         DC    Y(CKROR-CKRINTRP)             OR        04               74280020
         DC    Y(CKRLPARN-CKRINTRP)          (         06               74300020
         DC    Y(CKRRPARN-CKRINTRP)          )         08               74320020
         DC    Y(CKRCOMIT-CKRINTRP)          /         0A               74340020
         DC    Y(CKRSTCMT-CKRINTRP) COLON STATM COMMIT 0C               74360020
         DC    Y(CKRITIND-CKRINTRP)          ...       0E               74380020
         DC    Y(CKRITDEF-CKRINTRP)          .N.       10               74400020
         DC    Y(CKRSYNS-CKRINTRP)           SYMBOL    12               74420020
         DC    Y(CKRMNAME-CKRINTRP)          M         14               74440020
         DC    Y(CKRNAME-CKRINTRP)           N         16               74460020
         DC    Y(CKRLETTR-CKRINTRP)          L         18               74480020
         DC    Y(CKRDIGIT-CKRINTRP)          D         1A               74500020
         DC    Y(CKRALMER-CKRINTRP)          A         1C               74520020
         DC    Y(CKRNUMBR-CKRINTRP)          K         1E               74540020
         DC    Y(CKRSTATM-CKRINTRP)          S         20               74560020
         DC    Y(CKRHOLLR-CKRINTRP)          H         22               74580020
         DC    Y(CKRCSTRG-CKRINTRP)          C         24               74600020
         DC    Y(CKRQUOTE-CKRINTRP)          'AA...A'  26               74620020
         DC    Y(CKRNOTQT-CKRINTRP)        NOT'AA...A' 28               74640020
         DC    Y(CKRSCAN-CKRINTRP)           &A        2A               74660020
         DC    Y(CKRSCANF-CKRINTRP)        &NOTA       2C               74680020
         DC    Y(CKRACTN-CKRINTRP)           $N        2E               74700020
         DC    Y(CKRMESSG-CKRINTRP)          *N        30               74720020
         DC    Y(CKRTABL-CKRINTRP)           +TBLNAME  32               74740020
         DC    Y(CKRTABL-CKRINTRP)           -TBLNAME  34               74760020
         DC    Y(CKRSYUNS-CKRINTRP)          END-OF-LN 36               74780020
CKRINVOP DC    A(*-CKROPNDX)            EXCEED HIGHEST OP-CODE          74800020
*                                                                       74820020
*              ACTION CODE ROUTINES BRANCH TABLE                        74840020
*                                                                       74860020
CKRACNDX DC    Y(CKRAR100-CKRACTN)      DISPL. TO ACTION CODE 100 RTNE  74880020
         DC    Y(CKRAR101-CKRACTN)                            101       74900020
         DC    Y(CKRAR102-CKRACTN)                            ETC       74920020
         DC    Y(CKRAR103-CKRACTN)                                      74940020
         DC    Y(CKRAR104-CKRACTN)                                      74960020
         DC    Y(CKRAR105-CKRACTN)                                      74980020
         DC    Y(CKRAR106-CKRACTN)                                      75000020
         DC    Y(CKRAR200-CKRACTN)                                      75020020
         DC    Y(CKRAR201-CKRACTN)                                      75040020
         DC    Y(CKRAR202-CKRACTN)                                      75060020
         DC    Y(CKRAR203-CKRACTN)                                      75080020
         DC    Y(CKRAR300-CKRACTN)                                      75100020
         DC    Y(CKRAR301-CKRACTN)                                      75120020
         DC    Y(CKRAR400-CKRACTN)                                      75140020
         DC    Y(CKRAR401-CKRACTN)                                      75160020
         DC    Y(CKRAR500-CKRACTN)                                      75180020
         DC    Y(CKRAR600-CKRACTN)                                      75200020
         DC    Y(CKRAR601-CKRACTN)                                      75220020
         DC    Y(CKRAR602-CKRACTN)                                      75240020
         DC    Y(CKRAR603-CKRACTN)                                      75260020
         DC    Y(CKRAR604-CKRACTN)                                      75280020
         DC    Y(CKRAR605-CKRACTN)                                      75300020
         DC    Y(CKRAR606-CKRACTN)                                      75320020
         DC    Y(CKRAR607-CKRACTN)                                      75340020
         DC    Y(CKRAR608-CKRACTN)                                      75360020
         DC    Y(CKRAR609-CKRACTN)                                      75380020
         DC    Y(CKRAR610-CKRACTN)                                      75400020
         DC    Y(CKRAR611-CKRACTN)                                      75420020
         DC    Y(CKRAR612-CKRACTN)                                      75440020
         DC    Y(CKRAR613-CKRACTN)                                      75460020
         DC    Y(CKRAR700-CKRACTN)                                      75480020
         DC    Y(CKRAR701-CKRACTN)                                      75500020
         DC    Y(CKRAR800-CKRACTN)                                      75520020
         DC    Y(CKRAR801-CKRACTN)                                      75540020
CKRINVAC DC    Y(*-CKRACNDX)       EXCEEDS HIGHEST ACTION CODE          75560020
*                                                                       75580020
*                                                                       75600020
*                                                                       75620020
CKRLNNSK DC    A(CKRNESTL)         LENGTH OF NEST.                      75640020
*******************CHARACTER DEPENDENT CODE FOLLOWS*******************  75660020
CKRCAPCN DC    A(CKRFOLD)          'OR' TO FOLD LETTER IN F WORD RTADJ  75680020
*******************CHARACTER DEPENDENT CODE***************************  75700020
CKRINTMX DC    F'10'               MAXIMUM ALLOWABLE DIGITS IN INTEGER  75720020
*                                                                       75740020
CKRMAXIG DC    C'2147483647'       MAXIMUM ALLOWABLE INTEGRAL VALUE     75760020
*                                                                       75780020
CKRFULL6 DC    F'6'                MAX NAME LENGTH, GT MAX STAT.NO.LENG 75800020
CKRFULL8 DC    F'8'                MAX. LENGTH IN DIGITS OF LEN 4 NOS.  75820020
CKRFULL2 DC    F'2'                MAX. EXPONENT LENGTH IN SIGNF.DIGITS 75840020
CKRF255  DC    F'255'              MAXIMUM SIZE FOR WIDTH               75860020
CKRF66   DC    F'66'              COL 66 IS UPPER BOUND ON F-F END STMT 75870020
CKRF0076 DC    F'76'               UPPER BOUND ON LOG OF K NUMBER       75880020
CKRFM078 DC    F'-78'              LOWER BOUND ON LOG OF K NUMBER       75900020
CKRF100M DC    F'100000000'        100,000,000 TO PREV.CKREVALU O'FLOW  75920020
CKRRLGOP DS    0H                                                       75940020
CKREQ    DC    C'EQ'                                                    75960020
CKRGT    DC    C'GT'                                                    75980020
CKRLT    DC    C'LT'                                                    76000020
CKRGE    DC    C'GE'                                                    76020020
CKRLE    DC    C'LE'                                                    76040020
CKRNE    DC    C'NE'                                                    76060020
CKRORE   DC    C'OR'                                                    76080020
CKRAN    DC    C'AN'                                                    76100020
*                                                                       76120020
*        STATEMENTS EXECUTED BY THE EXECUTE INSTRUCTION                 76140020
*                                                                       76160020
CKRCOMPR CLC   0(1,REGWORKB),WKASCHRS   COMPARE LITERAL TO SOURCE       76180020
CKRTCMPR CLC   1(1,REGTDFPT),WKASCHRS   COMPARE TBL LITERAL TO SOURCE   76200020
CKRSERT  TRT   0(0,R1),WKASERTB                                         76220020
         EJECT                                                          76240020
*                                                                       76260020
*        TRANSLATE AND TEST TABLE FOR A THROUGH Z AND 0 THROUGH 9       76280020
*                                                                       76300020
CKRLETRA DC    9X'00'                  A-I                              76320020
         DC    7X'01'                                                   76340020
         DC    9X'00'                  J-R                              76360020
         DC    8X'01'                                                   76380020
         DC    8X'00'                  S-Z                              76400020
         DC    6X'01'                                                   76420020
         DC    10X'00'                 0-9                              76440020
         DC    6X'01'                                                   76460020
CKRAMTBL EQU   CKRLETRA-193                                             76480020
*                                                                       76500020
*                                                                       76520020
*                                                                       76540020
*        EQUATES                                                        76560020
*                                                                       76580020
CKRH     EQU   C'H'                                                     76600020
CKRA     EQU     C'A'                                                   76620020
CKRZ     EQU     C'Z'                                                   76640020
CKR$     EQU     C'$'                                                   76660020
CKR0     EQU     C'0'                                                   76680020
CKR9     EQU     C'9'                                                   76700020
CKRDOT   EQU     C'.'                                                   76720020
CKRE     EQU     C'E'                                                   76740020
CKRD     EQU     C'D'                                                   76760020
CKRSGLQT EQU     C''''             SINGLE QUOTE                         76780020
CKRPLUS  EQU   C'+'                PLUS                                 76800020
CKRMINUS EQU   C'-'                MINUS                                76820020
CKRHYPHN EQU   C'-'                HYPHEN                               76840020
*******************CHARACTER DEPENDENT CODE FOLLOWS*******************  76860020
CKRLZ    EQU   X'A9'               LOWER CASE Z                         76880020
CKRLA    EQU   X'81'               LOWER CASE A                         76900020
CKRFOLD  EQU   X'40'               'OR' TO FOLD LOWER CASE TO UPPER     76920020
*******************CHARACTER DEPENDENT CODE***************************  76940020
*                                                                       76960020
*        OP-CODES REFERENCED DIRECTLY                                   76980020
CKRPLTBL EQU   X'32'               +TABLENAME                           77000020
CKRMITBL EQU   X'34'               -TABLENAME                           77020020
CKRACTON EQU   X'2E'               ACTION OR NULL (N =X'FFFF' FOR NULL) 77040020
CKRSYMLN EQU   X'12'               SYMBOLIC-LINE                        77060020
*                                                                       77080020
*        ERROR  CODES                                                   77100020
*                                                                       77120020
CKRSBUGT EQU   01                  SYSTEM OR SYNTAX CHECKER FAILURE     77140020
CKRLGNMC EQU    82                 NAME TOO LONG                        77160020
CKRINVSC EQU    84                 INVALID STATEMENT NUMBER             77180020
CKRINCHT EQU    87                 LITERAL IN WH FORMAT INCOMPLETE      77200020
CKRINVWC EQU    88                 FIELD WIDTH NOT IN RANGE 1-255       77220020
CKRLGCST EQU    91                 LITERAL EXCEEDS 255 CHARACTERS       77240020
CKROFLOT EQU    93                 NEST/QUAL LIST OVERFLOW              77260020
CKREXSCT EQU    97                 EXCESS SOURCE DATA                   77280020
CKRXPNGC EQU   116                 EXPONENT MISSING OR INVALID          77300020
CKRKWODC EQU   118                 REAL NUMBER MUST HAVE SOME DIGIT(S)  77320020
CKRLGINC EQU   120                 INTEGER TOO LARGE                    77340020
CKRQTMST EQU   123                 CLOSING  '  MISSING                  77360020
CKRINVRC EQU   130                 REAL NO. OUTSIDE ALLOWABLE RANGE     77380020
CKREMTCC EQU   144                 '' LITERAL CONTAINS NO CHARS.        77400020
CKRINVDC EQU   148                 INVALID DECIMAL POINT                77420020
*        ACTION ROUTINE ERROR MESSAGE CODES                             77440020
CKRPXSBC EQU   8                   POSSIBLY TOO MANY SUBSCRIPTS         77460020
CKREXSBC EQU   10                  TOO MANY SUBSCRIPTS                  77480020
*                                     NEXT OPERATOR                     77500020
*                                                                       77520020
*                                                                       77540020
*********************************************************************** 77560020
*                                                                     * 77580020
*        THE FOLLOWING ROUTINES, CKRLETTR (L), CKRDIGIT (D), AND      * 77600020
*        CHRALMER (A), TEST THE SOURCE FOR FORTRAN ALPHABETIC,        * 77620020
*        DIGIT, AND FORTRAN ALPHAMERIC ($, A THROUGH Z, 0 THROUGH 9), * 77640020
*        RESPECTIVELY.                                                * 77660020
*                                                                     * 77680020
*                                                                     * 77700020
*********************************************************************** 77720020
*                                                                       77740020
CKRLETTR EQU   *                   TEST FOR A LETTER, FORTRAN ALPHABET  77760020
*                                                                       77780020
         BAL   REGLRETN,CKRGTNB1   GO GET NEXT  NON-BLANK  SOURCE CHAR  77800020
         CLI   WKASCHRS,CKRZ       IS SOURCE CHAR HIGHER THAN Z         77820020
         BH    CKRFAIL              YES, FAIL                           77840020
CKRALPHA TSTAM CKRFAIL              NO, TEST FOR ALPHAMERIC,FAIL IF NOT 77860020
*                                                                       77880020
         UPDSC                     UPDATE SOURCE PT BEYOND CHAR OBTAIND 77900020
*                                                                       77920020
         B     CKRINTRP             AND GO INTERPRET NEXT OPERATOR      77940020
*                                                                       77960020
*                                                                       77980020
CKRDIGIT EQU   *                   TEST FOR DIGIT                       78000020
*                                                                       78020020
         BAL   REGLRETN,CKRGTNB1   GO GET NEXT NON-BLANK SOURCE CHAR    78040020
*                                                                       78060020
         CLI   WKASCHRS,CKR0       IS IT LOWER THAN ZERO IN EBCDIC SEQ  78080020
         BL    CKRFAIL              YES, FAIL                           78100020
         CLI   WKASCHRS,CKR9        NO, IS IT GREATER THAN 9            78120020
         BH    CKRFAIL               YES, FAIL                          78140020
*                                    NO, GOOD DIGIT                     78160020
         UPDSC                     UPDATE SOURCE POINTER BEYOND DIGIT   78180020
*                                                                       78200020
         B     CKRINTRP             AND GO INTERPRET NEXT OPERATOR      78220020
*                                                                       78240020
*                                                                       78260020
CKRALMER EQU   *                   TEST FOR ALPHAMERIC                  78280020
*                                                                       78300020
         BAL   REGLRETN,CKRGTNB1   GO GET NEXT NON-BLANK SOURCE CHAR    78320020
*                                                                       78340020
         B     CKRALPHA             AND GO TEST IT FOR ALPHAMERIC       78360020
*                                                                       78380020
*                                                                       78400020
*                                                                       78420020
*********************************************************************** 78440020
*                                                                     * 78460020
*        THE FOLLOWING ROUTINE TESTS THE SOURCE FOR A FORTRAN         * 78480020
CKRNZIRC EQU   20                  NON-ZERO INTEGER REQUIRED            78500020
CKRIDSNC EQU   26                  INVALID DATASET REF. NUMBER          78520020
CKRMSNOC EQU   42                  STATEMENT NO. MISSING (FROM FORMAT)  78540020
CKRNZRQC EQU   00                  NON-0 NO. REQ'D--NOT CURRENTLY USED  78560020
CKRINTRC EQU   72                  INTEGER REQUIRED                     78580020
CKRICPXC EQU   74                  INVALID COMPLEX NUMBER               78600020
CKRIENDT EQU    95                 BLANKS REQD IN COLUMNS 1-6 (OF END)  78620020
CKRINIMT EQU    99                 INVALID IMPLICIT RANGE               78640020
CKRDCXWC EQU   106                 DEC PLACES NOT LESS THAN FIELD WIDTH 78660020
CKRDCPUC EQU   108                 DECIMAL PLACES MUST BE SPECIFIED     78680020
CKRRPRQT EQU   111                 RIGHT PARENTHESIS REQD FOR IMPL'D DO 78700020
CKRVRSBC EQU   112                 VARIABLE MAY NOT BE SUBSCRIPTED      78720020
CKRNODBT EQU   115                 DEBUG NOT SUPPORTED                  78740020
CKRRLRQC EQU   126                 REAL NO. REQUIRED                    78760020
CKRLDILC EQU   136                 LIST-DIRECTED I/O ILLEGAL            78780020
CKRXSBPC EQU   158                 TOO MANY SUBSCRIPTS PRECEDING        78800020
CKRIENDF EQU   161                F-F END STMNT PAST COL 66             78810020
*                                                                       78820020
         LTORG                                                          78840020
CKRSOFAR EQU   *-IPDSNCKR         TROUBLE IF THIS EXCEEDS CKRLENGT      78860020
CKREXPAN EQU   CKRLENGT-CKRSOFAR                                        78880020
         DC    (CKREXPAN)C'C'      EXPANSION SPACE FILLED WITH C'S      78900020
CKRCSEND EQU   *                                                        78920020
         EJECT                                                          78940020
IPDSNWKA DSECT                                                          78960020
*                                 AREA OBTAINED FROM GETMAIN            78980020
*                                 AND PASSED TO CHECKER.                79000020
*                                                                       79020020
WKARLENT EQU   4096               LENGTH OF WORK AREA IN BYTES          79040020
*                                 MUST BE INTEGRAL MULTIPLE OF 8        79060020
*                                                                       79080020
EXCSVRGS DS    18F                EXECUTIVE'S REG. SAVE AREA.           79100020
*                                                                       79120020
*                                 PARAMETERS PASSED TO CHECKER.        C79140020
                                  ALSO, IPDSNCKR EXPECTS THIS LIST TO  C79160020
                                  BE IN IPDSNWKA                        79180020
WKACKPRM DS    0F                 PARAMETER LIST FOR IPDSNCKR           79200020
WKABEGST DS    A                  PNTR TO STMNT FIELD PORTION OF STMNT  79220020
WKAENDST DS    A                  ADDR OF LAST COL OF CHAR STRING       79240020
WKADEEF  DS    A                       ADDR. OF TABLE MODULE.           79260020
WKAWADDR DS    A                       ADDR. OF WORK AREA.              79280020
WKAOPTPT DS    A                       ADDR. OF OPTIONS WORD.           79300020
         SPACE 1                                                        79320020
*                                                                       79340020
*              ZERO IN THE EXCSYNXS TABLE INDICATES THAT THE TABLE      79360020
*              WAS NOT REQUESTED BY A 1 BIT IN THE 2ND BYTE OF THE      79380020
*              OPTIONS WORD AT INITIAL CALL, AND THAT THE TABLE WAS     79400020
*              NOT LOADED.                                              79420020
EXCSYNXS DS    A                  ZERO OR LOCATION OF IPDTEE            79440020
         DS    A                  ZERO OR LOCATION OF IPDAGH            79460020
*              CURRENT CARD LOCATION INFORMATION SET BY EXCGETRC        79480020
EXCCRCRD DS    A                  LOC OF CURRENT CARD.                  79500020
EXCCRBUF DS    A                  LOC OF BUFFER CONTAINING CURRENT CARD 79520020
EXCCRBRL DS    H                 REL POSIT OF CUR REC IN BUFFER         79540020
EXCCRREL DS    H                  REL POSIT OF CUR CARD IN BUF CHAIN    79560020
INF      EQU   *-EXCCRCRD                                               79580020
*              SAME AS EXCCRCRD INFO BUT FOR NEXT CARD. INPUT TO AND    79600020
EXCNXCRD DS    A                  ALSO SET BY EXCGETRC                  79620020
EXCNXBUF DS    A                                                        79640020
EXCNXBRL DS    H                                                        79660020
EXCNXREL DS    H                                                        79680020
*              EXCCRCRD INFO FOR FRST CARD OF A STATEMENT               79700020
EXCFSCRD DS    A                                                        79720020
         DS    A                                                        79740020
         DS    H                                                        79760020
EXCFSREL DS    H                                                        79780020
*              EXCCRCRD INFO IS SAVED HERE FOR FRST CARD OF NEXT        79800020
EXCSVCRD DS    A                  STATEMENT AND FOR FRST COMMENT        79820020
EXCSVBUF DS    A                  CARD ENCOUNTERED WITHIN A STATEMENT.  79840020
EXCSVBRL DS    H                                                        79860020
EXCSVREL DS    H                                                        79880020
BLDLLIST DS    0H                                                       79882021
FF       DS    H            LIST FOR BLDL                               79884021
LL       DS    H                                                        79886021
NAME     DS    8C                                                       79888021
TTR      DS    50C                                                      79890021
*                                                                       79892021
BLDLSWH  DS    X                                                        79894021
         DS    1C                                                       79896021
         SPACE 2                                                        79900020
WKALEVEL DS    XL1                 OPTLEVEL SAVED--FTN DEF'N FOR SCAN   79920020
WKALEVLE EQU   X'01'                LEVEL E                             79940020
WKALEVLG EQU   X'02'                LEVEL G                             79960020
WKALEVLH EQU   X'00'                LEVEL H                             79980020
WKALEVLT EQU   X'03'                   LEVEL TSO                        80000020
WKALEVG1 EQU   X'04'                   LEVEL G1                         80020020
*                                                                       80040020
WKACNCOL DS    CL1                ST-FORM, CONTENTS OF COL. 6 OF LAST   80060020
*                                 LINE OF STMNT.                        80080020
*                                 FR-FORM, NON-BLANK FOR STMNT OF MORE  80100020
*                                 THAN ONE LINE, ELSE BLANK.            80120020
*                                                                       80140020
*********************************************************************** 80160020
IPDERWKA DS    0D                 PORTION OF WORK AREA ACCESSIBLE TO    80180020
*                                  IPDERERR--MUST MATCH IPDERWKA DSECT  80200020
*                                   IN IPDER MODULE                     80220020
WKAEROPT DS    A               LOC OF 4TH BYTE OF OPTION WORD. 2ND BIT  80240020
*                              =0 INDICATES DATA SET HAS LINE NOS.      80260020
         CNOP  4,8             ALIGNED TO MIDDLE OF DOUBLE WORD         80280020
WKAERBFR DS    CL72            ERROR MESSAGE BUFFER.  MESSAGE IS LEFT-  80300020
*                              ADJUSTED IN BUFFER WITH TRAILING BLANKS. 80320020
WKAERRSC DS    A               LOC OF 6 CHARACTER ERROR STRING. WILL BE 80340020
*                              INCLUDED IN MSG UNLESS WKAERRSC IS ZERO. 80360020
WKAERPOS DS    H               LINE POSITION IN BUFFER, IN BINARY.      80380020
WKAERRCD DS    XL1             ERROR CODE. SPECIFIES WHICH MSG TO FORM. 80400020
WKAERRTM EQU   X'01'              TEST RIGHT-MOST BIT OF ERROR CODE.    80420020
*                                 1=ON FOR TERMINATING ERROR            80440020
WKASFAIL DS    XL1             NOT-OPERATIONAL ERROR BYTE               80460020
*                                  00, NO ERRORS                        80480020
*                                  01-0F, EXC NOT OPERATIONAL           80500020
*                                  11-1F, CKR NOT OPERATIONAL           80520020
*                                  21-2F, ERR NOT OPERATIONAL           80540020
WKAERNUM DS    CL8             LINE NUMBER RIGHT-ADJUSTED IN EBCDIC.    80560020
WKAERPAD DS    CL1             SPACE FOR BLANK BETWEEN WKAERNUM AND     80580020
*                              WKAERCHR.                                80600020
WKAERCHR DS    CL6             6 CHARACTER ERROR STRING                 80620020
*                                                                       80640020
*                                                                       80660020
*********************************************************************** 80680020
*                                                                       80700020
         SPACE 3                                                        80720020
*                                                                       80740020
*                                                                       80760020
*        THE AREA FROM WKACERSW TO EXCSLERR IS ZEROED WHENEVER A NEW    80780020
*        STATEMENT IS ENCOUNTERED.                                      80800020
*                                                                       80820020
WKACERSW DS    XL1                ERROR FOUND BY CHECKER.               80840020
*              FULL BYTE SWITCH  --  '01' = ON,  X'00' = OFF            80860020
EXCNCKER EQU   X'01'               1=ON WHEN CHECKER DETECTS ERROR IN   80880020
*                                       CURRENT STATEMENT               80900020
*                                                                       80920020
*                                                                       80940020
WKASNOSW DS    XL1                STATEMENT-NUMBER SWITCH BYTE.         80960020
*              FULL BYTE SWITCH  --  '01' = ON,  X'00' = OFF            80980020
*                                 1 - INITIAL LINE HAS STMNT-NO.        81000020
*                                 0 - INITIAL LINE HAS NO STMNT-NO.     81020020
EXCNSTNO EQU   X'01'               1=ON WHEN STATEMENT IS LABELLED      81040020
*                                                                       81060020
*                                                                       81080020
*                                                                       81100020
EXCFSCOM DS    X        0   - NO COMMENT CARD SINCE BEGINNING OF STMNT C81120020
                        255 - HAVE ENCOUNTERED A COMMENT CARD           81140020
EXCOMSG  DS    X        0   - INTERVENING COMMENT CARD MSG HAS NOT     C81160020
                              BEEN SENT.                               C81180020
                        255 - IT HAS TOO BEEN SENT                      81200020
EXCFSCON DS    X        0   - NO CONTINUATION HAS PRECEDED FRST STMNT  C81220020
                              IN BUFFER CHAIN                          C81240020
                        255 -CONTINUATION ENCOUNTERED FIRST             81260020
EXCEXSLN DS    X             0   -NO EXTRA STMNT LINES ENCOUNTERED      81280020
*                                      BEFORE THIS LINE                 81300020
*                            255 -HAVE ENCOUNTERED EXTRA STMNT LINE     81320020
*        STATEMENT LABEL ERROR SWITCH.  SETTINGS INDICATE ERRORS        81340020
*        OR POTENTIAL ERRORS TO BE FOUND WHILE PROCESSING FREE-FORM     81360020
*        STATEMENT LABEL FIELD.                                         81380020
*                                                                       81400020
EXCSLERR DS    XL1                ONE BYTE SWITCH                       81420020
EXCDGLBL EQU   X'80'                   LBL CONTAINS DIGIT 1-9           81440020
EXCSLZRO EQU   X'40'                   ZERO FOUND IN LBL                81460020
EXCSLER2 EQU   X'20'                   INVAL STMNT LBL (EXTRAN. CHARS)  81480020
EXCEXTCH EQU   X'10'                   EXTRANEOUS CHAR FOUND            81500020
EXCSLER1 EQU   X'04'                   STMNT FIELD MISSING              81520020
EXCLBMSG EQU   X'02'                   MSG FOR INVAL LBL ALREADY SENT   81540020
*                                                                       81560020
EXCRLSBF EQU   X'80'              ALLOW BUFFER RELEASE                  81580020
*                                                                       81600020
IPDEXCWK DS    0C                 MISCELLANEOUS EXECUTIVE (IPDSNEXC)    81620020
*                                 WORK AREA                             81640020
EXCSVLNN DS    CL8                TEMP. STORAGE FOR LINE NO. OF RECORD  81660020
*                                 POINTED TO BY EXCSVCRD                81680020
WKATECHR DS    CL6               TEMP. STORAGE FOR 6-CHAR. ERROR STRING 81700020
EXCSVLBL DS    A                  SAVE AREA FOR CURRENT DIGIT ADDR      81720020
*                                      IN STMNT LABEL                   81740020
WKATERSC DS    A                 TEMP. STORAGE FOR LOC. OF ERROR STRING 81760020
EXCFCHAR DS    XL1                     FOR FOLDING OF ALPHABETICS       81780020
         SPACE 3                                                        81800020
*              WKATINU TABLE.  CONTAINS 20 ENTRIES TO ALLOW FOR UP TO   81820020
*              20 LINES PER STATEMENT.  EACH ENTRY ALLOWS SPACE FOR THE 81840020
*              DISPLACEMENT OF THE LAST BYTE OF LINE TEXT (2 BYTES)     81860020
*              FROM THE BEGINNING OF THE CHARACTER STRING AND THE DATA  81880020
*              SET OR RELATIVE LINE NUMBER (8 BYTES) ASSOCIATED WITH    81900020
*              THE LINE.  BIT 0 OF THE NTH ENTRY IS SET=1 WHEN THE      81920020
*              (N-1)TH ENTRY POINTS TO THE LAST LINE OF THE STATEMENT.  81940020
         SPACE 3                                                        81960020
WKATINU  DS    0H                 WKATINU TABLE                         81980020
         DS    20CL10                                                   82000020
         DS    CL2                                                      82020020
         SPACE 3                                                        82040020
         SPACE 1                                                        82060020
WKACHRST DS    CL1325             CHARACTER STRING WORK AREA            82080020
*                                 CONTAINS FORTRAN SOURCE MOVED FROM    82100020
*                                 THE INPUT BUFFER BY IPDSNEXC.         82120020
         SPACE 3                                                        82140020
WKASERTB DS    CL256              TRT TABLE USED BY CKRSERCH ROUTINE    82160020
         SPACE 3                                                        82180020
WKAGTCHR DS    0F             AREAS FOR COMMUNIC. WITH GET CHAR. RTNES  82200020
*                                                                       82220020
WKASRCCR DS    F                  CURRENT SOURCE POINTER                82240020
WKASRCUP DS    F                  UPDATE SOURCE POINTER.                82260020
WKANOMOR EQU   X'80'               IN HIGH-ORDER BYTE OF PT (PT NEG.)   82280020
*                                  INDICATES NO MORE SOURCE CHARS)      82300020
         SPACE 3                                                        82320020
         DS    0H                 HALF-WORD ALIGNMENT FOR WKASCHRS      82340020
WKASCHRS DS    20CL1               CHAR.RESULT AREA OF GET CHAR. RTNES  82360020
WKASCMAX EQU   *-WKASCHRS         LENGTH OF CHAR.AREA, FOLLOW WKASCHRS. 82380020
*                                                                       82400020
WKASRCNT DS    H                  NO. CHARS. TO BE MOVED                82420020
WKAMVCNT DS    H                  NO. CHARS. MOVED                      82440020
*                                       TO WKASCHRS BY GET CHAR. RTNES  82460020
*                                                                       82480020
WKASRCHX DS    XL1                SERCH CHARACTER                       82500020
*                                                                       82520020
WKASNDSW DS    XL1                SOURCE-END SWITCH.                    82540020
*              FULL BYTE SWITCH  --  '01' = ON,  X'00' = OFF            82560020
EXCNSEND EQU   X'01'               1=ON WHEN END OF SOURCE ENCOUNTERED  82580020
*                                                                       82600020
WKASPCHR EQU   X'30'               SPECIAL CHAR. FOR NO-MORE-SOURCE,    82620020
*                                                                       82640020
*                                                                       82660020
*                                                                       82680020
IPDCKWRK DS    0F             MISCELLANEOUS CHECKER WORK AREAS          82700020
*                                                                       82720020
WKASVR13 DS    F                   CALLERS REGISTER 13 SAVED BY CKR     82740020
WKABEGSC DS    F                   PTR TO 1ST NONBLANK CHAR IN STAT.    82760020
WKALDZCT DS    F              K OPERATOR LEADING-ZEROES COUNT           82780020
WKADGTCT DS    F              K OPERATOR DIGIT COUNT                    82800020
WKAZROCT DS    F              K OPERATOR ZERO COUNT                     82820020
WKATENPW DS    F                   POWER OF TEN .D=0, DD=2, .000D=-3    82840020
*                                  (USED IN K-OPERATOR, WITH EXPONENT,  82860020
*                                   TO TEST SIZE OF A REAL NUMBER)      82880020
*                                                                       82900020
WKAADNLS DS    F                   A(WKANLIST)                          82920020
WKATPQLS DS    F              TOP OF Q LIST--CAN SHIFT TO WKAQLIST      82940020
WKAVALUE DS    F                   COMPUTED BY CKREVALU SUBR.           82960020
WKAWIDTH DS    F                   W OF FIELD DESCRIPTOR FORMS          82980020
WKACKRGS DS    16F                 CHECKER REGS 0-15                    83000020
WKASAVNQ DS    F                   NEST POINTER SAVED                   83020020
         DS    F                   QUAL POINTER SAVED                   83040020
WKACSVSC DS    F              SAVED SOURCE POINTER                      83060020
WKASVRTN DS    F                   RETURN REG SAVE AREA FOR CKREVALU    83080020
WKAGTSV  DS    4F                  REG. SAVE AREA FOR GET CHAR. SUBRS.  83100020
*                                                                       83120020
*                                  MESSAGES-ISSUED TABLE                83140020
*                                                                       83160020
WKAMSGAD DS    A(WKAMSGTB)         LOC. FOR NEXT MSG IN TABLE           83180020
WKAMSGTB DS    0F                  TABLE OF MSG'S ISSUED THIS STATEMENT 83200020
         DS    X                   CODE AS EVEN NUMBR                   83220020
         DS    AL3                 FAILING CHARACTER ADDRESS            83240020
         DS    4F                  SPACE FOR 5 IN ALL                   83260020
WKAMGTND EQU   *                   LOC. PAST END OF TABLE               83280020
WKATEMPH DS    H                   HALFWORD FOR REG LOADING             83300020
WKACNTDG DS    H                   NO. OF CONTINUOUS DIGITS EVALUATED   83320020
WKACKRSW DS    XL1            IPDSNCKR SWITCHES                         83340020
WKAFALSW EQU   WKACKRSW       FALSE SWITCH                              83360020
WKAGLCMT EQU   WKACKRSW       GLOBAL (STATEMENT) COMMIT SWITCH          83380020
CKRGLCMT EQU   X'40'               BIT DEFN 1=GLOBAL COMMIT IN EFFECT   83400020
*                                              FOR STATEMENT            83420020
CKRFALSW EQU   X'80'               BIT DEFINED 1= FAILURE               83440020
*                                                                       83460020
WKAKSWCH DS    XL1            K OPERATOR SWITCHES                       83480020
CKRKTYPI EQU   X'01'               TYPE BIT    1=INTEGER, 0 = REAL      83500020
CKRKLEND EQU   X'02'               LENGTH BIT  1 = D ,    0 = E         83520020
CKRKVALU EQU   X'04'               VALUE BIT   1=NONZERO, 0 = ZERO      83540020
CKRKFAIL EQU   CKRKTYPI+CKRKLEND+CKRKVALU      1,1,1 IS FAILURE         83560020
WKASVKSW DS    XL1            SAVED K SWITCHES FOR REAL PART OF CMPX NO 83580020
WKANONZS DS    XL1                 SWITCH--0 IF NO.NON-ZERO DIGITS WERE 83600020
*                                            ENCOUNTERED (IN K OPER.)   83620020
*                                          OTHERWIZE, NOT 0             83640020
*                                                                       83660020
WKAEXPSN DS    CL1                 SIGN OF EXPONENT (USED IN K OPER.)   83680020
WKAEXINT EQU   X'FF'               INITIAL VALUE FOR K OPERATOR. TURNED 83700020
*                                  OFF ON RECOGNITION OF 1ST EXP.       83720020
WKASWTCH DS    XL1            TEMPORARY PROCESSING SWITCHES             83740020
CKRLGNMA EQU   X'01'               NAME OPERATOR SW ,1=LONG NAME ALLOWD 83760020
CKRMATCH EQU   X'02'               QUOTED LITERAL OP SW, 1=MATCH REQD   83780020
CKRSUBSC EQU   X'04'               SUBSCRIPTING SW, 1= VARIABLE IS SUBD 83800020
WKAIMPL1 DS    CL1                 IMPLICIT RANGE L1 (OR  JUST L)       83820020
WKASVICT DS    XL1            SAVED ITERATION COUNT                     83840020
WKATBLOP DS    XL1                 CODE FOR + OR - TABLE OPERATOR       83860020
*                                                                       83880020
         DS    0H                                                       83900020
WKALNEST DS    0CL6           LINE NEST                                 83920020
WKANDFPT DS    H                   POINTER TO CURRENT DEFINITION LINE   83940020
WKANDFBK DS    H                   POINTER BACK TO EARLIER DEFINITION   83960020
WKANLVLN DS    XL1                 LEVEL OF NESTING (= 1 FOR TOP LINE)  83980020
WKANFMSG DS    XL1                 MESSAGE CODE IN EFFECT               84000020
CKRNESTL EQU   *-WKALNEST     LENGTH OF LINE NEST                       84020020
*                                                                       84040020
WKANLIST EQU   *              NEST LIST FOLLOWS LINE NEST               84060020
*                                                                       84080020
*                                                                       84100020
               DS    XL1616       NEST/QUALIFICATION STACK              84120020
*                                                                       84140020
*                                                                       84160020
         DS    0F                                                       84180020
WKAQLIST EQU   *              QUALIFICATION LIST PRECEDES QUALIFICATION 84200020
         DS    0F                                                       84220020
WKAQUALF DS    0CL12          QUALIFICATION                             84240020
WKAQSCPT DS    F                   POINTER TO SOURCE FOR RETRY          84260020
WKAQDFBK DS    H                   POINTER TO DEFINITION FOR ITERATION  84280020
WKAQNLVL DS    XL1                 LEVEL OF CORRESPONDING LINE NEST     84300020
WKAQFALS DS    XL1                 DISPLACEMENT TO ALTERNATIVE DEFIN'N  84320020
WKAQTRUE DS    XL1                 DISPLACEMENT TO RIGHT BRACE          84340020
WKAQICNT DS    XL1                 ITERATION COUNT                      84360020
WKAQSWCH DS    XL1                 SWITCH FIELD                         84380020
CKRCMTSW EQU   X'80'                    COMMIT SWITCH                   84400020
         DS    XL1                 FILLER                               84420020
CKRQUALL EQU   *-WKAQUALF     LENGTH OF QUALIFICATION                   84440020
*                                                                       84460020
*                                                                       84480020
*                                                                       84500020
WKASPACE EQU   *-IPDSNWKA+8        TROUBLE IF THIS EXCEEDS WKARLENT     84520020
WKAEXPAN EQU   WKARLENT-WKASPACE                                        84540020
         DS    (WKAEXPAN)C         EXPANSION SPACE                      84560020
*                                                                       84580020
*                                                                       84600020
*                                                                       84620020
WKADNAME DS    CL8'IPDSNWKA'       NAME OF DSECT FOR RECOG. IN DUMPS    84640020
WKAREAND EQU   *                  ASSEMBLY VALUE SHOULD MATCH WKARLENT  84660020
*                                                                       84680020
*                                                                       84700020
*                                                                       84720020
*                                                                       84740020
NLSDSECT DSECT                                                          84760020
NLSLNEST DS    0CL6           LINE NEST LIST ENTRY                      84780020
*                                  FIELDS CORRESPOND TO WKALNEST FIELDS 84800020
NLSNDFPT DS    H                                                        84820020
NLSNDFBK DS    H                                                        84840020
NLSNLEVL DS    XL1                                                      84860020
NLSNFMSG DS    XL1                                                      84880020
*                                                                       84900020
*                                                                       84920020
*                                                                       84940020
*                                                                       84960020
QLSDSECT DSECT                                                          84980020
QLSQUALF DS    0CL12          QUALIFICATION LIST ENTRY                  85000020
*                                  FIELDS CORRESPOND TO WKAQUALF FIELDS 85020020
QLSQSCPT DS    F                                                        85040020
QLSQDFBK DS    H                                                        85060020
QLSQNLVL DS    XL1                                                      85080020
QLSQFALS DS    XL1                                                      85100020
QLSQTRUE DS    XL1                                                      85120020
QLSQICNT DS    XL1                                                      85140020
QLSQSWCH DS    XL1                                                      85160020
         DS    XL1                                                      85180020
*                                                                       85200020
*                                                                       85220020
*                                                                       85240020
*                                                                       85260020
DEFTABLE DSECT                LANGUAGE SYNTAX DEFINITION TABLE          85280020
DEFFIELD DS    0XL1                                                     85300020
DEFOPCDE DS    XL1                 OPERATION                            85320020
DEFARGUM DS    XL1                 OPERATION'S ARGUMENT, IF ANY         85340020
         END   IPDSNEXC                                                 92340020
