IGE0010D CSECT                                                          00200000
         TITLE 'IGE0010D ERROR RTN'                                     00300000
* TITLE:       5450 ERROR RECOVERY PROCEDURE                            00400000
*                                                                       00600000
* STATUS:      CHANGE LEVEL= 0                                          00800000
*                                                                       01000000
* FUNCTION:    ANALYZE STATUS AND SENSE DATA AND ATTEMPT ERROR RECOVERY 01200000
*              IF THE ERROR IS CORRECTED, PROCEED IN A NORMAL MANNER.   01400000
*              IF A PERMANENT ERROR IS DETECTED, INDICATE IT TO THE     01600000
*              USER BY A COMPLETION CODE IN THE ECB.                    01800000
* ENTRY:       IGE001OD                                                 02000000
*                                                                       02200000
* INPUT:       REQUEST ELEMENT POINTER IN REGISTER 1.                   02400000
*                                                                       02600000
* OUTPUT:      NONE                                                     02800000
*                                                                       03000000
* EXITS:       1.ERREXCP EXIT TO I/O SUPERVISOR TO RE-EXECUTE THE       03200000
*                CHANNEL PROGRAM IN ERROR.                              03400000
*              2.SVC 3 TO RETURN CONTROL TO THE SUPERVISOR AND          03600000
*                RELINQUISH CONTROL OVER THE TRANSIENT AREA             03800000
*              3.XCTL EXIT TO STATISTICS UPDATE ROUTINE TO LOG ERROR    04000000
*                THIS ROUTINE WILL RETURN TO THE SUPERVISOR VIA SUC 3.  04200000
*                                                                       04400000
* NOTES:       IOB EXCEPTION AND IOB ERROR FLAGS ARE INTERPRETED AS     04600000
*              FOLLOWS                                                  04800000
*                   IOBEX ON AND IOBERR ON, ERROR RTN. IN CONTROL.      05000000
*                   IOBEX ON AND IOBERR OFF, PERMANENT ERROR.           05200000
*                   IOBEX OFF AND IOBERR OFF, NO ERROR OR CORRECTED.    05400000
*                                                                       05600000
* TABLES:      STATISTICS TABLE AND IOB                                 05800000
*                                                                       06000000
* OPERATION:   THIS ROUTINE CHECKS THE STATUS AND SENSE BYTES STORED IN 06200000
*              THE UCB AND IOB AND TAKES ACTION AS SPECIFIED IN THE     06400000
*              DEVICE STANDARDS. STATISTICS ARE KEPT AS TO THE KIND AND 06600000
*              FREQUENCY OF ERRORS. THESE STATISTICS ARE USED BY THE    06800000
*              CE TO ISOLATE AND RECOGNIZE ERRORS.                      07000000
*              A COMMON INTERPRETER ROUTINE IS USED TO CHECK BOTH       07200000
*              STATUS AND SENSE. ON RETURN FROM THE INTERPRETER THE     07400000
*              PROPER ACTION OF RETRY OR LOG OUT AND EXIT TO STATISTICS 07460000
*              UPDATE ROUTINE IS TAKEN. FOR NON-PERMANENT ERRORS, SVC   07520000
*              15(RETRY CHANNEL PROGRAM) AND SVC 3 ARE EXECUTED. FOR    07580000
*              PERMANENT ERRORS, THE SENSE INFORMATION IS MOVED INTO    07640000
*              BYTES 9 AND 10 OF THE STATISTICS TABLE, THEN EXIT IS     07700000
*              MADE TO THE STATISTICS UPDATE ROUTINE (IGE0025D).        07760000
*              ERRORS CAUSING UNIT CHECKS ARE RETRIED ONCE. NO RETRY IS 07820000
*              PERFORMED FOR PROG. CHECK, PROTECT CHECK,UNIT EXCEPTION. 07880000
*              FOR CHANNEL CHECK ERRORS, THE ERP TRACES BACK THROUGH    08000000
*              THE CCH LINKAGE TO LOCATE THE APPROPRIATE ERP INTERFACE  08200000
*              BYTE (ERPIB) FOR THE CHANNEL ERROR. THE ERPIB IS         08400000
*              GENERATED BY CCH AND CONTAINS DATA WHICH AUGMENTS AND    08600000
*              INFLUENCES SUBSEQUENT RECOVERY HANDLING OF THE ERROR.    08800000
*              IF NO ERPIB IS FOUND FOR THE ERROR, IT WILL BE TREATED   09000000
*              AS A PERMANENT ERROR.                                    09200000
*              IF THE APPROPRIATE ERPIB IS FOUND. A RETRY IS PERFORMED  09240000
*              AND THE ERPIB IS ZEROED.                                 09280000
*              FOR CHANNEL DATA CHECKS, A BIT IS SET IN THE STATISTICS  09320000
*              TABLE. ONE RETRY IS PERFORMED.                           09360000
*                                                                       09400000
*   IOB DEFINITION                 FUNCTION            LENGTH           09600000
IOBFL1   EQU   0                   IOB FLAG 1            1              09800000
IOBFL2   EQU   1                   IOB FLAG 2            1              10000000
IOBSNS   EQU   2          IOBSNS       2                                10200000
IOBCOD   EQU   4                   ECB COMPLETION CODE   1              10400000
INTERCPT EQU   X'7E'               INTERCEPT CONDITION                  10600000
IOBECB   EQU   5                   ECB ADDRESS           3              10800000
IOBFL3   EQU   8                   IOB FLAG 3 - ERROR    1              11000000
IOBCSW   EQU   8                   LAST CSW              8              11200000
IOBSTOCC EQU   16                  SIO CONDITION CODE    1              11400000
IOBSTART EQU   17                  CHANNEL PROG ADDR     3              11600000
IOBDCB   EQU   20                  ADDRESS OF DCB        4              11800000
IOBRSTR  EQU   25                  IOS RESTART ADDR      3              12000000
IOBBCT   EQU   28                                        2              12200000
IOBERCT  EQU   30                  ERROR RETRY COUNT     2              12400000
         SPACE 2                                                        12600000
*  FLAGS IN IOB FLAG 3                                                  12800000
IOBCRJ   EQU   X'80'               COMMAND REJECT COUNT                 13000000
IOBBOE   EQU   X'40'               BUSOUT ERROR COUNT                   13200000
IOBCECE  EQU   X'20'               EQUIPMENT CHECK COUNT                13400000
IOBDCE   EQU   X'10'               DATA CHECK ERROR COUNT               13600000
IOBBPC   EQU   X'08'               BUFFER ADDR PARITY ERROR COUNT       13800000
IOBIBA   EQU   X'04'               INVALID BUFFER ADDR ERROR COUNT      14000000
IOBLOG   EQU   X'01'                                                    14200000
IOBRTCDC EQU   X'40'          CHANNEL DATA CHECK RETRY FLAG             14400000
CDCBIT   EQU   X'01'          CDC BIT - TURNED ON IN STAT TABLE         14600000
*                                                                       14800000
*              INPUT/OUTPUT BLOCK FORMAT                                15000000
*                                                                       15200000
*      ************************************                             15400000
*      *       *        *                 *       FLAG DEFINITIONS      15600000
* + 0  * FLAGS * FLAGS  *  SENSE BYTES    *     FLAGS 1- OFFSET 0       15800000
*      *   1   *   2    *                 *     X'20'-I/O REQUEST UNDER 16000000
*      ************************************           CONTROL OF ERROR  16200000
*      *       *                          *           ROUTINE           16400000
* + 4  * ECB   *    ECB ADDRESS           *     X'04'-IOB EXCEPTION     16600000
*      * CODE  *                          *           LEFT ON IF ERROR  16800000
*      ************************************           UNCORRECTED       17000000
*      *       *                          *     X'01'-START/RESTART     17200000
* + 8  * FLAGS *                          *                             17400000
*      *   3   *    CHANNEL STATUS        *     FLAGS 3- OFFSET 8       17600000
*      *********                          *              RETRY FLAGS    17800000
*      *            WORD                  *     X'80' - COMMAND REJECT  18000000
*      *                                  *     X'40'- BUSOUT CHECK     18200000
*      *                                  *     X'10'- DATA CHECK       18400000
*      ************************************     X'08'- BUFFER ADDRESS   18600000
*      *       *                          *            PARITY CHECK     18800000
* + 16 * SIO   *    START ADDRESS         *     X'04'- INVALID BUFFER   19000000
*      *  CC   *                          *            ADDRESS          19200000
*       ***********************************     X'01'- LOG OUT FLAG     19400000
*      *       *                          *     ERROR COUNT- OFFSET 30  19600000
* + 20 *       *    DCB ADDRESS           *     X'80'- RETRY FOR INTER. 19800000
*      *       *                          *            CONTROL CHECK OR 20000000
*      ************************************            CHAN.CONTR CHECK 20200000
*      *       *                          *     X'40'- RETRY FOR CHAN.  20400000
* + 24 *       *    RESTART ADDRESS       *            DATA CHECK       20600000
*      *       *                          *                             20800000
*      ************************************                             21000000
*      *                *                 *                             21200000
* + 28 *                *  ERROR COUNT    *                             21400000
*      *                *                 *                             21600000
*      ************************************                             21800000
*  TWELVE STAR DEFINITION                                               22000000
TSTLNK   EQU   0                   FORWARD 12* LINK                     22200000
TSTUCB   EQU   2                   UCB POINTER                          22400000
TSTIOB   EQU   5                   IOB POINTER                          22600000
TSTPR    EQU   8                   ENTRY PRIORITY                       22800000
TSTDEB   EQU   9                   DEB POINTER                          23000000
*  FLAGS IN IOB FLAG 1                                                  23200000
IOBDTC   EQU   X'80'               DATA CHAIN FLAG                      23400000
IOBCMC   EQU   X'40'               COMMAND CHAIN FLAG                   23600000
IOBERR   EQU   X'20'               ERROR RTN IN CONTROL FLAG            23800000
IOBMD1   EQU   X'10'               MOD 1 FLAG                           24000000
IOBMD2   EQU   X'08'               MOD 2 FLAG                           24200000
IOBEX    EQU   X'04'               EXCEPT FLAG                          24400000
IOBSRS   EQU   X'01'               START/RESTART FLAG                   24600000
IOBEXE   EQU   IOBEX+IOBERR        EXCEPT AND ERROR FLAGS               24800000
IOBCXE   EQU   255-IOBEXE          CLEAR EXCEPT AND ERROR FLAGS         25000000
         SPACE 2                                                        25200000
*  FLAGS IN IOB FLAG 2                                                  25400000
IOBUEX   EQU   X'08'               WRITE                                25600000
         SPACE 2                                                        25800000
*  UCB DEFINITION                                                       26000000
UCBFL1   EQU   6                   UCB FLAGS                            26200000
UCBSTI   EQU   9                   STATISTICS POINTER                   26400000
* UCB FLAGS                                                             26600000
UCBNRY   EQU   X'40'               UCB NOT READY                        26800000
*  STATUS INDICATORS  -  CSW                                            27000000
CSWPC    EQU   X'20'               PROGRAM CHECK                        27200000
CSWPCK   EQU   X'10'               PROTECTION CHECK                     27400000
CSWCHE   EQU   X'08'               CHANNEL END                          27600000
CSWUCK   EQU   X'02'               UNIT CHECK                           27800000
CSWCCK   EQU   X'01'               CHAINING CHECK                       28000000
CSWVEX   EQU   X'01'               UNIT EXCEPTION                       28200000
CSWCCC   EQU   X'04'               CHANNEL CONTROL CHECK                28400000
CSWICC   EQU   X'02'               INTERFACE CONTROL CHECK              28600000
CSWCDC   EQU   X'08'               CHANNEL DATA CHECK                   28800000
*   MISCELLANEOUS  DEFINITIONS                                          29000000
ABADVEC  EQU   16                  ADDRESS OF VECTOR TABLE              29200000
VECT44   EQU   44                  POINTER TO XCTL ROUTINE              29400000
EXCPER   EQU   15                  EXCP ERROR                           29600000
ERRETURN EQU   3                   RETURN                               29800000
IOBCC1   EQU   X'10'                                                    30000000
STATAB   EQU   112                 NDX TO STATISTICS TABLE              30200000
CNTLAL   EQU   X'0B'                                                    30400000
VECT68   EQU   68                  NDX TO INTERPRETOR ROUTINE PTR       30600000
NORCOD   EQU   X'7F'               IOB  NORMAL CODE                     30800000
VECT116  EQU   116                 PTR TO CHAN CHECK PTR TAB            31000000
IOBCHN   EQU   X'80'               ICC-CCC FLAG                         31200000
DCBFL   EQU   44                                                        31400000
DCBCEX   EQU   X'C0'                                                    31600000
*   RQE DEFINITIONS                                                     31800000
RQEUCB   EQU   0    UCB PTR                                             32000000
RQEIOB   EQU   4                   IOB POINTER                          32200000
IB3037   EQU   67                                                       32400000
IB3069   EQU   69                                                       32600000
IB3130   EQU   130                                                      32800000
WTORTN   EQU   253                 LOAD NAME TO WTO RTN                 33000000
TABEND   EQU   X'FF'                   END OF ERPIB TABLE INDICATOR     33200000
N0       EQU   0             NUMBER                                     33400000
N1       EQU   1             NUMBER                                     33600000
N2       EQU   2             NUMBER                                     33800000
N3       EQU   3             NUMBER                                     34000000
N4       EQU   4             NUMBER                                     34200000
N5       EQU   5             NUMBER                                     34400000
N6       EQU   6             NUMBER                                     34600000
N7       EQU   7             NUMBER                                     34800000
N8       EQU   8             NUMBER                                     35000000
N9       EQU   9             NUMBER                                     35200000
N10      EQU   10            NUMBER                                     35400000
N12      EQU   12            NUMBER                                     35600000
N13      EQU   13            NUMBER                                     35800000
N14      EQU   14            NUMBER                                     36000000
N15      EQU   15            NUMBER                                     36200000
N16      EQU   16            NUMBER                                     36400000
N18      EQU   18            NUMBER                                     36600000
N255     EQU   255           NUMBR                                      36800000
STATUP   EQU   254           DISPLACEMENT                               37000000
VECTXL   EQU   44            IBID.                                      37200000
IOCLBT   EQU   0             IBID.                                      37400000
*   REGISTER EQUATES AND USAGES                                         37600000
PBASE    EQU   15        PROGRAM BASE REG                               37800000
XCTL     EQU   14        PTR TO XCTL ROUTINE                            38000000
XDCB     EQU   13        DCB POINTER                                    38200000
ERRLNK   EQU   12        ERROR LINK REG                                 38400000
XUCB     EQU   11        UCB POINTER                                    38600000
XIOB     EQU   10        IOB POINTER                                    38800000
XSAV     EQU   9         SAVE REGISTER                                  39000000
XVEC     EQU   8         VECTOR TABLE POINTER                           39200000
XLNK     EQU   7         LINK REGISTER                                  39400000
XCCW     EQU   6         CCW POINTER                                    39600000
XER5     EQU   5         WORK REG                                       39800000
XER4     EQU   4         WORK REG                                       40000000
XERP     EQU   3                                                        40200000
X2       EQU   2                                                        40400000
XRQE     EQU   1         RQE POINTER    12*                             40600000
X0       EQU   0                                                        40800000
*     COMPLETION CODE SETTINGS                                          41000000
IOBINT   EQU   X'7E'               IOB INTERCEPT CODE                   41200000
INTCOD   EQU   X'44'               INTERCEPT POST CODE                  41400000
IOBFIN   EQU   X'7F'               NORMAL COMPLETION CODE               41600000
*                                                                       41800000
IBFLG1   EQU   4                   ERPIB BYTE 4                         42000000
IBUNR    EQU   X'01'               UNCONDITIONAL NO-RETRY BIT           42200000
IBSIB1   EQU   X'C0'               SIO                                  42400000
IBSIO1   EQU   X'80'               SIO BIT                              42600000
IBSNS1   EQU   X'04'               VALID SENSE                          42800000
*                                                                       43000000
IBFLG2   EQU   6                   ERPIB BYTE 6                         43200000
IBALL2   EQU   X'1C'               VALIDITY BITS                        43400000
*                                                                       43600000
IBFLG3   EQU   7                   ERPIB BYTE 7 - TERMINATION/RETRY     43800000
IB3001   EQU   1                                                        44000000
IB3002   EQU   2                                                        44200000
IB3003   EQU   3                                                        44400000
IB3004   EQU   4                                                        44600000
IB3005   EQU   5                                                        44800000
*                                                                       44850000
*C622000                                                         A48088 44900000
*                                                                       44950000
*  INITIALIZATION                                                       45000000
*                                                                       45200000
         USING *,15                ESTABLISH PROGRAM BASE               45400000
ER5450   EQU   *                                                        45600000
         L     XIOB,RQEIOB(XRQE)        GET IOB ADDR FROM RQE           45800000
         OI    IOBFL1(XIOB),IOBEXE      INDICATE ERP IN CONTROL         46000000
         L     XVEC,ABADVEC        GET VECTOR TABLE ADDRESS             46200000
         L     XCTL,VECT44(XVEC)   GET XCTL RTN POINTER                 46400000
         L     XDCB,IOBDCB(XIOB)   GET DCB POINTER                      46600000
         LA    XLNK,ERR618         SET ADDR TO SVC 15/SVC3 RETURN       46800000
         LH    XUCB,TSTUCB(XRQE)   POINT TO UCB - PTR DEFINED AS 2 BYTE 47000000
         NI    IOBFL1(XIOB),N255-IOBMD1     CLEAR MODE ONE FLAG         47200000
         L     XER5,STATAB(XVEC)   POINT TO STATISTICS TABLE            47400000
         SR    XER4,XER4           CLEAR REG                            47600000
         IC    XER4,UCBSTI(XUCB)   GET STATAB INDEX FROM UCB            47800000
         MH    XER4,ERRCN2         MULTIPLY BY TEN                      48000000
         AR    XER5,XER4           NDX TO DEVICE ENTRY IN STATAB        48200000
*  TEST CSW FOR CHANNEL CONTROL CHECK OR INTERFACE CONTROL CHECK        48400000
*  BRANCH IF EITHER ON TO FIND ERPIB                                    48600000
         CLI   IOBCOD(XIOB),INTERCPT    Q. INTERCEPT COND.- ASYNC ERROR 48800000
         BE    ERR603                   YES, LOG SENSE INFO AND EXIT    49000000
         TM    IOBCSW+N5(XIOB),CSWCCC+CSWICC  Q.   ICC OR CCC ON        49200000
         BC    N7,ERR630                      YES  CHECK CHANNEL ERROR  49400000
         TM    IOBCSW+N5(XIOB),CSWCDC    Q.   CHANNEL DATA CHECK        49600000
         BNO   ERR600              NO, CHECK FOR UNIT CHECK             49800000
         OI    N1(XER5),CDCBIT     TURN ON BIT IN STAT TABLE            50000000
         TM    IOBERCT(XIOB),IOBRTCDC   Q HAS CHAN DATA C BEEN RETRIED  50200000
         BO    ERR603              YES, EXIT                            50400000
         OI    IOBERCT(XIOB),IOBRTCDC   TURN ON RETRY FLAG              50600000
         B     ERR650              GO RETRY                             50800000
ERR600   EQU   *                                                        51000000
         TM    IOBCSW+N4(XIOB),CSWUCK    Q.   UNIT CHECK                51200000
         BNO   ERR618                   NO   CHECK STATUS INFO          51400000
         LR    XSAV,PBASE               YES  CHECK SENSE INFO - SAV BAS 51600000
         L     PBASE,VECT68(XVEC)  POINT TO RESIDENT INTERPRETER RTN    51800000
ERR601   EQU   *                                                        52000000
         BALR  ERRLNK,PBASE        LINK TO INTERPRET SENSE INFO         52200000
         DC    X'02'                    BUS OUT CHECK                   52400000
         DC    AL1(ERR606-ERR601-N2)         ADDRESS TO BRANCH TO       52600000
         DC    X'04'                    DATA CHECK                      52800000
         DC    AL1(ERR605-ERR601-N4)         ADDRESS TO BRANCH TO       53000000
         DC    X'07'               BUFFER ADDRESS PARITY CHECK          53200000
         DC    AL1(ERR607-ERR601-N6)         ADDRESS TO BRANCH TO       53400000
         DC    X'06'                    INVALID BUFFER ADDRESS          53600000
         DC    AL1(ERR608-ERR601-N8)         ADDRESS TO BRANCH TO       53800000
         DC    X'00'                    COMMAND REJECT                  54000000
         DC    AL1(ERR609-ERR601-N10)        ADDRESS TO BRANCH TO       54200000
         DC    X'2F'                    TEST END - PERMANENT ERROR      54400000
         DC    AL1(ERR603-ERR601-N12)        ADDRESS TO BRANCH TO       54600000
ERR603   EQU   *                   PERMANENT ERROR                      54800000
         OI    IOBFL3(XIOB),IOBLOG      SET LOG OUT FLAG                55000000
         NI    IOBFL1(XIOB),N255-IOBERR   MARK IOB AS PERM ERR          55200000
         NI    IOBFL3(XIOB),N255-IOBLOG  TURN OFF RETRY INDICATORS      55260000
         NI    IOBERCT(XIOB),IOBCHN+IOBRTCDC TURN OFF CHAN RETRY INDIC  55320000
ERR625   EQU   *                                                        55400000
         OC    N8(N1,XER5),IOBSNS(XIOB)    PUT SENSE DATA IN STATAB     55600000
         LA    N13,STATUP           GET ADDR STATUP RTN                 55800000
         BR    N14                  XCTL TO STATISTICS UPDATE RTN       56000000
ERR606   EQU   *              BUSOUT CHECK                              56200000
         TM    IOBFL3(XIOB),IOBBOE  Q.  BUS OUT RETRY                   56400000
         BO    ERR603              YES  CONSIDER PERM ERROR             56600000
         OI    IOBFL3(XIOB),IOBBOE  INDICATE BUS OUT RETRY              56800000
ERR650   EQU   *                                                        57000000
         SVC   EXCPER              ERROR EXCP                           57600000
         SVC   ERRETURN            RETURN                               57800000
ERR605   EQU   *              DATA CHECK                                58000000
         TM    IOBFL3(XIOB),IOBDCE  Q.  DATA CHECK RETRY                58200000
         BO    ERR603              YES  PERM ERROR                      58400000
         OI    IOBFL3(XIOB),IOBDCE NO  INDICATE RETRY                   58600000
         B     ERR650                  GO RETRY                         58800000
ERR607   EQU   *              BUFFER ADDRESS PARITY CHECK               59000000
         TM    IOBFL3(XIOB),IOBBPC  Q.  FIRST CHECK                     59200000
         BO    ERR603               NO  PERM ERROR                      59400000
         OI    IOBFL3(XIOB),IOBBPC      INDICATE RETRY                  59600000
         B     ERR650                   GO RETRY                        59800000
ERR608   EQU   *              INVALID BUFFER ADDRESS                    60000000
         TM    IOBFL3(XIOB),IOBIBA  Q.  FIRST CHECK                     60200000
         BO    ERR603               NO  PERM ERROR                      60400000
         OI    IOBFL3(XIOB),IOBIBA  INDICATE RETRY                      60600000
         B     ERR650               GO RETRY                            60800000
ERR609   EQU   *              COMMAND REJECT                            61000000
         TM    IOBFL3(XIOB),IOBCRJ  Q.  FIRST CHECK                     61200000
         BO    ERR603               NO  PERM ERROR                      61400000
         OI    IOBFL3(XIOB),IOBCRJ  INDICATE RETRY                      61600000
         B     ERR650                  GO RETRY                         61800000
ERR618   EQU   *    PERMANENT ERROR FOR PROG CHECK, PROTECT CHECK, UNIT 61900000
*                   EXCEPTION                                           62000000
         TM    IOBCSW+N5(XIOB),CSWPC+CSWPCK Q. PROTECTION OR PROG CHK   62100000
         BZ    ERR621            NO,THEN ENTERED FROM NORMAL END A48088 62200000
         NI    IOBFL1(XIOB),N255-IOBERR       SET  PERM ERROR           62400000
         SVC   EXCPER              SVC 15 WILL POST PERMANENT ERROR     62600000
         SVC   ERRETURN            AND EXIT                             62800000
*  ERROR CORRECTED                                                      63000000
ERR621   EQU   *                                                        63200000
         L     XER4,IOBDCB(XIOB)        POINT TO DCB                    63400000
         NI    DCBFL(XER4),N255-DCBCEX      RESET DCB EXCEPTION         63600000
         NI    IOBFL1(XIOB),IOBCXE-IOBSRS RESET IOB EX, ERROR, RESTART  63800000
         MVI   IOBFL3(XIOB),IOCLBT      CLEAR ERROR COUNTS              64000000
         NI    IOBCSW+N4(XIOB),N255-CSWUCK  RESET CSW UNIT CHK          64200000
ERR622   EQU   *                                                        64400000
         LA    N13,STATUP                GET STAT UPDATE PTR            64600000
         L     ERRETURN,VECTXL(XVEC)    GET XCTL RTN                    64800000
         BCR   N15,ERRETURN            RETURN                           65000000
ERR630   EQU   *                                                        65200000
         L     XERP,VECT116(XVEC)  POINT TO PARAM TABLE                 65400000
         L     XERP,N0(XERP)        POINT TO CCH PTR TABLE              65600000
         L     XERP,N0(XERP)        POINT TO ERPIB TABLE                65800000
*                                                                       66000000
*   SEARCH ERPIBS - WHEN UCB POINTER SAME AS 12* UCB, ERPIB             66200000
*   FOUND FOR ERROR.                                                    66400000
*   FIRST ERPIB BYTE X'FF' BEFORE MATCH - NO ERPIB                      66600000
*                                                                       66800000
ERR615   EQU   *                                                        67000000
         TM    N0(XERP),TABEND      Q.   END OF ERPIB TABLE             67200000
         BO   ERR603    YES- LOGOUT AND EXIT                            67400000
         L     X2,N0(XERP)         NO GET ERPIB UCB ADDR                67600000
         LA    X2,N0(X2)           CLEAR HIGH BYTE                      67800000
         CLR   X2,XUCB             Q. UCB S MATCH                       68000000
         BE    ERR670              YES-TEST ERPIB                       68200000
         LA    XERP,N8(XERP)        NEXT ERPIB                          68400000
         B     ERR615              LOOP                                 68600000
*                                                                       68800000
*        ERPIB FOUND - CHECK IF RETRY - IF ICC-CCC CAUSED BY ICC-CCC    69000000
*        RETRY, PERMANET ERROR                                          69200000
*                                                                       69400000
ERR670   EQU   *                                                        69600000
         TM    IOBERCT(XIOB),IOBCHN     Q.   RETRY OF ICC-CCC           69800000
         BO    ERR685                   YES  BR                         70000000
*                                                                       70200000
*        TEST FOR IOB INTERCEPT                                         70400000
*                                                                       70600000
         CLI   IOBCOD(XIOB),IOBINT      Q.   IOB INTERCEPTED            70800000
         BE    ERR680                   YES  BR                         71000000
*                                                                       71200000
*        TEST FOR UNCONDITIONAL NO-RETRY                                71400000
*                                                                       71600000
         TM    IBFLG1(XERP),IBUNR                                       71800000
         BO    ERR685                   YES  BR                         72000000
ERR651   EQU   *                                                        72200000
         OI    IOBERCT(XIOB),IOBCHN     SET RETRY                       72400000
         XC    N0(N8,XERP),N0(XERP)    ZERO ERPIB                       72600000
         B     ERR650              GO ISSUE RETRY AND RETURN            72900000
ERR680   EQU   *                                                        73200000
         MVI   IOBCOD(XIOB),INTCOD      SET INTERCEPT CODE              73400000
ERR685   EQU   *                                                        73600000
         XC    N0(N8,XERP),N0(XERP)    CLEAR ERPIB                      73800000
         B     ERR603                  GO LOG OUT AND EXIT              74000000
* CONSTANTS                                                             74200000
ERRCN1   DC    H'08'               CCW LENGTH                           74400000
ERRCN2   DC    H'10'               MULTIPLIER                           74600000
         END                                                            74800000
