DMA      TITLE '   IHEDMA    ARITHMETIC CONVERSION DIRECTOR            *00500013
               O/S 360 PL/1 LIBRARY'                                    01000013
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  01500013
*                                                                       02000013
*   STATUS    CHANGE LEVEL 01                                           02100056
*                                                                       02200056
*C720000                                                      MA  47694 02300056
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DMA000-TSS 02600001
*        ----------------------------------------------------DMA000-TSS 02700001
*                                                                       03000013
*   SIZE       248 BYTES                                                03500013
*                                                                       04000013
*   FUNCTION   TO SET UP THE INTERMODULAR FLOW TO EFFECT CONVERSION     04500013
*              FROM ONE ARITHMETIC DATA TYPE TO ANOTHER                 05000013
*                                                                       05500013
*   ENTRY POINTS                                                        06000013
*              IHEDMAA                                                  06500013
*                  RA = A(SOURCE)                                       07000013
*                  RB = A(SOURCE DED)                                   07500013
*                  RC = A(TARGET)                                       08000013
*                  RD = A(TARGET DED)                                   08500013
*                                                                       09000013
*   INPUT      N/A                                                      09500013
*                                                                       10000013
*   OUTPUT     WRB1 - ADDRESS OF 2ND ROUTINE                            10500013
*              WRB2 - ADDRESS OF 3RD ROUTINE                            11000013
*              WRCD - CONTENTS OF RC AND RD                             11500013
*                                                                       12000013
*   EXTERNAL MODULES                                                    12500013
*              IHEVKB                                                   13000013
*              IHEVKC                                                   13500013
*              IHEVPE                                                   14000013
*              IHEVPF                                                   14500013
*              IHEVPG                                                   15000013
*              IHEVPH                                                   15500013
*              IHEVFD                                                   16000013
*              IHEVFE                                                   16500013
*                                                                       17000013
*   EXIT       NORMAL - TRANSFER CONTROL TO ONE OF THE ABOVE MODULES    17500013
*                                                                       18000013
*   TABLES/WORK AREA                                                    18500013
*              WORK AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)         19000013
*                                                                       19500013
*   ATTRIBUTES READ ONLY AND REENTRANT                                  20000013
*                                                                       20500013
*   PRIVATE MACROS                                                      21000013
*              IHELIB,IHEPRV,IHESDR                                     21500013
*                                                                       22000013
*   ASSEMBLY REQUIREMENTS                                               22500013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   23000013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        23500013
*                                                                       24000013
*   NOTES      SEE OS/360 PL/1 LIBRARY PLM FOR DESCRIPTION OF LIBRARY   24500013
*              CONVENTIONS AND STANDARDS                                25000013
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    25500013
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    26000013
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  26500013
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  27000013
*              CONSTANTS,BY REASSEMBLY,WILL RESULT IN A CORRECT MODULE  27500013
*              FOR THE NEW DEFINITIONS.                                 28000013
         EJECT                                                          28500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DMA001-TSS 28700001
*  THE FOLLOWING MODULES MUST BE INCLUDED IF REQUIRED                   29000013
         PUNCH     ' LIBRARY *(IHEVPAA,IHEVPBA,IHEVPCA,IHEVPDA,IHEVPEA,/29500013
               IHEVPFA,IHEVPGA)     DMA0000A'                           30000013
         PUNCH     ' LIBRARY *(IHEVPHA,IHEVFAA,IHEVFBA,IHEVFCA,IHEVFDA,/30500013
               IHEVFEA,IHEVKBA)     DMA0000B'                           31000013
         PUNCH     ' LIBRARY *(IHEVKCA,IHEVKFA,IHEVKGA)                /31500013
                                    DMA0000C'                           32000013
*        ----------------------------------------------------DMA001-TSS 32200001
         SPACE                                                          32500013
IHEDMA   CSECT                                                          33000013
         IHELIB                                                         33500013
IHEZLW0  DSECT                                                          34000013
         DS    15D                                                      34500013
WORK     EQU   IHEZLW0                                                  35000013
IHEDMA   CSECT                                                          35500013
         ENTRY IHEDMAA                                                  36000013
         USING *,BR                                                     36500013
         USING IHEZLCA,WR                                               37000013
         USING IHEZLW0,DR                                               37500013
IHEDMAA  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          38000013
         IHESDR LW0,WR                  UPDATE SAVE AREA POINTER        38500013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  39000013
         STM   RC,RD,WRCD               SAVE TARGET PARAMETERS IN LCA   39500013
DM010    LA    RH,4                  .  SET RH INITIALLY TO 4(D-D).     40000013
         SR    RJ,RJ                                                    40500013
         IC    RJ,0(RD)                 LOAD DED-TARGET FIRST BYTE      41000013
         IC    RJ,XT01(RJ)              GET FUNCTION VALUE FROM TABLE.  41500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DMA999-TSS 41700000
         L     RG,AT01(RJ)              GET ADDR OF TARGET CONVERSION.  42000013
*        ----------------------------------------------------DMA999-TSS 42200000
         CH    RJ,AC01                  IS IT A DECIMAL TARGET..        42500013
         BC    10,DM020                 YES  RH REMAINS AT 4( -D).      43000013
         AR    RH,RH                    NO   RH IS NOW 8( -B).          43500013
DM020    IC    RJ,0(RB)                 LOAD DED-SOURCE FIRST BYTE      44000013
         IC    RJ,XT01(RJ)              GET FUNCTION VALUE FROM TABLE.  44500013
         CH    RJ,AC01                  IS IT A DECIMAL SOURCE..        45000013
         BC    10,DM030                 YES  RH STAYS AT 4(D-D),8(D-B). 45500013
         SH    RH,DM010+2               NO   RH IS NOW 0(B-D),4(B-B).   46000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DMA993-TSS 46200000
DM030    EX    0,DM110(RH)              IF RH=0,8 LOAD RADIX CONVERSION 46500013
*        ----------------------------------------------------DMA993-TSS 46700000
*                                        ROUTINE ADDR,=4 NOP.           47000013
         EX    0,DM120(RH)              IF RH=0,8 STORE RADIX&TARGET    47500013
*                                        ADDRS,=4 STORE TARGET ADDR.    48000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DMA998-TSS 48200000
DM040    L     BR,AT21(RJ)              LOAD SOURCE CONVERSION ADDR.    48500013
*        ----------------------------------------------------DMA998-TSS 48700000
         BCR   15,BR                 X  ENTER SOURCE CONVERSION ROUTINE 49000013
         SPACE 4                                                        49500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DMA997-TSS 49700000
DM110    L     RF,AT11                  +0 LOAD HEX-FLT TO DEC FLT RTNE 50000013
*        ----------------------------------------------------DMA997-TSS 50200000
         BCR   0,0                      +4 NOPR.                        50500013
AC01     DC    AL2(AT02-AT01)           (CONSTANT FOR DEC/BIN TYPE).    51000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DMA996-TSS 51200000
         L     RF,AT12                  +8 LOAD DEC-FLT TO HEX-FLT RTNE 51500013
*        ----------------------------------------------------DMA996-TSS 51700000
         SPACE                                                          52000013
DM120    STM   RF,RG,WBR1               +0, STORE RADIX&TARGET CONV.NS. 52500013
         ST    RG,WBR1                  +4, STORE TARGET CONVERSION.    53000013
         STM   RF,RG,WBR1               +8, STORE RADIX&TARGET CONV.NS. 53500013
         SPACE 2                                                        54000013
*        ADDRESSES OF TARGET CONVERSION ROUTINES.                       54500013
         SPACE                                                          55000013
         DS    0F     FUNCTION CODE.    CONVERSION.                     55500013
         SPACE                                                          56000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DMA995-TSS 56200000
AT01     DC    V(IHEVFBA)               FLI TO FXB                      56500013
         DC    V(IHEVFCA)               FLI TO FLT                      57000013
VKEA     DC    A(0)                     FUTURE DC V IHEVKEA             57500013
*        INTERMEDIATE CONVERSION ROUTINES                               58000013
         SPACE                                                          58500013
AT11     DC    V(IHEVFAA)               FLI TO PDI                      59000013
AT12     DC    V(IHEVPAA)               PDI TO FLI                      59500013
         SPACE                                                          60000013
AT02     DC    V(IHEVKGA)               PDI TO NFS                      60500013
         DC    V(IHEVPDA)               PDI TO PD                       61000013
         DC    V(IHEVKFA)               PDI TO NFD                      61500013
         DC    V(IHEVPBA)               PDI TO F                        62000013
         DC    V(IHEVPCA)               PDI TO E                        62500013
*        ----------------------------------------------------DMA995-TSS 62700000
         SPACE 2                                                        63000013
XT01     EQU   *-124                    BASE ADDRESS OF FUNCTION TABLE  63500013
         SPACE 2                                                        64000013
         ORG   XT01+125                                                 64500013
         SPACE                                                          65000013
         DC    X'0C'                    BIT CONSTANT                    65500013
         DC    X'24'                    E OUTPUT                        66000013
         DC    X'20'                    F OUTPUT                        66500013
         DC    4X'1C'                   NFD                             67000013
         DC    4X'08'                   NFB                             67500013
         DC    2X'18'                   FXD                             68000013
         DC    2X'04'                   FLT                             68500013
         DC    2X'00'                   FXB                             69000013
         DC    2X'04'                   FLT                             69500013
         DS    2C                                                       70000013
         DC    2X'1C'                   NFD                             70500013
         DS    2C                                                       71000013
         DC    2X'08'                   NFB                             71500013
         DC    2X'18'                  FXD                        47694 72000056
         DC    2X'04'                   FLT                             72500013
         DC    2X'00'             FXB                                   73000001
         DC    2X'04'                   FLT                             73500013
         DC    2X'14'                   NFS                             74000013
         SPACE 2                                                        74500013
*              ADDRESSES OF SOURCE CONVERSION ROUTINES.                 75000013
         SPACE                                                          75500013
         DS    0F     FUNCTION CODE.    CONVERSION.                     76000013
         SPACE                                                          76500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DMA994-TSS 76700000
AT21     DC    V(IHEVFDA)               FXB TO FLI                      77000013
         DC    V(IHEVFEA)               FLT TO FLI                      77500013
VKAA     DC    A(0)                     FUTURE DC V IHEVKAA             78000013
         DC    V(IHEVPHA)               BITCON TO FLI                   78500013
         DC    V(IHEVPGA)               BINCON TO FLI                   79000013
         DC    V(IHEVKCA)               NFS TO PDI                      79500013
         DC    V(IHEVPFA)               FXD TO PDI                      80000013
         DC    V(IHEVKBA)               NFD TO PDI                      80500013
         DC    V(IHEVPEA)               F/E TO PDI                      81000013
*        ----------------------------------------------------DMA994-TSS 81200000
         SPACE                                                          81500013
         DS    0F     FUNCTION BYTES (3)                                82000013
         SPACE                                                          82500013
         DC    4X'20'                   F/E INPUT                       83000013
         DC    4X'10'                   BIN CONST                       83500013
         DS    10C                                                      84000013
         DC    2X'20'                   LONG DEC FLT INPUT              84500013
         DS    2C                                                       85000013
         DC    2X'10'                   LONG BIN FLT CON INPUT          85500013
       END                                                              86000013
