IHCFDXPD CSECT                                                          00020000
         EXTRN IBCOM#                                                   00040000
         EXTRN IHCERRM                                                  00050016
           EXTRN DLOG                                                   00060000
           EXTRN DEXP                                                   00080000
           ENTRY FDXPD#                                                 00100000
* DBL PREC FLOATING POINT BASE, FLOATING POINT EXPONENT LIBRARY ROUTINE 00120000
         USING     *,15                                                 00140000
FDXPD#   B         12(0,15)                                             00160000
         DC        AL1(6)                                               00180000
         DC        CL6'FDXPD#'                                          00200000
         STM       14,ADDR,12(13)                                       00220000
         BALR  BASADD,0                                                 00222016
         USING *,BASADD                                                 00224016
         LR    ADDR,SAVE                                                00226016
         LA    SAVE,SAVREG                                              00228016
         ST    ADDR,4(SAVE)                                             00230016
         ST    SAVE,8(ADDR)                                             00232016
BEGIN    EQU   *                                                        00234016
           L     ADDR,0(0,PLIST)   LOAD PLIST OF BASE NO IN ADDR REG    00240000
           LD    BASE,0(0,ADDR)    LOAD BASE NO INTO BASE NO REG        00260000
           L     ADDR,4(0,PLIST)   LOAD PLIST OF EXPONENT IN ADDR REG   00280000
           LD    EXPN,0(0,ADDR)    LOAD EXPONENT INTO EXPN REG          00300000
           LTDR  BASE,BASE         CHECK IF BASE NO PLUS, MINUS,OR ZERO 00360000
           BC    8,ERROR           IF BASE NO IS ZERO, BRANCH TO ERROR  00380000
           LTDR  EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 00400000
           BC    8,LOAD1           IF EXPONENT IS ZERO, BRANCH TO LOAD1 00420000
           STD   EXPN,PARAM        STORE EXPONENT FOR LATER USE IN RTN  00520000
           L     LINK,ACDLOG       LOAD ADCON OF DLOG RTN IN LINK REG   00540000
           BALR  RTN,LINK          BRANCH TO DLOG RTN FOR LOG OF BASE   00560000
           LD    EXPN,PARAM        RELOAD EXPN REG WITH EXPONENT        00580000
           MDR   BASE,EXPN         MULTIPLY LOG OF BASE NO BY EXPONENT  00600000
           STD   BASE,PARAM        STORE RESULT AS EXP RTN PARAMETER    00620000
           LA    PLIST,ADCPAR      MOD PLIST TO POINT TO EXP RTN PARAM  00640000
           L     LINK,ACDEXP       LOAD ADCON OF DEXP RTN IN LINK REG   00660000
           BALR  RTN,LINK          BRANCH TO DEXP RTN TO COMPUTE RESULT 00680000
           BC    15,EXIT           BRANCH TO EXIT (RESULT IN BASE REG)  00720000
LOAD1      LD    BASE,ONE          LOAD PLUS 1 AS RESULT IN BASE NO REG 00740000
EXIT     L     13,4(13)                                                 00750016
         LM    14,ADDR,12(13)                                           00760016
           MVI   12(SAVE),X'FF'    STORE ALL 1 BITS IN SAVE AREA WORD 4 00780000
           BCR   15,RTN            BRANCH TO ADDRESS IN RETURN REG RTN  00800000
ERROR      LTDR  EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 00820000
           BC    2,EXIT            IF EXPN IS POSITIVE, BRANCH TO EXIT  00840000
         STD   BASE,DATA                                                00845016
         STD   EXPN,DATA1                                               00850016
         LA    3,MSGDATA                                                00855016
         L     15,VIBCOM                                                00860016
         LR    14,2                SAVE ADDRESSABILITY                  00865016
         LA    2,DATA1                                                  00870016
         EX    0,90(LINK)                                               00875016
         BALR  0,1                                                      00880016
         DC    X'08171000'              LL=8 WW=23 DD=16 SS=0           00885016
         LR    2,14                RESTORE ADDRESSABILITY               00890016
         LA    PLIST,ERRLIST                                            00895016
         L     LINK,AERRMON                                             00900016
         BALR  14,15                                                    00905016
         CLI   RETCODE+3,X'00'    DID USER FIX DATA                     00910016
         BZ    EXIT                    RESULT IN REG ALREADY ZERO       00915016
FIXUP    LA    PLIST,ERRLIST+12        POINT TO ADCONS OF DATA          00920016
         B     BEGIN                                                    00925016
*                FLOATING POINT REGISTERS                               00940000
BASE       EQU   0                 REGISTER FOR BASE NO, PASSING RESULT 00960000
EXPN       EQU   2                 REGISTER FOR EXPONENT IN COMPUTATION 00980000
*                GENERAL PURPOSE REGISTERS                              01000000
SAVE       EQU   13                REGISTER CONTAINS SAVE REG AREA ADDR 01020000
RTN        EQU   14                REGISTER FOR RETURN TO PREVIOUS RTN  01040000
LINK       EQU   15                REGISTER FOR LINKAGE TO ANOTHER RTN  01060000
PLIST      EQU   1                 REGISTER USED FOR PARAMETER LIST REF 01080000
BASADD     EQU   2                 REGISTER USED FOR SECOND BASE ADDR   01100000
ADDR       EQU   3                 REGISTER FOR INDEXING PARAMETER ADDR 01120000
*                CONSTANTS AND ADCON AREAS                              01140000
PARAM      DS    D                      PARAM FOR DATA IN DEXP MATH RTN 01180000
DATA     DS    D                                                        01186016
DATA1    DS    D                        EXPONENT                        01192016
ONE        DC    X'4110000000000000'    CONSTANT ONE IN DOUBLE PREC F P 01200000
ADCPAR     DC    AL4(PARAM)             ADCON OF PARAMETER FOR EXP RTN  01220000
ACDLOG     DC    AL4(DLOG)              ADCON OF DLOG MATH LIBRARY RTN  01240000
ACDEXP     DC    AL4(DEXP)              ADCON OF DEXP MATH LIBRARY RTN  01260000
VIBCOM   DC    A(IBCOM#)                                                01280000
SAVREG   DS    18F                                                      01281016
AERRMON  DC    V(IHCERRM)                                               01282016
ERRNUM   DC    F'245'                                                   01283016
ERRLIST  DC    A(MSGLNG)                                                01284016
         DC    A(RETCODE)                                               01285016
         DC    A(ERRNUM)                                                01286016
         DC    A(DATA)                                                  01287016
         DC    X'80'                    LAST LIST ITEM                  01288016
         DC    AL3(DATA1)                                               01289016
RETCODE  DS    F                                                        01290016
         EJECT                                                          01291016
MSGLNG   DC    A(ENDMSG-MSG)                                            01292016
MSG      DC    C'IHC245I FDXPD REAL*8 BASE=0.0, REAL*8 EXPONENT='       01293016
MSGDATA  DS    23C                                                      01294016
         DC    C', LE 0'                                                01295016
ENDMSG   EQU   *                                                        01296016
           END                                                          01300000
