*//    IHDFIDSR                                                         00020000
IDSR     TITLE     'IHDFIDSR'                                           00040000
*                                                                       00060000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00080000
*        TITLE 'IHDFIDSR - INTERNAL DECIMAL TO STERLING REPORT'         00100000
*                                                                       00120000
*        LEVEL  180     09/14/66                                        00140000
*                                                                       00160000
*FUNCTION/OPERATION0  THIS ROUTINE EDITS A PACKED DECIMAL QUANTITY      00180000
*   INTO A STERLING REPORT FIELD, AS DEFINED BY A STERLING REPORT       00200000
*   PICTURE AND OTHER PARAMETERS IN THE CALLING SEQUENCE.               00220000
*    THE PACKED DECIMAL QUANTITY CONTAINS 31 DIGITS,SIGNED,AND IS NOT   00240000
*   CHANGED BY THE ROUTINE. THE REPORT FIELD MAY BE UP TO 127 BYTES     00260000
*   LONG.                                                               00280000
*    THE DECIMAL FIELD,PENCE,IS CONVERTED TO POUNDS,SHILLING,PENCE AND  00300000
*   PENCE DECIMAL FIELDS ACCORDING TO THE SPECIFICATIONS IN THE CALLING 00320000
*   SEQUENCE. THE POUND INTEGER FIELD IS EDITED USING THE EDIT-AND-MARK 00340000
*   INSTUCTION. ALL OTHER FIELDS ARE EDITED DIRECTLY BY THE SUBROUTINE. 00360000
*                                                                       00380000
*ENTRY   IHDFIDSR ONLY.                                                 00400000
*   THE CALLING SEQUENCE IS                                             00420000
*                                                                       00440000
*   (    LA   REGISTER0(ADDRESS OF REPORT FIELD)                        00460000
*        LA   REGISTER13(ADDRESS OF WORKSPACE)    )                     00480000
*                                                                       00500000
*        LA   REGISTER15(IHDFIDSR)   ROUTINE ADDRESS                    00520000
*        BALR REGISTER14,REGISTER15  BRANCH TO ROUTINE,WITH REGISTER14  00540000
*                                   SET TO NEXT INSTRUCTION             00560000
*        DC   AL4(SOURCE FIELD ADDRESS)                                 00580000
*        DC   AL1(PICTURE LENGTH)                                       00600000
*        DC   AL3(PICTURE ADDRESS)                                      00620000
*        DC   AL4(ON-SIZE-ERROR ROUTINE)                                00640000
*        DC   AL1(LENGTH OF REPORT FIELD)                               00660000
*        DC   AL1(NO.OF DECIMAL DIGITS)                                 00680000
*        DC   AL1(NO.OF POUND INTEGERS)                                 00700000
*        DC   X'INFOA' (1BYTE)                                          00720000
*   NORMAL RETURN POINT.                                                00740000
*                                                                       00760000
*   NOTES ON CALLING SEQUENCE0                                          00780000
*   'REPORT FIELD' IS THE STERLING REPORT FIELD REQUIRED.               00800000
*   'SOURCE FIELD' CONTAINS THE SIGNED,PACKED DECIMAL,QUANTITY.         00820000
*   'PICTURE' IS THE DEFINITION OF THE OUTPUT FORMAT REQUIRED.          00840000
*   REGISTER 13 CONTAINS THE ADDRESS OF A WORK AREA FIELD,STARTING ON A 00860000
*   DOUBLE WORD BOUNDARY.(THE ROUTINE REQUIRES ONLY A FULL WORD         00880000
*    BOUNDARY).THE FIRST 96 BYTES ARE PRE-EMPTED BY COBOL.              00900000
*   REGISTER 14 IS POINTING TO THE PARAMETER LIST.                      00920000
*   REGISTER 15 CONTAINS THE ADDRESS OF THE SUBROUTINE.                 00940000
*   'ON-SIZE-ERROR ROUTINE' IS THE POINTER TO THE P.G.T. WHICH CONTAINS 00960000
*    THE ADDRESS OF THE ROUTINE TO BE USED IN                           00980000
*   THE CASE OF AN ON-SIZE-ERROR OCCURRING.                             01000000
*   THE 1 BYTE FIELD 'INFOA' CONTAINS THE FOLLOWING INFORMATION         01020000
*   BIT 0 X'80'   BLANK WHEN ZERO           0 = NO, 1 = YES             01040000
*       1 X'40'   SHILLING DELIMITER = C    0 = NO, 1 = YES             01060000
*       2 X'20'   POUND DELIMITER = C       0 = NO, 1 = YES             01080000
*       3 X'10'   NO POUNDS PRESENT         0 = NO  1 = YES             01100000
*   NOTE THAT 'NO POUNDS PRESENT' MEANS THAT IF THERE ARE ANY           01120000
*   CHARACTERS PRESENT BEFORE THE POUND DELIMITER,THEY ARE ALL ONLY     01140000
*   SEPARATOR CHARACTERS.                                               01160000
         EJECT                                                          01180000
*INPUT0  ALL INPUT PARAMETERS ARE DEFINED EXPLICITLY BY THE CALLING     01200000
*   SEQUENCE                                                            01220000
*    THE INPUT DATA CONSISTS OF A 16 BYTE FIELD, CONTAINING 31 PACKED   01240000
*   DECIMAL DIGITS AND A SIGN. THE DATA IS IN PENCE AND PENCE DECIMAL,  01260000
*   THE NUMBER OF DECIMAL PLACES BEING GIVEN BY THE 'NO.OF DECIMAL      01280000
*   DIGITS' PARAMETER.                                                  01300000
*   THE PICTURE CONTAINS THE FORMAT REQUIRED FOR OUTPUT. IT CONSISTS    01320000
*   OF A STRING OF BYTE PAIRS (OF TOTAL LENGTH GIVEN BY THE 'PICTURE    01340000
*   LENGTH' PARAMETER) CONTAINING THE REQUIRED CHARACTER IN THE FIRST   01360000
*   BYTE,AND THE COUNT OF SUCCESSIVE OCCURENCES OF THAT CHARACTER IN    01380000
*   THE SECOND BYTE.                                                    01400000
*                                                                       01420000
*OUTPUT0 THE OUTPUT CONSISTS OF THE EDITED STERLING REPORT FIELD,AT THE 01440000
*   ADDRESS DEFINED BY REGISTER 0 UPON ENTRY.                           01460000
*    ALL INPUT FIELDS, AND PARAMETERS ARE UNCHANGED. ALL REGISTERS ARE  01480000
*   RESTORED, WITH THE EXCEPTION OF REGISTER 15 (THE BASE REGISTER OF   01500000
*   THE ROUTINE) AND REGISTER 14,WHICH IS CHANGED TO THE ADDRESS OF THE 01520000
*   FIRST INSTUCTION AFTER THE PARAMETER LIST IF THE NORMAL EXIT IS     01540000
*   TAKEN.                                                              01560000
*                                                                       01580000
*EXITS-NORMAL0  THE NORMAL EXIT IS TO THE FIRST INSTUCTION AFTER THE    01600000
*   CALLING SEQUENCE PARAMETER LIST, WITH REGISTER 14 SET TO THIS       01620000
*   ADDRESS. REGISTER 15 CONTAINS THE ADDRESS OF THE ROUTINE.           01640000
*                                                                       01660000
*EXITS-ERROR0   THE ONLY ERROR EXIT IS TO THE ON-SIZE-ERROR ROUTINE.    01680000
*    THIS WILL OCCUR IF AN ON-SIZE-ERROR ROUTINE IS GIVEN (THE          01700000
*   PARAMETER IS NOT ZERO) AND EITHER THE 'NO. OF POUND INTEGERS'       01720000
*   PARAMETER IS NOT ZERO,BUT THE NO.OF POUND DIGITS GENERATED FROM THE 01740000
*   SOURCE FIELD IS GREATER THAN THE NO.OF POUND INTEGERS SPECIFIED,    01760000
*   OR,IF THE 'NO OF POUND INTEGERS' PARAMETER IS ZERO,BUT THE NUMBER   01780000
*   OF SHILLINGS DIGITS GENERATED IS GREATER THAN TWO. NOTE THAT IF     01800000
*   NO POUND INTEGERS ARE SPECIFIED,SHILLINGS ARE NOT CONVERTED TO      01820000
*   POUNDS AND SHILLINGS,SO THE SIZE LIMIT IS 99 SHILLINGS,NOT 19.      01840000
*    REGISTER 15 IS POINTING AT THE ON-SIZE-ERROR ROUTINE.              01860000
*    NOTE THAT REGISTER 14 IS NOT CHANGED IF THE ON-SIZE-ERROR EXIT IS  01880000
*   TAKEN,AND REMAINS POINTING AT THE PARAMETER LIST.                   01900000
*                                                                       01920000
*TABLES0  NONE                                                          01940000
*                                                                       01960000
*WORK AREAS0   THE ROUTINE USES ONE WORK AREA,246 BYTES IN LENGTH.THE   01980000
*   ADDRESS OF THIS WORK AREA IS GIVEN TO THE ROUTINE THROUGH REGISTER  02000000
*   13,AND STARTS ON A FULL-WORD BOUNDARY.THE STRUCTURE OF THE AREA IS  02020000
*   12 FULL WORDS FOR REGISTER SAVE AREA,3 FULL WORDS FOR TEMPORARY     02040000
*   ADDRESS SAVE AREAS,1 HALF-WORD AREA,AND THE REST NON-ALLIGNED AREAS 02060000
*                                                                       02080000
*ATTRIBUTES0  THE ROUTINE IS RE-ENTRANT.                                02100000
*   THE ONLY CORE STORAGE CHANGED BY THE ROUTINE IS THE OUTPUT AREA AND 02120000
*   THE WORK AREA.                                                      02140000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 02160000
         EJECT                                                          02180000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 02200000
*   FURTHER NOTES ON THE OPERATION OF THE ROUTINE.                      02220000
*                            **********                                 02240000
*    THE SOURCE FIELD,IN PENCE,PENCE DECIMAL,AND SIGN,IS CONVERTED TO   02260000
*   POUNDS,SHILLINGS,PENCE,AND PENCE DECIMAL,WITH SIGN SAVED.           02280000
*    THE EDITING MAY THEN COMMENCE                                      02300000
*                                                                       02320000
*    IF BLANK-WHEN-ZERO IS SPECIFIED,AND THE FIELD IS ZERO,THE COMPLETE 02340000
*   OUTPUT FIELD IS SET TO BLANK                                        02360000
*                                                                       02380000
*    EDITING IS CARRIED OUT FROM LEFT TO RIGHT.                         02400000
*                            **********                                 02420000
*    THE STERLING REPORT FIELD IS DEVIDED INTO 3 FIELDS BY THE          02440000
*   DELIMITER CHARACTERS(C OR D),THESE FIELDS BEING POUNDS,SHILLINGS    02460000
*   AND PENCE WITH PENCE DECIMALS.                                      02480000
*    THESE FIELDS ARE FURTHER DEVIDED AS FOLLOWS-                       02500000
*   POUNDS - STATIC CHARACTERS,DIGIT FIELD,SEPARATORS                   02520000
*   SHILLS - DIGIT FIELD,SEPARATORS                                     02540000
*   PENCE  - DIGIT FIELD,SEPARATORS,DECIMALS,TERMINATORS.               02560000
*    THESE SUB-FIELDS ARE DEFINED AS-                                   02580000
*   POUND DIGITS-THAT PART OF THE FIELD FROM THE FIRST DIGIT POSITION   02600000
*    TO THE LAST DIGIT POSITION.THESE MAY INCLUDE INSERTION (NON-DIGIT) 02620000
*    CHARACTERS.                                                        02640000
*   POUND STATIC CHARACTERS-ALL CHARACTERS PRECEDING THE DIGIT FIELD    02660000
*   POUND SEPARATORS-ALL CHARACTERS AFTER THE DIGIT FIELD,BUT BEFORE    02680000
*    THE DELIMITER.                                                     02700000
*   SHILLS DIGITS-THE 2 DIGITS AT THE START OF THE FIELD.               02720000
*    SHILLS.SEPARATORS-ALL REMAINING CHARACTERS BEFORE THE DELIMITER.   02740000
*    PENCE DIGITS-THE 2 DIGITS AT THE START OF THE FIELD                02760000
*    PENCE SEPARATORS-THE CHARACTERS UP TO THE NEXT DIGIT POSITION.     02780000
*    PENCE DECIMALS-THAT PART OF THE FIELD FROM THE FIRST DIGIT         02800000
*     POSITION (AFTER THE SEPARATORS) UP TO THE LAST DIGIT POSITION.    02820000
*    PENCE TERMINATORS-ALL REMAINING CHARACTERS.                        02840000
*    ANY OF THESE FIELDS MAY BE OMITTED,EXCEPT THE SHILLINGS AND PENCE  02860000
*    DIGITS.TO RESOLVE AMBIGUITY WHEN FIELDS ARE OMITTED,THE FOLLOWING  02880000
*     RULES APPLY-                                                      02900000
*    IF POUND DIGIT FIELD IS OMITTED,(NO.OF POUND INTEGERS IS ZERO)     02920000
*     THEN THE ENTIRE POUND FIELD IS CONSIDERED AS SEPARATORS,UNLESS    02940000
*     THERE IS A SIGN (+ OR -) IN THE FIELD.IN THIS CASE,THE SIGN IS    02960000
*     THE TERMINATOR OF THE STATIC FIELD,AND THE NO POUND BIT IN INFOA  02980000
*     (BIT 3,X'10') WILL NOT BE SET ON.                                 03000000
*    IF THE PENCE DECIMAL FIELD IS OMITTED,THE PENCE SEPARATORS ARE     03020000
*    COMBINED WITH THE PENCE TERMINATORS.                               03040000
*                            **********                                 03060000
         EJECT                                                          03080000
*                                                                       03100000
*    THE RULES FOR EDITING ARE AS FOLLOWS-                              03120000
*    POUND STATIC CHARACTERS WILL ALWAYS APPEAR                         03140000
*    POUND DIGITS ARE EDITED IN THE NORMAL WAY. IF THE COMPLETE FIELD   03160000
*     IS A FLOAT CHARACTER ($ OR SIGN),THE FLOAT CHARACTER WILL BE      03180000
*    REPLACED BY A BLANK IF THE VALUE OF FIELD IS ZERO,BUT STATIC       03200000
*    CHARACTERS WILL STILL APPEAR.                                      03220000
*    THE POUND SEPARATOR FIELD WILL APPEAR UNLESS THE LAST CHARACTER    03240000
*     OF THE POUND DIGIT FIELD RESULTED IN AN * OR BLANK AND THE        03260000
*     DELIMITER IS A C,IN WHICH CASE THE LAST CHARACTER WILL BE         03280000
*     PROPOGATED THROUGH THE FIELD.(NOTE THAT THIS CAN ONLY OCCUR IF    03300000
*     THE POUND DIGIT FIELD IS PRESENT,CONTAINS NO NINE,AND THE VALUE   03320000
*     OF THE FIELD IS ZERO).                                            03340000
*    THE SHILLING DIGITS WILL ALWAYS APPEAR.THIS FIELD IS INDEPENDENT   03360000
*     OF THE POUND FIELD,EXCEPT FOR THE X8 TYPE EDITING,WHEN THE 8 IS   03380000
*     TREATED AS 9 UNLESS POUND FIELD VALUE WAS ZERO.                   03400000
*    THE SHILLING SEPARATOR FIELD WILL APPEAR UNLESS THE LAST DIGIT     03420000
*     CHARACTER OF THE DIGIT FIELD RESULTED IN AN * OR BLANK AND THE    03440000
*     DELIMITER IS A C,IN WHICH CASE THE LAST CHARACTER WILL BE         03460000
*     PROPOGATED THROUGH THE FIELD.(THIS CAN ONLY OCCUR IF THE SHILLS   03480000
*     FIELD VALUE IS ZERO,AND THE 2ND DIGIT WAS NOT A 9 OR FORCED TO    03500000
*     9 BY THE VALUE OF THE POUND FIELD).THIS FIELD IS INDEPENDENT      03520000
*     OF THE POUND FIELD EXCEPT FOR THE EFFECT OF X8 TYPE EDIT.         03540000
*    THE PENCE DIGIT FIELD WILL ALWAYS APPEAR.THIS FIELD IS INDEPENDENT 03560000
*     OF PRECEDING FIELDS,EXCEPT FOR THE X8 TYPE EDITING,WHEN THE 8 IS  03580000
*     TREATED AS 9 UNLESS BOTH POUND AND SHILLINGS VALUES ARE ZERO.     03600000
*    THE REMAINING PENCE FIELDS WILL ALWAYS APPEAR.                     03620000
*                                                                       03640000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 03660000
       EJECT                                                            03680000
IHD04100  CSECT                                                         03700000
         ENTRY IHD04101                                                 03720000
*            DEFINE SYMBOLIC REGISTERS                                  03740000
*                                                                       03760000
R1       EQU   1         USED FOR TRT,EDIT AND MARK INSTRUCTIONS        03780000
R2       EQU   2                                                        03800000
RG       EQU   3                   A( GLOBAL TABLE )                    03820000
MASKER   EQU   4         POSITION IN EDIT MASK                          03840000
GEN      EQU   5         GENERAL USAGE REGISTER                         03860000
WREG1    EQU   6         THESE MUST BE EVEN/ODD PAIR,USED               03880000
WREG2    EQU   7          FOR WORKREGISTERS                             03900000
TARGET   EQU   8         CURRENT BYTE IN TARGET (OUTPUT AREA)           03920000
PICTURE  EQU   9         CURRENT CHARACTER IN PICTURE                   03940000
SOURCE   EQU   10        ADDRESS OF SOURCE (INPUT) FIELD                03960000
WORK     EQU   11        USED TO ADDRESS WORKSPACE                      03980000
GLOBAL   EQU   12   X    RESERVED BY COBOL                              04000000
WORKSP   EQU   3                                                        04020000
RETURN   EQU   14   X    RESERVED BY COBOL - ADDRESS OF PARAMETER LIST  04040000
*                        ALSO RETURN POSITION                           04060000
CALLER   EQU   15        CALLING REGISTER,USED AS BASE REGISTER         04080000
*                                                                       04100000
*            OTHER DEFINITIONS                                          04120000
XX       EQU   16        NO.OF BYTES IN SOURCE FIELD                    04140000
WC       EQU   96   NO.OF.BYTES AT START OF WORK AREA RESERVED BY COBOL 04160000
REGFROM  EQU   0         FIRST REGISTER TO BE SAVED                     04180000
REGTO    EQU   11        LAST REGISTER TO BE SAVED                      04200000
*                                                                       04220000
*            ESTABLISH BASE REGISTER USAGES                             04240000
       USING *,CALLER                                                   04260000
       USING PARAM,RETURN                                               04280000
*            SAVE REGISTERS                                             04300000
IHD04101 STM   3,11,REGSAVE                                             04320000
* SET UP POINTERS TO INPUT,OUTPUT,PICTURE AND WORK AREA.CLEAR WORKAREA  04340000
         LR    SOURCE,R1           PICK UP SOURCE ADDRESS               04360000
*            PICK UP TARGET ADDR                                        04380000
       LR    TARGET,0         (ALSO IN REGSAVE 0 TO 3)                  04400000
         LR    PICTURE,R2                                               04420000
         ST    R2,PCTADD                                                04440000
*            ZERO WORK AREA BEYOND REGISTER SAVE AREA                   04460000
       XC    TEMP1(ENDSTOR-TEMP1),TEMP1      EXC.OR WITH SELF =0        04480000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 04500000
*   THE SOURCE FIELD CONSISTS OF PENCE INTEGERS,PENCE DECIMALS AND SIGN 04520000
*   THE SIGN IS MOVED TO FIELD 'SSIGN'                                  04540000
*   THE INTEGER PENCE ARE MOVED TO A 16 BYTE FIELD 'INTEGER'            04560000
*   WITH A PLUS SIGN                                                    04580000
*   THE INTEGER PENCE ARE CONVERTED TO SHILLINGS AND PENCE,WITH         04600000
*   14 BYTES SHILLINGS (27 DIGITS,WITH PLUS SIGN)                       04620000
*    2 BYTES PENCE     (03 DIGITS,WITH PLUS SIGN)                       04640000
*   IF POUNDS ARE SPECIFIED (NO.POUND INTEGERS NOT ZERO)                04660000
*   THE INTEGER SHILLINGS ARE CONVERTED TO POUNDS AND SHILLINGS,WITH    04680000
*   12 BYTES POUNDS    (23 DIGITS,WITH PLUS SIGN)                       04700000
*    2 BYTES SHILLINGS (03 DIGITS,WITH PLUS SIGN)                       04720000
*   THE FIELD INTEGER THEREFORE CONTAINS (16 BYTES)                     04740000
*                    P O U N D S              SHILL  PENCE              04760000
*        00 00 00 00 DD DD DD DD DD DD DD D+  0D D+  0D D+              04780000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 04800000
*                                                                       04820000
*            SAVE SIGN                                                  04840000
         MVC   SSIGN(1),XX-1(SOURCE)                                    04860000
       OI    SSIGN,X'10' ENSURE NON ZERO                                04880000
*            IS SOURCE ZERO                                             04900000
       CP    0(XX,SOURCE),ZERO(1)                                       04920000
       BE    ZEROSRC          SOURCE IS ZERO                            04940000
* TRANSFER VALUE TO WORK AREA,AND CONVERT TO LSD.                       04960000
*            POSITION DECIMAL POINT                                     04980000
       SR    WREG1,WREG1                                                05000000
       IC    WREG1,DECDGT     PICK UP NO. DECIMAL DIGITS                05020000
*            SHIFT RIGHT ONE BIT,CONVERTING DIGITS TO CHARS - FOR MVC   05040000
         SRL   WREG1,1                                                  05060000
*                                                                       05080000
*            INITIALLY JUST MOVE TO GET INTEGER R.J AT INTEGER+15       05100000
*            COMPUTE STARTING POINT FOR MOVE                            05120000
       LA    WREG2,INTEGER(WREG1)                                       05140000
         TM    DECDGT,X'01'        COUNT ODD                            05160000
       BO    OFFSET           LOW BIT TEST                              05180000
*            BIT=ZERO, STRAIGHT MOVE                                    05200000
       MVC   0(XX,WREG2),0(SOURCE)                                      05220000
       B     MOVDGT                                                     05240000
*            ODD NO. DEC DIGITS,MOVE WITH OFFSET, DROPPING LOW ORDER    05260000
*            BYTE, BECAUSE MOVE IS ONLY 16 BYTES.                       05280000
OFFSET MVO   0(XX,WREG2),0(XX-1,SOURCE)                                 05300000
GETLSD   EQU   *                                                        05320000
*            NOW INSERT PLUS SIGN IN LOW ORDER INTEGER                  05340000
MOVDGT MVN   INTEGER+XX-1(1),ZERO                                       05360000
* INTEGER NOW CONTAINS PENCE ONLY,WITH A PLUS SIGN                      05380000
* CONVERT PENCE TO SHILLINGS AND PENCE                                  05400000
*            PROCESS DECIMAL DIGITS LATER ON                            05420000
COMPS  DP    INTEGER(XX),TWLV(2)                                        05440000
*            SHILLINGS ARE IN INTEGER(0 TO XX-1-2)                      05460000
*            TEST FOR ZERO SHILLINGS                                    05480000
       CP    INTEGER(XX-2),ZERO(1)                                      05500000
       BE    ZEROSH                                                     05520000
* CONVERT SHILLINGS TO POUNDS AND SHILLINGS.                            05540000
         TM    PNDDGT,X'FF'   ANY POUND DIGITS SPECIFIED                05560000
         BM    COMPP          YES CONVERT SHILLS TO POUNDS              05580000
*   IF NO POUND DIGITS,CHECK FOR SHILLS OVERFLOW                        05600000
         CP    INTEGER(XX-2),MAXSHILS(2) SHILLS GREATER THAN MAXIMUM    05620000
         BH    SIZERR          YES THEN SIZE ERROR                      05640000
         B     POUND                                                    05660000
COMPP  DP    INTEGER(XX-2),TWNTY(2)                                     05680000
*            POUNDS ARE NOW IN INTEGER(0 TO XX-1-2-2)                   05700000
*            TEST FOR ZERO POUNDS                                       05720000
       CP    INTEGER(XX-2-2),ZERO(1)                                    05740000
       BE    ZEROPD                                                     05760000
*            FIND OUT HOW MANY POUND DIGITS THERE ARE                   05780000
*            USE TRT  AND STOP ON NON ZERO                              05800000
COMPX  SR      R1,R1                                                    05820000
         TRT   SCAN(XX-4),INTEGER                                       05840000
*            ARGUMENT ADDR (BYTE NO.) IS IN REG 1                       05860000
*            GET BYTE AT WHICH WE STOPPED    N BYTES FROM INTEGER       05880000
       LA      WREG1,INTEGER                                            05900000
       SR    WREG2,WREG2                                                05920000
       IC    WREG2,0(R1)                                                05940000
       AR    WREG1,WREG2                                                05960000
*              CONVERT BYTE COUNT TO DIGITS                             05980000
       AR      WREG2,WREG2                                              06000000
*              IF HIGH DIGIT ZERO R1 OFF BY 1                           06020000
       TM      0(WREG1),X'F0'                                           06040000
       BM      TEST1          NOT ZERO                                  06060000
         LA    WREG2,1(WREG2)                                           06080000
TEST1  LH      WREG1,PDIGITS                                            06100000
       SR    WREG1,WREG2                                                06120000
*            COMPARE AGAINST NO. POUND DIGITS                           06140000
       IC    WREG2,PNDDGT                                               06160000
       CR    WREG1,WREG2                                                06180000
         BNH   POUND                                                    06200000
       EJECT                                                            06220000
SIZERR   EQU   *                                                        06240000
*            TOO MANY POUND DIGITS, IS THERE A SIZE ERROR EXIT          06260000
*              OR TOO MANY SHILLINGS                                    06280000
SIZEER   L     WREG1,0(RG)                                              06300000
       LTR   WREG1,WREG1           IS THERE AN ADDRESS                  06320000
       BZ    POUND         NO                                           06340000
         LM    3,11,REGSAVE                                             06360000
         B     6(RETURN)                                                06380000
         SPACE 1                                                        06400000
ZEROSRC  TM    INFOA,BLANKWZ   IS BLANK WHEN ZERO SPECIFIED             06420000
         BZ    GETLSD    NO, NORMAL TREATMENT,INTEGER IS ALREADY ZERO   06440000
*              BLANK OUT THE TARGET                                     06460000
         MVI   0(TARGET),C' '                                           06480000
*              PICK UP TARGET LENGTH                                    06500000
         SR    WREG2,WREG2                                              06520000
         IC    WREG2,TRGLNG                                             06540000
         BCT   WREG2,ZAA                                                06560000
         B     FINISH                                                   06580000
ZAA      EQU   *                                                        06600000
         BCTR  WREG2,0             REDUCE FOR THE MVC                   06620000
         EX    WREG2,PROPTRGT      PROPAGATE BLANK                      06640000
         B     FINISH              ALL DONE                             06660000
*                                                                       06680000
ZEROSH   OI    FLAGA,NOSHILL       NO POUNDS OR SHILLS                  06700000
ZEROPD   OI    FLAGA,NOPOUND       NO POUNDS                            06720000
         EJECT                                                          06740000
* THE CONVERSION TO LSD IS COMPLETE,AND THE EDIT MAY BE STARTED.        06760000
*     THE STATIC CHARACTERS ARE MOVED DIRECTLY TO THE OUTPUT AREA.      06780000
*     THE DIGIT FIELD IS PROCESSED USING THE EDIT-AND-MARK INSTRUCTION. 06800000
*    AN EDIT MASK IS BUILT UP FROM THE PICTURE STRING,IN THE WORKAREA.  06820000
*    THE EDIT MASK IS INITIALISED BEFORE PROCESSING THE STATIC CHARS.   06840000
*                                                                       06860000
*    FIRST DETERMINE IF EDIT MASK IS REQUIRED                           06880000
*            PICK UP PICTURE LENGTH AND ADDRESS                         06900000
POUND    EQU   *                                                        06920000
*            SET NO. OF DIGITS TO THAT GIVEN BY PICTURE                 06940000
         SR    WREG1,WREG1                                              06960000
         IC    WREG1,PNDDGT                                             06980000
         TM    INFOA,PSEPONLY  ANY STATIC OR DIGIT FIELDS               07000000
         BO    LOOPS1         NO PROCESS POUND SEPARATORS,IF ANY        07020000
         LTR   WREG1,WREG1    IS POUND COUNT ZERO                       07040000
         BZ    POUNDA         YES PROCESS LEADING STATIC CHARACTERS     07060000
*                                                                       07080000
*    AN EDIT MASK IS REQUIRED,SO INITIALISE IT.                         07100000
*              IF NO. OF DIGITS TO EDIT IS EVEN THERE WILL BE           07120000
*              AN EXTRA HIGH ORDER DIGIT PROCESSED, TO HANDLE           07140000
*              LEAVE A DUMMY POSITION IN MASK                           07160000
*                                                                       07180000
         SR    WREG2,WREG2                                              07200000
         SRL   WREG1,1                                                  07220000
         TM    PNDDGT,X'01'        COUNT ODD                            07240000
         BO    POUND1         LOW BIT WAS 1                             07260000
       LA      MASKER,MASKXX TWO SPACES                                 07280000
*              STORE BLANK AS FILL CHAR, AND DIGIT SEL                  07300000
       MVC   0(2,MASKER),BLDS                                           07320000
         OI    FLAGB,DUMMYPOS      NOTE THE DUMMY POSITION              07340000
         B     POUND2                                                   07360000
POUND1 EQU     *                                                        07380000
       LA      MASKER,MASKX  ONE SPACE                                  07400000
*              START WITH BLANK AS FILL CHAR                            07420000
         MVI   0(MASKER),C' '                                           07440000
POUND2 EQU     *                                                        07460000
*              STORE OFFSET FROM INTEGER FOR EDMK                       07480000
       LH      WREG2,PBYTESZ                                            07500000
         SR    WREG2,WREG1                                              07520000
         STH   WREG2,SAVEOFF                                            07540000
*              IF EXTRA DIGIT IS PRESENT ZERO IT OUT                    07560000
*              THIS ENSURES NO TROUBLE WITH 0 NOT BEING BLANKED OUT     07580000
         TM    FLAGB,DUMMYPOS                                           07600000
         BZ    POUNDA                                                   07620000
         LA    R1,INTEGER(WREG2)                                        07640000
         NI    0(R1),X'0F'                                              07660000
         EJECT                                                          07680000
*     NOW PROCESS THE PICTURE STRING.                                   07700000
*     EACH CHARACTER IS EXAMINED TO SEE IF IT IS A DIGIT CHARACTER.     07720000
*     INITIALLY,ALL CHARACTERS ARE TREATED AS STATIC CHARACTERS,AND ARE 07740000
*    MOVED TO THE OUTPUT AREA.AS SOON AS A DIGIT CHARACTER IS FOUND,    07760000
*    THIS DEFINES THE START OF THE DIGIT FIELD.FROM THEN ON,THE         07780000
*    CHARACTERS ARE MOVED TO THE EDIT MASK.THIS CONTINUES UNTIL THE     07800000
*    NO.OF DIGITS PROCESSED IS EQUAL TO THE NUMBER SPECIFIED.           07820000
POUNDA   EQU   *                                                        07840000
*              PUT DIGIT COUNT BACK INTO WREG1                          07860000
       IC      WREG1,PNDDGT                                             07880000
*              SAVE START                                               07900000
       ST      MASKER,SAVEMASK                                          07920000
*      START AT MASK                                                    07940000
       LA      MASKER,MASK                                              07960000
PICKUP   EQU   *                                                        07980000
*            SCAN PICTURE                                               08000000
*            CHAR FOUND, BRANCH TO ROUTINE                              08020000
         CLI   0(PICTURE),C'9'                                          08040000
         BE    NINE                                                     08060000
         CLI   0(PICTURE),C'Z'                                          08080000
         BE    ZZED                                                     08100000
         CLI   0(PICTURE),C'*'                                          08120000
         BE    STAR                                                     08140000
         CLI   0(PICTURE),C'$'                                          08160000
         BE    POND                                                     08180000
         CLI   0(PICTURE),C'+'                                          08200000
         BE    SIGN                                                     08220000
         CLI   0(PICTURE),C'-'                                          08240000
         BE    SIGN                                                     08260000
*    THEN MUST BE SEPARATOR                                             08280000
         B     SEPT                                                     08300000
         EJECT                                                          08320000
*              ROUTINES TO HANDLE POUND CHARACTERS                      08340000
*                                                                       08360000
POND     EQU   *                                                        08380000
* POUND MAY BE STATIC OR A FLOAT STRING                                 08400000
         TM    FLAGB,TRANMASK      TRANSFER TO DIGIT MASK YET           08420000
         BO    STARDGT       YES, STORE DIGIT SELECT                    08440000
*              NO, MAY BE FLOAT STRING                                  08460000
         SR    WREG2,WREG2                                              08480000
         IC    WREG2,1(PICTURE)    TEST COUNT = 1                       08500000
         BCT   WREG2,FLTCHAR                                            08520000
NOFLT    EQU   *    COUNT IS 1,SO STATIC - MOVE TO OUTPUT AREA          08540000
         MVC   0(1,TARGET),0(PICTURE)                                   08560000
         LA    TARGET,1(TARGET)                                         08580000
         LA    PICTURE,2(PICTURE)                                       08600000
         B     PICKUP         GET NEXT CHARACTER                        08620000
*              COUNT EXCEEDS 1, FLOATING STRING                         08640000
FLTCHAR  EQU   *                                                        08660000
         MVC   FLOAT(1),0(PICTURE)     SAVE FLOAT CHAR                  08680000
         B     STARDGTA                                                 08700000
         SPACE 1                                                        08720000
SIGN     EQU   *                                                        08740000
* SIGN MAY BE STATIC OR A FLOAT STRING                                  08760000
         TM    FLAGB,TRANMASK      TRANSFER TO DIGIT MASK YET           08780000
         BO    STARDGT       YES STORE DIGIT SELECT                     08800000
*     HOW IS SIGN TO PRINT                                              08820000
*              IS CHAR +                                                08840000
         CLI   0(PICTURE),C'+'                                          08860000
         BNE   SIGNA          NO                                        08880000
*              CHAR IS + IS SIGN +                                      08900000
         MVI   SIGNCHAR,C'+'                                            08920000
         CP    SSIGN(1),ZERO(1)                                         08940000
         BH    SIGNB          YES                                       08960000
         MVI   SIGNCHAR,C'-'  NO                                        08980000
         B     SIGNB                                                    09000000
*              CHAR IS -, IS SIGN - TOO                                 09020000
SIGNA    MVI   SIGNCHAR,C' '                                            09040000
         CP    SSIGN(1),ZERO(1)                                         09060000
         BH    SIGNB          NO                                        09080000
         MVI   SIGNCHAR,C'-'  NO                                        09100000
*              IS CHAR FLOATING                                         09120000
SIGNB    EQU   *                                                        09140000
         SR    WREG2,WREG2                                              09160000
         IC    WREG2,1(PICTURE)                                         09180000
         BCT   WREG2,SIGNC    YES                                       09200000
*                   COUNT IS 1,SO STATIC - MOVE TO OUTPUT AREA          09220000
         MVC   0(1,TARGET),SIGNCHAR                                     09240000
         LA    TARGET,1(TARGET)                                         09260000
         LA    PICTURE,2(PICTURE)                                       09280000
         LTR   WREG1,WREG1    IS IT STATIC SIGN,NO POUND DIGITS         09300000
         BP    PICKUP         NO.SINCE POUND COUNT PLUS                 09320000
         B     LOOPS1         YES.THEN PROCESS POUND SEPARATORS         09340000
*              FLOAT CHAR, SAVE IN FLOAT                                09360000
SIGNC    EQU   *                                                        09380000
         MVC   FLOAT(1),SIGNCHAR                                        09400000
         B     STARDGTA                                                 09420000
         EJECT                                                          09440000
*              CHAR IS 9                                                09460000
NINE     EQU   *                                                        09480000
*              IF FIRST 9 ENCOUNTERED SAVE POSITION                     09500000
*              SO THAT 0 CAN BE INSERTED IF FIRST DIGIT IS ZERO         09520000
         TM    FIRST9,X'01'                                             09540000
         BO    STARDGT                                                  09560000
         ST    MASKER,FIRST9                                            09580000
         OI    FIRST9,X'01'                                             09600000
*              STORE SIGNIFICANT START IN MASK                          09620000
NINE1    MVI   0(MASKER),X'21'                                          09640000
         LA    MASKER,1(MASKER)                                         09660000
         BCTR  WREG1,0        ONE FROM DIGIT COUNT                      09680000
         SR    WREG2,WREG2                                              09700000
         IC    WREG2,1(PICTURE)                                         09720000
*              IF ONLY ONE CHAR UPDATE COUNTERS,                        09740000
*              OTHERWISE PROPAGATE DIGIT SELECTS.                       09760000
         BCT   WREG2,STARDGTA                                           09780000
         B     STARA                                                    09800000
*                                                                       09820000
SEPT     EQU   *                                                        09840000
*              0 , AND B                                                09860000
* SEPARATOR MAY BE STATIC OR AN INSERTION CHARACTER                     09880000
         LR    R1,MASKER                                                09900000
         TM    FLAGB,TRANMASK      TRANSFER TO DIGIT MASK YET           09920000
         BO    SEPTM               YES,STORE IN MASK                    09940000
         LR    R1,TARGET           ELSE STORE IN OUTPUT AREA            09960000
SEPTM  MVC     0(1,R1),0(PICTURE)                                       09980000
       SR      WREG2,WREG2                                              10000000
       IC      WREG2,1(PICTURE)                                         10020000
*              PROPAGATE IF COUNT NOT 1                                 10040000
         BCT   WREG2,SEPTMC                                             10060000
         B     SEPTMA                                                   10080000
SEPTMC   EQU   *                                                        10100000
       BCTR    WREG2,0                                                  10120000
       EX      WREG2,SEPTMV                                             10140000
SEPTMA   IC    WREG2,1(PICTURE)                                         10160000
         LA    PICTURE,2(PICTURE)                                       10180000
         TM    FLAGB,TRANMASK      TRANSFER TO DIGIT MASK YET           10200000
         BO    SEPTMB         YES UPDATE MASK POSITION                  10220000
       AR      TARGET,WREG2                                             10240000
         B     PICKUP         GET NEXT CHARACTER                        10260000
SEPTMB AR      MASKER,WREG2                                             10280000
         B     PICKUP         GET NEXT CHARACTER                        10300000
SEPTMV MVC     1(0,R1),0(R1)                                            10320000
         EJECT                                                          10340000
STARDGT  EQU   *                                                        10360000
*     STORE DIGIT SELECT CHARACTERS IN THE EDIT MASK                    10380000
*  PICK UP COUNT FROM PICTURE                                           10400000
         SR    WREG2,WREG2                                              10420000
         IC    WREG2,1(PICTURE)                                         10440000
STARDGTA EQU   *    ENTRY WHEN WREG2 ALREADY SET TO TRUE COUNT          10460000
*              STORE DIGIT SELECTS IN MASK                              10480000
         MVI   0(MASKER),X'20'     DIGIT SELECT                         10500000
         BCT   WREG2,PONDA                                              10520000
         LA    WREG2,1(WREG2)                                           10540000
         B     STARA                                                    10560000
PONDA    EQU   *                                                        10580000
*              DECREMENT COUNT BY 1 FOR EX OF MVC                       10600000
         BCTR  WREG2,0                                                  10620000
PONDSET  EX    WREG2,PONDMV                                             10640000
*              RESET COUNT                                              10660000
         LA    WREG2,2(WREG2)                                           10680000
STARA    EQU   *                                                        10700000
         OI    FLAGB,TRANMASK      TRANSFER TO DIGIT MASK HAS STARTED   10720000
*              UPDATE MASK AND PICTURE                                  10740000
         AR    MASKER,WREG2                                             10760000
         LA    PICTURE,2(PICTURE)                                       10780000
*              DECREMENT DIGIT COUNTER (WREG1)                          10800000
         SR    WREG1,WREG2                                              10820000
         BP    PICKUP         GET NEXT CHARACTER IF ANY LEFT            10840000
         B     EDIT        ELSE START EDIT                              10860000
PONDMV   MVC   1(0,MASKER),0(MASKER)    LENGTH SET BY PONDSET           10880000
         SPACE 1                                                        10900000
*              CHAR IS *                                                10920000
*                                                                       10940000
STAR     EQU   *                                                        10960000
*              STORE * AS FILL CHAR                                     10980000
         L     WREG2,SAVEMASK      START OF MASK                        11000000
         MVI   0(WREG2),C'*'                                            11020000
         B     STARDGT                                                  11040000
         SPACE 1                                                        11060000
*              CHAR IS Z USE STARDGT                                    11080000
ZZED     EQU   STARDGT                                                  11100000
         EJECT                                                          11120000
*              NO MORE, NOW EDIT AND MARK (MAY BE FLOATING CHAR)        11140000
EDIT     EQU   *                                                        11160000
*              COMPUTE STARTING POINT                                   11180000
         L     R1,SAVEMASK                                              11200000
         LR    WREG2,R1       FOR EDMK                                  11220000
         LA    R1,1(R1)      FIRST CHAR + 1                             11240000
*              COMPUTE LENGTH OF EDIT                                   11260000
       LR      GEN,MASKER     SAVE POSITION                             11280000
         SR    MASKER,R1      (END+1)-(START+1) = LENGTH-1              11300000
*              ESTABLISH R1                                             11320000
         L     R1,FIRST9      SET REG 1 TO FLOAT POSITION               11340000
       LA      WREG1,INTEGER                                            11360000
       AH      WREG1,SAVEOFF                                            11380000
EDITEX   EX    MASKER,EDITPND                                           11400000
*              OVERLAY SIG. START DIGIT IF FILL CHAR                    11420000
         L     WREG2,FIRST9                                             11440000
       LTR     WREG2,WREG2                                              11460000
       BZ      EDITCA                                                   11480000
         CLI   0(WREG2),C' '                                            11500000
         BE    EDITC                                                    11520000
         CLI   0(WREG2),C'*'                                            11540000
         BNE   EDITCA                                                   11560000
EDITC    MVI   0(WREG2),C'0'                                            11580000
*              DIGIT WASN'T ZERO                                        11600000
EDITCA   EQU   *                                                        11620000
         TM    FLAGA,NOPOUND    IS POUND FIELD ZERO                     11640000
         BO    PSEPA          YES                                       11660000
*              IS THERE A FLOAT CHAR                                    11680000
EDITA1   TM    FLOAT,X'FF'                                              11700000
         BZ    EDITB          NO                                        11720000
         MVI   MASKX,C' '                                               11740000
*              STORE FLOAT AT R1-1                                      11760000
EDITB1   BCTR  R1,0                                                     11780000
         MVC   0(1,R1),FLOAT                                            11800000
*              MOVE EDITED RESULT TO TARGET                             11820000
EDITE    LA    R1,MASKX                                                 11840000
         B     EDITD                                                    11860000
EDITB  LA      R1,MASK                                                  11880000
EDITD    EQU   *                                                        11900000
*              COMPUTE LENGTH OF MOVE                                   11920000
         SR    GEN,R1              END+1-START=LENGTH                   11940000
       BCTR    GEN,0                                                    11960000
       EX      GEN,EDITX                                                11980000
*              UPDATE TARGET                                            12000000
       AR      TARGET,GEN                                               12020000
         LA    TARGET,1(TARGET)      OFF BY 1                           12040000
*              NOW PROCESS L SEPARATOR TILL C OR D                      12060000
         B     LOOPS1                                                   12080000
EDITPND EDMK   0(0,WREG2),0(WREG1)                                      12100000
EDITX    MVC   0(0,TARGET),0(R1)                                        12120000
*                                                                       12140000
*              POUND FIELD ZERO, ANYTHING SPECIAL                       12160000
PSEPA    EQU   *                                                        12180000
*              WAS THERE A NINE IN THE PICTURE                          12200000
         TM    FIRST9,X'01'                                             12220000
         BO    EDITA1       THEN TEST FOR FLOAT                         12240000
*              NOTHING SPECIAL, BUT DELIMITER MAY BE C                  12260000
PSEPX   TM     INFOA,PDILIMC       DILIMITER A C                        12280000
         BZ    PSEPB          NO                                        12300000
         OI    FLAGA,DROPPSEP   DELIMITER IS C SO DROP SEPARATORS       12320000
PSEPB    EQU   *    WAS THERE A FLOAT CHARACTER                         12340000
         TM    FLOAT,X'FF'                                              12360000
         BZ    EDITB                                                    12380000
         B     EDITE                                                    12400000
         EJECT                                                          12420000
*    LOOPS1 PROCESSES L SEPARATORS                                      12440000
*  TARGET IS POINTING TO NEXT AVAILABLE ENTRY                           12460000
* PICTURE IS POINTING TO NEXT CHARACTER                                 12480000
*                                                                       12500000
LOOPS1   CLI   0(PICTURE),C'C'                                          12520000
         BE    GETSHILL                                                 12540000
         CLI   0(PICTURE),C'D'                                          12560000
         BE    GETSHILL                                                 12580000
*              THEN MUST BE SEPARATORS                                  12600000
         TM    FLAGA,DROPPSEP   SEPORATOR CHARS TO BE DROPPED           12620000
         BO    LOOPS1A             YES                                  12640000
         MVC   0(1,TARGET),0(PICTURE)                                   12660000
*              IF COUNT NOT 1 PROPAGATE                                 12680000
LOOPS3 SR      WREG2,WREG2                                              12700000
       IC      WREG2,1(PICTURE)                                         12720000
         BCT   WREG2,STARG                                              12740000
         B     LOOPS1B                                                  12760000
STARG    EQU   *                                                        12780000
*              NOT 1                                                    12800000
         BCTR  WREG2,0                                                  12820000
         EX    WREG2,PROPTRGT   PROPAGATE IN TARGET                     12840000
*              RESET WREG2                                              12860000
LOOPS1B  IC    WREG2,1(PICTURE)                                         12880000
*              UPDATE TARGET                                            12900000
         AR    TARGET,WREG2                                             12920000
         LA    PICTURE,2(PICTURE)                                       12940000
*              NOW GET NEXT SEPARATOR                                   12960000
         B     LOOPS1                                                   12980000
*              EITHER BLANK OR * TO BE INSERTED                         13000000
LOOPS1A  EQU   *                                                        13020000
*              REDUCE TARGET BY 1 TO GET PREVIOUS CHAR                  13040000
         BCTR  TARGET,0                                                 13060000
         MVC   1(1,TARGET),0(TARGET)                                    13080000
         LA    TARGET,1(TARGET)                                         13100000
         B     LOOPS3                                                   13120000
         EJECT                                                          13140000
*              PROCESS SHILLINGS FIELD                                  13160000
*   PICTURE POINTS TO DELIMITER                                         13180000
*  TARGET POINTS TO NEXT ENTRY IN TARGET FIELD                          13200000
GETSHILL EQU   *                                                        13220000
*              UPDATE PICTURE - SKIP DELIMITER                          13240000
PNDSKP   EQU   *                                                        13260000
         LA    PICTURE,2(PICTURE)                                       13280000
*              UNPACK SHILLINGS                                         13300000
*              ONLY TWO LOW ORDER DIGITS ARE UNPACKED                   13320000
*              HENCE UP TO 99 SHILLS WILL BE HANDLED                    13340000
         UNPK  WORKSH(4),INTEGER+XX-3-1(3)        HIGH ZERO IS DROPPED  13360000
*              ENTRY FROM GETPENCE                                      13380000
*            SAME PROCESSING FOR SHILL AS PENCE                         13400000
*              OPERATE ON HIGH ORDER DIGIT                              13420000
*              IS IT ZERO                                               13440000
GETSHILM CLI   WORKSH,C'0'                                              13460000
         BE    SHILLA         YES                                       13480000
*              NON ZERO, STORE IN TARGET                                13500000
SHILLB   OI    FLAGB,HIDIGSIG  HIGH DIGIT SIGNIFICANT                   13520000
         MVC   0(1,TARGET),WORKSH                                       13540000
         B     LOWSH                                                    13560000
*              IS PICTURE 9                                             13580000
SHILLA   CLI   0(PICTURE),C'9'                                          13600000
         BE    SHILLB                                                   13620000
*              IS PICTURE *                                             13640000
         CLI   0(PICTURE),C'*'                                          13660000
         BNE   SHILLC         NO                                        13680000
SHILLD   MVI   0(TARGET),C'*'                                           13700000
         B     LOWSH                                                    13720000
SHILLC EQU     *                                                        13740000
*              NO, STORE BLANK                                          13760000
SHILLCX  MVI   0(TARGET),C' '                                           13780000
LOWSH    EQU   *                                                        13800000
*   DOES PICTURE POINTER NEED UPDATING  IS CHARACTER COUNT 1            13820000
         CLI   1(PICTURE),X'01'                                         13840000
         BNE   LOWSHB                NO                                 13860000
         LA    PICTURE,2(PICTURE)   YES UPDATE POINTER                  13880000
LOWSHB   EQU   *                                                        13900000
*              NOW OPERATE ON LOW SHILL DIGIT                           13920000
         CLI   WORKSH+1,C'0'                                            13940000
         BE    SHILLE         ZERO                                      13960000
SHILLF   MVC   1(1,TARGET),WORKSH+1                                     13980000
         B     SHILLSEP                                                 14000000
*              DIGIT ZERO, IS PICTURE 9                                 14020000
SHILLE   CLI   0(PICTURE),C'9'                                          14040000
         BE    SHILLF         YES                                       14060000
         TM    FLAGB,HIDIGSIG  HIGH DIGIT SIGNIFICANT                   14080000
         BO    SHILLF         YES, STORE DIGIT                          14100000
*              NO, IS PICTURE 8                                         14120000
         CLI   0(PICTURE),C'8'                                          14140000
         BNE   SHILLG         NO                                        14160000
*              YES, IF POUNDS NON ZERO STORE DIGIT                      14180000
         TM    FLAGB,PENPROC  IS THIS PENCE PROCESSING                  14200000
         BZ    SHILLEA        NO                                        14220000
         TM    FLAGA,NOSHILL  ANY SHILLINGS                             14240000
         BZ    SHILLF    YES                                            14260000
*              NO SHILL, SO NO POUNDS                                   14280000
         B     SHILLEB                                                  14300000
SHILLEA  TM    FLAGA,NOPOUND    IS POUND FIELD ZERO                     14320000
         BZ    SHILLF         POUNDS PRESENT                            14340000
*              NO POUNDS PRESENT,PROPAGATE PREVIOUS CHAR                14360000
SHILLEB  MVC   1(1,TARGET),0(TARGET)                                    14380000
         B     SHILLSEP                                                 14400000
*              IS PICTURE *                                             14420000
SHILLG   CLI   0(PICTURE),C'*'                                          14440000
         BNE   SHILLH         NO                                        14460000
SHILLI   MVI   1(TARGET),C'*' YES, STORE *                              14480000
         B     SHILLSEP                                                 14500000
*              PICTURE IS Z, PROPAGATE PREVIOUS CHAR                    14520000
SHILLH   MVI   1(TARGET),C' '                                           14540000
*   NOW PROCESS SEPARATORS IF ANY                                       14560000
         EJECT                                                          14580000
SHILLSEP EQU    *   PROCESS SEPARATORS,FIRST INITIALISE,CHK SUPPRESSION 14600000
*      TARGET IS POINTING TO HIGH SHILLING ENTRY                        14620000
*   PICTURE IS POINTING TO LOW  SHILLING ENTRY                          14640000
         LA    TARGET,1(TARGET)   NOW AT LOW SHILLING ENTRY             14660000
         LA    PICTURE,2(PICTURE)  NOW AT NEXT PICTURE ENTRY            14680000
         TM    FLAGB,PENPROC  IS THIS PENCE PROCESSING                  14700000
         BO    GETPENCF       YES,EXIT                                  14720000
         TM    INFOA,SDILIMC     IS DILIMITER A C                       14740000
         BZ    SHILLSA        NO                                        14760000
*              ZERO SHILL, DELIMITER C, DROP SEPARATORS                 14780000
*              IF PREVIOUS CHAR IS * OR BLANK                           14800000
         CLI   0(TARGET),C'*'                                           14820000
         BE    SHILLSE                                                  14840000
         CLI   0(TARGET),C' '                                           14860000
         BNE   SHILLSA                                                  14880000
SHILLSE  EQU   *                                                        14900000
         OI    FLAGA,DROPSSEP   DROP SEPARATORS                         14920000
SHILLSA  EQU   *    RESET POINTERS   (TARGET IS AT LOW SHILLING ENTRY)  14940000
         LA    TARGET,1(TARGET)   NOW AT NEXT AVAILABLE ENTRY           14960000
SHILLSF  EQU   *    NOW PROCESS SEPARATORS                              14980000
*  TARGET POINTS TO NEXT AVAILABLE ENTRY                                15000000
* PICTURE POINTS TO NEXT CHARACTER                                      15020000
***    IS DELIMITER REACHED YET                                         15040000
         CLI   0(PICTURE),C'C'                                          15060000
         BE    SHILLSB        DELIMITER                                 15080000
         CLI   0(PICTURE),C'D'                                          15100000
         BE    SHILLSB        DELIMITER                                 15120000
*              NOT DELIMITER, STORE CHAR,OR SUPPRESS WITH * OR BLANK    15140000
         MVC   0(1,TARGET),0(PICTURE)                                   15160000
         TM    FLAGA,DROPSSEP   DROP SEPARATORS                         15180000
         BZ    SHILLSC        NO                                        15200000
*              SUPPRESS,WITH PREVIOUS TARGET CHAR.                      15220000
         BCTR  TARGET,0                                                 15240000
         MVC   1(1,TARGET),0(TARGET)                                    15260000
         LA    TARGET,1(TARGET)                                         15280000
*              NOW SEE IF SEPARATOR IS TO BE PROPAGATED                 15300000
SHILLSC  SR    WREG2,WREG2                                              15320000
         IC    WREG2,1(PICTURE)                                         15340000
         BCT   WREG2,SHILLT                                             15360000
         B     SHILLSD                                                  15380000
SHILLT   EQU   *                                                        15400000
         BCTR  WREG2,0                                                  15420000
         EX    WREG2,PROPTRGT    PROPAGATE IN TARGET                    15440000
*      UPDATE POINTERS TO NEXT ENTRY                                    15460000
SHILLSD  IC    WREG2,1(PICTURE)                                         15480000
         AR    TARGET,WREG2                                             15500000
         LA    PICTURE,2(PICTURE)                                       15520000
         B     SHILLSF    PROCESS NEXT PICTURE CHARACTER                15540000
         EJECT                                                          15560000
SHILLSB  EQU    *    DELIMITER REACHED,SO SPACE OVER,AND PROCESS PENCE  15580000
         LA    PICTURE,2(PICTURE)   POINT TO NEXT PICTURE CHARACTER     15600000
*              PROCESS PENCE, USE GETSHILL, BUT TURN ON PENCE SW        15620000
GETPENCE EQU   *                                                        15640000
*   TARGET POINTS TO NEXT AVAILABLE ENTRY                               15660000
*  PICTURE POINTS TO NEXT PICTURE CHARACTER                             15680000
         OI    FLAGB,PENPROC  NOTE THIS IS PENCE                        15700000
         NI    FLAGB,IHDIGSIG  RESET HIDIGSIG BIT                       15720000
         UNPK  WORKSH(4),INTEGER+XX-1-1(3)                              15740000
         B     GETSHILM                                                 15760000
*                                                                       15780000
GETPENCF EQU   *         RETURN FROM GETSHILM                           15800000
*   TARGET POINTS TO LOW PENCE ENTRY                                    15820000
*  PICTURE POINTS TO NEXT PICTURE CHARACTER                             15840000
*   AT THE END OF THE PICTURE YET                                       15860000
         MVC   TEMP1+1(3),PCTADD+1                                      15880000
         L     WREG2,TEMP1                                              15900000
         LA    WREG2,0(WREG2)     CLEAR TOP 8 BITS                      15920000
         SR    GEN,GEN                                                  15940000
         IC    GEN,PCTLNG                                               15960000
         AR    WREG2,GEN                                                15980000
*   WREG2 NOW HAS LOCATION OF END OF PICTURE PLUS ONE                   16000000
*                                                                       16020000
         CR    WREG2,PICTURE                                            16040000
         BH    PENCESEP     PROCESS PENCE SEPARATORS OR DECIMALS        16060000
       B       FINISH                                                   16080000
*              MORE TO GO,  HANDLE SEPARATOR                            16100000
PENCESEP EQU   *                                                        16120000
*              PROCESS PENCE SEPARATORS                                 16140000
*                                                                       16160000
*              ANY DECIMAL PENCE                                        16180000
         SR    WREG1,WREG1                                              16200000
         IC    WREG1,DECDGT                                             16220000
         LTR   WREG1,WREG1                                              16240000
         BZ    NOPDEC         NO                                        16260000
*              YES, UNPACK INTO DECIMAL                                 16280000
       UNPK  DECIMAL(16),2(8,SOURCE)                                    16300000
       UNPK  DECIMAL+15(2*XX-17),9(XX-8,SOURCE)                         16320000
*              PUT LOCATION FIRST DIGIT IN REGISTER GEN                 16340000
         LA    GEN,DECIMAL+28                                           16360000
         SR    GEN,WREG1                                                16380000
         EJECT                                                          16400000
NOPDEC   EQU   *                                                        16420000
*              PICK UP PICTURE CHAR AND PROCESS                         16440000
         LA    TARGET,1(TARGET)     SET TARGET TO NEXT AVAIL ENTRY      16460000
*  IT WAS AT LOW PENCE                                                  16480000
*              END OF PICTURE IS IN WREG2                               16500000
PLOOP    CR    WREG2,PICTURE                                            16520000
         BNH   FINISH         PAST END - THATS IT                       16540000
         CLI   0(PICTURE),C'9'                                          16560000
         BE    PNINE          NINE                                      16580000
         CLI   0(PICTURE),C'C'                                          16600000
         BE    PCRED          CREDIT                                    16620000
         CLI   0(PICTURE),C'D'                                          16640000
         BE    PDEBIT         DEBIT                                     16660000
         CLI   0(PICTURE),C'+'                                          16680000
         BE    PPLUS          PLUS                                      16700000
         CLI   0(PICTURE),C'-'                                          16720000
         BE    PMINUS         MINUS                                     16740000
*              NOTHING SPECIAL, SO STORE                                16760000
         MVC   0(0,TARGET),0(PICTURE)                                   16780000
*              PROPAGATE IF NEED BE                                     16800000
         SR    WREG1,WREG1                                              16820000
         IC    WREG1,1(PICTURE)    EXAMINE COUNT                        16840000
         BCT   WREG1,PLOOR                                              16860000
         B     PLOOP1                                                   16880000
PLOOR    EQU   *                                                        16900000
         BCTR  WREG1,0                                                  16920000
         EX    WREG1,PROPTRGT    PROPAGATE IN TARGET                    16940000
*   UPDATE POINTERS TO NEXT AVAILABLE ENTRY                             16960000
PLOOP1   IC    WREG1,1(PICTURE)                                         16980000
         LA    PICTURE,2(PICTURE)                                       17000000
         AR    TARGET,WREG1                                             17020000
         B     PLOOP                                                    17040000
         EJECT                                                          17060000
PNINE    EQU   *                                                        17080000
*              STORE DIGITS                                             17100000
*              SEE HOW MANY                                             17120000
         SR    WREG1,WREG1                                              17140000
         IC    WREG1,1(PICTURE)                                         17160000
         BCTR  WREG1,0        REDUCE FOR MOVE                           17180000
         EX    WREG1,PNINEMV  MOVE FROM DECIMAL TO TARGET               17200000
         LA    WREG1,1(WREG1)                                           17220000
         AR    TARGET,WREG1                                             17240000
         LA    PICTURE,2(PICTURE)                                       17260000
         AR    GEN,WREG1                                                17280000
         B     PLOOP                                                    17300000
PNINEMV  MVC   0(0,TARGET),0(GEN)                                       17320000
*              CREDIT, INSERT CR IF SIGN -                              17340000
*              DEBIT, INSERT DB IF SIGN -                               17360000
PCRED    OI    FLAGB,INSERTCR  INSERT CREDIT                            17380000
PDEBIT   EQU   *              INSERT DB                                 17400000
*              IS SIGN -                                                17420000
         CP    SSIGN(1),ZERO(1)                                         17440000
         BH    PBLANK    NO, SIGN +                                     17460000
*              SIGN MINUS, MOVE CR OR DB                                17480000
         TM    FLAGB,INSERTCR  INSERT CREDIT SYMBOL                     17500000
         BO    PCREDA    CR                                             17520000
*              INSERT DB                                                17540000
         MVC   0(2,TARGET),DB                                           17560000
         B     FINISH                                                   17580000
PCREDA   MVC   0(2,TARGET),CR                                           17600000
         B     FINISH                                                   17620000
PBLANK   MVC   0(2,TARGET),BL                                           17640000
         B     FINISH                                                   17660000
*                                                                       17680000
PPLUS    EQU   *    INSERT +                                            17700000
         CP    SSIGN(1),ZERO(1)                                         17720000
         BL    PMINUSA                                                  17740000
         MVI   0(TARGET),C'+'                                           17760000
         B     FINISH                                                   17780000
PPLUSA   MVI   0(TARGET),C' '                                           17800000
         B     FINISH                                                   17820000
PMINUS   CP    SSIGN(1),ZERO(1)                                         17840000
         BH    PPLUSA                                                   17860000
PMINUSA  MVI   0(TARGET),C'-'                                           17880000
         EJECT                                                          17900000
FINISH EQU     *                                                        17920000
         L     WREG1,0(RG)                                              17940000
         LTR   WREG1,WREG1         IS SIZE ERROR OPTION SPEC'D          17960000
         BZ    FINSH1              NO, EXIT                             17980000
         LR    RETURN,WREG1        YES, RETURN TO NO ERROR ADDRESS      18000000
         LM    3,11,REGSAVE                                             18020000
         BR    RETURN                                                   18040000
FINSH1   EQU   *                                                        18060000
*      RESTORE THE REGISTERS AND EXIT                                   18080000
         LM    3,11,REGSAVE                                             18100000
         B     6(RETURN)                                                18120000
*                                                                       18140000
PROPTRGT MVC   1(0,TARGET),0(TARGET)  PROPOGATE IN TARGET               18160000
*                                                                       18180000
*            CONSTANTS                                                  18200000
PDIGITS DC     AL2(2*(XX-4)-1)                                          18220000
PBYTESZ DC     AL2(XX-4-1)                                              18240000
DB       DC    C'DB'                                                    18260000
CR       DC    C'CR'                                                    18280000
BL       DC    C'  '                                                    18300000
TWNTY  DC    PL2'20'     20+                                            18320000
TWLV   DC    PL2'12'     12+                                            18340000
MAXSHILS DC    PL2'99'   99 SHILLS MAX IF NO POUNDS                     18360000
ZERO   DC    PL1'0'      0+                                             18380000
BLDS   DC      C' '                                                     18400000
       DC      X'20'         MUST FOLLOW BLDS                           18420000
*             SCAN IS USED TO EXAMINE TWELVE BYTES IN A TRT INST.       18440000
SCAN     DC    XL(XX-4)'000102030405060708090A0B'                       18460000
       EJECT                                                            18480000
STORAGE  EQU   *                                                        18500000
*            DEFINE STRUCTURE OF WORKING STORAGE                        18520000
*            SPACE TO SAVE REGISTERS                                    18540000
REGSAVE DS   (REGTO-REGFROM+1)F                                         18560000
*            TEMPORARY STORES                                           18580000
PCTADD   DS    F                                                        18600000
SZEERR   DS    F                                                        18620000
TEMP1  DS    FL1                                                        18640000
SAVEMASK DS    F                                                        18660000
FIRST9   DS    F                                                        18680000
FIRST91  EQU   FIRST9+1                                                 18700000
SAVEOFF  DS    H                                                        18720000
SIGNCHAR DS    C                                                        18740000
*                                                                       18760000
FLAGA  DS    CL1    STATUS FLAGS                                        18780000
*              BIT MEANINGS FOR FLAG A                                  18800000
NOPOUND  EQU   X'01'     POUND VALUE IS ZERO                            18820000
NOSHILL  EQU   X'02'     SHILL VALUE IS ZERO (ALSO POUND)               18840000
DROPPSEP EQU   X'04'     DROP POUND SEPARATORS                          18860000
DROPSSEP EQU   X'08'     DROP SHILL SEPARATORS                          18880000
*                                                                       18900000
FLAGB    DS    CL1                                                      18920000
*              BIT MEANINGS FOR FLAG B                                  18940000
TRANMASK EQU   X'10'     TRANSFER TO POUND DIGIT MASK HAS STARTED       18960000
DUMMYPOS EQU   X'20'     DUMMY DIGIT POSITION IN MASK                   18980000
HIDIGSIG EQU   X'40'     HIGH ORDER DIGIT POSIT IS SIGNIF SHILL OR PEN  19000000
IHDIGSIG EQU   X'BF'    X'-40' INVERT OF HISIGDIG                       19020000
PENPROC  EQU   X'80'     PENCE PROCESSING IN SHILLS LOOP                19040000
INSERTCR EQU   X'01'     INSERT CREDIT SYMBOL                           19060000
*                                                                       19080000
FLOAT  DS    CL1    FLOATING CHAR                                       19100000
SSIGN  DS    CL1         SIGN OF SOURCE                                 19120000
MASKXX DS      CL1         DUMMY DIGIT                                  19140000
MASKX  DS    CL1    FOR EXTRA DIGIT                                     19160000
MASK   DS    CL127  127BYTE EDIT MASK                                   19180000
WORKSH   DS    CL2                                                      19200000
INTEGER DS   CL(XX)      XX BYTES FOR SOURCE INTEGER DIGITS   PACKED    19220000
DECIMAL DS   CL(2*XX)  2*XX BYTES FOR SOURCE DECIMAL DIGITS  UNPACKED   19240000
ENDSTOR DS   0F                                                         19260000
STORESIZ EQU   ENDSTOR-REGSAVE        AMOUNT OF WORKSPACE NEEDED        19280000
PARAM  DSECT                                                            19300000
*              DEFINE CALLING SEQUENCE PARAMETERS                       19320000
PAR1     DS    0C                                                       19340000
PCTLNG DS    CL1    PICTURE LENGTH                                      19360000
TRGLNG DS    CL1    TARGET LENGTH                                       19380000
DECDGT DS    CL1    NO. DECIMAL DIGITS                                  19400000
PNDDGT DS    CL1    NO. POUND DIGITS                                    19420000
*                                                                       19440000
INFOA    DS    C    SOURCE INFO FLAGS                                   19460000
*  BIT MEANINGS FOR INFOA                                               19480000
BLANKWZ  EQU   X'80'     BLANK WHEN ZERO CLAUSE                         19500000
SDILIMC  EQU   X'40'     SHILL DELIM IS C                               19520000
PDILIMC  EQU   X'20'     POUND DELIM IS C                               19540000
PSEPONLY EQU   X'10'      POUND FIELD SEPARATORS ONLY                   19560000
*                                                                       19580000
PAR2     DS    0C                                                       19600000
DISPLACE EQU   PAR2-PAR1                                                19620000
         EJECT                                                          19640000
       END                                                              19660000
         EJECT                                                          19680000
