*TITLE 'GRAPHIC ATTENTION ANALYSIS ROUTINE'                             00020000
*STATUS:CHANGE LEVEL 0                                                  00040000
*FUNCTION/OPERATION:THIS ROUTINE DETERMINES IF AN ATTENTION HAS OCCURED 00060000
*   BY POLLING BITS 6 AND 7 IN THE INDIVIDUAL GRAPHIC CONTROL BYTES     00080000
*   (GCB).THIS ROUTINE DETERMINES THE TYPE OF ATTENTION THAT OCCURED    00100000
*   BY USE OF GCB BITS 6 AND 7 AND THE SENSE BYTES IN THE UNIT CONTROL  00120000
*   BLOCK(UCB).A UNIQUE RETURN CODE FOR EACH TYPE OF ATTENTION IE.LITE  00140000
*   PEN,KEYBOARD,END ORDER SEQUENCE OR ASYNCH.ERROR IS PUT IN GR#15.    00160000
*   CODES ARE PLACED IN GR#15 FOR PARAMETERS MISSING,WORD 5 IN TABLE    00180000
*   OF ADDRESSES MISSING OR NO ATTENTIONS OCCURED.WHEN RETURN IS        00200000
*   MADE TO THE CALLING PROGRAM THE REST OF THE CODING GENERATED BY     00220000
*   THE ANALYZ MACRO DECODES GR#15 AND EITHER PASSES CONTROL TO A USER  00240000
*   ATTENTION ROUTINE OR GENERATES A RETURN CODE TO PLACE IN GR#15      00260000
*   AS PER THE SRL.REGISTERS 1 THRU 12 ARE SAVED ON ENTRY AND RESTORED  00280000
*   UPON EXIT.SAVE AREA POINTED TO BY GR#13 AS PER CONVENTIONS.         00300000
*ENTRY POINTS:IFFANA ALIAS ANLZ.POLL FOR AN ATTENTION.                  00320000
*       L    15,ADDR                                                    00340000
*       BALR 14,15                                                      00360000
*               X                                                       00380000
*               X                                                       00400000
*   ADR DC   V(ANLZ)                                                    00420000
*               X                                                       00440000
*               X                                                       00460000
*               X                                                       00480000
*INPUT:GR#1 CONTAINS ADR OF PARAMETER LIST WHICH IS CONSTRUCTED AS      00500000
*   FOLLOWS:                                                            00520000
*       ******************                                              00540000
*   LIST* DCBLST ADDRESS *(0)                                           00560000
*       ******************                                              00580000
*       * POINTR ADDRESS *(4)                                           00600000
*       ******************                                              00620000
*       * RESERVED       *(8)                                           00640000
*       ******************                                              00660000
*OUTPUT:GR#0 CONTAINS ADDRESS OF OUTPUT AREA(IN CASE OF MULTIPLE OUTPUT 00680000
*   AREAS DEFINED BY MULTIPLE ANALYZ MACROS IN A SINGLE ASSEMBLY).      00700000
*   OUTPUT AREA IS AS FOLLOWS:                                          00720000
*       ****************                                                00740000
*   OUT * SENSE INFO   * (0)                                            00760000
*       ****************                                                00780000
*       * IX * DCB ADR * (4)                                            00800000
*       ****************                                                00820000
*         IX=VALID USE ONLY FOR MULTIPLE 2260S ASSIGNED TO A SINGLE     00840000
*   DATA CONTROL BLOCK(DCB).GIVES THE NUMBER OF THE UCB ADR EXTENT TO   00860000
*   THE DATA EXTENT BLOCK IE 0,1,2 ETC.                                 00880000
*   SENSE INFO VALID ONLY FOR LITE PEN,END ORDER SEQUENCE AND ASYNCH.   00900000
*   ERROR ATTENTIONS.                                                   00920000
*   GR#15 CONTAINS RETURN CODES AS DESCRIBED IN EXITS NORMAL AND ERROR. 00940000
*   RETURN CODES ARE FOR DECODING BY ANALYZ MACRO EXPANSION.            00960000
*EXTERNAL ROUTINES:N/A                                                  00980000
*EXITS NORMAL:IN ALL CASES CONTROL IS RETURNED TO THE ANALYZ MACRO      01000000
*   EXPANSION CODING IN THE CALLING PROG.WITH A RETURN CODE IN GR#15.   01020000
*   THE RETURN CODES ARE AS FOLLOWS:                                    01040000
*   LITE PEN=00               X                                         01060000
*   KEYBOARD(AN OR PF)=04     X                                         01080000
*   ASYNCHRONOUS ERROR=08     XXCODES ARE IN HEX                        01100000
*   END ORDER SEQUENCE=0C     X                                         01120000
*   NO ATTENTIONS PRESENT=10  X                                         01140000
*   LA  15,RETURN CODE                                                  01160000
*   BR  14                                                              01180000
*EXITS-ERROR:IN ALL CASES CONTROL IS RETURNED TO THE ANALYZ MACRO       01200000
*   EXPANSION CODING IN THE CALLING PROG.WITH A RETURN CODE IN GR#15.   01220000
*   THE RETURN CODES ARE AS FOLLOWS:                                    01240000
*   PARAMETER MISSING=18                      XCODES ARE IN HEX         01260000
*   WORD 5 IN ADDRESS TABLE(POINTR)MISSING=20 X                         01280000
*   LA  15,RETURN CODE                                                  01300000
*   BR  14                                                              01320000
*TABLES/WORK AREAS:A TABLE OF USER ATTENTION ROUTINE ADDRS. AS POINTED  01340000
*   TO BY THE POINTR PARAMETER OF THE ANALYZ MACRO.IT IS CONSTRUCTED AS 01360000
*   FOLLOWS.                                                            01380000
*   **************************                                          01400000
*   * LITE PEN ADR           *(0)                                       01420000
*   **************************                                          01440000
*   * KEYBOARD ADR           *(4)                                       01460000
*   **************************                                          01480000
*   * ASYNCHRONOUS ERROR ADR *(8)                                       01500000
*   **************************                                          01520000
*   * END ORDER SEQUENCE ADR *(12)                                      01540000
*   **************************                                          01560000
*  * OUTPUT AREA ADR         *(16)  OUTPUT AREA CONSTRUCTED AS SHOWN    01580000
*   **************************      IN OUTPUT HEADING ABOVE.            01600000
*ATTRIBUTES:RE-ENTRANT                                                  01620000
*NOTES:THE RETURN CODES AS GENERATED BY THIS ROUTINE ARE FOR INTERNAL   01640000
*   USE ONLY AND ARE NOT THE RETURN CODES LOGICALLY PRESENTED TO THE    01660000
*   CALLING PROBLEM PROGRAM.THE RETURN CODES LOGICALLY PRESENTED  TO    01680000
*   THE PROBLEM PROGRAM ARE AS FOLLOWS:                                 01700000
*   NORMAL RETURN=00                                  X                 01720000
*   NO ATTENTIONS=04                                  X                 01740000
*   ATTENTION OCCURED BUT NO USER ROUTINE PROVIDED 08 XCODES ARE IN HEX 01760000
*   PARAMETER MISSING=0C                              X                 01780000
*   WORD 5 IN ADDRESS TABLE MISSING=10                X                 01800000
*   IT IS THE RESPONSIBILITY OF THE USER ATTENTION ROUTINES TO SAVE AND 01820000
*   RESTORE REGISTERS ONCE CONTROL IS GIVEN TO THEM.                    01840000
*                                                                       01860000
*        REGISTER DEFINITION                                            01880000
REG0     EQU   0                       PARAM REGISTER                   01900000
LISTRG   EQU   1                        POINTER TO PARAMETER LIST       01920000
BASERG   EQU   2                        BASE REGISTER                   01940000
TABREG   EQU   3                        POINTER TO TABLE                01960000
DCBREG   EQU   4                        POINTER TO DCB LIST             01980000
INDXRG   EQU   5                        INDEX REGISTER                  02000000
GBREG1   EQU   6                        WORK REG                        02020000
GBREG2   EQU   7                        WORK REG                        02040000
GBREG3   EQU   8                        WORK REG                        02060000
GBREG4   EQU   9                        WORK REG                        02080000
GBREG5   EQU   10                       WORK REG                        02100000
GBREG6   EQU   11                       WORK REG                        02120000
GBREG7   EQU   12                       WORK REG                        02140000
SAVEREG  EQU   13                      SAVE AREA REGISTER               02160000
RETREG   EQU   14                       RETURN REGISTER                 02180000
BRNCHREG EQU   15                      BRANCH TO ADDRESS REGISTER       02200000
ERCODE   EQU   15                      RETURN CODE REGISTER             02220000
*                                                                       02240000
UCBADR   EQU   32                       CONSTANT TO ACCESS START OF     02260000
*                                       UCB LIST IN DEB                 02280000
DEBADR   EQU   44                      CONSTANT TO ACCESS DEB ADDRESS   02300000
SENSE    EQU   22                       SENSE DATA STARTING ADDRESS     02320000
GCBADR   EQU   27                       DISPLACEMENT CONSTANT TO GIVE   02340000
*                                       GCB BYTE AT END OF UCB          02360000
GASR     EQU   70                      GSERV SVC ID                     02380000
*                                                                       02400000
IFFANA   CSECT                                                          02420000
* 040600,041400,042200,025800                                    S21016 02430021
         ENTRY ANLZ                                                     02440000
ANLZ     STM   LISTRG,GBREG7,24(SAVEREG) SAVE REGISTERS CONTENTS        02460000
         BALR  BASERG,0                 SET UP BASE REGISTER            02480000
         USING *,BASERG                 DEFINE BASE REGISTER            02500000
RECYCLE  CLC   1(3,LISTRG),ZERO        TEST FOR ZERO IN DCBLST PARAM    02520000
         BC    8,EXIT1                  BRANCH IF ZERO                  02540000
         CLC   5(3,LISTRG),ZERO        TEST FOR ZERO IN POINTR PARAM    02560000
         BE    EXIT6                   BRANCH IF ZERO            S21016 02580021
         L     TABREG,4(0,LISTRG)       LOAD POINTER PARAMETER          02600000
         L     DCBREG,0(0,LISTRG)       LOAD DCB LIST POINTER           02620000
         LA    DCBREG,0(0,DCBREG)      ZERO HIGH ORDER BYTE             02640000
         CLC   9(3,LISTRG),ZERO        IS RESUME PTR ZERO               02660000
         BC    8,PTR0                   BRANCH IF YES                   02680000
         CLC   9(3,LISTRG),1(DCBREG)   IS RESUME PTR GREATER THAN       02700000
*                                       LAST DCBLST ENTRY ADDRESS       02720000
         BC    2,PTR0                   BRANCH IF RESUME PTR GREATER    02740000
         L     DCBREG,8(0,LISTRG)       LOAD RESUME PTR                 02760000
         LA    DCBREG,0(0,DCBREG)      ZERO HIGH ORDER BYTE             02780000
         BC    15,IDCHEK                BRANCH                          02800000
PTR0     LA    DCBREG,4(0,DCBREG)      INCREMENT ADDRESS                02820000
         ST    DCBREG,8(0,LISTRG)       STORE ADDRESS IN RESUME PTR     02840000
IDCHEK   CLC   17(3,TABREG),ZERO       TEST FOR ZERO IN TABLE WORD 5    02860000
         BC    8,EXIT3                  BRANCH IF ZERO                  02880000
BACK     L     GBREG1,0(DCBREG)         LOAD DCB ADDRESS                02900000
         L     GBREG1,DEBADR(GBREG1)    LOAD DEB ADDRESS                02920000
         L     INDXRG,0(DCBREG)         LOAD INDEX FACTOR FOR UCB ADR   02940000
*                                       LOCATED IN DEB                  02960000
         SRL   INDXRG,24                LOCATE INDEX FOR MULTIPLICATION 02980000
         LA    GBREG3,0                 ZERO EVEN REGISTER              03000000
         LA    GBREG4,4                LOAD MULTIPLICAND                03020000
         MR    GBREG3,INDXRG            DETERMINE DEB DISPLACEMENT      03040000
*                                       FACTOR FOR PROPER UCB ADR.      03060000
*                                       PRODUCT IS IN GBREG3 AND GBREG4 03080000
         L     GBREG2,UCBADR(GBREG4,GBREG1)  LOAD UCB ADDRESS           03100000
         TM    GCBADR(GBREG2),X'03'     TEST FOR POSTED GCB             03120000
         BC    5,POSTED                 BRANCH IF EITHER OR BOTH        03140000
*                                       BITS POSTED.                    03160000
         L     GBREG3,0(0,LISTRG)       LOAD DCB LIST PTR               03180000
         L     GBREG3,0(0,GBREG3)      LOAD END OF LIST POINTER         03200000
         LA    GBREG3,0(0,GBREG3)      ZERO HIGH ORDER BYTE             03220000
         CLR   GBREG3,DCBREG           COMPARE PRESENR DCBLST POINTER   03240000
*                                      WITH LAST DCBLST ADDRESS         03260000
         BC    8,LAST1                  BRANCH IF PRESENT EQUAL TO      03280000
*                                       LAST IN LIST                    03300000
         LA    DCBREG,4(0,DCBREG)      INCREMENT POINTER                03320000
COMPAR   L     GBREG6,8(0,LISTRG)      LOAD RESUME PTR                  03340000
         LA    GBREG6,0(0,GBREG6)      ZERO HIGH ORDER BYTE             03360000
         CLR   DCBREG,GBREG6           COMPARE TO SEE IF COMPLETE       03380000
*                                      LIST WAS POLLED                  03400000
         BC    8,EXIT4                  NO GCBS POSTED                  03420000
         BC    15,BACK                                                  03440000
LAST1    L     DCBREG,0(0,LISTRG)       LOAD DCB LIST POINTER           03460000
         LA    DCBREG,4(0,DCBREG)      INCREMENT POINTER                03480000
         BC    15,COMPAR                BRANCH                          03500000
POSTED   LA    GBREG5,4(0,DCBREG)      BUMP PTR TO SERVICE NEXT DCB     03520000
*                                      UPON RE-ENTRY                    03540000
         ST    GBREG5,8(0,LISTRG)      STORE ADR OF NEXT DCBLST ENTRY   03560000
*                                      TO SERVICE IN RESUME PTR         03580000
         L     GBREG5,16(0,TABREG)     LOAD OUTPUT AREA ADDRESS         03600000
         MVC   0(4,GBREG5),SENSE(GBREG2)  MOVE SENSE DATA TO OUTPUT     03620000
         L     GBREG3,0(0,DCBREG)       LOAD DCB ADDRESS                03640000
         ST    GBREG3,4(0,GBREG5)      STORE DCB ADDRESS IN OUTPUT      03660000
         TM    GCBADR(GBREG2),X'01'     TEST FOR KEYBOARD ATTENTION     03680000
         BC    1,TEST0                  BRANCH IF KYBD.ATTN.            03700000
         LA    LISTRG,2                LOAD BIT 6 RESET MASK            03720000
         SLL   LISTRG,24               POSITION BIT MASK                03740000
         AR    LISTRG,DCBREG           ADD DCBLST ADDRESS TO PARAMETER  03760000
         SVC   GASR                    RESET BIT 6 IN GCB               03780000
         LR    REG0,GBREG5             OUTPUT AREA ADDRESS TO REG 0     03800000
         BC    15,NOTKEY                                                03820000
TEST0    LA    LISTRG,1                LOAD BIT 7 RESET MASK            03840000
         SLL   LISTRG,24               POSITION BIT MASK                03860000
         AR    LISTRG,DCBREG           ADD DCBLST ADDRESS TO PARAMETER  03880000
         SVC   GASR                    RESET BIT 7 IN GCB               03900000
         LR    REG0,GBREG5             OUTPUT AREA ADDRESS TO REG 0     03920000
         BC    15,EXIT2                BRANCH                           03940000
NOTKEY   TM    1(GBREG5),X'40'         TEST FOR END OF ORDERS SEQUENCE  03960000
         BC    1,EOS                    BRANCH IF SET                   03980000
         TM    1(GBREG5),X'80'         TEST FOR LITE PEN ATTENTION      04000000
         BC    1,LPA                    BRANCH IF SET                   04020000
         BC    15,EXIT5                BRANCH                           04040000
EXIT1    EQU   *                                                 S21016 04048021
         WTO   'IFF401I ANALYZ FOUND NO POLST ADDRESS IN PARAMETER LISTX04056021
               ',ROUTCDE=11,DESC=7                               S21016 04064021
         LA    ERCODE,24               POLST PARAM MISSING              04072021
         B     LPA+4                   BRANCH                           04080000
EXIT2    LA    ERCODE,4                KYBD                             04100000
         B     LPA+4                   BRANCH                           04120000
EXIT3    EQU   *                                                 S21016 04128021
         WTO   'IFF403I ANALYZ FOUND NO OUTPUT AREA ADDRESS IN ATTENTIOX04136021
               N ROUTINE LIST',ROUTCDE=11,DESC=7                 S21016 04144021
         LA    ERCODE,32               OUTPUT AREA ADDR MISSING  S21016 04152021
         B     LPA+4                   BRANCH                           04160000
EXIT4    LA    ERCODE,16               NONE POSTED                      04180000
         B     LPA+4                   BRANCH                           04200000
EXIT5    EQU   *                                                 S21016 04208021
         WTO   'IFF404I ANALYZ DETERMINED AN ASYNCHRONOUS ERROR ATTENTIX04216021
               ON OCCURRED',ROUTCDE=11,DESC=7                    S21016 04224021
         LA    ERCODE,8                                                 04232021
         B     LPA+4                   BRANCH                           04240000
EXIT6    EQU   *                                                 S21016 04243021
         WTO   'IFF402I ANALYZ FOUND NO ATTENTION ROUTINE LIST',ROUTCDEX04246021
               =11,DESC=7                                        S21016 04249021
         LA    ERCODE,24                                         S21016 04252021
         B     LPA+4                   GO RETURN                 S21016 04255000
EOS      LA    ERCODE,12               EOS                              04260000
         B     LPA+4                   BRANCH                           04280000
LPA      LA    ERCODE,0                LP                               04300000
         LM    LISTRG,GBREG7,24(SAVEREG) RESTORE REGISTERS              04320000
         BCR   15,14                   RETURN                           04340000
         DS    0F                                                       04360000
ZERO     DC    4XL1'00'                 ZERO                            04380000
         CNOP  0,8                                                      04400000
         END                                                            04420000
