DIE      TITLE '   IHEDIE    NUMERIC PICTURE INPUT DIRECTOR            *00400013
               O/S 360 PL/1 LIBRARY'                                    00800013
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  01200013
*                                                                       01600013
*   STATUS     CHANGE LEVEL - 0                                         02000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIE000-TSS 02100001
*        ----------------------------------------------------DIE000-TSS 02200001
*                                                                       02400013
*   SIZE       376 BYTES                                                02800013
*                                                                       03200013
*   FUNCTION   TO DIRECT THE CONVERSION OF EXTERNAL DATA DESCRIBED BY   03600013
*              A NUMERIC PICTURE FORMAT TO ANY INTERNAL DATA TYPE.      04000013
*                                                                       04400013
*   ENTRY POINTS                                                        04800013
*              IHEDIEA                                                  05200013
*                RA = A(TARGET/TARGET DOPE VECTOR)                      05600013
*                RB = A(TARGET DED)                                     06000013
*                RC = A(FED)                                            06400013
*                                                                       06800013
*   INPUT      BIT   SET IN SWITCH WSWA IN LIBRARY COMMUNICATION AREA   07200013
*              IF CALLED BY C FORMAT DIRECTOR (IHEDIM)                  07600013
*                                                                       08000013
*   OUTPUT     N/A                                                      08400013
*                                                                       08800013
*   EXTERNAL MODULES                                                    09200013
*              IHEIOD - TO GET ADDRESS OF EXTERNAL DATA.                09600013
*              IHEKCA - TO CHECK DATA AGAINST DECIMAL PICTURE           10000013
*              IHEKCB - TO CHECK DATA AGAINST STERLING PICTURE          10400013
*              IHEDMA - ARITHMETIC CONVERSION DIRECTOR.                 10800013
*              IHEDNB - ARITHMETIC TO BIT CONVERSION                    11200013
*              IHEDNC - ARITHMETIC TO CHARACTER CONVERSION              11600013
*              IHEUPA - ZERO IMAG.PART OF CODED COMPLEX TARGET          12000013
*              IHEUPB - ZERO IMAG.PART OF NUMERIC COMPLEX TARGET        12400013
*              IHEVSD - CHARACTER TO BIT CONVERSION                     12800013
*                                                                       13200013
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              13600013
*              ABNORMAL - AFTER ENDFILE CONDITION HAS BEEN RAISED       14000013
*                         CONTROL IS PASSED TO THE NEXT LANGUAGE        14400013
*                         STATEMENT.(POINTED AT BY IHEQCFL).            14800013
*                                                                       15200013
*   TABLES/WORKAREA                                                     15600013
*              WORK AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)         16000013
*                                                                       16400013
*   ATTRIBUTES READ ONLY AND REENTRANT.                                 16800013
*                                                                       17200013
*   PRIVATE MACROS                                                      17600013
*              IHELIB,IHEPRV,IHESDR                                     18000013
*                                                                       18400013
*   ASSEMBLY REQUIREMENTS                                               18800013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   19200013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        19600013
*                                                                       20000013
*   NOTE       SEE O/S360 PL/1 LIBRARY PLM FOR LIBRARY MODULE           20400013
*              CONVENTIONS AND STANDARDS                                20800013
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON        21200013
*              A PARTICULAR INTERNAL REPRESENTATION OF THE              21600013
*              EXTERNAL CHARACTER SET                                   22000013
         EJECT                                                          22400013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIE001-TSS 22600001
*  THE FOLLOWING MODULES MUST BE INCLUDED IF REQUIRED                   22800013
         PUNCH     ' LIBRARY *(IHEKCAA,IHEKCBA,IHEDMAA,IHEVSDA,IHEVSCA,/23200013
               IHEVSEA,IHEUPAB)     DIE0000A'                           23600013
         PUNCH     ' LIBRARY *(IHEUPBB)                                /24000013
                                    DIE0000B'                           24400013
*        ----------------------------------------------------DIE001-TSS 24600001
         SPACE                                                          24800013
IHEDIE   CSECT                                                          25200013
         IHELIB                                                         25600013
IHEZLW3  DSECT                                                          26000013
         DS    15D                                                      26400013
WORK     EQU   IHEZLW3                                                  26800013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIE002-TSS 27000001
IHEQCFL  DXD   2A                                                       27200013
*        ----------------------------------------------------DIE002-TSS 27400001
IHEDIE   CSECT                                                          27600013
         ENTRY IHEDIEA                                                  28000013
         USING *,RJ                                                     28400013
         USING IHEZLCA,WR                                               28800013
         USING IHEZLW3,DR                                               29200013
IHEDIEA  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          29600013
         IHESDR LW3,WR                  UPDATE SAVE AREA POINTER        30000013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  30400013
         LR    RJ,BR                    TRANSFER BASE REGISTER          30800013
         IHEPRV ERR,RE,OP=LA            GET ADDRESS OF ERROR CODE       31200013
         OI    0(RE),IOBT               SET FOR                         31600013
         TM    WSWA,X'40'               TEST WHO CALLED                 32000013
         BO    TESTC                    BRANCH IF C FORMAT              32400013
         SR    RF,RF                    CLEAR RF                        32800013
         IC    RF,3(RC)                 WIDTH OF FIELD IN RF            33200013
         STH   RF,WSDV+6                THEN TO WSDV                    33600013
         L     BR,IODG                  FOR CALL                        34000013
         BALR  LR,BR                    TO LIBIOP                       34400013
         LTR   BR,BR                    TEST RETURN CODE                34800013
         BNZ   ABNRM                    BRANCH IF NOT ZERO              35200013
         MVC   WOFD(8),WSDV             SET ON SORCE DOPE VECTOR        35600013
         LA    LR,RETRY                 STORE RETRY ENTRY POINT AND     36000013
         STM   DR,LR,WCNV               SAVE AREA ADDRESS IN LCA        36400013
TESTC    STM   RA,RC,PWRK               STORE PARAMETERS                36800013
         SR    RI,RI                    ZERO TYPE CODE                  37200013
         TM    0(RC),BINY               TEST FOR BINARY PICTURE         37600013
         BO    BCODE                                                    38000013
         LA    RI,4(RI)                 INCREMENT TYPE CODE             38400013
         TM    0(RC),STER               TEST FOR STERLING CODE          38800013
         BZ    BCODE                                                    39200013
         LA    RI,4(RI)                 INCREMENT TYPE CODE             39600013
BCODE    L     BR,KCCA(RI)              SET BR TO PICTURE CHECK ROUTINE 40000013
         LR    RB,RC                    TRANSFER PIC TO RB              40400013
         L     RA,WSDV                  BUFFER ADDRESS IN RA            40800013
         BALR  LR,BR                    CALL A PICTURE CHECK            41200013
         LM    RC,RD,PWRK               GET TARGET PARAMETERS           41600013
         LTR   RI,RI                    TEST FOR BINARY SOURCE          42000013
         BZ    BINRY                    IF SO BRANCH                    42400013
BINRT    TM    0(RD),STRG               TEST TARGET TYPE                42800013
         BZ    STRNG                    BRANCH IF STRING                43200013
COMPR    CLC   0(1,RD),0(RB)            COMPARE FLAG BYTE               43600013
         BNE   ARITH                    NO BRANCH                       44000013
         IC    RF,4(RB)                  LENGTH OF PICTURE              44400013
         LA    RF,4(RF)                  IN RF                          44800013
         EX    RF,COMPR                 LENGTH FOR COMPARE              45200013
         BNE   ARITH                     NOT EQUAL BRANCH               45600013
         IC    RF,3(RB)                  GET WIDTH FOR MOVE             46000013
         BCTR  RF,0                      MINUS ONE                      46400013
         EX    RF,MOVER                 MOVE SOURCE TO TARGET           46800013
         B     CPLEX                                                    47200013
ARITH    L     BR,DMAA                  SET TO CALL ARITH CONVERSION    47600013
         BALR  LR,BR                    CONVERSION                      48000013
CPLEX    TM    WSWA,CPLX                TEST IMAG FORMAT SWITCH         48400013
         BO    ENDRT                    BRANCH IF SET                   48800013
         TM    0(RD),MODE               TEST MODE OF TARGET             49200013
         BO    CALUP                    BRANCH IF COMPLEX               49600013
ENDRT    TM    WSWA,X'40'               TEST WHO CALLED                 50000013
         BO    FINIS                    BRANCH IF C FORMAT              50400013
         L     BR,IODT                  TERMINAL CALL                   50800013
         BALR  LR,BR                    TO FREE ANY VDA                 51200013
FINIS    SR    RE,RE                    RESET                           51600013
         IHEPRV ERR,RE,OP=STH           ERROR CODE                      52000013
         L     DR,OFDR(DR)              RESET SAVE AREA POINTER         52400013
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       52800013
         SR    BR,BR                    SET CODE FOR NORMAL RETURN      53200013
         BR    LR                       EXIT                            53600013
CALUP    LR    RA,RC                    TRANSFER TARGET                 54000013
         LR    RB,RD                    PARAMETERS                      54400013
         L     BR,UPAB                  SET FOR CODED TARGET            54800013
         TM    0(RB),CODE               TEST TARGET TYPE                55200013
         BO    CALLR                    BRANCH IF CODED                 55600013
         L     BR,UPBB                  SET FOR NUMERIC TARGET          56000013
CALLR    BALR  LR,BR                    CALL ROUTINE TO ZERO IMAG PART  56400013
         B     ENDRT                    GO TO EXIT                      56800013
RETRY    LM    RA,RC,PWRK               RESTORE PARAMETER REGISTERS     57200013
         B     TESTC                    GO TRY AGAIN                    57600013
ABNRM    TM    WSWA,X'40'               TEST C FORMAT SWITCH            58000013
         L     DR,OFDR(DR)              RESET SAVE AREA POINTER         58400013
         BO    CFRMT                    BRANCH IF SWITCH SET            58800013
         IHEPRV CFL,BR,OP=LA                                            59200013
         L     LR,4(BR)                 LOAD ADDRESS OF NEXT STATEMENT  59600013
         LM    RB,WR,OFRB(DR)           RESTORE CALLERS REGISTERS       60000013
         BR    LR                       EXIT                            60400013
CFRMT    LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       60800013
         BR    LR                       EXIT                            61200013
BINRY    LA    RA,WSDV                  LOAD SOURCE ADDRESS             61600013
         LA    RB,CDED                  LOAD SOURCE STRING DED          62000013
         LA    RH,PWRK+20               CREATE BIT STRING DOPE VECTOR   62400013
         ST    RH,PWRK+12               IN WORKSPACE WITH ADDRESS OF    62800013
         MVC   PWRK+16(4),WSDV+4        TEMP AND EXTERNAL LENGTH        63200013
         LA    RC,PWRK+12               SET DOPE VECTOR POINTER         63600013
         LA    RD,BDED                  LOAD TARGET DED                 64000013
         L     BR,VSDA                  CALLCHARACTER                   64400013
         BALR  LR,BR                    TO BIT                          64800013
         LA    RA,PWRK+12               SET UP CALL                     65200013
         L     RB,PWRK+8                TO                              65600013
         LM    RC,RD,PWRK               DMA                             66000013
         B     BINRT                    RETURN                          66400013
STRNG    L     BR,DNBA                  SET TO CALL ARITH TO BIT        66800013
         TM    0(RD),CHAR               TEST FOR CHARACTER TARGET       67200013
         BO    CHARY                    YES BRANCH                      67600013
CALEB    BALR  LR,BR                    CALL CONVERSION                 68000013
         B     ENDRT                    RETURN                          68400013
CHARY    LA    RB,CDED                                                  68500015
         LA    RA,WSDV                                                  68600015
         L     BR,VSCA                                                  68700015
         TM    0(RD),PICT                                               68800015
         BO    CALEB                                                    68900015
         L     BR,VSEA                                                  69000015
         B     CALEB                    CHARACTER STRING                69200013
MOVER    MVC   0(0,RC),0(RA)                                            69600013
CDED     DC    X'0C'                                                    70000013
BDED     DC    X'08'                                                    70400013
IODG     DC    V(IHEIODG)                                               70800013
KCCA     DC    A(0)                     FUTURE IHEKCCA                  71200013
KCAA     DC    V(IHEKCAA)                                               71600013
KCBA     DC    V(IHEKCBA)                                               72000013
IODT     DC    V(IHEIODT)                                               72400013
DMAA     DC    V(IHEDMAA)                                               72800013
VSDA     DC    V(IHEVSDA)                                               73200013
DNBA     DC    V(IHEDNBA)                                               73600013
DNCA     DC    V(IHEDNCA)                                               74000013
UPAB     DC    V(IHEUPAB)                                               74400013
UPBB     DC    V(IHEUPBB)                                               74800013
VSCA     DC    V(IHEVSCA)                                               74900015
VSEA     DC    V(IHEVSEA)                                               75000015
PICT     EQU   X'08'                                                    75200013
CHAR     EQU   X'04'                                                    75600013
PWRK     EQU   WORK+72                                                  76000013
ZERO     EQU   0                                                        76400013
CPLX     EQU   X'01'                                                    76800013
MODE     EQU   X'01'                                                    77200013
CODE     EQU   X'08'                                                    77600013
IOBT     EQU   X'80'                                                    78000013
BINY     EQU   X'04'                                                    78400013
STER     EQU   X'20'                                                    78800013
STRG     EQU   X'80'                                                    79200013
         END                                                            79600013
