IHCFIXPI CSECT                                                          00020000
         EXTRN IBCOM#                                                   00040000
         EXTRN IHCERRM                                                  00050016
           ENTRY FIXPI#                                                 00060000
*          FIXED POINT BASE, FIXED POINT EXPONENT LIBRARY ROUTINE       00080000
         USING     *,15                                                 00100000
FIXPI#   B         12(0,15)                                             00120000
         DC        AL1(6)                                               00140000
         DC        CL6'FIXPI#'                                          00160000
         STM       14,ADDR,12(13)                                       00180000
           L     ADDR,0(0,PLIST)   LOAD PLIST OF BASE NO IN ADDR REG    00200000
           L     BASE,0(0,ADDR)    LOAD BASE NO INTO BASE NO REG        00220000
           L     ADDR,4(0,PLIST)   LOAD PLIST OF EXPONENT IN ADDR REG   00240000
           L     EXPN,0(0,ADDR)    LOAD EXPONENT INTO EXPN REG          00260000
BEGIN    LR    RESULT,BASE                                              00280016
           LTR   BASE,BASE         CHECK IF BASE NO PLUS, MINUS,OR ZERO 00300000
           BC    8,ERROR           IF BASE NO IS ZERO, BRANCH TO ERROR  00320000
           LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 00340000
           BC    8,LOAD1           IF EXPONENT IS ZERO, BRANCH TO LOAD1 00360000
           BCTR  BASE,0            DECREMENT BY ONE VALUE OF BASE NO    00380000
           LTR   BASE,BASE         CHECK IF BASE NO PLUS, MINUS,OR ZERO 00400000
           BC    8,EXIT            IF BASE NO NOW ZERO, BRANCH TO EXIT  00420000
           LA    BASE,2(BASE)      INCREMENT BY TWO VALUE OF BASE NO    00440000
           LTR   BASE,BASE         CHECK IF BASE NO PLUS, MINUS,OR ZERO 00460000
           BC    8,TEST            IF BASE NO NOW ZERO, BRANCH TO TEST  00480000
           LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 00500000
           BC    2,PLUS            IF EXPN IS POSITIVE, BRANCH TO PLUS  00520000
           SR    RESULT,RESULT     EXPN MINUS,MAKE VALUE OF RESULT ZERO 00540000
           BC    15,EXIT           BRANCH TO EXIT TO LEAVE THIS ROUTINE 00560000
PLUS       LR    BASE,RESULT       RELOAD ORG BASE NO FROM RESULT REG   00580000
           L     FACTOR,ONE        LOAD FACTOR OF ONE IN FACTOR REG     00600000
LOOP       SRDL  EXPN,1            SHIFT LOW BIT EXPN REG INTO ADDR REG 00620000
           LTR   ADDR,ADDR         TEST SIGN POS ADDR REG FOR MINUS BIT 00640000
           BC    10,JUMP           IF SIGN BIT NOT MINUS,BRANCH TO JUMP 00660000
           MR    FACT,BASE         MULTIPLY FACTOR REGS BY BASE NO REGS 00680000
JUMP       LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 00700000
           BC    8,NEXT            IF EXPONENT NOW ZERO, BRANCH TO NEXT 00720000
           MR    BASE1,BASE        MULTIPLY BASE NO BY DOUBLING ITSELF  00740000
           BC    15,LOOP           BRANCH TO LOOP TO TEST NEXT EXPN BIT 00760000
NEXT       LR    RESULT,FACTOR     LOAD FACTOR (ANSWER) INTO RESULT REG 00780000
           BC    15,EXIT           BRANCH TO EXIT TO LEAVE THIS ROUTINE 00800000
TEST       SRDL  EXPN,1            SHIFT LOW BIT EXPN REG INTO ADDR REG 00820000
           LTR   ADDR,ADDR         TEST SIGN POS ADDR REG FOR MINUS BIT 00840000
           BC    4,EXIT            IF SIGN MINUS (EXPN ODD), GO TO EXIT 00860000
LOAD1      L     RESULT,ONE        LOAD RESULT REG WITH VALUE OF PLUS 1 00880000
EXIT       LM    RTN,LINK,12(SAVE) RELOAD FORMER VALUES OF GP REG 14-15 00900000
           LM   FACT,ADDR,28(SAVE) RELOAD FORMER VALUES OF GP REG 2-7   00920000
           MVI   12(SAVE),X'FF'    STORE ALL 1 BITS IN SAVE AREA WORD 4 00940000
           BCR   15,RTN            BRANCH TO ADDRESS IN RETURN REG RTN  00960000
ERROR      LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 00980000
           BC    2,EXIT            IF EXPN IS POSITIVE, BRANCH TO EXIT  01000000
         STM   BASE,EXPN,DATA           DATA IN ERROR                   01003016
         LA    2,DATA1                                                  01006016
         LA    3,MSGDATA                AREA IN MSG FOR DATA            01009016
         LR    ADDR,SAVE                SAVE ADDR OF CALLER'S SAVEAREA  01012016
         LR    4,15               SAVE ADDRESSABILITY                   01015016
         LM    14,15,AERRMON                                            01018016
         LA    SAVE,OFFSET(15)         ADDR OF SAVE AREA IN IBCOM       01021016
         ST    ADDR,4(SAVE)             CALLER SAVE AREA IN IBCOM SAVE  01024016
         ST    SAVE,8(ADDR)             STORE MY SAVEADDR IN CALLERAREA 01027016
         EX    0,82(15)                FCVIO                            01030016
         BALR  0,1                                                      01033016
         DC    X'040B'                  LL=4 WW=11                      01036016
*                                                                       01039016
* ADDRESSABILITY IN REG  4 WHEN BRANCHING TO ERMON                      01042016
*                                                                       01045016
         USING FIXPI#,4                                                 01048016
 DROP 15                                                                01051016
         LA    PLIST,ERRLIST                                            01054016
         LR    LINK,RTN           ADDR OF ERMON                         01057016
         BALR  14,15                                                    01060016
         LR    15,4                     RESTORE ADDRESSABILITY          01063016
         USING FIXPI#,15                                                01066016
 DROP 4                                                                 01069016
         L     13,4(13)                 RESTORE 13 TO CALLER AREA       01072016
         L     RESULT,RETCODE                                           01075016
         LTR   RESULT,RESULT            DID USER FIX DATA               01078016
         BZ    EXIT                    RESULT IN REG ALREADY ZERO       01081016
FIXUP    LM    BASE,EXPN,DATA                                           01084016
         B     BEGIN                                                    01087016
*                GENERAL PURPOSE REGISTERS                              01100000
SAVE       EQU   13                REGISTER CONTAINS SAVE REG AREA ADDR 01120000
RTN        EQU   14                REGISTER FOR RETURN TO PREVIOUS RTN  01140000
LINK       EQU   15                REGISTER FOR LINKAGE TO ANOTHER RTN  01160000
RESULT     EQU   0                 REGISTER FOR PASSING ON FINAL RESULT 01180000
PLIST      EQU   1                 REGISTER USED FOR PARAMETER LIST REF 01200000
FACT       EQU   2                 REGISTER USED AS MPY REG FOR FACTOR  01220000
FACTOR     EQU   3                 REGISTER USED FOR FACTOR AND ANSWER  01240000
BASE1      EQU   4                 REGISTER USED AS MPY REG FOR BASE NO 01260000
BASE       EQU   5                 REGISTER FOR BASE NO IN COMPUTATION  01280000
EXPN       EQU   6                 REGISTER FOR EXPONENT IN COMPUTATION 01300000
ADDR       EQU   7                 REGISTER FOR INDEXING PARAMETER ADDR 01320000
*                ADCONS AND CONSTANTS AREA                              01340000
ONE        DC    F'1'              INTERGER CONSTANT OF ONE             01360000
OFFSET   EQU   X'C4'                                                    01366016
AERRMON  DC    V(IHCERRM)                                               01372016
VIBCOM   DC    A(IBCOM#)                                                01380000
ERRLIST  DC    A(MSGLNG)                                                01381016
         DC    A(RETCODE)                                               01382016
         DC    A(ERRNUM)                                                01383016
         DC    A(DATA)                                                  01384016
         DC    X'80'                                                    01385016
         DC    AL3(DATA1)                                               01386016
DATA     DS    F                                                        01387016
DATA1    DS    F                                                        01388016
ERRNUM   DC    F'241'                                                   01389016
RETCODE  DS    F'0'                                                     01390016
         EJECT                                                          01391016
MSGLNG   DC    A(ENDMSG-MSG)                                            01392016
MSG      DC    C'IHC241I FIXPI INTEGER BASE=0,INTEGER EXPONENT='        01393016
MSGDATA  DS    11C                                                      01394016
         DC    C', LE 0'                                                01395016
ENDMSG   EQU   *                                                        01396016
           END                                                          01400000
