ADJS TITLE 'IHCADJST - FORTRAN G/H LIBRARY BOUNDRY ALIGNMENT MODULE'    00020000
* IHCADJST                                                              00040000
*                                                                       00043000
*1332    017000,020650,030800,039600,059600                       MAINT 00046000
*C053400                                                          59714 00047022
*A053500                                                          59714 00048022
*                                                                       00049000
*   STATUS  --  CHANGE LEVEL 02 -- 1 AUGUST 1974  --  RELEASE 21.8      00052022
*                                                                       00055000
* FUNCTION/OPERATION--IHCADJST IS A MEMBER OF THE LINK LIBRARY AND IS   00060000
*    USED TO PROVIDE EXECUTION-TIME ADJUSTMENT OF BOUNDARY              00080000
*    MISALIGNMENTS OCCURRING IN A FORTRAN PROGRAM.                      00100000
* ENTRY POINT -                                                         00140000
*        'IHCADJST' IS THE FIRST INSTRUCTION OF THE BOUNDARY ALIGNMENT  00160000
*                   ROUTINE.  ENTRY IS FROM THE INTERRUPT HANDLING      00180000
*                   ROUTINE ( ARITH) IN IBCOM (IHCFCOMH).               00200000
* INPUT  - INPUT CONSISTS OF PARAMETERS PASSED FROM ARITH IN REGISTERS. 00220014
*                   REGISTER 14 CONTAINS ENTRY POINT TO IHCADJST (USED  00240000
*                               TO ESTABLISH ADDRESSABILITY)            00260000
*                   REGISTER 15 CONTAINS THE ADDRESS OF REGISTER SAVE   00280000
*                               AREA IN ARITH.                          00300000
*                   REGISTER  1 CONTAINS THE ADDRESS OF A PARAMETER     00308014
*                               LIST IN ARITH. THE PARAMETER LIST       00316014
*                               CONSISTS OF  -                          00324014
*                                 (1) THE SUPERVISOR RETURN ADDRESS     00332014
*                                 (2) AN S-TYPE ADCON OF THE ROUTINE IN 00340014
*                                   ARITH WHICH IS USED TO WRITE THE    00348014
*                                   BOUNDARY ALIGNMENT MESSAGE          00356014
*                                 (3) THE ADDRESS OF THE PIE            00364014
*                                 (4) THE ADDRESS OF IHCUOPT.           00372014
*                                     (IHCUOPT SPECIFIES THE MAXIMUM    00380014
*                                     NUMBER OF BOUNDARY ALIGNMENT      00388014
*                                     MESSAGES TO BE WRITTEN)           00396014
*                                 (5) THE ADDRESS OF INT6SW             00404014
*                                     (INT6SW IS A SWITCH LOCATED IN    00412014
*                                     IHCFCVTH WHICH INDICATES WHETHER  00420014
*                                     A BOUND. ALIGNMENT ERROR HAS      00428014
*                                     OCCURRED FOR AN ITEM BEING READ   00436014
*                                     OR WRITTEN)                       00444014
*                   REGISTER  2 CONTAINS ADCON OF FIOCS#                00460000
* OUTPUT - OUTPUT CONSISTS OF MESSAGES AND PROPER EXECUTION OF          00480000
*          INSTRUCTION WHICH CAUSED BOUNDARY ALIGNMENT ERROR.           00500000
* EXTERNAL ROUTINES-                                                    00520000
*          ROUTINE ARITH IN IBCOM                                       00540000
* EXITS-                                                                00560000
*        NORMAL-                                                        00580000
*                   1. RETURN TO PROBLEM PROGRAM VIA SUPERVISOR         00600000
*                   2. RETURN TO PROBLEM PROGRAM VIA ROUTINE ARITH IN   00620000
*                      CASE OF AN ARITHMETIC INTERRUPT OCCURRING WHEN   00640000
*                      REEXECUTING THE BOUNDARY ALIGNMENT ERROR INSTR.  00660000
*        ERROR-                                                         00680000
*                   JOB WILL ABEND UNDER THE FOLLOWING CONDITIONS-      00700000
*                   1. BOUNDARY ALIGNMENT WAS ENTERED AS A RESULT OF    00720000
*                      A BRANCH TO AN ODD LOCATION.                     00740000
*                   2. INSTRUCTION LENGTH IS NOT EQUAL TO 2             00760000
*                   3. INSTRUCTION IS ONE ON WHICH AN ALIGNMENT         00780000
*                      PROBLEM SHOULD NOT OCCUR                         00800000
*                   4. OTHER SPECIFICATION ERRORS EXIST (OTHER THAN     00820000
*                      DATA MISALIGNMENT)                               00840000
*                   5. A DATA, PROTECTION, OR ADDRESSING INTERRUPT      00860000
*                      OCCURRING ON THE BOUNDARY ALIGNMENT ERROR INSTR. 00880000
* TABLES/WORK AREAS-   'PIESAVE' - SAVE AREA FOR THE PROGRAM            00900000
*                                 INTERRUPTION ELEMENT WHICH EXISTS ON  00920000
*                                 ENTRY TO THE BOUNDARY ALIGNMENT       00940000
*                                 ROUTINE.                              00960000
*                      REGISTER SAVE AREAS                              00980000
* ATTRIBUTES - SERIALLY REUSABLE                                        01000000
* NOTES-                                                                01020000
*                   THE ROUTINE IS BROUGHT INTO CORE BY A LOAD MACRO    01040000
*                   ON THE FIRST OCCURRENCE OF A SPECIFICATION          01060000
*                   INTERRUPT IN THE PROBLEM PROGRAM.                   01080000
*                   THE CALLING OF THIS ROUTINE AT EXECUTION TIME IS    01100000
*                   DEPENDENT ON A SYSGEN OPTION SPECIFIED IN THE       01120000
*                   MODULE IHCUOPT WHICH IS LINK EDITED WITH IBCOM.     01140000
*                   THE NUMBER OF BOUNDARY ALIGNMENT MESSAGES ISSUED    01160000
*                   IS ALSO AN OPTION SPECIFIED IN IHCUOPT.             01180000
*                                                                       01200000
IHCADJST CSECT                                                          01220000
         USING *,BASE                                                   01240000
         B     ADJBGN                                                   01260000
         DC    X'07'                                                    01280000
         DC    CL7'BNDRADJ'                                             01300000
*                                                                       01320000
ADJBGN   MVC   RETURN(24),0(1)      GET PARAMETERS                 HWRE 01360014
         ST    2,ADFIOCS               SAVE A(FIOCS=)                   01400000
         L     1,PIEADDR                                           HWRE 01415014
         LM    2,13,8(15)         RESTORE REGS USED BY ARITH       HWRE 01420014
         TM    11(1),X'01'                                              01440000
         BO    INSTEND                  INSTR ON WRONG BOUNDARY- ABEND  01460000
         MVI   SWITCH1,X'00'            RESET SWITCHES                  01480000
         MVI   SWITCH2,X'00'                                            01500000
         L     WORK1,8(0,1)            OBTAIN INSTRUCTION WHICH         01520000
         N     WORK1,ADRMSK              CAUSED SPEC. INTERRUPT AND     01540000
         SH    WORK1,HFOUR               HOLD IN WORK1                  01560000
         TM    8(1),X'40'               ILC NOT = 2, ABEND              01580000
         BO    SPECERR                                                  01600000
         MVC   INSTRWA,0(WORK1)         MOVE INSTR TO WORK AREA         01620000
*              TEST OP CODE OF INSTRUCTION TO DETERMINE IF IT IS ONE    01640000
*                FOR WHICH BOUNDARY VIOLATION IS HANDLED.               01660000
         CLI   INSTRWA,X'80'                                            01680000
         BNL   RSTEST              TEST IF LM,STM RS INSTRUCTION  MAINT 01700000
         CLI   INSTRWA,X'5F'            TEST INSTRUCTION TYPE           01720000
         BNH   FIXPT                    FIXED PT                        01740000
*              INSTRUCTION IS FLOATING POINT                            01760000
         MVI   FLPTSW,FLOAT             SET SW TO SPECIFY FL PT         01780000
*                                  TEST IF FLOAT PT REGISTER  USED      01800000
         TM    INSTRWA+1,B'10010000'                                    01820000
         BNZ   SPECEND                  IMPROPER REGISTER - ABEND       01840000
BOUND10  TM    INSTRWA,X'0F'            TEST OP CODE = STORE            01860000
         BZ    STSWSET                  STORE INSTR                     01880000
         TM    INSTRWA,B'00000010'                                      01900000
         BO    CCSWSET                  BIT 2 NOT = 0                   01920000
         TM    INSTRWA,B'00000001'                                      01940000
         BZ    BOUND20                  BIT 1 =0                        01960000
         TM    INSTRWA,B'00000100'                                      01980000
         BZ    CCSWSET                  BIT 4 = 0                       02000000
BOUND20  MVC   PIESAVE,0(1)             PLACE CURRENT PIE IN SAVE AREA  02020000
         MVC   REEXEC(2),INSTRWA        MOVE OP,R1 OF INST TO AREA      02040000
         CLI   RSSW,LMSTM                                         MAINT 02046000
         BE    SAVERG3             SAVE R3FIELD OF INSTRUCTION    MAINT 02052000
         NI    REEXEC+1,X'F0'             USED FOR REEXECUTION          02060000
SAVERG3  L     WORK2,AINT6SW                                      MAINT 02065000
         CLI   0(WORK2),X'00'                                      4648 02070013
         BNE   NOMSG                                               4648 02075013
         L     WORK2,ADROPT       LOAD REG FOR REFERENCE TO IHCUOPT     02080000
         CLI   5(WORK2),X'FF'          IS ERROR HANDLING INCLUDED?      02086016
         BNE   WRTMSG                  YES, BRANCH                      02092016
         CLI   6(WORK2),X'00'          TEST IF MSG TO BE WRITTEN        02102016
         BZ    NOMSG                   BRANCH IF NO MSG TO BE WRITTEN   02120000
         IC    WORK3,6(WORK2)                                           02140016
         BCTR  WORK3,0                 DECREMENT MSG COUNT AND PLACE    02160000
         STC   WORK3,6(WORK2)               NEW COUNT IN IHCUOPT        02180016
*              WRITE BOUNDARY ERROR MESSAGE  BY WAY OF A                02200000
*                   LINKAGE INTO IBCOM                                  02220000
*                                                                       02240000
WRTMSG   EQU   *                                                        02260016
         L     15,AARITH           LOAD BASE REG FOR ARITH              02280000
         MVC   ALRTLNK+2(2),SALERTA+2       GET LINK ADDR FOR ALERTA    02300000
         CNOP  0,4                                                      02320000
ALRTLNK  BAL   14,0(0)                                                  02340000
         L     BASE,8(14)               RESTABLISH PROPER BASE IN 14    02360000
         B     NEXT                                                     02380000
         DC    A(BOUND)                                                 02400000
NEXT     EQU   *                                                        02420000
NOMSG    EQU   *                                                        02460000
         LR    WORK3,BASE              SAVE CONTENTS OF BASE REG        02480000
         SPIE  PAEXCPT,(4,5)                                            02500000
         LR    BASE,WORK3              RESTORE BASE REG CONTENTS        02520000
         ST    1,PREVPICA              SAVE PREVIOUS PICA ADDRESS       02540000
*              CALCULATE X2+B2+D2 OF INSTRUCTION TO OBTAIN EFFECTIVE    02560000
*                ADDRESS OF OPERAND 2.                                  02580000
         L     2,PR2SAVE               RESTORE MAIN PROG CONTENTS OF R2 02600000
         L     WORK2,INSTRWA                                            02620000
         N     WORK2,DISPMSK            LOAD WORK2 WITH D2              02640000
         SR    WORK1,WORK1                                              02660000
         CLI   RSSW,LMSTM          IS THIS A LM OR STM INSTRUCT   MAINT 02666000
         BE    BOUND50             YES,BRANCH (NO X2 FLD TO COMP) MAINT 02672000
         IC    WORK1,INSTRWA+1          LOAD WORK1 WITH X2              02680000
         N     WORK1,REGMSK                                             02700000
         BZ    BOUND50                  X2 IS ZERO,  BRANCH TO TEST B2  02720000
         CH    WORK1,H14                                                02740000
         BE    BOUND100                 X2=14                           02760000
         BH    BOUND110                 X2>14 , =15                     02780000
         CH    WORK1,HONE                                               02800000
         BE    BOUND120                 X2=1                            02820000
         EX    WORK1,ADD                ADD CONTENTS OF X2 TO D2        02840000
BOUND50  IC    WORK1,INSTRWA+2          LOAD WORK1 WITH B2              02860000
         SRA   WORK1,4                                                  02880000
         BZ    BOUND60                  B2 IS ZERO                      02900000
         CH    WORK1,H14                                                02920000
         BE    BOUND130                 B2=14                           02940000
         BH    BOUND140                 B2>14, =15                      02960000
         CH    WORK1,HONE                                               02980000
         BE    BOUND150                 B2=1                            03000000
         EX    WORK1,ADD                ADD IN CONTENTS OF B2           03020000
*                        WORK2 NOW CONTAINS EFFECTIVE ADDR OF OPERAND 2 03040000
BOUND60  ST    WORK2,EFFADR             SAVE ADDRESS                    03060000
         CLI   RSSW,LMSTM          IS THIS LM OR STM?             MAINT 03066000
         BE    COMPUTEL           YES,COMPUTE # OF REGS TO MOVE   MAINT 03072000
         LA    WORK1,7             DEFAULT LENTH OF DATA MVC=8    MAINT 03078000
MOVEDATA STH   WORK1,LENGTH        SAVE LENGTH OF DATA FLD        MAINT 03084000
         EX    WORK1,MVCDATA       MOVE DATA TO DBL-WORD BOUND    MAINT 03090000
BOUND70  LR    WORK3,BASE               SAVE CONTENTS OF BASE REG       03100000
         SPIE  EXCPTN,(4,7,9,11,12,13,15)                               03120000
         LR    BASE,WORK3               RESTORE BASE REG CONTENTS       03140000
         CLI   FLPTSW,FLOAT                                             03160000
         BE    REEXEC                   INSTR IS FLOAT PT-GO TO REEXEC  03180000
         LM    15,2,PR15SAVE    RESTORE MAIN PROG REGS EXCEPT 14        03200000
         CLI   RSSW,LMSTM          LM OR STM INSTRUCTION?         MAINT 03206000
         BE    REEXEC              YES, BRANCH                    MAINT 03212000
         TM    INSTRWA+1,X'F0'         TEST R1 = REG 15                 03220000
         BO    REEXEC                  YES                              03240000
         TM    INSTRWA+1,X'E0'          TEST R1 OF INSTR = REG 14       03260000
         BNO   REEXEC                   NO                              03280000
         OI    REG14SW,REG14            YES. SET REGISTER 14 SWITCH     03300000
         MVI   REEXEC+1,X'00'           NO- USE REG 0 AS R1 OF INSTR    03320000
         L     0,PR14SAVE               LOAD 0 WITH CONTENTS OF 14      03340000
         TM    MDSW,MPYDIV              IS INSTR MPY OR DIV             03360000
         BNO   REEXEC                   NO- GO TO REEXECUTE             03380000
         L     1,PR15SAVE           YES-LOAD REG 1 WITH CONTENTS OF 15  03400000
*             SIMULATION OF INSTRUCTION WHICH CAUSED BOUNDARY ERROR.    03420000
*              THE OP CODE AND R1 FIELDS OF THE FOLLOWING INSTRUCTION   03440000
*               WILL BE REPLACED BY THOSE OF THE SIMULATED INSTRUCTION  03460000
*               EXCEPT WHEN R1 = REGISTER 14.  IN THAT CASE REGISTER 0  03480000
*               WILL BE USED (WITH REGISTER 1 IN THE CASE OF A FULL     03500000
*               WORD MULTIPLY OR DIVIDE.)                               03520000
REEXEC   A     0,TEMP                   DUMMY INSTRUCTION               03540000
         ST    15,SAVER15               SAVE CONTENTS OF 15             03560000
         BALR  15,0                     SAVE NEW COND CODE SETTING      03580000
         ST    15,CCSAVE                                                03600000
         L     15,SAVER15               RESTORE CONTENTS OF 15          03620000
         CLI   FLPTSW,FLOAT             IS INSTR GLOATING PT            03640000
         BE    CCTEST                   YES                             03660000
         CLI   REG14SW,REG14            NO-TEST MPY/DIV + REG14 SWS     03680000
         BL    RESETALL                 NEITHER REG 14 NOR 15 INDICATED 03700000
         BE    RESET14                  ONLY REG 14 INDICATED           03720000
         ST    1,PR15SAVE               BOTH REG 14 AND 15-REPLACE 15   03740000
RESET14  ST    0,PR14SAVE               REPLACE 14                      03760000
RESETPIE L     WORK2,PIEADDR            PLACE NEW REGISTER CONTENTS IN  03780000
         MVC   12(20,WORK2),PR14SAVE      PIE                           03800000
CCTEST   CLI   CCSW,CCON                WAS COND CODE AFFECTED          03820000
         BNE   STTEST                   NO                              03840000
         L     WORK2,PIEADDR                                            03860000
         MVC   8(1,WORK2),CCSAVE        YES MOVE NEW CC TO PIE          03880000
STTEST   CLI   STSW,STORE               IS INSTR A STORE                03900000
         BNE   SPIEREST                 NO                              03920000
         L     WORK2,EFFADR             YES- MOVE DATA TO PROPER        03940000
         LH    WORK1,LENGTH        LOCATION IN MAIN PROGRAM       MAINT 03950000
         EX    WORK1,STINST        GET PROPER LGTH OF DATA FLD    MAINT 03960000
SPIEREST L     1,PREVPICA               ISSUE SPIE TO RESTORE ORIGINAL  03980000
         SPIE  MF=(E,(1))                 PICA.                         04000000
         L     14,RETURN                                                04020000
         BR    14                       RETURN TO SUPERVISOR            04040000
*                                                                       04060000
*                                                                       04080000
FIXPT    MVI   FLPTSW,FIX               SET SW TO INDICATE FIXED POINT  04100000
*        TEST OP CODE OF INSTRUCTION  TO DETERMINE IF IT IS A STORE     04120000
*              TYPE, IF THE CONDITION CODE IS AFFECTED WHEN INSTRUCTION 04140000
*              IS EXECUTED, IF ANY OTHER SPECIFICATION ERRORS EXIST.    04160000
         CLI   INSTRWA,X'50'                                            04180000
         BE    STSWSET                  =50                             04200000
         BL    FIXPT20                  <50                             04220000
         CLI   INSTRWA,X'5C'            >50                             04240000
         BE    FIXPT10                  =5C                             04260000
         BL    FIXPT30                  <5C                             04280000
         CLI   INSTRWA,X'5D'            >5C                             04300000
         BNE   CCSWSET                  NOT =5D                         04320000
*                             INSTR IS FULL WORD MPY OR DIV             04340000
FIXPT10  OI    MDSW,MPYDIV              SET MPY/DIV SWITCH              04360000
         TM    INSTRWA+1,X'10'          TEST R1 OF INSTR FOR ODD REG    04380000
         BO    SPECEND                  ODD REGISTER -ABEND             04400000
         B     BOUND20                                                  04420000
FIXPT20  CLI   INSTRWA,X'4E'                                            04440000
         BE    STSWSET                  =4E                             04460000
         BH    BOUND20                  >4E , =4F                       04480000
         CLI   INSTRWA,X'44'                                            04500000
         BE    SPECEND                  =44, ABEND                      04520000
         B     BOUND10                                                  04540000
FIXPT30  CLI   INSTRWA,X'58'                                            04560000
         BE    BOUND20                                                  04580000
*                             EXECUTION OF INSTR AFFECTS COND CODE -SET 04600000
*                               SWITCH TO INDICATE NEW CC MUST BE SAVED 04620000
*                               FOLLOWING REEXECUTION OF INSTR          04640000
CCSWSET  OI    CCSW,CCON                                                04660000
         B     BOUND20                                                  04680000
*                            INSTR IS A STORE (CVD,ST,STH,STD, OR STE)  04700000
STSWSET  OI    STSW,STORE               SET  STORE SWITCH               04720000
         B     BOUND20                                                  04740000
BOUND100 AL    WORK2,PR14SAVE      ADD CONTENTS OF X2 FROM R14 IN PIE   04760000
         B     BOUND50                                                  04780000
BOUND110 AL    WORK2,PR15SAVE      ADD CONTENTS OF X2 FROM R15 IN PIE   04800000
         B     BOUND50                                                  04820000
BOUND120 AL    WORK2,PR1SAVE       ADD CONTENTS OF X2 FROM R1 IN PIE    04840000
         B     BOUND50                                                  04860000
BOUND130 AL    WORK2,PR14SAVE                                           04880000
         B     BOUND60                                                  04900000
BOUND140 AL    WORK2,PR15SAVE      ADD CONTENTS OF B2 FROM R15 IN PIE   04920000
         B     BOUND60                                                  04940000
BOUND150 AL    WORK2,PR1SAVE       ADD CONTENTS OF B2 FROM R1 IN PIE    04960000
         B     BOUND60                                                  04980000
RESETALL STM   15,2,PR15SAVE            REPLACE 15-2                    05000000
         B     RESETPIE                                                 05020000
RSTEST   EQU   *                                                  MAINT 05020800
         CLI   INSTRWA,X'98'       IS THE OP CODE FOR A LM?       MAINT 05021600
         BE    RSSWSET             YES,BRANCH TO SET SWITCH       MAINT 05022400
         CLI   INSTRWA,X'90'       IS THE OP CODE FOR A STM?      MAINT 05023200
         BNE   SPECEND            NO,INSTRUCTION OUT OF RANGE     MAINT 05024000
         MVI   STSW,STORE          SET STORE SWITCH               MAINT 05024800
RSSWSET  MVI   RSSW,LMSTM          SET SWITCH TO INDICATE RS INST MAINT 05025600
         MVI   FLPTSW,FIX          INDICATE INST. IS FIXED POINT  MAINT 05026400
         B     BOUND20                                            MAINT 05027200
COMPUTEL EQU  *                                                   MAINT 05028000
        SR    WORK1,WORK1                                         MAINT 05028800
        IC    WORK1,INSTRWA+1     PICK UP R1 AND R3 FIELD OF INST MAINT 05029600
         N     WORK1,R1MSK         ISOLATE THE R1 FIELD           MAINT 05030400
        SRA   WORK1,4            MVC R1 TO LOW ORDER BYTE OF REG  MAINT 05031200
        STH   WORK1,R1SAVE                                        MAINT 05032000
        IC    WORK1,INSTRWA+1                                     MAINT 05032800
        N     WORK1,REGMSK        ISOLATE R3 FIELD                MAINT 05033600
*COMPUTE NUMBER OF REGS(N) INVOLVED IN THE LM OR STM              MAINT 05034400
         SH    WORK1,R1SAVE        N=R3-R1+1                      MAINT 05035200
         AH    WORK1,HONE                                         MAINT 05036000
         SLA   WORK1,2           N*4=LENGTH IN BYTES OF DATA FLD  MAINT 05036800
         B     MOVEDATA            TO BE MOVED                    MAINT 05037600
*                                                                       05040000
*      ISSUE SPIE MACRO TO ELIMINATE SPECIAL INTERRUPT HANDLING.  THEN  05060000
*        FORCE ABEND BY REEXECUTING INSTRUCTION WHICH CAUSED            05080000
*        THE SPECIFICATION INTERRUPT.                                   05100000
*                                                                       05120000
SPECERR  TM    8(1),X'80'              TEST ILC TO GET INSTR LENGTH.    05140000
         BZ    SPECERR1                BRANCH IF INSTR IS 2 BYTES       05160000
         SH    WORK1,HTWO              MODIFY ADDR FOR 6 BYTE INSTR     05180000
         B     SPECEND                                                  05200000
SPECERR1 AH    WORK1,HTWO              MODIFY ADDR FOR 2 BYTE INSTR     05220000
*                   WORK1 CONTAINS ADDR OF INSTR WHICH CAUSED SPEC INT. 05240000
SPECEND  ST    WORK1,PSWSAVE+4                                          05260000
         L     1,PIEADDR                RESET PSW ADDR IN PIE TO  INSTR 05280000
         MVC   9(3,1),PSWSAVE+5          WHICH CAUSED INTERRUPT.        05300000
INSTEND  L     2,RETURN                 LOAD RETURN ADDR                05320000
         SR   1,1     ZERO REG                                59714 1/2 05340022
          SPIE  MF=(E,(1))       SPIE DELETE                  59714 2/2 05350022
         BR    2                        RETURN TO SUPERVISOR            05360000
*                                                                       05380000
*                                                                       05400000
BOUND    EQU   IHCADJST                                                 05420000
*                   SAVE AREA FOR PROG INTERRUPT ELEMENT (PIE)          05440000
         DS    0D                                                       05460000
PIESAVE  DS    0CL32                                                    05480000
PICASAVE DS    F                                                        05500000
PSWSAVE  DS    2F                                                       05520000
PR14SAVE DS    F                                                        05540000
PR15SAVE DS    F                                                        05560000
PR0SAVE  DS    F                                                        05580000
PR1SAVE  DS    F                                                        05600000
PR2SAVE  DS    F                                                        05620000
*                                                                       05640000
         DS    0F                                                       05660000
RETURN   DS    F         RETURN ADDRESS (TO SUPERVISOR)                 05680000
AARITH   DS    F         A(ARITH) IN IBCOM                              05700000
SALERTA  DS    F         S(ALERTA) IN IBCOM                             05720000
PIEADDR  DS    F         ADDRESS OF PROGRAM INTERUPTION ELEMENT (PIE)   05740000
ADROPT   DS    F         A(IHCUOPT) FROM IBCOM                          05780000
AINT6SW  DS    F         ADCON OF INT6SW IN IHCFCVTH(FROM IBCOM)   4648 05790013
ADFIOCS  DS    F                   A(FIOCS) FROM IBCOM             HWRE 05795014
EFFADR   DS    F         EFFECTIVE ADDR OF INSTR (D2+B2+X2)             05800000
PREVPICA DS    F         PREVIOUS PICA ADDRESS                          05820000
CCSAVE   DS    F         SAVE AREA FOR COND CODE SETTING                05840000
SAVER15  DS    F         TEMP SAVE AREA FOR R15                         05860000
SAVER3   DS    F         TEMP SAVE AREA FOR R3                          05880000
SAVEMPR8 DS    F        SAVE AREA FOR MAIN PROG CONTENTS OF REG 8  HWRE 05886014
SAVEBR8  DS    F        SAVE AREA FOR CONTENTS OF ARITH BASE REG 8 HWRE 05892014
*                                                                       05900000
*                                                                       05920000
         DS    0D                                                       05940000
TEMP    DS    4D               WORK AREA FOR CONTENTS OF OPERAND2 MAINT 05960000
*                                                                       05980000
*                                                                       06000000
         DS    0F                                                       06020000
INSTRWA  DS    F              WORK AREA FOR INSTR CAUSING SPEC INTERPT  06040000
*        REGISTER DEFINITIONS                                           06060000
R0       EQU   0                       REGISTER 0                       06080000
R1       EQU   1                       REGISTER 1                       06100000
BASE     EQU   14                       BASE REGISTER                   06120000
WORK1    EQU   15                       WORK REGISTER                   06140000
WORK2    EQU   1                        WORK REGISTER                   06160000
WORK3    EQU   2                        WORK REGISTER                   06180000
*                                                                       06200000
         DS    0F                                                       06220000
ADRMSK   DC    X'00FFFFFF'              MASK FOR 24 BIT ADDRESS         06240000
DISPMSK  DC    X'00000FFF'              MASK FOR DISPLACEMENT           06260000
REGMSK   DC    X'0000000F'                                              06280000
R1MSK    DC    X'000000F0'                                        MAINT 06290000
HFOUR    DC    H'4'                                                     06300000
H14      DC    H'14'                                                    06320000
HONE     DC    H'1'                                                     06340000
HTWO     DC    H'2'                                                     06360000
LENGTH  DS    H                                                   MAINT 06366000
R1SAVE  DS    H                                                   MAINT 06372000
*                             SWITCHES                                  06380000
*                                                                       06400000
FLPTSW   DC    X'00'          SWITCH SET TO 00 IF FIXED PT, 01 IF FL PT 06420000
*        COND CODE SW = FIRST HALF OF BYTE                              06440000
*              SETTING - BITS 0-2  ALWAYS ZERO                          06460000
*                        BIT  3    0 IF INSTR DOES NOT AFFECT CC        06480000
*                                  1 IF INSTR DOES AFFECT CC            06500000
*        STORE SWITCH = SECOND HALF OF BYTE                             06520000
*              SETTING - BITS 4-6  ALWAYS ZERO                          06540000
*                        BIT  7    0 IF INSTR IS NOT STORE TYPE         06560000
*                                  1 IF INSTR IS STORE TYPE             06580000
SWITCH1  DC    X'00'          COND CODE SWITCH AND STORE SWITCH         06600000
CCSW     EQU   SWITCH1                                                  06620000
STSW     EQU   SWITCH1                                                  06640000
*     REGISTER 14 SWITCH = FIRST HALF OF BYTE                           06660000
*              SETTING-  BITS 0-2  ALWAYS ZERO                          06680000
*                        BIT  3    0 IF R1 OF INSTR NOT REGISTER  14    06700000
*                                  1 IF R1 OF INSTR EQUALS REGISTER 14  06720000
*     MULTIPLY/DIVIDE SWITCH                                            06740000
*              SETTING-  BITS 4-6  ALWAYS ZERO                          06760000
*                        BIT  7    0 IF INSTR NOT FULL WORD MPY OR DIV  06780000
*                                  1 IF INSTR IS FULL WORD MPY OR DIV   06800000
SWITCH2  DC    X'00'          REGISTER SWITCH AND MULTIPLY/DIV SWITCH   06820000
REG14SW  EQU   SWITCH2                                                  06840000
MDSW     EQU   SWITCH2                                                  06860000
RSSW    DC    X'00'               LM,ST, INSTRUCTION SWITCH       MAINT 06870000
*                                                                       06880000
ADD      ALR   WORK2,0                                                  06900000
MVCDATA MVC    TEMP(0),0(WORK2)    DATA MOVED TO DBL WORD BOUND   MAINT 06906000
STINST   MVC   0(0,WORK2),TEMP    PUT DATA IN PROPER LOC IN MAIN  MAINT 06912000
*                             CODES  FOR SWITCH SETTINGS                06920000
FIX      EQU   X'00'                                                    06940000
FLOAT    EQU   X'01'                                                    06960000
STORE    EQU   X'01'                                                    06980000
CCON     EQU   X'10'                                                    07000000
MPYDIV   EQU   X'01'                                                    07020000
REG14    EQU   X'10'                                                    07040000
LMSTM   EQU   X'FF'               LM,STM SWITCH SET               MAINT 07050000
*                                                                       07060000
*      INTERRUPT HANDLER FOR INTERRUPTS WHICH MAY OCCUR ON              07080000
*        REEXECUTION OF THE BOUNDARY ALIGNMENT ERROR INSTRUCTION.       07100000
*                                                                       07120000
         DS    0F                                                       07140000
EXCPTN   ST    14,16(0,15)              SAVE REG 14                     07160000
         L     BASE,12(0,15)            REESTABLISH 14 AS BASE REG      07180000
         B     BEGIN                                                    07200000
         DC    A(BOUND)                                                 07220000
REGSAVE  DS    F                        SAVE AREA FOR REG 14            07240000
BEGIN    EQU   *                                                        07260000
         CLI   7(1),X'07'              TEST FOR DATA,PROTECT EXCPT      07280000
         BNH   PROC4                   YES- GO TO WR MSG AND ABEND      07300000
         STM   0,1,SALERTA              SAVE REGS  0,1                  07320000
         CLI   CCSW,CCON                DID EXEC OF INSTR AFFECT CC     07340000
         BE    RESETAD                  YES -PIE CONTAINS PROPER CC     07360000
         MVC   8(1,1),PSWSAVE+4         NO- MOVE CC FROM OLD PIE TO NEW 07380000
RESETAD  MVC   9(3,1),PSWSAVE+5         RESTORE OLD PSW ADDR IN PIE     07400000
         CLI   FLPTSW,FLOAT                                             07420000
         BE    EXCPTN30                 INSTR IS FLOAT POINT            07440000
         CLI   REG14SW,REG14       FIX PT- TEST MPY/DIV + REG14 SWS     07460000
         BL    EXCPTN40            NEITHER REG 14 NOT REG 15 INDICATED  07480000
         BE    EXCPTN10            ONLY REG 14 INDICATED                07500000
         MVC   16(4,1),24(1)       BOTH REG 14 AND 15-SET NEW 15 IN PIE 07520000
         MVC   24(4,1),PR1SAVE     RESTORE OLD REG 1                    07540000
EXCPTN10 MVC   12(4,1),20(1)       SET NEW 14 IN PIE                    07560000
         MVC   20(4,1),PR0SAVE     RESTORE OLD REG 0                    07580000
EXCPTN20 L     1,PREVPICA          ISSUE SPIE TO RESTORE ORIGINAL PICA  07600000
         SPIE  MF=(E,(1))                                               07620000
         L     15,AARITH           LOAD R15 WITH ADDR OF ARITH          07640000
         LM    0,1,SALERTA         RESTORE REGISTERS                    07660000
         L     14,REGSAVE                                               07680000
         B     4(0,15)            GO TO ARITH TO PROCESS INTERRUPT      07700000
EXCPTN30 MVC   12(20,1),PR14SAVE        PLACE REGS FROM OLD PIE IN NEW  07720000
         B     EXCPTN20                                                 07740000
EXCPTN40 MVC   12(4,1),PR14SAVE         RESTORE OLD REG 14 INTO PIE     07760000
         B     EXCPTN20                                                 07780000
*                                                                       07800000
*      INTERRUPT HANDLER FOR DATA OR PROTECTION INTERRUPTS WHICH MAY    07820000
*        OCCUR DURING FETCHING OF MISALIGNED DATA PRIOR TO              07840000
*        REEXECUTING BOUNDARY ALIGNEMNT ERROR INSTRUCTION.              07860000
*                                                                       07880000
         CNOP  0,4                                                      07900000
PAEXCPT  ST    14,16(15)               SAVE REG 14                      07920000
         L     BASE,12(15)             REESTABLISH PROPER BASE IN 14    07940000
         B     PROCESS                                                  07960000
         DC    A(BOUND)                                                 07980000
REG14SAV DS    F                                                        08000000
PROCESS  EQU   *                                                        08020000
         MVC   RETURN,REG14SAV         SAVE RETURN ADDR TO SUPERVISOR   08040000
PROC2    ST    1,PIEADDR               SAVE ADDR OF PIE                 08060000
         MVC   9(3,1),PSWSAVE+5        REPLACE CURRENT PSW ADDR WITH    08080000
*                                          MAIN PROGRAM ADDRESS         08100000
         MVC   12(20,1),PR14SAVE       REPLACE CURRENT PIE REGS WITH    08120000
*                                             MAIN PROG REGS            08140000
*              WRITE ERROR MESSAGE BY WAY OF LINK INTO IBCOM            08160000
*                                                                       08180000
         L     15,AARITH               LOAD BASE REG FOR ARITH          08220000
         MVC   MSGLNK+2(2),SALERTA+2   GET LINK ADDR FOR ALERTA         08240000
         CNOP  0,4                                                      08260000
MSGLNK   BAL   14,0(0)                                                  08280000
         L     BASE,8(14)              REESTABLISH PROPER BASE          08300000
         B     PROC3                                                    08320000
         DC    A(BOUND)                                                 08340000
PROC3    EQU   *                                                        08360000
         L     R1,ADFIOCS                                               08380000
         BALR  R0,R1                                                    08400000
         DC    AL1(4)                                                   08420000
         DC    AL1(0)                                                   08440000
         L     WORK1,PSWSAVE+4         SUB 4 FROM PSW ADDR IN SAVED     08480000
         N     WORK1,ADRMSK               PIE TO GET ADDR OF INSTR      08500000
         SH    WORK1,HFOUR                WHICH CAUSED SPEC INTERRUPT   08520000
         B     SPECEND                 BRANCH TO FORCE ABEND            08540000
*                                                                       08560000
PROC4    MVC   RETURN,REGSAVE          SAVE RETURN ADDR TO SUPERVISOR   08580000
         B     PROC2                   HANDLE DATA EXCEPTION            08600000
         END                                                            08620000
