DBN      TITLE '   IHEDBN    BIT STRING TO ARITHMETIC DIRECTOR         *00500013
               OS/360 PL/1 LIBRARY'                                     01000013
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  01500013
*                                                                       02000013
*   STATUS     CHANGE LEVEL - 0                                         02500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DBN000-TSS 02600001
*        ----------------------------------------------------DBN000-TSS 02700001
*                                                                       03000013
*   SIZE       296 BYTES                                                03500013
*                                                                       04000013
*   FUNCTION   CONVERTS A FIXED OR VARYING LENGTH BIT STRING            04500013
*              TO ANY ARITHMETIC DATA TYPE,REAL OR COMPLEX.             05000013
*                                                                       05500013
*   ENTRY POINT                                                         06000013
*              IHEDBNA -                                                06500013
*                  RA = A(BIT SDV)                                      07000013
*                  RB = A(BIT DED)                                      07500013
*                  RC = A(TARGET)                                       08000013
*                  RD = A(TARGET DED)                                   08500013
*                                                                       09000013
*   INPUT      N/A                                                      09500013
*                                                                       10000013
*   OUTPUT     N/A                                                      10500013
*                                                                       11000013
*   EXTERNAL MODULES                                                    11500013
*              IHEDMA - ARITHMETIC CONVERSION DIRECTOR                  12000013
*              IHEUPA/IHEUPB - ZERO IMAGINARY PART OF COMPLEX           12500013
*                  TARGET FOR CODED OR NUMERIC TARGETS.                 13000013
*                                                                       13500013
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              14000013
*              ERROR  - CALL IHEERRB TO RAISE SIZE ERROR IF             14500013
*                       STRING CONTAINS MORE THAN THIRTY ONE            15000013
*                       SIGNIFICANT BITS                                15500013
*                                                                       16000013
*   TABLES/WORK AREA                                                    16500013
*              WORK AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)         17000013
*                                                                       17500013
*   ATTRIBUTES READ ONLY AND REENTRANT                                  18000013
*                                                                       18500013
*   PRIVATE MACROS                                                      19000013
*              IHELIB,IHEPRV,IHESDR                                     19500013
*                                                                       20000013
*   ASSEMBLY REQUIREMENTS                                               20500013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   21000013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        21500013
*                                                                       22000013
*   NOTES      SEE OS/360 PL/1 LIBRARY PLM FOR LIBRARY MODULE           22500013
*              CONVENTIONS AND STANDARDS.                               23000013
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND             23500013
*              UPON A PARTICULAR INTERNAL REPRESENTATION OF             24000013
*              THE EXTERNAL CHARACTER SET.                              24500013
         EJECT                                                          25000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DBN001-TSS 25200001
*  THE FOLLOWING MODULES MUST BE INCLUDED IF REQUIRED                   25500013
         PUNCH     ' LIBRARY *(IHEDMAA,IHEUPBB,IHEUPAB)                /26000013
                                    DBN0000A'                           26500013
*        ----------------------------------------------------DBN001-TSS 26700001
         SPACE                                                          27000013
IHEDBN   CSECT                                                          27500013
         IHELIB                                                         28000013
IHEZLW2  DSECT                                                          28500013
         DS    15D                                                      29000013
WORK     EQU   IHEZLW2                                                  29500013
IHEDBN   CSECT                                                          30000013
         ENTRY IHEDBNA                                                  30500013
         USING *,RJ                                                     31000013
         USING IHEZLCA,WR                                               31500013
         USING IHEZLW2,DR                                               32000013
IHEDBNA  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          32500013
         IHESDR LW2,WR                  UPDATE SAVE AREA POINTER        33000013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  33500013
         LR    RJ,BR                    TRANSFER BASE REGISTER          34000013
         MVI   SWCH,X'00'               INITIALISE SWITCH               34500013
         SR    RH,RH                    ZERO RESULT                     35000013
         LR    RI,RH                    REGISTERS                       35500013
         L     RF,0(RA)                 GET STRING ADDRESS              36000013
         LR    RG,RF                    GET BIT                         36500013
         SLDL  RF,3                     ADDRESS                         37000013
         LH    R0,6(RA)                 GET CURRENT LENGTH              37500013
         LTR   R0,R0                    TEST CURRENT LENGTH             38000013
         BZ    MKFLT                    BRANCH IF ZERO                  38500013
         AR    RF,R0                    CALC END OF STRING ADDRESS      39000013
COMPR    CH    R0,K056                  TEST CURRENT LENGTH             39500013
         BH    GET56                    BRANCH IF GREATER THAN 56       40000013
         BAL   RE,GETNB                 GO GET N BITS                   40500013
         TM    SWCH,ZERO                TEST SWITCH                     41000013
         BZ    MKFLT                    BRANCH NOT SET                  41500013
         SLDA  RH,0                     TEST N BITS                     42000013
         BZ    RESTR                    BRANCH IF ALL ZERO              42500013
ERROR    IHEPRV ERR,RA,OP=LA                                            43000013
         OI    0(RA),SIZE               SET FOR SIZE ERROR              43500013
         L     BR,ERRB                  CALL EXECUTION                  44000013
         BALR  LR,BR                    ERROR PACKAGE                   44500013
         SR    RH,RH                    ZERO RESULT                     45000013
         SR    RI,RI                     OF SIZE ERROR                  45500013
MKFLT    CLI   0(RD),X'8C'              TEST FOR FIXED BINARY TARGET.   46000013
         BE    FIXED                                                    46500013
SRHRI    STM   RH,RI,STORE              STORE COLLECTED BITS            47000013
RESTR    MVI   STORE,X'4E'              SET CHARACTERISTIC              47500013
         SWR   FA,FA                    NORMALISE                       48000013
         AD    FA,STORE                 FLOATING POINT                  48500013
         STD   FA,STORE                 NUMBER                          49000013
         LA    RA,STORE                 SET TO CALL                     49500013
         LA    RB,FLTD                  ARITH CONVERSION                50000013
         L     BR,DMAA                  LOAD BRANCH ADDRESS             50500013
         BALR  LR,BR                    CALL ARITH.CONVERSION DIRECTOR  51000013
         TM    0(RD),X'81'              TEST MODE OF TARGET             51500013
         BC    12,RSTDR                 BRANCH NOT COMPLEX INTERNAL     52000013
         LR    RA,RC                    SET TARGET                      52500013
         LR    RB,RD                    PARAMETERS                      53000013
         L     BR,UPAB                  LOAD BRANCH ADDRESS FOR CODED   53500013
         TM    0(RD),CODE               TARGET CODED ARITHMETIC         54000013
         BO    SETLK                    YES,BRANCH                      54500013
         L     BR,UPBB                  LOAD BRANCH ADDRESS FOR NUMERIC 55000013
SETLK    BALR  LR,BR                    CALL IHEUPA/B TO ZERO IMAG.PART 55500013
RSTDR    L     DR,OFDR(DR)              RESET SAVE AREA POINTER         56000013
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       56500013
         BR    LR                       RETURN                          57000013
GET56    LR    RB,R0                    SAVE CURRENT LENGTH             57500013
         LA    R0,56                    SET TO GET 56 BITS              58000013
         BAL   RE,GETNB                                                 58500013
         LR    R0,RB                    RESTORE CURRENT LENGTH          59000013
         TM    SWCH,ZERO                TEST SWITCH                     59500013
         BZ    STORF                    BRANCH NOT SET                  60000013
         SLDA  RH,0                     TEST BITS                       60500013
         BZ    DECMT                    BRANCH IF ALL ZERO              61000013
         B     ERROR                    GO TO ERROR                     61500013
STORF    STM   RH,RI,STORE              SAVE FIRST 56 BITS              62000013
DECMT    SH    R0,K056                  DECREMENT CURRENT LENGTH        62500013
         OI    SWCH,ZERO                SET SWITCH                      63000013
         B     COMPR                    LOOP                            63500013
GETNB    LR    RG,RF                    CONVERT BIT ADDRESS             64000013
         SRDL  RF,3                     TO BYTE ADDDRESS AND OFFSET     64500013
         LA    RA,0(RG)                 GET BYTE ADDRESS                65000013
         SH    RA,K008                  MINUS EIGHT                     65500013
         MVC   ALIGN(8),0(RA)           ALIGN EIGHT BYTES               66000013
         LM    RH,RI,ALIGN              LOAD EIGHT BYTES                66500013
         LR    RA,RG                    CALCULATE                       67000013
         SRL   RA,29                     OFFSET                         67500013
         LCR   R0,R0                     GET -N                         68000013
         AR    RA,R0                     GET -N+OFFSET                  68500013
         SLDL  RH,56(RA)                 SHIFT 64-(N+(8-OFFSET))        69000013
         LR    RA,R0                     GET -N THEN SHIFT              69500013
         SRDL  RH,0(RA)                 (64-N) TO REMOVE RUBBISH        70000013
         LR    RF,RG                    RESTORE BIT ADDRESS             70500013
         SLDL  RF,3                     AND DECREMENT                   71000013
         AR    RF,RA                    BY N                            71500013
         BR    RE                       RETURN                          72000013
FIXED    CLI   2(RD),X'80'              TEST FOR FIXED BINARY INTEGER.  72500013
         BNE   SRHRI                                                    73000013
         LR    RF,RH                    MOVE BITS TO OTHER              73500013
         LR    RG,RI                    REGISTER PAIR                   74000013
         SR    RE,RE                    GET PRECISION.                  74500013
         IC    RE,1(RD)                                                 75000013
         LCR   RE,RE                                                    75500013
         SLDL  RF,32(RE)                SHIFT LEFT 32 - P BITS.         76000013
         LTR   RF,RF                    TEST FOR SIZE ERROR             76500013
         BNZ   SRHRI                    LET DMA DO THE WORK.            77000013
         SRL   RG,32(RE)                                                77500013
         TM    0(RD),HWRD         TEST DED FOR HALF WORD                77700001
         BO    FIXH                                                     77900001
         ST    RG,0(RC)           STPRE FULL WORD                       78100001
         B     FIX                                                      78300001
FIXH     STH   RG,0(RC)           STORE HALF WORD                       78500001
FIX      B     RSTDR                                                    78700001
DMAA     DC    V(IHEDMAA)                                               79000013
UPBB     DC    V(IHEUPBB)                                               79500013
UPAB     DC    V(IHEUPAB)                                               80000013
ERRB     DC    V(IHEERRB)                                               80500013
K056     DC    H'56'                                                    81000013
K008     DC    H'7'                                                     81500013
FLTD     DC    X'9E3500'                                                82000013
CODE     EQU   X'08'                                                    82500013
SIZE     EQU   X'20'                                                    83000013
ZERO     EQU   X'01'                                                    83500013
ALIGN    EQU   WORK+72                                                  84000013
STORE    EQU   ALIGN+8                                                  84500013
SWCH     EQU   STORE+8                                                  85000013
HWRD     EQU   X'10'                                                    85200001
       END                                                              85500013
