TE67     TITLE '    2280,2282 STANDARD ERROR ROUTINE'  TRAPCODE/2280ERR 00020000
IGE0010C START X'00'                                                    00040000
*********************************************************************** 00060000
*                                                                       00080000
*TITLE         2280,2282 STANDARD ERROR ROUTINE                         00100000
*                                                                       00120000
*                                                                       00140000
*FUNCTION      1. TO RETRY I/O OPERATIONS THAT HAVE FAILED DUE TO HARD- 00160000
*    WARE ERRORS IN ORDER TO DETERMINE PERMANENCY.                      00180000
*              2. TO KEEP TRACK OF RETRIES AND NOTIFY SYSTEM OPERATOR   00200000
*    OF ALL PERMANENT HARDWARE ERRORS.                                  00220000
*              3. TO NOTIFY SYSTEM OPERATOR IF INTERVENTION IS REQUIRED 00240000
*    ON THE FILM UNITS.                                                 00260000
*              4. TO KEEP STATISTICS ON THE NUMBER OF HARDWARE FAILURES 00280000
*    FOR USE BY THE CUSTOMER ENGINEER.                                  00300000
*              5. TO CAUSE PERMANENT ERROR CODES TO BE POSTED IN THE    00320000
*    ECB FOR PERMANENT HARDWARE ERRORS AND PROGRAM ERRORS DETECTED.     00340000
*                                                                       00360000
*                                                                       00380000
*ENTRY POINT   ENTRY IS MADE TO THIS ROUTINE AT IGE0010C UPON DETECTION 00400000
*    OF AN ERROR BY THE  I O S  INTERRUPTION SUPERVISOR.                00420000
*                                                                       00440000
*                                                                       00460000
*INPUT         ADDRESS OF 12 STAR ELEMENT IN GENERAL REGISTER 1.        00480000
*                                                                       00500000
*                                                                       00520000
*OUTPUT        1. MESSAGE TO SYSTEM OPERATOR (WHEN REQUIRED).           00540000
*              2. STATISTICS TO STATISTICS TABLE (WHEN REQUIRED).       00560000
*                                                                       00580000
*                                                                       00600000
*EXITS -                                                                00620000
*    NORMAL    1. EXIT TO STATISTICS UPDATE ROUTINE (CORRECT ERROR).    00640000
*              2. EXIT TO SUPERVISOR VIA SVC3 AFTER INITIATING SVC15.   00660000
*                                                                       00680000
*    ERROR     1. EXIT TO WTO ROUTINE FOR PERMANENT HARDWARE ERROR.     00700000
*              2. EXIT TO STATISTICS UPDATE ROUTINE FOR ALL PERMANENT   00720000
*                 PROGRAM ERRORS.                                       00740000
*                                                                       00760000
*                                                                       00780000
*TABLES/WORK AREAS                                                      00800000
*              SEE STANDARD CONTROL BLOCK LAYOUTS DESCRIBED IN OS/360   00820000
*    I O S  PLM, AND INTRO TO CONTROL PROGRAM LOGIC PLM.                00840000
*                                                                       00860000
*                                                                       00880000
*ATTRIBUTES    REENTRANT                                                00900000
*                                                                       00920000
*                                                                       00940000
*NOTES         N/A                                                      00960000
*                                                                       00980000
*********************************************************************** 01000000
*                                                                       01020000
*   REGISTER DEFINITION                                                 01040000
*                                                                       01060000
STAR12   EQU   1                        12* ADDRESS REGISTER (RQE ADDR) 01080000
BASEREG  EQU   15                       BASE REGISTER                   01100000
IOBREG   EQU   10                       IOB ADDRESS REGISTER            01120000
UCBREG   EQU   11                       UCB ADDRESS REGISTER            01140000
ERREG2   EQU   12                       WORK REGISTER                   01160000
ERREG3   EQU   13                       WORK REGISTER                   01180000
ERREG4   EQU   0                        WORK REGISTER                   01200000
RTNREG   EQU   14                       RETURN REGISTER                 01220000
*                                                                       01240000
*   DEFINITIONS OF FLAGS, FLAG FIELDS, AND CODES IN CONTROL BLOCKS      01260000
*                                                                       01280000
IOBFLAG1 EQU   0                        FLAG1 FIELD IN IOB              01300000
IOBECI   EQU   X'20'                    ERROR CORRECTION INDICATOR BIT  01320000
IOBEXCFG EQU   X'04'                    EXCEPTION FLAG                  01340000
FLAG1ALL EQU   IOBECI+IOBEXCFG          TWO BIT COMBINATION             01360000
*                                                                       01380000
IOBFLAG2 EQU   1                        FLAG2 FIELD IN IOB              01400000
IOBDNP   EQU   X'02'                    DEVICE END POST CODE            01420000
*                                                                       01440000
IOBFLAG3 EQU   8                        FLAG3 FIELD IN IOB              01460000
IOBMSGTP EQU   X'04'                    MESSAGE TYPE INDICATOR          01480000
SEROUTID EQU   X'01'                    SERR LOG OUT INDICATOR          01500000
*                                                                       01520000
UCBTYPE  EQU   19                       DEVICE TYPE FIELD IN UCB        01540000
TYPE2280 EQU   X'05'                    TYPE CODE ID FOR 2280           01560000
TYPE2282 EQU   X'06'                    TYPE CODE ID FOR 2282           01580000
*                                                                       01600000
IOBSTAT1 EQU   12                       FIRST STATUS BYTE IN IOB        01620000
ATENTION EQU   X'80'                    ATTENTION                       01640000
CHANLEND EQU   X'08'                    CHANNEL END                     01660000
DEVICEND EQU   X'04'                    DEVICE END                      01680000
UNITCHEK EQU   X'02'                    UNIT CHECK                      01700000
UNITEXCP EQU   X'01'                    UNIT EXCEPTION                  01720000
SNOCRST1 EQU   ATENTION+UNITEXCP        SHOULD NOT OCCUR BITS STATUS 1  01740000
UCUE     EQU   X'FF'-UNITCHEK-UNITEXCP  MASK TO RESET UNIT CHECK/EXCEPT 01760000
*                                                                       01780000
IOBSTAT2 EQU   13                       SECOND STATUS BYTE IN IOB       01800000
INCLEN   EQU   X'40'                    INCORRECT LENGTH                01820000
PROGCHEK EQU   X'20'                    PROGRAM CHECK                   01840000
PROTCHEK EQU   X'10'                    PROTECTION CHECK                01860000
CHAINCK  EQU   X'01'                    CHAINING CHECK                  01880000
STAT2ALL EQU   INCLEN+PROGCHEK+PROTCHEK THREE BIT COMBINATION           01900000
SNOCRST2 EQU   CHAINCK                  SHOULD NOT OCCUR BIT STATUS 2   01920000
*                                                                       01940000
IOBSENS0 EQU   2                        IOB SENSE FIELD ZERO            01960000
CMDREJCT EQU   X'80'                    COMMAND REJECT                  01980000
INTVNREQ EQU   X'40'                    INTERVENTION REQUIRED           02000000
BUSOUTCK EQU   X'20'                    BUS OUT CHECK                   02020000
EQUIPCHK EQU   X'10'                    EQUIPMENT CHECK                 02040000
DATACHEK EQU   X'08'                    DATA CHECK                      02060000
ILLGLSEQ EQU   X'01'                    ILLEGAL SEQUENCE                02080000
SNOCUR0  EQU   X'06'                    SHOULD NOT OCCUR SENSE DATA 0   02100000
*                                                                       02120000
IOBSENS1 EQU   3                        IOB SENSE FIELD 1               02140000
READBCZ  EQU   X'80'                    READ BYTE COUNT ZERO            02160000
RECFLMLW EQU   X'40'                    RECORDER FILM LOW               02180000
RECFORCG EQU   X'20'                    RECORDER FORCED GAP             02200000
FILMOTLT EQU   X'10'                    FILM MOTION LIMIT               02220000
OUTCKBUF EQU   X'04'                    2840 OUTPUT CHECK               02240000
INCHKBUF EQU   X'02'                    2840 INPUT CHECK                02260000
GRAPICHK EQU   X'01'                    GRAPHIC CHECK                   02280000
SNOCUR10 EQU   X'18'                    2280 SHOULD NOT OCCUR SENSE 1   02300000
SNOCUR12 EQU   X'08'                    2282 SHOULD NOT OCCUR SENSE 1   02320000
*                                                                       02340000
IOBRETRY EQU   30                       IOB RETRY COUNT FIELD           02360000
BUSOUT1  EQU   X'80'                    BUS OUT 1 RETRY INDICATOR       02380000
BUSOUT2  EQU   X'40'                    BUS OUT 2 RETRY INDICATOR       02400000
DATACHK  EQU   X'20'                    DATA CHECK RETRY INDICATOR      02420000
INPIND   EQU   X'08'                    2840 INPUT CHECK RETRY INDICATR 02440000
IOBAEA   EQU   X'02'                    ABNORMAL END APPENDAGE INDICATR 02460000
RETRYALL EQU   BUSOUT1+BUSOUT2+DATACHK+INPIND  FOUR BIT COMBINATION     02480000
*                                                                       02500000
*   MISCELLANEOUS                                                       02520000
*                                                                       02540000
UCBADR   EQU   2                        UCB ADDRESS FIELD IN 12 *       02560000
DCBADR   EQU   20                       DCB ADDRESS FIELD IN IOB        02580000
DCBERFLG EQU   44                       DCB ERROR FLAG FIELD IN DCB     02600000
DCBPERM  EQU   X'C0'                    DCB PERMANENT ERROR FLAGS       02620000
EXCPER   EQU   15                       ERROR EXECUTE CHANNEL PROGRAM   02640000
EXIT     EQU   3                        EXIT TO SUPERVISOR    SVC ID    02660000
STATAB   EQU   9                        STATISTICS TABLE INDEX BYTE     02680000
ERRNM1   EQU   254                      POST STATISTICS IDENTIFICATION  02700000
WTO      EQU   253                      WRITE TO OPERATOR IDENT         02720000
COMADR   EQU   16                       LOCATION CONTAINING COMMUNICA-  02740000
*                                       TIONS VECTOR TABLE ADDR (CVT)   02760000
XCLADR   EQU   44                       LOCATION IN CVT OF XCTL ADDR    02780000
STATADR  EQU   112                      LOCATION IN CVT THAT CONTAINS   02800000
*                                       THE STARTING ADDR OF STAT TBLS  02820000
STATDISP EQU   8                        STATISTIC TABLE DISPLACEMENT TO 02840000
*                                       'OR' SENSE DATA FROM IOB TO TBL 02860000
IOBADR   EQU   4                        IOB ADDRESS FIELD IN 12 *       02880000
BITRESET EQU   X'7F'                    MASKS UNUSED BITS IN STAT TABLE 02900000
*                                                                       02920000
*                                                                       02940000
         ENTRY ER2280                                                   02960000
         USING *,BASEREG                DEFINE BASE REGISTER            02980000
*                                                                       03000000
*   SET EXCEPTION BIT AND ERROR FLAG IN  IOB                            03020000
*                                                                       03040000
ER2280   L     IOBREG,IOBADR(0,STAR12)  LOAD IOB ADDRESS                03060000
         LH    UCBREG,UCBADR(0,STAR12)  LOAD UCB ADDRESS                03080000
         OI    IOBFLAG1(IOBREG),FLAG1ALL TURN ON ERROR BITS IN IOB FLG1 03100000
*                                                                       03120000
*                                                                       03140000
*   TEST CSW STATUS BITS                                                03160000
*                                                                       03180000
*   TEST SHOULD NOT OCCUR CONDITIONS                                    03200000
*                                                                       03220000
         TM    IOBSTAT1(IOBREG),SNOCRST1 TEST SHOULD NOT OCCUR STATUS 1 03240000
         BC    5,SEROUT                 BRANCH IF ANY/ALL PRESENT       03260000
         TM    IOBSTAT2(IOBREG),SNOCRST2 TEST SHOULD NOT OCCUR STATUS 2 03280000
         BC    5,SEROUT                 BRANCH IF ANY/ALL PRESENT       03300000
*                                                                       03320000
*   TEST UNIT CHECK                                                     03340000
*                                                                       03360000
         TM    IOBSTAT1(IOBREG),UNITCHEK TEST FOR UNIT CHECK            03380000
         BC    1,MAINER                 BRANCH IF PRESENT               03400000
*                                                                       03420000
*   TEST PERMANENT ERROR                                                03440000
*                                                                       03460000
TESTST   TM    IOBSTAT2(IOBREG),STAT2ALL TEST FOR PROG CHECK,PROT CHECK 03480000
*                                        AND INCORRECT LENGTH           03500000
         BC    5,PERMER                 BRANCH IF ANY/ALL PRESENT       03520000
*                                                                       03540000
*   CLEAR EXCEPTION BIT IN IOB                                          03560000
*                                                                       03580000
NOERR    NI    IOBFLAG1(IOBREG),X'FF'-FLAG1ALL    CLEAR PERMANENT ERROR 03600000
*                                                 FLAGS IN IOB          03620000
         NI    IOBSTAT1(IOBREG),UCUE    CLEAR STATUS                    03640000
         L     ERREG2,DCBADR(ERREG4,IOBREG)  LOAD DCB ADDRESS           03660000
         NI    DCBERFLG(ERREG2),X'FF'-DCBPERM     CLEAR DCB ERROR FLAGS 03680000
         NI    IOBRETRY(IOBREG),X'FF'-IOBAEA      RESET AEA FLAG        03700000
         BC    15,RESET                 BRANCH                          03720000
*                                                                       03740000
*   SET LOG OUT BIT IN IOB                                              03760000
*                                                                       03780000
SEROUT   OI    IOBFLAG3(IOBREG),SEROUTID     INDICATE LOG OUT TO SERR   03800000
*                                                                       03820000
*   CLEAR ERROR FLAG IN IOB                                             03840000
*                                                                       03860000
PERMER   NI    IOBFLAG1(IOBREG),X'FF'-IOBECI INDICATE PERMANENT ERROR   03880000
RESET    NI    IOBRETRY(IOBREG),X'FF'-RETRYALL    RESET ALL RETRY FLAGS 03900000
POST     LA    ERREG3,ERRNM1            LOAD POST STATISTICS ROUTINE ID 03920000
         L     RTNREG,COMADR            LOAD ADDR OF CVT                03940000
         L     RTNREG,XCLADR(ERREG4,RTNREG)  LOAD ADDR OF XCTL ROUTINE  03960000
         BCR   15,RTNREG                BRANCH TO XCTL ROUTINE          03980000
*                                                                       04000000
*   TEST SENSE BITS                                                     04020000
*                                                                       04040000
MAINER   LR    ERREG4,IOBREG            SAVE REGISTER                   04060000
         L     IOBREG,COMADR            LOAD COMMUNICATION TABLE ADDR   04080000
         L     IOBREG,STATADR(ERREG4,IOBREG) LOAD STAT TABLE START ADR  04100000
         SR    ERREG2,ERREG2            ZERO REGISTER                   04120000
         IC    ERREG2,STATAB(ERREG4,UCBREG)  STAT TAB INDEX TO REGISTER 04140000
         LA    ERREG3,10                CONSTANT TO REGISTER            04160000
         MR    ERREG2,ERREG2            COMPUTE ABSOLUTE INDEX          04180000
         AR    ERREG3,IOBREG            COMPUTE ABSOLUTE ADDRESS OF     04200000
*                                       DEVICE STATISTIC TABLE          04220000
         LR    IOBREG,ERREG4            RESTORE REGISTER                04240000
         OC    STATDISP(2,ERREG3),IOBSENS0(IOBREG)     SENSE DATA IS    04260000
*                                       'OR' INTO STATISTICS TABLE SO   04280000
*                                       THAT DIFFERENCES DUE TO RETRY   04300000
*                                       WILL BE COMBINED AT UPDATE TIME 04320000
         NI    STATDISP(ERREG3),BITRESET     RESET NOT USED BIT         04340000
         TM    IOBSENS0(IOBREG),SNOCUR0      TEST FOR SHOULD NOT OCCUR  04360000
*                                            SENSE BITS IN BYTE 0       04380000
         BC    5,SEROUT                 BRANCH IF ANY/ALL PRESENT       04400000
         CLI   UCBTYPE(UCBREG),TYPE2280 TEST FOR 2280                   04420000
         BC    8,IS2280                 BRANCH IF 2280                  04440000
         CLI   UCBTYPE(UCBREG),TYPE2282 TEST FOR 2282                   04460000
         BC    8,IS2282                 BRANCH IF 2282                  04480000
         BC    15,SEROUT                GO TO SYSTEM ERROR RECORDING    04500000
*                                                                       04520000
*   TEST SHOULD NOT OCCUR SENSE BITS IN BYTE 1                          04540000
*                                                                       04560000
IS2280   TM    IOBSENS1(IOBREG),SNOCUR10  TEST 2280 NOT OCCUR SENSE 1   04580000
         BC    5,SEROUT                 BRANCH IF ANY/ALL PRESENT       04600000
         BC    15,AROUND                BRANCH OVER 2282 CODE           04620000
IS2282   TM    IOBSENS1(IOBREG),SNOCUR12  TEST 2282 NOT OCCUR SENSE 1   04640000
         BC    5,SEROUT                 BRANCH IF ANY/ALL PRESENT       04660000
AROUND   TM    IOBFLAG2(IOBREG),IOBDNP  TEST FOR DEVICE END ONLY        04680000
         BC    1,DEONLY                 BRANCH IF DEVICE END ONLY       04700000
         TM    IOBSTAT1(IOBREG),CHANLEND+DEVICEND TEST FOR CE AND DE    04720000
         BC    1,ISCEDE                 BRANCH IF CE AND DE             04740000
*                                                                       04760000
*   TEST ERROR CONDITIONS POSSIBLE WITH UNIT CHECK                      04780000
*                                                                       04800000
         TM    IOBSENS0(IOBREG),BUSOUTCK TEST FOR BUS OUT CHECK         04820000
         BC    1,ISBUSOT1               BRANCH IF BUS OUT PRESENT       04840000
         TM    IOBSENS0(IOBREG),CMDREJCT TEST FOR COMMAND REJECT        04860000
         BC    1,PERMER                 BRANCH IF PRESENT               04880000
         BC    15,TESTST                BRANCH TO TEST REMAINDER OF     04900000
*                                       STATUS BITS                     04920000
ISBUSOT1 TM    IOBRETRY(IOBREG),BUSOUT1 HAS ERROR BEEN RETRIED          04940000
         BC    1,WTORTN                 BRANCH IF YES                   04960000
         OI    IOBRETRY(IOBREG),BUSOUT1 IF NOT, SET RETRY INDICATOR     04980000
*                                                                       05000000
*   ALL ERRORS TO BE RETRIED WILL EXIT HERE                             05020000
*                                                                       05040000
RETRY    SVC   EXCPER                   ISSUE ERROR EXCP                05060000
         SVC   EXIT                     RETURN TO IOS                   05080000
*                                                                       05100000
*                                                                       05120000
*   TEST ERROR CONDITIONS POSSIBLE WITH CHANNEL END, DEVICE END, AND    05140000
*   UNIT CHECK                                                          05160000
*                                                                       05180000
ISCEDE   TM    IOBSENS0(IOBREG),BUSOUTCK TEST FOR BUS OUT CHECK         05200000
         BC    1,ISBUSOT2               BRANCH IF PRESENT               05220000
         TM    IOBSENS0(IOBREG),DATACHEK TEST FOR DATA CHECK            05240000
         BC    1,ISDATACK               BRANCH IF PRESENT               05260000
         TM    IOBSENS1(IOBREG),INCHKBUF TEST FOR 2840 INPUT CHECK      05280000
         BC    1,ISBFINCK               BRANCH IF PRESENT               05300000
         BC    15,TESTST                IF NOT, BRANCH TO TEST REMAINDR 05320000
*                                       OF STATUS BITS                  05340000
ISBUSOT2 TM    IOBRETRY(IOBREG),BUSOUT2 HAS ERROR BEEN RETRIED          05360000
         BC    1,WTORTN                 BRANCH IF YES                   05380000
         OI    IOBRETRY(IOBREG),BUSOUT2 SET RETRY INDICATOR             05400000
         BC    15,RETRY                 BRANCH TO RETRY I/O REQUEST     05420000
ISDATACK TM    IOBRETRY(IOBREG),DATACHK HAS ERROR BEEN RETRIED          05440000
         BC    1,WTORTN                 BRANCH IF YES                   05460000
         OI    IOBRETRY(IOBREG),DATACHK SET RETRY INDICATOR             05480000
         BC    15,RETRY                 BRANCH TO RETRY I/O REQUEST     05500000
ISBFINCK TM    IOBRETRY(IOBREG),INPIND  HAS ERROR BEEN RETRIED          05520000
         BC    1,WTORTN                 BRANCH IF YES                   05540000
         OI    IOBRETRY(IOBREG),INPIND  SET RETRY INDICATOR             05560000
         BC    15,RETRY                 BRANCH TO RETRY I/O REQUEST     05580000
*                                                                       05600000
*   TEST ERROR CONDITIONS POSSIBLE WITH DEVICE END AND UNIT CHECK       05620000
*                                                                       05640000
DEONLY   TM    IOBSENS0(IOBREG),EQUIPCHK TEST FOR EQUIPMENT CHECK       05660000
         BC    1,PERMER                 BRANCH IF PRESENT               05680000
         TM    IOBSENS0(IOBREG),INTVNREQ TEST FOR INTERVENTION REQUIRED 05700000
         BC    1,INTERVEN               BRANCH IF PRESENT               05720000
         TM    IOBSENS0(IOBREG),DATACHEK+ILLGLSEQ TEST FOR DATA CHECK   05740000
*                                                 OR ILLEGAL SEQUENCE   05760000
         BC    5,PERMER                 BRANCH IF EITHER/BOTH PRESENT   05780000
         TM    IOBSENS1(IOBREG),READBCZ+RECFORCG+FILMOTLT+GRAPICHK      05800000
*                                       TEST FOR READ BYTE COUNT ZERO   05820000
*                                       OR RECORDER FORCED GAP OR FILM  05840000
*                                       MOTION LIMIT OR GRAPHIC CHECK   05860000
         BC    5,PERMER                 BRANCH IF ANY/ALL PRESENT       05880000
         BC    15,TESTST                BRANCH TO TEST REMAINDER OF     05900000
*                                       STATUS BITS                     05920000
*                                                                       05940000
*   ATTEMPT TO RETRY WAS NOT SUCCESSFUL                                 05960000
*                                                                       05980000
WTORTN   OI    IOBFLAG3(IOBREG),IOBMSGTP INDICATE PERMANENT ERROR MSG   06000000
         NI    IOBRETRY(IOBREG),X'FF'-RETRYALL    RESET ALL RETRY FLAGS 06020000
WOPOST   NI    IOBFLAG1(IOBREG),X'FF'-IOBECI INDICATE PERM ERROR IN IOB 06040000
         OI    IOBFLAG3(IOBREG),SEROUTID     INDICATE POSTING NEEDED    06060000
         LA    ERREG3,WTO               LOAD WRITE TO OPERATOR ID       06080000
         L     RTNREG,COMADR            LOAD ADDRESS OF COMM VECTOR TBL 06100000
         L     RTNREG,XCLADR(0,RTNREG)  LOAD ADDRESS OF XCTL ROUTINE    06120000
         BCR   15,RTNREG                BRANCH TO XCTL ROUTINE          06140000
*                                                                       06160000
*   INTERVENTION REQUIRED MESSAGE MUST BE WRITTEN TO OPERATOR           06180000
*                                                                       06200000
INTERVEN NI    IOBFLAG3(IOBREG),X'FF'-IOBMSGTP INDICATE I.R. MESSAGE    06220000
         BC    15,WOPOST                BRANCH TO FINISH WTO INTERFACE  06240000
*                                                                       06260000
*                                                                       06280000
         CNOP  0,8                                                      06300000
*                                                                       06320000
*                                                                       06340000
         END                                                            06360000
