IHCFRXPI CSECT                                                          00020000
         EXTRN IBCOM#                                                   00040000
         EXTRN IHCERRM                                                  00050016
           ENTRY FRXPI#                                                 00060000
* SGL PREC FLOATING POINT BASE, FIXED POINT EXPONENT LIBRARY ROUTINE    00080000
         USING     *,15                                                 00100000
FRXPI#   B         12(0,15)                                             00120000
         DC        AL1(6)                                               00140000
         DC        CL6'FRXPI#'                                          00160000
         STM       14,ADDR,12(13)                                       00180000
BEGIN    EQU   *                                                        00190016
           L     ADDR,0(0,PLIST)   LOAD PLIST OF BASE NO IN ADDR REG    00200000
           LE    BASE,0(0,ADDR)    LOAD BASE NO INTO BASE NO REG        00220000
           L     ADDR,4(0,PLIST)   LOAD PLIST OF EXPONENT IN ADDR REG   00240000
           L     EXPN,0(0,ADDR)    LOAD EXPONENT INTO EXPN REG          00260000
           LTER  BASE,BASE         CHECK IF BASE NO PLUS, MINUS,OR ZERO 00280000
           BC    8,ERROR           IF BASE NO IS ZERO, BRANCH TO ERROR  00300000
           SR    EXPSW,EXPSW       SET NEGATIVE EXPN SWITCH REG TO ZERO 00320000
           LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 00340000
           BC    2,PLUS            IF EXPN IS POSITIVE, BRANCH TO PLUS  00360000
           BC    8,LOAD1           IF EXPONENT IS ZERO, BRANCH TO LOAD1 00380000
           LCR   EXPN,EXPN         EXPN MINUS, CONVERT TO 2S COMPLIMENT 00400000
           LA    EXPSW,1(EXPSW)    SET EXP SW REG TO ONE FOR MINUS EXPN 00420000
PLUS       LE    FACTOR,ONE        LOAD FACTOR OF ONE IN FACTOR REG     00440000
LOOP       SRDL  EXPN,1            SHIFT LOW BIT EXPN REG INTO ADDR REG 00460000
           LTR   ADDR,ADDR         TEST SIGN POS ADDR REG FOR MINUS BIT 00480000
           BC    10,JUMP           IF SIGN BIT NOT MINUS,BRANCH TO JUMP 00500000
           MER   FACTOR,BASE       MULTIPLY FACTOR REG BY BASE NO REG   00520000
JUMP       LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 00540000
           BC    8,NEXT            IF EXPONENT NOW ZERO, BRANCH TO NEXT 00560000
           MER   BASE,BASE         MULTIPLY BASE NO BY DOUBLING ITSELF  00580000
           BC    15,LOOP           BRANCH TO LOOP TO TEST NEXT EXPN BIT 00600000
NEXT       LTR   EXPSW,EXPSW       TEST IF EXPSW REG PLUS,MINUS,OR ZERO 00620000
           BC    8,SWAP            IF EXPN IS NOT MINUS, BRANCH TO SWAP 00640000
           LE    BASE,ONE          LOAD ONE IN BASE NO REG AS DIVIDEND  00660000
           DER   BASE,FACTOR       DIV BASE REG BY FACTOR REG (RESULT)  00680000
           BC    15,EXIT           BRANCH TO EXIT (RESULT IN BASE REG)  00700000
SWAP       LER   BASE,FACTOR       LOAD FACTOR REG INTO BASE NO REG     00720000
           BC    15,EXIT           BRANCH TO EXIT (RESULT IN BASE REG)  00740000
LOAD1      LE    BASE,ONE          LOAD PLUS 1 AS RESULT IN BASE NO REG 00760000
EXIT       LM    RTN,ADDR,12(SAVE) RELOAD FORMER VALUES OF GP REG 14-3  00780000
           MVI   12(SAVE),X'FF'    STORE ALL 1 BITS IN SAVE AREA WORD 4 00800000
           BCR   15,RTN            BRANCH TO ADDRESS IN RETURN REG RTN  00820000
ERROR      LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 00840000
           BC    2,EXIT            IF EXPN IS POSITIVE, BRANCH TO EXIT  00860000
         STE   BASE,DATA                                                00863016
         ST    EXPN,DATA1                                               00866016
         LA    2,DATA1                                                  00869016
         LA    3,MSGDATA                AREA IN MSG FOR DATA            00872016
         LR    14,15                    SAVE ADDRESSABILITY             00875016
         LR    PLIST,SAVE               SAVE CALLER'S SAVE AREA ADDR    00878016
         L     15,VIBCOM                                                00881016
         LA    SAVE,OFFSET(15)          SAVE AREA IN IBCOM              00884016
         ST    PLIST,4(SAVE)            STORE CALLER ADDR IN NEW SAVE   00887016
         ST    SAVE,8(PLIST)            STORE NEW SAVE IN CALLER'S AREA 00890016
         EX    0,82(15)                 FCVIO                           00893016
         BALR  0,1                                                      00896016
         DC    X'040B'                  LL=4 WW=11                      00899016
         DROP  15                                                       00902016
         USING FRXPI#,14                                                00905016
         LA    PLIST,ERRLIST                                            00908016
         L     LINK,AERRMON                                             00911016
         LR    0,14                     SAVE ADDRESSABILITY             00914016
         BALR  14,15                                                    00917016
         LR    15,0                     RESTORE ADDRESSABILITY          00920016
         DROP  14                                                       00923016
         USING FRXPI#,15                                                00926016
         L     13,4(13)                 RESTORE 13 TO CALLER AREA       00929016
         CLI   RETCODE+3,X'00'    DID USER FIX DATA                     00932016
         BZ    EXIT                    RESULT IN REG ALREADY ZERO       00935016
FIXUP    LA    PLIST,ERRLIST+12        POINT TO ADCONS OF DATA          00938016
         B     BEGIN                                                    00941016
*                FLOATING POINT REGISTERS                               00960000
BASE       EQU   0                 REGISTER FOR BASE NO, PASSING RESULT 00980000
FACTOR     EQU   2                 REGISTER FOR FACTOR,COMPUTING RESULT 01000000
*                GENERAL PURPOSE REGISTERS                              01020000
SAVE       EQU   13                REGISTER CONTAINS SAVE REG AREA ADDR 01040000
RTN        EQU   14                REGISTER FOR RETURN TO PREVIOUS RTN  01060000
LINK       EQU   15                REGISTER FOR LINKAGE TO ANOTHER RTN  01080000
EXPSW      EQU   0                 REGISTER FOR TESTING FOR MINUS EXPN  01100000
PLIST      EQU   1                 REGISTER USED FOR PARAMETER LIST REF 01120000
EXPN       EQU   2                 REGISTER FOR EXPONENT IN COMPUTATION 01140000
ADDR       EQU   3                 REGISTER FOR INDEXING PARAMETER ADDR 01160000
*                ADCONS AND CONSTANTS AREA                              01180000
OFFSET   EQU   X'C4'                                                    01190016
           DS    0F                    FORCE TO NEXT FULL WORD BOUNDARY 01200000
ONE        DC    X'41100000'            CONSTANT ONE IN SINGLE PREC F P 01220000
VIBCOM   DC    A(IBCOM#)                                                01240000
AERRMON  DC    V(IHCERRM)                                               01241016
ERRLIST  DC    A(MSGLNG)                                                01242016
         DC    A(RETCODE)                                               01243016
         DC    A(ERRNUM)                                                01244016
         DC    A(DATA)                                                  01245016
         DC    X'80'                                                    01246016
         DC    AL3(DATA1)                                               01247016
DATA     DS    F                                                        01248016
DATA1    DS    F                                                        01249016
ERRNUM   DC    F'242'                                                   01250016
RETCODE  DS    F'0'                                                     01251016
         EJECT                                                          01252016
MSGLNG   DC    A(ENDMSG-MSG)                                            01253016
MSG      DC    C'IHC242I FRXPI REAL*4 BASE=0.0, INTEGER EXPONENT='      01254016
MSGDATA  DS    11C                                                      01255016
         DC    C', LE 0'                                                01256016
ENDMSG   EQU   *                                                        01257016
           END                                                          01260000
