DIB      TITLE '   IHEDIB    A AND CP FORMAT INPUT DIRECTOR            *00020000
               O/S 360 PL/1 LIBRARY'                                    00040000
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  00060000
*                                                                       00080000
*   STATUS     CHANGE LEVEL - 0                                         00100000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIB000-TSS 00106001
*        ----------------------------------------------------DIB000-TSS 00112001
*                                                                       00120000
*   SIZE       272 BYTES                                                00140000
*                                                                       00160000
*   FUNCTION   TO DIRECT THE CONVERSION OF EXTERNAL DATA DESCRIBED      00180000
*              BY A FORMAT OR CHARACTER PICTURE FORMAT TO ANY           00200000
*              INTERNAL DATA TYPE                                       00220000
*                                                                       00240000
*   ENTRY POINTS                                                        00260000
*              IHEDIBA - A FORMAT                                       00280000
*                  RA = A(TARGET/TARGET DOPE VECTOR)                    00300000
*                  RB = A(TARGET DED)                                   00320000
*                  RC = A(FED)                                          00340000
*              IHEDIBB - CHARACTER PICTURE FORMAT                       00360000
*                  AS FOR IHEDIBA                                       00380000
*                                                                       00400000
*   INPUT      N/A                                                      00420000
*                                                                       00440000
*   OUTPUT     N/A                                                      00460000
*                                                                       00480000
*   EXTERNAL MODULES                                                    00500000
*              IHEDCN -ARITHMETIC TO CHARACTER STRING CONVERSION        00520000
*              IHEIOD -TO GET EXTERNAL DATA ADDRESS                     00540000
*              IHEKCD -TO CHECK DATA AGAINST CHARACTER PICTURE          00560000
*              IHEVSC -CHARACTER STRING ASSIGNMENT                      00580000
*              IHEVSD -CHARACTER TO BIT CONVERSION                      00600000
*              IHEVSE -CHARACTER TO PICTURED CHARACTER CONVERSION       00620000
*                                                                       00640000
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              00660000
*              ABNORMAL - AFTER ENDFILE CONDITION HAS BEEN RAISED       00680000
*                         CONTROL IS PASSED TO THE NEXT LANGUAGE        00700000
*                         STATEMENT(POINTED TO BY IHEQCFL)              00720000
*                                                                       00740000
*   TABLES/WORKAREA                                                     00760000
*              WORK AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)         00780000
*                                                                       00800000
*   ATTRIBUTES READ ONLY AND REENTRANT                                  00820000
*                                                                       00840000
*   PRIVATE MACROS                                                      00860000
*              IHELIB,IHEPRV,IHESDR                                     00880000
*                                                                       00900000
*   ASSEMBLY REQUIREMENTS                                               00920000
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   00940000
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        00960000
*                                                                       00980000
*   NOTES      SEE O/S 360 PL/1 LIBRARY PLM FOR LIBRARY MODULE          01000000
*              CONVENTIONS AND STANDARDS                                01020000
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON        01040000
*              A PARTICULAR INTERNAL REPRESENTATION OF THE              01060000
*              EXTERNAL CHARACTER SET.                                  01080000
         EJECT                                                          01100000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIB001-TSS 01110001
*  THE FOLLOWING MODULES MUST BE INCLUDED IF REQUIRED                   01120000
         PUNCH     ' LIBRARY *(IHEDMAA,IHEUPAB,IHEUPBB,IHEVSCA,IHEVSDA,/01140000
               IHEVSEA,IHEKCDA)     DIB0000A'                           01160000
*        ----------------------------------------------------DIB001-TSS 01170001
         SPACE                                                          01180000
IHEDIB   CSECT                                                          01200000
         IHELIB                                                         01220000
IHEZLW3  DSECT                                                          01240000
         DS    15D                                                      01260000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIB002-TSS 01270001
IHEQCFL  DXD   2A                                                       01280000
*        ----------------------------------------------------DIB002-TSS 01290001
IHEDIB   CSECT                                                          01300000
         ENTRY IHEDIBA                                                  01320000
         ENTRY IHEDIBB                                                  01340000
         USING IHEZLCA,WR                                               01360000
         USING IHEZLW3,DR                                               01380000
IHEDIBA  NOPR  0                        A-FORMAT ENTRY POINT            01400000
IHEDIBB  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          01420000
         BALR  RJ,0                     SET UP ADDRESSABILITY           01440000
         USING *,RJ                                                     01460000
         LR    RI,DR                    SAVE ENTRY POINT REFERENCE      01480000
         LR    RH,RC                    SAVE FED POINTER                01500000
         IHESDR LW3,WR                  UPDATE SAVE AREA POINTER        01520000
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  01540000
         LR    RC,RA                    SET TARGET                      01560000
         LR    RD,RB                    PARAMETERS                      01580000
SIOBT    IHEPRV ERR,RE,OP=LA            GET ADDRESS OF ERROR CODE       01600000
         OI    0(RE),IOBT               SET FOR                         01620000
         LR    RF,RH                    GET POINTER                     01640000
         TM    OFBR+3(RI),X'02'         TEST ENTRY POINT                01660000
         BZ    MVCHR                    BRANCH IF A FORMAT              01680000
         LA    RF,1(RF)                 MOVE POINTER                    01700000
MVCHR    MVC   WSDV+6(2),0(RF)          GET LENGTH FROM FED             01720000
         SR    RF,RF                    GET W                           01740000
         AH    RF,WSDV+6                FROM SDV                        01760000
         BNH   TSTRG                    BRANCH IF W ZERO OR MINUS       01780000
         L     BR,IODG                  GET FIELD ADDRESS               01800000
         BALR  LR,BR                    WITHIN BUFFER                   01820000
         LTR   BR,BR                    TEST RETURN CODE                01840000
         BNZ   ABNRM                    BRANCH IF NOT ZERO              01860000
         MVC   WOFD(8),WSDV             SET ON FIELD DOPE VECTOR        01880000
RETRY    L     RA,WSDV                  LOAD SOURCE ADDRESS             01900000
         TM    OFBR+3(RI),X'02'         TEST ENTRY POINT                01920000
         BZ    NOPIC                    NOT A PICTURE CHARACTER FORMAT  01940000
         LR    RB,RH                    SET FED POINTER                 01960000
         LA    LR,RETRY                 STORE RETRY ENTRY POINT AND     01980000
         STM   DR,LR,WCNV               SAVE AREA ADDRESS IN LCA.       02000000
         L     BR,KCDA                  CALL PICTURE                    02020000
         BALR  LR,BR                    CHECK                           02040000
NOPIC    LA    RB,CDED                  SOURCE DED                      02060000
         LA    RA,WSDV                  SOURCE SDV                      02080000
         TM    0(RD),STRG               TARGET TYPE STRING              02100000
         BZ    STRNG                    YES,BRANCH                      02120000
         L     BR,DCNA                  CALL CHARACTER                  02140000
         BALR  LR,BR                    TO ARITHMETIC CONVERSION        02160000
ENDRT    L     BR,IODT                  TERMINAL CALL                   02180000
         BALR  LR,BR                    TO FREE ANY VDA.                02200000
FINIS    SR    RE,RE                    ZERO REGISTER                   02220000
         IHEPRV ERR,RE,OP=STH           RESET ERROR CODE                02240000
         L     DR,OFDR(DR)              RESET SAVE AREA POINTER         02260000
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       02280000
         BR    LR                       EXIT                            02300000
ABNRM    IHEPRV CFL,BR,OP=LA                                            02320000
         L     LR,4(BR)                 LOAD ADDRESS OF NEXT STATEMENT  02340000
         L     DR,OFDR(DR)              RESET SAVE AREA POINTER         02360000
         LM    RB,WR,OFRB(DR)           RESTORE CALLERS REGISTERS       02380000
         BR    LR                       EXIT                            02400000
STRNG    LA    RG,ENDRT                 SET UP RETURN ADDRESS           02420000
COMON    L     BR,VSDA                  SET UP CHARACTER TO BIT         02440000
         TM    0(RD),CHAR               TEST FOR CHARACTER TARGET       02460000
         BZ    CALEB                                                    02480000
         L     BR,VSCA                  SET UP CHARACTER TO CHARACTER   02500000
         TM    0(RD),PICK               TEST FOR PICTURE TARGET         02520000
         BO    CALEB                                                    02540000
         L     BR,VSEA                  SET UP CHARCTER TO CHAR PIC     02560000
CALEB    BALR  LR,BR                    CALL CONVERSION                 02580000
         BR    RG                                                       02600000
TSTRG    TM    0(RD),STRG               TEST TARGET TYPE                02620000
         BO    FINIS                    BRANCH NOT STRING               02640000
         LA    RA,NULD                  SET NULL DOPE VECTOR POINTER    02660000
         LA    RB,CDED                  SET FOR CHARACTER STRING        02680000
         LA    RG,FINIS                 SET UP RETURN ADDRESS           02700000
         B     COMON                    GO TO ASSIGN NULL STRING        02720000
CDED     DC    X'1C'                    VARIABLE LENGTH CHAR.STR.DED    02740000
VSDA     DC    V(IHEVSDA)                                               02760000
VSEA     DC    V(IHEVSEA)                                               02780000
KCDA     DC    V(IHEKCDA)                                               02800000
DCNA     DC    V(IHEDCNA)                                               02820000
IODG     DC    V(IHEIODG)                                               02840000
IODT     DC    V(IHEIODT)                                               02860000
VSCA     DC    V(IHEVSCA)                                               02880000
NULD     DC    A(*)                                                     02900000
         DC    F'0'                                                     02920000
IOBT     EQU   X'80'                                                    02940000
ZERO     EQU   X'00'                                                    02960000
STRG     EQU   X'80'                                                    02980000
PICK     EQU   X'08'                                                    03000000
CHAR     EQU   X'04'                                                    03020000
         END                                                            03040000
