         TITLE 'GSPLOT-SCALE AND PLOT'                                  00020000
*STATUS. CHANGE LEVEL 0                                                 00040000
*                                                                       00060000
*FUNCTION/OPERATION. GSPLOT GENERATES THE GRAPHIC ORDERS TO DISPLAY A   00080000
*   POINT,CHARACTER,OR VECTOR PLOT.  A COMBINATION OF THE VARIOUS PLOT  00100000
*   TYPES MAY BE DISPLAYED.                                             00120000
*   THE GRAPHIC ORDERS ARE STORED IN THE GRAPHIC DATA OUTPUT AREA(GDOA) 00140000
*                                                                       00160000
*ENTRY POINTS. GSPLOT VIA CALL OR LINK MACRO   ALIAS NAME IFFPDA        00180000
*                                                                       00200000
*INPUT.OUTPUT CONTROL BLOCK POINTER (OCBP) AND A PARAMETER ADDRESS      00220000
*   WHICH POINTS TO A SEQUENCE OF ADDRESSES AND EBCDIC CHARACTERS IN A  00240000
*   USER PROVIDED PARAMETER TABLE                                       00260000
*                                                                       00280000
*OUTPUT. A STRING OF GRAPHIC ORDERS SUITABLE FOR PLOTTING               00300000
*                                                                       00320000
*EXTERNAL ROUTINES. GOFFSG-OFF SCREEN/GRID INTERSECTION ROUTINE         00340000
*                                                                       00360000
*EXITS-NORMAL. COMPLETION OF TASK EXIT VIA RETURN MACRO                 00380000
*     -ERROR. HEXADECIMAL 4,C,10,18,1C, OR 20 IN REG. 15                00400000
*  IMMEDIATE RETURN. EXIT VIA RETURN MACRO                              00420000
*     -ERROR. HEXADECIMAL 28,2C OR 30 IN REG. 15 DOES NOT RETURN        00440000
*      IMMEDIATELY-COMPLETION OF TASK AND RETURN VIA RETURN MACRO       00460000
*                                                                       00480000
*TABLES/WORK AREAS. USER SPECIFIED PARAMETER TABLE, XYLIM TABLE, UTAB,  00500000
*   VTAB VALUE TABLES AND A USER SUPPLIED WORK AREA                     00520000
*                                                                       00540000
*ATTRIBUTES. READ ONLY, REENTRANT                                       00560000
*                                                                       00580000
IFFPDAPL CSECT                          GSPLOT                          00600000
*0669                                                              7468 00610017
* A69100-69120                                                LI A44596 00615000
* GSPLOT ROUTINE-SAVE REGISTERS-SET RETURN REGISTER AND INITIALIZE      00620000
*                                                                       00640000
         ENTRY GSPLOT                                                   00660000
GSPLOT   SAVE  (14,12),T,*              SYSTEM SAVE MACRO               00680000
         BALR  9,0                                                      00700000
         USING *,9                      BASE REGISTER                   00720000
         USING XYLIM,PATREG                                             00740000
         USING X1,XYLREG                                                00760000
         USING OVFSAVE,WKAREG                                           00780000
         SR    15,15                    CLEAR RETURN CODE               00800000
         LM    OBPREG,PATREG,0(1)       LOAD CONTROL BLOCK AND PARTAB   00820000
         L     OABREG,0(0,OBPREG)       CONTROL BLOCK ADDRESS           00840000
         L     WKAREG,4(0,OBPREG)       WORK AREA ADDRESS               00860000
*  SAVE MASK BITS AS SET BY USER                                        00880000
         ST    9,MASKSV                                                 00900000
         SR    WRKREG,WRKREG                                            00920000
         SPM   WRKREG                                                   00940000
*   CLEAR WORKAREA-TOTAL TEMPORARY STORAGE                              00960000
*                                                                       00980000
         LA    CNTREG,72                COUNT FOR WORK AREA             01000000
         SR    CONREG,CONREG            SET INDEX CONTROL               01020000
CLEARWK  ST    15,OVFSAVE(CONREG)       CLEAR WORK AREA                 01040000
         A     CONREG,FOUR              MODIFY                          01060000
         BCT   CNTREG,CLEARWK           CONTINUE                        01080000
         MVI   COUNT+1,X'01'            SET COUNT TO 1                  01100000
* CHECK INPUT PARAMETERS                                                01120000
*                                                                       01140000
         L     XYLREG,XYLIM             XYLIM ADDRESS                   01160000
         BAL   INTREG,XYLCHK            CHK X1,X2,Y1,Y2 FOR LIMITS      01180000
*                                                                       01200000
* TEST IF FLOATING PT.OR FIXED IS SPECIFIED                             01220000
*                                                                       01240000
         CLI   F,C'B'                   FIXED PARAMETER                 01260000
         BE    OV1                      YES                             01280000
         CLI   F,C'F'                   FLOAT PRAAMETER                 01300000
         BE    OV1                      YES                             01320000
         BAL   LINREG,ERR40             SET ERROR CODE-COUNT ERRORS     01340000
OV1      CLI   S,C'S'                   SCALE                           01360000
         BE    OV2                      YES                             01380000
         CLI   S,C'N'                   NO SCALE                        01400000
         BE    OV2                      YES                             01420000
         BAL   LINREG,ERR40             SET ERROR CODE-COUNT ERRORS     01440000
*                                                                       01460000
* TEST FOR ABSOLUTE OR RELATIVE MODE                                    01480000
*                                                                       01500000
OV2      CLI   A,C'A'                   ABSOLUTE MODE                   01520000
         BE    OV3                      YES                             01540000
         CLI   A,C'R'                   RELATIVE MODE                   01560000
         BE    OV3                      YES                             01580000
         BAL   LINREG,ERR40             SET ERROR CODE-COUNT ERRORS     01600000
*                                                                       01620000
* TEST INCREMENT CODE                                                   01640000
*                                                                       01660000
OV3      CLI   I,C'W'                   NO-INCREMENT                    01680000
         BE    OV4                      YES                             01700000
         CLI   I,C'X'                   INCREMENT U-ONLY                01720000
         BE    OV4                      YES                             01740000
         CLI   I,C'Y'                   INCREMENT V-ONLY                01760000
         BE    OV4                      YES                             01780000
         CLI   I,C'Z'                   INCREMENT U AND V               01800000
         BE    OV4                      YES                             01820000
         BAL   LINREG,ERR40             SET ERROR CODE-COUNT ERRORS     01840000
*                                                                       01860000
* TEST PLOT TYPE CODE                                                   01880000
*                                                                       01900000
*                                                                       01920000
OV4      CLI   PTYPE,C'A'               POINT PLOT                      01940000
         BE    OV5                      YES                             01960000
         CLI   PTYPE,C'B'               CHARACTER PLOT                  01980000
         BE    OV5                      YES                             02000000
         CLI   PTYPE,C'C'               VECTOR PLOT                     02020000
         BE    OV5                      YES                             02040000
         CLI   PTYPE,C'D'               VECTOR AND POINT                02060000
         BE    OV5                      YES                             02080000
         CLI   PTYPE,C'E'               VECTOR AND CHARACTER            02100000
         BE    OV5                      YES                             02120000
         BAL   LINREG,ERR40             SET ERROR CODE-COUNT ERRORS     02140000
*                                                                       02160000
* CHECK S/G OPTIONS                                                     02180000
*                                                                       02200000
*                                                                       02220000
*   TEST OFF S/G OPTION SPECIFIED AND DECIDE BOUNDARY TO BE OBSERVED    02240000
*                                                                       02260000
OV5      CLI   SG,C'A'                  IS OPTION A SPECIFIED           02280000
         BE    MVGRDLIM                 IF YES USE GRID LIMITS          02300000
         CLI   SG,C'B'                  IS OPTION B SPECIFIED           02320000
         BE    MVSCRLIM                 IF YES USE SCREEN LIMITS        02340000
         CLI   SG,C'C'                  IS C OPTION SPECIFIED           02360000
         BE    MVGRDLIM                 IF YES USE GRID LIMITS          02380000
         CLI   SG,C'D'                  IS D OPTION SPECIFIED           02400000
         BE    MVGRDLIM                 IF YES USE GRID LIMITS          02420000
         CLI   SG,C'E'                  IS E OPTION SPECIFIED           02440000
         BE    MVSCRLIM                 IF YES USE SCREEN LIMITS        02460000
         BAL   LINREG,ERR40             OTHERWISE INPUT ERROR ASSUME E  02480000
MVSCRLIM LA    WRKREG,SCLCHK           GET SCREEN CHECK RT ADDRESS      02500000
         ST    WRKREG,WRTADDR           STORE THE ROUTINE ADDR USED     02520000
         LA    WRKREG,LOHI              SCREEN LIMITS START ADDRESS     02540000
         ST    WRKREG,SABL              STORE THE ADDRESS AT SABL       02560000
         B     OV6                                                      02580000
MVGRDLIM LA    WRKREG,GRLCHK           LOAD GRID ROUTINE CHECK ADDRESS  02600000
         ST    WRKREG,WRTADDR           STORE THE ROUTINE ADDR USED     02620000
         ST    XYLREG,SABL              STORE GRID LIMITS ADDR          02640000
OV6      CLC   N,ZERO                   N COMPARED TO ZERO              02660000
         BH    OV7                      N GREATER THAN ZERO             02680000
         BAL   LINREG,ERR40             SET ERROR CODE-COUNT ERRORS     02700000
* IS SYMBOL IN PARAMETER TABLE                                          02720000
*                                                                       02740000
OV7      CLI   PTYPE,C'B'               CHARACTER PLOT SPECIFIED        02760000
         BE    OV8                      YES                             02780000
         CLI   PTYPE,C'E'               VECTOR AND CHARACTER SPECIFIED  02800000
         BNE   STADD                    SKIP OVER-LAP CHECK             02820000
*                                                                       02840000
* IS CHARACTER GIVEN IN TABLE                                           02860000
*                                                                       02880000
OV8      LH    VALREG,SYMBOL            LETTER TO PLOT                  02900000
         N     VALREG,BYTE3             MASK FOR THIRD BYTE             02920000
         BC    4,CHSMOD                 LETTER PRESENT                  02940000
         BAL   LINREG,ERR40             SET ERROR CODE-COUNT ERRORS     02960000
*                                                                       02980000
*   SUBROUTINE TO TEST AND DEVELOPE GRAPHIC ORDER  FOR                  03000000
*   CHARACTER MODE AND SIZE                                             03020000
*   PATREG CONTAINS THE ADDRESS OF THE PARAMETER TABLE ON ENTRY         03040000
*   ORDREG CONTAINS THE GRAPHIC ORDER DEVELOPED ON RETURN               03060000
*   IF MODE OR SIZE ARE INCORRECTLY SPECIFIED, UNPROTECTED AND BASIC    03080000
*   ARE ASSUMED                                                         03100000
CHSMOD   CLI   CMOD,C'P'                PROTECTED                       03120000
         BE    PLEG                                                     03140000
         CLI   CMOD,C'F'                UNPROTECTED                     03160000
         BE    FLEG                                                     03180000
         BAL   LINREG,ERR40             SET ERROR CODE-COUNT ERRORS     03200000
FLEG     LH    VALREG,GFSC                                              03220000
SIZE     CLI   CSIZE,C'L'               LARGE                           03240000
         BE    SIZEL                                                    03260000
         CLI   CSIZE,C'B'               BASIC                           03280000
         BE    ORDSTO                                                   03300000
         BAL   LINREG,ERR40             SET ERROR CODE-COUNT ERRORS     03320000
ORDSTO   STH   VALREG,CHARMOD           ORDER-MODE-SIZE                 03340000
         B     NOCHK                    CHECK OVERLAP LETTER            03360000
SIZEL    A     VALREG,ONE               MODIFY ORDER TO LARGE           03380000
         B     ORDSTO                                                   03400000
PLEG     LH    VALREG,GFPC                                              03420000
         B     SIZE                                                     03440000
GFSC     DC    X'2A40'                                                  03460000
GFPC     DC    X'2A44'                                                  03480000
*                                                                       03500000
* CHECK OVERLAP LETTERS                                                 03520000
NOCHK    CLI   E,C'O'                   OVERLAP LETTER PRESENT          03540000
         BE    STADD                    YES                             03560000
         CLI   E,C'N'                   NO-OVERLAP-WANTED               03580000
         BE    STADD                    YES                             03600000
         BAL   LINREG,ERR40             SET ERROR CODE-COUNT ERRORS     03620000
*                                                                       03640000
* STORE VALUES FROM UTAB AND VTAB IN WORKAREA-SCALED VALUES AFTER SCALE 03660000
*                                                                       03680000
STADD    L     WRKREG,UTAB              UTAB ADDRESS                    03700000
         L     VALREG,0(0,WRKREG)       FIRST VALUE                     03720000
         ST    VALREG,UA                ABSOLUTE UA                     03740000
         ST    VALREG,UASCALE           ABSOLUTE-MAY BE SCALED          03760000
         STH   VALREG,X2FIN             MAY BE FINAL FIXED VALUE        03780000
         L     WRKREG,VTAB              VTAB ADDRESS                    03800000
         L     VALREG,0(0,WRKREG)       FIRST VALUE                     03820000
         ST    VALREG,VA                ABSOLUTE VA                     03840000
         ST    VALREG,VASCALE           ABSOLUTE-MAY BE SCALED          03860000
         STH   VALREG,Y2FIN             MAY BE FINAL FIXED VALUE        03880000
*                                                                       03900000
* IS FLOATING SPECIFIED                                                 03920000
*                                                                       03940000
         CLI   F,C'F'                   FLOATING PT. SPECIFIED          03960000
         BNE   NOFLOAT                  INDICATES FIXED OR NO PARAMETER 03980000
*                                                                       04000000
* IS SCALING SPECIFIED                                                  04020000
*                                                                       04040000
         CLI   S,C'S'                   SCALING SPECIFIED               04060000
         BNE   NOSCALE1                 INDICATES NO SCALE-CONVERT TO   04080000
*                                       FIXED PT. UA VALUES             04100000
*                                                                       04120000
* SET UP VALUES TO CONVERT XYLIM TABLE TO FLOATING POINT VALUES         04140000
*                                                                       04160000
         LA    CONREG,4                 DO FOUR VALUES                  04180000
         SR    INXREG,INXREG            CLEAR CONTROL MODIFICATION      04200000
         SR    CNTREG,CNTREG            CLEAR CONTROL MODIFICATION      04220000
NEXTXY   LH    VALREG,X1(INXREG)        GET X1,Y1,X2,Y2 VALUES          04240000
         BAL   LINREG,FLTCONV           CONVERT FIXED VALUE TO FLOAT PT 04260000
         ST    VALREG,FX1(CNTREG)       STORE IN WORKAREA               04280000
         A     INXREG,TWO               MODIFY BY TWO BYTES             04300000
         A     CNTREG,FOUR              MODIFY BY FOUR BYTES            04320000
         BCT   CONREG,NEXTXY                                            04340000
*                                                                       04360000
* FLOATING POINT SCALE-SUBROUTINE                                       04380000
* EQUATION XS=(UA-U1)*(X2-X1)/(U2-U1)+X1                                04400000
* EQUATION YS=(VA-V1)*(Y2-Y1)/(V2-V1)+Y1                                04420000
*                                                                       04440000
FLTSCAL  LA    CNTREG,2                 SET CONTROL                     04460000
         SR    CONREG,CONREG            CLEAR MODIFIER                  04480000
         SR    INXREG,INXREG            CLEAR MODIFIER                  04500000
FLTSCAL1 LE    6,U1(CONREG)             U1 THEN V1                      04520000
         LE    4,U2(CONREG)             U2 THEN V2                      04540000
         SER   4,6                      U2-U1 THEN V2-V1                04560000
         BC    13,ERR16RET         MINUS OR ZERO                        04580000
* LOAD FLOATING PT VALUE FROM WORKAREA                                  04600000
         LE    0,UA(INXREG)             UA-STORED THRU UN               04620000
         SER   0,6                      UA-U1 VARIABLE RESULT           04640000
         LE    6,FX1(INXREG)            X1 OR Y1 CONVERTED VALUE        04660000
         LE    2,FX2(INXREG)            X2 OR Y2 CONVERTED VALUE        04680000
         SER   2,6                                                      04700000
         MER   0,2                      UA-U1*X2-X1 OR VA-V1*Y2-Y1      04720000
         DER   0,4                      /U2-U1 OR V2-V1                 04740000
         AER   0,6                      +X1 OR Y1                       04760000
         STE   0,UASCALE(INXREG)        X OR Y SCALED VALUE             04780000
         A     CONREG,EIGHT             MODIFY FOR V1-V2                04800000
         A     INXREG,FOUR                                              04820000
         BCT   CNTREG,FLTSCAL1                                          04840000
*                                                                       04860000
* SCALE WAS SPECIFIED OR NO SCALE IS REQUIRED-CONVERT DATA TO FIXED PT. 04880000
*                                                                       04900000
*                                                                       04920000
NOSCALE1 LA    CONREG,2                 SET CONTROL                     04940000
         SR    CNTREG,CNTREG            CLEAR INDEX VALUE               04960000
         SR    INXREG,INXREG                                            04980000
NEXTSCAL L     VALREG,UASCALE(INXREG)   LOAD SCALED OR UNSCALED VALUE   05000000
         BAL   INTREG,FIXCONV           CONVERT TO FIXED PT.            05020000
         ST    VALREG,UASCALE(INXREG)   CONVERTED FIXED VALUE           05040000
         STH   VALREG,X2FIN(CNTREG)     FINAL VALUE                     05060000
         A     CNTREG,TWO               MODIFY                          05080000
         A     INXREG,FOUR                                              05100000
         BCT   CONREG,NEXTSCAL                                          05120000
         B     CHKCNT                                                   05140000
*                                                                       05160000
* FLOATING PT IS NOT SPECIFIED                                          05180000
* IS SCALING SPECIFIED                                                  05200000
*                                                                       05220000
*                                                                       05240000
*                                                                       05260000
* STORE  X1,Y1,X2,Y2 IN WORK AREA                                       05280000
NOFLOAT  LA    CONREG,4                                                 05300000
         SR    INXREG,INXREG                                            05320000
         SR    CNTREG,CNTREG                                            05340000
NEXXY    LH    VALREG,X1(INXREG)        X1,Y1,X2,Y2                     05360000
         ST    VALREG,FX1(CNTREG)       X1,Y1,X2,Y2 IN WORKAREA         05380000
         A     INXREG,TWO                                               05400000
         A     CNTREG,FOUR                                              05420000
         BCT   CONREG,NEXXY                                             05440000
*                                                                       05460000
         CLI   S,C'S'                   IS SCALE INDICATED              05480000
         BNE   CHKCNT                   INDICATES NO SCALE              05500000
* DATA MUST BE SCALED IN FIXED PT.                                      05520000
*                                                                       05540000
FIXSCAL  LA    INTREG,2                 SET INTERNAL CONTROL            05560000
         SR    CONREG,CONREG            CLEAR MODIFIER                  05580000
         SR    INXREG,INXREG            CLEAR MODIFIER                  05600000
FIXSCAL1 L     VALREG,U1(CONREG)        U1 THEN V1                      05620000
         L     TEMREG,U2(CONREG)        U2 THEN V2                      05640000
         SR    TEMREG,VALREG            U2-U1                           05660000
         BC    13,ERR16RET         MINUS OR ZERO                        05680000
         L     XREG,UA(INXREG)          UA                              05700000
         SR    XREG,VALREG              UA-U1  VARIABLE RESULT          05720000
         L     YREG,FX1(INXREG)         X1 OR Y1                        05740000
         L     VALREG,FX2(INXREG)       X2 OR Y2                        05760000
         SR    VALREG,YREG              X2-X1                           05780000
         SR    EREG,EREG                CLEAR MULTIPLICAND              05800000
         MR    EREG,VALREG              UA-U1*X2-X1                     05820000
         DR    EREG,TEMREG                                              05840000
         AR    XREG,YREG                                                05860000
         ST    XREG,UASCALE(INXREG)     X OR Y SCALED                   05880000
         A     CONREG,EIGHT                                             05900000
         A     INXREG,FOUR                                              05920000
         BCT   INTREG,FIXSCAL1                                          05940000
         LH    VALREG,UAS2              X                               05960000
         STH   VALREG,X2FIN             SCALED VALUE OF X               05980000
         LH    VALREG,VAS2              Y                               06000000
         STH   VALREG,Y2FIN             SCALED VALUE OF Y               06020000
*                                                                       06040000
*CHECK COUNT-IS IT EQUAL TO TWO OR MORE                                 06060000
*                                                                       06080000
CHKCNT   CLC   COUNT,TWO+2              COMPARE COUNT TO TWO            06100000
         BNL   SECOND                   YES                             06120000
         L     WRKREG,WRTADDR           CHECK FOR GRID IF APPLIES       06140000
         BALR  LINREG,WRKREG                                            06160000
         CLC   N,ONE+2                 FOR ONLY ONE POINT               06180000
         BE    ONEPT                   HANDLE IT IN POINT MODE          06200000
         LA    CNTREG,2                                                 06220000
         LA    ADDREG,ORDER1                                            06240000
         CLI   PTYPE,C'B'                                               06260000
         BNH   PTMODE                   MODE INITIALIZE GDOA FOR PTONLY 06280000
*                                       GENERATE                        06300000
         MVI   ORDER1,X'2A'             ORDER FOR VECTOR PLOTTING       06320000
         MVI   ORDER2,X'02'                                             06340000
         MVC   GOMODE,ORDER1                                            06360000
         BAL   LINREG,STORE             GIVE TO STORE ROUTINE           06380000
         B     SECOND                                                   06400000
PTMODE   MVI   ORDER1,X'2A'             ORDER FOR POINT PLOTTING        06420000
         MVI   ORDER2,X'00'             GENERATED GIVE                  06440000
         MVC   GOMODE,ORDER1                                            06460000
         BAL   LINREG,STORE             TO STORE ROUTINE                06480000
         B     SECOND                                                   06500000
*                                                                       06520000
* IS N VALUE EQUAL TO OR LESS THAN 1                                    06540000
*                                                                       06560000
*                                                                       06580000
*                                                                       06600000
* WAS PT. OFF SCREEN-ONLY 1 POINT ESTABLISHED                           06620000
*                                                                       06640000
ONEPT    BAL   LINREG,SCLCHK            DISCONTINUE IF ONLY ONE         06660000
         CLC   SWSTATUS,STATUS1         POINT AND IT IS OFF SCREEN      06680000
         BNE   ERR32RET                                                 06700000
*                                                                       06720000
* PT ON SCREEN- SET UP ORDER FOR A PT.                                  06740000
*                                                                       06760000
         MVI   ORDER1,X'2A'             PT PLOT MODE                    06780000
         MVI   ORDER2,X'00'                                             06800000
         MVC   ORDER3,X2FINAL           X AND Y FOR A POINT             06820000
         MVC   GOMODE,ORDER1                                            06840000
         LA    CNTREG,6                 MOVE SIX BYTES                  06860000
         LA    ADDREG,ORDER1            ADDRESS OF DATA                 06880000
         BAL   LINREG,STORE             STORE GRAPHIC DATA IN GDOA      06900000
         BAL   LINREG,PLTCH        GO PLOT A CHARECTOR        LI A44596 06910000
         BAL   LINREG,STORE        STORE IN GDOA              LI A44596 06912000
         B     RET                      RETURN TO USER                  06920000
*                                                                       06940000
* IS COUNT EQUAL TO N                                                   06960000
*                                                                       06980000
NOT1     CLC   N,COUNT                  COMPARE N TO COUNT              07000000
         BE    RET                      END OF PROGRAM                  07020000
* UPDATE COUNT FOR NEXT POINT                                           07040000
         LH    CNTREG,COUNT             COUNT                           07060000
         A     CNTREG,ONE               UPDATE COUNT                    07080000
         STH   CNTREG,COUNT             SAVE COUNT                      07100000
*                                                                       07120000
         L     VALREG,ZERO              CLEAR SKIPSW                    07140000
         STH   VALREG,SKIPSW                                            07160000
         MVC   PT1SW,OFFSW              UPDATE SCREEN GRID SWITCH       07180000
* SAVE THE PREVIOUS CALCULATED VALUE                                    07200000
         L     VALREG,UASCALE           X VALUE MAXIMUM SIZE            07220000
         ST    VALREG,UASCALE2          PT1-X-VALUE                     07240000
         L     VALREG,VASCALE           Y VALUE MAXIMUM SIZE            07260000
         ST    VALREG,VASCALE2          PT1-Y-VALUE                     07280000
         L     VALREG,X2FINAL                                           07300000
         ST    VALREG,X1FINAL                                           07320000
*                                                                       07340000
         SR    CONREG,CONREG            CLEAR MODIFIER                  07360000
         LA    CNTREG,2                 SET LOOP CONTROL                07380000
* THIS ROUTINE GET U-AND V TABLE VALUES                                 07400000
*                                                                       07420000
* GET NEXT VALUE FROM TABLE-UTAB                                        07440000
*                                                                       07460000
INCU     LH    INXREG,INDEX             TABLE INDEX VALUE               07480000
         L     WRKREG,UTAB              UTAB ADDRESS                    07500000
         CLI   I,C'X'                   U ARRAY INCREMENTAL             07520000
         BE    UINCR                    YES                             07540000
         CLI   I,C'Z'                   U AND V ARRAY INCREMENTAL       07560000
         BE    UINCR                    YES-BOTH U AND V ARE INCREMENT  07580000
FLCHK    CLI   F,C'F'                   FLOATING PT.                    07600000
         BE    FLRCHK                   YES-IS IT RELATIVE              07620000
FIXVAL   L     VALREG,4(INXREG,WRKREG)  NO -BINARY OR ASSUMED BINARY    07640000
         CLI   A,C'R'                   RELATIVE                        07660000
         BNE   USTORE                   NOT RELATIVE-STORE INDEXED VAL. 07680000
         B     USTORA                   RELATIVE-ADD PREVIOUS VALUE     07700000
UINCR    CLI   F,C'F'                   FLOATING PT.                    07720000
         BE    FLOATAD                  FLOAT SPECIFIED                 07740000
         L     VALREG,4(0,WRKREG)       FIXED INCREMENT VALUE-NOT INDEX 07760000
USTORA   A     VALREG,UA(CONREG)        ADD PREVIOUS ABS. VALUE         07780000
USTORE   ST    VALREG,UA(CONREG)        NEXT ABS. VALUE                 07800000
         ST    VALREG,UASCALE(CONREG)   NEW X OR Y VALUE                07820000
         B     INCV                     GET THE V VALUE                 07840000
*                                                                       07860000
* FLOATING PT NUMBERS SPECIFIED                                         07880000
*                                                                       07900000
FLRCHK   LE    0,4(INXREG,WRKREG)       NEXT FLOATING VALUE-INDEXED     07920000
         CLI   A,C'R'                   IS FLOAT RELATIVE               07940000
         BNE   STORFL                   NO REPLACE VALUE                07960000
         B     STORAF                   YES                             07980000
FLOATAD  LE    0,4(0,WRKREG)            FLOAT INCREMENT-NOT INDEXED     08000000
STORAF   AE    0,UA(CONREG)             FLOAT ADD ABS. VALUE            08020000
STORFL   STE   0,UA(CONREG)             NEW VALUE X OR Y                08040000
         STE   0,UASCALE(CONREG)        NEW X OR Y VALUE                08060000
*                                                                       08080000
* SET UP V TABLE AND MAKE CHECKS                                        08100000
*                                                                       08120000
INCV     BCT   CNTREG,DOV               DO V TABLE                      08140000
         B     OUT                                                      08160000
DOV      LA    CONREG,4                 SET MODIFIER                    08180000
         L     WRKREG,VTAB              VTAB ADDRESS                    08200000
         CLI   I,C'Y'                   V INCREMENTAL                   08220000
         BE    UINCR                    YES                             08240000
         CLI   I,C'Z'                   V AND U INCREMENTAL             08260000
         BE    UINCR                    YES                             08280000
         B     FLCHK                    NO                              08300000
*                                                                       08320000
* BOTH TABLE VALUES STORED-UPDATE INDEX                                 08340000
*                                                                       08360000
OUT      A     INXREG,FOUR              UPDATE INDEX VALUE              08380000
         STH   INXREG,INDEX             SAVE TABLE INDEX VALUE          08400000
         CLI   F,C'F'                                                   08420000
         BE    CHKSCA                   YES                             08440000
         CLI   S,C'S'                                                   08460000
         BE    FIXSCAL                  YES-SCALE NEW VALUES            08480000
* STORE FIXED UNSCALED VALUES FOR NEXT PT VALUE                         08500000
STOXY    L     VALREG,UA                                                08520000
         STH   VALREG,X2FIN             X2 UNSCALED FIXED VALUE         08540000
         L     VALREG,VA                                                08560000
         STH   VALREG,Y2FIN             Y2 UNSCALED FIXED VALUE         08580000
         B     CHKCNT                   NO                              08600000
CHKSCA   CLI   S,C'S'                   SCALING SPECIFIED               08620000
         BE    FLTSCAL                  YES                             08640000
         B     NOSCALE1                 NO                              08660000
SECOND   BAL   LINREG,SCRNGRD                                           08680000
         CLC   SKIPSW,ONE+2             SKIP PLOTTING IF REQUIRED       08700000
         BE    NOT1                                                     08720000
         CLI   PTYPE,C'B'               FOR CHARACTER MODE              08740000
         BE    BEAMOFF                  POSITION BEAM OFF               08760000
         CLI   PTYPE,C'A'               FOR POINT MODE                  08780000
         BE    BEAMON                   POSITION BEAM ON                08800000
         CLC   COUNT,ONE+2              FOR OTHER THAN                  08820000
         BH    BEAMON                   FIRST POINT,POSITION BEAM ON    08840000
BEAMOFF  MVC   ORDER3,X2FINAL           OTHERWISE INSERT                08860000
         OI    ORDER3,X'40'             BLANK BEAM BIT IN               08880000
         LA    CNTREG,4                 ORDER AND                       08900000
         LA    ADDREG,ORDER3                                            08920000
         BAL   LINREG,STORE             STORE                           08940000
         B     FLOW2                    BACK TO NORMAL FLOW             08960000
BEAMON   CLI   PTYPE,C'B'               IF NOT VECTOR MODE USE          08980000
         BNH   REGOUT                  STANDARD OUTPUT                  09000000
         BAL   LINREG,VECTOR            OTHERWISE GENERATE PSEUDO VEC.  09020000
         B     FLOW2                                                    09040000
REGOUT   MVC   ORDER3,X2FINAL          POSITION AT                      09060000
         LA    ADDREG,ORDER3                                            09080000
         LA    CNTREG,4                 PT2,BEAM ON                     09100000
         BAL   LINREG,STORE             STORE                           09120000
FLOW2    CLI   PTYPE,C'B'               IF CHARACTER                    09140000
         BE    CHAR                     MODE OR                         09160000
         CLI   PTYPE,C'E'               VECTOR AND CHARACTER            09180000
         BE    CHAR                     PLOT CHARACTER                  09200000
         CLI   PTYPE,C'D'               IF NOT POINT-VECTOR MODE        09220000
         BNE   NOT1                     GO TO UPDATE THE COUNTER        09240000
         LA    CNTREG,4                 OTHERWISE REPEAT ORDER TO       09260000
         LA    ADDREG,ORDER3                                            09280000
         BAL   LINREG,STORE             STORE TO INTENSIFY END POINT    09300000
         B     NOT1                     GO TO UPDATE THE COUNTER        09320000
CHAR     BAL   LINREG,PLTCH             GO PLOT A CHARACTER             09340000
         BAL   LINREG,STORE             STORE GRAPHIC ORDERS IN GDOA    09360000
         CLI   PTYPE,C'E'               IF NOT VECTOR CHARACTER MODE    09380000
         BNE   REPTM                    REPEAT ENTER POINT MODE         09400000
         MVI   ORDER1,X'2A'             OTHERWISE REENTER VECTOR MODE   09420000
         MVI   ORDER2,X'02'                                             09440000
         OI    ORDER3,X'40'             TURN BEAM OFF                   09460000
         MVC   GOMODE,ORDER1                                            09480000
         LA    CNTREG,6                 AND REPEAT ORDER                09500000
         LA    ADDREG,ORDER1                                            09520000
         BAL   LINREG,STORE             TO STORE OF CURRENT POSITION    09540000
         B     NOT1                     GET NEXT VALUES                 09560000
REPTM    LA    CNTREG,2                                                 09580000
         LA    ADDREG,ORDER1                                            09600000
         MVI   ORDER1,X'2A'             ORDER FOR POINT PLOTTING        09620000
         MVI   ORDER2,X'00'                                             09640000
         MVC   GOMODE,ORDER1                                            09660000
         BAL   LINREG,STORE             TO STORE ROUTINE                09680000
         B     NOT1                     UPDATE THE COUNTER              09700000
* STORE GRAPHIC DATA IN GDOA FOR POR                                    09720000
* INPUT TO SUBROUTINE                                                   09740000
*   CNTREG = NUMBER OF BYTES OF GRAPHIC DATA TO STORE                   09760000
*   ADDREG = ADDRESS OF THE GRAPHIC DATA                                09780000
*   WKAREG = REGISTER 1 MUST CONTAIN THE WORKAREA ADDRESS               09800000
*   OABREG = ADDRESS OF OACB                                            09820000
STORE    STM   8,12,PORSAVE             SAVE REGISTERS                  09840000
         SR    PASREG,PASREG            CLEAR OVERFLOW INDICATOR        09860000
STORE1   L     OLPREG,16(0,OABREG)      ADDRESS OF OLP FROM OACB        09880000
         LR    WRKREG,CNTREG            LOAD BYTES TO MOVE              09900000
*                                                                       09920000
* CALCULATE ADDRESSES BASED ON N VALUE AND SIZE OF GDOA                 09940000
*                                                                       09960000
STORE2   AR    OLPREG,WRKREG            OLP ADDRESS PLUS N VALUE        09980000
         LA    TEMREG,4                                                 10000000
         AR    TEMREG,OLPREG            OLP PLUS N PLUS 4               10020000
         L     SLOREG,0(OABREG)         SLOA ADDRESS                    10040000
         A     SLOREG,4(OABREG)         ADD LOA EQUALS TOTAL GDOA       10060000
         L     OLPREG,16(0,OABREG)      RESET INITIAL OLP ADDRESS       10080000
         CR    TEMREG,SLOREG                                            10100000
         BNH   OK                                                       10120000
*                                                                       10140000
* NOT ENOUGH ROOM TO STORE ALL OF THE DATA-DETERMINE AMOUNT TO STORE    10160000
*                                                                       10180000
         SR    TEMREG,SLOREG            EQUAL BYTES-CAN'T STORE         10200000
         SR    WRKREG,TEMREG            NUMBER OF BYTES CAN STORE       10220000
*                                                                       10240000
* ANY BYTES TO STORE                                                    10260000
*                                                                       10280000
         C     WRKREG,ZERO                                              10300000
         BNH   STORE4                   LESS OF EQUAL TO ZERO           10320000
         LH    TEMREG,H2A02                                             10340000
         CH    TEMREG,GOMODE                                            10360000
         BH    STORE3A                                                  10380000
         LH    TEMREG,H0003                                             10400000
         NR    TEMREG,WRKREG                                            10420000
         BM    STORE4      GO TO USER OVERFLOW ROUTINE (DAPL)      7468 10440017
STORE3A  SR    CNTREG,WRKREG       BYTES REMAINING                      10460000
         BAL   INTREG,STORE6            LINK INTERNALLY                 10480000
STORE3   LA    PASREG,1                 SET PASS INDICATOR              10500000
*                                                                       10520000
* STORE REGISTERS IN WORKAREA                                           10540000
*                                                                       10560000
         STM   0,15,OVFSAVE             OVERFLOW SAVE IN WORKAREA       10580000
         CLC   ADGOFFSG,ZERO            WAS OFF SCREEN/GRID LOADED      10600000
         BE    LAOVFLO                  NO                              10620000
         SR    WRKREG,WRKREG                                            10640000
         ST    WRKREG,ADGOFFSG          CLEAR ADDRESS                   10660000
         LR    3,1                      SAVE REG 1.                     10680000
         DELETE EP=GOFFSG                                               10700000
         LR    1,3                      RESTORE REG 1.                  10720000
LAOVFLO  L     15,8(0,OABREG)           LOAD OVERFLOW ADDRESS           10740000
         LM    2,12,28(13)              RELOAD USER'S REGISTERS         10760000
         BALR  14,15                    LINK TO ROUTINE-SET RETURN      10780000
         LM    0,15,OVFSAVE             RELOAD AND CONTINUE TO STORE    10800000
         B     STORE1                   GET NEW OLP ADDRESS-CONTINUE    10820000
*                                                                       10840000
* NO SPACE AVAILABLE                                                    10860000
*                                                                       10880000
*                                                                       10900000
STORE4   C     PASREG,ONE               WAS A TRANSFER TO OVERFLOW MADE 10920000
         BL    STORE3                                                   10940000
*                                                                       10960000
* SET ERROR CODE AND RETURN TO POR-LEAVE POR WITH RETURN MACRO          10980000
*                                                                       11000000
         B     ERR24RET                                                 11020000
*                                                                       11040000
*                                                                       11060000
OK       BAL   INTREG,STORE6            LINK INTERNALLY                 11080000
         LM    8,12,PORSAVE            RELOAD REGISTERS                 11100000
         BR    LINREG                                                   11120000
STORE6   LA    TEMREG,255               SET REG. EQUAL TO 255           11140000
STORE6A  CR    WRKREG,TEMREG            IS AMOUNT TO MOVE OVER 255      11160000
         BH    STORE7                                                   11180000
         LR    TEMREG,WRKREG                                            11200000
         S     TEMREG,ONE               COMPENSATE FOR EXTRA BYTE       11220000
         EX    TEMREG,MOVE              MOVE GRAPHIC DATA               11240000
         AR    OLPREG,WRKREG            UPDATE OLP ADDRESS              11260000
         AR    ADDREG,WRKREG            UPDATE DATA ADDR                11280000
         ST    OLPREG,16(0,OABREG)      STORE NEW OLP ADDRESS           11300000
         BR    INTREG                   RETURN INTERNALLY               11320000
STORE7   LR    SLOREG,TEMREG                                            11340000
         S     SLOREG,ONE               COMPENSATE FOR EXTRA BYTE       11360000
         EX    SLOREG,MOVE              MOVE GRAPHIC DATA               11380000
         AR    OLPREG,TEMREG            UPDATE OLP ADDRESS              11400000
         AR    ADDREG,TEMREG            UPDATE INPUT ADDRESS            11420000
         SR    WRKREG,TEMREG           REDUCE BY 255                    11440000
         B     STORE6A                  MAKE NEXT COMPARISON            11460000
MOVE     MVC   0(0,OLPREG),0(ADDREG)    MOVE DATA TO GDOA               11480000
*                                                                       11500000
*    CONVERT  FLOATING  POINT  TO  FIXED  POINT  VALUES                 11520000
*    VALREG CONTAINS THE VALUE TO BE CONVERTED                          11540000
*                                                                       11560000
FIXCONV  ST    1,OVFSAVE                STORE IN FIRST WORD REG. 1      11580000
         TM    OVFSAVE+3,X'07'          TEST LAST THREE BITS            11600000
         BZ    SETMODI                  NO BITS ON SET INDEX TO ZERO    11620000
         LA    TEMREG,4                 SET MODIFIER                    11640000
         B     SAVFLT                   START CONVERSION                11660000
         MVC   GOMODE,CHARMOD                                           11680000
SETMODI  LA    TEMREG,0                 SET MODIFIER TO ZERO            11700000
SAVFLT   ST    VALREG,TEMFLT(TEMREG)    SAVE FLOAT VALUE                11720000
         SR    WRKREG,WRKREG                                            11740000
         ST    WRKREG,TEMFLT+4(TEMREG)  CLEAR SECOND WORD               11760000
         LD    6,TEMFLT(TEMREG)         VALUE TO FLOAT REGISTERS        11780000
         N     VALREG,FCHAR                                             11800000
         BE    FLERR1                   CHARACTERISTIC IS ZERO          11820000
         AE    6,FLPT5                  ADD .5 TO ROUND                 11840000
         AW    6,X4E                    ADD UNNORMALIZED-RIGHT JUSTIFY  11860000
         STD   6,TEMFLT(TEMREG)         SAVE VALUES                     11880000
         L     WRKREG,TEMFLT+4(TEMREG)  CHECK SECOND WORD               11900000
         N     WRKREG,MZERO             CHECK BIT 32                    11920000
         BM    ERR12RET                 INDICATE ERROR                  11940000
         L     WRKREG,TEMFLT(TEMREG)                                    11960000
         N     WRKREG,BYTE123                                           11980000
         BM    ERR12RET                                                 12000000
         L     WRKREG,TEMFLT(TEMREG)                                    12020000
         N     WRKREG,MZERO             DROP CHARACTERISTIC             12040000
         L     VALREG,TEMFLT+4(TEMREG)  NEW FIXED VALUE                 12060000
         LTR   WRKREG,WRKREG                                            12080000
         BNL   NOTNEG                   NOT NEGATIVE                    12100000
         LNR   VALREG,VALREG            TAKE TWO'S COMPLIMENT           12120000
NOTNEG   BR    INTREG                   RETURN TO N S I                 12140000
FLERR1   CE    6,ZERO                   IS TOTAL VALUE ZERO             12160000
         BE    NOTNEG                   RETURN                          12180000
         B     ERR12RET                 SET ERROR CODE AND RETURN       12200000
*                                                                       12220000
*    CONVERT  FIXED  POINT  TO  FLOATING  POINT  VALUES                 12240000
*    VALREG CONTAINS THE VALUE TO BE CONVERTED                          12260000
*                                                                       12280000
FLTCONV  O     VALREG,X6                EXPONENT OF 6                   12300000
         ST    VALREG,OVFSAVE                                           12320000
         LE    0,OVFSAVE                LOAD TO FLOAT REG.              12340000
         AE    0,X6                     NORMALIZE                       12360000
         STE   0,OVFSAVE                                                12380000
         L     VALREG,OVFSAVE           FLOAT PT. VALUE IN REG.         12400000
         BR    LINREG                                                   12420000
*   ROUTINE TO CHECK IF PT. IS OUTSIDE OF GRID BOUNDARY                 12440000
*                                                                       12460000
GRLCHK   LH    VALREG,X1                X1                              12480000
         C     VALREG,UASCALE           X VALUE COMPARED TO X1          12500000
         BH    SETIND                   OFF GRID LIMIT                  12520000
         LH    VALREG,X2                X2                              12540000
         C     VALREG,UASCALE           X VALUE COMPARED TO X2          12560000
         BL    SETIND                   OFF GRID LIMIT                  12580000
         LH    VALREG,Y1                Y1                              12600000
         C     VALREG,VASCALE           Y VALUE COMPARED TO Y1          12620000
         BH    SETIND                   OFF GRID                        12640000
         LH    VALREG,Y2                Y2                              12660000
         C     VALREG,VASCALE           Y VALUE COMPARED TO Y2          12680000
         BL    SETIND                   OFF GRID                        12700000
         MVI   OFFSW,X'00'              WITHIN LIMIT SET OFF            12720000
         B     OV10                                                     12740000
SETIND   MVI   OFFSW,X'11'              SET INDICATOR                   12760000
         BR    LINREG                   RETURN                          12780000
OV10     BR    LINREG                   RETURN                          12800000
*                                                                       12820000
*                                                                       12840000
*    ROUTINE TO CHECK IF POINT IS OFF THE SCREEN                        12860000
*                                                                       12880000
SCLCHK   L     VALREG,UASCALE           GET X VALUE                     12900000
         C     VALREG,ZERO              X VALUE COMPARED TO ZERO        12920000
         BL    SETBITS                  OFF SCREEN                      12940000
         C     VALREG,HIGH              X VALUE COMPARED TO 4095        12960000
         BH    SETBITS                  OFF SCREEN                      12980000
         L     VALREG,VASCALE           GET Y VALUE                     13000000
         C     VALREG,ZERO              Y VALUE COMPARED TO ZERO        13020000
         BL    SETBITS                  OFF SCREEN                      13040000
         C     VALREG,HIGH              Y VALUE COMPARED TO 4095        13060000
         BH    SETBITS                  OFF SCREEN                      13080000
         MVI   OFFSW,X'00'              WITHIN LIMIT SET OFF            13100000
         BR    LINREG                   RETURN                          13120000
SETBITS  MVI   OFFSW,X'11'              SET INDICATOR                   13140000
         BR    LINREG                   RETURN                          13160000
*                                                                       13180000
*                                                                       13200000
SCRNGRD  ST    LINREG,RSAVE             SAVE THE BRANCH REGISTER        13220000
         L     WRKREG,WRTADDR           GET BOUNDARY CHECK RT ADDRESS   13240000
         BALR  LINREG,WRKREG             AND BRANCH TO CHECK            13260000
         CLC   SWSTATUS,STATUS1         CHECK THE SWS STATUS IF STATUS1 13280000
         BE    RESREG                   ARE ALL POINTS ON ANSWER  YES   13300000
OPTIONA  CLI   SG,C'A'                  OTHERWISE OFFSG CONDITION EXIST 13320000
         BNE   OPTIONB                   CHECK USER-SPECIFIED OPTION    13340000
         BAL   LINREG,ERR44             IF A OPTION SET ERR CODE AND    13360000
         B     ANALOFF                   ANALIZE OFF STATUS TO HANDLE   13380000
OPTIONB  CLI   SG,C'B'                  IS B OPTION SPECIFIED           13400000
         BNE   OPTIONC                  IF NOT TEST FOR C               13420000
         BAL   LINREG,ERR48             IF YES SET ERR CODE AND         13440000
         B     ANALOFF                   ANALIZE OFF STATUS TO HANDLE   13460000
OPTIONC  CLI   SG,C'C'                  IS C OPTION SPECIFIED           13480000
         BNE   OPTIOND                  IF NOT TEST FOR D               13500000
         BAL LINREG,SCLCHK              CHECK FURTHER IF POINT          13520000
         CLI   OFFSW,X'11'               OFF SCREEN                     13540000
         BE    ERR32RET                 IFF OFF SCREEN IMMEDIATE RET    13560000
         LA    15,32                    OTHERWISE SET ERROR CODE AND    13580000
         BAL   LINREG,ERRCNT             CONTINUE THE JOB               13600000
         BAL   LINREG,GRLCHK            CHECK FURTHER FOR GRID          13620000
         B     ANALOFF                  GO TO ANALIZE OFF STATUS        13640000
OPTIOND  CLI   SG,C'D'                  IS OPTION D SPECIFIED           13660000
         BNE   ASSUMEE                  IF NOT ASSUME OPTION E          13680000
         B     ERR28RET                 IMMEDIATE ERROR RETURN          13700000
ASSUMEE  B     ERR32RET                 IMMEDIATE ERROR RETURN          13720000
         BE    ERR32RET                 IF OFF SCREEN IMMEDIATE RETURN  13740000
         BAL   LINREG,SCLCHK            IF OPTION C TEST FOR OFF SCRN   13760000
         LA    15,32                    OTHERWISE SET ERROR CODE        13780000
         BAL   LINREG,ERRCNT            UPDATE ERROR COUNT              13800000
         MVI   OFFSW,X'11'              RESTORE OFF BOUNDARY STATUS     13820000
         B     RESREG                   CONTINUE JOB                    13840000
SETSKIP  L     VALREG,ONE               SET SWITCH TO SKIP TO NEXT      13860000
         STH   VALREG,SKIPSW            POINT                           13880000
         B     RESREG                   AND RETURN VIA RESTORE REG      13900000
ANALOFF  CLI   PTYPE,C'B'               IF NOT VECTOR                   13920000
         BH    ANALVEC                  TYPE SKIP IT IF                 13940000
         CLC   SWSTATUS,STATUS3         IT IS POINT 2 OFF               13960000
         BE    SETSKIP                                                  13980000
         B     RESREG                   OTHERWISE CONTINUE              14000000
ANALVEC  CLC   COUNT,ONE+2              IF FIRST POINT OFF, GET         14020000
         BNH   SETSKIP                  GET ANOTHER                     14040000
         STM   13,0,PORSAVE             SAVE REGISTERS                  14060000
         ST    13,OVFSAVE+4             SAVE POR SAVEAREA CHAINING ADDR 14080000
         ST    15,SVR15                 SAVE ERROR REGISTER             14100000
         LA    13,OVFSAVE               LOAD GOFFSG RT SAVEAREA ADDR    14120000
         LR    WRKREG,1                 SAVE REG1-WKAREA POINTER        14140000
         CLC   GOFFSGAD,ZERO            CHECK IF GOFFSG RT ADDR AREA 0  14160000
         BNE   OFFHDLG                  IF NOT RT BROUGHT IN GO TO HDL  14180000
         LA    1,SABL                   LOAD 24-WORD PARTAB START ADDR  14200000
         LOAD  EP=GOFFSG                RETAIN THE MODULE               14220000
         LR    1,WRKREG                 RESTORE REGISTER 1              14240000
         ST    0,GOFFSGAD               SAVE GOFFSG RT ADDRESS          14260000
OFFHDLG  L     15,GOFFSGAD              LOAD GOFFSG RT ADDRESS          14280000
         LA    1,SABL                   LOAD 24-WORD PARTAB ADDR        14300000
         BALR  14,15                    BRANCH TO GOFFSG RT             14320000
         LR    1,WRKREG                 RESTORE REG 1                   14340000
LINKOUT  LM    13,0,PORSAVE             RESTORE REG 13 TO 0             14360000
         L     15,SVR15                 RESTORE ERROR REGISTER          14380000
*   ANALIZE THE RESPONSE OF GOFFSG ROUTINE AND GENERATE PROPER DATA     14400000
ANALRES  CLC   NI,ZERO                  IS NI=0                         14420000
         BE    NOINTS                   IF SO GO TO NO INTERSECT RT     14440000
         CLC   NI,ONE                   IS NI=1                         14460000
         BE    ONEINTS                  IF SO GO TO ONE INTERSECT RT    14480000
BOTHOUT  MVC   X1FINAL,XYINT1           OTHERWISE GDV I1X,I1Y,B         14500000
         MVC   X2FINAL,XYINT2                                           14520000
         MVC   ORDER3,X1FINAL           AND GDV I2X,I2Y,U               14540000
         MVC   ORDER4,X2FINAL                                           14560000
         OI    ORDER3,X'40'                                             14580000
         LA    CNTREG,8                 LOAD BYTE NUMBER                14600000
         LA    ADDREG,ORDER3                                            14620000
         BAL   LINREG,STORE             GIVE TO STORE ROUTINE           14640000
         B     SETSKIP                  SKIP THE NEXT POINT             14660000
NOINTS   CLC   SWSTATUS,STATUS2         SEE IF PT1 OFF PT2 ON           14680000
         BE    NOINTSA                  IF SO IT'S NO INTS CONDITION A  14700000
         B     SETSKIP                  GO ON TO NEXT POINT             14720000
NOINTSA  MVC   X1FINAL,X2FINAL          GDV X2,Y2,B                     14740000
         MVC   ORDER3,X1FINAL           AND GDV X2,Y2,U                 14760000
         MVC   ORDER4,X2FINAL                                           14780000
         OI    ORDER3,X'40'                                             14800000
         LA    CNTREG,8                 AND GIVE TO STORE ROUTINE       14820000
         LA    ADDREG,ORDER3                                            14840000
         B     STOREP                                                   14860000
ONEINTS  CLC   SWSTATUS,STATUS2         SEE IF PT1 OFF PT2 ON           14880000
         BE    ONEINTSA                 IF SO GO TO ONE INTS CONDITIONA 14900000
         CLC   SWSTATUS,STATUS3         SEE IF PT1 ON PT2 OFF           14920000
         BE    ONEINTSB                 IF SO GO TO ONE INTS CONDITIONB 14940000
         B     BOTHOUT                                                  14960000
ONEINTSA MVC   X1FINAL,XYINT1           GENERATE I1X,I1Y,B              14980000
         MVC   ORDER3,X1FINAL                                           15000000
         OI    ORDER3,X'40'             BLAND BEAM BIT                  15020000
         LA CNTREG,4                    AND GIVE TO STORE ROUTINE       15040000
         LA    ADDREG,ORDER3                                            15060000
         B     STOREP                                                   15080000
ONEINTSB MVC   X2FINAL,XYINT1                                           15100000
         MVC   ORDER3,X2FINAL                                           15120000
         LA CNTREG,4                    GDVI1X,I1Y,U AND THEN STORE     15140000
         LA    ADDREG,ORDER3                                            15160000
         BAL   LINREG,STORE             STORE THE POINT AND             15180000
         B     SETSKIP                  AND SKIP ANYTHING ELSE          15200000
STOREP   BAL   LINREG,STORE                                             15220000
RESREG   L     LINREG,RSAVE             RESTORE THE L INE REGISTER      15240000
         BR    LINREG                   AND RETURN                      15260000
* SUBROUTINE TO PLOT A CHARACTER                                        15280000
PLTCH    CLI   E,C'O'                   NO OVERLAP                      15300000
         BE    OV9                      YES-NO OVER LAP PERMITTER       15320000
         B     PLTCH1                   VECTOR AND CHAR OR VECTOR ONLY  15340000
OV9      LH    VALREG,X2FIN             X2                              15360000
         SH    VALREG,X1FIN             X2-X1                           15380000
         LPR   XREG,VALREG              ABSOLUTE OF DELTA X             15400000
         C     XREG,EIGHT                                               15420000
         BH    PLTCH1                   MORE THAN EIGHT                 15440000
         LH    VALREG,Y2FIN             Y2                              15460000
         SH    VALREG,Y1FIN             Y2-Y1                           15480000
         LPR   YREG,VALREG              ABSOLUTE OF DELTA Y             15500000
         C     YREG,EIGHT                                               15520000
         BH    PLTCH1                   MOVE THAN EIGHT                 15540000
*                                                                       15560000
* DIFFERENCE IS LESS THAN EIGHT BETWEEN POINTS                          15580000
*                                                                       15600000
         L     VALREG,X1FINAL           X1,Y1                           15620000
         ST    VALREG,X2FINAL           STORE X1,Y1 OVER X2,Y2          15640000
         B     NOT1                     CHECK COUNT                     15660000
PLTCH1   MVC   ORDER5,CHARMOD           MODE AND CHARACTER SIZE         15680000
         MVC   ORDER6,SYMBOL            LETTER                          15700000
         MVI   ORDER7,X'00'             NULL CHARACTER                  15720000
         LA    CNTREG,4                 COUNT TO MOVE                   15740000
         LA    ADDREG,ORDER5                                            15760000
         BR    LINREG                                                   15780000
*                                                                       15800000
*        PSUEDO VECTOR GENERATOR                                        15820000
*        THIS ROUTINE TAKES ADVANTAGE OF THE LIMITED                    15840000
*        VECTOR CAPABILITY OF A 2250 WITHOUT THE ABSOLUTE               15860000
*        VECTOR GRAPHICS FEATURE                                        15880000
*                                                                       15900000
VECTOR   ST    LINREG,RSAVE             SAVE BRANCH REGISTER            15920000
         L     VALREG,X1FINAL           GET X1 AND Y1                   15940000
         ST    VALREG,PT1VEC            TEMP CALCULATIONS               15960000
         L     VALREG,X2FINAL           X2,Y2                           15980000
         ST    VALREG,PT2VEC            TEMP CALCULATIONS               16000000
* DETERMINE DELTA X AND DELTA Y                                         16020000
         LH    VALREG,X2FIN             X2                              16040000
         SH    VALREG,X1FIN             X2-X1                           16060000
         STH   VALREG,DELTAX            SAVE DELTA X                    16080000
         LPR   XREG,VALREG              ABSOLUTE OF DELTA X             16100000
*                                                                       16120000
         LH    VALREG,Y2FIN             Y2                              16140000
         SH    VALREG,Y1FIN             Y2-Y1                           16160000
         STH   VALREG,DELTAY            SAVE DELTA  Y                   16180000
         LPR   YREG,VALREG              ABSOLUTE OF DELTA Y             16200000
*                                                                       16220000
* IS DELTA X EQUAL TO ZERO                                              16240000
*                                                                       16260000
         CLC   DELTAX,ZERO              DELTA X EQUAL ZERO              16280000
         BE    SETCNT                   LINE IS VERTICAL-ENTER ORDERS   16300000
         CLC   DELTAY,ZERO              DELTA Y EQUAL ZERO              16320000
         BNE   DETPTS                   DELTA X AND DELTA Y HAVE VALUES 16340000
* ON DROP THRU LINE IS HORIZONTAL                                       16360000
* HORIZONTAL LINE-ENTER GRAPHIC ORDERS ABSOLUTE VECTOR MODE             16380000
SETCNT   LA    CNTREG,10                TEN BYTES THIS PATH             16400000
         LA    ADDREG,ORDER1            ORDER ADDRESS                   16420000
* ENTER ABSOLUTE VECTOR MODE                                            16440000
NOMODE   MVC   ORDER3,X1FINAL           OLD PT.                         16460000
         OI    ORDER3,X'40'             BLANK BIT                       16480000
         MVC   ORDER4,X2FINAL           NEW PT.                         16500000
         BAL   LINREG,STORE             STORE GRAPHIC ORDERS IN GDOA    16520000
ENDVEC   L     LINREG,RSAVE RELOAD LINE REGISTER                        16540000
         BR    LINREG                   RETURN                          16560000
*                                                                       16580000
*                                                                       16600000
* DETERMINE INTERMEDIATE POINT                                          16620000
DETPTS   SR    CONREG,CONREG            CLEAR MODIFIER                  16640000
         CR    XREG,YREG                                                16660000
         BH    NPATH                    DELTA  X LESS THAN DELTA Y      16680000
         STH   YREG,NC                  SET NC=YREG                     16700000
         STH   YREG,NT                  SET NT=YREG                     16720000
         STH   XREG,NR                  SET NR=XREG                     16740000
         LH    VALREG,NR                AND NA                          16760000
         SRA   VALREG,1(0)              EQUAL TO                        16780000
         STH   VALREG,NA                NR/2                            16800000
OVCHG    LH    VALREG,NC                WHEN NC =0 ALL DONE             16820000
         CH    VALREG,ZERO                                              16840000
         BNH   ENDVEC                                                   16860000
         LH    VALREG,DELTAY                                            16880000
         LPR   YREG,VALREG                                              16900000
         LH    VALREG,DELTAX                                            16920000
         LPR   XREG,VALREG                                              16940000
         LH    VALREG,NA                                                16960000
         AH    VALREG,NR                NA=NA+NR                        16980000
         STH   VALREG,NA                                                17000000
         CH    VALREG,NT                IF NA GREATER OR EQUAL TO NT    17020000
         BNL   ANG45                    USE 45 DEGREE LINE              17040000
         CR    YREG,XREG                IF ABS. VALUE DELTA Y GREATER   17060000
         BH    ROUTE2                   THAN ABS.VALUE DELTAX-ROUTE2    17080000
         LH    VALREG,DELTAX            IF DELTA X LESS THAN 0          17100000
         CH    VALREG,ZERO                                              17120000
         BL    XNEG                     GO TO XNEG                      17140000
         LH    VALREG,PT1VE             OTHERWISE                       17160000
         A     VALREG,EIGHT             INCREMENT X ONE SMALL DELTA(SMD 17180000
         STH   VALREG,PT1VE                                             17200000
         B     NCDECR                                                   17220000
NPATH    STH   XREG,NC                                                  17240000
         STH   XREG,NT                                                  17260000
         STH   YREG,NR                                                  17280000
         LH    VALREG,NR                                                17300000
         SRA   VALREG,1(0)                                              17320000
         STH   VALREG,NA                                                17340000
         B     OVCHG                                                    17360000
ROUTE2   LH    VALREG,DELTAY            IF DELTAX IS ZERO AND Y         17380000
         CH    VALREG,ZERO              IS       LESS THAN ZERO         17400000
         BL    YNEG                     USE YNEG                        17420000
         LH    VALREG,PT2VE             OTHERWISE                       17440000
         A     VALREG,EIGHT             IMCREMENT Y                     17460000
         STH   VALREG,PT2VE             ONE SMD                         17480000
         B     NCDECR                                                   17500000
XNEG     LH    VALREG,PT1VE             DECREMENT                       17520000
         S     VALREG,EIGHT             X BY ONE SMD                    17540000
         STH   VALREG,PT1VE                                             17560000
         B     NCDECR                                                   17580000
YNEG     LH    VALREG,PT2VE             DECREMENT Y                     17600000
         S     VALREG,EIGHT             BY ONE SMD                      17620000
         STH   VALREG,PT2VE            STUFF IT AWAY                    17640000
         B     NCDECR                                                   17660000
ANG45    LH    VALREG,DELTAX            IF DELTA X IS LESS THAN         17680000
         CH    VALREG,ZERO              ZERO                            17700000
         BL    ROUTE3                   GO TO ROUTE3                    17720000
         LH    VALREG,DELTAY            IF DELTAY IS                    17740000
         CH    VALREG,ZERO              LESS THAN ZERO                  17760000
         BL    XPYN                     GO TO XPYN                      17780000
         LH    VALREG,PT1VE             OTHERWISE INCREMENT             17800000
         A     VALREG,EIGHT             BOTH BY ONE SMD                 17820000
         STH   VALREG,PT1VE                                             17840000
         LH    VALREG,PT2VE                                             17860000
         A     VALREG,EIGHT                                             17880000
         STH   VALREG,PT2VE                                             17900000
         B     NADECR                                                   17920000
*                                                                       17940000
ROUTE3   LH    VALREG,DELTAY            IF BOTH DELTA X AND Y ARE       17960000
         CH    VALREG,ZERO              LESS THAN ZERO                  17980000
         BL    BTHNEG                   GO TO BTHNEG                    18000000
         LH    VALREG,PT1VE             OTHERWISE                       18020000
         S     VALREG,EIGHT             DECREMENT X AND INCREMENT Y     18040000
         STH   VALREG,PT1VE             BY ONE SMD                      18060000
         LH    VALREG,PT2VE                                             18080000
         A     VALREG,EIGHT                                             18100000
         STH   VALREG,PT2VE                                             18120000
         B     NADECR                                                   18140000
*                                                                       18160000
XPYN     LH    VALREG,PT1VE             INCREMENT X                     18180000
         A     VALREG,EIGHT             AND DECREMENT Y BY ONE SMD      18200000
         STH   VALREG,PT1VE                                             18220000
         LH    VALREG,PT2VE                                             18240000
         S     VALREG,EIGHT                                             18260000
         STH   VALREG,PT2VE                                             18280000
         B     NADECR                                                   18300000
*                                                                       18320000
BTHNEG   LH    VALREG,PT1VE             DECREMENT X AN Y BY ONE SMD     18340000
         S     VALREG,EIGHT                                             18360000
         STH   VALREG,PT1VE                                             18380000
         LH    VALREG,PT2VE                                             18400000
         S     VALREG,EIGHT                                             18420000
         STH   VALREG,PT2VE                                             18440000
NADECR   LH    VALREG,NA                                                18460000
         SH    VALREG,NT                SUBTRACT NT FROM NA             18480000
         STH   VALREG,NA                                                18500000
NCDECR   LH    VALREG,NC                SUBTRACT ONE SMD FROM ABS.VALUE 18520000
         S     VALREG,EIGHT             OF THE LARGEST DELTA            18540000
         STH   VALREG,NC                SAVE FOR COMPLETION TEST        18560000
         MVC   ORDER3,PT1VEC            OUTPUT SMALL VECTOR             18580000
         LA    CNTREG,4                 USING THE STORE ROUTINE         18600000
         LA    ADDREG,ORDER3                                            18620000
         BAL   LINREG,STORE                                             18640000
         B     OVCHG                    AND CONTINUE                    18660000
*        XYLCHK     SUBROUTINE                                          18680000
*        ADDRESS OF XYLIM TABLE IN  XYLREG BEFORE  BAL                  18700000
XYLCHK   LA    CONREG,4                SET LOOP CONTROL                 18720000
         LA    INXREG,0                 SET  INDEX                      18740000
XYLLOOP  LH    TEMREG,X1(INXREG)        X1,Y1,X2,Y2                     18760000
         C     TEMREG,ZERO                                              18780000
         BL    ERR4RET                                                  18800000
         C     TEMREG,HIGH                                              18820000
         BH    ERR4RET                                                  18840000
         A     INXREG,TWO                                               18860000
         BCT   CONREG,XYLLOOP                                           18880000
         CLC   X1,X2                    X1 COMPARED TO X2               18900000
         BNL   ERR4RET                                                  18920000
         CLC   Y1,Y2                    Y1 COMPARED TO Y2               18940000
         BNL   ERR4RET                                                  18960000
         BR    INTREG                   RETURN TO MAIN LINE             18980000
ERR4RET  LA    15,4                     XYLIM X1,Y2,X2,Y2 LIMIT ERROR   19000000
         B     ERRCNTR                                                  19020000
ERR8RET  LA    15,8                                                     19040000
         B     ERRCNTR                                                  19060000
ERR12RET LA    15,12                    FLOATING POINT ERROR DETECTED   19080000
         B     ERRCNTR                                                  19100000
ERR16RET LA    15,16                    U1,V1 GREATER THAN U2,V2        19120000
         B     ERRCNTR                                                  19140000
ERR20RET LA    15,20                                                    19160000
         B     ERRCNTR                                                  19180000
ERR24RET LA    15,24                    USERS OVERFLOW-OLP NOT RESET    19200000
         B     ERRCNTR                                                  19220000
ERR28RET LA    15,28                                                    19240000
         B     ERRCNTR                                                  19260000
ERR32RET LA    15,32                    OPTION C                        19280000
         B     ERRCNTR                                                  19300000
ERR40    LA    15,40                    PARAMETERS ERROR-NOT SERIOUS    19320000
         B     ERRCNT                   ADD TO COUNT                    19340000
ERR44    LA    15,44                                                    19360000
         B     ERRCNT                                                   19380000
ERR48    LA    15,48                                                    19400000
         B     ERRCNT                   ADD TO COUNT                    19420000
ERRCNTR  LA    LINREG,RET                                               19440000
ERRCNT   L     TEMREG,ERRCOUNT                                          19460000
         A     TEMREG,ONE                                               19480000
         ST    TEMREG,ERRCOUNT                                          19500000
         BR    LINREG                                                   19520000
*                                                                       19540000
*   RET SUBROUTINE TESTS COUNT IN WORK AREA,(ERRCOUNT) AND              19560000
*   SETS BIT IN SIGN POSITION OF REG. 15 IF MULTIBLE ERRORS             19580000
*   (MORE THAN ONE)                                                     19600000
RET      CLC   ADGOFFSG,ZERO            HAS OFF SCREEN/GRID ROUTINE     19620000
         BE    RET1                                                     19640000
         ST    15,SVR15                 SAVE ERROR REGISTER             19660000
         LR    WRKREG,1                 SAVE REGISTER 1                 19680000
         DELETE EP=GOFFSG                                               19700000
         LR    1,WRKREG                 RESTORE REGISTER 1              19720000
         L     15,SVR15                 RESTORE ERROR REGISTER          19740000
RET1     LA    TEMREG,1                                                 19760000
         C     TEMREG,ERRCOUNT                                          19780000
         BL    SETBIT                                                   19800000
* RESTORE PROGRAM MASK TO SETTING UPON ENTRY                            19820000
RETMACRO L     WRKREG,MASKSV                                            19840000
         SPM   WRKREG                                                   19860000
         RETURN (14,12),T,RC=(15)                                       19880000
SETBIT   O     15,MZERO                                                 19900000
         B     RETMACRO                                                 19920000
BYCT     DC    F'120'                                                   19940000
ZERO     DC    F'0'                     ZERO                            19960000
MZERO    DC    X'80000000'              MINUS ZERO                      19980000
ONE      DC    F'1'                                                     20000000
TWO      DC    F'2'                                                     20020000
MTWO     DC    X'FFFFFFFE'              MINUS TWO                       20040000
FOUR     DC    F'4'                                                     20060000
EIGHT    DC    F'8'                                                     20080000
HIGH     DC    F'4095'                  HIGH LIMIT                      20100000
BYTE3    DC    X'0000FF00'              MASK SYMBOL-EBCDIC CODE         20120000
BYTE123  DC    X'00FFFFFF'                                              20140000
ALLFF    DC    X'FFFFFFFF'              ALL BITS                        20160000
X6       DC    X'46000000'              EXPONENT OF SIX                 20180000
         DS    0D                       ALIGN BOUNDARY                  20200000
X4E      DC    X'4E00000000000000'                                      20220000
FLPT5    DC    E'.5'                                                    20240000
FCHAR    DC    X'7F000000'              MASK FOR CHARACTERISTIC         20260000
LOHI     DC    F'0'                     X1,Y1                           20280000
         DC    H'4095'                  UPPER LIMIT                     20300000
         DC    H'4095'                  UPPER LIMIT                     20320000
STATUS1  DC    H'0'                     BOTH PT1 AND PT2 WITHIN LIMITS  20340000
H2A02    DC    X'2A02'                                                  20360000
H0003    DC    H'0003'                                                  20380000
STATUS2  DC    X'1100'                  PT1 OFF PT2 ON                  20400000
STATUS3  DC    X'0011'                  PT1 ON PT2 OFF                  20420000
* REGISTER ASSIGN MENT                                                  20440000
VALREG   EQU   0                                                        20460000
PASREG   EQU   0                                                        20480000
WKAREG   EQU   1                                                        20500000
XYLREG   EQU   2                                                        20520000
OBPREG   EQU   2                        MUST BE IN THIS ORDER           20540000
PATREG   EQU   3                        MUST BE IN THIS ORDER           20560000
WRKREG   EQU   4                                                        20580000
EREG     EQU   4                        EVEN REGISTER                   20600000
XREG     EQU   5                        ODD  REGISTER                   20620000
CNTREG   EQU   5                                                        20640000
TEMREG   EQU   6                                                        20660000
OREG     EQU   6                        EVEN REGISTER                   20680000
YREG     EQU   7                        ODD REGISTER                    20700000
ADDREG   EQU   7                                                        20720000
INXREG   EQU   8                                                        20740000
SLOREG   EQU   8                                                        20760000
OABREG   EQU   10                                                       20780000
INTREG   EQU   11                                                       20800000
OLPREG   EQU   12                                                       20820000
CONREG   EQU   12                                                       20840000
LINREG   EQU   14                                                       20860000
* PARTAB DEFINED STORAGE MAP                                            20880000
* PATREG EQUALS A GENERAL REGISTER                                      20900000
PARTAB   DSECT                                                          20920000
XYLIM    DS    CL4                      XYLIM ADDRESS                   20940000
UTAB     DS    CL4                      UTAB  ADDRESS                   20960000
VTAB     DS    CL4                      VTAB  ADDRESS                   20980000
F        DS    CL1                      MODE OF INPUT                   21000000
S        DS    CL1                      SCALE OR NO SCALE               21020000
CSIZE    DS    CL1                      CHARACTER SIZE                  21040000
CMOD     DS    CL1                      PROTECTED OR UNPROTECTED MODE   21060000
A        DS    CL1                      RELATIVE OR ABSOLUTE            21080000
I        DS    CL1                      INCREMENT OR NO INCREMENT       21100000
PTYPE    DS    CL1                      PLOT TYPE                       21120000
SG       DS    CL1                                                      21140000
N        DS    CL2                      NUMBER OF POINTS TO PLOT        21160000
SYMBOL   DS    CL1                      LETTER TO PLOT                  21180000
E        DS    CL1                      OVERLAP OR NO OVERLAP           21200000
* XYLIM TABLE DEFINED.STORAGE MAP                                       21220000
* XYLREG EQUALS A GENERAL REGISTER                                      21240000
XYLIMTB  DSECT                                                          21260000
X1       DS    CL2                      LOWER LEFT COORDINATE VALUE     21280000
Y1       DS    CL2                      LOWER LEFT COORDINATE VALUE     21300000
X2       DS    CL2                      UPPER RIGHT COORDINATE VALUE    21320000
Y2       DS    CL2                      UPPER RIGHT COORDINATE VALUE    21340000
U1       DS    CL4                      LOWER LEFT SCALING COORDINATE   21360000
U2       DS    CL4                      LOWER LEFT SCALING COORDINATE   21380000
V1       DS    CL4                      UPPER RIGHT SCALING COORDINATE  21400000
V2       DS    CL4                      UPPER RIGHT SCALING COORDINATE  21420000
* WORK AREA DEFINED STORAGE MAP                                         21440000
* WKAREG EQUALS A GENERAL REGISTER                                      21460000
WKAREA   DSECT                                                          21480000
         DS    0D                                                       21500000
OVFSAVE  DS    0CL72                                                    21520000
TEMFLT   DS    0CL8                                                     21540000
         DS    CL72                                                     21560000
ERRCOUNT DS    CL4                      COUNT OF PARAMETER ERRORS       21580000
INCOUNT  DS    CL4                                                      21600000
         ORG   INCOUNT                                                  21620000
INDEX    DS    CL2                      TABLE INDEX OF UTAB OR VTAB     21640000
COUNT    DS    CL2                      NUMBER OF POINTS PROCESSED      21660000
MASKSV   DS    F                   SAVE SETTING OF USER PROGRAM MASK    21680000
FX1      DS    CL4                      FLOAT X1                        21700000
FY1      DS    CL4                      FLOAT Y1                        21720000
FX2      DS    CL4                      FLOAT X2                        21740000
FY2      DS    CL4                      FLOAT Y2                        21760000
UA       DS    CL4                      ABSOLUTE FLOAT OR FIXED UA      21780000
VA       DS    CL4                      ABSOLUTE FLOAT OR FIXED VA      21800000
X1FINAL  DS    CL4                      X1,Y1                           21820000
         ORG   X1FINAL                                                  21840000
X1FIN    DS    CL2                      X1                              21860000
Y1FIN    DS    CL2                      Y1                              21880000
X2FINAL  DS    CL4                      X2,Y2                           21900000
         ORG   X2FINAL                                                  21920000
X2FIN    DS    CL2                      X2                              21940000
Y2FIN    DS    CL2                      Y2                              21960000
WRTADDR  DS    CL4                      ADDR OF GRID OR SCREEN CHECK RT 21980000
GOFFSGAD DS    CL4                      GOFFSG RT ADDR AREA             22000000
SWSTATUS DS    CL2                      SWITCH STATUS OF PT1 AND PT2    22020000
         ORG   SWSTATUS                                                 22040000
PT1SW    DS    CL1                      PREVIOUS STATUS                 22060000
OFFSW    DS    CL1                      CURRENT STATUS                  22080000
SKIPSW   DS    CL2                      SET TO ONE TO SKIP POINT        22100000
NC       DS    CL2                                                      22120000
NT       DS    CL2                                                      22140000
NR       DS    CL2                                                      22160000
NA       DS    CL2                                                      22180000
RSAVE    DS    CL4                      PLACE TO SAVE LINE REGISTER     22200000
SVR15    DS    CL4                      PLACE TO SAVE ERROR REGISTER    22220000
ORDER1   DS    CL1                      GRAPHICORDERS-MODE              22240000
ORDER2   DS    CL1                                                      22260000
ORDER3   DS    CL4                      PT. TO PLOT                     22280000
ORDER4   DS    CL4                                                      22300000
         ORG   ORDER4                                                   22320000
ORDER5   DS    CL2                                                      22340000
ORDER6   DS    CL1                                                      22360000
ORDER7   DS    CL1                                                      22380000
ORDER8   DS    CL2                                                      22400000
EPRGMOD  DS    CL4                                                      22420000
         ORG   EPRGMOD                                                  22440000
EOPRG    DS    CL2                      LAST PT. INDICATOR              22460000
CHARMOD  DS    CL2                      ORDER FOR CHARACTER AND MODE    22480000
PT1VEC   DS    CL4                      SIMULATED VECTOR X1,Y1          22500000
         ORG   PT1VEC                                                   22520000
PT1VE    DS    CL2                                                      22540000
PT2VE    DS    CL2                                                      22560000
PT2VEC   DS    CL4                      SIMULATED VECTOR X2,Y2          22580000
         ORG   PT2VEC                                                   22600000
PT2VECT  DS    CL2                                                      22620000
PT2VECS  DS    CL2                                                      22640000
DELTAX   DS    CL2                      DELTA X                         22660000
DELTAY   DS    CL2                      DELTA Y                         22680000
TOTAL    DS    CL4                                                      22700000
         ORG   TOTAL                                                    22720000
INTEGER  DS    CL2                      INTEGER-SIMULATED VECTOR        22740000
FRACTION DS    CL2                      FRACTION-SIMULATED VECTOR       22760000
ABVTEMP  DS    CL4                      VECTOR MODE-TEMP STORAGE        22780000
         ORG   ABVTEMP                                                  22800000
ABVMODE  DS    CL2                      VECTOR MODE INDICATOR           22820000
TEMP     DS    CL2                      TEMP STORAGE                    22840000
XYINCR   DS    CL4                      CHANGING X OR Y VALUE           22860000
PORSAVE  DS    CL28                                                     22880000
ADGOFFSG DS    CL4                      ADDRESS OF GOFFSG               22900000
SABL     DS    CL4                      ADDRESS OF BOUNDARY             22920000
UASCALE2 DS    CL4                                                      22940000
VASCALE2 DS    CL4                                                      22960000
UASCALE  DS    CL4                      ABSOLUTE FLOAT-FIX-THEN SCALE   22980000
         ORG   UASCALE                                                  23000000
UAS1     DS    CL2                                                      23020000
UAS2     DS    CL2                      FIXED HALF WORD-MAY BE SCALED   23040000
VASCALE  DS    CL4                                                      23060000
         ORG   VASCALE                                                  23080000
VAS1     DS    CL2                                                      23100000
VAS2     DS    CL2                      FIXED HALF WORD-MAY BE SCALED   23120000
NI       DS    CL4                      NUMBER OF INTERATIONS           23140000
XYINT1   DS    CL4                      FIRST INTERSECTION              23160000
XYINT2   DS    CL4                      SECOND INTERSECTION             23180000
INTWKA   DS    CL64                     INTERNAL WORKAREA               23200000
         DS    0D                                                       23220000
         DS    0D                                                       23240000
         DS    0D                                                       23260000
         ORG   OVFSAVE+396                                              23280000
GOMODE   DS    CL2                                                      23300000
         END                                                            23320000
