IHCFCXPI CSECT                                                          00020000
*                                      2/23/66                          00040000
         EXTRN IBCOM#                                                   00060000
         EXTRN IHCERRM                                                  00070016
           EXTRN CMPY#                                                  00080000
           EXTRN CDVD#                                                  00100000
           ENTRY FCXPI#                                                 00120000
* SGL PREC COMPLEX NUMBER BASE, FIXED POINT EXPONENT LIBRARY ROUTINE    00140000
       USING   *,15                                                     00160000
FCXPI# B       12(0,15)                                                 00180000
       DC      AL1(6)                                                   00200000
       DC      CL6'FCXPI#'                                              00220000
         STM   RTN,BASADD,12(SAVE)                                      00224016
         BALR  BASADD,0                                                 00228016
         USING *,BASADD                                                 00232016
         LR    ADDR,SAVE                                                00236016
         LA    SAVE,SAVREG                                              00240016
         ST    ADDR,4(SAVE)                                             00244016
         ST    SAVE,8(ADDR)                                             00248016
BEGIN    EQU   *                                                        00252016
           L     ADDR,0(0,PLIST)   LOAD PLIST OF COMPLEX NO IN ADDR REG 00260000
           LE    REAL,0(0,ADDR)    LOAD REAL PART OF NO INTO REAL REG   00280000
           LE    IMAG,4(0,ADDR)    LOAD IMAG PART OF NO INTO IMAG REG   00300000
           L     ADDR,4(0,PLIST)   LOAD PLIST OF EXPONENT IN ADDR REG   00320000
           L     EXPN,0(0,ADDR)    LOAD EXPONENT INTO EXPN REG          00340000
           LTER  REAL,REAL         CHECK IF REAL NO PLUS, MINUS,OR ZERO 00400000
           BC    6,TEST            IF REAL NO NOT ZERO, BRANCH TO TEST  00420000
           LTER  IMAG,IMAG         CHECK IF IMAG NO PLUS, MINUS,OR ZERO 00440000
           BC    8,ERROR           IF IMAG NO IS ZERO, BRANCH TO ERROR  00460000
TEST       SR    EXPSW,EXPSW       SET NEGATIVE EXPN SWITCH REG TO ZERO 00480000
           LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 00500000
           BC    2,PLUS            IF EXPN IS POSITIVE, BRANCH TO PLUS  00520000
           BC    8,LOAD1           IF EXPONENT IS ZERO, BRANCH TO LOAD1 00540000
           LCR   EXPN,EXPN         EXPN MINUS, CONVERT TO 2S COMPLIMENT 00560000
           LA    EXPSW,1(EXPSW)    SET EXP SW REG TO ONE FOR MINUS EXPN 00580000
PLUS     MVC   FACTR(8),ONE                                             00640016
LOOP       STE   REAL,BASER        STORE REAL PART COMPLEX NO AT BASER  00700000
           STE   IMAG,BASEI        STORE IMAG PART COMPLEX NO AT BASEI  00720000
           SRDL  EXPN,1            SHIFT LOW BIT EXPN REG INTO ADDR REG 00740000
           LTR   ADDR,ADDR         TEST SIGN POS ADDR REG FOR MINUS BIT 00760000
           BC    10,JUMP           IF SIGN BIT NOT MINUS,BRANCH TO JUMP 00780000
           LA    PLIST,PARAM2      SET PARAM LIST REG FOR CMPY ROUTINE  00800000
           L     LINK,ACMPY        LOAD ADCON OF CMPY RTN IN LINK REG   00820000
           BALR  RTN,LINK          BRANCH TO  CMPY RTN FOR COMPLEX MULT 00840000
           STE   REAL,FACTR        STORE REAL PART COMPLEX NO AT FACTR  00860000
           STE   IMAG,FACTI        STORE IMAG PART COMPLEX NO AT FACTI  00880000
JUMP       LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 00900000
           BC    8,NEXT            IF EXPONENT NOW ZERO, BRANCH TO NEXT 00920000
           LA    PLIST,PARAM3      SET PARAM LIST REG FOR CMPY ROUTINE  00940000
           L     LINK,ACMPY        LOAD ADCON OF CMPY RTN IN LINK REG   00960000
           BALR  RTN,LINK          BRANCH TO  CMPY RTN FOR COMPLEX MULT 00980000
           BC    15,LOOP           BRANCH TO LOOP TO TEST NEXT EXPN BIT 01000000
NEXT       LTR   EXPSW,EXPSW       TEST IF EXPSW REG PLUS,MINUS,OR ZERO 01020000
         BC    8,EXIT              IF EXP NOT MINUS-TO EXIT             01040016
           LA    PLIST,PARAM1      SET PARAM LIST REG FOR CDVD ROUTINE  01060000
           L     LINK,ACDVD        LOAD ADCON OF CDVD RTN IN LINK REG   01080000
           BALR  RTN,LINK          BRANCH TO  CDVD RTN FOR COMPLEX DVSN 01100000
           BC    15,EXIT           BRANCH TO EXIT(RESULT IN FP REG 0,2) 01140000
LOAD1      LE    REAL,ONE          LOAD ONE  AS REAL RESULT IN REAL REG 01160000
           LE    IMAG,ZERO         LOAD ZERO AS IMAG RESULT IN IMAG REG 01180000
EXIT     L     SAVE,4(SAVE)                                             01190016
         LM    RTN,BASADD,12(SAVE)                                      01200016
           MVI   12(SAVE),X'FF'    STORE ALL 1 BITS IN SAVE AREA WORD 4 01220000
           BCR   15,RTN            BRANCH TO ADDRESS IN RETURN REG RTN  01240000
ERROR      LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 01260000
           BC    2,EXIT            IF EXPN IS POSITIVE, BRANCH TO EXIT  01280000
         STE   REAL,BASER               STORE  FOR  USER  TO  FIX  UP   01285016
         STE   IMAG,BASEI                                               01290016
         ST    EXPN,EXPON                                               01295016
         LA    2,EXPON                                                  01300016
         LA    3,MSGDATA                                                01305016
         LM    RTN,LINK,AERRMON    ADDR ERMON IN 14, ADDR IBCOM IN 15   01310016
         EX    0,82(LINK)               ADDR OF I CONVERSION            01315016
         BALR  0,1                                                      01320016
         DC    X'040B'                  LL=4 WW=11                      01325016
         LA    PLIST,ERRLIST                                            01330016
         LR    LINK,RTN            ADDR OF ERRMON IN 15 FOR BALR        01335016
         BALR  14,15                    TO ERROR MONITOR                01340016
         CLI   RETCODE+3,X'00'    DID USER FIX DATA                     01345016
         BZ    EXIT                    RESULT IN REG ALREADY ZERO       01350016
FIXUP    LA    PLIST,ERRLIST+12        POINT TO ADCONS OF DATA          01355016
         B     BEGIN                                                    01360016
         EJECT                                                          01365016
*                FLOATING POINT REGISTERS                               01380000
REAL       EQU   0                 REGISTER FOR REAL PART OF COMPLEX NO 01400000
IMAG       EQU   2                 REGISTER FOR IMAG PART OF COMPLEX NO 01420000
*                GENERAL PURPOSE REGISTERS                              01440000
SAVE       EQU   13                REGISTER CONTAINS SAVE REG AREA ADDR 01460000
RTN        EQU   14                REGISTER FOR RETURN TO PREVIOUS RTN  01480000
LINK       EQU   15                REGISTER FOR LINKAGE TO ANOTHER RTN  01500000
PLIST      EQU   1                 REGISTER USED FOR PARAMETER LIST REF 01520000
EXPN     EQU   2                   EXP FOR COMPUTATION                  01540016
ADDR     EQU   3                   INDEX PARAM                          01560016
EXPSW    EQU   4                   TEST FOR MINUS EXPN                  01580016
BASADD   EQU   5                                                        01600016
*                ADCONS AND CONSTANTS AREA                              01620000
SAVREG   DS    18F                                                      01640016
BASER      DS    F                      USED TO HOLD REAL PART BASE NO  01660000
BASEI      DS    F                      USED TO HOLD IMAG PART BASE NO  01680000
FACTR      DC    X'41100000'            USED IN FACTORING REAL BASE NO  01700000
FACTI      DC    X'00000000'            USED IN FACTORING IMAG BASE NO  01720000
ONE        DC    X'41100000'            CONSTANT ONE IN SINGLE PREC F P 01740000
ZERO       DC    X'00000000'            CONS OF ZERO IN SINGLE PREC F P 01760000
PARAM1     DC    AL4(ONE)               ADCON OF 1ST PARAM IN CDVD RTN  01780000
PARAM2     DC    AL4(FACTR)             ADCON OF 2ND PARAM IN CDVD RTN  01800000
PARAM3     DC    AL4(BASER)             ADCON OF 1ST PARAM IN CMPY RTN  01820000
           DC    AL4(BASER)             ADCON OF 2ND PARAM IN CMPY RTN  01840000
ACMPY      DC    AL4(CMPY#)             ADCON OF CMPY MATH LIBRARY RTN  01860000
ACDVD      DC    AL4(CDVD#)             ADCON OF CDVD MATH LIBRARY RTN  01880000
AERRMON  DC    V(IHCERRM)                                               01890016
VIBCOM   DC    A(IBCOM#)                ADCON OF STANDARD ERROR ROUTINE 01900000
EXPON    DS    F                                                        01901016
ERRLIST  DC    A(MSGLNG)                                                01902016
         DC    A(RETCODE)                                               01903016
         DC    A(ERRNUM)                                                01904016
         DC    A(BASER)                 USER INFORMATION IS REAL BASE,  01905016
         DC    X'80'                   IMAG BASE, AND EXPONENT          01906016
         DC    AL3(EXPON)                                               01907016
ERRNUM   DC    F'246'                                                   01908016
RETCODE  DS    F                                                        01909016
         EJECT                                                          01910016
MSGLNG   DC    A(ENDMSG-MSG)                                            01911016
MSG      DC    C'IHC246I FCXPI COMPLEX*8 BASE=0.0+0.0I, INTEGER EXPONENX01912016
               T='                                                      01913016
MSGDATA  DS    11C                                                      01914016
         DC    C', LE 0'                                                01915016
ENDMSG   EQU   *                                                        01916016
           END                                                          01920000
