DID      TITLE '   IHEDID    B FORMAT INPUT DIRECTOR                   *00020000
               O/S 360 PL/1 LIBRARY'                                    00040000
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  00060000
*                                                                       00080000
*   STATUS     CHANGE LEVEL -0                                          00100000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DID000-TSS 00106001
*        ----------------------------------------------------DID000-TSS 00112001
*                                                                       00120000
*   SIZE       456 BYTES                                                00140000
*                                                                       00160000
*   FUNCTION   TO DIRECT THE CONVERSION OF EXTERNAL DATA DESCRIBED BY   00180000
*              A 'B' FORMAT ITEM, TO ANY INTERNAL DATA TYPE             00200000
*                                                                       00220000
*   ENTRY POINTS                                                        00240000
*              IHEDIDA                                                  00260000
*                  RA = A(TARGET/TARGET DOPE VECTOR)                    00280000
*                  RB = A(TARGET DED)                                   00300000
*                  RC = A(FED)                                          00320000
*                                                                       00340000
*   INPUT      N/A                                                      00360000
*                                                                       00380000
*   OUTPUT     N/A                                                      00400000
*                                                                       00420000
*   EXTERNAL MODULES                                                    00440000
*              IHEDMA - ARITHMETIC CONVERSION DIRECTOR                  00460000
*              IHEIOD - TO GET EXTERNAL DATA ADDRESS                    00480000
*              IHEUPA - TO ZERO IMAGINARY PART OF CODED                 00500000
*                       COMPLEX TARGET                                  00520000
*              IHEUPB - TO ZERO IMAGINARY PART OF NUMERIC               00540000
*                       COMPLEX TARGET                                  00560000
*              IHEVSC - CHARACTER STRING ASSIGNMENT ROUTINE             00580000
*              IHEVSD - CHARACTER TO BIT CONVERSION                     00600000
*              IHEVSE - CHARACTER TO PICTURED CHARACTER CONVERSION      00620000
*                                                                       00640000
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              00660000
*              ABNORMAL - PASS CONTROL TO NEXT LANGUAGE STATEMENT,IF    00680000
*                         ENDFILE CONDITION WAS RAISED BY IHEIOD.       00700000
*              ERROR - CALL EXECUTION ERROR PACKAGE TO RAISE CONVERSION 00720000
*                      CONDITION IF EXTERNAL DATA CONTAINS CHARACTERS   00740000
*                      OTHER THAN ONE OR ZERO.                          00760000
*                                                                       00780000
*   TABLES/WORK AREA                                                    00800000
*              WORK AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS).        00820000
*                                                                       00840000
*   PRIVATE MACROS                                                      00860000
*              IHELIB,IHEPRV,IHESDR                                     00880000
*                                                                       00900000
*   ASSEMBLY REQUIREMENTS                                               00920000
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   00940000
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        00960000
*                                                                       00980000
*   NOTE       SEE O/S 360 PL/1 LIBRARY PLM FOR LIBRARY MODULE          01000000
*              CONVENTIONS AND STANDARDS.                               01020000
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    01040000
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    01060000
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  01080000
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  01100000
*              CONSTANTS,BY REASSEMBLY,WILL RESULT IN A CORRECT MODULE  01120000
*              FOR THE NEW DEFINITIONS.                                 01140000
*                                                                       01160000
*   ATTRIBUTES READ ONLY AND REENTRANT                                  01180000
         EJECT                                                          01200000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DID001-TSS 01210001
*  THE FOLLOWING MODULES MUST BE INCLUDED IF REQUIRED                   01220000
         PUNCH     ' LIBRARY *(IHEDMAA,IHEUPAB,IHEUPBB,IHEVSCA,IHEVSEA,/01240000
               IHEVSDA)             DID0000A'                           01260000
*        ----------------------------------------------------DID001-TSS 01270001
         SPACE                                                          01280000
IHEDID   CSECT                                                          01300000
         IHELIB                                                         01320000
IHEZLW3  DSECT                                                          01340000
         DS    15D                                                      01360000
WORK     EQU   IHEZLW3                                                  01380000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DID002-TSS 01390001
IHEQCFL  DXD   2A                                                       01400000
*        ----------------------------------------------------DID002-TSS 01410001
IHEDID   CSECT                                                          01420000
         ENTRY IHEDIDA                                                  01440000
         USING IHEZLCA,WR                                               01460000
         USING IHEZLW3,DR                                               01480000
IHEDIDA  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          01500000
         BALR  RJ,0                     SET UP ADDRESSABILITY           01520000
         USING *,RJ                                                     01540000
         LR    RH,RC                    SAVE FED POINTER                01560000
         IHESDR LW3,WR                  UPDATE SAVE AREA POINTER        01580000
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  01600000
         LR    RC,RA                    SET TARGET                      01620000
         LR    RD,RB                    PARAMETERS                      01640000
SIOBT    IHEPRV ERR,RE,OP=LA            GET ADDRESS OF ERROR CODE       01660000
         OI    0(RE),IOBT               SET FOR                         01680000
         SR    RF,RF                    GET W                           01700000
         AH    RF,0(RH)                 FROM FED                        01720000
         BNH   TSTRG                    BRANCH IF W ZERO OR MINUS       01740000
         STH   RF,WSDV+6                SET UP FIELD WIDTH              01760000
         L     BR,IODG                  GET FIELD ADDRESS               01780000
         BALR  LR,BR                    WITHIN BUFFER                   01800000
         LTR   BR,BR                    TEST RETURN CODE                01820000
         BNZ   ABNRM                    BRANCH IF NOT ZERO              01840000
         MVC   WOFD(8),WSDV             SET ON FIELD DOPE VECTOR        01860000
RETRY    L     RG,WSDV                  LOAD SOURCE ADDRESS             01880000
         LH    RF,WSDV+6                GET SOURCE LENGTH               01900000
TESTB    CLI   0(RG),C' '               TEST SOURCE                     01920000
         BE    LOOPB                    BRANCH IF LEADING BLANK         01940000
         ST    RG,TPDV                 SAVE STRING START ADDRESS        01960000
CHECK    CLI   0(RG),C'0'               TEST SOURCE                     01980000
         ST    RG,WOCH                  SET POSSIBLE ERROR ADDRESS      02000000
         BE    COUNT                   BRANCH IF CHARACTER ZERO         02020000
         CLI   0(RG),C'1'               TEST SOURCE                     02040000
         BE    COUNT                    BRANCH IF CHARACTER ONE         02060000
         CLI   0(RG),C' '               TEST SOURCE                     02080000
         BE    SAVEA                    BRANCH IF TRAILING BLANK        02100000
         BAL   RB,ERCAL                 GO TO ERROR ROUTINE             02120000
         B     COUNT                    CONTINUE IF RETURN              02140000
SAVEA    ST    RG,TPDV+4                SAVE END OF STRING ADDRESS      02160000
         B     ERRET                                                    02180000
BUMPG    LA    RG,1(RG)                 BUMP SCAN ADDRESS               02200000
         CLI   0(RG),C' '               TEST SOURCE                     02220000
         ST    RG,WOCH                  SAVE POSSIBLE ERROR ADDRESS     02240000
         BE    ERRET                    BRANCH IFTRAILING BLANK         02260000
         BAL   RB,ERCAL                 GO TO ERROR ROUTINE             02280000
ERRET    BCT   RF,BUMPG                 TEST FOR END OF STRING AND LOOP 02300000
         L     RG,TPDV+4                CALCULATE                       02320000
STTTT    S     RG,TPDV                  LENGTH OF                       02340000
         STH   RG,TPDV+4                STRING AND STORE                02360000
         STH   RG,TPDV+6                IN DOPE VECTOR                  02380000
         B     SETUP                    GO CONVERT TO BIT STRING        02400000
LOOPB    LA    RG,1(RG)                 BUMP SCAN ADDRESS               02420000
         BCT   RF,TESTB                 TEST FOR END OF STRING AND LOOP 02440000
         BCTR  RG,0                     GET END OF STRING ADDRESS       02460000
         ST    RG,WOCH                  STORE AS ERROR POINTER          02480000
         BAL   RB,ERCAL                 GO TO ERROR ROUTINE             02500000
         B     ENDRT                    CONTINUE IF RETURN              02520000
COUNT    LA    RG,1(RG)                 BUMP SCAN ADDRESS               02540000
         BCT   RF,CHECK                 LOOP IF NOT END OF STRING       02560000
         B     STTTT                                                    02580000
SETUP    LA    RB,CDED                  SET UP SOURCE DED AND           02600000
         LA    RA,TPDV                  DOPE VECTOR ADDRESS             02620000
         TM    0(RD),STRG               TARGET TYPE STRING              02640000
         BZ    STRNG                                                    02660000
         LA    RB,BTDD                  BIT CONSTANT DED                02680000
         L     RA,TPDV                  SET UP FIRST                    02700000
         ST    RA,WCN1                  AND LAST ADDRESS                02720000
         AH    RA,TPDV+6                IN WCN1                         02740000
         BCTR  RA,0                                                     02760000
         ST    RA,WCN1+4                                                02780000
         L     BR,DMAA                  CONVERT                         02800000
         BALR  LR,BR                                                    02820000
         TM    0(RD),CPLX               ZERO IMAGINARY                  02840000
         BZ    ENDRT                    PART IF COMPLEX                 02860000
         L     BR,UPAB                  CAD                             02880000
         TM    0(RD),PICK                                               02900000
         BO    NOPIC                    OR                              02920000
         L     BR,UPBB                  PICTURE                         02940000
NOPIC    BALR  LR,BR                                                    02960000
ENDRT    L     BR,IODT                  TERMINAL CALL                   02980000
         BALR  LR,BR                    TO FREE ANY VDA.                03000000
FINIS    SR    RE,RE                    ZERO REGISTER                   03020000
         IHEPRV ERR,RE,OP=STH           RESET ERROR CODE                03040000
         L     DR,OFDR(DR)              RESET SAVE AREA POINTER         03060000
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       03080000
         BR    LR                       EXIT                            03100000
ABNRM    IHEPRV CFL,BR,OP=LA                                            03120000
         L     LR,4(BR)                 LOAD ADDRESS OF NEXT STATEMENT  03140000
         L     DR,OFDR(DR)              RESET SAVE AREA POINTER         03160000
         LM    RB,WR,OFRB(DR)           RESTORE CALLERS REGISTERS       03180000
         BR    LR                       EXIT                            03200000
STRNG    LA    RI,ENDRT                 SET UP RETURN ADDRESS           03220000
COMON    L     BR,VSDA                  SET UP CHARACTER TO BIT         03240000
         TM    0(RD),CHAR               TEST FOR CHARACTER TARGET       03260000
         BZ    CALEB                                                    03280000
         L     BR,VSCA                  SET UP CHARACTER TO CHARACTER   03300000
         TM    0(RD),PICK               TEST FOR PICTURE TARGET         03320000
         BO    CALEB                                                    03340000
         L     BR,VSEA                  SET UP CHARACTER TO CHAR PIC    03360000
CALEB    BALR  LR,BR                                                    03380000
         BR    RI                                                       03400000
TSTRG    TM    0(RD),STRG               TEST TARGET TYPE                03420000
         BO    FINIS                    BRANCH NOT STRING               03440000
         LA    RA,NULD                  SET NULL DOPE VECTOR POINTER    03460000
         LA    RB,CDED                  SET FOR CHARACTER STRING        03480000
         LA    RI,FINIS                 SET UP RETURN ADDRESS           03500000
         B     COMON                                                    03520000
ERCAL    OI    0(RE),CONV                                               03540000
         OI    1(RE),FMTB               SET UP B-FORMAT SOURCE          03560000
         LA    LR,RETRY                 STORE RETRY ENTRY POINT AND     03580000
         STM   DR,LR,WCNV               SAVE AREA ADDRESS IN LCA.       03600000
         L     BR,ERRB                                                  03620000
         BALR  LR,BR                                                    03640000
         BR    RB                       CONTINUE IF RETURN              03660000
BTDD     DC    X'7D'                                                    03680000
CDED     DC    X'1C'                    VARIABLE LENGTH CHAR.STR.DED    03700000
IODG     DC    V(IHEIODG)                                               03720000
IODT     DC    V(IHEIODT)                                               03740000
DMAA     DC    V(IHEDMAA)                                               03760000
UPAB     DC    V(IHEUPAB)                                               03780000
UPBB     DC    V(IHEUPBB)                                               03800000
VSCA     DC    V(IHEVSCA)                                               03820000
VSEA     DC    V(IHEVSEA)                                               03840000
VSDA     DC    V(IHEVSDA)                                               03860000
ERRB     DC    V(IHEERRB)                                               03880000
NULD     DC    A(*)                                                     03900000
         DC    F'0'                                                     03920000
PICK     EQU   X'08'                                                    03940000
IOBT     EQU   X'80'                                                    03960000
ZERO     EQU   X'00'                                                    03980000
STRG     EQU   X'80'                                                    04000000
CPLX     EQU   X'01'                                                    04020000
CHAR     EQU   X'04'                                                    04040000
CONV     EQU   X'40'                                                    04060000
FMTB     EQU   X'03'                                                    04080000
TPDV     EQU   WORK+72                                                  04100000
         END                                                            04120000
