REL TITLE  'IEWLRELO--OBJECT MODULE PROCESSING AND RELOCATION'          00060000
*STATUS - CHANGE LEVEL 20                                             * 00090000
*    INCREMENTAL 288 - W-CON ADDED        INC288                        00130000
*              APAR FIX 27445 - ZERO/LENGTH CSECTS OKAY                 00140000
*    APAR  30142   DUPLICATE CSECTS            $256300-256400,257200    00142021
*                                              $257400-258000           00144021
*    APAR  30162   BAD IEW1182 MSG             $119100,131200           00146021
*    APAR  62460                               $247200,$248400-248992   00148021
*        TSO CHANGES FOR IDENTIFY AND INCORE DATA SET                 * 00150000
*    APAR  70542   LRS INCORRECTLY RESOLVED    $239400,334800,355800,   00160021
*                                              $760200,817300           00170021
*FUNCTION/OPERATION:                                                  * 00180000
*        1)IEWLRELO-DETERMINES RECORD TYPE,THEN PASSES CONTROL TO THE * 00240000
*              APPROPRIATE ROUTINE FOR RECORD PROCESSING              * 00300000
*        2)IEWLESD-PROCESSES ESD RECORDS,BUILDS AND MAINTAINS CESD    * 00360000
*        3)IEWLTXT-PROCESSES TXT RECORDS                              * 00420000
*        4)IEWLRLD-PROCESSES RLD RECORDS,BUILDS AND MAINTAINS RLD     * 00480000
*              TABLE                                                  * 00540000
*        5)IEWLEND-PROCESSES END RECORDS,DEFINES ENTRY POINT,UPDATES  * 00600000
*              THE TEXT LOCATION POINTER, CLEARS THE TRANSLATION      * 00660000
*              TABLE                                                  * 00720000
*        6)ALLOCATE-ALLOCATES STORAGE FOR THE CESD,RLD TABLE AND      * 00780000
*              TRANSLATION TABLE                                      * 00840000
*        7)TRANSID-TRANSLATES ESDID TO TRANSLATION TABLE ENTRY ADDRESS* 00900000
*        8)IEWLERTN-RELOCATES RLDS                                    * 00960000
*        9)IEWLMAP-CREATES MAP PRINTOUT                               * 01020000
*       10)IEWLCNVT-CONVERTS BINARY QUANTITIES TO PRINT CHARACTERS    * 01080000
*        11)IEWLMOD - PROCESSES MOD RECORDS                           * 01110000
*ENTRY POINTS:                                                        * 01140000
*        1)IEWLRELO-FOR OBJECT MODULE PROCESSING                      * 01200000
*        2)IEWLESD-FOR ESD PROCESSING                                 * 01260000
*        3)IEWLRLD-FOR RLD PROCESSING                                 * 01320000
*        4)IEWLEND-FOR END OF MODULE PROCESSING                       * 01380000
*        5)TRANSID-FOR ESDID-TRANSLATION TABLE ADDRESS CONVERSION     * 01440000
*        6)IEWLERTN-FOR RELOCATION OF RLDS ON CHAIN                   * 01500000
*        7)IEWLCNVT-FOR CONVERSION TO PRINT CHARACTERS                * 01560000
*        8)IEWLMAP-FOR MAKING MAP ENTRIES                             * 01620000
*INPUT:  ALL ROUTINES EXPECT:                                         * 01680000
*             #13-ADDR OF SAVE AREA                                   * 01740000
*             #14-RETURN ADDRESS                                      * 01800000
*             #11-ADDR.OF COMMUNICATIONS AREA                         * 01860000
*        IN ADDITION:                                                 * 01920000
*          IEWLESD EXPECTS:                                           * 01980000
*             #5-ID OF FIRST ESD ITEM                                 * 02040000
*             #7-LENGTH OF ESD INFORMATION                            * 02100000
*             #8-ADDRESS OF ESD INFORMATION                           * 02160000
*          IEWLRLD EXPECTS:                                           * 02220000
*             #7-LENGTH OF RLD INFORMATION                            * 02280000
*             #8-ADDRESS OF RLD INFORMATION                           * 02340000
*          TRANSID EXPECTS:                                           * 02400000
*             #5-ID TO BE TRANSLATED                                  * 02460000
*          IEWLERTN EXECTS:                                           * 02520000
*             #1-STARTING ADDRESS OF RLD CHAIN                        * 02580000
*             #9-ADDRESS OF CESD ENTRY TO BE USED FOR RELOCATION      * 02640000
*          IEWLCNVT EXPECTS:                                          * 02700000
*             #1-QUANTITY TO BE CONVERTED                             * 02760000
*          IEWLMAP EXPECTS:                                           * 02820000
*             #9-ADDRESS OF CESD ENTRY TO BE MAPPED                   * 02880000
*          IEWLMOD EXPECTS -                                            02890000
*             #7=LENGTH OF MOD INFO                                   * 02900000
*             #8=ADDRESS OF MOD INFO                                  * 02910000
*OUTPUT:   IEWLCNVT:CMXDBLWD CONTAINS CONVERTED VALUE                 * 02940000
*          TRANSID:#1-CONTAINS TRANSLATION TABLE ENTRY ADDRESS        * 03000000
*EXTERNAL ROUTINES:                                                   * 03060000
*          IEWLREAD-READ AND DEBLOCK OBJECT RECORDS                   * 03120000
*          IEWLPRNT-PRINT MAP                                         * 03180000
*          IEWERROR-LOG ERRORS                                        * 03240000
*EXITS-NORMAL:TO CALLER                                               * 03300000
*     -ERROR:TO IEWERROR      LA   0,ERRCODE                          * 03360000
*                             L    15,=V(IEWERROR)                    * 03420000
*                             BALR 14,15                              * 03480000
*                                                                     * 03540000
*TABLES/WORKAREAS: REFER TO LOADER PLM FOR DETAILED DESCRIPTION       * 03600000
*        1)CESD                                                       * 03660000
*        2)RLD TABLE                                                  * 03720000
*        3)TRANSLATION TABLE                                          * 03780000
*        4)COMMUNICATIONS AREA(IEWLOCOM)                              * 03840000
*ATTRIBUTES: READ ONLY,REUSABLE,REENTRANT                             * 03900000
*NOTES:  NONE                                                         * 03960000
*********************************************************************** 04020000
         EJECT                                                          04080000
IEWLRELO CSECT                                                          04140000
*A073800                                                         A39336 04160021
*C244900-245000                                                  A39336 04180021
*A750000,760800                                                  A46172 04190021
*A621500-621520,D837600-846300,A867700-868706,D868200,A868733    A47048 04192021
*                                                               SA49491 04194000
*                                                               SA56381 04196021
*                                                               SA59776 04198021
*                                                                 M5453 04198421
*                                                                 M5478 04198821
*                                                                     * 04200000
*                       REGISTER ASSIGNMENTS                          * 04260000
*                                                                     * 04320000
BRANCH   EQU   15                       BRANCH REGISTER                 04380000
RETURN   EQU   14                       LINK REGISTER                   04440000
SAVEREG  EQU   13                       SAVE AREA POINTER               04500000
BASE     EQU   12                       BASE REGISTER                   04560000
CMPTR    EQU   11                       POINTER TO COMMUNICATIONS AREA  04620000
BASE2    EQU   10                       SECOND BASE REG         SA49491 04680000
CESD     EQU   9                        CESD ENTRY ADDR                 04740000
PTR      EQU   8                        USED FOR POINTER VALUE          04800000
*                                           -POINTER WITHIN INPUT BUF.  04860000
*                                           -POINTER WITHIN OUTPUT BUF. 04920000
LNG      EQU   7                        LENGTH OF INFORMATION           04980000
ADR      EQU   6                        ADDR FROM OBJECT RECORD         05040000
ID       EQU   5                        ID                              05100000
WORKC    EQU   4                        WORK REG.-EVEN FOR DEV          05160000
WORKA    EQU   3                        WORK REG.-ODD FOR BXLE          05220000
WORKB    EQU   2                        WORK REG.                       05280000
PARM     EQU   1                        PARAMETER REGISTER              05340000
ZERO     EQU   0                                                        05400000
*                                                                     * 05460000
*                    MAP FORMAT DISPLACEMENTS                         * 05520000
PREFIXNM EQU   2                                                        05580000
NAME     EQU   3                                                        05640000
TYPE     EQU   14                                                       05700000
ADDR     EQU   17                                                       05760000
SUFFIXNM EQU   11                                                       05820000
ENTRYSZ  EQU   24                                                       05880000
*                                                                     * 05940000
*                     CESD  DISPLACEMENTS                             * 06000000
*                                                                     * 06060000
CNAME    EQU   4                                                        06120000
CTYPE    EQU   12                                                       06180000
CADR     EQU   12                                                       06240000
CREL     EQU   16                                                       06300000
CLNG     EQU   16                                                       06360000
*                                                                     * 06420000
*                       CESD  INDICATORS                              * 06480000
*                                                                     * 06540000
SD       EQU   X'00'                    SECTION DEFINITION              06600000
LD       EQU   X'01'                    LABEL DEFINITION                06660000
ER       EQU   X'02'                    EXTERNAL REFERENCE              06720000
LR       EQU   X'03'                    LABEL REFERENCE                 06780000
PC       EQU   X'04'                    PRIVATE CODE                    06840000
CM       EQU   X'05'                    COMMON                          06900000
PR       EQU   X'06'                    PSEUDO REGISTER                 06960000
NULL     EQU   X'07'                    NULL ENTRY                      07020000
DELETE   EQU   X'80'                    DELETE  INDICATOR               07080000
NOLEN    EQU   X'20'               ZERO LENGTH                  27445   07110000
DELINK   EQU   X'80'                    RLD'S FOR ENTRY NEED DELINKING  07140000
LDCHAIN  EQU   X'40'                    ON LD CHAIN,ALREADY PROCESSED   07200000
*                                            THIS RECORD                07260000
WX       EQU   X'0A'               W-CON - EXTERNAL FORMAT  INC288      07270000
WEAKCALL EQU   X'40'               W-CON - INTERNAL FORMAT  INC288      07280000
NEVERCAL EQU   X'08'                   'ER' NEVER CALL                  07320000
BLANK    EQU   C' '                                                     07380000
ERWEAK   EQU   X'42'               FOR ER AND WEAKCALL BIT CHECK A39336 07410021
********                                                       ******** 07440000
*                       TRANSLATION TABLE INDICATORS                  * 07500000
********                                                       ******** 07560000
ERMATCH  EQU   X'80'                    ABSOLUTE RELOCATION INDIC.      07620000
*                                                                     * 07680000
*                       ESD DISPLACEMENTS                             * 07740000
*                                                                     * 07800000
ENAME    EQU   0                                                        07860000
ETYPE    EQU   8                                                        07920000
EADR     EQU   8                                                        07980000
ELNG     EQU   12                                                       08040000
ESUBTYP  EQU   13                      SUBTYPE FIELD                    08100000
EID      EQU   14                                                       08160000
ESDADDR  EQU   12                                                       08220000
ESEGNO   EQU   12                       SEGMENT NUMBER                  08280000
*                                                                     * 08340000
*                            RLD  FLAGS                               * 08400000
*                                                                     * 08460000
CONT     EQU   X'01'                                                    08520000
VCON     EQU   X'10'                    CHECK FOR ABSOLUTE RELOCATION   08580000
PRRLD    EQU   X'20'                    PSEUDO REGISTER RLD INDICATOR   08640000
ACCUMPR  EQU   X'30'                   ACCUMULATIVE PSEUDO REGISTER     08700000
*                                                                     * 08760000
*                      RLD DISPLACEMENTS                              * 08820000
*                                                                     * 08880000
P        EQU   2                        P PTR DISPLACEMENT              08940000
R        EQU   0                        R PTR DISPLACEMENT              09000000
RLDFLG   EQU   4                        FLAG FIELD                      09060000
RLDADR   EQU   4                        ADDRESS FIELD                   09120000
*                                                                     * 09180000
*                   DISPLACEMENTS WITHIN OBJECT BUFFER                * 09240000
*                                                                     * 09300000
COL1     EQU   0                                                        09360000
COL5     EQU   4                                                        09420000
COL11    EQU   10                                                       09480000
COL15    EQU   14                                                       09540000
COL29    EQU   12                       ADDED TO INFO ADDR TO GET COL.  09600000
*                                                  29 ADDR.             09660000
CQFF     EQU   X'FF'                   USED TO TURN OFF INDIC.          09720000
         EJECT                                                          09780000
         ENTRY IEWLERTN                 EXTERNAL REFERENCE RESOLUTION   09840000
         ENTRY IEWLMAP                  MAP PROCESSING                  09900000
         ENTRY IEWLCNVT                 CONVERSION                      09960000
         ENTRY IEWLRLD                  RLD RECORD PROCESSING           10020000
         ENTRY IEWLESD                  ESD RECORD PROCESSING           10080000
         ENTRY IEWLEND                  END OF MODULE PROCESSING        10140000
         ENTRY TRANSID                 TRANSLATE ID ROUTINE             10200000
         SAVE  (14,12),T,*              SAVE REGISTERS                  10260000
         USING IEWLRELO,BRANCH                                          10320000
         LR    BASE,BRANCH              SET BASE TO START       SA49491 10380000
         USING IEWLRELO,BASE            ESTABLISH  ADDRESSABILITY       10440000
         DROP  BRANCH                                                   10500000
         L     SAVEREG,8(SAVEREG)       PICK UP NEXT SAVE AREA          10560000
         USING IEWLDCOM,CMPTR           ESTABLISH ADDR. TO COMM.AREA    10620000
         USING ERCODES,0               ERROR CODE DSECT                 10680000
         L     BASE2,ABEG4096          SET UP SECOND BASE REG   SA49491 10730000
         USING IEWLRELO+4096,BASE2     ESTABLISH ADDRESSABILITY SA49491 10732000
*                                                                     * 10740000
*              GET A RECORD TO PROCESS                                * 10800000
*                                                                     * 10860000
RELOREAD L     BRANCH,ADREAD                                            10920000
         BALR  RETURN,BRANCH            GO TO READ A RECORD             10980000
         TM    CMIOFLGS,CQEOCB          END OF CONCATENATION?           11040000
         BZ    RELO10                   NO, PROCESS RECORD              11100000
         TM    CMRELFLG,CQNOEND        WAS AN END CARD RECEIVED         11160000
         BO    RELO1                   YES                              11220000
         TM    CMRELFLG,CQINPUT        WAS IT A DUMMY DATA SET          11280000
         BZ    RELO1                   YES,RETURN                       11340000
         BAL   RETURN,IEWLEND          GO TO PREFORM CLOSE-OUT PROC.    11400000
        BAL    RETURN,RERINPTA          WARNING--NO END CARD            11460000
RELO1    NI    CMRELFLG,CQFF-CQNOEND   SET OFF END CARD INDIC.          11520000
         L     SAVEREG,4(SAVEREG)                                       11580000
         RETURN (14,12),T                                               11640000
*                                                                     * 11700000
*                  SET-UP FOR RECORD PROCESSING                       * 11760000
*                                                                     * 11820000
RELO10   L     PTR,CMGETREC            LOAD ADDR. OF OBJ. BUFFER A30162 11910000
         CLI   0(PTR),BLANK             CHECK FOR L.E.CONTROL CARD      12000000
         BNE   RELO20                   IT IS NOT A CONTROL CARD        12060000
         BAL   RETURN,RERINPT8          WARNING-CARD NOT AN OBJ.CARD    12120000
         B     RELOREAD                GO TO READ NEXT RECORD           12180000
RELO20   L     ADR,COL5(PTR)            LOAD COLS 5 THRU 8 - ADDRESS    12240000
         LA    ADR,0(ADR)                                               12300000
         LH    LNG,COL11(PTR)           LOAD COLS 11 AND 12 -BYTE CT    12360000
         LH    ID,COL15(PTR)            LOAD COLS IS AND 16 - ID        12420000
         L     WORKA,COL1(PTR)          LOAD COLS 1 THRU 4-CARD IDENT.  12480000
         LA    PTR,16(PTR)              ADDR. OF COL 17- ADDR.OF INFO   12540000
*                                                                     * 12600000
*   THE FOLLOWING CODE DETERMINES TYPE OF RECORD AND THEN BRANCHES TO * 12660000
*            THE APPROPRIATE ROUTINE FOR PROCESSING                   * 12720000
*                                                                     * 12780000
         LA    WORKC,6             GET TABLE ENTRY NUMBER               12840000
         LA    WORKB,TYPETBLE           GET TABLE ADDRESS               12900000
RELO30   LM    RETURN,BRANCH,0(WORKB)   PICK UP TABLE ENTRY             12960000
         CR    WORKA,RETURN             ARE TYPES EQUAL                 13020000
         BC    7,RELO40                 NO , CONTINUE SEARCH            13080000
         OI    CMRELFLG,CQINPUT        SET INDICATOR FOR VALID INPUT    13100000
*                                      RECEIVED                  A30162 13120000
         BALR  RETURN,BRANCH            YES, THEN GO TO PROCESS REC.    13140000
         B     RELOREAD                 GO TO READ NEXT RECORD          13200000
RELO40   LA    WORKB,8(WORKB)           UPDATE TABLE PTR                13260000
         BCT   WORKC,RELO30             LOOP AGAIN                      13320000
         BAL   RETURN,RERINPT9         INVALID INPUT FROM OBJ.MODULE    13380000
         B     RELOREAD                 GO TO READ NEXT RECORD          13440000
         EJECT                                                          13500000
*                                                                     * 13560000
**************************  ESD PROCESSOR  **************************** 13620000
*                                                                     * 13680000
*   THIS SUBROUTINE CREATES THE CESD FROM THE ESD/CESD SENT TO IT.    * 13740000
*     IT EXPECTS                                                      * 13800000
*            #LNG-LENGTH OF ESD INFORMATION                           * 13860000
*            #PTR- ADR. OF ESD INFORMATION                            * 13920000
*            #ID- ID OF FIRST ESD ITEM OTHER THAN LD                    13980000
*                                                                     * 14040000
*********************************************************************** 14100000
IEWLESD  EQU   *                                                        14160000
         STM   14,12,12(13)             SAVE REGISTERS                  14220000
         BALR  BASE,0                                                   14280000
         USING *,BASE                                                   14340000
         L     BASE,ABEGIN                                              14400000
         USING IEWLRELO,BASE           RESET BASE TO INITIAL VALUE      14460000
         L     BASE2,ABEG4096          SET UP SECOND BASE REG   SA49491 14510000
         USING IEWLRELO+4096,BASE2     ESTABLISH ADDRESSABILITY SA49491 14512000
         B     NESD+8                                                   14520000
NESD     DC    C'IEWLESD '                                              14580000
         L     SAVEREG,8(SAVEREG)          GET NEXT SAVE AREA           14640000
ESDSTART STH   ID,CMCURRID              SAVE CURRENT ID                 14700000
         OI    CMFLAG4,CQESDS     SHOW ESDS RECHD FOR THIS MODULE       14730000
         TM    CMIOFLGS,CQRECFM         IS A LOAD MODULE BEING PROC.    14760000
         BO    LOADPROC                 YES                             14820000
****                                                               **** 14880000
*                       INPUT ESD TYPE IS 'NULL'                      * 14940000
****                                                               **** 15000000
ESD10    TM    ETYPE(PTR),WX       IS INPUT TYPE WX         INC288      15070000
         BNO   ESD12               NO. BRANCH               INC288      15080000
         MVI   ETYPE(PTR),WEAKCALL+ER  YES. SET ER WITH WEAKCALL INC288 15090000
*                                     FLAG ON               INC288      15100000
ESD12    TM    ETYPE(PTR),NULL     IS INPUT ESD TYPE NULL   INC288      15110000
         BZ    CESDSRCH                 NO, TYPE IS SD - SEARCH CESD    15120000
         BC    6,ESD20                  NO, CHECK FOR TYPE 'PC'         15180000
ESD15    L     CESD,CMNULCHN            IS THE CESD NULL ENTRY CREATED  15240000
*                                       ALL NULL ENTRIES ARE RENUMBERED 15300000
*                                         TO THE SAME CESD'DELETE'ENTRY 15360000
         LTR   CESD,CESD                                                15420000
         BC    7,TRANSLAT               YES                             15480000
         BAL   RETURN,CESDENT           NO, GET CESD ENTRY              15540000
         XC    0(20,CESD),0(CESD)       CLEAR ENTRY                     15600000
         OI    CTYPE(CESD),DELETE       SET DELETE INDICATOR            15660000
         ST    CESD,CMNULCHN            SAVE CESD ADDR.FOR FUTURE NULLS 15720000
         B     TRANSLAT                 GO TO TRANSLATE ID              15780000
********                                                        ******* 15840000
*                         INPUT ESD TYPE IS 'PC'                      * 15900000
********                                                        ******* 15960000
ESD20    TM    ETYPE(PTR),X'03'         IS INPUT ESD TYPE 'PC'          16020000
         BC    7,ESD35                  NO, CHECK FOR 'LD'/'LR'         16080000
ESD30    BAL   RETURN,CESDENT           GET CESD ENTRY                  16140000
         BAL   RETURN,ENTER             MAKE CESD ENTRY                 16200000
         BAL   RETURN,CHECKEP          CHECK FOR EP NAME                16260000
         B     MATERSD2                 GO TO TEST LNG.AND MAP          16320000
********                                                        ******* 16380000
*                        INPUT ESD TYPE IS 'LR'OR'LD'                 * 16440000
********                                                        ******* 16500000
ESD35    TM    ETYPE(PTR),CM           IS ESD TYPE'LR'OR'LD'            16560000
         BC    11,CESDSRCH             NO                               16620000
         TM    ETYPE(PTR),PR           IS ESD TYPE 'PR'                 16680000
         BO    CESDSRCH                YES                              16740000
         LH    ID,EID(PTR)              GET 'SD' ID                     16800000
         OI    CMRELFLG,CQESD          ESD CALLER INDICATOR             16860000
         BAL   RETURN,TRANSID           TRANSLATE ID                    16920000
         NI    CMRELFLG,CQFF-CQESD     SET ESD CALLER INDIC. OFF        16980000
         LH    ID,CMCURRID              RESTORE ID                      17040000
         LTR   PARM,PARM                WAS AN INVALID ID FOUND         17100000
         BZ    NEXTESD                  YES                             17160000
         L     CESD,0(PARM)             GET'SD' CESD ADDR.              17220000
         LTR   CESD,CESD                IS 'SD' DEFINED YET             17280000
         BZ    ESD40                    NO                              17340000
         ST    CESD,ESDADDR(PTR)        SAVE 'SD' CESD ADDR.            17400000
         B     CESDSRCH                 GO TO SEARCH CESD               17460000
*   THE SECTION DEFINITION(SD) FOR A LABEL DEFINITION(LD) MUST BE     * 17520000
*    DEFINED BEFORE THE LD CAN BE PROCESSED. THEREFORE, ALL LDS WHOSE * 17580000
*    SD IS NOT DEFINED WHEN ENCOUNTERED ARE PLACED ON A CHAIN UNTIL   * 17640000
*    THEIR CORRESPONDING SD IS DEFINED. THE CHAIN IS PROCESSED AT     * 17700000
*    THE END OF EACH RECORD.(THIS SPECIAL CASE SHOULD OCCUR ONLY IF   * 17760000
*    THE USER REARRANGES THE OBJECT DECK IN THIS MANNER.              * 17820000
ESD40    LR    CESD,PTR                GET CESD ENTRY ADDR              17880000
         SH    CESD,CONT4                                               17940000
         TM    ETYPE(PTR),LDCHAIN      HAS CESD ENTRY BEEN CREATED      18000000
         BO    ESD50                    YES, RECHAIN                    18060000
         BAL   RETURN,CESDENT          GET CESD ENTRY                   18120000
         MVC   CNAME(16,CESD),ENAME(PTR) MOVE ESD INFO TO CESD          18180000
ESD50    L     WORKC,CMLDCHN                                            18240000
         ST    CESD,CMLDCHN                                             18300000
         ST    WORKC,0(CESD)            CHAIN ENTRY TO 'LD' CHAIN       18360000
         B     NEXTESD                  GET NEXT ESD ITEM               18420000
         EJECT                                                          18480000
****************************  CESD SEARCH  **************************** 18540000
*                                                                     * 18600000
*      THIS ROUTINE SEARCHES THE CESD FOR A GIVEN NAME. IT USES       * 18660000
*        HIERTBLE TO DETERMINE WHICH CESD CHAINS TO SEARCH AND THEN   * 18720000
*        GETS THE CHAIN BEGINNING ADDRESSES FROM THE CMTYPCHN TABLE   * 18780000
*                                                                     * 18840000
*********************************************************************** 18900000
CESDSRCH XC    CMPREVPT(4),CMPREVPT     CLEAR PREVIOUS CHAIN POINTER    18960000
         IC    WORKA,ETYPE(PTR)         GET INPUT ESD TYPE              19020000
         N     WORKA,TYPEONLY           CLEAR ALL BUT TYPE FIELD        19080000
         CH    WORKA,ONE               IS INPUT TYPE 'LD'               19140000
         BNE   SRCH05                  NO                               19200000
         LA    WORKA,3                 SET TYPE TO 'LR'                 19260000
SRCH05   SLL   WORKA,2                                                  19320000
         LA    WORKA,HIERTBLE(WORKA)   CALC HIERTBLE ENTRY ADDR         19380000
SRCH10   IC    CESD,0(WORKA)            GET CESD TYPE                   19440000
         N     CESD,TYPEONLY           CLEAR ALL BUT TYPE               19500000
         SLL   CESD,2                                                   19560000
         LA    CESD,CMTYPCHN(CESD)     CALC CHAIN TABLE ENTRY ADDR      19620000
SRCH20   L     CESD,0(CESD)             GET ADDR. OF FIRST ON CHAIN     19680000
         LTR   CESD,CESD                IS THIS END OF CHAIN            19740000
         BZ    SRCH30                   YES                             19800000
         CLC   CNAME(8,CESD),ENAME(PTR)  ARE NAMES EQUAL                19860000
         BE    MATCHED                  YES, GO TO MATCH PROCESSING     19920000
         ST    CESD,CMPREVPT            SAVE PREVIOUS CHAIN POINTER     19980000
         B     SRCH20                   GET NEXT IN CHAIN               20040000
SRCH30   TM    0(WORKA),X'80'           LAST ENTRY IN HIERTBLE          20100000
         BO    NOMATCH                  YES, GO TO NO MATCH PROCESSING  20160000
         LA    WORKA,1(WORKA)           UPDATE TO NEXT ENTRY            20220000
         XC    CMPREVPT(4),CMPREVPT     CLEAR PREVIOUS CHAIN POINTER    20280000
         B     SRCH10                   CONTINUE SEARCH                 20340000
         EJECT                                                          20400000
*********************************************************************** 20460000
*                                                                     * 20520000
***********************  NO MATCH PROCESSING   ************************ 20580000
*                                                                     * 20640000
*********************************************************************** 20700000
********                                                        ******* 20760000
*                          INPUT ESD TYPE IS 'SD'                     * 20820000
********                                                        ******* 20880000
NOMATCH  EQU   *                                                        20940000
         TM    ETYPE(PTR),NULL          IS INPUT ESD TYPE 'SD'          21000000
         BZ    ESD30                    YES, HANDLE SAME AS 'PC'        21060000
         BAL   RETURN,CESDENT           GET CESD ENTRY FOR NOMATCH PROC 21120000
********                                                        ******* 21180000
*                          INPUT ESD TYPE IS 'PR'                     * 21240000
********                                                        ******* 21300000
         TM    ETYPE(PTR),PR            IS INPUT ESD TYPE 'PR'          21360000
         BZ    NOMATLD1                 NO, TYPE IS'LD'                 21420000
         BC    6,NOMATCM                NO, CHECK FOR 'CM'              21480000
         MVC   CNAME(16,CESD),ENAME(PTR) YES, MOVE ESD INFO.TO CESD     21540000
         XC    CTYPE+1(3,CESD),CTYPE+1(CESD)  CLEAR RLD CHAIN FIELD     21600000
*                                       CHAIN PR TO END OF PR CHAIN IN  21660000
*                                       ORDER TO MAINTAIN INPUT PR      21720000
*                                       ORDER.                          21780000
         LA    WORKB,CMPRCHN                                            21840000
         L     WORKC,CMPRCHN            GET ADDRESS OF 1ST PR ENTRY     21900000
NOMATPR1 LTR   WORKC,WORKC              IS THIS LAST ON CHAIN           21960000
         BZ    NOMATPR2                 YES                             22020000
         LR    WORKB,WORKC              NO,SAVE PREVIOUS ENTRY ADDRESS  22080000
         L     WORKC,0(WORKC)           GET ADDR. OF NEXT PR ENTRY      22140000
         B     NOMATPR1                                                 22200000
NOMATPR2 ST    CESD,0(WORKB)            CHAIN PR AT END OF CHAIN        22260000
         XC    0(4,CESD),0(CESD)        CLEAR CHAIN FIELD               22320000
         B     TRANSLAT                 GO TO TRANSLATE ID              22380000
********                                                        ******* 22440000
*                          INPUT ESD TYPE IS 'CM'                     * 22500000
********                                                        ******* 22560000
NOMATCM  TM    ETYPE(PTR),CM            IS TYPE 'CM'                    22620000
         BC    14,NOMATLD               NO                              22680000
         MVC   CTYPE(8,CESD),ETYPE(PTR)  KEEP INPUT ADDR.AND LNG.       22740000
         LR    WORKC,CESD               SAVE EXTENDED ENTRY ADDR        22800000
         BAL   RETURN,CESDENT           GET ANOTHER CESD ENTRY          22860000
         MVC   CNAME(9,CESD),ENAME(PTR) MOVE NAME AND TYPE              22920000
         NI    CTYPE(CESD),X'07'        CLEAR FLAGS EXCEPT TYPE         22980000
         XC    CTYPE+1(3,CESD),CTYPE+1(CESD) CLEAR ER CHAIN             23040000
         ST    WORKC,CREL(CESD)         SAVE PTR TO EXTENDED ENTRY      23100000
         B     CHAINING                 GO TO CHAIN AND TRANSLATE       23160000
********                                                        ******* 23220000
*                          INPUT ESD TYPE IS 'LR' OR 'LD'             * 23280000
********                                                        ******* 23340000
NOMATLD  TM    ETYPE(PTR),LR            IS TYPE'LR'                     23400000
         BM    NOMATER                  NO, TYPE IS 'ER'                23460000
NOMATLD1 L     WORKC,ESDADDR(PTR)       CESD ADDR OF SD ENTRY           23520000
         MVC   CNAME(8,CESD),ENAME(PTR) YES, MOVE NAME TO CESD          23580000
         TM    CTYPE(WORKC),DELETE      IS 'SD' FOR 'LR' DELETE         23640000
         BZ    NOMATLD2                 NO                              23700000
         MVI   ETYPE(PTR),ER            SET TYPE TO 'ER'                23760000
         MVI   CTYPE(CESD),ER+DELINK    SET CESD TYPE TO ER WITH DELINK 23820000
         MVC   CREL+1(3,CESD),EADR+1(PTR) SAVE DELINKING FACTOR         23880000
         XC    CADR+1(3,CESD),CADR+1(CESD) CLEAR RLD CHAIN FIELD        23940000
         OI    CREL(CESD),X'80'        TURN SPEC DELETE BIT ON  SA70542 23990021
         B     CHAINING                 GO TO CHAIN ENTRY               24000000
NOMATLD2 BAL   RETURN,ENTERLR           MAKE LR CESD ENTRY              24060000
         BAL   RETURN,CHECKEP          CHECK FOR EP NAME                24120000
         BAL   RETURN,IEWLMAP           GO TO MAKE MAP ENTRY            24180000
         B     CHAINING                 GO TO CHAIN AND TRANSLATE       24240000
********                                                        ******* 24300000
*                         INPUT ESD TYPE IS 'ER'                      * 24360000
********                                                        ******* 24420000
NOMATER  MVC   CNAME(16,CESD),ENAME(PTR) MOVE ESD INFO. TO CESD ENTRY   24480000
         CLI   ETYPE(PTR),ERWEAK   IS THIS W-CON                 A39336 24500021
         BE    NOMATER1            YES, DON'T CLEAR FLAGS        A39336 24520021
         NI    CTYPE(CESD),X'07'         CLEAR FLAGS EXCEPT FOR TYPE    24540000
NOMATER1 EQU   *                                            INC288      24550000
         XC    CADR+1(7,CESD),CADR+1(CESD) CLEAR ALL BUT NAME AND TYPE  24600000
         CLI   ESUBTYP(PTR),X'06'      IS ESD MARKED NEVER-CALL         24660000
         BNE   ENTERCH                NO                        SA62460 24720021
         OI    CTYPE(CESD),NEVERCAL    SET NEVER-CALL INCIC IN CESD'ER' 24780000
ENTERCH  LA    WORKB,CMERCHN                                    SA62460 24830021
         L     WORKC,CMERCHN                                    SA62460 24880021
NOMATER2 LTR   WORKC,WORKC                                      SA62460 24890021
         BZ    NOMATER3                                         SA62460 24892021
         LR    WORKB,WORKC                                      SA62460 24894021
         L     WORKC,0(WORKC)                                   SA62460 24896021
         B     NOMATER2                                         SA62460 24898021
NOMATER3 ST    CESD,0(WORKB)                                    SA62460 24898421
         XC    0(4,CESD),0(CESD)                                SA62460 24898821
         B     TRANSLAT                                         SA62460 24899221
         EJECT                                                          24900000
*********************************************************************** 24960000
**************************  MATCH  PROCESSING  ************************ 25020000
*                                                                     * 25080000
*********************************************************************** 25140000
********                                                        ******* 25200000
*                CESD TYPE IS 'SD' --- INPUT ESD TYPE IS 'SD'         * 25260000
********                                                        ******* 25320000
MATCHED  EQU   *                                                        25380000
         TM    CTYPE(CESD),NULL         IS CESD TYPE 'SD'               25440000
         BC    7,MATCHPR                NO                              25500000
         TM    ETYPE(PTR),NULL          IS INPUT ESD TYPE 'SD'          25560000
         BC    7,MATSDER                NO                              25620000
DELETE1  TM    CMFLAG4,CQMOD       IS THIS CMPLER-LDED TXT       A30142 25630021
         BZ    DELETE2             NO. WE WON'T READ TEXT               25650000
         L     WORKC,ELNG(PTR)     YES. GET ESD LENGTH                  25660000
         LA    WORKC,0(WORKC)      CLEAR HI-ORDER BYTE                  25670000
         A     WORKC,CMMODLNG      UPDATE MODULE LENGTH                 25680000
         LA    WORKC,7(WORKC)      AND ROUND IT                         25690000
         N     WORKC,DBLWRD                                             25700000
         ST    WORKC,CMMODLNG      STORE IT BACK                        25710000
DELETE2  TM    CTYPE(CESD),DELETE  IS ORIGINAL DELETE            A30142 25715021
         BO    UPDATERC            YES, USE IT                   A30142 25720021
         ST    CESD,CMESDSAV       SAVE CESD ADDR               SA56381 25725021
         BAL   RETURN,CESDENT      GET CESD ENTRY                A30142 25730021
         MVC   CNAME(8,CESD),ENAME(PTR)  MOVE NAME AND TYPE      A30142 25735021
         L     WORKC,CMESDSAV      GET ORIGINAL'S ADDR          SA56381 25740021
         L     WORKC,CADR(WORKC)   INTO WORKC                   SA49491 25742000
         LA    WORKC,0(WORKC)                                    A30142 25745021
         ST    WORKC,CADR(CESD)    STORE IT HERE                 A30142 25750021
         L     WORKB,EADR(PTR)     GET ESD INPUT ADDR            A30142 25755021
         LA    WORKB,0(WORKB)      CALC RELOCATION CONSTANT      A30142 25760021
         SR    WORKC,WORKB                                       A30142 25765021
         ST    WORKC,CREL(CESD)    STORE IT                      A30142 25770021
         MVC   CTYPE(1,CESD),ETYPE(PTR)  SET TYPE                A30142 25775021
         OI    CTYPE(CESD),DELETE  SET TO DELETE                 A30142 25780021
         B     CHAINING            GO TO CHAIN AND TRANSLATE     A30142 25785021
********                                                        ******* 25800000
*                CESD TYPE IS 'SD' --- INPUT ESD TYPE IS 'ER'         * 25860000
********                                                        ******* 25920000
MATSDER  TM    ETYPE(PTR),CM            IS INPUT ESD TYPE 'ER'          25980000
         BZ    TRANSLAT                YES,GO TO TRANSLATE              26040000
********                                                        ******* 26100000
*                CESD TYPE IS 'SD' --- INPUT ESD TYPE IS 'CM'         * 26160000
********                                                        ******* 26220000
MATSDCM  BO    UPDATERC                 BRANCH IF INPUT TYPE IS CM      26280021
********                                                        ******* 26340000
*                CESD TYPE IS 'SD' --- INPUT ESD TYPE IS 'LD'/'LR'    * 26400000
********                                                        ******* 26460000
MATSDLR  L     WORKC,ESDADDR(PTR)       GET'SD' ADDR                    26520000
         TM    CTYPE(WORKC),DELETE      IS'SD' MARKED DELETE            26580000
         BO    UPDATERC                 GO TO UPDATE RELOC. CONSTANT    26640000
         BAL   RETURN,RERINPT4         DUPLIC.SYMBOL-CONFLICTING TYPE   26700000
         B     UPDATERC                 GO TO UPDATE RELOC. CONSTANT    26760000
********                                                        ******* 26820000
*                CESD TYPE IS 'PR'---INPUT ESD TYPE IS 'PR'           * 26880000
********                                                        ******* 26940000
MATCHPR  TM    CTYPE(CESD),PR           IS CESD TYPE 'PR'               27000000
         BC    14,MATCHCM               NO                              27060000
         BNH   MATPRPR1                 NO, GO TO CHECK ALIGNMENT       27120000
         MVC   CLNG+1(3,CESD),ELNG+1(PTR) YES, USE ESD LNG              27180000
MATPRPR1 OC    CLNG(1,CESD),ELNG(PTR)   SET ALIGN. TO HIGHER VALUE      27240000
         B     TRANSLAT                 GO TO TRANSLATE                 27300000
********                                                        ******* 27360000
*               CESD TYPE IS 'CM' --- INPUT ESD TYPE IS 'SD'          * 27420000
********                                                        ******* 27480000
MATCHCM  TM    CTYPE(CESD),CM           IS CESD TYPE 'CM'               27540000
         BZ    MATCHER                  NO, CESD TYPE IS 'ER'           27600000
         BC    6,MATCHLR                NO, CESD TYPE IS 'LR'           27660000
         TM    ETYPE(PTR),NULL          YES, IS INPUT ESD TYPE 'SD'     27720000
         BC    7,MATCMER                NO                              27780000
         L     ADR,CREL(CESD)           GET ADDR OF EXTENDED ENTRY      27840000
         CLC   ELNG+1(3,PTR),CLNG+1(ADR) IS INPUT LNG GT CESD LNG       27900000
         BNL   MATCMSD1                  YES,USE INPUT LNG        M5478 27960021
         LA    ZERO,22                   MSG IEW1232              M5453 28010021
         LR    PARM,PTR                  PT TO ESD NAME           M5453 28060021
         L     BRANCH,ADERROR            ADDR OF ERROR ROUTINE    M5453 28070021
         BALR  RETURN,BRANCH             BR TO ERROR ROUTINE      M5453 28072021
MATCMSD1 L     WORKC,CMESDCHN                                           28080000
         ST    ADR,CMESDCHN                                             28140000
         ST    WORKC,0(ADR)             PUT EXTENDED ENTRY ON FREE CHN. 28200000
         B     MATERSD0                 GO TO HANDLE SAME AS SD-ER      28260000
********                                                        ******* 28320000
*           CESD TYPE IS 'CM' --- INPUT ESD TYPE IS 'ER'              * 28380000
********                                                        ******* 28440000
MATCMER  L     WORKC,CREL(CESD)         GET ADDR OF EXTENDED ENTRY      28500000
         MVC   CADR+1(3,WORKC),EADR+1(PTR)  SAVE INPUT ADDRESS          28560000
         TM    ETYPE(PTR),CM            IS ESD TYPE 'ER'                28620000
         BO    MATCMCM                  NO, ESD TYPE IS 'CM'            28680000
         BM    MATCMLR                  NO, TYPE IS 'LR' OR 'LD'        28740000
         XC    CADR+1(3,WORKC),CADR+1(WORKC)  MAKE SURE ADDR IS ZERO    28800000
         B     TRANSLAT                 GO TO TRANSLATE ID              28860000
********                                                        ******* 28920000
*           CESD  TYPE IS 'CM' --- INPUT ESD TYPE IS 'LR'/'LD'        * 28980000
********                                                        ******* 29040000
MATCMLR  L     WORKC,ESDADDR(PTR)       GET 'SD' ADDR                   29100000
         TM    CTYPE(WORKC),DELETE      IS'SD' DELETE                   29160000
         BO    TRANSLAT                 YES                             29220000
         BAL   RETURN,RERINPT4         DUPLIC.SYMBOL-CONFLICTING TYPE   29280000
         B     TRANSLAT                 GO TO TRANSLATE                 29340000
********                                                        ******* 29400000
*          CESD TYPE IS 'CM' --- INPUT ESD TYPE IS 'CM'               * 29460000
********                                                        ******* 29520000
MATCMCM  CLC   CLNG+1(3,WORKC),ELNG+1(PTR) IS CESD LNG BT ESD LNG       29580000
         BH    TRANSLAT                   YES, USE CESD LNG             29640000
         MVC   CLNG+1(3,WORKC),ELNG+1(PTR) USE ESD LENGTH               29700000
         B     TRANSLAT                  GO TO TRANSLATE                29760000
********                                                        ******* 29820000
*               CESD TYPE IS 'LR' ---INPUT ESD TYPE IS 'SD'           * 29880000
********                                                        ******* 29940000
MATCHLR  TM    ETYPE(PTR),NULL          IS ESD TYPE 'SD'                30000000
         BC    7,MATLRER               NO                               30060000
         B     DELETE1             YES. GO TO DELETE                    30150000
********                                                        ******* 30240000
*               CESD TYPE IS 'LR'--- INPUT ESD TYPE IS  'ER'          * 30300000
********                                                        ******* 30360000
MATLRER  TM    ETYPE(PTR),CM            IS ESD TYPE 'ER'                30420000
         BZ    TRANSLAT                 YES, GO TO TRANSLATE            30480000
********                                                        ******* 30540000
*               CESD TYPE IS 'LR' --- INPUT ESD TYPE IS 'LR'/'LD'     * 30600000
********                                                        ******* 30660000
MATLRLR  BC    6,MATSDLR               HANDLE SAME AS 'SD'-'LR'MATCH    30720000
********                                                        ******* 30780000
*           CESD TYPE IS 'LR' --- INPUT ESD TYPE IS 'CM'              * 30840000
********                                                        ******* 30900000
         BAL   RETURN,RERINPT4         DUPLIC.SYMBOL-CONFLICTING TYPE   30960000
         B     UPDATERC                 GO TO UPDATE RELOC.CONSTANT     31020000
********                                                        ******* 31080000
*           CESD TYPE IS 'ER' --- INPUT ESD TYPE IS 'SD'              * 31140000
********                                                        ******* 31200000
MATCHER  TM    ETYPE(PTR),NULL          IS INPUT ESD TYPE 'SD'          31260000
         BC    7,MATERLR                NO                              31320000
MATERSD0 L     WORKB,CMPREVPT           GET ADDR OF PREV ENTRY ON CHAIN 31380000
         L     WORKC,0(CESD)                                            31440000
         LTR   WORKB,WORKB              IS MATCH FIRST ON CHAIN         31500000
         BZ    MATERSD5                 YES                             31560000
         ST    WORKC,0(WORKB)           DECHAIN ENTRY                   31620000
MATERSD1 L     PARM,CADR(CESD)          GET ADDR. OF RLD CHAIN          31680000
         LA    PARM,0(PARM)            CLEAR TYPE FIELD                 31740000
         BAL   RETURN,ENTER             GO TO MAKE CESD  ENTRY          31800000
         BAL   RETURN,CHECKEP          CHECK FOR EP NAME                31860000
         BAL   RETURN,IEWLERTN          GO TO RESOLVE RLD CHAIN         31920000
MATERSD2 L     WORKC,ELNG(PTR)          GET ESD LENGTH                  31980000
         LA    WORKC,0(WORKC)          CLEAR HIGH ORDER BYTE            32040000
         LTR   WORKC,WORKC              IS LNG EQUAL TO ZERO            32100000
         BC    7,MATERSD3               NO                              32160000
         OI    CMRELFLG,CQNOLNG         YES, SET NOLENGTH INDICATOR     32220000
         OI    CTYPE(CESD),NOLEN   SET NOLENGTH INDICATOR       27445   32250000
         B     MATERSD4                                                 32280000
MATERSD3 A     WORKC,CMMODLNG                                           32340000
         ST    WORKC,CMMODLNG           UPDATE ACCUM. LENGTH            32400000
MATERSD4 BAL   RETURN,IEWLMAP           GO TO MAKE MAP ENTRY            32460000
         B     CHAINING                 GO TO CHAIN AND TRANSLATE       32520000
MATERSD5 TM    CTYPE(CESD),CM           IS 'CM' TO BE DECHAINED         32580000
         BO    MATERSD6                 YES                             32640000
         ST    WORKC,CMERCHN            DECHAIN 'ER'                    32700000
         B     MATERSD1                                                 32760000
MATERSD6 ST    WORKC,CMCMCHN            DECHAIN 'CM'                    32820000
         B     MATERSD1                                                 32880000
********                                                        ******* 32940000
*           CESD TYPE IS 'ER' --- INPUT ESD TYPE IS 'LD'/'LR'         * 33000000
********                                                        ******* 33060000
MATERLR  TM    ETYPE(PTR),CM            IS INPUT ESD TYPE'LD'OR'LR'     33120000
         BZ    MATERER                  NO, TYPE IS 'ER'                33180000
         BO    MATERCM                  NO, TYPE IS 'CM'                33240000
         L     PARM,CADR(CESD)          GET ADDR. OF RLD CHAIN          33300000
         LA    PARM,0(PARM)            CLEAR TYPE FIELD                 33360000
         LA    RETURN,MATERLR2          SET RETURN ADDR FOR ENTERLR RTN 33420000
         L     WORKC,ESDADDR(PTR)      GET 'SD' CESD ADDR               33480000
         NI    CREL(CESD),X'7F'        TURN OFF DELETE BIT      SA70542 33530021
         TM    CTYPE(WORKC),DELETE     IS 'SD' FOR 'LR' DELETE  SA70542 33532021
         BZ    ENTERLR                 NO,CONTINUE              SA70542 33534021
         OI    CREL(CESD),X'80'        TURN SPEC DELETE BIT ON  SA70542 33536021
         MVC   CREL+1(3,CESD),EADR+1(PTR) SAVE DELINKING FACTOR SA70542 33538021
         B     TRANSLAT                GO TO TRANSLATE ID       SA70542 33538421
ENTERLR  L     WORKB,EADR(PTR)          GET INPUT ADDR                  33540000
         LA    WORKB,0(WORKB)                                           33600000
         LR    WORKA,WORKB              SAVE FOR RC CALC.               33660000
         A     WORKB,CREL(WORKC)        CALC. LOADER ASSIGNED ADDR(LAA) 33720000
         ST    WORKB,CADR(CESD)         PUT IN CESD ENTRY               33780000
         TM    CMFLAG4,CQMOD       IS THIS COMPILER-LOADED TEXT         33800000
         BO    MATERLR1            YES. DON'T WORRY                     33820000
         CL    WORKB,CMLOWTBL           HAVE TABLES BEEN EXCEEDED       33840000
         BNH   MATERLR1                NO                               33900000
         B     RERSIZE2                PROGRAM TOO LARGE--ABORT         33960000
MATERLR1 MVI   CTYPE(CESD),LR           SET TYPE TO 'LR'                34020000
         SR    WORKB,WORKA              CALC RELOCATION CONSTANT        34080000
         ST    WORKB,CREL(CESD)         PUT RC IN CESD ENTRY            34140000
         BR    RETURN                                                   34200000
MATERLR2 BAL   RETURN,IEWLERTN          GO TO RESOLVE RLD CHAIN         34260000
         BAL   RETURN,CHECKEP          CHECK FOR EP NAME                34320000
         BAL   RETURN,IEWLMAP           GO TO MAKE MAP ENTRY            34380000
         B     DECHAIN                  GO TO DECHAIN'ER',CHAIN 'LR',   34440000
*                                            AND TRANSLATE ID           34500000
********                                                        ******* 34560000
*           CESD TYPE IS 'ER' --- INPUT ESD TYPE IS 'CM'              * 34620000
********                                                        ******* 34680000
MATERCM  LR    WORKC,CESD               SAVE CESD ADDR OF 'ER'          34740000
         BAL   RETURN,CESDENT           GET CESD ENTRY FOR EXTENDED ENT 34800000
         MVC   CADR(8,CESD),EADR(PTR)   MOVE TYPE,ADDR.AND LNG          34860000
         ST    CESD,CREL(WORKC)         SAVE PTR TO EXTENDED ENTRY      34920000
         LR    CESD,WORKC               RESTORE CESD ADDR OF 'ER'       34980000
         MVI   CTYPE(CESD),CM           SET TYPE TO 'CM'                35040000
         B     DECHAIN                  GO TO DECHAIN'ER',CHAIN'CM'     35100000
*                                          AND TRANSLATE ID             35160000
********                                                        ******* 35220000
*           CESD TYPE IS 'ER' --- INPUT ESD TYPE IS 'ER'              * 35280000
********                                                        ******* 35340000
MATERER  CLI   CTYPE(CESD),ER+DELINK    IS ER MARKED DELINK             35400000
         BNE   MATERER2                 NO                              35460000
         NI    CTYPE(CESD),X'FF'-DELINK SET DELINK INDIC OFF            35520000
         XC    CREL(4,CESD),CREL(CESD) CLEAR DELINK FIELD       SA70542 35580021
MATERER2 TM    ETYPE(PTR),WEAKCALL IS WEAKCALL FLAG ON INC288           35650000
         BO    MATERER3            YES. LEAVE CESD AS IS   INC288       35660000
         NI    CTYPE(CESD),X'FF'-WEAKCALL  NO. MAKE SURE  INC288        35670000
*                                  WX IS OFF   INC288                   35680000
MATERER3 CLI   ESUBTYP(PTR),X'06'  IS ESD MARKED NEVCAL  INC288         35690000
         BNE   TRANSLAT                 NO, GO TO TRANSLATE ID          35700000
         OI    CTYPE(CESD),NEVERCAL    SET NEVERCALL INDIC.IN CESD'ER'  35760000
         B     TRANSLAT                GO TO TRANSLATE ID               35820000
         EJECT                                                          35880000
********                                                        ******* 35940000
*        THIS ROUTINE DECHAINS CESD ENTRIES WHEN THEIR TYPE CHANGES   * 36000000
********                                                        ******* 36060000
DECHAIN  L     WORKB,CMPREVPT           GET ADDR.OF PREV.ENTRY ON CHAIN 36120000
         L     WORKC,0(CESD)            GET ADDR.OF NEXT ENTRY ON CHAIN 36180000
         LTR   WORKB,WORKB             IS MATCH FIRST ON CHAIN          36240000
         BZ    DECHAIN1                YES                              36300000
         ST    WORKC,0(WORKB)           DECHAIN ENTRY                   36360000
         B     CHAINING                                                 36420000
DECHAIN1 ST    WORKC,CMERCHN           DECHAIN FIRST 'ER' ENTRY         36480000
********                                                        ******* 36540000
*        THIS ROUTINE CHAINS CESD ENTRIES ACCORDING TO TYPE           * 36600000
********                                                        ******* 36660000
CHAINING IC    WORKC,CTYPE(CESD)        GET CESD TYPE                   36720000
         N     WORKC,TYPEONLY                                           36780000
         SLL   WORKC,2                                                  36840000
         LA    WORKC,CMTYPCHN(WORKC)   CALC ADDR OF CHAIN TABLE         36900000
         L     WORKB,0(WORKC)                                           36960000
         ST    CESD,0(WORKC)            CHAIN NEW CESD ENTRY            37020000
         ST    WORKB,0(CESD)                                            37080000
********                                                        ******* 37140000
*        THIS ROUTINE MAKES A TRANSLATION TABLE ENTRY                 * 37200000
********                                                        ******* 37260000
TRANSLAT TM    ETYPE(PTR),X'06'         IS INPUT TYPE 'LD'              37320000
         BC    7,TRANS10                NO, GO TO TRANSLATE ID.         37380000
         TM    ETYPE(PTR),LD                                            37440000
         BO    NEXTESD                  YES,DON'T TRANSLATE             37500000
TRANS10  OI    CMRELFLG,CQESD           YES, SET ESD CALLER INDICATOR   37560000
         BAL   RETURN,TRANSID           GO TO TRANSLATE ID              37620000
         NI    CMRELFLG,CQFF-CQESD      SET OFF ESD CALLER INDICATOR    37680000
         LTR   PARM,PARM                WAS BAD ID ENCOUNTERED          37740000
         BZ    NEXTESD                  YES, GET NEXT ESD ITEM          37800000
         ST    CESD,0(PARM)             MAKE TRANSLATION TABLE ENTRY    37860000
         TM    ETYPE(PTR),X'05'         IS ESD TYPE 'ER'                37920000
         BC    7,NEXTESD               NO                               37980000
         TM    ETYPE(PTR),X'02'                                         38040000
         BZ    NEXTESD         '       NO                               38100000
         OI    0(PARM),ERMATCH         YES, SET INDIC FOR ABS. FACTOR   38160000
*                                            IF AN 'A'TYPE ADCON IS     38220000
*                                            USED TO REFERENCE THIS     38280000
*                                            EXTERNAL REFERENCE, THE    38340000
*                                            LOADER ASSIGNED ADDR.MUST  38400000
*                                            BE USED FOR RELOCATION     38460000
*                                            INSTEAD OF THE NORMAL      38520000
*                                            RELATIVE RELOCATION FACTOR 38580000
********                                                       ******** 38640000
*  THIS ROUTINE PREPARES TO PROCESS THE NEXT ESD IF THERE IS ONE      * 38700000
********                                                       ******** 38760000
NEXTESD  TM    ETYPE(PTR),X'06'         IS INPUT ESD TYPE'LD'           38820000
         BC    7,NEXT10                 NO                              38880000
         TM    ETYPE(PTR),LD                                            38940000
         BO    NEXT20                   YES, DON'T UPDATE ID            39000000
NEXT10   LA    ID,1(ID)                 UPDATE ID                       39060000
NEXT20   LA    PTR,16(PTR)              UPDATE INPUT RECORD PTR         39120000
         SH    LNG,CONT16                                               39180000
         BP    ESDSTART                 GO TO PROCESS NEXT ESD          39240000
********                                                        ******* 39360000
*   THIS ROUTINE DOES END OF RECORD PROCESSING FOR THE LD CHAIN,IF IT * 39420000
*     EXISTS. THIS CHAIN CONSISTS OF LDS WHOSE SD WAS NOT DEFINED WHEN* 39480000
*     THE LD WAS PROCESSED.                                           * 39540000
********                                                        ******* 39600000
LDRTN    L     PTR,CMLDCHN             GET BEGINNING OF 'LD' CHAIN      39660000
         LTR   PTR,PTR                  IS THERE AN LD CHAIN            39720000
         BZ    LD20                     NO                              39780000
         TM    CTYPE(PTR),LDCHAIN       HAS CHAIN BEEN PROCESSED FOR    39840000
*                                            THIS RECORD                39900000
         BZ    LD10                     NO                              39960000
         NI    CTYPE(PTR),X'FF'-LDCHAIN TURN OFF PROCESSED INDIC        40020000
         B     ESDEND                   BRANCH TO RETURN                40080000
LD10     L     WORKB,0(PTR)             DECHAIN LD ENTRY                40140000
         ST    WORKB,CMLDCHN                                            40200000
         LA    LNG,16                   SET ESD LENGTH TO ONE ENTRY     40260000
         OI    CTYPE(PTR),LDCHAIN       SET PROCESSED THIS RECORD INDIC 40320000
         LA    PTR,4(PTR)              POINT TO ESD ITEM                40380000
         B     ESD35                                                    40440000
LD20     TM    CMLIBFLG,CQCESDR         IS THIS END OF CESD PROCESSING  40500000
         BZ    CESDEND                  YES,CONTINUE END OF CESD PROC.  40560000
ESDEND   L     SAVEREG,4(SAVEREG)       RESTORE SAVE AREA PTR           40620000
         RETURN (14,12),T                                               40680000
         EJECT                                                          40740000
**********************  SPECIAL LOAD MODULE PROCESSING **************** 40800000
*     THIS ROUTINE SETS ASIDE ALL PC,SD,AND LR CESD TYPES FOR A LOAD  * 40860000
*       MODULE AND THEN PROCESSES THEM AT END OF CESD.  THIS IS NEEDED* 40920000
*       BECAUSE SOME LOAD MODULES ARE NOT ASSIGNED ADDRESSES ACCORDING* 40980000
*       TO THE ORDER IN THE CESD.                                     * 41040000
*********************************************************************** 41100000
LOADPROC TM    CMLIBFLG,CQCESDR         IS THIS END OF CESD             41160000
         BZ    CESDEND                  YES,GO TO END OF CESD PROCESS   41220000
         TM    ETYPE(PTR),NULL          IS TYPE SD,PC OR LR             41280000
         BO    ESD15                    TYPE IS NULL                    41340000
         BZ    LOAD20                   TYPE IS SD                      41400000
         TM    ETYPE(PTR),LR                                            41460000
         BC    6,ESD10                  TYPE IS CM,PR,OR ER             41520000
         BZ    LOAD10                   TYPE IS PC                      41580000
         OI    CMCURRID,X'80'           IDENTIFY TYPE AS LR             41640000
         B     LOAD20                                                   41700000
LOAD10   TM    ETYPE(PTR),X'10'        IS PC DELETE(ENTAB-SEGTAB)       41760000
         BO    ESD15                   GO TO PROCESS AS NULL            41820000
LOAD20   BAL   RETURN,CESDENT           GET CESD ENTRY                  41880000
         MVC   CNAME(16,CESD),ENAME(PTR) MOVE  INFO.TO CESD ENTRY       41940000
         MVC   CTYPE+2(3,CESD),EADR+1(PTR) CREATE SPECIAL ENTRY FOR ID  42000000
         MVC   CTYPE(2,CESD),CMCURRID   MOVE ID AND TYPE TO CESD ENTRY  42060000
         NI    CMCURRID,X'7F'          CLEAR LR INDIC                   42120000
         LA    WORKA,CMLOADCH           SET AS PREVIOUS CHAIN ADDR      42180000
         L     WORKC,CMLOADCH           GET BEGINNING CHAIN ADDR        42240000
LOAD25   LA    WORKC,0(WORKC)           CLEAR SEGMENT NUMBER            42300000
         LTR   WORKC,WORKC              IS THIS END OF CHAIN            42360000
         BZ    LOAD45                   YES,GO TO CHAIN ENTRY           42420000
         CLC   ESEGNO(1,PTR),0(WORKC)   COMPARE SEGMENT NUMBERS         42480000
         BL    LOAD45                   CHAIN BEFORE                    42540000
         BH    LOAD30                   CONTINUE SEARCH                 42600000
         CLC   EADR+1(3,PTR),CADR+2(WORKC) COMPARE ADDRESSES            42660000
         BE    LOAD40                   ADDR. EQUAL                     42720000
         BL    LOAD45                   INPUT ADDR. LT EXISTING ADDR.   42780000
LOAD30   LR    WORKA,WORKC              SAVE AS RPEVIOUS CHAIN ADDR     42840000
         L     WORKC,0(WORKC)           GET NEXT ENTRY FROM CHAIN       42900000
         B     LOAD25                   CONTINUE SEARCH                 42960000
LOAD40   TM    ETYPE(PTR),X'03'        CHAIN LRS AFTER SDS,PCS   A59776 43020021
         BO    LOAD30                  TYPE IS LR. CONT SEARCH   A59776 43080021
LOAD45   LR    WORKC,WORKA              CHAIN BEFORE MATCHED ENTRY      43140000
LOAD50   L     WORKB,0(WORKC)           CHAIN AFTER  MATCHED ENTRY      43200000
         ST    WORKB,0(CESD)                                            43260000
         MVC   0(1,CESD),ESEGNO(PTR)    ENTER SEGMENT NUMBER            43320000
         ST    CESD,0(WORKC)                                            43380000
         SRL   WORKB,24                 RIGHT ADJUST SEGMENT NUMBER     43440000
         STC   WORKB,0(WORKC)           PRESERVE SEGMENT NUMBER         43500000
         B     NEXTESD                  GET NEXT ESD                    43560000
CESDEND  L     WORKC,CMTEMPCH           GET ADDR.OF FREE LOAD CHN.ENTRY 43620000
         LTR   WORKC,WORKC             IS THERE A LOAD CH ENTRY TO FREE 43680000
         BZ    CESDEND0                NO                               43740000
         L     WORKB,CMESDCHN          YES,CHAIN IT TO FREE ESD CHAIN   43800000
         ST    WORKC,CMESDCHN                                           43860000
         ST    WORKB,0(WORKC)                                           43920000
         XC    CMTEMPCH(4),CMTEMPCH    CLEAR CHAIN POINTER              43980000
CESDEND0 L     PTR,CMLOADCH            GET NEXT ESD                     44040000
         LA    PTR,0(PTR)               CLEAR SEGMENT NUMBER            44100000
         LTR   PTR,PTR                  ANY ENTRIES ON CHAIN            44160000
         BZ    ESDEND                   NO, RETURN TO CALLER            44220000
         LA    LNG,16                   SET LENGTH EQ TO ONE ESD ENTRY  44280000
         LH    ID,CTYPE(PTR)            GET  ID                         44340000
         MVC   CADR+1(3,PTR),CADR+2(PTR) READJUST INPUT ADDR FIELD      44400000
         MVI   CREL(PTR),X'00'         CLEAR HIGH BYTE OF R.C.          44460000
         TM    CTYPE(PTR),X'80'         IS TYPE'LR'                     44520000
         BZ    CESDEND1                 NO                              44580000
         SLL   ID,17                    YES, ZERO HIGH ORDER BITS OF ID 44640000
         SRL   ID,17                                                    44700000
         MVI   CTYPE(PTR),LR           SET TYPE TO 'LR'                 44760000
         B     CESDEND2                                                 44820000
CESDEND1 MVI   CTYPE(PTR),SD           SET TYPE TO 'SD'                 44880000
         CLI   CNAME(PTR),C' '         IS TYPE 'PC'                     44940000
         BNE   CESDEND2                NO                               45000000
         MVI   CTYPE(PTR),PC           SET TYPE TO 'PC'                 45060000
CESDEND2 L     WORKC,0(PTR)             TAKE ENTRY OFF LOAD CHAIN       45120000
         LA    WORKC,0(WORKC)           CLEAR SEGMENT NUMBER            45180000
         ST    WORKC,CMLOADCH                                           45240000
         LA    PTR,0(PTR)               CLEAR SEGMENT NUMBER            45300000
         ST    PTR,CMTEMPCH            SAVE ESD PTR TO FREE AFTER PROC. 45360000
         LA    PTR,4(PTR)               UPDATE PAST CHAIN FIELD         45420000
         STH   ID,CMCURRID             SAVE ID                          45480000
         B     ESD10                    GO TO PROCESS ESD               45540000
         EJECT                                                          45600000
********************  CESD ENTRY ALLOCATION  ************************** 45660000
*                                                                     * 45720000
*    THIS SUBROUTINE GETS A CESD ENTRY FROM CESD FREE ENTRIES CHAIN   * 45780000
*       OR CALLS THE ALLOCATE ROUTINE FOR ALLOCATION OF ONE ENTRY     * 45840000
*       THE ENTRY ADDRESS IS RETURNED IN #PARM AND #CESD              * 45900000
*                                                                     * 45960000
*********************************************************************** 46020000
CESDENT  STM   14,1,12(13)              SAVE REGISTERS 14-1             46080000
         L     PARM,CMESDCHN            GET BEGINNING OF FREE CESD CHN  46140000
         LTR   PARM,PARM                IS IT EMPTY                     46200000
         BC    7,CESDDCHN              NO                               46260000
         LA    ZERO,20                  SET ENTRY LENGTH                46320000
         BAL   RETURN,ALLOCATE          GO TO ALLOCATE A CESD ENTRY     46380000
CESDRTRN LM    14,0,12(13)              YES,RESTORE REGS. 14-0          46440000
         LR    CESD,PARM                                                46500000
         BR    RETURN                   RETURN                          46560000
CESDDCHN L     ZERO,0(PARM)            DECHAIN ENTRY FROM FREE CHAIN    46620000
         ST    ZERO,CMESDCHN                                            46680000
         B     CESDRTRN                 GO TO RETURN                    46740000
         EJECT                                                          46800000
**********************  MAKE CESD ENTRY FOR PC AND SD  **************** 46860000
*                          #CESD-ADDR.OF CESD ENTRY                   * 46920000
*                          #PTR-ADDR.OF INPUT ESD ITEM                * 46980000
*********************************************************************** 47040000
ENTER    MVC   CNAME(8,CESD),ENAME(PTR) MOVE NAME TO CESD               47100000
         L     WORKC,CMMODLNG          GET ACCUM. LENGTH                47160000
         LA    WORKC,7(WORKC)                                           47220000
         N     WORKC,DBLWRD            ROUND TO DOUBLE WORD             47280000
         ST    WORKC,CMMODLNG          SAVE ROUNDED LENGTH              47340000
         TM    CMFLAG4,CQMOD      IS THIS COMPILER-LOADED TEXT          47360000
         BZ    ENTER05            NO                                    47380000
         A     WORKC,CMCORE1      YES. USE COMPILER-ASSIGNED ADR        47400000
         B     ENTER10                                                  47420000
ENTER05  A     WORKC,CMNXTTXT     CALCUATE NEXT CSECT ADDRESS           47440000
         CL    WORKC,CMLOWTBL           HAS CORE BEEN EXCEEDED          47460000
         BH    RERSIZE2                 YES,PROGRAM TOO LARGE-ABORT     47520000
ENTER10  ST    WORKC,CADR(CESD)         LOADER ASSIGNED ADDR TO CESD    47580000
         MVC   CTYPE(1,CESD),ETYPE(PTR) MOVE FLAG FIELD TO CESD         47640000
         NI    CTYPE(CESD),X'07'        CLEAR FLAGS EXCEPT FOR TYPE     47700000
         L     WORKB,EADR(PTR)          GET INPUT ADDR.                 47760000
         LA    WORKB,0(WORKB)           CLEAR HIGH ORDER BYTES          47820000
         SR    WORKC,WORKB              RELOC.VALUE=LAA-INPUT ADDR      47880000
         ST    WORKC,CREL(CESD)         RELOC.VALUE TO CESD             47940000
         BR    RETURN                   RETURN                          48000000
         EJECT                                                          48060000
********                                                        ******* 48120000
*    THIS ROUTINE UPDATE THE RELOCATION CONSTANT,THEN GOES TO TRANSLAT* 48180000
********                                                        ******* 48240000
UPDATERC L     WORKC,EADR(PTR)          GET ESD INPUT ADDR.             48300000
         LA    WORKC,0(WORKC)                                           48360000
         L     WORKB,CADR(CESD)        GET LOADER ASSIGNED ADDR.        48420000
         LA    WORKB,0(WORKB)                                           48480000
         SR    WORKB,WORKC              CALC. RELOCATION CONSTANT       48540000
         ST    WORKB,CREL(CESD)         UPDATE RC.                      48600000
         B     TRANSLAT                 GO TO TRANSLATE                 48660000
         EJECT                                                          48720000
********                                                        ******* 48780000
*                        CHECK FOR ENTRY POINT NAME                   * 48840000
********                                                        ******* 48900000
CHECKEP  TM    CMPRMFLG,CQEPNAME+CQEPADDR HAS ENTRY PT.BEEN DEFINED     48960000
         BCR   9,RETURN                 YES OR AN ENTRY POINT WAS NOT   49020000
*                                            SPECIFIED                  49080000
         TM    CMPRMFLG,CQEPNAME        WAS A NAME DEFINED              49140000
         BCR   8,RETURN                 NO,RETURN                       49200000
         CLC   CMEPNAME(8),CNAME(CESD)  IS CURRENT CESD THE ENTRY POINT 49260000
         BCR   7,RETURN                NO                               49320000
         MVC   CMEPADDR+1(3),CADR+1(CESD) YES, SAVE EP  ADDR            49380000
         OI    CMPRMFLG,CQEPADDR        SET EP ADDR DEFINED INDICATOR   49440000
         BR    RETURN                                                   49500000
         EJECT                                                          49560000
***************************  TEXT PROCESSOR  ************************** 49620000
*                                                                     * 49680000
*    THIS ROUTINE LOADS TEXT INTO MAIN STORAGE.   IT  EXPECTS THE     * 49740000
*        FOLLOWING REGISTER CONTENT:                                  * 49800000
*                                                                     * 49860000
*             #ID - TEXT ID                                           * 49920000
*             #ADR- DISPLACEMENT ADDR OF TEXT                         * 49980000
*             #LNG- LENGTH OF TEXT                                    * 50040000
*             #PTR- ADDRESS OF TEXT IN BUFFER                         * 50100000
*                                                                     * 50160000
*********************************************************************** 50220000
IEWLTXT  LTR   LNG,LNG                  IS THERE ANY TEXT               50280000
         BZ    RELOREAD                 NO, GO TO READ NEXT RECORD      50340000
         TM    CMFLAG4,CQMOD      WAS MOD RECORD ALSO RECEIVED          50360000
         BO    RELOREAD           IGNORE THIS TEXT                      50380000
         BAL   RETURN,TRANSID           CONVERT ID TO TRANS.TABLE ADDR  50400000
         LTR   PARM,PARM                WAS CONVERSION POSSIBLE         50460000
         BZ    RELOREAD                 NO,BAD ID ENCOUNTERED           50520000
TXT10    TM    CTYPE(CESD),DELETE       SHOULD TEXT BE DELETED          50580000
         BO    RELOREAD                 TEXT IS DELETE,GO TO READ       50640000
         OI    CMLIBFLG,CQNOTXT        SET TEXT RECEIVED INDICATOR      50700000
         TM    CTYPE(CESD),NOLEN   WAS THIS ZERO-LENGTH CSECT   27445   50720000
         BNO   TXT20               NO                           27445   50740000
         OI    CMRELFLG,CQNOLNTX   SHOW TEXT WAS RECEIVED       27445   50760000
TXT20    A     ADR,CREL(CESD)      CALC MAIN STORAGE TEXT ADR   27445   50780000
         LA    WORKC,0(LNG,ADR)        CALC END TEXT ADDR.              50820000
         CL    WORKC,CMLOWTBL          WILL TEXT OVERLAP TABLES         50880000
         BH    RERSIZE2                YES,PROGRAM TOO LARGE--ABORT     50940000
         BCTR  LNG,0                                                    51000000
         EX    LNG,MOVE2                MOVE TEXT INTO MAIN STORAGE     51060000
         LA    ADR,1(ADR,LNG)          CALC. EXTENT OF TEXT ADDED       51120000
         CL    ADR,CMLSTTXT             IS HIGHEST TEXT ADDR.EXCEEDED   51180000
         BNH   RELOREAD                 NO                              51240000
         ST    ADR,CMLSTTXT             UPDATE HIGHEST TXT ADDR         51300000
         B     RELOREAD                GO TO READ NEXT RECORD           51360000
         EJECT                                                          51361000
****************************MOD PROCESSOR****************************** 51362000
*                                                                     * 51363000
*        THIS ROUTINE PICKS UP ORIGIN AND EXTENT INFORMATION          * 51364000
*        FOR COMPILER-LOADED TEXT FROM MOD CARDS PASSED THROUGH AN    * 51365000
*        INCORE DATA SET.  IT EXPECTS THE FOLLOWING REGISTER CONTENT  * 51366000
*                                                                     * 51367000
*              #LNG - LENGTH OF INFO                                  * 51368000
*         #PTR - ADDRESS OF INFO IN BUFFER                            * 51369000
*                                                                     * 51370000
*********************************************************************** 51371000
IEWLMOD  TM    CMFLAG3,CQINCORE   IS THIS INCORE DATA SET               51372000
         BZ    RELOREAD           NO. IGNORE IT                         51373000
         TM    CMFLAG4,CQESDS     ESD CARDS ALREADY RECEIVED            51374000
         BNZ   RELOREAD           YES. IGNORE THIS THEN                 51375000
         LTR   LNG,LNG            ANY MOD INFO                          51376000
         BZ    RELOREAD           NO. IGNORE IT                         51377000
         OI    CMLIBFLG,CQNOTXT    SET TEXT RECEIVED                    51378000
         OI    CMFLAG4,CQMOD      SET MOD RECEIVED                      51379000
         L     WORKC,0(PTR)       GET ORIGIN OF TEXT                    51380000
         LTR   WORKC,WORKC         WAS IT SPECIFIED                     51381000
         BZ    MODEXTNT            NO. SEE IF EXTENTS DEFINED           51382000
MOD10    ST    WORKC,CMCORE1      SAVE ORIGIN OF TEXT                   51383000
         L     WORKC,4(PTR)       GET LAST ADDRESS                      51384000
         ST    WORKC,CMCORE2      SAVE IT                               51385000
MODEXTNT LA    WORKC,8             SEE IF THERE'S EXTENT INFO           51386000
         SR    LNG,WORKC           IS LENGTH GREATER THAN 8             51387000
         BNP   RELOREAD            NO. BRANCH                           51388000
MODEXT   LA    ZERO,12             GET THREE WORDS TO SAVE              51389000
         BAL   RETURN,ALLOCATE     EXTENT INFO IN                       51390000
         L     WORKC,CMLOWTBL      FIND ADDRESS                         51391000
         MVC   0(4,WORKC),CMXLCHN  CHAIN IT                             51392000
         MVC   CMXLCHN(4),CMLOWTBL TO OTHER EXTENTS                     51393000
         MVC   4(8,WORKC),8(PTR)   MOVE IN EXTENT INFO                  51394000
         LH    WORKC,CMNUMXS       PICK UP NUMBER OF EXTENTS            51395000
         TM    CMPRMFLG,CQEPNAME+CQEPADDR   HAS ENTRY POINT BEEN DEF    51396000
         BNZ   MODEXT1             YES.                                 51397000
         LTR   WORKC,WORKC         NO. IS THIS FIRST EXTENT             51398000
         BNZ   MODEXT1             NO                                   51399000
         MVC   CMEPADDR(4),8(PTR)  YES. USE IT AS ENTRY POINT           51400000
MODEXT1  LA    WORKC,1(WORKC)      ADD AN EXTENT                        51401000
         STH   WORKC,CMNUMXS       TO TOTAL                             51402000
         B     RELOREAD            GO GET ANOTHER RECORD                51411000
         EJECT                                                          51420000
*************************   RLD PROCESSOR   *************************** 51480000
*                                                                     * 51540000
*    THIS SUBROUTINE RELOCATES ADDRESS CONSTANTS USING THE RELOCATION * 51600000
*      DICTIONARY (RLDS) ENTRIES SENT IT.  IF RELOCATION IS NOT       * 51660000
*      POSSIBLE, THE RLDS ARE CHAINED OFF OF THE R PTR CESD ENTRY.    * 51720000
*      IT EXPECTS:                                                    * 51780000
*            #PTR-POINTER TO RLD INFORMATION                          * 51840000
*            #LNG-LENGTH OF RLD INFORMATION                           * 51900000
*********************************************************************** 51960000
IEWLRLD  EQU   *                                                        52020000
         STM   14,12,12(13)             SAVE REGISTERS                  52080000
RLDBASE  BALR  BASE,0                                                   52140000
         USING *,BASE                                                   52200000
         L     BASE,ABEGIN                                              52260000
         USING IEWLRELO,BASE           RESET BASE TO INITIAL VALUE      52320000
         L     BASE2,ABEG4096          SET UP SECOND BASE REG   SA49491 52370000
         USING IEWLRELO+4096,BASE2     ESTABLISH ADDRESSABILITY SA49491 52372000
         B     NRLD+8                                                   52380000
NRLD     DC    C'IEWLRLD '                                              52440000
         L     SAVEREG,8(SAVEREG)       PICK UP NEXT SAVE AREA ADDR.    52500000
RLD10    LTR   LNG,LNG                  ARE ALL RLDS PROCESSED          52560000
         BC    2,RLD30                  NO.                             52620000
RLD19    L     SAVEREG,4(SAVEREG)       RESTORE SAVE AREA PTR           52680000
         RETURN (14,12),T                                               52740000
*                                                                     * 52800000
*                    CHECK VALIDITY OF P PTR                          * 52860000
*                                                                     * 52920000
RLD30    TM    CMRELFLG,CQENTRY         IS THIS THE ENTRY POINT RLD     52980000
         BO    RLD35                    YES                             53040000
         LH    ID,P(PTR)                GET P PTR                       53100000
         BAL   RETURN,TRANSID           GET TRANS. TABLE ENTRY ADDR     53160000
         LTR   PARM,PARM                WAS TRANSLATION POSSIBLE        53220000
         BZ    RLD65                    NO                              53280000
         L     WORKA,0(PARM)            GET CESD ENTRY ADDR             53340000
         TM    CTYPE(WORKA),DELETE      IS CSECT MARKED DELETE          53400000
         BO    RLD65                    YES                             53460000
         TM    RLDFLG(PTR),ACCUMPR     IS RLD CXD PSEUDO REG. TYPE      53520000
         BO    RLD40                   YES                              53580000
*                                                                     * 53640000
*                       CHECK VALIDITY OF R PTR                       * 53700000
*                                                                     * 53760000
RLD35    LH    ID,R(PTR)                GET R PTR                       53820000
         BAL   RETURN,TRANSID           GET TRANS, TABLE ENTRY ADDR     53880000
         LTR   PARM,PARM                WAS TRANSLATION POSSIBLE        53940000
         BZ    RLD65                    NO                              54000000
*                                                                     * 54060000
*           RELOCATE ADCON ADDRESS - MAKE RLD TABLE ENTRY             * 54120000
*                                                                     * 54180000
RLD40    L     PARM,CMRLDCHN            GET BEG.ADDR OF FREE RLD TABLE  54240000
*                                            ENTRIES                    54300000
         LTR   PARM,PARM                IS IT EMPTY                     54360000
         BC    7,RLD45                  NO                              54420000
         LA    ZERO,8                   YES, INDICATE ENTRY SIZE        54480000
         BAL   RETURN,ALLOCATE          GO TO ALLOCATE ENTRY            54540000
         B     RLD48                    NO, CONTINUE PROCESSING         54600000
RLD45    L     ZERO,0(PARM)             DECHAIN ENTRY FROM FREE CHAIN   54660000
         ST    ZERO,CMRLDCHN                                            54720000
RLD48    L     WORKB,RLDADR(PTR)                                        54780000
         LA    WORKB,0(WORKB)                                           54840000
         A     WORKB,CREL(WORKA)        CALC. ADCON ADDRESS             54900000
         ST    WORKB,4(PARM)            SAVE ADCON ADDRESS IN RLD TABLE 54960000
         TM    RLDFLG(PTR),ACCUMPR     IS RLD CXD PSEUDO REG. TYPE      55020000
         BO    RLD100                  YES                              55080000
         MVC   4(1,PARM),RLDFLG(PTR)    SAVE FLAG FIELD IN RLD TABLE    55140000
         LTR   CESD,CESD               IS ABSOLUTE FACTOR NEEDED        55200000
         BC    11,RLD49                NO                               55260000
         OI    4(PARM),ERMATCH         USE ABSOLUTE FACTOR              55320000
*                                                                     * 55380000
*        CHECK R PTR TYPE --- RELOCATE RLD OR CHAIN IT TO CESD ENTRY  * 55440000
*                                                                     * 55500000
RLD49    TM    CTYPE(CESD),LR          R PTR TYPE IS SD,PC,OR LR        55560000
         BM    RLD70                    NO                              55620000
         XC    0(4,PARM),0(PARM)       CLEAR CHAIN FIELD                55680000
         BAL   RETURN,IEWLERTN         GO TO RELOCATE RLD               55740000
RLD50    TM    RLDFLG(PTR),CONT         IS NEXT RLD ITEM CHAINED        55800000
         BC    14,RLD60                 NO, GO TO GET NEXT R-P PTR      55860000
*                                                                     * 55920000
*                     UPDATE TO NEXT FA FIELD                         * 55980000
*                                                                     * 56040000
         LA    PTR,4(PTR)               UPDATE TO NEXT FA FIELD         56100000
         SH    LNG,CONT4                                                56160000
         CH    LNG,CONT4                ARE ANY RLDS LEFT               56220000
         BH    RLD40                    YES, GO TO PROCESS NEXT RLD     56280000
         BAL   RETURN,RERINPT9          INVALID INPUT FROM OBJ MODULE   56340000
         B     RLD19                   RETURN                           56400000
*                                                                     * 56460000
*              UPDATE TO NEXT R-P PTR                                 * 56520000
*                                                                     * 56580000
RLD60    LA    PTR,8(PTR)               UPDATE RLD PTR                  56640000
         SH    LNG,CONT8                DECR. LENGTH                    56700000
         B     RLD10                    GO TO PROCESS NEXT R-P PTR      56760000
RLD65    TM    RLDFLG(PTR),CONT         NEXT ITEM CHAINED               56820000
         BZ    RLD60                    NO                              56880000
         LA    PTR,4(PTR)               UPDATE POINTER                  56940000
         SH    LNG,CONT4                                                57000000
         LTR   LNG,LNG                  HAS RECORD END BEEN REACHED     57060000
         BC    2,RLD65                  NO, CONTINUE SEARCH FOR R-P     57120000
         B     RLD19                    YES, RETURN TO CALLER           57180000
*                                                                     * 57240000
*     R PTR TYPE IS CM,PR,OR ER  - CHAIN RLD TO CESD ENTRY            * 57300000
*                                                                     * 57360000
RLD70    TM    CTYPE(CESD),CM          IS CESD TYPE COMMON              57420000
         BO    RLD75                   YES                              57480000
         BZ    RLD72                    NO, CESD TYPE IS ER             57540000
         OI    4(PARM),PRRLD            CESD TYPE IS 'PR',SET PR FLAG   57600000
         B     RLD80                                                    57660000
*                                       PRECEDING CODING TO MARK RLD AS 57720000
*                                       DISPLACEMENT PR IS INCLUDED     57780000
*                                       BECAUSE THE ASSEMBLER PUTS OUT  57840000
*                                       NON-BRANCH RLDS FOR Q-TYPE      57900000
*                                       ADDRESS CONSTANTS               57960000
RLD72    TM    CTYPE(CESD),DELINK       DOES RLD NEED DELINKING         58020000
         BZ    RLD80                    NO                              58080000
RLD75    OI    CMRELFLG,CQDELINK        SET SPECIAL RELOCATION INDIC.   58140000
         BAL   RETURN,IEWLERTN          GO TO DELINK ADCON              58200000
RLD80    L     WORKC,CADR(CESD)                                         58260000
         ST    PARM,CADR(CESD)                                          58320000
         ST    WORKC,0(PARM)            CHAIN RLD TO CESD ENTRY         58380000
         MVC   CADR(1,CESD),0(PARM)    PRESERVE TYPE INDIC              58440000
         MVI   0(PARM),X'00'           CLEAR TYPE FROM CHAIN ADDR       58500000
         B     RLD50                    GO TO CHECK IF NEXT R-P OR ADDR 58560000
*                                                                     * 58620000
*                 RLD IS CXD PSEUDO REGISTER TYPE                     * 58680000
*                                                                     * 58740000
RLD100   L     WORKB,CMCXDPT           CHAIN ACCUM PSEUDO REGISTER      58800000
         ST    PARM,CMCXDPT                                             58860000
         ST    WORKB,0(PARM)                                            58920000
         B     RLD50                   GO TO CHECK IF NEXT R-P OR ADDR  58980000
         EJECT                                                          59040000
****************************  END PROCESSOR  ************************** 59100000
*                                                                     * 59160000
*    THIS ROUTINE PROCESSES THE END CARD FOR LENGTH AND ENTRY POINT.  * 59220000
*      IT ALSO CLEARS THE TRANSLATION TABLE.  IT EXPECTS:             * 59280000
*              #ID - CONTAINS ID OF ASSEMBLED ADDR. ENTRY             * 59340000
*              #PTR- ADDR OF SYMBOLIC ENTRY POINT NAME                * 59400000
*              #ADR- ENTRY POINT ADDRESS IF PRESENT                   * 59460000
*                                                                     * 59520000
*********************************************************************** 59580000
IEWLEND  EQU   *                                                        59640000
         STM   14,12,12(13)             SAVE REGISTERS                  59700000
         BALR  BASE,0                                                   59760000
         USING *,BASE                                                   59820000
         L     BASE,ABEGIN                                              59880000
         USING IEWLRELO,BASE           RESET BASE TO INITIAL VALUE      59940000
         L     BASE2,ABEG4096          SET UP SECOND BASE REG   SA49491 59990000
         USING IEWLRELO+4096,BASE2     ESTABLISH ADDRESSABILITY SA49491 59992000
         B     NEND+8                                                   60000000
NEND     DC    C'IEWLEND '                                              60060000
         L     SAVEREG,8(SAVEREG)       PICK UP NEXT SAVE AREA          60120000
         TM    CMIOFLGS,CQEOCB+CQRECFM  IS THIS END OF MODULE PROCESS   60180000
         BC    7,ENDLNG                YES                              60240000
         OI    CMRELFLG,CQNOEND        SET END CARD RECEIVED INDIC      60300000
         L     WORKB,CMLDCHN           GET START OF 'LD' CHAIN          60360000
         LTR   WORKB,WORKB             IS 'LD' CHAIN EMPTY              60420000
         BZ    ENDEPCHK                YES                              60480000
         BAL   RETURN,RERINPT7         INVALID ID ON 'LD' ENTRY         60540000
ENDEPCHK TM    CMPRMFLG,CQEPNAME+CQEPADDR HAS ENTRY POINT BEEN DEFINED  60600000
         BZ    ENDENTRY                 NO                              60660000
********                                                     ********** 60720000
*                  DEFINE CSECT LENGTH AND MODULE EXTENT              * 60780000
********                                                     ********** 60840000
ENDLNG   L     WORKA,CMNXTTXT           GET MODULE START ADDR           60900000
         TM    CMFLAG4,CQMOD      IS THIS COMPILER-LOADED TEXT          60910000
         BZ    END05              NO                                    60920000
         BAL   RETURN,SWITCH      SWITCH LIMIT ADDRESSES                60930000
END05    EQU   *                                                        60940000
         TM    CMRELFLG,CQNOLNG         WAS LENGTH ALREADY SPECIFIED    60960000
         BZ    END19                    YES                             61020000
         TM    CMRELFLG,CQNOEND        WAS END CARD MISSING             61080000
         BZ    END12                   YES                              61140000
END10    L     LNG,COL29(PTR)           GET LENGTH FIELD                61200000
         CLI   COL29(PTR),X'00'         IS LENGTH ON END CARD           61260000
         BE    END13                    YES                             61320000
END12    TM    CMRELFLG,CQNOLNTX   WAS TEXT RECEIVED            27445   61350000
         BNO   END12A              NO. CSECT WITH LNG ZERO OKAY 27445   61380000
         BAL   RETURN,RERINPT2     YES. ERROR                   27445   61410000
END12A   EQU   *                                                SA49491 61440021
         SR    LNG,LNG       CSECT LENGTH 0                     SA49491 61490021
         C     LNG,CMMODLNG           MORE THAN ONE CSECT?      SA49491 61550021
         BL    END12B                 MULT CSECTS, ONE ZERO     SA49491 61552021
         L     WORKA,CMLSTTXT         USE CMLSTTXT              SA49491 61554021
         B     END20                                            SA49491 61560021
END12B   EQU   *                                                SA49491 61570021
         L     LNG,CMMODLNG            USE CMMODLNG             SA49491 61580021
         L     WORKA,CMOBJST           GET BEGINING ADDRESS     SA58095 61590021
         B     END20                                            SA49491 61600021
END13    EQU   *                                                SA49491 61610021
         A     LNG,CMMODLNG            UPDATE NEW ACCUM LENGTH  SA49491 61660021
         ST    LNG,CMMODLNG            STORE IT BACK            SA49491 61710021
         A     LNG,CMOBJST             COMPUTE HIGH ADDRESS     SA58095 61712021
         CL    LNG,CMLSTTXT            ACCUM GREATER THAN TXT?  SA58095 61720021
         L     LNG,CMMODLNG            RESTORE LNG REGISTER     SA49491 61722021
         BH    END20                   YES, GO USE IT           SA49491 61730021
         L     WORKA,CMNXTTXT          GET LENGTH               SA49491 61732021
         ST    WORKA,CMOBJST           SAVE IT                  SA49491 61734021
         B     END20                   GO CALCULATE MODULE LNG  SA49491 61736021
END19    L     LNG,CMMODLNG             NO,USE ACCUM MODULE LNG         61740000
END20    AR    WORKA,LNG                CALC. PROGRAM HIGHEST ADDR.     61800000
         LA    WORKA,7(WORKA)                                           61860000
         N     WORKA,DBLWRD             UPDATE TO DBLE. WORD BOUNDARY   61920000
         CL    WORKA,CMLSTTXT           HAS TEXT EXCEEDED SPECIFIED LNG 61980000
         BNL   END25                    NO                              62040000
         L     WORKA,CMLSTTXT           YES,USE ACTUAL TEXT LENGTH      62100000
         LA    WORKA,7(WORKA)           ROUND OFF TO             A47048 62150021
         N     WORKA,DBLWRD             DOUBLEWORD BOUNDARY      A47048 62152021
         BAL   RETURN,RERINPT2          ERROR,TXT RECEIVED EXCEEDS LNG  62160000
END25    ST    WORKA,CMNXTTXT           UPDATE NEXT TEXT ADDRESS        62220000
         ST    WORKA,CMOBJST           SAVE AMOUNT IN OBJST     SA49491 62270021
         ST    WORKA,CMLSTTXT          INITIAL TEXT POINTER             62280000
         TM    CMFLAG4,CQMOD      IS THERE INCORE TEXT                  62290000
         BZ    END26              NO                                    62300000
         BAL   RETURN,SWITCH                                            62310000
END26    EQU   *                                                        62320000
         CL    WORKA,CMHITBL            HAS CORE EXTENT BEEN EXCEEDED   62340000
         BNH   ENDTRCLR                NO                               62400000
         B     RERSIZE2                PROGRAM TOO LARGE--ABORT         62460000
SWITCH   L     WORKB,CMCORE1      SWITCH ADDRESSES                      62466000
         ST    WORKA,CMCORE1      FOR  COMPILER-LOADED TEXT             62472000
         ST    WORKB,CMNXTTXT                                           62478000
         ST    WORKB,CMOBJST      SAVE IT                       SA49491 62480021
         L     WORKA,CMCORE2                                            62484000
         L     WORKB,CMLSTTXT                                           62490000
         ST    WORKA,CMLSTTXT                                           62496000
         ST    WORKA,CMLSTTXT                                           62502000
         ST    WORKB,CMCORE2                                            62508000
         BR    RETURN                                                   62514000
********                                                        ******* 62520000
*                       CLEAR TRANSLATION TABLE                       * 62580000
********                                                        ******* 62640000
ENDTRCLR LA    WORKC,CQMAXEXT           NO. OF TRANS. TABLE EXTENTS     62700000
         BCTR  WORKC,0                                                  62760000
         SLL   WORKC,2                  CALC. DISP INTO TRANS. CTRL.TBL 62820000
         LA    WORKB,CMTRCTRL           ADDR. OF TRANS.CTRL. TABLE      62880000
         LH    WORKA,NEG4                                               62940000
ENDCLEAR L     PTR,0(WORKB,WORKC)       GET ADDR OF EXTENT              63000000
         LTR   PTR,PTR                  HAS EXTENT BEEN ALLOCATED       63060000
         BZ    ENDLOOP                  NO                              63120000
         XC    0(CQEXTSIZ,PTR),0(PTR)   CLEAR EXTENT                    63180000
ENDLOOP  BXH   WORKC,WORKA,ENDCLEAR     DECR-TEST-LOOP OR CONTINUE      63240000
         XC    CMMODLNG(4),CMMODLNG     CLEAR MODULE LENGTH             63300000
         NI    CMRELFLG,CQNOEND+CQLIB   CLEAR FLAGS                     63360000
         NI    CMFLAG4,X'FF'-CQESDS-CQMOD    SET FLAGS 0                63390000
         L     SAVEREG,4(SAVEREG)       RESTORE SAVE AREA PTR           63420000
         RETURN (14,12),T                                               63480000
********                                                        ******* 63540000
*                        ENTRY POINT DEFINITION                       * 63600000
********                                                        ******* 63660000
ENDENTRY CH    ID,BLNK+2                IS ID PRESENT                   63720000
         BE    ENDSYM                   NO                              63780000
         CL    ADR,BLNK                 HAS ADDR.BEEN SPECIFIED         63840000
         BNE   END100                   YES                             63900000
         SR    ADR,ADR                  NO, SET ADDR TO ZERO            63960000
END100   ST    ADR,CMEPADDR             SAVE ENTRY POINT  ADDR.         64020000
         BAL   RETURN,TRANSID           CONVERT ID TO TRANS.TABLE ADDR  64080000
         LTR   PARM,PARM                WAS TRANSLATION POSSIBLE        64140000
         BZ    ENDLNG                   NO                              64200000
         LA    WORKC,CMEPADDR           CREATE RLD FOR EP               64260000
         ST    WORKC,CMEPNAME+4                                         64320000
         MVI   CMEPNAME+4,X'0C'         SET FLAG  FIELD FOR EP RLD      64380000
         STH   ID,CMEPNAME              SAVE R PTR FOR EP RLD           64440000
         XC    CMEPCESD(4),CMEPCESD     SET RELOC VALUE TO ZERO         64500000
         LA    WORKA,CMEPCESD-16        SIMULATE P PTR CESD ADDR        64560000
         LA    LNG,8                    GET LENGTH OF RLD ENTRY         64620000
         LR    WORKC,PTR                SAVE BUFFER POINTER             64680000
         LA    PTR,CMEPNAME             GET ADDR OF RLD ENTRY           64740000
         OI    CMRELFLG,CQENTRY         SET INDIC NOT TO TRANS P PTR    64800000
         BAL   RETURN,IEWLRLD           GO TO PROCESS RLD FOR EP        64860000
         LR    PTR,WORKC                RESTORE BUFFER POINTER          64920000
ENDADDR  ST    CESD,CMEPCESD            SAVE ENTRY POINT CESD ADDR      64980000
         OI    CMPRMFLG,CQEPADDR        SET EP ADDR RECEIVED            65040000
         B     ENDLNG                                                   65100000
ENDSYM   CLI   0(PTR),BLANK             IS NAME ON END CARD             65160000
         BE    ENDLNG                   NO                              65220000
         MVC   CMEPNAME(8),0(PTR)       SAVE ENTRY POINT NAME           65280000
         OI    CMPRMFLG,CQEPNAME        SET EP NAME RECEIVED            65340000
*                                                                     * 65400000
*                 CHECK IF ENTRY POINT NAME DEFINED YET               * 65460000
*                                                                     * 65520000
         L     WORKC,CMSDCHN            CHECK 'SD' CHAIN                65580000
         LA    RETURN,ENDLRCHN                                          65640000
ENDEP    LTR   WORKC,WORKC              IS THIS END OF CHAIN            65700000
         BCR   8,RETURN                 YES                             65760000
         CLC   CNAME(8,WORKC),CMEPNAME  CHECK FOR ENTRY POINT NAME      65820000
         BE    ENDEPADR                                                 65880000
         L     WORKC,0(WORKC)           UPDATE TO NEXT ENTRY            65940000
         B     ENDEP                                                    66000000
ENDLRCHN LA    RETURN,ENDLNG            SET RETURN REGISTER             66060000
         L     WORKC,CMLRCHN            GET BEGINNING OF LR CHAIN       66120000
         B     ENDEP                    GO TO SEARCH CHAIN              66180000
ENDEPADR MVC   CMEPADDR+1(3),CADR+1(WORKC) SAVE ENTRY POINT ADDR.       66240000
         OI    CMPRMFLG,CQEPADDR        SET INDICATOR FOR EP ADDR       66300000
         B     ENDLNG                   GO TO CHECK LENGTH              66360000
         EJECT                                                          66420000
***********************  TABLE ALLOCATION ROUTINE  ******************** 66480000
*                                                                     * 66540000
*   THIS ROUTINE ALLOCATES TABLE EXTENTS AND RETURNS THE ENTRY ADDR.  * 66600000
*     IN #PARM.  #ZERO MUST CONTAIN EXTENT SIZE ON ENTRY.             * 66660000
*                                                                     * 66720000
*********************************************************************** 66780000
ALLOCATE EQU   *                                                        66840000
         L     PARM,CMLOWTBL            ADDR OF LOWEST USED TABLE ADDR  66900000
         SR    PARM,ZERO                                                66960000
         C     PARM,CMLSTTXT            HAVE TABLES OVERLAPPED TEXT     67020000
         BNL   ALLOC                                                    67080000
         B     RERSIZE2                PROGRAM TOO LARGE--ABORT         67140000
ALLOC    ST    PARM,CMLOWTBL            UPDATE LOWEST TABLE ADDRESS     67200000
         BR    RETURN                   RETURN                          67260000
         EJECT                                                          67320000
**************************  TRANSLATE ROUTINE  ************************ 67380000
*                                                                     * 67440000
*  THIS SUBROUTINE TRANSLATES THE ESD ID TO A CORRESPONDING ENTRY     * 67500000
*     ADDRESS IN  THE TRANSLATE TABLE.  #ID MUST CONTAIN THE ESD ID.  * 67560000
*     THE LOW ORDER BIT OF CMRELFLG SHOULD BE SET TO INDICATE WHETHER * 67620000
*     THE TRANSLATION TABLE ENTRY SHOULD EXIST OR NOT                 * 67680000
*     THE ENTRY ADDRESS IS RETURNED IN #PARM. IF BAD ID,#PARM= 0.     * 67740000
*     THE CONTENTS OF THE ENTRY(CESD ADDR) ARE RETURNED IN #CESD IF   * 67800000
*     REQUESTED BY CQESD FLAG                                         * 67860000
*********************************************************************** 67920000
TRANSID  EQU   *                                                        67980000
         STM   14,12,12(13)             SAVE REGISTERS                  68040000
         BALR  BASE,0                                                   68100000
         USING *,BASE                                                   68160000
         L     BASE,ABEGIN                                              68220000
         USING IEWLRELO,BASE           RESET BASE TO INITIAL VALUE      68280000
         L     BASE2,ABEG4096          SET UP SECOND BASE REG   SA49491 68330000
         USING IEWLRELO+4096,BASE2     ESTABLISH ADDRESSABILITY SA49491 68332000
         B     NTRAN+8                                                  68340000
NTRAN    DC    C'TRANSID '                                              68400000
         L     SAVEREG,8(SAVEREG)       GET NEXT SAVE AREA              68460000
         LTR   ID,ID                    IS ID EQ TO 0                   68520000
         BZ    TRBADID                  YES-ERROR                       68580000
         LA    ZERO,CQEXTSIZ            NO.OF TRANSLATE EXTENT ENTRIES  68640000
         LA    WORKA,CQMAXEXT           MAX. NO. OF EXTENTS             68700000
         SR    WORKC,WORKC              CLEAR EVEN DIVIDE REGISTER      68760000
         DR    WORKC,ZERO               CALC.TRANSLATE CTRL ENTRY NO.   68820000
         CR    ID,WORKA                 HAS EXTENT BEEN ALLOCATED       68880000
         BNL   TRANSERR                 NO                              68940000
         SLL   ID,2                     CALC DISP                       69000000
         LA    ID,CMTRCTRL(ID)          CALC TRANSLATE CTRL ENTRY ADDR  69060000
         L     PARM,0(ID)                                               69120000
         LTR   PARM,PARM                HAS THE EXTENT BEEN ALLOCATED   69180000
         BC    7,CALCADDR               YES, GO TO CALC ADDR            69240000
         TM    CMRELFLG,CQESD           ERROR OR ALLOCATE MORE          69300000
         BZ    TRBADID                  ERROR-BAD ID                    69360000
         LA    ZERO,CQEXTSIZ*4          SIZE OF EXTENT                  69420000
         BAL   RETURN,ALLOCATE          GO TO ALLOCATE EXTENT           69480000
         ST    PARM,0(ID)               PUT EXTENT ADDR IN CTRL TABLE   69540000
         XC    0(CQEXTSIZ*4,PARM),0(PARM) CLEAR TRANSLATION TABLE ENTRY 69600000
CALCADDR SLL   WORKC,2                                                  69660000
         AR    PARM,WORKC               CALC TRANSLATE ENTRY ADDR       69720000
         TM    CMRELFLG,CQESD           SHOULD ESD BE DEFINED           69780000
         BO    ENDALLOC                 NO                              69840000
         L     CESD,0(PARM)             YES,CHECK IF IT IS DEFINED      69900000
         LTR   CESD,CESD                                                69960000
         BZ    TRBADID                  ERROR, IT IS NOT DEFINED        70020000
ENDALLOC L     SAVEREG,4(SAVEREG)       RESTORE REGISTERS               70080000
         LM    2,8,28(13)               PRESERVE REGISTER 1 AND 9       70140000
         LM    10,12,60(13)                                             70200000
         L     14,12(13)                                                70260000
         MVI   12(13),X'FF'             FLAG SAVE AREA                  70320000
         BR    RETURN                   RETURN                          70380000
TRANSERR TM    CMRELFLG,CQESD           TABLE OVERFLOW OR BAD ID        70440000
         BZ    TRBADID                  BAD ID                          70500000
         B     RERSIZE3                TRANS.TABLE SIZE EXCEEDED        70560000
TRBADID  BAL   RETURN,RERINPT7         INVALID ID                       70620000
         SR    PARM,PARM                CLEAR PARM REG.                 70680000
         B     ENDALLOC                 RETURN TO CALLER                70740000
         EJECT                                                          70800000
********************     EXTERNAL REFERENCE RESOLUTION  *************** 70860000
*                                                                     * 70920000
*   THIS SUBROUTINE RELOCATES ALL RLDS ON A CHAIN, THEN RETURNS. WHEN * 70980000
*      ENTERED #PARM-MUST CONTAIN THE STARTING ADDR.OF THE ER CHAIN   * 71040000
*              #CESD-MUST CONTAIN THE CESD ENTRY ADDR TO BE USED FOR  * 71100000
*                    RELOCATION (R PTR ENTRY)                         * 71160000
*                                                                     * 71220000
*********************************************************************** 71280000
IEWLERTN EQU   *                                                        71340000
         STM   14,12,12(13)             SAVE REGISTERS                  71400000
RESOLVER BALR  BASE,0                                                   71460000
         USING *,BASE                                                   71520000
         L     BASE,ABEGIN                                              71580000
         USING IEWLRELO,BASE           RESET BASE TO INITIAL VALUE      71640000
         L     BASE2,ABEG4096          SET UP SECOND BASE REG   SA49491 71690000
         USING IEWLRELO+4096,BASE2     ESTABLISH ADDRESSABILITY SA49491 71692000
         B     NERTN+8                                                  71700000
NERTN    DC    C'IEWLERTN'                                              71760000
         L     SAVEREG,8(SAVEREG)       GET NEXT SAVE AREA              71820000
ERRTN    LTR   PARM,PARM                IS THIS LAST ON CHAIN           71880000
         BC    7,ER5                   NO                               71940000
ER2      L     SAVEREG,4(SAVEREG)       RESTORE PTR TO SAVE AREA        72000000
         RETURN (14,12),T                                               72060000
ER5      LA    LNG,3                    SET LNG OF 4 FOR EX INSTRUCTION 72120000
         TM    4(PARM),X'0C'            IS THE LENGTH EQ TO 4           72180000
         BO    ER10                     YES                             72240000
         LA    LNG,2                    SET LNG OF 3 FOR EX INSTRUCTION 72300000
         TM    4(PARM),X'04'            IS IT A TWO BYTE ADCON          72360000
         BZ    ER10                     NO,CONTINUE RELOCATION          72420000
         LA    LNG,1                    SET LNG EQ 1                    72480000
         TM    4(PARM),PRRLD            IS IT A VALID 2 BYTE PR         72540000
         BO    ER10                     YES,CONTINUE RELOCATION         72600000
         BAL   RETURN,RERINPT5         INVALID TWO BYTE ADCON           72660000
*                                                                     * 72720000
*        MOVE ADCON FROM TEXT TO WORK AREA                            * 72780000
*                                                                     * 72840000
ER10     L     WORKA,4(PARM)            GET TEXT ADDR. OF ADCON         72900000
         LA    WORKA,0(WORKA)           CLEAR HIGH ORDER FLAG FIELD     72960000
         LA    WORKB,CMADCON+3          END ADDR OF ADCON SAVE AREA     73020000
         SR    WORKB,LNG                                                73080000
         MVI   CMADCON,X'00'           CLEAR HIGH ORDER BYTE            73140000
         EX    LNG,MOVEOUT              MOVE ADCON TO WORK AREA         73200000
*                                                                     * 73260000
*        TEST TYPE TO DETERMINE WHAT TYPE OF RELOCATION TO PERFORM    * 73320000
*                                                                     * 73380000
         TM    CMRELFLG,CQDELINK        IS DELINKING NEEDED             73440000
         BO    ER60                     YES                             73500000
         TM    4(PARM),PRRLD           IS THIS A PR RLD                 73560000
         BO    ER15                    YES, GO FOR ABSOLUTE RELOCATION  73620000
         TM    4(PARM),VCON             IS ADCON BRANCH TYPE            73680000
         BZ    ER40                     NO, IT IS NON-BRANCH TYPE       73740000
*                                                                     * 73800000
*                       ABSOLUTE  RELOCATION                          * 73860000
*                                                                     * 73920000
ER15     MVC   CMADCON(4),CADR(CESD)   GET LOADER ASSIGNED ADDRESS      73980000
         MVI   CMADCON,X'00'            CLEAR HIGH ORDER BYTE           74040000
         EX    LNG,MOVEIN               SET ADCON=LOADER ASSIGNED ADDR  74100000
*                                                                     * 74160000
*              PUT RLD ENTRY ON FREE ENTRY CHAIN                      * 74220000
*                                                                     * 74280000
ER20     L     WORKA,0(PARM)            SAVE ER CHAIN PTR               74340000
         L     WORKB,CMRLDCHN           GET START OF CHAIN              74400000
         ST    WORKB,0(PARM)                                            74460000
         ST    PARM,CMRLDCHN            ADD ENTRY TO TOP OF CHAIN       74520000
         LR    PARM,WORKA                                               74580000
         B     ERRTN                    CONTINUE RESOLUTION             74640000
********                                                        ******* 74700000
*                 RELATIVE    RELOCATION                              * 74760000
********                                                        ******* 74820000
ER40     L     WORKA,CREL(CESD)         GET RELOCATION VALUE            74880000
         TM    4(PARM),X'80'           IS ABSOLUTE RELOC FACTOR NEEDED  74940000
         BZ    ER45                    NO                               75000000
         CLI   CTYPE(CESD),CM           IS THIS COMMON           A46172 75020021
         BE    ER45                     YES-ABSOL FACTOR IN CREL A46172 75040021
         L     WORKA,CADR(CESD)        GET ABSOLUTE RELOC FACTOR        75060000
         LA    WORKA,0(WORKA)                                           75120000
ER45     TM    4(PARM),X'02'           DOES RLD INDICATE SUBT.          75180000
         BZ    ER50                     NO                              75240000
         LCR   WORKA,WORKA              COMPLEMENT VALUE                75300000
ER50     A     WORKA,CMADCON           RELOCATE ADCON                   75360000
         ST    WORKA,CMADCON            STORE ADCON VALUE FOR MOVE      75420000
         L     WORKA,4(PARM)            GET TEXT ADDR. FOR ADCON        75480000
         EX    LNG,MOVEIN               MOVE RELOCATED ADCON TO TEXT    75540000
         B     ER20                                                     75600000
*                                                                     * 75660000
*       SPECIAL DELINKING FOR ADCONS POINTING TO COMMON AREAS.        * 75720000
*                                                                     * 75780000
ER60     L     WORKC,CREL(CESD)         GET ADDR OF EXTENDED CM ENTRY   75840000
         TM    CTYPE(CESD),CM           DOES WORKC CONTAIN ADDR OF EXT. 75900000
*                                          ENTRY(CM) OR INPUT ADDR(ER)  75960000
         BNZ   ER65                     WORKC CONTAINS INPUT ADDR(ER)   76020021
         NI    CREL(CESD),X'7F'         TURN OFF DELETE BIT     SA70542 76070021
         B     ER70                     CONTINUE                SA70542 76072021
ER65     EQU   *                        HERE IF COMMON          SA70542 76074021
         L     WORKC,CADR(WORKC)        GET INPUT ADDR FOR COMMON       76080000
         OI    4(PARM),X'80'            SHOW ABS RELO FAC NEEDED A46172 76110021
ER70     LA    WORKC,0(WORKC)           CLEAR HIGH ORDER BYTE           76140000
         L     ZERO,CMADCON             GET ADCON VALUE                 76200000
         SR    ZERO,WORKC               SUBTRACT INPUT ADDR             76260000
         ST    ZERO,CMADCON                                             76320000
         EX    LNG,MOVEIN               MOVE DELINKED VALUE BACK TO TXT 76380000
         NI    CMRELFLG,CQFF-CQDELINK   SET DELINK INDICATOR OFF        76440000
         B     ER2                                                      76500000
         EJECT                                                          76560000
******************************* IEWLMAP ******************************* 76620000
*                                                                     * 76680000
* THIS SUBROUTINE FORMATS THE MAP PRINT LINE AND USES THE PRINT  RTN. * 76740000
*     #CESD=ADDR OF CESD ENTRY TO BE MAPPED                           * 76800000
*                                                                     * 76860000
**********                                                      ******* 76920000
IEWLMAP  EQU   *                                                        76980000
         STM   14,12,12(13)             SAVE REGISTERS                  77040000
         BALR  BASE,0                                                   77100000
         USING *,BASE                                                   77160000
         L     BASE,ABEGIN                                              77220000
         USING IEWLRELO,BASE                                            77280000
         L     BASE2,ABEG4096          SET UP SECOND BASE REG   SA49491 77330000
         USING IEWLRELO+4096,BASE2     ESTABLISH ADDRESSABILITY SA49491 77332000
         B     NMAP+8                                                   77340000
NMAP     DC    C'IEWLMAP '                                              77400000
         TM    CMPRMFLG,CQMAP           IS MAP OPTION SPECIFIED         77460000
         BZ    MAPRETRN                 NO                              77520000
         L     SAVEREG,8(SAVEREG)       PICK UP NEXT SAVE AREA          77580000
         CLC   CMWTBFCT(2),CMMAPLIN   IS LINE FULL                      77640000
         BL    MAP20                    NO,MAKE ENTRY                   77700000
         L     BRANCH,ADPRINT                                           77760000
         BALR  RETURN,BRANCH            GO TO PRINT LINE-GET NEW LINE   77820000
MAP20    L     PTR,CMPUTREC                                             77880000
         AH    PTR,CMWTBFCT             CALC NEXT BUFFER ADDR.          77940000
         TM    CMFLAG4,CQMOD       WAS THIS PASSED THROUGH MOD RECORD   77950000
         BNO   MAP30               NO. CHECK AUTOCALL                   77960000
         MVC   SUFFIXNM(3,PTR),TRISTAR   YES. MARK AS PRE-LOADED TEXT   77970000
         B     MAPNAME                                                  77980000
MAP30    EQU   *                                                        77990000
         TM    CMLIBFLG,CQAUTOC         WAS ENTRY CREATED BY AUTOCALL   78000000
         BZ    MAPNAME                  NO                              78060000
         MVI   SUFFIXNM(PTR),C'*'       YES, MOVE IN LIBRARY DESIGNATOR 78120000
         TM    CMRELFLG,CQLIB           IS RESOLUTION FROM SYSLIB       78180000
         BO    MAPNAME                  YES                             78240000
         MVI   SUFFIXNM+1(PTR),C'*'     NO,FROM LINK PACK AREA          78300000
MAPNAME  MVC   NAME(8,PTR),CNAME(CESD)  MOVE IN NAME                    78360000
         TM    CTYPE(CESD),NULL         IS IT AN 'SD'                   78420000
         BZ    MAPSD                    YES                             78480000
         TM    CTYPE(CESD),LR           IS IT AN 'LR'                   78540000
         BO    MAPLR                    YES                             78600000
         BZ    MAPPC                    IT IS 'PC'                      78660000
         TM    CTYPE(CESD),CM           IS IT A 'CM'                    78720000
         BO    MAPCM                    YES                             78780000
MAPPR    MVC   TYPE(2,PTR),PRTYPE       IT IS A 'PR',MOVE IN 'PR'TYPE   78840000
         B     MAPADDR                  GO TO MAP ADDR                  78900000
MAPSD    MVC   TYPE(2,PTR),SDTYPE       IT IS AN 'SD'MOVE IN 'SD' TYPE  78960000
         B     MAPADDR                  GO TO CHECK FOR EP NAME         79020000
MAPLR    MVC   TYPE(2,PTR),LRTYPE       IT IS AN 'LR' MOVE IN 'LR'TYPE  79080000
         B     MAPADDR                  GO TO CHECK FOR EP NAME         79140000
MAPPC    MVC   PREFIXNM(13,PTR),PRIVATE IT IS A 'PC',MOVE IN PRIVATE    79200000
         B     MAPADDR                               DESIGNATOR         79260000
MAPCM    MVC   TYPE(2,PTR),CMNTYPE      IT IS CM, MOVE IN TYPE          79320000
         CLI   CNAME(CESD),BLANK        IS IT BLANK COMMON              79380000
         BNE   MAPADDR                  NO                              79440000
         MVC   PREFIXNM(9,PTR),BLANKCOM MOVE IN BLANK COMMON DESIGNATOR 79500000
MAPADDR  L     PARM,CADR(CESD)          GET ADDR TO BE MAPPED           79560000
         BAL   14,IEWLCNVT              GO TO CONVERSION ROUTINE        79620000
         MVC   ADDR(6,PTR),CMXDBLWD+1   MOVE IN CONVERTED ADDR          79680000
         LH    PARM,CMWTBFCT                                            79740000
         LA    PARM,ENTRYSZ(PARM)                                       79800000
         STH   PARM,CMWTBFCT            UPDATE BUFFER BYTE COUNT        79860000
         L     SAVEREG,4(SAVEREG)       PICK UP LAST SAVE AREA          79920000
MAPRETRN RETURN (14,12),T                                               79980000
         EJECT                                                          80040000
************************ CONVERSION  ROUTINE  ************************* 80100000
*                                                                     * 80160000
*   THIS SUBROUTINE CONVERTS A BINARY QUANTITY IN REGISTER 1  TO      * 80220000
*       PRINT CHARACTERS.  THE RESULT IS IN THE COMMUNICATIONS AREA   * 80280000
*       CMDBLEWD+1. REGISTERS  0 AND 1 DESTROYED                      * 80340000
*                                                                     * 80400000
***************                             *************************** 80460000
IEWLCNVT EQU   *                                                        80520000
         BALR  BASE,0                                                   80580000
         USING *,BASE                                                   80640000
         L     BASE,ABEGIN                                              80700000
         USING IEWLRELO,BASE           RESET BASE TO INITIAL VALUE      80760000
         L     BASE2,ABEG4096          SET UP SECOND BASE REG   SA49491 80810000
         USING IEWLRELO+4096,BASE2     ESTABLISH ADDRESSABILITY SA49491 80812000
         LA    PARM,0(PARM)             CLEAR HIGH ORDER BITS           80820000
         LTR   PARM,PARM                TEST FOR ZERO                   80880000
         BC    7,CVTCONT                NO                              80940000
         MVC   CMXDBLWD+1(6),ZEROADDR   STORE ZERO                      81000000
         BR    RETURN                   RETURN                          81060000
CVTCONT  ST    PARM,CMXDBLWD            PLACE BINARY QUANTITY IN AREA   81120000
         UNPK  CMXDBLWD+1(7),CMXDBLWD+1(4) UNPACK BINARY QUANTITY       81180000
         MVZ   CMXDBLWD+1(6),CMXDBLWD   ZERO ZONES FOR TRANSLATE        81240000
         TR    CMXDBLWD+1(6),TRTABLE    TRANSLATE FOR PRINTING          81300000
         LA    ZERO,1                   LOAD INCREMENT                  81360000
         LA    PARM,CMXDBLWD+1          GET ADDR. OF CONVERTED QUANTITY 81420000
HIGHZERO CLI   0(PARM),C'0'             TEST FOR ZERO                   81480000
         BCR   7,RETURN                 NONE, SO RETURN                 81540000
         MVI   0(PARM),C' '             REPLACE ZERO WITH BLANK         81600000
         BXH   PARM,ZERO,HIGHZERO       INCR AND LOOP TO NEXT DIGIT     81660000
         EJECT                                                          81720000
         DS    0F                                       SA70542,SA49491 81730021
*   THE FOLLOWING TWO CONSTANTS MUST BE WITHIN THE FIRST 2K     SA49491 81770021
ABEGIN   DC    A(IEWLRELO)              USED TO ESTABLISH ADDR. SA49491 81772021
ABEG4096 DC    A(IEWLRELO+4096)         ADCON FOR SECOND BASE   SA49491 81774021
*                                                                     * 81780000
***********************  ERROR  ROUTINES  ***************************** 81840000
*                                                                     * 81900000
RERINPT2 LA    ZERO,ERINPT2             INVALID LNG SPECIFIED FOR CSECT 81960000
         B     ERROR                                                    82020000
RERINPT4 LA    ZERO,ERINPT4            DOUBLY DEFINED SYMBOL----        82080000
         LR    PARM,PTR                      CONFLICTING TYPES          82140000
         B     ERROR                                                    82200000
RERINPT5 LA    ZERO,ERINPT5            INVALID TWO-BYTE ADCON           82260000
         B     ERROR                                                    82320000
RERINPT7 LA    ZERO,ERINPT7            INVALID ID                       82380000
         B     ERROR                                                    82440000
RERINPT8 LA    ZERO,ERINPT8            CARD PRINTED NOT OBJECT CARD     82500000
         B     ERR                                                      82560000
RERINPT9 LA    ZERO,ERINPT9            INVALID INPUT FROM OBJ. MODULE   82620000
         B     ERR                                                      82680000
RERINPTA LA    ZERO,ERINPT10            WARNING--NO END CARD            82740000
         B     ERROR                                                    82800000
RERSIZE2 LA    ZERO,ERSIZE2            PROGRAM TOO LARGE                82860000
         B     ERROR                                                    82920000
RERSIZE3 LA    ZERO,ERSIZE3            TRANS. TABLE OVERFLOW            82980000
         B     ERROR                        CONFLICTING TYPES           83040000
ERR      L     PARM,CMGETREC           GET ADDR.OF BUF.TO BE PRINTED    83100000
         TM    CMFLAG3,CQINCORE    IS THIS INCORE DATA SET              83110000
         BZ    ERROR               NO. GO AHEAD                         83120000
         OI    CMIOFLGS,CQEOFB+CQEOCB  YES. SET FLAGS SO WE WON'T READ  83130000
*                                           ANY MORE                    83140000
ERROR    LR    WORKC,RETURN            SAVE RETURN REGISTER             83160000
         L     BRANCH,ADERROR                                           83220000
         BALR  RETURN,BRANCH           GO TO LOG ERROR                  83280000
         LR    RETURN,WORKC            RESTORE RETURN REGISTER          83340000
         BR    RETURN                                                   83400000
         EJECT                                                          83460000
MOVE2    MVC   0(1,ADR),0(PTR)          MOVE TEXT FROM REC.TO STORAGE   83520000
MOVEOUT  MVC   0(1,WORKB),0(WORKA)      MOVE ADCON TO WORK AREA         83580000
MOVEIN   MVC   0(1,WORKA),0(WORKB)      MOVE ADCON FROM WORK AREA       83640000
         DS    0F                                               SA49491 83650000
BLANKCOM DC    C'$BLANKCOM'             BLANK COMMON DESIGNATOR         85440000
PRIVATE  DC    C'$PRIVATE   PC'         PRIVATE CODE DESIGNATOR         85500000
TRTABLE  DC    C'0123456789ABCDEF'      TRANSLATION TABLE               85560000
ZEROADDR DC    C'    00'                ADDR OR DISP VALUE EQ 0         85620000
TRISTAR  DC    C'***'              FLAG PRE-LOADED TEXT IN MAP          85980000
         DS    0F                       ALIGNMENT                       86040000
BLNK     DC    X'00'                    BLANK ADDR. ON WORK BOUNDARY    86100000
         DC    C'   '                                                   86160000
TYPEONLY DC    X'00000007'              CLEAR ALL BUT TYPE FIELD        86280000
ADPRINT  DC    V(IEWLPRNT)              ADDRESS OF PRINT ROUTINE        86580000
ADERROR  DC    V(IEWERROR)              ADDRESS OF ERROR ROUTINE        86640000
ADREAD   DC    V(IEWLREAD)              ADDRESS OF OBJ.READ ROUTINE     86700000
         DS    0F                                                       86872800
*                                                                     * 86873200
* THIS TABLE IDENTIFIES THE CESD CHAINS TO BE SEARCHED FOR EACH INPUT * 86889900
*                              ESD TYPE                               * 86899900
*                                                                     * 86901900
HIERTBLE EQU   *                                                        86903900
         DC    X'02000583'             SD--ER,SD,CM,LR                  86905900
         DC    X'80000000'             LD--NEVER SEARCHED               86906300
         DC    X'00020385'             ER--SD,ER,LR,CM                  86906400
         DC    X'02030085'             LR--ER,LR,SD,CM                  86906500
         DC    X'80000000'             PC--NEVER SEARCHED               86912100
         DC    X'05020083'             CM--CM,ER,SD,LR                  86914100
         DC    X'86000000'             PR--PR--------                   86916100
         DC    X'80000000'             NULL-----NEVER SEARCHED          86916500
NEG4     DC    H'-4'            DECR. FOR TRANS.TABLE CLEARING          86916900
ONE      DC    H'1'                                                     86917300
CONT4    DC    H'4'                                                     86917400
CONT8    DC    H'8'                                                     86917500
CONT16   DC    H'16'                                                    86917600
         DS    0F                                               SA49491 86919600
DBLWRD   DC    X'FFFFFFF8'              MASK TO ZERO LAST 3 BITS        86923200
PRTYPE   DC    C'PR'                    USED FOR MAPPING TYPE           86925200
SDTYPE   DC    C'SD'                    USED FOR MAPPING TYPE           86927200
CMNTYPE  DC    C'CM'                    USED FOR MAPPING TYPE           86927600
LRTYPE   DC    C'LR'                    USED FOR MAPPING TYPE           86928000
         DS    0F                                                       86928400
TYPETBLE DC    X'02'                    TYPE COMPARISON TABLE           86928500
         DC    C'TXT'                                                   86928600
         DC    A(IEWLTXT)               TXT PROCESSOR                   86928700
         DC    X'02'                                                    86942900
         DC    C'RLD'                                                   86952900
         DC    A(IEWLRLD)               RLD PROCESSOR                   86954900
         DC    X'02'                                                    86956900
         DC    C'ESD'                                                   86957300
         DC    A(IEWLESD)               ESD PROCESSOR                   86962000
         DC    X'02'                                                    86964000
         DC    C'SYM'                                                   86966000
         DC    A(RELOREAD)              READ REQUEST ROUTINE            86966400
         DC    X'02'                                                    86966800
         DC    C'END'                                                   86971500
         DC    A(IEWLEND)               END PROCESSOR                   86973500
         DC    X'02'                                                    86975500
         DC    C'MOD'                                                   86975900
         DC    A(IEWLMOD)                                               86976300
MAINTAIN DS    50F                     MAINTENANCE AREA                 87085800
         EJECT                                                          87135800
         IEWLDCOM                                                       87185800
         END                                                            87235800
