IHCFRXPR CSECT                                                          00020000
         EXTRN IBCOM#                                                   00040000
         EXTRN IHCERRM                                                  00050016
           EXTRN ALOG                                                   00060000
           EXTRN EXP                                                    00080000
           ENTRY FRXPR#                                                 00100000
* SGL PREC FLOATING POINT BASE, FLOATING POINT EXPONENT LIBRARY ROUTINE 00120000
         USING     *,15                                                 00140000
FRXPR#   B         12(0,15)                                             00160000
         DC        AL1(6)                                               00180000
         DC        CL6'FRXPR#'                                          00200000
         STM       14,ADDR,12(13)                                       00220000
         BALR  BASADD,0                                                 00222016
         USING *,BASADD                                                 00224016
         LR    ADDR,SAVE                                                00226016
         LA    SAVE,SAVREG                                              00228016
         ST    ADDR,4(SAVE)                                             00230016
         ST    SAVE,8(ADDR)                                             00232016
BEGIN    EQU   *                                                        00234016
           L     ADDR,0(0,PLIST)   LOAD PLIST OF BASE NO IN ADDR REG    00240000
           LE    BASE,0(0,ADDR)    LOAD BASE NO INTO BASE NO REG        00260000
           L     ADDR,4(0,PLIST)   LOAD PLIST OF EXPONENT IN ADDR REG   00280000
           LE    EXPN,0(0,ADDR)    LOAD EXPONENT INTO EXPN REG          00300000
           LTER  BASE,BASE         CHECK IF BASE NO PLUS, MINUS,OR ZERO 00360000
           BC    8,ERROR           IF BASE NO IS ZERO, BRANCH TO ERROR  00380000
           LTER  EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 00400000
           BC    8,LOAD1           IF EXPONENT IS ZERO, BRANCH TO LOAD1 00420000
           STE   EXPN,PARAM        STORE EXPONENT FOR LATER USE IN RTN  00520000
           L     LINK,ADCLOG       LOAD ADCON OF ALOG RTN IN LINK REG   00540000
           BALR  RTN,LINK          BRANCH TO ALOG RTN FOR LOG OF BASE   00560000
           LE    EXPN,PARAM        RELOAD EXPN REG WITH EXPONENT        00580000
           MER   BASE,EXPN         MULTIPLY LOG OF BASE NO BY EXPONENT  00600000
           STE   BASE,PARAM        STORE RESULT AS EXP RTN PARAMETER    00620000
           LA    PLIST,ADCPAR      MOD PLIST TO POINT TO EXP RTN PARAM  00640000
           L     LINK,ADCEXP       LOAD ADCON OF  EXP RTN IN LINK REG   00660000
           BALR  RTN,LINK          BRANCH TO  EXP RTN TO COMPUTE RESULT 00680000
           BC    15,EXIT           BRANCH TO EXIT (RESULT IN BASE REG)  00720000
LOAD1      LE    BASE,ONE          LOAD PLUS 1 AS RESULT IN BASE NO REG 00740000
EXIT     L     13,4(13)                                                 00750016
         LM    14,ADDR,12(13)                                           00760016
           MVI   12(SAVE),X'FF'    STORE ALL 1 BITS IN SAVE AREA WORD 4 00780000
           BCR   15,RTN            BRANCH TO ADDRESS IN RETURN REG RTN  00800000
ERROR      LTER  EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 00820000
           BC    2,EXIT            IF EXPN IS POSITIVE, BRANCH TO EXIT  00840000
         STE   BASE,DATA                                                00845016
         STE   EXPN,DATA1                                               00850016
         LA    3,MSGDATA                                                00855016
         L     15,VIBCOM                                                00860016
         LR    14,2                SAVE ADDRESSABILITY                  00865016
         LA    2,DATA1                                                  00870016
         EX    0,86(15)                 FCVEO                           00875016
         BALR  0,1                                                      00880016
         DC    X'040E0700'              LL=4 WW=14 DD=7 SS=0            00885016
         LR    2,14                RESTORE ADDRESSABILITY               00890016
         L     LINK,AERRMON                                             00895016
         LA    PLIST,ERRLIST                                            00900016
         BALR  14,15                                                    00905016
         CLI   RETCODE+3,X'00'    DID USER FIX DATA                     00910016
         BZ    EXIT                    RESULT IN REG ALREADY ZERO       00915016
FIXUP    LA    PLIST,ERRLIST+12        POINT TO ADCONS OF DATA          00920016
         B     BEGIN                                                    00925016
*                FLOATING POINT REGISTERS                               00940000
BASE       EQU   0                 REGISTER FOR BASE NO, PASSING RESULT 00960000
EXPN       EQU   2                 REGISTER FOR EXPONENT IN COMPUTATION 00980000
*                GENERAL PURPOSE REGISTERS                              01000000
SAVE       EQU   13                REGISTER CONTAINS SAVE REG AREA ADDR 01020000
RTN        EQU   14                REGISTER FOR RETURN TO PREVIOUS RTN  01040000
LINK       EQU   15                REGISTER FOR LINKAGE TO ANOTHER RTN  01060000
PLIST      EQU   1                 REGISTER USED FOR PARAMETER LIST REF 01080000
BASADD     EQU   2                 REGISTER USED FOR SECOND BASE ADDR   01100000
ADDR       EQU   3                 REGISTER FOR INDEXING PARAMETER ADDR 01120000
*                CONSTANTS AND ADCON AREAS                              01140000
SAVREG   DS    18F                                                      01160016
PARAM      DS    F                      PARAM FOR DATA IN EXP MATH RTN  01180000
ONE        DC    X'41100000'            CONSTANT ONE IN SINGLE PREC F P 01200000
ADCPAR     DC    AL4(PARAM)             ADCON OF PARAMETER FOR EXP RTN  01220000
ADCLOG     DC    AL4(ALOG)              ADCON OF ALOG MATH LIBRARY RTN  01240000
ADCEXP     DC    AL4(EXP)               ADCON OF  EXP MATH LIBRARY RTN  01260000
VIBCOM   DC    A(IBCOM#)                                                01280000
AERRMON  DC    V(IHCERRM)                                               01281016
DATA     DS    F                                                        01282016
DATA1    DS    F                                                        01283016
ERRNUM   DC    F'244'                                                   01284016
RETCODE  DS    F                                                        01285016
ERRLIST  DC    A(MSGLNG)                                                01286016
         DC    A(RETCODE)                                               01287016
         DC    A(ERRNUM)                                                01288016
         DC    A(DATA)                                                  01289016
         DC    X'80'                    LAST LIST ITEM                  01290016
         DC    AL3(DATA1)                                               01291016
         EJECT                                                          01292016
MSGLNG   DC    A(ENDMSG-MSG)                                            01293016
MSG      DC    C'IHC244I FRXPR REAL*4 BASE=0.0, REAL*4 EXPONENT='       01294016
MSGDATA  DS    14C                                                      01295016
         DC    C', LE 0'                                                01296016
ENDMSG   EQU   *                                                        01297016
           END                                                          01300000
