IHCFCDXI CSECT                                                          00020000
*                                      3/9/66                           00040000
         EXTRN IBCOM#                                                   00060000
         EXTRN IHCERRM                                                  00070016
           EXTRN CDMPY#                                                 00080000
           EXTRN CDDVD#                                                 00100000
           ENTRY FCDXI#                                                 00120000
* DBL PREC COMPLEX NUMBER BASE, FIXED POINT EXPONENT LIBRARY ROUTINE    00140000
       USING   *,15                                                     00160000
FCDXI# B       12(0,15)                                                 00180000
       DC      AL1(6)                                                   00200000
       DC      CL6'FCDXI#'                                              00220000
         STM   RTN,BASADD,12(SAVE)                                      00226016
         LR    ADDR,SAVE                                                00232016
         LA    SAVE,SAVREG              GET ADDR OF OWN SAVE            00238016
         ST    ADDR,4(SAVE)             STORE FORMER SAVE AREA ADDR     00244016
         ST    SAVE,8(ADDR)             STORE NEW SAVE ADDR IN FORMER   00250016
         BALR  BASADD,0                                                 00256016
         USING *,BASADD                                                 00262016
BEGIN    L     ADDR,0(PLIST)            LOAD PLIST OF COMPLEX NUM       00268016
           LD    REAL,0(0,ADDR)    LOAD REAL PART OF NO INTO REAL REG   00280000
           LD    IMAG,8(0,ADDR)    LOAD IMAG PART OF NO INTO IMAG REG   00300000
           L     ADDR,4(0,PLIST)   LOAD PLIST OF EXPONENT IN ADDR REG   00320000
           L     EXPN,0(0,ADDR)    LOAD EXPONENT INTO EXPN REG          00340000
           LTDR  REAL,REAL         CHECK IF REAL NO PLUS, MINUS,OR ZERO 00400000
           BC    6,TEST            IF REAL NO NOT ZERO, BRANCH TO TEST  00420000
           LTDR  IMAG,IMAG         CHECK IF IMAG NO PLUS, MINUS,OR ZERO 00440000
           BC    8,ERROR           IF IMAG NO IS ZERO, BRANCH TO ERROR  00460000
TEST       SR    EXPSW,EXPSW       SET NEGATIVE EXPN SWITCH REG TO ZERO 00480000
           LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 00500000
           BC    2,PLUS            IF EXPN IS POSITIVE, BRANCH TO PLUS  00520000
           BC    8,LOAD1           IF EXPONENT IS ZERO, BRANCH TO LOAD1 00540000
           LCR   EXPN,EXPN         EXPN MINUS, CONVERT TO 2S COMPLIMENT 00560000
           LA    EXPSW,1(EXPSW)    SET EXP SW REG TO ONE FOR MINUS EXPN 00580000
PLUS     MVC   FACTR(16),ONE                                            00640016
LOOP       STD   REAL,BASER        STORE REAL PART COMPLEX NO AT BASER  00700000
           STD   IMAG,BASEI        STORE IMAG PART COMPLEX NO AT BASEI  00720000
           SRDL  EXPN,1            SHIFT LOW BIT EXPN REG INTO ADDR REG 00740000
           LTR   ADDR,ADDR         TEST SIGN POS ADDR REG FOR MINUS BIT 00760000
           BC    10,JUMP           IF SIGN BIT NOT MINUS,BRANCH TO JUMP 00780000
           LA    PLIST,PARAM2      SET PARAM LIST REG FOR CDMPY ROUTINE 00800000
           L     LINK,ACDMPY       LOAD ADCON OF CDMPY RTN IN LINK REG  00820000
           BALR  RTN,LINK          BRANCH TO CDMPY RTN FOR COMPLEX MULT 00840000
           STD   REAL,FACTR        STORE REAL PART COMPLEX NO AT FACTR  00860000
           STD   IMAG,FACTI        STORE IMAG PART COMPLEX NO AT FACTI  00880000
JUMP       LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 00900000
           BC    8,NEXT            IF EXPONENT NOW ZERO, BRANCH TO NEXT 00920000
           LA    PLIST,PARAM3      SET PARAM LIST REG FOR CDMPY ROUTINE 00940000
           L     LINK,ACDMPY       LOAD ADCON OF CDMPY RTN IN LINK REG  00960000
           BALR  RTN,LINK          BRANCH TO CDMPY RTN FOR COMPLEX MULT 00980000
           BC    15,LOOP           BRANCH TO LOOP TO TEST NEXT EXPN BIT 01000000
NEXT       LTR   EXPSW,EXPSW       TEST IF EXPSW REG PLUS,MINUS,OR ZERO 01020000
         BC    8,EXIT              IF EXP NOT MINUS-TO EXIT             01040016
           LA    PLIST,PARAM1      SET PARAM LIST REG FOR CDDVD ROUTINE 01060000
           L     LINK,ACDDVD       LOAD ADCON OF CDDVD RTN IN LINK REG  01080000
           BALR  RTN,LINK          BRANCH TO CDDVD RTN FOR COMPLEX DVSN 01100000
           BC    15,EXIT           BRANCH TO EXIT(RESULT IN FP REG 0,2) 01140000
LOAD1      LD    REAL,ONE          LOAD ONE  AS REAL RESULT IN REAL REG 01160000
           LD    IMAG,ZERO         LOAD ZERO AS IMAG RESULT IN IMAG REG 01180000
EXIT     L     SAVE,4(SAVE)             RESTORE TO FORMER SAVE AREA     01190016
         LM    RTN,BASADD,12(SAVE)      RELOAD 14-5                     01200016
           MVI   12(SAVE),X'FF'    STORE ALL 1 BITS IN SAVE AREA WORD 4 01220000
           BCR   15,RTN            BRANCH TO ADDRESS IN RETURN REG RTN  01240000
ERROR      LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 01260000
           BC    2,EXIT            IF EXPN IS POSITIVE, BRANCH TO EXIT  01280000
         STD   REAL,BASER                                               01285016
         STD   IMAG,BASEI                                               01290016
         ST    EXPN,EXPON                                               01295016
         LM    RTN,LINK,AERRMON    14 HAS ADDR ERMON, 15 HAS ADDR IBCOM 01300016
         LA    2,EXPON                 ADDR OF EXPONENT                 01305016
         LA    3,MSGDATA                                                01310016
         EX    0,82(LINK)               FCVIO                           01315016
         BALR  0,1                                                      01320016
         DC    X'040B'                  LL=4 WW=11                      01325016
         LA    PLIST,ERRLIST                                            01330016
         LR    LINK,RTN            ADDR ERMON IN LINK FOR BALR          01335016
         BALR  RTN,LINK                                                 01340016
         CLI   RETCODE+3,X'00'    DID USER FIX DATA                     01345016
STNDFIX  BZ    EXIT                     RESULT ALREADY ZERO IN REGS     01350016
FIXUP    LA    PLIST,ERRLIST+12        ADDR OF REAL,IMAG,EXP            01355016
         B     BEGIN                                                    01360016
*                FLOATING POINT REGISTERS                               01380000
REAL       EQU   0                 REGISTER FOR REAL PART OF COMPLEX NO 01400000
IMAG       EQU   2                 REGISTER FOR IMAG PART OF COMPLEX NO 01420000
*                GENERAL PURPOSE REGISTERS                              01440000
SAVE       EQU   13                REGISTER CONTAINS SAVE REG AREA ADDR 01460000
RTN        EQU   14                REGISTER FOR RETURN TO PREVIOUS RTN  01480000
LINK       EQU   15                REGISTER FOR LINKAGE TO ANOTHER RTN  01500000
PLIST      EQU   1                 REGISTER USED FOR PARAMETER LIST REF 01520000
EXPN     EQU   2                                                        01540016
ADDR     EQU   3                                                        01560016
EXPSW    EQU   4                                                        01580016
BASADD   EQU   5                                                        01600016
*                ADCONS AND CONSTANTS AREA                              01620000
SAVREG   DS    18F                                                      01640016
BASER      DS    D                      USED TO HOLD REAL PART BASE NO  01660000
BASEI      DS    D                      USED TO HOLD IMAG PART BASE NO  01680000
FACTR      DC    X'4110000000000000'    USED IN FACTORING REAL BASE NO  01700000
FACTI      DC    X'0000000000000000'    USED IN FACTORING IMAG BASE NO  01720000
ONE        DC    X'4110000000000000'    CONSTANT ONE IN DOUBLE PREC F P 01740000
ZERO       DC    X'0000000000000000'    CONS OF ZERO IN DOUBLE PREC F P 01760000
PARAM1     DC    AL4(ONE)               ADCON OF 1ST PARAM IN CDDVD RTN 01780000
PARAM2     DC    AL4(FACTR)             ADCON OF 2ND PARAM IN CDDVD RTN 01800000
PARAM3     DC    AL4(BASER)             ADCON OF 1ST PARAM IN CDMPY RTN 01820000
           DC    AL4(BASER)             ADCON OF 2ND PARAM IN CDMPY RTN 01840000
ACDMPY     DC    AL4(CDMPY#)            ADCON OF CDMPY MATH LIBRARY RTN 01860000
ACDDVD     DC    AL4(CDDVD#)            ADCON OF CDDVD MATH LIBRARY RTN 01880000
AERRMON  DC    V(IHCERRM)                                               01890016
VIBCOM   DC    A(IBCOM#)                ADCON OF STANDARD ERROR ROUTINE 01900000
ERRLIST  DC    A(MSGLNG)                                                01901016
         DC    A(RETCODE)                                               01902016
         DC    A(ERRNUM)                                                01903016
         DC    A(BASER)                                                 01904016
         DC    X'80'                                                    01905016
         DC    AL3(EXPON)                                               01906016
EXPON    DS    F                                                        01907016
RETCODE  DS    F                                                        01908016
ERRNUM   DC    F'247'                                                   01909016
MSGLNG   DC    A(ENDMSG-MSG)                                            01910016
MSG      DC    C'IHC247I FCDXI COMPLEX*16 BASE=0.0+0.0I, INTEGER EXPONEX01911016
               NT='                                                     01912016
MSGDATA  DS    11C                                                      01913016
         DC    C', LE 0'                                                01914016
ENDMSG   EQU   *                                                        01915016
           END                                                          01920000
