*TITLE 'GRAPHIC ATTENTION HANDLING MODULE'                              00020000
*STATUS:CHANGE LEVEL 0                                                  00040000
*FUNCTION:PROVIDE FIRST LEVEL GRAPHIC ATTENTION HANDLING.               00060000
*   1.DETERMINE IF DEVICE UNDER BASIC OR EXPRESS ENVIRONMENT.           00080000
*   2.IF EXPRESS IT SETS THE APPROPRIATE BIT IN THE GCB EXTENSION OF    00100000
*     THE UCB.                                                          00120000
*   3.IF BASIC IT SCHEDULES THE SECOND LEVEL GRAPHIC CONTROL PROGRAM    00140000
*     VIA STAGE 2 OF THE ASYNCRONOUS EXIT EFFECTOR(AEE).UCB ADDRESS     00160000
*     AND STATUS BITS ARE PASSED VIA PARAMETER FIELD OF IQE.            00180000
*INPUT:GR#7 CONTAINS UCB ADDRESS AND GR#14 CONTAINS RETURN ADDRESS.     00200000
*OUTPUT:IQE TO AEE STAGE 2 TO SCHEDULE SECOND LEVEL GRAPHIC CONTROL     00220000
*       PROGRAM(BASIC) OR A BIT SET IN GCB(EXPRESS).                    00240000
*EXTERNAL ROUTINE:1.BASIC-AEE STAGE 2.                                  00260000
*                 2.EXPRESS-N/A                                         00280000
*EXITS:ALL EXITS VIA GR#14.                                             00300000
*TABLES/WORKAREAS:N/A                                                   00320000
*ATTRIBUTES:1.RESIDENT IN NUCLEUS                                       00340000
*           2.SUPERVISOR STATE                                          00360000
*           3.DISABLED                                                  00380000
*           4.SERIAL REUSEABLE                                          00400000
*NOTES:N/A                                                              00420000
PARREG   EQU   1                       PARAMETER REG                    00440000
BASEREG  EQU   2                       BASE REG                         00460000
RTE      EQU   3                       TE ADR REG                       00480000
GASREG   EQU   4                       GAS IRB ADR REG                  00500000
IQEREG   EQU   5                       IQE ADR REG                      00520000
TCBREG   EQU   6                        TASK CONTROL BLOCK       A28435 00530000
UCBREG   EQU   7                       UCB ADR REG                      00540000
AEEREG   EQU   10                      AEE ADR REG                      00560000
RTNREG   EQU   14                      RETURN REG                       00580000
ENTREG   EQU   15                      ENTRY  REG                       00600000
STATA    EQU   3                       OFFSET TO STATUS A FLD IN UCB    00620000
ALLOCATE EQU   X'08'                   ALLOCATE BIT                     00640000
USERTE   EQU   28                      OFFSET TO USER TE PTR            00660000
GRAPHTE  EQU   32                      OFFSET TO GRAPHIC INITIATOR TE   00680000
TEBTCB   EQU   8                        DISPLACEMENT IN TASK     A28435 00684000
*                                            ENTRY BLOCK FOR TASKA28435 00688000
*                                            CONTROL BLOCK       A28435 00692000
*                                            ADDRESS             A28435 00696000
TEFLG    EQU   20                      OFFSET TO TE FLAGS FLD           00700000
TE       EQU   X'80'                   TE BIT                           00720000
TEGAS    EQU   24                      OFFSET TO GAS IRB ADR            00740000
NEXAVL   EQU   96                      NEXT AVAIL IQE FLD IN IRB        00760000
LINK     EQU   0                       IQE LINK FLD                     00780000
TCBFLGS  EQU   29                       TASK CONTROL BLOCK FLAG  A28435 00783000
*                                            BYTE FIELD          A28435 00786000
*                                            DISPLACEMENT        A28435 00789000
TCBFA    EQU   X'80'                    TASK ABEND IN PROGRESS   A28435 00792000
*                                            FLAG                A28435 00795000
PARAM    EQU   4                       PARAM FLD OF IQE                 00800000
STATUS   EQU   68                      STATUS FLD OF CSW                00820000
LPORAS   EQU   X'02'                   LITE PEN OR ASYNCHRONOUS ERR.BIT 00840000
KEYBRD   EQU   X'01'                   KEYBORAD BIT                     00860000
UNTCHK   EQU   X'02'                   UNIT CHECK BIT                   00880000
ATTENT   EQU   X'80'                   ATTENTION BIT                    00900000
CSWSTA   EQU   68                      CSW STATUS BYTE 1                00920000
BASIC    EQU   X'08'                   INDICATES BASIC SYSTEM DESIRED   00940000
PROATTN  EQU   X'40'                   GCB FLAG INDICATES THAT   A32068 00945000
*                                      ATTNS WILL BE ACCEPTED    A32068 00950000
*                                      FROM THIS DEVICE          A32068 00955000
GCB      EQU   27                      OFFSET TO GCB                    00960000
GFX      EQU   8                                                   RSTC 00963016
USECNT   EQU   26                                                  RSTC 00966016
GJPBIT   EQU   X'80'                                               RSTC 00969016
CVT      EQU   16                                                  RSTC 00972016
CVTQOCR  EQU   X'AC'                                               RSTC 00975016
IFFABA   CSECT                                                          00980000
*A9450-9550,A13060-13300                                         A32068 00982000
*D13200                                                          A32068 00988000
*1033,012400                                                       RSTC 00990016
         ENTRY IFFIOM                                                   01000000
         USING *,15                                                     01020000
IFFIOM   STM   14,12,SAVE              SAVE REGISTERS                   01040000
         DROP  15                                                       01060000
         BALR  BASEREG,0               SET UP NEW BASE REGISTER         01080000
         USING *,2                     DEFINE BASE REGISTER             01100000
         TM    GCB(UCBREG),BASIC       BASIC OR EXPRESS DESIRED         01120000
         BC    1,GA01                  BRANCH IF BASIC                  01140000
         TM    CSWSTA(0),ATTENT        TEST FOR AN ATTN                 01160000
         BC    14,GAOUT                BRANCH IF NO ATTN                01180000
         TM    CSWSTA(0),UNTCHK        TEST FOR UNIT CHECK              01200000
         BC    1,GA04                  BRANCH IF ON                     01220000
*   TEST FOR GJP ENVIRONMENT                                       RSTC 01222016
         TM    GCB(UCBREG),GJPBIT       TEST FOR GJP BIT IN UCB    RSTC 01224016
         BC    8,GA05                   BRANCH NOT ON              RSTC 01226016
         CLI   USECNT(UCBREG),X'00'     TEST USECNT FOR 0          RSTC 01228016
         BNE   GA05                     BRANCH IF NOT              RSTC 01230016
         L     ENTREG,CVT               PIDK UP CVT ADDR           RSTC 01232016
         L     ENTREG,CVTQOCR(ENTREG)  LOAD PTR TO PARAM LIST      RSTC 01234016
         LTR   ENTREG,ENTREG                                       RSTC 01236016
         BC    8,GA05                                              RSTC 01238016
         L     ENTREG,GFX(ENTREG)       LOAD GFX ADR               RSTC 01240016
         LR    PARREG,UCBREG            PUT UCB ADR IN PARM REG1   RSTC 01242016
         LA    PARREG,0(PARREG)         CLEAR HIGH ORDER BYTE      RSTC 01244016
         BALR  14,15                    BRANCH TO GFX              RSTC 01246016
         B     GAOUT                                               RSTC 01248016
GA05     OI    GCB(UCBREG),KEYBRD       SET KEYBOARD BIT           RSTC 01250016
         B     GAOUT                   BRANCH                           01260000
GA04     OI    GCB(UCBREG),LPORAS      SET LITE PEN OR ASYNCH.ERR.BIT   01280000
         B     GAOUT                   BRANCH                           01300000
GA01     TM    GCB(UCBREG),PROATTN     IS FLAG ON INDICATING     A32068 01306000
*                                      DEVICE IS ACTIVE          A32068 01312000
         BZ    GAOUT                   NO - DO NOT PROCESS ATTNS A32068 01318000
*                                      FROM THIS DEVICE          A32068 01324000
         L     RTE,USERTE(0,UCBREG)    LOAD USER TE ADDR                01330000
GA02     LA    RTE,0(0,RTE)            ZERO HI ORDER BYTE               01340000
         LTR   RTE,RTE                 DOES TE ADR  EXIST               01360000
         BC    7,GA03                  BRANCH IF YES                    01380000
GAOUT    LM    14,12,SAVE              RESTORE REGS                     01400000
         BR    RTNREG                  RETURN TO SUPV                   01420000
GA03     TM    TEFLG(RTE),TE           IS TE FLAG ON                    01440000
         BC    14,GAOUT                BRANCH IF NO                     01460000
         L     TCBREG,TEBTCB(RTE)       GET TASK CONTROL BLOCK   A28435 01462000
*                                            FOR TASK IN CONTROL A28435 01464000
*                                            OF DEVICE THE       A28435 01466000
*                                            ATTENTION IS FROM   A28435 01468000
         TM    TCBFLGS(TCBREG),TCBFA    IS ABEND IN PROCESS      A28435 01470000
*                                            FLAG ON FOR THIS    A28435 01472000
*                                            TASK                A28435 01474000
         BO    GAOUT                    IF YES TAKE BRANCH       A28435 01476000
         L     GASREG,TEGAS(0,RTE)     LOAD GAS IRB ADR                 01480000
         L     IQEREG,NEXAVL(0,GASREG) LOAD ADR OF NEXT AVAILABLE IQE   01500000
         LA    IQEREG,0(0,IQEREG)      ZERO HI ORDER BYTE               01520000
         LTR   IQEREG,IQEREG           ANY IQES AVAILABLE               01540000
         BC    8,GAOUT                 BRANCH IF NONE AVAILABLE         01560000
         MVC   NEXAVL(4,GASREG),LINK(IQEREG) IQE LINK ADR TO IRB NEXAVL 01580000
         ST    UCBREG,PARAM(IQEREG)    UCB ADR TO THE IQE PARAM FLD     01600000
         MVC   PARAM(1,IQEREG),STATUS  STATUS BITS TO IQE PARAM FLD     01620000
         LR    ENTREG,AEEREG           AEE STAGE TWO ADR TO ENTRY REG   01640000
         LNR   PARREG,IQEREG           IQE ADR IN COMP FORM TO REG1     01660000
         BALR  RTNREG,ENTREG           LINK TO AEE                      01680000
         B     GAOUT                   BRANCH                           01700000
         DS    0F                                                       01720000
SAVE     DC    15F'0'                                                   01740000
         END                                                            01760000
