DCN      TITLE '   IHEDCN    CHARACTER STRING TO ARITHMETIC            *00400013
               O/S 360 PL/1 LIBRARY'                                    00800013
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  01200013
*                                                                       01600013
*   STATUS     CHANGE LEVEL - 0                                         02000013
*                                                                       02050072
* 5.5  A 890000                                                KT 62583 02100072
* 5.5  C 780000-800000,916000-920000                           KT 62583 02150072
*1412 492000 772000                                               18357 02200017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DCN000-TSS 02260001
*        ----------------------------------------------------DCN000-TSS 02320001
*                                                                       02400013
*   SIZE       704 BYTES                                                02800013
*                                                                       03200013
*   FUNCTION   CONVERTS A FIXED OR VARYING LENGTH CHARACTER             03600013
*              STRING TO ANY ARITHMETIC DATA TYPE,REAL OR COMLEX        04000013
*                                                                       04400013
*   ENTRY POINTS                                                        04800013
*              IHEDCNA - INITIALISE ON SOURCE INFORMATION               05200013
*                        AND THEN CONVERT                               05600013
*                  RA = A(CHARACTER SDV)                                06000013
*                  RB = A(CHARACTER DED)                                06400013
*                  RC = A(TARGET)                                       06800013
*                  RD = A(TARGET DED)                                   07200013
*              IHEDCNB - CONVERSION ONLY,ARGUMENTS AS FOR IHEDCNA       07600013
*                                                                       08000013
*   INPUT      N/A                                                      08400013
*                                                                       08800013
*   OUTPUT     N/A                                                      09200013
*                                                                       09600013
*   EXTERNAL MODULES                                                    10000013
*              IHEDMA - ARITHMETIC CONVERSION DIRECTOR                  10400013
*              IHEUPA/IHEUPB - ZERO REAL OR IMAGINARY PART OF           10800013
*                  CODED OR NUMERIC TARGET RESPECTIVELY.                11200013
*                                                                       11600013
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              12000013
*              ERROR  - CALL IHEERRB TO RAISE CONVERSION ERROR          12400013
*                       STRING DOES NOT CONTAIN VALID ARITHMETIC        12800013
*                       CONSTANT OR COMPLEX EXPRESSION                  13200013
*                                                                       13600013
*   TABLES/WORK AREA                                                    14000013
*              WORK AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)         14400013
*                                                                       14800013
*   ATTRIBUTES READ ONLY AND REENTRANT                                  15200013
*                                                                       15600013
*   PRIVATE MACROS                                                      16000013
*              IHELIB,IHEPRV,IHESDR                                     16400013
*                                                                       16800013
*   ASSEMBLY REQUIREMENTS                                               17200013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   17600013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        18000013
*                                                                       18400013
*   NOTES      SEE OS/360 PL/1 LIBRARY PLM FOR DESCRIPTION OF LIBRARY   18800013
*              CONVENTIONS AND STANDARDS                                19200013
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    19600013
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    20000013
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  20400013
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  20800013
*              CONSTANTS,BY REASSEMBLY,WILL RESULT IN A CORRECT MODULE  21200013
*              FOR THE NEW DEFINITIONS.                                 21600013
         EJECT                                                          22000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DCN001-TSS 22200001
*  THE FOLLOWING MODULES MUST BE INCLUDED IF REQUIRED                   22400013
         PUNCH ' LIBRARY *(IHEDMAA,IHEUPAA,IHEUPBA,IHEUPBB,IHEUPAB,IHEV/22800013
               QBA)             DCN0000A'                               23200013
*        ----------------------------------------------------DCN001-TSS 23400001
         SPACE                                                          23600013
IHEDCN   CSECT                                                          24000013
         IHELIB                                                         24400013
IHEZLW2  DSECT                                                          24800013
         DS    15D                                                      25200013
WORK     EQU   IHEZLW2                                                  25600013
IHEDCN   CSECT                                                          26000013
         ENTRY IHEDCNA                                                  26400013
         ENTRY IHEDCNB                                                  26800013
         USING IHEZLCA,WR                                               27200013
         USING IHEZLW2,DR                                               27600013
IHEDCNA  NOPR  0                                                        28000013
IHEDCNB  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          28400013
         BALR  RJ,0                     TRANSFER BASE REGISTER          28800013
         USING *,RJ                                                     29200013
         TM    OFBR+3(DR),X'02'         TEST ENTRY POINT                29600013
         IHESDR LW2,WR                  GET WORKSPACE ADDRESS           30000013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS. 30400013
         BO    GETSA                    BRANCH IF SECOND ENTRY POINT    30800013
         MVC   WOFD(8),0(RA)            SAVE ON SOURCE INFORMATION      31200013
         LA    LR,RETRY                 STORE RETRY ENTRY POINT AND     31600013
         STM   DR,LR,WCNV               SAVE AREA POINTER IN LCA        32000013
GETSA    L     RB,0(RA)                 GET STRING ADDRESS.             32400013
         LA    RB,0(RB)                 ZERO TOP BYTE.                  32800013
         LH    RE,6(RA)                 GET CURRENT LENGTH              33200013
         NI    WSWB,255-3                                         25917 33400019
         LTR   RE,RE                    TEST FOR NULL STRING.           33600013
         BZ    NULLS                                                    34000013
         AR    RE,RB                    FIND END OF                     34400013
         BCTR  RE,0                     STRING                          34800013
         ST    RB,WOCH                  SET ERROR ADDRESS               35200013
         IHEPRV ERR,RI,OP=LA            GET ADDRESS OF IHEQERR.         36000013
         MVI   1(RI),CFOR                                               36400013
LOOP1    CLI   0(RB),C' '               TEST FOR LEADING BLANK.         36800013
         BNE   TRAIL                                                    37200013
         CR    RB,RE                    ALL BLANK FIELD?                37600013
         BE    ERROR                                                    38000013
         LA    RB,1(RB)                 SCAN FROM LEFT.                 38400013
         B     LOOP1                                                    38800013
         SPACE                                                          39200013
TRAIL    CLI   0(RE),C' '               TEST FOR TRAILING BLANK.        39600013
         BNE   SQEZD                                                    40000013
         BCT   RE,TRAIL                                                 40400013
         SPACE                                                          40800013
SQEZD    CLI   0(RE),C'I'               COMPLEX SOURCE?                 41200013
         BE    CMPLX                                                    41600013
         LA    RH,CTEST                 SET FOR REAL SOURCE.            42000013
PARTY    CLI   0(RE),C'B'               BINARY SOURCE?                  42400013
         BE    BINRY                                                    42800013
         SPACE                                                          43200013
         TM    0(RD),X'88'              TEST FOR C.A.D. TARGET          43600013
         BO    QPOSS                                                    44000013
QGONE    LR    RA,RB                    SOURCE ADDRESS.                 44400013
         LA    RB,EDED                  SOURCE DED.                     44800013
         SR    RE,RA                                                    45200013
         LA    RE,1(RE)                                                 45600013
         STH   RE,PWRK                  W IN FED                        46000013
         MVI   PWRK+2,0                 D IN FED                        46400013
         LA    RE,PWRK                  ADDRESS OF FED                  46800013
         ST    RE,WFED                                                  47200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DCN999-TSS 47400056
DMACL    L     BR,DMAA                  CALL IHEDMAA                    47600013
*        ----------------------------------------------------DCN999-TSS 47800056
         BALR  LR,BR                                                    48000013
         BR    RH                                                       48400013
         SPACE                                                          48800013
CTEST    TM    0(RD),CPLX              COMPLEX TARGET?            18357 49200017
         BO    CTARG                                                    49600013
ENDRT    L     DR,OFDR(DR)              RESET SAVE AREA POINTER         50000013
         LM    LR,WR,OFLR(DR)          RESTORE CALLERS REGISTERS        50400013
         BR    LR                       RETURN TO CALLER.               50800013
         SPACE                                                          51200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DCN998-TSS 51400056
QPOSS    L     BR,VQBA                  IS VQB PRESENT?                 51600013
*        ----------------------------------------------------DCN998-TSS 51800056
         LTR   BR,BR                                                    52000013
         BZ    QGONE                    NO. USE DMA                     52400013
         LH    BR,0(BR)                 GET TOP TWO BYTES OF VCON.      52420001
         CH    BR,XFER               +  IS IT A TRANSFER VECTOR.        52440001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DCN989-TSS 52450056
         L     BR,VQBA                  GET VCON ONCE AGAIN.            52460001
*        ----------------------------------------------------DCN989-TSS 52470056
         BNE   SHRLIB                *  NO. MUST BE A(CONV MODULE).     52480001
         LR    R0,RA                    SAVE REGISTER ONE.              52500001
         LH    LR,2(BR)                 STEP DOWN TRANSFER              52520001
         LH    RA,6(BR)                  VECTOR UNTILL THE              52540001
         L     BR,0(LR,PR)               REAL VCON IS                   52560001
         L     BR,0(RA,BR)               LOADED INTO BR.                52580001
         LR    RA,R0                    RESTORE REGISTER ONE.           52600001
         LTR   BR,BR                 +  IS THE MODULE PRESENT.          52620001
         BZ    QGONE                 *  NO. USE IHEDMA.                 52640001
SHRLIB   EQU   *                                                        52660001
         LR    RA,RB                    FIRST CHARACTER.                52800013
         LR    RB,RE                    LAST CHARACTER.                 53200013
         BALR  LR,BR                    CALL CHARACTER TO CAD CONV.     53600013
         BR    RH                                                       54000013
         SPACE                                                          54400013
RETRY    L     RA,OFDR(DR)              RESTORE ORIGINAL                54800013
         LM    RA,RD,OFRA(RA)           PARAMETER REGISTERS             55200013
         B     GETSA                    AND GO TRY AGAIN                55600013
         SPACE                                                          56000013
NULLS    LA    RB,NULL                                                  56400013
         LR    RE,RB                   POINT AT DUMMY SOURCE OF ZERO.   56800013
         B     SQEZD                                                    57200013
         SPACE                                                          57600013
BINRY    BCTR  RE,0                                                     58000013
         ST    RB,PWRK+16               STORE ENDS OF CONSTANT.         58400013
         ST    RE,PWRK+20                                               58800013
         LA    RB,PWRK+16                                               59200013
         ST    RB,WCNP              SET POINTER TO ADDRESS PAIR.        59600013
         LA    RB,BDED                  DED OF CONSTANT.                60000013
         B     DMACL                                                    60400013
         SPACE                                                          60800013
CTARG    LR    RA,RC                                                    61200013
         LR    RB,RD                    MOVE TARGET PARAMETERS.         61600013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DCN991-TSS 61800056
         L     BR,UPAB                                                  62000013
*        ----------------------------------------------------DCN991-TSS 62200056
         TM    0(RD),X'88'              TEST FOR C.A.D. TARGET.         62400013
         BO    UPCAL                                                    62800013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DCN997-TSS 63000056
         L     BR,UPBB                  ZERO IMAGINARY PART.            63200013
*        ----------------------------------------------------DCN997-TSS 63400056
UPCAL    BALR  LR,BR                                                    63600013
         B     ENDRT                                                    64000013
         SPACE                                                          64400013
ERROR    OI    0(RI),CONV               SET CONVERSION ERROR.           64800013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DCN996-TSS 65000056
         L     BR,VERB                  CALL ERROR PACKAGE.             65200013
*        ----------------------------------------------------DCN996-TSS 65400056
         BALR  LR,BR                                                    65600013
         B     NULLS                                                    66000013
         SPACE                                                          66400013
CMPLX    ST    RB,WOCH                                                  66800013
         CR    RB,RE                    TEST FOR SINGLE 'I'             67200013
         BE    ERROR                                                    67600013
         BCTR  RE,0                     SCAN BACK FROM 'I'.             68000013
         LR    RF,RE                    SAVE END OF IMAG PART.          68400013
CLOOP    CR    RE,RB                    IS SOURCE ALL IMAG?             68800013
         BE    PIMAG                                                    69200013
         CLI   0(RE),C'+'              LOOK                             69600013
         BE    SIGN1                    FOR                             70000013
         CLI   0(RE),C'-'               SIGN.                           70400013
         BE    SIGN1                                                    70800013
         BCT   RE,CLOOP                                                 71200013
         SPACE                                                          71600013
PIMAG    LR    RG,RB                    SAVE BEGINNING OF IMAG PART.    72000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DCN995-TSS 72200056
         L     BR,UPAA                  SET UP CALL TO                  72400013
*        ----------------------------------------------------DCN995-TSS 72600056
         TM    0(RD),X'88'              ZERO THE REAL PART              72800013
         BO    CALUP                    OF THE TARGET.                  73200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DCN994-TSS 73400056
         L     BR,UPBA                                                  73600013
*        ----------------------------------------------------DCN994-TSS 73800056
CALUP    LR    RA,RC                    MOVE                            74000013
         LR    RB,RD                    PARAMETERS.                     74400013
         BALR  LR,BR                    CALL UPXX.                      74800013
         L     RC,WRCD                  RETRIEVE ADDRESS OF IMAG PART.  75200013
         LR    RE,RF                    GET ENDS OF IMAG PART.          75600013
         LR    RB,RG                                                    76000013
         LA    RH,ENDRT                                                 76400013
         MVI   1(RI),CFOR               SET CONVERSION CODE             76800013
         TM    0(RD),CPLX              COMPLEX TARGET?            18357 77200017
         BO    PARTY                    YES.                            77600013
*********************************************************************** 78000072
*        IF THE TARGET IS NOT COMPLEX WE MUST STILL CARRY ON      62583 78100072
*        WITH THE ASSIGNMENT AS WE MAY WISH TO RAISE CONVERSION   62583 78200072
*        THOUGH WE MUST BE CAREFUL NOT TO RAISE SIZE DURING       62583 78300072
*        THE ASSIGNMENT. WE DO THIS BY POINTING AT A DUMMY        62583 78400072
*        TARGET AREA AND SUPPLYING A SUITABLE DUMMY DED TO THE    62583 78500072
*        CONVERSION ROUTINES.                                     62583 78600072
         LA    LR,7                    * INITIALIZE LOOP COUNT    62583 78700072
         LA    RC,FXDDED               * POINT AT 1ST DUMMY DED   62583 78800072
         IC    RD,0(RD)                * PICK UP TARGET DED FLAG  62583 78900072
         N     RD,FULL9E               * TURN OFF UNNECESSARY BITS 2583 79000072
         SR    BR,BR                   * INITIALIZE COMPERAND     62583 79100072
LOOP2    IC    BR,0(RC)                * SEARCH FOR MATCHING      62583 79200072
         CR    BR,RD                   * DED FLAG BYTE, ON MATCH  62583 79300072
         BE    LOOP2END                * POINT RD AT EQUIVALENT   62583 79400072
         LA    RC,3(RC)                * MAX PRECISION DED        62583 79500072
         BCT   LR,LOOP2                * NO MATCH , TRY NEXT DED  62583 79600072
*        IF WE REACH THIS POINT WEVE FAILED TO DETERMINE          62583 79610072
*        A VALID TARGET TYPE SO WE DEFAULT TO FIXED DEC           62583 79620072
*        IF THE SOURCE IS NOT BINARY, ELSE DEFAULT TO FLOAT BIN   62583 79630072
         LA    RC,FXDDED               * POINT AT FIXED DEC DED   62583 79640072
         CLI   0(RE),C'B'              * TEST FOR BINARY SOURCE   62583 79650072
         BNE   LOOP2END                                           62583 79660072
         LA    RC,FLBDEDL              * POINT AT FLOAT BIN DED   62583 79670072
LOOP2END LR    RD,RC                   *                          62583 79700072
         LA    RC,PWRK+8               * POINT RC AT DUMMY TARGET 62583 79800072
         B     PARTY                   * GO TRY CONVERSION        62583 79900072
*********************************************************************** 80000072
         SPACE                                                          80400013
SIGN1    LR    RG,RE                    SAVE ADDRESS                    80800013
         BCTR  RE,0                     SCAN BACK                       81200013
         CLI   0(RE),C'E'               TEST FOR 'E'                    81600013
         BE    CLOOP                    GO TO SCAN SOME MORE.           82000013
         LA    RH,REALP                 SET REAL PART OF COMPLEX.       82400013
         B     PARTY                    GO TO CONVERT.                  82800013
         SPACE                                                          83200013
REALP    OI    WSWA,UPDO                SET UPDATE ONLY SWITCH.         83600013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DCN993-TSS 83800056
         L     BR,UPAB                                                  84000013
*        ----------------------------------------------------DCN993-TSS 84200056
         TM    0(RD),X'88'                                              84400013
         BO    CALUP                                                    84800013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DCN990-TSS 85000056
         L     BR,UPBB                                                  85200013
*        ----------------------------------------------------DCN990-TSS 85400056
         B     CALUP                                                    85600013
         SPACE                                                          86000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DCN992-TSS 86200056
DMAA     DC    V(IHEDMAA)                                               86400013
VQBA     DC    V(IHEVQBA)                                               86800013
VERB     DC    V(IHEERRB)                                               87200013
UPAB     DC    V(IHEUPAB)                                               87600013
UPBB     DC    V(IHEUPBB)                                               88000013
UPAA     DC    V(IHEUPAA)                                               88400013
UPBA     DC    V(IHEUPBA)                                               88800013
*        ----------------------------------------------------DCN992-TSS 89000056
FULL9E   DC    F'158'                  * X'0000009E' USED AS MASK 62583 89100072
PWRK     EQU   WORK+72                                                  89200013
UPDO     EQU   4                                                        89600013
CONV     EQU   X'40'                                                    90000013
CFOR     EQU   4                                                        90400013
CPLX     EQU   X'81'                                              18357 90600017
BDED     DC    X'CC'                                                    90800013
EDED     DC    X'CA'                                                    91200013
*********************************************************************** 91600072
*        THE FOLLOWING FOUR DECLARATIONS MUST NOT BE MOVED              91670072
*        THEY ARE MAXIMUM PRESICION DEDS FOR THE VARIOS DATA TYPES 2583 91740072
FXDDED   DC    X'880F80'               * FIXED DECIMAL            62583 91810072
FLDDEDS  DC    X'8A0680'               * SHORT FLOAT DECIMAL      62583 91880072
FXBDED   DC    X'8C1F80'               * FIXED BINARY             62583 91950072
FLBDEDS  DC    X'8E1580'               * SHORT FLOAT BINARY       62583 92020072
FLDDEDL  DC    X'9A1080'               * LONG FLOAT DECIMAL       62583 92090072
FXBDEDS  DC    X'9C0F80'               * HALFWORD FIX BIN         62583 92120072
FLBDEDL  DC    X'9E3580'               * LONG FLOAT BINARY        62583 92160072
*                                                                       92230072
*********************************************************************** 92300072
NULL     DC    C'0'                                                     92400013
         DS    0H                                                       92500001
XFER     DC    X'58FC'                                                  92600001
         END                                                            92800013
