         TITLE 'IGG0196C - UPDATE DCB FROM FORMAT 2 DSCB'               00100000
         COPY  LCGASMSW                                                 00100400
IGG0196C CSECT                                                          00102000
*********************************************************************** 00110000
*          RELEASE 24 DELETIONS                                       * 00150000
*          RELEASE 23 DELETIONS                                       * 00200000
*          RELEASE 22 DELETIONS                                       * 00250000
*          RELEASE 21 DELETIONS                                       * 00300000
*C083500                                                        SA59407 00310001
*                                                                       00370001
* STATUS CHANGE LEVEL 000                                             * 00400000
*                                                                     * 00450000
* FUNCTION -                                                          * 00500000
*    THIS MODULE MOVES APPLICABLE FORMAT 2 DSCB FIELDS INTO THE DCB.  * 00550000
*    IT ALSO UPDATES TWO FIELDS IN THE ISAM WORK AREA.                * 00560000
*                                                                     * 00600000
* ENTRY POINTS -                                                      * 00650000
*    IGG0196C - ENTRY VIA AN XCTL FROM THE FOLLOWING MODULES--        * 00700000
*    IGG01950 - VARIABLE LENGTH RECORDS                               * 00750000
*    IGG01922 - FIXED LENGTH RECORDS                                  * 00800000
*                                                                     * 00850000
* INPUT -                                                             * 00900000
*    REGISTER 5 - POINTER TO OPEN MACRO PARAMETER LIST                * 00950000
*    REGISTER 6 - POINTER TO THE WHERE-TO-GO TABLE                    * 01000000
*    REGISTER 7 - POINTER TO CURRENT ENTRY IN OPEN PARAMETER LIST     * 01050000
*    REGISTER 8 - POINTER TO CURRENT ENTRY IN WHERE-TO-GO TABLE       * 01100000
*                                                                     * 01150000
* OUTPUT -                                                            * 01200000
*    UPON NORMAL EXIT FROM THIS MODULE VIA XCTL, REGISTERS 5, 6, 7    * 01250000
*    AND 8 WILL CONTAIN THE SAME POINTERS AS UPON ENTRANCE TO THIS    * 01300000
*    MODULE.                                                          * 01350000
*                                                                     * 01400000
* EXTERNAL REFERENCES -                                               * 01450000
*    IHADCB   - DCB CONTROL BLOCK IN USER'S PROGRAM.                  * 01500000
*    FORCORE  - OPEN, CLOSE EOV WORK AREA                             * 01550000
*    ISLCOMON - ISAM WORK AREA                                        * 01600000
*    DSCBF2   - FORMAT 2 DSCB IN THE O/C/EOV WORK AREA                * 01650000
*                                                                     * 01700000
* EXITS, NORMAL -                                                     * 01750000
*    EXIT VIA XCTL TO IGG0196D TO CONTINUE OPEN RESUME LOAD           * 01800000
*    PROCESSING.                                                      * 01850000
*                                                                     * 01900000
* EXITS, ERROR - NONE.                                                * 01950000
*                                                                     * 02000000
* TABLES/WORK AREAS -                                                 * 02050000
*    FORCORE  - DSECT FOR OPEN WORK AREA                              * 02100000
*    IHADCB   - DSECT FOR DATA CONTROL BLOCK                          * 02150000
*    DSCBF2   - DSECT FOR FORMAT 2 DSCB                               * 02200000
*    ISLCOMON - DSECT FOR ISAM WORK AREA                              * 02250000
*                                                                     * 02300000
* ATTRIBUTES -                                                        * 02350000
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 02400000
*                                                                     * 02450000
* CHARACTER CODE DEPENDENCY -                                         * 02500000
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 02550000
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 02600000
*    DIFFERENT CHARACTER SET IS USED.                                 * 02650000
*                                                                     * 02700000
* NOTES - NONE                                                        * 02750000
*                                                                     * 02800000
*********************************************************************** 02810000
* SYMBOLIC REGISTER EQUATES                                             02850000
*                                                                       02900000
R0       EQU   0                   USED ONLY FOR SAVING AND RESTORING   02950000
*                                  REGISTERS                            02970000
R1       EQU   1                   UNUSED                               03000000
RFMT2    EQU   2                   BASE FOR FORMAT 2 DSCB               03050000
RBASE    EQU   3                   BASE REGISTER FOR THIS MODULE        03100000
RCORE    EQU   4                   BASE FOR OPEN WORK AREA              03150000
RPAR     EQU   5                   POINTER TO PARAMETER LIST            03200000
RWTG     EQU   6                   POINTER TO WHERE-TO-GO TABLE         03250000
RPARC    EQU   7                   CURRENT ENTRY IN PARAMETER LIST      03300000
RWTGC    EQU   8                   CURRENT ENTRY IN WHERE-TO-GO TABLE   03350000
RISLMWA  EQU   9                   POINTER TO LOAD MODE WORK AREA       03400000
RDCB     EQU   10                  CURRENT DCB BEING PROCESSED          03450000
RWORK    EQU   11                  WORK REGISTER                        03500000
RC       EQU   12                  UNUSED                               03550000
RD       EQU   13                  UNUSED                               03600000
RE       EQU   14                  UNUSED                               03650000
RF       EQU   15                  USED ONLY FOR SAVING AND RESTORING   03700000
*                                  REGISTERS AND FOR XCTL               03720000
NULL     EQU   0                   ZERO FOR DUMMY INDEXING USE          03750000
WAOFF    EQU   4                   OFFSET IN WTG TABLE OF OPEN WORK     03800000
*                                  AREA ADDRESS                         03850000
WTGOFF   EQU   8                   VALUE FOR INCREMENTING WTG ENTRY     03900000
DCBOFF   EQU   4                   VALUE FOR INCREMENTING TO NEXT DCB   03950000
IDLEN    EQU   2                   LENGTH OF ID                         03960000
TTRLEN   EQU   3                   LENGTH OF TTR                        03970000
IDOFF    EQU   6                   OFFSET FOR XCTL ID                   03980000
TTROFF   EQU   14                  OFFSET FOR XCTL TTR                  03990000
RESETOFF EQU   32                  OFFSET TO REPOSITION TO START OF     03992000
*                                  LIST                                 03994000
*                                                                       04000000
*                                                                       04050000
         BALR  RBASE,NULL          ESTABLISH                            04100000
         USING *,RBASE             *         ADDRESSABILITY             04150000
         USING FORCORE,RCORE       ADDRESSABILITY FOR OPEN WORK AREA    04250000
         USING DSCBF2,RFMT2        ADDRESSABILITY FOR FORMAT 2 DSCB     04350000
         USING IHADCB,RDCB         ADDRESSABILITY FOR DCB               04360000
         USING ISLCOMON,RISLMWA    ADDRESSABILITY FOR ISAM WORK AREA    04370000
*                                                                       04400000
UPDTLOOP EQU   *                                                        04450000
         L     RCORE,WAOFF(RWTGC)  ADDRESS OF OPEN WORK AREA            04500000
         L     RFMT2,DSCCORE       ADDRESS OF FORMAT 2 DSCB             04550000
         L     RDCB,NULL(RPARC)    GET DCB TO PROCESS                   04700000
         L     RISLMWA,DCBWKPT1    ADDRESS OF LOAD MODE WORK AREA       04720000
         STM   R0,RF,ISLVRSAV      SAVE REGISTERS                       04740000
         SR    RWORK,RWORK         CLEAR REGISTER                       04750000
         STC   RWORK,DCBEXCD1      SET DCBEXCD1 TO ZERO                 04800000
         STC   RWORK,DCBEXCD2      SET DCBEXCD2 TO ZERO                 04850000
*                                                                       04900000
*********************************************************************** 04910000
* THE FOLLOWING INSTRUCTIONS UPDATE DCB AND WORK AREA FIELDS FROM THE * 04950000
* FORMAT 2 DSCB.                                                      * 05000000
*********************************************************************** 05060000
*                                                                       05070000
         MVC   DCBNLEV,DS2NOLEV    NUMBER OF INDEX LEVELS               05100000
         MVC   DCBNTM,DS2DVIND     NUMBER OF TRACKS THAT DETERMINE THE  05150000
*                                  DEVELOPMENT OF A MASTER INDEX        05200000
         MVC   DCBFIRSH,DS21RCYL   HHR OF THE FIRST DATA RECORD ON      05250000
*                                  EACH CYLINDER                        05300000
         MVC   DCBLDT,DS2LTCYL     HH OF THE LAST PRIME DATA TRACK ON   05350000
*                                  EACH CYLINDER                        05400000
         MVC   DCBCYLOF,DS2CYLOV   NUMBER OF TRACKS ON EACH PRIME       05450000
*                                  CYLINDER TO BE RESERVED FOR          05500000
*                                  RECORDS THAT OVERFLOW FROM OTHER     05550000
*                                  TRACKS ON THAT CYLINDER              05600000
         MVC   DCBHIRCM,DS2HIRIN   HIGHEST POSSIBLE R ON A TRACK        05650000
*                                  CONTAINING HIGH LEVEL INDEX ENTRIES  05700000
         MVC   DCBHIRPD,DS2HIRPR   HIGHEST R ON ANY PRIME TRACK         05710000
*                                  IN THE DATA SET                      05720000
         MVC   DCBHIROV,DS2HIROV   HIGHEST POSSIBLE R FOR OVERFLOW      05730000
*                                  DATA TRACKS                          05740000
         MVC   DCBHIRSH,DS2RSHTR   R OF LAST DATA RECORD ON A           05742000
*                                  SHARED TRACK                         05744000
         MVC   DCBTDC,DS2TAGDT     USER SUPPLIED NUMBER OF RECORDS      05750000
*                                  TAGGED FOR DELETION                  05800000
         MVC   DCBRORG3+L'DCBRORG3-L'DS2RORG3(L'DS2RORG3),DS2RORG3      05860000
*                                  FOR EACH USE OF A DATA SET, THE      05900000
*                                  NUMBER OF ACCESSES TO AN OVERFLOW    05950000
*                                  RECORD WHICH IS NOT THE FIRST IN     06000000
*                                  A CHAIN OF SUCH RECORDS              06050000
         MVC   DCBNCRHI,DS2NOBYT   NUMBER OF BYTES OF MAIN STORAGE      06100000
*                                  NEEDED TO HOLD THE HIGHEST LEVEL     06150000
*                                  INDEX                                06200000
         MVC   DCBNTHI,DS2NOTRK    NUMBER OF TRACKS OCCUPIED BY THE     06250000
*                                  HIGHEST LEVEL INDEX                  06300000
*                                                                       06350000
*********************************************************************** 06360000
* THE FOLLOWING THREE STATEMENTS MOVE FIELDS WHICH ARE CONTIGUOUS IN  * 06400000
* THE FORMAT 2 AND IN THE DCB.  THEY MAY BE COMBINED INTO ONE         * 06450000
* INSTRUCTION TO SAVE SPACE.                                          * 06500000
*********************************************************************** 06510000
*                                                                       06550000
         MVC   DCBNREC,DS2PRCTR    NUMBER OF LOGICAL RECORDS IN THE     06600000
*                                  PRIME DATA AREA                      06650000
         MVC   DCBST,DS2STIND      STATUS INDICATORS                    06700000
         MVC   DCBFTCI,DS2CYLAD    MBBCCHH OF THE FIRST TRACK OF THE    06750000
*                                  CYLINDER INDEX                       06800000
*********************************************************************** 06810000
*                                                                       06850000
*                                                                       06900000
         MVC   DCBFTMI1,DS2ADLIN   MBBCCHH OF THE LOWEST LEVEL MASTER   06950000
*                                  INDEX                                07000000
*                                                                       07050000
*                                                                       07100000
*********************************************************************** 07110000
* THE FOLLOWING THREE STATEMENTS MOVE FIELDS WHICH ARE CONTIGUOUS IN  * 07150000
* THE FORMAT 2 AND IN THE DCB.  THEY MAY BE COMBINED INTO ONE         * 07200000
* INSTRUCTION TO SAVE SPACE.                                          * 07250000
*********************************************************************** 07260000
*                                                                       07300000
         MVC   DCBFTHI,DS2ADHIN    MBBCCHH OF THE FIRST TRACK OF THE    07350000
*                                  HIGHEST LEVEL INDEX                  07400000
         MVC   DCBLPDA,DS2LPRAD    MBBCCHHR OF THE LAST PRIME DATA      07450000
*                                  RECORD IN THE PRIME DATA AREA        07500000
         MVC   DCBLETI,DS2LTRAD    CCHHR OF THE LAST ACTIVE NORMAL      07550000
*                                  ENTRY OF THE TRACK INDEX ON THE      07650000
*                                  LAST ACTIVE CYLINDER                 07700000
*********************************************************************** 07710000
         MVC   DCBLECI,DS2LCYAD    CCHHR OF THE LAST ACTIVE ENTRY IN    07750000
*                                  THE CYLINDER INDEX                   07800000
         MVC   DCBLEMI1,DS2LMSAD   CCHHR OF THE LAST INDEX ENTRY IN     07850000
*                                  THE FIRST LEVEL INDEX                07900000
         MVC   DCBLIOV,DS2LOVAD    MBBCCHHR OF THE LAST RECORD WRITTEN  07950000
*                                  IN THE INDEPENDENT OVERFLOW AREA     08000000
         MVC   DCBNBOV,DS2BYOVL    NUMBER OF BYTES REMAINING ON THE     08050000
*                                  CURRENT OVERFLOW TRACK               08100000
         MVC   DCBRORG2,DS2RORG2   NUMBER OF TRACKS REMAINING IN THE    08150000
*                                  INDEPENDENT OVERFLOW AREA            08200000
         MVC   DCBNOREC,DS2OVRCT   NUMBER OF LOGICAL RECORDS IN THE     08250000
*                                  OVERFLOW AREA                        08300000
         MVC   DCBRORG1,DS2RORG1   NUMBER OF CYLINDER OVERFLOW  SA59407 08350001
*                                 AREAS THAT ARE FULL                   08400001
*                                                                       08450000
*********************************************************************** 08460000
* THE FOLLOWING FOUR STATEMENTS MOVE FIELDS WHICH ARE CONTIGUOUS IN   * 08500000
* THE FORMAT 2 AND IN THE DCB.  THEY MAY BE COMBINED INTO ONE         * 08550000
* INSTRUCTION TO SAVE SPACE.                                          * 08600000
*********************************************************************** 08610000
*                                                                       08650000
         MVC   DCBFTMI2,DS22MIND   MBBCCHH OF THE FIRST TRACK OF THE    08700000
*                                  SECOND LEVEL MASTER INDEX            08750000
         MVC   DCBLEMI2,DS2L2MEN   CCHHR OF THE LAST ACTIVE ENTRY IN    08800000
*                                  THE SECOND LEVEL MASTER INDEX        08850000
         MVC   DCBLEMI3,DS2L3MIN   CCHHR OF THE LAST ACTIVE ENTRY IN    08900000
*                                  THE THIRD LEVEL MASTER INDEX         08950000
         MVC   DCBLPDT,DS2LPDT     MBBCCHHR OF THE LAST PRIME TRACK     08960000
*                                  ON THE LAST PRIME CYLINDER           09050000
*********************************************************************** 09060000
         MVC   DCBHIRTI,DS2HIRTI   HIGHEST NUMBER OF INDEX ENTRIES THAT 09100000
*                                  FIT ON A PRIME DATA TRACK            09150000
*                                                                       09200000
* ISAM WORK AREA FIELDS                                                 09250000
*                                                                       09300000
         MVC   ISLNIRT,DS2NIRT     HHR OF THE DUMMY TRACK INDEX ENTRY   09350000
         MVC   ISLHIRT,DS2HIRTI    HIGHEST NUMBER OF INDEX ENTRIES      09400000
*                                  THAT FIT ON A PRIME DATA TRACK       09450000
*                                                                       09500000
*                                                                       09550000
EXITRTN  EQU   *                                                        09600000
         LM    R0,RF,ISLVRSAV      RESTORE REGISTERS                    09650000
         MVC   NULL(IDLEN+TTRLEN,RWTGC),LOAD6D                          09700000
*                                  MOVE IN ID-TTR OF IGG0196D           09750000
LOOP     EQU   *                                                        09800000
         LA    RWTGC,WTGOFF(RWTGC) POINT TO NEXT WTG ENTRY              09850000
         LA    RPARC,DCBOFF(RPARC) POINT TO NEXT ENTRY IN PARM LIST     09900000
         CLC   NULL(L'THISLOAD,RWTGC),THISLOAD                          09950000
*                                  SHOULD WE PROCESS IN THIS MODULE     10000000
         BE    UPDTLOOP            YES, GO DO NEXT DCB                  10050000
         CLC   NULL(L'OPNLOD7,RWTGC),OPNLOD7                            10100000
*                                  IS IT THE END OF THE WTG TABLE       10150000
         BNE   LOOP                NO, CHECK NEXT DCB                   10200000
END      EQU   *                                                        10250000
         LR    RPARC,RPAR          RESET PARM LIST POINTER              10300000
         LA    RWTGC,RESETOFF(RWTG)                                     10350000
*                                  RESET WTG TABLE POINTER              10360000
ZEROCHK  EQU   *                                                        10400000
         CLI   NULL(RWTGC),NULL    IS ENTRY ALREADY PROCESSED           10450000
         BNE   XCTLRTN             NO, GIVE CONTROL TO PROPER MODULE    10500000
         LA    RWTGC,WTGOFF(RWTGC) POINT TO NEXT WTG ENTRY              10550000
         LA    RPARC,DCBOFF(RPARC) POINT TO NEXT ENTRY IN PARM LIST     10600000
         B     ZEROCHK             CHECK NEXT ENTRY                     10650000
*                                                                       10700000
*                                                                       10750000
*                                                                       10800000
XCTLRTN  EQU   *                                                        10850000
         MVC   IDOFF(IDLEN,RWTG),NULL(RWTGC)                            10900000
*                                  MOVE ID                              10910000
         MVC   TTROFF(TTRLEN,RWTG),IDLEN(RWTGC)                         10950000
*                                  MOVE TTR                             10960000
         LA    RF,DXCCW12                                               11000000
         XCTL  DE=(RWTG),SF=(E,(15))                                    11050000
*                                                                       11100000
*                                                                       11150000
* CONSTANTS                                                             11200000
THISLOAD DC    C'6C'               CURRENT MODULE ID                    11250000
OPNLOD7  DC    C'0S'               LAST OPEN MODULE ID                  11300000
*                                                                       11350000
         XCTLTABL ID=(LOAD6D,6D),SVC=019                                11360000
FORCORE  DSECT                                                          11450000
         IECDSECT                                                       11500000
DSCBF2   DSECT                                                          11550000
         IECSDSL1 (2)                                                   11600000
         DCBD  DSORG=IS,DEVD=DA                                         11650000
ISLCOMON IGGLOAD                                                        11700000
         END                                                            11750000
