* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00020000
*                                                                     * 00040000
*TITLE 'BASIC BUFFER MANAGEMENT  -  IGC0007A LOAD 1    ASSIGN/RELEASE * 00060000
*                                                                     * 00080000
*STATUS: CHANGE LEVEL 0                                               * 00100000
*                                                                     * 00120000
*FUNCTION/OPERATION: CONTROLS ASSIGNMENT AND RELEASE OF BUFFER STORAGE* 00140000
*                                                                     * 00160000
*   IN THE BUFFERED 2250,MODEL 1, AND IN THE 2840 DISPLAY CONTROL USED* 00180000
*                                                                     * 00200000
*   BY THE 2250, MODEL 2.                                             * 00220000
*                                                                     * 00240000
*ENTRY POINTS: IGC0007A - VIA AN SVC IN BUFFER MANAGEMENT MACROS      * 00260000
*                                                                     * 00280000
*INPUT: ADDRESS OF PARAMETER LIST BUILT BY MACROS IN REGISTER 1       * 00300000
*                                                                     * 00320000
*OUTPUT: RETURN CODES IN REGISTER 15                                  * 00340000
*                                                                     * 00360000
*              00 = REQUEST FULFILLED                                 * 00380000
*                                                                     * 00400000
*              04 = REQUEST AMT EXCEEDS AVAILABLE AMT (ASGNBFR ONLY)  * 00420000
*                                                                     * 00440000
*              08 = CONTIGUOUS STORAGE NOT AVAILABLE (ASGNBFR ONLY)   * 00460000
*                                                                     * 00480000
*              0C = INVALID/UNOPENED DCB                              * 00500000
*                                                                     * 00520000
*              10 = ATTEMPT TO RELEASE ANOTHER'S BUFFER STORAGE       * 00540000
*                                                                     * 00560000
*              14 = BUFFER RESTART ADDRESS NO LONGER VALID(RLSEBFR)   * 00580000
*                                                                     * 00600000
*              18 = BUFPRAM INVALID (ASGNBFR AND RLSEBFR)             * 00620000
*                                                                     * 00640000
*EXTERNAL ROUTINES: N/A                                               * 00660000
*                                                                     * 00680000
*EXITS-NORMAL: VIA AN SVC                                             * 00700000
*                                                                     * 00720000
*     -ERROR:  ABEND                                                  * 00740000
*                                                                     * 00760000
*TABLES/WORKAREAS: BUFFER TABLES BUILT AT SYSGEN TIME IN PROTECTED    * 00780000
*                                                                     * 00800000
*   CORE FOR EACH BUFFERED 2250 MODEL 1 AND EACH 2840 CONTROL UNIT.   * 00820000
*                                                                     * 00840000
*ATTRIBUTES: SUPERVISOR MODE, SERIALLY REUSEABLE                      * 00860000
*                                                                     * 00880000
*NOTES: N/A                                                           * 00900000
*                                                                     * 00920000
* * * * * * * * * * * * * * *  * * * * * * * * * * * * * * * * * * *  * 00940000
RX       EQU   0                                                        00960000
RY       EQU   1                                                        00980000
RZ       EQU   2                                                        01000000
RA       EQU   3                                                        01020000
RB       EQU   4                                                        01040000
RC       EQU   5                                                        01060000
RD       EQU   6                                                        01080000
RE       EQU   7                                                        01100000
RUCB     EQU   8                                                        01120000
RDCB     EQU   9                                                        01140000
RBFTBL   EQU   10                       BUFFER TABLE DSECT REGISTER     01160000
RDSECT   EQU   11                       PARAM LIST DSECT REGISTER       01180000
RBASE    EQU   12                       CONTROL SECTION BASE REGISTER   01200000
RSAVE    EQU   13                       SAVEAREA REGISTER               01220000
RNSI     EQU   14                       RETURN LINKAGE REGISETER        01240000
RBAL     EQU   15                       LINKAGE REGISTER                01260000
RHOLD    EQU   15                                                       01280000
CVT      EQU   16                                                       01300000
*RETURN CODE EQUATES                                                    01320000
BFRPRM   EQU   24                       X'18'                           01340000
BADADR   EQU   20                       X'14'                           01360000
BADRLS   EQU   16                       X'10'                           01380000
MASK1    EQU   X'FF'                                                    01400000
HEADER   EQU   40                                                       01420000
UNOPEN   EQU   X'0C'                   DCB NOT OPEN              S21016 01421021
BADREQ   EQU   X'1C'                   BAD REQUEST CODE          S21016 01422021
RELNEG   EQU   X'20'                   RELEASE NEGATIVE COUNT    S21016 01423021
NOSECTS  EQU   X'24'                   CONTIG BUFFER UNAVAILABLE S21016 01424021
DCBBAD   EQU   X'28'                   DCB AND IOB DCB NOT EQUAL S21016 01425021
NOTGRPHC EQU   X'2C'                   NON-GRAPHIC DCB           S21016 01426021
BADREL   EQU   X'30'                   RELEASE FOR UNASSIGNED    S21016 01427021
D0       EQU   0                       DISPLACEMENT              S21016 01428021
D8       EQU   8                       DISPLACEMENT              S21016 01429021
RCODE    EQU   7                       RET CODE FOR ERROR MSG MODS21016 01430021
R8       EQU   8                       ADDR EP NAME FOR XCTL     S21016 01431021
*                                                                       01440000
PARLST   DSECT                          DSECT FOR PARAM LIST PASSED     01460000
CODE     DS    CL1                      REQUEST CODE                    01480000
DCBADR   DS    CL3                      DCB-ADDRESS                     01500000
BUFPRM   DS    CL4                      BUFPRAM PTR                     01520000
TABADR   DS    CL4                      TABLE-ADDRESS                   01540000
TABSIZ   DS    CL4                      TABLE SIZE                      01560000
BFRTBL   DSECT                                                          01580000
TBLNGTH  DS    CL2                                                      01600000
NUMDEV   DS    CL2                                                      01620000
EXPBFR   DS    CL2                                                      01640000
TOTAVAIL DS    CL2                                                      01660000
TASGND   DS    CL2                                                      01680000
DISP     DS    CL2                                                      01700000
ZONESZ   DS    CL2                                                      01720000
TG       DS    CL2                                                      01740000
         DS    CL56                                                     01760000
DVCASGND DS    CL128                                                    01780000
IGC0007A CSECT                                                          01800000
*0638,025600-026000                                                JFCA 01810017
*2515,018600-019800,020000                                         TMGA 01815018
* 021200,021800,022200,025600-025800,027200,029000,049400,063200 S21016 01816021
* 063800-064400,065000-065200,077400,085400-085800               S21016 01817021
         BALR  RBASE,RX            ESTABLISH ADDRESSABILITY             01820000
         USING *,RBASE                                                  01840000
         LR    RDSECT,RY           CONSTR PARM LIST DSECT FROM     TMGA 01930018
         USING PARLST,RDSECT            ADDRESS PASSED IN GR1           02020000
         LR    RSAVE,RY            SAVE REG 1 WITH PARAM LIST ADR       02040000
*CHECK DCB FOR VALIDITY AND OPENED                                      02060000
         L     RDCB,CODE                REGY CONTAINS DCB ADDRESS       02080000
         TM    48(RDCB),X'10'           CHECK DCB FOR OPENED CONDITION  02100000
         BZ    ERRDCB1                 ISSUE RET CODE IF NOT OPENS21016 02120021
         L     RZ,28(RDCB)              RZ CONTAINS IOB ADDR,TO CHECK   02140000
         CLC   DCBADR(3),21(RZ)         IOB FOR VALIDITY OF THIS DCB    02160000
         BNE   ERRDCB2                 ISSUE RET CODE-INVALID DCBS21016 02180021
         TM    27(RDCB),X'80'           VALID GAM DCB? IF NOT GO TO ERR 02200000
         BZ    ERRDCB3                 ISSUE RET CODE-INVALID DCBS21016 02220021
*ACCESS UCB                                                             02240000
         L     RUCB,44(RDCB)            RUCB CONTAINS DEB ADR FROM DCB  02260000
         L     RUCB,32(RUCB)            RUCB CONTAINS UCB ADR FROM DEB  02280000
*SET UP BUFFER TABLE DSECT                                              02300000
         L     RBFTBL,36(RUCB)     LOAD BFRTBL ADR FROM UCB             02320000
         LA    RBFTBL,0(RBFTBL)        ELIMINATE DEVNDX                 02340000
         USING BFRTBL,RBFTBL                                            02360000
*CHECK POSITIVELY FOR REQUEST CODE IN PARAM LIST                        02380000
         CLI   CODE,X'04'               IF CODE '04' GO TO ASSIGN SUB-  02400000
         BE    ASSIGN                   ROUTINE                         02420000
         CLI   CODE,X'08'               IF CODE '08' GO TO RELEASE SUB- 02440000
         BE    RELEASE                  ROUTINE                         02460000
         CLI   CODE,X'0C'               IF CODE '0C' GO TO RELEASE ALL  02480000
         BE    XCTLOAD2                           TRANSFER TO LOAD2     02500000
         CLI   CODE,X'10'          IF CODE '10' GO TO BUFINQ SUBROUTINE 02520000
         BE    XCTLOAD2                           TRANSFER TO LOAD2     02540000
         LA    RBAL,BADREQ             LOAD RETURN CODE          S21016 02547021
         B     XCTLOAD3                GO INVOKE MSG MODULE      S21016 02554021
EXIT3    EQU   *                                                 S21016 02561021
         SSM   MASKON                  ENABLE INTERRUPTS         S21016 02568021
XCTLOAD3 EQU   *                       SET UP TO XCTL TO MSG MOD S21016 02575021
         LR    RCODE,RBAL              PASS RET CODE IN RCODE    S21016 02582021
         LA    R8,EPLOAD3              ADDR OF NAME FOR LOAD 3   S21016 02589021
         B     XCTLGO                  GO TO XCTL MECHANISM      S21016 02596021
XCTLOAD2 EQU   *                       SET UP TO XCTL TO LOAD 2  S21016 02603021
         LA    R8,EPLOAD2              ADDR OF NAME FOR LOAD 2   S21016 02610021
*********************************************************************** 02620000
*                                                                     * 02640000
*              TRANSFER CONTROL MECHANISM TO LOAD 2 (BUFINQ)          * 02660000
*                                                                     * 02680000
*********************************************************************** 02700000
XCTLGO   EQU   *                                                 S21016 02710021
         L     RZ,CVT                  LOAD CVT ADDR                    02720021
         L     RZ,0(RZ)            LOAD TCB PTR TO DOUBLE WORD          02740000
         L     RZ,4(RZ)            LOAD CURRENT TCB ADR                 02760000
         L     RZ,0(RZ)            LOAD CURRENT RB PTR                  02780000
         LA    RBAL,96(RZ)         LOAD ADR OF REMOTE SUPRVSR PARAM LST 02800000
         LA    RZ,104(RZ)               WHICH IS AT SVRB+96, THEN SET   02820000
         ST    RZ,0(RBAL)               UP LIST AS FOLLOWS --           02840000
         SR    RA,RA                    WORD1 - PTR TO BUFINQ ADR (*+8) 02860000
         ST    RA,4(RBAL)               WORD2 - DCB ADR SET TO 0        02880000
         MVC   D8(D8,RBAL),D0(R8)           WORD 3,4 - EP NAME   S21016 02900021
         XCTL  MF=(E,(1)),SF=(E,(15)) TRANSFER CONTROL                  02920000
EPLOAD2  DC    CL8'IGC0107A'       CSECT NAME FOR LOAD 2                02940000
EPLOAD3  DC    CL8'IGC0207A'           NAME FOR MSG MODULE       S21016 02950021
*     *     *     *     *     *    *     *     *     *     *     *      02960000
*                                                                *      02980000
*THE FOLLOWING SUBROUTINE ASSIGNS BUFFER STORAGE AND IS ACCESSED *      03000000
*WHENEVER THE ASGNBFR MACRO-INSTRUCTION IS ISSUED.               *      03020000
*                                                                *      03040000
*     *     *     *     *     *     *     *     *     *     *    *      03060000
ASSIGN   L     RA,BUFPRM                RA EQ ADDR OF HALFWORD          03080000
         LH    RA,0(RA)                 RA EQ BYTES REQUESTED           03100000
         LA    RX,MASK1                 RX CONTAINS X'FF',ADD TO RA,TO  03120000
         AR    RA,RX                    CONVERT BYTES TO SECTIONS       03140000
         SRA   RA,8                     PUT NUMB IN LO-ORDER BYTE OF RA 03160000
         SR    RX,RX                    CLEAR RX TO ZERO AND COMPARE TO 03180000
         CR    RA,RX               CHECK RA FOR NEG OR ZERO REQUEST     03200000
         BNH   ERRPRM                   GO TO RET CODE '18' RTN         03220000
*DISABLE: MASK OFF ALL INTERRUPTS IN SYSTEM MASK                        03240000
         LA    RZ,MASKOFF          LOAD RZ WITH 0 TO MASK OFF SYSTEM    03260000
         SSM   0(RZ)                    SET SYSTEM MASK                 03280000
*INITIALIZE SUBROUTINE                                                  03300000
BASIC    LH    RB,TOTAVAIL         SET RB EQ TO TOTAVAIL IN BFRTBL      03320000
         LH    RC,NUMDEV                RC HAS NUMBER OF DEVICES/2840   03340000
         CLR   RA,RB                    IF REQUEST GREATER THAN AMT     03360000
         BH    ERRASG4                  AVAIL,LOAD RETURN CODE          03380000
*ACCESS AND SEARCH THIS DEVICE'S ZONE                                   03400000
         BAL   RNSI,INFODISP      GO TO INFO RTN                        03420000
*                                                                       03440000
         LH    RE,4(RZ)                 RE CONTAINS THIS DEVICE'S ZONSZ 03460000
         CLR   RA,RE               COMPARE REQUEST TO ZONESZ            03480000
        BH    ERRASG8             IF REQUEST GREATER NO ASGNMENT        03500000
*BEGIN SEARCH OF THIS DEVICE'S ZONE--                                   03520000
         LH    RB,2(RZ)                 RB EQ DEVICE'S ZONE DISP        03540000
         AR    RB,RBFTBL                RB EQ DISP + ADDR OF BFR TBL    03560000
         LR    RX,RZ                    SAVE DISP OF THIS DEVICE'S INFO 03580000
REEX     EX    RE,SEEK1            SEARCH FOR AVAIL SECTION             03600000
         BC    10,CONTINU1             IF NOT FOUND GO TO NEXT ZONE     03620000
         BAL   14,COMPUTE              SET UP REG AND CTRS              03640000
*OTHERWISE SEARCH FOR CONTIGUOUS STORAGE IN DEVICE'S ZONE               03660000
         EX    RA,SEEK2                 SEARCH FOR CONTIG PER REQUEST   03680000
         BC    4,GETADR                                                 03700000
*                                                                       03720000
*UPDATE TABLES, ASSIGN STORAGE AND SET DCB FLDS                         03740000
*                                                                       03760000
SETDCB   LR    RZ,RB                    CONVERT BFR TBL ENTRY DISP TO   03780000
         SR    RZ,RBFTBL                ACTUAL BFR STORAGE ADDRESS BY   03800000
         CLI   16(RUCB),X'31'          IS IT MOD 1                      03820000
         BE    MODASG                                                   03840000
         S     RZ,HEADISP               MULTIPLYING ENTRY DISP BY 256   03860000
MULTI    SLL   RZ,8                SUBTRACT BFRTBL ADDR AND 72          03880000
         STH   RZ,16(RDCB)              SET BFRST FLD IN DCB            03900000
         LR    RZ,RA                    CONVERT SECTIONS IN REQUEST TO  03920000
         SLL   RZ,8                     BYTES BY MULTIPLYING BY 256     03940000
         STH   RZ,18(RDCB)              SET BFRSZ FLD IN DCB            03960000
*ASSIGN--FILL IN BFR TABLE                                              03980000
*                                                                       04000000
         LH    RE,TOTAVAIL              UPDATE TOTAVAIL FLD OF BFR TBL  04020000
         SR    RE,RA                    SUBTRACT REQUEST                04040000
         STH   RE,TOTAVAIL              STORE UPDATED TOTAVAIL IN TBL   04060000
         LH    RZ,0(RHOLD)         LOAD TASGND FIELD TO UPDATE          04080000
         AR    RZ,RA               ADD REQUEST                          04100000
         STH   RZ,0(RHOLD)         RESTORE UPDATED TASGND               04120000
         MVC   0(1,RB),36(RUCB)         PUT DEVNDX IN 1ST BYTE ENTRY    04140000
         LA    RX,RY                    SET RX EQ 1                     04160000
         CLR   RX,RA               IS REQUEST EQ 1 SECTION              04180000
         BE    SUCCESS                  GO TO RETURN ROUTINE            04200000
         LA    RX,RZ                    SET RX EQ 2                     04220000
         SR    RA,RX                    SET RA EQ REQUEST-2 TO USE EX   04240000
         EX    RA,ASGSCTN               INSTRUCTION WITH LNG ADJUSTED   04260000
         B     SUCCESS                  GO TO RETURN ROUTINE            04280000
COMPUTE  AR    RE,RB                   RE EQ DISP ADR + ZONESZ          04300000
         SR    RE,RY                   RE EQ REMAINING ZONESZ           04320000
         CLR   RA,RE                   IS REQUEST HIGHER THAN ZONESZ    04340000
         BH    CONTINU1                GO TO NEXT ZONE                  04360000
         LR    RB,RY                   PUT NEW TRT ADR IN RB            04380000
         BR    RNSI                    GO BACK                          04400000
GETADR   BAL   14,COMPUTE              UPDATE REG AND CTRS              04420000
         B     REEX                                                     04440000
*                                                                       04460000
INFODISP SR    RD,RD                    CLEAT RD TO ZERO                04480000
         IC    RD,36(RUCB)              RD CONTAINS DEVNDX              04500000
         LR    RZ,RD                    RZ CONTAINS DEVNDX TO COMPUTE   04520000
*                                       LOCATION OF THIS DEVICE'S INFO  04540000
*                                       IN THE BFR TBL                  04560000
         BCT   RZ,*+4              SUBTRACT ONE FROM DEVNDX (RZ)        04580000
         SLL   RZ,3                     MULTIPLY RZ BY 8                04600000
         LA    RE,8(RBFTBL)             RE EQUALS BFR TBL ADDR + 8      04620000
         AR    RZ,RE                    RZ EQUALS DISP OF THIS DEVICE'S 04640000
*                                       INFO IN BFR TBL                 04660000
         LR    RHOLD,RZ            SAVE THIS DEVICE'S INFO DISP         04680000
         B     0(RNSI)                                                  04700000
MODASG   S     RZ,HEAD16           SUBTRACT MOD1 BFRTBL ADR             04720000
         B     MULTI               RZ AND RETURN TO NORMAL FLOW         04740000
*WHEN AN ASSIGNMENT CANNOT BE FULFILLED WITHIN THE DEVICES OWN ZONE     04760000
*THE NEXT SEQUENTIAL ZONE'S UNGUARANTEED AREA IS SEARCHED, STARTING     04780000
*AT THE BOTTOM OF THE AVAILABLE AREA                                    04800000
CONTINU1 LR    RZ,RX                    LOAD BFR INFO DISP INTO RZ      04820000
         SR    RC,RD               SET RC EQ NUMDEV-DEVNDX              04840000
         AR    RD,RC                    SET RC EQ NUMDEV TO USE AS CTR  04860000
         BCT   RD,*+4              SUBTRACT ONE FROM NUMDEV (RD)        04880000
CONTINU3 SR    RX,RX                    SET RX EQ 0                     04900000
         CLR   RX,RD               NUMDEV EQ 0?                         04920000
         BE    ERRASG                  GO TO ERR RETURN RTN      S21016 04940021
         CLR   RX,RC               RC CTR EQ 0?                         04960000
         BE    TBLTOP                   GO TO RTN TO ACCESS 1ST DEVICES 04980000
*                                            ZONE                       05000000
*                                       OTHERWISE ACCESS NEXT ZONE AND  05020000
*                                            CHECK ZONE SIZE            05040000
         LA    RZ,RUCB(RZ)         ADD 8 TO BFR INFO DISP IN RZ         05060000
CONTINU4 LH    RY,6(RZ)                 LOAD TG INTO RY                 05080000
         LH    RE,4(RZ)                 LOAD RE WITH ZONESZ             05100000
         SLR   RE,RY               SUBTRACT TG FROM ZONESIZ             05120000
*                                            AVAILABLE UNGTD SIZE       05140000
         CLR   RA,RE               IS REQUEST LARGER THAN ZONESZ        05160000
         BH    CONTINU6                 GO TO DECREMENT RC,RD           05180000
*                                                                       05200000
*OTHERWISE BEGIN BACKWARD SEARCH IN UNGTD PORTION OF THIS ZONE BY TRT   05220000
*INSTRUCTION WITH USE OF ZONESZ COUNTER                                 05240000
*                                                                       05260000
         LH    RB,2(RZ)                 SET RB EQ DISP FOR THIS ZONE    05280000
         AR    RB,RBFTBL                ADD BFR TBL ADDR TO THIS DISP   05300000
         AR    RB,RY                    ADD TG TO THIS TOTAL DISP TO PT 05320000
*                                            TO START OF UNGTD AREA     05340000
         AR    RB,RE                    ADD ZONESZ TO TOTAL DISP TO PT  05360000
*                                            TO END OF UNGTD AREA       05380000
SEARCH1  LR    RX,RZ                    SET DISP EQ REQUEST LNG FROM RB 05400000
SEARCH2  SR    RB,RA                         AFTER SAVING RZ IN RX      05420000
         EX    RA,SEEK2                 EXECUTE THE TRT-INSTRUCTION FOR 05440000
         BC    8,SETDCB                LNG OF REQUEST, IF ENOUGH        05460000
         BC    2,SETDCB                      CONTIGUOUS STORAGE GO TO   05480000
*                                            ASSIGN AND UPDATE ROUTINE  05500000
         AR    RB,RA                    OTHERWISE BEGIN SEARCH BACKWARD 05520000
*                                            FROM ADDR IN GR2 AS RESULT 05540000
*                                            OF TRT-INSTRUCTION. RB EQ  05560000
*                                            LAST END DISP OF UNGTD     05580000
*                                            AREA                       05600000
         SR    RB,RY                    SUBTRACT TRT ADDR REG (GR2)     05620000
*                                            FROM DISP FOR ZONESZ UN-   05640000
*                                            AVAILABLE                  05660000
         SR    RE,RB                    SUBTRACT THAT AMT FROM ZONESZ   05680000
         CLR   RA,RE               COMPARE REQUEST TO ZONESZ            05700000
         BH    CONTINU5                 IF HIGH GO TO DECREMENT RD,RC   05720000
*                                       OTHERWISE, LOAD TRT-ADDR INTO   05740000
         LR    RB,RY                         RB AND GO TO SEARCH2       05760000
         B     SEARCH2                                                  05780000
*                                       DECREMENT RC,RD CTRS (NUMDEV)   05800000
CONTINU5 LR    RZ,RX                         BY LOADING BFR INFO INTO   05820000
CONTINU6 LA    RX,RY                    RZ, SET RX EQ 1                 05840000
         SR    RC,RX                    SUBTRACT 1 FROM RC CTR          05860000
         SR    RD,RX                    SUBTRACT 1 FROM FROM NUMDEV     05880000
         B     CONTINU3                 GO TO CHECK CTR ROUTINE AND     05900000
*                                            CONTINUE SEARCH IN NEXT    05920000
*                                            ZONE                       05940000
TBLTOP   LR    RC,RD                    SET RC CTR TO RD CTR            05960000
         LA    RZ,RUCB(RBFTBL)     ADD 8 TO ADDR OF BFR TBL IN RZ       05980000
*RZ CONTAINS BFR INFO DISP                                              06000000
         B     CONTINU4                                                 06020000
         CNOP  2,4                                                      06040000
SEEK1    TRT   0(1,RB),FREESCTN         SEARCH FOR 1ST FREE SECTION     06060000
FREESCTN DC    X'FF'                                                    06080000
         DC    4X'00'                                                   06100000
         CNOP  2,4                                                      06120000
SEEK2    TRT   0(1,RB),CONTIG           SEARCH FOR SUBSEQUENT FREE      06140000
CONTIG   DC    X'00'                    SECTIONS                        06160000
         DC    4X'FF'                                                   06180000
         CNOP  2,4                                                      06200000
ASGSCTN  MVC   1(1,RB),0(RB)            INSERT DEVNDX IN BFR TBL TO     06220000
*                                       INDICATE ASSIGNMENT OF SECTIONS 06240000
*RETURN CODE ROUTINES                                                   06260000
ERRASG4  XC    16(4,RDCB),16(RDCB)      CLEAR DCB FLDS TO ZERO          06280000
         LA    RBAL,RB                  SET GR15 EQ 4  (X'04'           06300000
         B     EXIT3                   GO INVOKE MSG MODULE      S21016 06320021
ERRASG8  XC    16(4,RDCB),16(RDCB)      CLEAR DCB FLDS TO ZERO          06340000
         LA    RBAL,RUCB                SET GR15 EQ 8  (X'08'           06360000
         B     EXIT3                   GO INVOKE MSG MODULE      S21016 06369021
ERRDCB1  EQU   *                                                 S21016 06378021
         LA    RBAL,UNOPEN             LOAD RETURN CODE          S21016 06387021
         B     XCTLOAD3                GO INVOKE MSG MODULE      S21016 06396021
ERRDCB2  EQU   *                                                 S21016 06405021
         LA    RBAL,DCBBAD                                       S21016 06414021
         B     XCTLOAD3                GO INVOKE MSG MODULE      S21016 06423021
ERRDCB3  EQU   *                                                 S21016 06432021
         LA    RBAL,NOTGRPHC           LOAD RETURN CODE          S21016 06441021
         B     XCTLOAD3                GO INVOKE MSG MODULE      S21016 06450021
ERRPRM   LA    RBAL,BFRPRM              SET GR15 EQ 24 (X'18')          06460000
         XC    16(4,RDCB),16(RDCB)      CLEAR DCB FLDS TO ZERO          06480000
         B     XCTLOAD3                GO INVOKE MSG MODULE      S21016 06490021
ERRASG   EQU   *                                                 S21016 06500021
         LA    RBAL,NOSECTS            LOAD RETURN CODE          S21016 06510021
         XC    16(4,RDCB),16(RDCB)     CLEAR DCB FIELDS TO ZERO  S21016 06520021
         B     XCTLOAD3                GO INVOKE MSG MODULE      S21016 06530021
SUCCESS  LA    RBAL,RX                  SET GR15 EQ 0 (X'00'            06540000
ENABLE   LA    RZ,MASKON                SET SYSTEM MASK ON              06560000
         SSM   0(RZ)                                                    06580000
         LR    RY,RSAVE            RESTORE PARAMLST ADR IN GR1 FOR OPEN 06600000
RETURN   SVC   3                                                        06620000
HEADISP  DC    F'40'                                                    06640000
HEAD16   DC    F'16'                   HEADER LNG OF MOD1 BFRTBL        06660000
         DS    0F                                                       06680000
MASKON   DC    4X'FF'                                                   06700000
MASKOFF  DC    X'00'               USED TO MASK OFF SYSTEM MASK         06720000
*THE RELEASE AND RLSEALL SUBROUTINES RELEASE BUFFER STORAGE BELONGING   06740000
*TO THE REQUESTING DEVICE AND ARE ACCESSED WHENVER THE RLSEBFR MACRO-   06760000
*INSTRUCTION IS ISSUED.                                                 06780000
*                                                                       06800000
*                                                                       06820000
RELEASE  L     RX,MASKON                CHECK BUFPRM FOR FULLWORD ONES  06840000
         L     RY,BUFPRM                RY HAS ADDR OF FULLWRD          06860000
         CL    RX,0(RY)            IS FULLWORD EQ TO ONES               06880000
         BE    XCTLOAD2                           TRANSFER TO LOAD2     06900000
*COMPUTE REQUEST AND STARTING ADDRESS TO MULTIPLES OF 256 AFTER MASKING 06920000
*OFF SYSTEM MASK                                                        06940000
*                                                                       06960000
         LA    RZ,MASKOFF          LOAD RZ WITH 0 TO MASK OFF SYSTEM    06980000
         SSM   0(RZ)                         SYSTEM INTERRUPTS          07000000
         LH    RA,2(RY)            RA EQ NUM BYTES FROM BFRPRM FULWRD   07020000
         LA    RY,MASK1                 SET RY EQ X'FF'                 07040000
         AR    RA,RY                    CONVERT BYTES TO SECTIONS       07060000
         SRA   RA,8                    PUT REQUEST IN LO ORDER BYTES    07080000
         SR    RX,RX                   ZERO RX                          07100000
         CR    RA,RX                   IS REQUEST GREATER THAN 0        07120000
         BNH   PRMERR                  NO - INVALID PARAM               07140000
*                                            ORDER BYTE OF RA           07160000
*                                                                       07180000
         BAL   RNSI,INFODISP            GO TO ACCESS INFO DISP ROUTINE  07200000
*                                       LOAD TASGND FOR DEVICE IN RY    07220000
         LH    RX,0(RZ)            SET RX EQ TASGND FOR DEVICE          07240000
         CLR   RA,RX               COMPARE REQUEST TO TASGND            07260000
         BH    ERRLSE16                 GO TO ERROR AND RETURN RTN      07280000
         L     RB,BUFPRM                RB EQ ADDR OF BUFPRM            07300000
         LH    RB,0(RB)                 RB EQ START ADDR                07320000
         SRL   RB,8                     TRUNCATE ADDRESS TO 256-MULTIPL 07340000
*                                            RX EQ DISP IN BFR TBL      07360000
*CHECK START ADDRESS FOR VALIDITY                                       07380000
*                                                                       07400000
         CLI   16(RUCB),X'31'          MOD 1                            07420000
         BE    EXPCHK                  YES - BRANCH                     07440000
         A     RB,HEADISP          ADD  FIXED HEADER OF MOD2 BFRTBL     07460000
FLOW1    AR    RB,RBFTBL               ADD BUF TBL ADR TO S DISP        07480000
         LR    RY,RB                         RB PTS TO START ADR IN BFR 07500000
*                                            TBL,SAVE RB IN RY          07520000
         LR    RC,RD               LOAD DEVNDX INTO RC                  07540000
         LR    RX,RZ                    SAVE BFR INFO DISP IN RX        07560000
*COMPARE EACH ENTRY FOR LNG OF REQUEST WITH DEVICE INDEX                07580000
         SR    RD,RD                    SET RD EQ 0                     07600000
         LA    RZ,RY                    SET RZ EQ 1                     07620000
         SR    RE,RE                    SET RE EQ 0                     07640000
BXH      BXH   RE,RZ,OUT                WHEN REQUEST HAS BEEN CHECKED   07660000
*                                            GO OUT                     07680000
         IC    RD,0(RB)                 PUT ENTRY IN RD                 07700000
         CLR   RC,RD                   COMPARE DEVNDX TO ENTRY          07720000
         BNE   ERRLSE30                IF UNEQUAL,GO TO ERR RTN  S21016 07740021
         AR    RB,RZ                    INCREMENT ENTRY ADDR BY 1       07760000
         B     BXH                      BRANCH BACK TO REPEAT           07780000
EXPCHK   A     RB,HEAD16           ADD MOD1 TBL HEADER LNG              07800000
         B     FLOW1               RETURN TO NORMAL FLOW                07820000
*CLEAR ENTRIES RELEASED TO ZERO                                         07840000
OUT      SR    RA,RZ                    SUBTRACT 1 FROM REQUEST TO USE  07860000
         EX    RA,CLRENT                     EX-INSTR                   07880000
*UPDATE TABLES,CHECK RESTART ADDR                                       07900000
         AR    RA,RZ                    ADD 1 TO REQUEST TO UPDATE TBLS 07920000
         LR    RZ,RX                    RESTORE BFR INFO DISP TO RZ     07940000
         LH    RX,0(RZ)                 LOAD RX WITH TASGND FOR DEVICE  07960000
         SR    RX,RA                    SUBTRACT REQUEST FROM TASGND    07980000
         STH   RX,0(RZ)                 STORE UPDATED TASGND            08000000
*                                                                       08020000
         LH    RX,6(RBFTBL)             LOAD RX WITH TOTAVAIL FLD       08040000
         AR    RX,RA                    ADD REQUEST TO TOTAVAIL         08060000
         STH   RX,6(RBFTBL)             STORE UPDATED TOTAVAIL IN BFRTB 08080000
*CHECK RESTART ADDRESS                                                  08100000
*                                                                       08120000
RESTART  LH    RD,34(RUCB)              LOAD RESTART ADDR IN RD         08140000
         SRL   RD,8                     SET RD EQ MULTIPLE-256-DISP     08160000
         CLI   16(RUCB),X'31'          MOD 1                            08180000
         BE    EXPRES                  YES - BRANCH                     08200000
         A     RD,HEADISP               ADD 72 TO RD                    08220000
FLOW2    AR    RD,RBFTBL           ADD BFR TBL ADR TO RD,RD NOW         08240000
*                                            HAS ADDR OF BFR TBL ENTRY  08260000
*                                            CONTAINING THAT RESTART AD 08280000
         SR    RE,RE                    CLEAR RE TO ZERO                08300000
         IC    RE,0(RD)                 SET RE EQ TO BFR TBL ENTRY      08320000
         CLR   RC,RE               COMPARE DEVNDX TO ENTRY              08340000
         BE    SUCCESS                                                  08360000
*IF RESTART ADR IS INVALID, SET ADR TO ALL ONES                         08380000
INVALID  LH    RX,MASKON           SET RX EQ TO ALL ONES                08400000
         STH   RX,34(RUCB)         CHANGE ADR IN UCB                    08420000
         LA    RBAL,BADADR         LOAD RETURN CODE EQ 20 (X'14')       08440000
         B     ENABLE                                                   08460000
EXPRES   A     RD,HEAD16                                                08480000
         B     FLOW2               RETURN TO NORMAL FLOW                08500000
ERRLSE16 LA    RBAL,BADRLS                                              08520000
         B     EXIT3                   GO INVOKE MSG MODULE      S21016 08530021
ERRLSE30 EQU   *                                                        08540021
         LA    RBAL,BADREL             LOAD RETURN CODE          S21016 08550021
         B     EXIT3                   GO INVOKE MSG MODULE      S21016 08560021
PRMERR   EQU   *                                                 S21016 08570021
         LA    RBAL,RELNEG             LOAD RETURN CODE          S21016 08580021
         B     EXIT3                   GO INVOKE MSG MODULE      S21016 08590021
         CNOP  2,4                                                      08600000
CLRENT   XC    0(1,RY),0(RY)                                            08620000
         CNOP   0,4                                                     08640000
         END                                                            08660000
