*   IBM SYSTEM/360 OPERATING SYSTEM                                   * 00020000
*   COBOL(E) 360S-CO-503                                              * 00040000
*   MODULE IHD02600                                                   * 00060000
 TITLE 'IHD02600 - CHECK LENGTH OF FIELD TO BE DISPLAYED'               00080000
*STATUS:  CHANGE LEVEL 10                                             * 00100000
*FUNCTION/OPERATION:                                                  * 00120000
*   THIS SUBROUTINE CHECKS THE LENGTH OF A FIELD TO BE DISPLAYED TO BE* 00140000
*   SURE IT FITS INTO THE DEFINED FIELD.  IT IS USED ONLY IF DISPLAY  * 00160000
*   DATA FIT CHECK IS TO BE DONE BEFORE MOVING DATA TO A DISPLAY BUFFER 00180000
*                                                                     * 00200000
*ENTRY POINTS:                                                        * 00220000
*        IHD02601       ENTRY POINT    CALLING SEQUENCE:              * 00240000
*                                      LA  15,IHD02601                * 00260000
*                                      BALR  14,15                    * 00280000
*                                                                     * 00300000
*INPUT:                                                               * 00320000
*   REGISTER 1 CONTAINS THE ADDRESS OF THE  NEXT AVAILABLE BYTE IN THE* 00340000
*   BUFFER.                                                           * 00360000
*   REGISTER 2 POINTS TO THE DATA TO BE MOVED                         * 00380000
*   REGISTER 3 CONTAINS THE ADDRESS OF THE FIRST BYTE BEYOND THE BUFFER 00400000
*                                                                     * 00420000
*OUTPUT:                                                              * 00440000
*   DISPLAY DATA MOVED TO BUFFER AREA                                 * 00460000
*                                                                     * 00480000
*EXTERNAL ROUTINES: N/A                                               * 00500000
*                                                                     * 00520000
*EXITS NORMAL:                                                        * 00540000
*   RETURN TO MAIN PROGRAM:  BR  14                                   * 00560000
*                                                                     * 00580000
*EXITS ERROR: N/A                                                     * 00600000
*                                                                     * 00620000
*TABLE/WORK AREAS:                                                    * 00640000
*   WORKW  CONTAINS THE PARAMETERS PASSED BY THE MAIN PROGRAM         * 00660000
*                                                                     * 00680000
*ATTRIBUTES:                                                          * 00700000
*   SERIALLY REUSABLE                                                 * 00720000
*                                                                     * 00740000
*NOTES:                                                               * 00760000
*                                                                       00780000
*                                                                       00800000
IHD02600 START 0                                                        00820000
       ENTRY IHD02601                                                   00840000
**********************************************************************  00860000
*** SUBROUTINE USED TO MOVE DATA TO BUFFER IF USER REQUESTED THAT   *** 00880000
*** OBJECT TIME FIT CHECKING BE DONE FOR MOVING DATA TO DISPLAY BUFF*** 00900000
**********************************************************************  00920000
R1     EQU   1                          NEXT BUFFER BYTE AVAILABLE      00940000
R2     EQU   2                          DATA POINTER                    00960000
R3     EQU   3                          ADDRESS OF BYTE BEYOND BUFFER   00980000
R4     EQU   4                          BYTES TO MOVE MINUS ONE         01000000
R5     EQU   5                          WORK REGISTER                   01020000
R13    EQU   13                         CALLERS SAVE AREA POINTER       01040000
R14    EQU   14                         RETURN ADDRESS                  01060000
R15    EQU   15                         SUBROUTINE POINTER & BASE REGIS 01080000
WORKW  EQU   0                          PARAMETER PASSING AREA          01100000
       USING *,R15                      SPECIFY BASE REGISTER           01120000
IHD02601 STM   R3,R5,32(R13)            SAVE REGS 2-5 IN CALLER SAVE    01140000
       LM    R3,R4,WORKW(R3)            GET PARAMETERS                  01160000
       LTR   R4,R4                      IS LENGTH TO MOVE ZERO          01180000
       BM    DONE                       IF SO MOVE NOTHING              01200000
       LA    R5,1(R1,R4)                CALC THEOR NEW NEXT AVAIL BYTE  01220000
       CR    R5,R3                      COMPARE TO BUFFER END PLUS 1    01240000
       BH    HI                         GO REDUCE LENGTH TO FIT         01260000
       EX    R4,MV                      MOVE WHOLE FIELD TO BUFFER      01280000
       LR    R1,R5                      GET NEW NEXT AVAILABLE BYTE     01300000
DONE   LM    R3,R5,32(R13)              RESTORE REGS 2-5                01320000
       BR    14                         RETURN TO CALLER                01340000
HI     LR    R4,R3                      ADDRESS OF BYTE AFTER BUFFER    01360000
       SR    R4,R1                      CALCULATE BYTES CAN MOVE        01380000
       BCTR  R4,0                       REDUCE TO MACHINE LENGTH        01400000
       LTR   R4,R4                      IS LENGTH TO MOVE ZERO          01420000
       BM    DONE                       IF SO MOVE NOTHING              01440000
       EX    R4,MV                      MOVE WHATS POSSIBLE             01460000
       LR    R1,R3                      POINT TO BYTE AFTER BUFFER      01480000
       B     DONE                       LEAVE                           01500000
MV     MVC   0(0,1),0(2)                MOVE DATA TO BUFFER             01520000
         LTORG                                                          01540000
       END                                                              01560000
