BSO      TITLE '   IHEBSO    BIT STRING ''OR''                         *00020000
               OS/360 PL/I LIBRARY'                                     00040000
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  00060000
*                                                                       00080000
*   STATUS     CHANGE LEVEL - 0.                                        00100000
*                                                                       00120000
*   SIZE       312 BYTES                                                00140000
*                                                                       00160000
*   FUNCTION   TO IMPLEMENT THE 'OR' OPERATOR BETWEEN TWO BYTE- ALIGNED 00180000
*              BIT STRINGS, PLACING THE RESULT IN A BYTE-ALIGNED TARGET 00200000
*              FIELD.                                                   00220000
*              THE CURRENT LENGTH OF THE TARGET STRING IS SET TO EITHER 00240000
*              THE MAXIMUM OF THOSE OF THE OPERANDS OR TO THE MAXIMUM   00260000
*              LENGTH OF THE TARGET FIELD (WHEN TRUNCATION IS NECESSARY 00280000
*              TO AVOID EXCEEDING THE LENGTH OF THIS FIELD). THE        00300000
*              MINIMUM OF THE LENGTHS OF THE OPERANDS IS THEN USED TO   00320000
*              CONTROL THE MOVING OF THE FIRST OPERAND TO THE TARGET    00340000
*              FIELD AND THE SUBSEQUENT OC INSTRUCTION(S). INCOMPLETE   00360000
*              LAST BYTES ARE HANDLED IN REGISTERS. ANY BITS REMAINING  00380000
*              IN THE LONGER OPERAND FIELD ARE MOVED INTO THE TARGET    00400000
*              FIELD UP TO THE CURRENT LENGTH CALCULATED FOR IT AND THE 00420000
*              REMAINDER OF THE TARGET IS LEFT UNCHANGED.               00440000
*                                                                       00460000
*   ENTRY POINTS                                                        00480000
*              IHEBSO0                                                  00500000
*                  RA = A(SDV OF FIRST OPERAND)                         00520000
*                  RB = A(SDV OF SECOND OPERAND)                        00540000
*                  RC = A(SDV OF TARGET FIELD)                          00560000
*                                                                       00580000
*   INPUT      N/A                                                      00600000
*                                                                       00620000
*   OUTPUT     N/A                                                      00640000
*                                                                       00660000
*   EXTERNAL MODULES                                                    00680000
*              N/A                                                      00700000
*                                                                       00720000
*   EXITS      NORMAL                                                   00740000
*               RETURN TO CALLER VIA LINK REGISTER.                     00760000
*                                                                       00780000
*   TABLES/WORK-AREA                                                    00800000
*              WORK-AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS).        00820000
*                                                                       00840000
*   ATTRIBUTES  READ-ONLY AND REENTRANT.                                00860000
*                                                                       00880000
*   PRIVATE MACROS                                                      00900000
*              IHELIB,IHESDR                                            00920000
*                                                                       00940000
*   ASSEMBLY REQUIREMENTS                                               00960000
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   00980000
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        01000000
*                                                                       01020000
*   NOTES      SEE OS/360 PL/I LIBRARY PLM FOR LIBRARY CONVENTIONS AND  01040000
*              STANDARDS.                                               01060000
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON        01080000
*              A PARTICULAR INTERNAL REPRESENTATION OF THE              01100000
*              EXTERNAL CHARACTER SET.                                  01120000
 EJECT                                                                  01140000
IHEBSO   CSECT                                                          01160000
 SPACE 2                                                                01180000
         IHELIB                                                         01200000
         SPACE                                                          01220000
*                  PRIVATE REGISTER ASSIGNMENTS.                        01240000
         SPACE                                                          01260000
IND      EQU   R0                                                       01280000
RS1      EQU   RA                                                       01300000
RS2      EQU   RB                                                       01320000
RT1      EQU   RC                                                       01340000
RE1      EQU   RD                  MUST BE                              01360000
RO1      EQU   RE                    EVEN-ODD PAIR.                     01380000
OFF      EQU   RF                                                       01400000
LNK      EQU   LR                                                       01420000
BAS      EQU   BR                                                       01440000
         SPACE                                                          01460000
*                  PRIVATE OFFSETS.                                     01480000
         SPACE                                                          01500000
MFLD     EQU   4                                                        01520000
LFLD     EQU   6                                                        01540000
         EJECT                                                          01560000
IHEBSO   CSECT                                                          01580000
 SPACE                                                                  01600000
         ENTRY IHEBSO0                                                  01620000
         SPACE 2                                                        01640000
         USING *,BAS                                                    01660000
IHEBSO0  STM   LR,RX,OFLR(DR)                                           01680000
         IHESDR LW0,RD                                                  01700000
         LH    IND,LFLD(RS1)                                            01720000
         LH    RE1,LFLD(RS2)                                            01740000
         LH    RO1,MFLD(RT1)                                            01760000
         CR    IND,RO1             SET IND TO CURRENT LENGTH OF FIRST   01780000
         BC    12,BO010              STRING OR MAXIMUM LENGTH OF TARGET 01800000
         LR    IND,RO1               WHICHEVER IS LEAST.                01820000
BO010    CR    RE1,RO1             SET RE1 TO CURRENT LENGTH OF SECOND  01840000
         BC    12,BO020              STRING OR MAXIMUM LENGTH OF TARGET 01860000
         LR    RE1,RO1               WHICHEVER IS LEAST.                01880000
BO020    SR    IND,RE1             RE1 CONTAINS THE LENGTH TO BE OR-ED  01900000
         BC    10,BO030              AND IND THE FOLLOWING LENGTH MOVED 01920000
         AR    RE1,IND               (NEGATIVE IF FROM STRING 2)        01940000
BO030    LPR   RO1,IND             STORE THE SUM OF THESE LENGTHS       01960000
         AR    RO1,RE1               IN THE TARGET SDV CURRENT          01980000
         STH   RO1,LFLD(RT1)         LENGTH SLOT.                       02000000
         L     RS1,0(RS1)          LOAD RS1,RS2,RT1 WITH THE ADDRESSES  02020000
         L     RS2,0(RS2)            OF THE TWO SOURCE AND TARGET       02040000
         L     RT1,0(RT1)            FIELDS.                            02060000
         SRDL  RE1,3               CONVERT THE LENGTH IN BITS TO A BYTE 02080000
         SRL   RO1,29                LENGTH AND BIT OVERLAP.            02100000
         LCR   OFF,RO1             SAVE THE COMPLEMENT OF THE OVERLAP   02120000
         SH    RE1,BOX01+2         SUBTRACT 1 FROM BYTE LENGTH          02140000
         BC    4,BO040             BRANCH IF LENGTH LESS THAN A BYTE    02160000
         SRDL  RE1,8               SET RE1 TO NUMBER OF TIMES THROUGH   02180000
         SRL   RO1,24                LOOP,RO1 TO LENGTH IN BYTES        02200000
BOX01    LA    RE1,1(RE1,0)          ON FIRST TIME.                     02220000
         SPACE                                                          02240000
BOOCL    EX    RO1,BOMVI           MOVE DATA FROM 1ST SOURCE TO TARGET  02260000
         EX    RO1,BOOCI             'OR' 2ND SOURCE DATA WITH IT.      02280000
         LA    RT1,1(RO1,RT1)      ADD LENGTH MOVED                     02300000
         LA    RS1,1(RO1,RS1)        TO TARGET AND                      02320000
         LA    RS2,1(RO1,RS2)        SOURCE ADDRESSES.                  02340000
         LA    RO1,255             SET RO1 TO 255 AFTER FIRST SEGMENT.  02360000
         BCT   RE1,BOOCL           LOOP IF MORE SEGMENTS.               02380000
         SPACE                                                          02400000
BO040    LPR   RE1,IND             RE1 NOW HAS LENGTH TO BE MOVED INTO  02420000
*                                    TARGET FROM LONGER STRING.         02440000
         SR    RE1,OFF             ADD BIT OVERLAP TO LENGTH IN RE1.    02460000
         BC    8,BO075             RETURN IF LENGTH ZERO. THIS BRANCH   02480000
*                                    IS TAKEN ONLY WHERE THE STRINGS    02500000
*                                    ARE OF EQUAL LENGTH AND END ON A   02520000
*                                    BYTE BOUNDARY.                     02540000
         LTR   IND,IND             TEST IND.                            02560000
         BC    8,BO080               IF ZERO, STRINGS ARE SAME LENGTH   02580000
         BC    2,BO050               IF POSITIVE, FIRST IS LONGER       02600000
         XR    RS1,RS2               OTHERWISE INTERCHANGE POINTERS     02620000
         XR    RS2,RS1                 SO THAT RS1 CONTAINS ADDRESS OF  02640000
         XR    RS1,RS2                 LONGER.                          02660000
BO050    IC    RS2,0(RS2)          PUT BITS OVERLAPPING SHORTER STRING  02680000
         SRL   RS2,8(OFF)            WITH ZEROS IN THE REST OF THE BYTE 02700000
         SLL   RS2,8(OFF)            INTO BITS 24-31 OF RS2.            02720000
         SRDL  RE1,3               CONVERT TO A BYTE LENGTH AND BIT     02740000
         SRL   RO1,29                OVERLAP.                           02760000
         LCR   OFF,RO1             SAVE COMPLEMENT OF OVERLAP.          02780000
         SH    RE1,BOX01+2         SUBTRACT 1 FROM BYTE LENGTH          02800000
         BC    4,BO090             BRANCH IF LENGTH LESS THAN A BYTE.   02820000
         SRDL  RE1,8               RE1 HAS NUMBER OF 256-BYTE SEGMENTS  02840000
         SRL   RO1,24                RO1 LENGTH OF FIRST MOVE.          02860000
         EX    RO1,BOMVI           EXECUTE MOVE USING THIS LENGTH.      02880000
         EX    RS2,BOOII           'OR' IN LAST BYTE OF SHORTER FIELD.  02900000
         LA    RS1,1(RO1,RS1)      ADD LENGTH TO LONGER FIELD ADDRESS   02920000
         LA    RT1,1(RO1,RT1)        AND TARGET FIELD ADDRESS.          02940000
         LTR   RE1,RE1             TEST RE1.                            02960000
         BC    12,BO060            BRANCH IF NO 256-BYTE SEGMENTS       02980000
         SPACE                                                          03000000
BOMVL    MVC   0(256,RT1),0(RS1)   MOVE 256 BYTES OF LONGER FIELD       03020000
         LA    RS1,256(RS1)        ADD 256 TO SOURCE AND                03040000
         LA    RT1,256(RT1)          TARGET ADDRESSES.                  03060000
         BCT   RE1,BOMVL           LOOP IF MORE SEGMENTS.               03080000
         SPACE                                                          03100000
BO060    LTR   OFF,OFF             TEST FOR ZERO OVERLAP                03120000
         BC    8,BO075               IF SO, RETURN TO CALLER.           03140000
         IC    RS1,0(RS1)          INSERT LAST BYTE OF LONGER FIELD IN  03160000
BO070    LA    RO1,X'FF'             RS1, SET MASK IN RO1               03180000
         SLL   RO1,8(OFF)            TO ZERO UNWANTED                   03200000
         NR    RS1,RO1               BITS.                              03220000
         SRL   RO1,8               MODIFY MASK FOR USE ON TARGET BYTE   03240000
         EX    RO1,BONII           STORE BIT OVERLAP IN TARGET BYTE     03260000
         EX    RS1,BOOII             LEAVING REMAINING BITS UNCHANGED.  03280000
BO075    L     DR,OFDR(DR)                                              03300000
         LM    RB,RF,OFRB(DR)                                           03320000
         MVI   OFLR(DR),X'FF'                                           03340000
         BCR   15,LNK              RETURN TO CALLER.                    03360000
         SPACE                                                          03380000
BO080    IC    RS2,0(RS2)          INSERT LAST BYTES OF SOURCE FIELDS   03400000
BO090    IC    RS1,0(RS1)            INTO RS1 AND RS2.                  03420000
         OR    RS1,RS2              'OR' TOGETHER                       03440000
         BC    15,BO070                                                 03460000
         SPACE 2                                                        03480000
*                           EXECUTED INSTRUCTIONS.                      03500000
         SPACE                                                          03520000
BOMVI    MVC   0(1,RT1),0(RS1)     EXECUTED MOVE INSTRUCTION.           03540000
BOOCI    OC    0(1,RT1),0(RS2)     EXECUTED 'OR' INSTRUCTION.           03560000
BONII    NI    0(RT1),X'00'        EXECUTED BIT STORING                 03580000
BOOII    OI    0(RT1),X'00'          INSTRUCTIONS.                      03600000
         SPACE 2                                                        03620000
         END                                                            03640000
