*TITLE 'GRAPHIC ATTENTION SERVICE ROUTINE'                              00020000
*STATUS:CHANGE LEVEL 0                                                  00040000
*FUNCTION/OPERATION:THIS ROUTINE RESETS TO 0  BIT 6 OR BIT 7 OR BOTH    00060000
*   THAT ARE LOCATED IN THE GRAPHIC CONTROL BYTE APPENDAGE TO THE       00080000
*   UNIT CONTROL BLOCK(UCB).                                            00100000
*ENTRY POINTS:SVC  070  OR USE GSERV MACRO.RESET BITS 6 AND/OR 7 IN GCB 00120000
*INPUT:GR#1 IS THE PARAMETER REGISTER.ITS CONTENTS ARE AS FOLLOWS:      00140000
*   ******************                                                  00160000
*   MASK*DCBLIST ADR*  MASK=01 FOR BIT7,02 FOR BIT6,03 FOR BOTH.        00180000
*   ******************                                                  00200000
*   DCBLIST ADR CONTAINS THE FOLLOWING INFORMATION:                     00220000
*   ****************                                                    00240000
*   * IX * DCB ADR * IX=DEB EXTENT TO ACCESS UCB ADDRESS.               00260000
*   ****************                                                    00280000
*OUTPUT:N/A                                                             00300000
*EXTERNAL ROUTINES:N/A                                                  00320000
*EXITS NORMAL:RETURN MADE TO CALLING ROUTINE VIA SVC 3.                 00340000
*EXITS ERROR:ABNORMAL TERMINATION OF TASK.SYSTEM COMPLETION CODES ARE   00360000
*   AS FOLLOWS:                                                         00380000
*               056=INVALID UNIT CONTROL BLOCK(UCB).                    00400000
*               057=NOT A GRAPHIC UCB.                                  00420000
*TABLES/WORK AREAS:N/A                                                  00440000
*ATTRIBUTES:RE-ENTRANT                                                  00460000
*NOTES:N/A                                                              00480000
*                                                                       00500000
*                                                                       00520000
*                                                                       00540000
PARMRG   EQU   1                        PARAMETER REGISTER              00560000
BASERG   EQU   2                        WORK REG                        00580000
SVCRG1   EQU   3                        WORK REG                        00600000
SVCRG2   EQU   4                        WORK REG                        00620000
SVCRG3   EQU   5                        WORK REG                        00640000
SVCRG4   EQU   6                        WORK REG                        00660000
SVCRG5   EQU   7                        WORK REG                        00680000
SVCRG6   EQU   8                        WORK REG                        00700000
*                                                                       00720000
UCBADR   EQU   32                       START OF UCB LIST IN DEB        00740000
DEBADR   EQU   44                       START OF DEB ADDRESS IN DCB     00760000
GCBADR   EQU   24                       START OF UCB GRAPHIC EXTENSION  00780000
EXIT     EQU   3                                                        00800000
GUCBTYP  EQU   18                      GRAPHIC ID IN UCB TYPE FIELD     00820000
IGC070   CSECT                                                          00840000
         ENTRY SVC070                                                   00860000
SVC070   DS    0D                      ALIGN SVC TO A DBLE WORD BNDRY   00880000
         BALR  BASERG,0                 SET UP BASE REGISTER            00900000
         USING *,BASERG                 DEFINE BASE REGISTER            00920000
         L     SVCRG4,0(0,PARMRG)       LOAD DCB ADDRESS AND INDX FACTR 00940000
         LR    SVCRG1,SVCRG4            TRANSFER INDEX FACTOR           00960000
         SRL   SVCRG1,24                POSITION INDEX FACTOR           00980000
         L     SVCRG4,DEBADR(0,SVCRG4)  LOAD DEB ADDRESS                01000000
         LA    SVCRG2,0                 ZERO EVEN REGISTER              01020000
         LA    SVCRG3,4                 LOAD MULTIPLICAND               01040000
         MR    SVCRG2,SVCRG1            DETERMINE UCB ADDRESS INDEX     01060000
         L     SVCRG4,UCBADR(SVCRG3,SVCRG4)  LOAD UCB ADDRESS           01080000
         TM    2(SVCRG4),X'FF'          TEST FOR VALID UCB  ID          01100000
         BC    1,GCBCHK                 BRANCH IF VALID                 01120000
         WTO   'IFF421I GSERV FOUND INVALID UCB',                S21016X01126021
               ROUTCDE=11,DESC=7                                 S21016 01132021
         LA    1,X'056'                LOAD ABEND ERROR CODE            01140000
         SLL   1,12                    POSITION CODE                    01160000
         ABEND (1),DUMP                                                 01180000
GCBCHK   TM    GUCBTYP(SVCRG4),X'10'   TEST FOR GRAPHIC ID IN TYPE FLD  01200000
         BC    1,RESET                  BRANCH IF VALID GCB             01220000
         WTO   'IFF422I GSERV FOUND NON-GRAPHIC UCB',            S21016X01226021
               ROUTCDE=11,DESC=7                                 S21016 01232021
         LA    1,X'057'                LOAD ABEND ERROR CODE            01240000
         SLL   1,12                    POSITION CODE                    01260000
         ABEND (1),DUMP                                                 01280000
RESET    SRL   PARMRG,24                POSITION BIT INDICATOR          01300000
         LA    SVCRG1,3                 LOAD PROTECT MASK FOR GRAPHIC   01320000
*                                       SUPERVISOR BITS IN GCB          01340000
         NR    PARMRG,SVCRG1            MASK OUT ANY USER REQUEST TO    01360000
*                                       RESET PROTECTED GRAPHIC         01380000
*                                       SUPERVISOR BITS IN GCB          01400000
         LA    SVCRG1,X'FF'             LOAD INITIAL RESET MASK         01420000
         XR    PARMRG,SVCRG1            DETERMINE FINAL RESETMASK       01440000
         L     SVCRG1,GCBADR(0,SVCRG4)  LOAD GCB                        01460000
         NR    PARMRG,SVCRG1            RESET SPECIFIED GCB BITS        01480000
         STC   PARMRG,GCBADR+3(0,SVCRG4)     STORE NEW GCB BYTE         01500000
         LA    PARMRG,0                 INDICATE NORMAL RETURN          01520000
         SR    14,14                    MAKE REG14 POSITIVE BEFORE EXIT 01540000
         SVC   EXIT                                                     01560000
         CNOP  0,8                                                      01580000
         END                                                            01600000
