         START                                                          00060000
*TITLE IFFPKADG                                                       * 00120000
*                                                                     * 00180000
*STATUS: CHANGE LEVEL 000                                             * 00240000
*                                                                     * 00300000
*FUNCTION/OPERATION: GENERATES A SERIES OF GRAPHIC ORDERS FROM DATA   * 00360000
*   SUPPLIED BY THE USER. THE ORDERS MAY CONSIST OF ABSOLUTE OR       * 00420000
*   INCREMENTAL ORDERS OR AN OPTIMIZED MIXTURE OF THE TWO. THE DATA   * 00480000
*   FORMAT AND MODE IS SPECIFIED BY THE USER IN HIS PARAMETER TABLE.  * 00540000
*   THE DATA IS SCALED IF DESIRED USING THE ENTRIES IN THE XYSCALE    * 00600000
*   TABLE TO DERIVE APPROPRIATE SCALING FACTORS.                      * 00660000
*                                                                     * 00720000
*INPUT: A PARAMETER TABLE (PARTAB) AND AN OUTPUT CONTROL BLOCK POINTER* 00780000
*   (OCBP). THESE POINT TO AN XYSCALE TABLE AND TO THE OUTPUT AREA    * 00840000
*   CONTROL BLOCK (OCBP) AND AN HUNDRED-WORD WORKAREA RESPECTIVELY.   * 00900000
*                                                                     * 00960000
*OUTPUT: THE GRAPHIC ORDERS TO PLOT THE DATA AS SPECIFIED ARE PLACED  * 01020000
*   IN THE USER'S GDOA.                                               * 01080000
*                                                                     * 01140000
*EXTERNAL ROUTINES: GOFFSG                                            * 01200000
*                                                                     * 01260000
*EXITS-NORMAL: VIA RETURN MACRO WITH A ZERO RETURN CODE ON SUCESSFUL  * 01320000
*   COMPLETION.                                                       * 01380000
*              VIA A BALR 14,15 TO THE USER'S OVERFLOW ROUTINE        * 01440000
*                                                                     * 01500000
*EXITS-ERROR: VIA RETURN MACRO WITH A NON-ZERO RETURN CODE IN REGISTER* 01560000
*   15                                                                * 01620000
*                                                                     * 01680000
*TABLES/WORKAREA: AN HUNDRED-WORD USER SUPPLIED WORKAREA. TABLES OF   * 01740000
*   POSSIBLE PARAMETER VALUES AND THE CORRESPONDING SWITCH SETTINGS   * 01800000
*                                                                     * 01860000
*ATTRIBUTES: PROBLEM STATE, REENTRANT, CHARACTER DEPENDENT.           * 01920000
*                                                                       01980000
WORKAREA DSECT                                                          02040000
         DS    0F                      FORCE FULL WORD ALIGNMENT        02100000
*                                                                       02160000
X1       DS    H                       GRID LIMITS-LOWER LEFT CORNER    02220000
Y1       DS    H                       IN 4096 RASTER UNITS             02280000
X2       DS    H                       GRID LIMITS-UPPER RIGHT CORNER   02340000
Y2       DS    H                       IN 4096 RASTER UNITS             02400000
*                                                                       02460000
OVERFLAG DS    C                                                        02520000
PTSGSW   DS    C                       PLOT TYPE-SCISSORING OPTIONS     02580000
*              X'80'         1=OPTIMIZED PLOT/0=NOT OPTIMIZED           02640000
*              X'40'         1=FIRST POINT FOR CALL                     02700000
*              X'20'         1=INCREMENTAL PLOT/0=ABSOLUTE PLOT         02760000
*              X'10'         1=VECTOR PLOT/0=POINT PLOT                 02820000
*              X'08'         1=DISCONTINUE WHEN SCREEN EXCEEDED         02880000
*                            0=CONTINUE                                 02940000
*              X'04'         1=DISCONTINUE WHEN GRID EXCEEDED           03000000
*                            0=CONTINUE                                 03060000
*              X'02'         1=SHOW ALL POINTS WITHIN SCREEN LIMITS     03120000
*                            0=SHOW ALL POINTS WITHIN GRID LIMITS       03180000
UMODE    DS    C                       CHARACTERISTICS OF U'S           03240000
VMODE    DS    C                       CHARACTERISTICS OF V'S           03300000
*              X'10'         1=FLOATING-POINT/0=INTEGER                 03360000
*              X'20'         INPUT VALUES ABSOLUTE                      03420000
*              X'40'         INPUT VALUES A TABLE OF INCREMENTS         03480000
*              X'80'         INPUT VALUES BY ADDING A FIXED INCREMENT   03540000
XP       DS    H                       LAST PHYSICAL LOCATION           03600000
YP       DS    H                       OF BEAM                          03660000
X        DS    F                       LAST LOGICAL LOCATION            03720000
Y        DS    F                       OF BEAM                          03780000
U        DS    F                       LAST U-VALUE                     03840000
V        DS    F                       LAST V-VALUE                     03900000
UTAB     DS    F                       LAST ENTRY IN U-ARRAY USED       03960000
VTAB     DS    F                       LAST ENTRY IN V-ARRAY USED       04020000
*                                                                       04080000
GIX1     DS    H                       COORDINATES OF FIRST INTERSEC-   04140000
GIY1     DS    H                       TION WITH GRID LIMITS            04200000
GIX2     DS    H                       COORDINATES OF SECOND  INTER-    04260000
GIY2     DS    H                       SECTION WITH GRID LIMITS         04320000
PTPOS    DS    C                       RELATIVE POSITIONS OF END-POINTS 04380000
*                                                                       04440000
DEFLG    DS    C                       DEFAULT FLAG                     04500000
RETCD    DS    H                       RETURN CODE WORK AREA            04560000
PARTABAD DS    F                       ADDRESS OF PARTAB                04620000
OACBAD   DS    F                       ADDRESS OF OACB                  04680000
*                                                                       04740000
NXTX1    DS    F                       X AND Y COORDINATES              04800000
NXTY1    DS    F                       OF FIRST POINT-VECTOR            04860000
SUPLT1   DS    C                       SUPRESS PLOT SWITCH              04920000
PTCNT1   DS    C                       NO. OF POINTS TO PLOT            04980000
BV11     DS    C                       BLANKED BEAM SWITCHES            05040000
BV21     DS    C                                                        05100000
ADJX11   DS    H                       ADJUSED X                        05160000
ADJY11   DS    H                                 AND Y                  05220000
ADJX21   DS    H                                      COORDINATES       05280000
ADJY21   DS    H                       TO PLOT VECTOR                   05340000
NXTX2    DS    F                       X AND Y COORDINATES              05400000
NXTY2    DS    F                       OF SECOND POINT-VECTOR           05460000
SUPLT2   DS    C                       SUPRESS PLOT SWITCH              05520000
PTCNT2   DS    C                       NO. OF POINTS TO PLOT            05580000
BV12     DS    C                       BLANKED BEAM SWITCHES            05640000
BV22     DS    C                                                        05700000
ADJX12   DS    H                       ADJUSTED X                       05760000
ADJY12   DS    H                                  AND Y                 05820000
ADJX22   DS    H                                        COORDINATES     05880000
ADJY22   DS    H                       TO PLOT VECTOR                   05940000
*                                                                       06000000
NXTX3    DS    F                       X AND Y COORDINATES FOR          06060000
NXTY3    DS    F                       OPTIMIZATION CHECK VECTOR        06120000
SUPLT3   DS    C                       SUPRESS PLOT                     06180000
PTCNT3   DS    C                       NO. OF POINTS TO PLOT            06240000
BV13     DS    C                       BLANKED VECTOR SWITCHES          06300000
BV23     DS    C                                                        06360000
ADJX13   DS    H                       ADJUSTED X                       06420000
ADJY13   DS    H                                  AND Y                 06480000
ADJX23   DS    H                                        COORDINATES     06540000
ADJY23   DS    H                       OF VECTOR                        06600000
SVAR1    DS    18F                     SAVE AREA-SUB-LEVEL 1            06660000
SVAR2    DS    18F                     SAVE AREA-SUB-LEVEL 2            06720000
*                                                                       06780000
SMSW     DS    C                       SET MODE SWITCH                  06840000
INTS     DS    C                       NUMBER OF INTERSECTIONS          06900000
*                                      BETWEEN GRID/SCREEN AND VECTOR   06960000
ABSPTS   DS    H                       NO. OF ABSOLUTE PTS. IN WORKAREA 07020000
INCPTS   DS    H                       NO. OF INCREMENTAL PTS.          07080000
BTCNT    DS    H                       NO. OF BYTES REMAINING           07140000
*                                                                       07200000
OPTIMSV  DS    6F                                                       07260000
*                                      LOOK-AHEAD                       07320000
WRKAR    DS    12F                                                      07380000
OPT14    DS    F                       SAVE AREA FOR REGISTER 14        07440000
DELTAX   DS    F                       TEMPORARY STORAGE-X AND Y        07500000
DELTAY   DS    F                       DISPLACEMENTS FROM LAST POINT    07560000
SIX1     DS    H                       COORDINATES OF FIRST INTER-      07620000
SIY1     DS    H                       SECTION WITH SCREEN LIMITS       07680000
SIX2     DS    H                       COORDINATES OF SECOND INTER-     07740000
SIY2     DS    H                       SECTION WITH SCREEN LIMITS       07800000
         ORG   WRKAR+8                                                  07860000
SABL     DS    F                       POINTER TO GRID/SCREEN LIMITS    07920000
PT1X     DS    F                       COORDINATES OF FROM POINT        07980000
PT1Y     DS    F                       OF VECTOR                        08040000
PT2X     DS    F                       COORDINATES OF TO POINT          08100000
PT2Y     DS    F                       OF VECTOR                        08160000
NI       DS    F                       NUMBER OF INTERSECTIONS          08220000
INTS1X   DS    H                       COORDINATES OF FIRST INTERSEC-   08280000
INTS1Y   DS    H                       TION POINT                       08340000
INTS2X   DS    H                       COORDINATES OF SECOND            08400000
INTS2Y   DS    H                       INTERSECTION POINT               08460000
         ORG   X1+396                                                   08520000
CURMOD   DS    H                       LAST SET MODE ORDER GENERATED    08580000
MODE     DS    C                       TEMPORARY STORAGE FOR UMODE &    08640000
*                                      VMODE                            08700000
         DS    C                       RESERVED                         08760000
PARTAB   DSECT                                                          08820000
XYSCALE  DS    F                  ADDRESS OF SCALING TABLES             08880000
UADDR    DS    F                  ADDRESSES OF FIRST U AND              08940000
VADDR    DS    F                  V VALUES                              09000000
F        DS    C                  MODE                                  09060000
IPU      DS    C                  FORMAT OF U VALUES                    09120000
IPV      DS    C                  FORMAT OF V VALUES                    09180000
PTYPE    DS    C                  TYPE OF PLOT                          09240000
POSOPT   DS    C                  POSITIONING OPTION                    09300000
SGOPT    DS    C                  SCREEN/GRID SCISSORING OPTION         09360000
S        DS    C                  SCALING                               09420000
SMOPT    DS    C                  INITIAL SET MODE OPTION               09480000
SEGOPT   DS    C                  SEGMENT OPTION                        09540000
         DS    C                  RESERVED                              09600000
N        DS    H                  NUMBER OF U,V PAIRS                   09660000
UINDEX   DS    F                  INDICES TO                            09720000
VINDEX   DS    F                             TABLE ENTRIES              09780000
UINCR    DS    F                  FIXED U AND                           09840000
VINCR    DS    F                              V INCREMENTS              09900000
SCALETAB DSECT                                                          09960000
GX1      DS    F                  GRID LIMITS-LOWER LEFT CORNER         10020000
GY1      DS    F                                                        10080000
GX2      DS    F                             -UPPER RIGHT CORNER        10140000
GY2      DS    F                                                        10200000
SX1      DS    F                  SCREEN LIMITS-LOWER LEFT CORNER       10260000
SY1      DS    F                                                        10320000
SX2      DS    F                               -UPPER RIGHT CORNER      10380000
SY2      DS    F                                                        10440000
DX1      DS    F                  DATA LIMITS-LOWER LEFT CORNER         10500000
DY1      DS    F                                                        10560000
DX2      DS    F                             -UPPER RIGHT CORNER        10620000
DY2      DS    F                                                        10680000
XALTER   DS    F                  X-ALTER SWITCH- ALSO, MULTIPLICA-     10740000
*                                 TIVE SCALING CONSTANT                 10800000
YALTER   DS    F                  Y-ALTER SWITCH- ALSO, MULTIPLICA-     10860000
*                                 TIVE Y SCALING CONSTANT               10920000
XCON     DS    F                  ADDITIVE X SCALING CONSTANT           10980000
YCON     DS    F                  ADDITIVE Y SCALING CONSTANT           11040000
SGPAR    DSECT                                                          11100000
NXTX     DS    F                                                        11160000
NXTY     DS    F                                                        11220000
SUPLT    DS    C                                                        11280000
PTCNT    DS    C                                                        11340000
BV1      DS    C                                                        11400000
BV2      DS    C                                                        11460000
ADJX1    DS    H                                                        11520000
ADJY1    DS    H                                                        11580000
ADJX2    DS    H                                                        11640000
ADJY2    DS    H                                                        11700000
IFFPKADG CSECT                                                          11760000
* 514200                                                         A29393 11790019
PARBASE  EQU   10                      BASE REGISTER FOR PARAMETERS     11820000
SCALBASE EQU   9                       BASE REGISTER FOR SCALING        11880000
*                                      CONSTANTS                        11940000
FPACC    EQU   0                                                        12000000
FPACC1   EQU   2                                                        12060000
FPACC2   EQU   4                                                        12120000
FPACC3   EQU   6                                                        12180000
ACC      EQU   0                       GENERAL ACCUMULATOR              12240000
PARLIST  EQU   1                       PARAMETER LIST REGISTER          12300000
NINC     EQU   1                       NUMBER OF VECTORS IN ABS. VECTOR 12360000
EVNACC   EQU   2                       ACCUMULATOR FOR MULTIPLICATION   12420000
*                                      AND DIVISION                     12480000
ERRX     EQU   2                       CUMULATIVE X-ERROR               12540000
ODDACC   EQU   3                       ACCUMULATOR FOR MULTIPLICATION   12600000
*                                      AND DIVISION                     12660000
ERRY     EQU   3                       CUMULATIVE Y-ERROR               12720000
ABIND    EQU   4                       POINTER TO ABSOLUTE VECTOR       12780000
*                                      BEING CONVERTED TO INCREMENTAL   12840000
ACC1     EQU   4                                                        12900000
INCIND   EQU   5                       POINTER TO STORAGE AREA FOR      12960000
*                                      INCREMENTAL VECTORS              13020000
ACC2     EQU   5                                                        13080000
ACC3     EQU   6                                                        13140000
COUNT    EQU   6                       NUMBER ABSOLUTE VECTORS          13200000
POINTS   EQU   6                                                        13260000
DELX     EQU   7                       CONSTANT X-DISPLACEMENT          13320000
MAGDELX  EQU   7                       MAGNITUDE OF DELTAX              13380000
OLPREG   EQU   7                       CURRENT VALUE OF OLP             13440000
RX       EQU   8                       FINAL X-REMAINDER                13500000
GDOACNT  EQU   8                       USABLE BYTES IN GDOA             13560000
DELY     EQU   9                       CONSTANT Y-DISPLACEMENT          13620000
MAGDELY  EQU   9                       MAGNITUDE OF DELTAY              13680000
RY       EQU   10                      Y-REMAINDER FOR LAST VECTOR      13740000
WORKBASE EQU   11                      BASE FOR SYMBOLIC REFERENCES     13800000
*                                      TO WORKAREA                      13860000
BASE     EQU   12                      BASE REGISTER FOR ROUTINE        13920000
SAVEREG  EQU   13                      POINTER TO SAVE AREA             13980000
RETREG   EQU   14                      RETURN REGISTER                  14040000
ENTREG   EQU   15                                                       14100000
         ENTRY GSDPLT                                                   14160000
GSDPLT   SAVE  (14,12)                                                  14220000
         BALR  BASE,0                  ADDRESSABILITY                   14280000
         USING *,BASE                  FOR ROUTINE                      14340000
*                                                                       14400000
         L     PARBASE,4(PARLIST)      ADDRESSABILITY                   14460000
         USING PARTAB,PARBASE          FOR PARAMETER TABLE              14520000
*                                                                       14580000
         L     EVNACC,0(PARLIST)       GET ADDRESS                      14640000
         L     WORKBASE,4(EVNACC)      OF WORKAREA                      14700000
         USING WORKAREA,WORKBASE       ADDRESSABILITY FOR WORKAREA      14760000
         XC    PTPOS(4),PTPOS          XET PT. POSITION & DEFAULT       14820000
*                                      FLAGS AND RETURN CODE WORKAREA   14880000
*                                      TO 0                             14940000
*                                                                       15000000
         ST    PARBASE,PARTABAD        S1VE ADDRESSES OF PARAMETER      15060000
         MVC   OACBAD(4),0(EVNACC)     TABLE AND OACB IN WORKBASE       15120000
*                                                                       15180000
         LA    EVNACC,SVAR1            SET UP SAVE AREA                 15240000
         ST    SAVEREG,4(EVNACC)       & CHAIN IT TO                    15300000
         ST    EVNACC,8(SAVEREG)       PREVIOUS SAVE AREA               15360000
         LR    SAVEREG,EVNACC                                           15420000
*                                                                       15480000
         CLC   N(2),H1                 SEE IF N POSITIVE                15540000
         BNL   PARMCHK                                                  15600000
         L     SAVEREG,4(SAVEREG)      N ZERO OR NEGATIVE-              15660000
         RETURN (14,12),RC=0           IMMEDIATE RETURN                 15720000
*                                                                       15780000
PARMCHK  LA    ACC,3                                                    15840000
         SPM   ACC                     UNMASK ALL PROGRAM INTERRUPTS    15900000
         LA    PARLIST,MODES           GET DATA/                        15960000
         LA    EVNACC,F                COMPUTATION                      16020000
         LA    ODDACC,4                MODE OF                          16080000
         BAL   RETREG,PRMCHKLP         INPUT                            16140000
         MVC   UMODE(1),1(PARLIST)     AND SET CONTROL SWITCHES         16200000
         MVC   VMODE(1),2(PARLIST)                                      16260000
*                                                                       16320000
         LA    ACC,2                                                    16380000
         LA    PARLIST,INPFORMS        GET FORMAT                       16440000
         LA    EVNACC,IPU              OF U-VALUE                       16500000
         LA    ODDACC,3                INPUT                            16560000
         BAL   RETREG,PRMCHKLP                                          16620000
         OC    UMODE(1),1(PARLIST)     AND SET SWITCH                   16680000
*                                                                       16740000
         LA    PARLIST,INPFORMS        GET FORMAT                       16800000
         LA    EVNACC,IPV              OF V-VALUE                       16860000
         LA    ODDACC,3                INPUT                            16920000
         BAL   RETREG,PRMCHKLP                                          16980000
         OC    VMODE(1),1(PARLIST)     AND SET SWITCH                   17040000
*                                                                       17100000
         LA    PARLIST,SMOPTS          DETERMINE                        17160000
         LA    EVNACC,SMOPT            SET MODE                         17220000
         LA    ODDACC,2                OPTIIN                           17280000
         BAL   RETREG,PRMCHKLP                                          17340000
         MVC   SMSW(1),1(PARLIST)      AND SET CONTROL SWITCH           17400000
*                                                                       17460000
         LA    PARLIST,SGOPTS          DETERMINE                        17520000
         LA    EVNACC,SGOPT            SCISSORING OPTION                17580000
         LA    ODDACC,5                REQUESTED                        17640000
         BAL   RETREG,PRMCHKLP         AND                              17700000
         MVC   PTSGSW(1),1(PARLIST)    SET CONTROL SWITCH               17760000
*                                                                       17820000
         LA    PARLIST,PTYPES          DETERMINE                        17880000
         LA    EVNACC,PTYPE            TYPE OF                          17940000
         LA    ODDACC,6                PLOT REQUESTED                   18000000
         BAL   RETREG,PRMCHKLP         AND                              18060000
         OC    PTSGSW(1),1(PARLIST)    SET CONTROL SWITCH               18120000
         TM    PTSGSW,X'80'            IF OPTIMIZED PLOT                18180000
         BZ    SCALPARM                IS REQUESTED,                    18240000
SCALPARM LA    ACC,4                                                    18300000
         LA    PARLIST,SOPTS           SEE IF SCALING REQUESTED         18360000
         LA    EVNACC,S                                                 18420000
         LA    ODDACC,2                                                 18480000
         BAL   RETREG,PRMCHKLP                                          18540000
         L     PARLIST,0(PARLIST)      BRANCH TO ROUTINE TO INITIALIZE  18600000
         L     SCALBASE,XYSCALE        SCALING REQUESTED, LOCATE        18660000
         USING SCALETAB,SCALBASE       SCALING CONTANTS                 18720000
         BR    PARLIST                                                  18780000
*                                                                       18840000
GRIDSF   LE    FPACC,SX2(EVNACC)       GET S2-S1                        18900000
         SE    FPACC,SX1(EVNACC)                                        18960000
         BC    12,RC4                  CHECK FOR LEGALITY               19020000
         LE    FPACC1,0(PARLIST)       GET COORDINATE TO BE SCALED      19080000
         SE    FPACC1,SX1(EVNACC)      SUBTRACT S1                      19140000
         ME    FPACC1,FOURKE           MULTIPLY BY 4K                   19200000
         DER   FPACC1,FPACC            DIVIDE BY S2-S1                  19260000
         STE   FPACC1,WRKAR            STORE                            19320000
         LA    PARLIST,WRKAR                                            19380000
         ST    RETREG,OPT14            SAVE RETURN REGISTER             19440000
         BAL   RETREG,FIX              FIX VALUE                        19500000
         LTR   ENTREG,ENTREG           CHECK FOR LEGALITY               19560000
         BC    7,BADTERM                                                19620000
         L     RETREG,OPT14            RETURN                           19680000
         BR    RETREG                                                   19740000
*                                                                       19800000
GRIDS    L     ACC,SX2(EVNACC)         GET S2-S1                        19860000
         S     ACC,SX1(EVNACC)         CHECK FOR LEGALITY               19920000
         BC    12,RC4                                                   19980000
         L     ODDACC,0(PARLIST)       GET COORDINATE TO BE SCALED      20040000
         S     ODDACC,SX1(EVNACC)      SUBSTRACT S1                     20100000
         ST    EVNACC,DELTAX           SAVE LOOP CONTROL                20160000
         M     EVNACC,FOURK            MULTIPLY BY 4K                   20220000
         DR    EVNACC,ACC              DIVIDE BY S2-S1                  20280000
         ST    ODDACC,WRKAR            STORE                            20340000
         L     EVNACC,DELTAX           RESTORE LOOP CONTROL             20400000
         BR    RETREG                  AND RETURN                       20460000
*                                                                       20520000
ABSGRID  MVC   WRKAR(16),GX1           MOVE GRID LIMITS TO WORKAREA     20580000
         SR    EVNACC,EVNACC           SET POINTER                      20640000
         TM    UMODE,X'10'             NEED TO FIX                      20700000
         BZ    FXABGRDV                NO, CHECK V                      20760000
FXABGRD  LA    PARLIST,WRKAR(EVNACC)   GET ADDRESS OF VALUE             20820000
         BAL   RETREG,FIX              FIX IT                           20880000
         LA    PARLIST,WRKAR+8(EVNACC) GET SECOND VALUE                 20940000
         BAL   RETREG,FIX              FIX IT                           21000000
         LTR   EVNACC,EVNACC           BOTH U AND V CHECKED             21060000
         BC    7,ABGRDXFR              YES, MOVE TO WORKAREA            21120000
FXABGRDV LA    EVNACC,4                GET POINTER TO Y VALUES          21180000
         TM    VMODE,X'10'             CHECK MODE                       21240000
         BO    FXABGRD                 FIX V VALUES                     21300000
ABGRDXFR MVC   X1(2),WRKAR+2           SAVE GRID LIMITS                 21360000
         MVC   Y1(2),WRKAR+6           IN PROPER                        21420000
         MVC   X2(2),WRKAR+10          LOCATIONS                        21480000
         MVC   Y2(2),WRKAR+14          IN THE WORKAREA                  21540000
         B     CHKGRD                  CHECK FOR VALIDITY               21600000
*                                                                       21660000
SCALGRID SR    EVNACC,EVNACC           SET UP POINTERS                  21720000
         LA    ACC2,X1                 TO U-X VALUES                    21780000
         TM    UMODE,X'10'             CHECK MODE                       21840000
         BZ    FIXGRD                  INTEGER                          21900000
FLTGRD   LA    PARLIST,GX1(EVNACC)     FLOATING- CONVERT COORDINATE OF  21960000
         BAL   RETREG,GRIDSF           LOWER-LEFT CORNER OF GRID TO     22020000
         MVC   0(2,ACC2),WRKAR+2       RASTER UNITS AND STORE           22080000
         LA    PARLIST,GX2(EVNACC)     LIKEWISE FOR                     22140000
         BAL   RETREG,GRIDSF           UPPER-RIGHT CORNER               22200000
         MVC   4(2,ACC2),WRKAR+2                                        22260000
GRDLP1   LTR   EVNACC,EVNACC           FINISHED PROCESSING Y-VALUES     22320000
         BC    7,CHKGRD                YES- CHECK                       22380000
         LA    EVNACC,4                NO- GET POINTERS TO              22440000
         LA    ACC2,Y1                 V-Y VALUES                       22500000
         TM    VMODE,X'10'             CHECK MODE                       22560000
         BO    FLTGRD                  FLOATING                         22620000
*                                                                       22680000
FIXGRD   LA    PARLIST,GX1(EVNACC)     INTEGER- EVALUATE                22740000
         BAL   RETREG,GRIDS            COORDINATES OF                   22800000
         MVC   0(2,ACC2),WRKAR+2       GRID CORNERS                     22860000
         LA    PARLIST,GX2(EVNACC)     USING                            22920000
         BAL   RETREG,GRIDS            INTEGER ARITHMETIC               22980000
         MVC   4(2,ACC2),WRKAR+2       AND STORE                        23040000
         B     GRDLP1                                                   23100000
*                                                                       23160000
CHKGRD   LH    PARLIST,ZERO            CHECK GRID                       23220000
         CH    PARLIST,X1              LIMITS TO                        23280000
         BH    RC4                     MAKE SURE                        23340000
         CH    PARLIST,Y1              THEY ARE                         23400000
         BH    RC4                     VALID                            23460000
         LH    PARLIST,ZERO+4          IF NOT,                          23520000
         CH    PARLIST,X2              SET RETURN                       23580000
         BL    RC4                     CODE FOR                         23640000
         CH    PARLIST,Y2              IMMEDIATE RETURN                 23700000
         BL    RC4                                                      23760000
         CLC   X1(2),X2                MAKE SURE LOWER GRID LIMITS      23820000
         BNL   RC4                                                      23880000
         CLC   Y1(2),Y2                ARE LESS THAN UPPER LIMITS       23940000
         BNL   RC4                                                      24000000
POSITION OI    PTSGSW,X'40'                                             24060000
         XC    ABSPTS(2),ABSPTS        SET POINT COUNT =0               24120000
         XC    INCPTS(2),INCPTS        SET NO. OF INCREMENTAL PTS.=0    24180000
         BAL   RETREG,GETNEXT          GET FIRST POINT                  24240000
         LTR   ENTREG,ENTREG           BAD DATA LIMITS                  24300000
         BP    ENDTERM                 YES, TERMINATE PROGRAM           24360000
         MVC   X(8),DELTAX             STORE                            24420000
         MVC   XP(2),DELTAX+2          IN HISTORICAL                    24480000
         MVC   YP(2),DELTAY+2          AREAS                            24540000
         LA    ACC,NXTX1               SET INITIAL                      24600000
         MVC   NXTX1(8),X              POSITION SWITCHES                24660000
         BAL   RETREG,SGCHECK          FOR FUTURE REFERENCE             24720000
         LA    POINTS,1                INITIALIZE COUNTER               24780000
         LA    ACC,4                   CHECK                            24840000
         LA    PARLIST,POSOPTS         POSITIONING                      24900000
         LA    EVNACC,POSOPT           OPTIONS                          24960000
         LA    ODDACC,3                                                 25020000
         BAL   RETREG,PRMCHKLP                                          25080000
         L     PARLIST,0(PARLIST)      GET ADDRESS OF ROUTINE           25140000
*                                                                       25200000
         L     EVNACC,OACBAD           GET NUMBER                       25260000
         L     GDOACNT,0(EVNACC)       OF FREE BYTES                    25320000
         A     GDOACNT,4(EVNACC)       IN THE GDOA                      25380000
         L     OLPREG,16(EVNACC)       AND THE VALUE                    25440000
         SR    GDOACNT,OLPREG          OF THE                           25500000
         SH    GDOACNT,H4              OLP                              25560000
         NI    PTSGSW,X'BF'                                             25620000
         MVI   BV21,X'00'              SET INCREMENTAL POSITIONING      25680000
*                                      SWITCH OFF                       25740000
         BR    PARLIST                 TO PROCESSING ROUTINE            25800000
*                                                                       25860000
ABSPOS   MVC   NXTX1(8),X              ABSOLUTE POSITIONING             25920000
         LA    ACC,NXTX1               CALL SCISSORING ROUTINE TO       25980000
         BAL   RETREG,SGCHECK          CHECK POSITIONING VECTOR         26040000
         LTR   ENTREG,ENTREG           TERMINATION CONDITION            26100000
         BP    ENDTERM                 YES, EXIT                        26160000
         TM    SUPLT1,X'FF'            NO.  PLOT SUPPRESSED             26220000
         BZ    ABSPOS1                 NO.  POSITION TO INPUT VALUE     26280000
         XC    XP(4),XP                YES, POSITION TO 0,0             26340000
ABSPOS1  MVC   WRKAR(4),XP                                              26400000
         MVC   ABSPTS(2),H1            STORE POSITION IN WORKAREA       26460000
         OI    WRKAR,X'40'             BLANK VECTOR                     26520000
         TM    PTSGSW,X'80'            OPTIMIZED PLOT                   26580000
         BZ    INCABPOS                                                 26640000
         NI    PTSGSW,X'1F'            YES,SET FOR ABSOLUTE PLOT        26700000
         OI    PTPOS,X'C0'             SIGNAL PLOT TYPE OVERIDE         26760000
         B     STRABS                  STORE DATA                       26820000
*                                                                       26880000
INCABPOS TM    PTSGSW,X'20'            INCREMENTAL PLOT                 26940000
         BZ    STRABS                  NO, STORE ABSOLUTE DATA          27000000
         OI    PTPOS,X'40'             YES, SIGNAL PTYPE OVERIDE        27060000
         NI    PTSGSW,X'DF'            OVERIDE TO ABSOLUTE PLOT         27120000
         B     STRABS                                                   27180000
*                                                                       27240000
INCPOS   CLI   SEGOPT,C'B'             IF SEG OPT B AND POS OPT C       27300000
         BE    ABSPOS                  ARE SPECIFIED, ASSUME POS OPT A  27360000
         MVI   BV21,X'FF'              BLANK OUT VECTOR                 27420000
*                                      INCREMENTAL POSITIONING          27480000
         TM    PTSGSW,X'80'            OPTIMIZED PLOT                   27540000
         BZ    ABINCPOS                                                 27600000
         OI    PTPOS,X'C0'             YES, SIGNAL PTYPE OVERIDE        27660000
         NI    PTSGSW,X'7F'            FORCE NON-OPTIMIZED PLOT         27720000
         B     MAINLOOP                                                 27780000
ABINCPOS TM    PTSGSW,X'20'            NON-OPTIMIZED INCREMENTAL        27840000
         BO    MAINLOOP                YES, PLOT POINT                  27900000
         OI    PTPOS,X'40'             NO, SIGNAL PTYPE OVERIDE         27960000
         OI    PTSGSW,X'20'            FORCE INCREMENTAL PLOT           28020000
         MVI   SMSW,X'FF'              AND SET MODE                     28080000
         B     MAINLOOP                                                 28140000
PRMCHKLP CLC   0(1,PARLIST),0(EVNACC)  COMPARE PARAMETER WITH TABLE     28200000
         BCR   8,RETREG                ENTRY. IF EQUAL, RETURN          28260000
         AR    PARLIST,ACC             NOT EQUAL, GET ADDRESS OF NEXT   28320000
         BCT   ODDACC,PRMCHKLP         ENTRY AND CHECK IT               28380000
         MVI   DEFLG,X'FF'             NO LEGAL OPTIONS TAKEN-SET       28440000
         BR    RETREG                  DEFAULT FLAG AND RETURN          28500000
MODES    DC    C'A'                    DATA COMPUTATION MODE            28560000
         DC    X'10'                   U FLOATING-POINT                 28620000
         DC    X'10'                   V FLOATING-POINT                 28680000
         DC    C'B'                                                     28740000
         DC    X'00'                   U INTEGER                        28800000
         DC    X'00'                   V INTEGER                        28860000
         DC    C'C'                                                     28920000
         DC    X'00'                   U INTEGER                        28980000
         DC    X'10'                   V FLOATING-POINT                 29040000
         DC    C'D'                                                     29100000
         DC    X'10'                   U FLOATING-POINT                 29160000
         DC    X'00'                   V INTEGER                        29220000
         DS    C                       DEFAULT                          29280000
         DC    X'10'                   U FLOATING-POINT                 29340000
         DC    X'10'                   V FLOATING-POINT                 29400000
*                                                                       29460000
*                                                                       29520000
*                                                                       29580000
INPFORMS DC    C'A'                    INPUT FORMATS                    29640000
         DC    X'20'                   ALL VALUES IN ABSOLUTE TABLE     29700000
         DC    C'B'                    FIRST VALUE IN TABLE,            29760000
         DC    X'40'                   OTHERS INCREMENTAL               29820000
         DC    C'C'                    FIRST VALUE IN TABLE,            29880000
         DC    X'80'                   OTHERS BY ADDING FIXED INCREMENT 29940000
         DS    C                       DEFAULT                          30000000
         DC    X'20'                   ALL VALUES ABSOLUTE              30060000
*                                                                       30120000
PTYPES   DC    C'A'                    PLOT TYPES                       30180000
         DC    X'10'                   ABSOLUTE VECTOR                  30240000
         DC    C'B'                                                     30300000
         DC    X'00'                   ABSOLUTE POINT                   30360000
         DC    C'C'                                                     30420000
         DC    X'30'                   INCREMENTAL VECTOR               30480000
         DC    C'D'                                                     30540000
         DC    X'20'                   INCREMENTAL POINT                30600000
         DC    C'E'                                                     30660000
         DC    X'B0'                   OPTIMIZED VECTOR                 30720000
         DC    C'F'                                                     30780000
         DC    X'A0'                   OPTIMIZED POINT                  30840000
         DS    C                       DEFAULT                          30900000
         DC    X'10'                   ABSOLUTE VECTOR                  30960000
*                                                                       31020000
SGOPTS   DC    C'A'                    OFF SCREEN/OFF GRID OPTIONS      31080000
         DC    X'00'                   SHOW ALL POINTS IN GRID          31140000
         DC    C'B'                                                     31200000
         DC    X'02'                   SHOW ALL POINTS IN SCREEN        31260000
         DC    C'C'                    SHOW ALL POINTS IN GRID          31320000
         DC    X'08'                   TERMINATE WHEN SCREEN EXCEEDED   31380000
         DC    C'D'                                                     31440000
         DC    X'04'                   TERMINATE WHEN GRID EXCEEDED     31500000
         DC    C'E'                    SHOW ALL POINTS IN SCREEN        31560000
         DC    X'0A'                   TERMINATE WHEN SCREEN EXCEEDED   31620000
         DS    C                       DEFAULT- SG OPT = E              31680000
         DC    X'0A'                                                    31740000
*                                                                       31800000
SMOPTS   DC    C'A'                                                     31860000
         DC    X'FF'                   SET MODE REQUESTED               31920000
         DC    C'B'                                                     31980000
         DC    X'00'                   PROPER MODE SET                  32040000
         DS    C                                                        32100000
         DC    X'FF'                   DEFAULT- SET MODE                32160000
*                                                                       32220000
         DS    0F                                                       32280000
POSOPTS  DC    C'A'                    POSITIONING OPTIONS              32340000
         DC    AL3(ABSPOS)             ABSOLUTE POSITIONING             32400000
         DC    C'B'                                                     32460000
         DC    AL3(FINOPT)             POSITION FOR INFORMATION ONLY    32520000
         DC    C'C'                                                     32580000
         DC    AL3(INCPOS)             INCREMENTAL POSITIONING          32640000
         DS    C                       DEFAULT                          32700000
         DC    AL3(ABSPOS)             ABSOLUTE POSITIONING             32760000
*                                                                       32820000
*                                                                       32880000
SOPTS    DC    C'A'                                                     32940000
         DC    AL3(ABSGRID)            NO SCALING                       33000000
         DC    C'B'                                                     33060000
         DC    AL3(SCALGRID)           SCALING REQUESTED                33120000
         DS    C                                                        33180000
         DC    AL3(ABSGRID)            DEFAULT - NO SCALING             33240000
*                                                                       33300000
MAINLOOP LA    POINTS,1(POINTS)        INCREMENT COUNTER BY ONE         33360000
         CH    POINTS,N                ALL POINTS PROCESSED             33420000
         BH    NORMTERM                YES, TERMINATE ROUTINE           33480000
         BAL   RETREG,GETNEXT                                           33540000
         MVC   NXTX1(8),DELTAX                                          33600000
*                                                                       33660000
         LA    ACC,NXTX1                                                33720000
         BAL   RETREG,SGCHECK                                           33780000
         LTR   ENTREG,ENTREG                                            33840000
         BC    7,STOLP                                                  33900000
         MVC   X(8),NXTX1              SAVE LOGICAL POSITION OF BEAM    33960000
         TM    SUPLT1,X'FF'                                             34020000
         BO    MAINLOOP                                                 34080000
         MVC   WRKAR(8),ADJX11                                          34140000
         TM    PTCNT1,X'F0'                                             34200000
         BZ    ONEABS                                                   34260000
         MVC   ABSPTS(2),H2                                             34320000
         B     BLANK                                                    34380000
ONEABS   MVC   ABSPTS(2),H1                                             34440000
BLANK    TM    BV11,X'FF'                                               34500000
         BZ    PTYPETST                                                 34560000
         OI    WRKAR,X'40'                                              34620000
PTYPETST TM    PTSGSW,X'A0'                                             34680000
         BZ    STRABS                                                   34740000
         TM    BV21,X'FF'              INCREMENTAL POSITIONING          34800000
         BZ    DISP                    NO                               34860000
         OI    WRKAR,X'40'             YES, BLANK ALL POSSSIBLE         34920000
         OI    WRKAR+4,X'40'           ABSOLUTE VECTORS                 34980000
         MVI   BV21,X'00'              SET SWITCH TO ZERO               35040000
*                                                                       35100000
DISP     BAL   RETREG,DISPLACE                                          35160000
         LTR   ENTREG,ENTREG           RETURN CODE NON-ZERO             35220000
         BP    STOLP                   YES, IMMEDIATE TERMINATION       35280000
         TM    PTSGSW,X'80'                                             35340000
         BZ    STRINC                                                   35400000
*                                                                       35460000
         TM    PTSGSW,X'20'            CURRENT MODE = ABSOLUTE          35520000
         BO    CURINC                  NO,                              35580000
         CLC   ABSPTS(2),H1            NUMBER OF ABSOLUTE VECTORS       35640000
         BL    KEEPMODE                   NONE                          35700000
         BH    TWOABS                     TWO                           35760000
         CLC   INCPTS(2),H1               ONE- ONLY ONE INCREMENTAL     35820000
         BE    LKAHEAD                 VECTOR REQUIRED, LOOK AHEAD      35880000
*                                      MORE THAN ONE REQUIRED           35940000
KEEPMODE MVI   SMSW,X'00'              SET SET MODE SWITCH OFF          36000000
         B     FINOPT                                                   36060000
*                                                                       36120000
TWOABS   CLC   INCPTS(2),H3            NUMBER OF INCREMENTAL VECTORS    36180000
         BE    LKAHEAD                 REQUIRED-- THREE, LOOK AHEAD     36240000
         BH    KEEPMODE                  FOUR OR MORE- STAY IN ABSOLUTE 36300000
*                                        LESS THAN THREE,               36360000
FLIPMODE XI    PTSGSW,X'20'            CHANGE MODE                      36420000
         MVI   SMSW,X'FF'              SET SET MODE SWITCH              36480000
         B     FINOPT                                                   36540000
*                                                                       36600000
LKAHEAD  MVC   OPTIMSV+8(16),U         SAVE CURRENT POSITION PARAMETERS 36660000
         BAL   RETREG,GETNEXT          GET NEXT POINT TO PLOT           36720000
         LTR   ENTREG,ENTREG           CHECK RETURN CODE                36780000
         BC    7,SKPNXT                NON-ZERO                         36840000
*                                                                       36900000
         MVC   NXTX3(8),DELTAX         SET UP SCISSORING PARAMETER LIST 36960000
         LA    ACC,NXTX3               SET UP CALL FOR SCISSORING       37020000
         BAL   RETREG,SGCHECK          SCISSOR                          37080000
         LTR   ENTREG,ENTREG           TEST RETURN CODE                 37140000
         BC    7,SKPNXT                NON-ZERO                         37200000
*                                                                       37260000
         TM    SUPLT3,X'FF'            PLOT SUPPRESSED,                 37320000
         BO    SKPNXT                  STAY IN CURRENT MODE             37380000
*                                                                       37440000
         LH    EVNACC,ADJX13           GET DELTAX                       37500000
         SH    EVNACC,XP                                                37560000
         CH    EVNACC,HILIM            IF GREATER THAN 255,             37620000
         BH    SKPNXT                  STAY IN ABSOLUTE                 37680000
         CH    EVNACC,LOWLIM           IF LESS THAN -256,               37740000
         BL    SKPNXT                  STAY IN ABSOLUTE                 37800000
*                                                                       37860000
         LH    EVNACC,ADJY13           GET DELTA Y                      37920000
         SH    EVNACC,YP                                                37980000
         CH    EVNACC,HILIM            IF GREATER THEN 255,             38040000
         BH    SKPNXT                  STAY IN CURRENT MODE             38100000
         CH    EVNACC,LOWLIM           IF LESS THAN -256                38160000
         BL    SKPNXT                  STAY IN CURRENT MODE             38220000
*                                                                       38280000
         MVC   U(16),OPTIMSV+8         RESTORE ORIGINAL BEAM POSITION   38340000
*                                      VALUES                           38400000
         B     FLIPMODE                CHANGE MODE AND EXIT             38460000
*                                                                       38520000
SKPNXT   MVC   U(16),OPTIMSV+8         RESTORE ORIGINAL BEAM POSITION   38580000
*                                      VALUES                           38640000
         B     KEEPMODE                STAY IN ABSOLUTE MODE            38700000
*                                                                       38760000
CURINC   CLC   ABSPTS(2),H2            IF ONE ABSOLUTE VECTOR           38820000
         BE    TWOABSI                 NEEDED,                          38880000
         CLC   INCPTS(2),H3            SEE HOW MANY INCREMENTALS        38940000
         BH    FLIPMODE                  MORE THAN 3- GO TO ABSOLUTE    39000000
         BNH   KEEPMODE                  3 OR LESS- STAY IN INCREMENTAL 39060000
*                                                                       39120000
TWOABSI  CLC   INCPTS(2),H5            IF TWO ABSOLUTE VECTORS,         39180000
         BH    FLIPMODE                  MORE THAN 5 INCREMENTALS       39240000
         BNH   KEEPMODE                  5 OR LESS                      39300000
FINOPT   TM    PTSGSW,X'20'                                             39360000
         BO    STRINC                                                   39420000
*                                                                       39480000
STRABS   LH    EVNACC,ABSPTS                                            39540000
         MH    EVNACC,H4                                                39600000
         TM    SMSW,X'FF'                                               39660000
         BZ    ABSPACE                                                  39720000
         LA    EVNACC,2(EVNACC)                                         39780000
ABSPACE  CR    EVNACC,GDOACNT                                           39840000
         BH    GDOAOVER                                                 39900000
         LA    ODDACC,WRKAR            GET ADDRESS OF DATA              39960000
         TM    SMSW,X'FF'                                               40020000
         BZ    STRDATAA                                                 40080000
         TM    PTSGSW,X'10'                                             40140000
         BO    ABSVECSM                                                 40200000
         MVC   0(2,OLPREG),GEPM                                         40260000
         MVC   CURMOD(2),GEPM                                           40320000
         B     SMUPDA                                                   40380000
ABSVECSM MVC   0(2,OLPREG),GEVM                                         40440000
         MVC   CURMOD(2),GEVM                                           40500000
SMUPDA   LA    OLPREG,2(OLPREG)                                         40560000
         SH    GDOACNT,H2              AVAILABLE SPACE BY 2 BYTES       40620000
         SH    EVNACC,H2               DECREMENT SPACE REQUIRED &       40680000
STRDATAA LTR   EVNACC,EVNACC           IF NO DATA IS PRESENT,           40740000
         BZ    CHKMODE                 BYPASS DATA STORAGE              40800000
         SR    GDOACNT,EVNACC          UPDATE AVAILABLE SPACE           40860000
         BCTR  EVNACC,0                                                 40920000
         EX    EVNACC,MVDATAI          MOVE DATA INTO GDOA              40980000
         LA    OLPREG,1(OLPREG,EVNACC) UPDATE OLP                       41040000
*                                      OFF                              41100000
         LH    EVNACC,ABSPTS           GET POINTER                      41160000
         MH    EVNACC,H4               TO LAST                          41220000
         SH    EVNACC,H4               ABSOLUTE                         41280000
         LA    EVNACC,WRKAR(EVNACC)    VECTOR IN WORK AREA              41340000
         MVC   XP(4),0(EVNACC)         SAVE AS LAST PHYSICAL LOCATION   41400000
*                                      OF THE BEAM                      41460000
         NI    XP,X'0F'                ELIMINATE BEAM BIT               41520000
CHKMODE  MVI   SMSW,X'00'                                               41580000
         MVI   OVERFLAG,X'00'                                           41640000
         XC    ABSPTS(2),ABSPTS        SET NUMBER OF ABSOLUTE POINTS    41700000
*                                      EQUAL TO ZERO                    41760000
         TM    PTPOS,X'40'             MODE OVERIDEN                    41820000
         BZ    SEGTEST                 NO- CONTINUE                     41880000
         TM    PTPOS,X'80'             YES- OPTIMIZATION OVERRIDEN      41940000
         BZ    RONGMODE                NO                               42000000
         OI    PTSGSW,X'80'            YES- SET OPTIMIZED MODE          42060000
         B     SEGTEST                 AND CONTINUE                     42120000
RONGMODE MVI   SMSW,X'FF'              SET MODE TO BE GENERATED         42180000
         XI    PTSGSW,X'20'            SET PROPER MODE                  42240000
SEGTEST  NI    PTPOS,X'3F'             TURN OFF OVERIDE SIGNAL          42300000
         CLI   SEGOPT,C'B'             SEE IF SEGMENT PLOT              42360000
         BE    SEGLOOP                                                  42420000
         B     MAINLOOP                                                 42480000
*                                                                       42540000
MVDATAI  MVC   0(0,OLPREG),0(ODDACC)                                    42600000
*                                                                       42660000
STRINC   LH    ODDACC,ABSPTS           GET LOCATION OF INCREMENTAL      42720000
         MH    ODDACC,H4               DATA                             42780000
         LH    EVNACC,INCPTS           GET NUMBER OF INCREMENTAL        42840000
         MH    EVNACC,H2               DATA BYTES                       42900000
         TM    SMSW,X'FF'              IF SET MODE REQUESTED,           42960000
         BZ    INCSPACE                                                 43020000
         LA    EVNACC,2(EVNACC)        INCREASE NUMBER OF BYTES         43080000
*                                      REQUIRED BY 2                    43140000
INCSPACE CR    EVNACC,GDOACNT          SEE IF ENOUGH SPACE IN GDOA      43200000
         BH    GDOAOVER                                                 43260000
         LA    ODDACC,WRKAR(ODDACC)    GET ADDRESS OF DATA              43320000
         TM    SMSW,X'FF'                                               43380000
         BZ    STRDATAA                                                 43440000
*                                                                       43500000
         TM    PTSGSW,X'10'            INSERT SET MODE INTO GDOA        43560000
         BO    INCVECSM                IF REQUESTED                     43620000
         MVC   0(2,OLPREG),GEPI2       INCREMENTAL POINT MODE           43680000
         MVC   CURMOD(2),GEPI2                                          43740000
         B     SMUPDA                  UPDATE OLP AND STORE DATA        43800000
INCVECSM MVC   0(2,OLPREG),GEVI2       INCREMENTAL VECTOR MODE          43860000
         MVC   CURMOD(2),GEVI2                                          43920000
         B     SMUPDA                  UPDATE OLP AND STORE DATA        43980000
SEGLOOP  LA    POINTS,2(POINTS)        INCREMENT COUNTER BY 2           44040000
         CH    POINTS,N                FINISHED WITH CALL               44100000
         BH    NORMTERM                YES, TERMINATE ROUTINE           44160000
         BAL   RETREG,GETNEXT                                           44220000
         MVC   NXTX1(8),DELTAX                                          44280000
*                                                                       44340000
         LM    EVNACC,ODDACC,X                                          44400000
         C     EVNACC,NXTX1                                             44460000
         BNE   NORMPROC                                                 44520000
         C     ODDACC,NXTY1                                             44580000
         BE    PROCSEC                                                  44640000
NORMPROC LA    ACC,NXTX1                                                44700000
         BAL   RETREG,SGCHECK                                           44760000
         LTR   ENTREG,ENTREG                                            44820000
         BC    7,STOLP                                                  44880000
         MVC   X(8),NXTX1              MODIFY LOGICAL POSITION          44940000
*                                      OF BEAM                          45000000
         TM    SUPLT1,X'FF'            PLOT OF 1ST POINT SUPPRESSED     45060000
         BO    PROCSEC                 YES, PROCESS 2ND POINT           45120000
         TM    PTCNT1,X'F0'            TWO VECTORS GENERATED            45180000
         BZ    ONEFRST                                                  45240000
         CLC   ADJX21(2),NXTX1+2       2ND ONE = INPUT VALUE            45300000
         BNE   PROCSEC                 NO, PROCESS 2ND POINT            45360000
         CLC   ADJY21(2),NXTY1+2                                        45420000
         BNE   PROCSEC                                                  45480000
         MVC   WRKAR(4),ADJX21         YES, GENERATE BLANKED VECTOR     45540000
         B     EPONE                   TO FIRST POINT                   45600000
*                                                                       45660000
ONEFRST  CLC   ADJX11(2),NXTX1+2       ONLY VECTOR RETURNED             45720000
         BNE   PROCSEC                 FROM SCISSORING=INPUT VALUE      45780000
         CLC   ADJY11(2),NXTY1+2       NO, PROCESS 2ND POINT            45840000
         BNE   PROCSEC                                                  45900000
         MVC   WRKAR(4),ADJX11         GENERATE BLANKED VECTOR TO       45960000
EPONE    OI    WRKAR,X'40'             TO 1ST POINT                     46020000
         OI    PTPOS,X'80'             SET SWITCH                       46080000
*                                                                       46140000
PROCSEC  BAL   RETREG,GETNEXT                                           46200000
         LA    ACC,NXTX2                                                46260000
         MVC   NXTX2(8),DELTAX                                          46320000
*                                                                       46380000
         BAL   RETREG,SGCHECK                                           46440000
         LTR   ENTREG,ENTREG                                            46500000
         BC    7,STOLP                                                  46560000
         MVC   X(8),NXTX2              MODIFY LOGICAL POSITION          46620000
*                                      OF BEAM                          46680000
         TM    SUPLT2,X'FF'            2ND POINT SUPPRESSED             46740000
         BZ    TWOTST                  NO, CHECK FURTHER                46800000
NODATA   NI    PTPOS,X'3F'             YES, GENERATE NO DATA            46860000
         B     SEGLOOP                                                  46920000
*                                                                       46980000
TWOTST   TM    PTCNT2,X'F0'            2 PTS RETURNED FROM SCISSORING   47040000
         BZ    ONETEST                 NO                               47100000
         MVC   WRKAR(8),ADJX12         YES, PLOT THEM WITH              47160000
         OI    WRKAR,X'40'             1ST BLANKED                      47220000
TWOSEG   MVC   ABSPTS(2),H2            SET POINT COUNT =2               47280000
PLTSEG   NI    PTPOS,X'3F'             SET SWITCH OFF                   47340000
         B     PTYPETST                                                 47400000
*                                                                       47460000
ONETEST  TM    BV12,X'FF'              BEAM BLANKED                     47520000
         BO    NODATA                  YES, GENERATE NO DATA            47580000
         TM    PTPOS,X'80'             POSITIONING VECTOR STORED        47640000
         BZ    ONESEG                  NO                               47700000
         MVC   WRKAR+4(4),ADJX12       YES, STORE SECOND PT             47760000
         B     TWOSEG                                                   47820000
*                                                                       47880000
ONESEG   MVC   WRKAR(4),ADJX12         ONLY ONE POINT, PLOT IT          47940000
         MVC   ABSPTS(2),H1            SET POINT COUNT =1               48000000
         B     PLTSEG                                                   48060000
*                                                                       48120000
NORMTERM L     EVNACC,OACBAD           GET ADDRESS OF THE OACB          48180000
         ST    OLPREG,16(EVNACC)       UPDATE THE VALUE OF THE OLP      48240000
*                                      IN THE OACB                      48300000
         CLC   RETCD(2),ZERO           RETURN CODE WORKAREA NON-ZERO    48360000
         BNE   BADTERM                 YES                              48420000
         TM    DEFLG,X'FF'             NO. ANY DEFAULTS TAKEN           48480000
         BO    BADTERM                 YES                              48540000
         L     SAVEREG,4(SAVEREG)      GET POINTER TO SAVE AREA         48600000
         L     RETREG,12(SAVEREG)      RESTORE REGISTER 14              48660000
         SPM   RETREG                  RESTORE USER'S PROGRAM MASK      48720000
         RETURN (15,12),RC=0           RESTORE OTHER REGISTERS          48780000
*                                                                       48840000
BADTERM  LH    ENTREG,RETCD            GET RETURN CODE                  48900000
         N     ENTREG,RRC                                               48960000
         TM    DEFLG,X'FF'             ANY DEFAULTS TAKEN               49020000
         BZ    BADOUT                  NO                               49080000
         LTR   ENTREG,ENTREG           YES. RETURN CODE                 49140000
         BM    BADOUT                  NEGATIVE-MULTIPLE ERROR FLAG SET 49200000
         BP    ORIN                    POSITIVE-OR IN MULTIPLE ERROR    49260000
         LA    ENTREG,X'28'            ZERO,SET RETURN CODE             49320000
BADOUT   L     SAVEREG,4(SAVEREG)      GET POINTER TO SAVE AREA         49380000
         L     RETREG,12(SAVEREG)      RESTORE REGISTER 14              49440000
         SPM   RETREG                  RESTORE USER'S PROGRAM MASK      49500000
         RETURN (0,12),RC=(15)                                          49560000
*                                                                       49620000
ORIN     O     ENTREG,HIGHBIT          SET MULTIPLE ERROR FLAG          49680000
         B     BADOUT                  AND EXIT                         49740000
*                                                                       49800000
STOLP    L     EVNACC,OACBAD           SAVE UPDATED OLP                 49860000
         ST    OLPREG,16(EVNACC)                                        49920000
ENDTERM  CLC   RETCD(2),ZERO           IMMEDIATE TERMINATION-           49980000
         BNE   ORIN                    SET MULTIPLE ERROR               50040000
         TM    DEFLG,X'FF'             FLAG IF ANY OTHER                50100000
         BO    ORIN                    ERROR CONDITIONS DETECTED        50160000
         B     BADOUT                  AND EXIT                         50220000
*                                                                       50280000
GDOAOVER TM    OVERFLAG,X'FF'          IS OVERFLOW FLAG SET             50340000
         BO    RC24                    YES, IMMEDIATE ERROR EXIT        50400000
         SAVE  (14,12)                 NO, SAVE REGISTERS               50460000
         LR    PARLIST,SAVEREG         SET UP CALL TO                   50520000
         L     SAVEREG,4(SAVEREG)      USER'S OVERFLOW                  50580000
         L     ENTREG,OACBAD           ROUTINE                          50640000
         ST    OLPREG,16(ENTREG)       UPDATE OLP                       50700000
         L     ENTREG,8(ENTREG)                                         50760000
         BALR  RETREG,ENTREG           CALL OVERFLOW ROUTINE            50820000
         LR    SAVEREG,PARLIST         RESTORE REGISTERS                50880000
         LM    14,12,12(SAVEREG)                                        50940000
         MVI   OVERFLAG,X'FF'                                           51000000
         L     EVNACC,OACBAD           GET NEW VALUES                   51060000
         L     OLPREG,16(EVNACC)       OF OLP                           51120000
         L     GDOACNT,0(EVNACC)       AND NUMBER OF                    51180000
         A     GDOACNT,4(EVNACC)       AVAILABLE BYTES                  51240000
         SR    GDOACNT,OLPREG          IN GDOA                          51300000
         SH    GDOACNT,H4              ALLOW SPACE FOR GTRU             51360000
         B     FINOPT                                            A29393 51420019
*                                                                       51480000
RC24     LA    ENTREG,24               OLP NOT SET TO PERMIT            51540000
         B     ENDTERM                 STORAGE OF DATA AFTER OVERFLOW   51600000
*                                                                       51660000
RC4      LA    ENTREG,4                ILLEGAL GRID LIMITS              51720000
         B     ENDTERM                                                  51780000
*                                                                       51840000
         DS    0F                                                       51900000
RRC      DC    X'800000FF'                                              51960000
HIGHBIT  DC    X'80000000'                                              52020000
*                                                                       52080000
GETNEXT  SAVE  (14,12)                 SAVE REGISTERS                   52140000
*                                                                       52200000
         LA    PARLIST,SVAR2           GET NEW SAVE AREA                52260000
         ST    SAVEREG,4(PARLIST)                                       52320000
         ST    PARLIST,8(SAVEREG)      CHAIN SAVE AREAS                 52380000
         LR    SAVEREG,PARLIST                                          52440000
*                                                                       52500000
*                                                                       52560000
*                                                                       52620000
*                                                                       52680000
UTEST    MVC   MODE(1),UMODE           MOVE MODE INTO TEMPORARY         52740000
*                                      LOCATION                         52800000
         SR    PARLIST,PARLIST         SET POINTER TO X-U VALUES        52860000
GETLOOP  TM    PTSGSW,X'40'            FIRST POINT THIS CALL            52920000
         BO    INITIAL                 YES, INITIALIZE                  52980000
*                                                                       53040000
         TM    MODE,X'80'              IF VALUES DERIVED FROM           53100000
         BO    INC                     TABLE,                           53160000
         L     EVNACC,UINDEX(PARLIST)  GET INDEX FACTOR TO TABLE        53220000
         MH    EVNACC,H4                                                53280000
         A     EVNACC,UTAB(PARLIST)    ADD ADDRESS OF LAST ENTRY USED   53340000
         ST    EVNACC,UTAB(PARLIST)    STORE ADDRESS OF CURRENT ENTRY   53400000
*                                                                       53460000
         TM    MODE,X'40'              IF VALUES INCREMENTAL            53520000
         BZ    ABS                                                      53580000
INCRMNT  TM    MODE,X'10'              CHECK MODE                       53640000
         BZ    FXINC                                                    53700000
         LE    FPACC,U(PARLIST)        EVALUATE NEW VALUE               53760000
         AE    FPACC,0(EVNACC)         IN FLOATING-POINT                53820000
         STE   FPACC,U(PARLIST)        AND STORE                        53880000
         B     SCALE                                                    53940000
*                                                                       54000000
FXINC    L     ODDACC,U(PARLIST)       EVALUATE NEW VALUE               54060000
         A     ODDACC,0(EVNACC)        IN INTEGER                       54120000
         ST    ODDACC,U(PARLIST)       AND STORE                        54180000
         B     SCALE                                                    54240000
*                                                                       54300000
INC      LA    EVNACC,UINCR(PARLIST)   GET ADDRESS OF FIXED INCREMENT   54360000
         B     INCRMNT                                                  54420000
*                                                                       54480000
INITIAL  L     EVNACC,UADDR(PARLIST)   GET ADDRESS OF FIRST ENTRY       54540000
         ST    EVNACC,UTAB(PARLIST)    INITIALIZE BOOKEEPING            54600000
*                                                                       54660000
ABS      L     ACC,0(EVNACC)           GET ABSOLUTE VALUE               54720000
         ST    ACC,U(PARLIST)          OF COORDINATE                    54780000
*                                                                       54840000
SCALE    CLI   S,C'B'                  IF SCALING NOT REQUESTED         54900000
         BNE   SKPSC                   SKIP IT                          54960000
         L     ODDACC,XALTER(PARLIST)  GET MULTIPLICATIVE CONSTANT      55020000
         LTR   ODDACC,ODDACC           IF SCALING CONSTANTS HAVE        55080000
         BZ    SCINT                   CHANGED, REEVALUATE              55140000
SCALE1   TM    MODE,X'10'              CHECK MODE                       55200000
         BZ    FXSCL                   INTEGER                          55260000
*                                                                       55320000
         LE    FPACC,XALTER(PARLIST)   MULTIPLY COORDINATE AND          55380000
         ME    FPACC,U(PARLIST)        MULTIPLICATIVE CONSTANT          55440000
         AE    FPACC,XCON(PARLIST)     ADD ADDITIVE CONSTANT            55500000
         STE   FPACC,OPTIMSV(PARLIST)  STORE SCALED VALUE               55560000
FIXVAL   ST    PARLIST,0(SAVEREG)      PRESERVE POINTER                 55620000
         LA    PARLIST,OPTIMSV(PARLIST)                                 55680000
         BAL   RETREG,FIX              CONVERT COORDINATE TO INTEGER    55740000
         L     PARLIST,0(SAVEREG)      GET POINTER                      55800000
         LTR   ENTREG,ENTREG                                            55860000
         BZ    VTEST                                                    55920000
         L     SAVEREG,4(SAVEREG)      ERROR(S) IN CONVERSION           55980000
         RETURN (14,12),RC=(15)        IMMEDIATE RETURN                 56040000
*                                                                       56100000
FXSCL    L     ODDACC,XALTER(PARLIST)  SCALE POINT                      56160000
         M     EVNACC,U(PARLIST)       USING                            56220000
         SRDA  EVNACC,12               INTEGER                          56280000
         A     ODDACC,XCON(PARLIST)    ARITMETIC                        56340000
         ST    ODDACC,OPTIMSV(PARLIST) AND STORE                        56400000
VTEST    LTR   PARLIST,PARLIST         IF NON-ZERO,                     56460000
         BC    7,GETERM                EXIT                             56520000
*                                                                       56580000
         MVC   MODE(1),VMODE           SET UP VALUES FOR                56640000
         LA    PARLIST,4               V-Y VALUES                       56700000
         B     GETLOOP                                                  56760000
SKPSC    L     ODDACC,U(PARLIST)       SET COORDINATE = UNSCALED        56820000
         ST    ODDACC,OPTIMSV(PARLIST) VALUE                            56880000
         TM    MODE,X'10'              CONVERT TO INTEGER               56940000
         BO    FIXVAL                  IF NECESSARY                     57000000
         B     VTEST                                                    57060000
SCINT    TM    MODE,X'10'              CHECK MODE                       57120000
         BO    FLTSCALE                CALL                             57180000
FIXSCALE L     ACC,GX2(PARLIST)        COMPUTE FIFFERENCE OF            57240000
         S     ACC,GX1(PARLIST)        GRID LIMITS                      57300000
         L     ACC1,SX2(PARLIST)       COMPUTE DIFFERENCE OF            57360000
         S     ACC1,SX1(PARLIST)       SCREEN LIMITS                    57420000
         L     ACC2,DX2(PARLIST)       COMPUTE DIFFERENCE OF            57480000
         S     ACC2,DX1(PARLIST)       DATA LIMITS                      57540000
         BC    12,RC16                 ILLEGAL DATA LIMITS              57600000
*                                                                       57660000
         L     ODDACC,FOURK            GET CONSTANT                     57720000
         MR    EVNACC,ACC              MULTIPLY BY GRID DIFFERENCE      57780000
         SLDA  EVNACC,12               SCALE TO PERMIT CONSTANTS        57840000
*                                      LESS THAN 1                      57900000
         DR    EVNACC,ACC1             DIVIDE BY DIFFERENCE IN SCREEN   57960000
         LR    EVNACC,ODDACC           AND DATA LIMITS                  58020000
         SRDA  EVNACC,32                                                58080000
         DR    EVNACC,ACC2                                              58140000
         ST    ODDACC,XALTER(PARLIST)  STORE MULTIPLICATIVE CONSTANT    58200000
*                                                                       58260000
         LR    ODDACC,ACC              COMPUTE 4095(GX2-GX1)            58320000
         M     EVNACC,FOURK                                             58380000
         SLDA  EVNACC,16               SCALE TO IMPROVE ACCURACY        58440000
         DR    EVNACC,ACC1             DIVIDE BY SX2-SX1                58500000
         M     EVNACC,DX1(PARLIST)     GET REST OF NUMERATOR            58560000
         SRDA  EVNACC,16               REMOVE SCALING FACTOR            58620000
         DR    EVNACC,ACC2             DIVIDE BY DX2-DX1                58680000
         ST    ODDACC,DELTAX           STORE COMPLETED TERM             58740000
*                                                                       58800000
         L     ODDACC,GX1(PARLIST)     COMPUTE GX1-SX1                  58860000
         S     ODDACC,SX1(PARLIST)                                      58920000
         M     EVNACC,FOURK            COMPUTE 4095(GX1-SX1)            58980000
         DR    EVNACC,ACC1             FINISH COMPUTATION OF TERM       59040000
         S     ODDACC,DELTAX           COMPUTE FULL ADDITIVE SONSTANT   59100000
         ST    ODDACC,XCON(PARLIST)    AND STORE IT                     59160000
         B     SCALE1                              ROUTINE              59220000
FLTSCALE LE    FPACC,GX2(PARLIST)      COMPUTE  G2-G1                   59280000
         SE    FPACC,GX1(PARLIST)                                       59340000
         LE    FPACC1,SX2(PARLIST)     COMPUTE  S2-S1                   59400000
         SE    FPACC1,SX1(PARLIST)                                      59460000
         LE    FPACC2,DX2(PARLIST)     COMPUTE  D2-D1                   59520000
         SE    FPACC2,DX1(PARLIST)                                      59580000
         BC    12,RC16                 ILLEGAL DATA LIMITS              59640000
*                                                                       59700000
         LE    FPACC3,FOURKE           GET CONSTANT (4096)              59760000
         MER   FPACC3,FPACC            MULTIPLY BY DIFFERENCE IN        59820000
*                                      GRID LIMITS                      59880000
         DER   FPACC3,FPACC1           DIVIDE BY DIFFERENCE IN SCREEN   59940000
*                                      LIMITS                           60000000
         DER   FPACC3,FPACC2           DIVIDE BY DIFFERENCE IN DATA     60060000
*                                      LIMITS                           60120000
         STE   FPACC3,XALTER(PARLIST)  STORE MULTIPLICATIVE CONSTANT    60180000
*                                                                       60240000
         LE    FPACC3,GX1(PARLIST)     COMPUTE G1-S1                    60300000
         SE    FPACC3,SX1(PARLIST)                                      60360000
         MER   FPACC3,FPACC2           COMPUTE (G1-S1)(D2-D1)           60420000
         ME    FPACC,DX1(PARLIST)      COMPUTE (D1)(G2-G1)              60480000
         SER   FPACC3,FPACC            COMPUTE VARIABLE PART OF         60540000
*                                      NUMERATOR                        60600000
         ME    FPACC3,FOURKE           COMPUTE COMPLETE NUMERATOR       60660000
         DER   FPACC3,FPACC1           DIVIDE BY DIFFERENCES IN SCREEN  60720000
         DER   FPACC3,FPACC2           AND DATA DIFFERENCES             60780000
         STE   FPACC3,XCON(PARLIST)    STORE ADDITIVE CONSTANT          60840000
*                                                                       60900000
         B     SCALE1                              SCALING CONSTANTS    60960000
*                                                                       61020000
GETERM   MVC   DELTAX(8),OPTIMSV       GET NEW COORDINATES              61080000
         L     SAVEREG,4(SAVEREG)      GET POINTER TO SAVE AREA         61140000
         RETURN (14,12),RC=0                                            61200000
*                                                                       61260000
*        ILLEGAL DATA LIMITS                                            61320000
RC16     L     SAVEREG,4(SAVEREG)      GET POINTER TO SAVE AREA         61380000
         RETURN (14,12),RC=16                                           61440000
*                                                                       61500000
FOURK    DC    F'4095'                                                  61560000
FOURKE   DC    E'4095'                                                  61620000
BEAM     DC    X'0FFFFFFF'                                              61680000
*                                                                       61740000
FIX      SAVE  (14,12)                                                  61800000
         SR    ENTREG,ENTREG                                            61860000
         L     ODDACC,0(PARLIST)       GET MANTISSA OF NUMBER           61920000
         N     ODDACC,MANTISSA         TO BE CONVERTED                  61980000
         LH    EVNACC,0(PARLIST)       GET CHARACTERISTIC OF            62040000
         N     EVNACC,CHAR             NUMBER TO BE CONVERTED           62100000
         BZ    RC12                    IF ZERO, CHECK FOR ZERO MANTISSA 62160000
         SRA   EVNACC,6                                                 62220000
         SH    EVNACC,H256             SEE IF NUMBER CAN BE CONVERTED   62280000
         BC    12,UNDERFLO             NO, EXPONENT LESS THAN 0         62340000
         CH    EVNACC,H32                                               62400000
         BH    OVERFLOW                NO, EXPONENT GREATER THAN 8      62460000
         BE    POSOVER                 OVERFLOW POSSIBLE ON CONVERSION  62520000
         SH    EVNACC,H24              GET SHIFT COUNT FOR MANTISSA     62580000
         BP    LFTSHIFT                POSITIVE, SHIFT LEFT             62640000
         LPR   EVNACC,EVNACC           NEGATIVE, CONVERT TO PROPER      62700000
         SRA   ODDACC,0(EVNACC)        SHIFT COUNT AND SHIFT RIGHT      62760000
SIGN     TM    0(PARLIST),X'80'        NUMBER TO BE CONVERTED NEGATIVE  62820000
         BZ    STFIXED                 NO, JUST STORE IT                62880000
         LNR   ODDACC,ODDACC           YES, COMPLEMENT IT               62940000
STFIXED  ST    ODDACC,0(PARLIST)                                        63000000
         RETURN (14,12),RC=(15)                                         63060000
*                                                                       63120000
LFTSHIFT SLA   ODDACC,0(EVNACC)        SHIFT MANTISSA LEFT              63180000
         B     SIGN                    CHECK SIGN                       63240000
*                                                                       63300000
UNDERFLO SR    ODDACC,ODDACC           SET NUMBER TO 0                  63360000
         B     STFIXED                                                  63420000
*                                                                       63480000
POSOVER  TM    1(PARLIST),X'80'        HIGH-ORDER BIT OF MANTISSA=1     63540000
         BZ    LFTSHIFT                NO, OVERFLOW WILL NOT OCCUR ON   63600000
*                                      CONVERSION                       63660000
OVERFLOW SR    ODDACC,ODDACC           SET NUMBER =0                    63720000
         LA    ENTREG,16               SET RETURN CODE                  63780000
         B     STFIXED                                                  63840000
*                                                                       63900000
RC12     LTR   ODDACC,ODDACC           IF MANTISSA                      63960000
         BZ    UNDERFLO                IS NON-ZERO                      64020000
         LA    ENTREG,12               SET RETURN CODE                  64080000
         B     UNDERFLO                                                 64140000
H24      DC    H'24'                                                    64200000
H32      DC    H'32'                                                    64260000
H256     DC    H'256'                                                   64320000
         DS    0F                                                       64380000
CHAR     DC    X'00007F00'             MASK FOR CHARACTERISTIC          64440000
MANTISSA DC    X'00FFFFFF'             MASK FOR MANTISSA                64500000
DISPLACE SAVE  (14,12)                 SAVE GENERAL REGISTERS           64560000
*                                                                       64620000
*   DO NOT SET UP SAVE AREA SINCE LOWESR LEVEL SUBROUTINE               64680000
*                                                                       64740000
         LA    ABIND,WRKAR             GET ADDRESS OF TEMPORARY         64800000
         LH    INCIND,ABSPTS           ORDER STORAGE AREAS              64860000
         MH    INCIND,H4                                                64920000
         AR    INCIND,ABIND                                             64980000
         LH    COUNT,ABSPTS            GET NO. OF ABSOLUTE VECTORS      65040000
         XC    INCPTS(2),INCPTS        SET NO. OF INCREMENTAL PTS.=0    65100000
         LTR   COUNT,COUNT             NO ABSOLUTE VECTORS,             65160000
         BZ    DISPRET                 GENERATE NO INCREMENTAL          65220000
         LA    EVNACC,CURMOD           GET NUMBER OF AVAILABLE BYTES    65280000
         SR    EVNACC,INCIND           IN THE WORK AREA                 65340000
         SRA   EVNACC,1                AND NUMBER OF INCREMENTAL        65400000
*                                      VECTORS THAT WILL FIT            65460000
         STH   EVNACC,BTCNT            AND STORE                        65520000
*                                                                       65580000
*   COMPUTE DISPLACEMENT TO NEXT POINT                                  65640000
*                                                                       65700000
NEXT     LH    EVNACC,XP               CURRENT X                        65760000
         N     EVNACC,REDUCE           ELIMINATE LOW-ORDE 2 BITS        65820000
         LH    ODDACC,0(ABIND)         NEXT X                           65880000
         N     ODDACC,HALFBEAM         ELIMINATE BEAM BIT               65940000
         SR    ODDACC,EVNACC           GET X-DISPLACEMENT               66000000
         ST    ODDACC,DELTAX           AND STORE                        66060000
*                                                                       66120000
         LH    EVNACC,YP               CURRENT Y                        66180000
         N     EVNACC,REDUCE           ELININATE LOW-ORDER 2 BITS       66240000
         LH    ODDACC,2(ABIND)         NEXT Y                           66300000
         SR    ODDACC,EVNACC           GET Y-DISPLACEMENT               66360000
         ST    ODDACC,DELTAY           AND STORE                        66420000
*                                                                       66480000
*                                                                       66540000
SPLITU   L     EVNACC,DELTAX           GET MAGNITUDE OF                 66600000
         LPR   MAGDELX,EVNACC          X-DISPLACEMENT                   66660000
         L     ODDACC,DELTAY           GET MAGNITUDE OF                 66720000
         LPR   MAGDELY,ODDACC          Y-DISPLACEMENT                   66780000
         CR    MAGDELX,MAGDELY                                          66840000
         BL    YHIU                    Y GREATER                        66900000
         BE    XEQYU                   EQUAL                            66960000
*                                      X GREATER                        67020000
         TM    DELTAX,X'80'            SEE IF DELTAX NEGATIVE           67080000
         BO    XHIN                                                     67140000
         LA    DELX,252                NO, ASSUME = 252 FOR STEP        67200000
         LA    ODDACC,252                                               67260000
         B     XHIUC                                                    67320000
XHIN     LH    DELX,LOWLIM             DELTAX NEGATIVE, ASSUME = -256   67380000
         LH    ODDACC,LOWLIM                                            67440000
XHIUC    M     EVNACC,DELTAY           GET Y DISPLACEMENT FOR STEP      67500000
         D     EVNACC,DELTAX                                            67560000
         LR    DELY,ODDACC             SAVE Y DISPLACEMENT              67620000
*                                                                       67680000
NOXS     L     EVNACC,DELTAX           GET NUMBER OF VECTORS            67740000
         SRDA  EVNACC,32               WITH LENGTH DELX                 67800000
         DR    EVNACC,DELX             TO DISPLAY ONE WITH              67860000
         LR    NINC,ODDACC             LENGTH DELTAX                    67920000
*                                                                       67980000
REMU     L     RX,DELTAX               COMPUTE X-DISPLACEMENT           68040000
         LR    ODDACC,DELX             REMAINING AFTER FIXED            68100000
         MR    EVNACC,NINC             LENGTH VECTORS USED              68160000
         SR    RX,ODDACC                                                68220000
*                                                                       68280000
         L     RY,DELTAY               COMPUTE Y-DISPLACEMENT           68340000
         LR    ODDACC,DELY             REMAINING AFTER                  68400000
         MR    EVNACC,NINC             OTHER VECTORS USED               68460000
         SR    RY,ODDACC                                                68520000
*                                                                       68580000
         SR    ERRX,ERRX               SET BOTH ERRORS                  68640000
         SR    ERRY,ERRY               TO ZERO                          68700000
*                                                                       68760000
CONVRTU  CH    NINC,BTCNT              MORE VECTORS NECESSARY THAN      68820000
*                                      WILL FIT INTO THE WORKAREA       68880000
         BNL   WRKOVER                 PREPARE FOR WORKAREA OVERFLOW    68940000
         LA    ACC,1                   ADD N+1                          69000000
         AH    ACC,INCPTS              TO NUMBER                        69060000
         AR    ACC,NINC                OF INCREMENTAL                   69120000
         STH   ACC,INCPTS              DATA POINTS                      69180000
         LTR   NINC,NINC               ONLY ONE INCREMENTAL VECTOR      69240000
         BZ    LASTSEG                 YES                              69300000
*                                                                       69360000
CNVRTLPU AR    ERRX,DELX               ADD CUMULATIVE ERROR TO          69420000
         L     ACC,REDUCE              X-DISPLACEMENT.                  69480000
         NR    ACC,ERRX                ELIMINATE LOW-ORDER 2 BITS       69540000
         SR    ERRX,ACC                GET ERROR FROM THIS STEP         69600000
         SRA   ACC,1                   CONVERT X-DISPLACEMENT           69660000
         STC   ACC,0(INCIND)           TO INCREMENTAL DATA FROM         69720000
         OI    0(INCIND),X'01'         AND STORE                        69780000
*                                                                       69840000
         AR    ERRY,DELY               ADD CUMULATIVE ERROR TO          69900000
         L     ACC,REDUCE              Y-DISPLACEMENT                   69960000
         NR    ACC,ERRY                ELIMINATE LOW-ORDER 2 BITS       70020000
         SR    ERRY,ACC                GET ERROR FROM THIS STEP         70080000
         SRA   ACC,1                   CONVERT Y-DISPLACEMENT TO        70140000
         STC   ACC,1(INCIND)           INCREMENTAL DATA FORM & STORE    70200000
         TM    0(ABIND),X'40'          IF ABSOLUTE VECTOR               70260000
         BO    BLNKPT                  BLANKED, BLANK                   70320000
         TM    PTSGSW,X'10'            BLANK BEAM                       70380000
         BO    UPDTU                   IF POINT PLOT                    70440000
BLNKPT   OI    1(INCIND),X'01'         REQUESTED                        70500000
*                                                                       70560000
UPDTU    LA    INCIND,2(INCIND)        INCREMENT POINTER TO WORKAREA    70620000
         BCT   NINC,CNVRTLPU           PROCESS NEXT SEGMENT             70680000
*                                                                       70740000
LASTSEG  AR    ERRX,RX                 LAST SEGMENT-ADD CUMULATIVE      70800000
         L     ACC,REDUCE              ERROR TO X-REMAINDER             70860000
         NR    ACC,ERRX                ELIMINATE LOW-ORDER 2 BITS       70920000
         SRA   ACC,1                   CONVERT TO INCREMENTAL DATA      70980000
         STC   ACC,0(INCIND)           FORM AND STORE                   71040000
         OI    0(INCIND),X'01'                                          71100000
*                                                                       71160000
         AR    ERRY,RY                 ADD CUMULATIVE ERROR TO          71220000
         L     ACC,REDUCE              Y-REMAINDER                      71280000
         NR    ACC,ERRY                ELIMINATE LOW-ORDER 2 BITS       71340000
         SRA   ACC,1                   CONVERT TO INCREMENTAL DATA FORM 71400000
         STC   ACC,1(INCIND)           & STORE WITH BEAM INTENSIFIED    71460000
         TM    0(ABIND),X'40'          IF ABSOLUTE VECTOR               71520000
         BZ    ENDTEST                 BLANKED, BLANK                   71580000
         OI    1(INCIND),X'01'         INCREMENTAL                      71640000
*                                                                       71700000
ENDTEST  MVC   XP(4),0(ABIND)          UPDATE PHYSICAL BEAM POSITION    71760000
         NI    XP,X'0F'                TURN OFF BEAM BIT                71820000
         LA    INCIND,2(INCIND)        INCREMENT                        71880000
         LA    ABIND,4(ABIND)                    POINTERS               71940000
         BCT   COUNT,NEXT              BRANCH BACK IF NOT FINISHED      72000000
*                                      AND GO THROUGH THE LOOP AGAIN    72060000
DISPRET  RETURN (14,12),RC=0           IF FINISHED, RETURN TO CALLING   72120000
*                                      PROGRAM                          72180000
*                                                                       72240000
*   ROUTINE TO SPLIT VECTOR INTO SMALLER ONES-UNBLANKED                 72300000
*                                                                       72360000
YHIU     TM    DELTAY,X'80'            SEE IF DELTAY NEGATIVE           72420000
         BO    YHIN                                                     72480000
         LA    DELY,252                NO, ASSUME = 252 FOR STEP        72540000
         LA    ODDACC,252                                               72600000
         B     YHIUC                                                    72660000
YHIN     LH    DELY,LOWLIM             DELTAY NEGATIVE, ASSUME = -256   72720000
         LH    ODDACC,LOWLIM           FOR STEP                         72780000
*                                                                       72840000
YHIUC    M     EVNACC,DELTAX           GET X-DISPLACEMENT FOR STEP      72900000
         D     EVNACC,DELTAY                                            72960000
         LR    DELX,ODDACC             AND SAVE IT                      73020000
         L     EVNACC,DELTAY           GET NUMBER OF                    73080000
         SRDA  EVNACC,32               FIXED-LENGTH                     73140000
         DR    EVNACC,DELY             VECTORS TO BE                    73200000
         LR    NINC,ODDACC             DISPLAYED                        73260000
*                                                                       73320000
         B     REMU                                                     73380000
*                                                                       73440000
XEQYU    LA    DELX,252                ASSUME DISPLACEMENTS OF          73500000
         LA    DELY,252                252 MAGNITUDE                    73560000
         TM    DELTAX,X'80'            IF DELTAX IS NAGATIVE,           73620000
         BZ    XEQU                                                     73680000
         LNR   DELX,DELX               MAKE DELX NEGATIVE               73740000
*                                                                       73800000
XEQU     TM    DELTAY,X'80'            GET SIGN OF DELTAY               73860000
         BZ    YEQU                    AND ADJUST SIGN OF DISPLACEMENT  73920000
         LNR   DELY,DELY               TO AGREE                         73980000
*                                                                       74040000
YEQU     B     NOXS                                                     74100000
*                                                                       74160000
WRKOVER  RETURN (14,12),RC=36                                           74220000
*                                                                       74280000
         DS    0F                                                       74340000
REDUCE   DC    X'FFFFFFFC'                                              74400000
HALFBEAM DC    X'00000FFF'                                              74460000
SGCHECK  SAVE  (14,12)                                                  74520000
         LR    PARBASE,ACC             ADDRESSABILITY FOR PARAMETERS    74580000
         USING SGPAR,PARBASE                                            74640000
*                                                                       74700000
         LA    PARLIST,SVAR2           CHAIN SAVE                       74760000
         ST    SAVEREG,4(PARLIST)                 AREAS                 74820000
         ST    PARLIST,8(SAVEREG)                                       74880000
         LR    SAVEREG,PARLIST                                          74940000
*                                                                       75000000
         MVI   MODE,X'C0'              SAVE FLAGS,                      75060000
         NC    MODE(1),PTPOS           IF ANY                           75120000
         IC    PARLIST,PTPOS           SET POSITION OF                  75180000
         SRL   PARLIST,3               INITIAL POINT OF VECTOR          75240000
         STC   PARLIST,PTPOS           EQUAL TO POSITION OF             75300000
         NI    PTPOS,X'07'             TERMINAL POINT OF LAST VECTOR    75360000
         OC    PTPOS(1),MODE           RESTORE FLAG                     75420000
*                                                                       75480000
         LM    EVNACC,ODDACC,NXTX      GET NEXT POINT                   75540000
         STM   EVNACC,ODDACC,PT2X      STORE IN DATA AREA FOR           75600000
*                                      SCISSORING ROUTINE               75660000
*                                                                       75720000
         CH    EVNACC,X1               X VALUE WITHIN GRID              75780000
         BL    XSCR                    NO                               75840000
         CH    EVNACC,X2               MAYBE                            75900000
         BH    XSCR                    NO                               75960000
         CH    ODDACC,Y1               Y VALUE WITHIN GRID              76020000
         BL    YSCR                    NO                               76080000
         CH    ODDACC,Y2               MAYBE                            76140000
         BH    YSCR                    NO                               76200000
         OI    PTPOS,X'08'             POINT WITHIN GRID                76260000
         B     TEST                                                     76320000
*                                                                       76380000
XSCR     CH    EVNACC,ZERO             X VALUE WITHIN SCREEN            76440000
         BL    OFFSCR                  NO                               76500000
         CH    EVNACC,ZERO+4           MAYBE                            76560000
         BH    OFFSCR                  NO                               76620000
YSCR     CH    ODDACC,ZERO             Y VALUE WITHIN SCREEN            76680000
         BL    OFFSCR                  NO                               76740000
         CH    ODDACC,ZERO+4           MAYBE                            76800000
         BH    OFFSCR                  NO                               76860000
         OI    PTPOS,X'10'             POINT BETWEEN SCREEN & GRID      76920000
         B     TEST                                                     76980000
*                                                                       77040000
OFFSCR   OI    PTPOS,X'20'             POINT OFF- SCREEN                77100000
*                                                                       77160000
TEST     TM    PTPOS,X'07'             CALL JUST TO SET SWITCHES        77220000
         BZ    GETOUT                  FOR INITIAL POINT-- EXIT         77280000
*                                                                       77340000
         TM    PTSGSW,X'10'            POINT PLOT                       77400000
         BZ    PTPLTCHK                YES - CHECK IT                   77460000
         TM    PTPOS,X'09'             VECTOR PLOT- BOTH POINTS         77520000
         BO    ONEPLOT                 WITHIN GRID, ADJUSTED X,Y VALUES 77580000
*                                      = INPUT VALUES                   77640000
         TM    PTSGSW,X'02'            SHOW ALL POINTS IN SCREEN        77700000
         BZ    GRDSCIS                 NO                               77760000
         TM    PTPOS,X'24'             YES. BOTH POINTS ON SCREEN       77820000
         BZ    ONEPLOT                 YES, PLOT VECTOR                 77880000
         MVI   MODE,X'04'              MASKS FOR PT1                    77940000
         MVI   MODE+1,X'20'            AND PT2 OUTSIDE BOUNDARY         78000000
         LA    PARLIST,ZERO            BOUNDARY                         78060000
         B     SCRTSTA                                                  78120000
*                                                                       78180000
GRDSCIS  MVI   MODE,X'06'              MASKS FOR PT1                    78240000
         MVI   MODE+1,X'30'            AND PT2 OUTSIDE BOUNDARY         78300000
         LA    PARLIST,X1              BOUNDARY                         78360000
SCRTSTA  TM    BV21,X'FF'              INCREMENTAL POSITIONING          78420000
         BO    SPTST                   CONFINE TERMINATION TESTS        78480000
*                                      TO SECOND VECTOR ONLY            78540000
         TM    PTPOS,X'24'             EITHER POINT OFF SCREEN          78600000
         BZ    GRDTSTA                 NO, TEST FOR GRID TERMINATION    78660000
SCRTST   TM    PTSGSW,X'08'            TERMINATE IF SCREEN EXCEEDED     78720000
         BO    SCRNTERM                YES                              78780000
*                                                                       78840000
*                                      TO SECOND POINT ONLY             78900000
GRDTSTA  TM    BV21,X'FF'              INCREMENTAL POSITIONING          78960000
         BO    SPTST2                  YES, CONFINE TERMINATION TESTS   79020000
GRDTST   TM    PTSGSW,X'04'            TERMINATE IF GRID EXCEEDED       79080000
         BO    GRIDTERM                YES                              79140000
GRDTSTB  ST    PARLIST,SABL            STORE POINTER TO BOUNDARY        79200000
*                                                                       79260000
         MVC   PT1X(8),X               PREVIOUS POINT                   79320000
*                                                                       79380000
         LOAD  EP=GOFFSG               LOAD OFF SCREEN/OFF GRID ROUTINE 79440000
         LR    ENTREG,ACC              GET ADDRESS OF ENTRY POINT       79500000
         LA    PARLIST,SABL            POINTER TO PARAMETER LIST        79560000
         CALL  (15)                    CALL IT                          79620000
         DELETE EP=GOFFSG                                               79680000
*                                                                       79740000
         L     EVNACC,NI               GET NUMBER OF INTERSECTIONS      79800000
         CH    EVNACC,H1                                                79860000
         BE    ONEINTS                 ONE                              79920000
         BH    TWOINTS                 TWO                              79980000
         IC    EVNACC,MODE+1           ZERO- IS END POINT ON BOUNDARY   80040000
         EX    EVNACC,TSTPOS                                            80100000
         BC    7,SUPRESS               NO, SUPRESS PLOT                 80160000
ONEPLOTB MVC   ADJX1(2),PT2X+2         YES, POSITION BEAM               80220000
         MVC   ADJY1(2),PT2Y+2                                          80280000
         MVI   BV1,X'FF'               BLANK BEAM                       80340000
         B     ONEPLT                                                   80400000
*                                                                       80460000
ONEINTS  IC    EVNACC,MODE             FIRST POINT IN BOUNDARY          80520000
         EX    EVNACC,TSTPOS                                            80580000
         BZ    ONEPLOTS                YES                              80640000
         IC    EVNACC,MODE+1           NO. SECOND POINT IN BOUNDARY     80700000
         EX    EVNACC,TSTPOS                                            80760000
         BC    7,SUPRESS               NO, SUPPRESS PLOT                80820000
         MVC   ADJX1(4),INTS1X         POSITION TO INTERSECTION         80880000
         MVC   ADJX2(2),PT2X+2         DRAW TO SECOND POINT             80940000
         MVC   ADJY2(2),PT2Y+2                                          81000000
TWOPLT   MVI   PTCNT,X'FF'             TWO VECTORS                      81060000
         MVI   BV1,X'FF'               FIRST ONE BLANKED                81120000
         MVI   SUPLT,X'00'             ALLOW PLOT                       81180000
         B     GETOUT                                                   81240000
*                                                                       81300000
ONEPLOTS MVC   ADJX1(4),INTS1X         PLOT TO POINT OF INTERSECTION    81360000
         MVI   BV1,X'00'               UNBLANKED                        81420000
         TM    PTSGSW,X'02'            SCISSORING AT GRID               81480000
         BZ    RC44                    YES                              81540000
         B     RC48                    NO                               81600000
*                                                                       81660000
TWOINTS  MVC   ADJX1(8),INTS1X         PLOT FROM FIRST TO SECOND        81720000
         B     TWOPLT                  INTERSECTION POINTS              81780000
*                                                                       81840000
ONEPLOT  MVC   ADJX1(2),PT2X+2         MOVE INPUT DATA INTO             81900000
         MVC   ADJY1(2),PT2Y+2         OUTPUT LOCATION                  81960000
         MVI   BV1,X'00'               UNBLANKED                        82020000
ONEPLT   MVI   SUPLT,X'00'             PERMIT PLOT                      82080000
         MVI   PTCNT,X'0F'             OF ONE POINT                     82140000
GETOUT   L     SAVEREG,4(SAVEREG)      RETURN TO CALLING                82200000
         RETURN (14,12),RC=0           ROUTINE                          82260000
*                                                                       82320000
SPTST    TM    PTPOS,X'20'             SECOND POINT OFF SCREEN          82380000
         BO    SCRTST                  TEST FOR OFF SCREEN TERMINATION  82440000
SPTST2   TM    PTPOS,X'30'             SECOND POINT OFF GRID            82500000
         BO    GRDTST                  TEST FOR OFF GRID TERMINATION    82560000
         B     GRDTSTB                 NO, SCISSOR BUT DO NOT END       82620000
TSTPOS   TM    PTPOS,X'00'             TEST POINT POSITION SWITCH       82680000
*                                                                       82740000
GRIDTERM L     SAVEREG,4(SAVEREG)      IMMEDIATE TERMINATION IF GRID    82800000
         RETURN (14,12),RC=28          LIMITS EXCEEDED                  82860000
*                                                                       82920000
SCRNTERM L     SAVEREG,4(SAVEREG)      IMMEDIATE TERMINATION IF SCREEN  82980000
         RETURN (14,12),RC=32          LIMITS EXCEEDED                  83040000
*                                                                       83100000
RC44     CLC   RETCD(2),ZERO           IF NOT FIRST ERROR DETECTED,     83160000
         BE    RC44A                                                    83220000
         MVI   RETCD,X'80'             SET HIGH ORDER BIT OF RC         83280000
RC44A    MVI   RETCD+1,44              SET RETURN CODE IN WORKAREA=44   83340000
         B     ONEPLT                                                   83400000
*                                                                       83460000
RC48     CLC   RETCD(2),ZERO           IF NOT FIRST ERROR DETECTED      83520000
         BE    RC48A                                                    83580000
         MVI   RETCD,X'80'             SET HIGH-ORDER BIT OF RC         83640000
RC48A    MVI   RETCD+1,48              SET RETURN CODE IN WORKAREA=48   83700000
         B     ONEPLT                                                   83760000
PTPLTCHK MVC   ADJX1(2),NXTX+2         SET UP COORDINATES OF POINT      83820000
         MVC   ADJY1(2),NXTY+2                                          83880000
         TM    PTPOS,X'08'             POINT WITHIN GRID                83940000
         BO    ONEPLOT                 PLOT IT AS IS                    84000000
         TM    PTSGSW,X'04'            TERMINATE IF                     84060000
         BO    GRIDTERM                GRID LIMITS EXCEEDED             84120000
         TM    PTPOS,X'10'             POINT BETWEEN SCREEN AND GRID    84180000
         BZ    PTOFFSCR                NO- OFF SCREEN                   84240000
         TM    PTSGSW,X'02'            YES. PLOT ALL POINTS ON SCREEN   84300000
         BO    ONEPLOT                 YES.                             84360000
         B     SUPRESS                 NO. SUPPRESS PLOT                84420000
*                                                                       84480000
PTOFFSCR TM    PTSGSW,X'08'            TERMINATE IF SCREEN LIMITS       84540000
         BO    SCRNTERM                EXCEEDED                         84600000
SUPRESS  MVI   SUPLT,X'FF'             SUPRESS PLOT OF POINT            84660000
         MVI   PTCNT,X'00'             SET POINT COUNT =0               84720000
         MVI   ABSPTS,X'00'            SET ABSOLUTE POINT COUNT =0      84780000
         B     GETOUT                                                   84840000
*                                                                       84900000
*                                                                       84960000
*                                                                       85020000
ZERO     DC    H'0,0'                  SCREEN LIMITS- LOWER LEFT CORNER 85080000
         DC    H'4095,4095'              -UPPER RIGHT CORNER            85140000
H1       DC    H'1'                                                     85200000
H2       DC    H'2'                                                     85260000
H3       DC    H'3'                                                     85320000
H4       DC    H'4'                                                     85380000
H5       DC    H'5'                                                     85440000
HILIM    DC    H'255'                  MAXIMUM POSITIVE INCREMENT       85500000
LOWLIM   DC    H'-256'                 MAXIMUM NEGATIVE INCREMENT       85560000
GEPM     DC    X'2A00'                 SET MODE ABSOLUTE POINT          85620000
GEVM     DC    X'2A02'                 SET MODE ABSOLUTE VECTOR         85680000
GEPI2    DC    X'2A04'                 SET MODE INCREMENTAL POINT       85740000
GEVI2    DC    X'2A05'                 SET MODE INCREMENTAL VECTOR      85800000
         END                                                            85860000
