DIM      TITLE '   IHEDIM    C FORMAT INPUT INPUT DIRECTOR             *00020000
               O/S 360 PL/1 LIBRARY'                                    00040000
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  00060000
*                                                                       00080000
*   STATUS     CHANGE LEVEL - 0                                         00100000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIM000-TSS 00106001
*        ----------------------------------------------------DIM000-TSS 00112001
*                                                                       00120000
*        THIS UPDATE FIXES APAR 40074 - RELEASE SHOWN BY ID#.           00128046
* 012800,*  015200  016000,*  019200  020200,*  041000  045600,*        00136046
*                                                                       00144046
*        SIZE  552 BYTES                                                00152046
*                                                                       00160000
*   FUNCTION   TO DIRECT THE CONVERSION OF EXTERNAL CHARACTER DATA      00180000
*              DESCRIBED BY A 'C' FORMAT ITEM TO ANY INTERNAL DATA TYPE 00200000
*                                                                       00220000
*   ENTRY POINTS                                                        00240000
*              IHEDIMA                                                  00260000
*                   RA = A(TARGET/TARGET DOPE VECTOR)                   00280000
*                   RB = A(TARGET DED)                                  00300000
*                   RC = A(REAL FORMAT INPUT DIRECTOR)                  00320000
*                   RD = A(REAL FED)                                    00340000
*                   RE = A(IMAGINARY FORMAT INPUT DIRECTOR)             00360000
*                   RF = A(IMAGINARY FED)                               00380000
*                                                                       00400000
*   INPUT      N/A                                                      00420000
*                                                                       00440000
*   OUTPUT     N/A                                                      00460000
*                                                                       00480000
*   EXTERNAL MODULES                                                    00500000
*              IHEDIA - F/E FORMAT INPUT DIRECTOR                       00520000
*              IHEDIE - NUMERIC PICTURE INPUT DIRECTOR                  00540000
*              IHEIOD - TO GET ADDRESS OF EXTERNAL DATA.                00560000
*              IHEKCA - TO CHECK DATA AGAINST PICTURE SPEC.             00580000
*              IHEVCA - TO GET BASE,SCALE AND PRECISION OF DATA.        00600000
*              IHEVCS - TO CONVERT EXTERNAL REPRESENTATION OF COMPLEX   00620000
*                       VALVE TO TYPE STRING.                           00640000
*                                                                       00660000
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              00680000
*              ABNORMAL - AFTER ENDFILE CONDITION HAS BEEN RAISED       00700000
*                         CONTROL IS PASSED TO NEXT LANGUAGE STATEMENT  00720000
*                         (POINTED TO BY IHEQCFL)                       00740000
*                                                                       00760000
*   TABLES/WORKAREA                                                     00780000
*              WORKAREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)          00800000
*                                                                       00820000
*   ATTRIBUTES READ ONLY AND REENTRANT                                  00840000
*                                                                       00860000
*   PRIVATE MACROS                                                      00880000
*              IHELIB,IHEPRV,IHESDR                                     00900000
*                                                                       00920000
*   ASSEMBLY REQUIREMENTS                                               00940000
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   00960000
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        00980000
*                                                                       01000000
*   NOTES      SEE O/S360 PL/1 LIBRARY PLM FOR DESCRIPTION OF LIBRARY   01020000
*              CONVENTIONS AND STANDARDS                                01040000
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND ON A        01060000
*              PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL       01080000
*              CHARACTER SET.                                           01100000
         EJECT                                                          01120000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIM001-TSS 01130001
*  THE FOLLOWING MODULES MUST BE INCLUDED IF REQUIRED                   01140000
         PUNCH     ' LIBRARY *(IHEDIAA,IHEDIEA,IHEVCAA,IHEVCSA,IHEKCAA)/01160000
                                    DIM0000A'                           01180000
*        ----------------------------------------------------DIM001-TSS 01190001
         SPACE                                                          01200000
IHEDIM   CSECT                                                          01220000
         IHELIB                                                         01240000
IHEZLW4  DSECT                                                          01260000
         DS    16D                                                      01280046
WORK     EQU   IHEZLW4                                                  01300000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIM002-TSS 01310001
IHEQCFL  DXD   2A                                                       01320000
*        ----------------------------------------------------DIM002-TSS 01330001
IHEDIM   CSECT                                                          01340000
         ENTRY IHEDIMA                                                  01360000
         USING *,RJ                                                     01380000
         USING IHEZLCA,WR                                               01400000
         USING IHEZLW4,DR                                               01420000
IHEDIMA  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          01440000
         IHESDR LW4,WR                  UPDATE SAVE AREA POINTER        01460000
         IHEPRV ,WR                     GOT COMMUNICATION AREA ADDRESS  01480000
         LR    RJ,BR                    TRANSFER BASE ADDRESS           01500000
         LA    LR,RETRY                 STORE RETRY ENTRY POINT AND     01520000
         MVI   SWIT,X'00'              ZERO ALL SWITCHES                01530046
         STM   DR,LR,WCNV               SAVE AREA ADDRESS IN LCA        01540000
AGAIN    STM   RE,RF,PWRK               SAVE IMAG PART PARAMETERS       01560000
         MVI   WSWA,X'40'               INITIALISE C FORMAT SWITCHES    01580000
         NI    SWIT,X'02'              RESET ALL SWTCHS EXC. GET RTN    01600046
         STM   RA,RB,PLIST+16           PUT TARGET PARAMETERS IN LIST   01620000
         LR    RF,RC                    TRANSFER DIRECTOR               01640000
         LR    RG,RD                    AND FED POINTERS                01660000
         LA    RI,2                     SET COUNT                       01680000
         SR    RE,RE                    INITIALISE ACCUMULATOR          01700000
COMPD    ST    RA,DOPV                  SAVE LENGTHS OF REAL PART       01720000
         STH   RA,DOPV                  IN WORKSPACE                    01740000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIM990-TSS 01750000
         C     RF,PMAT                  TEST FORMAT TYPE                01760000
*        ----------------------------------------------------DIM990-TSS 01770000
         BE    GETWD                    BRANCH IF PICTURE FORMAT        01780000
         LH    RA,0(RG)                 GET FIELD WIDTH FROM DED        01800000
UPDAT    AR    RE,RA                    ADD TO TOTAL FIELD WIDTH        01820000
         LM    RF,RG,PWRK               LOAD IMAG PART PARAMETERS       01840000
         BCT   RI,COMPD                 BRANCH IF COUNT NOT ZERO        01860000
         STH   RE,WSDV+6                SET CURRENT LENGTH (W)          01880000
         ST    RA,DOPV+4                STORE LENGTH OF IMAG PART       01900000
         STH   RA,DOPV+4                IN WORKSPACE                    01920000
         TM    SWIT,X'02'              HAS GET RTN BEEN PROCESSED?      01922046
         BO    SKPGET                  YES.                             01924046
         OI    SWIT,X'02'              SET GET ROUTINE SW ON.           01926046
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIM999-TSS 01930000
         L     BR,IODG                  CALL ROUTINE TO GET             01940000
*        ----------------------------------------------------DIM999-TSS 01950000
         BALR  LR,BR                    ADDRESS OF W BYTES              01960000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIM003-TSS 01970021
         LTR   BR,BR                    TEST RETURN CODE                01980000
         BNZ   ABNRM                    BRANCH IF NOT ZERO              02000000
         MVC   WSPACE(8),WSDV          STORE DOPE VECTOR IN CASE        02010046
*                                      OF RETRY.                        02020046
*        ----------------------------------------------------DIM003-TSS 02025021
SKPGET   MVC   WOFD(8),WSDV            SET ON SOURCE DOPE VECTOR.       02030046
         ST    RI,WSDV+4                ZERO FIELD WIDTH                02040000
         LA    RF,STRNG                                                 02060000
         LA    RG,SCOMP                 SET RETURN ADDRESSES            02080000
         LM    RA,RB,PLIST+16           RESTORE TARGET PARAMETERS       02100000
CALFD    TM    0(RB),STRG               TEST TARGET TYPE                02120000
         BCR   8,RF                     BRANCH IF STRING                02140000
         BAL   BR,GBUFF                 GO GET FIELD ADDRESS            02160000
         LR    BR,RC                    LOAD DIRECTOR ADDRESS           02180000
         LR    RC,RD                    SET FED POINTET                 02200000
         BALR  LR,BR                    CALL I/O DIRECTOR               02220000
         LTR   BR,BR                    TEST RETURN CODE                02240000
         BCR   8,RG                     BRANCH IF ZERO                  02260000
ABNRM    MVI   WSWA,ZERO                RESET C FORMAT SWITCHES         02280000
         IHEPRV CFL,BR,OP=LA                                            02300000
         L     LR,4(BR)                 LOAD ADDRESS OF NEXT STATEMENT  02320000
         L     DR,OFDR(DR)              RESET SAVE AREA POINTER         02340000
         LM    RB,WR,OFRB(DR)           RESTORE CALLERS REGISTERS       02360000
         BR    LR                       EXIT                            02380000
SCOMP    TM    0(RB),MODE               TEST MODE OF TARGET             02400000
         BZ    ENDRT                    BRANCH IF REAL                  02420000
         OI    WSWA,COMP                SET COMPLEX FORMAT SWITCH       02440000
         LM    RC,RD,PWRK               RESTORE IMAG PART PARAMETERS    02460000
         L     RA,WRCD                  LOAD UPDATED TARGET ADDRESS     02480000
         BAL   RG,TESFT                 LOOP AND SET RETURN ADDRES      02500000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIM998-TSS 02510000
ENDRT    L     BR,IODT                  TERMINAL CALL                   02520000
*        ----------------------------------------------------DIM998-TSS 02530000
         BALR  LR,BR                    TO FREE ANY VDA                 02540000
         SR    RE,RE                    RESET ERROR CODE                02560000
         IHEPRV ERR,RE,OP=STH                                           02580000
         MVI   WSWA,ZERO                RESET C FORMAT SWITCHES         02600000
         L     DR,OFDR(DR)              RESET SAVE AREA POINTER         02620000
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       02640000
         BR    LR                       RETURN                          02660000
STRNG    SR    RG,RG                    INITIALISE LOOP INDEX           02680000
LOOP1    IHEPRV ERR,RE,OP=LA                                            02700000
         OI    0(RE),IOBT               SET FOR I/O ERROR               02720000
         BAL   BR,GBUFF                 GO GET FIELD ADDRESS            02740000
LOADL    L     LR,WSDV                  LOAD BUFFER ADDRESS             02760000
         ST    LR,WCN1(RG)              STORE IN COMMUNICATION AREA     02780000
         AH    LR,WSDV+6                CALCULATE DATA                  02800000
         BCTR  LR,0                     END ADDRESS                     02820000
         ST    LR,WCN1+4(RG)            STORE IN COMMUNICATION AREA     02840000
         LA    LR,WCN1(RG)              GET START/END POINTER           02860000
         ST    LR,WCNP                  STORE IN COMMUNICATION AREA     02880000
         ST    LR,PLIST(RG)             AND PARAMETER LIST              02900000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIM997-TSS 02910000
         C     RC,PMAT                  TEST FORMAT TYPE                02920000
*        ----------------------------------------------------DIM997-TSS 02930000
         BE    PICRT                    BRANCH IF PICTURED              02940000
         LA    RA,DEDS(RI)              SET DED POINTER                 02960000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIM996-TSS 02970000
         L     BR,VCAA                  CALL ROUTINE TO SCAN DATA TO    02980000
*        ----------------------------------------------------DIM996-TSS 02990000
         BALR  LR,BR                    DETERMINE TYPE AND PRECISION    03000000
         B     STAR4(BR)                TEST RETURN CODE                03020000
STAR4    B     ANYDS                    BRANCH IF RETURN CODE ZERO      03040000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIM995-TSS 03050000
TESTF    C     RD,FMAT                  TEST FORMAT TYPE                03060000
*        ----------------------------------------------------DIM995-TSS 03070000
         BNE   SETDD                    BRANCH IF NOT F FORMAT          03080000
         SR    RF,RF                    GET                             03100000
         LR    RG,RF                    SCALE FACTOR                    03120000
         IC    RF,DEDS+2(RI)            FROM CREATED DED                03140000
         IC    RG,3(RD)                 GET P SPECIFICATION             03160000
         SR    RF,RG                    FROM FED AND COMINE WITH SF.    03180000
         AH    RF,K128                  ADD EXCESS                      03200000
         STC   RF,DEDS+2(RI)            STORE COMBINED SF IN DED        03220000
         LA    RF,FDED                  SET CREATED DED FIXED TO SHOW   03240000
         STC   RF,DEDS(RI)              F FORMAT FOR CHECKING.          03260000
SETDD    LA    RF,DEDS(RI)              GET CREATED DED POINTER         03280000
         ST    RF,PLIST+4(RG)           STORE IN PARAMETER LIST         03300000
         ST    RD,PLIST+24(RI)          SET UP FED POINTER              03320000
TSWTC    TM    SWIT,IMAG                TEST SWITCH                     03340000
         BO    CALVS                    BRANCH IF SET                   03360000
         OI    SWIT,IMAG                SET SWITCH                      03380000
         LM    RC,RD,PWRK               RESTORE IMAG PART PARAMETERS    03400000
         LA    RG,8(RG)                 BUMP INDICES                    03420000
         LA    RI,4(RI)                 FOR PARAMETER LIST AND DEDS     03440000
         LA    RF,LOOP1                 SET BRANCH ADDRESS FOR LOOP     03460000
         B     TESFT                    REPEAT FOR IMAG PART            03480000
ANYDS    SR    RF,RF                    GET D SPECIFICATION             03500000
         IC    RF,2(RD)                 FROM FED                        03520000
         AH    RF,K128                  ADD EXCESS                      03540000
         STC   RF,DEDS+2(RI)            STORE AS SCALE FACTOR IN DED    03560000
         B     TESTF                    GO TEST FORMAT TYPE             03580000
CALVS    LA    RA,PLIST                 SET PARAMETER LIST POINTER      03600000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIM994-TSS 03610000
         L     BR,VCSA                  CALL COMPLEX TO                 03620000
*        ----------------------------------------------------DIM994-TSS 03630000
         BALR  LR,BR                    STRING ROUTINE                  03640000
         B     ENDRT                    GO TO EXIT ROUTINE              03660000
GETWD    SR    RA,RA                    ZERO REGISTER                   03680000
         IC    RA,3(RG)                 INSERT FIELD WIDTH              03700000
         B     UPDAT                                                    03720000
GBUFF    L     LR,WSDV                  SET                             03740000
         AH    LR,WSDV+4                ADDRESSOF FIELD                 03760000
         ST    LR,WSDV                  AND STORE                       03780000
         MVC   WSDV+4(4),DOPV           INSERT FIELD WIDTH              03800000
         MVC   DOPV(4),DOPV+4           SET FOR NEXT FIELD              03820000
         BR    BR                       RETURN                          03840000
PICRT    L     RA,WSDV                  SET SOURCE POINTER              03860000
         LR    RF,RB                    SAVE TARGET DED POINTER         03880000
         LR    RB,RD                    SET SOURCE FED POINTER          03900000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIM993-TSS 03910000
         L     BR,KCAA                  SET FOR DECIMAL PICTURE         03920000
*        ----------------------------------------------------DIM993-TSS 03930000
         TM    0(RB),DECM               TEST PICTURE TYPE               03940000
         BZ    CALLS                    BRANCH IF DECIMAL               03960000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIM992-TSS 03970000
         L     BR,KCCA                  SET FOR BINARY PICTURE          03980000
*        ----------------------------------------------------DIM992-TSS 03990000
CALLS    BALR  LR,BR                    CALL PICTURE CHECK ROUTINE      04000000
         ST    RB,PLIST+4(RG)           STORE DED POINTER IN PLIST      04020000
         LR    RB,RF                    RESTORE TRUE TARGET DED POINTER 04040000
         B     TSWTC                    GO TEST SWITCH.                 04060000
RETRY    L     RA,OFDR(DR)              RESTORE ORIGINAL                04080000
         LM    RA,RF,OFRA(RA)           PARAMETERS                      04100000
         MVC   WSDV(8),WSPACE          RESTORE ORIGINAL D.V.            04110046
         B     AGAIN                    GO TRY AGAIN                    04120000
K128     DC    H'128'                                                   04140000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DIM991-TSS 04150000
FMAT     DC    V(IHEDIAA)                                               04160000
PMAT     DC    V(IHEDIEA)                                               04180000
IODG     DC    V(IHEIODG)                                               04200000
IODT     DC    V(IHEIODT)                                               04220000
VCAA     DC    V(IHEVCAA)                                               04240000
VCSA     DC    V(IHEVCSA)                                               04260000
KCAA     DC    V(IHEKCAA)                                               04280000
KCCA     DC    A(0)                     FUTURE DC V IHEKCCA             04300000
*        ----------------------------------------------------DIM991-TSS 04310000
DECM     EQU   X'04'                                                    04320000
IMAG     EQU   X'01'                                                    04340000
FDED     EQU   X'C8'                                                    04360000
COMP     EQU   X'01'                                                    04380000
CPLX     EQU   X'FE'                                                    04400000
MODE     EQU   X'01'                                                    04420000
ZERO     EQU   X'00'                                                    04440000
STRG     EQU   X'80'                                                    04460000
DOPV     EQU   WORK+72                                                  04480000
DEDS     EQU   DOPV+8                                                   04500000
SWIT     EQU   DEDS+3                                                   04520000
PWRK     EQU   DEDS+8                                                   04540000
WSPACE   EQU   PWRK+8                                                   04550046
PLIST    EQU   WSPACE+8                                                 04560046
TESFT    EQU   CALFD                                                    04580000
IOBT     EQU   X'80'                                                    04600000
         END                                                            04620000
