DIA      TITLE '   IHEDIA    F/E FORMAT INPUT DIRECTOR                 *00300013
               O/S 360 PL/1 LIBRARY'                                    00600013
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  00900013
         SPACE 1                                                        00970019
* R19       423000,*                                               H438 01040019
         SPACE 1                                                        01110019
*                                                                       01200013
*   STATUS     CHANGE LEVEL - 0                                         01500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIA000-TSS 01600001
*        ----------------------------------------------------DIA000-TSS 01700001
*                                                                       01800013
*   SIZE       778 BYTES                                                02100001
*                                                                       02400013
*   FUNCTION   TO DIRECT THE CONVERSION OF EXTERNAL DATA                02700013
*              OF F OR E FORMAT TO ANY INTERNAL DATA TYPE               03000013
*                                                                       03300013
*   ENTRY POINTS                                                        03600013
*              IHEDIAA - F FORMAT INPUT                                 03900013
*                  RA = A(TARGET)                                       04200013
*                  RB = A(TARGET DED)                                   04500013
*                  RC = A(SOURCE FED)                                   04800013
*              IHEDIAB - E FORMAT INPUT                                 05100013
*                  CF IHEDIAA                                           05400013
*                                                                       05700013
*   INPUT      BIT SET IN SWITCH WSWA IN LCA IF THIS MODULE CALLED BY   06000013
*              'C' FORMAT DIRECTOR                                      06300013
*   OUTPUT     N/A                                                      06600013
*                                                                       06900013
*   EXTERNAL MODULES                                                    07200013
*              IHEIODG- REQUEST ADDRESS OF EXTERNAL DATUM               07500013
*              IHEIODT- SIGNAL CONVERSION COMPLETE                      07800013
*              IHEDMAA- ARITHMETIC CONVERSION DIRECTOR                  08100013
*              IHEUPA/IHEUPB - ZERO IMAGINARY PART OF COMPLEX           08400013
*                       CODED OR NUMERIC TARGET                         08700013
*              IHEDNC - ARITHMETIC TO CHARACTER STRING DIRECTOR         09000013
*              IHEDNB - ARITHMETIC TO BIT DIRECTOR                      09300013
*              IHEVSC - CHARACTER STRING ASSIGNMENT ROUTINE             09600013
*              IHEVSA - BIT STRING ASSIGNMENT ROUTINE                   09900013
*              IHEVCA - DYNAMIC CONSTANT ANALYSER ROUTINE               10200013
*                                                                       10500013
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              10800013
*              ABNORMAL - END FILE SIGNALLED                            11100013
*                                                                       11400013
*   TABLES/WORKAREA                                                     11700013
*              WORKAREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)          12000013
*                                                                       12300013
*   ATTRIBUTES READ ONLY AND REENTRANT                                  12600013
*                                                                       12900013
*   PRIVATE MACROS                                                      13200013
*              IHELIB,IHEPRV,IHESDR                                     13500013
*                                                                       13800013
*   ASSEMBLY REQUIREMENTS                                               14100013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   14400013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        14700013
*                                                                       15000013
*   NOTE       SEE O/S360 PL/1 LIBRARY PLM FOR DESCRIPTION OF           15300013
*              LIBRARY CONVENTIONS AND STANDARDS.                       15600013
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON        15900013
*              1 PARTICULAR INTERNAL REPRESENTATION OF THE              16200013
*              EXTERNAL CHARACTER SET.                                  16500013
         EJECT                                                          16800013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIA001-TSS 16900001
*  THE FOLLOWING MODULES MUST BE INCLUDED IF REQUIRED                   17100013
         PUNCH     ' LIBRARY *(IHEDMAA,IHEUPAB,IHEUPBB,IHEDNCA,IHEDNBA,/17400013
               IHEVSCA,IHEVSAA)     DIA0000A'                           17700013
         PUNCH     ' LIBRARY *(IHEVCAA,IHEVQBA)                        /18000013
                                    DIA0000B'                           18300013
*        ----------------------------------------------------DIA001-TSS 18400001
         SPACE                                                          18600013
IHEDIA   CSECT                                                          18900013
         IHELIB                                                         19200013
         IHEZAP                                                         19260001
TMVD     EQU   X'40'                   VDA USED SWITCH.                 19320001
TCFL     EQU   X'04'                   XMIT STACK FLAG.                 19380001
ERR1     EQU   X'9802'                 ON-CODE FOR INPUT TRANSMIT.      19440001
IHEZLW3  DSECT                                                          19500013
         DS    15D                                                      19800013
WORK     EQU   IHEZLW3                                                  20100013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIA002-TSS 20300001
*        ----------------------------------------------------DIA002-TSS 20500001
IHEDIA   CSECT                                                          20700013
         ENTRY IHEDIAA                                                  21000013
         ENTRY IHEDIAB                                                  21300013
         USING IHEZLCA,WR                                               21600013
         USING IHEZLW3,DR                                               21900013
IHEDIAA  NOPR  0                        F FORMAT ENTRY POINT            22200013
IHEDIAB  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          22500013
         BALR  RJ,0                     SET UP ADDRESSABILITY           22800013
         USING *,RJ                                                     23100013
         TM    OFBR+3(DR),X'02'         TEST ENTRY POINT                23700013
         IHESDR LW3,WR                  UPDATE SAVE AREA POINTER        24000013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  24300013
         ST    RC,WFED                  SAVE FED POINTER                24600013
         LR    RC,RA                    SET TARGET                      24900013
         LR    RD,RB                    PARAMETERS                      25200013
         BZ    SFMAT                    BRANCH IF F FORMAT ENTRY        25500013
         LA    RB,EDED                  SET FOR E FORMAT                25800013
         IHEPRV ERR,RE,OP=LA                                            26100013
         OI    1(RE),FMTE               SET UP E-FORMAT TYPE SOURCE     26400013
SIOBT    OI    0(RE),IOBT                                               26700013
         ST    RB,PWRK+8                                                26800015
         SR    RF,RF                    GET W                           27000013
         L     RE,WFED                 FROM FED.                        27200001
         AH    RF,0(RE)                                                 27400001
         BNH   TSTRG                    BRANCH IF W ZERO OR MINUS       27600013
         TM    WSWA,X'40'               TEST WHO CALLED                 27900013
         BO    TESTC                    BRANCH IF C FORMAT              28200013
         STH   RF,WSDV+6                SET UP FIELD WIDTH              28500013
         USING IHEZAPE,RH              DEFINE BASE-REG. FOR DCBAPE.     28520001
         IHEPRV CFL,RA                 ADDRESS CFL FCB,                 28540001
         LH    RA,DPRO-IHEZDCL(RA)     VIA DCLCB,                       28560001
         L     RH,0(RA,PR)             THEN FILE REGISTER.              28580001
         LR    RA,RC                    RESTORE RA.                     28600001
         TM    TFLX,TMEF               ENDFILE ALREADY ENCOUNTERED..    28620001
         BO    CIODG                   YES. CALL IODG.                  28640001
         MVC   WSDV+4(2),WSDV+6                                         28660001
         NI    WONC+2,255-TMVD         CLEAR VDA ALLOCATED FLAG.        28680001
         NI    TFLX,255-TMIT-TMLC      UNSET TMIT AND TMLC FLAGS.       28700001
         IHEPRV CFL,BR,OP=LA                                            28720001
         NI    4(BR),255-TCFL          UNSET XMIT FLAG.                 28740001
         TM    TFLX,TMIE               IS INPUT TRANSMIT ON FOR BLOCK.. 28760001
         BZ    TYPES                   NO.                              28780001
         NC    TREM,TREM               ANY LEFT IN BUFFER..             28800001
         BZ    TYPES                   NO.                              28820001
         OI    TFLX,TMIT               YES. SET DATAFIELD TRANS. ON.    28840001
         OI    4(BR),TCFL              SET XMIT FLAG.                   28860001
TYPES    LH    RI,TREM                 NUMBER OF BYTES LEFT IN RECORD.  28880001
         CH    RI,WSDV+6               BYTES WANTED GT.CURRENT REC..    28900001
         BL    CIODG                   YES. CALL IODG.                  28920001
         L     RI,TCBA                 SET A(DATAFIELD) WITHIN          28940001
         ST    RI,WSDV                 BUFFER FOR CALLER.               28960001
         TM    TFIO,TMCY               GET WITH COPY OPTION..           28980001
         BO    CIODG                   YES. CALL IODG.                  29000001
         TM    WONC+2,TMVD             NO. VDA ALLOCATED..              29020001
         BO    RETUR                   YES.                             29040001
         AH    RI,WSDV+6               NO. UPDATE BUFFER PTRS.          29060001
         ST    RI,TCBA                                                  29080001
         LH    RI,TREM                                                  29100001
         SH    RI,WSDV+6                                                29120001
         STH   RI,TREM                                                  29140001
         B     RETUR                                                    29160001
CIODG    L     BR,IODG                 GET FIELD ADDRESS                29180001
         BALR  LR,BR                   WITHIN BUFFER.                   29200001
         LTR   BR,BR                    TEST RETURN CODE                29400013
         BNZ   ABNRM                    BRANCH IF NOT ZERO              29700013
RETUR    MVC   WOFD(8),WSDV            SET ON-SOURCE DOPE VECTOR.       30000001
         LA    LR,RETRY                 STORE RETRY ENTRY POINT         30300013
         STM   DR,LR,WCNV               AND SAVE AREA ADDRESS IN LCA    30600013
TESTC    L     RA,WSDV                  SET SOURCE POINTER              30900013
         TM    0(RD),STRG               TARGET TYPE STRING              31200013
         BZ    STRNG                    YES,BRANCH                      31500013
         TM    0(RD),CADD               TEST FOR C.A.D. TARGET.         31800013
         BO    QPOSS                    YES.                            32100013
QGONE    L     BR,DMAA                  CALL ARITHMETIC                 32400013
         BALR  LR,BR                    CONVERSION DIRECTOR             32700013
TCOMP    TM    WSWA,CPLX                TEST COMPLEX FORMAT SWITCH      33000013
         BO    ENDRT                    BRANCH IF SET                   33300013
         TM    0(RD),MODE               TEST MODE OF TARGET             33600013
         BO    CALUP                    BRANCH IF COMPLEX               33900013
ENDRT    TM    WSWA,X'40'               TEST WHO CALLED                 34200013
         BO    FINIS                    BRANCH IF C FORMAT              34500013
         L     RI,TCNT                 BUMP COUNT VALUE.                34550001
         LA    RI,1(RI)                                                 34600001
         ST    RI,TCNT                                                  34650001
         TM    TFLX,TMIT               INPUT TRANSMIT ON DATAFIELD..    34700001
         BZ    ALLOC                    NO.                             34750001
         LH    RI,ERRB                  YES. SET ERROR CODE.            34800001
         IHEPRV ERR,RI,OP=STH                                           34850001
         LR    RE,RA                    SAVE RA.                        34900001
         L     RA,TDCL                  GET A(DCLCB).                   34950001
         L     BR,VERRB                                                 35000001
         BALR  LR,BR                    TELL EXEP.                      35050001
         LR    RA,RE                    RESTORE RA.                     35100001
ALLOC    TM    WONC+2,TMVD              VDA ALLOCATED..                 35150001
         BZ    FINIS                   NO.                              35200001
         NI    WONC+2,TMVD             YES. UNSET FLAG.                 35250001
         IHEPRV FVD,BR                                                  35300001
         BALR  LR,BR                   FREE VDA.                        35350001
FINIS    SR    RE,RE                    ZERO REGISTER                   35400013
         IHEPRV ERR,RE,OP=STH           RESET ERROR CODE                35700013
         L     DR,OFDR(DR)              RESET SAVE AREA POINTER         36000013
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       36300013
         SR    BR,BR                    SET CODE FOR NORMAL RETURN      36600013
         BR    LR                       EXIT                            36900013
ABNRM    TM    WSWA,X'40'               TEST C FORMAT SWITCH            37200013
         L     DR,OFDR(DR)              RESET SAVE AREA POINTER         37500013
         BO    CFRMT                    BRANCH IF SWITCH SET            37800013
         IHEPRV CFL,BR,OP=LA                                            38100013
         L     LR,4(BR)                 LOAD ADDRESS OF NEXT STATEMENT  38400013
         LM    RB,WR,OFRB(DR)           RESTORE CALLERS REGISTERS       38700013
         BR    LR                       EXIT                            39000013
CFRMT    LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       39300013
         BR    LR                       EXIT                            39600013
CALUP    LR    RA,RC                    SET PARAMETERS                  39900013
         LR    RB,RD                    FOR CALL                        40200013
         L     BR,UPAB                  SET FOR CODED TARGET            40500013
         TM    0(RB),CODE               TEST TARGET TYPE                40800013
         BO    CALLR                    BRANCH IF CODED                 41100013
         L     BR,UPBB                  SET FOR NUMBERIC TARGET         41400013
CALLR    BALR  LR,BR                    CALL ZERO IMAG.PART ROUTINE     41700013
         B     ENDRT                                                    42000013
RETRY    EQU   *                        RE-ESTABLISH I/O AND SOURCEH438 42040019
*                                       ENVIRONMENT IN ERROR SLOT. H438 42080019
*                                       IN CASE ERROR IS RAISED AGAIN.  42120019
         L     RF,OFDR(DR)              ADDRESS PREVIOUS SAVE AREA.H438 42160019
         IHEPRV ERR,RE,OP=LA            GET ERROR SLOT IN PRV.     H438 42200019
         TM    OFBR+3(RF),X'02'         TEST ENTRY POINT.          H438 42240019
         BZ    RETRY1                   BRANCH IF F-FORMAT.        H438 42280019
         OI    1(RE),FMTF               INDICATE F-FORMAT TYPE SOURCE.  42320019
         B     RETRY2                                              H438 42360019
RETRY1   OI    1(RE),FMTE               INDICATE E-FORMAT TYPE SOURCE.  42400019
RETRY2   OI    0(RE),IOBT               INDICATE I/O OPERATIVE.    H438 42440019
         L     RF,WFED                  GET ADDRESS OF FED.        H438 42480019
         LH    RF,0(RF)                 RESTORE FIELD WIDTH             42600013
         B     TESTC                    GO TRY CONVERSION AGAIN         42900013
STRNG    LA    RG,WCN1                  SET DESCRIPTOR POINTER          43200013
         ST    RG,WCNP                  IN COMMUNICATION AREA           43500013
         ST    RA,WCN1                  SET DATA START ADDRESS          43800013
         AR    RF,RA                    CALC.END ADDRESS                44100013
         BCTR  RF,0                     AND STORE                       44400013
         ST    RF,WCN1+4                IN DESCRIPTOR                   44700013
         LA    RA,PWRK                  ALLOCATE DED                    45000013
         L     BR,VCAA                  CALL                            45300013
         BALR  LR,BR                    DATA ANALYSIS ROUTINE           45600013
         B     STAR4(BR)                TEST RETURN CODE                45900013
STAR4    B     ADDDS                    BRANCH IF ZERO                  46200013
TESTF    CLI   0(RB),FMAT               TEST FOR F-FORMAT               46500013
         BNE   SETDD                                                    46800013
         SR    RF,RF                    ZERO REGISTERS                  47100013
         LR    RG,RF                                                    47400013
         IC    RF,PWRK+2                GET S FROM CREATED DED          47700013
         L     RE,WFED                                                  47900001
         IC    RG,3(RE)                GET S FROM FED.                  48100001
         SR    RF,RG                    COMBINE                         48300013
         AH    RF,K128                  RESTORE EXCESS                  48600013
         STC   RF,PWRK+2                STORE IN CREATED DED            48900013
SETDD    MVC   PWRK(1),0(RB)            SET TRUE FORMAT FLAG BYTE       49200013
         LA    RB,PWRK                  SET SOURCE DED POINTER          49500013
         L     RA,WSDV                  SET SOURCE POINTER              49800013
         L     BR,DNCA                  SET FOR CHARACTER STRING TARGET 50100013
         TM    0(RD),CHAR               TEST TARGET TYPE                50400013
         BO    CALLR                    BRANCH IF CHARACTER             50700013
         L     BR,DNBA                  SET FOR BIT STRING TARGET       51000013
         B     CALLR                    GO CALL ASSIGNMENT ROUTINE      51300013
SFMAT    LA    RB,FDED                  SET FOR F FORMAT                51600013
         IHEPRV ERR,RE,OP=LA                                            51900013
         OI    1(RE),FMTF               SET UP F-FORMAT TYPE SOURCE     52200013
         B     SIOBT                                                    52500013
TSTRG    TM    0(RD),STRG               TEST TARGET TYPE                52800013
         BO    FINIS                    BRANCH NOT STRING               53100013
         LA    RA,NULD                  SET NULL DOPE VECTOR POINTER    53400013
         LA    RB,CDED                  SET FOR CHARACTER STRING        53700013
         L     BR,VSCA                  SET TO ASSIGN CHAR STRING       54000013
         TM    0(RD),CHAR               TEST TARGET STRING TYPE         54300013
         BO    CALSA                    BRANCH IF CHARACTER             54600013
         LA    RB,BDED                  SET FOR BIT STRING              54900013
         L     BR,VSAA                  SET TO ASSIGN BIT STRING        55200013
CALSA    BALR  LR,BR                    CALL ASSIGNMENT ROUTINE         55500013
         B     FINIS                                                    55800013
ADDDS    SR    RF,RF                                                    56100013
         L     RE,WFED                                                  56300001
         IC    RF,2(RE)                GET D FROM FED.                  56500001
         AH    RF,K128                  ADD EXCESS                      56700013
         STC   RF,PWRK+2                STORE IN CREATED FED            57000013
         B     TESTF                                                    57300013
         SPACE                                                          57600013
QPOSS    EQU   *                                                        58200001
         NI    WSWB,255-3               RESET SWITCH BITS.              58800013
         L     RB,PWRK+8                                                58900015
         TM    0(RB),FLOT               SET                             59100013
         BZ    QEFFF                    WSWB                            59400013
         OI    WSWB,2                   ACCORDING                       59700013
         B     QCALL                    TO                              60000013
QEFFF    OI    WSWB,1                   FORMAT.                         60300013
QCALL    EQU   *                                                        60400001
         L     BR,VQBA                  GET A(IHEVQB).                  60500001
         LTR   BR,BR                    IS THE MODULE PRESENT.          60600001
         BZ    QGONE                    NO. USE IHEDMA.                 60700001
         LH    BR,0(BR)                 GET TOP TWO BYTES OF VCON.      60707001
         CH    BR,XFER               +  IS IT A TRANSFER VECTOR.        60714001
         L     BR,VQBA                  GET VCON ONCE AGAIN.            60721001
         BNE   SHRLIB                *  NO. MUST BE A(CONV MODULE).     60728001
         LR    R0,RA                    SAVE REGISTER ONE.              60735001
         LH    LR,2(BR)                 STEP DOWN TRANSFER              60742001
         LH    RA,6(BR)                  VECTOR UNTILL THE              60749001
         L     BR,0(LR,PR)               REAL VCON IS                   60756001
         L     BR,0(RA,BR)               LOADED INTO BR.                60763001
         LR    RA,R0                    RESTORE REGISTER ONE.           60770001
         LTR   BR,BR                 +  IS THE MODULE PRESENT.          60777001
         BZ    QGONE                 *  NO. USE IHEDMA.                 60784001
SHRLIB   EQU   *                                                        60791001
         LR    RB,RA                    YES. USE IHEVQB.                60800001
         L     RE,WFED                                                  60900013
         AH    RB,0(RE)                                                 61200013
         BCTR  RB,0                     FIND LAST CHARACTER.            61500013
QLOOP    CLI   0(RA),C' '               REMOVE LEADING BLANKS.          61800013
         BNE   QTAIL                                                    62100013
         CR    RA,RB                    ALL BLANK ?                     62400013
         BE    CVQBA                    YES.                            62700013
         LA    RA,1(RA)                 FIND FIRST NON-BLANK CHARACTER. 63000013
         B     QLOOP                                                    63300013
QTAIL    CLI   0(RB),C' '               FIND LAST NON BLANK CHAR.       63600013
         BNE   CVQBA                                                    63900013
         BCT   RB,QTAIL                                                 64200013
CVQBA    BALR  LR,BR                    CALL CONVERSION.                64500013
         B     TCOMP                                                    64800013
         SPACE                                                          65100013
K128     DC    H'128'                                                   65400013
EDED     DC    X'CA'                                                    65700013
FDED     DC    X'C8'                                                    66000013
CDED     DC    X'1C'                    VARIABLE LENGTH CHAR.STR.DED    66300013
BDED     DC    X'18'                                                    66600013
IODG     DC    V(IHEIODG)                                               66900013
IODT     DC    V(IHEIODT)                                               67200013
DMAA     DC    V(IHEDMAA)                                               67500013
UPAB     DC    V(IHEUPAB)                                               67800013
UPBB     DC    V(IHEUPBB)                                               68100013
DNCA     DC    V(IHEDNCA)                                               68400013
DNBA     DC    V(IHEDNBA)                                               68700013
VSCA     DC    V(IHEVSCA)                                               69000013
VQBA     DC    V(IHEVQBA)                                               69300013
VSAA     DC    V(IHEVSAA)                                               69600013
VCAA     DC    V(IHEVCAA)                                               69900013
NULD     DC    A(*)                                                     70200013
         DC    F'0'                                                     70500013
FMTF     EQU   X'01'                                                    70800013
FMTE     EQU   X'02'                                                    71100013
FMAT     EQU   X'C8'                    F-FORMAT FLAG BYTE              71400013
IOBT     EQU   X'80'                                                    71700013
ZERO     EQU   X'00'                                                    72000013
STRG     EQU   X'80'                                                    72300013
CPLX     EQU   X'01'                                                    72600013
MODE     EQU   X'01'                                                    72900013
CODE     EQU   X'08'                                                    73200013
CHAR     EQU   X'04'                                                    73500013
PWRK     EQU   WORK+72                                                  73800013
CADD     EQU   X'88'                                                    74100013
FLOT     EQU   X'02'                                                    74400013
VERRB    DC    V(IHEERRB)              EXEP (ON CONDITIONS).            74500001
ERRB     DC    AL2(ERR1)                                                74600001
         DS    0H                                                       74630001
XFER     DC    X'58FC'                                                  74660001
         END                                                            74700013
