 TITLE 'IEWLCTRL - LOADER CONTROL'                                      00700000
*********************************************************************** 01400000
* STATUS - CHANGE LEVEL 21.7                                          * 01700021
*              IEWLCTRL DOES THE FOLLOWING - (1) CHECKS CVT TO SEE    * 01800000
*              IF MVT IS OPERATING, (2) IF MVT,INVOKES IEWLOAD TO     * 01900000
*              LOAD AND IDENTIFY PROBLEM PROGRAM.  IF NOT MVT,INVOKES * 02000000
*              IEWLOADR TO LOAD P/P WITHOUT IDENTIFICATION. (3)       * 02100000
*              IF MVT, ATTACHES PROGRAM.  IF NOT MVT, LOADER BRANCHES * 02200000
*              AND LINKS TO IT.                                         02300000
*FUNCTION/OPERATION: IEWLCTRL CONTROLS LINKAGES TO AND FROM THE       * 02800000
*    PROCESSING PORTION OF THE LOADER AND LINKAGES TO AND FROM THE    * 03500000
*    OBJECT PROGRAM.                                                  * 04200000
*ENTRY POINTS:                                                        * 04900000
*        IEWLCTRL(IEWLDRGO,LOADER)--VIA EXEC JCL STATEMENT            * 05600000
*                                 --VIA LINK,ATTACH,XCTL,OR LOAD/BALR * 06300000
*INPUT: REGISTER 1 MUST POINT TO A VALID PARAMETER LIST ADDRESS       * 07000000
*    EVENTHOUGH NO PARAMETERS ARE SPECIFIED                           * 07700000
*OUTPUT:NONE                                                          * 08400000
*EXTERNAL ROUTINES:                                                   * 09100000
*              IEWLOAD - TO LOAD AND IDENTIFY P/P                     * 09500000
*              IEWLOADR - TO LOAD P/P WITHOUT IDENTIFCATION           * 09900000
*        OBJECT PROGRAM- FOR EXECUTION                                * 10500000
*EXITS-NORMAL:RETURN TO CALLING PROGRAM VIA REGISTER 14 AFTER OBJECT  * 11200000
*    PROGRAM EXECUTION                                                * 11900000
*     -ERROR: RETURN TO CALLING PROGRAM VIA REGISTER 14 WITH ERROR    * 12600000
*    SEVERITY CODE RIGHT ADJUSTED IN REGISTER 15                      * 13300000
*TABLES/WORK AREAS: NONE                                              * 14000000
*ATTRIBUTES: READ ONLY,REUSABLE,REENTRANT                             * 14700000
*NOTES: NONE                                                          * 15400000
*********************************************************************** 16100000
IEWLCTRL CSECT                                                          16800000
*A809800,927300,930500                                           A43867 16850021
*A343000,441000,483000,637500,930300                             A44270 16900021
*C469000,637500,840000                                           A44270 17000021
*A286400,809300                                                  A40641 17100021
*A809881                                                         M2702  17150021
*                                                               SA53170 17200000
*                                                               SA54498 17250000
*                                                               SA49491 17300000
*                                                               SA53276 17350021
*D343100,I343500,C847500,C850000                                SA58076 17400021
BRANCH   EQU   15                                                       17500000
RETURN   EQU   14                  RETURN ADDRESS REGISTER              18200000
SAVEREG  EQU   13                  ADDRESS REGISTER SAVE AREA           18900000
BASE     EQU   12                  BASE REGISTER                        19600000
PGMPARM  EQU   11                  OBJ. PROGRAM PARAMETER LIST ADDRESS  20300000
SAVEPARM EQU   10                  PARAMETER REGISTER SAVE AREA         21000000
FREEADDR EQU   9                   ADDRESS OF STORAGE TO BE FREED       21700000
R8       EQU   8                   WORK REGISTER                        22400000
CT       EQU   7                       PARMETER LENGTH                  23100000
TEMPSAVE EQU   6                   ADDR OF CALLING PROGRAM SAVE AREA    23800000
SAVECT   EQU   5                   SAVE OBJ. PROGRAM PARM LENGTH        24500000
SAVEPTR  EQU   4                   SAVE PTR. TO OBJ. PROG. PARMS        25200000
SAVEEP   EQU   3                   SAVE OBJECT PROGRAM ENTRY POINT      25900000
LDRPARM  EQU   2                   ADDRESS OF LOADER PARAMETERS         26600000
PARM     EQU   1                   ADDRESS OF OBJ. PROGRAM PARAMETERS   27300000
ZERO     EQU   0                   LOAD AND FREEMAIN REGISTER           28000000
EMVT     EQU   X'10'               MVT FLAG IN CVT                      28520000
CVTPTR   EQU   16                  POINTER TO CVT                       28580000
CVTDCB   EQU   X'74'               DISPLACEMENT OF MVT FLAG IN CVT      28640000
ABBIT    EQU   29                  ABEND BIT IN TCB              A40641 28660021
ABMASK   EQU   X'80'               FLAG TO TEST ABEND BIT        A40641 28680021
         SAVE  (14,12),T,*                                              28700021
         BALR  BASE,0              ESTABLISH ADDRESSIBILITY             29400000
         USING *,BASE                                                   30100000
         LR    SAVEPARM,PARM       SAVE PARAMETER REGISTER              30800000
         LR    TEMPSAVE,SAVEREG    SAVE ADDR.OF CALLING PGM. SAVE AREA  31500000
         L     SAVEPTR,0(PARM)     GET PTR TO PARM LIST          A53170 31550021
         LH    CT,0(SAVEPTR)       GET LENGTH OF PARM LIST       A53170 31600021
         LA    CT,CTRLEN(CT)       ADD IN FIXED LENGTH           A53170 31650021
         GETMAIN R,LV=(CT)         GET FOR SA, ATTCH PARM LIST   A53170 32500021
*                                  AND PARAMETER LIST FOR P/P    A53170 32550021
         LR    FREEADDR,PARM       SAVE ADDR FOR FREEMAIN               33600000
         USING CTRSTOR,FREEADDR                                         34300000
         ST    ZERO,GETLEN         SAVE LENGTH OF GETMAIN        A53170 34350021
         MVI   GETLEN,X'00'        ZERO OUT HIGH ORDER BYTE     SA58076 34400021
         MVI   CTRFLG,X'00'        ZERO OUT FLAG BYTE            A44270 34600021
         ST    SAVEREG,4(PARM)     FORWARD AND BACKWARD CHAIN SAVEAREAS 35000000
         ST    PARM,8(SAVEREG)                                          35700000
         LR    SAVEREG,PARM        ESTABLISH SAVE AREA REGISTER         36400000
********                                                      ********* 36460000
*                        TEST FOR MVT OR NON-MVT SYSTEM               * 36520000
********                                                      ********* 36580000
         MVC   CTRNAM(8),NAMLOAD   PLAN TO INVOKE LOADER VIA IEWLOAD    36640000
*                                            IEWLOAD                    36700000
         LA    R8,CVTPTR           GET ADDR OF PTR TO CVT               36760000
         L     R8,0(R8)            GET ADDR OF CVT                      36820000
         TM    CVTDCB(R8),EMVT     IS THIS MVT SYSTEM                   36880000
         BO    GETLDR              YES. BRANCH                          36940000
         MVI   CTRNAM+7,C'R'   NO. INVOKE VIA IEWLOADR                  37020000
********                                                       ******** 37100000
*               LOAD THE PROCESSING PORTION OF THE LOADER             * 37800000
********                                                       ******** 38500000
GETLDR   LOAD  EPLOC=CTRNAM        LOAD PROCESSING PART OF LOADER       39200000
********                                                       ******** 39900000
*                 SET  UP  PARAMETERS FOR  THE  LOADER                * 40600000
********                                                       ******** 41300000
         LR    PARM,SAVEPARM       RESTORE PARM REGISTER                42000000
         L     SAVEPTR,0(PARM)                                          42700000
         LH    CT,0(SAVEPTR)       GET PARAMETER COUNT                  43400000
         LR    SAVECT,CT               SAVE FOR RESIDUAL CT. CALC.      44100000
         STH   CT,CTRBYT           SAVE RESIDUAL COUNT           A44270 44400021
         LTR   CT,CT               ARE THERE ANY PARAMETERS             44800000
         BZ    PROCESS             GO TO LOAD PROGRAM                   45500000
LOOP     CLI   2(SAVEPTR),C'/'         IS THIS END OF LOADER PARMS.     46200000
         BE    PRMSET1                                           A44270 46900021
         LA    SAVEPTR,1(SAVEPTR)  UPDATE PARM POINTER                  47600000
         BCT   SAVECT,LOOP         CONTINUE LOOP                        48300000
         B     PRMSETUP            PREPARE TO LOAD PROGRAM       A44270 48500021
PRMSET1  OI    CTRFLG,X'01'        LOADED PROGRAM PARMS          A44270 48700021
PRMSETUP L     LDRPARM,0(PARM)     GET PARM ADDR                        49000000
         SR    CT,SAVECT           CALC RESIDUAL COUNT                  49700000
         STH   CT,0(LDRPARM)       RESET COUNT FOR LOADER               50400000
********                                                       ******** 51100000
*             GO TO PROCESSING PORTION OF LOADER FOR LOADING          * 51800000
********                                                       ******** 52500000
PROCESS  LR    BRANCH,ZERO         GET ADDRESS OF LOADER                53200000
         BALR  RETURN,BRANCH                                            53900000
         LR    PGMPARM,PARM        SAVE ADDRESS OF PARAMETERS           54600000
         LR    SAVEEP,ZERO         SAVE OBJECT PROGRAM ENTRY POINT      55300000
         LR    CT,BRANCH           SAVE RETURN CODE                     56000000
********                                                       ******** 56700000
*          FREE CORE OCCUPIED BY PROCESSING PORTION OF THE LOADER     * 57400000
********                                                       ******** 58100000
         DELETE EPLOC=CTRNAM       FREE SPACE OCCUPIED BY LOADER        58800000
         LR    BRANCH,CT           RESTORE RETURN CODE                  59500000
         CH    BRANCH,FOUR         IS CONDITION CODE GT 4               60200000
         BNH   PARMSET             NO.                                  60400000
         CLI   CTRNAM+7,C'R'       YES. DID WE INVOKE BY IEWLOADR       60600000
         BNE   CTRLRTRN            NO.                                  60800000
         B     FR2                     YES.                             61200000
********                                                       ******** 61600000
*                 SET UP PARAMETERS FOR LOADED PROGRAM                * 62300000
********                                                       ******** 63000000
PARMSET  EQU   *                                                        63300000
         LR    PARM,SAVEPARM       RESTORE PARM REGISTER                63700000
         LA    LDRPARM,PPARMSAC    POINT TO START OF PARM AREA   A53170 64400021
*                                  LOADED PROGRAM WILL USE       A53170 64450021
         O     LDRPARM,PPARMSOR    SHOW LAST WORD AND            A59398 64460021
         ST    LDRPARM,PPARMS      SET UP ADDR OF PARMS          A53170 64500021
         BCTR  SAVECT,0            FORGET SLASH                  A59398 65100021
         STH   SAVECT,PPARMSAC     STORE LENGTH FOR PP           A59398 65800021
         LA    CT,255                   MAXIMUM LENGTH OF MOVE          66500000
         LTR   SAVECT,SAVECT       ANY PARMS FOR OBJ. PROGRAM           67200000
         BP    CTSETUP                  YES                             67900000
         XC    0(2,LDRPARM),0(LDRPARM) SET PARM CT EQ 0                 68600000
         B     EXECUTE             GO TO EXECUTE OBJ. PROGRAM           69300000
CTSETUP  CH    SAVECT,CONT256          ARE THERE MORE THAN 255 BYTES    70000000
         BNL   MOVEPARM                 YES                             70700000
         LR    CT,SAVECT                NO, USE ACTUAL COUNT            71400000
         BCTR  CT,0                     DECR COUNT FOR EX INST.         72100000
MOVEPARM EX    CT,MOVE                  MOVE PARAMETERS                 72800000
         SH    SAVECT,CONT256           DECR CT BY BYTES MOVED          73500000
         LTR   SAVECT,SAVECT            MORE PARAMETERS TO MOVE         74200000
         BNH   EXECUTE                  NO                              74900000
         AH    LDRPARM,CONT256          YES,UPDATE DESTINATION PTR      75600000
         AH    SAVEPTR,CONT256          UPDATE ORIGINATION PTR          76300000
         B     CTSETUP                  GO TO CONTINUE MOVE             77000000
********                                                       ******** 77700000
*                           EXECUTE LOADED PROGRAM                    * 78400000
********                                                       ******** 79100000
EXECUTE  CLI   CTRNAM+7,C'R'       DID WE INVOKE VIA IEWLOADR           79170000
         BNE   LINK                NO. LINK TO PROGRAM                  79240000
         LR    BRANCH,SAVEEP       YES. BRANCH TO LOADER. GET EP        79310000
         LA    PARM,PPARMS              GET ADDRESS OF PARM LIST SM4390 79360021
*                                       FOR PROBLEM PROGRAM INTO SM4390 79370021
*                                       REGISTER ONE             SM4390 79372021
         BALR  RETURN,BRANCH       EXECUTE OBJECT PROGRAM               79380000
         LR    CT,BRANCH           SAVE OBJECT PROGRAM RETURN CODE      79450000
EX1      L     PARM,8(PGMPARM)         GET START OF FIRST EXTENT OF     79458000
*                                      COMPILER-LOADED TEXT             79466000
         LTR   PARM,PARM               IS THERE ANY?                    79474000
         BZ    FR2                     NO.                              79482000
         L     ZERO,12(PGMPARM)        YES.  GET LENGTH                 79490000
         FREEMAIN R,LV=(0),A=(1)       FREE IT                          79498000
FR2      EQU   *                                                        79506000
         L     PARM,0(PGMPARM)     GET START OF PROGRAM                 79520000
         L     ZERO,4(PGMPARM)     GET LENGTH                           79590000
         FREEMAIN R,LV=(0),A=(1)   FREE PROGRAM                         79660000
         B     CTRLRTRN            BRANCH TO FREE SAVE AREA             79730000
********                                                        ******  79830000
*                     ATTACH PROBLEM PROGRAM                          * 79930000
********                                                        ******* 80030000
LINK     MVC   CTRATTCH(CTRATTLN),ATTCH MOVE ATTACH LIST IN             80130000
         ST    PGMPARM,CTRATTCH    STORE PTR TO NAME                    80230000
         SR    R8,R8               ZERO OUT                             80330000
         ST    R8,CTRECB                ECB.                            80430000
         LA    PARM,PPARMS              GET ADDRESS OF PARM LIST SM4390 80480000
*                                       FOR PROBLEM PROGRAM INTO SM4390 80490000
*                                       REGISTER ONE             SM4390 80500000
         ATTACH ECB=CTRECB,MF=(E,(1)),SF=(E,CTRATTCH),SHSPV=78  SA53276 80530021
         ST    PARM,CTRTCB         SAVE TCB POINTER                     80630000
         WAIT  ECB=CTRECB          WAIT FOR P/P TO FINISH               80730000
         NI    CTRECB,X'3F'        ISOLATE RETURN OR COMPLETION CODE    80830000
         L     CT,CTRECB           AND SAVE IT                          80930000
         L     PARM,CTRTCB         PICK UP TCB ADDRESS           A40641 80940021
         TM    ABBIT(PARM),ABMASK  HAS USER PGM ABENDED          A40641 80950021
         BZ    DETACH              NO                            A40641 80960021
         WTO   'IEW199I ERROR - USER PROGRAM HAS ABNORMALLY TERMINATED'X80970021
               ,ROUTCDE=(2,11)                                   A40641 80980021
RELTEST  EQU   *                                                SA54498 80980100
         LA    R8,CVTPTR           GET POINTER                  SA54498 80980400
         L     R8,0(R8)            TO CVT                       SA54498 80980500
         SH    R8,HALF3            BACK UP TO RELEASE LEVEL     SA54498 80980600
         CLI   0(R8),C'2'          RELEASE 20.0 OR HIGHER?      SA54498 80983600
         BNE   AB1                 BYPASS EXTRACT IF NOT        SA54498 80985600
         MVC   INITEXTR(EXTRLEN),EXTR MOVE EXTRACT PARM LIST     A43867 80988000
         LA    R8,INITEXAD         GET ADDRESS FOR TSO PTR       A43867 80991000
         ST    R8,INITEXTR         PUT IT IN LIST                A43867 80994000
         EXTRACT MF=(E,INITEXTR)   POINT TO LIST FORM            A43867 80997000
         L     R8,INITEXAD         GET IT                        A43867 81000000
         LTR   R8,R8               WAS IT DEFINED                A43867 81003000
         BZ    AB1                 NO, BRANCH                    A43867 81006000
         TM    0(R8),TCBTSTSK      YES, IT IT TIME-SHARING       A43867 81009000
         BO    DETACH              YES                           A43867 81012000
AB1      L     PARM,CTRTCB         PICK UP TCB ADDRESS           A43867 81015000
         L     PARM,16(PARM)                                     A43867 81018000
         LA    PARM,0(PARM)        SUPPRESS DUMP                 M2702  81021000
         SVC   13                                                A43867 81024000
DETACH   EQU   *                                                 A40641 81027000
         DETACH CTRTCB             DETACH P/P                           81030000
********                                                       ******** 81900000
*          FREE SAVE AREA AND ATTCH PARAM LIST                          82600000
********                                                       ******** 83300000
CTRLRTRN EQU   *                                                 A44270 83500021
         TM    CTRFLG,X'01'        LOADED PROG PARMS?            A44270 83700021
         BZ    CT1                 NO                            A44270 83900021
         NI    0(SAVEPARM),X'7F'   TURN OFF LAST PARM FLAG       A44270 84100021
CT1      L     PARM,0(SAVEPARM)    A(OPTIONS)                    A44270 84300021
         MVC   0(2,PARM),CTRBYT    RESTORE RESIDUAL COUNT        A44270 84500021
         LR    PARM,FREEADDR       ADDR OF STORAGE TO BE FREED   A44270 84700021
         L     ZERO,GETLEN         GET LENGTH OF GOTTEN CORE    SA58076 84750021
         FREEMAIN R,LV=(0),A=(1)   FREE SA AND PARM LIST        SA58076 85000021
         LR    BRANCH,CT           RESTORE OBJECT PROG RETURN CODE      87000021
         LR    SAVEREG,TEMPSAVE    RESTORE CALLING PGM SAVE AREA ADDR.  89600000
         RETURN (14,12),T,RC=(15)                                       90300000
         DS    0F                  ALIGN                                90302021
PPARMSOR DC    X'80000000'         MASK TO SET HIGH ORDER BIT    A59398 90310021
HALF3    DC    H'3'                CONSTANT TO BACK UP CVT PTR  SA54498 90350000
FOUR     DC    H'4'                                                     91000000
CONT256  DC    H'256'                   DECR LENGTH FOR PARM. MOVES     91700000
MOVE     MVC   2(1,LDRPARM),3(SAVEPTR) MOVE PARM. FIELD                 92400000
NAMLOAD  DC    CL8'IEWLOAD '       NAME TO INVOKE PROCESSING PORTION BY 92700000
ATTCH    ATTACH SF=L               ATTACH PARAM LIST                    92730000
EXTR     EXTRACT EXTR,'S',FIELDS=(TSO),MF=L                      A43867 92740021
TCBTSTSK EQU   X'80'               TSO FLAG                      A43867 92750021
******                                                          ******* 92760000
*              DSECT FOR CTR'S DYNAMIC STORAGE                        * 92790000
******                                                          ******* 92820000
CTRSTOR  DSECT                                                          92850000
CTRSA    DS    18F                 SAVE AREA                            92880000
CTRATTCH ATTACH ECB=CTRECB,SF=L                                         92910000
CTRATTLN EQU   *-CTRATTCH          LENGTH OF ATTCH PARAM LIST           92940000
CTRECB   DS    F                   ECB FOR P/P TASK                     92970000
CTRTCB   DS    F                   TCB FOR P/P                          93000000
CTRNAM   DS    CL8                 NAME BY WHICH TO INVOKE LOADER       93030000
CTRFLG   DS    X                   SPECIAL FLAGS                 A44270 93040021
CTRBYT   DC    H'0'                FOR RESIDUAL COUNT            A44270 93050021
INITEXTR EXTRACT INITEXAD,'S',FIELDS=(TSO),MF=L                  A43867 93052021
EXTRLEN  EQU   *-INITEXTR                                        A43867 93054021
INITEXAD DS    F                   EXTRACT WILL PUT ADDR OF      A43867 93056021
*                                  TSO FIELD HERE                A43867 93058021
GETLEN   DS    F                   LENGTH OF GETMAIN WILL        A53170 93058421
*                                  BE SAVED HERE                 A53170 93058821
         DS    0D                  ALIGNMENT FOR PP PARM LIST    A53170 93059221
CTRLEN   EQU   *-CTRSTOR+6         CTR WILL GETMAIN FOR THIS     A58736 93060021
*                                  VALUE PLUS THE LENGTH OF      A53170 93062021
*                                  PARM LIST PASSED TO LOADER    A53170 93064021
*                                  BY THE INVOKING PROGRAM       A53170 93066021
PPARMS   EQU   *                   PARMS FOR PP WILL BE MOVED    A53170 93080021
*                                  HERE FOR ALIGNMENT            A53170 93092021
PPARMSAC EQU   *+4                 ACTUAL POSITION OF START      A53170 93094021
*                                  OF PARM LIST FOR LOADED       A53170 93096021
*                                  PROGRAM                       A53170 93098021
         END                                                            93100000
