IFFPAAST CSECT                          GSTOR                           00020000
         TITLE 'GSTOR' STORE GRAPHIC DATA                               00040000
*TITLE. STORE GRAPHIC ORDERS ROUTINE                                    00050000
*                                                                       00052000
*STATUS. CHANGE LEVEL 0                                                 00060000
*                                                                       00080000
*FUNCTION/OPERATION. GSTOR STORES GRAPHIC DATA IN THE GDOA              00100000
*    (GRAPHIC DATA OUTPUT AREA)                                         00120000
*                                                                       00140000
*ENTRY POINTS. GSTOR VIA CALL OR LINK MACRO  ALIAS NAME IFFPAA          00160000
*                                                                       00180000
*INPUT.OUTPUT CONTROL BLOCK POINTER (OCBP) AND A PARAMETER ADDRESS      00200000
*   WHICH CONTAINS THE ADDRESS OF THE DATA TO STORE AND THE 'N'         00220000
*   NUMBER OF BYTES TO STORE                                            00240000
*                                                                       00260000
*OUTPUT. GRAPHIC DATA STORED IN THE G D O A (GRAPHIC DATA OUTPUT AREA)  00280000
*                                                                       00300000
*EXTERNAL ROUTINES. NONE                                                00320000
*                                                                       00340000
*EXITS-NORMAL. COMPLETION OF TASK EXIT VIA RETURN MACRO                 00360000
*    -ERROR. HEXADECIMAL 14 OR 18 IN REG. 15                            00380000
*  IMMEDIATE RETURN. EXIT VIA RETURN MACRO                              00400000
*                                                                       00420000
*TABLES/WORK AREAS. USER SPECIFIED PARAMETER TABLE AND USER             00440000
*    SUPPLIED WORK AREA                                                 00460000
*                                                                       00480000
*ATTRIBUTES. READ ONLY, REENTRANT                                       00500000
* STORE GRAPHIC DATA IN USER PROVIDED GRAPHIC DATA OUTPUT AREA-N BYTES  00520000
         ENTRY GSTOR                                                    00540000
GSTOR    SAVE  (14,12),T,*              SYSTEM SAVE 14,15,0 THRU 12     00560000
         BALR  9,0                      SET UP BASE ADDRESS             00580000
         USING *,9                                                      00600000
         SR    15,15                    CLEAR RETURN CODE               00620000
         SR    PASREG,PASREG            CLEAR OVERFLOW PASS REGISTER    00640000
         LM    OBPREG,PATREG,0(1)       LOAD OCBP AND PARTAB ADDRESS    00660000
         LM    ADDREG,CNTREG,0(PATREG)  LOAD INPUT DATA ADDRESS AND N   00680000
GSTOR1   L     OABREG,0(0,OBPREG)       ADDRESS OF OACB                 00700000
         L     OLPREG,16(0,OABREG)      ADDRESS OF OLP FROM OACB        00720000
         LTR   WRKREG,CNTREG            LOAD N AND TEST IF ZERO OR LESS 00740000
         BC    2,GSTOR2                 GREATER THAN ZERO               00760000
         WTO   'IFF541I GSTOR FOUND NON-POSITIVE BYTE COUNT IN PARTAB',X00766021
               ROUTCDE=11,DESC=7                                 S21016 00772021
         LA    15,20                    LOAD RETURN CODE                00780000
         B     EXIT                     RETURN                          00800000
*                                                                       00820000
* CALCULATE ADDRESSES BASED ON N VALUE AND SIZE OF GDOA                 00840000
*                                                                       00860000
GSTOR2   AR    OLPREG,WRKREG            OLP ADDRESS PLUS N              00880000
         LA    TEMREG,4                                                 00900000
         AR    TEMREG,OLPREG            OLP ADDRESS PLUS N PLUS 4       00920000
         L     SLOREG,0(OABREG)         GET STARTING ADDRESS            00940000
         A     SLOREG,4(OABREG)         LAST ADDRESS OF GDOA            00960000
         L     OLPREG,16(0,OABREG)      RESET OLP ADDRESS               00980000
         CR    TEMREG,SLOREG            COMPARE LAST TO TOTAL AVAILABLE 01000000
         BNH   OK                       ROOM FOR NEW DATA               01020000
*                                                                       01040000
* NOT ENOUGH ROOM TO STORE ALL OF THE DATA-DETERMINE AMOUNT TO STORE    01060000
*                                                                       01080000
         SR    TEMREG,SLOREG            EQUALS BYTES-CAN'T STORE        01100000
         SR    WRKREG,TEMREG            NUMBER OF BYTES-CAN STORE       01120000
         C     WRKREG,ZERO                                              01140000
         BNH   GSTOR4                   NO STORAGE AVAILABLE            01160000
         SR    CNTREG,WRKREG            BYTES REMAINING                 01180000
         BAL   LINREG,GSTOR6            MOVE GRAPHIC DATA               01200000
GSTOR3   LA    PASREG,1                 SET PASS INDICATOR              01220000
         L     WKAREG,4(0,OBPREG)       ADDRESS OF WORKAREA             01240000
         STM   0,15,0(WKAREG)           SAVE REGISTERS                  01260000
         L     15,8(0,OABREG)           OVERFLOW ADDRESS                01280000
         LM    2,12,28(13)              RELOAD USER'S REGISTERS         01300000
*   SAVE AREA. THIS GIVES HIS BASE REGISTER THE RIGHT VALUE             01320000
         BALR  14,15                    LINK TO ROUTINE-SET RETURN      01340000
         LM    0,15,0(WKAREG)           RELOAD REGISTERS                01360000
         B     GSTOR1                   STORE REMAINING DATA            01380000
*                                                                       01400000
*                                                                       01420000
*                                                                       01440000
*                                                                       01460000
* NO DATA TO MOVE-NO SPACE AVAILABLE                                    01480000
*                                                                       01500000
GSTOR4   C     PASREG,ONE               WAS A TRANSFER MADE TO OVERFLOW 01520000
         BL    GSTOR3                   NO                              01540000
         WTO   'IFF542I GSTOR, AFTER RETURN FROM OVERFLOW ROUTINE, FOUNX01546021
               D GDOA STILL FULL',ROUTCDE=11,DESC=7              S21016 01552021
         LA    15,24                    SET ERROR RETURN CODE           01560000
         B     EXIT                     RETURN WITH ERROR INDICATION    01580000
*                                                                       01600000
*                                                                       01620000
*                                                                       01640000
* STORE GRAPHIC DATA IN GDOA                                            01660000
*                                                                       01680000
GSTOR6   LA    TEMREG,255               SET REG EQUAL TO 255            01700000
GSTOR6A  CR    WRKREG,TEMREG            IS NO. TO MOVE OVER 255         01720000
         BH    GSTOR7                   YES                             01740000
         LR    TEMREG,WRKREG            LOAD NO. TO MOVE                01760000
         S     TEMREG,ONE               COMPENSATE FOR BYTE OVER        01780000
         EX    TEMREG,MOVE              MOVE DATA                       01800000
         AR    OLPREG,WRKREG            UPDATE OLP ADDRESS              01820000
         AR    ADDREG,WRKREG            UPDATE DATA ADDR                01840000
         ST    OLPREG,16(0,OABREG)      STORE NEW OLP ADDRESS           01860000
         BR    LINREG                   RETURN INTERNAL                 01880000
GSTOR7   LR    SLOREG,TEMREG            SET REG TO 255                  01900000
         S     SLOREG,ONE               REDUCE BY ONE                   01920000
         EX    SLOREG,MOVE              MOVE DATA                       01940000
         AR    OLPREG,TEMREG            UPDATE OLP ADDRESS              01960000
         AR    ADDREG,TEMREG            UPDATE DATA ADDRESS             01980000
         SR    WRKREG,TEMREG            REDUCE AMOUNT TO MOVE           02000000
         B     GSTOR6A                  DO NEXT GROUP                   02020000
OK       BAL   LINREG,GSTOR6            MOVE GRAPHIC DATA               02040000
EXIT     RETURN (14,12),T,RC=(15)       RETURN -CODE SET IN RET CODE    02060000
MOVE     MVC   0(0,OLPREG),0(ADDREG)                                    02080000
ZERO     DC    F'0'                                                     02100000
ONE      DC    F'1'                                                     02120000
FOUR     DC    F'4'                                                     02140000
PASREG   EQU   0                                                        02160000
WKAREG   EQU   1                                                        02180000
OBPREG   EQU   2                                                        02200000
PATREG   EQU   3                                                        02220000
OABREG   EQU   4                                                        02240000
OLPREG   EQU   5                                                        02260000
ADDREG   EQU   6                                                        02280000
CNTREG   EQU   7                                                        02300000
WRKREG   EQU   8                                                        02320000
TEMREG   EQU   10                                                       02340000
LOAREG   EQU   12                                                       02360000
SLOREG   EQU   11                                                       02380000
LINREG   EQU   14                                                       02400000
         DS    0D                                                       02420000
         END                                                            02440000
