         TITLE 'IGG0193L - LOAD 3 BASIC GRAPHICS OPEN EXECUTOR'         00100019
IGG0193L CSECT                                                          00200019
* 170440-170760,361200-361600,370300-370600                      A25381 00230019
*A228300-228600,A370700                                          A35615 00240000
* C212000                                                        A38909 00250021
* A228700,A228800                                                A38909 00252021
* D170100-171000,D261000                                         A40756 00254000
* A170300-171500, A226300-226600, A2665000                       A40756 00256000
* A103100-103500,A389300-389600                                  A40953 00258000
*A171600-171700,332500                                           A55318 00259021
*A111500                                                     JLM A57385 00259521
         EJECT                                                          00260019
*********************************************************************** 00300019
*                                                                     * 00400019
* TITLE - IGG0193L - LOAD 3 BASIC GRAPHICS OPEN EXECUTOR              * 00500019
*                                                                     * 00600019
* FUNCTION - 1. LOADS                                                 * 00700019
*                A.BUFFER PROTECTION(2250 ONLY)  ****************     * 00800019
*                B.GAS                           *              *     * 00900019
*                C.GEIR                          * BASIC ONLY   *     * 01000019
*                D.TE                            *              *     * 01100019
*                I.IFFCAN03                      ****************     * 01200019
*                                                                     * 01300019
* ENTRY POINT - ENTERED BY GRAPHICS OPEN EXECUTOR LOAD 2 AT IGG0193L  * 01400019
*                                                                     * 01500019
* INPUT - PARAMETER LIST ADDRESS IN REGISTER 7                        * 01600019
*                                                                     * 01700019
* OUTPUT - 1. IRB'S FOR-                                              * 01800019
*                 A.GAS                                               * 01900019
*                 B.IFFCAN03                                          * 02000019
*          2.IQE'S FOR-                                               * 02100019
*                 A.GAS                                               * 02200019
*                 B.IFFCAN03                                          * 02300019
*                 C.TE                                                * 02400019
*                                                                     * 02500019
* EXTERNAL                                                            * 02600019
* REFERENCES - 1.GETMAIN                                              * 02700019
*              2.FREEMAIN                                             * 02800019
*              3.CIRB                                                 * 02900019
*              4.LOAD                                                 * 03000019
*              5.XCTL                                                 * 03100019
*                                                                     * 03200019
* EXITS - 1.NORMAL - OS/360 OPEN                                      * 03300019
*         2.ABNORMAL - ABEND SVC                                      * 03400019
*                                                                     * 03500019
* RETURN CODES - N/A                                                  * 03600019
*                                                                     * 03700019
* TABLES/WORK AREAS - DSECTS DESCRIBED IN LISTING                     * 03800019
*                                                                     * 03900019
* ATTRIBUTES - 1.REENTRANT                                            * 04000019
*              2.ENABLED                                              * 04100019
*              3.PRIVILEDGED                                          * 04200019
*                                                                     * 04300019
* NOTES - ALL NOTES CONTAINED IN LISTING                              * 04400019
*                                                                     * 04500019
         EJECT                                                          04600019
*********************************************************************** 04700019
*                            REGISTER EQUATES                         * 04800019
*                                                                     * 04900019
*********************************************************************** 05000019
RE       EQU   0                  WORK/PARAMETER REGISTER               05100019
RF       EQU   1                  WORK/PARAMETER REGISTER               05200019
RDCB     EQU   2                  DCB ADDRESS REGISTER                  05300019
RTE      EQU   2                  TE ADDRESS                            05400019
RBASE    EQU   3                  BASE REGISTER                         05500019
RIRB     EQU   4                  GAR IRB ADDRESS                       05600019
RPAR     EQU   5                  PARAMETER LIST REGISTER               05700019
RWTG     EQU   6                  WHERE-TO-GO TABLE                     05800019
RPARC    EQU   7                  CURRENT PARAMETER LIST ENTRY          05900019
RWTGC    EQU   8                  CURRENT WTG TABLE ENTRY               06000019
TCBREG   EQU   9                  TCB ADDRESS                           06100019
RCOUNT   EQU   10                 LOOP COUNTER REG                      06200019
RUCB     EQU   10                 CURRENT UCB ADDRESS                   06300019
RDEB     EQU   11                 DEB ADDRESS                           06400019
RC       EQU   12                 WORK REG                              06500019
SAVER    EQU   13                 BASE REG FOR SAVE                     06600019
RD       EQU   14                 WORK/PARAMETER REG                    06700019
RJ       EQU   15                 WORK/PARAMETER REG                    06800019
         EJECT                                                          06900019
*********************************************************************** 07000019
*                                                                     * 07100019
*                        INITIALIZATION                               * 07200019
*                                                                     * 07300019
*********************************************************************** 07400019
         USING IHADCB,RDCB        BASE REG FOR DCB DSECT                07500019
         USING IECTDEB,RDEB       BASE REG FOR DEB DSECT                07600019
         BALR  RBASE,ZERO              SET UP                           07700019
         USING *,RBASE                     BASE REGISTER                07800019
*********************************************************************** 07900019
*                                                                     * 08000019
*  GETMAIN FOR SAVE AREA TO BE USED BY GIOCR WHEN THE READ MANUAL     * 08100019
*  INPUT IS ISSUED TO UNLOCK THE KEYBOARD. THE SAVE AREA WILL ALSO BE * 08200019
*  USED TO TEMPORARILY STORE THE USER'S DECB                          * 08300019
*                                                                     * 08400019
*********************************************************************** 08500019
         GETMAIN  R,LV=116,SP=253                                       08600019
         LR    SAVER,RF                SET UP BASE REG TO               08700019
         USING SAVEAREA,SAVER          SAVE AREA                        08800019
         L     RDCB,ZERO(RPARC,ZERO)   INITIALIZE DCB BASE REG          08900019
*********************************************************************** 09000019
*                                                                     * 09100019
*  SAVE DCB POINTER INTO DECB                                         * 09200019
*                                                                     * 09300019
*********************************************************************** 09400019
         ST    RDCB,DECBDCB            SAVE DCB ADDRESS                 09500019
         L     RDEB,DCBDEBAD           INITIALIZE DEB BASE REG          09600019
         LA    RDEB,ZERO(ZERO,RDEB)    CLEAR HIGH ORDER BYTE            09700019
         S     RDEB,DISPDEB            GET CORRECT DEB BASE             09800019
*********************************************************************** 09900019
*                                                                     * 10000019
* IF DCBGTYPE=BASIC PROCEED-IF NOT DO RMI AND XCTL                    * 10100019
*                                                                     * 10200019
*********************************************************************** 10300019
         L     RD,DEBUCBAD         UCB ADDRESS                   A40953 10310000
         CLC   18(2,RD),DEV2280    2280 ?                        A40953 10320000
         BE    OAM210              YES-XCTL OUT                  A40953 10330000
         CLC   18(2,RD),DEV2282    2282 ?                        A40953 10340000
         BE    OAM210              YES-XCTL OUT                  A40953 10350000
         TM    DCBGTYPE,BASIC          IS THIS A BASIC SYSTEM           10400019
         BZ    OAM210                  NO -- XCTL OUT                   10500019
         SR    RD,RD                   CLEAR SUB ID REGISTER            10600019
         LA    RUCB,DEBUCBAD           SUB ID SECTION FOLLOWS UCBS      10700019
         IC    RD,DEBNMEXT             GET NUMBER OF UCBS               10800019
         SLL   RD,TWO                  ACCESS ACTUAL SIZE OF UCBS       10900019
         AR    RUCB,RD                 PTR TO SUB ID SECTION            11000019
         SR    RD,RD                   CLEAR SUB COUNT REGISTER         11100019
         IC    RD,DEBNMSUB       # ROUTINES ALREADY LOADED   JLM A57385 11150021
         MVI   N22(RWTG),ATBL          SET REENTRANT ATTRIBUTE          11200019
OAM218   L     RF,CVTADPTR             GET ADDRESS OF CVT               11300019
         L     TCBREG,CVTTCBP(RF)      GET ADDRESS OF NEW/OLD TCBS      11400019
         L     TCBREG,TCBLST(TCBREG)   GET ADDRESS OF OLD TCB           11500019
         EJECT                                                          11600019
*********************************************************************** 11700019
*                                                                     * 11800019
*                        LOAD GAS                                     * 11900019
*                                                                     * 12000019
*********************************************************************** 12100019
         L     RF,COMVECPT(ZERO,ZERO)  GET POINTER TO CVT               12200019
         L     RF,DCBOFF(ZERO,RF)      GET SVC DCB ADDRESS              12300019
         LOAD  EP=IGG019OE,DCB=(1)                                      12400019
         ST    RE,GARSVE               SAVE GAR ADDRESS                 12500019
         LA    RF,GAS                  GET GAS ID ADDRESS               12600019
         LA    RUCB,FOUR(RUCB)         POINT TO DEB SUB ID SECTION      12650019
         MVC   ZERO(TWO,RUCB),ZERO(RF)     MOVE ID TO DEB               12700019
         LA    RUCB,TWO(ZERO,RUCB)     POINT TO NEXT DEB SUBID SECTION  12800019
         LA    RD,ONE(ZERO,RD)         INCREMENT ROUTINES LOADED COUNT  12900019
         STC   RD,DEBNMSUB             STORE COUNT IN DEB               13000019
*********************************************************************** 13100019
*                                                                     * 13200019
*                        LOAD GEIR                                    * 13300019
*                                                                     * 13400019
*********************************************************************** 13500019
         L     RF,COMVECPT             GET POINTER TO CVT               13600019
         L     RF,DCBOFF(ZERO,RF)      GET SVC DCB ADDRESS              13700019
         LOAD  EP=IGG019OJ,DCB=(1)                                      13800019
         ST    RE,GEIRSVE              SAVE GEIR ADDRESS                13900019
         LA    RF,GIR                  LOAD GEIR ID ADDRESS             14000019
         MVC   ZERO(TWO,RUCB),ZERO(RF)   MOVE ID TO DEB                 14100019
         LA    RUCB,TWO(RUCB)          POINT TO NEXT SUB ID SECTION     14150019
         LA    RD,ONE(ZERO,RD)         INCREMENT ROUTINE LOADED COUNT   14200019
         STC   RD,DEBNMSUB             STORE COUNT IN DEB               14300019
         L     RF,DEBUCBAD              GET UCB ADDRESS FROM DEB  M4218 14320019
         LH    RJ,EIGHTEEN(RF)          LOAD DEVICE AND UNIT TYPE M4218 14340019
         CH    RJ,DEV2250               IS THIS A 2250 ?          M4218 14360019
         BNE   NOCAN03                  NO - DO NOT LOAD IFFCAN03 M4218 14380019
*********************************************************************** 14400019
*                                                                     * 14500019
*                        LOAD IFFCAN03                                * 14600019
*                                                                     * 14700019
*********************************************************************** 14800019
         LOAD  EP=IFFCAN03                                              14900019
         ST    RE,CAN03SVE             SAVE IFFCAN03 ADDRESS            15000019
         LA    RF,CAN03                LOAD IFFCAN03 ID ADDRESS         15100019
         MVC   ZERO(TWO,RUCB),ZERO(RF)    MOVE ID TO DEB                15200019
         LA    RD,ONE(ZERO,RD)         INCREMENT ROUTINES LOADED COUNT  15300019
         STC   RD,DEBNMSUB             STORE COUNT IN DEB               15400019
NOCAN03  L     RTE,DEBUCBAD             LOAD FIRST UCB POINTER    M4218 15500019
         SSM   DISABLE                                                  15600019
         EJECT                                                          15700019
*********************************************************************** 15800019
*                                                                     * 15900019
*                        DOES TE EXIST FOR TASK - CHECK OTHER DEBS    * 16000019
*                          IN TASK                                    * 16100019
*                                                                     * 16200019
*********************************************************************** 16300019
         L     RTE,USERTE(RTE)         LOAD UCB TE FIELD                16400019
         LA    RTE,ZERO(RTE)           CLEAR HIGH-ORDER BYTE            16500019
         LTR   RTE,RTE                 DOES TE ADDRESS EXIST IN UCB     16600019
         BP    SETSSM                  BRANCH IF YES                    16700019
         L     RD,EIGHT(TCBREG)        LOAD FIRST DEB IN TCBDEB CHAIN   16800019
         LA    RD,ZERO(RD)             CLEAR HIGH ORDER BYTE            16900019
OAM200   EQU   *                                                        16910019
         SPACE 3                                                        16920019
***                 TEST FOR A DUMMY DEB OR A DEB WITHOUT        A25381 16930019
*                   ANY EXTENTS.                                 A25381 16940019
*                                                                A25381 16950019
*                   THE DEB WILL BE SCANNED FOR EXTENTS. FOR     A25381 16960019
*                   GRAPHICS THERE WILL BE AT LEAST ONE EXTENT   A25381 16970019
*                                                                A25381 16980019
         TM    EXTNUMB(RD),FULLMASK    ARE THERE ANY EXTENTS     A25381 16990019
         BZ    NEXTDEB                 IF NOT TAKE BRANCH        A25381 17000019
         LA    RF,UCBADR(RD)      PTR TO FIRST UCB ADDR          A40756 17030000
UCBA     L     RUCB,ZERO(RF)      LOAD FIRST UCB ADDRESS         A40756 17060000
         LA    RF,FOUR(RF)        POINT TO NEXT UCB ADDRESS      A40756 17090000
         LTR   RUCB,RUCB          UCB ADDRESS=0                  A40756 17120000
         BZ    UCBA               YES, CHECK NEXT UCB            A40756 17150000
         TM    UCBID(RUCB),FULLMASK     IS THIS A VALID UCB?     A55318 17160021
         BZ    UCBA                     BRANCH IF NO.            A55318 17170021
         LH    RF,EIGHTEEN(RUCB)       LOAD DEVICE AND UNIT TYPE        17200019
         CH    RF,DEV2250              IS THIS A 2250 - CODE 1002       17300019
         BE    OAM201                  YES                              17400019
         CH    RF,DEV2260              IS THIS A 2260 - CODE 1003       17500019
         BE    OAM201                  YES                              17600019
         CH    RF,DEV1053              IS THIS A 1053 - CODE 1004       17700019
         BE    OAM201                  YES                              17800019
NEXTDEB  L     RD,FOUR(RD)             LOAD DEB LINK FIELD              17900019
         LA    RD,ZERO(RD)             CLEAR HIGH ORDER BYTE            18000019
         C     RD,ZERO1                IS LINK FIELD 0                  18100019
         BE    OAM202                  YES                              18200019
         B     OAM200                  TEST DEVICE AND TYPE AGAIN       18300019
OAM201   L     RTE,USERTE(RUCB)        LOAD TE FIELD FROM UCB           18400019
         LA    RTE,ZERO(RTE)           CLEAR HIGH ORDER BYTE            18500019
         LTR   RTE,RTE                 IS TE FIRLD 0                    18600019
         BZ    NEXTDEB                 YES                              18700019
         B     OAM203                  OTHERWISE BRANCH TO BUILD IQES   18800019
         EJECT                                                          18900019
*********************************************************************** 19000019
*                                                                     * 19100019
*                        ISSUE GETMAIN FOR TE                         * 19200019
*                                                                     * 19300019
*********************************************************************** 19400019
OAM202   L     RE,TE                   LOAD TE BYTE REQUEST             19500019
         GETMAIN  R,LV=(0)                                              19600019
         XC    ZERO(WAOFF,RF),ZERO(RF)    CLEAR TE CORE TO ZERO         19700019
         LR    RTE,RF                  SAVE TE ADDRESS                  19800019
*********************************************************************** 19900019
*                                                                     * 20000019
*                        CREATE IRBS FOR GAR AND IFFCAN03             * 20100019
*                                                                     * 20200019
*********************************************************************** 20300019
         L     RE,GARSVE               LOAD GAR ADDRESS                 20400019
         CIRB  EP=(0),SVAREA=YES,WKAREA=1,MODE=SUPR,KEY=SUPR            20500019
         ST    RF,TEGARIRB(RTE)        STORE GAR IRB ADDRESS IN TE      20600019
         ST    TCBREG,TETCB(RTE)       STORE CURRENT TCB ADDRESS IN TE  20700019
         MVC   TEGIR(FOUR,RTE),GEIRSVE      STORE GEIR ADDRESS IN TE    20800019
         OI    TEFLG(RTE),TEFLAG       INDICATE THIS IS A TE            20900019
         XC    NEXT(FOUR,RF),NEXT(RF)   CLEAR NEXTAVAIL FIELD IN IRB    21000019
*                                                                       21100019
         L     RUCB,DEBUCBAD            GET UCB ADDRESS FROM DEB  M4218 21110019
         LH    RJ,EIGHTEEN(RUCB)        LOAD DEVICE AND UNIT TYPE M4218 21120019
         CH    RJ,DEV2250               IS THIS A 2250 ?          M4218 21130019
         BNE   OAM203                   NO - DO NOT CREATE CAW03  M4218 21140019
*                                            IRB                  M4218 21150019
CAN03IRB L     RE,CAN03SVE             LOAD IFFCAN03 ADDRESS     A38909 21200021
         CIRB  EP=(0),SVAREA=YES,WKAREA=1,MODE=SUPR,KEY=SUPR            21300019
         ST    RF,ZERO(RTE)            STORE IFFCAN03 IRB ADDR IN TE    21400019
         XC    NEXT(FOUR,RF),NEXT(RF)    CLEAR NEXT AVAIL FIELD IN IRB  21500019
         EJECT                                                          21600019
*********************************************************************** 21700019
*                                                                     * 21800019
*                PREPARE FOR GAR/IFFCAN03 IQES                        * 21900019
*                                                                     * 22000019
*********************************************************************** 22100019
OAM203   SR    RD,RD                   CLEAR REGISTER                   22200019
         L     RIRB,TEGARIRB(RTE)      LOAD GAR IRB ADDRESS FROM TE     22300019
         IC    RD,DEBNMEXT             LOAD NUMBER OF UCB EXTENTS       22400019
         LA    RC,DEBUCBAD             LOAD PTR TO FIRST UCB ADDR       22500019
OAM204   L     RUCB,ZERO(RC)           LOAD UCB ADDR                    22600019
         LTR   RUCB,RUCB          UCB ADDRESS=0                  A40756 22630000
         BZ    NEXTUCB            YES, CHECK NEXT UCB            A40756 22660000
         CLI   TYPE(RUCB),T2260        IS DEVICE A 2260                 22700019
         BE    ONEIQE                  YES - GET ONE IQE                22800019
         CLI   TYPE(RUCB),T1053    IS DEVICE A 1053              A35615 22830020
         BE    ONEIQE              YES - GET ONE IQE             A35615 22860020
         CLC   ZERO(FOUR,RTE),ZERO1  DOES IFFCAN03 IRB EXIST     A38909 22870021
         BE    CAN03IRB              NO, CREATE ONE              A38909 22880021
         LA    RCOUNT,THREE            LOAD LOOP COUNT FOR 2250         22900019
*********************************************************************** 23000019
*                                                                     * 23100019
*                        ISSUE GETMAIN FOR IFFCAN03 IQE               * 23200019
*                                                                     * 23300019
*********************************************************************** 23400019
         L     RE,IQE                  LOAD BYTE REQUEST FOR CAN03 IQES 23500019
         GETMAIN  R,LV=(0)                                              23600019
         L     RIRB,ZERO(RTE)          GET CAN03 IRB ADDRESS            23700019
         ST    RIRB,EIGHT(RF)          STORE CAN03 IRB ADDR IN CAN03IQE 23800019
         MVC   ZERO(FOUR,RF),NEXT(RIRB)   MOVE ADDR TO IQE LINK FIELD   23900019
         ST    RF,NEXT(RIRB)           STORE IQE ADDR IN IRB NEXTAVAIL  24000019
         XC    FOUR(FOUR,RF),FOUR(RF)   ZERO PARM FIELD IN IQE          24100019
         ST    TCBREG,IQETCB(RF)       STORE TCB ADDR TO IQE            24200019
         B     GARIQES                 GET IQE/S FOR GAR                24400019
ONEIQE   LA    RCOUNT,ONE              LOAD LOOP COUNT FOR 2260         24500019
         EJECT                                                          24600019
*********************************************************************** 24700019
*                                                                     * 24800019
*                        ISSUE GETMAIN FOR GAR IQE/S                  * 24900019
*                                                                     * 25000019
*********************************************************************** 25100019
GARIQES  L     RIRB,TEGARIRB(RTE)       REINITIALIZE GAR'S IRB    M4218 25140019
*                                            ADDRESS                    25180019
         L     RE,IQE                   LOAD BYTE REQUEST FOR     M4218 25220019
*                                            GAR IQE'S            M4218 25260019
         GETMAIN  R,LV=(0)                                              25300019
         ST    RIRB,EIGHT(RF)          STORE GAR IRB ADDR IN IQE        25400019
         MVC   ZERO(FOUR,RF),NEXT(RIRB)   MOVE ADDR TO IQE LINK FIELD   25500019
         ST    RF,NEXT(RIRB)           STORE IQE ADDR IN IRB NEXTAVAIL  25600019
         XC    FOUR(FOUR,RF),FOUR(RF)    ZERO PARM FIELD IN IQE         25700019
         ST    TCBREG,IQETCB(RF)       STORE TCB ADDR IN IQE            25800019
         BCT   RCOUNT,GARIQES          BRANCH IF MORE IQES FOR DEVICE   25900019
         L     RUCB,ZERO(RC)           RELOAD UCB ADDRESS               26000019
         ST    RTE,USERTE(RUCB)        STORE TE ADDRESS IN UCB          26200019
         OI    GCB(RUCB),BASIC1        INDICATE BASIC UCB               26300019
         OI    GCB(RUCB),PROATTN       BIT TURNED ON TO INDICATE A32068 26320020
*                                      THAT ATTENTIONS WILL BE   A32068 26340020
*                                      ACCEPTED FROM THIS DEVICE A32068 26360020
         L     RF,TEUSECT(RTE)         LOAD TE USE COUNT                26400019
         LA    RF,ONE(RF)              INCREMENT USE COUNT BY ONE       26500019
         ST    RF,TEUSECT(RTE)         STORE UPDATED COUNT              26600019
NEXTUCB  LA    RC,FOUR(RC)        POINT TO NEXT UCB ADDRESS      A40756 26650000
         BCT   RD,OAM204               BRANCH IF MORE UCBS TO SERVICE   26700019
SETSSM   SSM   ENABLE                                                   26800019
OAM210   L     RC,FOUR(RWTGC)          GET WORK AREA ADDRESS            26900019
         MVC   N22(SEVEN,RWTG),CONTAB   RESTORE WTG                     27000019
         XC    ZERO(TWO,RWTGC),ZERO(RWTGC)   CLEAR ID IND COMPLETION    27100019
RELOOP   EQU   *                                                        27200019
         LA    RWTGC,WGOFF(RWTGC)      BUMP CURRENT WTG REGISTER        27300019
         LA    RPARC,PLOFF(RPARC)      BUMP CUR PARM REG TO NEXT ENTRY  27400019
         CLC   ZERO(TWO,RWTGC),GIDCNST1     CHECK NEXT WTG ENTRY        27500019
         BCR   EIGHT,RBASE             YES START AGAIN                  27600019
         CLC   ZERO(TWO,RWTGC),OPIDCNST    NO TEST FOR END OF TABLE     27700019
         BNE   RELOOP                   NOT EQUAL CHECK NEXT ENTRY      27800019
         LR    RPARC,RPAR               RESET CURRENT WTG REG           27900019
         LA    RWTGC,WAOFF(RWTG)        RESET CURRENT PARM REG          28000019
ZCHECK   EQU   *                                                        28100019
         CLI   ZERO(RWTGC),ZEROENT      TEST FOR ZERO ENTRY             28200019
         BNE   RMI                      NOT - XCTL                      28300019
         LA    RWTGC,WGOFF(RWTGC)      ZERO - GET NEXT ENTRY AND        28400019
         LA    RPARC,PLOFF(RPARC)      RETURN TO ZCHECK                 28500019
         B     ZCHECK                  RETURN                           28600019
         EJECT                                                          28700019
*********************************************************************** 28800019
*                                                                     * 28900019
*                        TRANSFER CONTROL ROUTINE                     * 29000019
*                                                                     * 29100019
*********************************************************************** 29200019
RMI      CLI   TYPE(RUCB),T2250        IS DEVICE A 2250                 29300019
         BNE   FREESAVE                NO                               29400019
         SPACE 1                                                        29500019
*                                                                       29600019
*   THE FOLLOWING CODE IS A SIMULATED MACRO EXPANTION FOR A GRAPHIC     29700019
*   READ MANUAL INPUT.                                                  29800019
*                                                                       29900019
         SPACE 1                                                        30000019
         L     RDCB,DECBDCB            GET POINTER TO DCB               30100019
         XC    DECBECB(DECBLN),DECBECB      CLEAR DECB                  30200019
         ST    RDCB,DECBDCB            RESTORE POINTER TO DCB           30300019
         MVI   DECBTYPE,RMICODE        SET RMI AS TYPE OF READ          30400019
         LA    RF,RMIAREA              PUT POINTER TO INPUT             30500019
         ST    RF,DECBADDR             AREA INTO DECB                   30600019
         LA    RF,DECBECB              LOAD PARM LIST FOR GIOCR         30700019
         L     RJ,GIOCRAD(RDCB)        GET GIOCR'S ENTRY ADDRESS        30800019
         BALR  RD,RJ                   BRANCH TO GIOCR                  30900019
         LTR   RJ,RJ                   WAS READ STARTED                 31000019
         BNE   FREESAVE                NO                               31100019
         WAIT  ECB=DECBECB                                              31200019
*********************************************************************** 31300019
*                                                                     * 31400019
*                        ISSUE FREEMAIN FOR SAVE AREA AND XCTL        * 31500019
*                                                                     * 31600019
*********************************************************************** 31700019
FREESAVE FREEMAIN  R,LV=116,A=(13),SP=253                               31800019
*                                                                       31900019
         MVC   SIX(TWO,RWTG),ZERO(RWTGC)     MOVE ID TO NAME            32000019
         MVC   TTROFF(THREE,RWTG),TWO(RWTGC)     MOVE TO TTR ROUTINE    32100019
         LA    RJ,DXCCW12(RC)          GET ADDRESS OF NEW NAME FOR XCTL 32200019
         XCTL  DE=(RWTG),SF=(E,(RJ))                                    32300019
         EJECT                                                          32400019
*********************************************************************** 32500019
*                                                                     * 32600019
*                        EQUATES                                      * 32700019
*                                                                     * 32800019
*********************************************************************** 32900019
CVTTCBP  EQU   0                                                        33000019
ONE      EQU   1                                                        33100019
TWO      EQU   2                                                        33200019
UCBID    EQU   2                        OFFSET OF UCBID FIELD    A55318 33250021
THREE    EQU   3                                                        33300019
PLOFF    EQU   4                                                        33400019
TCBLST   EQU   4                                                        33500019
SIX      EQU   6                                                        33600019
SEVEN    EQU   7                                                        33700019
EIGHT    EQU   8                                                        33800019
TETCB    EQU   8                                                        33900019
WGOFF    EQU   8                                                        34000019
FOUR     EQU   4                                                        34100019
ZERO     EQU   0                                                        34200019
GIOCRAD  EQU   48                                                       34300019
DECBLN   EQU   32                                                       34400019
GCB      EQU   27                                                       34500019
UCBADR   EQU   32                                                       34600019
TEUSECT  EQU   16                                                       34700019
TEFLG    EQU   20                                                       34800019
TEGARIRB EQU   24                                                       34900019
TEGIR    EQU   28                                                       35000019
NEXT     EQU   96                                                       35100019
TYPE     EQU   19                                                       35200019
IQETCB   EQU   12                                                       35300019
USERTE   EQU   28                                                       35400019
DCBOFF   EQU   84                                                       35500019
COMVECPT EQU   16                                                       35600019
WAOFF    EQU   32                                                       35700019
TTROFF   EQU   14                                                       35800019
N22      EQU   22                                                       35900019
EIGHTEEN EQU   18                                                       36000019
CVTADPTR EQU   16                                                       36100019
EXTNUMB  EQU   16                      DISP INTO DEB FOR EXTENTS A25381 36150019
*                                                                       36200019
T2250    EQU   X'02'                                                    36300019
BASIC1   EQU   X'08'                                                    36400019
PROATTN  EQU   X'40'                   GCB FLAG INDICATES THAT   A32068 36420020
*                                      ATTNS WILL BE ACCEPTED    A32068 36440020
*                                      FROM THIS DEVICE          A32068 36460020
BASIC    EQU   X'01'                                                    36500019
ZEROENT  EQU   X'00'                                                    36600019
TEFLAG   EQU   X'80'                                                    36700019
T2260    EQU   X'03'                                                    36800019
DXCCW12  EQU   X'1C8'                                                   36900019
ATBL     EQU   X'CA'                                                    37000019
FULLMASK EQU   X'FF'                   MASK OF ALL ONES          A25381 37050019
T1053    EQU   X'04'               1053 DEVICE TYPE              A35615 37070020
         EJECT                                                          37100019
*********************************************************************** 37200019
*                                                                     * 37300019
*                        CONSTANTS                                    * 37400019
*                                                                     * 37500019
*********************************************************************** 37600019
         SPACE 1                                                        37700019
         DS    0F                                                       37800019
RMIAREA  DC    F'0'                    RMI DATA AREA                    37900019
ZERO1    DC    F'0'                                                     38000019
IQE      DC    X'FD'                   SUBPOOL 253                      38100019
         DC    AL3(16)                 BYTE REQUEST (IQES)              38200019
TE       DC    X'FF'                   SUBPOOL 255                      38300019
         DC    AL3(32)                 TE BYTE REQUEST                  38400019
DISPDEB  DC    A(DEBNMSUB-DEBEOEA)                                      38500019
OPIDCNST DC    C'0S'                    END OF TABLE              M4216 38600019
GIDCNST1 DC    C'3Z'                                                    38700019
DEV2250  DC    XL2'1002'                                                38800019
DEV2260  DC    XL2'1003'                                                38900019
DEV2280  DC    XL2'1005'                                         A40953 38930000
DEV2282  DC    XL2'1006'                                         A40953 38960000
DEV1053  DC    XL2'1004'                                                39000019
GAS      DC    C'OE'                                                    39100019
CAN03    DC    C'03'                                                    39200019
GIR      DC    C'OJ'                                                    39300019
CONTAB   DC    X'C3780004000400'                                        39400019
DISABLE  DC    X'00'                                                    39500019
ENABLE   DC    X'FF'                                                    39600019
         ORG   IGG0193L+984                                             39700019
XCTLEND  DC    X'0000'                                                  39800019
         ORG   IGG0193L+1020                                            39900019
         DC    C'019'                                                   40000019
         DC    X'7B'                                                    40100019
         EJECT                                                          40200019
*********************************************************************** 40300019
*                                                                     * 40400019
*                        DSECTS                                       * 40500019
*                                                                     * 40600019
*********************************************************************** 40700019
         SPACE 3                                                        40800019
*                                                                       40900019
         SPACE 3                                                        41000019
*********************************************************************** 41100019
*                                                                     * 41200019
*                        GRAPHIC DEB DUMMY SECTION                    * 41300019
*                                                                     * 41400019
*********************************************************************** 41500019
         SPACE 1                                                        41600019
IECTDEB  DSECT                                                          41700019
DEBEOEA  DS    CL4                     END OF EXTENT APP ROUTINE PTR    41800019
DEBSIOA  DS    CL4                     START I/O APP ROUTINE PTR        41900019
DEBPCIA  DS    CL4                     PROG CONTROL APP ROUTINE PTR     42000019
DEBCEA   DS    CL4                     CHANNEL END APP ROUTINE PTR      42100019
DEBXCEA  DS    CL4                     EX CHANNEL END APP ROUTINE PTR   42200019
DEBWKARA DS    CL1                     I/O SUPPORT WORK AREA            42300019
DEBDSCBA DS    CL7                     I/O SUPPORT DSCB AREA            42400019
DEBDCBMK DS    CL4                     I/O DCB MODIFICATION MASK        42500019
DEBLNGTH DS    CL4                     DEB LENGTH IN DOUBLE WORDS       42600019
DEBNMSUB DS    CL1                     NO. SUBROUTINES LOADED BY OPEN   42700019
DEBTCBAD DS    CL3                     TCB ADDR OF THIS DEB             42800019
DEBAMLNG DS    CL1                     NO. BYTES IN ACCESS METHOD SECT  42900019
DEBDEBAD DS    CL3                     NEXT DEB PTR IN THIS TASK        43000019
DEBOFLGS DS    CL1                     DATA SET STATUS FLAG             43100019
DEBIRBAD DS    CL3                     IRB ADDR FOR ERROR EXIT          43200019
DEBOPATB DS    CL1                     FILE TYPES                       43300019
DEBSYSPG DS    CL3                     SYSTEM PURGE CHAIN               43400019
DEBNMEXT DS    CL1                     NO. OF EXTENTS BUILT FOR DSCB'S  43500019
DEBUSRPG DS    CL3                     USER PURGE CHAIN                 43600019
DEBPRIOR DS    CL1                     TCB PRIORITY-IOS CH QUEING IOB   43700019
DEBECBAD DS    CL3                     IOS INTERNAL ECB ADDR            43800019
DEBPROTG DS    CL1                     TASK PROTECTION TAG              43900019
DEBDCBAD DS    CL3                     DCB ADDR                         44000019
DEBEXSCL DS    CL1                     EXTENT SCALE                     44100019
DEBAPPAD DS    CL3                     I/O APP BLOCK PTR                44200019
DEBUCBAD DS    CL4                     UCB PTR FOR GIVEN DATA EXTENT    44300019
         EJECT                                                          44400019
*********************************************************************** 44500019
*                                                                     * 44600019
*                        DCB DSECT                                    * 44700019
*                                                                     * 44800019
*********************************************************************** 44900019
         SPACE 1                                                        45000019
         DCBD  DSORG=GS                                                 45100019
         EJECT                                                          45200019
*********************************************************************** 45300019
*                                                                     * 45400019
*                        SAVE AREA DSECT                              * 45500019
*                                                                     * 45600019
*********************************************************************** 45700019
         SPACE 1                                                        45800019
SAVEAREA DSECT                                                          45900019
WD1      DS    F                       WORK WORD                        46000019
HSA      DS    F                       HEAD SAVE AREA                   46100019
LSA      DS    F                       LAST SAVE AREA                   46200019
RET      DS    F                       RETURN ADDRESS                   46300019
EPA      DS    F                       CALLING PROG ENTRY POINT         46400019
R0       DS    F                       REG ZERO                         46500019
R1       DS    F                       REG ONE                          46600019
R2       DS    F                       REG TWO                          46700019
R3       DS    F                       REG THREE                        46800019
R4       DS    F                       REG FOUR                         46900019
R5       DS    F                       REG FIVE                         47000019
R6       DS    F                       REG SIX                          47100019
R7       DS    F                       REG SEVEN                        47200019
R8       DS    F                       REG EIGHT                        47300019
R9       DS    F                       REG NINE                         47400019
R10      DS    F                       REG TEN                          47500019
R11      DS    F                       REG ELEVEN                       47600019
R12      DS    F                       REG TWELVE                       47700019
CAN03SVE DS    F                       IFFCAN03 ADDRESS SAVE            47800019
GARSVE   DS    F                       GAR ADDRESS SAVE                 47900019
GEIRSVE  DS    F                       GEIR ADDRESS SAVE                48000019
*                                                                     * 48100019
*    THE FOLLOWING SECTION OF THE DSECT IS USED FOR THE READ          * 48200019
*    MANUAL INPUT FROM THE 2250 AT OPEN TIME TO UNLOCK THE            * 48300019
*    KEYBOARD. THE GETMAIN AREA IS USED FOR THE DECB TO MAKE          * 48400019
*    THE MODULE REENTRANT.                                            * 48500019
*                                                                     * 48600019
*                        DECB                                         * 48700019
*                                                                     * 48800019
DECBECB  DS    F                       ECB WORD                         48900019
DECBTYPE DS    F                       TYPE OF I/O OPERATION            49000019
RMICODE  EQU   X'08'                   TYPE CODE FOR RMI                49100019
DECBDCB  DS    F                       POINTER TO DCB                   49200019
DECBADDR DS    F                       I/O BUFFER-DATA TO BE            49300019
*                                      TRANSFERRED                      49400019
DECBHEX  DS    C                       ECB POSTING CODE                 49500019
DECBCNT  DS    3C                      RESIDUAL COUNT FROM CSW AFTER    49600019
*                                      I/O COMPLETED                    49700019
DECBOCBP DS    F                       O/P CONTROL BLOCK POINTER        49800019
DECBSTRT DS    F                       START ADDR OF CONTROL ORDERS     49900019
DECBUNIT DS    C                       UNIT INDEX                       50000019
DECBBUFF DS    3C                      BUFFER ADDRESS                   50100019
         END                                                            50200019
