DDI      TITLE '   IHEDDI    DATA DIRECTED INPUT                       /00100013
               OS/360 PL/I LIBRARY'                                     00200013
*    VERSION   FOURTH VERSION OF F-LEVEL COMPILER                       00300015
*                                                                       00400013
*   STATUS     CHANGE LEVEL - 0                                         00500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI000-TSS 00510001
*        ----------------------------------------------------DDI000-TSS 00520001
*3219 208000,210000                                               16776 00550017
*3219                                                             18041 00570017
*                                                                       00574001
*APARS FIXED                                                            00578001
*                                                                       00582001
*        21183                                                          00586001
*        22459                                                          00590001
* R21.6 45929  A136500,A146500,A196000                        CAS 45929 00590856
*    45929     A291000,A494000,A494600                        CAS 45929 00591656
*A285600                                                      SRC 45925 00592456
*D288000                                                      SRC 45925 00593256
*                                                                       00594001
*                                                                       00600013
*   SIZE       1096 BYTES.                                              00700013
*                                                                       00800013
*   FUNCTION                                                            00900013
*              1)READ AN ITEM FROM THE SPECIFIED INPUT STREAM ACCORDING 01000013
*              TO THE RULES SPECIFIED FOR DATA DIRECTED INPUT. IF THE   01100013
*              ITEM SPANS MORE THAN ONE RECORD, THEN THE INFORMATION IN 01200013
*              EACH RECORD IS STACKED BY THE AQUISITION OF VDA'S UNTIL  01300013
*              THE ITEM DELIMITER/TRANSMISSION TERMINATOR IS FOUND. THE 01400013
*              ITEM IS THEN CONCATENATED INTO A SINGLE VDA FOR ANALYSIS 01500013
*              THE ITEM IS SCANNED AS FOLLOWS -                         01600013
*                A) ANY LEADING BLANKS ARE IGNORED.                     01700013
*                B) A SEARCH IS MADE FOR AN EQUATE SIGN OR A LEFT       01800013
*                 PARENTHESIS.                                          01900013
*                C) IF AN EQUATE SIGN IS FOUND THE INPUT CONTAINS A     02000013
*                 SCALAR ITEM AND CONTROL PASSES TO D).                 02100013
*                   IF A LEFT PARENTHESIS IS FOUND THE INPUT CONTAINS   02200013
*                 AN ARRAY ITEM AND SCANNING IS CONTINUED UNTIL AN      02300013
*                 EQUATE SIGN IS FOUND.                                 02400013
*                D) LIST DIRECTED INPUT MODULE IS CALLED TO SCAN THE    02500013
*                 VALUE PART, ENTERING AT IHELDIC.                      02600013
*                                                                       02700013
*              2)SEARCH SYMBOL TABLE FOR A NAME THE SAME AS THAT JUST   02800013
*              SCANNED. IF THERE IS NO SUCH NAME THIS IS AN ERROR.      02900013
*              THE SEARCH IS PERFORMED EITHER BY -                      03000013
*                A) SEARCHING THE SPECIFIED ENTRIES IN THE SYMBOL TABLE 03100013
*                 (ENTRY POINT IHEDDIA).                                03200013
*                B) SEARCHING THE WHOLE OF THE SYMBOL TABLE KNOWN AT    03300013
*                 THIS POINT (ENTRY POINT IHEDDIB).                     03400013
*                                                                       03500013
*              3)CHECK THAT THE DIMENSIONALITY IS CORRECT -             03600013
*                A) IF THE ENTRY IS FOR A SCALAR THEN IF SUBSCRIPTS     03700013
*                 APPEARED ON THE INPUT STREAM THIS IS AN ERROR.        03800013
*                B) IF THE ENTRY IS FOR AN ARRAY THEN IF NO SUBSCRIPTS  03900013
*                 APPEARED ON THE INPUT STREAM THIS IS AN ERROR.        04000013
*              OTHERWISE IHEDDJ IS CALLED TO CHECK THE SUBSCRIPTS OF    04100013
*              THE INPUT ITEM, AND ADDRESS THE SPECIFIED ELEMENT OF THE 04200013
*              ARRAY.                                                   04300013
*                                                                       04400013
*              4) ALL THINGS BEING EQUAL ASSIGN THE VALUE TO THE        04500013
*              INTERNAL VARIABLE USING LIST DIRECTED INPUT (ENTRY       04600013
*              POINT IHELDID).                                          04700013
*                                                                       04800013
*              5) IF THE TRANSMISSION TERMINATOR IS FOUND RETURN TO     04900013
*              CALLER. OTHERWISE REPEAT PROCESSING FROM 1).             05000013
         EJECT                                                          05100013
*   ENTRY POINTS                                                        05200013
*              IHEDDIA                                                  05300013
*                  RA = A(PLIST)                                        05400013
*                  PLIST = A(SYMBOL TABLE ENTRY FOR SPECIFIED VARIABLE) 05500013
*                              ........                                 05600013
*              IHEDDIB                                                  05700013
*                  PLIST = A(SYMTAB CHAIN) THAT IS THE SYMBOL TABLE     05800013
*                                 OF VARIABLES KNOWN AT THIS POINT.     05900013
*                                                                       06000013
*   INPUT                                                               06100013
*              CURRENT FILE PSEUDO-REGISTER (IHEQCFL).                  06200013
*                                                                       06300013
*   OUTPUT                                                              06400013
*              ASSIGNMENT OF ITEM(S) TO INTERNAL VARIABLE(S).           06500013
*                                                                       06600013
*   EXTERNAL MODULES                                                    06700013
*              IHELDI - 1)SCAN VALUE PART OF INPUT ITEM AND             06800013
*                       2)ASSIGN VALUE TO INTERNAL VARIABLE.            06900013
*              IHEDDJ - CHECK SUBSCRIPTS AND COMPUTE ELEMENT ADDRESS.   07000013
*              IHEIOF - ADDRESS INPUT STREAM.                           07100013
*              IHESAD - GET VDA'S AS NECESSARY.                         07200013
*              IHESAF - FREE THOSE VDA'S GOTTEN IN THIS PASS.           07300013
*              IHEERR - EXECUTION ERROR PACKAGE                         07400013
*                                                                       07500013
*   EXITS      NORMAL                                                   07600013
*                  RETURN VIA LINK REGISTER                             07700013
*              ERROR                                                    07800013
*                  1. 'NAME'                                            07900013
*                            UNRECOGNISED NAME ON INPUT STREAM.         08000013
*                            IF CONTROL IS RETURNED TO THIS MODULE      08100013
*                            THE ITEM IS IGNORED.                       08200013
*                  2. 'GET/PUT STRING SIZE EXCEEDED'                    08300013
*                                                    AN ATTEMPT         08400013
*                            WAS MADE TO GO PAST THE END OF THE SOURCE  08500013
*                            STRING.                                    08600013
*                  3. 'INVALID ARRAY DATUM'                             08700013
*                                           THE DIMENSIONALITY OF THE   08800013
*                            INPUT ITEM IS NOT THE SAME AS THE INTERNAL 08900013
*                            VARIABLE.                                  09000013
*              NOTE - IF CONTROL IS RETURNED TO THIS MODULE AFTER       09100013
*                  END OF FILE CONDITION HAS BEEN RAISED RETURN IS      09200013
*                  VIA ADDRESS IN SECOND WORD OF IHEQCFL.               09300013
*                                                                       09400013
*   TABLES/WORK AREA                                                    09500013
*              SEE OS/360 PL/I LIBRARY PLM FOR DESCRIPTION OF THE       09600013
*               SYMBOL TABLE AND FILE CONTROL BLOCK.                    09700013
*                                                                       09800013
*   ATTRIBUTES  READ ONLY AND REENTRANT                                 09900013
         EJECT                                                          10000013
*   PRIVATE MACROS                                                      10100013
*              IHELIB,IHEPRV,IHESDR,IHEZAP                              10200013
*                                                                       10300013
*   ASSEMBLY REQUIREMENTS                                               10400013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   10500013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        10600013
*                                                                       10700013
*   NOTES                                                               10800013
*              SEE OS/360 PL/I LIBRARY PLM FOR DESCRIPTION OF LIBRARY   10900013
*               CONVENTIONS AND STANDARDS.                              11000013
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    11100013
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    11200013
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  11300013
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  11400013
*              CONSTANTS, BY REASSEMBLY, WILL RESULT IN A CORRECT       11500013
*              MODULE FOR THE NEW DEFINITIONS.                          11600013
        EJECT                                                           11700013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI001-TSS 11750001
*  THE FOLLOWING MODULES MUST BE INCLUDED IF REQUIRED                   11800013
         PUNCH     ' LIBRARY *(IHEDDJA)                                /11900013
                                    DDI0000A'                           12000013
*        ----------------------------------------------------DDI001-TSS 12050001
         SPACE                                                          12100013
IHEDDI   CSECT                                                          12200013
         IHELIB                                                         12300013
         IHEZAP                                                         12400013
DDISAVE  DSECT                                                          12500013
         DS    18F                                                      12600001
WPFL     DS    0B                                                       12700013
WPRA     DS    A                                                        12800013
TEMP      DS   2D                                                       12850015
WSSS     DS    2A                                                       12900013
WNAM     DS    0A                       TWO WORDS.                      13000013
         DS    A                                                        13100013
WADD     DS    A                        SECOND WORD OF WNAM.            13200013
IVDA     DS    H                                                        13300013
         DS    B                                                        13400013
WSDS     DS    2A                                                       13500013
WPDV     DS    2A                                                       13600013
WADF     DS    2F                                                 19644 13650017
WNGW     DS    B                   FLAG BYTE NAME VDA         CAS 45929 13660056
         DS    3B                  SPARE                      CAS 45929 13670056
LSAV     EQU   *-DDISAVE                                                13700013
         SPACE 2                                                        13800013
PWR      EQU   WR                                                       13900013
STRN     EQU   X'80'                                                    14000013
PERD     EQU   B'01000000'                                              14100013
BLNK     EQU   B'10000000'                                              14200013
NTRY     EQU   B'00000010'                                              14300013
LBLK     EQU   B'00000001'                                              14400013
NTRF     EQU   B'00000110'                                              14500013
EOFF     EQU   B'00001000'                                              14600013
INVL    EQU   B'00010000'                                               14650001
*      WNGW                                                   CAS 45929 14660056
FNGT     EQU   X'80'               NAME VDA OBTAINED          CAS 45929 14670056
CURL     EQU   6                                                        14700013
TERM     EQU   1                                                        14800013
DEOF     EQU   1                                                        14900013
ONCH     EQU   X'48'                                                    15000013
ERR1     EQU   X'B800'                  END OF FILE                     15030015
ERR2     EQU   X'0012'                  UNEXPECTED END OF FILE          15060015
         SPACE 2                                                        15100013
*   MAP OF SYMBOL TABLE ENTRY  AND  FLAGS.                              15200013
         SPACE                                                          15300013
SYMTABF  DSECT                                                          15400013
SPTR     DS    A                        ADDRESS OF NEXT ENTRY/0         15500013
SLEN     DS    X                        LENGTH OF VARIABLE NAME.        15600013
SNAM     DS    255C                     VARIABLE NAME                   15700013
         SPACE                                                          15800013
SYMTABE  DSECT                                                          15900013
SSUB     DS    0X                       DIMENSIONALITY.                 16000013
SDED     DS    A                        ADDRESS OF DED.                 16100013
SFLG     DS    0B                       FLAG BOX.                       16200013
SADD     DS    A                        ADDRESS/OFFSET VARIABLE/DV.     16300013
SPRO     DS    H                        OFFSET TO DISPLAY/ANCHOR IN PRV 16400013
         SPACE                                                          16500013
CLSS     EQU   B'00000011'              STORAGE CLASS.                  16600013
NSTC     EQU   X'01'                                                    16700013
TCFL     EQU   X'04'                    XMIT STACK FLAG                 16800013
CHCK     EQU   B'01000000'              ON 'CHECK' FOR VARIABLE.        16900013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI002-TSS 16930021
*        ----------------------------------------------------DDI002-TSS 16960021
         EJECT                                                          17000013
IHEDDI   CSECT                                                          17100013
         ENTRY IHEDDIA,IHEDDIB                                          17200013
IHEDDIA  NOPR  0                     .  ENTRY FOR RESTRICTED READ.      17300013
IHEDDIB  STM   LR,PWR,OFLR(DR)       .  ENTRY FOR UNRESTRICTED READ.    17400013
         BALR  PWR-1,0                                                  17500013
         USING *,PWR-1                                                  17600013
         LR    RD,DR                                                    17700013
         IHESDR LW4                     UPDATE DR TO PGM SAVE AREA.     17800013
         USING DDISAVE,DR                                               17900013
         LR    RC,RA                                                    18000013
         LR    RF,BR                                                    18100013
         LA    R0,LSAV+8                                                18200013
         IHEPRV VDA,BR               $$ GET VDA FOR SA AND WORKAREA     18300015
         BALR  LR,BR                                                    18400013
         ST    RD,OFDR+8(RA)                                            18500013
         LA    DR,8(RA)                                                 18600013
         MVI   0(DR),X'61'                                              18700013
         ST    RC,WPRA                  SAVE PLIST POINTER.             18800013
         STC   RF,WPFL               /  SET FLAGS FOR ENTRY POINT.      18900013
         IHEPRV LCA                     ADDRESS LIB COMMUNICATIONS AREA 19000013
         USING IHEZLCA,PWR                                              19100013
         IHEPRV CFL,RF                                                  19200013
         USING IHEZDCL,RF                                               19300013
         LH    RF,DPRO                                                  19400013
         L     RF,0(RF,PR)              ADDRESS CURRENT FILE FCB.       19500013
         USING IHEZAPE,RF                                               19600013
         MVI   WNGW,00             SET NO NAME VDA            CAS 45929 19610056
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI003-TSS 19630021
*        ----------------------------------------------------DDI003-TSS 19660021
         SPACE                                                          19700013
*   BEGIN PROCESSING AN ITEM.                                           19800013
         SPACE                                                          19900013
DD000    LA    RH,DD010                 RETURN ADDRESS                  20000013
         TM    TFLX,TMEF             +  END FILE ALREADY ENCOUNTERED    20030015
         BO    DIDOF                 ** YES,RAISE ENDFILE CONDITION     20060015
     NI  IVDA+2,255-EOFF                                          18041 20070017
         OI    WPFL,LBLK+PERD+BLNK                                      20080015
         SR    BR,BR                                              16776 20086017
         STH   BR,IVDA                                            16776 20092017
         NI    TFLX,255-TMIT-TMLC    /  UNSET TMIT AND TMLC FLAGS.      20100013
         IHEPRV CFL,BR,OP=LA                                            20200013
         NI    4(BR),255-TCFL           UNSET XMIT FLAG                 20300013
         LH    RD,TREM                  LENGTH OF BUFFER LEFT.          20400013
         LTR   RD,RD                    ANY BYTES LEFT..                20500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI004-TSS 20550021
         BZ    DDGET                 $  NO GET ANOTHER BUFFER.          20600013
         B     DDSET                 $  YES SET UP LOOP PARAMETERS.     20700013
*        ----------------------------------------------------DDI004-TSS 20800021
DD010    EQU   *                                                  16776 20900017
DD020    CLI   0(RC),C' '               TEST FOR LEADING BLANK.         21100013
         BNE   DD030                    NO.                             21200013
         BAL   RH,DDNXT              $  YES  GET NEXT CHARACTER.        21300013
         B     DD020                    FLUSHING LEADING BLANKS.        21400013
         SPACE                                                          21500013
DD030    NI    WPFL,255-LBLK-INVL    /  UNSET LEADING BLANK SWITCH      21560001
*                                       AND INVALID FIELD FLAG.   22459 21620001
         CLI   0(RC),C','               TEST FOR COMMA                  21700013
         BE    DDNUL                    YES NULL FIELD.                 21800013
         CLI   0(RC),C';'               TEST FOR SEMI-COLON             21900013
         BE    DDNLT                    YES NULL AND END OF INPUT.      22000013
         ST    RC,WSDS                  SET BUFFER SDV TO FIRST NON-    22100013
         ST    RE,WSDS+4                 BLANK AND LENGTH FROM IT.      22200013
         ST    RC,TCBA                  SET BUFFER POINTERS TO          22300013
         STH   RE,TREM                   BEGINNING OF ITEM.             22400013
         ST    RI,WSSS+4                SET SUBSCRIPT FIELD LENGTH ZERO 22500013
         ST    RI,WOFD+4                SET LENGTH OF FIELD TO ZERO.    22600013
         ST    RC,WOFD                  ADDRESS OF FIELD                22700013
DD040    AR    RI,RD                    INCREMENT FIELD COUNT.          22800013
         CLI   0(RC),C'='               TEST FOR EQUATE SIGN.           22900013
         BE    DD080                    YES.                            23000013
         CLI   0(RC),C'('               TEST FOR LEFT PARENTHESIS.      23100013
         BE    DD050                    YES.                            23200013
         BAL   RH,DDNXT              $  GET NEXT CHARACTER.             23300013
         B     DD040                    CONTINUE TO SCAN NAME.          23400013
         SPACE                                                          23500013
DD050    LR    BR,RI                                                    23600013
         AH    BR,WOFD+CURL                                             23700013
         ST    BR,WNAM+4                SET LENGTH OF NAME FIELD.       23800013
DD060   BAL   RH,DDNXT                GET NEXT CHAR       22459         23830001
        AR    RI,RD                   UP COUNT BY ONE     22459         23860001
        CLI   0(RC),C')'              IS IT BRACKET       22459         23890001
        BNE   DD060                   NO. SEARCH ON       22459         23920001
DD061    BAL   RH,DDNXT                GET NEXT CHAR       22459        23950001
         AR    RI,RD                   UP COUNT BY ONE     22459        23980001
        CLI   0(RC),C'='              IS IT EQUATE        22459         24010001
        BE    DD070                   YES. GOOD           22459         24040001
        CLI   0(RC),C' '              NO. IS IT BLANK     22459         24070001
        BE    DD061                   YES. SEARCH ON      22459         24100001
        OI    WPFL,INVL               NO. INVALID CHAR    22459         24130001
        B     DD061                   SEARCH ON           22459         24160001
DD070    LR    BR,RI                                                    24300013
         AH    BR,WOFD+CURL                                             24400013
         SH    BR,WNAM+CURL                                             24500013
         BCTR  BR,0                                                     24600013
         ST    BR,WSSS+4                SET LENGTH OF SUBSCRIPTS FIELD. 24700013
         B     DD090                                                    24800013
         SPACE                                                          24900013
DD080    LR    BR,RI                                                    25000013
         AH    BR,WOFD+CURL                                             25100013
         ST    BR,WNAM+4                SET LENGTH OF NAME FIELD.       25200013
         SPACE                                                          25300013
*   'FLUSH' BLANKS BETWEEN EQUATE SIGN AND VALUE FIELD.                 25400013
         SPACE                                                          25500013
DD090    BAL   RH,DDNXT              $  GET NEXT CHARACTER.             25600013
         AR    RI,RD                                                    25700013
         CLI   0(RC),C' '               TEST FOR BALNK.                 25800013
         BE    DD090                    YES.                            25900013
         SPACE                                                          26000013
         BCTR  RI,0                     NO, END OF 'FLUSH'.             26100013
         STH   RI,WSDS+4                PART OF NAME STILL IN BUFFER.   26200013
         AH    RI,WOFD+CURL             TOTAL LENGTH OF NAME.           26300013
         ST    RI,WODF+4                                                26400013
         LA    RA,IVDA                                                  26500013
         LA    RB,WSDS                                                  26600013
         OI    WPFL,TERM                                                26700013
         MVC   WADF(8),WODF                                       19644 26750017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI999-TSS 26770000
         L     BR,VLDIC              $$ CALL LDI TO SCAN VALUE FIELD.   26800013
*        ----------------------------------------------------DDI999-TSS 26850000
         BALR  LR,BR                                                    26900013
         MVC   WODF(8),WADF                                       19644 26950017
         B     *+4(BR)                BR                                27000013
         NI    WPFL,255-TERM         /0 ITEM FOUND BUT NOT THE LAST.    27100013
         B     DNEOF                  4 LAST ITEM FOUND.                27200013
         B     DIEOF                  8 END OF FILE BEFORE END OF FIELD 27300013
         SPACE                                                          27400013
DNEOF    NI    IVDA+2,255-NTRF       /  CLEAR ENTRY FLAGS.              27500013
         LM    RB,RC,WOFD               SDV FOR DATAFIELD.              27600013
         ST    RB,WNAM                  SET ADDRESS OF NAME FIELD.      27700013
         AH    RB,WODF+CURL                                             27800013
         SH    RC,WODF+CURL                                             27900013
         MVC   WODF(8),WOFD                                             28000013
         STM   RB,RC,WOFD               SDV FOR SOURCEFIELD.            28100013
         LM    RB,RC,WNAM                                               28200013
         LR    BR,RB                                                    28300013
         AR    BR,RC                    ADDRESS OF SUBS FIELD IF ANY.   28400013
         ST    BR,WSSS                                                  28500013
         TM    WPFL,INVL             +  INVALID FIELD.            22459 28530001
         BO    ERROR                    YES RAISE NAME.           22459 28560001
         BCTR  RC,0                                               45925 28580056
         LTR   RC,RC                    WAS NAME FIELD OMITTED..        28600013
         BZ    ERROR                    YES RAISE 'NAME' CONDITION      28700013
         LA    R0,9(RC)                                                 28900013
         IHEPRV VDA,BR               $$ GET CORE TO COLLECT NAME        29000015
         BALR  LR,BR                                                    29100013
         OI    WNGW,FNGT           SET NAME VDA  GOT          CAS 45929 29150056
         SR    RI,RI                    CLEAR COUNT                     29200013
         LA    RE,8(RA)                                                 29300013
         SPACE                                                          29400013
*   COLLECT NAME FIELD                                                  29500013
         SPACE                                                          29600013
SCANN    CLI   0(RB),C' '               TEST FOR BLANK.                 29700013
         BE    BLANK                                                    29800013
         CLI   0(RB),C'.'               TEST FOR A PERIOD.              29900013
         BE    PRIOD                                                    30000013
         TM    WPFL,BLNK+PERD        +  ARE SWITCHES SAME..             30100013
         BM    ERROR                    NO.                             30200013
         NI    WPFL,255-BLNK-PERD    /  UNSET SWITCHES.                 30300013
MOVEP    MVC   1(1,RE),0(RB)                                            30400013
         AR    RI,RD                                                    30500013
         AR    RE,RD                                                    30600013
UPDAT    AR    RB,RD                                                    30700013
         BCT   RC,SCANN                 LOOP OVER SOURCE NAME FIELD     30800013
         CH    RI,H255                  ARE THERE MORE THAN 255 CHARS.. 30900013
         BH    ERROR                    YES RAISE 'NAME' CONDITION.     31000013
         STC   RI,8(RA)                 NO, SET LENGTH OF NAME.         31100013
         SPACE                                                          31200013
*   SEARCH SYMTAB.                                                      31300013
         SPACE                                                          31400013
         L     RD,WPRA                  ADDRESS PLIST.                  31500013
         TM    WPFL,NTRY             +  ENTRY A..                       31600013
         BZ    RESTR                    YES, RESTRICTED READ.           31700013
         SPACE                                                          31800013
*   SEARCH WHOLE OF SYMTAB KNOWN AT THIS POINT.                         31900013
         SPACE                                                          32000013
         LR    RC,RD                    FIRST ENTRY ADDRESS.            32100013
COMPU    L     RC,0(RC)                 ADDRESS IT.                     32200013
         USING SYMTABF,RC                                               32300013
         LTR   RC,RC                    IS THERE AN ENTRY..             32400013
         BZ    ERROR                    NO, RAISE 'NAME' CONDITION.     32500013
         EX    RI,CLCHR                 YES, IS THIS THE REQUIRED NAME  32600013
         BE    FOUND                    YES.                            32700013
         B     COMPU                    NO, CONTINUE SEARCH.            32800013
         SPACE                                                          32900013
*   SEARCH THOSE ENTRIES SPECIFIED IN PLIST.                            33000013
         SPACE                                                          33100013
COMPR    TM    0(RD),X'80'           +  END OF LIST.                    33200013
         BO    ERROR                    YES, RAISE 'NAME' CONDITION.    33300013
         LA    RD,4(RD)                 NEXT ENTRY ADDRESS.             33400013
RESTR    L     RC,0(RD)              .  ADDRESS ENTRY.                  33500013
         EX    RI,CLCHR                 IS THIS THE REQUIRED NAME..     33600013
         BNE   COMPR                    NO, CONTINUE SEARCH.            33700013
         SPACE                                                          33800013
FOUND    IHEPRV FVD,BR               $$ FREE VDA FOR NAME               33900015
         BALR  LR,BR                                                    34000013
         NI    WNGW,255-FNGT       SET NAME VDA   RELEASED    CAS 45929 34050056
         ST    RC,WNAM                  SAVE ENTRY ADDRESS.             34100013
         LA    RE,8(RI,RC)                                              34200013
         N     RE,ALGN                  ADDRESS PART TWO OF ENTRY.      34300013
         USING SYMTABE,RE                                               34400013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI005-TSS 34430021
*        ----------------------------------------------------DDI005-TSS 34460021
         L     RA,SADD                  ADDR/OFFSET OF VARIABLE/DV.     34500013
         L     RB,SDED                  ADDRESS DED.                    34600013
         TM    SFLG,CLSS                TEST FOR STATIC.                34700013
         BZ    STTIC                    YES.                            34800013
         LH    BR,SPRO                  OFFSET TO ANCHOR/DISPLAY CELL.  34900013
         A     RA,0(BR,PR)              ADDRESS OF VARIABLE/DV.         35000013
         TM    SFLG,NSTC                TEST FOR STRUCTURE.             35100013
         BO    STTIC                    NO.                             35200013
         TM    0(RB),STRN               TEST FOR STRING.                35300013
         BZ    STTIC                    YES.                            35400013
         CLI   SSUB,0                   TEST FOR ARRAY.                 35500013
         BNE   STTIC                    YES.                            35600013
         L     RA,0(RA)                 ADDRESS ELEMENT FROM STRUCTDV.  35700013
STTIC    CLI   SSUB,0                   WHAT IS DIMENSIONALITY..        35800013
         BE    SCLAR                    0 - SCALAR.                     35900013
         LA    RD,WPDV                                                  36000013
         ST    RD,WADD                                                  36100013
         LA    RC,WADD                                                  36200013
         LA    RD,SSUB                                                  36300013
         LR    RH,RE                                                    36400013
         LA    RE,WSSS                                                  36500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI998-TSS 36550000
         L     BR,VDDJA              $$ CALL ARRAY ELEMENT ADRESS CALC  36600013
*        ----------------------------------------------------DDI998-TSS 36650000
         BALR  LR,BR                                                    36700013
         LR    RE,RH                                                    36800013
         L     RA,WADD                                                  36900013
         B     ASSGN                                                    37000013
         SPACE                                                          37100013
SCLAR    CLC   ZERO,WSSS+CURL           SCALAR INTERNAL - ANY SUBSCR..  37200013
         BE    ASSGN                    NO, GOOD.                       37300013
         LA    RA,ARRR                                                  37400013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI987-TSS 37450000
         L     BR,VERRC              $$ 'INVALID ARRAY DATUM'.          37500013
*        ----------------------------------------------------DDI987-TSS 37550000
         BR    BR                                                       37600013
         SPACE                                                          37700013
ASSGN    ST    RA,WNAM+4                SAVE ADDRESS OF VARIABLE.       37800013
          TM   0(RB),X'88'                                              37810015
          BNO  NTCD1                    NOT CODED ARITH.                37820015
          TM   0(RB),X'06'                                              37830015
          BZ   NTCD1                    FIXED DECIMAL.                  37840015
          LA   RA,TEMP                  CONVERT INTO TEMP               37850015
NTCD1     EQU  *                                                        37860015
         LA    RC,IVDA                                                  37900013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI997-TSS 37950000
         L     BR,VLDID              $$ CALL LDI TO ASSIGN VALUE.       38000013
*        ----------------------------------------------------DDI997-TSS 38050000
         BALR  LR,BR                                                    38100013
          TM   0(RB),X'88'                                              38106015
          BNO  NTCD2                    NOT CODED ARITH.                38112015
          TM   0(RB),X'06'                                              38118015
          BZ   NTCD2                    FIXED DECIMAL.                  38124015
        LA     BR,2                   ASSUME HALFWORD BINARY.           38126001
        TM    0(RB),X'01'             TEST FOR REAL/COMPLEX.            38128001
        BZ    SKIP1                   SKIP IF REAL.                     38130001
        AR     BR,BR                  DOUBLE UP IF COMPLEX.             38132001
SKIP1   TM    0(RB),X'02'             TEST FOR FIXED/FLOAT.             38134001
        BZ    SKIP2                   BRANCH IF FIXED.                  38136001
        AR     BR,BR                  DOUBLE UP IF FLOAT.               38138001
        TM    0(RB),X'10'             TEST FOR SHORT/LONG.              38140001
        BZ     MOVES                  SKIP IF SHORT.                    38142001
        AR     BR,BR                  DOUBLE UP IF LONG.                38144001
        B      MOVES                                                    38146001
SKIP2   TM    0(RB),X'10'             TEST FOR HALFWORD BINARY.         38148001
        BO     MOVES                  SKIP IF HALFWORD BINARY.          38150001
        AR     BR,BR                  DOUBLE UP IF FULLWORD.            38152001
MOVES     BCTR BR,0                                                     38166015
          L    RA,WNAM+4                                                38172015
          EX   BR,MVCAD                 MOVE DATA TO TARGET.            38178015
NTCD2     EQU  *                                                        38184015
         LR    RB,RE                                                    38200013
         TM    SFLG,CHCK             +  ON 'CHECK' FOR VARIABLE..       38300013
         BZ    DDEXT                    NO.                             38400013
         MVI   WNAM,ONCH                SET ON CODE FOR ONCHECK VAR.    38500013
         LA    RA,WNAM                                                  38600013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI996-TSS 38650000
         L     BR,VERRD              $$ 'CHECK(IDENTIFIER)'.            38700013
*        ----------------------------------------------------DDI996-TSS 38750000
         BALR  LR,BR                                                    38800013
DDEXT    TM    WPFL,TERM             +  TEST FOR END OF TRANSMISSION.   38900013
         BZ    DD000                    NO, PROCESS NEXT INPUT ITEM.    39000013
         TM    IVDA+2,EOFF           +  WAS EOF FOUND AT END OF FIELD.  39100013
         BO    DIEOF                    YES.                            39200013
         L     RD,OFDR(DR)              RESTORE DR.                     39300013
         L     RE,OFLR(RD)              NORMAL RETURN ADDRESS.          39400013
DEOFX    IHEPRV LW4,RC                                                  39500013
         ST    RD,OFDR(RC)                                              39600013
         LR    DR,RC                                                    39700013
         IHEPRV FVD,BR                                                  39800015
         BALR  LR,BR                                                    39900013
         LR    DR,RD                                                    40000013
         LR    LR,RE                    RETURN ADDRESS.                 40100013
DEXIT    LM    BR,PWR,OFBR(DR)          RESTORE OTHER REGISTERS.        40200013
         BR    LR                    X  RETURN.                         40300013
         EJECT                                                          40400013
BLANK    OI    WPFL,BLNK             /  SET BLANK FLAG.                 40500013
         B     UPDAT                                                    40600013
         SPACE                                                          40700013
PRIOD    TM    WPFL,PERD             +  LAST NON-BLANK A PERIOD..       40800013
         BO    ERROR                    YES, RAISE 'NAME' CONDITION.    40900013
         OI    WPFL,BLNK+PERD        /  SET BLANK AND PERIOD FLAGS.     41000013
         B     MOVEP                                                    41100013
         SPACE 10                                                       41200013
*  ROUTINE TO GET NEXT CHARACTER.                                       41300013
         SPACE                                                          41400013
DDNXT    AR    RC,RD                    NEXT SOURCE CHARACTER.          41500013
         BCTR  RE,RH                    CONTINUE UNLESS END OF BUFFER.  41600013
         TM    WPFL,LBLK                TEST FOR LEADING BLANKS.        41700013
         BO    DDGET                    YES.                            41800013
         LA    R0,16                    NO, STACK INFORMATION .         41900013
         AH    R0,WSDS+CURL                                             42000013
         IHEPRV VDA,BR               $$ GET VDA TO STACK IT             42100015
         BALR  LR,BR                                                    42200013
         MVC   8(8,RA),WSDS                                             42300013
         LA    LR,16(RA)                                                42400013
         ST    LR,8(RA)                 SET SDV FOR STACKED INFORMATION 42500013
         LR    RA,LR                                                    42600013
         LH    LR,IVDA                                                  42700013
         AR    LR,RD                                                    42800013
         STH   LR,IVDA                  INCREMENT VDA COUNT.            42900013
         LA    RG,WSDS                                                  43000013
         BAL   LR,DIMOV                 $  MOVE BUFFER TO VDA.          43100013
         LH    RA,WSDS+CURL                                             43200013
         AH    RA,WOFD+CURL                                             43300013
         STH   RA,WOFD+CURL             INCREMENT FIELD COUNT SO FAR.   43400013
DDGET    LR    RA,RF                                                    43500013
         TM    TTYP,TMST             +  TEST FOR STRING I/O.            43600013
         BO    ENDST                    YES HOW SILLY,.                 43700013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI995-TSS 43750000
         L     BR,VIOFA              $$ GET ANOTHER RECORD.             43800013
*        ----------------------------------------------------DDI995-TSS 43850000
         BALR  LR,BR                                                    43900013
         LTR   BR,BR                    TEST FOR END OF FILE.           44000013
         BZ    DDIOK                    NO.                             44100013
* ENDFILE CONDITION HAS BEEN RAISED.                                    44200013
         BAL   RD,DIVDA              $  FREE ANY VDA'S.                 44300013
DIEOF    EQU   *                                                        44310015
         TM    WPFL,LBLK             +  SCANNING LEADING BLANKS         44320015
         BZ    DIER3                 ** NO, GO RAISE ERROR              44330015
DIDOF    EQU   *                                                        44340015
         TM    TTYP,TMST           IS IT A STRING                 21183 44343001
         BO    ENDST               BR IF YES                      21183 44346001
         LH    RA,ERRA                  END OF FILE CODE                44350015
         IHEPRV ERR,RA,OP=STH                                           44360015
         L     RA,TDCL                  GET A(DCLCB)                    44370015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI994-TSS 44375000
         L     BR,VERRB                                                 44380015
*        ----------------------------------------------------DDI994-TSS 44385000
         BALR  LR,BR                 $$ RAISE ENDFILE CONDITION         44390015
         IHEPRV CFL,RE,OP=LA                                            44440015
         L     RE,4(RE)                 GET ABNORMAL RETURN ADDRESS.    44500013
         L     RD,OFDR(DR)                                              44600013
         B     DEOFX                                                    44700013
         SPACE                                                          44800013
DDIOK    LH    RD,TREM                                                  44900013
DDSET    L     RC,TCBA                                                  45000013
         STM   RC,RD,WSDS               SET UP BUFFER SDV.              45100013
         LR    RE,RD                                                    45200013
         LA    RD,1                                                     45300013
         SR    RI,RI                                                    45400013
         TM    TFLX,TMIE             +  HAS A TRANSMIT ERROR OCCURRED.. 45500013
         BCR   8,RH                     NO.                             45600013
         OI    TFLX,TMIT             /  YES, SET TRANSMIT ERROR FLAG.   45700013
         IHEPRV CFL,BR,OP=LA                                            45800013
         OI    4(BR),TCFL               SET XMIT FLAG                   45900013
         BR    RH                                                       46000013
         SPACE 3                                                        46010015
*    RAISE ERROR                                                        46020015
         SPACE                                                          46030015
DIER3    EQU   *                                                        46040015
         LA    RA,EROF                  LOAD ERROR CODE                 46050015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI993-TSS 46055000
         L     BR,VERRC                 A( ERROR ROUTINE )              46060015
*        ----------------------------------------------------DDI993-TSS 46065000
         BR    BR                    $$ RAISE ERROR                     46070015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI006-TSS 46080021
*        ----------------------------------------------------DDI006-TSS 46090021
         EJECT                                                          46100013
DIMOV    LA    RB,256                                                   46200013
         LH    BR,CURL(RG)                                              46300013
         L     RC,0(RG)                                                 46400013
TESTC    CR    BR,RB                                                    46500013
         BNH   MVRST                                                    46600013
         MVC   0(256,RA),0(RC)                                          46700013
         AR    RA,RB                                                    46800013
         AR    RC,RB                                                    46900013
         SR    BR,RB                                                    47000013
         B     TESTC                                                    47100013
MVRST    BCTR  BR,0                                                     47200013
         EX    BR,MOVEC                                                 47300013
         BR    LR                                                       47400013
MOVEC    MVC   0(*-*,RA),0(RC)                                          47500013
         SPACE 5                                                        47600013
*  FREE VDA'S.                                                          47700013
DIVDA    LH    RI,IVDA                                                  47800013
         LTR   RI,RI                    ANY TO BE FREED..               47900013
         BCR   8,RD                     NO.                             48000013
DIFRE    IHEPRV FVD,BR               $$ FREE VDA                        48100015
         BALR  LR,BR                                                    48200013
         BCT   RI,DIFRE                 CONTINUE UNTIL ALL ARE FREED.   48300013
         BR    RD                       ALL FREED.                      48400013
         SPACE 5                                                        48500013
* RAISE 'NAME' ERROR CONDITION.                                         48600013
         SPACE                                                          48700013
ERROR    TM    TTYP,TMST             +  TEST FOR GET STRING             48800013
         BO    STRNM                    YES RAISE STRING NAME ERROR.    48900013
         LH    RA,NAME                  RAISE ' NAME' CONDITION.        49000013
         IHEPRV ERR,RA,OP=STH                                           49100013
         L     RA,TDCL                  ADDRESS OF DCLCB.               49200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI992-TSS 49250000
         L     BR,VERRB                                                 49300013
*        ----------------------------------------------------DDI992-TSS 49350000
ERRR2    BALR  LR,BR                                                    49400013
         TM    WNGW,FNGT           WAS NAME VDA OBTAINED ?    CAS 45929 49410056
         BZ    DDFREVDA            NO BRANCH ROUND            CAS 45929 49420056
         IHEPRV FVD,BR                  FREE VDA FOR NAME               49430015
         BALR  LR,BR                                                    49460015
         NI    WNGW,255-FNGT       SET NAME VDA   RELEASED    CAS 45929 49470056
DDFREVDA EQU   *                                              CAS 45929 49480056
         BAL   RD,DIVDA                                                 49500013
DDTRN    TM    TFLX,TMIT             +  TEST TRANSMIT FLAG.             49600013
         BZ    DDEXT                    OFF - NO TRANSMIT ERROR.        49700013
         LH    RA,TRER                                                  49800013
         IHEPRV ERR,RA,OP=STH           SET TRANSMIT ERROR CODE.        49900013
         L     RA,TDCL                  ADDRESS OF DCLCB.               50000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI991-TSS 50050000
         L     BR,VERRB              $$ EXEP.                           50100013
*        ----------------------------------------------------DDI991-TSS 50150000
         BALR  LR,BR                                                    50200013
         B     DDEXT                                                    50300013
         SPACE                                                          50400013
STRNM    LA    RA,STRR                  RAISE STRING NAME CONDITION.    50500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI990-TSS 50550000
         L     BR,VERRC              $$ CALL ERRC UNTIL CLEAR.          50600013
*        ----------------------------------------------------DDI990-TSS 50650000
         B     ERRR2                    TO ENSURE RETURN IF PLANNED.    50700013
         SPACE                                                          50800013
DDNLT    OI    WPFL,TERM             /  SET TEMINATOR FOUND FLAG.       50900013
DDNUL    AR    RC,RD                                                    51000013
         ST    RC,TCBA                                                  51100013
         BCTR  RE,0                                                     51200013
         STH   RE,TREM                                                  51300013
         B     DDTRN                                                    51400013
         SPACE                                                          51500013
ENDST    LA    RA,NDST                                                  51600013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI989-TSS 51650000
         L     BR,VERRC                                                 51700013
*        ----------------------------------------------------DDI989-TSS 51750000
         BR    BR                                                       51800013
         EJECT                                                          51900013
*                      CONSTANTS.                                       52000013
         SPACE                                                          52100013
ZERO     DC    H'0'                                                     52200013
NAME     DC    X'8800'                                                  52300013
ARRR     DC    H'8'                                                     52400013
CLCHR    CLC   SLEN(*-*),8(RA)                                          52500013
MVCAD     MVC  0(*-*,RA),TEMP                                           52550015
H255     DC    H'255'                                                   52600013
NDST     DC    H'2'                                                     52700013
TRER     DC    X'9802'                  TRANSMIT ERROR CODE.            52800013
STRR     DC    H'4'                                                     52900013
ERRA     DC    AL2(ERR1)                END OF FILR                     52930015
EROF     DC    AL2(ERR2)                ENDFILE RAISED UNEXPECTEDLY     52960015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DDI988-TSS 52980000
VLDIC    DC    V(IHELDIC)                                               53000013
VLDID    DC    V(IHELDID)                                               53100013
VDDJA    DC    V(IHEDDJA)                                               53300013
VERRB    DC    V(IHEERRB)                                               53400013
VIOFA    DC    V(IHEIOFA)                                               53600013
VERRC    DC    V(IHEERRC)                                               53700013
VERRD    DC    V(IHEERRD)                                               53800013
*        ----------------------------------------------------DDI988-TSS 53850000
ALGN     DC    X'FFFFFFFC'                                              53900013
         END                                                            54000013
